compiler/typecheck/TcInteract.lhs

   1 \begin{code}
   2 module TcInteract (
   3      solveInteract, solveInteractGiven, solveInteractWanted,
   4      AtomicInert, tyVarsOfInert,
   5      InertSet, emptyInert, updInertSet, extractUnsolved, solveOne,
   6   ) where
   7
   8 #include "HsVersions.h"
   9
  10
  11 import BasicTypes
  12 import TcCanonical
  13 import VarSet
  14 import Type
  15
  16 import Id
  17 import Var
  18
  19 import TcType
  20 import HsBinds
  21
  22 import Inst( tyVarsOfEvVar )
  23 import Class
  24 import TyCon
  25 import Name
  26
  27 import FunDeps
  28
  29 import Coercion
  30 import Outputable
  31
  32 import TcRnTypes
  33 import TcErrors
  34 import TcSMonad
  35 import Bag
  36 import qualified Data.Map as Map
  37
  38 import Control.Monad( when )
  39
  40 import FastString ( sLit )
  41 import DynFlags
  42 \end{code}
  43
  44 Note [InertSet invariants]
  45 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
  46 An InertSet is a bag of canonical constraints, with the following invariants:
  47
  48   1 No two constraints react with each other.
  49
  50     A tricky case is when there exists a given (solved) dictionary
  51     constraint and a wanted identical constraint in the inert set, but do
  52     not react because reaction would create loopy dictionary evidence for
  53     the wanted. See note [Recursive dictionaries]
  54
  55   2 Given equalities form an idempotent substitution [none of the
  56     given LHS's occur in any of the given RHS's or reactant parts]
  57
  58   3 Wanted equalities also form an idempotent substitution
  59
  60   4 The entire set of equalities is acyclic.
  61
  62   5 Wanted dictionaries are inert with the top-level axiom set
  63
  64   6 Equalities of the form tv1 ~ tv2 always have a touchable variable
  65     on the left (if possible).
  66
  67   7 No wanted constraints tv1 ~ tv2 with tv1 touchable. Such constraints
  68     will be marked as solved right before being pushed into the inert set.
  69     See note [Touchables and givens].
  70
  71   8 No Given constraint mentions a touchable unification variable,
  72     except if the
  73
  74 Note that 6 and 7 are /not/ enforced by canonicalization but rather by
  75 insertion in the inert list, ie by TcInteract.
  76
  77 During the process of solving, the inert set will contain some
  78 previously given constraints, some wanted constraints, and some given
  79 constraints which have arisen from solving wanted constraints. For
  80 now we do not distinguish between given and solved constraints.
  81
  82 Note that we must switch wanted inert items to given when going under an
  83 implication constraint (when in top-level inference mode).
  84
  85 \begin{code}
  86
  87 data CCanMap a = CCanMap { cts_given   :: Map.Map a CanonicalCts
  88                                           -- Invariant: all Given
  89                          , cts_derived :: Map.Map a CanonicalCts
  90                                           -- Invariant: all Derived
  91                          , cts_wanted  :: Map.Map a CanonicalCts }
  92                                           -- Invariant: all Wanted
  93
  94 cCanMapToBag :: Ord a => CCanMap a -> CanonicalCts
  95 cCanMapToBag cmap = Map.fold unionBags rest_wder (cts_given cmap)
  96   where rest_wder = Map.fold unionBags rest_der  (cts_wanted cmap)
  97         rest_der  = Map.fold unionBags emptyCCan (cts_derived cmap)
  98
  99 emptyCCanMap :: CCanMap a
 100 emptyCCanMap = CCanMap { cts_given = Map.empty
 101                        , cts_derived = Map.empty, cts_wanted = Map.empty }
 102
 103 updCCanMap:: Ord a => (a,CanonicalCt) -> CCanMap a -> CCanMap a
 104 updCCanMap (a,ct) cmap
 105   = case cc_flavor ct of
 106       Wanted {}
 107           -> cmap { cts_wanted = Map.insertWith unionBags a this_ct (cts_wanted cmap) }
 108       Given {}
 109           -> cmap { cts_given = Map.insertWith unionBags a this_ct (cts_given cmap) }
 110       Derived {}
 111           -> cmap { cts_derived = Map.insertWith unionBags a this_ct (cts_derived cmap) }
 112   where this_ct = singleCCan ct
 113
 114 getRelevantCts :: Ord a => a -> CCanMap a -> (CanonicalCts, CCanMap a)
 115 -- Gets the relevant constraints and returns the rest of the CCanMap
 116 getRelevantCts a cmap
 117     = let relevant = unionManyBags [ Map.findWithDefault emptyCCan a (cts_wanted cmap)
 118                                    , Map.findWithDefault emptyCCan a (cts_given cmap)
 119                                    , Map.findWithDefault emptyCCan a (cts_derived cmap) ]
 120           residual_map = cmap { cts_wanted = Map.delete a (cts_wanted cmap)
 121                               , cts_given = Map.delete a (cts_given cmap)
 122                               , cts_derived = Map.delete a (cts_derived cmap) }
 123       in (relevant, residual_map)
 124
 125 extractUnsolvedCMap :: Ord a => CCanMap a -> (CanonicalCts, CCanMap a)
 126 -- Gets the wanted or derived constraints and returns a residual
 127 -- CCanMap with only givens.
 128 extractUnsolvedCMap cmap =
 129   let wntd = Map.fold unionBags emptyCCan (cts_wanted cmap)
 130       derd = Map.fold unionBags emptyCCan (cts_derived cmap)
 131   in (wntd `unionBags` derd,
 132            cmap { cts_wanted = Map.empty, cts_derived = Map.empty })
 133
 134
 135 -- See Note [InertSet invariants]
 136 data InertSet
 137   = IS { inert_eqs          :: CanonicalCts               -- Equalities only (CTyEqCan)
 138        , inert_dicts        :: CCanMap Class              -- Dictionaries only
 139        , inert_ips          :: CCanMap (IPName Name)      -- Implicit parameters
 140        , inert_frozen       :: CanonicalCts
 141        , inert_funeqs       :: CCanMap TyCon              -- Type family equalities only
 142                -- This representation allows us to quickly get to the relevant
 143                -- inert constraints when interacting a work item with the inert set.
 144        }
 145
 146 tyVarsOfInert :: InertSet -> TcTyVarSet
 147 tyVarsOfInert (IS { inert_eqs    = eqs
 148                   , inert_dicts  = dictmap
 149                   , inert_ips    = ipmap
 150                   , inert_frozen = frozen
 151                   , inert_funeqs = funeqmap }) = tyVarsOfCanonicals cts
 152   where
 153     cts = eqs `andCCan` frozen `andCCan` cCanMapToBag dictmap
 154               `andCCan` cCanMapToBag ipmap `andCCan` cCanMapToBag funeqmap
 155
 156 instance Outputable InertSet where
 157   ppr is = vcat [ vcat (map ppr (Bag.bagToList $ inert_eqs is))
 158                 , vcat (map ppr (Bag.bagToList $ cCanMapToBag (inert_dicts is)))
 159                 , vcat (map ppr (Bag.bagToList $ cCanMapToBag (inert_ips is)))
 160                 , vcat (map ppr (Bag.bagToList $ cCanMapToBag (inert_funeqs is)))
 161                 , vcat (map ppr (Bag.bagToList $ inert_frozen is))
 162                 ]
 163
 164 emptyInert :: InertSet
 165 emptyInert = IS { inert_eqs    = Bag.emptyBag
 166                 , inert_frozen = Bag.emptyBag
 167                 , inert_dicts  = emptyCCanMap
 168                 , inert_ips    = emptyCCanMap
 169                 , inert_funeqs = emptyCCanMap }
 170
 171 updInertSet :: InertSet -> AtomicInert -> InertSet
 172 updInertSet is item
 173   | isCTyEqCan item                     -- Other equality
 174   = let eqs' = inert_eqs is `Bag.snocBag` item
 175     in is { inert_eqs = eqs' }
 176   | Just cls <- isCDictCan_Maybe item   -- Dictionary
 177   = is { inert_dicts = updCCanMap (cls,item) (inert_dicts is) }
 178   | Just x  <- isCIPCan_Maybe item      -- IP
 179   = is { inert_ips   = updCCanMap (x,item) (inert_ips is) }
 180   | Just tc <- isCFunEqCan_Maybe item   -- Function equality
 181   = is { inert_funeqs = updCCanMap (tc,item) (inert_funeqs is) }
 182   | otherwise
 183   = is { inert_frozen = inert_frozen is `Bag.snocBag` item }
 184
 185 extractUnsolved :: InertSet -> (InertSet, CanonicalCts)
 186 -- Postcondition: the returned canonical cts are either Derived, or Wanted.
 187 extractUnsolved is@(IS {inert_eqs = eqs})
 188   = let is_solved  = is { inert_eqs    = solved_eqs
 189                         , inert_dicts  = solved_dicts
 190                         , inert_ips    = solved_ips
 191                         , inert_frozen = emptyCCan
 192                         , inert_funeqs = solved_funeqs }
 193     in (is_solved, unsolved)
 194
 195   where (unsolved_eqs, solved_eqs)       = Bag.partitionBag (not.isGivenCt) eqs
 196         (unsolved_ips, solved_ips)       = extractUnsolvedCMap (inert_ips is)
 197         (unsolved_dicts, solved_dicts)   = extractUnsolvedCMap (inert_dicts is)
 198         (unsolved_funeqs, solved_funeqs) = extractUnsolvedCMap (inert_funeqs is)
 199
 200         unsolved = unsolved_eqs `unionBags` inert_frozen is `unionBags`
 201                    unsolved_ips `unionBags` unsolved_dicts `unionBags` unsolved_funeqs
 202 \end{code}
 203
 204 %*********************************************************************
 205 %*                                                                   *
 206 *                      Main Interaction Solver                       *
 207 *                                                                    *
 208 **********************************************************************
 209
 210 Note [Basic plan]
 211 ~~~~~~~~~~~~~~~~~
 212 1. Canonicalise (unary)
 213 2. Pairwise interaction (binary)
 214     * Take one from work list
 215     * Try all pair-wise interactions with each constraint in inert
 216
 217    As an optimisation, we prioritize the equalities both in the
 218    worklist and in the inerts.
 219
 220 3. Try to solve spontaneously for equalities involving touchables
 221 4. Top-level interaction (binary wrt top-level)
 222    Superclass decomposition belongs in (4), see note [Superclasses]
 223
 224 \begin{code}
 225 type AtomicInert = CanonicalCt     -- constraint pulled from InertSet
 226 type WorkItem    = CanonicalCt     -- constraint pulled from WorkList
 227
 228 ------------------------
 229 data StopOrContinue
 230   = Stop                        -- Work item is consumed
 231   | ContinueWith WorkItem       -- Not consumed
 232
 233 instance Outputable StopOrContinue where
 234   ppr Stop             = ptext (sLit "Stop")
 235   ppr (ContinueWith w) = ptext (sLit "ContinueWith") <+> ppr w
 236
 237 -- Results after interacting a WorkItem as far as possible with an InertSet
 238 data StageResult
 239   = SR { sr_inerts     :: InertSet
 240            -- The new InertSet to use (REPLACES the old InertSet)
 241        , sr_new_work   :: WorkList
 242            -- Any new work items generated (should be ADDED to the old WorkList)
 243            -- Invariant:
 244            --    sr_stop = Just workitem => workitem is *not* in sr_inerts and
 245            --                               workitem is inert wrt to sr_inerts
 246        , sr_stop       :: StopOrContinue
 247        }
 248
 249 instance Outputable StageResult where
 250   ppr (SR { sr_inerts = inerts, sr_new_work = work, sr_stop = stop })
 251     = ptext (sLit "SR") <+>
 252       braces (sep [ ptext (sLit "inerts =") <+> ppr inerts <> comma
 253                   , ptext (sLit "new work =") <+> ppr work <> comma
 254                   , ptext (sLit "stop =") <+> ppr stop])
 255
 256 type SubGoalDepth = Int   -- Starts at zero; used to limit infinite
 257                           -- recursion of sub-goals
 258 type SimplifierStage = SubGoalDepth -> WorkItem -> InertSet -> TcS StageResult
 259
 260 -- Combine a sequence of simplifier 'stages' to create a pipeline
 261 runSolverPipeline :: SubGoalDepth
 262                   -> [(String, SimplifierStage)]
 263                   -> InertSet -> WorkItem
 264                   -> TcS (InertSet, WorkList)
 265 -- Precondition: non-empty list of stages
 266 runSolverPipeline depth pipeline inerts workItem
 267   = do { traceTcS "Start solver pipeline" $
 268             vcat [ ptext (sLit "work item =") <+> ppr workItem
 269                  , ptext (sLit "inerts    =") <+> ppr inerts]
 270
 271        ; let itr_in = SR { sr_inerts = inerts
 272                          , sr_new_work = emptyWorkList
 273                          , sr_stop = ContinueWith workItem }
 274        ; itr_out <- run_pipeline pipeline itr_in
 275        ; let new_inert
 276               = case sr_stop itr_out of
 277                   Stop              -> sr_inerts itr_out
 278                   ContinueWith item -> sr_inerts itr_out `updInertSet` item
 279        ; return (new_inert, sr_new_work itr_out) }
 280   where
 281     run_pipeline :: [(String, SimplifierStage)]
 282                  -> StageResult -> TcS StageResult
 283     run_pipeline [] itr                         = return itr
 284     run_pipeline _  itr@(SR { sr_stop = Stop }) = return itr
 285
 286     run_pipeline ((name,stage):stages)
 287                  (SR { sr_new_work = accum_work
 288                      , sr_inerts   = inerts
 289                      , sr_stop     = ContinueWith work_item })
 290       = do { itr <- stage depth work_item inerts
 291            ; traceTcS ("Stage result (" ++ name ++ ")") (ppr itr)
 292            ; let itr' = itr { sr_new_work = accum_work `unionWorkList` sr_new_work itr }
 293            ; run_pipeline stages itr' }
 294 \end{code}
 295
 296 Example 1:
 297   Inert:   {c ~ d, F a ~ t, b ~ Int, a ~ ty} (all given)
 298   Reagent: a ~ [b] (given)
 299
 300 React with (c~d)     ==> IR (ContinueWith (a~[b]))  True    []
 301 React with (F a ~ t) ==> IR (ContinueWith (a~[b]))  False   [F [b] ~ t]
 302 React with (b ~ Int) ==> IR (ContinueWith (a~[Int]) True    []
 303
 304 Example 2:
 305   Inert:  {c ~w d, F a ~g t, b ~w Int, a ~w ty}
 306   Reagent: a ~w [b]
 307
 308 React with (c ~w d)   ==> IR (ContinueWith (a~[b]))  True    []
 309 React with (F a ~g t) ==> IR (ContinueWith (a~[b]))  True    []    (can't rewrite given with wanted!)
 310 etc.
 311
 312 Example 3:
 313   Inert:  {a ~ Int, F Int ~ b} (given)
 314   Reagent: F a ~ b (wanted)
 315
 316 React with (a ~ Int)   ==> IR (ContinueWith (F Int ~ b)) True []
 317 React with (F Int ~ b) ==> IR Stop True []    -- after substituting we re-canonicalize and get nothing
 318
 319 \begin{code}
 320 -- Main interaction solver: we fully solve the worklist 'in one go',
 321 -- returning an extended inert set.
 322 --
 323 -- See Note [Touchables and givens].
 324 solveInteractGiven :: InertSet -> GivenLoc -> [EvVar] -> TcS InertSet
 325 solveInteractGiven inert gloc evs
 326   = do { (_, inert_ret) <- solveInteract inert $ listToBag $
 327                            map mk_given evs
 328        ; return inert_ret }
 329   where
 330     flav = Given gloc
 331     mk_given ev = mkEvVarX ev flav
 332
 333 solveInteractWanted :: InertSet -> [WantedEvVar] -> TcS InertSet
 334 solveInteractWanted inert wvs
 335   = do { (_,inert_ret) <- solveInteract inert $ listToBag $
 336                           map wantedToFlavored wvs
 337        ; return inert_ret }
 338
 339 solveInteract :: InertSet -> Bag FlavoredEvVar -> TcS (Bool, InertSet)
 340 -- Post: (True,  inert_set) means we managed to discharge all constraints
 341 --                          without actually doing any interactions!
 342 --       (False, inert_set) means some interactions occurred
 343 solveInteract inert ws
 344   = do { dyn_flags <- getDynFlags
 345        ; sctx <- getTcSContext
 346
 347        ; traceTcS "solveInteract, before clever canonicalization:" $
 348          vcat [ text "ws = " <+>  ppr (mapBag (\(EvVarX ev ct)
 349                                                    -> (ct,evVarPred ev)) ws)
 350               , text "inert = " <+> ppr inert ]
 351
 352        ; can_ws <- mkCanonicalFEVs ws
 353
 354        ; (flag, inert_ret)
 355            <- foldrWorkListM (tryPreSolveAndInteract sctx dyn_flags) (True,inert) can_ws
 356
 357        ; traceTcS "solveInteract, after clever canonicalization (and interaction):" $
 358          vcat [ text "No interaction happened = " <+> ppr flag
 359               , text "inert_ret = " <+> ppr inert_ret ]
 360
 361        ; return (flag, inert_ret) }
 362
 363 tryPreSolveAndInteract :: SimplContext
 364                        -> DynFlags
 365                        -> CanonicalCt
 366                        -> (Bool, InertSet)
 367                        -> TcS (Bool, InertSet)
 368 -- Returns: True if it was able to discharge this constraint AND all previous ones
 369 tryPreSolveAndInteract sctx dyn_flags ct (all_previous_discharged, inert)
 370   = do { let inert_cts = get_inert_cts (evVarPred ev_var)
 371
 372        ; this_one_discharged <-
 373            if isCFrozenErr ct then
 374                return False
 375            else
 376                dischargeFromCCans inert_cts ev_var fl
 377
 378        ; if this_one_discharged
 379          then return (all_previous_discharged, inert)
 380
 381          else do
 382        { inert_ret <- solveOneWithDepth (ctxtStkDepth dyn_flags,0,[]) ct inert
 383        ; return (False, inert_ret) } }
 384
 385   where
 386     ev_var = cc_id ct
 387     fl = cc_flavor ct
 388
 389     get_inert_cts (ClassP clas _)
 390       | simplEqsOnly sctx = emptyCCan
 391       | otherwise         = fst (getRelevantCts clas (inert_dicts inert))
 392     get_inert_cts (IParam {})
 393       = emptyCCan -- We must not do the same thing for IParams, because (contrary
 394                   -- to dictionaries), work items /must/ override inert items.
 395                  -- See Note [Overriding implicit parameters] in TcInteract.
 396     get_inert_cts (EqPred {})
 397       = inert_eqs inert `unionBags` cCanMapToBag (inert_funeqs inert)
 398
 399 dischargeFromCCans :: CanonicalCts -> EvVar -> CtFlavor -> TcS Bool
 400 -- See if this (pre-canonicalised) work-item is identical to a
 401 -- one already in the inert set. Reasons:
 402 --    a) Avoid creating superclass constraints for millions of incoming (Num a) constraints
 403 --    b) Termination for improve_eqs in TcSimplify.simpl_loop
 404 dischargeFromCCans cans ev fl
 405   = Bag.foldrBag discharge_ct (return False) cans
 406   where
 407     the_pred = evVarPred ev
 408
 409     discharge_ct :: CanonicalCt -> TcS Bool -> TcS Bool
 410     discharge_ct ct _rest
 411       | evVarPred (cc_id ct) `tcEqPred` the_pred
 412       , cc_flavor ct `canSolve` fl
 413       = do { when (isWanted fl) $ set_ev_bind ev (cc_id ct)
 414                  -- Deriveds need no evidence
 415                  -- For Givens, we already have evidence, and we don't need it twice
 416            ; return True }
 417       where
 418          set_ev_bind x y
 419             | EqPred {} <- evVarPred y = setEvBind x (EvCoercion (mkCoVarCoercion y))
 420             | otherwise                = setEvBind x (EvId y)
 421
 422     discharge_ct _ct rest = rest
 423 \end{code}
 424
 425 Note [Avoiding the superclass explosion]
 426 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 427 This note now is not as significant as it used to be because we no
 428 longer add the superclasses of Wanted as Derived, except only if they
 429 have equality superclasses or superclasses with functional
 430 dependencies. The fear was that hundreds of identical wanteds would
 431 give rise each to the same superclass or equality Derived's which
 432 would lead to a blo-up in the number of interactions.
 433
 434 Instead, what we do with tryPreSolveAndCanon, is when we encounter a
 435 new constraint, we very quickly see if it can be immediately
 436 discharged by a class constraint in our inert set or the previous
 437 canonicals. If so, we add nothing to the returned canonical
 438 constraints.
 439
 440 \begin{code}
 441 solveOne :: WorkItem -> InertSet -> TcS InertSet
 442 solveOne workItem inerts
 443   = do { dyn_flags <- getDynFlags
 444        ; solveOneWithDepth (ctxtStkDepth dyn_flags,0,[]) workItem inerts
 445        }
 446
 447 -----------------
 448 solveInteractWithDepth :: (Int, Int, [WorkItem])
 449                        -> WorkList -> InertSet -> TcS InertSet
 450 solveInteractWithDepth ctxt@(max_depth,n,stack) ws inert
 451   | isEmptyWorkList ws
 452   = return inert
 453
 454   | n > max_depth
 455   = solverDepthErrorTcS n stack
 456
 457   | otherwise
 458   = do { traceTcS "solveInteractWithDepth" $
 459               vcat [ text "Current depth =" <+> ppr n
 460                    , text "Max depth =" <+> ppr max_depth
 461                    , text "ws =" <+> ppr ws ]
 462
 463
 464        ; foldrWorkListM (solveOneWithDepth ctxt) inert ws }
 465               -- use foldr to preserve the order
 466
 467 ------------------
 468 -- Fully interact the given work item with an inert set, and return a
 469 -- new inert set which has assimilated the new information.
 470 solveOneWithDepth :: (Int, Int, [WorkItem])
 471                   -> WorkItem -> InertSet -> TcS InertSet
 472 solveOneWithDepth (max_depth, depth, stack) work inert
 473   = do { traceFireTcS depth (text "Solving {" <+> ppr work)
 474        ; (new_inert, new_work) <- runSolverPipeline depth thePipeline inert work
 475
 476          -- Recursively solve the new work generated
 477          -- from workItem, with a greater depth
 478        ; res_inert <- solveInteractWithDepth (max_depth, depth+1, work:stack) new_work new_inert
 479
 480        ; traceFireTcS depth (text "Done }" <+> ppr work)
 481
 482        ; return res_inert }
 483
 484 thePipeline :: [(String,SimplifierStage)]
 485 thePipeline = [ ("interact with inert eqs", interactWithInertEqsStage)
 486               , ("interact with inerts",    interactWithInertsStage)
 487               , ("spontaneous solve",       spontaneousSolveStage)
 488               , ("top-level reactions",     topReactionsStage) ]
 489 \end{code}
 490
 491 *********************************************************************************
 492 *                                                                               *
 493                        The spontaneous-solve Stage
 494 *                                                                               *
 495 *********************************************************************************
 496
 497 Note [Efficient Orientation]
 498 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 499
 500 There are two cases where we have to be careful about
 501 orienting equalities to get better efficiency.
 502
 503 Case 1: In Rewriting Equalities (function rewriteEqLHS)
 504
 505     When rewriting two equalities with the same LHS:
 506           (a)  (tv ~ xi1)
 507           (b)  (tv ~ xi2)
 508     We have a choice of producing work (xi1 ~ xi2) (up-to the
 509     canonicalization invariants) However, to prevent the inert items
 510     from getting kicked out of the inerts first, we prefer to
 511     canonicalize (xi1 ~ xi2) if (b) comes from the inert set, or (xi2
 512     ~ xi1) if (a) comes from the inert set.
 513
 514     This choice is implemented using the WhichComesFromInert flag.
 515
 516 Case 2: Functional Dependencies
 517     Again, we should prefer, if possible, the inert variables on the RHS
 518
 519 Case 3: IP improvement work
 520     We must always rewrite so that the inert type is on the right.
 521
 522 \begin{code}
 523 spontaneousSolveStage :: SimplifierStage
 524 spontaneousSolveStage depth workItem inerts
 525   = do { mSolve <- trySpontaneousSolve workItem
 526
 527        ; case mSolve of
 528            SPCantSolve -> -- No spontaneous solution for him, keep going
 529                return $ SR { sr_new_work   = emptyWorkList
 530                            , sr_inerts     = inerts
 531                            , sr_stop       = ContinueWith workItem }
 532
 533            SPSolved workItem'
 534                | not (isGivenCt workItem)
 535                  -- Original was wanted or derived but we have now made him
 536                  -- given so we have to interact him with the inerts due to
 537                  -- its status change. This in turn may produce more work.
 538                  -- We do this *right now* (rather than just putting workItem'
 539                  -- back into the work-list) because we've solved
 540                -> do { bumpStepCountTcS
 541                      ; traceFireTcS depth (ptext (sLit "Spontaneous (w/d)") <+> ppr workItem)
 542                      ; (new_inert, new_work) <- runSolverPipeline depth
 543                              [ ("recursive interact with inert eqs", interactWithInertEqsStage)
 544                              , ("recursive interact with inerts", interactWithInertsStage)
 545                              ] inerts workItem'
 546                      ; return $ SR { sr_new_work = new_work
 547                                    , sr_inerts   = new_inert -- will include workItem'
 548                                    , sr_stop     = Stop }
 549                      }
 550                | otherwise
 551                    -> -- Original was given; he must then be inert all right, and
 552                       -- workList' are all givens from flattening
 553                       do { bumpStepCountTcS
 554                          ; traceFireTcS depth (ptext (sLit "Spontaneous (g)") <+> ppr workItem)
 555                          ; return $ SR { sr_new_work = emptyWorkList
 556                                        , sr_inerts   = inerts `updInertSet` workItem'
 557                                        , sr_stop     = Stop } }
 558            SPError -> -- Return with no new work
 559                return $ SR { sr_new_work = emptyWorkList
 560                            , sr_inerts   = inerts
 561                            , sr_stop     = Stop }
 562        }
 563
 564 data SPSolveResult = SPCantSolve | SPSolved WorkItem | SPError
 565 -- SPCantSolve means that we can't do the unification because e.g. the variable is untouchable
 566 -- SPSolved workItem' gives us a new *given* to go on
 567 -- SPError means that it's completely impossible to solve this equality, eg due to a kind error
 568
 569
 570 -- @trySpontaneousSolve wi@ solves equalities where one side is a
 571 -- touchable unification variable.
 572 --          See Note [Touchables and givens]
 573 trySpontaneousSolve :: WorkItem -> TcS SPSolveResult
 574 trySpontaneousSolve workItem@(CTyEqCan { cc_id = cv, cc_flavor = gw, cc_tyvar = tv1, cc_rhs = xi })
 575   | isGiven gw
 576   = return SPCantSolve
 577   | Just tv2 <- tcGetTyVar_maybe xi
 578   = do { tch1 <- isTouchableMetaTyVar tv1
 579        ; tch2 <- isTouchableMetaTyVar tv2
 580        ; case (tch1, tch2) of
 581            (True,  True)  -> trySpontaneousEqTwoWay cv gw tv1 tv2
 582            (True,  False) -> trySpontaneousEqOneWay cv gw tv1 xi
 583            (False, True)  -> trySpontaneousEqOneWay cv gw tv2 (mkTyVarTy tv1)
 584            _ -> return SPCantSolve }
 585   | otherwise
 586   = do { tch1 <- isTouchableMetaTyVar tv1
 587        ; if tch1 then trySpontaneousEqOneWay cv gw tv1 xi
 588                  else do { traceTcS "Untouchable LHS, can't spontaneously solve workitem:"
 589                                     (ppr workItem)
 590                          ; return SPCantSolve }
 591        }
 592
 593   -- No need for
 594   --      trySpontaneousSolve (CFunEqCan ...) = ...
 595   -- See Note [No touchables as FunEq RHS] in TcSMonad
 596 trySpontaneousSolve _ = return SPCantSolve
 597
 598 ----------------
 599 trySpontaneousEqOneWay :: CoVar -> CtFlavor -> TcTyVar -> Xi -> TcS SPSolveResult
 600 -- tv is a MetaTyVar, not untouchable
 601 trySpontaneousEqOneWay cv gw tv xi
 602   | not (isSigTyVar tv) || isTyVarTy xi
 603   = do { let kxi = typeKind xi -- NB: 'xi' is fully rewritten according to the inerts
 604                                -- so we have its more specific kind in our hands
 605        ; if kxi `isSubKind` tyVarKind tv then
 606              solveWithIdentity cv gw tv xi
 607          else return SPCantSolve
 608 {-
 609          else if tyVarKind tv `isSubKind` kxi then
 610              return SPCantSolve -- kinds are compatible but we can't solveWithIdentity this way
 611                                 -- This case covers the  a_touchable :: * ~ b_untouchable :: ??
 612                                 -- which has to be deferred or floated out for someone else to solve
 613                                 -- it in a scope where 'b' is no longer untouchable.
 614          else do { addErrorTcS KindError gw (mkTyVarTy tv) xi -- See Note [Kind errors]
 615                  ; return SPError }
 616 -}
 617        }
 618   | otherwise -- Still can't solve, sig tyvar and non-variable rhs
 619   = return SPCantSolve
 620
 621 ----------------
 622 trySpontaneousEqTwoWay :: CoVar -> CtFlavor -> TcTyVar -> TcTyVar -> TcS SPSolveResult
 623 -- Both tyvars are *touchable* MetaTyvars so there is only a chance for kind error here
 624 trySpontaneousEqTwoWay cv gw tv1 tv2
 625   | k1 `isSubKind` k2
 626   , nicer_to_update_tv2 = solveWithIdentity cv gw tv2 (mkTyVarTy tv1)
 627   | k2 `isSubKind` k1
 628   = solveWithIdentity cv gw tv1 (mkTyVarTy tv2)
 629   | otherwise -- None is a subkind of the other, but they are both touchable!
 630   = return SPCantSolve
 631     -- do { addErrorTcS KindError gw (mkTyVarTy tv1) (mkTyVarTy tv2)
 632     --   ; return SPError }
 633   where
 634     k1 = tyVarKind tv1
 635     k2 = tyVarKind tv2
 636     nicer_to_update_tv2 = isSigTyVar tv1 || isSystemName (Var.varName tv2)
 637 \end{code}
 638
 639 Note [Kind errors]
 640 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 641 Consider the wanted problem:
 642       alpha ~ (# Int, Int #)
 643 where alpha :: ?? and (# Int, Int #) :: (#). We can't spontaneously solve this constraint,
 644 but we should rather reject the program that give rise to it. If 'trySpontaneousEqTwoWay'
 645 simply returns @CantSolve@ then that wanted constraint is going to propagate all the way and
 646 get quantified over in inference mode. That's bad because we do know at this point that the
 647 constraint is insoluble. Instead, we call 'recKindErrorTcS' here, which will fail later on.
 648
 649 The same applies in canonicalization code in case of kind errors in the givens.
 650
 651 However, when we canonicalize givens we only check for compatibility (@compatKind@).
 652 If there were a kind error in the givens, this means some form of inconsistency or dead code.
 653
 654 You may think that when we spontaneously solve wanteds we may have to look through the
 655 bindings to determine the right kind of the RHS type. E.g one may be worried that xi is
 656 @alpha@ where alpha :: ? and a previous spontaneous solving has set (alpha := f) with (f :: *).
 657 But we orient our constraints so that spontaneously solved ones can rewrite all other constraint
 658 so this situation can't happen.
 659
 660 Note [Spontaneous solving and kind compatibility]
 661 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 662 Note that our canonical constraints insist that *all* equalities (tv ~
 663 xi) or (F xis ~ rhs) require the LHS and the RHS to have *compatible*
 664 the same kinds.  ("compatible" means one is a subKind of the other.)
 665
 666   - It can't be *equal* kinds, because
 667      b) wanted constraints don't necessarily have identical kinds
 668                eg   alpha::? ~ Int
 669      b) a solved wanted constraint becomes a given
 670
 671   - SPJ thinks that *given* constraints (tv ~ tau) always have that
 672     tau has a sub-kind of tv; and when solving wanted constraints
 673     in trySpontaneousEqTwoWay we re-orient to achieve this.
 674
 675   - Note that the kind invariant is maintained by rewriting.
 676     Eg wanted1 rewrites wanted2; if both were compatible kinds before,
 677        wanted2 will be afterwards.  Similarly givens.
 678
 679 Caveat:
 680   - Givens from higher-rank, such as:
 681           type family T b :: * -> * -> *
 682           type instance T Bool = (->)
 683
 684           f :: forall a. ((T a ~ (->)) => ...) -> a -> ...
 685           flop = f (...) True
 686      Whereas we would be able to apply the type instance, we would not be able to
 687      use the given (T Bool ~ (->)) in the body of 'flop'
 688
 689
 690 Note [Avoid double unifications]
 691 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 692 The spontaneous solver has to return a given which mentions the unified unification
 693 variable *on the left* of the equality. Here is what happens if not:
 694   Original wanted:  (a ~ alpha),  (alpha ~ Int)
 695 We spontaneously solve the first wanted, without changing the order!
 696       given : a ~ alpha      [having unified alpha := a]
 697 Now the second wanted comes along, but he cannot rewrite the given, so we simply continue.
 698 At the end we spontaneously solve that guy, *reunifying*  [alpha := Int]
 699
 700 We avoid this problem by orienting the resulting given so that the unification
 701 variable is on the left.  [Note that alternatively we could attempt to
 702 enforce this at canonicalization]
 703
 704 See also Note [No touchables as FunEq RHS] in TcSMonad; avoiding
 705 double unifications is the main reason we disallow touchable
 706 unification variables as RHS of type family equations: F xis ~ alpha.
 707
 708 \begin{code}
 709 ----------------
 710
 711 solveWithIdentity :: CoVar -> CtFlavor -> TcTyVar -> Xi -> TcS SPSolveResult
 712 -- Solve with the identity coercion
 713 -- Precondition: kind(xi) is a sub-kind of kind(tv)
 714 -- Precondition: CtFlavor is Wanted or Derived
 715 -- See [New Wanted Superclass Work] to see why solveWithIdentity
 716 --     must work for Derived as well as Wanted
 717 -- Returns: workItem where
 718 --        workItem = the new Given constraint
 719 solveWithIdentity cv wd tv xi
 720   = do { traceTcS "Sneaky unification:" $
 721                        vcat [text "Coercion variable:  " <+> ppr wd,
 722                              text "Coercion:           " <+> pprEq (mkTyVarTy tv) xi,
 723                              text "Left  Kind is     : " <+> ppr (typeKind (mkTyVarTy tv)),
 724                              text "Right Kind is     : " <+> ppr (typeKind xi)
 725                   ]
 726
 727        ; setWantedTyBind tv xi
 728        ; cv_given <- newGivenCoVar (mkTyVarTy tv) xi xi
 729
 730        ; when (isWanted wd) (setCoBind cv xi)
 731            -- We don't want to do this for Derived, that's why we use 'when (isWanted wd)'
 732
 733        ; return $ SPSolved (CTyEqCan { cc_id = cv_given
 734                                      , cc_flavor = mkGivenFlavor wd UnkSkol
 735                                      , cc_tyvar  = tv, cc_rhs = xi }) }
 736 \end{code}
 737
 738
 739 *********************************************************************************
 740 *                                                                               *
 741                        The interact-with-inert Stage
 742 *                                                                               *
 743 *********************************************************************************
 744
 745 Note [The Solver Invariant]
 746 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
 747 We always add Givens first.  So you might think that the solver has
 748 the invariant
 749
 750    If the work-item is Given,
 751    then the inert item must Given
 752
 753 But this isn't quite true.  Suppose we have,
 754     c1: [W] beta ~ [alpha], c2 : [W] blah, c3 :[W] alpha ~ Int
 755 After processing the first two, we get
 756      c1: [G] beta ~ [alpha], c2 : [W] blah
 757 Now, c3 does not interact with the the given c1, so when we spontaneously
 758 solve c3, we must re-react it with the inert set.  So we can attempt a
 759 reaction between inert c2 [W] and work-item c3 [G].
 760
 761 It *is* true that [Solver Invariant]
 762    If the work-item is Given,
 763    AND there is a reaction
 764    then the inert item must Given
 765 or, equivalently,
 766    If the work-item is Given,
 767    and the inert item is Wanted/Derived
 768    then there is no reaction
 769
 770 \begin{code}
 771 -- Interaction result of  WorkItem <~> AtomicInert
 772 data InteractResult
 773    = IR { ir_stop         :: StopOrContinue
 774             -- Stop
 775             --   => Reagent (work item) consumed.
 776             -- ContinueWith new_reagent
 777             --   => Reagent transformed but keep gathering interactions.
 778             --      The transformed item remains inert with respect
 779             --      to any previously encountered inerts.
 780
 781         , ir_inert_action :: InertAction
 782             -- Whether the inert item should remain in the InertSet.
 783
 784         , ir_new_work     :: WorkList
 785             -- new work items to add to the WorkList
 786
 787         , ir_fire :: Maybe String    -- Tells whether a rule fired, and if so what
 788         }
 789
 790 -- What to do with the inert reactant.
 791 data InertAction = KeepInert | DropInert
 792
 793 mkIRContinue :: String -> WorkItem -> InertAction -> WorkList -> TcS InteractResult
 794 mkIRContinue rule wi keep newWork
 795   = return $ IR { ir_stop = ContinueWith wi, ir_inert_action = keep
 796                 , ir_new_work = newWork, ir_fire = Just rule }
 797
 798 mkIRStopK :: String -> WorkList -> TcS InteractResult
 799 mkIRStopK rule newWork
 800   = return $ IR { ir_stop = Stop, ir_inert_action = KeepInert
 801                 , ir_new_work = newWork, ir_fire = Just rule }
 802
 803 mkIRStopD :: String -> WorkList -> TcS InteractResult
 804 mkIRStopD rule newWork
 805   = return $ IR { ir_stop = Stop, ir_inert_action = DropInert
 806                 , ir_new_work = newWork, ir_fire = Just rule }
 807
 808 noInteraction :: Monad m => WorkItem -> m InteractResult
 809 noInteraction wi
 810   = return $ IR { ir_stop = ContinueWith wi, ir_inert_action = KeepInert
 811                 , ir_new_work = emptyWorkList, ir_fire = Nothing }
 812
 813 data WhichComesFromInert = LeftComesFromInert | RightComesFromInert
 814      -- See Note [Efficient Orientation]
 815
 816
 817 ---------------------------------------------------
 818 -- Interact a single WorkItem with the equalities of an inert set as
 819 -- far as possible, i.e. until we get a Stop result from an individual
 820 -- reaction (i.e. when the WorkItem is consumed), or until we've
 821 -- interact the WorkItem with the entire equalities of the InertSet
 822
 823 interactWithInertEqsStage :: SimplifierStage
 824 interactWithInertEqsStage depth workItem inert
 825   = Bag.foldrBagM (interactNext depth) initITR (inert_eqs inert)
 826                         -- use foldr to preserve the order
 827   where
 828     initITR = SR { sr_inerts   = inert { inert_eqs = emptyCCan }
 829                  , sr_new_work = emptyWorkList
 830                  , sr_stop     = ContinueWith workItem }
 831
 832 ---------------------------------------------------
 833 -- Interact a single WorkItem with *non-equality* constraints in the inert set.
 834 -- Precondition: equality interactions must have already happened, hence we have
 835 -- to pick up some information from the incoming inert, before folding over the
 836 -- "Other" constraints it contains!
 837
 838 interactWithInertsStage :: SimplifierStage
 839 interactWithInertsStage depth workItem inert
 840   = let (relevant, inert_residual) = getISRelevant workItem inert
 841         initITR = SR { sr_inerts   = inert_residual
 842                      , sr_new_work = emptyWorkList
 843                      , sr_stop     = ContinueWith workItem }
 844     in Bag.foldrBagM (interactNext depth) initITR relevant
 845                         -- use foldr to preserve the order
 846   where
 847     getISRelevant :: CanonicalCt -> InertSet -> (CanonicalCts, InertSet)
 848     getISRelevant (CFrozenErr {}) is = (emptyCCan, is)
 849                   -- Nothing s relevant; we have alread interacted
 850                   -- it with the equalities in the inert set
 851
 852     getISRelevant (CDictCan { cc_class = cls } ) is
 853       = let (relevant, residual_map) = getRelevantCts cls (inert_dicts is)
 854         in (relevant, is { inert_dicts = residual_map })
 855     getISRelevant (CFunEqCan { cc_fun = tc } ) is
 856       = let (relevant, residual_map) = getRelevantCts tc (inert_funeqs is)
 857         in (relevant, is { inert_funeqs = residual_map })
 858     getISRelevant (CIPCan { cc_ip_nm = nm }) is
 859       = let (relevant, residual_map) = getRelevantCts nm (inert_ips is)
 860         in (relevant, is { inert_ips = residual_map })
 861     -- An equality, finally, may kick everything except equalities out
 862     -- because we have already interacted the equalities in interactWithInertEqsStage
 863     getISRelevant _eq_ct is  -- Equality, everything is relevant for this one
 864                              -- TODO: if we were caching variables, we'd know that only
 865                              --       some are relevant. Experiment with this for now.
 866       = let cts = cCanMapToBag (inert_ips is) `unionBags`
 867                     cCanMapToBag (inert_dicts is) `unionBags` cCanMapToBag (inert_funeqs is)
 868         in (cts, is { inert_dicts  = emptyCCanMap
 869                     , inert_ips    = emptyCCanMap
 870                     , inert_funeqs = emptyCCanMap })
 871
 872 interactNext :: SubGoalDepth -> AtomicInert -> StageResult -> TcS StageResult
 873 interactNext depth inert it
 874   | ContinueWith work_item <- sr_stop it
 875   = do { let inerts = sr_inerts it
 876
 877        ; IR { ir_new_work = new_work, ir_inert_action = inert_action
 878             , ir_fire = fire_info, ir_stop = stop }
 879             <- interactWithInert inert work_item
 880
 881        ; let mk_msg rule
 882                = text rule <+> keep_doc
 883                  <+> vcat [ ptext (sLit "Inert =") <+> ppr inert
 884                           , ptext (sLit "Work =")  <+> ppr work_item
 885                           , ppUnless (isEmptyWorkList new_work) $
 886                             ptext (sLit "New =") <+> ppr new_work ]
 887              keep_doc = case inert_action of
 888                           KeepInert -> ptext (sLit "[keep]")
 889                           DropInert -> ptext (sLit "[drop]")
 890        ; case fire_info of
 891            Just rule -> do { bumpStepCountTcS
 892                            ; traceFireTcS depth (mk_msg rule) }
 893            Nothing  -> return ()
 894
 895        -- New inerts depend on whether we KeepInert or not
 896        ; let inerts_new = case inert_action of
 897                             KeepInert -> inerts `updInertSet` inert
 898                             DropInert -> inerts
 899
 900        ; return $ SR { sr_inerts   = inerts_new
 901                      , sr_new_work = sr_new_work it `unionWorkList` new_work
 902                      , sr_stop     = stop } }
 903   | otherwise
 904   = return $ it { sr_inerts = (sr_inerts it) `updInertSet` inert }
 905
 906 -- Do a single interaction of two constraints.
 907 interactWithInert :: AtomicInert -> WorkItem -> TcS InteractResult
 908 interactWithInert inert workItem
 909   = do { ctxt <- getTcSContext
 910        ; let is_allowed  = allowedInteraction (simplEqsOnly ctxt) inert workItem
 911
 912        ; if is_allowed then
 913               doInteractWithInert inert workItem
 914           else
 915               noInteraction workItem
 916        }
 917
 918 allowedInteraction :: Bool -> AtomicInert -> WorkItem -> Bool
 919 -- Allowed interactions
 920 allowedInteraction eqs_only (CDictCan {}) (CDictCan {}) = not eqs_only
 921 allowedInteraction eqs_only (CIPCan {})   (CIPCan {})   = not eqs_only
 922 allowedInteraction _ _ _ = True
 923
 924 --------------------------------------------
 925 doInteractWithInert :: CanonicalCt -> CanonicalCt -> TcS InteractResult
 926 -- Identical class constraints.
 927
 928 doInteractWithInert
 929   inertItem@(CDictCan { cc_id = d1, cc_flavor = fl1, cc_class = cls1, cc_tyargs = tys1 })
 930    workItem@(CDictCan { cc_id = d2, cc_flavor = fl2, cc_class = cls2, cc_tyargs = tys2 })
 931   | cls1 == cls2 && (and $ zipWith tcEqType tys1 tys2)
 932   = solveOneFromTheOther "Cls/Cls" (EvId d1,fl1) workItem
 933
 934   | cls1 == cls2 && (not (isGiven fl1 && isGiven fl2))
 935   =      -- See Note [When improvement happens]
 936     do { let pty1 = ClassP cls1 tys1
 937              pty2 = ClassP cls2 tys2
 938              inert_pred_loc     = (pty1, pprFlavorArising fl1)
 939              work_item_pred_loc = (pty2, pprFlavorArising fl2)
 940              fd_eqns = improveFromAnother
 941                                   inert_pred_loc     -- the template
 942                                   work_item_pred_loc -- the one we aim to rewrite
 943                                   -- See Note [Efficient Orientation]
 944
 945        ; m <- rewriteWithFunDeps fd_eqns tys2 fl2
 946        ; case m of
 947            Nothing -> noInteraction workItem
 948            Just (rewritten_tys2, cos2, fd_work)
 949              | tcEqTypes tys1 rewritten_tys2
 950              -> -- Solve him on the spot in this case
 951                 case fl2 of
 952                   Given   {} -> pprPanic "Unexpected given" (ppr inertItem $$ ppr workItem)
 953                   Derived {} -> mkIRStopK "Cls/Cls fundep (solved)" fd_work
 954                   Wanted  {}
 955                     | isDerived fl1
 956                    -> do { setDictBind d2 (EvCast d1 dict_co)
 957                          ; let inert_w = inertItem { cc_flavor = fl2 }
 958                            -- A bit naughty: we take the inert Derived,
 959                            -- turn it into a Wanted, use it to solve the work-item
 960                            -- and put it back into the work-list
 961                            -- Maybe rather than starting again, we could *replace* the
 962                            -- inert item, but its safe and simple to restart
 963                          ; mkIRStopD "Cls/Cls fundep (solved)" $
 964                            workListFromNonEq inert_w `unionWorkList` fd_work }
 965                     | otherwise
 966                     -> do { setDictBind d2 (EvCast d1 dict_co)
 967                           ; mkIRStopK "Cls/Cls fundep (solved)" fd_work }
 968
 969              | otherwise
 970              -> -- We could not quite solve him, but we still rewrite him
 971                 -- Example: class C a b c | a -> b
 972                 --          Given: C Int Bool x, Wanted: C Int beta y
 973                 --          Then rewrite the wanted to C Int Bool y
 974                 --          but note that is still not identical to the given
 975                 -- The important thing is that the rewritten constraint is
 976                 -- inert wrt the given.
 977                 -- However it is not necessarily inert wrt previous inert-set items.
 978                 --      class C a b c d |  a -> b, b c -> d
 979                 --      Inert: c1: C b Q R S, c2: C P Q a b
 980                 --      Work: C P alpha R beta
 981                 --      Does not react with c1; reacts with c2, with alpha:=Q
 982                 --      NOW it reacts with c1!
 983                 -- So we must stop, and put the rewritten constraint back in the work list
 984                 do { d2' <- newDictVar cls1 rewritten_tys2
 985                    ; case fl2 of
 986                        Given {}   -> pprPanic "Unexpected given" (ppr inertItem $$ ppr workItem)
 987                        Wanted {}  -> setDictBind d2 (EvCast d2' dict_co)
 988                        Derived {} -> return ()
 989                    ; let workItem' = workItem { cc_id = d2', cc_tyargs = rewritten_tys2 }
 990                    ; mkIRStopK "Cls/Cls fundep (partial)" $
 991                      workListFromNonEq workItem' `unionWorkList` fd_work }
 992
 993              where
 994                dict_co = mkTyConCoercion (classTyCon cls1) cos2
 995   }
 996
 997 -- Class constraint and given equality: use the equality to rewrite
 998 -- the class constraint.
 999 doInteractWithInert (CTyEqCan { cc_id = cv, cc_flavor = ifl, cc_tyvar = tv, cc_rhs = xi })
1000                     (CDictCan { cc_id = dv, cc_flavor = wfl, cc_class = cl, cc_tyargs = xis })
1001   | ifl `canRewrite` wfl
1002   , tv `elemVarSet` tyVarsOfTypes xis
1003   = do { rewritten_dict <- rewriteDict (cv,tv,xi) (dv,wfl,cl,xis)
1004             -- Continue with rewritten Dictionary because we can only be in the
1005             -- interactWithEqsStage, so the dictionary is inert.
1006        ; mkIRContinue "Eq/Cls" rewritten_dict KeepInert emptyWorkList }
1007
1008 doInteractWithInert (CDictCan { cc_id = dv, cc_flavor = ifl, cc_class = cl, cc_tyargs = xis })
1009            workItem@(CTyEqCan { cc_id = cv, cc_flavor = wfl, cc_tyvar = tv, cc_rhs = xi })
1010   | wfl `canRewrite` ifl
1011   , tv `elemVarSet` tyVarsOfTypes xis
1012   = do { rewritten_dict <- rewriteDict (cv,tv,xi) (dv,ifl,cl,xis)
1013        ; mkIRContinue "Cls/Eq" workItem DropInert (workListFromNonEq rewritten_dict) }
1014
1015 -- Class constraint and given equality: use the equality to rewrite
1016 -- the class constraint.
1017 doInteractWithInert (CTyEqCan { cc_id = cv, cc_flavor = ifl, cc_tyvar = tv, cc_rhs = xi })
1018                     (CIPCan { cc_id = ipid, cc_flavor = wfl, cc_ip_nm = nm, cc_ip_ty = ty })
1019   | ifl `canRewrite` wfl
1020   , tv `elemVarSet` tyVarsOfType ty
1021   = do { rewritten_ip <- rewriteIP (cv,tv,xi) (ipid,wfl,nm,ty)
1022        ; mkIRContinue "Eq/IP" rewritten_ip KeepInert emptyWorkList }
1023
1024 doInteractWithInert (CIPCan { cc_id = ipid, cc_flavor = ifl, cc_ip_nm = nm, cc_ip_ty = ty })
1025            workItem@(CTyEqCan { cc_id = cv, cc_flavor = wfl, cc_tyvar = tv, cc_rhs = xi })
1026   | wfl `canRewrite` ifl
1027   , tv `elemVarSet` tyVarsOfType ty
1028   = do { rewritten_ip <- rewriteIP (cv,tv,xi) (ipid,ifl,nm,ty)
1029        ; mkIRContinue "IP/Eq" workItem DropInert (workListFromNonEq rewritten_ip) }
1030
1031 -- Two implicit parameter constraints.  If the names are the same,
1032 -- but their types are not, we generate a wanted type equality
1033 -- that equates the type (this is "improvement").
1034 -- However, we don't actually need the coercion evidence,
1035 -- so we just generate a fresh coercion variable that isn't used anywhere.
1036 doInteractWithInert (CIPCan { cc_id = id1, cc_flavor = ifl, cc_ip_nm = nm1, cc_ip_ty = ty1 })
1037            workItem@(CIPCan { cc_flavor = wfl, cc_ip_nm = nm2, cc_ip_ty = ty2 })
1038   | nm1 == nm2 && isGiven wfl && isGiven ifl
1039   =     -- See Note [Overriding implicit parameters]
1040         -- Dump the inert item, override totally with the new one
1041         -- Do not require type equality
1042         -- For example, given let ?x::Int = 3 in let ?x::Bool = True in ...
1043         --              we must *override* the outer one with the inner one
1044     mkIRContinue "IP/IP override" workItem DropInert emptyWorkList
1045
1046   | nm1 == nm2 && ty1 `tcEqType` ty2
1047   = solveOneFromTheOther "IP/IP" (EvId id1,ifl) workItem
1048
1049   | nm1 == nm2
1050   =     -- See Note [When improvement happens]
1051     do { co_var <- newCoVar ty2 ty1 -- See Note [Efficient Orientation]
1052        ; let flav = Wanted (combineCtLoc ifl wfl)
1053        ; cans <- mkCanonical flav co_var
1054        ; mkIRContinue "IP/IP fundep" workItem KeepInert cans }
1055
1056 -- Never rewrite a given with a wanted equality, and a type function
1057 -- equality can never rewrite an equality. We rewrite LHS *and* RHS
1058 -- of function equalities so that our inert set exposes everything that
1059 -- we know about equalities.
1060
1061 -- Inert: equality, work item: function equality
1062 doInteractWithInert (CTyEqCan { cc_id = cv1, cc_flavor = ifl, cc_tyvar = tv, cc_rhs = xi1 })
1063                     (CFunEqCan { cc_id = cv2, cc_flavor = wfl, cc_fun = tc
1064                                , cc_tyargs = args, cc_rhs = xi2 })
1065   | ifl `canRewrite` wfl
1066   , tv `elemVarSet` tyVarsOfTypes (xi2:args) -- Rewrite RHS as well
1067   = do { rewritten_funeq <- rewriteFunEq (cv1,tv,xi1) (cv2,wfl,tc,args,xi2)
1068        ; mkIRStopK "Eq/FunEq" (workListFromEq rewritten_funeq) }
1069          -- Must Stop here, because we may no longer be inert after the rewritting.
1070
1071 -- Inert: function equality, work item: equality
1072 doInteractWithInert (CFunEqCan {cc_id = cv1, cc_flavor = ifl, cc_fun = tc
1073                               , cc_tyargs = args, cc_rhs = xi1 })
1074            workItem@(CTyEqCan { cc_id = cv2, cc_flavor = wfl, cc_tyvar = tv, cc_rhs = xi2 })
1075   | wfl `canRewrite` ifl
1076   , tv `elemVarSet` tyVarsOfTypes (xi1:args) -- Rewrite RHS as well
1077   = do { rewritten_funeq <- rewriteFunEq (cv2,tv,xi2) (cv1,ifl,tc,args,xi1)
1078        ; mkIRContinue "FunEq/Eq" workItem DropInert (workListFromEq rewritten_funeq) }
1079          -- One may think that we could (KeepTransformedInert rewritten_funeq)
1080          -- but that is wrong, because it may end up not being inert with respect
1081          -- to future inerts. Example:
1082          -- Original inert = {    F xis ~  [a], b ~ Maybe Int }
1083          -- Work item comes along = a ~ [b]
1084          -- If we keep { F xis ~ [b] } in the inert set we will end up with:
1085          --      { F xis ~ [b], b ~ Maybe Int, a ~ [Maybe Int] }
1086          -- At the end, which is *not* inert. So we should unfortunately DropInert here.
1087
1088 doInteractWithInert (CFunEqCan { cc_id = cv1, cc_flavor = fl1, cc_fun = tc1
1089                                , cc_tyargs = args1, cc_rhs = xi1 })
1090            workItem@(CFunEqCan { cc_id = cv2, cc_flavor = fl2, cc_fun = tc2
1091                                , cc_tyargs = args2, cc_rhs = xi2 })
1092   | fl1 `canSolve` fl2 && lhss_match
1093   = do { cans <- rewriteEqLHS LeftComesFromInert  (mkCoVarCoercion cv1,xi1) (cv2,fl2,xi2)
1094        ; mkIRStopK "FunEq/FunEq" cans }
1095   | fl2 `canSolve` fl1 && lhss_match
1096   = do { cans <- rewriteEqLHS RightComesFromInert (mkCoVarCoercion cv2,xi2) (cv1,fl1,xi1)
1097        ; mkIRContinue "FunEq/FunEq" workItem DropInert cans }
1098   where
1099     lhss_match = tc1 == tc2 && and (zipWith tcEqType args1 args2)
1100
1101 doInteractWithInert (CTyEqCan { cc_id = cv1, cc_flavor = fl1, cc_tyvar = tv1, cc_rhs = xi1 })
1102            workItem@(CTyEqCan { cc_id = cv2, cc_flavor = fl2, cc_tyvar = tv2, cc_rhs = xi2 })
1103 -- Check for matching LHS
1104   | fl1 `canSolve` fl2 && tv1 == tv2
1105   = do { cans <- rewriteEqLHS LeftComesFromInert (mkCoVarCoercion cv1,xi1) (cv2,fl2,xi2)
1106        ; mkIRStopK "Eq/Eq lhs" cans }
1107
1108   | fl2 `canSolve` fl1 && tv1 == tv2
1109   = do { cans <- rewriteEqLHS RightComesFromInert (mkCoVarCoercion cv2,xi2) (cv1,fl1,xi1)
1110        ; mkIRContinue "Eq/Eq lhs" workItem DropInert cans }
1111
1112 -- Check for rewriting RHS
1113   | fl1 `canRewrite` fl2 && tv1 `elemVarSet` tyVarsOfType xi2
1114   = do { rewritten_eq <- rewriteEqRHS (cv1,tv1,xi1) (cv2,fl2,tv2,xi2)
1115        ; mkIRStopK "Eq/Eq rhs" rewritten_eq }
1116
1117   | fl2 `canRewrite` fl1 && tv2 `elemVarSet` tyVarsOfType xi1
1118   = do { rewritten_eq <- rewriteEqRHS (cv2,tv2,xi2) (cv1,fl1,tv1,xi1)
1119        ; mkIRContinue "Eq/Eq rhs" workItem DropInert rewritten_eq }
1120
1121 doInteractWithInert (CTyEqCan   { cc_id = cv1, cc_flavor = fl1, cc_tyvar = tv1, cc_rhs = xi1 })
1122                     (CFrozenErr { cc_id = cv2, cc_flavor = fl2 })
1123   | fl1 `canRewrite` fl2 && tv1 `elemVarSet` tyVarsOfEvVar cv2
1124   = do { rewritten_frozen <- rewriteFrozen (cv1, tv1, xi1) (cv2, fl2)
1125        ; mkIRStopK "Frozen/Eq" rewritten_frozen }
1126
1127 doInteractWithInert (CFrozenErr { cc_id = cv2, cc_flavor = fl2 })
1128            workItem@(CTyEqCan   { cc_id = cv1, cc_flavor = fl1, cc_tyvar = tv1, cc_rhs = xi1 })
1129   | fl1 `canRewrite` fl2 && tv1 `elemVarSet` tyVarsOfEvVar cv2
1130   = do { rewritten_frozen <- rewriteFrozen (cv1, tv1, xi1) (cv2, fl2)
1131        ; mkIRContinue "Frozen/Eq" workItem DropInert rewritten_frozen }
1132
1133 -- Fall-through case for all other situations
1134 doInteractWithInert _ workItem = noInteraction workItem
1135
1136 -------------------------
1137 -- Equational Rewriting
1138 rewriteDict  :: (CoVar, TcTyVar, Xi) -> (DictId, CtFlavor, Class, [Xi]) -> TcS CanonicalCt
1139 rewriteDict (cv,tv,xi) (dv,gw,cl,xis)
1140   = do { let cos  = substTysWith [tv] [mkCoVarCoercion cv] xis -- xis[tv] ~ xis[xi]
1141              args = substTysWith [tv] [xi] xis
1142              con  = classTyCon cl
1143              dict_co = mkTyConCoercion con cos
1144        ; dv' <- newDictVar cl args
1145        ; case gw of
1146            Wanted {}         -> setDictBind dv (EvCast dv' (mkSymCoercion dict_co))
1147            Given {}          -> setDictBind dv' (EvCast dv dict_co)
1148            Derived {}        -> return () -- Derived dicts we don't set any evidence
1149
1150        ; return (CDictCan { cc_id = dv'
1151                           , cc_flavor = gw
1152                           , cc_class = cl
1153                           , cc_tyargs = args }) }
1154
1155 rewriteIP :: (CoVar,TcTyVar,Xi) -> (EvVar,CtFlavor, IPName Name, TcType) -> TcS CanonicalCt
1156 rewriteIP (cv,tv,xi) (ipid,gw,nm,ty)
1157   = do { let ip_co = substTyWith [tv] [mkCoVarCoercion cv] ty     -- ty[tv] ~ t[xi]
1158              ty'   = substTyWith [tv] [xi] ty
1159        ; ipid' <- newIPVar nm ty'
1160        ; case gw of
1161            Wanted {}         -> setIPBind ipid  (EvCast ipid' (mkSymCoercion ip_co))
1162            Given {}          -> setIPBind ipid' (EvCast ipid ip_co)
1163            Derived {}        -> return () -- Derived ips: we don't set any evidence
1164
1165        ; return (CIPCan { cc_id = ipid'
1166                         , cc_flavor = gw
1167                         , cc_ip_nm = nm
1168                         , cc_ip_ty = ty' }) }
1169
1170 rewriteFunEq :: (CoVar,TcTyVar,Xi) -> (CoVar,CtFlavor,TyCon, [Xi], Xi) -> TcS CanonicalCt
1171 rewriteFunEq (cv1,tv,xi1) (cv2,gw, tc,args,xi2)                   -- cv2 :: F args ~ xi2
1172   = do { let arg_cos = substTysWith [tv] [mkCoVarCoercion cv1] args
1173              args'   = substTysWith [tv] [xi1] args
1174              fun_co  = mkTyConCoercion tc arg_cos                 -- fun_co :: F args ~ F args'
1175
1176              xi2'    = substTyWith [tv] [xi1] xi2
1177              xi2_co  = substTyWith [tv] [mkCoVarCoercion cv1] xi2 -- xi2_co :: xi2 ~ xi2'
1178
1179        ; cv2' <- newCoVar (mkTyConApp tc args') xi2'
1180        ; case gw of
1181            Wanted {} -> setCoBind cv2  (fun_co               `mkTransCoercion`
1182                                         mkCoVarCoercion cv2' `mkTransCoercion`
1183                                         mkSymCoercion xi2_co)
1184            Given {}  -> setCoBind cv2' (mkSymCoercion fun_co `mkTransCoercion`
1185                                         mkCoVarCoercion cv2  `mkTransCoercion`
1186                                         xi2_co)
1187            Derived {} -> return ()
1188
1189        ; return (CFunEqCan { cc_id = cv2'
1190                            , cc_flavor = gw
1191                            , cc_tyargs = args'
1192                            , cc_fun = tc
1193                            , cc_rhs = xi2' }) }
1194
1195
1196 rewriteEqRHS :: (CoVar,TcTyVar,Xi) -> (CoVar,CtFlavor,TcTyVar,Xi) -> TcS WorkList
1197 -- Use the first equality to rewrite the second, flavors already checked.
1198 -- E.g.          c1 : tv1 ~ xi1   c2 : tv2 ~ xi2
1199 -- rewrites c2 to give
1200 --               c2' : tv2 ~ xi2[xi1/tv1]
1201 -- We must do an occurs check to sure the new constraint is canonical
1202 -- So we might return an empty bag
1203 rewriteEqRHS (cv1,tv1,xi1) (cv2,gw,tv2,xi2)
1204   | Just tv2' <- tcGetTyVar_maybe xi2'
1205   , tv2 == tv2'  -- In this case xi2[xi1/tv1] = tv2, so we have tv2~tv2
1206   = do { when (isWanted gw) (setCoBind cv2 (mkSymCoercion co2'))
1207        ; return emptyWorkList }
1208   | otherwise
1209   = do { cv2' <- newCoVar (mkTyVarTy tv2) xi2'
1210        ; case gw of
1211              Wanted {} -> setCoBind cv2 $ mkCoVarCoercion cv2' `mkTransCoercion`
1212                                           mkSymCoercion co2'
1213              Given {}  -> setCoBind cv2' $ mkCoVarCoercion cv2 `mkTransCoercion`
1214                                            co2'
1215              Derived {} -> return ()
1216        ; canEqToWorkList gw cv2' (mkTyVarTy tv2) xi2' }
1217   where
1218     xi2' = substTyWith [tv1] [xi1] xi2
1219     co2' = substTyWith [tv1] [mkCoVarCoercion cv1] xi2  -- xi2 ~ xi2[xi1/tv1]
1220
1221 rewriteEqLHS :: WhichComesFromInert -> (Coercion,Xi) -> (CoVar,CtFlavor,Xi) -> TcS WorkList
1222 -- Used to ineract two equalities of the following form:
1223 -- First Equality:   co1: (XXX ~ xi1)
1224 -- Second Equality:  cv2: (XXX ~ xi2)
1225 -- Where the cv1 `canRewrite` cv2 equality
1226 -- We have an option of creating new work (xi1 ~ xi2) OR (xi2 ~ xi1),
1227 --    See Note [Efficient Orientation] for that
1228 rewriteEqLHS LeftComesFromInert (co1,xi1) (cv2,gw,xi2)
1229   = do { cv2' <- newCoVar xi2 xi1
1230        ; case gw of
1231            Wanted {} -> setCoBind cv2 $
1232                         co1 `mkTransCoercion` mkSymCoercion (mkCoVarCoercion cv2')
1233            Given {}  -> setCoBind cv2' $
1234                         mkSymCoercion (mkCoVarCoercion cv2) `mkTransCoercion` co1
1235            Derived {} -> return ()
1236        ; mkCanonical gw cv2' }
1237
1238 rewriteEqLHS RightComesFromInert (co1,xi1) (cv2,gw,xi2)
1239   = do { cv2' <- newCoVar xi1 xi2
1240        ; case gw of
1241            Wanted {} -> setCoBind cv2 $
1242                         co1 `mkTransCoercion` mkCoVarCoercion cv2'
1243            Given {}  -> setCoBind cv2' $
1244                         mkSymCoercion co1 `mkTransCoercion` mkCoVarCoercion cv2
1245            Derived {} -> return ()
1246        ; mkCanonical gw cv2' }
1247
1248 rewriteFrozen :: (CoVar,TcTyVar,Xi) -> (CoVar,CtFlavor) -> TcS WorkList
1249 rewriteFrozen (cv1, tv1, xi1) (cv2, fl2)
1250   = do { cv2' <- newCoVar ty2a' ty2b'  -- ty2a[xi1/tv1] ~ ty2b[xi1/tv1]
1251        ; case fl2 of
1252              Wanted {} -> setCoBind cv2 $ co2a'                `mkTransCoercion`
1253                                           mkCoVarCoercion cv2' `mkTransCoercion`
1254                                           mkSymCoercion co2b'
1255
1256              Given {} -> setCoBind cv2' $ mkSymCoercion co2a'  `mkTransCoercion`
1257                                           mkCoVarCoercion cv2  `mkTransCoercion`
1258                                           co2b'
1259
1260              Derived {} -> return ()
1261
1262       ; return (workListFromNonEq $ CFrozenErr { cc_id = cv2', cc_flavor = fl2 }) }
1263   where
1264     (ty2a, ty2b) = coVarKind cv2          -- cv2 : ty2a ~ ty2b
1265     ty2a' = substTyWith [tv1] [xi1] ty2a
1266     ty2b' = substTyWith [tv1] [xi1] ty2b
1267
1268     co2a' = substTyWith [tv1] [mkCoVarCoercion cv1] ty2a  -- ty2a ~ ty2a[xi1/tv1]
1269     co2b' = substTyWith [tv1] [mkCoVarCoercion cv1] ty2b  -- ty2b ~ ty2b[xi1/tv1]
1270
1271 solveOneFromTheOther :: String -> (EvTerm, CtFlavor) -> CanonicalCt -> TcS InteractResult
1272 -- First argument inert, second argument work-item. They both represent
1273 -- wanted/given/derived evidence for the *same* predicate so
1274 -- we can discharge one directly from the other.
1275 --
1276 -- Precondition: value evidence only (implicit parameters, classes)
1277 --               not coercion
1278 solveOneFromTheOther info (ev_term,ifl) workItem
1279   | isDerived wfl
1280   = mkIRStopK ("Solved[DW] " ++ info) emptyWorkList
1281
1282   | isDerived ifl -- The inert item is Derived, we can just throw it away,
1283                   -- The workItem is inert wrt earlier inert-set items,
1284                   -- so it's safe to continue on from this point
1285   = mkIRContinue ("Solved[DI] " ++ info) workItem DropInert emptyWorkList
1286
1287   | otherwise
1288   = ASSERT( ifl `canSolve` wfl )
1289       -- Because of Note [The Solver Invariant], plus Derived dealt with
1290     do { when (isWanted wfl) $ setEvBind wid ev_term
1291            -- Overwrite the binding, if one exists
1292            -- If both are Given, we already have evidence; no need to duplicate
1293        ; mkIRStopK ("Solved " ++ info) emptyWorkList }
1294   where
1295      wfl = cc_flavor workItem
1296      wid = cc_id workItem
1297 \end{code}
1298
1299 Note [Superclasses and recursive dictionaries]
1300 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1301     Overlaps with Note [SUPERCLASS-LOOP 1]
1302                   Note [SUPERCLASS-LOOP 2]
1303                   Note [Recursive instances and superclases]
1304     ToDo: check overlap and delete redundant stuff
1305
1306 Right before adding a given into the inert set, we must
1307 produce some more work, that will bring the superclasses
1308 of the given into scope. The superclass constraints go into
1309 our worklist.
1310
1311 When we simplify a wanted constraint, if we first see a matching
1312 instance, we may produce new wanted work. To (1) avoid doing this work
1313 twice in the future and (2) to handle recursive dictionaries we may ``cache''
1314 this item as given into our inert set WITHOUT adding its superclass constraints,
1315 otherwise we'd be in danger of creating a loop [In fact this was the exact reason
1316 for doing the isGoodRecEv check in an older version of the type checker].
1317
1318 But now we have added partially solved constraints to the worklist which may
1319 interact with other wanteds. Consider the example:
1320
1321 Example 1:
1322
1323     class Eq b => Foo a b        --- 0-th selector
1324     instance Eq a => Foo [a] a   --- fooDFun
1325
1326 and wanted (Foo [t] t). We are first going to see that the instance matches
1327 and create an inert set that includes the solved (Foo [t] t) but not its superclasses:
1328        d1 :_g Foo [t] t                 d1 := EvDFunApp fooDFun d3
1329 Our work list is going to contain a new *wanted* goal
1330        d3 :_w Eq t
1331
1332 Ok, so how do we get recursive dictionaries, at all:
1333
1334 Example 2:
1335
1336     data D r = ZeroD | SuccD (r (D r));
1337
1338     instance (Eq (r (D r))) => Eq (D r) where
1339         ZeroD     == ZeroD     = True
1340         (SuccD a) == (SuccD b) = a == b
1341         _         == _         = False;
1342
1343     equalDC :: D [] -> D [] -> Bool;
1344     equalDC = (==);
1345
1346 We need to prove (Eq (D [])). Here's how we go:
1347
1348         d1 :_w Eq (D [])
1349
1350 by instance decl, holds if
1351         d2 :_w Eq [D []]
1352         where   d1 = dfEqD d2
1353
1354 *BUT* we have an inert set which gives us (no superclasses):
1355         d1 :_g Eq (D [])
1356 By the instance declaration of Eq we can show the 'd2' goal if
1357         d3 :_w Eq (D [])
1358         where   d2 = dfEqList d3
1359                 d1 = dfEqD d2
1360 Now, however this wanted can interact with our inert d1 to set:
1361         d3 := d1
1362 and solve the goal. Why was this interaction OK? Because, if we chase the
1363 evidence of d1 ~~> dfEqD d2 ~~-> dfEqList d3, so by setting d3 := d1 we
1364 are really setting
1365         d3 := dfEqD2 (dfEqList d3)
1366 which is FINE because the use of d3 is protected by the instance function
1367 applications.
1368
1369 So, our strategy is to try to put solved wanted dictionaries into the
1370 inert set along with their superclasses (when this is meaningful,
1371 i.e. when new wanted goals are generated) but solve a wanted dictionary
1372 from a given only in the case where the evidence variable of the
1373 wanted is mentioned in the evidence of the given (recursively through
1374 the evidence binds) in a protected way: more instance function applications
1375 than superclass selectors.
1376
1377 Here are some more examples from GHC's previous type checker
1378
1379
1380 Example 3:
1381 This code arises in the context of "Scrap Your Boilerplate with Class"
1382
1383     class Sat a
1384     class Data ctx a
1385     instance  Sat (ctx Char)             => Data ctx Char       -- dfunData1
1386     instance (Sat (ctx [a]), Data ctx a) => Data ctx [a]        -- dfunData2
1387
1388     class Data Maybe a => Foo a
1389
1390     instance Foo t => Sat (Maybe t)                             -- dfunSat
1391
1392     instance Data Maybe a => Foo a                              -- dfunFoo1
1393     instance Foo a        => Foo [a]                            -- dfunFoo2
1394     instance                 Foo [Char]                         -- dfunFoo3
1395
1396 Consider generating the superclasses of the instance declaration
1397          instance Foo a => Foo [a]
1398
1399 So our problem is this
1400     d0 :_g Foo t
1401     d1 :_w Data Maybe [t]
1402
1403 We may add the given in the inert set, along with its superclasses
1404 [assuming we don't fail because there is a matching instance, see
1405  tryTopReact, given case ]
1406   Inert:
1407     d0 :_g Foo t
1408   WorkList
1409     d01 :_g Data Maybe t  -- d2 := EvDictSuperClass d0 0
1410     d1 :_w Data Maybe [t]
1411 Then d2 can readily enter the inert, and we also do solving of the wanted
1412   Inert:
1413     d0 :_g Foo t
1414     d1 :_s Data Maybe [t]           d1 := dfunData2 d2 d3
1415   WorkList
1416     d2 :_w Sat (Maybe [t])
1417     d3 :_w Data Maybe t
1418     d01 :_g Data Maybe t
1419 Now, we may simplify d2 more:
1420   Inert:
1421       d0 :_g Foo t
1422       d1 :_s Data Maybe [t]           d1 := dfunData2 d2 d3
1423       d1 :_g Data Maybe [t]
1424       d2 :_g Sat (Maybe [t])          d2 := dfunSat d4
1425   WorkList:
1426       d3 :_w Data Maybe t
1427       d4 :_w Foo [t]
1428       d01 :_g Data Maybe t
1429
1430 Now, we can just solve d3.
1431   Inert
1432       d0 :_g Foo t
1433       d1 :_s Data Maybe [t]           d1 := dfunData2 d2 d3
1434       d2 :_g Sat (Maybe [t])          d2 := dfunSat d4
1435   WorkList
1436       d4 :_w Foo [t]
1437       d01 :_g Data Maybe t
1438 And now we can simplify d4 again, but since it has superclasses we *add* them to the worklist:
1439   Inert
1440       d0 :_g Foo t
1441       d1 :_s Data Maybe [t]           d1 := dfunData2 d2 d3
1442       d2 :_g Sat (Maybe [t])          d2 := dfunSat d4
1443       d4 :_g Foo [t]                  d4 := dfunFoo2 d5
1444   WorkList:
1445       d5 :_w Foo t
1446       d6 :_g Data Maybe [t]           d6 := EvDictSuperClass d4 0
1447       d01 :_g Data Maybe t
1448 Now, d5 can be solved! (and its superclass enter scope)
1449   Inert
1450       d0 :_g Foo t
1451       d1 :_s Data Maybe [t]           d1 := dfunData2 d2 d3
1452       d2 :_g Sat (Maybe [t])          d2 := dfunSat d4
1453       d4 :_g Foo [t]                  d4 := dfunFoo2 d5
1454       d5 :_g Foo t                    d5 := dfunFoo1 d7
1455   WorkList:
1456       d7 :_w Data Maybe t
1457       d6 :_g Data Maybe [t]
1458       d8 :_g Data Maybe t            d8 := EvDictSuperClass d5 0
1459       d01 :_g Data Maybe t
1460
1461 Now, two problems:
1462    [1] Suppose we pick d8 and we react him with d01. Which of the two givens should
1463        we keep? Well, we *MUST NOT* drop d01 because d8 contains recursive evidence
1464        that must not be used (look at case interactInert where both inert and workitem
1465        are givens). So we have several options:
1466        - Drop the workitem always (this will drop d8)
1467               This feels very unsafe -- what if the work item was the "good" one
1468               that should be used later to solve another wanted?
1469        - Don't drop anyone: the inert set may contain multiple givens!
1470               [This is currently implemented]
1471
1472 The "don't drop anyone" seems the most safe thing to do, so now we come to problem 2:
1473   [2] We have added both d6 and d01 in the inert set, and we are interacting our wanted
1474       d7. Now the [isRecDictEv] function in the ineration solver
1475       [case inert-given workitem-wanted] will prevent us from interacting d7 := d8
1476       precisely because chasing the evidence of d8 leads us to an unguarded use of d7.
1477
1478       So, no interaction happens there. Then we meet d01 and there is no recursion
1479       problem there [isRectDictEv] gives us the OK to interact and we do solve d7 := d01!
1480
1481 Note [SUPERCLASS-LOOP 1]
1482 ~~~~~~~~~~~~~~~~~~~~~~~~
1483 We have to be very, very careful when generating superclasses, lest we
1484 accidentally build a loop. Here's an example:
1485
1486   class S a
1487
1488   class S a => C a where { opc :: a -> a }
1489   class S b => D b where { opd :: b -> b }
1490
1491   instance C Int where
1492      opc = opd
1493
1494   instance D Int where
1495      opd = opc
1496
1497 From (instance C Int) we get the constraint set {ds1:S Int, dd:D Int}
1498 Simplifying, we may well get:
1499         $dfCInt = :C ds1 (opd dd)
1500         dd  = $dfDInt
1501         ds1 = $p1 dd
1502 Notice that we spot that we can extract ds1 from dd.
1503
1504 Alas!  Alack! We can do the same for (instance D Int):
1505
1506         $dfDInt = :D ds2 (opc dc)
1507         dc  = $dfCInt
1508         ds2 = $p1 dc
1509
1510 And now we've defined the superclass in terms of itself.
1511 Two more nasty cases are in
1512         tcrun021
1513         tcrun033
1514
1515 Solution:
1516   - Satisfy the superclass context *all by itself*
1517     (tcSimplifySuperClasses)
1518   - And do so completely; i.e. no left-over constraints
1519     to mix with the constraints arising from method declarations
1520
1521
1522 Note [SUPERCLASS-LOOP 2]
1523 ~~~~~~~~~~~~~~~~~~~~~~~~
1524 We need to be careful when adding "the constaint we are trying to prove".
1525 Suppose we are *given* d1:Ord a, and want to deduce (d2:C [a]) where
1526
1527         class Ord a => C a where
1528         instance Ord [a] => C [a] where ...
1529
1530 Then we'll use the instance decl to deduce C [a] from Ord [a], and then add the
1531 superclasses of C [a] to avails.  But we must not overwrite the binding
1532 for Ord [a] (which is obtained from Ord a) with a superclass selection or we'll just
1533 build a loop!
1534
1535 Here's another variant, immortalised in tcrun020
1536         class Monad m => C1 m
1537         class C1 m => C2 m x
1538         instance C2 Maybe Bool
1539 For the instance decl we need to build (C1 Maybe), and it's no good if
1540 we run around and add (C2 Maybe Bool) and its superclasses to the avails
1541 before we search for C1 Maybe.
1542
1543 Here's another example
1544         class Eq b => Foo a b
1545         instance Eq a => Foo [a] a
1546 If we are reducing
1547         (Foo [t] t)
1548
1549 we'll first deduce that it holds (via the instance decl).  We must not
1550 then overwrite the Eq t constraint with a superclass selection!
1551
1552 At first I had a gross hack, whereby I simply did not add superclass constraints
1553 in addWanted, though I did for addGiven and addIrred.  This was sub-optimal,
1554 becuase it lost legitimate superclass sharing, and it still didn't do the job:
1555 I found a very obscure program (now tcrun021) in which improvement meant the
1556 simplifier got two bites a the cherry... so something seemed to be an Stop
1557 first time, but reducible next time.
1558
1559 Now we implement the Right Solution, which is to check for loops directly
1560 when adding superclasses.  It's a bit like the occurs check in unification.
1561
1562 Note [Recursive instances and superclases]
1563 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1564 Consider this code, which arises in the context of "Scrap Your
1565 Boilerplate with Class".
1566
1567     class Sat a
1568     class Data ctx a
1569     instance  Sat (ctx Char)             => Data ctx Char
1570     instance (Sat (ctx [a]), Data ctx a) => Data ctx [a]
1571
1572     class Data Maybe a => Foo a
1573
1574     instance Foo t => Sat (Maybe t)
1575
1576     instance Data Maybe a => Foo a
1577     instance Foo a        => Foo [a]
1578     instance                 Foo [Char]
1579
1580 In the instance for Foo [a], when generating evidence for the superclasses
1581 (ie in tcSimplifySuperClasses) we need a superclass (Data Maybe [a]).
1582 Using the instance for Data, we therefore need
1583         (Sat (Maybe [a], Data Maybe a)
1584 But we are given (Foo a), and hence its superclass (Data Maybe a).
1585 So that leaves (Sat (Maybe [a])).  Using the instance for Sat means
1586 we need (Foo [a]).  And that is the very dictionary we are bulding
1587 an instance for!  So we must put that in the "givens".  So in this
1588 case we have
1589         Given:  Foo a, Foo [a]
1590         Wanted: Data Maybe [a]
1591
1592 BUT we must *not not not* put the *superclasses* of (Foo [a]) in
1593 the givens, which is what 'addGiven' would normally do. Why? Because
1594 (Data Maybe [a]) is the superclass, so we'd "satisfy" the wanted
1595 by selecting a superclass from Foo [a], which simply makes a loop.
1596
1597 On the other hand we *must* put the superclasses of (Foo a) in
1598 the givens, as you can see from the derivation described above.
1599
1600 Conclusion: in the very special case of tcSimplifySuperClasses
1601 we have one 'given' (namely the "this" dictionary) whose superclasses
1602 must not be added to 'givens' by addGiven.
1603
1604 There is a complication though.  Suppose there are equalities
1605       instance (Eq a, a~b) => Num (a,b)
1606 Then we normalise the 'givens' wrt the equalities, so the original
1607 given "this" dictionary is cast to one of a different type.  So it's a
1608 bit trickier than before to identify the "special" dictionary whose
1609 superclasses must not be added. See test
1610    indexed-types/should_run/EqInInstance
1611
1612 We need a persistent property of the dictionary to record this
1613 special-ness.  Current I'm using the InstLocOrigin (a bit of a hack,
1614 but cool), which is maintained by dictionary normalisation.
1615 Specifically, the InstLocOrigin is
1616              NoScOrigin
1617 then the no-superclass thing kicks in.  WATCH OUT if you fiddle
1618 with InstLocOrigin!
1619
1620 Note [MATCHING-SYNONYMS]
1621 ~~~~~~~~~~~~~~~~~~~~~~~~
1622 When trying to match a dictionary (D tau) to a top-level instance, or a
1623 type family equation (F taus_1 ~ tau_2) to a top-level family instance,
1624 we do *not* need to expand type synonyms because the matcher will do that for us.
1625
1626
1627 Note [RHS-FAMILY-SYNONYMS]
1628 ~~~~~~~~~~~~~~~~~~~~~~~~~~
1629 The RHS of a family instance is represented as yet another constructor which is
1630 like a type synonym for the real RHS the programmer declared. Eg:
1631     type instance F (a,a) = [a]
1632 Becomes:
1633     :R32 a = [a]      -- internal type synonym introduced
1634     F (a,a) ~ :R32 a  -- instance
1635
1636 When we react a family instance with a type family equation in the work list
1637 we keep the synonym-using RHS without expansion.
1638
1639
1640 *********************************************************************************
1641 *                                                                               *
1642                        The top-reaction Stage
1643 *                                                                               *
1644 *********************************************************************************
1645
1646 \begin{code}
1647 -- If a work item has any form of interaction with top-level we get this
1648 data TopInteractResult
1649   = NoTopInt         -- No top-level interaction
1650                      -- Equivalent to (SomeTopInt emptyWorkList (ContinueWith work_item))
1651   | SomeTopInt
1652       { tir_new_work  :: WorkList       -- Sub-goals or new work (could be given,
1653                                         --                        for superclasses)
1654       , tir_new_inert :: StopOrContinue -- The input work item, ready to become *inert* now:
1655       }                                 -- NB: in ``given'' (solved) form if the
1656                                         -- original was wanted or given and instance match
1657                                         -- was found, but may also be in wanted form if we
1658                                         -- only reacted with functional dependencies
1659                                         -- arising from top-level instances.
1660
1661 topReactionsStage :: SimplifierStage
1662 topReactionsStage depth workItem inerts
1663   = do { tir <- tryTopReact workItem
1664        ; case tir of
1665            NoTopInt ->
1666                return $ SR { sr_inerts   = inerts
1667                            , sr_new_work = emptyWorkList
1668                            , sr_stop     = ContinueWith workItem }
1669            SomeTopInt tir_new_work tir_new_inert ->
1670                do { bumpStepCountTcS
1671                   ; traceFireTcS depth (ptext (sLit "Top react")
1672                        <+> vcat [ ptext (sLit "Work =") <+> ppr workItem
1673                                 , ptext (sLit "New =") <+> ppr tir_new_work ])
1674                   ; return $ SR { sr_inerts   = inerts
1675                                 , sr_new_work = tir_new_work
1676                                 , sr_stop     = tir_new_inert
1677                                 } }
1678        }
1679
1680 tryTopReact :: WorkItem -> TcS TopInteractResult
1681 tryTopReact workitem
1682   = do {  -- A flag controls the amount of interaction allowed
1683           -- See Note [Simplifying RULE lhs constraints]
1684          ctxt <- getTcSContext
1685        ; if allowedTopReaction (simplEqsOnly ctxt) workitem
1686          then do { traceTcS "tryTopReact / calling doTopReact" (ppr workitem)
1687                  ; doTopReact workitem }
1688          else return NoTopInt
1689        }
1690
1691 allowedTopReaction :: Bool -> WorkItem -> Bool
1692 allowedTopReaction eqs_only (CDictCan {}) = not eqs_only
1693 allowedTopReaction _        _             = True
1694
1695 doTopReact :: WorkItem -> TcS TopInteractResult
1696 -- The work item does not react with the inert set, so try interaction with top-level instances
1697 -- NB: The place to add superclasses in *not* in doTopReact stage. Instead superclasses are
1698 --     added in the worklist as part of the canonicalisation process.
1699 -- See Note [Adding superclasses] in TcCanonical.
1700
1701 -- Given dictionary
1702 -- See Note [Given constraint that matches an instance declaration]
1703 doTopReact (CDictCan { cc_flavor = Given {} })
1704   = return NoTopInt -- NB: Superclasses already added since it's canonical
1705
1706 -- Derived dictionary: just look for functional dependencies
1707 doTopReact workItem@(CDictCan { cc_flavor = fl@(Derived loc)
1708                               , cc_class = cls, cc_tyargs = xis })
1709   = do { instEnvs <- getInstEnvs
1710        ; let fd_eqns = improveFromInstEnv instEnvs
1711                                                 (ClassP cls xis, pprArisingAt loc)
1712        ; m <- rewriteWithFunDeps fd_eqns xis fl
1713        ; case m of
1714            Nothing -> return NoTopInt
1715            Just (xis',_,fd_work) ->
1716                let workItem' = workItem { cc_tyargs = xis' }
1717                    -- Deriveds are not supposed to have identity (cc_id is unused!)
1718                in return $ SomeTopInt { tir_new_work  = fd_work
1719                                       , tir_new_inert = ContinueWith workItem' } }
1720
1721 -- Wanted dictionary
1722 doTopReact workItem@(CDictCan { cc_id = dv, cc_flavor = fl@(Wanted loc)
1723                               , cc_class = cls, cc_tyargs = xis })
1724   = do { -- See Note [MATCHING-SYNONYMS]
1725        ; lkp_inst_res <- matchClassInst cls xis loc
1726        ; case lkp_inst_res of
1727            NoInstance ->
1728              do { traceTcS "doTopReact/ no class instance for" (ppr dv)
1729
1730                 ; instEnvs <- getInstEnvs
1731                 ; let fd_eqns = improveFromInstEnv instEnvs
1732                                                          (ClassP cls xis, pprArisingAt loc)
1733                 ; m <- rewriteWithFunDeps fd_eqns xis fl
1734                 ; case m of
1735                     Nothing -> return NoTopInt
1736                     Just (xis',cos,fd_work) ->
1737                         do { let dict_co = mkTyConCoercion (classTyCon cls) cos
1738                            ; dv'<- newDictVar cls xis'
1739                            ; setDictBind dv (EvCast dv' dict_co)
1740                            ; let workItem' = CDictCan { cc_id = dv', cc_flavor = fl,
1741                                                         cc_class = cls, cc_tyargs = xis' }
1742                            ; return $
1743                              SomeTopInt { tir_new_work  = workListFromNonEq workItem' `unionWorkList` fd_work
1744                                         , tir_new_inert = Stop } } }
1745
1746            GenInst wtvs ev_term -- Solved
1747                    -- No need to do fundeps stuff here; the instance
1748                    -- matches already so we won't get any more info
1749                    -- from functional dependencies
1750              | null wtvs
1751              -> do { traceTcS "doTopReact/ found nullary class instance for" (ppr dv)
1752                    ; setDictBind dv ev_term
1753                     -- Solved in one step and no new wanted work produced.
1754                     -- i.e we directly matched a top-level instance
1755                     -- No point in caching this in 'inert'; hence Stop
1756                    ; return $ SomeTopInt { tir_new_work  = emptyWorkList
1757                                          , tir_new_inert = Stop } }
1758
1759              | otherwise
1760              -> do { traceTcS "doTopReact/ found nullary class instance for" (ppr dv)
1761                    ; setDictBind dv ev_term
1762                         -- Solved and new wanted work produced, you may cache the
1763                         -- (tentatively solved) dictionary as Given! (used to be: Derived)
1764                    ; let solved   = workItem { cc_flavor = given_fl }
1765                          given_fl = Given (setCtLocOrigin loc UnkSkol)
1766                    ; inst_work <- canWanteds wtvs
1767                    ; return $ SomeTopInt { tir_new_work  = inst_work
1768                                          , tir_new_inert = ContinueWith solved } }
1769        }
1770
1771 -- Type functions
1772 doTopReact (CFunEqCan { cc_id = cv, cc_flavor = fl
1773                       , cc_fun = tc, cc_tyargs = args, cc_rhs = xi })
1774   = ASSERT (isSynFamilyTyCon tc)   -- No associated data families have reached that far
1775     do { match_res <- matchFam tc args -- See Note [MATCHING-SYNONYMS]
1776        ; case match_res of
1777            MatchInstNo
1778              -> return NoTopInt
1779            MatchInstSingle (rep_tc, rep_tys)
1780              -> do { let Just coe_tc = tyConFamilyCoercion_maybe rep_tc
1781                          Just rhs_ty = tcView (mkTyConApp rep_tc rep_tys)
1782                             -- Eagerly expand away the type synonym on the
1783                             -- RHS of a type function, so that it never
1784                             -- appears in an error message
1785                             -- See Note [Type synonym families] in TyCon
1786                          coe = mkTyConApp coe_tc rep_tys
1787                    ; cv' <- case fl of
1788                               Wanted {} -> do { cv' <- newCoVar rhs_ty xi
1789                                               ; setCoBind cv $
1790                                                     coe `mkTransCoercion`
1791                                                       mkCoVarCoercion cv'
1792                                               ; return cv' }
1793                               Given {}   -> newGivenCoVar xi rhs_ty $
1794                                             mkSymCoercion (mkCoVarCoercion cv) `mkTransCoercion` coe
1795                               Derived {} -> newDerivedId (EqPred xi rhs_ty)
1796                    ; can_cts <- mkCanonical fl cv'
1797                    ; return $ SomeTopInt can_cts Stop }
1798            _
1799              -> panicTcS $ text "TcSMonad.matchFam returned multiple instances!"
1800        }
1801
1802
1803 -- Any other work item does not react with any top-level equations
1804 doTopReact _workItem = return NoTopInt
1805 \end{code}
1806
1807
1808 Note [FunDep and implicit parameter reactions]
1809 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1810 Currently, our story of interacting two dictionaries (or a dictionary
1811 and top-level instances) for functional dependencies, and implicit
1812 paramters, is that we simply produce new wanted equalities.  So for example
1813
1814         class D a b | a -> b where ...
1815     Inert:
1816         d1 :g D Int Bool
1817     WorkItem:
1818         d2 :w D Int alpha
1819
1820     We generate the extra work item
1821         cv :w alpha ~ Bool
1822     where 'cv' is currently unused.  However, this new item reacts with d2,
1823     discharging it in favour of a new constraint d2' thus:
1824         d2' :w D Int Bool
1825         d2 := d2' |> D Int cv
1826     Now d2' can be discharged from d1
1827
1828 We could be more aggressive and try to *immediately* solve the dictionary
1829 using those extra equalities. With the same inert set and work item we
1830 might dischard d2 directly:
1831
1832         cv :w alpha ~ Bool
1833         d2 := d1 |> D Int cv
1834
1835 But in general it's a bit painful to figure out the necessary coercion,
1836 so we just take the first approach. Here is a better example. Consider:
1837     class C a b c | a -> b
1838 And:
1839      [Given]  d1 : C T Int Char
1840      [Wanted] d2 : C T beta Int
1841 In this case, it's *not even possible* to solve the wanted immediately.
1842 So we should simply output the functional dependency and add this guy
1843 [but NOT its superclasses] back in the worklist. Even worse:
1844      [Given] d1 : C T Int beta
1845      [Wanted] d2: C T beta Int
1846 Then it is solvable, but its very hard to detect this on the spot.
1847
1848 It's exactly the same with implicit parameters, except that the
1849 "aggressive" approach would be much easier to implement.
1850
1851 Note [When improvement happens]
1852 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1853 We fire an improvement rule when
1854
1855   * Two constraints match (modulo the fundep)
1856       e.g. C t1 t2, C t1 t3    where C a b | a->b
1857     The two match because the first arg is identical
1858
1859   * At least one is not Given.  If they are both given, we don't fire
1860     the reaction because we have no way of constructing evidence for a
1861     new equality nor does it seem right to create a new wanted goal
1862     (because the goal will most likely contain untouchables, which
1863     can't be solved anyway)!
1864
1865 Note that we *do* fire the improvement if one is Given and one is Derived.
1866 The latter can be a superclass of a wanted goal. Example (tcfail138)
1867     class L a b | a -> b
1868     class (G a, L a b) => C a b
1869
1870     instance C a b' => G (Maybe a)
1871     instance C a b  => C (Maybe a) a
1872     instance L (Maybe a) a
1873
1874 When solving the superclasses of the (C (Maybe a) a) instance, we get
1875   Given:  C a b  ... and hance by superclasses, (G a, L a b)
1876   Wanted: G (Maybe a)
1877 Use the instance decl to get
1878   Wanted: C a b'
1879 The (C a b') is inert, so we generate its Derived superclasses (L a b'),
1880 and now we need improvement between that derived superclass an the Given (L a b)
1881
1882 Note [Overriding implicit parameters]
1883 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1884 Consider
1885    f :: (?x::a) -> Bool -> a
1886
1887    g v = let ?x::Int = 3
1888          in (f v, let ?x::Bool = True in f v)
1889
1890 This should probably be well typed, with
1891    g :: Bool -> (Int, Bool)
1892
1893 So the inner binding for ?x::Bool *overrides* the outer one.
1894 Hence a work-item Given overrides an inert-item Given.
1895
1896 Note [Given constraint that matches an instance declaration]
1897 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1898 What should we do when we discover that one (or more) top-level
1899 instances match a given (or solved) class constraint? We have
1900 two possibilities:
1901
1902   1. Reject the program. The reason is that there may not be a unique
1903      best strategy for the solver. Example, from the OutsideIn(X) paper:
1904        instance P x => Q [x]
1905        instance (x ~ y) => R [x] y
1906
1907        wob :: forall a b. (Q [b], R b a) => a -> Int
1908
1909        g :: forall a. Q [a] => [a] -> Int
1910        g x = wob x
1911
1912        will generate the impliation constraint:
1913             Q [a] => (Q [beta], R beta [a])
1914        If we react (Q [beta]) with its top-level axiom, we end up with a
1915        (P beta), which we have no way of discharging. On the other hand,
1916        if we react R beta [a] with the top-level we get  (beta ~ a), which
1917        is solvable and can help us rewrite (Q [beta]) to (Q [a]) which is
1918        now solvable by the given Q [a].
1919
1920      However, this option is restrictive, for instance [Example 3] from
1921      Note [Recursive dictionaries] will fail to work.
1922
1923   2. Ignore the problem, hoping that the situations where there exist indeed
1924      such multiple strategies are rare: Indeed the cause of the previous
1925      problem is that (R [x] y) yields the new work (x ~ y) which can be
1926      *spontaneously* solved, not using the givens.
1927
1928 We are choosing option 2 below but we might consider having a flag as well.
1929
1930
1931 Note [New Wanted Superclass Work]
1932 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1933 Even in the case of wanted constraints, we may add some superclasses
1934 as new given work. The reason is:
1935
1936         To allow FD-like improvement for type families. Assume that
1937         we have a class
1938              class C a b | a -> b
1939         and we have to solve the implication constraint:
1940              C a b => C a beta
1941         Then, FD improvement can help us to produce a new wanted (beta ~ b)
1942
1943         We want to have the same effect with the type family encoding of
1944         functional dependencies. Namely, consider:
1945              class (F a ~ b) => C a b
1946         Now suppose that we have:
1947                given: C a b
1948                wanted: C a beta
1949         By interacting the given we will get given (F a ~ b) which is not
1950         enough by itself to make us discharge (C a beta). However, we
1951         may create a new derived equality from the super-class of the
1952         wanted constraint (C a beta), namely derived (F a ~ beta).
1953         Now we may interact this with given (F a ~ b) to get:
1954                   derived :  beta ~ b
1955         But 'beta' is a touchable unification variable, and hence OK to
1956         unify it with 'b', replacing the derived evidence with the identity.
1957
1958         This requires trySpontaneousSolve to solve *derived*
1959         equalities that have a touchable in their RHS, *in addition*
1960         to solving wanted equalities.
1961
1962 We also need to somehow use the superclasses to quantify over a minimal,
1963 constraint see note [Minimize by Superclasses] in TcSimplify.
1964
1965
1966 Finally, here is another example where this is useful.
1967
1968 Example 1:
1969 ----------
1970    class (F a ~ b) => C a b
1971 And we are given the wanteds:
1972       w1 : C a b
1973       w2 : C a c
1974       w3 : b ~ c
1975 We surely do *not* want to quantify over (b ~ c), since if someone provides
1976 dictionaries for (C a b) and (C a c), these dictionaries can provide a proof
1977 of (b ~ c), hence no extra evidence is necessary. Here is what will happen:
1978
1979      Step 1: We will get new *given* superclass work,
1980              provisionally to our solving of w1 and w2
1981
1982                g1: F a ~ b, g2 : F a ~ c,
1983                w1 : C a b, w2 : C a c, w3 : b ~ c
1984
1985              The evidence for g1 and g2 is a superclass evidence term:
1986
1987                g1 := sc w1, g2 := sc w2
1988
1989      Step 2: The givens will solve the wanted w3, so that
1990                w3 := sym (sc w1) ; sc w2
1991
1992      Step 3: Now, one may naively assume that then w2 can be solve from w1
1993              after rewriting with the (now solved equality) (b ~ c).
1994
1995              But this rewriting is ruled out by the isGoodRectDict!
1996
1997 Conclusion, we will (correctly) end up with the unsolved goals
1998     (C a b, C a c)
1999
2000 NB: The desugarer needs be more clever to deal with equalities
2001     that participate in recursive dictionary bindings.
2002
2003 \begin{code}
2004 data LookupInstResult
2005   = NoInstance
2006   | GenInst [WantedEvVar] EvTerm
2007
2008 matchClassInst :: Class -> [Type] -> WantedLoc -> TcS LookupInstResult
2009 matchClassInst clas tys loc
2010    = do { let pred = mkClassPred clas tys
2011         ; mb_result <- matchClass clas tys
2012         ; case mb_result of
2013             MatchInstNo   -> return NoInstance
2014             MatchInstMany -> return NoInstance -- defer any reactions of a multitude until
2015                                                -- we learn more about the reagent
2016             MatchInstSingle (dfun_id, mb_inst_tys) ->
2017               do { checkWellStagedDFun pred dfun_id loc
2018
2019         -- It's possible that not all the tyvars are in
2020         -- the substitution, tenv. For example:
2021         --      instance C X a => D X where ...
2022         -- (presumably there's a functional dependency in class C)
2023         -- Hence mb_inst_tys :: Either TyVar TcType
2024
2025                  ; tys <- instDFunTypes mb_inst_tys
2026                  ; let (theta, _) = tcSplitPhiTy (applyTys (idType dfun_id) tys)
2027                  ; if null theta then
2028                        return (GenInst [] (EvDFunApp dfun_id tys []))
2029                    else do
2030                      { ev_vars <- instDFunConstraints theta
2031                      ; let wevs = [EvVarX w loc | w <- ev_vars]
2032                      ; return $ GenInst wevs (EvDFunApp dfun_id tys ev_vars) }
2033                  }
2034         }
2035 \end{code}