compiler/typecheck/TcHsType.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5 \section[TcMonoType]{Typechecking user-specified @MonoTypes@}
   6
   7 \begin{code}
   8 {-# OPTIONS -w #-}
   9 -- The above warning supression flag is a temporary kludge.
  10 -- While working on this module you are encouraged to remove it and fix
  11 -- any warnings in the module. See
  12 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  13 -- for details
  14
  15 module TcHsType (
  16         tcHsSigType, tcHsDeriv,
  17         tcHsInstHead, tcHsQuantifiedType,
  18         UserTypeCtxt(..),
  19
  20                 -- Kind checking
  21         kcHsTyVars, kcHsSigType, kcHsLiftedSigType,
  22         kcCheckHsType, kcHsContext, kcHsType,
  23
  24                 -- Typechecking kinded types
  25         tcHsKindedContext, tcHsKindedType, tcHsBangType,
  26         tcTyVarBndrs, dsHsType, tcLHsConResTy,
  27         tcDataKindSig,
  28
  29                 -- Pattern type signatures
  30         tcHsPatSigType, tcPatSig
  31    ) where
  32
  33 #include "HsVersions.h"
  34
  35 import HsSyn
  36 import RnHsSyn
  37 import TcRnMonad
  38 import TcEnv
  39 import TcMType
  40 import TcUnify
  41 import TcIface
  42 import TcType
  43 import {- Kind parts of -} Type
  44 import Var
  45 import TyCon
  46 import Class
  47 import Name
  48 import OccName
  49 import NameSet
  50 import PrelNames
  51 import TysWiredIn
  52 import BasicTypes
  53 import SrcLoc
  54 import UniqSupply
  55 import Outputable
  56 \end{code}
  57
  58
  59         ----------------------------
  60                 General notes
  61         ----------------------------
  62
  63 Generally speaking we now type-check types in three phases
  64
  65   1.  kcHsType: kind check the HsType
  66         *includes* performing any TH type splices;
  67         so it returns a translated, and kind-annotated, type
  68
  69   2.  dsHsType: convert from HsType to Type:
  70         perform zonking
  71         expand type synonyms [mkGenTyApps]
  72         hoist the foralls [tcHsType]
  73
  74   3.  checkValidType: check the validity of the resulting type
  75
  76 Often these steps are done one after the other (tcHsSigType).
  77 But in mutually recursive groups of type and class decls we do
  78         1 kind-check the whole group
  79         2 build TyCons/Classes in a knot-tied way
  80         3 check the validity of types in the now-unknotted TyCons/Classes
  81
  82 For example, when we find
  83         (forall a m. m a -> m a)
  84 we bind a,m to kind varibles and kind-check (m a -> m a).  This makes
  85 a get kind *, and m get kind *->*.  Now we typecheck (m a -> m a) in
  86 an environment that binds a and m suitably.
  87
  88 The kind checker passed to tcHsTyVars needs to look at enough to
  89 establish the kind of the tyvar:
  90   * For a group of type and class decls, it's just the group, not
  91         the rest of the program
  92   * For a tyvar bound in a pattern type signature, its the types
  93         mentioned in the other type signatures in that bunch of patterns
  94   * For a tyvar bound in a RULE, it's the type signatures on other
  95         universally quantified variables in the rule
  96
  97 Note that this may occasionally give surprising results.  For example:
  98
  99         data T a b = MkT (a b)
 100
 101 Here we deduce                  a::*->*,       b::*
 102 But equally valid would be      a::(*->*)-> *, b::*->*
 103
 104
 105 Validity checking
 106 ~~~~~~~~~~~~~~~~~
 107 Some of the validity check could in principle be done by the kind checker,
 108 but not all:
 109
 110 - During desugaring, we normalise by expanding type synonyms.  Only
 111   after this step can we check things like type-synonym saturation
 112   e.g.  type T k = k Int
 113         type S a = a
 114   Then (T S) is ok, because T is saturated; (T S) expands to (S Int);
 115   and then S is saturated.  This is a GHC extension.
 116
 117 - Similarly, also a GHC extension, we look through synonyms before complaining
 118   about the form of a class or instance declaration
 119
 120 - Ambiguity checks involve functional dependencies, and it's easier to wait
 121   until knots have been resolved before poking into them
 122
 123 Also, in a mutually recursive group of types, we can't look at the TyCon until we've
 124 finished building the loop.  So to keep things simple, we postpone most validity
 125 checking until step (3).
 126
 127 Knot tying
 128 ~~~~~~~~~~
 129 During step (1) we might fault in a TyCon defined in another module, and it might
 130 (via a loop) refer back to a TyCon defined in this module. So when we tie a big
 131 knot around type declarations with ARecThing, so that the fault-in code can get
 132 the TyCon being defined.
 133
 134
 135 %************************************************************************
 136 %*                                                                      *
 137 \subsection{Checking types}
 138 %*                                                                      *
 139 %************************************************************************
 140
 141 \begin{code}
 142 tcHsSigType :: UserTypeCtxt -> LHsType Name -> TcM Type
 143   -- Do kind checking, and hoist for-alls to the top
 144   -- NB: it's important that the foralls that come from the top-level
 145   --     HsForAllTy in hs_ty occur *first* in the returned type.
 146   --     See Note [Scoped] with TcSigInfo
 147 tcHsSigType ctxt hs_ty
 148   = addErrCtxt (pprHsSigCtxt ctxt hs_ty) $
 149     do  { kinded_ty <- kcTypeType hs_ty
 150         ; ty <- tcHsKindedType kinded_ty
 151         ; checkValidType ctxt ty
 152         ; returnM ty }
 153
 154 tcHsInstHead :: LHsType Name -> TcM ([TyVar], ThetaType, Type)
 155 -- Typecheck an instance head.  We can't use
 156 -- tcHsSigType, because it's not a valid user type.
 157 tcHsInstHead hs_ty
 158   = do  { kinded_ty <- kcHsSigType hs_ty
 159         ; poly_ty   <- tcHsKindedType kinded_ty
 160         ; return (tcSplitSigmaTy poly_ty) }
 161
 162 tcHsQuantifiedType :: [LHsTyVarBndr Name] -> LHsType Name -> TcM ([TyVar], Type)
 163 -- Behave very like type-checking (HsForAllTy sig_tvs hs_ty),
 164 -- except that we want to keep the tvs separate
 165 tcHsQuantifiedType tv_names hs_ty
 166   = kcHsTyVars tv_names $ \ tv_names' ->
 167     do  { kc_ty <- kcHsSigType hs_ty
 168         ; tcTyVarBndrs tv_names' $ \ tvs ->
 169     do  { ty <- dsHsType kc_ty
 170         ; return (tvs, ty) } }
 171
 172 -- Used for the deriving(...) items
 173 tcHsDeriv :: LHsType Name -> TcM ([TyVar], Class, [Type])
 174 tcHsDeriv = addLocM (tc_hs_deriv [])
 175
 176 tc_hs_deriv tv_names (HsPredTy (HsClassP cls_name hs_tys))
 177   = kcHsTyVars tv_names                 $ \ tv_names' ->
 178     do  { cls_kind <- kcClass cls_name
 179         ; (tys, res_kind) <- kcApps cls_kind (ppr cls_name) hs_tys
 180         ; tcTyVarBndrs tv_names'        $ \ tyvars ->
 181     do  { arg_tys <- dsHsTypes tys
 182         ; cls <- tcLookupClass cls_name
 183         ; return (tyvars, cls, arg_tys) }}
 184
 185 tc_hs_deriv tv_names1 (HsForAllTy _ tv_names2 (L _ []) (L _ ty))
 186   =     -- Funny newtype deriving form
 187         --      forall a. C [a]
 188         -- where C has arity 2.  Hence can't use regular functions
 189     tc_hs_deriv (tv_names1 ++ tv_names2) ty
 190
 191 tc_hs_deriv _ other
 192   = failWithTc (ptext SLIT("Illegal deriving item") <+> ppr other)
 193 \end{code}
 194
 195         These functions are used during knot-tying in
 196         type and class declarations, when we have to
 197         separate kind-checking, desugaring, and validity checking
 198
 199 \begin{code}
 200 kcHsSigType, kcHsLiftedSigType :: LHsType Name -> TcM (LHsType Name)
 201         -- Used for type signatures
 202 kcHsSigType ty       = kcTypeType ty
 203 kcHsLiftedSigType ty = kcLiftedType ty
 204
 205 tcHsKindedType :: LHsType Name -> TcM Type
 206   -- Don't do kind checking, nor validity checking.
 207   -- This is used in type and class decls, where kinding is
 208   -- done in advance, and validity checking is done later
 209   -- [Validity checking done later because of knot-tying issues.]
 210 tcHsKindedType hs_ty = dsHsType hs_ty
 211
 212 tcHsBangType :: LHsType Name -> TcM Type
 213 -- Permit a bang, but discard it
 214 tcHsBangType (L span (HsBangTy b ty)) = tcHsKindedType ty
 215 tcHsBangType ty                       = tcHsKindedType ty
 216
 217 tcHsKindedContext :: LHsContext Name -> TcM ThetaType
 218 -- Used when we are expecting a ClassContext (i.e. no implicit params)
 219 -- Does not do validity checking, like tcHsKindedType
 220 tcHsKindedContext hs_theta = addLocM (mappM dsHsLPred) hs_theta
 221 \end{code}
 222
 223
 224 %************************************************************************
 225 %*                                                                      *
 226                 The main kind checker: kcHsType
 227 %*                                                                      *
 228 %************************************************************************
 229
 230         First a couple of simple wrappers for kcHsType
 231
 232 \begin{code}
 233 ---------------------------
 234 kcLiftedType :: LHsType Name -> TcM (LHsType Name)
 235 -- The type ty must be a *lifted* *type*
 236 kcLiftedType ty = kcCheckHsType ty liftedTypeKind
 237
 238 ---------------------------
 239 kcTypeType :: LHsType Name -> TcM (LHsType Name)
 240 -- The type ty must be a *type*, but it can be lifted or
 241 -- unlifted or an unboxed tuple.
 242 kcTypeType ty = kcCheckHsType ty openTypeKind
 243
 244 ---------------------------
 245 kcCheckHsType :: LHsType Name -> TcKind -> TcM (LHsType Name)
 246 -- Check that the type has the specified kind
 247 -- Be sure to use checkExpectedKind, rather than simply unifying
 248 -- with OpenTypeKind, because it gives better error messages
 249 kcCheckHsType (L span ty) exp_kind
 250   = setSrcSpan span                             $
 251     do  { (ty', act_kind) <- add_ctxt ty (kc_hs_type ty)
 252                 -- Add the context round the inner check only
 253                 -- because checkExpectedKind already mentions
 254                 -- 'ty' by name in any error message
 255
 256         ; checkExpectedKind (strip ty) act_kind exp_kind
 257         ; return (L span ty') }
 258   where
 259         -- Wrap a context around only if we want to show that contexts.
 260     add_ctxt (HsPredTy p)                thing = thing
 261         -- Omit invisble ones and ones user's won't grok (HsPred p).
 262     add_ctxt (HsForAllTy _ _ (L _ []) _) thing = thing
 263         -- Omit wrapping if the theta-part is empty
 264         -- Reason: the recursive call to kcLiftedType, in the ForAllTy
 265         --         case of kc_hs_type, will do the wrapping instead
 266         --         and we don't want to duplicate
 267     add_ctxt other_ty thing = addErrCtxt (typeCtxt other_ty) thing
 268
 269         -- We infer the kind of the type, and then complain if it's
 270         -- not right.  But we don't want to complain about
 271         --      (ty) or !(ty) or forall a. ty
 272         -- when the real difficulty is with the 'ty' part.
 273     strip (HsParTy (L _ ty))          = strip ty
 274     strip (HsBangTy _ (L _ ty))       = strip ty
 275     strip (HsForAllTy _ _ _ (L _ ty)) = strip ty
 276     strip ty                          = ty
 277 \end{code}
 278
 279         Here comes the main function
 280
 281 \begin{code}
 282 kcHsType :: LHsType Name -> TcM (LHsType Name, TcKind)
 283 kcHsType ty = wrapLocFstM kc_hs_type ty
 284 -- kcHsType *returns* the kind of the type, rather than taking an expected
 285 -- kind as argument as tcExpr does.
 286 -- Reasons:
 287 --      (a) the kind of (->) is
 288 --              forall bx1 bx2. Type bx1 -> Type bx2 -> Type Boxed
 289 --          so we'd need to generate huge numbers of bx variables.
 290 --      (b) kinds are so simple that the error messages are fine
 291 --
 292 -- The translated type has explicitly-kinded type-variable binders
 293
 294 kc_hs_type (HsParTy ty)
 295  = kcHsType ty          `thenM` \ (ty', kind) ->
 296    returnM (HsParTy ty', kind)
 297
 298 kc_hs_type (HsTyVar name)
 299   = kcTyVar name        `thenM` \ kind ->
 300     returnM (HsTyVar name, kind)
 301
 302 kc_hs_type (HsListTy ty)
 303   = kcLiftedType ty                     `thenM` \ ty' ->
 304     returnM (HsListTy ty', liftedTypeKind)
 305
 306 kc_hs_type (HsPArrTy ty)
 307   = kcLiftedType ty                     `thenM` \ ty' ->
 308     returnM (HsPArrTy ty', liftedTypeKind)
 309
 310 kc_hs_type (HsNumTy n)
 311    = returnM (HsNumTy n, liftedTypeKind)
 312
 313 kc_hs_type (HsKindSig ty k)
 314   = kcCheckHsType ty k  `thenM` \ ty' ->
 315     returnM (HsKindSig ty' k, k)
 316
 317 kc_hs_type (HsTupleTy Boxed tys)
 318   = mappM kcLiftedType tys      `thenM` \ tys' ->
 319     returnM (HsTupleTy Boxed tys', liftedTypeKind)
 320
 321 kc_hs_type (HsTupleTy Unboxed tys)
 322   = mappM kcTypeType tys        `thenM` \ tys' ->
 323     returnM (HsTupleTy Unboxed tys', ubxTupleKind)
 324
 325 kc_hs_type (HsFunTy ty1 ty2)
 326   = kcCheckHsType ty1 argTypeKind       `thenM` \ ty1' ->
 327     kcTypeType ty2                      `thenM` \ ty2' ->
 328     returnM (HsFunTy ty1' ty2', liftedTypeKind)
 329
 330 kc_hs_type ty@(HsOpTy ty1 op ty2)
 331   = addLocM kcTyVar op                  `thenM` \ op_kind ->
 332     kcApps op_kind (ppr op) [ty1,ty2]   `thenM` \ ([ty1',ty2'], res_kind) ->
 333     returnM (HsOpTy ty1' op ty2', res_kind)
 334
 335 kc_hs_type ty@(HsAppTy ty1 ty2)
 336   = kcHsType fun_ty                       `thenM` \ (fun_ty', fun_kind) ->
 337     kcApps fun_kind (ppr fun_ty) arg_tys  `thenM` \ ((arg_ty':arg_tys'), res_kind) ->
 338     returnM (foldl mk_app (HsAppTy fun_ty' arg_ty') arg_tys', res_kind)
 339   where
 340     (fun_ty, arg_tys) = split ty1 [ty2]
 341     split (L _ (HsAppTy f a)) as = split f (a:as)
 342     split f                   as = (f,as)
 343     mk_app fun arg = HsAppTy (noLoc fun) arg    -- Add noLocs for inner nodes of
 344                                                 -- the application; they are
 345                                                 -- never used
 346
 347 kc_hs_type ty@(HsPredTy (HsEqualP _ _))
 348   = wrongEqualityErr
 349
 350 kc_hs_type (HsPredTy pred)
 351   = kcHsPred pred               `thenM` \ pred' ->
 352     returnM (HsPredTy pred', liftedTypeKind)
 353
 354 kc_hs_type (HsForAllTy exp tv_names context ty)
 355   = kcHsTyVars tv_names         $ \ tv_names' ->
 356     do  { ctxt' <- kcHsContext context
 357         ; ty'   <- kcLiftedType ty
 358              -- The body of a forall is usually a type, but in principle
 359              -- there's no reason to prohibit *unlifted* types.
 360              -- In fact, GHC can itself construct a function with an
 361              -- unboxed tuple inside a for-all (via CPR analyis; see
 362              -- typecheck/should_compile/tc170)
 363              --
 364              -- Still, that's only for internal interfaces, which aren't
 365              -- kind-checked, so we only allow liftedTypeKind here
 366
 367         ; return (HsForAllTy exp tv_names' ctxt' ty', liftedTypeKind) }
 368
 369 kc_hs_type (HsBangTy b ty)
 370   = do { (ty', kind) <- kcHsType ty
 371        ; return (HsBangTy b ty', kind) }
 372
 373 kc_hs_type ty@(HsSpliceTy _)
 374   = failWithTc (ptext SLIT("Unexpected type splice:") <+> ppr ty)
 375
 376 -- remove the doc nodes here, no need to worry about the location since
 377 -- its the same for a doc node and it's child type node
 378 kc_hs_type (HsDocTy ty _)
 379   = kc_hs_type (unLoc ty)
 380
 381 ---------------------------
 382 kcApps :: TcKind                        -- Function kind
 383        -> SDoc                          -- Function
 384        -> [LHsType Name]                -- Arg types
 385        -> TcM ([LHsType Name], TcKind)  -- Kind-checked args
 386 kcApps fun_kind ppr_fun args
 387   = split_fk fun_kind (length args)     `thenM` \ (arg_kinds, res_kind) ->
 388     zipWithM kc_arg args arg_kinds      `thenM` \ args' ->
 389     returnM (args', res_kind)
 390   where
 391     split_fk fk 0 = returnM ([], fk)
 392     split_fk fk n = unifyFunKind fk     `thenM` \ mb_fk ->
 393                     case mb_fk of
 394                         Nothing       -> failWithTc too_many_args
 395                         Just (ak,fk') -> split_fk fk' (n-1)     `thenM` \ (aks, rk) ->
 396                                          returnM (ak:aks, rk)
 397
 398     kc_arg arg arg_kind = kcCheckHsType arg arg_kind
 399
 400     too_many_args = ptext SLIT("Kind error:") <+> quotes ppr_fun <+>
 401                     ptext SLIT("is applied to too many type arguments")
 402
 403 ---------------------------
 404 kcHsContext :: LHsContext Name -> TcM (LHsContext Name)
 405 kcHsContext ctxt = wrapLocM (mappM kcHsLPred) ctxt
 406
 407 kcHsLPred :: LHsPred Name -> TcM (LHsPred Name)
 408 kcHsLPred = wrapLocM kcHsPred
 409
 410 kcHsPred :: HsPred Name -> TcM (HsPred Name)
 411 kcHsPred pred   -- Checks that the result is of kind liftedType
 412   = kc_pred pred                                `thenM` \ (pred', kind) ->
 413     checkExpectedKind pred kind liftedTypeKind  `thenM_`
 414     returnM pred'
 415
 416 ---------------------------
 417 kc_pred :: HsPred Name -> TcM (HsPred Name, TcKind)
 418         -- Does *not* check for a saturated
 419         -- application (reason: used from TcDeriv)
 420 kc_pred pred@(HsIParam name ty)
 421   = do { (ty', kind) <- kcHsType ty
 422        ; returnM (HsIParam name ty', kind)
 423        }
 424 kc_pred pred@(HsClassP cls tys)
 425   = do { kind <- kcClass cls
 426        ; (tys', res_kind) <- kcApps kind (ppr cls) tys
 427        ; returnM (HsClassP cls tys', res_kind)
 428        }
 429 kc_pred pred@(HsEqualP ty1 ty2)
 430   = do { (ty1', kind1) <- kcHsType ty1
 431 --       ; checkExpectedKind ty1 kind1 liftedTypeKind
 432        ; (ty2', kind2) <- kcHsType ty2
 433 --       ; checkExpectedKind ty2 kind2 liftedTypeKind
 434        ; checkExpectedKind ty2 kind2 kind1
 435        ; returnM (HsEqualP ty1' ty2', liftedTypeKind)
 436        }
 437
 438 ---------------------------
 439 kcTyVar :: Name -> TcM TcKind
 440 kcTyVar name    -- Could be a tyvar or a tycon
 441   = traceTc (text "lk1" <+> ppr name)   `thenM_`
 442     tcLookup name       `thenM` \ thing ->
 443     traceTc (text "lk2" <+> ppr name <+> ppr thing)     `thenM_`
 444     case thing of
 445         ATyVar _ ty             -> returnM (typeKind ty)
 446         AThing kind             -> returnM kind
 447         AGlobal (ATyCon tc)     -> returnM (tyConKind tc)
 448         other                   -> wrongThingErr "type" thing name
 449
 450 kcClass :: Name -> TcM TcKind
 451 kcClass cls     -- Must be a class
 452   = tcLookup cls                                `thenM` \ thing ->
 453     case thing of
 454         AThing kind             -> returnM kind
 455         AGlobal (AClass cls)    -> returnM (tyConKind (classTyCon cls))
 456         other                   -> wrongThingErr "class" thing cls
 457 \end{code}
 458
 459
 460 %************************************************************************
 461 %*                                                                      *
 462                 Desugaring
 463 %*                                                                      *
 464 %************************************************************************
 465
 466 The type desugarer
 467
 468         * Transforms from HsType to Type
 469         * Zonks any kinds
 470
 471 It cannot fail, and does no validity checking, except for
 472 structural matters, such as
 473         (a) spurious ! annotations.
 474         (b) a class used as a type
 475
 476 \begin{code}
 477 dsHsType :: LHsType Name -> TcM Type
 478 -- All HsTyVarBndrs in the intput type are kind-annotated
 479 dsHsType ty = ds_type (unLoc ty)
 480
 481 ds_type ty@(HsTyVar name)
 482   = ds_app ty []
 483
 484 ds_type (HsParTy ty)            -- Remove the parentheses markers
 485   = dsHsType ty
 486
 487 ds_type ty@(HsBangTy _ _)       -- No bangs should be here
 488   = failWithTc (ptext SLIT("Unexpected strictness annotation:") <+> ppr ty)
 489
 490 ds_type (HsKindSig ty k)
 491   = dsHsType ty -- Kind checking done already
 492
 493 ds_type (HsListTy ty)
 494   = dsHsType ty                 `thenM` \ tau_ty ->
 495     checkWiredInTyCon listTyCon `thenM_`
 496     returnM (mkListTy tau_ty)
 497
 498 ds_type (HsPArrTy ty)
 499   = dsHsType ty                 `thenM` \ tau_ty ->
 500     checkWiredInTyCon parrTyCon `thenM_`
 501     returnM (mkPArrTy tau_ty)
 502
 503 ds_type (HsTupleTy boxity tys)
 504   = dsHsTypes tys               `thenM` \ tau_tys ->
 505     checkWiredInTyCon tycon     `thenM_`
 506     returnM (mkTyConApp tycon tau_tys)
 507   where
 508     tycon = tupleTyCon boxity (length tys)
 509
 510 ds_type (HsFunTy ty1 ty2)
 511   = dsHsType ty1                        `thenM` \ tau_ty1 ->
 512     dsHsType ty2                        `thenM` \ tau_ty2 ->
 513     returnM (mkFunTy tau_ty1 tau_ty2)
 514
 515 ds_type (HsOpTy ty1 (L span op) ty2)
 516   = dsHsType ty1                `thenM` \ tau_ty1 ->
 517     dsHsType ty2                `thenM` \ tau_ty2 ->
 518     setSrcSpan span (ds_var_app op [tau_ty1,tau_ty2])
 519
 520 ds_type (HsNumTy n)
 521   = ASSERT(n==1)
 522     tcLookupTyCon genUnitTyConName      `thenM` \ tc ->
 523     returnM (mkTyConApp tc [])
 524
 525 ds_type ty@(HsAppTy _ _)
 526   = ds_app ty []
 527
 528 ds_type (HsPredTy pred)
 529   = dsHsPred pred       `thenM` \ pred' ->
 530     returnM (mkPredTy pred')
 531
 532 ds_type full_ty@(HsForAllTy exp tv_names ctxt ty)
 533   = tcTyVarBndrs tv_names               $ \ tyvars ->
 534     mappM dsHsLPred (unLoc ctxt)        `thenM` \ theta ->
 535     dsHsType ty                         `thenM` \ tau ->
 536     returnM (mkSigmaTy tyvars theta tau)
 537
 538 ds_type (HsSpliceTy {}) = panic "ds_type: HsSpliceTy"
 539
 540 ds_type (HsDocTy ty _)  -- Remove the doc comment
 541   = dsHsType ty
 542
 543 dsHsTypes arg_tys = mappM dsHsType arg_tys
 544 \end{code}
 545
 546 Help functions for type applications
 547 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 548
 549 \begin{code}
 550 ds_app :: HsType Name -> [LHsType Name] -> TcM Type
 551 ds_app (HsAppTy ty1 ty2) tys
 552   = ds_app (unLoc ty1) (ty2:tys)
 553
 554 ds_app ty tys
 555   = dsHsTypes tys                       `thenM` \ arg_tys ->
 556     case ty of
 557         HsTyVar fun -> ds_var_app fun arg_tys
 558         other       -> ds_type ty               `thenM` \ fun_ty ->
 559                        returnM (mkAppTys fun_ty arg_tys)
 560
 561 ds_var_app :: Name -> [Type] -> TcM Type
 562 ds_var_app name arg_tys
 563  = tcLookup name                        `thenM` \ thing ->
 564     case thing of
 565         ATyVar _ ty         -> returnM (mkAppTys ty arg_tys)
 566         AGlobal (ATyCon tc) -> returnM (mkTyConApp tc arg_tys)
 567         other               -> wrongThingErr "type" thing name
 568 \end{code}
 569
 570
 571 Contexts
 572 ~~~~~~~~
 573
 574 \begin{code}
 575 dsHsLPred :: LHsPred Name -> TcM PredType
 576 dsHsLPred pred = dsHsPred (unLoc pred)
 577
 578 dsHsPred pred@(HsClassP class_name tys)
 579   = do { arg_tys <- dsHsTypes tys
 580        ; clas <- tcLookupClass class_name
 581        ; returnM (ClassP clas arg_tys)
 582        }
 583 dsHsPred pred@(HsEqualP ty1 ty2)
 584   = do { arg_ty1 <- dsHsType ty1
 585        ; arg_ty2 <- dsHsType ty2
 586        ; returnM (EqPred arg_ty1 arg_ty2)
 587        }
 588 dsHsPred (HsIParam name ty)
 589   = do { arg_ty <- dsHsType ty
 590        ; returnM (IParam name arg_ty)
 591        }
 592 \end{code}
 593
 594 GADT constructor signatures
 595
 596 \begin{code}
 597 tcLHsConResTy :: LHsType Name -> TcM (TyCon, [TcType])
 598 tcLHsConResTy res_ty
 599   = addErrCtxt (gadtResCtxt res_ty) $
 600     case get_largs res_ty [] of
 601            (HsTyVar tc_name, args)
 602               -> do { args' <- mapM dsHsType args
 603                     ; thing <- tcLookup tc_name
 604                     ; case thing of
 605                         AGlobal (ATyCon tc) -> return (tc, args')
 606                         other -> failWithTc (badGadtDecl res_ty) }
 607            other -> failWithTc (badGadtDecl res_ty)
 608   where
 609         -- We can't call dsHsType on res_ty, and then do tcSplitTyConApp_maybe
 610         -- because that causes a black hole, and for good reason.  Building
 611         -- the type means expanding type synonyms, and we can't do that
 612         -- inside the "knot".  So we have to work by steam.
 613     get_largs (L _ ty) args = get_args ty args
 614     get_args (HsAppTy fun arg)            args = get_largs fun (arg:args)
 615     get_args (HsParTy ty)                 args = get_largs ty  args
 616     get_args (HsOpTy ty1 (L span tc) ty2) args = (HsTyVar tc, ty1:ty2:args)
 617     get_args ty                           args = (ty, args)
 618
 619 gadtResCtxt ty
 620   = hang (ptext SLIT("In the result type of a data constructor:"))
 621        2 (ppr ty)
 622 badGadtDecl ty
 623   = hang (ptext SLIT("Malformed constructor result type:"))
 624        2 (ppr ty)
 625
 626 typeCtxt ty = ptext SLIT("In the type") <+> quotes (ppr ty)
 627 \end{code}
 628
 629 %************************************************************************
 630 %*                                                                      *
 631                 Type-variable binders
 632 %*                                                                      *
 633 %************************************************************************
 634
 635
 636 \begin{code}
 637 kcHsTyVars :: [LHsTyVarBndr Name]
 638            -> ([LHsTyVarBndr Name] -> TcM r)    -- These binders are kind-annotated
 639                                                 -- They scope over the thing inside
 640            -> TcM r
 641 kcHsTyVars tvs thing_inside
 642   = mappM (wrapLocM kcHsTyVar) tvs      `thenM` \ bndrs ->
 643     tcExtendKindEnvTvs bndrs (thing_inside bndrs)
 644
 645 kcHsTyVar :: HsTyVarBndr Name -> TcM (HsTyVarBndr Name)
 646         -- Return a *kind-annotated* binder, and a tyvar with a mutable kind in it
 647 kcHsTyVar (UserTyVar name)        = newKindVar  `thenM` \ kind ->
 648                                     returnM (KindedTyVar name kind)
 649 kcHsTyVar (KindedTyVar name kind) = returnM (KindedTyVar name kind)
 650
 651 ------------------
 652 tcTyVarBndrs :: [LHsTyVarBndr Name]     -- Kind-annotated binders, which need kind-zonking
 653              -> ([TyVar] -> TcM r)
 654              -> TcM r
 655 -- Used when type-checking types/classes/type-decls
 656 -- Brings into scope immutable TyVars, not mutable ones that require later zonking
 657 tcTyVarBndrs bndrs thing_inside
 658   = mapM (zonk . unLoc) bndrs   `thenM` \ tyvars ->
 659     tcExtendTyVarEnv tyvars (thing_inside tyvars)
 660   where
 661     zonk (KindedTyVar name kind) = do { kind' <- zonkTcKindToKind kind
 662                                       ; return (mkTyVar name kind') }
 663     zonk (UserTyVar name) = WARN( True, ptext SLIT("Un-kinded tyvar") <+> ppr name )
 664                             return (mkTyVar name liftedTypeKind)
 665
 666 -----------------------------------
 667 tcDataKindSig :: Maybe Kind -> TcM [TyVar]
 668 -- GADT decls can have a (perhaps partial) kind signature
 669 --      e.g.  data T :: * -> * -> * where ...
 670 -- This function makes up suitable (kinded) type variables for
 671 -- the argument kinds, and checks that the result kind is indeed *.
 672 -- We use it also to make up argument type variables for for data instances.
 673 tcDataKindSig Nothing = return []
 674 tcDataKindSig (Just kind)
 675   = do  { checkTc (isLiftedTypeKind res_kind) (badKindSig kind)
 676         ; span <- getSrcSpanM
 677         ; us   <- newUniqueSupply
 678         ; let uniqs = uniqsFromSupply us
 679         ; return [ mk_tv span uniq str kind
 680                  | ((kind, str), uniq) <- arg_kinds `zip` names `zip` uniqs ] }
 681   where
 682     (arg_kinds, res_kind) = splitKindFunTys kind
 683     mk_tv loc uniq str kind = mkTyVar name kind
 684         where
 685            name = mkInternalName uniq occ loc
 686            occ  = mkOccName tvName str
 687
 688     names :: [String]   -- a,b,c...aa,ab,ac etc
 689     names = [ c:cs | cs <- "" : names, c <- ['a'..'z'] ]
 690
 691 badKindSig :: Kind -> SDoc
 692 badKindSig kind
 693  = hang (ptext SLIT("Kind signature on data type declaration has non-* return kind"))
 694         2 (ppr kind)
 695 \end{code}
 696
 697
 698 %************************************************************************
 699 %*                                                                      *
 700                 Scoped type variables
 701 %*                                                                      *
 702 %************************************************************************
 703
 704
 705 tcAddScopedTyVars is used for scoped type variables added by pattern
 706 type signatures
 707         e.g.  \ ((x::a), (y::a)) -> x+y
 708 They never have explicit kinds (because this is source-code only)
 709 They are mutable (because they can get bound to a more specific type).
 710
 711 Usually we kind-infer and expand type splices, and then
 712 tupecheck/desugar the type.  That doesn't work well for scoped type
 713 variables, because they scope left-right in patterns.  (e.g. in the
 714 example above, the 'a' in (y::a) is bound by the 'a' in (x::a).
 715
 716 The current not-very-good plan is to
 717   * find all the types in the patterns
 718   * find their free tyvars
 719   * do kind inference
 720   * bring the kinded type vars into scope
 721   * BUT throw away the kind-checked type
 722         (we'll kind-check it again when we type-check the pattern)
 723
 724 This is bad because throwing away the kind checked type throws away
 725 its splices.  But too bad for now.  [July 03]
 726
 727 Historical note:
 728     We no longer specify that these type variables must be univerally
 729     quantified (lots of email on the subject).  If you want to put that
 730     back in, you need to
 731         a) Do a checkSigTyVars after thing_inside
 732         b) More insidiously, don't pass in expected_ty, else
 733            we unify with it too early and checkSigTyVars barfs
 734            Instead you have to pass in a fresh ty var, and unify
 735            it with expected_ty afterwards
 736
 737 \begin{code}
 738 tcHsPatSigType :: UserTypeCtxt
 739                -> LHsType Name          -- The type signature
 740                -> TcM ([TyVar],         -- Newly in-scope type variables
 741                         Type)           -- The signature
 742 -- Used for type-checking type signatures in
 743 -- (a) patterns           e.g  f (x::Int) = e
 744 -- (b) result signatures  e.g. g x :: Int = e
 745 -- (c) RULE forall bndrs  e.g. forall (x::Int). f x = x
 746
 747 tcHsPatSigType ctxt hs_ty
 748   = addErrCtxt (pprHsSigCtxt ctxt hs_ty) $
 749     do  {       -- Find the type variables that are mentioned in the type
 750                 -- but not already in scope.  These are the ones that
 751                 -- should be bound by the pattern signature
 752           in_scope <- getInLocalScope
 753         ; let span = getLoc hs_ty
 754               sig_tvs = [ L span (UserTyVar n)
 755                         | n <- nameSetToList (extractHsTyVars hs_ty),
 756                           not (in_scope n) ]
 757
 758         ; (tyvars, sig_ty) <- tcHsQuantifiedType sig_tvs hs_ty
 759         ; checkValidType ctxt sig_ty
 760         ; return (tyvars, sig_ty)
 761       }
 762
 763 tcPatSig :: UserTypeCtxt
 764          -> LHsType Name
 765          -> BoxySigmaType
 766          -> TcM (TcType,           -- The type to use for "inside" the signature
 767                  [(Name,TcType)])  -- The new bit of type environment, binding
 768                                    -- the scoped type variables
 769 tcPatSig ctxt sig res_ty
 770   = do  { (sig_tvs, sig_ty) <- tcHsPatSigType ctxt sig
 771
 772         ; if null sig_tvs then do {
 773                 -- The type signature binds no type variables,
 774                 -- and hence is rigid, so use it to zap the res_ty
 775                   boxyUnify sig_ty res_ty
 776                 ; return (sig_ty, [])
 777
 778         } else do {
 779                 -- Type signature binds at least one scoped type variable
 780
 781                 -- A pattern binding cannot bind scoped type variables
 782                 -- The renamer fails with a name-out-of-scope error
 783                 -- if a pattern binding tries to bind a type variable,
 784                 -- So we just have an ASSERT here
 785         ; let in_pat_bind = case ctxt of
 786                                 BindPatSigCtxt -> True
 787                                 other          -> False
 788         ; ASSERT( not in_pat_bind || null sig_tvs ) return ()
 789
 790                 -- Check that pat_ty is rigid
 791         ; checkTc (isRigidTy res_ty) (wobblyPatSig sig_tvs)
 792
 793                 -- Now match the pattern signature against res_ty
 794                 -- For convenience, and uniform-looking error messages
 795                 -- we do the matching by allocating meta type variables,
 796                 -- unifying, and reading out the results.
 797                 -- This is a strictly local operation.
 798         ; box_tvs <- mapM tcInstBoxyTyVar sig_tvs
 799         ; boxyUnify (substTyWith sig_tvs (mkTyVarTys box_tvs) sig_ty) res_ty
 800         ; sig_tv_tys <- mapM readFilledBox box_tvs
 801
 802                 -- Check that each is bound to a distinct type variable,
 803                 -- and one that is not already in scope
 804         ; let tv_binds = map tyVarName sig_tvs `zip` sig_tv_tys
 805         ; binds_in_scope <- getScopedTyVarBinds
 806         ; check binds_in_scope tv_binds
 807
 808                 -- Phew!
 809         ; return (res_ty, tv_binds)
 810         } }
 811   where
 812     check in_scope []            = return ()
 813     check in_scope ((n,ty):rest) = do { check_one in_scope n ty
 814                                       ; check ((n,ty):in_scope) rest }
 815
 816     check_one in_scope n ty
 817         = do { checkTc (tcIsTyVarTy ty) (scopedNonVar n ty)
 818                 -- Must bind to a type variable
 819
 820              ; checkTc (null dups) (dupInScope n (head dups) ty)
 821                 -- Must not bind to the same type variable
 822                 -- as some other in-scope type variable
 823
 824              ; return () }
 825         where
 826           dups = [n' | (n',ty') <- in_scope, tcEqType ty' ty]
 827 \end{code}
 828
 829
 830 %************************************************************************
 831 %*                                                                      *
 832                 Scoped type variables
 833 %*                                                                      *
 834 %************************************************************************
 835
 836 \begin{code}
 837 pprHsSigCtxt :: UserTypeCtxt -> LHsType Name -> SDoc
 838 pprHsSigCtxt ctxt hs_ty = vcat [ ptext SLIT("In") <+> pprUserTypeCtxt ctxt <> colon,
 839                                  nest 2 (pp_sig ctxt) ]
 840   where
 841     pp_sig (FunSigCtxt n)  = pp_n_colon n
 842     pp_sig (ConArgCtxt n)  = pp_n_colon n
 843     pp_sig (ForSigCtxt n)  = pp_n_colon n
 844     pp_sig other           = ppr (unLoc hs_ty)
 845
 846     pp_n_colon n = ppr n <+> dcolon <+> ppr (unLoc hs_ty)
 847
 848
 849 wobblyPatSig sig_tvs
 850   = hang (ptext SLIT("A pattern type signature cannot bind scoped type variables")
 851                 <+> pprQuotedList sig_tvs)
 852        2 (ptext SLIT("unless the pattern has a rigid type context"))
 853
 854 scopedNonVar n ty
 855   = vcat [sep [ptext SLIT("The scoped type variable") <+> quotes (ppr n),
 856                nest 2 (ptext SLIT("is bound to the type") <+> quotes (ppr ty))],
 857           nest 2 (ptext SLIT("You can only bind scoped type variables to type variables"))]
 858
 859 dupInScope n n' ty
 860   = hang (ptext SLIT("The scoped type variables") <+> quotes (ppr n) <+> ptext SLIT("and") <+> quotes (ppr n'))
 861        2 (vcat [ptext SLIT("are bound to the same type (variable)"),
 862                 ptext SLIT("Distinct scoped type variables must be distinct")])
 863
 864 wrongEqualityErr
 865   = failWithTc (text "Equality predicate used as a type")
 866 \end{code}
 867