compiler/typecheck/TcHsType.lhs

   1
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcMonoType]{Typechecking user-specified @MonoTypes@}
   5
   6 \begin{code}
   7 module TcHsType (
   8         tcHsSigType, tcHsDeriv,
   9         UserTypeCtxt(..),
  10
  11                 -- Kind checking
  12         kcHsTyVars, kcHsSigType, kcHsLiftedSigType,
  13         kcCheckHsType, kcHsContext, kcHsType,
  14
  15                 -- Typechecking kinded types
  16         tcHsKindedContext, tcHsKindedType, tcHsBangType,
  17         tcTyVarBndrs, dsHsType, tcLHsConResTy,
  18         tcDataKindSig,
  19
  20                 -- Pattern type signatures
  21         tcHsPatSigType, tcPatSig
  22    ) where
  23
  24 #include "HsVersions.h"
  25
  26 import HsSyn            ( HsType(..), LHsType, HsTyVarBndr(..), LHsTyVarBndr,
  27                           LHsContext, HsPred(..), LHsPred, HsExplicitForAll(..) )
  28 import RnHsSyn          ( extractHsTyVars )
  29 import TcRnMonad
  30 import TcEnv            ( tcExtendTyVarEnv, tcExtendKindEnvTvs,
  31                           tcLookup, tcLookupClass, tcLookupTyCon,
  32                           TyThing(..), getInLocalScope, getScopedTyVarBinds,
  33                           wrongThingErr
  34                         )
  35 import TcMType          ( newKindVar,
  36                           zonkTcKindToKind,
  37                           tcInstBoxyTyVar, readFilledBox,
  38                           checkValidType
  39                         )
  40 import TcUnify          ( boxyUnify, unifyFunKind, checkExpectedKind )
  41 import TcIface          ( checkWiredInTyCon )
  42 import TcType           ( Type, PredType(..), ThetaType, BoxySigmaType,
  43                           TcType, TcKind, isRigidTy,
  44                           UserTypeCtxt(..), pprUserTypeCtxt,
  45                           substTyWith, mkTyVarTys, tcEqType,
  46                           tcIsTyVarTy, mkFunTy, mkSigmaTy, mkPredTy,
  47                           mkTyConApp, mkAppTys, typeKind )
  48 import Kind             ( Kind, isLiftedTypeKind, liftedTypeKind, ubxTupleKind,
  49                           openTypeKind, argTypeKind, splitKindFunTys )
  50 import Var              ( TyVar, mkTyVar, tyVarName )
  51 import TyCon            ( TyCon, tyConKind )
  52 import Class            ( Class, classTyCon )
  53 import Name             ( Name, mkInternalName )
  54 import OccName          ( mkOccName, tvName )
  55 import NameSet
  56 import PrelNames        ( genUnitTyConName )
  57 import TysWiredIn       ( mkListTy, listTyCon, mkPArrTy, parrTyCon, tupleTyCon )
  58 import BasicTypes       ( Boxity(..) )
  59 import SrcLoc           ( Located(..), unLoc, noLoc, getLoc, srcSpanStart )
  60 import UniqSupply       ( uniqsFromSupply )
  61 import Outputable
  62 \end{code}
  63
  64
  65         ----------------------------
  66                 General notes
  67         ----------------------------
  68
  69 Generally speaking we now type-check types in three phases
  70
  71   1.  kcHsType: kind check the HsType
  72         *includes* performing any TH type splices;
  73         so it returns a translated, and kind-annotated, type
  74
  75   2.  dsHsType: convert from HsType to Type:
  76         perform zonking
  77         expand type synonyms [mkGenTyApps]
  78         hoist the foralls [tcHsType]
  79
  80   3.  checkValidType: check the validity of the resulting type
  81
  82 Often these steps are done one after the other (tcHsSigType).
  83 But in mutually recursive groups of type and class decls we do
  84         1 kind-check the whole group
  85         2 build TyCons/Classes in a knot-tied way
  86         3 check the validity of types in the now-unknotted TyCons/Classes
  87
  88 For example, when we find
  89         (forall a m. m a -> m a)
  90 we bind a,m to kind varibles and kind-check (m a -> m a).  This makes
  91 a get kind *, and m get kind *->*.  Now we typecheck (m a -> m a) in
  92 an environment that binds a and m suitably.
  93
  94 The kind checker passed to tcHsTyVars needs to look at enough to
  95 establish the kind of the tyvar:
  96   * For a group of type and class decls, it's just the group, not
  97         the rest of the program
  98   * For a tyvar bound in a pattern type signature, its the types
  99         mentioned in the other type signatures in that bunch of patterns
 100   * For a tyvar bound in a RULE, it's the type signatures on other
 101         universally quantified variables in the rule
 102
 103 Note that this may occasionally give surprising results.  For example:
 104
 105         data T a b = MkT (a b)
 106
 107 Here we deduce                  a::*->*,       b::*
 108 But equally valid would be      a::(*->*)-> *, b::*->*
 109
 110
 111 Validity checking
 112 ~~~~~~~~~~~~~~~~~
 113 Some of the validity check could in principle be done by the kind checker,
 114 but not all:
 115
 116 - During desugaring, we normalise by expanding type synonyms.  Only
 117   after this step can we check things like type-synonym saturation
 118   e.g.  type T k = k Int
 119         type S a = a
 120   Then (T S) is ok, because T is saturated; (T S) expands to (S Int);
 121   and then S is saturated.  This is a GHC extension.
 122
 123 - Similarly, also a GHC extension, we look through synonyms before complaining
 124   about the form of a class or instance declaration
 125
 126 - Ambiguity checks involve functional dependencies, and it's easier to wait
 127   until knots have been resolved before poking into them
 128
 129 Also, in a mutually recursive group of types, we can't look at the TyCon until we've
 130 finished building the loop.  So to keep things simple, we postpone most validity
 131 checking until step (3).
 132
 133 Knot tying
 134 ~~~~~~~~~~
 135 During step (1) we might fault in a TyCon defined in another module, and it might
 136 (via a loop) refer back to a TyCon defined in this module. So when we tie a big
 137 knot around type declarations with ARecThing, so that the fault-in code can get
 138 the TyCon being defined.
 139
 140
 141 %************************************************************************
 142 %*                                                                      *
 143 \subsection{Checking types}
 144 %*                                                                      *
 145 %************************************************************************
 146
 147 \begin{code}
 148 tcHsSigType :: UserTypeCtxt -> LHsType Name -> TcM Type
 149   -- Do kind checking, and hoist for-alls to the top
 150   -- NB: it's important that the foralls that come from the top-level
 151   --     HsForAllTy in hs_ty occur *first* in the returned type.
 152   --     See Note [Scoped] with TcSigInfo
 153 tcHsSigType ctxt hs_ty
 154   = addErrCtxt (pprHsSigCtxt ctxt hs_ty) $
 155     do  { kinded_ty <- kcTypeType hs_ty
 156         ; ty <- tcHsKindedType kinded_ty
 157         ; checkValidType ctxt ty
 158         ; returnM ty }
 159
 160 -- Used for the deriving(...) items
 161 tcHsDeriv :: LHsType Name -> TcM ([TyVar], Class, [Type])
 162 tcHsDeriv = addLocM (tc_hs_deriv [])
 163
 164 tc_hs_deriv tv_names (HsPredTy (HsClassP cls_name hs_tys))
 165   = kcHsTyVars tv_names                 $ \ tv_names' ->
 166     do  { cls_kind <- kcClass cls_name
 167         ; (tys, res_kind) <- kcApps cls_kind (ppr cls_name) hs_tys
 168         ; tcTyVarBndrs tv_names'        $ \ tyvars ->
 169     do  { arg_tys <- dsHsTypes tys
 170         ; cls <- tcLookupClass cls_name
 171         ; return (tyvars, cls, arg_tys) }}
 172
 173 tc_hs_deriv tv_names1 (HsForAllTy _ tv_names2 (L _ []) (L _ ty))
 174   =     -- Funny newtype deriving form
 175         --      forall a. C [a]
 176         -- where C has arity 2.  Hence can't use regular functions
 177     tc_hs_deriv (tv_names1 ++ tv_names2) ty
 178
 179 tc_hs_deriv _ other
 180   = failWithTc (ptext SLIT("Illegal deriving item") <+> ppr other)
 181 \end{code}
 182
 183         These functions are used during knot-tying in
 184         type and class declarations, when we have to
 185         separate kind-checking, desugaring, and validity checking
 186
 187 \begin{code}
 188 kcHsSigType, kcHsLiftedSigType :: LHsType Name -> TcM (LHsType Name)
 189         -- Used for type signatures
 190 kcHsSigType ty       = kcTypeType ty
 191 kcHsLiftedSigType ty = kcLiftedType ty
 192
 193 tcHsKindedType :: LHsType Name -> TcM Type
 194   -- Don't do kind checking, nor validity checking.
 195   -- This is used in type and class decls, where kinding is
 196   -- done in advance, and validity checking is done later
 197   -- [Validity checking done later because of knot-tying issues.]
 198 tcHsKindedType hs_ty = dsHsType hs_ty
 199
 200 tcHsBangType :: LHsType Name -> TcM Type
 201 -- Permit a bang, but discard it
 202 tcHsBangType (L span (HsBangTy b ty)) = tcHsKindedType ty
 203 tcHsBangType ty                       = tcHsKindedType ty
 204
 205 tcHsKindedContext :: LHsContext Name -> TcM ThetaType
 206 -- Used when we are expecting a ClassContext (i.e. no implicit params)
 207 -- Does not do validity checking, like tcHsKindedType
 208 tcHsKindedContext hs_theta = addLocM (mappM dsHsLPred) hs_theta
 209 \end{code}
 210
 211
 212 %************************************************************************
 213 %*                                                                      *
 214                 The main kind checker: kcHsType
 215 %*                                                                      *
 216 %************************************************************************
 217
 218         First a couple of simple wrappers for kcHsType
 219
 220 \begin{code}
 221 ---------------------------
 222 kcLiftedType :: LHsType Name -> TcM (LHsType Name)
 223 -- The type ty must be a *lifted* *type*
 224 kcLiftedType ty = kcCheckHsType ty liftedTypeKind
 225
 226 ---------------------------
 227 kcTypeType :: LHsType Name -> TcM (LHsType Name)
 228 -- The type ty must be a *type*, but it can be lifted or
 229 -- unlifted or an unboxed tuple.
 230 kcTypeType ty = kcCheckHsType ty openTypeKind
 231
 232 ---------------------------
 233 kcCheckHsType :: LHsType Name -> TcKind -> TcM (LHsType Name)
 234 -- Check that the type has the specified kind
 235 -- Be sure to use checkExpectedKind, rather than simply unifying
 236 -- with OpenTypeKind, because it gives better error messages
 237 kcCheckHsType (L span ty) exp_kind
 238   = setSrcSpan span                             $
 239     do  { (ty', act_kind) <- add_ctxt ty (kc_hs_type ty)
 240                 -- Add the context round the inner check only
 241                 -- because checkExpectedKind already mentions
 242                 -- 'ty' by name in any error message
 243
 244         ; checkExpectedKind (strip ty) act_kind exp_kind
 245         ; return (L span ty') }
 246   where
 247         -- Wrap a context around only if we want to show that contexts.
 248         -- Omit invisble ones and ones user's won't grok (HsPred p).
 249     add_ctxt (HsPredTy p)                                thing = thing
 250     add_ctxt (HsForAllTy Implicit tvs (L _ []) (L _ ty)) thing = add_ctxt ty thing
 251     add_ctxt other_ty thing = addErrCtxt (typeCtxt ty) thing
 252
 253         -- We infer the kind of the type, and then complain if it's
 254         -- not right.  But we don't want to complain about
 255         --      (ty) or !(ty) or forall a. ty
 256         -- when the real difficulty is with the 'ty' part.
 257     strip (HsParTy (L _ ty))          = strip ty
 258     strip (HsBangTy _ (L _ ty))       = strip ty
 259     strip (HsForAllTy _ _ _ (L _ ty)) = strip ty
 260     strip ty                          = ty
 261 \end{code}
 262
 263         Here comes the main function
 264
 265 \begin{code}
 266 kcHsType :: LHsType Name -> TcM (LHsType Name, TcKind)
 267 kcHsType ty = wrapLocFstM kc_hs_type ty
 268 -- kcHsType *returns* the kind of the type, rather than taking an expected
 269 -- kind as argument as tcExpr does.
 270 -- Reasons:
 271 --      (a) the kind of (->) is
 272 --              forall bx1 bx2. Type bx1 -> Type bx2 -> Type Boxed
 273 --          so we'd need to generate huge numbers of bx variables.
 274 --      (b) kinds are so simple that the error messages are fine
 275 --
 276 -- The translated type has explicitly-kinded type-variable binders
 277
 278 kc_hs_type (HsParTy ty)
 279  = kcHsType ty          `thenM` \ (ty', kind) ->
 280    returnM (HsParTy ty', kind)
 281
 282 kc_hs_type (HsTyVar name)
 283   = kcTyVar name        `thenM` \ kind ->
 284     returnM (HsTyVar name, kind)
 285
 286 kc_hs_type (HsListTy ty)
 287   = kcLiftedType ty                     `thenM` \ ty' ->
 288     returnM (HsListTy ty', liftedTypeKind)
 289
 290 kc_hs_type (HsPArrTy ty)
 291   = kcLiftedType ty                     `thenM` \ ty' ->
 292     returnM (HsPArrTy ty', liftedTypeKind)
 293
 294 kc_hs_type (HsNumTy n)
 295    = returnM (HsNumTy n, liftedTypeKind)
 296
 297 kc_hs_type (HsKindSig ty k)
 298   = kcCheckHsType ty k  `thenM` \ ty' ->
 299     returnM (HsKindSig ty' k, k)
 300
 301 kc_hs_type (HsTupleTy Boxed tys)
 302   = mappM kcLiftedType tys      `thenM` \ tys' ->
 303     returnM (HsTupleTy Boxed tys', liftedTypeKind)
 304
 305 kc_hs_type (HsTupleTy Unboxed tys)
 306   = mappM kcTypeType tys        `thenM` \ tys' ->
 307     returnM (HsTupleTy Unboxed tys', ubxTupleKind)
 308
 309 kc_hs_type (HsFunTy ty1 ty2)
 310   = kcCheckHsType ty1 argTypeKind       `thenM` \ ty1' ->
 311     kcTypeType ty2                      `thenM` \ ty2' ->
 312     returnM (HsFunTy ty1' ty2', liftedTypeKind)
 313
 314 kc_hs_type ty@(HsOpTy ty1 op ty2)
 315   = addLocM kcTyVar op                  `thenM` \ op_kind ->
 316     kcApps op_kind (ppr op) [ty1,ty2]   `thenM` \ ([ty1',ty2'], res_kind) ->
 317     returnM (HsOpTy ty1' op ty2', res_kind)
 318
 319 kc_hs_type ty@(HsAppTy ty1 ty2)
 320   = kcHsType fun_ty                       `thenM` \ (fun_ty', fun_kind) ->
 321     kcApps fun_kind (ppr fun_ty) arg_tys  `thenM` \ ((arg_ty':arg_tys'), res_kind) ->
 322     returnM (foldl mk_app (HsAppTy fun_ty' arg_ty') arg_tys', res_kind)
 323   where
 324     (fun_ty, arg_tys) = split ty1 [ty2]
 325     split (L _ (HsAppTy f a)) as = split f (a:as)
 326     split f                   as = (f,as)
 327     mk_app fun arg = HsAppTy (noLoc fun) arg    -- Add noLocs for inner nodes of
 328                                                 -- the application; they are never used
 329
 330 kc_hs_type (HsPredTy pred)
 331   = kcHsPred pred               `thenM` \ pred' ->
 332     returnM (HsPredTy pred', liftedTypeKind)
 333
 334 kc_hs_type (HsForAllTy exp tv_names context ty)
 335   = kcHsTyVars tv_names         $ \ tv_names' ->
 336     kcHsContext context         `thenM` \ ctxt' ->
 337     kcLiftedType ty             `thenM` \ ty' ->
 338         -- The body of a forall is usually a type, but in principle
 339         -- there's no reason to prohibit *unlifted* types.
 340         -- In fact, GHC can itself construct a function with an
 341         -- unboxed tuple inside a for-all (via CPR analyis; see
 342         -- typecheck/should_compile/tc170)
 343         --
 344         -- Still, that's only for internal interfaces, which aren't
 345         -- kind-checked, so we only allow liftedTypeKind here
 346     returnM (HsForAllTy exp tv_names' ctxt' ty', liftedTypeKind)
 347
 348 kc_hs_type (HsBangTy b ty)
 349   = do { (ty', kind) <- kcHsType ty
 350        ; return (HsBangTy b ty', kind) }
 351
 352 kc_hs_type ty@(HsSpliceTy _)
 353   = failWithTc (ptext SLIT("Unexpected type splice:") <+> ppr ty)
 354
 355
 356 ---------------------------
 357 kcApps :: TcKind                        -- Function kind
 358        -> SDoc                          -- Function
 359        -> [LHsType Name]                -- Arg types
 360        -> TcM ([LHsType Name], TcKind)  -- Kind-checked args
 361 kcApps fun_kind ppr_fun args
 362   = split_fk fun_kind (length args)     `thenM` \ (arg_kinds, res_kind) ->
 363     zipWithM kc_arg args arg_kinds      `thenM` \ args' ->
 364     returnM (args', res_kind)
 365   where
 366     split_fk fk 0 = returnM ([], fk)
 367     split_fk fk n = unifyFunKind fk     `thenM` \ mb_fk ->
 368                     case mb_fk of
 369                         Nothing       -> failWithTc too_many_args
 370                         Just (ak,fk') -> split_fk fk' (n-1)     `thenM` \ (aks, rk) ->
 371                                          returnM (ak:aks, rk)
 372
 373     kc_arg arg arg_kind = kcCheckHsType arg arg_kind
 374
 375     too_many_args = ptext SLIT("Kind error:") <+> quotes ppr_fun <+>
 376                     ptext SLIT("is applied to too many type arguments")
 377
 378 ---------------------------
 379 kcHsContext :: LHsContext Name -> TcM (LHsContext Name)
 380 kcHsContext ctxt = wrapLocM (mappM kcHsLPred) ctxt
 381
 382 kcHsLPred :: LHsPred Name -> TcM (LHsPred Name)
 383 kcHsLPred = wrapLocM kcHsPred
 384
 385 kcHsPred :: HsPred Name -> TcM (HsPred Name)
 386 kcHsPred pred   -- Checks that the result is of kind liftedType
 387   = kc_pred pred                                `thenM` \ (pred', kind) ->
 388     checkExpectedKind pred kind liftedTypeKind  `thenM_`
 389     returnM pred'
 390
 391 ---------------------------
 392 kc_pred :: HsPred Name -> TcM (HsPred Name, TcKind)
 393         -- Does *not* check for a saturated
 394         -- application (reason: used from TcDeriv)
 395 kc_pred pred@(HsIParam name ty)
 396   = kcHsType ty         `thenM` \ (ty', kind) ->
 397     returnM (HsIParam name ty', kind)
 398
 399 kc_pred pred@(HsClassP cls tys)
 400   = kcClass cls                 `thenM` \ kind ->
 401     kcApps kind (ppr cls) tys   `thenM` \ (tys', res_kind) ->
 402     returnM (HsClassP cls tys', res_kind)
 403
 404 ---------------------------
 405 kcTyVar :: Name -> TcM TcKind
 406 kcTyVar name    -- Could be a tyvar or a tycon
 407   = traceTc (text "lk1" <+> ppr name)   `thenM_`
 408     tcLookup name       `thenM` \ thing ->
 409     traceTc (text "lk2" <+> ppr name <+> ppr thing)     `thenM_`
 410     case thing of
 411         ATyVar _ ty             -> returnM (typeKind ty)
 412         AThing kind             -> returnM kind
 413         AGlobal (ATyCon tc)     -> returnM (tyConKind tc)
 414         other                   -> wrongThingErr "type" thing name
 415
 416 kcClass :: Name -> TcM TcKind
 417 kcClass cls     -- Must be a class
 418   = tcLookup cls                                `thenM` \ thing ->
 419     case thing of
 420         AThing kind             -> returnM kind
 421         AGlobal (AClass cls)    -> returnM (tyConKind (classTyCon cls))
 422         other                   -> wrongThingErr "class" thing cls
 423 \end{code}
 424
 425
 426 %************************************************************************
 427 %*                                                                      *
 428                 Desugaring
 429 %*                                                                      *
 430 %************************************************************************
 431
 432 The type desugarer
 433
 434         * Transforms from HsType to Type
 435         * Zonks any kinds
 436
 437 It cannot fail, and does no validity checking, except for
 438 structural matters, such as
 439         (a) spurious ! annotations.
 440         (b) a class used as a type
 441
 442 \begin{code}
 443 dsHsType :: LHsType Name -> TcM Type
 444 -- All HsTyVarBndrs in the intput type are kind-annotated
 445 dsHsType ty = ds_type (unLoc ty)
 446
 447 ds_type ty@(HsTyVar name)
 448   = ds_app ty []
 449
 450 ds_type (HsParTy ty)            -- Remove the parentheses markers
 451   = dsHsType ty
 452
 453 ds_type ty@(HsBangTy _ _)       -- No bangs should be here
 454   = failWithTc (ptext SLIT("Unexpected strictness annotation:") <+> ppr ty)
 455
 456 ds_type (HsKindSig ty k)
 457   = dsHsType ty -- Kind checking done already
 458
 459 ds_type (HsListTy ty)
 460   = dsHsType ty                 `thenM` \ tau_ty ->
 461     checkWiredInTyCon listTyCon `thenM_`
 462     returnM (mkListTy tau_ty)
 463
 464 ds_type (HsPArrTy ty)
 465   = dsHsType ty                 `thenM` \ tau_ty ->
 466     checkWiredInTyCon parrTyCon `thenM_`
 467     returnM (mkPArrTy tau_ty)
 468
 469 ds_type (HsTupleTy boxity tys)
 470   = dsHsTypes tys               `thenM` \ tau_tys ->
 471     checkWiredInTyCon tycon     `thenM_`
 472     returnM (mkTyConApp tycon tau_tys)
 473   where
 474     tycon = tupleTyCon boxity (length tys)
 475
 476 ds_type (HsFunTy ty1 ty2)
 477   = dsHsType ty1                        `thenM` \ tau_ty1 ->
 478     dsHsType ty2                        `thenM` \ tau_ty2 ->
 479     returnM (mkFunTy tau_ty1 tau_ty2)
 480
 481 ds_type (HsOpTy ty1 (L span op) ty2)
 482   = dsHsType ty1                `thenM` \ tau_ty1 ->
 483     dsHsType ty2                `thenM` \ tau_ty2 ->
 484     setSrcSpan span (ds_var_app op [tau_ty1,tau_ty2])
 485
 486 ds_type (HsNumTy n)
 487   = ASSERT(n==1)
 488     tcLookupTyCon genUnitTyConName      `thenM` \ tc ->
 489     returnM (mkTyConApp tc [])
 490
 491 ds_type ty@(HsAppTy _ _)
 492   = ds_app ty []
 493
 494 ds_type (HsPredTy pred)
 495   = dsHsPred pred       `thenM` \ pred' ->
 496     returnM (mkPredTy pred')
 497
 498 ds_type full_ty@(HsForAllTy exp tv_names ctxt ty)
 499   = tcTyVarBndrs tv_names               $ \ tyvars ->
 500     mappM dsHsLPred (unLoc ctxt)        `thenM` \ theta ->
 501     dsHsType ty                         `thenM` \ tau ->
 502     returnM (mkSigmaTy tyvars theta tau)
 503
 504 dsHsTypes arg_tys = mappM dsHsType arg_tys
 505 \end{code}
 506
 507 Help functions for type applications
 508 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 509
 510 \begin{code}
 511 ds_app :: HsType Name -> [LHsType Name] -> TcM Type
 512 ds_app (HsAppTy ty1 ty2) tys
 513   = ds_app (unLoc ty1) (ty2:tys)
 514
 515 ds_app ty tys
 516   = dsHsTypes tys                       `thenM` \ arg_tys ->
 517     case ty of
 518         HsTyVar fun -> ds_var_app fun arg_tys
 519         other       -> ds_type ty               `thenM` \ fun_ty ->
 520                        returnM (mkAppTys fun_ty arg_tys)
 521
 522 ds_var_app :: Name -> [Type] -> TcM Type
 523 ds_var_app name arg_tys
 524  = tcLookup name                        `thenM` \ thing ->
 525     case thing of
 526         ATyVar _ ty         -> returnM (mkAppTys ty arg_tys)
 527         AGlobal (ATyCon tc) -> returnM (mkTyConApp tc arg_tys)
 528         other               -> wrongThingErr "type" thing name
 529 \end{code}
 530
 531
 532 Contexts
 533 ~~~~~~~~
 534
 535 \begin{code}
 536 dsHsLPred :: LHsPred Name -> TcM PredType
 537 dsHsLPred pred = dsHsPred (unLoc pred)
 538
 539 dsHsPred pred@(HsClassP class_name tys)
 540   = dsHsTypes tys                       `thenM` \ arg_tys ->
 541     tcLookupClass class_name            `thenM` \ clas ->
 542     returnM (ClassP clas arg_tys)
 543
 544 dsHsPred (HsIParam name ty)
 545   = dsHsType ty                                 `thenM` \ arg_ty ->
 546     returnM (IParam name arg_ty)
 547 \end{code}
 548
 549 GADT constructor signatures
 550
 551 \begin{code}
 552 tcLHsConResTy :: LHsType Name -> TcM (TyCon, [TcType])
 553 tcLHsConResTy res_ty
 554   = addErrCtxt (gadtResCtxt res_ty) $
 555     case get_largs res_ty [] of
 556            (HsTyVar tc_name, args)
 557               -> do { args' <- mapM dsHsType args
 558                     ; thing <- tcLookup tc_name
 559                     ; case thing of
 560                         AGlobal (ATyCon tc) -> return (tc, args')
 561                         other -> failWithTc (badGadtDecl res_ty) }
 562            other -> failWithTc (badGadtDecl res_ty)
 563   where
 564         -- We can't call dsHsType on res_ty, and then do tcSplitTyConApp_maybe
 565         -- because that causes a black hole, and for good reason.  Building
 566         -- the type means expanding type synonyms, and we can't do that
 567         -- inside the "knot".  So we have to work by steam.
 568     get_largs (L _ ty) args = get_args ty args
 569     get_args (HsAppTy fun arg)            args = get_largs fun (arg:args)
 570     get_args (HsParTy ty)                 args = get_largs ty  args
 571     get_args (HsOpTy ty1 (L span tc) ty2) args = (HsTyVar tc, ty1:ty2:args)
 572     get_args ty                           args = (ty, args)
 573
 574 gadtResCtxt ty
 575   = hang (ptext SLIT("In the result type of a data constructor:"))
 576        2 (ppr ty)
 577 badGadtDecl ty
 578   = hang (ptext SLIT("Malformed constructor result type:"))
 579        2 (ppr ty)
 580
 581 typeCtxt ty = ptext SLIT("In the type") <+> quotes (ppr ty)
 582 \end{code}
 583
 584 %************************************************************************
 585 %*                                                                      *
 586                 Type-variable binders
 587 %*                                                                      *
 588 %************************************************************************
 589
 590
 591 \begin{code}
 592 kcHsTyVars :: [LHsTyVarBndr Name]
 593            -> ([LHsTyVarBndr Name] -> TcM r)    -- These binders are kind-annotated
 594                                                 -- They scope over the thing inside
 595            -> TcM r
 596 kcHsTyVars tvs thing_inside
 597   = mappM (wrapLocM kcHsTyVar) tvs      `thenM` \ bndrs ->
 598     tcExtendKindEnvTvs bndrs (thing_inside bndrs)
 599
 600 kcHsTyVar :: HsTyVarBndr Name -> TcM (HsTyVarBndr Name)
 601         -- Return a *kind-annotated* binder, and a tyvar with a mutable kind in it
 602 kcHsTyVar (UserTyVar name)        = newKindVar  `thenM` \ kind ->
 603                                     returnM (KindedTyVar name kind)
 604 kcHsTyVar (KindedTyVar name kind) = returnM (KindedTyVar name kind)
 605
 606 ------------------
 607 tcTyVarBndrs :: [LHsTyVarBndr Name]     -- Kind-annotated binders, which need kind-zonking
 608              -> ([TyVar] -> TcM r)
 609              -> TcM r
 610 -- Used when type-checking types/classes/type-decls
 611 -- Brings into scope immutable TyVars, not mutable ones that require later zonking
 612 tcTyVarBndrs bndrs thing_inside
 613   = mapM (zonk . unLoc) bndrs   `thenM` \ tyvars ->
 614     tcExtendTyVarEnv tyvars (thing_inside tyvars)
 615   where
 616     zonk (KindedTyVar name kind) = do { kind' <- zonkTcKindToKind kind
 617                                       ; return (mkTyVar name kind') }
 618     zonk (UserTyVar name) = pprTrace "Un-kinded tyvar" (ppr name) $
 619                             return (mkTyVar name liftedTypeKind)
 620
 621 -----------------------------------
 622 tcDataKindSig :: Maybe Kind -> TcM [TyVar]
 623 -- GADT decls can have a (perhaps partial) kind signature
 624 --      e.g.  data T :: * -> * -> * where ...
 625 -- This function makes up suitable (kinded) type variables for
 626 -- the argument kinds, and checks that the result kind is indeed *
 627 tcDataKindSig Nothing = return []
 628 tcDataKindSig (Just kind)
 629   = do  { checkTc (isLiftedTypeKind res_kind) (badKindSig kind)
 630         ; span <- getSrcSpanM
 631         ; us   <- newUniqueSupply
 632         ; let loc   = srcSpanStart span
 633               uniqs = uniqsFromSupply us
 634         ; return [ mk_tv loc uniq str kind
 635                  | ((kind, str), uniq) <- arg_kinds `zip` names `zip` uniqs ] }
 636   where
 637     (arg_kinds, res_kind) = splitKindFunTys kind
 638     mk_tv loc uniq str kind = mkTyVar name kind
 639         where
 640            name = mkInternalName uniq occ loc
 641            occ  = mkOccName tvName str
 642
 643     names :: [String]   -- a,b,c...aa,ab,ac etc
 644     names = [ c:cs | cs <- "" : names, c <- ['a'..'z'] ]
 645
 646 badKindSig :: Kind -> SDoc
 647 badKindSig kind
 648  = hang (ptext SLIT("Kind signature on data type declaration has non-* return kind"))
 649         2 (ppr kind)
 650 \end{code}
 651
 652
 653 %************************************************************************
 654 %*                                                                      *
 655                 Scoped type variables
 656 %*                                                                      *
 657 %************************************************************************
 658
 659
 660 tcAddScopedTyVars is used for scoped type variables added by pattern
 661 type signatures
 662         e.g.  \ ((x::a), (y::a)) -> x+y
 663 They never have explicit kinds (because this is source-code only)
 664 They are mutable (because they can get bound to a more specific type).
 665
 666 Usually we kind-infer and expand type splices, and then
 667 tupecheck/desugar the type.  That doesn't work well for scoped type
 668 variables, because they scope left-right in patterns.  (e.g. in the
 669 example above, the 'a' in (y::a) is bound by the 'a' in (x::a).
 670
 671 The current not-very-good plan is to
 672   * find all the types in the patterns
 673   * find their free tyvars
 674   * do kind inference
 675   * bring the kinded type vars into scope
 676   * BUT throw away the kind-checked type
 677         (we'll kind-check it again when we type-check the pattern)
 678
 679 This is bad because throwing away the kind checked type throws away
 680 its splices.  But too bad for now.  [July 03]
 681
 682 Historical note:
 683     We no longer specify that these type variables must be univerally
 684     quantified (lots of email on the subject).  If you want to put that
 685     back in, you need to
 686         a) Do a checkSigTyVars after thing_inside
 687         b) More insidiously, don't pass in expected_ty, else
 688            we unify with it too early and checkSigTyVars barfs
 689            Instead you have to pass in a fresh ty var, and unify
 690            it with expected_ty afterwards
 691
 692 \begin{code}
 693 tcHsPatSigType :: UserTypeCtxt
 694                -> LHsType Name          -- The type signature
 695                -> TcM ([TyVar],         -- Newly in-scope type variables
 696                         Type)           -- The signature
 697 -- Used for type-checking type signatures in
 698 -- (a) patterns           e.g  f (x::Int) = e
 699 -- (b) result signatures  e.g. g x :: Int = e
 700 -- (c) RULE forall bndrs  e.g. forall (x::Int). f x = x
 701
 702 tcHsPatSigType ctxt hs_ty
 703   = addErrCtxt (pprHsSigCtxt ctxt hs_ty) $
 704     do  {       -- Find the type variables that are mentioned in the type
 705                 -- but not already in scope.  These are the ones that
 706                 -- should be bound by the pattern signature
 707           in_scope <- getInLocalScope
 708         ; let span = getLoc hs_ty
 709               sig_tvs = [ L span (UserTyVar n)
 710                         | n <- nameSetToList (extractHsTyVars hs_ty),
 711                           not (in_scope n) ]
 712
 713         -- Behave very like type-checking (HsForAllTy sig_tvs hs_ty),
 714         -- except that we want to keep the tvs separate
 715         ; (kinded_tvs, kinded_ty) <- kcHsTyVars sig_tvs $ \ kinded_tvs -> do
 716                                     { kinded_ty <- kcTypeType hs_ty
 717                                     ; return (kinded_tvs, kinded_ty) }
 718         ; tcTyVarBndrs kinded_tvs $ \ tyvars -> do
 719         { sig_ty <- dsHsType kinded_ty
 720         ; checkValidType ctxt sig_ty
 721         ; return (tyvars, sig_ty)
 722       } }
 723
 724 tcPatSig :: UserTypeCtxt
 725          -> LHsType Name
 726          -> BoxySigmaType
 727          -> TcM (TcType,           -- The type to use for "inside" the signature
 728                  [(Name,TcType)])  -- The new bit of type environment, binding
 729                                    -- the scoped type variables
 730 tcPatSig ctxt sig res_ty
 731   = do  { (sig_tvs, sig_ty) <- tcHsPatSigType ctxt sig
 732
 733         ; if null sig_tvs then do {
 734                 -- The type signature binds no type variables,
 735                 -- and hence is rigid, so use it to zap the res_ty
 736                   boxyUnify sig_ty res_ty
 737                 ; return (sig_ty, [])
 738
 739         } else do {
 740                 -- Type signature binds at least one scoped type variable
 741
 742                 -- A pattern binding cannot bind scoped type variables
 743                 -- The renamer fails with a name-out-of-scope error
 744                 -- if a pattern binding tries to bind a type variable,
 745                 -- So we just have an ASSERT here
 746         ; let in_pat_bind = case ctxt of
 747                                 BindPatSigCtxt -> True
 748                                 other          -> False
 749         ; ASSERT( not in_pat_bind || null sig_tvs ) return ()
 750
 751                 -- Check that pat_ty is rigid
 752         ; checkTc (isRigidTy res_ty) (wobblyPatSig sig_tvs)
 753
 754                 -- Now match the pattern signature against res_ty
 755                 -- For convenience, and uniform-looking error messages
 756                 -- we do the matching by allocating meta type variables,
 757                 -- unifying, and reading out the results.
 758                 -- This is a strictly local operation.
 759         ; box_tvs <- mapM tcInstBoxyTyVar sig_tvs
 760         ; boxyUnify (substTyWith sig_tvs (mkTyVarTys box_tvs) sig_ty) res_ty
 761         ; sig_tv_tys <- mapM readFilledBox box_tvs
 762
 763                 -- Check that each is bound to a distinct type variable,
 764                 -- and one that is not already in scope
 765         ; let tv_binds = map tyVarName sig_tvs `zip` sig_tv_tys
 766         ; binds_in_scope <- getScopedTyVarBinds
 767         ; check binds_in_scope tv_binds
 768
 769                 -- Phew!
 770         ; return (res_ty, tv_binds)
 771         } }
 772   where
 773     check in_scope []            = return ()
 774     check in_scope ((n,ty):rest) = do { check_one in_scope n ty
 775                                       ; check ((n,ty):in_scope) rest }
 776
 777     check_one in_scope n ty
 778         = do { checkTc (tcIsTyVarTy ty) (scopedNonVar n ty)
 779                 -- Must bind to a type variable
 780
 781              ; checkTc (null dups) (dupInScope n (head dups) ty)
 782                 -- Must not bind to the same type variable
 783                 -- as some other in-scope type variable
 784
 785              ; return () }
 786         where
 787           dups = [n' | (n',ty') <- in_scope, tcEqType ty' ty]
 788 \end{code}
 789
 790
 791 %************************************************************************
 792 %*                                                                      *
 793                 Scoped type variables
 794 %*                                                                      *
 795 %************************************************************************
 796
 797 \begin{code}
 798 pprHsSigCtxt :: UserTypeCtxt -> LHsType Name -> SDoc
 799 pprHsSigCtxt ctxt hs_ty = vcat [ ptext SLIT("In") <+> pprUserTypeCtxt ctxt <> colon,
 800                                  nest 2 (pp_sig ctxt) ]
 801   where
 802     pp_sig (FunSigCtxt n)  = pp_n_colon n
 803     pp_sig (ConArgCtxt n)  = pp_n_colon n
 804     pp_sig (ForSigCtxt n)  = pp_n_colon n
 805     pp_sig (RuleSigCtxt n) = pp_n_colon n
 806     pp_sig other           = ppr (unLoc hs_ty)
 807
 808     pp_n_colon n = ppr n <+> dcolon <+> ppr (unLoc hs_ty)
 809
 810
 811 wobblyPatSig sig_tvs
 812   = hang (ptext SLIT("A pattern type signature cannot bind scoped type variables")
 813                 <+> pprQuotedList sig_tvs)
 814        2 (ptext SLIT("unless the pattern has a rigid type context"))
 815
 816 scopedNonVar n ty
 817   = vcat [sep [ptext SLIT("The scoped type variable") <+> quotes (ppr n),
 818                nest 2 (ptext SLIT("is bound to the type") <+> quotes (ppr ty))],
 819           nest 2 (ptext SLIT("You can only bind scoped type variables to type variables"))]
 820
 821 dupInScope n n' ty
 822   = hang (ptext SLIT("The scoped type variables") <+> quotes (ppr n) <+> ptext SLIT("and") <+> quotes (ppr n'))
 823        2 (vcat [ptext SLIT("are bound to the same type (variable)"),
 824                 ptext SLIT("Distinct scoped type variables must be distinct")])
 825 \end{code}
 826