compiler/typecheck/TcHsSyn.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The AQUA Project, Glasgow University, 1996-1998
   4 %
   5
   6 TcHsSyn: Specialisations of the @HsSyn@ syntax for the typechecker
   7
   8 This module is an extension of @HsSyn@ syntax, for use in the type
   9 checker.
  10
  11 \begin{code}
  12 module TcHsSyn (
  13         mkHsConApp, mkHsDictLet, mkHsApp,
  14         hsLitType, hsLPatType, hsPatType,
  15         mkHsAppTy, mkSimpleHsAlt,
  16         nlHsIntLit,
  17         shortCutLit, hsOverLitName,
  18
  19         -- re-exported from TcMonad
  20         TcId, TcIdSet, TcDictBinds,
  21
  22         zonkTopDecls, zonkTopExpr, zonkTopLExpr,
  23         zonkId, zonkTopBndrs
  24   ) where
  25
  26 #include "HsVersions.h"
  27
  28 -- friends:
  29 import HsSyn    -- oodles of it
  30
  31 -- others:
  32 import Id
  33
  34 import TcRnMonad
  35 import PrelNames
  36 import TcType
  37 import TcMType
  38 import TysPrim
  39 import TysWiredIn
  40 import DataCon
  41 import Name
  42 import Var
  43 import VarSet
  44 import VarEnv
  45 import Literal
  46 import BasicTypes
  47 import Maybes
  48 import SrcLoc
  49 import Util
  50 import Bag
  51 import Outputable
  52 \end{code}
  53
  54 \begin{code}
  55 -- XXX
  56 thenM :: Monad a => a b -> (b -> a c) -> a c
  57 thenM = (>>=)
  58
  59 thenM_ :: Monad a => a b -> a c -> a c
  60 thenM_ = (>>)
  61
  62 returnM :: Monad m => a -> m a
  63 returnM = return
  64
  65 mappM :: (Monad m) => (a -> m b) -> [a] -> m [b]
  66 mappM = mapM
  67 \end{code}
  68
  69
  70 %************************************************************************
  71 %*                                                                      *
  72 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
  73 %*                                                                      *
  74 %************************************************************************
  75
  76 Note: If @hsLPatType@ doesn't bear a strong resemblance to @exprType@,
  77 then something is wrong.
  78 \begin{code}
  79 hsLPatType :: OutPat Id -> Type
  80 hsLPatType (L _ pat) = hsPatType pat
  81
  82 hsPatType :: Pat Id -> Type
  83 hsPatType (ParPat pat)                = hsLPatType pat
  84 hsPatType (WildPat ty)                = ty
  85 hsPatType (VarPat var)                = idType var
  86 hsPatType (VarPatOut var _)           = idType var
  87 hsPatType (BangPat pat)               = hsLPatType pat
  88 hsPatType (LazyPat pat)               = hsLPatType pat
  89 hsPatType (LitPat lit)                = hsLitType lit
  90 hsPatType (AsPat var _)               = idType (unLoc var)
  91 hsPatType (ViewPat _ _ ty)            = ty
  92 hsPatType (ListPat _ ty)              = mkListTy ty
  93 hsPatType (PArrPat _ ty)              = mkPArrTy ty
  94 hsPatType (TuplePat _ _ ty)           = ty
  95 hsPatType (ConPatOut { pat_ty = ty }) = ty
  96 hsPatType (SigPatOut _ ty)            = ty
  97 hsPatType (NPat lit _ _)              = overLitType lit
  98 hsPatType (NPlusKPat id _ _ _)        = idType (unLoc id)
  99 hsPatType (CoPat _ _ ty)              = ty
 100 hsPatType p                           = pprPanic "hsPatType" (ppr p)
 101
 102 hsLitType :: HsLit -> TcType
 103 hsLitType (HsChar _)       = charTy
 104 hsLitType (HsCharPrim _)   = charPrimTy
 105 hsLitType (HsString _)     = stringTy
 106 hsLitType (HsStringPrim _) = addrPrimTy
 107 hsLitType (HsInt _)        = intTy
 108 hsLitType (HsIntPrim _)    = intPrimTy
 109 hsLitType (HsWordPrim _)   = wordPrimTy
 110 hsLitType (HsInteger _ ty) = ty
 111 hsLitType (HsRat _ ty)     = ty
 112 hsLitType (HsFloatPrim _)  = floatPrimTy
 113 hsLitType (HsDoublePrim _) = doublePrimTy
 114 \end{code}
 115
 116 Overloaded literals. Here mainly becuase it uses isIntTy etc
 117
 118 \begin{code}
 119 shortCutLit :: OverLitVal -> TcType -> Maybe (HsExpr TcId)
 120 shortCutLit (HsIntegral i) ty
 121   | isIntTy ty && inIntRange i   = Just (HsLit (HsInt i))
 122   | isWordTy ty && inWordRange i = Just (mkLit wordDataCon (HsWordPrim i))
 123   | isIntegerTy ty               = Just (HsLit (HsInteger i ty))
 124   | otherwise                    = shortCutLit (HsFractional (fromInteger i)) ty
 125         -- The 'otherwise' case is important
 126         -- Consider (3 :: Float).  Syntactically it looks like an IntLit,
 127         -- so we'll call shortCutIntLit, but of course it's a float
 128         -- This can make a big difference for programs with a lot of
 129         -- literals, compiled without -O
 130
 131 shortCutLit (HsFractional f) ty
 132   | isFloatTy ty  = Just (mkLit floatDataCon  (HsFloatPrim f))
 133   | isDoubleTy ty = Just (mkLit doubleDataCon (HsDoublePrim f))
 134   | otherwise     = Nothing
 135
 136 shortCutLit (HsIsString s) ty
 137   | isStringTy ty = Just (HsLit (HsString s))
 138   | otherwise     = Nothing
 139
 140 mkLit :: DataCon -> HsLit -> HsExpr Id
 141 mkLit con lit = HsApp (nlHsVar (dataConWrapId con)) (nlHsLit lit)
 142
 143 ------------------------------
 144 hsOverLitName :: OverLitVal -> Name
 145 -- Get the canonical 'fromX' name for a particular OverLitVal
 146 hsOverLitName (HsIntegral {})   = fromIntegerName
 147 hsOverLitName (HsFractional {}) = fromRationalName
 148 hsOverLitName (HsIsString {})   = fromStringName
 149 \end{code}
 150
 151 %************************************************************************
 152 %*                                                                      *
 153 \subsection[BackSubst-HsBinds]{Running a substitution over @HsBinds@}
 154 %*                                                                      *
 155 %************************************************************************
 156
 157 \begin{code}
 158 -- zonkId is used *during* typechecking just to zonk the Id's type
 159 zonkId :: TcId -> TcM TcId
 160 zonkId id
 161   = zonkTcType (idType id) `thenM` \ ty' ->
 162     returnM (Id.setIdType id ty')
 163 \end{code}
 164
 165 The rest of the zonking is done *after* typechecking.
 166 The main zonking pass runs over the bindings
 167
 168  a) to convert TcTyVars to TyVars etc, dereferencing any bindings etc
 169  b) convert unbound TcTyVar to Void
 170  c) convert each TcId to an Id by zonking its type
 171
 172 The type variables are converted by binding mutable tyvars to immutable ones
 173 and then zonking as normal.
 174
 175 The Ids are converted by binding them in the normal Tc envt; that
 176 way we maintain sharing; eg an Id is zonked at its binding site and they
 177 all occurrences of that Id point to the common zonked copy
 178
 179 It's all pretty boring stuff, because HsSyn is such a large type, and
 180 the environment manipulation is tiresome.
 181
 182 \begin{code}
 183 data ZonkEnv = ZonkEnv  (TcType -> TcM Type)    -- How to zonk a type
 184                         (IdEnv Id)              -- What variables are in scope
 185         -- Maps an Id to its zonked version; both have the same Name
 186         -- Is only consulted lazily; hence knot-tying
 187
 188 emptyZonkEnv :: ZonkEnv
 189 emptyZonkEnv = ZonkEnv zonkTypeZapping emptyVarEnv
 190
 191 extendZonkEnv :: ZonkEnv -> [Id] -> ZonkEnv
 192 extendZonkEnv (ZonkEnv zonk_ty env) ids
 193   = ZonkEnv zonk_ty (extendVarEnvList env [(id,id) | id <- ids])
 194
 195 extendZonkEnv1 :: ZonkEnv -> Id -> ZonkEnv
 196 extendZonkEnv1 (ZonkEnv zonk_ty env) id
 197   = ZonkEnv zonk_ty (extendVarEnv env id id)
 198
 199 setZonkType :: ZonkEnv -> (TcType -> TcM Type) -> ZonkEnv
 200 setZonkType (ZonkEnv _ env) zonk_ty = ZonkEnv zonk_ty env
 201
 202 zonkEnvIds :: ZonkEnv -> [Id]
 203 zonkEnvIds (ZonkEnv _ env) = varEnvElts env
 204
 205 zonkIdOcc :: ZonkEnv -> TcId -> Id
 206 -- Ids defined in this module should be in the envt;
 207 -- ignore others.  (Actually, data constructors are also
 208 -- not LocalVars, even when locally defined, but that is fine.)
 209 -- (Also foreign-imported things aren't currently in the ZonkEnv;
 210 --  that's ok because they don't need zonking.)
 211 --
 212 -- Actually, Template Haskell works in 'chunks' of declarations, and
 213 -- an earlier chunk won't be in the 'env' that the zonking phase
 214 -- carries around.  Instead it'll be in the tcg_gbl_env, already fully
 215 -- zonked.  There's no point in looking it up there (except for error
 216 -- checking), and it's not conveniently to hand; hence the simple
 217 -- 'orElse' case in the LocalVar branch.
 218 --
 219 -- Even without template splices, in module Main, the checking of
 220 -- 'main' is done as a separate chunk.
 221 zonkIdOcc (ZonkEnv _zonk_ty env) id
 222   | isLocalVar id = lookupVarEnv env id `orElse` id
 223   | otherwise     = id
 224
 225 zonkIdOccs :: ZonkEnv -> [TcId] -> [Id]
 226 zonkIdOccs env ids = map (zonkIdOcc env) ids
 227
 228 -- zonkIdBndr is used *after* typechecking to get the Id's type
 229 -- to its final form.  The TyVarEnv give
 230 zonkIdBndr :: ZonkEnv -> TcId -> TcM Id
 231 zonkIdBndr env id
 232   = zonkTcTypeToType env (idType id)    `thenM` \ ty' ->
 233     returnM (Id.setIdType id ty')
 234
 235 zonkIdBndrs :: ZonkEnv -> [TcId] -> TcM [Id]
 236 zonkIdBndrs env ids = mappM (zonkIdBndr env) ids
 237
 238 zonkDictBndrs :: ZonkEnv -> [Var] -> TcM [Var]
 239 -- "Dictionary" binders can be coercion variables or dictionary variables
 240 zonkDictBndrs env ids = mappM (zonkDictBndr env) ids
 241
 242 zonkDictBndr :: ZonkEnv -> Var -> TcM Var
 243 zonkDictBndr env var | isTyVar var = zonkTyVarBndr env var
 244                      | otherwise   = zonkIdBndr env var
 245
 246 zonkTopBndrs :: [TcId] -> TcM [Id]
 247 zonkTopBndrs ids = zonkIdBndrs emptyZonkEnv ids
 248
 249 -- Zonk the kind of a non-TC tyvar in case it is a coercion variable (their
 250 -- kind contains types).
 251 --
 252 zonkTyVarBndr :: ZonkEnv -> TyVar -> TcM TyVar
 253 zonkTyVarBndr env tv
 254   | isCoVar tv
 255   = do { kind <- zonkTcTypeToType env (tyVarKind tv)
 256        ; return $ setTyVarKind tv kind
 257        }
 258   | otherwise = return tv
 259 \end{code}
 260
 261
 262 \begin{code}
 263 zonkTopExpr :: HsExpr TcId -> TcM (HsExpr Id)
 264 zonkTopExpr e = zonkExpr emptyZonkEnv e
 265
 266 zonkTopLExpr :: LHsExpr TcId -> TcM (LHsExpr Id)
 267 zonkTopLExpr e = zonkLExpr emptyZonkEnv e
 268
 269 zonkTopDecls :: LHsBinds TcId -> [LRuleDecl TcId] -> [LForeignDecl TcId]
 270              -> TcM ([Id],
 271                      Bag (LHsBind  Id),
 272                      [LForeignDecl Id],
 273                      [LRuleDecl    Id])
 274 zonkTopDecls binds rules fords
 275   = do  { (env, binds') <- zonkRecMonoBinds emptyZonkEnv binds
 276                         -- Top level is implicitly recursive
 277         ; rules' <- zonkRules env rules
 278         ; fords' <- zonkForeignExports env fords
 279         ; return (zonkEnvIds env, binds', fords', rules') }
 280
 281 ---------------------------------------------
 282 zonkLocalBinds :: ZonkEnv -> HsLocalBinds TcId -> TcM (ZonkEnv, HsLocalBinds Id)
 283 zonkLocalBinds env EmptyLocalBinds
 284   = return (env, EmptyLocalBinds)
 285
 286 zonkLocalBinds env (HsValBinds binds)
 287   = do  { (env1, new_binds) <- zonkValBinds env binds
 288         ; return (env1, HsValBinds new_binds) }
 289
 290 zonkLocalBinds env (HsIPBinds (IPBinds binds dict_binds))
 291   = mappM (wrapLocM zonk_ip_bind) binds `thenM` \ new_binds ->
 292     let
 293         env1 = extendZonkEnv env [ipNameName n | L _ (IPBind n _) <- new_binds]
 294     in
 295     zonkRecMonoBinds env1 dict_binds    `thenM` \ (env2, new_dict_binds) ->
 296     returnM (env2, HsIPBinds (IPBinds new_binds new_dict_binds))
 297   where
 298     zonk_ip_bind (IPBind n e)
 299         = mapIPNameTc (zonkIdBndr env) n        `thenM` \ n' ->
 300           zonkLExpr env e                       `thenM` \ e' ->
 301           returnM (IPBind n' e')
 302
 303
 304 ---------------------------------------------
 305 zonkValBinds :: ZonkEnv -> HsValBinds TcId -> TcM (ZonkEnv, HsValBinds Id)
 306 zonkValBinds _ (ValBindsIn _ _)
 307   = panic "zonkValBinds" -- Not in typechecker output
 308 zonkValBinds env (ValBindsOut binds sigs)
 309   = do  { (env1, new_binds) <- go env binds
 310         ; return (env1, ValBindsOut new_binds sigs) }
 311   where
 312     go env []         = return (env, [])
 313     go env ((r,b):bs) = do { (env1, b')  <- zonkRecMonoBinds env b
 314                            ; (env2, bs') <- go env1 bs
 315                            ; return (env2, (r,b'):bs') }
 316
 317 ---------------------------------------------
 318 zonkRecMonoBinds :: ZonkEnv -> LHsBinds TcId -> TcM (ZonkEnv, LHsBinds Id)
 319 zonkRecMonoBinds env binds
 320  = fixM (\ ~(_, new_binds) -> do
 321         { let env1 = extendZonkEnv env (collectHsBindBinders new_binds)
 322         ; binds' <- zonkMonoBinds env1 binds
 323         ; return (env1, binds') })
 324
 325 ---------------------------------------------
 326 zonkMonoBinds :: ZonkEnv -> LHsBinds TcId -> TcM (LHsBinds Id)
 327 zonkMonoBinds env binds = mapBagM (wrapLocM (zonk_bind env)) binds
 328
 329 zonk_bind :: ZonkEnv -> HsBind TcId -> TcM (HsBind Id)
 330 zonk_bind env bind@(PatBind { pat_lhs = pat, pat_rhs = grhss, pat_rhs_ty = ty})
 331   = do  { (_env, new_pat) <- zonkPat env pat            -- Env already extended
 332         ; new_grhss <- zonkGRHSs env grhss
 333         ; new_ty    <- zonkTcTypeToType env ty
 334         ; return (bind { pat_lhs = new_pat, pat_rhs = new_grhss, pat_rhs_ty = new_ty }) }
 335
 336 zonk_bind env (VarBind { var_id = var, var_rhs = expr, var_inline = inl })
 337   = zonkIdBndr env var                  `thenM` \ new_var ->
 338     zonkLExpr env expr                  `thenM` \ new_expr ->
 339     returnM (VarBind { var_id = new_var, var_rhs = new_expr, var_inline = inl })
 340
 341 zonk_bind env bind@(FunBind { fun_id = var, fun_matches = ms, fun_co_fn = co_fn })
 342   = wrapLocM (zonkIdBndr env) var       `thenM` \ new_var ->
 343     zonkCoFn env co_fn                  `thenM` \ (env1, new_co_fn) ->
 344     zonkMatchGroup env1 ms              `thenM` \ new_ms ->
 345     returnM (bind { fun_id = new_var, fun_matches = new_ms, fun_co_fn = new_co_fn })
 346
 347 zonk_bind env (AbsBinds { abs_tvs = tyvars, abs_dicts = dicts,
 348                           abs_exports = exports, abs_binds = val_binds })
 349   = ASSERT( all isImmutableTyVar tyvars )
 350     zonkDictBndrs env dicts                     `thenM` \ new_dicts ->
 351     fixM (\ ~(new_val_binds, _) ->
 352         let
 353           env1 = extendZonkEnv env new_dicts
 354           env2 = extendZonkEnv env1 (collectHsBindBinders new_val_binds)
 355         in
 356         zonkMonoBinds env2 val_binds            `thenM` \ new_val_binds ->
 357         mappM (zonkExport env2) exports         `thenM` \ new_exports ->
 358         returnM (new_val_binds, new_exports)
 359     )                                           `thenM` \ (new_val_bind, new_exports) ->
 360     returnM (AbsBinds { abs_tvs = tyvars, abs_dicts = new_dicts,
 361                         abs_exports = new_exports, abs_binds = new_val_bind })
 362   where
 363     zonkExport env (tyvars, global, local, prags)
 364         -- The tyvars are already zonked
 365         = zonkIdBndr env global                 `thenM` \ new_global ->
 366           mapM zonk_prag prags                  `thenM` \ new_prags ->
 367           returnM (tyvars, new_global, zonkIdOcc env local, new_prags)
 368     zonk_prag (L loc (SpecPrag co_fn inl))
 369         = do { (_, co_fn') <- zonkCoFn env co_fn
 370              ; return (L loc (SpecPrag co_fn' inl)) }
 371 \end{code}
 372
 373 %************************************************************************
 374 %*                                                                      *
 375 \subsection[BackSubst-Match-GRHSs]{Match and GRHSs}
 376 %*                                                                      *
 377 %************************************************************************
 378
 379 \begin{code}
 380 zonkMatchGroup :: ZonkEnv -> MatchGroup TcId-> TcM (MatchGroup Id)
 381 zonkMatchGroup env (MatchGroup ms ty)
 382   = do  { ms' <- mapM (zonkMatch env) ms
 383         ; ty' <- zonkTcTypeToType env ty
 384         ; return (MatchGroup ms' ty') }
 385
 386 zonkMatch :: ZonkEnv -> LMatch TcId-> TcM (LMatch Id)
 387 zonkMatch env (L loc (Match pats _ grhss))
 388   = do  { (env1, new_pats) <- zonkPats env pats
 389         ; new_grhss <- zonkGRHSs env1 grhss
 390         ; return (L loc (Match new_pats Nothing new_grhss)) }
 391
 392 -------------------------------------------------------------------------
 393 zonkGRHSs :: ZonkEnv -> GRHSs TcId -> TcM (GRHSs Id)
 394
 395 zonkGRHSs env (GRHSs grhss binds)
 396   = zonkLocalBinds env binds    `thenM` \ (new_env, new_binds) ->
 397     let
 398         zonk_grhs (GRHS guarded rhs)
 399           = zonkStmts new_env guarded   `thenM` \ (env2, new_guarded) ->
 400             zonkLExpr env2 rhs          `thenM` \ new_rhs ->
 401             returnM (GRHS new_guarded new_rhs)
 402     in
 403     mappM (wrapLocM zonk_grhs) grhss    `thenM` \ new_grhss ->
 404     returnM (GRHSs new_grhss new_binds)
 405 \end{code}
 406
 407 %************************************************************************
 408 %*                                                                      *
 409 \subsection[BackSubst-HsExpr]{Running a zonkitution over a TypeCheckedExpr}
 410 %*                                                                      *
 411 %************************************************************************
 412
 413 \begin{code}
 414 zonkLExprs :: ZonkEnv -> [LHsExpr TcId] -> TcM [LHsExpr Id]
 415 zonkLExpr  :: ZonkEnv -> LHsExpr TcId   -> TcM (LHsExpr Id)
 416 zonkExpr   :: ZonkEnv -> HsExpr TcId    -> TcM (HsExpr Id)
 417
 418 zonkLExprs env exprs = mappM (zonkLExpr env) exprs
 419 zonkLExpr  env expr  = wrapLocM (zonkExpr env) expr
 420
 421 zonkExpr env (HsVar id)
 422   = returnM (HsVar (zonkIdOcc env id))
 423
 424 zonkExpr env (HsIPVar id)
 425   = returnM (HsIPVar (mapIPName (zonkIdOcc env) id))
 426
 427 zonkExpr env (HsLit (HsRat f ty))
 428   = zonkTcTypeToType env ty        `thenM` \ new_ty  ->
 429     returnM (HsLit (HsRat f new_ty))
 430
 431 zonkExpr _ (HsLit lit)
 432   = returnM (HsLit lit)
 433
 434 zonkExpr env (HsOverLit lit)
 435   = do  { lit' <- zonkOverLit env lit
 436         ; return (HsOverLit lit') }
 437
 438 zonkExpr env (HsLam matches)
 439   = zonkMatchGroup env matches  `thenM` \ new_matches ->
 440     returnM (HsLam new_matches)
 441
 442 zonkExpr env (HsApp e1 e2)
 443   = zonkLExpr env e1    `thenM` \ new_e1 ->
 444     zonkLExpr env e2    `thenM` \ new_e2 ->
 445     returnM (HsApp new_e1 new_e2)
 446
 447 zonkExpr env (HsBracketOut body bs)
 448   = mappM zonk_b bs     `thenM` \ bs' ->
 449     returnM (HsBracketOut body bs')
 450   where
 451     zonk_b (n,e) = zonkLExpr env e      `thenM` \ e' ->
 452                    returnM (n,e')
 453
 454 zonkExpr _ (HsSpliceE s) = WARN( True, ppr s ) -- Should not happen
 455                              returnM (HsSpliceE s)
 456
 457 zonkExpr env (OpApp e1 op fixity e2)
 458   = zonkLExpr env e1    `thenM` \ new_e1 ->
 459     zonkLExpr env op    `thenM` \ new_op ->
 460     zonkLExpr env e2    `thenM` \ new_e2 ->
 461     returnM (OpApp new_e1 new_op fixity new_e2)
 462
 463 zonkExpr env (NegApp expr op)
 464   = zonkLExpr env expr  `thenM` \ new_expr ->
 465     zonkExpr env op     `thenM` \ new_op ->
 466     returnM (NegApp new_expr new_op)
 467
 468 zonkExpr env (HsPar e)
 469   = zonkLExpr env e     `thenM` \new_e ->
 470     returnM (HsPar new_e)
 471
 472 zonkExpr env (SectionL expr op)
 473   = zonkLExpr env expr  `thenM` \ new_expr ->
 474     zonkLExpr env op            `thenM` \ new_op ->
 475     returnM (SectionL new_expr new_op)
 476
 477 zonkExpr env (SectionR op expr)
 478   = zonkLExpr env op            `thenM` \ new_op ->
 479     zonkLExpr env expr          `thenM` \ new_expr ->
 480     returnM (SectionR new_op new_expr)
 481
 482 zonkExpr env (ExplicitTuple tup_args boxed)
 483   = do { new_tup_args <- mapM zonk_tup_arg tup_args
 484        ; return (ExplicitTuple new_tup_args boxed) }
 485   where
 486     zonk_tup_arg (Present e) = do { e' <- zonkLExpr env e; return (Present e') }
 487     zonk_tup_arg (Missing t) = do { t' <- zonkTcTypeToType env t; return (Missing t') }
 488
 489 zonkExpr env (HsCase expr ms)
 490   = zonkLExpr env expr          `thenM` \ new_expr ->
 491     zonkMatchGroup env ms       `thenM` \ new_ms ->
 492     returnM (HsCase new_expr new_ms)
 493
 494 zonkExpr env (HsIf e1 e2 e3)
 495   = zonkLExpr env e1    `thenM` \ new_e1 ->
 496     zonkLExpr env e2    `thenM` \ new_e2 ->
 497     zonkLExpr env e3    `thenM` \ new_e3 ->
 498     returnM (HsIf new_e1 new_e2 new_e3)
 499
 500 zonkExpr env (HsLet binds expr)
 501   = zonkLocalBinds env binds    `thenM` \ (new_env, new_binds) ->
 502     zonkLExpr new_env expr      `thenM` \ new_expr ->
 503     returnM (HsLet new_binds new_expr)
 504
 505 zonkExpr env (HsDo do_or_lc stmts body ty)
 506   = zonkStmts env stmts         `thenM` \ (new_env, new_stmts) ->
 507     zonkLExpr new_env body      `thenM` \ new_body ->
 508     zonkTcTypeToType env ty     `thenM` \ new_ty   ->
 509     returnM (HsDo (zonkDo env do_or_lc)
 510                   new_stmts new_body new_ty)
 511
 512 zonkExpr env (ExplicitList ty exprs)
 513   = zonkTcTypeToType env ty     `thenM` \ new_ty ->
 514     zonkLExprs env exprs        `thenM` \ new_exprs ->
 515     returnM (ExplicitList new_ty new_exprs)
 516
 517 zonkExpr env (ExplicitPArr ty exprs)
 518   = zonkTcTypeToType env ty     `thenM` \ new_ty ->
 519     zonkLExprs env exprs        `thenM` \ new_exprs ->
 520     returnM (ExplicitPArr new_ty new_exprs)
 521
 522 zonkExpr env (RecordCon data_con con_expr rbinds)
 523   = do  { new_con_expr <- zonkExpr env con_expr
 524         ; new_rbinds   <- zonkRecFields env rbinds
 525         ; return (RecordCon data_con new_con_expr new_rbinds) }
 526
 527 zonkExpr env (RecordUpd expr rbinds cons in_tys out_tys)
 528   = do  { new_expr    <- zonkLExpr env expr
 529         ; new_in_tys  <- mapM (zonkTcTypeToType env) in_tys
 530         ; new_out_tys <- mapM (zonkTcTypeToType env) out_tys
 531         ; new_rbinds  <- zonkRecFields env rbinds
 532         ; return (RecordUpd new_expr new_rbinds cons new_in_tys new_out_tys) }
 533
 534 zonkExpr env (ExprWithTySigOut e ty)
 535   = do { e' <- zonkLExpr env e
 536        ; return (ExprWithTySigOut e' ty) }
 537
 538 zonkExpr _ (ExprWithTySig _ _) = panic "zonkExpr env:ExprWithTySig"
 539
 540 zonkExpr env (ArithSeq expr info)
 541   = zonkExpr env expr           `thenM` \ new_expr ->
 542     zonkArithSeq env info       `thenM` \ new_info ->
 543     returnM (ArithSeq new_expr new_info)
 544
 545 zonkExpr env (PArrSeq expr info)
 546   = zonkExpr env expr           `thenM` \ new_expr ->
 547     zonkArithSeq env info       `thenM` \ new_info ->
 548     returnM (PArrSeq new_expr new_info)
 549
 550 zonkExpr env (HsSCC lbl expr)
 551   = zonkLExpr env expr  `thenM` \ new_expr ->
 552     returnM (HsSCC lbl new_expr)
 553
 554 zonkExpr env (HsTickPragma info expr)
 555   = zonkLExpr env expr  `thenM` \ new_expr ->
 556     returnM (HsTickPragma info new_expr)
 557
 558 -- hdaume: core annotations
 559 zonkExpr env (HsCoreAnn lbl expr)
 560   = zonkLExpr env expr   `thenM` \ new_expr ->
 561     returnM (HsCoreAnn lbl new_expr)
 562
 563 -- arrow notation extensions
 564 zonkExpr env (HsProc pat body)
 565   = do  { (env1, new_pat) <- zonkPat env pat
 566         ; new_body <- zonkCmdTop env1 body
 567         ; return (HsProc new_pat new_body) }
 568
 569 zonkExpr env (HsArrApp e1 e2 ty ho rl)
 570   = zonkLExpr env e1                    `thenM` \ new_e1 ->
 571     zonkLExpr env e2                    `thenM` \ new_e2 ->
 572     zonkTcTypeToType env ty             `thenM` \ new_ty ->
 573     returnM (HsArrApp new_e1 new_e2 new_ty ho rl)
 574
 575 zonkExpr env (HsArrForm op fixity args)
 576   = zonkLExpr env op                    `thenM` \ new_op ->
 577     mappM (zonkCmdTop env) args         `thenM` \ new_args ->
 578     returnM (HsArrForm new_op fixity new_args)
 579
 580 zonkExpr env (HsWrap co_fn expr)
 581   = zonkCoFn env co_fn  `thenM` \ (env1, new_co_fn) ->
 582     zonkExpr env1 expr  `thenM` \ new_expr ->
 583     return (HsWrap new_co_fn new_expr)
 584
 585 zonkExpr _ expr = pprPanic "zonkExpr" (ppr expr)
 586
 587 zonkCmdTop :: ZonkEnv -> LHsCmdTop TcId -> TcM (LHsCmdTop Id)
 588 zonkCmdTop env cmd = wrapLocM (zonk_cmd_top env) cmd
 589
 590 zonk_cmd_top :: ZonkEnv -> HsCmdTop TcId -> TcM (HsCmdTop Id)
 591 zonk_cmd_top env (HsCmdTop cmd stack_tys ty ids)
 592   = zonkLExpr env cmd                   `thenM` \ new_cmd ->
 593     zonkTcTypeToTypes env stack_tys     `thenM` \ new_stack_tys ->
 594     zonkTcTypeToType env ty             `thenM` \ new_ty ->
 595     mapSndM (zonkExpr env) ids          `thenM` \ new_ids ->
 596     returnM (HsCmdTop new_cmd new_stack_tys new_ty new_ids)
 597
 598 -------------------------------------------------------------------------
 599 zonkCoFn :: ZonkEnv -> HsWrapper -> TcM (ZonkEnv, HsWrapper)
 600 zonkCoFn env WpHole   = return (env, WpHole)
 601 zonkCoFn env (WpCompose c1 c2) = do { (env1, c1') <- zonkCoFn env c1
 602                                     ; (env2, c2') <- zonkCoFn env1 c2
 603                                     ; return (env2, WpCompose c1' c2') }
 604 zonkCoFn env (WpCast co)    = do { co' <- zonkTcTypeToType env co
 605                                  ; return (env, WpCast co') }
 606 zonkCoFn env (WpLam id)     = do { id' <- zonkDictBndr env id
 607                                  ; let env1 = extendZonkEnv1 env id'
 608                                  ; return (env1, WpLam id') }
 609 zonkCoFn env (WpTyLam tv)   = ASSERT( isImmutableTyVar tv )
 610                               do { tv' <- zonkTyVarBndr env tv
 611                                  ; return (env, WpTyLam tv') }
 612 zonkCoFn env (WpApp v)
 613         | isTcTyVar v       = do { co <- zonkTcTyVar v
 614                                  ; return (env, WpTyApp co) }
 615                 -- Yuk!  A mutable coercion variable is a TcTyVar
 616                 --       not a CoVar, so don't use isCoVar!
 617                 -- Yuk!  A WpApp can't hold the zonked type,
 618                 --       so we switch to WpTyApp
 619         | otherwise         = return (env, WpApp (zonkIdOcc env v))
 620 zonkCoFn env (WpTyApp ty)   = do { ty' <- zonkTcTypeToType env ty
 621                                  ; return (env, WpTyApp ty') }
 622 zonkCoFn env (WpLet bs)     = do { (env1, bs') <- zonkRecMonoBinds env bs
 623                                  ; return (env1, WpLet bs') }
 624
 625
 626 -------------------------------------------------------------------------
 627 zonkDo :: ZonkEnv -> HsStmtContext Name -> HsStmtContext Name
 628 -- Only used for 'do', so the only Ids are in a MDoExpr table
 629 zonkDo env (MDoExpr tbl) = MDoExpr (mapSnd (zonkIdOcc env) tbl)
 630 zonkDo _   do_or_lc      = do_or_lc
 631
 632 -------------------------------------------------------------------------
 633 zonkOverLit :: ZonkEnv -> HsOverLit TcId -> TcM (HsOverLit Id)
 634 zonkOverLit env lit@(OverLit { ol_witness = e, ol_type = ty })
 635   = do  { ty' <- zonkTcTypeToType env ty
 636         ; e' <- zonkExpr env e
 637         ; return (lit { ol_witness = e', ol_type = ty' }) }
 638
 639 -------------------------------------------------------------------------
 640 zonkArithSeq :: ZonkEnv -> ArithSeqInfo TcId -> TcM (ArithSeqInfo Id)
 641
 642 zonkArithSeq env (From e)
 643   = zonkLExpr env e             `thenM` \ new_e ->
 644     returnM (From new_e)
 645
 646 zonkArithSeq env (FromThen e1 e2)
 647   = zonkLExpr env e1    `thenM` \ new_e1 ->
 648     zonkLExpr env e2    `thenM` \ new_e2 ->
 649     returnM (FromThen new_e1 new_e2)
 650
 651 zonkArithSeq env (FromTo e1 e2)
 652   = zonkLExpr env e1    `thenM` \ new_e1 ->
 653     zonkLExpr env e2    `thenM` \ new_e2 ->
 654     returnM (FromTo new_e1 new_e2)
 655
 656 zonkArithSeq env (FromThenTo e1 e2 e3)
 657   = zonkLExpr env e1    `thenM` \ new_e1 ->
 658     zonkLExpr env e2    `thenM` \ new_e2 ->
 659     zonkLExpr env e3    `thenM` \ new_e3 ->
 660     returnM (FromThenTo new_e1 new_e2 new_e3)
 661
 662
 663 -------------------------------------------------------------------------
 664 zonkStmts :: ZonkEnv -> [LStmt TcId] -> TcM (ZonkEnv, [LStmt Id])
 665 zonkStmts env []     = return (env, [])
 666 zonkStmts env (s:ss) = do { (env1, s')  <- wrapLocSndM (zonkStmt env) s
 667                           ; (env2, ss') <- zonkStmts env1 ss
 668                           ; return (env2, s' : ss') }
 669
 670 zonkStmt :: ZonkEnv -> Stmt TcId -> TcM (ZonkEnv, Stmt Id)
 671 zonkStmt env (ParStmt stmts_w_bndrs)
 672   = mappM zonk_branch stmts_w_bndrs     `thenM` \ new_stmts_w_bndrs ->
 673     let
 674         new_binders = concat (map snd new_stmts_w_bndrs)
 675         env1 = extendZonkEnv env new_binders
 676     in
 677     return (env1, ParStmt new_stmts_w_bndrs)
 678   where
 679     zonk_branch (stmts, bndrs) = zonkStmts env stmts    `thenM` \ (env1, new_stmts) ->
 680                                  returnM (new_stmts, zonkIdOccs env1 bndrs)
 681
 682 zonkStmt env (RecStmt { recS_stmts = segStmts, recS_later_ids = lvs, recS_rec_ids = rvs
 683                       , recS_ret_fn = ret_id, recS_mfix_fn = mfix_id, recS_bind_fn = bind_id
 684                       , recS_rec_rets = rets, recS_dicts = binds })
 685   = do { new_rvs <- zonkIdBndrs env rvs
 686        ; new_lvs <- zonkIdBndrs env lvs
 687        ; new_ret_id  <- zonkExpr env ret_id
 688        ; new_mfix_id <- zonkExpr env mfix_id
 689        ; new_bind_id <- zonkExpr env bind_id
 690        ; let env1 = extendZonkEnv env new_rvs
 691        ; (env2, new_segStmts) <- zonkStmts env1 segStmts
 692         -- Zonk the ret-expressions in an envt that
 693         -- has the polymorphic bindings in the envt
 694        ; new_rets <- mapM (zonkExpr env2) rets
 695        ; let env3 = extendZonkEnv env new_lvs   -- Only the lvs are needed
 696        ; (env4, new_binds) <- zonkRecMonoBinds env3 binds
 697        ; return (env4,
 698                  RecStmt { recS_stmts = new_segStmts, recS_later_ids = new_lvs
 699                          , recS_rec_ids = new_rvs, recS_ret_fn = new_ret_id
 700                          , recS_mfix_fn = new_mfix_id, recS_bind_fn = new_bind_id
 701                          , recS_rec_rets = new_rets, recS_dicts = new_binds }) }
 702
 703 zonkStmt env (ExprStmt expr then_op ty)
 704   = zonkLExpr env expr          `thenM` \ new_expr ->
 705     zonkExpr env then_op        `thenM` \ new_then ->
 706     zonkTcTypeToType env ty     `thenM` \ new_ty ->
 707     returnM (env, ExprStmt new_expr new_then new_ty)
 708
 709 zonkStmt env (TransformStmt (stmts, binders) usingExpr maybeByExpr)
 710   = do { (env', stmts') <- zonkStmts env stmts
 711     ; let binders' = zonkIdOccs env' binders
 712     ; usingExpr' <- zonkLExpr env' usingExpr
 713     ; maybeByExpr' <- zonkMaybeLExpr env' maybeByExpr
 714     ; return (env', TransformStmt (stmts', binders') usingExpr' maybeByExpr') }
 715
 716 zonkStmt env (GroupStmt (stmts, binderMap) groupByClause)
 717   = do { (env', stmts') <- zonkStmts env stmts
 718     ; binderMap' <- mappM (zonkBinderMapEntry env') binderMap
 719     ; groupByClause' <-
 720         case groupByClause of
 721             GroupByNothing usingExpr -> (zonkLExpr env' usingExpr) >>= (return . GroupByNothing)
 722             GroupBySomething eitherUsingExpr byExpr -> do
 723                 eitherUsingExpr' <- mapEitherM (zonkLExpr env') (zonkExpr env') eitherUsingExpr
 724                 byExpr' <- zonkLExpr env' byExpr
 725                 return $ GroupBySomething eitherUsingExpr' byExpr'
 726
 727     ; let env'' = extendZonkEnv env' (map snd binderMap')
 728     ; return (env'', GroupStmt (stmts', binderMap') groupByClause') }
 729   where
 730     mapEitherM f g x = do
 731       case x of
 732         Left a -> f a >>= (return . Left)
 733         Right b -> g b >>= (return . Right)
 734
 735     zonkBinderMapEntry env (oldBinder, newBinder) = do
 736         let oldBinder' = zonkIdOcc env oldBinder
 737         newBinder' <- zonkIdBndr env newBinder
 738         return (oldBinder', newBinder')
 739
 740 zonkStmt env (LetStmt binds)
 741   = zonkLocalBinds env binds    `thenM` \ (env1, new_binds) ->
 742     returnM (env1, LetStmt new_binds)
 743
 744 zonkStmt env (BindStmt pat expr bind_op fail_op)
 745   = do  { new_expr <- zonkLExpr env expr
 746         ; (env1, new_pat) <- zonkPat env pat
 747         ; new_bind <- zonkExpr env bind_op
 748         ; new_fail <- zonkExpr env fail_op
 749         ; return (env1, BindStmt new_pat new_expr new_bind new_fail) }
 750
 751 zonkMaybeLExpr :: ZonkEnv -> Maybe (LHsExpr TcId) -> TcM (Maybe (LHsExpr Id))
 752 zonkMaybeLExpr _   Nothing  = return Nothing
 753 zonkMaybeLExpr env (Just e) = (zonkLExpr env e) >>= (return . Just)
 754
 755
 756 -------------------------------------------------------------------------
 757 zonkRecFields :: ZonkEnv -> HsRecordBinds TcId -> TcM (HsRecordBinds TcId)
 758 zonkRecFields env (HsRecFields flds dd)
 759   = do  { flds' <- mappM zonk_rbind flds
 760         ; return (HsRecFields flds' dd) }
 761   where
 762     zonk_rbind fld
 763       = do { new_id   <- wrapLocM (zonkIdBndr env) (hsRecFieldId fld)
 764            ; new_expr <- zonkLExpr env (hsRecFieldArg fld)
 765            ; return (fld { hsRecFieldId = new_id, hsRecFieldArg = new_expr }) }
 766
 767 -------------------------------------------------------------------------
 768 mapIPNameTc :: (a -> TcM b) -> IPName a -> TcM (IPName b)
 769 mapIPNameTc f (IPName n) = f n  `thenM` \ r -> returnM (IPName r)
 770 \end{code}
 771
 772
 773 %************************************************************************
 774 %*                                                                      *
 775 \subsection[BackSubst-Pats]{Patterns}
 776 %*                                                                      *
 777 %************************************************************************
 778
 779 \begin{code}
 780 zonkPat :: ZonkEnv -> OutPat TcId -> TcM (ZonkEnv, OutPat Id)
 781 -- Extend the environment as we go, because it's possible for one
 782 -- pattern to bind something that is used in another (inside or
 783 -- to the right)
 784 zonkPat env pat = wrapLocSndM (zonk_pat env) pat
 785
 786 zonk_pat :: ZonkEnv -> Pat TcId -> TcM (ZonkEnv, Pat Id)
 787 zonk_pat env (ParPat p)
 788   = do  { (env', p') <- zonkPat env p
 789         ; return (env', ParPat p') }
 790
 791 zonk_pat env (WildPat ty)
 792   = do  { ty' <- zonkTcTypeToType env ty
 793         ; return (env, WildPat ty') }
 794
 795 zonk_pat env (VarPat v)
 796   = do  { v' <- zonkIdBndr env v
 797         ; return (extendZonkEnv1 env v', VarPat v') }
 798
 799 zonk_pat env (VarPatOut v binds)
 800   = do  { v' <- zonkIdBndr env v
 801         ; (env', binds') <- zonkRecMonoBinds (extendZonkEnv1 env v') binds
 802         ; returnM (env', VarPatOut v' binds') }
 803
 804 zonk_pat env (LazyPat pat)
 805   = do  { (env', pat') <- zonkPat env pat
 806         ; return (env',  LazyPat pat') }
 807
 808 zonk_pat env (BangPat pat)
 809   = do  { (env', pat') <- zonkPat env pat
 810         ; return (env',  BangPat pat') }
 811
 812 zonk_pat env (AsPat (L loc v) pat)
 813   = do  { v' <- zonkIdBndr env v
 814         ; (env', pat') <- zonkPat (extendZonkEnv1 env v') pat
 815         ; return (env', AsPat (L loc v') pat') }
 816
 817 zonk_pat env (ViewPat expr pat ty)
 818   = do  { expr' <- zonkLExpr env expr
 819         ; (env', pat') <- zonkPat env pat
 820         ; ty' <- zonkTcTypeToType env ty
 821         ; return (env', ViewPat expr' pat' ty') }
 822
 823 zonk_pat env (ListPat pats ty)
 824   = do  { ty' <- zonkTcTypeToType env ty
 825         ; (env', pats') <- zonkPats env pats
 826         ; return (env', ListPat pats' ty') }
 827
 828 zonk_pat env (PArrPat pats ty)
 829   = do  { ty' <- zonkTcTypeToType env ty
 830         ; (env', pats') <- zonkPats env pats
 831         ; return (env', PArrPat pats' ty') }
 832
 833 zonk_pat env (TuplePat pats boxed ty)
 834   = do  { ty' <- zonkTcTypeToType env ty
 835         ; (env', pats') <- zonkPats env pats
 836         ; return (env', TuplePat pats' boxed ty') }
 837
 838 zonk_pat env p@(ConPatOut { pat_ty = ty, pat_dicts = dicts, pat_binds = binds, pat_args = args })
 839   = ASSERT( all isImmutableTyVar (pat_tvs p) )
 840     do  { new_ty <- zonkTcTypeToType env ty
 841         ; new_dicts <- zonkDictBndrs env dicts
 842         ; let env1 = extendZonkEnv env new_dicts
 843         ; (env2, new_binds) <- zonkRecMonoBinds env1 binds
 844         ; (env', new_args) <- zonkConStuff env2 args
 845         ; returnM (env', p { pat_ty = new_ty, pat_dicts = new_dicts,
 846                              pat_binds = new_binds, pat_args = new_args }) }
 847
 848 zonk_pat env (LitPat lit) = return (env, LitPat lit)
 849
 850 zonk_pat env (SigPatOut pat ty)
 851   = do  { ty' <- zonkTcTypeToType env ty
 852         ; (env', pat') <- zonkPat env pat
 853         ; return (env', SigPatOut pat' ty') }
 854
 855 zonk_pat env (NPat lit mb_neg eq_expr)
 856   = do  { lit' <- zonkOverLit env lit
 857         ; mb_neg' <- case mb_neg of
 858                         Nothing  -> return Nothing
 859                         Just neg -> do { neg' <- zonkExpr env neg
 860                                        ; return (Just neg') }
 861         ; eq_expr' <- zonkExpr env eq_expr
 862         ; return (env, NPat lit' mb_neg' eq_expr') }
 863
 864 zonk_pat env (NPlusKPat (L loc n) lit e1 e2)
 865   = do  { n' <- zonkIdBndr env n
 866         ; lit' <- zonkOverLit env lit
 867         ; e1' <- zonkExpr env e1
 868         ; e2' <- zonkExpr env e2
 869         ; return (extendZonkEnv1 env n', NPlusKPat (L loc n') lit' e1' e2') }
 870
 871 zonk_pat env (CoPat co_fn pat ty)
 872   = do { (env', co_fn') <- zonkCoFn env co_fn
 873        ; (env'', pat') <- zonkPat env' (noLoc pat)
 874        ; ty' <- zonkTcTypeToType env'' ty
 875        ; return (env'', CoPat co_fn' (unLoc pat') ty') }
 876
 877 zonk_pat _ pat = pprPanic "zonk_pat" (ppr pat)
 878
 879 ---------------------------
 880 zonkConStuff :: ZonkEnv
 881              -> HsConDetails (OutPat TcId) (HsRecFields id (OutPat TcId))
 882              -> TcM (ZonkEnv,
 883                      HsConDetails (OutPat Id) (HsRecFields id (OutPat Id)))
 884 zonkConStuff env (PrefixCon pats)
 885   = do  { (env', pats') <- zonkPats env pats
 886         ; return (env', PrefixCon pats') }
 887
 888 zonkConStuff env (InfixCon p1 p2)
 889   = do  { (env1, p1') <- zonkPat env  p1
 890         ; (env', p2') <- zonkPat env1 p2
 891         ; return (env', InfixCon p1' p2') }
 892
 893 zonkConStuff env (RecCon (HsRecFields rpats dd))
 894   = do  { (env', pats') <- zonkPats env (map hsRecFieldArg rpats)
 895         ; let rpats' = zipWith (\rp p' -> rp { hsRecFieldArg = p' }) rpats pats'
 896         ; returnM (env', RecCon (HsRecFields rpats' dd)) }
 897         -- Field selectors have declared types; hence no zonking
 898
 899 ---------------------------
 900 zonkPats :: ZonkEnv -> [OutPat TcId] -> TcM (ZonkEnv, [OutPat Id])
 901 zonkPats env []         = return (env, [])
 902 zonkPats env (pat:pats) = do { (env1, pat') <- zonkPat env pat
 903                      ; (env', pats') <- zonkPats env1 pats
 904                      ; return (env', pat':pats') }
 905 \end{code}
 906
 907 %************************************************************************
 908 %*                                                                      *
 909 \subsection[BackSubst-Foreign]{Foreign exports}
 910 %*                                                                      *
 911 %************************************************************************
 912
 913
 914 \begin{code}
 915 zonkForeignExports :: ZonkEnv -> [LForeignDecl TcId] -> TcM [LForeignDecl Id]
 916 zonkForeignExports env ls = mappM (wrapLocM (zonkForeignExport env)) ls
 917
 918 zonkForeignExport :: ZonkEnv -> ForeignDecl TcId -> TcM (ForeignDecl Id)
 919 zonkForeignExport env (ForeignExport i _hs_ty spec) =
 920    returnM (ForeignExport (fmap (zonkIdOcc env) i) undefined spec)
 921 zonkForeignExport _ for_imp
 922   = returnM for_imp     -- Foreign imports don't need zonking
 923 \end{code}
 924
 925 \begin{code}
 926 zonkRules :: ZonkEnv -> [LRuleDecl TcId] -> TcM [LRuleDecl Id]
 927 zonkRules env rs = mappM (wrapLocM (zonkRule env)) rs
 928
 929 zonkRule :: ZonkEnv -> RuleDecl TcId -> TcM (RuleDecl Id)
 930 zonkRule env (HsRule name act (vars{-::[RuleBndr TcId]-}) lhs fv_lhs rhs fv_rhs)
 931   = mappM zonk_bndr vars                `thenM` \ new_bndrs ->
 932     newMutVar emptyVarSet               `thenM` \ unbound_tv_set ->
 933     let
 934         env_rhs = extendZonkEnv env [id | b <- new_bndrs, let id = unLoc b, isId id]
 935         -- Type variables don't need an envt
 936         -- They are bound through the mutable mechanism
 937
 938         env_lhs = setZonkType env_rhs (zonkTypeCollecting unbound_tv_set)
 939         -- We need to gather the type variables mentioned on the LHS so we can
 940         -- quantify over them.  Example:
 941         --   data T a = C
 942         --
 943         --   foo :: T a -> Int
 944         --   foo C = 1
 945         --
 946         --   {-# RULES "myrule"  foo C = 1 #-}
 947         --
 948         -- After type checking the LHS becomes (foo a (C a))
 949         -- and we do not want to zap the unbound tyvar 'a' to (), because
 950         -- that limits the applicability of the rule.  Instead, we
 951         -- want to quantify over it!
 952         --
 953         -- It's easiest to find the free tyvars here. Attempts to do so earlier
 954         -- are tiresome, because (a) the data type is big and (b) finding the
 955         -- free type vars of an expression is necessarily monadic operation.
 956         --      (consider /\a -> f @ b, where b is side-effected to a)
 957     in
 958     zonkLExpr env_lhs lhs               `thenM` \ new_lhs ->
 959     zonkLExpr env_rhs rhs               `thenM` \ new_rhs ->
 960
 961     readMutVar unbound_tv_set           `thenM` \ unbound_tvs ->
 962     let
 963         final_bndrs :: [Located Var]
 964         final_bndrs = map noLoc (varSetElems unbound_tvs) ++ new_bndrs
 965     in
 966     returnM (HsRule name act (map RuleBndr final_bndrs) new_lhs fv_lhs new_rhs fv_rhs)
 967                 -- I hate this map RuleBndr stuff
 968   where
 969    zonk_bndr (RuleBndr v)
 970         | isId (unLoc v) = wrapLocM (zonkIdBndr env)   v
 971         | otherwise      = ASSERT( isImmutableTyVar (unLoc v) )
 972                            return v
 973    zonk_bndr (RuleBndrSig {}) = panic "zonk_bndr RuleBndrSig"
 974 \end{code}
 975
 976
 977 %************************************************************************
 978 %*                                                                      *
 979 \subsection[BackSubst-Foreign]{Foreign exports}
 980 %*                                                                      *
 981 %************************************************************************
 982
 983 \begin{code}
 984 zonkTcTypeToType :: ZonkEnv -> TcType -> TcM Type
 985 zonkTcTypeToType (ZonkEnv zonk_ty _) ty = zonk_ty ty
 986
 987 zonkTcTypeToTypes :: ZonkEnv -> [TcType] -> TcM [Type]
 988 zonkTcTypeToTypes env tys = mapM (zonkTcTypeToType env) tys
 989
 990 zonkTypeCollecting :: TcRef TyVarSet -> TcType -> TcM Type
 991 -- This variant collects unbound type variables in a mutable variable
 992 zonkTypeCollecting unbound_tv_set
 993   = zonkType zonk_unbound_tyvar
 994   where
 995     zonk_unbound_tyvar tv
 996         = zonkQuantifiedTyVar tv                                `thenM` \ tv' ->
 997           readMutVar unbound_tv_set                             `thenM` \ tv_set ->
 998           writeMutVar unbound_tv_set (extendVarSet tv_set tv')  `thenM_`
 999           return (mkTyVarTy tv')
1000
1001 zonkTypeZapping :: TcType -> TcM Type
1002 -- This variant is used for everything except the LHS of rules
1003 -- It zaps unbound type variables to (), or some other arbitrary type
1004 zonkTypeZapping ty
1005   = zonkType zonk_unbound_tyvar ty
1006   where
1007         -- Zonk a mutable but unbound type variable to an arbitrary type
1008         -- We know it's unbound even though we don't carry an environment,
1009         -- because at the binding site for a type variable we bind the
1010         -- mutable tyvar to a fresh immutable one.  So the mutable store
1011         -- plays the role of an environment.  If we come across a mutable
1012         -- type variable that isn't so bound, it must be completely free.
1013     zonk_unbound_tyvar tv = do { let ty = anyTypeOfKind (tyVarKind tv)
1014                                ; writeMetaTyVar tv ty
1015                                ; return ty }
1016 \end{code}