compiler/typecheck/TcHsType.lhs

   1
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcMonoType]{Typechecking user-specified @MonoTypes@}
   5
   6 \begin{code}
   7 module TcHsType (
   8         tcHsSigType, tcHsDeriv,
   9         UserTypeCtxt(..),
  10
  11                 -- Kind checking
  12         kcHsTyVars, kcHsSigType, kcHsLiftedSigType,
  13         kcCheckHsType, kcHsContext, kcHsType,
  14
  15                 -- Typechecking kinded types
  16         tcHsKindedContext, tcHsKindedType, tcHsBangType,
  17         tcTyVarBndrs, dsHsType, tcLHsConResTy,
  18         tcDataKindSig,
  19
  20                 -- Pattern type signatures
  21         tcHsPatSigType, tcPatSig
  22    ) where
  23
  24 #include "HsVersions.h"
  25
  26 import HsSyn            ( HsType(..), LHsType, HsTyVarBndr(..), LHsTyVarBndr,
  27                           LHsContext, HsPred(..), LHsPred )
  28 import RnHsSyn          ( extractHsTyVars )
  29 import TcRnMonad
  30 import TcEnv            ( tcExtendTyVarEnv, tcExtendKindEnvTvs,
  31                           tcLookup, tcLookupClass, tcLookupTyCon,
  32                           TyThing(..), getInLocalScope, getScopedTyVarBinds,
  33                           wrongThingErr
  34                         )
  35 import TcMType          ( newKindVar,
  36                           zonkTcKindToKind,
  37                           tcInstBoxyTyVar, readFilledBox,
  38                           checkValidType
  39                         )
  40 import TcUnify          ( boxyUnify, unifyFunKind, checkExpectedKind )
  41 import TcIface          ( checkWiredInTyCon )
  42 import TcType           ( Type, PredType(..), ThetaType, BoxySigmaType,
  43                           TcType, TcKind, isRigidTy,
  44                           UserTypeCtxt(..), pprUserTypeCtxt,
  45                           substTyWith, mkTyVarTys, tcEqType,
  46                           tcIsTyVarTy, mkFunTy, mkSigmaTy, mkPredTy,
  47                           mkTyConApp, mkAppTys, typeKind )
  48 import {- Kind parts of -} Type                 ( Kind, isLiftedTypeKind, liftedTypeKind, ubxTupleKind,
  49                           openTypeKind, argTypeKind, splitKindFunTys )
  50 import Var              ( TyVar, mkTyVar, tyVarName )
  51 import TyCon            ( TyCon, tyConKind )
  52 import Class            ( Class, classTyCon )
  53 import Name             ( Name, mkInternalName )
  54 import OccName          ( mkOccName, tvName )
  55 import NameSet
  56 import PrelNames        ( genUnitTyConName )
  57 import TysWiredIn       ( mkListTy, listTyCon, mkPArrTy, parrTyCon, tupleTyCon )
  58 import BasicTypes       ( Boxity(..) )
  59 import SrcLoc           ( Located(..), unLoc, noLoc, getLoc, srcSpanStart )
  60 import UniqSupply       ( uniqsFromSupply )
  61 import Outputable
  62 \end{code}
  63
  64
  65         ----------------------------
  66                 General notes
  67         ----------------------------
  68
  69 Generally speaking we now type-check types in three phases
  70
  71   1.  kcHsType: kind check the HsType
  72         *includes* performing any TH type splices;
  73         so it returns a translated, and kind-annotated, type
  74
  75   2.  dsHsType: convert from HsType to Type:
  76         perform zonking
  77         expand type synonyms [mkGenTyApps]
  78         hoist the foralls [tcHsType]
  79
  80   3.  checkValidType: check the validity of the resulting type
  81
  82 Often these steps are done one after the other (tcHsSigType).
  83 But in mutually recursive groups of type and class decls we do
  84         1 kind-check the whole group
  85         2 build TyCons/Classes in a knot-tied way
  86         3 check the validity of types in the now-unknotted TyCons/Classes
  87
  88 For example, when we find
  89         (forall a m. m a -> m a)
  90 we bind a,m to kind varibles and kind-check (m a -> m a).  This makes
  91 a get kind *, and m get kind *->*.  Now we typecheck (m a -> m a) in
  92 an environment that binds a and m suitably.
  93
  94 The kind checker passed to tcHsTyVars needs to look at enough to
  95 establish the kind of the tyvar:
  96   * For a group of type and class decls, it's just the group, not
  97         the rest of the program
  98   * For a tyvar bound in a pattern type signature, its the types
  99         mentioned in the other type signatures in that bunch of patterns
 100   * For a tyvar bound in a RULE, it's the type signatures on other
 101         universally quantified variables in the rule
 102
 103 Note that this may occasionally give surprising results.  For example:
 104
 105         data T a b = MkT (a b)
 106
 107 Here we deduce                  a::*->*,       b::*
 108 But equally valid would be      a::(*->*)-> *, b::*->*
 109
 110
 111 Validity checking
 112 ~~~~~~~~~~~~~~~~~
 113 Some of the validity check could in principle be done by the kind checker,
 114 but not all:
 115
 116 - During desugaring, we normalise by expanding type synonyms.  Only
 117   after this step can we check things like type-synonym saturation
 118   e.g.  type T k = k Int
 119         type S a = a
 120   Then (T S) is ok, because T is saturated; (T S) expands to (S Int);
 121   and then S is saturated.  This is a GHC extension.
 122
 123 - Similarly, also a GHC extension, we look through synonyms before complaining
 124   about the form of a class or instance declaration
 125
 126 - Ambiguity checks involve functional dependencies, and it's easier to wait
 127   until knots have been resolved before poking into them
 128
 129 Also, in a mutually recursive group of types, we can't look at the TyCon until we've
 130 finished building the loop.  So to keep things simple, we postpone most validity
 131 checking until step (3).
 132
 133 Knot tying
 134 ~~~~~~~~~~
 135 During step (1) we might fault in a TyCon defined in another module, and it might
 136 (via a loop) refer back to a TyCon defined in this module. So when we tie a big
 137 knot around type declarations with ARecThing, so that the fault-in code can get
 138 the TyCon being defined.
 139
 140
 141 %************************************************************************
 142 %*                                                                      *
 143 \subsection{Checking types}
 144 %*                                                                      *
 145 %************************************************************************
 146
 147 \begin{code}
 148 tcHsSigType :: UserTypeCtxt -> LHsType Name -> TcM Type
 149   -- Do kind checking, and hoist for-alls to the top
 150   -- NB: it's important that the foralls that come from the top-level
 151   --     HsForAllTy in hs_ty occur *first* in the returned type.
 152   --     See Note [Scoped] with TcSigInfo
 153 tcHsSigType ctxt hs_ty
 154   = addErrCtxt (pprHsSigCtxt ctxt hs_ty) $
 155     do  { kinded_ty <- kcTypeType hs_ty
 156         ; ty <- tcHsKindedType kinded_ty
 157         ; checkValidType ctxt ty
 158         ; returnM ty }
 159
 160 -- Used for the deriving(...) items
 161 tcHsDeriv :: LHsType Name -> TcM ([TyVar], Class, [Type])
 162 tcHsDeriv = addLocM (tc_hs_deriv [])
 163
 164 tc_hs_deriv tv_names (HsPredTy (HsClassP cls_name hs_tys))
 165   = kcHsTyVars tv_names                 $ \ tv_names' ->
 166     do  { cls_kind <- kcClass cls_name
 167         ; (tys, res_kind) <- kcApps cls_kind (ppr cls_name) hs_tys
 168         ; tcTyVarBndrs tv_names'        $ \ tyvars ->
 169     do  { arg_tys <- dsHsTypes tys
 170         ; cls <- tcLookupClass cls_name
 171         ; return (tyvars, cls, arg_tys) }}
 172
 173 tc_hs_deriv tv_names1 (HsForAllTy _ tv_names2 (L _ []) (L _ ty))
 174   =     -- Funny newtype deriving form
 175         --      forall a. C [a]
 176         -- where C has arity 2.  Hence can't use regular functions
 177     tc_hs_deriv (tv_names1 ++ tv_names2) ty
 178
 179 tc_hs_deriv _ other
 180   = failWithTc (ptext SLIT("Illegal deriving item") <+> ppr other)
 181 \end{code}
 182
 183         These functions are used during knot-tying in
 184         type and class declarations, when we have to
 185         separate kind-checking, desugaring, and validity checking
 186
 187 \begin{code}
 188 kcHsSigType, kcHsLiftedSigType :: LHsType Name -> TcM (LHsType Name)
 189         -- Used for type signatures
 190 kcHsSigType ty       = kcTypeType ty
 191 kcHsLiftedSigType ty = kcLiftedType ty
 192
 193 tcHsKindedType :: LHsType Name -> TcM Type
 194   -- Don't do kind checking, nor validity checking.
 195   -- This is used in type and class decls, where kinding is
 196   -- done in advance, and validity checking is done later
 197   -- [Validity checking done later because of knot-tying issues.]
 198 tcHsKindedType hs_ty = dsHsType hs_ty
 199
 200 tcHsBangType :: LHsType Name -> TcM Type
 201 -- Permit a bang, but discard it
 202 tcHsBangType (L span (HsBangTy b ty)) = tcHsKindedType ty
 203 tcHsBangType ty                       = tcHsKindedType ty
 204
 205 tcHsKindedContext :: LHsContext Name -> TcM ThetaType
 206 -- Used when we are expecting a ClassContext (i.e. no implicit params)
 207 -- Does not do validity checking, like tcHsKindedType
 208 tcHsKindedContext hs_theta = addLocM (mappM dsHsLPred) hs_theta
 209 \end{code}
 210
 211
 212 %************************************************************************
 213 %*                                                                      *
 214                 The main kind checker: kcHsType
 215 %*                                                                      *
 216 %************************************************************************
 217
 218         First a couple of simple wrappers for kcHsType
 219
 220 \begin{code}
 221 ---------------------------
 222 kcLiftedType :: LHsType Name -> TcM (LHsType Name)
 223 -- The type ty must be a *lifted* *type*
 224 kcLiftedType ty = kcCheckHsType ty liftedTypeKind
 225
 226 ---------------------------
 227 kcTypeType :: LHsType Name -> TcM (LHsType Name)
 228 -- The type ty must be a *type*, but it can be lifted or
 229 -- unlifted or an unboxed tuple.
 230 kcTypeType ty = kcCheckHsType ty openTypeKind
 231
 232 ---------------------------
 233 kcCheckHsType :: LHsType Name -> TcKind -> TcM (LHsType Name)
 234 -- Check that the type has the specified kind
 235 -- Be sure to use checkExpectedKind, rather than simply unifying
 236 -- with OpenTypeKind, because it gives better error messages
 237 kcCheckHsType (L span ty) exp_kind
 238   = setSrcSpan span                             $
 239     do  { (ty', act_kind) <- add_ctxt ty (kc_hs_type ty)
 240                 -- Add the context round the inner check only
 241                 -- because checkExpectedKind already mentions
 242                 -- 'ty' by name in any error message
 243
 244         ; checkExpectedKind (strip ty) act_kind exp_kind
 245         ; return (L span ty') }
 246   where
 247         -- Wrap a context around only if we want to show that contexts.
 248     add_ctxt (HsPredTy p)                thing = thing
 249         -- Omit invisble ones and ones user's won't grok (HsPred p).
 250     add_ctxt (HsForAllTy _ _ (L _ []) _) thing = thing
 251         -- Omit wrapping if the theta-part is empty
 252         -- Reason: the recursive call to kcLiftedType, in the ForAllTy
 253         --         case of kc_hs_type, will do the wrapping instead
 254         --         and we don't want to duplicate
 255     add_ctxt other_ty thing = addErrCtxt (typeCtxt other_ty) thing
 256
 257         -- We infer the kind of the type, and then complain if it's
 258         -- not right.  But we don't want to complain about
 259         --      (ty) or !(ty) or forall a. ty
 260         -- when the real difficulty is with the 'ty' part.
 261     strip (HsParTy (L _ ty))          = strip ty
 262     strip (HsBangTy _ (L _ ty))       = strip ty
 263     strip (HsForAllTy _ _ _ (L _ ty)) = strip ty
 264     strip ty                          = ty
 265 \end{code}
 266
 267         Here comes the main function
 268
 269 \begin{code}
 270 kcHsType :: LHsType Name -> TcM (LHsType Name, TcKind)
 271 kcHsType ty = wrapLocFstM kc_hs_type ty
 272 -- kcHsType *returns* the kind of the type, rather than taking an expected
 273 -- kind as argument as tcExpr does.
 274 -- Reasons:
 275 --      (a) the kind of (->) is
 276 --              forall bx1 bx2. Type bx1 -> Type bx2 -> Type Boxed
 277 --          so we'd need to generate huge numbers of bx variables.
 278 --      (b) kinds are so simple that the error messages are fine
 279 --
 280 -- The translated type has explicitly-kinded type-variable binders
 281
 282 kc_hs_type (HsParTy ty)
 283  = kcHsType ty          `thenM` \ (ty', kind) ->
 284    returnM (HsParTy ty', kind)
 285
 286 kc_hs_type (HsTyVar name)
 287   = kcTyVar name        `thenM` \ kind ->
 288     returnM (HsTyVar name, kind)
 289
 290 kc_hs_type (HsListTy ty)
 291   = kcLiftedType ty                     `thenM` \ ty' ->
 292     returnM (HsListTy ty', liftedTypeKind)
 293
 294 kc_hs_type (HsPArrTy ty)
 295   = kcLiftedType ty                     `thenM` \ ty' ->
 296     returnM (HsPArrTy ty', liftedTypeKind)
 297
 298 kc_hs_type (HsNumTy n)
 299    = returnM (HsNumTy n, liftedTypeKind)
 300
 301 kc_hs_type (HsKindSig ty k)
 302   = kcCheckHsType ty k  `thenM` \ ty' ->
 303     returnM (HsKindSig ty' k, k)
 304
 305 kc_hs_type (HsTupleTy Boxed tys)
 306   = mappM kcLiftedType tys      `thenM` \ tys' ->
 307     returnM (HsTupleTy Boxed tys', liftedTypeKind)
 308
 309 kc_hs_type (HsTupleTy Unboxed tys)
 310   = mappM kcTypeType tys        `thenM` \ tys' ->
 311     returnM (HsTupleTy Unboxed tys', ubxTupleKind)
 312
 313 kc_hs_type (HsFunTy ty1 ty2)
 314   = kcCheckHsType ty1 argTypeKind       `thenM` \ ty1' ->
 315     kcTypeType ty2                      `thenM` \ ty2' ->
 316     returnM (HsFunTy ty1' ty2', liftedTypeKind)
 317
 318 kc_hs_type ty@(HsOpTy ty1 op ty2)
 319   = addLocM kcTyVar op                  `thenM` \ op_kind ->
 320     kcApps op_kind (ppr op) [ty1,ty2]   `thenM` \ ([ty1',ty2'], res_kind) ->
 321     returnM (HsOpTy ty1' op ty2', res_kind)
 322
 323 kc_hs_type ty@(HsAppTy ty1 ty2)
 324   = kcHsType fun_ty                       `thenM` \ (fun_ty', fun_kind) ->
 325     kcApps fun_kind (ppr fun_ty) arg_tys  `thenM` \ ((arg_ty':arg_tys'), res_kind) ->
 326     returnM (foldl mk_app (HsAppTy fun_ty' arg_ty') arg_tys', res_kind)
 327   where
 328     (fun_ty, arg_tys) = split ty1 [ty2]
 329     split (L _ (HsAppTy f a)) as = split f (a:as)
 330     split f                   as = (f,as)
 331     mk_app fun arg = HsAppTy (noLoc fun) arg    -- Add noLocs for inner nodes of
 332                                                 -- the application; they are never used
 333
 334 kc_hs_type (HsPredTy pred)
 335   = kcHsPred pred               `thenM` \ pred' ->
 336     returnM (HsPredTy pred', liftedTypeKind)
 337
 338 kc_hs_type (HsForAllTy exp tv_names context ty)
 339   = kcHsTyVars tv_names         $ \ tv_names' ->
 340     do  { ctxt' <- kcHsContext context
 341         ; ty'   <- kcLiftedType ty
 342              -- The body of a forall is usually a type, but in principle
 343              -- there's no reason to prohibit *unlifted* types.
 344              -- In fact, GHC can itself construct a function with an
 345              -- unboxed tuple inside a for-all (via CPR analyis; see
 346              -- typecheck/should_compile/tc170)
 347              --
 348              -- Still, that's only for internal interfaces, which aren't
 349              -- kind-checked, so we only allow liftedTypeKind here
 350
 351         ; return (HsForAllTy exp tv_names' ctxt' ty', liftedTypeKind) }
 352
 353 kc_hs_type (HsBangTy b ty)
 354   = do { (ty', kind) <- kcHsType ty
 355        ; return (HsBangTy b ty', kind) }
 356
 357 kc_hs_type ty@(HsSpliceTy _)
 358   = failWithTc (ptext SLIT("Unexpected type splice:") <+> ppr ty)
 359
 360 -- remove the doc nodes here, no need to worry about the location since
 361 -- its the same for a doc node and it's child type node
 362 kc_hs_type (HsDocTy ty _)
 363   = kc_hs_type (unLoc ty)
 364
 365 ---------------------------
 366 kcApps :: TcKind                        -- Function kind
 367        -> SDoc                          -- Function
 368        -> [LHsType Name]                -- Arg types
 369        -> TcM ([LHsType Name], TcKind)  -- Kind-checked args
 370 kcApps fun_kind ppr_fun args
 371   = split_fk fun_kind (length args)     `thenM` \ (arg_kinds, res_kind) ->
 372     zipWithM kc_arg args arg_kinds      `thenM` \ args' ->
 373     returnM (args', res_kind)
 374   where
 375     split_fk fk 0 = returnM ([], fk)
 376     split_fk fk n = unifyFunKind fk     `thenM` \ mb_fk ->
 377                     case mb_fk of
 378                         Nothing       -> failWithTc too_many_args
 379                         Just (ak,fk') -> split_fk fk' (n-1)     `thenM` \ (aks, rk) ->
 380                                          returnM (ak:aks, rk)
 381
 382     kc_arg arg arg_kind = kcCheckHsType arg arg_kind
 383
 384     too_many_args = ptext SLIT("Kind error:") <+> quotes ppr_fun <+>
 385                     ptext SLIT("is applied to too many type arguments")
 386
 387 ---------------------------
 388 kcHsContext :: LHsContext Name -> TcM (LHsContext Name)
 389 kcHsContext ctxt = wrapLocM (mappM kcHsLPred) ctxt
 390
 391 kcHsLPred :: LHsPred Name -> TcM (LHsPred Name)
 392 kcHsLPred = wrapLocM kcHsPred
 393
 394 kcHsPred :: HsPred Name -> TcM (HsPred Name)
 395 kcHsPred pred   -- Checks that the result is of kind liftedType
 396   = kc_pred pred                                `thenM` \ (pred', kind) ->
 397     checkExpectedKind pred kind liftedTypeKind  `thenM_`
 398     returnM pred'
 399
 400 ---------------------------
 401 kc_pred :: HsPred Name -> TcM (HsPred Name, TcKind)
 402         -- Does *not* check for a saturated
 403         -- application (reason: used from TcDeriv)
 404 kc_pred pred@(HsIParam name ty)
 405   = kcHsType ty         `thenM` \ (ty', kind) ->
 406     returnM (HsIParam name ty', kind)
 407
 408 kc_pred pred@(HsClassP cls tys)
 409   = kcClass cls                 `thenM` \ kind ->
 410     kcApps kind (ppr cls) tys   `thenM` \ (tys', res_kind) ->
 411     returnM (HsClassP cls tys', res_kind)
 412
 413 ---------------------------
 414 kcTyVar :: Name -> TcM TcKind
 415 kcTyVar name    -- Could be a tyvar or a tycon
 416   = traceTc (text "lk1" <+> ppr name)   `thenM_`
 417     tcLookup name       `thenM` \ thing ->
 418     traceTc (text "lk2" <+> ppr name <+> ppr thing)     `thenM_`
 419     case thing of
 420         ATyVar _ ty             -> returnM (typeKind ty)
 421         AThing kind             -> returnM kind
 422         AGlobal (ATyCon tc)     -> returnM (tyConKind tc)
 423         other                   -> wrongThingErr "type" thing name
 424
 425 kcClass :: Name -> TcM TcKind
 426 kcClass cls     -- Must be a class
 427   = tcLookup cls                                `thenM` \ thing ->
 428     case thing of
 429         AThing kind             -> returnM kind
 430         AGlobal (AClass cls)    -> returnM (tyConKind (classTyCon cls))
 431         other                   -> wrongThingErr "class" thing cls
 432 \end{code}
 433
 434
 435 %************************************************************************
 436 %*                                                                      *
 437                 Desugaring
 438 %*                                                                      *
 439 %************************************************************************
 440
 441 The type desugarer
 442
 443         * Transforms from HsType to Type
 444         * Zonks any kinds
 445
 446 It cannot fail, and does no validity checking, except for
 447 structural matters, such as
 448         (a) spurious ! annotations.
 449         (b) a class used as a type
 450
 451 \begin{code}
 452 dsHsType :: LHsType Name -> TcM Type
 453 -- All HsTyVarBndrs in the intput type are kind-annotated
 454 dsHsType ty = ds_type (unLoc ty)
 455
 456 ds_type ty@(HsTyVar name)
 457   = ds_app ty []
 458
 459 ds_type (HsParTy ty)            -- Remove the parentheses markers
 460   = dsHsType ty
 461
 462 ds_type ty@(HsBangTy _ _)       -- No bangs should be here
 463   = failWithTc (ptext SLIT("Unexpected strictness annotation:") <+> ppr ty)
 464
 465 ds_type (HsKindSig ty k)
 466   = dsHsType ty -- Kind checking done already
 467
 468 ds_type (HsListTy ty)
 469   = dsHsType ty                 `thenM` \ tau_ty ->
 470     checkWiredInTyCon listTyCon `thenM_`
 471     returnM (mkListTy tau_ty)
 472
 473 ds_type (HsPArrTy ty)
 474   = dsHsType ty                 `thenM` \ tau_ty ->
 475     checkWiredInTyCon parrTyCon `thenM_`
 476     returnM (mkPArrTy tau_ty)
 477
 478 ds_type (HsTupleTy boxity tys)
 479   = dsHsTypes tys               `thenM` \ tau_tys ->
 480     checkWiredInTyCon tycon     `thenM_`
 481     returnM (mkTyConApp tycon tau_tys)
 482   where
 483     tycon = tupleTyCon boxity (length tys)
 484
 485 ds_type (HsFunTy ty1 ty2)
 486   = dsHsType ty1                        `thenM` \ tau_ty1 ->
 487     dsHsType ty2                        `thenM` \ tau_ty2 ->
 488     returnM (mkFunTy tau_ty1 tau_ty2)
 489
 490 ds_type (HsOpTy ty1 (L span op) ty2)
 491   = dsHsType ty1                `thenM` \ tau_ty1 ->
 492     dsHsType ty2                `thenM` \ tau_ty2 ->
 493     setSrcSpan span (ds_var_app op [tau_ty1,tau_ty2])
 494
 495 ds_type (HsNumTy n)
 496   = ASSERT(n==1)
 497     tcLookupTyCon genUnitTyConName      `thenM` \ tc ->
 498     returnM (mkTyConApp tc [])
 499
 500 ds_type ty@(HsAppTy _ _)
 501   = ds_app ty []
 502
 503 ds_type (HsPredTy pred)
 504   = dsHsPred pred       `thenM` \ pred' ->
 505     returnM (mkPredTy pred')
 506
 507 ds_type full_ty@(HsForAllTy exp tv_names ctxt ty)
 508   = tcTyVarBndrs tv_names               $ \ tyvars ->
 509     mappM dsHsLPred (unLoc ctxt)        `thenM` \ theta ->
 510     dsHsType ty                         `thenM` \ tau ->
 511     returnM (mkSigmaTy tyvars theta tau)
 512
 513 ds_type (HsSpliceTy {}) = panic "ds_type: HsSpliceTy"
 514
 515 dsHsTypes arg_tys = mappM dsHsType arg_tys
 516 \end{code}
 517
 518 Help functions for type applications
 519 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 520
 521 \begin{code}
 522 ds_app :: HsType Name -> [LHsType Name] -> TcM Type
 523 ds_app (HsAppTy ty1 ty2) tys
 524   = ds_app (unLoc ty1) (ty2:tys)
 525
 526 ds_app ty tys
 527   = dsHsTypes tys                       `thenM` \ arg_tys ->
 528     case ty of
 529         HsTyVar fun -> ds_var_app fun arg_tys
 530         other       -> ds_type ty               `thenM` \ fun_ty ->
 531                        returnM (mkAppTys fun_ty arg_tys)
 532
 533 ds_var_app :: Name -> [Type] -> TcM Type
 534 ds_var_app name arg_tys
 535  = tcLookup name                        `thenM` \ thing ->
 536     case thing of
 537         ATyVar _ ty         -> returnM (mkAppTys ty arg_tys)
 538         AGlobal (ATyCon tc) -> returnM (mkTyConApp tc arg_tys)
 539         other               -> wrongThingErr "type" thing name
 540 \end{code}
 541
 542
 543 Contexts
 544 ~~~~~~~~
 545
 546 \begin{code}
 547 dsHsLPred :: LHsPred Name -> TcM PredType
 548 dsHsLPred pred = dsHsPred (unLoc pred)
 549
 550 dsHsPred pred@(HsClassP class_name tys)
 551   = dsHsTypes tys                       `thenM` \ arg_tys ->
 552     tcLookupClass class_name            `thenM` \ clas ->
 553     returnM (ClassP clas arg_tys)
 554
 555 dsHsPred (HsIParam name ty)
 556   = dsHsType ty                                 `thenM` \ arg_ty ->
 557     returnM (IParam name arg_ty)
 558 \end{code}
 559
 560 GADT constructor signatures
 561
 562 \begin{code}
 563 tcLHsConResTy :: LHsType Name -> TcM (TyCon, [TcType])
 564 tcLHsConResTy res_ty
 565   = addErrCtxt (gadtResCtxt res_ty) $
 566     case get_largs res_ty [] of
 567            (HsTyVar tc_name, args)
 568               -> do { args' <- mapM dsHsType args
 569                     ; thing <- tcLookup tc_name
 570                     ; case thing of
 571                         AGlobal (ATyCon tc) -> return (tc, args')
 572                         other -> failWithTc (badGadtDecl res_ty) }
 573            other -> failWithTc (badGadtDecl res_ty)
 574   where
 575         -- We can't call dsHsType on res_ty, and then do tcSplitTyConApp_maybe
 576         -- because that causes a black hole, and for good reason.  Building
 577         -- the type means expanding type synonyms, and we can't do that
 578         -- inside the "knot".  So we have to work by steam.
 579     get_largs (L _ ty) args = get_args ty args
 580     get_args (HsAppTy fun arg)            args = get_largs fun (arg:args)
 581     get_args (HsParTy ty)                 args = get_largs ty  args
 582     get_args (HsOpTy ty1 (L span tc) ty2) args = (HsTyVar tc, ty1:ty2:args)
 583     get_args ty                           args = (ty, args)
 584
 585 gadtResCtxt ty
 586   = hang (ptext SLIT("In the result type of a data constructor:"))
 587        2 (ppr ty)
 588 badGadtDecl ty
 589   = hang (ptext SLIT("Malformed constructor result type:"))
 590        2 (ppr ty)
 591
 592 typeCtxt ty = ptext SLIT("In the type") <+> quotes (ppr ty)
 593 \end{code}
 594
 595 %************************************************************************
 596 %*                                                                      *
 597                 Type-variable binders
 598 %*                                                                      *
 599 %************************************************************************
 600
 601
 602 \begin{code}
 603 kcHsTyVars :: [LHsTyVarBndr Name]
 604            -> ([LHsTyVarBndr Name] -> TcM r)    -- These binders are kind-annotated
 605                                                 -- They scope over the thing inside
 606            -> TcM r
 607 kcHsTyVars tvs thing_inside
 608   = mappM (wrapLocM kcHsTyVar) tvs      `thenM` \ bndrs ->
 609     tcExtendKindEnvTvs bndrs (thing_inside bndrs)
 610
 611 kcHsTyVar :: HsTyVarBndr Name -> TcM (HsTyVarBndr Name)
 612         -- Return a *kind-annotated* binder, and a tyvar with a mutable kind in it
 613 kcHsTyVar (UserTyVar name)        = newKindVar  `thenM` \ kind ->
 614                                     returnM (KindedTyVar name kind)
 615 kcHsTyVar (KindedTyVar name kind) = returnM (KindedTyVar name kind)
 616
 617 ------------------
 618 tcTyVarBndrs :: [LHsTyVarBndr Name]     -- Kind-annotated binders, which need kind-zonking
 619              -> ([TyVar] -> TcM r)
 620              -> TcM r
 621 -- Used when type-checking types/classes/type-decls
 622 -- Brings into scope immutable TyVars, not mutable ones that require later zonking
 623 tcTyVarBndrs bndrs thing_inside
 624   = mapM (zonk . unLoc) bndrs   `thenM` \ tyvars ->
 625     tcExtendTyVarEnv tyvars (thing_inside tyvars)
 626   where
 627     zonk (KindedTyVar name kind) = do { kind' <- zonkTcKindToKind kind
 628                                       ; return (mkTyVar name kind') }
 629     zonk (UserTyVar name) = pprTrace "Un-kinded tyvar" (ppr name) $
 630                             return (mkTyVar name liftedTypeKind)
 631
 632 -----------------------------------
 633 tcDataKindSig :: Maybe Kind -> TcM [TyVar]
 634 -- GADT decls can have a (perhaps partial) kind signature
 635 --      e.g.  data T :: * -> * -> * where ...
 636 -- This function makes up suitable (kinded) type variables for
 637 -- the argument kinds, and checks that the result kind is indeed *.
 638 -- We use it also to make up argument type variables for for data instances.
 639 tcDataKindSig Nothing = return []
 640 tcDataKindSig (Just kind)
 641   = do  { checkTc (isLiftedTypeKind res_kind) (badKindSig kind)
 642         ; span <- getSrcSpanM
 643         ; us   <- newUniqueSupply
 644         ; let loc   = srcSpanStart span
 645               uniqs = uniqsFromSupply us
 646         ; return [ mk_tv loc uniq str kind
 647                  | ((kind, str), uniq) <- arg_kinds `zip` names `zip` uniqs ] }
 648   where
 649     (arg_kinds, res_kind) = splitKindFunTys kind
 650     mk_tv loc uniq str kind = mkTyVar name kind
 651         where
 652            name = mkInternalName uniq occ loc
 653            occ  = mkOccName tvName str
 654
 655     names :: [String]   -- a,b,c...aa,ab,ac etc
 656     names = [ c:cs | cs <- "" : names, c <- ['a'..'z'] ]
 657
 658 badKindSig :: Kind -> SDoc
 659 badKindSig kind
 660  = hang (ptext SLIT("Kind signature on data type declaration has non-* return kind"))
 661         2 (ppr kind)
 662 \end{code}
 663
 664
 665 %************************************************************************
 666 %*                                                                      *
 667                 Scoped type variables
 668 %*                                                                      *
 669 %************************************************************************
 670
 671
 672 tcAddScopedTyVars is used for scoped type variables added by pattern
 673 type signatures
 674         e.g.  \ ((x::a), (y::a)) -> x+y
 675 They never have explicit kinds (because this is source-code only)
 676 They are mutable (because they can get bound to a more specific type).
 677
 678 Usually we kind-infer and expand type splices, and then
 679 tupecheck/desugar the type.  That doesn't work well for scoped type
 680 variables, because they scope left-right in patterns.  (e.g. in the
 681 example above, the 'a' in (y::a) is bound by the 'a' in (x::a).
 682
 683 The current not-very-good plan is to
 684   * find all the types in the patterns
 685   * find their free tyvars
 686   * do kind inference
 687   * bring the kinded type vars into scope
 688   * BUT throw away the kind-checked type
 689         (we'll kind-check it again when we type-check the pattern)
 690
 691 This is bad because throwing away the kind checked type throws away
 692 its splices.  But too bad for now.  [July 03]
 693
 694 Historical note:
 695     We no longer specify that these type variables must be univerally
 696     quantified (lots of email on the subject).  If you want to put that
 697     back in, you need to
 698         a) Do a checkSigTyVars after thing_inside
 699         b) More insidiously, don't pass in expected_ty, else
 700            we unify with it too early and checkSigTyVars barfs
 701            Instead you have to pass in a fresh ty var, and unify
 702            it with expected_ty afterwards
 703
 704 \begin{code}
 705 tcHsPatSigType :: UserTypeCtxt
 706                -> LHsType Name          -- The type signature
 707                -> TcM ([TyVar],         -- Newly in-scope type variables
 708                         Type)           -- The signature
 709 -- Used for type-checking type signatures in
 710 -- (a) patterns           e.g  f (x::Int) = e
 711 -- (b) result signatures  e.g. g x :: Int = e
 712 -- (c) RULE forall bndrs  e.g. forall (x::Int). f x = x
 713
 714 tcHsPatSigType ctxt hs_ty
 715   = addErrCtxt (pprHsSigCtxt ctxt hs_ty) $
 716     do  {       -- Find the type variables that are mentioned in the type
 717                 -- but not already in scope.  These are the ones that
 718                 -- should be bound by the pattern signature
 719           in_scope <- getInLocalScope
 720         ; let span = getLoc hs_ty
 721               sig_tvs = [ L span (UserTyVar n)
 722                         | n <- nameSetToList (extractHsTyVars hs_ty),
 723                           not (in_scope n) ]
 724
 725         -- Behave very like type-checking (HsForAllTy sig_tvs hs_ty),
 726         -- except that we want to keep the tvs separate
 727         ; (kinded_tvs, kinded_ty) <- kcHsTyVars sig_tvs $ \ kinded_tvs -> do
 728                                     { kinded_ty <- kcTypeType hs_ty
 729                                     ; return (kinded_tvs, kinded_ty) }
 730         ; tcTyVarBndrs kinded_tvs $ \ tyvars -> do
 731         { sig_ty <- dsHsType kinded_ty
 732         ; checkValidType ctxt sig_ty
 733         ; return (tyvars, sig_ty)
 734       } }
 735
 736 tcPatSig :: UserTypeCtxt
 737          -> LHsType Name
 738          -> BoxySigmaType
 739          -> TcM (TcType,           -- The type to use for "inside" the signature
 740                  [(Name,TcType)])  -- The new bit of type environment, binding
 741                                    -- the scoped type variables
 742 tcPatSig ctxt sig res_ty
 743   = do  { (sig_tvs, sig_ty) <- tcHsPatSigType ctxt sig
 744
 745         ; if null sig_tvs then do {
 746                 -- The type signature binds no type variables,
 747                 -- and hence is rigid, so use it to zap the res_ty
 748                   boxyUnify sig_ty res_ty
 749                 ; return (sig_ty, [])
 750
 751         } else do {
 752                 -- Type signature binds at least one scoped type variable
 753
 754                 -- A pattern binding cannot bind scoped type variables
 755                 -- The renamer fails with a name-out-of-scope error
 756                 -- if a pattern binding tries to bind a type variable,
 757                 -- So we just have an ASSERT here
 758         ; let in_pat_bind = case ctxt of
 759                                 BindPatSigCtxt -> True
 760                                 other          -> False
 761         ; ASSERT( not in_pat_bind || null sig_tvs ) return ()
 762
 763                 -- Check that pat_ty is rigid
 764         ; checkTc (isRigidTy res_ty) (wobblyPatSig sig_tvs)
 765
 766                 -- Now match the pattern signature against res_ty
 767                 -- For convenience, and uniform-looking error messages
 768                 -- we do the matching by allocating meta type variables,
 769                 -- unifying, and reading out the results.
 770                 -- This is a strictly local operation.
 771         ; box_tvs <- mapM tcInstBoxyTyVar sig_tvs
 772         ; boxyUnify (substTyWith sig_tvs (mkTyVarTys box_tvs) sig_ty) res_ty
 773         ; sig_tv_tys <- mapM readFilledBox box_tvs
 774
 775                 -- Check that each is bound to a distinct type variable,
 776                 -- and one that is not already in scope
 777         ; let tv_binds = map tyVarName sig_tvs `zip` sig_tv_tys
 778         ; binds_in_scope <- getScopedTyVarBinds
 779         ; check binds_in_scope tv_binds
 780
 781                 -- Phew!
 782         ; return (res_ty, tv_binds)
 783         } }
 784   where
 785     check in_scope []            = return ()
 786     check in_scope ((n,ty):rest) = do { check_one in_scope n ty
 787                                       ; check ((n,ty):in_scope) rest }
 788
 789     check_one in_scope n ty
 790         = do { checkTc (tcIsTyVarTy ty) (scopedNonVar n ty)
 791                 -- Must bind to a type variable
 792
 793              ; checkTc (null dups) (dupInScope n (head dups) ty)
 794                 -- Must not bind to the same type variable
 795                 -- as some other in-scope type variable
 796
 797              ; return () }
 798         where
 799           dups = [n' | (n',ty') <- in_scope, tcEqType ty' ty]
 800 \end{code}
 801
 802
 803 %************************************************************************
 804 %*                                                                      *
 805                 Scoped type variables
 806 %*                                                                      *
 807 %************************************************************************
 808
 809 \begin{code}
 810 pprHsSigCtxt :: UserTypeCtxt -> LHsType Name -> SDoc
 811 pprHsSigCtxt ctxt hs_ty = vcat [ ptext SLIT("In") <+> pprUserTypeCtxt ctxt <> colon,
 812                                  nest 2 (pp_sig ctxt) ]
 813   where
 814     pp_sig (FunSigCtxt n)  = pp_n_colon n
 815     pp_sig (ConArgCtxt n)  = pp_n_colon n
 816     pp_sig (ForSigCtxt n)  = pp_n_colon n
 817     pp_sig (RuleSigCtxt n) = pp_n_colon n
 818     pp_sig other           = ppr (unLoc hs_ty)
 819
 820     pp_n_colon n = ppr n <+> dcolon <+> ppr (unLoc hs_ty)
 821
 822
 823 wobblyPatSig sig_tvs
 824   = hang (ptext SLIT("A pattern type signature cannot bind scoped type variables")
 825                 <+> pprQuotedList sig_tvs)
 826        2 (ptext SLIT("unless the pattern has a rigid type context"))
 827
 828 scopedNonVar n ty
 829   = vcat [sep [ptext SLIT("The scoped type variable") <+> quotes (ppr n),
 830                nest 2 (ptext SLIT("is bound to the type") <+> quotes (ppr ty))],
 831           nest 2 (ptext SLIT("You can only bind scoped type variables to type variables"))]
 832
 833 dupInScope n n' ty
 834   = hang (ptext SLIT("The scoped type variables") <+> quotes (ppr n) <+> ptext SLIT("and") <+> quotes (ppr n'))
 835        2 (vcat [ptext SLIT("are bound to the same type (variable)"),
 836                 ptext SLIT("Distinct scoped type variables must be distinct")])
 837 \end{code}
 838