compiler/typecheck/TcHsType.lhs

   1
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcMonoType]{Typechecking user-specified @MonoTypes@}
   5
   6 \begin{code}
   7 module TcHsType (
   8         tcHsSigType, tcHsDeriv,
   9         UserTypeCtxt(..),
  10
  11                 -- Kind checking
  12         kcHsTyVars, kcHsSigType, kcHsLiftedSigType,
  13         kcCheckHsType, kcHsContext, kcHsType,
  14
  15                 -- Typechecking kinded types
  16         tcHsKindedContext, tcHsKindedType, tcHsBangType,
  17         tcTyVarBndrs, dsHsType, tcLHsConResTy,
  18         tcDataKindSig,
  19
  20                 -- Pattern type signatures
  21         tcHsPatSigType, tcPatSig
  22    ) where
  23
  24 #include "HsVersions.h"
  25
  26 import HsSyn            ( HsType(..), LHsType, HsTyVarBndr(..), LHsTyVarBndr,
  27                           LHsContext, HsPred(..), LHsPred, HsExplicitForAll(..) )
  28 import RnHsSyn          ( extractHsTyVars )
  29 import TcRnMonad
  30 import TcEnv            ( tcExtendTyVarEnv, tcExtendKindEnvTvs,
  31                           tcLookup, tcLookupClass, tcLookupTyCon,
  32                           TyThing(..), getInLocalScope, getScopedTyVarBinds,
  33                           wrongThingErr
  34                         )
  35 import TcMType          ( newKindVar,
  36                           zonkTcKindToKind,
  37                           tcInstBoxyTyVar, readFilledBox,
  38                           checkValidType
  39                         )
  40 import TcUnify          ( boxyUnify, unifyFunKind, checkExpectedKind )
  41 import TcIface          ( checkWiredInTyCon )
  42 import TcType           ( Type, PredType(..), ThetaType, BoxySigmaType,
  43                           TcType, TcKind, isRigidTy,
  44                           UserTypeCtxt(..), pprUserTypeCtxt,
  45                           substTyWith, mkTyVarTys, tcEqType,
  46                           tcIsTyVarTy, mkFunTy, mkSigmaTy, mkPredTy,
  47                           mkTyConApp, mkAppTys, typeKind )
  48 import Kind             ( Kind, isLiftedTypeKind, liftedTypeKind, ubxTupleKind,
  49                           openTypeKind, argTypeKind, splitKindFunTys )
  50 import Var              ( TyVar, mkTyVar, tyVarName )
  51 import TyCon            ( TyCon, tyConKind )
  52 import Class            ( Class, classTyCon )
  53 import Name             ( Name, mkInternalName )
  54 import OccName          ( mkOccName, tvName )
  55 import NameSet
  56 import PrelNames        ( genUnitTyConName )
  57 import TysWiredIn       ( mkListTy, listTyCon, mkPArrTy, parrTyCon, tupleTyCon )
  58 import BasicTypes       ( Boxity(..) )
  59 import SrcLoc           ( Located(..), unLoc, noLoc, getLoc, srcSpanStart )
  60 import UniqSupply       ( uniqsFromSupply )
  61 import Outputable
  62 \end{code}
  63
  64
  65         ----------------------------
  66                 General notes
  67         ----------------------------
  68
  69 Generally speaking we now type-check types in three phases
  70
  71   1.  kcHsType: kind check the HsType
  72         *includes* performing any TH type splices;
  73         so it returns a translated, and kind-annotated, type
  74
  75   2.  dsHsType: convert from HsType to Type:
  76         perform zonking
  77         expand type synonyms [mkGenTyApps]
  78         hoist the foralls [tcHsType]
  79
  80   3.  checkValidType: check the validity of the resulting type
  81
  82 Often these steps are done one after the other (tcHsSigType).
  83 But in mutually recursive groups of type and class decls we do
  84         1 kind-check the whole group
  85         2 build TyCons/Classes in a knot-tied way
  86         3 check the validity of types in the now-unknotted TyCons/Classes
  87
  88 For example, when we find
  89         (forall a m. m a -> m a)
  90 we bind a,m to kind varibles and kind-check (m a -> m a).  This makes
  91 a get kind *, and m get kind *->*.  Now we typecheck (m a -> m a) in
  92 an environment that binds a and m suitably.
  93
  94 The kind checker passed to tcHsTyVars needs to look at enough to
  95 establish the kind of the tyvar:
  96   * For a group of type and class decls, it's just the group, not
  97         the rest of the program
  98   * For a tyvar bound in a pattern type signature, its the types
  99         mentioned in the other type signatures in that bunch of patterns
 100   * For a tyvar bound in a RULE, it's the type signatures on other
 101         universally quantified variables in the rule
 102
 103 Note that this may occasionally give surprising results.  For example:
 104
 105         data T a b = MkT (a b)
 106
 107 Here we deduce                  a::*->*,       b::*
 108 But equally valid would be      a::(*->*)-> *, b::*->*
 109
 110
 111 Validity checking
 112 ~~~~~~~~~~~~~~~~~
 113 Some of the validity check could in principle be done by the kind checker,
 114 but not all:
 115
 116 - During desugaring, we normalise by expanding type synonyms.  Only
 117   after this step can we check things like type-synonym saturation
 118   e.g.  type T k = k Int
 119         type S a = a
 120   Then (T S) is ok, because T is saturated; (T S) expands to (S Int);
 121   and then S is saturated.  This is a GHC extension.
 122
 123 - Similarly, also a GHC extension, we look through synonyms before complaining
 124   about the form of a class or instance declaration
 125
 126 - Ambiguity checks involve functional dependencies, and it's easier to wait
 127   until knots have been resolved before poking into them
 128
 129 Also, in a mutually recursive group of types, we can't look at the TyCon until we've
 130 finished building the loop.  So to keep things simple, we postpone most validity
 131 checking until step (3).
 132
 133 Knot tying
 134 ~~~~~~~~~~
 135 During step (1) we might fault in a TyCon defined in another module, and it might
 136 (via a loop) refer back to a TyCon defined in this module. So when we tie a big
 137 knot around type declarations with ARecThing, so that the fault-in code can get
 138 the TyCon being defined.
 139
 140
 141 %************************************************************************
 142 %*                                                                      *
 143 \subsection{Checking types}
 144 %*                                                                      *
 145 %************************************************************************
 146
 147 \begin{code}
 148 tcHsSigType :: UserTypeCtxt -> LHsType Name -> TcM Type
 149   -- Do kind checking, and hoist for-alls to the top
 150   -- NB: it's important that the foralls that come from the top-level
 151   --     HsForAllTy in hs_ty occur *first* in the returned type.
 152   --     See Note [Scoped] with TcSigInfo
 153 tcHsSigType ctxt hs_ty
 154   = addErrCtxt (pprHsSigCtxt ctxt hs_ty) $
 155     do  { kinded_ty <- kcTypeType hs_ty
 156         ; ty <- tcHsKindedType kinded_ty
 157         ; checkValidType ctxt ty
 158         ; returnM ty }
 159
 160 -- Used for the deriving(...) items
 161 tcHsDeriv :: LHsType Name -> TcM ([TyVar], Class, [Type])
 162 tcHsDeriv = addLocM (tc_hs_deriv [])
 163
 164 tc_hs_deriv tv_names (HsPredTy (HsClassP cls_name hs_tys))
 165   = kcHsTyVars tv_names                 $ \ tv_names' ->
 166     do  { cls_kind <- kcClass cls_name
 167         ; (tys, res_kind) <- kcApps cls_kind (ppr cls_name) hs_tys
 168         ; tcTyVarBndrs tv_names'        $ \ tyvars ->
 169     do  { arg_tys <- dsHsTypes tys
 170         ; cls <- tcLookupClass cls_name
 171         ; return (tyvars, cls, arg_tys) }}
 172
 173 tc_hs_deriv tv_names1 (HsForAllTy _ tv_names2 (L _ []) (L _ ty))
 174   =     -- Funny newtype deriving form
 175         --      forall a. C [a]
 176         -- where C has arity 2.  Hence can't use regular functions
 177     tc_hs_deriv (tv_names1 ++ tv_names2) ty
 178
 179 tc_hs_deriv _ other
 180   = failWithTc (ptext SLIT("Illegal deriving item") <+> ppr other)
 181 \end{code}
 182
 183         These functions are used during knot-tying in
 184         type and class declarations, when we have to
 185         separate kind-checking, desugaring, and validity checking
 186
 187 \begin{code}
 188 kcHsSigType, kcHsLiftedSigType :: LHsType Name -> TcM (LHsType Name)
 189         -- Used for type signatures
 190 kcHsSigType ty       = kcTypeType ty
 191 kcHsLiftedSigType ty = kcLiftedType ty
 192
 193 tcHsKindedType :: LHsType Name -> TcM Type
 194   -- Don't do kind checking, nor validity checking,
 195   --    but do hoist for-alls to the top
 196   -- This is used in type and class decls, where kinding is
 197   -- done in advance, and validity checking is done later
 198   -- [Validity checking done later because of knot-tying issues.]
 199 tcHsKindedType hs_ty = dsHsType hs_ty
 200
 201 tcHsBangType :: LHsType Name -> TcM Type
 202 -- Permit a bang, but discard it
 203 tcHsBangType (L span (HsBangTy b ty)) = tcHsKindedType ty
 204 tcHsBangType ty                       = tcHsKindedType ty
 205
 206 tcHsKindedContext :: LHsContext Name -> TcM ThetaType
 207 -- Used when we are expecting a ClassContext (i.e. no implicit params)
 208 -- Does not do validity checking, like tcHsKindedType
 209 tcHsKindedContext hs_theta = addLocM (mappM dsHsLPred) hs_theta
 210 \end{code}
 211
 212
 213 %************************************************************************
 214 %*                                                                      *
 215                 The main kind checker: kcHsType
 216 %*                                                                      *
 217 %************************************************************************
 218
 219         First a couple of simple wrappers for kcHsType
 220
 221 \begin{code}
 222 ---------------------------
 223 kcLiftedType :: LHsType Name -> TcM (LHsType Name)
 224 -- The type ty must be a *lifted* *type*
 225 kcLiftedType ty = kcCheckHsType ty liftedTypeKind
 226
 227 ---------------------------
 228 kcTypeType :: LHsType Name -> TcM (LHsType Name)
 229 -- The type ty must be a *type*, but it can be lifted or
 230 -- unlifted or an unboxed tuple.
 231 kcTypeType ty = kcCheckHsType ty openTypeKind
 232
 233 ---------------------------
 234 kcCheckHsType :: LHsType Name -> TcKind -> TcM (LHsType Name)
 235 -- Check that the type has the specified kind
 236 -- Be sure to use checkExpectedKind, rather than simply unifying
 237 -- with OpenTypeKind, because it gives better error messages
 238 kcCheckHsType (L span ty) exp_kind
 239   = setSrcSpan span                             $
 240     do  { (ty', act_kind) <- add_ctxt ty (kc_hs_type ty)
 241                 -- Add the context round the inner check only
 242                 -- because checkExpectedKind already mentions
 243                 -- 'ty' by name in any error message
 244
 245         ; checkExpectedKind ty act_kind exp_kind
 246         ; return (L span ty') }
 247   where
 248         -- Wrap a context around only if we want to
 249         -- show that contexts.  Omit invisble ones
 250         -- and ones user's won't grok (HsPred p).
 251     add_ctxt (HsPredTy p)                          thing = thing
 252     add_ctxt (HsForAllTy Implicit tvs (L _ []) ty) thing = thing
 253     add_ctxt other_ty thing = addErrCtxt (typeCtxt ty) thing
 254 \end{code}
 255
 256         Here comes the main function
 257
 258 \begin{code}
 259 kcHsType :: LHsType Name -> TcM (LHsType Name, TcKind)
 260 kcHsType ty = wrapLocFstM kc_hs_type ty
 261 -- kcHsType *returns* the kind of the type, rather than taking an expected
 262 -- kind as argument as tcExpr does.
 263 -- Reasons:
 264 --      (a) the kind of (->) is
 265 --              forall bx1 bx2. Type bx1 -> Type bx2 -> Type Boxed
 266 --          so we'd need to generate huge numbers of bx variables.
 267 --      (b) kinds are so simple that the error messages are fine
 268 --
 269 -- The translated type has explicitly-kinded type-variable binders
 270
 271 kc_hs_type (HsParTy ty)
 272  = kcHsType ty          `thenM` \ (ty', kind) ->
 273    returnM (HsParTy ty', kind)
 274
 275 kc_hs_type (HsTyVar name)
 276   = kcTyVar name        `thenM` \ kind ->
 277     returnM (HsTyVar name, kind)
 278
 279 kc_hs_type (HsListTy ty)
 280   = kcLiftedType ty                     `thenM` \ ty' ->
 281     returnM (HsListTy ty', liftedTypeKind)
 282
 283 kc_hs_type (HsPArrTy ty)
 284   = kcLiftedType ty                     `thenM` \ ty' ->
 285     returnM (HsPArrTy ty', liftedTypeKind)
 286
 287 kc_hs_type (HsNumTy n)
 288    = returnM (HsNumTy n, liftedTypeKind)
 289
 290 kc_hs_type (HsKindSig ty k)
 291   = kcCheckHsType ty k  `thenM` \ ty' ->
 292     returnM (HsKindSig ty' k, k)
 293
 294 kc_hs_type (HsTupleTy Boxed tys)
 295   = mappM kcLiftedType tys      `thenM` \ tys' ->
 296     returnM (HsTupleTy Boxed tys', liftedTypeKind)
 297
 298 kc_hs_type (HsTupleTy Unboxed tys)
 299   = mappM kcTypeType tys        `thenM` \ tys' ->
 300     returnM (HsTupleTy Unboxed tys', ubxTupleKind)
 301
 302 kc_hs_type (HsFunTy ty1 ty2)
 303   = kcCheckHsType ty1 argTypeKind       `thenM` \ ty1' ->
 304     kcTypeType ty2                      `thenM` \ ty2' ->
 305     returnM (HsFunTy ty1' ty2', liftedTypeKind)
 306
 307 kc_hs_type ty@(HsOpTy ty1 op ty2)
 308   = addLocM kcTyVar op                  `thenM` \ op_kind ->
 309     kcApps op_kind (ppr op) [ty1,ty2]   `thenM` \ ([ty1',ty2'], res_kind) ->
 310     returnM (HsOpTy ty1' op ty2', res_kind)
 311
 312 kc_hs_type ty@(HsAppTy ty1 ty2)
 313   = kcHsType fun_ty                       `thenM` \ (fun_ty', fun_kind) ->
 314     kcApps fun_kind (ppr fun_ty) arg_tys  `thenM` \ ((arg_ty':arg_tys'), res_kind) ->
 315     returnM (foldl mk_app (HsAppTy fun_ty' arg_ty') arg_tys', res_kind)
 316   where
 317     (fun_ty, arg_tys) = split ty1 [ty2]
 318     split (L _ (HsAppTy f a)) as = split f (a:as)
 319     split f                   as = (f,as)
 320     mk_app fun arg = HsAppTy (noLoc fun) arg    -- Add noLocs for inner nodes of
 321                                                 -- the application; they are never used
 322
 323 kc_hs_type (HsPredTy pred)
 324   = kcHsPred pred               `thenM` \ pred' ->
 325     returnM (HsPredTy pred', liftedTypeKind)
 326
 327 kc_hs_type (HsForAllTy exp tv_names context ty)
 328   = kcHsTyVars tv_names         $ \ tv_names' ->
 329     kcHsContext context         `thenM` \ ctxt' ->
 330     kcLiftedType ty             `thenM` \ ty' ->
 331         -- The body of a forall is usually a type, but in principle
 332         -- there's no reason to prohibit *unlifted* types.
 333         -- In fact, GHC can itself construct a function with an
 334         -- unboxed tuple inside a for-all (via CPR analyis; see
 335         -- typecheck/should_compile/tc170)
 336         --
 337         -- Still, that's only for internal interfaces, which aren't
 338         -- kind-checked, so we only allow liftedTypeKind here
 339     returnM (HsForAllTy exp tv_names' ctxt' ty', liftedTypeKind)
 340
 341 kc_hs_type (HsBangTy b ty)
 342   = do { (ty', kind) <- kcHsType ty
 343        ; return (HsBangTy b ty', kind) }
 344
 345 kc_hs_type ty@(HsSpliceTy _)
 346   = failWithTc (ptext SLIT("Unexpected type splice:") <+> ppr ty)
 347
 348
 349 ---------------------------
 350 kcApps :: TcKind                        -- Function kind
 351        -> SDoc                          -- Function
 352        -> [LHsType Name]                -- Arg types
 353        -> TcM ([LHsType Name], TcKind)  -- Kind-checked args
 354 kcApps fun_kind ppr_fun args
 355   = split_fk fun_kind (length args)     `thenM` \ (arg_kinds, res_kind) ->
 356     zipWithM kc_arg args arg_kinds      `thenM` \ args' ->
 357     returnM (args', res_kind)
 358   where
 359     split_fk fk 0 = returnM ([], fk)
 360     split_fk fk n = unifyFunKind fk     `thenM` \ mb_fk ->
 361                     case mb_fk of
 362                         Nothing       -> failWithTc too_many_args
 363                         Just (ak,fk') -> split_fk fk' (n-1)     `thenM` \ (aks, rk) ->
 364                                          returnM (ak:aks, rk)
 365
 366     kc_arg arg arg_kind = kcCheckHsType arg arg_kind
 367
 368     too_many_args = ptext SLIT("Kind error:") <+> quotes ppr_fun <+>
 369                     ptext SLIT("is applied to too many type arguments")
 370
 371 ---------------------------
 372 kcHsContext :: LHsContext Name -> TcM (LHsContext Name)
 373 kcHsContext ctxt = wrapLocM (mappM kcHsLPred) ctxt
 374
 375 kcHsLPred :: LHsPred Name -> TcM (LHsPred Name)
 376 kcHsLPred = wrapLocM kcHsPred
 377
 378 kcHsPred :: HsPred Name -> TcM (HsPred Name)
 379 kcHsPred pred   -- Checks that the result is of kind liftedType
 380   = kc_pred pred                                `thenM` \ (pred', kind) ->
 381     checkExpectedKind pred kind liftedTypeKind  `thenM_`
 382     returnM pred'
 383
 384 ---------------------------
 385 kc_pred :: HsPred Name -> TcM (HsPred Name, TcKind)
 386         -- Does *not* check for a saturated
 387         -- application (reason: used from TcDeriv)
 388 kc_pred pred@(HsIParam name ty)
 389   = kcHsType ty         `thenM` \ (ty', kind) ->
 390     returnM (HsIParam name ty', kind)
 391
 392 kc_pred pred@(HsClassP cls tys)
 393   = kcClass cls                 `thenM` \ kind ->
 394     kcApps kind (ppr cls) tys   `thenM` \ (tys', res_kind) ->
 395     returnM (HsClassP cls tys', res_kind)
 396
 397 ---------------------------
 398 kcTyVar :: Name -> TcM TcKind
 399 kcTyVar name    -- Could be a tyvar or a tycon
 400   = traceTc (text "lk1" <+> ppr name)   `thenM_`
 401     tcLookup name       `thenM` \ thing ->
 402     traceTc (text "lk2" <+> ppr name <+> ppr thing)     `thenM_`
 403     case thing of
 404         ATyVar _ ty             -> returnM (typeKind ty)
 405         AThing kind             -> returnM kind
 406         AGlobal (ATyCon tc)     -> returnM (tyConKind tc)
 407         other                   -> wrongThingErr "type" thing name
 408
 409 kcClass :: Name -> TcM TcKind
 410 kcClass cls     -- Must be a class
 411   = tcLookup cls                                `thenM` \ thing ->
 412     case thing of
 413         AThing kind             -> returnM kind
 414         AGlobal (AClass cls)    -> returnM (tyConKind (classTyCon cls))
 415         other                   -> wrongThingErr "class" thing cls
 416 \end{code}
 417
 418
 419 %************************************************************************
 420 %*                                                                      *
 421                 Desugaring
 422 %*                                                                      *
 423 %************************************************************************
 424
 425 The type desugarer
 426
 427         * Transforms from HsType to Type
 428         * Zonks any kinds
 429
 430 It cannot fail, and does no validity checking, except for
 431 structural matters, such as
 432         (a) spurious ! annotations.
 433         (b) a class used as a type
 434
 435 \begin{code}
 436 dsHsType :: LHsType Name -> TcM Type
 437 -- All HsTyVarBndrs in the intput type are kind-annotated
 438 dsHsType ty = ds_type (unLoc ty)
 439
 440 ds_type ty@(HsTyVar name)
 441   = ds_app ty []
 442
 443 ds_type (HsParTy ty)            -- Remove the parentheses markers
 444   = dsHsType ty
 445
 446 ds_type ty@(HsBangTy _ _)       -- No bangs should be here
 447   = failWithTc (ptext SLIT("Unexpected strictness annotation:") <+> ppr ty)
 448
 449 ds_type (HsKindSig ty k)
 450   = dsHsType ty -- Kind checking done already
 451
 452 ds_type (HsListTy ty)
 453   = dsHsType ty                 `thenM` \ tau_ty ->
 454     checkWiredInTyCon listTyCon `thenM_`
 455     returnM (mkListTy tau_ty)
 456
 457 ds_type (HsPArrTy ty)
 458   = dsHsType ty                 `thenM` \ tau_ty ->
 459     checkWiredInTyCon parrTyCon `thenM_`
 460     returnM (mkPArrTy tau_ty)
 461
 462 ds_type (HsTupleTy boxity tys)
 463   = dsHsTypes tys               `thenM` \ tau_tys ->
 464     checkWiredInTyCon tycon     `thenM_`
 465     returnM (mkTyConApp tycon tau_tys)
 466   where
 467     tycon = tupleTyCon boxity (length tys)
 468
 469 ds_type (HsFunTy ty1 ty2)
 470   = dsHsType ty1                        `thenM` \ tau_ty1 ->
 471     dsHsType ty2                        `thenM` \ tau_ty2 ->
 472     returnM (mkFunTy tau_ty1 tau_ty2)
 473
 474 ds_type (HsOpTy ty1 (L span op) ty2)
 475   = dsHsType ty1                `thenM` \ tau_ty1 ->
 476     dsHsType ty2                `thenM` \ tau_ty2 ->
 477     setSrcSpan span (ds_var_app op [tau_ty1,tau_ty2])
 478
 479 ds_type (HsNumTy n)
 480   = ASSERT(n==1)
 481     tcLookupTyCon genUnitTyConName      `thenM` \ tc ->
 482     returnM (mkTyConApp tc [])
 483
 484 ds_type ty@(HsAppTy _ _)
 485   = ds_app ty []
 486
 487 ds_type (HsPredTy pred)
 488   = dsHsPred pred       `thenM` \ pred' ->
 489     returnM (mkPredTy pred')
 490
 491 ds_type full_ty@(HsForAllTy exp tv_names ctxt ty)
 492   = tcTyVarBndrs tv_names               $ \ tyvars ->
 493     mappM dsHsLPred (unLoc ctxt)        `thenM` \ theta ->
 494     dsHsType ty                         `thenM` \ tau ->
 495     returnM (mkSigmaTy tyvars theta tau)
 496
 497 dsHsTypes arg_tys = mappM dsHsType arg_tys
 498 \end{code}
 499
 500 Help functions for type applications
 501 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 502
 503 \begin{code}
 504 ds_app :: HsType Name -> [LHsType Name] -> TcM Type
 505 ds_app (HsAppTy ty1 ty2) tys
 506   = ds_app (unLoc ty1) (ty2:tys)
 507
 508 ds_app ty tys
 509   = dsHsTypes tys                       `thenM` \ arg_tys ->
 510     case ty of
 511         HsTyVar fun -> ds_var_app fun arg_tys
 512         other       -> ds_type ty               `thenM` \ fun_ty ->
 513                        returnM (mkAppTys fun_ty arg_tys)
 514
 515 ds_var_app :: Name -> [Type] -> TcM Type
 516 ds_var_app name arg_tys
 517  = tcLookup name                        `thenM` \ thing ->
 518     case thing of
 519         ATyVar _ ty         -> returnM (mkAppTys ty arg_tys)
 520         AGlobal (ATyCon tc) -> returnM (mkTyConApp tc arg_tys)
 521         other               -> wrongThingErr "type" thing name
 522 \end{code}
 523
 524
 525 Contexts
 526 ~~~~~~~~
 527
 528 \begin{code}
 529 dsHsLPred :: LHsPred Name -> TcM PredType
 530 dsHsLPred pred = dsHsPred (unLoc pred)
 531
 532 dsHsPred pred@(HsClassP class_name tys)
 533   = dsHsTypes tys                       `thenM` \ arg_tys ->
 534     tcLookupClass class_name            `thenM` \ clas ->
 535     returnM (ClassP clas arg_tys)
 536
 537 dsHsPred (HsIParam name ty)
 538   = dsHsType ty                                 `thenM` \ arg_ty ->
 539     returnM (IParam name arg_ty)
 540 \end{code}
 541
 542 GADT constructor signatures
 543
 544 \begin{code}
 545 tcLHsConResTy :: LHsType Name -> TcM (TyCon, [TcType])
 546 tcLHsConResTy ty@(L span _)
 547   = setSrcSpan span $
 548     addErrCtxt (gadtResCtxt ty) $
 549     tc_con_res ty []
 550
 551 tc_con_res (L _ (HsAppTy fun res_ty)) res_tys
 552   = do  { res_ty' <- dsHsType res_ty
 553         ; tc_con_res fun (res_ty' : res_tys) }
 554
 555 tc_con_res ty@(L _ (HsTyVar name)) res_tys
 556   = do  { thing <- tcLookup name
 557         ; case thing of
 558             AGlobal (ATyCon tc) -> return (tc, res_tys)
 559             other -> failWithTc (badGadtDecl ty)
 560         }
 561
 562 tc_con_res ty _ = failWithTc (badGadtDecl ty)
 563
 564 gadtResCtxt ty
 565   = hang (ptext SLIT("In the result type of a data constructor:"))
 566        2 (ppr ty)
 567 badGadtDecl ty
 568   = hang (ptext SLIT("Malformed constructor result type:"))
 569        2 (ppr ty)
 570
 571 typeCtxt ty = ptext SLIT("In the type") <+> quotes (ppr ty)
 572 \end{code}
 573
 574 %************************************************************************
 575 %*                                                                      *
 576                 Type-variable binders
 577 %*                                                                      *
 578 %************************************************************************
 579
 580
 581 \begin{code}
 582 kcHsTyVars :: [LHsTyVarBndr Name]
 583            -> ([LHsTyVarBndr Name] -> TcM r)    -- These binders are kind-annotated
 584                                                 -- They scope over the thing inside
 585            -> TcM r
 586 kcHsTyVars tvs thing_inside
 587   = mappM (wrapLocM kcHsTyVar) tvs      `thenM` \ bndrs ->
 588     tcExtendKindEnvTvs bndrs (thing_inside bndrs)
 589
 590 kcHsTyVar :: HsTyVarBndr Name -> TcM (HsTyVarBndr Name)
 591         -- Return a *kind-annotated* binder, and a tyvar with a mutable kind in it
 592 kcHsTyVar (UserTyVar name)        = newKindVar  `thenM` \ kind ->
 593                                     returnM (KindedTyVar name kind)
 594 kcHsTyVar (KindedTyVar name kind) = returnM (KindedTyVar name kind)
 595
 596 ------------------
 597 tcTyVarBndrs :: [LHsTyVarBndr Name]     -- Kind-annotated binders, which need kind-zonking
 598              -> ([TyVar] -> TcM r)
 599              -> TcM r
 600 -- Used when type-checking types/classes/type-decls
 601 -- Brings into scope immutable TyVars, not mutable ones that require later zonking
 602 tcTyVarBndrs bndrs thing_inside
 603   = mapM (zonk . unLoc) bndrs   `thenM` \ tyvars ->
 604     tcExtendTyVarEnv tyvars (thing_inside tyvars)
 605   where
 606     zonk (KindedTyVar name kind) = do { kind' <- zonkTcKindToKind kind
 607                                       ; return (mkTyVar name kind') }
 608     zonk (UserTyVar name) = pprTrace "Un-kinded tyvar" (ppr name) $
 609                             return (mkTyVar name liftedTypeKind)
 610
 611 -----------------------------------
 612 tcDataKindSig :: Maybe Kind -> TcM [TyVar]
 613 -- GADT decls can have a (perhpas partial) kind signature
 614 --      e.g.  data T :: * -> * -> * where ...
 615 -- This function makes up suitable (kinded) type variables for
 616 -- the argument kinds, and checks that the result kind is indeed *
 617 tcDataKindSig Nothing = return []
 618 tcDataKindSig (Just kind)
 619   = do  { checkTc (isLiftedTypeKind res_kind) (badKindSig kind)
 620         ; span <- getSrcSpanM
 621         ; us   <- newUniqueSupply
 622         ; let loc   = srcSpanStart span
 623               uniqs = uniqsFromSupply us
 624         ; return [ mk_tv loc uniq str kind
 625                  | ((kind, str), uniq) <- arg_kinds `zip` names `zip` uniqs ] }
 626   where
 627     (arg_kinds, res_kind) = splitKindFunTys kind
 628     mk_tv loc uniq str kind = mkTyVar name kind
 629         where
 630            name = mkInternalName uniq occ loc
 631            occ  = mkOccName tvName str
 632
 633     names :: [String]   -- a,b,c...aa,ab,ac etc
 634     names = [ c:cs | cs <- "" : names, c <- ['a'..'z'] ]
 635
 636 badKindSig :: Kind -> SDoc
 637 badKindSig kind
 638  = hang (ptext SLIT("Kind signature on data type declaration has non-* return kind"))
 639         2 (ppr kind)
 640 \end{code}
 641
 642
 643 %************************************************************************
 644 %*                                                                      *
 645                 Scoped type variables
 646 %*                                                                      *
 647 %************************************************************************
 648
 649
 650 tcAddScopedTyVars is used for scoped type variables added by pattern
 651 type signatures
 652         e.g.  \ ((x::a), (y::a)) -> x+y
 653 They never have explicit kinds (because this is source-code only)
 654 They are mutable (because they can get bound to a more specific type).
 655
 656 Usually we kind-infer and expand type splices, and then
 657 tupecheck/desugar the type.  That doesn't work well for scoped type
 658 variables, because they scope left-right in patterns.  (e.g. in the
 659 example above, the 'a' in (y::a) is bound by the 'a' in (x::a).
 660
 661 The current not-very-good plan is to
 662   * find all the types in the patterns
 663   * find their free tyvars
 664   * do kind inference
 665   * bring the kinded type vars into scope
 666   * BUT throw away the kind-checked type
 667         (we'll kind-check it again when we type-check the pattern)
 668
 669 This is bad because throwing away the kind checked type throws away
 670 its splices.  But too bad for now.  [July 03]
 671
 672 Historical note:
 673     We no longer specify that these type variables must be univerally
 674     quantified (lots of email on the subject).  If you want to put that
 675     back in, you need to
 676         a) Do a checkSigTyVars after thing_inside
 677         b) More insidiously, don't pass in expected_ty, else
 678            we unify with it too early and checkSigTyVars barfs
 679            Instead you have to pass in a fresh ty var, and unify
 680            it with expected_ty afterwards
 681
 682 \begin{code}
 683 tcHsPatSigType :: UserTypeCtxt
 684                -> LHsType Name          -- The type signature
 685                -> TcM ([TyVar],         -- Newly in-scope type variables
 686                         Type)           -- The signature
 687 -- Used for type-checking type signatures in
 688 -- (a) patterns           e.g  f (x::Int) = e
 689 -- (b) result signatures  e.g. g x :: Int = e
 690 -- (c) RULE forall bndrs  e.g. forall (x::Int). f x = x
 691
 692 tcHsPatSigType ctxt hs_ty
 693   = addErrCtxt (pprHsSigCtxt ctxt hs_ty) $
 694     do  {       -- Find the type variables that are mentioned in the type
 695                 -- but not already in scope.  These are the ones that
 696                 -- should be bound by the pattern signature
 697           in_scope <- getInLocalScope
 698         ; let span = getLoc hs_ty
 699               sig_tvs = [ L span (UserTyVar n)
 700                         | n <- nameSetToList (extractHsTyVars hs_ty),
 701                           not (in_scope n) ]
 702
 703         -- Behave very like type-checking (HsForAllTy sig_tvs hs_ty),
 704         -- except that we want to keep the tvs separate
 705         ; (kinded_tvs, kinded_ty) <- kcHsTyVars sig_tvs $ \ kinded_tvs -> do
 706                                     { kinded_ty <- kcTypeType hs_ty
 707                                     ; return (kinded_tvs, kinded_ty) }
 708         ; tcTyVarBndrs kinded_tvs $ \ tyvars -> do
 709         { sig_ty <- dsHsType kinded_ty
 710         ; checkValidType ctxt sig_ty
 711         ; return (tyvars, sig_ty)
 712       } }
 713
 714 tcPatSig :: UserTypeCtxt
 715          -> LHsType Name
 716          -> BoxySigmaType
 717          -> TcM (TcType,           -- The type to use for "inside" the signature
 718                  [(Name,TcType)])  -- The new bit of type environment, binding
 719                                    -- the scoped type variables
 720 tcPatSig ctxt sig res_ty
 721   = do  { (sig_tvs, sig_ty) <- tcHsPatSigType ctxt sig
 722
 723         ; if null sig_tvs then do {
 724                 -- The type signature binds no type variables,
 725                 -- and hence is rigid, so use it to zap the res_ty
 726                   boxyUnify sig_ty res_ty
 727                 ; return (sig_ty, [])
 728
 729         } else do {
 730                 -- Type signature binds at least one scoped type variable
 731
 732                 -- A pattern binding cannot bind scoped type variables
 733                 -- The renamer fails with a name-out-of-scope error
 734                 -- if a pattern binding tries to bind a type variable,
 735                 -- So we just have an ASSERT here
 736         ; let in_pat_bind = case ctxt of
 737                                 BindPatSigCtxt -> True
 738                                 other          -> False
 739         ; ASSERT( not in_pat_bind || null sig_tvs ) return ()
 740
 741                 -- Check that pat_ty is rigid
 742         ; checkTc (isRigidTy res_ty) (wobblyPatSig sig_tvs)
 743
 744                 -- Now match the pattern signature against res_ty
 745                 -- For convenience, and uniform-looking error messages
 746                 -- we do the matching by allocating meta type variables,
 747                 -- unifying, and reading out the results.
 748                 -- This is a strictly local operation.
 749         ; box_tvs <- mapM tcInstBoxyTyVar sig_tvs
 750         ; boxyUnify (substTyWith sig_tvs (mkTyVarTys box_tvs) sig_ty) res_ty
 751         ; sig_tv_tys <- mapM readFilledBox box_tvs
 752
 753                 -- Check that each is bound to a distinct type variable,
 754                 -- and one that is not already in scope
 755         ; let tv_binds = map tyVarName sig_tvs `zip` sig_tv_tys
 756         ; binds_in_scope <- getScopedTyVarBinds
 757         ; check binds_in_scope tv_binds
 758
 759                 -- Phew!
 760         ; return (res_ty, tv_binds)
 761         } }
 762   where
 763     check in_scope []            = return ()
 764     check in_scope ((n,ty):rest) = do { check_one in_scope n ty
 765                                       ; check ((n,ty):in_scope) rest }
 766
 767     check_one in_scope n ty
 768         = do { checkTc (tcIsTyVarTy ty) (scopedNonVar n ty)
 769                 -- Must bind to a type variable
 770
 771              ; checkTc (null dups) (dupInScope n (head dups) ty)
 772                 -- Must not bind to the same type variable
 773                 -- as some other in-scope type variable
 774
 775              ; return () }
 776         where
 777           dups = [n' | (n',ty') <- in_scope, tcEqType ty' ty]
 778 \end{code}
 779
 780
 781 %************************************************************************
 782 %*                                                                      *
 783                 Scoped type variables
 784 %*                                                                      *
 785 %************************************************************************
 786
 787 \begin{code}
 788 pprHsSigCtxt :: UserTypeCtxt -> LHsType Name -> SDoc
 789 pprHsSigCtxt ctxt hs_ty = vcat [ ptext SLIT("In") <+> pprUserTypeCtxt ctxt <> colon,
 790                                  nest 2 (pp_sig ctxt) ]
 791   where
 792     pp_sig (FunSigCtxt n)  = pp_n_colon n
 793     pp_sig (ConArgCtxt n)  = pp_n_colon n
 794     pp_sig (ForSigCtxt n)  = pp_n_colon n
 795     pp_sig (RuleSigCtxt n) = pp_n_colon n
 796     pp_sig other           = ppr (unLoc hs_ty)
 797
 798     pp_n_colon n = ppr n <+> dcolon <+> ppr (unLoc hs_ty)
 799
 800
 801 wobblyPatSig sig_tvs
 802   = hang (ptext SLIT("A pattern type signature cannot bind scoped type variables")
 803                 <+> pprQuotedList sig_tvs)
 804        2 (ptext SLIT("unless the pattern has a rigid type context"))
 805
 806 scopedNonVar n ty
 807   = vcat [sep [ptext SLIT("The scoped type variable") <+> quotes (ppr n),
 808                nest 2 (ptext SLIT("is bound to the type") <+> quotes (ppr ty))],
 809           nest 2 (ptext SLIT("You can only bind scoped type variables to type variables"))]
 810
 811 dupInScope n n' ty
 812   = hang (ptext SLIT("The scoped type variables") <+> quotes (ppr n) <+> ptext SLIT("and") <+> quotes (ppr n'))
 813        2 (vcat [ptext SLIT("are bound to the same type (variable)"),
 814                 ptext SLIT("Distinct scoped type variables must be distinct")])
 815 \end{code}
 816