compiler/typecheck/TcInteract.lhs

   1 \begin{code}
   2 module TcInteract (
   3      solveInteract, solveInteractGiven, solveInteractWanted,
   4      AtomicInert, tyVarsOfInert,
   5      InertSet, emptyInert, updInertSet, extractUnsolved, solveOne,
   6   ) where
   7
   8 #include "HsVersions.h"
   9
  10
  11 import BasicTypes
  12 import TcCanonical
  13 import VarSet
  14 import Type
  15
  16 import Id
  17 import Var
  18
  19 import TcType
  20 import HsBinds
  21
  22 import Inst( tyVarsOfEvVar )
  23 import Class
  24 import TyCon
  25 import Name
  26
  27 import FunDeps
  28
  29 import Coercion
  30 import Outputable
  31
  32 import TcRnTypes
  33 import TcErrors
  34 import TcSMonad
  35 import Bag
  36 import qualified Data.Map as Map
  37
  38 import Control.Monad( when )
  39
  40 import FastString ( sLit )
  41 import DynFlags
  42 \end{code}
  43
  44 Note [InertSet invariants]
  45 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
  46 An InertSet is a bag of canonical constraints, with the following invariants:
  47
  48   1 No two constraints react with each other.
  49
  50     A tricky case is when there exists a given (solved) dictionary
  51     constraint and a wanted identical constraint in the inert set, but do
  52     not react because reaction would create loopy dictionary evidence for
  53     the wanted. See note [Recursive dictionaries]
  54
  55   2 Given equalities form an idempotent substitution [none of the
  56     given LHS's occur in any of the given RHS's or reactant parts]
  57
  58   3 Wanted equalities also form an idempotent substitution
  59
  60   4 The entire set of equalities is acyclic.
  61
  62   5 Wanted dictionaries are inert with the top-level axiom set
  63
  64   6 Equalities of the form tv1 ~ tv2 always have a touchable variable
  65     on the left (if possible).
  66
  67   7 No wanted constraints tv1 ~ tv2 with tv1 touchable. Such constraints
  68     will be marked as solved right before being pushed into the inert set.
  69     See note [Touchables and givens].
  70
  71   8 No Given constraint mentions a touchable unification variable,
  72     except if the
  73
  74 Note that 6 and 7 are /not/ enforced by canonicalization but rather by
  75 insertion in the inert list, ie by TcInteract.
  76
  77 During the process of solving, the inert set will contain some
  78 previously given constraints, some wanted constraints, and some given
  79 constraints which have arisen from solving wanted constraints. For
  80 now we do not distinguish between given and solved constraints.
  81
  82 Note that we must switch wanted inert items to given when going under an
  83 implication constraint (when in top-level inference mode).
  84
  85 \begin{code}
  86
  87 data CCanMap a = CCanMap { cts_given   :: Map.Map a CanonicalCts
  88                                           -- Invariant: all Given
  89                          , cts_derived :: Map.Map a CanonicalCts
  90                                           -- Invariant: all Derived
  91                          , cts_wanted  :: Map.Map a CanonicalCts }
  92                                           -- Invariant: all Wanted
  93
  94 cCanMapToBag :: Ord a => CCanMap a -> CanonicalCts
  95 cCanMapToBag cmap = Map.fold unionBags rest_wder (cts_given cmap)
  96   where rest_wder = Map.fold unionBags rest_der  (cts_wanted cmap)
  97         rest_der  = Map.fold unionBags emptyCCan (cts_derived cmap)
  98
  99 emptyCCanMap :: CCanMap a
 100 emptyCCanMap = CCanMap { cts_given = Map.empty
 101                        , cts_derived = Map.empty, cts_wanted = Map.empty }
 102
 103 updCCanMap:: Ord a => (a,CanonicalCt) -> CCanMap a -> CCanMap a
 104 updCCanMap (a,ct) cmap
 105   = case cc_flavor ct of
 106       Wanted {}
 107           -> cmap { cts_wanted = Map.insertWith unionBags a this_ct (cts_wanted cmap) }
 108       Given {}
 109           -> cmap { cts_given = Map.insertWith unionBags a this_ct (cts_given cmap) }
 110       Derived {}
 111           -> cmap { cts_derived = Map.insertWith unionBags a this_ct (cts_derived cmap) }
 112   where this_ct = singleCCan ct
 113
 114 getRelevantCts :: Ord a => a -> CCanMap a -> (CanonicalCts, CCanMap a)
 115 -- Gets the relevant constraints and returns the rest of the CCanMap
 116 getRelevantCts a cmap
 117     = let relevant = unionManyBags [ Map.findWithDefault emptyCCan a (cts_wanted cmap)
 118                                    , Map.findWithDefault emptyCCan a (cts_given cmap)
 119                                    , Map.findWithDefault emptyCCan a (cts_derived cmap) ]
 120           residual_map = cmap { cts_wanted = Map.delete a (cts_wanted cmap)
 121                               , cts_given = Map.delete a (cts_given cmap)
 122                               , cts_derived = Map.delete a (cts_derived cmap) }
 123       in (relevant, residual_map)
 124
 125 extractUnsolvedCMap :: Ord a => CCanMap a -> (CanonicalCts, CCanMap a)
 126 -- Gets the wanted or derived constraints and returns a residual
 127 -- CCanMap with only givens.
 128 extractUnsolvedCMap cmap =
 129   let wntd = Map.fold unionBags emptyCCan (cts_wanted cmap)
 130       derd = Map.fold unionBags emptyCCan (cts_derived cmap)
 131   in (wntd `unionBags` derd,
 132            cmap { cts_wanted = Map.empty, cts_derived = Map.empty })
 133
 134
 135 -- See Note [InertSet invariants]
 136 data InertSet
 137   = IS { inert_eqs          :: CanonicalCts               -- Equalities only (CTyEqCan)
 138        , inert_dicts        :: CCanMap Class              -- Dictionaries only
 139        , inert_ips          :: CCanMap (IPName Name)      -- Implicit parameters
 140        , inert_frozen       :: CanonicalCts
 141        , inert_funeqs       :: CCanMap TyCon              -- Type family equalities only
 142                -- This representation allows us to quickly get to the relevant
 143                -- inert constraints when interacting a work item with the inert set.
 144        }
 145
 146 tyVarsOfInert :: InertSet -> TcTyVarSet
 147 tyVarsOfInert (IS { inert_eqs    = eqs
 148                   , inert_dicts  = dictmap
 149                   , inert_ips    = ipmap
 150                   , inert_frozen = frozen
 151                   , inert_funeqs = funeqmap }) = tyVarsOfCanonicals cts
 152   where
 153     cts = eqs `andCCan` frozen `andCCan` cCanMapToBag dictmap
 154               `andCCan` cCanMapToBag ipmap `andCCan` cCanMapToBag funeqmap
 155
 156 instance Outputable InertSet where
 157   ppr is = vcat [ vcat (map ppr (Bag.bagToList $ inert_eqs is))
 158                 , vcat (map ppr (Bag.bagToList $ cCanMapToBag (inert_dicts is)))
 159                 , vcat (map ppr (Bag.bagToList $ cCanMapToBag (inert_ips is)))
 160                 , vcat (map ppr (Bag.bagToList $ cCanMapToBag (inert_funeqs is)))
 161                 , vcat (map ppr (Bag.bagToList $ inert_frozen is))
 162                 ]
 163
 164 emptyInert :: InertSet
 165 emptyInert = IS { inert_eqs    = Bag.emptyBag
 166                 , inert_frozen = Bag.emptyBag
 167                 , inert_dicts  = emptyCCanMap
 168                 , inert_ips    = emptyCCanMap
 169                 , inert_funeqs = emptyCCanMap }
 170
 171 updInertSet :: InertSet -> AtomicInert -> InertSet
 172 updInertSet is item
 173   | isCTyEqCan item                     -- Other equality
 174   = let eqs' = inert_eqs is `Bag.snocBag` item
 175     in is { inert_eqs = eqs' }
 176   | Just cls <- isCDictCan_Maybe item   -- Dictionary
 177   = is { inert_dicts = updCCanMap (cls,item) (inert_dicts is) }
 178   | Just x  <- isCIPCan_Maybe item      -- IP
 179   = is { inert_ips   = updCCanMap (x,item) (inert_ips is) }
 180   | Just tc <- isCFunEqCan_Maybe item   -- Function equality
 181   = is { inert_funeqs = updCCanMap (tc,item) (inert_funeqs is) }
 182   | otherwise
 183   = is { inert_frozen = inert_frozen is `Bag.snocBag` item }
 184
 185 extractUnsolved :: InertSet -> (InertSet, CanonicalCts)
 186 -- Postcondition: the returned canonical cts are either Derived, or Wanted.
 187 extractUnsolved is@(IS {inert_eqs = eqs})
 188   = let is_solved  = is { inert_eqs    = solved_eqs
 189                         , inert_dicts  = solved_dicts
 190                         , inert_ips    = solved_ips
 191                         , inert_frozen = emptyCCan
 192                         , inert_funeqs = solved_funeqs }
 193     in (is_solved, unsolved)
 194
 195   where (unsolved_eqs, solved_eqs)       = Bag.partitionBag (not.isGivenCt) eqs
 196         (unsolved_ips, solved_ips)       = extractUnsolvedCMap (inert_ips is)
 197         (unsolved_dicts, solved_dicts)   = extractUnsolvedCMap (inert_dicts is)
 198         (unsolved_funeqs, solved_funeqs) = extractUnsolvedCMap (inert_funeqs is)
 199
 200         unsolved = unsolved_eqs `unionBags` inert_frozen is `unionBags`
 201                    unsolved_ips `unionBags` unsolved_dicts `unionBags` unsolved_funeqs
 202 \end{code}
 203
 204 %*********************************************************************
 205 %*                                                                   *
 206 *                      Main Interaction Solver                       *
 207 *                                                                    *
 208 **********************************************************************
 209
 210 Note [Basic plan]
 211 ~~~~~~~~~~~~~~~~~
 212 1. Canonicalise (unary)
 213 2. Pairwise interaction (binary)
 214     * Take one from work list
 215     * Try all pair-wise interactions with each constraint in inert
 216
 217    As an optimisation, we prioritize the equalities both in the
 218    worklist and in the inerts.
 219
 220 3. Try to solve spontaneously for equalities involving touchables
 221 4. Top-level interaction (binary wrt top-level)
 222    Superclass decomposition belongs in (4), see note [Superclasses]
 223
 224 \begin{code}
 225 type AtomicInert = CanonicalCt     -- constraint pulled from InertSet
 226 type WorkItem    = CanonicalCt     -- constraint pulled from WorkList
 227
 228 -- A mixture of Given, Wanted, and Derived constraints.
 229 -- We split between equalities and the rest to process equalities first.
 230 type WorkList = CanonicalCts
 231
 232 unionWorkLists :: WorkList -> WorkList -> WorkList
 233 unionWorkLists = andCCan
 234
 235 isEmptyWorkList :: WorkList -> Bool
 236 isEmptyWorkList = isEmptyCCan
 237
 238 emptyWorkList :: WorkList
 239 emptyWorkList = emptyCCan
 240
 241 workListFromCCan :: CanonicalCt -> WorkList
 242 workListFromCCan = singleCCan
 243
 244 ------------------------
 245 data StopOrContinue
 246   = Stop                        -- Work item is consumed
 247   | ContinueWith WorkItem       -- Not consumed
 248
 249 instance Outputable StopOrContinue where
 250   ppr Stop             = ptext (sLit "Stop")
 251   ppr (ContinueWith w) = ptext (sLit "ContinueWith") <+> ppr w
 252
 253 -- Results after interacting a WorkItem as far as possible with an InertSet
 254 data StageResult
 255   = SR { sr_inerts     :: InertSet
 256            -- The new InertSet to use (REPLACES the old InertSet)
 257        , sr_new_work   :: WorkList
 258            -- Any new work items generated (should be ADDED to the old WorkList)
 259            -- Invariant:
 260            --    sr_stop = Just workitem => workitem is *not* in sr_inerts and
 261            --                               workitem is inert wrt to sr_inerts
 262        , sr_stop       :: StopOrContinue
 263        }
 264
 265 instance Outputable StageResult where
 266   ppr (SR { sr_inerts = inerts, sr_new_work = work, sr_stop = stop })
 267     = ptext (sLit "SR") <+>
 268       braces (sep [ ptext (sLit "inerts =") <+> ppr inerts <> comma
 269                   , ptext (sLit "new work =") <+> ppr work <> comma
 270                   , ptext (sLit "stop =") <+> ppr stop])
 271
 272 type SubGoalDepth = Int   -- Starts at zero; used to limit infinite
 273                           -- recursion of sub-goals
 274 type SimplifierStage = SubGoalDepth -> WorkItem -> InertSet -> TcS StageResult
 275
 276 -- Combine a sequence of simplifier 'stages' to create a pipeline
 277 runSolverPipeline :: SubGoalDepth
 278                   -> [(String, SimplifierStage)]
 279                   -> InertSet -> WorkItem
 280                   -> TcS (InertSet, WorkList)
 281 -- Precondition: non-empty list of stages
 282 runSolverPipeline depth pipeline inerts workItem
 283   = do { traceTcS "Start solver pipeline" $
 284             vcat [ ptext (sLit "work item =") <+> ppr workItem
 285                  , ptext (sLit "inerts    =") <+> ppr inerts]
 286
 287        ; let itr_in = SR { sr_inerts = inerts
 288                          , sr_new_work = emptyWorkList
 289                          , sr_stop = ContinueWith workItem }
 290        ; itr_out <- run_pipeline pipeline itr_in
 291        ; let new_inert
 292               = case sr_stop itr_out of
 293                   Stop              -> sr_inerts itr_out
 294                   ContinueWith item -> sr_inerts itr_out `updInertSet` item
 295        ; return (new_inert, sr_new_work itr_out) }
 296   where
 297     run_pipeline :: [(String, SimplifierStage)]
 298                  -> StageResult -> TcS StageResult
 299     run_pipeline [] itr                         = return itr
 300     run_pipeline _  itr@(SR { sr_stop = Stop }) = return itr
 301
 302     run_pipeline ((name,stage):stages)
 303                  (SR { sr_new_work = accum_work
 304                      , sr_inerts   = inerts
 305                      , sr_stop     = ContinueWith work_item })
 306       = do { itr <- stage depth work_item inerts
 307            ; traceTcS ("Stage result (" ++ name ++ ")") (ppr itr)
 308            ; let itr' = itr { sr_new_work = accum_work `unionWorkLists` sr_new_work itr }
 309            ; run_pipeline stages itr' }
 310 \end{code}
 311
 312 Example 1:
 313   Inert:   {c ~ d, F a ~ t, b ~ Int, a ~ ty} (all given)
 314   Reagent: a ~ [b] (given)
 315
 316 React with (c~d)     ==> IR (ContinueWith (a~[b]))  True    []
 317 React with (F a ~ t) ==> IR (ContinueWith (a~[b]))  False   [F [b] ~ t]
 318 React with (b ~ Int) ==> IR (ContinueWith (a~[Int]) True    []
 319
 320 Example 2:
 321   Inert:  {c ~w d, F a ~g t, b ~w Int, a ~w ty}
 322   Reagent: a ~w [b]
 323
 324 React with (c ~w d)   ==> IR (ContinueWith (a~[b]))  True    []
 325 React with (F a ~g t) ==> IR (ContinueWith (a~[b]))  True    []    (can't rewrite given with wanted!)
 326 etc.
 327
 328 Example 3:
 329   Inert:  {a ~ Int, F Int ~ b} (given)
 330   Reagent: F a ~ b (wanted)
 331
 332 React with (a ~ Int)   ==> IR (ContinueWith (F Int ~ b)) True []
 333 React with (F Int ~ b) ==> IR Stop True []    -- after substituting we re-canonicalize and get nothing
 334
 335 \begin{code}
 336 -- Main interaction solver: we fully solve the worklist 'in one go',
 337 -- returning an extended inert set.
 338 --
 339 -- See Note [Touchables and givens].
 340 solveInteractGiven :: InertSet -> GivenLoc -> [EvVar] -> TcS InertSet
 341 solveInteractGiven inert gloc evs
 342   = do { (_, inert_ret) <- solveInteract inert $ listToBag $
 343                            map mk_given evs
 344        ; return inert_ret }
 345   where
 346     flav = Given gloc
 347     mk_given ev = mkEvVarX ev flav
 348
 349 solveInteractWanted :: InertSet -> [WantedEvVar] -> TcS InertSet
 350 solveInteractWanted inert wvs
 351   = do { (_,inert_ret) <- solveInteract inert $ listToBag $
 352                           map wantedToFlavored wvs
 353        ; return inert_ret }
 354
 355 solveInteract :: InertSet -> Bag FlavoredEvVar -> TcS (Bool, InertSet)
 356 -- Post: (True,  inert_set) means we managed to discharge all constraints
 357 --                          without actually doing any interactions!
 358 --       (False, inert_set) means some interactions occurred
 359 solveInteract inert ws
 360   = do { dyn_flags <- getDynFlags
 361        ; sctx <- getTcSContext
 362
 363        ; traceTcS "solveInteract, before clever canonicalization:" $
 364          vcat [ text "ws = " <+>  ppr (mapBag (\(EvVarX ev ct)
 365                                                    -> (ct,evVarPred ev)) ws)
 366               , text "inert = " <+> ppr inert ]
 367
 368        ; (flag, inert_ret) <- foldlBagM (tryPreSolveAndInteract sctx dyn_flags) (True,inert) ws
 369
 370        ; traceTcS "solveInteract, after clever canonicalization (and interaction):" $
 371          vcat [ text "No interaction happened = " <+> ppr flag
 372               , text "inert_ret = " <+> ppr inert_ret ]
 373
 374        ; return (flag, inert_ret) }
 375
 376
 377 tryPreSolveAndInteract :: SimplContext
 378                        -> DynFlags
 379                        -> (Bool, InertSet)
 380                        -> FlavoredEvVar
 381                        -> TcS (Bool, InertSet)
 382 -- Returns: True if it was able to discharge this constraint AND all previous ones
 383 tryPreSolveAndInteract sctx dyn_flags (all_previous_discharged, inert)
 384                        flavev@(EvVarX ev_var fl)
 385   = do { let inert_cts = get_inert_cts (evVarPred ev_var)
 386
 387        ; this_one_discharged <- dischargeFromCCans inert_cts flavev
 388
 389        ; if this_one_discharged
 390          then return (all_previous_discharged, inert)
 391
 392          else do
 393        { extra_cts <- mkCanonical fl ev_var
 394        ; inert_ret <- solveInteractWithDepth (ctxtStkDepth dyn_flags,0,[])
 395                                              inert extra_cts
 396        ; return (False, inert_ret) } }
 397
 398   where
 399     get_inert_cts (ClassP clas _)
 400       | simplEqsOnly sctx = emptyCCan
 401       | otherwise         = fst (getRelevantCts clas (inert_dicts inert))
 402     get_inert_cts (IParam {})
 403       = emptyCCan -- We must not do the same thing for IParams, because (contrary
 404                   -- to dictionaries), work items /must/ override inert items.
 405                  -- See Note [Overriding implicit parameters] in TcInteract.
 406     get_inert_cts (EqPred {})
 407       = inert_eqs inert `unionBags` cCanMapToBag (inert_funeqs inert)
 408
 409 dischargeFromCCans :: CanonicalCts -> FlavoredEvVar -> TcS Bool
 410 dischargeFromCCans cans (EvVarX ev fl)
 411   = Bag.foldlBagM discharge_ct False cans
 412   where discharge_ct :: Bool -> CanonicalCt -> TcS Bool
 413         discharge_ct True _ct = return True
 414         discharge_ct False ct
 415           | evVarPred (cc_id ct) `tcEqPred` evVarPred ev
 416           , cc_flavor ct `canSolve` fl
 417           = do { when (isWanted fl) $ set_ev_bind ev (cc_id ct)
 418                ; return True }
 419           where set_ev_bind x y
 420                     | EqPred {} <- evVarPred y
 421                     = setEvBind x (EvCoercion (mkCoVarCoercion y))
 422                     | otherwise = setEvBind x (EvId y)
 423         discharge_ct False _ct = return False
 424 \end{code}
 425
 426 Note [Avoiding the superclass explosion]
 427 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 428 This note now is not as significant as it used to be because we no
 429 longer add the superclasses of Wanted as Derived, except only if they
 430 have equality superclasses or superclasses with functional
 431 dependencies. The fear was that hundreds of identical wanteds would
 432 give rise each to the same superclass or equality Derived's which
 433 would lead to a blo-up in the number of interactions.
 434
 435 Instead, what we do with tryPreSolveAndCanon, is when we encounter a
 436 new constraint, we very quickly see if it can be immediately
 437 discharged by a class constraint in our inert set or the previous
 438 canonicals. If so, we add nothing to the returned canonical
 439 constraints.
 440
 441 \begin{code}
 442 solveOne :: InertSet -> WorkItem -> TcS InertSet
 443 solveOne inerts workItem
 444   = do { dyn_flags <- getDynFlags
 445        ; solveOneWithDepth (ctxtStkDepth dyn_flags,0,[]) inerts workItem
 446        }
 447
 448 -----------------
 449 solveInteractWithDepth :: (Int, Int, [WorkItem])
 450                        -> InertSet -> WorkList -> TcS InertSet
 451 solveInteractWithDepth ctxt@(max_depth,n,stack) inert ws
 452   | isEmptyWorkList ws
 453   = return inert
 454
 455   | n > max_depth
 456   = solverDepthErrorTcS n stack
 457
 458   | otherwise
 459   = do { traceTcS "solveInteractWithDepth" $
 460               vcat [ text "Current depth =" <+> ppr n
 461                    , text "Max depth =" <+> ppr max_depth ]
 462
 463               -- Solve equalities first
 464        ; let (eqs, non_eqs) = Bag.partitionBag isCTyEqCan ws
 465        ; is_from_eqs <- Bag.foldlBagM (solveOneWithDepth ctxt) inert eqs
 466        ; Bag.foldlBagM (solveOneWithDepth ctxt) is_from_eqs non_eqs }
 467
 468 ------------------
 469 -- Fully interact the given work item with an inert set, and return a
 470 -- new inert set which has assimilated the new information.
 471 solveOneWithDepth :: (Int, Int, [WorkItem])
 472                   -> InertSet -> WorkItem -> TcS InertSet
 473 solveOneWithDepth (max_depth, depth, stack) inert work
 474   = do { traceFireTcS depth (text "Solving {" <+> ppr work)
 475        ; (new_inert, new_work) <- runSolverPipeline depth thePipeline inert work
 476
 477          -- Recursively solve the new work generated
 478          -- from workItem, with a greater depth
 479        ; res_inert <- solveInteractWithDepth (max_depth, depth+1, work:stack)
 480                                 new_inert new_work
 481
 482        ; traceFireTcS depth (text "Done }" <+> ppr work)
 483
 484        ; return res_inert }
 485
 486 thePipeline :: [(String,SimplifierStage)]
 487 thePipeline = [ ("interact with inert eqs", interactWithInertEqsStage)
 488               , ("interact with inerts",    interactWithInertsStage)
 489               , ("spontaneous solve",       spontaneousSolveStage)
 490               , ("top-level reactions",     topReactionsStage) ]
 491 \end{code}
 492
 493 *********************************************************************************
 494 *                                                                               *
 495                        The spontaneous-solve Stage
 496 *                                                                               *
 497 *********************************************************************************
 498
 499 Note [Efficient Orientation]
 500 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 501
 502 There are two cases where we have to be careful about
 503 orienting equalities to get better efficiency.
 504
 505 Case 1: In Rewriting Equalities (function rewriteEqLHS)
 506
 507     When rewriting two equalities with the same LHS:
 508           (a)  (tv ~ xi1)
 509           (b)  (tv ~ xi2)
 510     We have a choice of producing work (xi1 ~ xi2) (up-to the
 511     canonicalization invariants) However, to prevent the inert items
 512     from getting kicked out of the inerts first, we prefer to
 513     canonicalize (xi1 ~ xi2) if (b) comes from the inert set, or (xi2
 514     ~ xi1) if (a) comes from the inert set.
 515
 516     This choice is implemented using the WhichComesFromInert flag.
 517
 518 Case 2: Functional Dependencies
 519     Again, we should prefer, if possible, the inert variables on the RHS
 520
 521 Case 3: IP improvement work
 522     We must always rewrite so that the inert type is on the right.
 523
 524 \begin{code}
 525 spontaneousSolveStage :: SimplifierStage
 526 spontaneousSolveStage depth workItem inerts
 527   = do { mSolve <- trySpontaneousSolve workItem
 528
 529        ; case mSolve of
 530            SPCantSolve -> -- No spontaneous solution for him, keep going
 531                return $ SR { sr_new_work   = emptyWorkList
 532                            , sr_inerts     = inerts
 533                            , sr_stop       = ContinueWith workItem }
 534
 535            SPSolved workItem'
 536                | not (isGivenCt workItem)
 537                  -- Original was wanted or derived but we have now made him
 538                  -- given so we have to interact him with the inerts due to
 539                  -- its status change. This in turn may produce more work.
 540                  -- We do this *right now* (rather than just putting workItem'
 541                  -- back into the work-list) because we've solved
 542                -> do { bumpStepCountTcS
 543                      ; traceFireTcS depth (ptext (sLit "Spontaneous (w/d)") <+> ppr workItem)
 544                      ; (new_inert, new_work) <- runSolverPipeline depth
 545                              [ ("recursive interact with inert eqs", interactWithInertEqsStage)
 546                              , ("recursive interact with inerts", interactWithInertsStage)
 547                              ] inerts workItem'
 548                      ; return $ SR { sr_new_work = new_work
 549                                    , sr_inerts   = new_inert -- will include workItem'
 550                                    , sr_stop     = Stop }
 551                      }
 552                | otherwise
 553                    -> -- Original was given; he must then be inert all right, and
 554                       -- workList' are all givens from flattening
 555                       do { bumpStepCountTcS
 556                          ; traceFireTcS depth (ptext (sLit "Spontaneous (g)") <+> ppr workItem)
 557                          ; return $ SR { sr_new_work = emptyWorkList
 558                                        , sr_inerts   = inerts `updInertSet` workItem'
 559                                        , sr_stop     = Stop } }
 560            SPError -> -- Return with no new work
 561                return $ SR { sr_new_work = emptyWorkList
 562                            , sr_inerts   = inerts
 563                            , sr_stop     = Stop }
 564        }
 565
 566 data SPSolveResult = SPCantSolve | SPSolved WorkItem | SPError
 567 -- SPCantSolve means that we can't do the unification because e.g. the variable is untouchable
 568 -- SPSolved workItem' gives us a new *given* to go on
 569 -- SPError means that it's completely impossible to solve this equality, eg due to a kind error
 570
 571
 572 -- @trySpontaneousSolve wi@ solves equalities where one side is a
 573 -- touchable unification variable.
 574 --          See Note [Touchables and givens]
 575 trySpontaneousSolve :: WorkItem -> TcS SPSolveResult
 576 trySpontaneousSolve workItem@(CTyEqCan { cc_id = cv, cc_flavor = gw, cc_tyvar = tv1, cc_rhs = xi })
 577   | isGiven gw
 578   = return SPCantSolve
 579   | Just tv2 <- tcGetTyVar_maybe xi
 580   = do { tch1 <- isTouchableMetaTyVar tv1
 581        ; tch2 <- isTouchableMetaTyVar tv2
 582        ; case (tch1, tch2) of
 583            (True,  True)  -> trySpontaneousEqTwoWay cv gw tv1 tv2
 584            (True,  False) -> trySpontaneousEqOneWay cv gw tv1 xi
 585            (False, True)  -> trySpontaneousEqOneWay cv gw tv2 (mkTyVarTy tv1)
 586            _ -> return SPCantSolve }
 587   | otherwise
 588   = do { tch1 <- isTouchableMetaTyVar tv1
 589        ; if tch1 then trySpontaneousEqOneWay cv gw tv1 xi
 590                  else do { traceTcS "Untouchable LHS, can't spontaneously solve workitem:"
 591                                     (ppr workItem)
 592                          ; return SPCantSolve }
 593        }
 594
 595   -- No need for
 596   --      trySpontaneousSolve (CFunEqCan ...) = ...
 597   -- See Note [No touchables as FunEq RHS] in TcSMonad
 598 trySpontaneousSolve _ = return SPCantSolve
 599
 600 ----------------
 601 trySpontaneousEqOneWay :: CoVar -> CtFlavor -> TcTyVar -> Xi -> TcS SPSolveResult
 602 -- tv is a MetaTyVar, not untouchable
 603 trySpontaneousEqOneWay cv gw tv xi
 604   | not (isSigTyVar tv) || isTyVarTy xi
 605   = do { let kxi = typeKind xi -- NB: 'xi' is fully rewritten according to the inerts
 606                                -- so we have its more specific kind in our hands
 607        ; if kxi `isSubKind` tyVarKind tv then
 608              solveWithIdentity cv gw tv xi
 609          else return SPCantSolve
 610 {-
 611          else if tyVarKind tv `isSubKind` kxi then
 612              return SPCantSolve -- kinds are compatible but we can't solveWithIdentity this way
 613                                 -- This case covers the  a_touchable :: * ~ b_untouchable :: ??
 614                                 -- which has to be deferred or floated out for someone else to solve
 615                                 -- it in a scope where 'b' is no longer untouchable.
 616          else do { addErrorTcS KindError gw (mkTyVarTy tv) xi -- See Note [Kind errors]
 617                  ; return SPError }
 618 -}
 619        }
 620   | otherwise -- Still can't solve, sig tyvar and non-variable rhs
 621   = return SPCantSolve
 622
 623 ----------------
 624 trySpontaneousEqTwoWay :: CoVar -> CtFlavor -> TcTyVar -> TcTyVar -> TcS SPSolveResult
 625 -- Both tyvars are *touchable* MetaTyvars so there is only a chance for kind error here
 626 trySpontaneousEqTwoWay cv gw tv1 tv2
 627   | k1 `isSubKind` k2
 628   , nicer_to_update_tv2 = solveWithIdentity cv gw tv2 (mkTyVarTy tv1)
 629   | k2 `isSubKind` k1
 630   = solveWithIdentity cv gw tv1 (mkTyVarTy tv2)
 631   | otherwise -- None is a subkind of the other, but they are both touchable!
 632   = return SPCantSolve
 633     -- do { addErrorTcS KindError gw (mkTyVarTy tv1) (mkTyVarTy tv2)
 634     --   ; return SPError }
 635   where
 636     k1 = tyVarKind tv1
 637     k2 = tyVarKind tv2
 638     nicer_to_update_tv2 = isSigTyVar tv1 || isSystemName (Var.varName tv2)
 639 \end{code}
 640
 641 Note [Kind errors]
 642 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 643 Consider the wanted problem:
 644       alpha ~ (# Int, Int #)
 645 where alpha :: ?? and (# Int, Int #) :: (#). We can't spontaneously solve this constraint,
 646 but we should rather reject the program that give rise to it. If 'trySpontaneousEqTwoWay'
 647 simply returns @CantSolve@ then that wanted constraint is going to propagate all the way and
 648 get quantified over in inference mode. That's bad because we do know at this point that the
 649 constraint is insoluble. Instead, we call 'recKindErrorTcS' here, which will fail later on.
 650
 651 The same applies in canonicalization code in case of kind errors in the givens.
 652
 653 However, when we canonicalize givens we only check for compatibility (@compatKind@).
 654 If there were a kind error in the givens, this means some form of inconsistency or dead code.
 655
 656 You may think that when we spontaneously solve wanteds we may have to look through the
 657 bindings to determine the right kind of the RHS type. E.g one may be worried that xi is
 658 @alpha@ where alpha :: ? and a previous spontaneous solving has set (alpha := f) with (f :: *).
 659 But we orient our constraints so that spontaneously solved ones can rewrite all other constraint
 660 so this situation can't happen.
 661
 662 Note [Spontaneous solving and kind compatibility]
 663 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 664 Note that our canonical constraints insist that *all* equalities (tv ~
 665 xi) or (F xis ~ rhs) require the LHS and the RHS to have *compatible*
 666 the same kinds.  ("compatible" means one is a subKind of the other.)
 667
 668   - It can't be *equal* kinds, because
 669      b) wanted constraints don't necessarily have identical kinds
 670                eg   alpha::? ~ Int
 671      b) a solved wanted constraint becomes a given
 672
 673   - SPJ thinks that *given* constraints (tv ~ tau) always have that
 674     tau has a sub-kind of tv; and when solving wanted constraints
 675     in trySpontaneousEqTwoWay we re-orient to achieve this.
 676
 677   - Note that the kind invariant is maintained by rewriting.
 678     Eg wanted1 rewrites wanted2; if both were compatible kinds before,
 679        wanted2 will be afterwards.  Similarly givens.
 680
 681 Caveat:
 682   - Givens from higher-rank, such as:
 683           type family T b :: * -> * -> *
 684           type instance T Bool = (->)
 685
 686           f :: forall a. ((T a ~ (->)) => ...) -> a -> ...
 687           flop = f (...) True
 688      Whereas we would be able to apply the type instance, we would not be able to
 689      use the given (T Bool ~ (->)) in the body of 'flop'
 690
 691
 692 Note [Avoid double unifications]
 693 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 694 The spontaneous solver has to return a given which mentions the unified unification
 695 variable *on the left* of the equality. Here is what happens if not:
 696   Original wanted:  (a ~ alpha),  (alpha ~ Int)
 697 We spontaneously solve the first wanted, without changing the order!
 698       given : a ~ alpha      [having unified alpha := a]
 699 Now the second wanted comes along, but he cannot rewrite the given, so we simply continue.
 700 At the end we spontaneously solve that guy, *reunifying*  [alpha := Int]
 701
 702 We avoid this problem by orienting the resulting given so that the unification
 703 variable is on the left.  [Note that alternatively we could attempt to
 704 enforce this at canonicalization]
 705
 706 See also Note [No touchables as FunEq RHS] in TcSMonad; avoiding
 707 double unifications is the main reason we disallow touchable
 708 unification variables as RHS of type family equations: F xis ~ alpha.
 709
 710 \begin{code}
 711 ----------------
 712
 713 solveWithIdentity :: CoVar -> CtFlavor -> TcTyVar -> Xi -> TcS SPSolveResult
 714 -- Solve with the identity coercion
 715 -- Precondition: kind(xi) is a sub-kind of kind(tv)
 716 -- Precondition: CtFlavor is Wanted or Derived
 717 -- See [New Wanted Superclass Work] to see why solveWithIdentity
 718 --     must work for Derived as well as Wanted
 719 -- Returns: workItem where
 720 --        workItem = the new Given constraint
 721 solveWithIdentity cv wd tv xi
 722   = do { traceTcS "Sneaky unification:" $
 723                        vcat [text "Coercion variable:  " <+> ppr wd,
 724                              text "Coercion:           " <+> pprEq (mkTyVarTy tv) xi,
 725                              text "Left  Kind is     : " <+> ppr (typeKind (mkTyVarTy tv)),
 726                              text "Right Kind is     : " <+> ppr (typeKind xi)
 727                   ]
 728
 729        ; setWantedTyBind tv xi
 730        ; cv_given <- newGivenCoVar (mkTyVarTy tv) xi xi
 731
 732        ; when (isWanted wd) (setWantedCoBind cv xi)
 733            -- We don't want to do this for Derived, that's why we use 'when (isWanted wd)'
 734
 735        ; return $ SPSolved (CTyEqCan { cc_id = cv_given
 736                                      , cc_flavor = mkGivenFlavor wd UnkSkol
 737                                      , cc_tyvar  = tv, cc_rhs = xi }) }
 738 \end{code}
 739
 740
 741
 742
 743 *********************************************************************************
 744 *                                                                               *
 745                        The interact-with-inert Stage
 746 *                                                                               *
 747 *********************************************************************************
 748
 749 \begin{code}
 750 -- Interaction result of  WorkItem <~> AtomicInert
 751 data InteractResult
 752    = IR { ir_stop         :: StopOrContinue
 753             -- Stop
 754             --   => Reagent (work item) consumed.
 755             -- ContinueWith new_reagent
 756             --   => Reagent transformed but keep gathering interactions.
 757             --      The transformed item remains inert with respect
 758             --      to any previously encountered inerts.
 759
 760         , ir_inert_action :: InertAction
 761             -- Whether the inert item should remain in the InertSet.
 762
 763         , ir_new_work     :: WorkList
 764             -- new work items to add to the WorkList
 765
 766         , ir_fire :: Maybe String    -- Tells whether a rule fired, and if so what
 767         }
 768
 769 -- What to do with the inert reactant.
 770 data InertAction = KeepInert | DropInert
 771
 772 mkIRContinue :: String -> WorkItem -> InertAction -> WorkList -> TcS InteractResult
 773 mkIRContinue rule wi keep newWork
 774   = return $ IR { ir_stop = ContinueWith wi, ir_inert_action = keep
 775                 , ir_new_work = newWork, ir_fire = Just rule }
 776
 777 mkIRStop :: String -> WorkList -> TcS InteractResult
 778 mkIRStop rule newWork
 779   = return $ IR { ir_stop = Stop, ir_inert_action = KeepInert
 780                 , ir_new_work = newWork, ir_fire = Just rule }
 781
 782 noInteraction :: Monad m => WorkItem -> m InteractResult
 783 noInteraction wi
 784   = return $ IR { ir_stop = ContinueWith wi, ir_inert_action = KeepInert
 785                 , ir_new_work = emptyWorkList, ir_fire = Nothing }
 786
 787 data WhichComesFromInert = LeftComesFromInert | RightComesFromInert
 788      -- See Note [Efficient Orientation]
 789
 790
 791 ---------------------------------------------------
 792 -- Interact a single WorkItem with the equalities of an inert set as
 793 -- far as possible, i.e. until we get a Stop result from an individual
 794 -- reaction (i.e. when the WorkItem is consumed), or until we've
 795 -- interact the WorkItem with the entire equalities of the InertSet
 796
 797 interactWithInertEqsStage :: SimplifierStage
 798 interactWithInertEqsStage depth workItem inert
 799   = Bag.foldlBagM (interactNext depth) initITR (inert_eqs inert)
 800   where
 801     initITR = SR { sr_inerts   = inert { inert_eqs = emptyCCan }
 802                  , sr_new_work = emptyWorkList
 803                  , sr_stop     = ContinueWith workItem }
 804
 805 ---------------------------------------------------
 806 -- Interact a single WorkItem with *non-equality* constraints in the inert set.
 807 -- Precondition: equality interactions must have already happened, hence we have
 808 -- to pick up some information from the incoming inert, before folding over the
 809 -- "Other" constraints it contains!
 810
 811 interactWithInertsStage :: SimplifierStage
 812 interactWithInertsStage depth workItem inert
 813   = let (relevant, inert_residual) = getISRelevant workItem inert
 814         initITR = SR { sr_inerts   = inert_residual
 815                      , sr_new_work = emptyWorkList
 816                      , sr_stop     = ContinueWith workItem }
 817     in Bag.foldlBagM (interactNext depth) initITR relevant
 818   where
 819     getISRelevant :: CanonicalCt -> InertSet -> (CanonicalCts, InertSet)
 820     getISRelevant (CFrozenErr {}) is = (emptyCCan, is)
 821                   -- Nothing s relevant; we have alread interacted
 822                   -- it with the equalities in the inert set
 823
 824     getISRelevant (CDictCan { cc_class = cls } ) is
 825       = let (relevant, residual_map) = getRelevantCts cls (inert_dicts is)
 826         in (relevant, is { inert_dicts = residual_map })
 827     getISRelevant (CFunEqCan { cc_fun = tc } ) is
 828       = let (relevant, residual_map) = getRelevantCts tc (inert_funeqs is)
 829         in (relevant, is { inert_funeqs = residual_map })
 830     getISRelevant (CIPCan { cc_ip_nm = nm }) is
 831       = let (relevant, residual_map) = getRelevantCts nm (inert_ips is)
 832         in (relevant, is { inert_ips = residual_map })
 833     -- An equality, finally, may kick everything except equalities out
 834     -- because we have already interacted the equalities in interactWithInertEqsStage
 835     getISRelevant _eq_ct is  -- Equality, everything is relevant for this one
 836                              -- TODO: if we were caching variables, we'd know that only
 837                              --       some are relevant. Experiment with this for now.
 838       = let cts = cCanMapToBag (inert_ips is) `unionBags`
 839                     cCanMapToBag (inert_dicts is) `unionBags` cCanMapToBag (inert_funeqs is)
 840         in (cts, is { inert_dicts  = emptyCCanMap
 841                     , inert_ips    = emptyCCanMap
 842                     , inert_funeqs = emptyCCanMap })
 843
 844 interactNext :: SubGoalDepth -> StageResult -> AtomicInert -> TcS StageResult
 845 interactNext depth it inert
 846   | ContinueWith work_item <- sr_stop it
 847   = do { let inerts = sr_inerts it
 848
 849        ; IR { ir_new_work = new_work, ir_inert_action = inert_action
 850             , ir_fire = fire_info, ir_stop = stop }
 851             <- interactWithInert inert work_item
 852
 853        ; let mk_msg rule
 854                = text rule <+> keep_doc
 855                  <+> vcat [ ptext (sLit "Inert =") <+> ppr inert
 856                           , ptext (sLit "Work =")  <+> ppr work_item
 857                           , ppUnless (isEmptyBag new_work) $
 858                             ptext (sLit "New =") <+> ppr new_work ]
 859              keep_doc = case inert_action of
 860                           KeepInert -> ptext (sLit "[keep]")
 861                           DropInert -> ptext (sLit "[drop]")
 862        ; case fire_info of
 863            Just rule -> do { bumpStepCountTcS
 864                            ; traceFireTcS depth (mk_msg rule) }
 865            Nothing  -> return ()
 866
 867        -- New inerts depend on whether we KeepInert or not
 868        ; let inerts_new = case inert_action of
 869                             KeepInert -> inerts `updInertSet` inert
 870                             DropInert -> inerts
 871
 872        ; return $ SR { sr_inerts   = inerts_new
 873                      , sr_new_work = sr_new_work it `unionWorkLists` new_work
 874                      , sr_stop     = stop } }
 875   | otherwise
 876   = return $ it { sr_inerts = (sr_inerts it) `updInertSet` inert }
 877
 878 -- Do a single interaction of two constraints.
 879 interactWithInert :: AtomicInert -> WorkItem -> TcS InteractResult
 880 interactWithInert inert workitem
 881   =  do { ctxt <- getTcSContext
 882         ; let is_allowed  = allowedInteraction (simplEqsOnly ctxt) inert workitem
 883
 884         ; if is_allowed then
 885               doInteractWithInert inert workitem
 886           else
 887               noInteraction workitem
 888         }
 889
 890 allowedInteraction :: Bool -> AtomicInert -> WorkItem -> Bool
 891 -- Allowed interactions
 892 allowedInteraction eqs_only (CDictCan {}) (CDictCan {}) = not eqs_only
 893 allowedInteraction eqs_only (CIPCan {})   (CIPCan {})   = not eqs_only
 894 allowedInteraction _ _ _ = True
 895
 896 --------------------------------------------
 897 doInteractWithInert :: CanonicalCt -> CanonicalCt -> TcS InteractResult
 898 -- Identical class constraints.
 899
 900 doInteractWithInert
 901            (CDictCan { cc_id = d1, cc_flavor = fl1, cc_class = cls1, cc_tyargs = tys1 })
 902   workItem@(CDictCan { cc_id = d2, cc_flavor = fl2, cc_class = cls2, cc_tyargs = tys2 })
 903   | cls1 == cls2 && (and $ zipWith tcEqType tys1 tys2)
 904   = solveOneFromTheOther (d1,fl1) workItem
 905
 906   | cls1 == cls2 && (not (isGiven fl1 && isGiven fl2))
 907   =      -- See Note [When improvement happens]
 908     do { let pty1 = ClassP cls1 tys1
 909              pty2 = ClassP cls2 tys2
 910              inert_pred_loc     = (pty1, pprFlavorArising fl1)
 911              work_item_pred_loc = (pty2, pprFlavorArising fl2)
 912              fd_eqns = improveFromAnother
 913                                   inert_pred_loc     -- the template
 914                                   work_item_pred_loc -- the one we aim to rewrite
 915                                   -- See Note [Efficient Orientation]
 916
 917        ; m <- rewriteWithFunDeps fd_eqns tys2 fl2
 918        ; case m of
 919            Nothing -> noInteraction workItem
 920            Just (rewritten_tys2, cos2, fd_work)
 921
 922              | tcEqTypes tys1 rewritten_tys2
 923              -> -- Solve him on the spot in this case
 924                 do { let dict_co = mkTyConCoercion (classTyCon cls1) cos2
 925                    ; when (isWanted fl2) $ setDictBind d2 (EvCast d1 dict_co)
 926                    ; mkIRStop "Cls/Cls fundep (solved)" fd_work }
 927
 928              | isWanted fl2
 929              -> -- We could not quite solve him, but we stil rewrite him
 930                 -- Example: class C a b c | a -> b
 931                 --          Given: C Int Bool x, Wanted: C Int beta y
 932                 --          Then rewrite the wanted to C Int Bool y
 933                 --          but note that is still not identical to the given
 934                 -- The important thing is that the rewritten constraint is
 935                 -- inert wrt the given.
 936                 -- In fact, it is inert wrt all the previous inerts too, so
 937                 -- we can keep on going rather than sending it back to the work list
 938                 do { let dict_co = mkTyConCoercion (classTyCon cls1) cos2
 939                    ; d2' <- newDictVar cls1 rewritten_tys2
 940                    ; setDictBind d2 (EvCast d2' dict_co)
 941                    ; let workItem' = workItem { cc_id = d2', cc_tyargs = rewritten_tys2 }
 942                    ; mkIRContinue "Cls/Cls fundep (partial)" workItem' KeepInert fd_work }
 943
 944              | otherwise
 945              -> ASSERT (isDerived fl2)  -- Derived constraints have no evidence,
 946                                         -- so just produce the rewritten constraint
 947                 let workItem' = workItem { cc_tyargs = rewritten_tys2 }
 948                 in mkIRContinue "Cls/Cls fundep" workItem' KeepInert fd_work
 949   }
 950
 951 -- Class constraint and given equality: use the equality to rewrite
 952 -- the class constraint.
 953 doInteractWithInert (CTyEqCan { cc_id = cv, cc_flavor = ifl, cc_tyvar = tv, cc_rhs = xi })
 954                     (CDictCan { cc_id = dv, cc_flavor = wfl, cc_class = cl, cc_tyargs = xis })
 955   | ifl `canRewrite` wfl
 956   , tv `elemVarSet` tyVarsOfTypes xis
 957   = do { rewritten_dict <- rewriteDict (cv,tv,xi) (dv,wfl,cl,xis)
 958             -- Continue with rewritten Dictionary because we can only be in the
 959             -- interactWithEqsStage, so the dictionary is inert.
 960        ; mkIRContinue "Eq/Cls" rewritten_dict KeepInert emptyWorkList }
 961
 962 doInteractWithInert (CDictCan { cc_id = dv, cc_flavor = ifl, cc_class = cl, cc_tyargs = xis })
 963            workItem@(CTyEqCan { cc_id = cv, cc_flavor = wfl, cc_tyvar = tv, cc_rhs = xi })
 964   | wfl `canRewrite` ifl
 965   , tv `elemVarSet` tyVarsOfTypes xis
 966   = do { rewritten_dict <- rewriteDict (cv,tv,xi) (dv,ifl,cl,xis)
 967        ; mkIRContinue "Cls/Eq" workItem DropInert (workListFromCCan rewritten_dict) }
 968
 969 -- Class constraint and given equality: use the equality to rewrite
 970 -- the class constraint.
 971 doInteractWithInert (CTyEqCan { cc_id = cv, cc_flavor = ifl, cc_tyvar = tv, cc_rhs = xi })
 972                     (CIPCan { cc_id = ipid, cc_flavor = wfl, cc_ip_nm = nm, cc_ip_ty = ty })
 973   | ifl `canRewrite` wfl
 974   , tv `elemVarSet` tyVarsOfType ty
 975   = do { rewritten_ip <- rewriteIP (cv,tv,xi) (ipid,wfl,nm,ty)
 976        ; mkIRContinue "Eq/IP" rewritten_ip KeepInert emptyWorkList }
 977
 978 doInteractWithInert (CIPCan { cc_id = ipid, cc_flavor = ifl, cc_ip_nm = nm, cc_ip_ty = ty })
 979            workItem@(CTyEqCan { cc_id = cv, cc_flavor = wfl, cc_tyvar = tv, cc_rhs = xi })
 980   | wfl `canRewrite` ifl
 981   , tv `elemVarSet` tyVarsOfType ty
 982   = do { rewritten_ip <- rewriteIP (cv,tv,xi) (ipid,ifl,nm,ty)
 983        ; mkIRContinue "IP/Eq" workItem DropInert (workListFromCCan rewritten_ip) }
 984
 985 -- Two implicit parameter constraints.  If the names are the same,
 986 -- but their types are not, we generate a wanted type equality
 987 -- that equates the type (this is "improvement").
 988 -- However, we don't actually need the coercion evidence,
 989 -- so we just generate a fresh coercion variable that isn't used anywhere.
 990 doInteractWithInert (CIPCan { cc_id = id1, cc_flavor = ifl, cc_ip_nm = nm1, cc_ip_ty = ty1 })
 991            workItem@(CIPCan { cc_flavor = wfl, cc_ip_nm = nm2, cc_ip_ty = ty2 })
 992   | nm1 == nm2 && isGiven wfl && isGiven ifl
 993   =     -- See Note [Overriding implicit parameters]
 994         -- Dump the inert item, override totally with the new one
 995         -- Do not require type equality
 996         -- For example, given let ?x::Int = 3 in let ?x::Bool = True in ...
 997         --              we must *override* the outer one with the inner one
 998     mkIRContinue "IP/IP override" workItem DropInert emptyWorkList
 999
1000   | nm1 == nm2 && ty1 `tcEqType` ty2
1001   = solveOneFromTheOther (id1,ifl) workItem
1002
1003   | nm1 == nm2
1004   =     -- See Note [When improvement happens]
1005     do { co_var <- newWantedCoVar ty2 ty1 -- See Note [Efficient Orientation]
1006        ; let flav = Wanted (combineCtLoc ifl wfl)
1007        ; cans <- mkCanonical flav co_var
1008        ; mkIRContinue "IP/IP fundep" workItem KeepInert cans }
1009
1010 -- Never rewrite a given with a wanted equality, and a type function
1011 -- equality can never rewrite an equality. We rewrite LHS *and* RHS
1012 -- of function equalities so that our inert set exposes everything that
1013 -- we know about equalities.
1014
1015 -- Inert: equality, work item: function equality
1016 doInteractWithInert (CTyEqCan { cc_id = cv1, cc_flavor = ifl, cc_tyvar = tv, cc_rhs = xi1 })
1017                     (CFunEqCan { cc_id = cv2, cc_flavor = wfl, cc_fun = tc
1018                                , cc_tyargs = args, cc_rhs = xi2 })
1019   | ifl `canRewrite` wfl
1020   , tv `elemVarSet` tyVarsOfTypes (xi2:args) -- Rewrite RHS as well
1021   = do { rewritten_funeq <- rewriteFunEq (cv1,tv,xi1) (cv2,wfl,tc,args,xi2)
1022        ; mkIRStop "Eq/FunEq" (workListFromCCan rewritten_funeq) }
1023          -- Must Stop here, because we may no longer be inert after the rewritting.
1024
1025 -- Inert: function equality, work item: equality
1026 doInteractWithInert (CFunEqCan {cc_id = cv1, cc_flavor = ifl, cc_fun = tc
1027                               , cc_tyargs = args, cc_rhs = xi1 })
1028            workItem@(CTyEqCan { cc_id = cv2, cc_flavor = wfl, cc_tyvar = tv, cc_rhs = xi2 })
1029   | wfl `canRewrite` ifl
1030   , tv `elemVarSet` tyVarsOfTypes (xi1:args) -- Rewrite RHS as well
1031   = do { rewritten_funeq <- rewriteFunEq (cv2,tv,xi2) (cv1,ifl,tc,args,xi1)
1032        ; mkIRContinue "FunEq/Eq" workItem DropInert (workListFromCCan rewritten_funeq) }
1033          -- One may think that we could (KeepTransformedInert rewritten_funeq)
1034          -- but that is wrong, because it may end up not being inert with respect
1035          -- to future inerts. Example:
1036          -- Original inert = {    F xis ~  [a], b ~ Maybe Int }
1037          -- Work item comes along = a ~ [b]
1038          -- If we keep { F xis ~ [b] } in the inert set we will end up with:
1039          --      { F xis ~ [b], b ~ Maybe Int, a ~ [Maybe Int] }
1040          -- At the end, which is *not* inert. So we should unfortunately DropInert here.
1041
1042 doInteractWithInert (CFunEqCan { cc_id = cv1, cc_flavor = fl1, cc_fun = tc1
1043                                , cc_tyargs = args1, cc_rhs = xi1 })
1044            workItem@(CFunEqCan { cc_id = cv2, cc_flavor = fl2, cc_fun = tc2
1045                                , cc_tyargs = args2, cc_rhs = xi2 })
1046   | fl1 `canSolve` fl2 && lhss_match
1047   = do { cans <- rewriteEqLHS LeftComesFromInert  (mkCoVarCoercion cv1,xi1) (cv2,fl2,xi2)
1048        ; mkIRStop "FunEq/FunEq" cans }
1049   | fl2 `canSolve` fl1 && lhss_match
1050   = do { cans <- rewriteEqLHS RightComesFromInert (mkCoVarCoercion cv2,xi2) (cv1,fl1,xi1)
1051        ; mkIRContinue "FunEq/FunEq" workItem DropInert cans }
1052   where
1053     lhss_match = tc1 == tc2 && and (zipWith tcEqType args1 args2)
1054
1055 doInteractWithInert (CTyEqCan { cc_id = cv1, cc_flavor = fl1, cc_tyvar = tv1, cc_rhs = xi1 })
1056            workItem@(CTyEqCan { cc_id = cv2, cc_flavor = fl2, cc_tyvar = tv2, cc_rhs = xi2 })
1057 -- Check for matching LHS
1058   | fl1 `canSolve` fl2 && tv1 == tv2
1059   = do { cans <- rewriteEqLHS LeftComesFromInert (mkCoVarCoercion cv1,xi1) (cv2,fl2,xi2)
1060        ; mkIRStop "Eq/Eq lhs" cans }
1061
1062   | fl2 `canSolve` fl1 && tv1 == tv2
1063   = do { cans <- rewriteEqLHS RightComesFromInert (mkCoVarCoercion cv2,xi2) (cv1,fl1,xi1)
1064        ; mkIRContinue "Eq/Eq lhs" workItem DropInert cans }
1065
1066 -- Check for rewriting RHS
1067   | fl1 `canRewrite` fl2 && tv1 `elemVarSet` tyVarsOfType xi2
1068   = do { rewritten_eq <- rewriteEqRHS (cv1,tv1,xi1) (cv2,fl2,tv2,xi2)
1069        ; mkIRStop "Eq/Eq rhs" rewritten_eq }
1070
1071   | fl2 `canRewrite` fl1 && tv2 `elemVarSet` tyVarsOfType xi1
1072   = do { rewritten_eq <- rewriteEqRHS (cv2,tv2,xi2) (cv1,fl1,tv1,xi1)
1073        ; mkIRContinue "Eq/Eq rhs" workItem DropInert rewritten_eq }
1074
1075 doInteractWithInert (CTyEqCan   { cc_id = cv1, cc_flavor = fl1, cc_tyvar = tv1, cc_rhs = xi1 })
1076                     (CFrozenErr { cc_id = cv2, cc_flavor = fl2 })
1077   | fl1 `canRewrite` fl2 && tv1 `elemVarSet` tyVarsOfEvVar cv2
1078   = do { rewritten_frozen <- rewriteFrozen (cv1, tv1, xi1) (cv2, fl2)
1079        ; mkIRStop "Frozen/Eq" rewritten_frozen }
1080
1081 doInteractWithInert (CFrozenErr { cc_id = cv2, cc_flavor = fl2 })
1082            workItem@(CTyEqCan   { cc_id = cv1, cc_flavor = fl1, cc_tyvar = tv1, cc_rhs = xi1 })
1083   | fl1 `canRewrite` fl2 && tv1 `elemVarSet` tyVarsOfEvVar cv2
1084   = do { rewritten_frozen <- rewriteFrozen (cv1, tv1, xi1) (cv2, fl2)
1085        ; mkIRContinue "Frozen/Eq" workItem DropInert rewritten_frozen }
1086
1087 -- Fall-through case for all other situations
1088 doInteractWithInert _ workItem = noInteraction workItem
1089
1090 -------------------------
1091 -- Equational Rewriting
1092 rewriteDict  :: (CoVar, TcTyVar, Xi) -> (DictId, CtFlavor, Class, [Xi]) -> TcS CanonicalCt
1093 rewriteDict (cv,tv,xi) (dv,gw,cl,xis)
1094   = do { let cos  = substTysWith [tv] [mkCoVarCoercion cv] xis -- xis[tv] ~ xis[xi]
1095              args = substTysWith [tv] [xi] xis
1096              con  = classTyCon cl
1097              dict_co = mkTyConCoercion con cos
1098        ; dv' <- newDictVar cl args
1099        ; case gw of
1100            Wanted {}         -> setDictBind dv (EvCast dv' (mkSymCoercion dict_co))
1101            Given {}          -> setDictBind dv' (EvCast dv dict_co)
1102            Derived {}        -> return () -- Derived dicts we don't set any evidence
1103
1104        ; return (CDictCan { cc_id = dv'
1105                           , cc_flavor = gw
1106                           , cc_class = cl
1107                           , cc_tyargs = args }) }
1108
1109 rewriteIP :: (CoVar,TcTyVar,Xi) -> (EvVar,CtFlavor, IPName Name, TcType) -> TcS CanonicalCt
1110 rewriteIP (cv,tv,xi) (ipid,gw,nm,ty)
1111   = do { let ip_co = substTyWith [tv] [mkCoVarCoercion cv] ty     -- ty[tv] ~ t[xi]
1112              ty'   = substTyWith [tv] [xi] ty
1113        ; ipid' <- newIPVar nm ty'
1114        ; case gw of
1115            Wanted {}         -> setIPBind ipid  (EvCast ipid' (mkSymCoercion ip_co))
1116            Given {}          -> setIPBind ipid' (EvCast ipid ip_co)
1117            Derived {}        -> return () -- Derived ips: we don't set any evidence
1118
1119        ; return (CIPCan { cc_id = ipid'
1120                         , cc_flavor = gw
1121                         , cc_ip_nm = nm
1122                         , cc_ip_ty = ty' }) }
1123
1124 rewriteFunEq :: (CoVar,TcTyVar,Xi) -> (CoVar,CtFlavor,TyCon, [Xi], Xi) -> TcS CanonicalCt
1125 rewriteFunEq (cv1,tv,xi1) (cv2,gw, tc,args,xi2)                   -- cv2 :: F args ~ xi2
1126   = do { let arg_cos = substTysWith [tv] [mkCoVarCoercion cv1] args
1127              args'   = substTysWith [tv] [xi1] args
1128              fun_co  = mkTyConCoercion tc arg_cos                 -- fun_co :: F args ~ F args'
1129
1130              xi2'    = substTyWith [tv] [xi1] xi2
1131              xi2_co  = substTyWith [tv] [mkCoVarCoercion cv1] xi2 -- xi2_co :: xi2 ~ xi2'
1132        ; cv2' <- case gw of
1133                    Wanted {} -> do { cv2' <- newWantedCoVar (mkTyConApp tc args') xi2'
1134                                    ; setWantedCoBind cv2 $
1135                                      fun_co `mkTransCoercion`
1136                                             mkCoVarCoercion cv2' `mkTransCoercion` mkSymCoercion xi2_co
1137                                    ; return cv2' }
1138                    Given {}  -> newGivenCoVar (mkTyConApp tc args') xi2' $
1139                                   mkSymCoercion fun_co `mkTransCoercion`
1140                                                 mkCoVarCoercion cv2 `mkTransCoercion` xi2_co
1141                    Derived {} -> newDerivedId (EqPred (mkTyConApp tc args') xi2')
1142
1143        ; return (CFunEqCan { cc_id = cv2'
1144                            , cc_flavor = gw
1145                            , cc_tyargs = args'
1146                            , cc_fun = tc
1147                            , cc_rhs = xi2' }) }
1148
1149
1150 rewriteEqRHS :: (CoVar,TcTyVar,Xi) -> (CoVar,CtFlavor,TcTyVar,Xi) -> TcS WorkList
1151 -- Use the first equality to rewrite the second, flavors already checked.
1152 -- E.g.          c1 : tv1 ~ xi1   c2 : tv2 ~ xi2
1153 -- rewrites c2 to give
1154 --               c2' : tv2 ~ xi2[xi1/tv1]
1155 -- We must do an occurs check to sure the new constraint is canonical
1156 -- So we might return an empty bag
1157 rewriteEqRHS (cv1,tv1,xi1) (cv2,gw,tv2,xi2)
1158   | Just tv2' <- tcGetTyVar_maybe xi2'
1159   , tv2 == tv2'  -- In this case xi2[xi1/tv1] = tv2, so we have tv2~tv2
1160   = do { when (isWanted gw) (setWantedCoBind cv2 (mkSymCoercion co2'))
1161        ; return emptyCCan }
1162   | otherwise
1163   = do { cv2' <-
1164            case gw of
1165              Wanted {}
1166                  -> do { cv2' <- newWantedCoVar (mkTyVarTy tv2) xi2'
1167                        ; setWantedCoBind cv2 $
1168                          mkCoVarCoercion cv2' `mkTransCoercion` mkSymCoercion co2'
1169                        ; return cv2' }
1170              Given {}
1171                  -> newGivenCoVar (mkTyVarTy tv2) xi2' $
1172                     mkCoVarCoercion cv2 `mkTransCoercion` co2'
1173              Derived {}
1174                  -> newDerivedId (EqPred (mkTyVarTy tv2) xi2')
1175
1176        ; canEq gw cv2' (mkTyVarTy tv2) xi2'
1177        }
1178   where
1179     xi2' = substTyWith [tv1] [xi1] xi2
1180     co2' = substTyWith [tv1] [mkCoVarCoercion cv1] xi2  -- xi2 ~ xi2[xi1/tv1]
1181
1182
1183 rewriteEqLHS :: WhichComesFromInert -> (Coercion,Xi) -> (CoVar,CtFlavor,Xi) -> TcS WorkList
1184 -- Used to ineract two equalities of the following form:
1185 -- First Equality:   co1: (XXX ~ xi1)
1186 -- Second Equality:  cv2: (XXX ~ xi2)
1187 -- Where the cv1 `canSolve` cv2 equality
1188 -- We have an option of creating new work (xi1 ~ xi2) OR (xi2 ~ xi1),
1189 --    See Note [Efficient Orientation] for that
1190 rewriteEqLHS which (co1,xi1) (cv2,gw,xi2)
1191   = do { cv2' <- case (isWanted gw, which) of
1192                    (True,LeftComesFromInert) ->
1193                        do { cv2' <- newWantedCoVar xi2 xi1
1194                           ; setWantedCoBind cv2 $
1195                             co1 `mkTransCoercion` mkSymCoercion (mkCoVarCoercion cv2')
1196                           ; return cv2' }
1197                    (True,RightComesFromInert) ->
1198                        do { cv2' <- newWantedCoVar xi1 xi2
1199                           ; setWantedCoBind cv2 $
1200                             co1 `mkTransCoercion` mkCoVarCoercion cv2'
1201                           ; return cv2' }
1202                    (False,LeftComesFromInert) ->
1203                        if isGiven gw then
1204                            newGivenCoVar xi2 xi1 $
1205                            mkSymCoercion (mkCoVarCoercion cv2) `mkTransCoercion` co1
1206                        else newDerivedId (EqPred xi2 xi1)
1207                    (False,RightComesFromInert) ->
1208                        if isGiven gw then
1209                            newGivenCoVar xi1 xi2 $
1210                            mkSymCoercion co1 `mkTransCoercion` mkCoVarCoercion cv2
1211                        else newDerivedId (EqPred xi1 xi2)
1212        ; mkCanonical gw cv2' }
1213
1214 rewriteFrozen :: (CoVar,TcTyVar,Xi) -> (CoVar,CtFlavor) -> TcS WorkList
1215 rewriteFrozen (cv1, tv1, xi1) (cv2, fl2)
1216   = do { cv2' <-
1217            case fl2 of
1218              Wanted {} -> do { cv2' <- newWantedCoVar ty2a' ty2b'
1219                                     -- ty2a[xi1/tv1] ~ ty2b[xi1/tv1]
1220                              ; setWantedCoBind cv2 $
1221                                  co2a'                `mkTransCoercion`
1222                                  mkCoVarCoercion cv2' `mkTransCoercion`
1223                                  mkSymCoercion co2b'
1224                              ; return cv2' }
1225
1226              Given {} -> newGivenCoVar ty2a' ty2b' $
1227                          mkSymCoercion co2a'  `mkTransCoercion`
1228                          mkCoVarCoercion cv2  `mkTransCoercion`
1229                          co2b'
1230
1231              Derived {} -> newDerivedId (EqPred ty2a' ty2b')
1232       ; return (singleCCan $ CFrozenErr { cc_id = cv2', cc_flavor = fl2 }) }
1233   where
1234     (ty2a, ty2b) = coVarKind cv2          -- cv2 : ty2a ~ ty2b
1235     ty2a' = substTyWith [tv1] [xi1] ty2a
1236     ty2b' = substTyWith [tv1] [xi1] ty2b
1237
1238     co2a' = substTyWith [tv1] [mkCoVarCoercion cv1] ty2a  -- ty2a ~ ty2a[xi1/tv1]
1239     co2b' = substTyWith [tv1] [mkCoVarCoercion cv1] ty2b  -- ty2b ~ ty2b[xi1/tv1]
1240
1241 solveOneFromTheOther :: (EvVar, CtFlavor) -> CanonicalCt -> TcS InteractResult
1242 -- First argument inert, second argument work-item. They both represent
1243 -- wanted/given/derived evidence for the *same* predicate so we try here to
1244 -- discharge one directly from the other.
1245 --
1246 -- Precondition: value evidence only (implicit parameters, classes)
1247 --               not coercion
1248 solveOneFromTheOther (iid,ifl) workItem
1249   | isDerived wfl
1250   = mkIRStop "Solved (derived)" emptyWorkList
1251
1252   | ifl `canSolve` wfl
1253   = do { when (isWanted wfl) $ setEvBind wid (EvId iid)
1254            -- Overwrite the binding, if one exists
1255            -- For Givens, which are lambda-bound, nothing to overwrite,
1256        ; mkIRStop "Solved" emptyWorkList }
1257
1258   | wfl `canSolve` ifl
1259   = do { when (isWanted ifl) $ setEvBind iid (EvId wid)
1260        ; mkIRContinue "Solved inert" workItem DropInert emptyWorkList }
1261
1262   | otherwise -- The inert item is Derived, we can just throw it away,
1263   = mkIRContinue "Discard derived inert" workItem DropInert emptyWorkList
1264
1265   where
1266      wfl = cc_flavor workItem
1267      wid = cc_id workItem
1268 \end{code}
1269
1270 Note [Superclasses and recursive dictionaries]
1271 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1272     Overlaps with Note [SUPERCLASS-LOOP 1]
1273                   Note [SUPERCLASS-LOOP 2]
1274                   Note [Recursive instances and superclases]
1275     ToDo: check overlap and delete redundant stuff
1276
1277 Right before adding a given into the inert set, we must
1278 produce some more work, that will bring the superclasses
1279 of the given into scope. The superclass constraints go into
1280 our worklist.
1281
1282 When we simplify a wanted constraint, if we first see a matching
1283 instance, we may produce new wanted work. To (1) avoid doing this work
1284 twice in the future and (2) to handle recursive dictionaries we may ``cache''
1285 this item as given into our inert set WITHOUT adding its superclass constraints,
1286 otherwise we'd be in danger of creating a loop [In fact this was the exact reason
1287 for doing the isGoodRecEv check in an older version of the type checker].
1288
1289 But now we have added partially solved constraints to the worklist which may
1290 interact with other wanteds. Consider the example:
1291
1292 Example 1:
1293
1294     class Eq b => Foo a b        --- 0-th selector
1295     instance Eq a => Foo [a] a   --- fooDFun
1296
1297 and wanted (Foo [t] t). We are first going to see that the instance matches
1298 and create an inert set that includes the solved (Foo [t] t) but not its superclasses:
1299        d1 :_g Foo [t] t                 d1 := EvDFunApp fooDFun d3
1300 Our work list is going to contain a new *wanted* goal
1301        d3 :_w Eq t
1302
1303 Ok, so how do we get recursive dictionaries, at all:
1304
1305 Example 2:
1306
1307     data D r = ZeroD | SuccD (r (D r));
1308
1309     instance (Eq (r (D r))) => Eq (D r) where
1310         ZeroD     == ZeroD     = True
1311         (SuccD a) == (SuccD b) = a == b
1312         _         == _         = False;
1313
1314     equalDC :: D [] -> D [] -> Bool;
1315     equalDC = (==);
1316
1317 We need to prove (Eq (D [])). Here's how we go:
1318
1319         d1 :_w Eq (D [])
1320
1321 by instance decl, holds if
1322         d2 :_w Eq [D []]
1323         where   d1 = dfEqD d2
1324
1325 *BUT* we have an inert set which gives us (no superclasses):
1326         d1 :_g Eq (D [])
1327 By the instance declaration of Eq we can show the 'd2' goal if
1328         d3 :_w Eq (D [])
1329         where   d2 = dfEqList d3
1330                 d1 = dfEqD d2
1331 Now, however this wanted can interact with our inert d1 to set:
1332         d3 := d1
1333 and solve the goal. Why was this interaction OK? Because, if we chase the
1334 evidence of d1 ~~> dfEqD d2 ~~-> dfEqList d3, so by setting d3 := d1 we
1335 are really setting
1336         d3 := dfEqD2 (dfEqList d3)
1337 which is FINE because the use of d3 is protected by the instance function
1338 applications.
1339
1340 So, our strategy is to try to put solved wanted dictionaries into the
1341 inert set along with their superclasses (when this is meaningful,
1342 i.e. when new wanted goals are generated) but solve a wanted dictionary
1343 from a given only in the case where the evidence variable of the
1344 wanted is mentioned in the evidence of the given (recursively through
1345 the evidence binds) in a protected way: more instance function applications
1346 than superclass selectors.
1347
1348 Here are some more examples from GHC's previous type checker
1349
1350
1351 Example 3:
1352 This code arises in the context of "Scrap Your Boilerplate with Class"
1353
1354     class Sat a
1355     class Data ctx a
1356     instance  Sat (ctx Char)             => Data ctx Char       -- dfunData1
1357     instance (Sat (ctx [a]), Data ctx a) => Data ctx [a]        -- dfunData2
1358
1359     class Data Maybe a => Foo a
1360
1361     instance Foo t => Sat (Maybe t)                             -- dfunSat
1362
1363     instance Data Maybe a => Foo a                              -- dfunFoo1
1364     instance Foo a        => Foo [a]                            -- dfunFoo2
1365     instance                 Foo [Char]                         -- dfunFoo3
1366
1367 Consider generating the superclasses of the instance declaration
1368          instance Foo a => Foo [a]
1369
1370 So our problem is this
1371     d0 :_g Foo t
1372     d1 :_w Data Maybe [t]
1373
1374 We may add the given in the inert set, along with its superclasses
1375 [assuming we don't fail because there is a matching instance, see
1376  tryTopReact, given case ]
1377   Inert:
1378     d0 :_g Foo t
1379   WorkList
1380     d01 :_g Data Maybe t  -- d2 := EvDictSuperClass d0 0
1381     d1 :_w Data Maybe [t]
1382 Then d2 can readily enter the inert, and we also do solving of the wanted
1383   Inert:
1384     d0 :_g Foo t
1385     d1 :_s Data Maybe [t]           d1 := dfunData2 d2 d3
1386   WorkList
1387     d2 :_w Sat (Maybe [t])
1388     d3 :_w Data Maybe t
1389     d01 :_g Data Maybe t
1390 Now, we may simplify d2 more:
1391   Inert:
1392       d0 :_g Foo t
1393       d1 :_s Data Maybe [t]           d1 := dfunData2 d2 d3
1394       d1 :_g Data Maybe [t]
1395       d2 :_g Sat (Maybe [t])          d2 := dfunSat d4
1396   WorkList:
1397       d3 :_w Data Maybe t
1398       d4 :_w Foo [t]
1399       d01 :_g Data Maybe t
1400
1401 Now, we can just solve d3.
1402   Inert
1403       d0 :_g Foo t
1404       d1 :_s Data Maybe [t]           d1 := dfunData2 d2 d3
1405       d2 :_g Sat (Maybe [t])          d2 := dfunSat d4
1406   WorkList
1407       d4 :_w Foo [t]
1408       d01 :_g Data Maybe t
1409 And now we can simplify d4 again, but since it has superclasses we *add* them to the worklist:
1410   Inert
1411       d0 :_g Foo t
1412       d1 :_s Data Maybe [t]           d1 := dfunData2 d2 d3
1413       d2 :_g Sat (Maybe [t])          d2 := dfunSat d4
1414       d4 :_g Foo [t]                  d4 := dfunFoo2 d5
1415   WorkList:
1416       d5 :_w Foo t
1417       d6 :_g Data Maybe [t]           d6 := EvDictSuperClass d4 0
1418       d01 :_g Data Maybe t
1419 Now, d5 can be solved! (and its superclass enter scope)
1420   Inert
1421       d0 :_g Foo t
1422       d1 :_s Data Maybe [t]           d1 := dfunData2 d2 d3
1423       d2 :_g Sat (Maybe [t])          d2 := dfunSat d4
1424       d4 :_g Foo [t]                  d4 := dfunFoo2 d5
1425       d5 :_g Foo t                    d5 := dfunFoo1 d7
1426   WorkList:
1427       d7 :_w Data Maybe t
1428       d6 :_g Data Maybe [t]
1429       d8 :_g Data Maybe t            d8 := EvDictSuperClass d5 0
1430       d01 :_g Data Maybe t
1431
1432 Now, two problems:
1433    [1] Suppose we pick d8 and we react him with d01. Which of the two givens should
1434        we keep? Well, we *MUST NOT* drop d01 because d8 contains recursive evidence
1435        that must not be used (look at case interactInert where both inert and workitem
1436        are givens). So we have several options:
1437        - Drop the workitem always (this will drop d8)
1438               This feels very unsafe -- what if the work item was the "good" one
1439               that should be used later to solve another wanted?
1440        - Don't drop anyone: the inert set may contain multiple givens!
1441               [This is currently implemented]
1442
1443 The "don't drop anyone" seems the most safe thing to do, so now we come to problem 2:
1444   [2] We have added both d6 and d01 in the inert set, and we are interacting our wanted
1445       d7. Now the [isRecDictEv] function in the ineration solver
1446       [case inert-given workitem-wanted] will prevent us from interacting d7 := d8
1447       precisely because chasing the evidence of d8 leads us to an unguarded use of d7.
1448
1449       So, no interaction happens there. Then we meet d01 and there is no recursion
1450       problem there [isRectDictEv] gives us the OK to interact and we do solve d7 := d01!
1451
1452 Note [SUPERCLASS-LOOP 1]
1453 ~~~~~~~~~~~~~~~~~~~~~~~~
1454 We have to be very, very careful when generating superclasses, lest we
1455 accidentally build a loop. Here's an example:
1456
1457   class S a
1458
1459   class S a => C a where { opc :: a -> a }
1460   class S b => D b where { opd :: b -> b }
1461
1462   instance C Int where
1463      opc = opd
1464
1465   instance D Int where
1466      opd = opc
1467
1468 From (instance C Int) we get the constraint set {ds1:S Int, dd:D Int}
1469 Simplifying, we may well get:
1470         $dfCInt = :C ds1 (opd dd)
1471         dd  = $dfDInt
1472         ds1 = $p1 dd
1473 Notice that we spot that we can extract ds1 from dd.
1474
1475 Alas!  Alack! We can do the same for (instance D Int):
1476
1477         $dfDInt = :D ds2 (opc dc)
1478         dc  = $dfCInt
1479         ds2 = $p1 dc
1480
1481 And now we've defined the superclass in terms of itself.
1482 Two more nasty cases are in
1483         tcrun021
1484         tcrun033
1485
1486 Solution:
1487   - Satisfy the superclass context *all by itself*
1488     (tcSimplifySuperClasses)
1489   - And do so completely; i.e. no left-over constraints
1490     to mix with the constraints arising from method declarations
1491
1492
1493 Note [SUPERCLASS-LOOP 2]
1494 ~~~~~~~~~~~~~~~~~~~~~~~~
1495 We need to be careful when adding "the constaint we are trying to prove".
1496 Suppose we are *given* d1:Ord a, and want to deduce (d2:C [a]) where
1497
1498         class Ord a => C a where
1499         instance Ord [a] => C [a] where ...
1500
1501 Then we'll use the instance decl to deduce C [a] from Ord [a], and then add the
1502 superclasses of C [a] to avails.  But we must not overwrite the binding
1503 for Ord [a] (which is obtained from Ord a) with a superclass selection or we'll just
1504 build a loop!
1505
1506 Here's another variant, immortalised in tcrun020
1507         class Monad m => C1 m
1508         class C1 m => C2 m x
1509         instance C2 Maybe Bool
1510 For the instance decl we need to build (C1 Maybe), and it's no good if
1511 we run around and add (C2 Maybe Bool) and its superclasses to the avails
1512 before we search for C1 Maybe.
1513
1514 Here's another example
1515         class Eq b => Foo a b
1516         instance Eq a => Foo [a] a
1517 If we are reducing
1518         (Foo [t] t)
1519
1520 we'll first deduce that it holds (via the instance decl).  We must not
1521 then overwrite the Eq t constraint with a superclass selection!
1522
1523 At first I had a gross hack, whereby I simply did not add superclass constraints
1524 in addWanted, though I did for addGiven and addIrred.  This was sub-optimal,
1525 becuase it lost legitimate superclass sharing, and it still didn't do the job:
1526 I found a very obscure program (now tcrun021) in which improvement meant the
1527 simplifier got two bites a the cherry... so something seemed to be an Stop
1528 first time, but reducible next time.
1529
1530 Now we implement the Right Solution, which is to check for loops directly
1531 when adding superclasses.  It's a bit like the occurs check in unification.
1532
1533 Note [Recursive instances and superclases]
1534 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1535 Consider this code, which arises in the context of "Scrap Your
1536 Boilerplate with Class".
1537
1538     class Sat a
1539     class Data ctx a
1540     instance  Sat (ctx Char)             => Data ctx Char
1541     instance (Sat (ctx [a]), Data ctx a) => Data ctx [a]
1542
1543     class Data Maybe a => Foo a
1544
1545     instance Foo t => Sat (Maybe t)
1546
1547     instance Data Maybe a => Foo a
1548     instance Foo a        => Foo [a]
1549     instance                 Foo [Char]
1550
1551 In the instance for Foo [a], when generating evidence for the superclasses
1552 (ie in tcSimplifySuperClasses) we need a superclass (Data Maybe [a]).
1553 Using the instance for Data, we therefore need
1554         (Sat (Maybe [a], Data Maybe a)
1555 But we are given (Foo a), and hence its superclass (Data Maybe a).
1556 So that leaves (Sat (Maybe [a])).  Using the instance for Sat means
1557 we need (Foo [a]).  And that is the very dictionary we are bulding
1558 an instance for!  So we must put that in the "givens".  So in this
1559 case we have
1560         Given:  Foo a, Foo [a]
1561         Wanted: Data Maybe [a]
1562
1563 BUT we must *not not not* put the *superclasses* of (Foo [a]) in
1564 the givens, which is what 'addGiven' would normally do. Why? Because
1565 (Data Maybe [a]) is the superclass, so we'd "satisfy" the wanted
1566 by selecting a superclass from Foo [a], which simply makes a loop.
1567
1568 On the other hand we *must* put the superclasses of (Foo a) in
1569 the givens, as you can see from the derivation described above.
1570
1571 Conclusion: in the very special case of tcSimplifySuperClasses
1572 we have one 'given' (namely the "this" dictionary) whose superclasses
1573 must not be added to 'givens' by addGiven.
1574
1575 There is a complication though.  Suppose there are equalities
1576       instance (Eq a, a~b) => Num (a,b)
1577 Then we normalise the 'givens' wrt the equalities, so the original
1578 given "this" dictionary is cast to one of a different type.  So it's a
1579 bit trickier than before to identify the "special" dictionary whose
1580 superclasses must not be added. See test
1581    indexed-types/should_run/EqInInstance
1582
1583 We need a persistent property of the dictionary to record this
1584 special-ness.  Current I'm using the InstLocOrigin (a bit of a hack,
1585 but cool), which is maintained by dictionary normalisation.
1586 Specifically, the InstLocOrigin is
1587              NoScOrigin
1588 then the no-superclass thing kicks in.  WATCH OUT if you fiddle
1589 with InstLocOrigin!
1590
1591 Note [MATCHING-SYNONYMS]
1592 ~~~~~~~~~~~~~~~~~~~~~~~~
1593 When trying to match a dictionary (D tau) to a top-level instance, or a
1594 type family equation (F taus_1 ~ tau_2) to a top-level family instance,
1595 we do *not* need to expand type synonyms because the matcher will do that for us.
1596
1597
1598 Note [RHS-FAMILY-SYNONYMS]
1599 ~~~~~~~~~~~~~~~~~~~~~~~~~~
1600 The RHS of a family instance is represented as yet another constructor which is
1601 like a type synonym for the real RHS the programmer declared. Eg:
1602     type instance F (a,a) = [a]
1603 Becomes:
1604     :R32 a = [a]      -- internal type synonym introduced
1605     F (a,a) ~ :R32 a  -- instance
1606
1607 When we react a family instance with a type family equation in the work list
1608 we keep the synonym-using RHS without expansion.
1609
1610
1611 *********************************************************************************
1612 *                                                                               *
1613                        The top-reaction Stage
1614 *                                                                               *
1615 *********************************************************************************
1616
1617 \begin{code}
1618 -- If a work item has any form of interaction with top-level we get this
1619 data TopInteractResult
1620   = NoTopInt         -- No top-level interaction
1621                      -- Equivalent to (SomeTopInt emptyWorkList (ContinueWith work_item))
1622   | SomeTopInt
1623       { tir_new_work  :: WorkList       -- Sub-goals or new work (could be given,
1624                                         --                        for superclasses)
1625       , tir_new_inert :: StopOrContinue -- The input work item, ready to become *inert* now:
1626       }                                 -- NB: in ``given'' (solved) form if the
1627                                         -- original was wanted or given and instance match
1628                                         -- was found, but may also be in wanted form if we
1629                                         -- only reacted with functional dependencies
1630                                         -- arising from top-level instances.
1631
1632 topReactionsStage :: SimplifierStage
1633 topReactionsStage depth workItem inerts
1634   = do { tir <- tryTopReact workItem
1635        ; case tir of
1636            NoTopInt ->
1637                return $ SR { sr_inerts   = inerts
1638                            , sr_new_work = emptyWorkList
1639                            , sr_stop     = ContinueWith workItem }
1640            SomeTopInt tir_new_work tir_new_inert ->
1641                do { bumpStepCountTcS
1642                   ; traceFireTcS depth (ptext (sLit "Top react")
1643                        <+> vcat [ ptext (sLit "Work =") <+> ppr workItem
1644                                 , ptext (sLit "New =") <+> ppr tir_new_work ])
1645                   ; return $ SR { sr_inerts   = inerts
1646                                 , sr_new_work = tir_new_work
1647                                 , sr_stop     = tir_new_inert
1648                                 } }
1649        }
1650
1651 tryTopReact :: WorkItem -> TcS TopInteractResult
1652 tryTopReact workitem
1653   = do {  -- A flag controls the amount of interaction allowed
1654           -- See Note [Simplifying RULE lhs constraints]
1655          ctxt <- getTcSContext
1656        ; if allowedTopReaction (simplEqsOnly ctxt) workitem
1657          then do { traceTcS "tryTopReact / calling doTopReact" (ppr workitem)
1658                  ; doTopReact workitem }
1659          else return NoTopInt
1660        }
1661
1662 allowedTopReaction :: Bool -> WorkItem -> Bool
1663 allowedTopReaction eqs_only (CDictCan {}) = not eqs_only
1664 allowedTopReaction _        _             = True
1665
1666 doTopReact :: WorkItem -> TcS TopInteractResult
1667 -- The work item does not react with the inert set, so try interaction with top-level instances
1668 -- NB: The place to add superclasses in *not* in doTopReact stage. Instead superclasses are
1669 --     added in the worklist as part of the canonicalisation process.
1670 -- See Note [Adding superclasses] in TcCanonical.
1671
1672 -- Given dictionary
1673 -- See Note [Given constraint that matches an instance declaration]
1674 doTopReact (CDictCan { cc_flavor = Given {} })
1675   = return NoTopInt -- NB: Superclasses already added since it's canonical
1676
1677 -- Derived dictionary: just look for functional dependencies
1678 doTopReact workItem@(CDictCan { cc_flavor = fl@(Derived loc)
1679                               , cc_class = cls, cc_tyargs = xis })
1680   = do { instEnvs <- getInstEnvs
1681        ; let fd_eqns = improveFromInstEnv instEnvs
1682                                                 (ClassP cls xis, pprArisingAt loc)
1683        ; m <- rewriteWithFunDeps fd_eqns xis fl
1684        ; case m of
1685            Nothing -> return NoTopInt
1686            Just (xis',_,fd_work) ->
1687                let workItem' = workItem { cc_tyargs = xis' }
1688                    -- Deriveds are not supposed to have identity (cc_id is unused!)
1689                in return $ SomeTopInt { tir_new_work  = fd_work
1690                                       , tir_new_inert = ContinueWith workItem' } }
1691
1692 -- Wanted dictionary
1693 doTopReact workItem@(CDictCan { cc_id = dv, cc_flavor = fl@(Wanted loc)
1694                               , cc_class = cls, cc_tyargs = xis })
1695   = do { -- See Note [MATCHING-SYNONYMS]
1696        ; lkp_inst_res <- matchClassInst cls xis loc
1697        ; case lkp_inst_res of
1698            NoInstance ->
1699              do { traceTcS "doTopReact/ no class instance for" (ppr dv)
1700
1701                 ; instEnvs <- getInstEnvs
1702                 ; let fd_eqns = improveFromInstEnv instEnvs
1703                                                          (ClassP cls xis, pprArisingAt loc)
1704                 ; m <- rewriteWithFunDeps fd_eqns xis fl
1705                 ; case m of
1706                     Nothing -> return NoTopInt
1707                     Just (xis',cos,fd_work) ->
1708                         do { let dict_co = mkTyConCoercion (classTyCon cls) cos
1709                            ; dv'<- newDictVar cls xis'
1710                            ; setDictBind dv (EvCast dv' dict_co)
1711                            ; let workItem' = CDictCan { cc_id = dv', cc_flavor = fl,
1712                                                         cc_class = cls, cc_tyargs = xis' }
1713                            ; return $
1714                              SomeTopInt { tir_new_work  = singleCCan workItem' `andCCan` fd_work
1715                                         , tir_new_inert = Stop } } }
1716
1717            GenInst wtvs ev_term -- Solved
1718                    -- No need to do fundeps stuff here; the instance
1719                    -- matches already so we won't get any more info
1720                    -- from functional dependencies
1721              | null wtvs
1722              -> do { traceTcS "doTopReact/ found nullary class instance for" (ppr dv)
1723                    ; setDictBind dv ev_term
1724                     -- Solved in one step and no new wanted work produced.
1725                     -- i.e we directly matched a top-level instance
1726                     -- No point in caching this in 'inert'; hence Stop
1727                    ; return $ SomeTopInt { tir_new_work  = emptyWorkList
1728                                          , tir_new_inert = Stop } }
1729
1730              | otherwise
1731              -> do { traceTcS "doTopReact/ found nullary class instance for" (ppr dv)
1732                    ; setDictBind dv ev_term
1733                         -- Solved and new wanted work produced, you may cache the
1734                         -- (tentatively solved) dictionary as Given! (used to be: Derived)
1735                    ; let solved   = workItem { cc_flavor = given_fl }
1736                          given_fl = Given (setCtLocOrigin loc UnkSkol)
1737                    ; inst_work <- canWanteds wtvs
1738                    ; return $ SomeTopInt { tir_new_work  = inst_work
1739                                          , tir_new_inert = ContinueWith solved } }
1740        }
1741
1742 -- Type functions
1743 doTopReact (CFunEqCan { cc_id = cv, cc_flavor = fl
1744                       , cc_fun = tc, cc_tyargs = args, cc_rhs = xi })
1745   = ASSERT (isSynFamilyTyCon tc)   -- No associated data families have reached that far
1746     do { match_res <- matchFam tc args -- See Note [MATCHING-SYNONYMS]
1747        ; case match_res of
1748            MatchInstNo
1749              -> return NoTopInt
1750            MatchInstSingle (rep_tc, rep_tys)
1751              -> do { let Just coe_tc = tyConFamilyCoercion_maybe rep_tc
1752                          Just rhs_ty = tcView (mkTyConApp rep_tc rep_tys)
1753                             -- Eagerly expand away the type synonym on the
1754                             -- RHS of a type function, so that it never
1755                             -- appears in an error message
1756                             -- See Note [Type synonym families] in TyCon
1757                          coe = mkTyConApp coe_tc rep_tys
1758                    ; cv' <- case fl of
1759                               Wanted {} -> do { cv' <- newWantedCoVar rhs_ty xi
1760                                               ; setWantedCoBind cv $
1761                                                     coe `mkTransCoercion`
1762                                                       mkCoVarCoercion cv'
1763                                               ; return cv' }
1764                               Given {}   -> newGivenCoVar xi rhs_ty $
1765                                             mkSymCoercion (mkCoVarCoercion cv) `mkTransCoercion` coe
1766                               Derived {} -> newDerivedId (EqPred xi rhs_ty)
1767                    ; can_cts <- mkCanonical fl cv'
1768                    ; return $ SomeTopInt can_cts Stop }
1769            _
1770              -> panicTcS $ text "TcSMonad.matchFam returned multiple instances!"
1771        }
1772
1773
1774 -- Any other work item does not react with any top-level equations
1775 doTopReact _workItem = return NoTopInt
1776 \end{code}
1777
1778
1779 Note [FunDep and implicit parameter reactions]
1780 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1781 Currently, our story of interacting two dictionaries (or a dictionary
1782 and top-level instances) for functional dependencies, and implicit
1783 paramters, is that we simply produce new wanted equalities.  So for example
1784
1785         class D a b | a -> b where ...
1786     Inert:
1787         d1 :g D Int Bool
1788     WorkItem:
1789         d2 :w D Int alpha
1790
1791     We generate the extra work item
1792         cv :w alpha ~ Bool
1793     where 'cv' is currently unused.  However, this new item reacts with d2,
1794     discharging it in favour of a new constraint d2' thus:
1795         d2' :w D Int Bool
1796         d2 := d2' |> D Int cv
1797     Now d2' can be discharged from d1
1798
1799 We could be more aggressive and try to *immediately* solve the dictionary
1800 using those extra equalities. With the same inert set and work item we
1801 might dischard d2 directly:
1802
1803         cv :w alpha ~ Bool
1804         d2 := d1 |> D Int cv
1805
1806 But in general it's a bit painful to figure out the necessary coercion,
1807 so we just take the first approach. Here is a better example. Consider:
1808     class C a b c | a -> b
1809 And:
1810      [Given]  d1 : C T Int Char
1811      [Wanted] d2 : C T beta Int
1812 In this case, it's *not even possible* to solve the wanted immediately.
1813 So we should simply output the functional dependency and add this guy
1814 [but NOT its superclasses] back in the worklist. Even worse:
1815      [Given] d1 : C T Int beta
1816      [Wanted] d2: C T beta Int
1817 Then it is solvable, but its very hard to detect this on the spot.
1818
1819 It's exactly the same with implicit parameters, except that the
1820 "aggressive" approach would be much easier to implement.
1821
1822 Note [When improvement happens]
1823 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1824 We fire an improvement rule when
1825
1826   * Two constraints match (modulo the fundep)
1827       e.g. C t1 t2, C t1 t3    where C a b | a->b
1828     The two match because the first arg is identical
1829
1830   * At least one is not Given.  If they are both given, we don't fire
1831     the reaction because we have no way of constructing evidence for a
1832     new equality nor does it seem right to create a new wanted goal
1833     (because the goal will most likely contain untouchables, which
1834     can't be solved anyway)!
1835
1836 Note that we *do* fire the improvement if one is Given and one is Derived.
1837 The latter can be a superclass of a wanted goal. Example (tcfail138)
1838     class L a b | a -> b
1839     class (G a, L a b) => C a b
1840
1841     instance C a b' => G (Maybe a)
1842     instance C a b  => C (Maybe a) a
1843     instance L (Maybe a) a
1844
1845 When solving the superclasses of the (C (Maybe a) a) instance, we get
1846   Given:  C a b  ... and hance by superclasses, (G a, L a b)
1847   Wanted: G (Maybe a)
1848 Use the instance decl to get
1849   Wanted: C a b'
1850 The (C a b') is inert, so we generate its Derived superclasses (L a b'),
1851 and now we need improvement between that derived superclass an the Given (L a b)
1852
1853 Note [Overriding implicit parameters]
1854 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1855 Consider
1856    f :: (?x::a) -> Bool -> a
1857
1858    g v = let ?x::Int = 3
1859          in (f v, let ?x::Bool = True in f v)
1860
1861 This should probably be well typed, with
1862    g :: Bool -> (Int, Bool)
1863
1864 So the inner binding for ?x::Bool *overrides* the outer one.
1865 Hence a work-item Given overrides an inert-item Given.
1866
1867 Note [Given constraint that matches an instance declaration]
1868 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1869 What should we do when we discover that one (or more) top-level
1870 instances match a given (or solved) class constraint? We have
1871 two possibilities:
1872
1873   1. Reject the program. The reason is that there may not be a unique
1874      best strategy for the solver. Example, from the OutsideIn(X) paper:
1875        instance P x => Q [x]
1876        instance (x ~ y) => R [x] y
1877
1878        wob :: forall a b. (Q [b], R b a) => a -> Int
1879
1880        g :: forall a. Q [a] => [a] -> Int
1881        g x = wob x
1882
1883        will generate the impliation constraint:
1884             Q [a] => (Q [beta], R beta [a])
1885        If we react (Q [beta]) with its top-level axiom, we end up with a
1886        (P beta), which we have no way of discharging. On the other hand,
1887        if we react R beta [a] with the top-level we get  (beta ~ a), which
1888        is solvable and can help us rewrite (Q [beta]) to (Q [a]) which is
1889        now solvable by the given Q [a].
1890
1891      However, this option is restrictive, for instance [Example 3] from
1892      Note [Recursive dictionaries] will fail to work.
1893
1894   2. Ignore the problem, hoping that the situations where there exist indeed
1895      such multiple strategies are rare: Indeed the cause of the previous
1896      problem is that (R [x] y) yields the new work (x ~ y) which can be
1897      *spontaneously* solved, not using the givens.
1898
1899 We are choosing option 2 below but we might consider having a flag as well.
1900
1901
1902 Note [New Wanted Superclass Work]
1903 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1904 Even in the case of wanted constraints, we may add some superclasses
1905 as new given work. The reason is:
1906
1907         To allow FD-like improvement for type families. Assume that
1908         we have a class
1909              class C a b | a -> b
1910         and we have to solve the implication constraint:
1911              C a b => C a beta
1912         Then, FD improvement can help us to produce a new wanted (beta ~ b)
1913
1914         We want to have the same effect with the type family encoding of
1915         functional dependencies. Namely, consider:
1916              class (F a ~ b) => C a b
1917         Now suppose that we have:
1918                given: C a b
1919                wanted: C a beta
1920         By interacting the given we will get given (F a ~ b) which is not
1921         enough by itself to make us discharge (C a beta). However, we
1922         may create a new derived equality from the super-class of the
1923         wanted constraint (C a beta), namely derived (F a ~ beta).
1924         Now we may interact this with given (F a ~ b) to get:
1925                   derived :  beta ~ b
1926         But 'beta' is a touchable unification variable, and hence OK to
1927         unify it with 'b', replacing the derived evidence with the identity.
1928
1929         This requires trySpontaneousSolve to solve *derived*
1930         equalities that have a touchable in their RHS, *in addition*
1931         to solving wanted equalities.
1932
1933 We also need to somehow use the superclasses to quantify over a minimal,
1934 constraint see note [Minimize by Superclasses] in TcSimplify.
1935
1936
1937 Finally, here is another example where this is useful.
1938
1939 Example 1:
1940 ----------
1941    class (F a ~ b) => C a b
1942 And we are given the wanteds:
1943       w1 : C a b
1944       w2 : C a c
1945       w3 : b ~ c
1946 We surely do *not* want to quantify over (b ~ c), since if someone provides
1947 dictionaries for (C a b) and (C a c), these dictionaries can provide a proof
1948 of (b ~ c), hence no extra evidence is necessary. Here is what will happen:
1949
1950      Step 1: We will get new *given* superclass work,
1951              provisionally to our solving of w1 and w2
1952
1953                g1: F a ~ b, g2 : F a ~ c,
1954                w1 : C a b, w2 : C a c, w3 : b ~ c
1955
1956              The evidence for g1 and g2 is a superclass evidence term:
1957
1958                g1 := sc w1, g2 := sc w2
1959
1960      Step 2: The givens will solve the wanted w3, so that
1961                w3 := sym (sc w1) ; sc w2
1962
1963      Step 3: Now, one may naively assume that then w2 can be solve from w1
1964              after rewriting with the (now solved equality) (b ~ c).
1965
1966              But this rewriting is ruled out by the isGoodRectDict!
1967
1968 Conclusion, we will (correctly) end up with the unsolved goals
1969     (C a b, C a c)
1970
1971 NB: The desugarer needs be more clever to deal with equalities
1972     that participate in recursive dictionary bindings.
1973
1974 \begin{code}
1975 data LookupInstResult
1976   = NoInstance
1977   | GenInst [WantedEvVar] EvTerm
1978
1979 matchClassInst :: Class -> [Type] -> WantedLoc -> TcS LookupInstResult
1980 matchClassInst clas tys loc
1981    = do { let pred = mkClassPred clas tys
1982         ; mb_result <- matchClass clas tys
1983         ; case mb_result of
1984             MatchInstNo   -> return NoInstance
1985             MatchInstMany -> return NoInstance -- defer any reactions of a multitude until
1986                                                -- we learn more about the reagent
1987             MatchInstSingle (dfun_id, mb_inst_tys) ->
1988               do { checkWellStagedDFun pred dfun_id loc
1989
1990         -- It's possible that not all the tyvars are in
1991         -- the substitution, tenv. For example:
1992         --      instance C X a => D X where ...
1993         -- (presumably there's a functional dependency in class C)
1994         -- Hence mb_inst_tys :: Either TyVar TcType
1995
1996                  ; tys <- instDFunTypes mb_inst_tys
1997                  ; let (theta, _) = tcSplitPhiTy (applyTys (idType dfun_id) tys)
1998                  ; if null theta then
1999                        return (GenInst [] (EvDFunApp dfun_id tys []))
2000                    else do
2001                      { ev_vars <- instDFunConstraints theta
2002                      ; let wevs = [EvVarX w loc | w <- ev_vars]
2003                      ; return $ GenInst wevs (EvDFunApp dfun_id tys ev_vars) }
2004                  }
2005         }
2006 \end{code}