compiler/typecheck/TcHsSyn.lhs

   1 1%
   2 % (c) The University of Glasgow 2006
   3 % (c) The AQUA Project, Glasgow University, 1996-1998
   4 %
   5
   6 TcHsSyn: Specialisations of the @HsSyn@ syntax for the typechecker
   7
   8 This module is an extension of @HsSyn@ syntax, for use in the type
   9 checker.
  10
  11 \begin{code}
  12 module TcHsSyn (
  13         mkHsConApp, mkHsDictLet, mkHsApp,
  14         hsLitType, hsLPatType, hsPatType,
  15         mkHsAppTy, mkSimpleHsAlt,
  16         nlHsIntLit,
  17         shortCutLit, hsOverLitName,
  18
  19         -- re-exported from TcMonad
  20         TcId, TcIdSet,
  21
  22         zonkTopDecls, zonkTopExpr, zonkTopLExpr,
  23         zonkId, zonkTopBndrs
  24   ) where
  25
  26 #include "HsVersions.h"
  27
  28 -- friends:
  29 import HsSyn    -- oodles of it
  30
  31 -- others:
  32 import Id
  33
  34 import TcRnMonad
  35 import PrelNames
  36 import TcType
  37 import TcMType
  38 import TysPrim
  39 import TysWiredIn
  40 import DataCon
  41 import Name
  42 import NameSet
  43 import Var
  44 import VarSet
  45 import VarEnv
  46 import Literal
  47 import BasicTypes
  48 import Maybes
  49 import SrcLoc
  50 import DynFlags( DynFlag(..) )
  51 import Bag
  52 import FastString
  53 import Outputable
  54 \end{code}
  55
  56 \begin{code}
  57 -- XXX
  58 thenM :: Monad a => a b -> (b -> a c) -> a c
  59 thenM = (>>=)
  60
  61 returnM :: Monad m => a -> m a
  62 returnM = return
  63
  64 mappM :: (Monad m) => (a -> m b) -> [a] -> m [b]
  65 mappM = mapM
  66 \end{code}
  67
  68
  69 %************************************************************************
  70 %*                                                                      *
  71 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
  72 %*                                                                      *
  73 %************************************************************************
  74
  75 Note: If @hsLPatType@ doesn't bear a strong resemblance to @exprType@,
  76 then something is wrong.
  77 \begin{code}
  78 hsLPatType :: OutPat Id -> Type
  79 hsLPatType (L _ pat) = hsPatType pat
  80
  81 hsPatType :: Pat Id -> Type
  82 hsPatType (ParPat pat)                = hsLPatType pat
  83 hsPatType (WildPat ty)                = ty
  84 hsPatType (VarPat var)                = idType var
  85 hsPatType (VarPatOut var _)           = idType var
  86 hsPatType (BangPat pat)               = hsLPatType pat
  87 hsPatType (LazyPat pat)               = hsLPatType pat
  88 hsPatType (LitPat lit)                = hsLitType lit
  89 hsPatType (AsPat var _)               = idType (unLoc var)
  90 hsPatType (ViewPat _ _ ty)            = ty
  91 hsPatType (ListPat _ ty)              = mkListTy ty
  92 hsPatType (PArrPat _ ty)              = mkPArrTy ty
  93 hsPatType (TuplePat _ _ ty)           = ty
  94 hsPatType (ConPatOut { pat_ty = ty }) = ty
  95 hsPatType (SigPatOut _ ty)            = ty
  96 hsPatType (NPat lit _ _)              = overLitType lit
  97 hsPatType (NPlusKPat id _ _ _)        = idType (unLoc id)
  98 hsPatType (CoPat _ _ ty)              = ty
  99 hsPatType p                           = pprPanic "hsPatType" (ppr p)
 100
 101 hsLitType :: HsLit -> TcType
 102 hsLitType (HsChar _)       = charTy
 103 hsLitType (HsCharPrim _)   = charPrimTy
 104 hsLitType (HsString _)     = stringTy
 105 hsLitType (HsStringPrim _) = addrPrimTy
 106 hsLitType (HsInt _)        = intTy
 107 hsLitType (HsIntPrim _)    = intPrimTy
 108 hsLitType (HsWordPrim _)   = wordPrimTy
 109 hsLitType (HsInteger _ ty) = ty
 110 hsLitType (HsRat _ ty)     = ty
 111 hsLitType (HsFloatPrim _)  = floatPrimTy
 112 hsLitType (HsDoublePrim _) = doublePrimTy
 113 \end{code}
 114
 115 Overloaded literals. Here mainly becuase it uses isIntTy etc
 116
 117 \begin{code}
 118 shortCutLit :: OverLitVal -> TcType -> Maybe (HsExpr TcId)
 119 shortCutLit (HsIntegral i) ty
 120   | isIntTy ty && inIntRange i   = Just (HsLit (HsInt i))
 121   | isWordTy ty && inWordRange i = Just (mkLit wordDataCon (HsWordPrim i))
 122   | isIntegerTy ty               = Just (HsLit (HsInteger i ty))
 123   | otherwise                    = shortCutLit (HsFractional (fromInteger i)) ty
 124         -- The 'otherwise' case is important
 125         -- Consider (3 :: Float).  Syntactically it looks like an IntLit,
 126         -- so we'll call shortCutIntLit, but of course it's a float
 127         -- This can make a big difference for programs with a lot of
 128         -- literals, compiled without -O
 129
 130 shortCutLit (HsFractional f) ty
 131   | isFloatTy ty  = Just (mkLit floatDataCon  (HsFloatPrim f))
 132   | isDoubleTy ty = Just (mkLit doubleDataCon (HsDoublePrim f))
 133   | otherwise     = Nothing
 134
 135 shortCutLit (HsIsString s) ty
 136   | isStringTy ty = Just (HsLit (HsString s))
 137   | otherwise     = Nothing
 138
 139 mkLit :: DataCon -> HsLit -> HsExpr Id
 140 mkLit con lit = HsApp (nlHsVar (dataConWrapId con)) (nlHsLit lit)
 141
 142 ------------------------------
 143 hsOverLitName :: OverLitVal -> Name
 144 -- Get the canonical 'fromX' name for a particular OverLitVal
 145 hsOverLitName (HsIntegral {})   = fromIntegerName
 146 hsOverLitName (HsFractional {}) = fromRationalName
 147 hsOverLitName (HsIsString {})   = fromStringName
 148 \end{code}
 149
 150 %************************************************************************
 151 %*                                                                      *
 152 \subsection[BackSubst-HsBinds]{Running a substitution over @HsBinds@}
 153 %*                                                                      *
 154 %************************************************************************
 155
 156 \begin{code}
 157 -- zonkId is used *during* typechecking just to zonk the Id's type
 158 zonkId :: TcId -> TcM TcId
 159 zonkId id
 160   = zonkTcType (idType id) `thenM` \ ty' ->
 161     returnM (Id.setIdType id ty')
 162 \end{code}
 163
 164 The rest of the zonking is done *after* typechecking.
 165 The main zonking pass runs over the bindings
 166
 167  a) to convert TcTyVars to TyVars etc, dereferencing any bindings etc
 168  b) convert unbound TcTyVar to Void
 169  c) convert each TcId to an Id by zonking its type
 170
 171 The type variables are converted by binding mutable tyvars to immutable ones
 172 and then zonking as normal.
 173
 174 The Ids are converted by binding them in the normal Tc envt; that
 175 way we maintain sharing; eg an Id is zonked at its binding site and they
 176 all occurrences of that Id point to the common zonked copy
 177
 178 It's all pretty boring stuff, because HsSyn is such a large type, and
 179 the environment manipulation is tiresome.
 180
 181 \begin{code}
 182 data ZonkEnv = ZonkEnv  (TcType -> TcM Type)    -- How to zonk a type
 183                         (VarEnv Var)            -- What variables are in scope
 184         -- Maps an Id or EvVar to its zonked version; both have the same Name
 185         -- Note that all evidence (coercion variables as well as dictionaries)
 186         --      are kept in the ZonkEnv
 187         -- Only *type* abstraction is done by side effect
 188         -- Is only consulted lazily; hence knot-tying
 189
 190 emptyZonkEnv :: ZonkEnv
 191 emptyZonkEnv = ZonkEnv zonkTypeZapping emptyVarEnv
 192
 193 extendZonkEnv :: ZonkEnv -> [Var] -> ZonkEnv
 194 extendZonkEnv (ZonkEnv zonk_ty env) ids
 195   = ZonkEnv zonk_ty (extendVarEnvList env [(id,id) | id <- ids])
 196
 197 extendZonkEnv1 :: ZonkEnv -> Var -> ZonkEnv
 198 extendZonkEnv1 (ZonkEnv zonk_ty env) id
 199   = ZonkEnv zonk_ty (extendVarEnv env id id)
 200
 201 setZonkType :: ZonkEnv -> (TcType -> TcM Type) -> ZonkEnv
 202 setZonkType (ZonkEnv _ env) zonk_ty = ZonkEnv zonk_ty env
 203
 204 zonkEnvIds :: ZonkEnv -> [Id]
 205 zonkEnvIds (ZonkEnv _ env) = varEnvElts env
 206
 207 zonkIdOcc :: ZonkEnv -> TcId -> Id
 208 -- Ids defined in this module should be in the envt;
 209 -- ignore others.  (Actually, data constructors are also
 210 -- not LocalVars, even when locally defined, but that is fine.)
 211 -- (Also foreign-imported things aren't currently in the ZonkEnv;
 212 --  that's ok because they don't need zonking.)
 213 --
 214 -- Actually, Template Haskell works in 'chunks' of declarations, and
 215 -- an earlier chunk won't be in the 'env' that the zonking phase
 216 -- carries around.  Instead it'll be in the tcg_gbl_env, already fully
 217 -- zonked.  There's no point in looking it up there (except for error
 218 -- checking), and it's not conveniently to hand; hence the simple
 219 -- 'orElse' case in the LocalVar branch.
 220 --
 221 -- Even without template splices, in module Main, the checking of
 222 -- 'main' is done as a separate chunk.
 223 zonkIdOcc (ZonkEnv _zonk_ty env) id
 224   | isLocalVar id = lookupVarEnv env id `orElse` id
 225   | otherwise     = id
 226
 227 zonkIdOccs :: ZonkEnv -> [TcId] -> [Id]
 228 zonkIdOccs env ids = map (zonkIdOcc env) ids
 229
 230 -- zonkIdBndr is used *after* typechecking to get the Id's type
 231 -- to its final form.  The TyVarEnv give
 232 zonkIdBndr :: ZonkEnv -> TcId -> TcM Id
 233 zonkIdBndr env id
 234   = zonkTcTypeToType env (idType id)    `thenM` \ ty' ->
 235     returnM (Id.setIdType id ty')
 236
 237 zonkIdBndrs :: ZonkEnv -> [TcId] -> TcM [Id]
 238 zonkIdBndrs env ids = mappM (zonkIdBndr env) ids
 239
 240 zonkTopBndrs :: [TcId] -> TcM [Id]
 241 zonkTopBndrs ids = zonkIdBndrs emptyZonkEnv ids
 242
 243 zonkEvBndrsX :: ZonkEnv -> [EvVar] -> TcM (ZonkEnv, [Var])
 244 zonkEvBndrsX = mapAccumLM zonkEvBndrX
 245
 246 zonkEvBndrX :: ZonkEnv -> EvVar -> TcM (ZonkEnv, EvVar)
 247 -- Works for dictionaries and coercions
 248 zonkEvBndrX env var
 249   = do { var' <- zonkEvBndr env var
 250        ; return (extendZonkEnv1 env var', var') }
 251
 252 zonkEvBndr :: ZonkEnv -> EvVar -> TcM EvVar
 253 -- Works for dictionaries and coercions
 254 -- Does not extend the ZonkEnv
 255 zonkEvBndr env var
 256   = do { ty' <- zonkTcTypeToType env (varType var)
 257        ; return (setVarType var ty') }
 258
 259 zonkEvVarOcc :: ZonkEnv -> EvVar -> EvVar
 260 zonkEvVarOcc env v = zonkIdOcc env v
 261 \end{code}
 262
 263
 264 \begin{code}
 265 zonkTopExpr :: HsExpr TcId -> TcM (HsExpr Id)
 266 zonkTopExpr e = zonkExpr emptyZonkEnv e
 267
 268 zonkTopLExpr :: LHsExpr TcId -> TcM (LHsExpr Id)
 269 zonkTopLExpr e = zonkLExpr emptyZonkEnv e
 270
 271 zonkTopDecls :: Bag EvBind
 272              -> LHsBinds TcId -> NameSet
 273              -> [LRuleDecl TcId] -> [LForeignDecl TcId]
 274              -> TcM ([Id],
 275                      Bag EvBind,
 276                      Bag (LHsBind  Id),
 277                      [LForeignDecl Id],
 278                      [LRuleDecl    Id])
 279 zonkTopDecls ev_binds binds sig_ns rules fords
 280   = do  { (env1, ev_binds') <- zonkEvBinds emptyZonkEnv ev_binds
 281
 282          -- Warn about missing signatures
 283          -- Do this only when we we have a type to offer
 284         ; warn_missing_sigs <- doptM Opt_WarnMissingSigs
 285         ; let sig_warn | warn_missing_sigs = topSigWarn sig_ns
 286                        | otherwise         = noSigWarn
 287
 288         ; (env2, binds') <- zonkRecMonoBinds env1 sig_warn binds
 289                         -- Top level is implicitly recursive
 290         ; rules' <- zonkRules env2 rules
 291         ; fords' <- zonkForeignExports env2 fords
 292         ; return (zonkEnvIds env2, ev_binds', binds', fords', rules') }
 293
 294 ---------------------------------------------
 295 zonkLocalBinds :: ZonkEnv -> HsLocalBinds TcId -> TcM (ZonkEnv, HsLocalBinds Id)
 296 zonkLocalBinds env EmptyLocalBinds
 297   = return (env, EmptyLocalBinds)
 298
 299 zonkLocalBinds _ (HsValBinds (ValBindsIn {}))
 300   = panic "zonkLocalBinds" -- Not in typechecker output
 301
 302 zonkLocalBinds env (HsValBinds vb@(ValBindsOut binds sigs))
 303   = do  { warn_missing_sigs <- doptM Opt_WarnMissingLocalSigs
 304         ; let sig_warn | not warn_missing_sigs = noSigWarn
 305                        | otherwise             = localSigWarn sig_ns
 306               sig_ns = getTypeSigNames vb
 307         ; (env1, new_binds) <- go env sig_warn binds
 308         ; return (env1, HsValBinds (ValBindsOut new_binds sigs)) }
 309   where
 310     go env _ []
 311       = return (env, [])
 312     go env sig_warn ((r,b):bs)
 313       = do { (env1, b')  <- zonkRecMonoBinds env sig_warn b
 314            ; (env2, bs') <- go env1 sig_warn bs
 315            ; return (env2, (r,b'):bs') }
 316
 317 zonkLocalBinds env (HsIPBinds (IPBinds binds dict_binds))
 318   = mappM (wrapLocM zonk_ip_bind) binds `thenM` \ new_binds ->
 319     let
 320         env1 = extendZonkEnv env [ipNameName n | L _ (IPBind n _) <- new_binds]
 321     in
 322     zonkTcEvBinds env1 dict_binds       `thenM` \ (env2, new_dict_binds) ->
 323     returnM (env2, HsIPBinds (IPBinds new_binds new_dict_binds))
 324   where
 325     zonk_ip_bind (IPBind n e)
 326         = mapIPNameTc (zonkIdBndr env) n        `thenM` \ n' ->
 327           zonkLExpr env e                       `thenM` \ e' ->
 328           returnM (IPBind n' e')
 329
 330 ---------------------------------------------
 331 zonkRecMonoBinds :: ZonkEnv -> SigWarn -> LHsBinds TcId -> TcM (ZonkEnv, LHsBinds Id)
 332 zonkRecMonoBinds env sig_warn binds
 333  = fixM (\ ~(_, new_binds) -> do
 334         { let env1 = extendZonkEnv env (collectHsBindsBinders new_binds)
 335         ; binds' <- zonkMonoBinds env1 sig_warn binds
 336         ; return (env1, binds') })
 337
 338 ---------------------------------------------
 339 type SigWarn = Bool -> [Id] -> TcM ()
 340      -- Missing-signature warning
 341      -- The Bool is True for an AbsBinds, False otherwise
 342
 343 noSigWarn :: SigWarn
 344 noSigWarn _ _ = return ()
 345
 346 topSigWarn :: NameSet -> SigWarn
 347 topSigWarn sig_ns _ ids = mapM_ (topSigWarnId sig_ns) ids
 348
 349 topSigWarnId :: NameSet -> Id -> TcM ()
 350 -- The NameSet is the Ids that *lack* a signature
 351 -- We have to do it this way round because there are
 352 -- lots of top-level bindings that are generated by GHC
 353 -- and that don't have signatures
 354 topSigWarnId sig_ns id
 355   | idName id `elemNameSet` sig_ns = warnMissingSig msg id
 356   | otherwise                      = return ()
 357   where
 358     msg = ptext (sLit "Top-level binding with no type signature:")
 359
 360 localSigWarn :: NameSet -> SigWarn
 361 localSigWarn sig_ns is_abs_bind ids
 362   | not is_abs_bind = return ()
 363   | otherwise       = mapM_ (localSigWarnId sig_ns) ids
 364
 365 localSigWarnId :: NameSet -> Id -> TcM ()
 366 -- NameSet are the Ids that *have* type signatures
 367 localSigWarnId sig_ns id
 368   | not (isSigmaTy (idType id))    = return ()
 369   | idName id `elemNameSet` sig_ns = return ()
 370   | otherwise                      = warnMissingSig msg id
 371   where
 372     msg = ptext (sLit "Polymophic local binding with no type signature:")
 373
 374 warnMissingSig :: SDoc -> Id -> TcM ()
 375 warnMissingSig msg id
 376   = do  { env0 <- tcInitTidyEnv
 377         ; let (env1, tidy_ty) = tidyOpenType env0 (idType id)
 378         ; addWarnTcM (env1, mk_msg tidy_ty) }
 379   where
 380     mk_msg ty = sep [ msg, nest 2 $ pprHsVar (idName id) <+> dcolon <+> ppr ty ]
 381
 382 ---------------------------------------------
 383 zonkMonoBinds :: ZonkEnv -> SigWarn -> LHsBinds TcId -> TcM (LHsBinds Id)
 384 zonkMonoBinds env sig_warn binds = mapBagM (wrapLocM (zonk_bind env sig_warn)) binds
 385
 386 zonk_bind :: ZonkEnv -> SigWarn -> HsBind TcId -> TcM (HsBind Id)
 387 zonk_bind env sig_warn bind@(PatBind { pat_lhs = pat, pat_rhs = grhss, pat_rhs_ty = ty})
 388   = do  { (_env, new_pat) <- zonkPat env pat            -- Env already extended
 389         ; sig_warn False (collectPatBinders new_pat)
 390         ; new_grhss <- zonkGRHSs env grhss
 391         ; new_ty    <- zonkTcTypeToType env ty
 392         ; return (bind { pat_lhs = new_pat, pat_rhs = new_grhss, pat_rhs_ty = new_ty }) }
 393
 394 zonk_bind env sig_warn (VarBind { var_id = var, var_rhs = expr, var_inline = inl })
 395   = do { new_var  <- zonkIdBndr env var
 396        ; sig_warn False [new_var]
 397        ; new_expr <- zonkLExpr env expr
 398        ; return (VarBind { var_id = new_var, var_rhs = new_expr, var_inline = inl }) }
 399
 400 zonk_bind env sig_warn bind@(FunBind { fun_id = L loc var, fun_matches = ms
 401                                      , fun_co_fn = co_fn })
 402   = do { new_var <- zonkIdBndr env var
 403        ; sig_warn False [new_var]
 404        ; (env1, new_co_fn) <- zonkCoFn env co_fn
 405        ; new_ms <- zonkMatchGroup env1 ms
 406        ; return (bind { fun_id = L loc new_var, fun_matches = new_ms
 407                       , fun_co_fn = new_co_fn }) }
 408
 409 zonk_bind env sig_warn (AbsBinds { abs_tvs = tyvars, abs_ev_vars = evs
 410                                  , abs_ev_binds = ev_binds
 411                                  , abs_exports = exports
 412                                  , abs_binds = val_binds })
 413   = ASSERT( all isImmutableTyVar tyvars )
 414     do { (env1, new_evs) <- zonkEvBndrsX env evs
 415        ; (env2, new_ev_binds) <- zonkTcEvBinds env1 ev_binds
 416        ; (new_val_bind, new_exports) <- fixM $ \ ~(new_val_binds, _) ->
 417          do { let env3 = extendZonkEnv env2 (collectHsBindsBinders new_val_binds)
 418             ; new_val_binds <- zonkMonoBinds env3 noSigWarn val_binds
 419             ; new_exports   <- mapM (zonkExport env3) exports
 420             ; return (new_val_binds, new_exports) }
 421        ; sig_warn True [b | (_,b,_,_) <- new_exports]
 422        ; return (AbsBinds { abs_tvs = tyvars, abs_ev_vars = new_evs, abs_ev_binds = new_ev_binds
 423                           , abs_exports = new_exports, abs_binds = new_val_bind }) }
 424   where
 425     zonkExport env (tyvars, global, local, prags)
 426         -- The tyvars are already zonked
 427         = zonkIdBndr env global                 `thenM` \ new_global ->
 428           zonkSpecPrags env prags               `thenM` \ new_prags ->
 429           returnM (tyvars, new_global, zonkIdOcc env local, new_prags)
 430
 431 zonkSpecPrags :: ZonkEnv -> TcSpecPrags -> TcM TcSpecPrags
 432 zonkSpecPrags _   IsDefaultMethod = return IsDefaultMethod
 433 zonkSpecPrags env (SpecPrags ps)  = do { ps' <- mapM zonk_prag ps
 434                                        ; return (SpecPrags ps') }
 435   where
 436     zonk_prag (L loc (SpecPrag co_fn inl))
 437         = do { (_, co_fn') <- zonkCoFn env co_fn
 438              ; return (L loc (SpecPrag co_fn' inl)) }
 439 \end{code}
 440
 441 %************************************************************************
 442 %*                                                                      *
 443 \subsection[BackSubst-Match-GRHSs]{Match and GRHSs}
 444 %*                                                                      *
 445 %************************************************************************
 446
 447 \begin{code}
 448 zonkMatchGroup :: ZonkEnv -> MatchGroup TcId-> TcM (MatchGroup Id)
 449 zonkMatchGroup env (MatchGroup ms ty)
 450   = do  { ms' <- mapM (zonkMatch env) ms
 451         ; ty' <- zonkTcTypeToType env ty
 452         ; return (MatchGroup ms' ty') }
 453
 454 zonkMatch :: ZonkEnv -> LMatch TcId-> TcM (LMatch Id)
 455 zonkMatch env (L loc (Match pats _ grhss))
 456   = do  { (env1, new_pats) <- zonkPats env pats
 457         ; new_grhss <- zonkGRHSs env1 grhss
 458         ; return (L loc (Match new_pats Nothing new_grhss)) }
 459
 460 -------------------------------------------------------------------------
 461 zonkGRHSs :: ZonkEnv -> GRHSs TcId -> TcM (GRHSs Id)
 462
 463 zonkGRHSs env (GRHSs grhss binds)
 464   = zonkLocalBinds env binds    `thenM` \ (new_env, new_binds) ->
 465     let
 466         zonk_grhs (GRHS guarded rhs)
 467           = zonkStmts new_env guarded   `thenM` \ (env2, new_guarded) ->
 468             zonkLExpr env2 rhs          `thenM` \ new_rhs ->
 469             returnM (GRHS new_guarded new_rhs)
 470     in
 471     mappM (wrapLocM zonk_grhs) grhss    `thenM` \ new_grhss ->
 472     returnM (GRHSs new_grhss new_binds)
 473 \end{code}
 474
 475 %************************************************************************
 476 %*                                                                      *
 477 \subsection[BackSubst-HsExpr]{Running a zonkitution over a TypeCheckedExpr}
 478 %*                                                                      *
 479 %************************************************************************
 480
 481 \begin{code}
 482 zonkLExprs :: ZonkEnv -> [LHsExpr TcId] -> TcM [LHsExpr Id]
 483 zonkLExpr  :: ZonkEnv -> LHsExpr TcId   -> TcM (LHsExpr Id)
 484 zonkExpr   :: ZonkEnv -> HsExpr TcId    -> TcM (HsExpr Id)
 485
 486 zonkLExprs env exprs = mappM (zonkLExpr env) exprs
 487 zonkLExpr  env expr  = wrapLocM (zonkExpr env) expr
 488
 489 zonkExpr env (HsVar id)
 490   = returnM (HsVar (zonkIdOcc env id))
 491
 492 zonkExpr env (HsIPVar id)
 493   = returnM (HsIPVar (mapIPName (zonkIdOcc env) id))
 494
 495 zonkExpr env (HsLit (HsRat f ty))
 496   = zonkTcTypeToType env ty        `thenM` \ new_ty  ->
 497     returnM (HsLit (HsRat f new_ty))
 498
 499 zonkExpr _ (HsLit lit)
 500   = returnM (HsLit lit)
 501
 502 zonkExpr env (HsOverLit lit)
 503   = do  { lit' <- zonkOverLit env lit
 504         ; return (HsOverLit lit') }
 505
 506 zonkExpr env (HsLam matches)
 507   = zonkMatchGroup env matches  `thenM` \ new_matches ->
 508     returnM (HsLam new_matches)
 509
 510 zonkExpr env (HsApp e1 e2)
 511   = zonkLExpr env e1    `thenM` \ new_e1 ->
 512     zonkLExpr env e2    `thenM` \ new_e2 ->
 513     returnM (HsApp new_e1 new_e2)
 514
 515 zonkExpr env (HsBracketOut body bs)
 516   = mappM zonk_b bs     `thenM` \ bs' ->
 517     returnM (HsBracketOut body bs')
 518   where
 519     zonk_b (n,e) = zonkLExpr env e      `thenM` \ e' ->
 520                    returnM (n,e')
 521
 522 zonkExpr _ (HsSpliceE s) = WARN( True, ppr s ) -- Should not happen
 523                              returnM (HsSpliceE s)
 524
 525 zonkExpr env (OpApp e1 op fixity e2)
 526   = zonkLExpr env e1    `thenM` \ new_e1 ->
 527     zonkLExpr env op    `thenM` \ new_op ->
 528     zonkLExpr env e2    `thenM` \ new_e2 ->
 529     returnM (OpApp new_e1 new_op fixity new_e2)
 530
 531 zonkExpr env (NegApp expr op)
 532   = zonkLExpr env expr  `thenM` \ new_expr ->
 533     zonkExpr env op     `thenM` \ new_op ->
 534     returnM (NegApp new_expr new_op)
 535
 536 zonkExpr env (HsPar e)
 537   = zonkLExpr env e     `thenM` \new_e ->
 538     returnM (HsPar new_e)
 539
 540 zonkExpr env (SectionL expr op)
 541   = zonkLExpr env expr  `thenM` \ new_expr ->
 542     zonkLExpr env op            `thenM` \ new_op ->
 543     returnM (SectionL new_expr new_op)
 544
 545 zonkExpr env (SectionR op expr)
 546   = zonkLExpr env op            `thenM` \ new_op ->
 547     zonkLExpr env expr          `thenM` \ new_expr ->
 548     returnM (SectionR new_op new_expr)
 549
 550 zonkExpr env (ExplicitTuple tup_args boxed)
 551   = do { new_tup_args <- mapM zonk_tup_arg tup_args
 552        ; return (ExplicitTuple new_tup_args boxed) }
 553   where
 554     zonk_tup_arg (Present e) = do { e' <- zonkLExpr env e; return (Present e') }
 555     zonk_tup_arg (Missing t) = do { t' <- zonkTcTypeToType env t; return (Missing t') }
 556
 557 zonkExpr env (HsCase expr ms)
 558   = zonkLExpr env expr          `thenM` \ new_expr ->
 559     zonkMatchGroup env ms       `thenM` \ new_ms ->
 560     returnM (HsCase new_expr new_ms)
 561
 562 zonkExpr env (HsIf e1 e2 e3)
 563   = zonkLExpr env e1    `thenM` \ new_e1 ->
 564     zonkLExpr env e2    `thenM` \ new_e2 ->
 565     zonkLExpr env e3    `thenM` \ new_e3 ->
 566     returnM (HsIf new_e1 new_e2 new_e3)
 567
 568 zonkExpr env (HsLet binds expr)
 569   = zonkLocalBinds env binds    `thenM` \ (new_env, new_binds) ->
 570     zonkLExpr new_env expr      `thenM` \ new_expr ->
 571     returnM (HsLet new_binds new_expr)
 572
 573 zonkExpr env (HsDo do_or_lc stmts body ty)
 574   = zonkStmts env stmts         `thenM` \ (new_env, new_stmts) ->
 575     zonkLExpr new_env body      `thenM` \ new_body ->
 576     zonkTcTypeToType env ty     `thenM` \ new_ty   ->
 577     zonkDo env do_or_lc         `thenM` \ new_do_or_lc ->
 578     returnM (HsDo new_do_or_lc new_stmts new_body new_ty)
 579
 580 zonkExpr env (ExplicitList ty exprs)
 581   = zonkTcTypeToType env ty     `thenM` \ new_ty ->
 582     zonkLExprs env exprs        `thenM` \ new_exprs ->
 583     returnM (ExplicitList new_ty new_exprs)
 584
 585 zonkExpr env (ExplicitPArr ty exprs)
 586   = zonkTcTypeToType env ty     `thenM` \ new_ty ->
 587     zonkLExprs env exprs        `thenM` \ new_exprs ->
 588     returnM (ExplicitPArr new_ty new_exprs)
 589
 590 zonkExpr env (RecordCon data_con con_expr rbinds)
 591   = do  { new_con_expr <- zonkExpr env con_expr
 592         ; new_rbinds   <- zonkRecFields env rbinds
 593         ; return (RecordCon data_con new_con_expr new_rbinds) }
 594
 595 zonkExpr env (RecordUpd expr rbinds cons in_tys out_tys)
 596   = do  { new_expr    <- zonkLExpr env expr
 597         ; new_in_tys  <- mapM (zonkTcTypeToType env) in_tys
 598         ; new_out_tys <- mapM (zonkTcTypeToType env) out_tys
 599         ; new_rbinds  <- zonkRecFields env rbinds
 600         ; return (RecordUpd new_expr new_rbinds cons new_in_tys new_out_tys) }
 601
 602 zonkExpr env (ExprWithTySigOut e ty)
 603   = do { e' <- zonkLExpr env e
 604        ; return (ExprWithTySigOut e' ty) }
 605
 606 zonkExpr _ (ExprWithTySig _ _) = panic "zonkExpr env:ExprWithTySig"
 607
 608 zonkExpr env (ArithSeq expr info)
 609   = zonkExpr env expr           `thenM` \ new_expr ->
 610     zonkArithSeq env info       `thenM` \ new_info ->
 611     returnM (ArithSeq new_expr new_info)
 612
 613 zonkExpr env (PArrSeq expr info)
 614   = zonkExpr env expr           `thenM` \ new_expr ->
 615     zonkArithSeq env info       `thenM` \ new_info ->
 616     returnM (PArrSeq new_expr new_info)
 617
 618 zonkExpr env (HsSCC lbl expr)
 619   = zonkLExpr env expr  `thenM` \ new_expr ->
 620     returnM (HsSCC lbl new_expr)
 621
 622 zonkExpr env (HsTickPragma info expr)
 623   = zonkLExpr env expr  `thenM` \ new_expr ->
 624     returnM (HsTickPragma info new_expr)
 625
 626 -- hdaume: core annotations
 627 zonkExpr env (HsCoreAnn lbl expr)
 628   = zonkLExpr env expr   `thenM` \ new_expr ->
 629     returnM (HsCoreAnn lbl new_expr)
 630
 631 -- arrow notation extensions
 632 zonkExpr env (HsProc pat body)
 633   = do  { (env1, new_pat) <- zonkPat env pat
 634         ; new_body <- zonkCmdTop env1 body
 635         ; return (HsProc new_pat new_body) }
 636
 637 zonkExpr env (HsArrApp e1 e2 ty ho rl)
 638   = zonkLExpr env e1                    `thenM` \ new_e1 ->
 639     zonkLExpr env e2                    `thenM` \ new_e2 ->
 640     zonkTcTypeToType env ty             `thenM` \ new_ty ->
 641     returnM (HsArrApp new_e1 new_e2 new_ty ho rl)
 642
 643 zonkExpr env (HsArrForm op fixity args)
 644   = zonkLExpr env op                    `thenM` \ new_op ->
 645     mappM (zonkCmdTop env) args         `thenM` \ new_args ->
 646     returnM (HsArrForm new_op fixity new_args)
 647
 648 zonkExpr env (HsWrap co_fn expr)
 649   = zonkCoFn env co_fn  `thenM` \ (env1, new_co_fn) ->
 650     zonkExpr env1 expr  `thenM` \ new_expr ->
 651     return (HsWrap new_co_fn new_expr)
 652
 653 zonkExpr _ expr = pprPanic "zonkExpr" (ppr expr)
 654
 655 zonkCmdTop :: ZonkEnv -> LHsCmdTop TcId -> TcM (LHsCmdTop Id)
 656 zonkCmdTop env cmd = wrapLocM (zonk_cmd_top env) cmd
 657
 658 zonk_cmd_top :: ZonkEnv -> HsCmdTop TcId -> TcM (HsCmdTop Id)
 659 zonk_cmd_top env (HsCmdTop cmd stack_tys ty ids)
 660   = zonkLExpr env cmd                   `thenM` \ new_cmd ->
 661     zonkTcTypeToTypes env stack_tys     `thenM` \ new_stack_tys ->
 662     zonkTcTypeToType env ty             `thenM` \ new_ty ->
 663     mapSndM (zonkExpr env) ids          `thenM` \ new_ids ->
 664     returnM (HsCmdTop new_cmd new_stack_tys new_ty new_ids)
 665
 666 -------------------------------------------------------------------------
 667 zonkCoFn :: ZonkEnv -> HsWrapper -> TcM (ZonkEnv, HsWrapper)
 668 zonkCoFn env WpHole   = return (env, WpHole)
 669 zonkCoFn env (WpCompose c1 c2) = do { (env1, c1') <- zonkCoFn env c1
 670                                     ; (env2, c2') <- zonkCoFn env1 c2
 671                                     ; return (env2, WpCompose c1' c2') }
 672 zonkCoFn env (WpCast co)    = do { co' <- zonkTcTypeToType env co
 673                                  ; return (env, WpCast co') }
 674 zonkCoFn env (WpEvLam ev)   = do { (env', ev') <- zonkEvBndrX env ev
 675                                  ; return (env', WpEvLam ev') }
 676 zonkCoFn env (WpEvApp arg)  = do { arg' <- zonkEvTerm env arg
 677                                  ; return (env, WpEvApp arg') }
 678 zonkCoFn env (WpTyLam tv)   = ASSERT( isImmutableTyVar tv )
 679                               return (env, WpTyLam tv)
 680 zonkCoFn env (WpTyApp ty)   = do { ty' <- zonkTcTypeToType env ty
 681                                  ; return (env, WpTyApp ty') }
 682 zonkCoFn env (WpLet bs)     = do { (env1, bs') <- zonkTcEvBinds env bs
 683                                  ; return (env1, WpLet bs') }
 684
 685 -------------------------------------------------------------------------
 686 zonkDo :: ZonkEnv -> HsStmtContext Name -> TcM (HsStmtContext Name)
 687 -- Only used for 'do', so the only Ids are in a MDoExpr table
 688 zonkDo env (MDoExpr tbl) = do { tbl' <- mapSndM (zonkExpr env) tbl
 689                               ; return (MDoExpr tbl') }
 690 zonkDo _   do_or_lc      = return do_or_lc
 691
 692 -------------------------------------------------------------------------
 693 zonkOverLit :: ZonkEnv -> HsOverLit TcId -> TcM (HsOverLit Id)
 694 zonkOverLit env lit@(OverLit { ol_witness = e, ol_type = ty })
 695   = do  { ty' <- zonkTcTypeToType env ty
 696         ; e' <- zonkExpr env e
 697         ; return (lit { ol_witness = e', ol_type = ty' }) }
 698
 699 -------------------------------------------------------------------------
 700 zonkArithSeq :: ZonkEnv -> ArithSeqInfo TcId -> TcM (ArithSeqInfo Id)
 701
 702 zonkArithSeq env (From e)
 703   = zonkLExpr env e             `thenM` \ new_e ->
 704     returnM (From new_e)
 705
 706 zonkArithSeq env (FromThen e1 e2)
 707   = zonkLExpr env e1    `thenM` \ new_e1 ->
 708     zonkLExpr env e2    `thenM` \ new_e2 ->
 709     returnM (FromThen new_e1 new_e2)
 710
 711 zonkArithSeq env (FromTo e1 e2)
 712   = zonkLExpr env e1    `thenM` \ new_e1 ->
 713     zonkLExpr env e2    `thenM` \ new_e2 ->
 714     returnM (FromTo new_e1 new_e2)
 715
 716 zonkArithSeq env (FromThenTo e1 e2 e3)
 717   = zonkLExpr env e1    `thenM` \ new_e1 ->
 718     zonkLExpr env e2    `thenM` \ new_e2 ->
 719     zonkLExpr env e3    `thenM` \ new_e3 ->
 720     returnM (FromThenTo new_e1 new_e2 new_e3)
 721
 722
 723 -------------------------------------------------------------------------
 724 zonkStmts :: ZonkEnv -> [LStmt TcId] -> TcM (ZonkEnv, [LStmt Id])
 725 zonkStmts env []     = return (env, [])
 726 zonkStmts env (s:ss) = do { (env1, s')  <- wrapLocSndM (zonkStmt env) s
 727                           ; (env2, ss') <- zonkStmts env1 ss
 728                           ; return (env2, s' : ss') }
 729
 730 zonkStmt :: ZonkEnv -> Stmt TcId -> TcM (ZonkEnv, Stmt Id)
 731 zonkStmt env (ParStmt stmts_w_bndrs)
 732   = mappM zonk_branch stmts_w_bndrs     `thenM` \ new_stmts_w_bndrs ->
 733     let
 734         new_binders = concat (map snd new_stmts_w_bndrs)
 735         env1 = extendZonkEnv env new_binders
 736     in
 737     return (env1, ParStmt new_stmts_w_bndrs)
 738   where
 739     zonk_branch (stmts, bndrs) = zonkStmts env stmts    `thenM` \ (env1, new_stmts) ->
 740                                  returnM (new_stmts, zonkIdOccs env1 bndrs)
 741
 742 zonkStmt env (RecStmt { recS_stmts = segStmts, recS_later_ids = lvs, recS_rec_ids = rvs
 743                       , recS_ret_fn = ret_id, recS_mfix_fn = mfix_id, recS_bind_fn = bind_id
 744                       , recS_rec_rets = rets, recS_dicts = binds })
 745   = do { new_rvs <- zonkIdBndrs env rvs
 746        ; new_lvs <- zonkIdBndrs env lvs
 747        ; new_ret_id  <- zonkExpr env ret_id
 748        ; new_mfix_id <- zonkExpr env mfix_id
 749        ; new_bind_id <- zonkExpr env bind_id
 750        ; let env1 = extendZonkEnv env new_rvs
 751        ; (env2, new_segStmts) <- zonkStmts env1 segStmts
 752         -- Zonk the ret-expressions in an envt that
 753         -- has the polymorphic bindings in the envt
 754        ; new_rets <- mapM (zonkExpr env2) rets
 755        ; let env3 = extendZonkEnv env new_lvs   -- Only the lvs are needed
 756        ; (env4, new_binds) <- zonkTcEvBinds env3 binds
 757        ; return (env4,
 758                  RecStmt { recS_stmts = new_segStmts, recS_later_ids = new_lvs
 759                          , recS_rec_ids = new_rvs, recS_ret_fn = new_ret_id
 760                          , recS_mfix_fn = new_mfix_id, recS_bind_fn = new_bind_id
 761                          , recS_rec_rets = new_rets, recS_dicts = new_binds }) }
 762
 763 zonkStmt env (ExprStmt expr then_op ty)
 764   = zonkLExpr env expr          `thenM` \ new_expr ->
 765     zonkExpr env then_op        `thenM` \ new_then ->
 766     zonkTcTypeToType env ty     `thenM` \ new_ty ->
 767     returnM (env, ExprStmt new_expr new_then new_ty)
 768
 769 zonkStmt env (TransformStmt stmts binders usingExpr maybeByExpr)
 770   = do { (env', stmts') <- zonkStmts env stmts
 771     ; let binders' = zonkIdOccs env' binders
 772     ; usingExpr' <- zonkLExpr env' usingExpr
 773     ; maybeByExpr' <- zonkMaybeLExpr env' maybeByExpr
 774     ; return (env', TransformStmt stmts' binders' usingExpr' maybeByExpr') }
 775
 776 zonkStmt env (GroupStmt stmts binderMap by using)
 777   = do { (env', stmts') <- zonkStmts env stmts
 778     ; binderMap' <- mappM (zonkBinderMapEntry env') binderMap
 779     ; by' <- fmapMaybeM (zonkLExpr env') by
 780     ; using' <- fmapEitherM (zonkLExpr env) (zonkExpr env) using
 781     ; let env'' = extendZonkEnv env' (map snd binderMap')
 782     ; return (env'', GroupStmt stmts' binderMap' by' using') }
 783   where
 784     zonkBinderMapEntry env (oldBinder, newBinder) = do
 785         let oldBinder' = zonkIdOcc env oldBinder
 786         newBinder' <- zonkIdBndr env newBinder
 787         return (oldBinder', newBinder')
 788
 789 zonkStmt env (LetStmt binds)
 790   = zonkLocalBinds env binds    `thenM` \ (env1, new_binds) ->
 791     returnM (env1, LetStmt new_binds)
 792
 793 zonkStmt env (BindStmt pat expr bind_op fail_op)
 794   = do  { new_expr <- zonkLExpr env expr
 795         ; (env1, new_pat) <- zonkPat env pat
 796         ; new_bind <- zonkExpr env bind_op
 797         ; new_fail <- zonkExpr env fail_op
 798         ; return (env1, BindStmt new_pat new_expr new_bind new_fail) }
 799
 800 zonkMaybeLExpr :: ZonkEnv -> Maybe (LHsExpr TcId) -> TcM (Maybe (LHsExpr Id))
 801 zonkMaybeLExpr _   Nothing  = return Nothing
 802 zonkMaybeLExpr env (Just e) = (zonkLExpr env e) >>= (return . Just)
 803
 804
 805 -------------------------------------------------------------------------
 806 zonkRecFields :: ZonkEnv -> HsRecordBinds TcId -> TcM (HsRecordBinds TcId)
 807 zonkRecFields env (HsRecFields flds dd)
 808   = do  { flds' <- mappM zonk_rbind flds
 809         ; return (HsRecFields flds' dd) }
 810   where
 811     zonk_rbind fld
 812       = do { new_id   <- wrapLocM (zonkIdBndr env) (hsRecFieldId fld)
 813            ; new_expr <- zonkLExpr env (hsRecFieldArg fld)
 814            ; return (fld { hsRecFieldId = new_id, hsRecFieldArg = new_expr }) }
 815
 816 -------------------------------------------------------------------------
 817 mapIPNameTc :: (a -> TcM b) -> IPName a -> TcM (IPName b)
 818 mapIPNameTc f (IPName n) = f n  `thenM` \ r -> returnM (IPName r)
 819 \end{code}
 820
 821
 822 %************************************************************************
 823 %*                                                                      *
 824 \subsection[BackSubst-Pats]{Patterns}
 825 %*                                                                      *
 826 %************************************************************************
 827
 828 \begin{code}
 829 zonkPat :: ZonkEnv -> OutPat TcId -> TcM (ZonkEnv, OutPat Id)
 830 -- Extend the environment as we go, because it's possible for one
 831 -- pattern to bind something that is used in another (inside or
 832 -- to the right)
 833 zonkPat env pat = wrapLocSndM (zonk_pat env) pat
 834
 835 zonk_pat :: ZonkEnv -> Pat TcId -> TcM (ZonkEnv, Pat Id)
 836 zonk_pat env (ParPat p)
 837   = do  { (env', p') <- zonkPat env p
 838         ; return (env', ParPat p') }
 839
 840 zonk_pat env (WildPat ty)
 841   = do  { ty' <- zonkTcTypeToType env ty
 842         ; return (env, WildPat ty') }
 843
 844 zonk_pat env (VarPat v)
 845   = do  { v' <- zonkIdBndr env v
 846         ; return (extendZonkEnv1 env v', VarPat v') }
 847
 848 zonk_pat env (VarPatOut v binds)
 849   = do  { v' <- zonkIdBndr env v
 850         ; (env', binds') <- zonkTcEvBinds (extendZonkEnv1 env v') binds
 851         ; returnM (env', VarPatOut v' binds') }
 852
 853 zonk_pat env (LazyPat pat)
 854   = do  { (env', pat') <- zonkPat env pat
 855         ; return (env',  LazyPat pat') }
 856
 857 zonk_pat env (BangPat pat)
 858   = do  { (env', pat') <- zonkPat env pat
 859         ; return (env',  BangPat pat') }
 860
 861 zonk_pat env (AsPat (L loc v) pat)
 862   = do  { v' <- zonkIdBndr env v
 863         ; (env', pat') <- zonkPat (extendZonkEnv1 env v') pat
 864         ; return (env', AsPat (L loc v') pat') }
 865
 866 zonk_pat env (ViewPat expr pat ty)
 867   = do  { expr' <- zonkLExpr env expr
 868         ; (env', pat') <- zonkPat env pat
 869         ; ty' <- zonkTcTypeToType env ty
 870         ; return (env', ViewPat expr' pat' ty') }
 871
 872 zonk_pat env (ListPat pats ty)
 873   = do  { ty' <- zonkTcTypeToType env ty
 874         ; (env', pats') <- zonkPats env pats
 875         ; return (env', ListPat pats' ty') }
 876
 877 zonk_pat env (PArrPat pats ty)
 878   = do  { ty' <- zonkTcTypeToType env ty
 879         ; (env', pats') <- zonkPats env pats
 880         ; return (env', PArrPat pats' ty') }
 881
 882 zonk_pat env (TuplePat pats boxed ty)
 883   = do  { ty' <- zonkTcTypeToType env ty
 884         ; (env', pats') <- zonkPats env pats
 885         ; return (env', TuplePat pats' boxed ty') }
 886
 887 zonk_pat env p@(ConPatOut { pat_ty = ty, pat_dicts = evs, pat_binds = binds, pat_args = args })
 888   = ASSERT( all isImmutableTyVar (pat_tvs p) )
 889     do  { new_ty <- zonkTcTypeToType env ty
 890         ; (env1, new_evs) <- zonkEvBndrsX env evs
 891         ; (env2, new_binds) <- zonkTcEvBinds env1 binds
 892         ; (env', new_args) <- zonkConStuff env2 args
 893         ; returnM (env', p { pat_ty = new_ty, pat_dicts = new_evs,
 894                              pat_binds = new_binds, pat_args = new_args }) }
 895
 896 zonk_pat env (LitPat lit) = return (env, LitPat lit)
 897
 898 zonk_pat env (SigPatOut pat ty)
 899   = do  { ty' <- zonkTcTypeToType env ty
 900         ; (env', pat') <- zonkPat env pat
 901         ; return (env', SigPatOut pat' ty') }
 902
 903 zonk_pat env (NPat lit mb_neg eq_expr)
 904   = do  { lit' <- zonkOverLit env lit
 905         ; mb_neg' <- case mb_neg of
 906                         Nothing  -> return Nothing
 907                         Just neg -> do { neg' <- zonkExpr env neg
 908                                        ; return (Just neg') }
 909         ; eq_expr' <- zonkExpr env eq_expr
 910         ; return (env, NPat lit' mb_neg' eq_expr') }
 911
 912 zonk_pat env (NPlusKPat (L loc n) lit e1 e2)
 913   = do  { n' <- zonkIdBndr env n
 914         ; lit' <- zonkOverLit env lit
 915         ; e1' <- zonkExpr env e1
 916         ; e2' <- zonkExpr env e2
 917         ; return (extendZonkEnv1 env n', NPlusKPat (L loc n') lit' e1' e2') }
 918
 919 zonk_pat env (CoPat co_fn pat ty)
 920   = do { (env', co_fn') <- zonkCoFn env co_fn
 921        ; (env'', pat') <- zonkPat env' (noLoc pat)
 922        ; ty' <- zonkTcTypeToType env'' ty
 923        ; return (env'', CoPat co_fn' (unLoc pat') ty') }
 924
 925 zonk_pat _ pat = pprPanic "zonk_pat" (ppr pat)
 926
 927 ---------------------------
 928 zonkConStuff :: ZonkEnv
 929              -> HsConDetails (OutPat TcId) (HsRecFields id (OutPat TcId))
 930              -> TcM (ZonkEnv,
 931                      HsConDetails (OutPat Id) (HsRecFields id (OutPat Id)))
 932 zonkConStuff env (PrefixCon pats)
 933   = do  { (env', pats') <- zonkPats env pats
 934         ; return (env', PrefixCon pats') }
 935
 936 zonkConStuff env (InfixCon p1 p2)
 937   = do  { (env1, p1') <- zonkPat env  p1
 938         ; (env', p2') <- zonkPat env1 p2
 939         ; return (env', InfixCon p1' p2') }
 940
 941 zonkConStuff env (RecCon (HsRecFields rpats dd))
 942   = do  { (env', pats') <- zonkPats env (map hsRecFieldArg rpats)
 943         ; let rpats' = zipWith (\rp p' -> rp { hsRecFieldArg = p' }) rpats pats'
 944         ; returnM (env', RecCon (HsRecFields rpats' dd)) }
 945         -- Field selectors have declared types; hence no zonking
 946
 947 ---------------------------
 948 zonkPats :: ZonkEnv -> [OutPat TcId] -> TcM (ZonkEnv, [OutPat Id])
 949 zonkPats env []         = return (env, [])
 950 zonkPats env (pat:pats) = do { (env1, pat') <- zonkPat env pat
 951                      ; (env', pats') <- zonkPats env1 pats
 952                      ; return (env', pat':pats') }
 953 \end{code}
 954
 955 %************************************************************************
 956 %*                                                                      *
 957 \subsection[BackSubst-Foreign]{Foreign exports}
 958 %*                                                                      *
 959 %************************************************************************
 960
 961
 962 \begin{code}
 963 zonkForeignExports :: ZonkEnv -> [LForeignDecl TcId] -> TcM [LForeignDecl Id]
 964 zonkForeignExports env ls = mappM (wrapLocM (zonkForeignExport env)) ls
 965
 966 zonkForeignExport :: ZonkEnv -> ForeignDecl TcId -> TcM (ForeignDecl Id)
 967 zonkForeignExport env (ForeignExport i _hs_ty spec) =
 968    returnM (ForeignExport (fmap (zonkIdOcc env) i) undefined spec)
 969 zonkForeignExport _ for_imp
 970   = returnM for_imp     -- Foreign imports don't need zonking
 971 \end{code}
 972
 973 \begin{code}
 974 zonkRules :: ZonkEnv -> [LRuleDecl TcId] -> TcM [LRuleDecl Id]
 975 zonkRules env rs = mappM (wrapLocM (zonkRule env)) rs
 976
 977 zonkRule :: ZonkEnv -> RuleDecl TcId -> TcM (RuleDecl Id)
 978 zonkRule env (HsRule name act (vars{-::[RuleBndr TcId]-}) lhs fv_lhs rhs fv_rhs)
 979   = do { (env_rhs, new_bndrs) <- mapAccumLM zonk_bndr env vars
 980
 981        ; unbound_tv_set <- newMutVar emptyVarSet
 982        ; let env_lhs = setZonkType env_rhs (zonkTypeCollecting unbound_tv_set)
 983         -- We need to gather the type variables mentioned on the LHS so we can
 984         -- quantify over them.  Example:
 985         --   data T a = C
 986         --
 987         --   foo :: T a -> Int
 988         --   foo C = 1
 989         --
 990         --   {-# RULES "myrule"  foo C = 1 #-}
 991         --
 992         -- After type checking the LHS becomes (foo a (C a))
 993         -- and we do not want to zap the unbound tyvar 'a' to (), because
 994         -- that limits the applicability of the rule.  Instead, we
 995         -- want to quantify over it!
 996         --
 997         -- It's easiest to find the free tyvars here. Attempts to do so earlier
 998         -- are tiresome, because (a) the data type is big and (b) finding the
 999         -- free type vars of an expression is necessarily monadic operation.
1000         --      (consider /\a -> f @ b, where b is side-effected to a)
1001
1002        ; new_lhs <- zonkLExpr env_lhs lhs
1003        ; new_rhs <- zonkLExpr env_rhs rhs
1004
1005        ; unbound_tvs <- readMutVar unbound_tv_set
1006        ; let final_bndrs :: [RuleBndr Var]
1007              final_bndrs = map (RuleBndr . noLoc) (varSetElems unbound_tvs) ++ new_bndrs
1008
1009        ; return (HsRule name act final_bndrs new_lhs fv_lhs new_rhs fv_rhs) }
1010   where
1011    zonk_bndr env (RuleBndr (L loc v))
1012       = do { (env', v') <- zonk_it env v; return (env', RuleBndr (L loc v')) }
1013    zonk_bndr _ (RuleBndrSig {}) = panic "zonk_bndr RuleBndrSig"
1014
1015    zonk_it env v
1016      | isId v     = do { v' <- zonkIdBndr env v; return (extendZonkEnv1 env v', v') }
1017      | isCoVar v  = do { v' <- zonkEvBndr env v; return (extendZonkEnv1 env v', v') }
1018      | otherwise  = ASSERT( isImmutableTyVar v) return (env, v)
1019 \end{code}
1020
1021
1022 %************************************************************************
1023 %*                                                                      *
1024               Constraints and evidence
1025 %*                                                                      *
1026 %************************************************************************
1027
1028 \begin{code}
1029 zonkEvTerm :: ZonkEnv -> EvTerm -> TcM EvTerm
1030 zonkEvTerm env (EvId v)           = ASSERT2( isId v, ppr v )
1031                                     return (EvId (zonkIdOcc env v))
1032 zonkEvTerm env (EvCoercion co)    = do { co' <- zonkTcTypeToType env co
1033                                        ; return (EvCoercion co') }
1034 zonkEvTerm env (EvCast v co)      = ASSERT( isId v)
1035                                     do { co' <- zonkTcTypeToType env co
1036                                        ; return (EvCast (zonkIdOcc env v) co') }
1037 zonkEvTerm env (EvSuperClass d n) = return (EvSuperClass (zonkIdOcc env d) n)
1038 zonkEvTerm env (EvDFunApp df tys tms)
1039   = do { tys' <- zonkTcTypeToTypes env tys
1040        ; let tms' = map (zonkEvVarOcc env) tms
1041        ; return (EvDFunApp (zonkIdOcc env df) tys' tms') }
1042
1043 zonkTcEvBinds :: ZonkEnv -> TcEvBinds -> TcM (ZonkEnv, TcEvBinds)
1044 zonkTcEvBinds env (TcEvBinds var) = do { (env', bs') <- zonkEvBindsVar env var
1045                                        ; return (env', EvBinds bs') }
1046 zonkTcEvBinds env (EvBinds bs)    = do { (env', bs') <- zonkEvBinds env bs
1047                                        ; return (env', EvBinds bs') }
1048
1049 zonkEvBindsVar :: ZonkEnv -> EvBindsVar -> TcM (ZonkEnv, Bag EvBind)
1050 zonkEvBindsVar env (EvBindsVar ref _) = do { bs <- readMutVar ref
1051                                            ; zonkEvBinds env (evBindMapBinds bs) }
1052
1053 zonkEvBinds :: ZonkEnv -> Bag EvBind -> TcM (ZonkEnv, Bag EvBind)
1054 zonkEvBinds env binds
1055   = fixM (\ ~( _, new_binds) -> do
1056          { let env1 = extendZonkEnv env (collect_ev_bndrs new_binds)
1057          ; binds' <- mapBagM (zonkEvBind env1) binds
1058          ; return (env1, binds') })
1059   where
1060     collect_ev_bndrs :: Bag EvBind -> [EvVar]
1061     collect_ev_bndrs = foldrBag add []
1062     add (EvBind var _) vars = var : vars
1063
1064 zonkEvBind :: ZonkEnv -> EvBind -> TcM EvBind
1065 zonkEvBind env (EvBind var term)
1066   = do { var' <- zonkEvBndr env var
1067        ; term' <- zonkEvTerm env term
1068        ; return (EvBind var' term') }
1069 \end{code}
1070
1071 %************************************************************************
1072 %*                                                                      *
1073 \subsection[BackSubst-Foreign]{Foreign exports}
1074 %*                                                                      *
1075 %************************************************************************
1076
1077 \begin{code}
1078 zonkTcTypeToType :: ZonkEnv -> TcType -> TcM Type
1079 zonkTcTypeToType (ZonkEnv zonk_ty _) ty = zonk_ty ty
1080
1081 zonkTcTypeToTypes :: ZonkEnv -> [TcType] -> TcM [Type]
1082 zonkTcTypeToTypes env tys = mapM (zonkTcTypeToType env) tys
1083
1084 zonkTypeCollecting :: TcRef TyVarSet -> TcType -> TcM Type
1085 -- This variant collects unbound type variables in a mutable variable
1086 zonkTypeCollecting unbound_tv_set
1087   = zonkType (mkZonkTcTyVar zonk_unbound_tyvar)
1088   where
1089     zonk_unbound_tyvar tv
1090         = do { tv' <- zonkQuantifiedTyVar tv
1091              ; tv_set <- readMutVar unbound_tv_set
1092              ; writeMutVar unbound_tv_set (extendVarSet tv_set tv')
1093              ; return (mkTyVarTy tv') }
1094
1095 zonkTypeZapping :: TcType -> TcM Type
1096 -- This variant is used for everything except the LHS of rules
1097 -- It zaps unbound type variables to (), or some other arbitrary type
1098 zonkTypeZapping ty
1099   = zonkType (mkZonkTcTyVar zonk_unbound_tyvar) ty
1100   where
1101         -- Zonk a mutable but unbound type variable to an arbitrary type
1102         -- We know it's unbound even though we don't carry an environment,
1103         -- because at the binding site for a type variable we bind the
1104         -- mutable tyvar to a fresh immutable one.  So the mutable store
1105         -- plays the role of an environment.  If we come across a mutable
1106         -- type variable that isn't so bound, it must be completely free.
1107     zonk_unbound_tyvar tv = do { let ty = anyTypeOfKind (tyVarKind tv)
1108                                ; writeMetaTyVar tv ty
1109                                ; return ty }
1110 \end{code}