compiler/typecheck/TcHsType.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5 \section[TcMonoType]{Typechecking user-specified @MonoTypes@}
   6
   7 \begin{code}
   8 module TcHsType (
   9         tcHsSigType, tcHsDeriv,
  10         UserTypeCtxt(..),
  11
  12                 -- Kind checking
  13         kcHsTyVars, kcHsSigType, kcHsLiftedSigType,
  14         kcCheckHsType, kcHsContext, kcHsType,
  15
  16                 -- Typechecking kinded types
  17         tcHsKindedContext, tcHsKindedType, tcHsBangType,
  18         tcTyVarBndrs, dsHsType, tcLHsConResTy,
  19         tcDataKindSig,
  20
  21                 -- Pattern type signatures
  22         tcHsPatSigType, tcPatSig
  23    ) where
  24
  25 #include "HsVersions.h"
  26
  27 import HsSyn
  28 import RnHsSyn
  29 import TcRnMonad
  30 import TcEnv
  31 import TcMType
  32 import TcUnify
  33 import TcIface
  34 import TcType
  35 import {- Kind parts of -} Type
  36 import Var
  37 import TyCon
  38 import Class
  39 import Name
  40 import OccName
  41 import NameSet
  42 import PrelNames
  43 import TysWiredIn
  44 import BasicTypes
  45 import SrcLoc
  46 import UniqSupply
  47 import Outputable
  48 \end{code}
  49
  50
  51         ----------------------------
  52                 General notes
  53         ----------------------------
  54
  55 Generally speaking we now type-check types in three phases
  56
  57   1.  kcHsType: kind check the HsType
  58         *includes* performing any TH type splices;
  59         so it returns a translated, and kind-annotated, type
  60
  61   2.  dsHsType: convert from HsType to Type:
  62         perform zonking
  63         expand type synonyms [mkGenTyApps]
  64         hoist the foralls [tcHsType]
  65
  66   3.  checkValidType: check the validity of the resulting type
  67
  68 Often these steps are done one after the other (tcHsSigType).
  69 But in mutually recursive groups of type and class decls we do
  70         1 kind-check the whole group
  71         2 build TyCons/Classes in a knot-tied way
  72         3 check the validity of types in the now-unknotted TyCons/Classes
  73
  74 For example, when we find
  75         (forall a m. m a -> m a)
  76 we bind a,m to kind varibles and kind-check (m a -> m a).  This makes
  77 a get kind *, and m get kind *->*.  Now we typecheck (m a -> m a) in
  78 an environment that binds a and m suitably.
  79
  80 The kind checker passed to tcHsTyVars needs to look at enough to
  81 establish the kind of the tyvar:
  82   * For a group of type and class decls, it's just the group, not
  83         the rest of the program
  84   * For a tyvar bound in a pattern type signature, its the types
  85         mentioned in the other type signatures in that bunch of patterns
  86   * For a tyvar bound in a RULE, it's the type signatures on other
  87         universally quantified variables in the rule
  88
  89 Note that this may occasionally give surprising results.  For example:
  90
  91         data T a b = MkT (a b)
  92
  93 Here we deduce                  a::*->*,       b::*
  94 But equally valid would be      a::(*->*)-> *, b::*->*
  95
  96
  97 Validity checking
  98 ~~~~~~~~~~~~~~~~~
  99 Some of the validity check could in principle be done by the kind checker,
 100 but not all:
 101
 102 - During desugaring, we normalise by expanding type synonyms.  Only
 103   after this step can we check things like type-synonym saturation
 104   e.g.  type T k = k Int
 105         type S a = a
 106   Then (T S) is ok, because T is saturated; (T S) expands to (S Int);
 107   and then S is saturated.  This is a GHC extension.
 108
 109 - Similarly, also a GHC extension, we look through synonyms before complaining
 110   about the form of a class or instance declaration
 111
 112 - Ambiguity checks involve functional dependencies, and it's easier to wait
 113   until knots have been resolved before poking into them
 114
 115 Also, in a mutually recursive group of types, we can't look at the TyCon until we've
 116 finished building the loop.  So to keep things simple, we postpone most validity
 117 checking until step (3).
 118
 119 Knot tying
 120 ~~~~~~~~~~
 121 During step (1) we might fault in a TyCon defined in another module, and it might
 122 (via a loop) refer back to a TyCon defined in this module. So when we tie a big
 123 knot around type declarations with ARecThing, so that the fault-in code can get
 124 the TyCon being defined.
 125
 126
 127 %************************************************************************
 128 %*                                                                      *
 129 \subsection{Checking types}
 130 %*                                                                      *
 131 %************************************************************************
 132
 133 \begin{code}
 134 tcHsSigType :: UserTypeCtxt -> LHsType Name -> TcM Type
 135   -- Do kind checking, and hoist for-alls to the top
 136   -- NB: it's important that the foralls that come from the top-level
 137   --     HsForAllTy in hs_ty occur *first* in the returned type.
 138   --     See Note [Scoped] with TcSigInfo
 139 tcHsSigType ctxt hs_ty
 140   = addErrCtxt (pprHsSigCtxt ctxt hs_ty) $
 141     do  { kinded_ty <- kcTypeType hs_ty
 142         ; ty <- tcHsKindedType kinded_ty
 143         ; checkValidType ctxt ty
 144         ; returnM ty }
 145
 146 -- Used for the deriving(...) items
 147 tcHsDeriv :: LHsType Name -> TcM ([TyVar], Class, [Type])
 148 tcHsDeriv = addLocM (tc_hs_deriv [])
 149
 150 tc_hs_deriv tv_names (HsPredTy (HsClassP cls_name hs_tys))
 151   = kcHsTyVars tv_names                 $ \ tv_names' ->
 152     do  { cls_kind <- kcClass cls_name
 153         ; (tys, res_kind) <- kcApps cls_kind (ppr cls_name) hs_tys
 154         ; tcTyVarBndrs tv_names'        $ \ tyvars ->
 155     do  { arg_tys <- dsHsTypes tys
 156         ; cls <- tcLookupClass cls_name
 157         ; return (tyvars, cls, arg_tys) }}
 158
 159 tc_hs_deriv tv_names1 (HsForAllTy _ tv_names2 (L _ []) (L _ ty))
 160   =     -- Funny newtype deriving form
 161         --      forall a. C [a]
 162         -- where C has arity 2.  Hence can't use regular functions
 163     tc_hs_deriv (tv_names1 ++ tv_names2) ty
 164
 165 tc_hs_deriv _ other
 166   = failWithTc (ptext SLIT("Illegal deriving item") <+> ppr other)
 167 \end{code}
 168
 169         These functions are used during knot-tying in
 170         type and class declarations, when we have to
 171         separate kind-checking, desugaring, and validity checking
 172
 173 \begin{code}
 174 kcHsSigType, kcHsLiftedSigType :: LHsType Name -> TcM (LHsType Name)
 175         -- Used for type signatures
 176 kcHsSigType ty       = kcTypeType ty
 177 kcHsLiftedSigType ty = kcLiftedType ty
 178
 179 tcHsKindedType :: LHsType Name -> TcM Type
 180   -- Don't do kind checking, nor validity checking.
 181   -- This is used in type and class decls, where kinding is
 182   -- done in advance, and validity checking is done later
 183   -- [Validity checking done later because of knot-tying issues.]
 184 tcHsKindedType hs_ty = dsHsType hs_ty
 185
 186 tcHsBangType :: LHsType Name -> TcM Type
 187 -- Permit a bang, but discard it
 188 tcHsBangType (L span (HsBangTy b ty)) = tcHsKindedType ty
 189 tcHsBangType ty                       = tcHsKindedType ty
 190
 191 tcHsKindedContext :: LHsContext Name -> TcM ThetaType
 192 -- Used when we are expecting a ClassContext (i.e. no implicit params)
 193 -- Does not do validity checking, like tcHsKindedType
 194 tcHsKindedContext hs_theta = addLocM (mappM dsHsLPred) hs_theta
 195 \end{code}
 196
 197
 198 %************************************************************************
 199 %*                                                                      *
 200                 The main kind checker: kcHsType
 201 %*                                                                      *
 202 %************************************************************************
 203
 204         First a couple of simple wrappers for kcHsType
 205
 206 \begin{code}
 207 ---------------------------
 208 kcLiftedType :: LHsType Name -> TcM (LHsType Name)
 209 -- The type ty must be a *lifted* *type*
 210 kcLiftedType ty = kcCheckHsType ty liftedTypeKind
 211
 212 ---------------------------
 213 kcTypeType :: LHsType Name -> TcM (LHsType Name)
 214 -- The type ty must be a *type*, but it can be lifted or
 215 -- unlifted or an unboxed tuple.
 216 kcTypeType ty = kcCheckHsType ty openTypeKind
 217
 218 ---------------------------
 219 kcCheckHsType :: LHsType Name -> TcKind -> TcM (LHsType Name)
 220 -- Check that the type has the specified kind
 221 -- Be sure to use checkExpectedKind, rather than simply unifying
 222 -- with OpenTypeKind, because it gives better error messages
 223 kcCheckHsType (L span ty) exp_kind
 224   = setSrcSpan span                             $
 225     do  { (ty', act_kind) <- add_ctxt ty (kc_hs_type ty)
 226                 -- Add the context round the inner check only
 227                 -- because checkExpectedKind already mentions
 228                 -- 'ty' by name in any error message
 229
 230         ; checkExpectedKind (strip ty) act_kind exp_kind
 231         ; return (L span ty') }
 232   where
 233         -- Wrap a context around only if we want to show that contexts.
 234     add_ctxt (HsPredTy p)                thing = thing
 235         -- Omit invisble ones and ones user's won't grok (HsPred p).
 236     add_ctxt (HsForAllTy _ _ (L _ []) _) thing = thing
 237         -- Omit wrapping if the theta-part is empty
 238         -- Reason: the recursive call to kcLiftedType, in the ForAllTy
 239         --         case of kc_hs_type, will do the wrapping instead
 240         --         and we don't want to duplicate
 241     add_ctxt other_ty thing = addErrCtxt (typeCtxt other_ty) thing
 242
 243         -- We infer the kind of the type, and then complain if it's
 244         -- not right.  But we don't want to complain about
 245         --      (ty) or !(ty) or forall a. ty
 246         -- when the real difficulty is with the 'ty' part.
 247     strip (HsParTy (L _ ty))          = strip ty
 248     strip (HsBangTy _ (L _ ty))       = strip ty
 249     strip (HsForAllTy _ _ _ (L _ ty)) = strip ty
 250     strip ty                          = ty
 251 \end{code}
 252
 253         Here comes the main function
 254
 255 \begin{code}
 256 kcHsType :: LHsType Name -> TcM (LHsType Name, TcKind)
 257 kcHsType ty = wrapLocFstM kc_hs_type ty
 258 -- kcHsType *returns* the kind of the type, rather than taking an expected
 259 -- kind as argument as tcExpr does.
 260 -- Reasons:
 261 --      (a) the kind of (->) is
 262 --              forall bx1 bx2. Type bx1 -> Type bx2 -> Type Boxed
 263 --          so we'd need to generate huge numbers of bx variables.
 264 --      (b) kinds are so simple that the error messages are fine
 265 --
 266 -- The translated type has explicitly-kinded type-variable binders
 267
 268 kc_hs_type (HsParTy ty)
 269  = kcHsType ty          `thenM` \ (ty', kind) ->
 270    returnM (HsParTy ty', kind)
 271
 272 kc_hs_type (HsTyVar name)
 273   = kcTyVar name        `thenM` \ kind ->
 274     returnM (HsTyVar name, kind)
 275
 276 kc_hs_type (HsListTy ty)
 277   = kcLiftedType ty                     `thenM` \ ty' ->
 278     returnM (HsListTy ty', liftedTypeKind)
 279
 280 kc_hs_type (HsPArrTy ty)
 281   = kcLiftedType ty                     `thenM` \ ty' ->
 282     returnM (HsPArrTy ty', liftedTypeKind)
 283
 284 kc_hs_type (HsNumTy n)
 285    = returnM (HsNumTy n, liftedTypeKind)
 286
 287 kc_hs_type (HsKindSig ty k)
 288   = kcCheckHsType ty k  `thenM` \ ty' ->
 289     returnM (HsKindSig ty' k, k)
 290
 291 kc_hs_type (HsTupleTy Boxed tys)
 292   = mappM kcLiftedType tys      `thenM` \ tys' ->
 293     returnM (HsTupleTy Boxed tys', liftedTypeKind)
 294
 295 kc_hs_type (HsTupleTy Unboxed tys)
 296   = mappM kcTypeType tys        `thenM` \ tys' ->
 297     returnM (HsTupleTy Unboxed tys', ubxTupleKind)
 298
 299 kc_hs_type (HsFunTy ty1 ty2)
 300   = kcCheckHsType ty1 argTypeKind       `thenM` \ ty1' ->
 301     kcTypeType ty2                      `thenM` \ ty2' ->
 302     returnM (HsFunTy ty1' ty2', liftedTypeKind)
 303
 304 kc_hs_type ty@(HsOpTy ty1 op ty2)
 305   = addLocM kcTyVar op                  `thenM` \ op_kind ->
 306     kcApps op_kind (ppr op) [ty1,ty2]   `thenM` \ ([ty1',ty2'], res_kind) ->
 307     returnM (HsOpTy ty1' op ty2', res_kind)
 308
 309 kc_hs_type ty@(HsAppTy ty1 ty2)
 310   = kcHsType fun_ty                       `thenM` \ (fun_ty', fun_kind) ->
 311     kcApps fun_kind (ppr fun_ty) arg_tys  `thenM` \ ((arg_ty':arg_tys'), res_kind) ->
 312     returnM (foldl mk_app (HsAppTy fun_ty' arg_ty') arg_tys', res_kind)
 313   where
 314     (fun_ty, arg_tys) = split ty1 [ty2]
 315     split (L _ (HsAppTy f a)) as = split f (a:as)
 316     split f                   as = (f,as)
 317     mk_app fun arg = HsAppTy (noLoc fun) arg    -- Add noLocs for inner nodes of
 318                                                 -- the application; they are never used
 319
 320 kc_hs_type (HsPredTy pred)
 321   = kcHsPred pred               `thenM` \ pred' ->
 322     returnM (HsPredTy pred', liftedTypeKind)
 323
 324 kc_hs_type (HsForAllTy exp tv_names context ty)
 325   = kcHsTyVars tv_names         $ \ tv_names' ->
 326     do  { ctxt' <- kcHsContext context
 327         ; ty'   <- kcLiftedType ty
 328              -- The body of a forall is usually a type, but in principle
 329              -- there's no reason to prohibit *unlifted* types.
 330              -- In fact, GHC can itself construct a function with an
 331              -- unboxed tuple inside a for-all (via CPR analyis; see
 332              -- typecheck/should_compile/tc170)
 333              --
 334              -- Still, that's only for internal interfaces, which aren't
 335              -- kind-checked, so we only allow liftedTypeKind here
 336
 337         ; return (HsForAllTy exp tv_names' ctxt' ty', liftedTypeKind) }
 338
 339 kc_hs_type (HsBangTy b ty)
 340   = do { (ty', kind) <- kcHsType ty
 341        ; return (HsBangTy b ty', kind) }
 342
 343 kc_hs_type ty@(HsSpliceTy _)
 344   = failWithTc (ptext SLIT("Unexpected type splice:") <+> ppr ty)
 345
 346 -- remove the doc nodes here, no need to worry about the location since
 347 -- its the same for a doc node and it's child type node
 348 kc_hs_type (HsDocTy ty _)
 349   = kc_hs_type (unLoc ty)
 350
 351 ---------------------------
 352 kcApps :: TcKind                        -- Function kind
 353        -> SDoc                          -- Function
 354        -> [LHsType Name]                -- Arg types
 355        -> TcM ([LHsType Name], TcKind)  -- Kind-checked args
 356 kcApps fun_kind ppr_fun args
 357   = split_fk fun_kind (length args)     `thenM` \ (arg_kinds, res_kind) ->
 358     zipWithM kc_arg args arg_kinds      `thenM` \ args' ->
 359     returnM (args', res_kind)
 360   where
 361     split_fk fk 0 = returnM ([], fk)
 362     split_fk fk n = unifyFunKind fk     `thenM` \ mb_fk ->
 363                     case mb_fk of
 364                         Nothing       -> failWithTc too_many_args
 365                         Just (ak,fk') -> split_fk fk' (n-1)     `thenM` \ (aks, rk) ->
 366                                          returnM (ak:aks, rk)
 367
 368     kc_arg arg arg_kind = kcCheckHsType arg arg_kind
 369
 370     too_many_args = ptext SLIT("Kind error:") <+> quotes ppr_fun <+>
 371                     ptext SLIT("is applied to too many type arguments")
 372
 373 ---------------------------
 374 kcHsContext :: LHsContext Name -> TcM (LHsContext Name)
 375 kcHsContext ctxt = wrapLocM (mappM kcHsLPred) ctxt
 376
 377 kcHsLPred :: LHsPred Name -> TcM (LHsPred Name)
 378 kcHsLPred = wrapLocM kcHsPred
 379
 380 kcHsPred :: HsPred Name -> TcM (HsPred Name)
 381 kcHsPred pred   -- Checks that the result is of kind liftedType
 382   = kc_pred pred                                `thenM` \ (pred', kind) ->
 383     checkExpectedKind pred kind liftedTypeKind  `thenM_`
 384     returnM pred'
 385
 386 ---------------------------
 387 kc_pred :: HsPred Name -> TcM (HsPred Name, TcKind)
 388         -- Does *not* check for a saturated
 389         -- application (reason: used from TcDeriv)
 390 kc_pred pred@(HsIParam name ty)
 391   = do { (ty', kind) <- kcHsType ty
 392        ; returnM (HsIParam name ty', kind)
 393        }
 394 kc_pred pred@(HsClassP cls tys)
 395   = do { kind <- kcClass cls
 396        ; (tys', res_kind) <- kcApps kind (ppr cls) tys
 397        ; returnM (HsClassP cls tys', res_kind)
 398        }
 399 kc_pred pred@(HsEqualP ty1 ty2)
 400   = do { (ty1', kind1) <- kcHsType ty1
 401        ; checkExpectedKind ty1 kind1 liftedTypeKind
 402        ; (ty2', kind2) <- kcHsType ty2
 403        ; checkExpectedKind ty2 kind2 liftedTypeKind
 404        ; returnM (HsEqualP ty1 ty2, liftedTypeKind)
 405        }
 406
 407 ---------------------------
 408 kcTyVar :: Name -> TcM TcKind
 409 kcTyVar name    -- Could be a tyvar or a tycon
 410   = traceTc (text "lk1" <+> ppr name)   `thenM_`
 411     tcLookup name       `thenM` \ thing ->
 412     traceTc (text "lk2" <+> ppr name <+> ppr thing)     `thenM_`
 413     case thing of
 414         ATyVar _ ty             -> returnM (typeKind ty)
 415         AThing kind             -> returnM kind
 416         AGlobal (ATyCon tc)     -> returnM (tyConKind tc)
 417         other                   -> wrongThingErr "type" thing name
 418
 419 kcClass :: Name -> TcM TcKind
 420 kcClass cls     -- Must be a class
 421   = tcLookup cls                                `thenM` \ thing ->
 422     case thing of
 423         AThing kind             -> returnM kind
 424         AGlobal (AClass cls)    -> returnM (tyConKind (classTyCon cls))
 425         other                   -> wrongThingErr "class" thing cls
 426 \end{code}
 427
 428
 429 %************************************************************************
 430 %*                                                                      *
 431                 Desugaring
 432 %*                                                                      *
 433 %************************************************************************
 434
 435 The type desugarer
 436
 437         * Transforms from HsType to Type
 438         * Zonks any kinds
 439
 440 It cannot fail, and does no validity checking, except for
 441 structural matters, such as
 442         (a) spurious ! annotations.
 443         (b) a class used as a type
 444
 445 \begin{code}
 446 dsHsType :: LHsType Name -> TcM Type
 447 -- All HsTyVarBndrs in the intput type are kind-annotated
 448 dsHsType ty = ds_type (unLoc ty)
 449
 450 ds_type ty@(HsTyVar name)
 451   = ds_app ty []
 452
 453 ds_type (HsParTy ty)            -- Remove the parentheses markers
 454   = dsHsType ty
 455
 456 ds_type ty@(HsBangTy _ _)       -- No bangs should be here
 457   = failWithTc (ptext SLIT("Unexpected strictness annotation:") <+> ppr ty)
 458
 459 ds_type (HsKindSig ty k)
 460   = dsHsType ty -- Kind checking done already
 461
 462 ds_type (HsListTy ty)
 463   = dsHsType ty                 `thenM` \ tau_ty ->
 464     checkWiredInTyCon listTyCon `thenM_`
 465     returnM (mkListTy tau_ty)
 466
 467 ds_type (HsPArrTy ty)
 468   = dsHsType ty                 `thenM` \ tau_ty ->
 469     checkWiredInTyCon parrTyCon `thenM_`
 470     returnM (mkPArrTy tau_ty)
 471
 472 ds_type (HsTupleTy boxity tys)
 473   = dsHsTypes tys               `thenM` \ tau_tys ->
 474     checkWiredInTyCon tycon     `thenM_`
 475     returnM (mkTyConApp tycon tau_tys)
 476   where
 477     tycon = tupleTyCon boxity (length tys)
 478
 479 ds_type (HsFunTy ty1 ty2)
 480   = dsHsType ty1                        `thenM` \ tau_ty1 ->
 481     dsHsType ty2                        `thenM` \ tau_ty2 ->
 482     returnM (mkFunTy tau_ty1 tau_ty2)
 483
 484 ds_type (HsOpTy ty1 (L span op) ty2)
 485   = dsHsType ty1                `thenM` \ tau_ty1 ->
 486     dsHsType ty2                `thenM` \ tau_ty2 ->
 487     setSrcSpan span (ds_var_app op [tau_ty1,tau_ty2])
 488
 489 ds_type (HsNumTy n)
 490   = ASSERT(n==1)
 491     tcLookupTyCon genUnitTyConName      `thenM` \ tc ->
 492     returnM (mkTyConApp tc [])
 493
 494 ds_type ty@(HsAppTy _ _)
 495   = ds_app ty []
 496
 497 ds_type (HsPredTy pred)
 498   = dsHsPred pred       `thenM` \ pred' ->
 499     returnM (mkPredTy pred')
 500
 501 ds_type full_ty@(HsForAllTy exp tv_names ctxt ty)
 502   = tcTyVarBndrs tv_names               $ \ tyvars ->
 503     mappM dsHsLPred (unLoc ctxt)        `thenM` \ theta ->
 504     dsHsType ty                         `thenM` \ tau ->
 505     returnM (mkSigmaTy tyvars theta tau)
 506
 507 ds_type (HsSpliceTy {}) = panic "ds_type: HsSpliceTy"
 508
 509 dsHsTypes arg_tys = mappM dsHsType arg_tys
 510 \end{code}
 511
 512 Help functions for type applications
 513 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 514
 515 \begin{code}
 516 ds_app :: HsType Name -> [LHsType Name] -> TcM Type
 517 ds_app (HsAppTy ty1 ty2) tys
 518   = ds_app (unLoc ty1) (ty2:tys)
 519
 520 ds_app ty tys
 521   = dsHsTypes tys                       `thenM` \ arg_tys ->
 522     case ty of
 523         HsTyVar fun -> ds_var_app fun arg_tys
 524         other       -> ds_type ty               `thenM` \ fun_ty ->
 525                        returnM (mkAppTys fun_ty arg_tys)
 526
 527 ds_var_app :: Name -> [Type] -> TcM Type
 528 ds_var_app name arg_tys
 529  = tcLookup name                        `thenM` \ thing ->
 530     case thing of
 531         ATyVar _ ty         -> returnM (mkAppTys ty arg_tys)
 532         AGlobal (ATyCon tc) -> returnM (mkTyConApp tc arg_tys)
 533         other               -> wrongThingErr "type" thing name
 534 \end{code}
 535
 536
 537 Contexts
 538 ~~~~~~~~
 539
 540 \begin{code}
 541 dsHsLPred :: LHsPred Name -> TcM PredType
 542 dsHsLPred pred = dsHsPred (unLoc pred)
 543
 544 dsHsPred pred@(HsClassP class_name tys)
 545   = do { arg_tys <- dsHsTypes tys
 546        ; clas <- tcLookupClass class_name
 547        ; returnM (ClassP clas arg_tys)
 548        }
 549 dsHsPred pred@(HsEqualP ty1 ty2)
 550   = do { arg_ty1 <- dsHsType ty1
 551        ; arg_ty2 <- dsHsType ty2
 552        ; returnM (EqPred arg_ty1 arg_ty2)
 553        }
 554 dsHsPred (HsIParam name ty)
 555   = do { arg_ty <- dsHsType ty
 556        ; returnM (IParam name arg_ty)
 557        }
 558 \end{code}
 559
 560 GADT constructor signatures
 561
 562 \begin{code}
 563 tcLHsConResTy :: LHsType Name -> TcM (TyCon, [TcType])
 564 tcLHsConResTy res_ty
 565   = addErrCtxt (gadtResCtxt res_ty) $
 566     case get_largs res_ty [] of
 567            (HsTyVar tc_name, args)
 568               -> do { args' <- mapM dsHsType args
 569                     ; thing <- tcLookup tc_name
 570                     ; case thing of
 571                         AGlobal (ATyCon tc) -> return (tc, args')
 572                         other -> failWithTc (badGadtDecl res_ty) }
 573            other -> failWithTc (badGadtDecl res_ty)
 574   where
 575         -- We can't call dsHsType on res_ty, and then do tcSplitTyConApp_maybe
 576         -- because that causes a black hole, and for good reason.  Building
 577         -- the type means expanding type synonyms, and we can't do that
 578         -- inside the "knot".  So we have to work by steam.
 579     get_largs (L _ ty) args = get_args ty args
 580     get_args (HsAppTy fun arg)            args = get_largs fun (arg:args)
 581     get_args (HsParTy ty)                 args = get_largs ty  args
 582     get_args (HsOpTy ty1 (L span tc) ty2) args = (HsTyVar tc, ty1:ty2:args)
 583     get_args ty                           args = (ty, args)
 584
 585 gadtResCtxt ty
 586   = hang (ptext SLIT("In the result type of a data constructor:"))
 587        2 (ppr ty)
 588 badGadtDecl ty
 589   = hang (ptext SLIT("Malformed constructor result type:"))
 590        2 (ppr ty)
 591
 592 typeCtxt ty = ptext SLIT("In the type") <+> quotes (ppr ty)
 593 \end{code}
 594
 595 %************************************************************************
 596 %*                                                                      *
 597                 Type-variable binders
 598 %*                                                                      *
 599 %************************************************************************
 600
 601
 602 \begin{code}
 603 kcHsTyVars :: [LHsTyVarBndr Name]
 604            -> ([LHsTyVarBndr Name] -> TcM r)    -- These binders are kind-annotated
 605                                                 -- They scope over the thing inside
 606            -> TcM r
 607 kcHsTyVars tvs thing_inside
 608   = mappM (wrapLocM kcHsTyVar) tvs      `thenM` \ bndrs ->
 609     tcExtendKindEnvTvs bndrs (thing_inside bndrs)
 610
 611 kcHsTyVar :: HsTyVarBndr Name -> TcM (HsTyVarBndr Name)
 612         -- Return a *kind-annotated* binder, and a tyvar with a mutable kind in it
 613 kcHsTyVar (UserTyVar name)        = newKindVar  `thenM` \ kind ->
 614                                     returnM (KindedTyVar name kind)
 615 kcHsTyVar (KindedTyVar name kind) = returnM (KindedTyVar name kind)
 616
 617 ------------------
 618 tcTyVarBndrs :: [LHsTyVarBndr Name]     -- Kind-annotated binders, which need kind-zonking
 619              -> ([TyVar] -> TcM r)
 620              -> TcM r
 621 -- Used when type-checking types/classes/type-decls
 622 -- Brings into scope immutable TyVars, not mutable ones that require later zonking
 623 tcTyVarBndrs bndrs thing_inside
 624   = mapM (zonk . unLoc) bndrs   `thenM` \ tyvars ->
 625     tcExtendTyVarEnv tyvars (thing_inside tyvars)
 626   where
 627     zonk (KindedTyVar name kind) = do { kind' <- zonkTcKindToKind kind
 628                                       ; return (mkTyVar name kind') }
 629     zonk (UserTyVar name) = pprTrace "Un-kinded tyvar" (ppr name) $
 630                             return (mkTyVar name liftedTypeKind)
 631
 632 -----------------------------------
 633 tcDataKindSig :: Maybe Kind -> TcM [TyVar]
 634 -- GADT decls can have a (perhaps partial) kind signature
 635 --      e.g.  data T :: * -> * -> * where ...
 636 -- This function makes up suitable (kinded) type variables for
 637 -- the argument kinds, and checks that the result kind is indeed *.
 638 -- We use it also to make up argument type variables for for data instances.
 639 tcDataKindSig Nothing = return []
 640 tcDataKindSig (Just kind)
 641   = do  { checkTc (isLiftedTypeKind res_kind) (badKindSig kind)
 642         ; span <- getSrcSpanM
 643         ; us   <- newUniqueSupply
 644         ; let loc   = srcSpanStart span
 645               uniqs = uniqsFromSupply us
 646         ; return [ mk_tv loc uniq str kind
 647                  | ((kind, str), uniq) <- arg_kinds `zip` names `zip` uniqs ] }
 648   where
 649     (arg_kinds, res_kind) = splitKindFunTys kind
 650     mk_tv loc uniq str kind = mkTyVar name kind
 651         where
 652            name = mkInternalName uniq occ loc
 653            occ  = mkOccName tvName str
 654
 655     names :: [String]   -- a,b,c...aa,ab,ac etc
 656     names = [ c:cs | cs <- "" : names, c <- ['a'..'z'] ]
 657
 658 badKindSig :: Kind -> SDoc
 659 badKindSig kind
 660  = hang (ptext SLIT("Kind signature on data type declaration has non-* return kind"))
 661         2 (ppr kind)
 662 \end{code}
 663
 664
 665 %************************************************************************
 666 %*                                                                      *
 667                 Scoped type variables
 668 %*                                                                      *
 669 %************************************************************************
 670
 671
 672 tcAddScopedTyVars is used for scoped type variables added by pattern
 673 type signatures
 674         e.g.  \ ((x::a), (y::a)) -> x+y
 675 They never have explicit kinds (because this is source-code only)
 676 They are mutable (because they can get bound to a more specific type).
 677
 678 Usually we kind-infer and expand type splices, and then
 679 tupecheck/desugar the type.  That doesn't work well for scoped type
 680 variables, because they scope left-right in patterns.  (e.g. in the
 681 example above, the 'a' in (y::a) is bound by the 'a' in (x::a).
 682
 683 The current not-very-good plan is to
 684   * find all the types in the patterns
 685   * find their free tyvars
 686   * do kind inference
 687   * bring the kinded type vars into scope
 688   * BUT throw away the kind-checked type
 689         (we'll kind-check it again when we type-check the pattern)
 690
 691 This is bad because throwing away the kind checked type throws away
 692 its splices.  But too bad for now.  [July 03]
 693
 694 Historical note:
 695     We no longer specify that these type variables must be univerally
 696     quantified (lots of email on the subject).  If you want to put that
 697     back in, you need to
 698         a) Do a checkSigTyVars after thing_inside
 699         b) More insidiously, don't pass in expected_ty, else
 700            we unify with it too early and checkSigTyVars barfs
 701            Instead you have to pass in a fresh ty var, and unify
 702            it with expected_ty afterwards
 703
 704 \begin{code}
 705 tcHsPatSigType :: UserTypeCtxt
 706                -> LHsType Name          -- The type signature
 707                -> TcM ([TyVar],         -- Newly in-scope type variables
 708                         Type)           -- The signature
 709 -- Used for type-checking type signatures in
 710 -- (a) patterns           e.g  f (x::Int) = e
 711 -- (b) result signatures  e.g. g x :: Int = e
 712 -- (c) RULE forall bndrs  e.g. forall (x::Int). f x = x
 713
 714 tcHsPatSigType ctxt hs_ty
 715   = addErrCtxt (pprHsSigCtxt ctxt hs_ty) $
 716     do  {       -- Find the type variables that are mentioned in the type
 717                 -- but not already in scope.  These are the ones that
 718                 -- should be bound by the pattern signature
 719           in_scope <- getInLocalScope
 720         ; let span = getLoc hs_ty
 721               sig_tvs = [ L span (UserTyVar n)
 722                         | n <- nameSetToList (extractHsTyVars hs_ty),
 723                           not (in_scope n) ]
 724
 725         -- Behave very like type-checking (HsForAllTy sig_tvs hs_ty),
 726         -- except that we want to keep the tvs separate
 727         ; (kinded_tvs, kinded_ty) <- kcHsTyVars sig_tvs $ \ kinded_tvs -> do
 728                                     { kinded_ty <- kcTypeType hs_ty
 729                                     ; return (kinded_tvs, kinded_ty) }
 730         ; tcTyVarBndrs kinded_tvs $ \ tyvars -> do
 731         { sig_ty <- dsHsType kinded_ty
 732         ; checkValidType ctxt sig_ty
 733         ; return (tyvars, sig_ty)
 734       } }
 735
 736 tcPatSig :: UserTypeCtxt
 737          -> LHsType Name
 738          -> BoxySigmaType
 739          -> TcM (TcType,           -- The type to use for "inside" the signature
 740                  [(Name,TcType)])  -- The new bit of type environment, binding
 741                                    -- the scoped type variables
 742 tcPatSig ctxt sig res_ty
 743   = do  { (sig_tvs, sig_ty) <- tcHsPatSigType ctxt sig
 744
 745         ; if null sig_tvs then do {
 746                 -- The type signature binds no type variables,
 747                 -- and hence is rigid, so use it to zap the res_ty
 748                   boxyUnify sig_ty res_ty
 749                 ; return (sig_ty, [])
 750
 751         } else do {
 752                 -- Type signature binds at least one scoped type variable
 753
 754                 -- A pattern binding cannot bind scoped type variables
 755                 -- The renamer fails with a name-out-of-scope error
 756                 -- if a pattern binding tries to bind a type variable,
 757                 -- So we just have an ASSERT here
 758         ; let in_pat_bind = case ctxt of
 759                                 BindPatSigCtxt -> True
 760                                 other          -> False
 761         ; ASSERT( not in_pat_bind || null sig_tvs ) return ()
 762
 763                 -- Check that pat_ty is rigid
 764         ; checkTc (isRigidTy res_ty) (wobblyPatSig sig_tvs)
 765
 766                 -- Now match the pattern signature against res_ty
 767                 -- For convenience, and uniform-looking error messages
 768                 -- we do the matching by allocating meta type variables,
 769                 -- unifying, and reading out the results.
 770                 -- This is a strictly local operation.
 771         ; box_tvs <- mapM tcInstBoxyTyVar sig_tvs
 772         ; boxyUnify (substTyWith sig_tvs (mkTyVarTys box_tvs) sig_ty) res_ty
 773         ; sig_tv_tys <- mapM readFilledBox box_tvs
 774
 775                 -- Check that each is bound to a distinct type variable,
 776                 -- and one that is not already in scope
 777         ; let tv_binds = map tyVarName sig_tvs `zip` sig_tv_tys
 778         ; binds_in_scope <- getScopedTyVarBinds
 779         ; check binds_in_scope tv_binds
 780
 781                 -- Phew!
 782         ; return (res_ty, tv_binds)
 783         } }
 784   where
 785     check in_scope []            = return ()
 786     check in_scope ((n,ty):rest) = do { check_one in_scope n ty
 787                                       ; check ((n,ty):in_scope) rest }
 788
 789     check_one in_scope n ty
 790         = do { checkTc (tcIsTyVarTy ty) (scopedNonVar n ty)
 791                 -- Must bind to a type variable
 792
 793              ; checkTc (null dups) (dupInScope n (head dups) ty)
 794                 -- Must not bind to the same type variable
 795                 -- as some other in-scope type variable
 796
 797              ; return () }
 798         where
 799           dups = [n' | (n',ty') <- in_scope, tcEqType ty' ty]
 800 \end{code}
 801
 802
 803 %************************************************************************
 804 %*                                                                      *
 805                 Scoped type variables
 806 %*                                                                      *
 807 %************************************************************************
 808
 809 \begin{code}
 810 pprHsSigCtxt :: UserTypeCtxt -> LHsType Name -> SDoc
 811 pprHsSigCtxt ctxt hs_ty = vcat [ ptext SLIT("In") <+> pprUserTypeCtxt ctxt <> colon,
 812                                  nest 2 (pp_sig ctxt) ]
 813   where
 814     pp_sig (FunSigCtxt n)  = pp_n_colon n
 815     pp_sig (ConArgCtxt n)  = pp_n_colon n
 816     pp_sig (ForSigCtxt n)  = pp_n_colon n
 817     pp_sig other           = ppr (unLoc hs_ty)
 818
 819     pp_n_colon n = ppr n <+> dcolon <+> ppr (unLoc hs_ty)
 820
 821
 822 wobblyPatSig sig_tvs
 823   = hang (ptext SLIT("A pattern type signature cannot bind scoped type variables")
 824                 <+> pprQuotedList sig_tvs)
 825        2 (ptext SLIT("unless the pattern has a rigid type context"))
 826
 827 scopedNonVar n ty
 828   = vcat [sep [ptext SLIT("The scoped type variable") <+> quotes (ppr n),
 829                nest 2 (ptext SLIT("is bound to the type") <+> quotes (ppr ty))],
 830           nest 2 (ptext SLIT("You can only bind scoped type variables to type variables"))]
 831
 832 dupInScope n n' ty
 833   = hang (ptext SLIT("The scoped type variables") <+> quotes (ppr n) <+> ptext SLIT("and") <+> quotes (ppr n'))
 834        2 (vcat [ptext SLIT("are bound to the same type (variable)"),
 835                 ptext SLIT("Distinct scoped type variables must be distinct")])
 836 \end{code}
 837