compiler/typecheck/TcInteract.lhs

   1 \begin{code}
   2 module TcInteract (
   3      solveInteract, solveInteractGiven, solveInteractWanted,
   4      AtomicInert, tyVarsOfInert,
   5      InertSet, emptyInert, updInertSet, extractUnsolved, solveOne,
   6   ) where
   7
   8 #include "HsVersions.h"
   9
  10
  11 import BasicTypes
  12 import TcCanonical
  13 import VarSet
  14 import Type
  15
  16 import Id
  17 import Var
  18
  19 import TcType
  20 import HsBinds
  21
  22 import Inst( tyVarsOfEvVar )
  23 import Class
  24 import TyCon
  25 import Name
  26
  27 import FunDeps
  28
  29 import Coercion
  30 import Outputable
  31
  32 import TcRnTypes
  33 import TcErrors
  34 import TcSMonad
  35 import Bag
  36 import qualified Data.Map as Map
  37
  38 import Control.Monad( when )
  39
  40 import FastString ( sLit )
  41 import DynFlags
  42 \end{code}
  43
  44 Note [InertSet invariants]
  45 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
  46 An InertSet is a bag of canonical constraints, with the following invariants:
  47
  48   1 No two constraints react with each other.
  49
  50     A tricky case is when there exists a given (solved) dictionary
  51     constraint and a wanted identical constraint in the inert set, but do
  52     not react because reaction would create loopy dictionary evidence for
  53     the wanted. See note [Recursive dictionaries]
  54
  55   2 Given equalities form an idempotent substitution [none of the
  56     given LHS's occur in any of the given RHS's or reactant parts]
  57
  58   3 Wanted equalities also form an idempotent substitution
  59
  60   4 The entire set of equalities is acyclic.
  61
  62   5 Wanted dictionaries are inert with the top-level axiom set
  63
  64   6 Equalities of the form tv1 ~ tv2 always have a touchable variable
  65     on the left (if possible).
  66
  67   7 No wanted constraints tv1 ~ tv2 with tv1 touchable. Such constraints
  68     will be marked as solved right before being pushed into the inert set.
  69     See note [Touchables and givens].
  70
  71   8 No Given constraint mentions a touchable unification variable,
  72     except if the
  73
  74 Note that 6 and 7 are /not/ enforced by canonicalization but rather by
  75 insertion in the inert list, ie by TcInteract.
  76
  77 During the process of solving, the inert set will contain some
  78 previously given constraints, some wanted constraints, and some given
  79 constraints which have arisen from solving wanted constraints. For
  80 now we do not distinguish between given and solved constraints.
  81
  82 Note that we must switch wanted inert items to given when going under an
  83 implication constraint (when in top-level inference mode).
  84
  85 \begin{code}
  86
  87 data CCanMap a = CCanMap { cts_given   :: Map.Map a CanonicalCts
  88                                           -- Invariant: all Given
  89                          , cts_derived :: Map.Map a CanonicalCts
  90                                           -- Invariant: all Derived
  91                          , cts_wanted  :: Map.Map a CanonicalCts }
  92                                           -- Invariant: all Wanted
  93
  94 cCanMapToBag :: Ord a => CCanMap a -> CanonicalCts
  95 cCanMapToBag cmap = Map.fold unionBags rest_wder (cts_given cmap)
  96   where rest_wder = Map.fold unionBags rest_der  (cts_wanted cmap)
  97         rest_der  = Map.fold unionBags emptyCCan (cts_derived cmap)
  98
  99 emptyCCanMap :: CCanMap a
 100 emptyCCanMap = CCanMap { cts_given = Map.empty
 101                        , cts_derived = Map.empty, cts_wanted = Map.empty }
 102
 103 updCCanMap:: Ord a => (a,CanonicalCt) -> CCanMap a -> CCanMap a
 104 updCCanMap (a,ct) cmap
 105   = case cc_flavor ct of
 106       Wanted {}
 107           -> cmap { cts_wanted = Map.insertWith unionBags a this_ct (cts_wanted cmap) }
 108       Given {}
 109           -> cmap { cts_given = Map.insertWith unionBags a this_ct (cts_given cmap) }
 110       Derived {}
 111           -> cmap { cts_derived = Map.insertWith unionBags a this_ct (cts_derived cmap) }
 112   where this_ct = singleCCan ct
 113
 114 getRelevantCts :: Ord a => a -> CCanMap a -> (CanonicalCts, CCanMap a)
 115 -- Gets the relevant constraints and returns the rest of the CCanMap
 116 getRelevantCts a cmap
 117     = let relevant = unionManyBags [ Map.findWithDefault emptyCCan a (cts_wanted cmap)
 118                                    , Map.findWithDefault emptyCCan a (cts_given cmap)
 119                                    , Map.findWithDefault emptyCCan a (cts_derived cmap) ]
 120           residual_map = cmap { cts_wanted = Map.delete a (cts_wanted cmap)
 121                               , cts_given = Map.delete a (cts_given cmap)
 122                               , cts_derived = Map.delete a (cts_derived cmap) }
 123       in (relevant, residual_map)
 124
 125 extractUnsolvedCMap :: Ord a => CCanMap a -> (CanonicalCts, CCanMap a)
 126 -- Gets the wanted or derived constraints and returns a residual
 127 -- CCanMap with only givens.
 128 extractUnsolvedCMap cmap =
 129   let wntd = Map.fold unionBags emptyCCan (cts_wanted cmap)
 130       derd = Map.fold unionBags emptyCCan (cts_derived cmap)
 131   in (wntd `unionBags` derd,
 132            cmap { cts_wanted = Map.empty, cts_derived = Map.empty })
 133
 134
 135 -- See Note [InertSet invariants]
 136 data InertSet
 137   = IS { inert_eqs          :: CanonicalCts               -- Equalities only (CTyEqCan)
 138        , inert_dicts        :: CCanMap Class              -- Dictionaries only
 139        , inert_ips          :: CCanMap (IPName Name)      -- Implicit parameters
 140        , inert_frozen       :: CanonicalCts
 141        , inert_funeqs       :: CCanMap TyCon              -- Type family equalities only
 142                -- This representation allows us to quickly get to the relevant
 143                -- inert constraints when interacting a work item with the inert set.
 144        }
 145
 146 tyVarsOfInert :: InertSet -> TcTyVarSet
 147 tyVarsOfInert (IS { inert_eqs    = eqs
 148                   , inert_dicts  = dictmap
 149                   , inert_ips    = ipmap
 150                   , inert_frozen = frozen
 151                   , inert_funeqs = funeqmap }) = tyVarsOfCanonicals cts
 152   where
 153     cts = eqs `andCCan` frozen `andCCan` cCanMapToBag dictmap
 154               `andCCan` cCanMapToBag ipmap `andCCan` cCanMapToBag funeqmap
 155
 156 instance Outputable InertSet where
 157   ppr is = vcat [ vcat (map ppr (Bag.bagToList $ inert_eqs is))
 158                 , vcat (map ppr (Bag.bagToList $ cCanMapToBag (inert_dicts is)))
 159                 , vcat (map ppr (Bag.bagToList $ cCanMapToBag (inert_ips is)))
 160                 , vcat (map ppr (Bag.bagToList $ cCanMapToBag (inert_funeqs is)))
 161                 , vcat (map ppr (Bag.bagToList $ inert_frozen is))
 162                 ]
 163
 164 emptyInert :: InertSet
 165 emptyInert = IS { inert_eqs    = Bag.emptyBag
 166                 , inert_frozen = Bag.emptyBag
 167                 , inert_dicts  = emptyCCanMap
 168                 , inert_ips    = emptyCCanMap
 169                 , inert_funeqs = emptyCCanMap }
 170
 171 updInertSet :: InertSet -> AtomicInert -> InertSet
 172 updInertSet is item
 173   | isCTyEqCan item                     -- Other equality
 174   = let eqs' = inert_eqs is `Bag.snocBag` item
 175     in is { inert_eqs = eqs' }
 176   | Just cls <- isCDictCan_Maybe item   -- Dictionary
 177   = is { inert_dicts = updCCanMap (cls,item) (inert_dicts is) }
 178   | Just x  <- isCIPCan_Maybe item      -- IP
 179   = is { inert_ips   = updCCanMap (x,item) (inert_ips is) }
 180   | Just tc <- isCFunEqCan_Maybe item   -- Function equality
 181   = is { inert_funeqs = updCCanMap (tc,item) (inert_funeqs is) }
 182   | otherwise
 183   = is { inert_frozen = inert_frozen is `Bag.snocBag` item }
 184
 185 extractUnsolved :: InertSet -> (InertSet, CanonicalCts)
 186 -- Postcondition: the returned canonical cts are either Derived, or Wanted.
 187 extractUnsolved is@(IS {inert_eqs = eqs})
 188   = let is_solved  = is { inert_eqs    = solved_eqs
 189                         , inert_dicts  = solved_dicts
 190                         , inert_ips    = solved_ips
 191                         , inert_frozen = emptyCCan
 192                         , inert_funeqs = solved_funeqs }
 193     in (is_solved, unsolved)
 194
 195   where (unsolved_eqs, solved_eqs)       = Bag.partitionBag (not.isGivenCt) eqs
 196         (unsolved_ips, solved_ips)       = extractUnsolvedCMap (inert_ips is)
 197         (unsolved_dicts, solved_dicts)   = extractUnsolvedCMap (inert_dicts is)
 198         (unsolved_funeqs, solved_funeqs) = extractUnsolvedCMap (inert_funeqs is)
 199
 200         unsolved = unsolved_eqs `unionBags` inert_frozen is `unionBags`
 201                    unsolved_ips `unionBags` unsolved_dicts `unionBags` unsolved_funeqs
 202 \end{code}
 203
 204 %*********************************************************************
 205 %*                                                                   *
 206 *                      Main Interaction Solver                       *
 207 *                                                                    *
 208 **********************************************************************
 209
 210 Note [Basic plan]
 211 ~~~~~~~~~~~~~~~~~
 212 1. Canonicalise (unary)
 213 2. Pairwise interaction (binary)
 214     * Take one from work list
 215     * Try all pair-wise interactions with each constraint in inert
 216
 217    As an optimisation, we prioritize the equalities both in the
 218    worklist and in the inerts.
 219
 220 3. Try to solve spontaneously for equalities involving touchables
 221 4. Top-level interaction (binary wrt top-level)
 222    Superclass decomposition belongs in (4), see note [Superclasses]
 223
 224 \begin{code}
 225 type AtomicInert = CanonicalCt     -- constraint pulled from InertSet
 226 type WorkItem    = CanonicalCt     -- constraint pulled from WorkList
 227
 228 ------------------------
 229 data StopOrContinue
 230   = Stop                        -- Work item is consumed
 231   | ContinueWith WorkItem       -- Not consumed
 232
 233 instance Outputable StopOrContinue where
 234   ppr Stop             = ptext (sLit "Stop")
 235   ppr (ContinueWith w) = ptext (sLit "ContinueWith") <+> ppr w
 236
 237 -- Results after interacting a WorkItem as far as possible with an InertSet
 238 data StageResult
 239   = SR { sr_inerts     :: InertSet
 240            -- The new InertSet to use (REPLACES the old InertSet)
 241        , sr_new_work   :: WorkList
 242            -- Any new work items generated (should be ADDED to the old WorkList)
 243            -- Invariant:
 244            --    sr_stop = Just workitem => workitem is *not* in sr_inerts and
 245            --                               workitem is inert wrt to sr_inerts
 246        , sr_stop       :: StopOrContinue
 247        }
 248
 249 instance Outputable StageResult where
 250   ppr (SR { sr_inerts = inerts, sr_new_work = work, sr_stop = stop })
 251     = ptext (sLit "SR") <+>
 252       braces (sep [ ptext (sLit "inerts =") <+> ppr inerts <> comma
 253                   , ptext (sLit "new work =") <+> ppr work <> comma
 254                   , ptext (sLit "stop =") <+> ppr stop])
 255
 256 type SubGoalDepth = Int   -- Starts at zero; used to limit infinite
 257                           -- recursion of sub-goals
 258 type SimplifierStage = SubGoalDepth -> WorkItem -> InertSet -> TcS StageResult
 259
 260 -- Combine a sequence of simplifier 'stages' to create a pipeline
 261 runSolverPipeline :: SubGoalDepth
 262                   -> [(String, SimplifierStage)]
 263                   -> InertSet -> WorkItem
 264                   -> TcS (InertSet, WorkList)
 265 -- Precondition: non-empty list of stages
 266 runSolverPipeline depth pipeline inerts workItem
 267   = do { traceTcS "Start solver pipeline" $
 268             vcat [ ptext (sLit "work item =") <+> ppr workItem
 269                  , ptext (sLit "inerts    =") <+> ppr inerts]
 270
 271        ; let itr_in = SR { sr_inerts = inerts
 272                          , sr_new_work = emptyWorkList
 273                          , sr_stop = ContinueWith workItem }
 274        ; itr_out <- run_pipeline pipeline itr_in
 275        ; let new_inert
 276               = case sr_stop itr_out of
 277                   Stop              -> sr_inerts itr_out
 278                   ContinueWith item -> sr_inerts itr_out `updInertSet` item
 279        ; return (new_inert, sr_new_work itr_out) }
 280   where
 281     run_pipeline :: [(String, SimplifierStage)]
 282                  -> StageResult -> TcS StageResult
 283     run_pipeline [] itr                         = return itr
 284     run_pipeline _  itr@(SR { sr_stop = Stop }) = return itr
 285
 286     run_pipeline ((name,stage):stages)
 287                  (SR { sr_new_work = accum_work
 288                      , sr_inerts   = inerts
 289                      , sr_stop     = ContinueWith work_item })
 290       = do { itr <- stage depth work_item inerts
 291            ; traceTcS ("Stage result (" ++ name ++ ")") (ppr itr)
 292            ; let itr' = itr { sr_new_work = accum_work `unionWorkList` sr_new_work itr }
 293            ; run_pipeline stages itr' }
 294 \end{code}
 295
 296 Example 1:
 297   Inert:   {c ~ d, F a ~ t, b ~ Int, a ~ ty} (all given)
 298   Reagent: a ~ [b] (given)
 299
 300 React with (c~d)     ==> IR (ContinueWith (a~[b]))  True    []
 301 React with (F a ~ t) ==> IR (ContinueWith (a~[b]))  False   [F [b] ~ t]
 302 React with (b ~ Int) ==> IR (ContinueWith (a~[Int]) True    []
 303
 304 Example 2:
 305   Inert:  {c ~w d, F a ~g t, b ~w Int, a ~w ty}
 306   Reagent: a ~w [b]
 307
 308 React with (c ~w d)   ==> IR (ContinueWith (a~[b]))  True    []
 309 React with (F a ~g t) ==> IR (ContinueWith (a~[b]))  True    []    (can't rewrite given with wanted!)
 310 etc.
 311
 312 Example 3:
 313   Inert:  {a ~ Int, F Int ~ b} (given)
 314   Reagent: F a ~ b (wanted)
 315
 316 React with (a ~ Int)   ==> IR (ContinueWith (F Int ~ b)) True []
 317 React with (F Int ~ b) ==> IR Stop True []    -- after substituting we re-canonicalize and get nothing
 318
 319 \begin{code}
 320 -- Main interaction solver: we fully solve the worklist 'in one go',
 321 -- returning an extended inert set.
 322 --
 323 -- See Note [Touchables and givens].
 324 solveInteractGiven :: InertSet -> GivenLoc -> [EvVar] -> TcS InertSet
 325 solveInteractGiven inert gloc evs
 326   = do { (_, inert_ret) <- solveInteract inert $ listToBag $
 327                            map mk_given evs
 328        ; return inert_ret }
 329   where
 330     flav = Given gloc
 331     mk_given ev = mkEvVarX ev flav
 332
 333 solveInteractWanted :: InertSet -> [WantedEvVar] -> TcS InertSet
 334 solveInteractWanted inert wvs
 335   = do { (_,inert_ret) <- solveInteract inert $ listToBag $
 336                           map wantedToFlavored wvs
 337        ; return inert_ret }
 338
 339 solveInteract :: InertSet -> Bag FlavoredEvVar -> TcS (Bool, InertSet)
 340 -- Post: (True,  inert_set) means we managed to discharge all constraints
 341 --                          without actually doing any interactions!
 342 --       (False, inert_set) means some interactions occurred
 343 solveInteract inert ws
 344   = do { dyn_flags <- getDynFlags
 345        ; sctx <- getTcSContext
 346
 347        ; traceTcS "solveInteract, before clever canonicalization:" $
 348          vcat [ text "ws = " <+>  ppr (mapBag (\(EvVarX ev ct)
 349                                                    -> (ct,evVarPred ev)) ws)
 350               , text "inert = " <+> ppr inert ]
 351
 352        ; can_ws <- mkCanonicalFEVs ws
 353
 354        ; (flag, inert_ret)
 355            <- foldrWorkListM (tryPreSolveAndInteract sctx dyn_flags) (True,inert) can_ws
 356
 357        ; traceTcS "solveInteract, after clever canonicalization (and interaction):" $
 358          vcat [ text "No interaction happened = " <+> ppr flag
 359               , text "inert_ret = " <+> ppr inert_ret ]
 360
 361        ; return (flag, inert_ret) }
 362
 363 tryPreSolveAndInteract :: SimplContext
 364                        -> DynFlags
 365                        -> CanonicalCt
 366                        -> (Bool, InertSet)
 367                        -> TcS (Bool, InertSet)
 368 -- Returns: True if it was able to discharge this constraint AND all previous ones
 369 tryPreSolveAndInteract sctx dyn_flags ct (all_previous_discharged, inert)
 370   = do { let inert_cts = get_inert_cts (evVarPred ev_var)
 371
 372        ; this_one_discharged <-
 373            if isCFrozenErr ct then
 374                return False
 375            else
 376                dischargeFromCCans inert_cts ev_var fl
 377
 378        ; if this_one_discharged
 379          then return (all_previous_discharged, inert)
 380
 381          else do
 382        { inert_ret <- solveOneWithDepth (ctxtStkDepth dyn_flags,0,[]) ct inert
 383        ; return (False, inert_ret) } }
 384
 385   where
 386     ev_var = cc_id ct
 387     fl = cc_flavor ct
 388
 389     get_inert_cts (ClassP clas _)
 390       | simplEqsOnly sctx = emptyCCan
 391       | otherwise         = fst (getRelevantCts clas (inert_dicts inert))
 392     get_inert_cts (IParam {})
 393       = emptyCCan -- We must not do the same thing for IParams, because (contrary
 394                   -- to dictionaries), work items /must/ override inert items.
 395                  -- See Note [Overriding implicit parameters] in TcInteract.
 396     get_inert_cts (EqPred {})
 397       = inert_eqs inert `unionBags` cCanMapToBag (inert_funeqs inert)
 398
 399 dischargeFromCCans :: CanonicalCts -> EvVar -> CtFlavor -> TcS Bool
 400 -- See if this (pre-canonicalised) work-item is identical to a
 401 -- one already in the inert set. Reasons:
 402 --    a) Avoid creating superclass constraints for millions of incoming (Num a) constraints
 403 --    b) Termination for improve_eqs in TcSimplify.simpl_loop
 404 dischargeFromCCans cans ev fl
 405   = Bag.foldrBag discharge_ct (return False) cans
 406   where
 407     the_pred = evVarPred ev
 408
 409     discharge_ct :: CanonicalCt -> TcS Bool -> TcS Bool
 410     discharge_ct ct _rest
 411       | evVarPred (cc_id ct) `eqPred` the_pred
 412       , cc_flavor ct `canSolve` fl
 413       = do { when (isWanted fl) $ setEvBind ev (evVarTerm (cc_id ct))
 414                  -- Deriveds need no evidence
 415                  -- For Givens, we already have evidence, and we don't need it twice
 416            ; return True }
 417
 418     discharge_ct _ct rest = rest
 419 \end{code}
 420
 421 Note [Avoiding the superclass explosion]
 422 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 423 This note now is not as significant as it used to be because we no
 424 longer add the superclasses of Wanted as Derived, except only if they
 425 have equality superclasses or superclasses with functional
 426 dependencies. The fear was that hundreds of identical wanteds would
 427 give rise each to the same superclass or equality Derived's which
 428 would lead to a blo-up in the number of interactions.
 429
 430 Instead, what we do with tryPreSolveAndCanon, is when we encounter a
 431 new constraint, we very quickly see if it can be immediately
 432 discharged by a class constraint in our inert set or the previous
 433 canonicals. If so, we add nothing to the returned canonical
 434 constraints.
 435
 436 \begin{code}
 437 solveOne :: WorkItem -> InertSet -> TcS InertSet
 438 solveOne workItem inerts
 439   = do { dyn_flags <- getDynFlags
 440        ; solveOneWithDepth (ctxtStkDepth dyn_flags,0,[]) workItem inerts
 441        }
 442
 443 -----------------
 444 solveInteractWithDepth :: (Int, Int, [WorkItem])
 445                        -> WorkList -> InertSet -> TcS InertSet
 446 solveInteractWithDepth ctxt@(max_depth,n,stack) ws inert
 447   | isEmptyWorkList ws
 448   = return inert
 449
 450   | n > max_depth
 451   = solverDepthErrorTcS n stack
 452
 453   | otherwise
 454   = do { traceTcS "solveInteractWithDepth" $
 455               vcat [ text "Current depth =" <+> ppr n
 456                    , text "Max depth =" <+> ppr max_depth
 457                    , text "ws =" <+> ppr ws ]
 458
 459
 460        ; foldrWorkListM (solveOneWithDepth ctxt) inert ws }
 461               -- use foldr to preserve the order
 462
 463 ------------------
 464 -- Fully interact the given work item with an inert set, and return a
 465 -- new inert set which has assimilated the new information.
 466 solveOneWithDepth :: (Int, Int, [WorkItem])
 467                   -> WorkItem -> InertSet -> TcS InertSet
 468 solveOneWithDepth (max_depth, depth, stack) work inert
 469   = do { traceFireTcS depth (text "Solving {" <+> ppr work)
 470        ; (new_inert, new_work) <- runSolverPipeline depth thePipeline inert work
 471
 472          -- Recursively solve the new work generated
 473          -- from workItem, with a greater depth
 474        ; res_inert <- solveInteractWithDepth (max_depth, depth+1, work:stack) new_work new_inert
 475
 476        ; traceFireTcS depth (text "Done }" <+> ppr work)
 477
 478        ; return res_inert }
 479
 480 thePipeline :: [(String,SimplifierStage)]
 481 thePipeline = [ ("interact with inert eqs", interactWithInertEqsStage)
 482               , ("interact with inerts",    interactWithInertsStage)
 483               , ("spontaneous solve",       spontaneousSolveStage)
 484               , ("top-level reactions",     topReactionsStage) ]
 485 \end{code}
 486
 487 *********************************************************************************
 488 *                                                                               *
 489                        The spontaneous-solve Stage
 490 *                                                                               *
 491 *********************************************************************************
 492
 493 Note [Efficient Orientation]
 494 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 495
 496 There are two cases where we have to be careful about
 497 orienting equalities to get better efficiency.
 498
 499 Case 1: In Rewriting Equalities (function rewriteEqLHS)
 500
 501     When rewriting two equalities with the same LHS:
 502           (a)  (tv ~ xi1)
 503           (b)  (tv ~ xi2)
 504     We have a choice of producing work (xi1 ~ xi2) (up-to the
 505     canonicalization invariants) However, to prevent the inert items
 506     from getting kicked out of the inerts first, we prefer to
 507     canonicalize (xi1 ~ xi2) if (b) comes from the inert set, or (xi2
 508     ~ xi1) if (a) comes from the inert set.
 509
 510     This choice is implemented using the WhichComesFromInert flag.
 511
 512 Case 2: Functional Dependencies
 513     Again, we should prefer, if possible, the inert variables on the RHS
 514
 515 Case 3: IP improvement work
 516     We must always rewrite so that the inert type is on the right.
 517
 518 \begin{code}
 519 spontaneousSolveStage :: SimplifierStage
 520 spontaneousSolveStage depth workItem inerts
 521   = do { mSolve <- trySpontaneousSolve workItem
 522
 523        ; case mSolve of
 524            SPCantSolve -> -- No spontaneous solution for him, keep going
 525                return $ SR { sr_new_work   = emptyWorkList
 526                            , sr_inerts     = inerts
 527                            , sr_stop       = ContinueWith workItem }
 528
 529            SPSolved workItem'
 530                | not (isGivenCt workItem)
 531                  -- Original was wanted or derived but we have now made him
 532                  -- given so we have to interact him with the inerts due to
 533                  -- its status change. This in turn may produce more work.
 534                  -- We do this *right now* (rather than just putting workItem'
 535                  -- back into the work-list) because we've solved
 536                -> do { bumpStepCountTcS
 537                      ; traceFireTcS depth (ptext (sLit "Spontaneous (w/d)") <+> ppr workItem)
 538                      ; (new_inert, new_work) <- runSolverPipeline depth
 539                              [ ("recursive interact with inert eqs", interactWithInertEqsStage)
 540                              , ("recursive interact with inerts", interactWithInertsStage)
 541                              ] inerts workItem'
 542                      ; return $ SR { sr_new_work = new_work
 543                                    , sr_inerts   = new_inert -- will include workItem'
 544                                    , sr_stop     = Stop }
 545                      }
 546                | otherwise
 547                    -> -- Original was given; he must then be inert all right, and
 548                       -- workList' are all givens from flattening
 549                       do { bumpStepCountTcS
 550                          ; traceFireTcS depth (ptext (sLit "Spontaneous (g)") <+> ppr workItem)
 551                          ; return $ SR { sr_new_work = emptyWorkList
 552                                        , sr_inerts   = inerts `updInertSet` workItem'
 553                                        , sr_stop     = Stop } }
 554            SPError -> -- Return with no new work
 555                return $ SR { sr_new_work = emptyWorkList
 556                            , sr_inerts   = inerts
 557                            , sr_stop     = Stop }
 558        }
 559
 560 data SPSolveResult = SPCantSolve | SPSolved WorkItem | SPError
 561 -- SPCantSolve means that we can't do the unification because e.g. the variable is untouchable
 562 -- SPSolved workItem' gives us a new *given* to go on
 563 -- SPError means that it's completely impossible to solve this equality, eg due to a kind error
 564
 565
 566 -- @trySpontaneousSolve wi@ solves equalities where one side is a
 567 -- touchable unification variable.
 568 --          See Note [Touchables and givens]
 569 trySpontaneousSolve :: WorkItem -> TcS SPSolveResult
 570 trySpontaneousSolve workItem@(CTyEqCan { cc_id = cv, cc_flavor = gw, cc_tyvar = tv1, cc_rhs = xi })
 571   | isGiven gw
 572   = return SPCantSolve
 573   | Just tv2 <- tcGetTyVar_maybe xi
 574   = do { tch1 <- isTouchableMetaTyVar tv1
 575        ; tch2 <- isTouchableMetaTyVar tv2
 576        ; case (tch1, tch2) of
 577            (True,  True)  -> trySpontaneousEqTwoWay cv gw tv1 tv2
 578            (True,  False) -> trySpontaneousEqOneWay cv gw tv1 xi
 579            (False, True)  -> trySpontaneousEqOneWay cv gw tv2 (mkTyVarTy tv1)
 580            _ -> return SPCantSolve }
 581   | otherwise
 582   = do { tch1 <- isTouchableMetaTyVar tv1
 583        ; if tch1 then trySpontaneousEqOneWay cv gw tv1 xi
 584                  else do { traceTcS "Untouchable LHS, can't spontaneously solve workitem:"
 585                                     (ppr workItem)
 586                          ; return SPCantSolve }
 587        }
 588
 589   -- No need for
 590   --      trySpontaneousSolve (CFunEqCan ...) = ...
 591   -- See Note [No touchables as FunEq RHS] in TcSMonad
 592 trySpontaneousSolve _ = return SPCantSolve
 593
 594 ----------------
 595 trySpontaneousEqOneWay :: CoVar -> CtFlavor -> TcTyVar -> Xi -> TcS SPSolveResult
 596 -- tv is a MetaTyVar, not untouchable
 597 trySpontaneousEqOneWay cv gw tv xi
 598   | not (isSigTyVar tv) || isTyVarTy xi
 599   = do { let kxi = typeKind xi -- NB: 'xi' is fully rewritten according to the inerts
 600                                -- so we have its more specific kind in our hands
 601        ; if kxi `isSubKind` tyVarKind tv then
 602              solveWithIdentity cv gw tv xi
 603          else return SPCantSolve
 604 {-
 605          else if tyVarKind tv `isSubKind` kxi then
 606              return SPCantSolve -- kinds are compatible but we can't solveWithIdentity this way
 607                                 -- This case covers the  a_touchable :: * ~ b_untouchable :: ??
 608                                 -- which has to be deferred or floated out for someone else to solve
 609                                 -- it in a scope where 'b' is no longer untouchable.
 610          else do { addErrorTcS KindError gw (mkTyVarTy tv) xi -- See Note [Kind errors]
 611                  ; return SPError }
 612 -}
 613        }
 614   | otherwise -- Still can't solve, sig tyvar and non-variable rhs
 615   = return SPCantSolve
 616
 617 ----------------
 618 trySpontaneousEqTwoWay :: CoVar -> CtFlavor -> TcTyVar -> TcTyVar -> TcS SPSolveResult
 619 -- Both tyvars are *touchable* MetaTyvars so there is only a chance for kind error here
 620 trySpontaneousEqTwoWay cv gw tv1 tv2
 621   | k1 `isSubKind` k2
 622   , nicer_to_update_tv2 = solveWithIdentity cv gw tv2 (mkTyVarTy tv1)
 623   | k2 `isSubKind` k1
 624   = solveWithIdentity cv gw tv1 (mkTyVarTy tv2)
 625   | otherwise -- None is a subkind of the other, but they are both touchable!
 626   = return SPCantSolve
 627     -- do { addErrorTcS KindError gw (mkTyVarTy tv1) (mkTyVarTy tv2)
 628     --   ; return SPError }
 629   where
 630     k1 = tyVarKind tv1
 631     k2 = tyVarKind tv2
 632     nicer_to_update_tv2 = isSigTyVar tv1 || isSystemName (Var.varName tv2)
 633 \end{code}
 634
 635 Note [Kind errors]
 636 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 637 Consider the wanted problem:
 638       alpha ~ (# Int, Int #)
 639 where alpha :: ?? and (# Int, Int #) :: (#). We can't spontaneously solve this constraint,
 640 but we should rather reject the program that give rise to it. If 'trySpontaneousEqTwoWay'
 641 simply returns @CantSolve@ then that wanted constraint is going to propagate all the way and
 642 get quantified over in inference mode. That's bad because we do know at this point that the
 643 constraint is insoluble. Instead, we call 'recKindErrorTcS' here, which will fail later on.
 644
 645 The same applies in canonicalization code in case of kind errors in the givens.
 646
 647 However, when we canonicalize givens we only check for compatibility (@compatKind@).
 648 If there were a kind error in the givens, this means some form of inconsistency or dead code.
 649
 650 You may think that when we spontaneously solve wanteds we may have to look through the
 651 bindings to determine the right kind of the RHS type. E.g one may be worried that xi is
 652 @alpha@ where alpha :: ? and a previous spontaneous solving has set (alpha := f) with (f :: *).
 653 But we orient our constraints so that spontaneously solved ones can rewrite all other constraint
 654 so this situation can't happen.
 655
 656 Note [Spontaneous solving and kind compatibility]
 657 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 658 Note that our canonical constraints insist that *all* equalities (tv ~
 659 xi) or (F xis ~ rhs) require the LHS and the RHS to have *compatible*
 660 the same kinds.  ("compatible" means one is a subKind of the other.)
 661
 662   - It can't be *equal* kinds, because
 663      b) wanted constraints don't necessarily have identical kinds
 664                eg   alpha::? ~ Int
 665      b) a solved wanted constraint becomes a given
 666
 667   - SPJ thinks that *given* constraints (tv ~ tau) always have that
 668     tau has a sub-kind of tv; and when solving wanted constraints
 669     in trySpontaneousEqTwoWay we re-orient to achieve this.
 670
 671   - Note that the kind invariant is maintained by rewriting.
 672     Eg wanted1 rewrites wanted2; if both were compatible kinds before,
 673        wanted2 will be afterwards.  Similarly givens.
 674
 675 Caveat:
 676   - Givens from higher-rank, such as:
 677           type family T b :: * -> * -> *
 678           type instance T Bool = (->)
 679
 680           f :: forall a. ((T a ~ (->)) => ...) -> a -> ...
 681           flop = f (...) True
 682      Whereas we would be able to apply the type instance, we would not be able to
 683      use the given (T Bool ~ (->)) in the body of 'flop'
 684
 685
 686 Note [Avoid double unifications]
 687 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 688 The spontaneous solver has to return a given which mentions the unified unification
 689 variable *on the left* of the equality. Here is what happens if not:
 690   Original wanted:  (a ~ alpha),  (alpha ~ Int)
 691 We spontaneously solve the first wanted, without changing the order!
 692       given : a ~ alpha      [having unified alpha := a]
 693 Now the second wanted comes along, but he cannot rewrite the given, so we simply continue.
 694 At the end we spontaneously solve that guy, *reunifying*  [alpha := Int]
 695
 696 We avoid this problem by orienting the resulting given so that the unification
 697 variable is on the left.  [Note that alternatively we could attempt to
 698 enforce this at canonicalization]
 699
 700 See also Note [No touchables as FunEq RHS] in TcSMonad; avoiding
 701 double unifications is the main reason we disallow touchable
 702 unification variables as RHS of type family equations: F xis ~ alpha.
 703
 704 \begin{code}
 705 ----------------
 706
 707 solveWithIdentity :: CoVar -> CtFlavor -> TcTyVar -> Xi -> TcS SPSolveResult
 708 -- Solve with the identity coercion
 709 -- Precondition: kind(xi) is a sub-kind of kind(tv)
 710 -- Precondition: CtFlavor is Wanted or Derived
 711 -- See [New Wanted Superclass Work] to see why solveWithIdentity
 712 --     must work for Derived as well as Wanted
 713 -- Returns: workItem where
 714 --        workItem = the new Given constraint
 715 solveWithIdentity cv wd tv xi
 716   = do { traceTcS "Sneaky unification:" $
 717                        vcat [text "Coercion variable:  " <+> ppr wd,
 718                              text "Coercion:           " <+> pprEq (mkTyVarTy tv) xi,
 719                              text "Left  Kind is     : " <+> ppr (typeKind (mkTyVarTy tv)),
 720                              text "Right Kind is     : " <+> ppr (typeKind xi)
 721                   ]
 722
 723        ; setWantedTyBind tv xi
 724        ; let refl_xi = mkReflCo xi
 725        ; cv_given <- newGivenCoVar (mkTyVarTy tv) xi refl_xi
 726
 727        ; when (isWanted wd) (setCoBind cv refl_xi)
 728            -- We don't want to do this for Derived, that's why we use 'when (isWanted wd)'
 729
 730        ; return $ SPSolved (CTyEqCan { cc_id = cv_given
 731                                      , cc_flavor = mkGivenFlavor wd UnkSkol
 732                                      , cc_tyvar  = tv, cc_rhs = xi }) }
 733 \end{code}
 734
 735
 736 *********************************************************************************
 737 *                                                                               *
 738                        The interact-with-inert Stage
 739 *                                                                               *
 740 *********************************************************************************
 741
 742 Note [The Solver Invariant]
 743 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
 744 We always add Givens first.  So you might think that the solver has
 745 the invariant
 746
 747    If the work-item is Given,
 748    then the inert item must Given
 749
 750 But this isn't quite true.  Suppose we have,
 751     c1: [W] beta ~ [alpha], c2 : [W] blah, c3 :[W] alpha ~ Int
 752 After processing the first two, we get
 753      c1: [G] beta ~ [alpha], c2 : [W] blah
 754 Now, c3 does not interact with the the given c1, so when we spontaneously
 755 solve c3, we must re-react it with the inert set.  So we can attempt a
 756 reaction between inert c2 [W] and work-item c3 [G].
 757
 758 It *is* true that [Solver Invariant]
 759    If the work-item is Given,
 760    AND there is a reaction
 761    then the inert item must Given
 762 or, equivalently,
 763    If the work-item is Given,
 764    and the inert item is Wanted/Derived
 765    then there is no reaction
 766
 767 \begin{code}
 768 -- Interaction result of  WorkItem <~> AtomicInert
 769 data InteractResult
 770    = IR { ir_stop         :: StopOrContinue
 771             -- Stop
 772             --   => Reagent (work item) consumed.
 773             -- ContinueWith new_reagent
 774             --   => Reagent transformed but keep gathering interactions.
 775             --      The transformed item remains inert with respect
 776             --      to any previously encountered inerts.
 777
 778         , ir_inert_action :: InertAction
 779             -- Whether the inert item should remain in the InertSet.
 780
 781         , ir_new_work     :: WorkList
 782             -- new work items to add to the WorkList
 783
 784         , ir_fire :: Maybe String    -- Tells whether a rule fired, and if so what
 785         }
 786
 787 -- What to do with the inert reactant.
 788 data InertAction = KeepInert | DropInert
 789
 790 mkIRContinue :: String -> WorkItem -> InertAction -> WorkList -> TcS InteractResult
 791 mkIRContinue rule wi keep newWork
 792   = return $ IR { ir_stop = ContinueWith wi, ir_inert_action = keep
 793                 , ir_new_work = newWork, ir_fire = Just rule }
 794
 795 mkIRStopK :: String -> WorkList -> TcS InteractResult
 796 mkIRStopK rule newWork
 797   = return $ IR { ir_stop = Stop, ir_inert_action = KeepInert
 798                 , ir_new_work = newWork, ir_fire = Just rule }
 799
 800 mkIRStopD :: String -> WorkList -> TcS InteractResult
 801 mkIRStopD rule newWork
 802   = return $ IR { ir_stop = Stop, ir_inert_action = DropInert
 803                 , ir_new_work = newWork, ir_fire = Just rule }
 804
 805 noInteraction :: Monad m => WorkItem -> m InteractResult
 806 noInteraction wi
 807   = return $ IR { ir_stop = ContinueWith wi, ir_inert_action = KeepInert
 808                 , ir_new_work = emptyWorkList, ir_fire = Nothing }
 809
 810 data WhichComesFromInert = LeftComesFromInert | RightComesFromInert
 811      -- See Note [Efficient Orientation]
 812
 813
 814 ---------------------------------------------------
 815 -- Interact a single WorkItem with the equalities of an inert set as
 816 -- far as possible, i.e. until we get a Stop result from an individual
 817 -- reaction (i.e. when the WorkItem is consumed), or until we've
 818 -- interact the WorkItem with the entire equalities of the InertSet
 819
 820 interactWithInertEqsStage :: SimplifierStage
 821 interactWithInertEqsStage depth workItem inert
 822   = Bag.foldrBagM (interactNext depth) initITR (inert_eqs inert)
 823                         -- use foldr to preserve the order
 824   where
 825     initITR = SR { sr_inerts   = inert { inert_eqs = emptyCCan }
 826                  , sr_new_work = emptyWorkList
 827                  , sr_stop     = ContinueWith workItem }
 828
 829 ---------------------------------------------------
 830 -- Interact a single WorkItem with *non-equality* constraints in the inert set.
 831 -- Precondition: equality interactions must have already happened, hence we have
 832 -- to pick up some information from the incoming inert, before folding over the
 833 -- "Other" constraints it contains!
 834
 835 interactWithInertsStage :: SimplifierStage
 836 interactWithInertsStage depth workItem inert
 837   = let (relevant, inert_residual) = getISRelevant workItem inert
 838         initITR = SR { sr_inerts   = inert_residual
 839                      , sr_new_work = emptyWorkList
 840                      , sr_stop     = ContinueWith workItem }
 841     in Bag.foldrBagM (interactNext depth) initITR relevant
 842                         -- use foldr to preserve the order
 843   where
 844     getISRelevant :: CanonicalCt -> InertSet -> (CanonicalCts, InertSet)
 845     getISRelevant (CFrozenErr {}) is = (emptyCCan, is)
 846                   -- Nothing s relevant; we have alread interacted
 847                   -- it with the equalities in the inert set
 848
 849     getISRelevant (CDictCan { cc_class = cls } ) is
 850       = let (relevant, residual_map) = getRelevantCts cls (inert_dicts is)
 851         in (relevant, is { inert_dicts = residual_map })
 852     getISRelevant (CFunEqCan { cc_fun = tc } ) is
 853       = let (relevant, residual_map) = getRelevantCts tc (inert_funeqs is)
 854         in (relevant, is { inert_funeqs = residual_map })
 855     getISRelevant (CIPCan { cc_ip_nm = nm }) is
 856       = let (relevant, residual_map) = getRelevantCts nm (inert_ips is)
 857         in (relevant, is { inert_ips = residual_map })
 858     -- An equality, finally, may kick everything except equalities out
 859     -- because we have already interacted the equalities in interactWithInertEqsStage
 860     getISRelevant _eq_ct is  -- Equality, everything is relevant for this one
 861                              -- TODO: if we were caching variables, we'd know that only
 862                              --       some are relevant. Experiment with this for now.
 863       = let cts = cCanMapToBag (inert_ips is) `unionBags`
 864                     cCanMapToBag (inert_dicts is) `unionBags` cCanMapToBag (inert_funeqs is)
 865         in (cts, is { inert_dicts  = emptyCCanMap
 866                     , inert_ips    = emptyCCanMap
 867                     , inert_funeqs = emptyCCanMap })
 868
 869 interactNext :: SubGoalDepth -> AtomicInert -> StageResult -> TcS StageResult
 870 interactNext depth inert it
 871   | ContinueWith work_item <- sr_stop it
 872   = do { let inerts = sr_inerts it
 873
 874        ; IR { ir_new_work = new_work, ir_inert_action = inert_action
 875             , ir_fire = fire_info, ir_stop = stop }
 876             <- interactWithInert inert work_item
 877
 878        ; let mk_msg rule
 879                = text rule <+> keep_doc
 880                  <+> vcat [ ptext (sLit "Inert =") <+> ppr inert
 881                           , ptext (sLit "Work =")  <+> ppr work_item
 882                           , ppUnless (isEmptyWorkList new_work) $
 883                             ptext (sLit "New =") <+> ppr new_work ]
 884              keep_doc = case inert_action of
 885                           KeepInert -> ptext (sLit "[keep]")
 886                           DropInert -> ptext (sLit "[drop]")
 887        ; case fire_info of
 888            Just rule -> do { bumpStepCountTcS
 889                            ; traceFireTcS depth (mk_msg rule) }
 890            Nothing  -> return ()
 891
 892        -- New inerts depend on whether we KeepInert or not
 893        ; let inerts_new = case inert_action of
 894                             KeepInert -> inerts `updInertSet` inert
 895                             DropInert -> inerts
 896
 897        ; return $ SR { sr_inerts   = inerts_new
 898                      , sr_new_work = sr_new_work it `unionWorkList` new_work
 899                      , sr_stop     = stop } }
 900   | otherwise
 901   = return $ it { sr_inerts = (sr_inerts it) `updInertSet` inert }
 902
 903 -- Do a single interaction of two constraints.
 904 interactWithInert :: AtomicInert -> WorkItem -> TcS InteractResult
 905 interactWithInert inert workItem
 906   = do { ctxt <- getTcSContext
 907        ; let is_allowed  = allowedInteraction (simplEqsOnly ctxt) inert workItem
 908
 909        ; if is_allowed then
 910               doInteractWithInert inert workItem
 911           else
 912               noInteraction workItem
 913        }
 914
 915 allowedInteraction :: Bool -> AtomicInert -> WorkItem -> Bool
 916 -- Allowed interactions
 917 allowedInteraction eqs_only (CDictCan {}) (CDictCan {}) = not eqs_only
 918 allowedInteraction eqs_only (CIPCan {})   (CIPCan {})   = not eqs_only
 919 allowedInteraction _ _ _ = True
 920
 921 --------------------------------------------
 922 doInteractWithInert :: CanonicalCt -> CanonicalCt -> TcS InteractResult
 923 -- Identical class constraints.
 924
 925 doInteractWithInert
 926   inertItem@(CDictCan { cc_id = d1, cc_flavor = fl1, cc_class = cls1, cc_tyargs = tys1 })
 927    workItem@(CDictCan { cc_id = d2, cc_flavor = fl2, cc_class = cls2, cc_tyargs = tys2 })
 928   | cls1 == cls2 && eqTypes tys1 tys2
 929   = solveOneFromTheOther "Cls/Cls" (EvId d1,fl1) workItem
 930
 931   | cls1 == cls2 && (not (isGiven fl1 && isGiven fl2))
 932   =      -- See Note [When improvement happens]
 933     do { let pty1 = ClassP cls1 tys1
 934              pty2 = ClassP cls2 tys2
 935              inert_pred_loc     = (pty1, pprFlavorArising fl1)
 936              work_item_pred_loc = (pty2, pprFlavorArising fl2)
 937              fd_eqns = improveFromAnother
 938                                   inert_pred_loc     -- the template
 939                                   work_item_pred_loc -- the one we aim to rewrite
 940                                   -- See Note [Efficient Orientation]
 941
 942        ; m <- rewriteWithFunDeps fd_eqns tys2 fl2
 943        ; case m of
 944            Nothing -> noInteraction workItem
 945            Just (rewritten_tys2, cos2, fd_work)
 946              | eqTypes tys1 rewritten_tys2
 947              -> -- Solve him on the spot in this case
 948                 case fl2 of
 949                   Given   {} -> pprPanic "Unexpected given" (ppr inertItem $$ ppr workItem)
 950                   Derived {} -> mkIRStopK "Cls/Cls fundep (solved)" fd_work
 951                   Wanted  {}
 952                     | isDerived fl1
 953                    -> do { setDictBind d2 (EvCast d1 dict_co)
 954                          ; let inert_w = inertItem { cc_flavor = fl2 }
 955                            -- A bit naughty: we take the inert Derived,
 956                            -- turn it into a Wanted, use it to solve the work-item
 957                            -- and put it back into the work-list
 958                            -- Maybe rather than starting again, we could *replace* the
 959                            -- inert item, but its safe and simple to restart
 960                          ; mkIRStopD "Cls/Cls fundep (solved)" $
 961                            workListFromNonEq inert_w `unionWorkList` fd_work }
 962                     | otherwise
 963                     -> do { setDictBind d2 (EvCast d1 dict_co)
 964                           ; mkIRStopK "Cls/Cls fundep (solved)" fd_work }
 965
 966              | otherwise
 967              -> -- We could not quite solve him, but we still rewrite him
 968                 -- Example: class C a b c | a -> b
 969                 --          Given: C Int Bool x, Wanted: C Int beta y
 970                 --          Then rewrite the wanted to C Int Bool y
 971                 --          but note that is still not identical to the given
 972                 -- The important thing is that the rewritten constraint is
 973                 -- inert wrt the given.
 974                 -- However it is not necessarily inert wrt previous inert-set items.
 975                 --      class C a b c d |  a -> b, b c -> d
 976                 --      Inert: c1: C b Q R S, c2: C P Q a b
 977                 --      Work: C P alpha R beta
 978                 --      Does not react with c1; reacts with c2, with alpha:=Q
 979                 --      NOW it reacts with c1!
 980                 -- So we must stop, and put the rewritten constraint back in the work list
 981                 do { d2' <- newDictVar cls1 rewritten_tys2
 982                    ; case fl2 of
 983                        Given {}   -> pprPanic "Unexpected given" (ppr inertItem $$ ppr workItem)
 984                        Wanted {}  -> setDictBind d2 (EvCast d2' dict_co)
 985                        Derived {} -> return ()
 986                    ; let workItem' = workItem { cc_id = d2', cc_tyargs = rewritten_tys2 }
 987                    ; mkIRStopK "Cls/Cls fundep (partial)" $
 988                      workListFromNonEq workItem' `unionWorkList` fd_work }
 989
 990              where
 991                dict_co = mkTyConAppCo (classTyCon cls1) cos2
 992   }
 993
 994 -- Class constraint and given equality: use the equality to rewrite
 995 -- the class constraint.
 996 doInteractWithInert (CTyEqCan { cc_id = cv, cc_flavor = ifl, cc_tyvar = tv, cc_rhs = xi })
 997                     (CDictCan { cc_id = dv, cc_flavor = wfl, cc_class = cl, cc_tyargs = xis })
 998   | ifl `canRewrite` wfl
 999   , tv `elemVarSet` tyVarsOfTypes xis
1000   = do { rewritten_dict <- rewriteDict (cv,tv,xi) (dv,wfl,cl,xis)
1001             -- Continue with rewritten Dictionary because we can only be in the
1002             -- interactWithEqsStage, so the dictionary is inert.
1003        ; mkIRContinue "Eq/Cls" rewritten_dict KeepInert emptyWorkList }
1004
1005 doInteractWithInert (CDictCan { cc_id = dv, cc_flavor = ifl, cc_class = cl, cc_tyargs = xis })
1006            workItem@(CTyEqCan { cc_id = cv, cc_flavor = wfl, cc_tyvar = tv, cc_rhs = xi })
1007   | wfl `canRewrite` ifl
1008   , tv `elemVarSet` tyVarsOfTypes xis
1009   = do { rewritten_dict <- rewriteDict (cv,tv,xi) (dv,ifl,cl,xis)
1010        ; mkIRContinue "Cls/Eq" workItem DropInert (workListFromNonEq rewritten_dict) }
1011
1012 -- Class constraint and given equality: use the equality to rewrite
1013 -- the class constraint.
1014 doInteractWithInert (CTyEqCan { cc_id = cv, cc_flavor = ifl, cc_tyvar = tv, cc_rhs = xi })
1015                     (CIPCan { cc_id = ipid, cc_flavor = wfl, cc_ip_nm = nm, cc_ip_ty = ty })
1016   | ifl `canRewrite` wfl
1017   , tv `elemVarSet` tyVarsOfType ty
1018   = do { rewritten_ip <- rewriteIP (cv,tv,xi) (ipid,wfl,nm,ty)
1019        ; mkIRContinue "Eq/IP" rewritten_ip KeepInert emptyWorkList }
1020
1021 doInteractWithInert (CIPCan { cc_id = ipid, cc_flavor = ifl, cc_ip_nm = nm, cc_ip_ty = ty })
1022            workItem@(CTyEqCan { cc_id = cv, cc_flavor = wfl, cc_tyvar = tv, cc_rhs = xi })
1023   | wfl `canRewrite` ifl
1024   , tv `elemVarSet` tyVarsOfType ty
1025   = do { rewritten_ip <- rewriteIP (cv,tv,xi) (ipid,ifl,nm,ty)
1026        ; mkIRContinue "IP/Eq" workItem DropInert (workListFromNonEq rewritten_ip) }
1027
1028 -- Two implicit parameter constraints.  If the names are the same,
1029 -- but their types are not, we generate a wanted type equality
1030 -- that equates the type (this is "improvement").
1031 -- However, we don't actually need the coercion evidence,
1032 -- so we just generate a fresh coercion variable that isn't used anywhere.
1033 doInteractWithInert (CIPCan { cc_id = id1, cc_flavor = ifl, cc_ip_nm = nm1, cc_ip_ty = ty1 })
1034            workItem@(CIPCan { cc_flavor = wfl, cc_ip_nm = nm2, cc_ip_ty = ty2 })
1035   | nm1 == nm2 && isGiven wfl && isGiven ifl
1036   =     -- See Note [Overriding implicit parameters]
1037         -- Dump the inert item, override totally with the new one
1038         -- Do not require type equality
1039         -- For example, given let ?x::Int = 3 in let ?x::Bool = True in ...
1040         --              we must *override* the outer one with the inner one
1041     mkIRContinue "IP/IP override" workItem DropInert emptyWorkList
1042
1043   | nm1 == nm2 && ty1 `eqType` ty2
1044   = solveOneFromTheOther "IP/IP" (EvId id1,ifl) workItem
1045
1046   | nm1 == nm2
1047   =     -- See Note [When improvement happens]
1048     do { co_var <- newCoVar ty2 ty1 -- See Note [Efficient Orientation]
1049        ; let flav = Wanted (combineCtLoc ifl wfl)
1050        ; cans <- mkCanonical flav co_var
1051        ; mkIRContinue "IP/IP fundep" workItem KeepInert cans }
1052
1053 -- Never rewrite a given with a wanted equality, and a type function
1054 -- equality can never rewrite an equality. We rewrite LHS *and* RHS
1055 -- of function equalities so that our inert set exposes everything that
1056 -- we know about equalities.
1057
1058 -- Inert: equality, work item: function equality
1059 doInteractWithInert (CTyEqCan { cc_id = cv1, cc_flavor = ifl, cc_tyvar = tv, cc_rhs = xi1 })
1060                     (CFunEqCan { cc_id = cv2, cc_flavor = wfl, cc_fun = tc
1061                                , cc_tyargs = args, cc_rhs = xi2 })
1062   | ifl `canRewrite` wfl
1063   , tv `elemVarSet` tyVarsOfTypes (xi2:args) -- Rewrite RHS as well
1064   = do { rewritten_funeq <- rewriteFunEq (cv1,tv,xi1) (cv2,wfl,tc,args,xi2)
1065        ; mkIRStopK "Eq/FunEq" (workListFromEq rewritten_funeq) }
1066          -- Must Stop here, because we may no longer be inert after the rewritting.
1067
1068 -- Inert: function equality, work item: equality
1069 doInteractWithInert (CFunEqCan {cc_id = cv1, cc_flavor = ifl, cc_fun = tc
1070                               , cc_tyargs = args, cc_rhs = xi1 })
1071            workItem@(CTyEqCan { cc_id = cv2, cc_flavor = wfl, cc_tyvar = tv, cc_rhs = xi2 })
1072   | wfl `canRewrite` ifl
1073   , tv `elemVarSet` tyVarsOfTypes (xi1:args) -- Rewrite RHS as well
1074   = do { rewritten_funeq <- rewriteFunEq (cv2,tv,xi2) (cv1,ifl,tc,args,xi1)
1075        ; mkIRContinue "FunEq/Eq" workItem DropInert (workListFromEq rewritten_funeq) }
1076          -- One may think that we could (KeepTransformedInert rewritten_funeq)
1077          -- but that is wrong, because it may end up not being inert with respect
1078          -- to future inerts. Example:
1079          -- Original inert = {    F xis ~  [a], b ~ Maybe Int }
1080          -- Work item comes along = a ~ [b]
1081          -- If we keep { F xis ~ [b] } in the inert set we will end up with:
1082          --      { F xis ~ [b], b ~ Maybe Int, a ~ [Maybe Int] }
1083          -- At the end, which is *not* inert. So we should unfortunately DropInert here.
1084
1085 doInteractWithInert (CFunEqCan { cc_id = cv1, cc_flavor = fl1, cc_fun = tc1
1086                                , cc_tyargs = args1, cc_rhs = xi1 })
1087            workItem@(CFunEqCan { cc_id = cv2, cc_flavor = fl2, cc_fun = tc2
1088                                , cc_tyargs = args2, cc_rhs = xi2 })
1089   | fl1 `canSolve` fl2 && lhss_match
1090   = do { cans <- rewriteEqLHS LeftComesFromInert  (mkCoVarCo cv1,xi1) (cv2,fl2,xi2)
1091        ; mkIRStopK "FunEq/FunEq" cans }
1092   | fl2 `canSolve` fl1 && lhss_match
1093   = do { cans <- rewriteEqLHS RightComesFromInert (mkCoVarCo cv2,xi2) (cv1,fl1,xi1)
1094        ; mkIRContinue "FunEq/FunEq" workItem DropInert cans }
1095   where
1096     lhss_match = tc1 == tc2 && eqTypes args1 args2
1097
1098 doInteractWithInert (CTyEqCan { cc_id = cv1, cc_flavor = fl1, cc_tyvar = tv1, cc_rhs = xi1 })
1099            workItem@(CTyEqCan { cc_id = cv2, cc_flavor = fl2, cc_tyvar = tv2, cc_rhs = xi2 })
1100 -- Check for matching LHS
1101   | fl1 `canSolve` fl2 && tv1 == tv2
1102   = do { cans <- rewriteEqLHS LeftComesFromInert (mkCoVarCo cv1,xi1) (cv2,fl2,xi2)
1103        ; mkIRStopK "Eq/Eq lhs" cans }
1104
1105   | fl2 `canSolve` fl1 && tv1 == tv2
1106   = do { cans <- rewriteEqLHS RightComesFromInert (mkCoVarCo cv2,xi2) (cv1,fl1,xi1)
1107        ; mkIRContinue "Eq/Eq lhs" workItem DropInert cans }
1108
1109 -- Check for rewriting RHS
1110   | fl1 `canRewrite` fl2 && tv1 `elemVarSet` tyVarsOfType xi2
1111   = do { rewritten_eq <- rewriteEqRHS (cv1,tv1,xi1) (cv2,fl2,tv2,xi2)
1112        ; mkIRStopK "Eq/Eq rhs" rewritten_eq }
1113
1114   | fl2 `canRewrite` fl1 && tv2 `elemVarSet` tyVarsOfType xi1
1115   = do { rewritten_eq <- rewriteEqRHS (cv2,tv2,xi2) (cv1,fl1,tv1,xi1)
1116        ; mkIRContinue "Eq/Eq rhs" workItem DropInert rewritten_eq }
1117
1118 doInteractWithInert (CTyEqCan   { cc_id = cv1, cc_flavor = fl1, cc_tyvar = tv1, cc_rhs = xi1 })
1119                     (CFrozenErr { cc_id = cv2, cc_flavor = fl2 })
1120   | fl1 `canRewrite` fl2 && tv1 `elemVarSet` tyVarsOfEvVar cv2
1121   = do { rewritten_frozen <- rewriteFrozen (cv1, tv1, xi1) (cv2, fl2)
1122        ; mkIRStopK "Frozen/Eq" rewritten_frozen }
1123
1124 doInteractWithInert (CFrozenErr { cc_id = cv2, cc_flavor = fl2 })
1125            workItem@(CTyEqCan   { cc_id = cv1, cc_flavor = fl1, cc_tyvar = tv1, cc_rhs = xi1 })
1126   | fl1 `canRewrite` fl2 && tv1 `elemVarSet` tyVarsOfEvVar cv2
1127   = do { rewritten_frozen <- rewriteFrozen (cv1, tv1, xi1) (cv2, fl2)
1128        ; mkIRContinue "Frozen/Eq" workItem DropInert rewritten_frozen }
1129
1130 -- Fall-through case for all other situations
1131 doInteractWithInert _ workItem = noInteraction workItem
1132
1133 -------------------------
1134 -- Equational Rewriting
1135 rewriteDict  :: (CoVar, TcTyVar, Xi) -> (DictId, CtFlavor, Class, [Xi]) -> TcS CanonicalCt
1136 rewriteDict (cv,tv,xi) (dv,gw,cl,xis)
1137   = do { let cos  = map (liftCoSubstWith [tv] [mkCoVarCo cv]) xis   -- xis[tv] ~ xis[xi]
1138              args = substTysWith [tv] [xi] xis
1139              con  = classTyCon cl
1140              dict_co = mkTyConAppCo con cos
1141        ; dv' <- newDictVar cl args
1142        ; case gw of
1143            Wanted {}         -> setDictBind dv (EvCast dv' (mkSymCo dict_co))
1144            Given {}          -> setDictBind dv' (EvCast dv dict_co)
1145            Derived {}        -> return () -- Derived dicts we don't set any evidence
1146
1147        ; return (CDictCan { cc_id = dv'
1148                           , cc_flavor = gw
1149                           , cc_class = cl
1150                           , cc_tyargs = args }) }
1151
1152 rewriteIP :: (CoVar,TcTyVar,Xi) -> (EvVar,CtFlavor, IPName Name, TcType) -> TcS CanonicalCt
1153 rewriteIP (cv,tv,xi) (ipid,gw,nm,ty)
1154   = do { let ip_co = liftCoSubstWith [tv] [mkCoVarCo cv] ty     -- ty[tv] ~ t[xi]
1155              ty'   = substTyWith   [tv] [xi] ty
1156        ; ipid' <- newIPVar nm ty'
1157        ; case gw of
1158            Wanted {}         -> setIPBind ipid  (EvCast ipid' (mkSymCo ip_co))
1159            Given {}          -> setIPBind ipid' (EvCast ipid ip_co)
1160            Derived {}        -> return () -- Derived ips: we don't set any evidence
1161
1162        ; return (CIPCan { cc_id = ipid'
1163                         , cc_flavor = gw
1164                         , cc_ip_nm = nm
1165                         , cc_ip_ty = ty' }) }
1166
1167 rewriteFunEq :: (CoVar,TcTyVar,Xi) -> (CoVar,CtFlavor,TyCon, [Xi], Xi) -> TcS CanonicalCt
1168 rewriteFunEq (cv1,tv,xi1) (cv2,gw, tc,args,xi2)                   -- cv2 :: F args ~ xi2
1169   = do { let co_subst = liftCoSubstWith [tv] [mkCoVarCo cv1]
1170              arg_cos  = map co_subst args
1171              args'    = substTysWith [tv] [xi1] args
1172              fun_co   = mkTyConAppCo tc arg_cos                -- fun_co :: F args ~ F args'
1173
1174              xi2'    = substTyWith [tv] [xi1] xi2
1175              xi2_co  = co_subst xi2 -- xi2_co :: xi2 ~ xi2'
1176
1177        ; cv2' <- newCoVar (mkTyConApp tc args') xi2'
1178        ; case gw of
1179            Wanted {} -> setCoBind cv2  (fun_co         `mkTransCo`
1180                                         mkCoVarCo cv2' `mkTransCo`
1181                                         mkSymCo xi2_co)
1182            Given {}  -> setCoBind cv2' (mkSymCo fun_co `mkTransCo`
1183                                         mkCoVarCo cv2  `mkTransCo`
1184                                         xi2_co)
1185            Derived {} -> return ()
1186
1187        ; return (CFunEqCan { cc_id = cv2'
1188                            , cc_flavor = gw
1189                            , cc_tyargs = args'
1190                            , cc_fun = tc
1191                            , cc_rhs = xi2' }) }
1192
1193
1194 rewriteEqRHS :: (CoVar,TcTyVar,Xi) -> (CoVar,CtFlavor,TcTyVar,Xi) -> TcS WorkList
1195 -- Use the first equality to rewrite the second, flavors already checked.
1196 -- E.g.          c1 : tv1 ~ xi1   c2 : tv2 ~ xi2
1197 -- rewrites c2 to give
1198 --               c2' : tv2 ~ xi2[xi1/tv1]
1199 -- We must do an occurs check to sure the new constraint is canonical
1200 -- So we might return an empty bag
1201 rewriteEqRHS (cv1,tv1,xi1) (cv2,gw,tv2,xi2)
1202   | Just tv2' <- tcGetTyVar_maybe xi2'
1203   , tv2 == tv2'  -- In this case xi2[xi1/tv1] = tv2, so we have tv2~tv2
1204   = do { when (isWanted gw) (setCoBind cv2 (mkSymCo co2'))
1205        ; return emptyWorkList }
1206   | otherwise
1207   = do { cv2' <- newCoVar (mkTyVarTy tv2) xi2'
1208        ; case gw of
1209              Wanted {} -> setCoBind cv2 $ mkCoVarCo cv2' `mkTransCo`
1210                                           mkSymCo co2'
1211              Given {}  -> setCoBind cv2' $ mkCoVarCo cv2 `mkTransCo`
1212                                            co2'
1213              Derived {} -> return ()
1214        ; canEqToWorkList gw cv2' (mkTyVarTy tv2) xi2' }
1215   where
1216     xi2' = substTyWith [tv1] [xi1] xi2
1217     co2' = liftCoSubstWith [tv1] [mkCoVarCo cv1] xi2  -- xi2 ~ xi2[xi1/tv1]
1218
1219 rewriteEqLHS :: WhichComesFromInert -> (Coercion,Xi) -> (CoVar,CtFlavor,Xi) -> TcS WorkList
1220 -- Used to ineract two equalities of the following form:
1221 -- First Equality:   co1: (XXX ~ xi1)
1222 -- Second Equality:  cv2: (XXX ~ xi2)
1223 -- Where the cv1 `canRewrite` cv2 equality
1224 -- We have an option of creating new work (xi1 ~ xi2) OR (xi2 ~ xi1),
1225 --    See Note [Efficient Orientation] for that
1226 rewriteEqLHS LeftComesFromInert (co1,xi1) (cv2,gw,xi2)
1227   = do { cv2' <- newCoVar xi2 xi1
1228        ; case gw of
1229            Wanted {} -> setCoBind cv2 $
1230                         co1 `mkTransCo` mkSymCo (mkCoVarCo cv2')
1231            Given {}  -> setCoBind cv2' $
1232                         mkSymCo (mkCoVarCo cv2) `mkTransCo` co1
1233            Derived {} -> return ()
1234        ; mkCanonical gw cv2' }
1235
1236 rewriteEqLHS RightComesFromInert (co1,xi1) (cv2,gw,xi2)
1237   = do { cv2' <- newCoVar xi1 xi2
1238        ; case gw of
1239            Wanted {} -> setCoBind cv2 $
1240                         co1 `mkTransCo` mkCoVarCo cv2'
1241            Given {}  -> setCoBind cv2' $
1242                         mkSymCo co1 `mkTransCo` mkCoVarCo cv2
1243            Derived {} -> return ()
1244        ; mkCanonical gw cv2' }
1245
1246 rewriteFrozen :: (CoVar,TcTyVar,Xi) -> (CoVar,CtFlavor) -> TcS WorkList
1247 rewriteFrozen (cv1, tv1, xi1) (cv2, fl2)
1248   = do { cv2' <- newCoVar ty2a' ty2b'  -- ty2a[xi1/tv1] ~ ty2b[xi1/tv1]
1249        ; case fl2 of
1250              Wanted {} -> setCoBind cv2 $ co2a'                `mkTransCo`
1251                                           mkCoVarCo cv2' `mkTransCo`
1252                                           mkSymCo co2b'
1253
1254              Given {} -> setCoBind cv2' $ mkSymCo co2a'  `mkTransCo`
1255                                           mkCoVarCo cv2  `mkTransCo`
1256                                           co2b'
1257
1258              Derived {} -> return ()
1259
1260       ; return (workListFromNonEq $ CFrozenErr { cc_id = cv2', cc_flavor = fl2 }) }
1261   where
1262     (ty2a, ty2b) = coVarKind cv2          -- cv2 : ty2a ~ ty2b
1263     ty2a' = substTyWith [tv1] [xi1] ty2a
1264     ty2b' = substTyWith [tv1] [xi1] ty2b
1265
1266     co2a' = liftCoSubstWith [tv1] [mkCoVarCo cv1] ty2a  -- ty2a ~ ty2a[xi1/tv1]
1267     co2b' = liftCoSubstWith [tv1] [mkCoVarCo cv1] ty2b  -- ty2b ~ ty2b[xi1/tv1]
1268
1269 solveOneFromTheOther :: String -> (EvTerm, CtFlavor) -> CanonicalCt -> TcS InteractResult
1270 -- First argument inert, second argument work-item. They both represent
1271 -- wanted/given/derived evidence for the *same* predicate so
1272 -- we can discharge one directly from the other.
1273 --
1274 -- Precondition: value evidence only (implicit parameters, classes)
1275 --               not coercion
1276 solveOneFromTheOther info (ev_term,ifl) workItem
1277   | isDerived wfl
1278   = mkIRStopK ("Solved[DW] " ++ info) emptyWorkList
1279
1280   | isDerived ifl -- The inert item is Derived, we can just throw it away,
1281                   -- The workItem is inert wrt earlier inert-set items,
1282                   -- so it's safe to continue on from this point
1283   = mkIRContinue ("Solved[DI] " ++ info) workItem DropInert emptyWorkList
1284
1285   | otherwise
1286   = ASSERT( ifl `canSolve` wfl )
1287       -- Because of Note [The Solver Invariant], plus Derived dealt with
1288     do { when (isWanted wfl) $ setEvBind wid ev_term
1289            -- Overwrite the binding, if one exists
1290            -- If both are Given, we already have evidence; no need to duplicate
1291        ; mkIRStopK ("Solved " ++ info) emptyWorkList }
1292   where
1293      wfl = cc_flavor workItem
1294      wid = cc_id workItem
1295 \end{code}
1296
1297 Note [Superclasses and recursive dictionaries]
1298 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1299     Overlaps with Note [SUPERCLASS-LOOP 1]
1300                   Note [SUPERCLASS-LOOP 2]
1301                   Note [Recursive instances and superclases]
1302     ToDo: check overlap and delete redundant stuff
1303
1304 Right before adding a given into the inert set, we must
1305 produce some more work, that will bring the superclasses
1306 of the given into scope. The superclass constraints go into
1307 our worklist.
1308
1309 When we simplify a wanted constraint, if we first see a matching
1310 instance, we may produce new wanted work. To (1) avoid doing this work
1311 twice in the future and (2) to handle recursive dictionaries we may ``cache''
1312 this item as given into our inert set WITHOUT adding its superclass constraints,
1313 otherwise we'd be in danger of creating a loop [In fact this was the exact reason
1314 for doing the isGoodRecEv check in an older version of the type checker].
1315
1316 But now we have added partially solved constraints to the worklist which may
1317 interact with other wanteds. Consider the example:
1318
1319 Example 1:
1320
1321     class Eq b => Foo a b        --- 0-th selector
1322     instance Eq a => Foo [a] a   --- fooDFun
1323
1324 and wanted (Foo [t] t). We are first going to see that the instance matches
1325 and create an inert set that includes the solved (Foo [t] t) but not its superclasses:
1326        d1 :_g Foo [t] t                 d1 := EvDFunApp fooDFun d3
1327 Our work list is going to contain a new *wanted* goal
1328        d3 :_w Eq t
1329
1330 Ok, so how do we get recursive dictionaries, at all:
1331
1332 Example 2:
1333
1334     data D r = ZeroD | SuccD (r (D r));
1335
1336     instance (Eq (r (D r))) => Eq (D r) where
1337         ZeroD     == ZeroD     = True
1338         (SuccD a) == (SuccD b) = a == b
1339         _         == _         = False;
1340
1341     equalDC :: D [] -> D [] -> Bool;
1342     equalDC = (==);
1343
1344 We need to prove (Eq (D [])). Here's how we go:
1345
1346         d1 :_w Eq (D [])
1347
1348 by instance decl, holds if
1349         d2 :_w Eq [D []]
1350         where   d1 = dfEqD d2
1351
1352 *BUT* we have an inert set which gives us (no superclasses):
1353         d1 :_g Eq (D [])
1354 By the instance declaration of Eq we can show the 'd2' goal if
1355         d3 :_w Eq (D [])
1356         where   d2 = dfEqList d3
1357                 d1 = dfEqD d2
1358 Now, however this wanted can interact with our inert d1 to set:
1359         d3 := d1
1360 and solve the goal. Why was this interaction OK? Because, if we chase the
1361 evidence of d1 ~~> dfEqD d2 ~~-> dfEqList d3, so by setting d3 := d1 we
1362 are really setting
1363         d3 := dfEqD2 (dfEqList d3)
1364 which is FINE because the use of d3 is protected by the instance function
1365 applications.
1366
1367 So, our strategy is to try to put solved wanted dictionaries into the
1368 inert set along with their superclasses (when this is meaningful,
1369 i.e. when new wanted goals are generated) but solve a wanted dictionary
1370 from a given only in the case where the evidence variable of the
1371 wanted is mentioned in the evidence of the given (recursively through
1372 the evidence binds) in a protected way: more instance function applications
1373 than superclass selectors.
1374
1375 Here are some more examples from GHC's previous type checker
1376
1377
1378 Example 3:
1379 This code arises in the context of "Scrap Your Boilerplate with Class"
1380
1381     class Sat a
1382     class Data ctx a
1383     instance  Sat (ctx Char)             => Data ctx Char       -- dfunData1
1384     instance (Sat (ctx [a]), Data ctx a) => Data ctx [a]        -- dfunData2
1385
1386     class Data Maybe a => Foo a
1387
1388     instance Foo t => Sat (Maybe t)                             -- dfunSat
1389
1390     instance Data Maybe a => Foo a                              -- dfunFoo1
1391     instance Foo a        => Foo [a]                            -- dfunFoo2
1392     instance                 Foo [Char]                         -- dfunFoo3
1393
1394 Consider generating the superclasses of the instance declaration
1395          instance Foo a => Foo [a]
1396
1397 So our problem is this
1398     d0 :_g Foo t
1399     d1 :_w Data Maybe [t]
1400
1401 We may add the given in the inert set, along with its superclasses
1402 [assuming we don't fail because there is a matching instance, see
1403  tryTopReact, given case ]
1404   Inert:
1405     d0 :_g Foo t
1406   WorkList
1407     d01 :_g Data Maybe t  -- d2 := EvDictSuperClass d0 0
1408     d1 :_w Data Maybe [t]
1409 Then d2 can readily enter the inert, and we also do solving of the wanted
1410   Inert:
1411     d0 :_g Foo t
1412     d1 :_s Data Maybe [t]           d1 := dfunData2 d2 d3
1413   WorkList
1414     d2 :_w Sat (Maybe [t])
1415     d3 :_w Data Maybe t
1416     d01 :_g Data Maybe t
1417 Now, we may simplify d2 more:
1418   Inert:
1419       d0 :_g Foo t
1420       d1 :_s Data Maybe [t]           d1 := dfunData2 d2 d3
1421       d1 :_g Data Maybe [t]
1422       d2 :_g Sat (Maybe [t])          d2 := dfunSat d4
1423   WorkList:
1424       d3 :_w Data Maybe t
1425       d4 :_w Foo [t]
1426       d01 :_g Data Maybe t
1427
1428 Now, we can just solve d3.
1429   Inert
1430       d0 :_g Foo t
1431       d1 :_s Data Maybe [t]           d1 := dfunData2 d2 d3
1432       d2 :_g Sat (Maybe [t])          d2 := dfunSat d4
1433   WorkList
1434       d4 :_w Foo [t]
1435       d01 :_g Data Maybe t
1436 And now we can simplify d4 again, but since it has superclasses we *add* them to the worklist:
1437   Inert
1438       d0 :_g Foo t
1439       d1 :_s Data Maybe [t]           d1 := dfunData2 d2 d3
1440       d2 :_g Sat (Maybe [t])          d2 := dfunSat d4
1441       d4 :_g Foo [t]                  d4 := dfunFoo2 d5
1442   WorkList:
1443       d5 :_w Foo t
1444       d6 :_g Data Maybe [t]           d6 := EvDictSuperClass d4 0
1445       d01 :_g Data Maybe t
1446 Now, d5 can be solved! (and its superclass enter scope)
1447   Inert
1448       d0 :_g Foo t
1449       d1 :_s Data Maybe [t]           d1 := dfunData2 d2 d3
1450       d2 :_g Sat (Maybe [t])          d2 := dfunSat d4
1451       d4 :_g Foo [t]                  d4 := dfunFoo2 d5
1452       d5 :_g Foo t                    d5 := dfunFoo1 d7
1453   WorkList:
1454       d7 :_w Data Maybe t
1455       d6 :_g Data Maybe [t]
1456       d8 :_g Data Maybe t            d8 := EvDictSuperClass d5 0
1457       d01 :_g Data Maybe t
1458
1459 Now, two problems:
1460    [1] Suppose we pick d8 and we react him with d01. Which of the two givens should
1461        we keep? Well, we *MUST NOT* drop d01 because d8 contains recursive evidence
1462        that must not be used (look at case interactInert where both inert and workitem
1463        are givens). So we have several options:
1464        - Drop the workitem always (this will drop d8)
1465               This feels very unsafe -- what if the work item was the "good" one
1466               that should be used later to solve another wanted?
1467        - Don't drop anyone: the inert set may contain multiple givens!
1468               [This is currently implemented]
1469
1470 The "don't drop anyone" seems the most safe thing to do, so now we come to problem 2:
1471   [2] We have added both d6 and d01 in the inert set, and we are interacting our wanted
1472       d7. Now the [isRecDictEv] function in the ineration solver
1473       [case inert-given workitem-wanted] will prevent us from interacting d7 := d8
1474       precisely because chasing the evidence of d8 leads us to an unguarded use of d7.
1475
1476       So, no interaction happens there. Then we meet d01 and there is no recursion
1477       problem there [isRectDictEv] gives us the OK to interact and we do solve d7 := d01!
1478
1479 Note [SUPERCLASS-LOOP 1]
1480 ~~~~~~~~~~~~~~~~~~~~~~~~
1481 We have to be very, very careful when generating superclasses, lest we
1482 accidentally build a loop. Here's an example:
1483
1484   class S a
1485
1486   class S a => C a where { opc :: a -> a }
1487   class S b => D b where { opd :: b -> b }
1488
1489   instance C Int where
1490      opc = opd
1491
1492   instance D Int where
1493      opd = opc
1494
1495 From (instance C Int) we get the constraint set {ds1:S Int, dd:D Int}
1496 Simplifying, we may well get:
1497         $dfCInt = :C ds1 (opd dd)
1498         dd  = $dfDInt
1499         ds1 = $p1 dd
1500 Notice that we spot that we can extract ds1 from dd.
1501
1502 Alas!  Alack! We can do the same for (instance D Int):
1503
1504         $dfDInt = :D ds2 (opc dc)
1505         dc  = $dfCInt
1506         ds2 = $p1 dc
1507
1508 And now we've defined the superclass in terms of itself.
1509 Two more nasty cases are in
1510         tcrun021
1511         tcrun033
1512
1513 Solution:
1514   - Satisfy the superclass context *all by itself*
1515     (tcSimplifySuperClasses)
1516   - And do so completely; i.e. no left-over constraints
1517     to mix with the constraints arising from method declarations
1518
1519
1520 Note [SUPERCLASS-LOOP 2]
1521 ~~~~~~~~~~~~~~~~~~~~~~~~
1522 We need to be careful when adding "the constaint we are trying to prove".
1523 Suppose we are *given* d1:Ord a, and want to deduce (d2:C [a]) where
1524
1525         class Ord a => C a where
1526         instance Ord [a] => C [a] where ...
1527
1528 Then we'll use the instance decl to deduce C [a] from Ord [a], and then add the
1529 superclasses of C [a] to avails.  But we must not overwrite the binding
1530 for Ord [a] (which is obtained from Ord a) with a superclass selection or we'll just
1531 build a loop!
1532
1533 Here's another variant, immortalised in tcrun020
1534         class Monad m => C1 m
1535         class C1 m => C2 m x
1536         instance C2 Maybe Bool
1537 For the instance decl we need to build (C1 Maybe), and it's no good if
1538 we run around and add (C2 Maybe Bool) and its superclasses to the avails
1539 before we search for C1 Maybe.
1540
1541 Here's another example
1542         class Eq b => Foo a b
1543         instance Eq a => Foo [a] a
1544 If we are reducing
1545         (Foo [t] t)
1546
1547 we'll first deduce that it holds (via the instance decl).  We must not
1548 then overwrite the Eq t constraint with a superclass selection!
1549
1550 At first I had a gross hack, whereby I simply did not add superclass constraints
1551 in addWanted, though I did for addGiven and addIrred.  This was sub-optimal,
1552 becuase it lost legitimate superclass sharing, and it still didn't do the job:
1553 I found a very obscure program (now tcrun021) in which improvement meant the
1554 simplifier got two bites a the cherry... so something seemed to be an Stop
1555 first time, but reducible next time.
1556
1557 Now we implement the Right Solution, which is to check for loops directly
1558 when adding superclasses.  It's a bit like the occurs check in unification.
1559
1560 Note [Recursive instances and superclases]
1561 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1562 Consider this code, which arises in the context of "Scrap Your
1563 Boilerplate with Class".
1564
1565     class Sat a
1566     class Data ctx a
1567     instance  Sat (ctx Char)             => Data ctx Char
1568     instance (Sat (ctx [a]), Data ctx a) => Data ctx [a]
1569
1570     class Data Maybe a => Foo a
1571
1572     instance Foo t => Sat (Maybe t)
1573
1574     instance Data Maybe a => Foo a
1575     instance Foo a        => Foo [a]
1576     instance                 Foo [Char]
1577
1578 In the instance for Foo [a], when generating evidence for the superclasses
1579 (ie in tcSimplifySuperClasses) we need a superclass (Data Maybe [a]).
1580 Using the instance for Data, we therefore need
1581         (Sat (Maybe [a], Data Maybe a)
1582 But we are given (Foo a), and hence its superclass (Data Maybe a).
1583 So that leaves (Sat (Maybe [a])).  Using the instance for Sat means
1584 we need (Foo [a]).  And that is the very dictionary we are bulding
1585 an instance for!  So we must put that in the "givens".  So in this
1586 case we have
1587         Given:  Foo a, Foo [a]
1588         Wanted: Data Maybe [a]
1589
1590 BUT we must *not not not* put the *superclasses* of (Foo [a]) in
1591 the givens, which is what 'addGiven' would normally do. Why? Because
1592 (Data Maybe [a]) is the superclass, so we'd "satisfy" the wanted
1593 by selecting a superclass from Foo [a], which simply makes a loop.
1594
1595 On the other hand we *must* put the superclasses of (Foo a) in
1596 the givens, as you can see from the derivation described above.
1597
1598 Conclusion: in the very special case of tcSimplifySuperClasses
1599 we have one 'given' (namely the "this" dictionary) whose superclasses
1600 must not be added to 'givens' by addGiven.
1601
1602 There is a complication though.  Suppose there are equalities
1603       instance (Eq a, a~b) => Num (a,b)
1604 Then we normalise the 'givens' wrt the equalities, so the original
1605 given "this" dictionary is cast to one of a different type.  So it's a
1606 bit trickier than before to identify the "special" dictionary whose
1607 superclasses must not be added. See test
1608    indexed-types/should_run/EqInInstance
1609
1610 We need a persistent property of the dictionary to record this
1611 special-ness.  Current I'm using the InstLocOrigin (a bit of a hack,
1612 but cool), which is maintained by dictionary normalisation.
1613 Specifically, the InstLocOrigin is
1614              NoScOrigin
1615 then the no-superclass thing kicks in.  WATCH OUT if you fiddle
1616 with InstLocOrigin!
1617
1618 Note [MATCHING-SYNONYMS]
1619 ~~~~~~~~~~~~~~~~~~~~~~~~
1620 When trying to match a dictionary (D tau) to a top-level instance, or a
1621 type family equation (F taus_1 ~ tau_2) to a top-level family instance,
1622 we do *not* need to expand type synonyms because the matcher will do that for us.
1623
1624
1625 Note [RHS-FAMILY-SYNONYMS]
1626 ~~~~~~~~~~~~~~~~~~~~~~~~~~
1627 The RHS of a family instance is represented as yet another constructor which is
1628 like a type synonym for the real RHS the programmer declared. Eg:
1629     type instance F (a,a) = [a]
1630 Becomes:
1631     :R32 a = [a]      -- internal type synonym introduced
1632     F (a,a) ~ :R32 a  -- instance
1633
1634 When we react a family instance with a type family equation in the work list
1635 we keep the synonym-using RHS without expansion.
1636
1637
1638 *********************************************************************************
1639 *                                                                               *
1640                        The top-reaction Stage
1641 *                                                                               *
1642 *********************************************************************************
1643
1644 \begin{code}
1645 -- If a work item has any form of interaction with top-level we get this
1646 data TopInteractResult
1647   = NoTopInt         -- No top-level interaction
1648                      -- Equivalent to (SomeTopInt emptyWorkList (ContinueWith work_item))
1649   | SomeTopInt
1650       { tir_new_work  :: WorkList       -- Sub-goals or new work (could be given,
1651                                         --                        for superclasses)
1652       , tir_new_inert :: StopOrContinue -- The input work item, ready to become *inert* now:
1653       }                                 -- NB: in ``given'' (solved) form if the
1654                                         -- original was wanted or given and instance match
1655                                         -- was found, but may also be in wanted form if we
1656                                         -- only reacted with functional dependencies
1657                                         -- arising from top-level instances.
1658
1659 topReactionsStage :: SimplifierStage
1660 topReactionsStage depth workItem inerts
1661   = do { tir <- tryTopReact workItem
1662        ; case tir of
1663            NoTopInt ->
1664                return $ SR { sr_inerts   = inerts
1665                            , sr_new_work = emptyWorkList
1666                            , sr_stop     = ContinueWith workItem }
1667            SomeTopInt tir_new_work tir_new_inert ->
1668                do { bumpStepCountTcS
1669                   ; traceFireTcS depth (ptext (sLit "Top react")
1670                        <+> vcat [ ptext (sLit "Work =") <+> ppr workItem
1671                                 , ptext (sLit "New =") <+> ppr tir_new_work ])
1672                   ; return $ SR { sr_inerts   = inerts
1673                                 , sr_new_work = tir_new_work
1674                                 , sr_stop     = tir_new_inert
1675                                 } }
1676        }
1677
1678 tryTopReact :: WorkItem -> TcS TopInteractResult
1679 tryTopReact workitem
1680   = do {  -- A flag controls the amount of interaction allowed
1681           -- See Note [Simplifying RULE lhs constraints]
1682          ctxt <- getTcSContext
1683        ; if allowedTopReaction (simplEqsOnly ctxt) workitem
1684          then do { traceTcS "tryTopReact / calling doTopReact" (ppr workitem)
1685                  ; doTopReact workitem }
1686          else return NoTopInt
1687        }
1688
1689 allowedTopReaction :: Bool -> WorkItem -> Bool
1690 allowedTopReaction eqs_only (CDictCan {}) = not eqs_only
1691 allowedTopReaction _        _             = True
1692
1693 doTopReact :: WorkItem -> TcS TopInteractResult
1694 -- The work item does not react with the inert set, so try interaction with top-level instances
1695 -- NB: The place to add superclasses in *not* in doTopReact stage. Instead superclasses are
1696 --     added in the worklist as part of the canonicalisation process.
1697 -- See Note [Adding superclasses] in TcCanonical.
1698
1699 -- Given dictionary
1700 -- See Note [Given constraint that matches an instance declaration]
1701 doTopReact (CDictCan { cc_flavor = Given {} })
1702   = return NoTopInt -- NB: Superclasses already added since it's canonical
1703
1704 -- Derived dictionary: just look for functional dependencies
1705 doTopReact workItem@(CDictCan { cc_flavor = fl@(Derived loc)
1706                               , cc_class = cls, cc_tyargs = xis })
1707   = do { instEnvs <- getInstEnvs
1708        ; let fd_eqns = improveFromInstEnv instEnvs
1709                                                 (ClassP cls xis, pprArisingAt loc)
1710        ; m <- rewriteWithFunDeps fd_eqns xis fl
1711        ; case m of
1712            Nothing -> return NoTopInt
1713            Just (xis',_,fd_work) ->
1714                let workItem' = workItem { cc_tyargs = xis' }
1715                    -- Deriveds are not supposed to have identity (cc_id is unused!)
1716                in return $ SomeTopInt { tir_new_work  = fd_work
1717                                       , tir_new_inert = ContinueWith workItem' } }
1718
1719 -- Wanted dictionary
1720 doTopReact workItem@(CDictCan { cc_id = dv, cc_flavor = fl@(Wanted loc)
1721                               , cc_class = cls, cc_tyargs = xis })
1722   = do { -- See Note [MATCHING-SYNONYMS]
1723        ; lkp_inst_res <- matchClassInst cls xis loc
1724        ; case lkp_inst_res of
1725            NoInstance ->
1726              do { traceTcS "doTopReact/ no class instance for" (ppr dv)
1727
1728                 ; instEnvs <- getInstEnvs
1729                 ; let fd_eqns = improveFromInstEnv instEnvs
1730                                                          (ClassP cls xis, pprArisingAt loc)
1731                 ; m <- rewriteWithFunDeps fd_eqns xis fl
1732                 ; case m of
1733                     Nothing -> return NoTopInt
1734                     Just (xis',cos,fd_work) ->
1735                         do { let dict_co = mkTyConAppCo (classTyCon cls) cos
1736                            ; dv'<- newDictVar cls xis'
1737                            ; setDictBind dv (EvCast dv' dict_co)
1738                            ; let workItem' = CDictCan { cc_id = dv', cc_flavor = fl,
1739                                                         cc_class = cls, cc_tyargs = xis' }
1740                            ; return $
1741                              SomeTopInt { tir_new_work  = workListFromNonEq workItem' `unionWorkList` fd_work
1742                                         , tir_new_inert = Stop } } }
1743
1744            GenInst wtvs ev_term -- Solved
1745                    -- No need to do fundeps stuff here; the instance
1746                    -- matches already so we won't get any more info
1747                    -- from functional dependencies
1748              | null wtvs
1749              -> do { traceTcS "doTopReact/ found nullary class instance for" (ppr dv)
1750                    ; setDictBind dv ev_term
1751                     -- Solved in one step and no new wanted work produced.
1752                     -- i.e we directly matched a top-level instance
1753                     -- No point in caching this in 'inert'; hence Stop
1754                    ; return $ SomeTopInt { tir_new_work  = emptyWorkList
1755                                          , tir_new_inert = Stop } }
1756
1757              | otherwise
1758              -> do { traceTcS "doTopReact/ found nullary class instance for" (ppr dv)
1759                    ; setDictBind dv ev_term
1760                         -- Solved and new wanted work produced, you may cache the
1761                         -- (tentatively solved) dictionary as Given! (used to be: Derived)
1762                    ; let solved   = workItem { cc_flavor = given_fl }
1763                          given_fl = Given (setCtLocOrigin loc UnkSkol)
1764                    ; inst_work <- canWanteds wtvs
1765                    ; return $ SomeTopInt { tir_new_work  = inst_work
1766                                          , tir_new_inert = ContinueWith solved } }
1767        }
1768
1769 -- Type functions
1770 doTopReact (CFunEqCan { cc_id = cv, cc_flavor = fl
1771                       , cc_fun = tc, cc_tyargs = args, cc_rhs = xi })
1772   = ASSERT (isSynFamilyTyCon tc)   -- No associated data families have reached that far
1773     do { match_res <- matchFam tc args -- See Note [MATCHING-SYNONYMS]
1774        ; case match_res of
1775            MatchInstNo
1776              -> return NoTopInt
1777            MatchInstSingle (rep_tc, rep_tys)
1778              -> do { let Just coe_tc = tyConFamilyCoercion_maybe rep_tc
1779                          Just rhs_ty = tcView (mkTyConApp rep_tc rep_tys)
1780                             -- Eagerly expand away the type synonym on the
1781                             -- RHS of a type function, so that it never
1782                             -- appears in an error message
1783                             -- See Note [Type synonym families] in TyCon
1784                          coe = mkAxInstCo coe_tc rep_tys
1785                    ; cv' <- case fl of
1786                               Wanted {} -> do { cv' <- newCoVar rhs_ty xi
1787                                               ; setCoBind cv $
1788                                                     coe `mkTransCo`
1789                                                       mkCoVarCo cv'
1790                                               ; return cv' }
1791                               Given {}   -> newGivenCoVar xi rhs_ty $
1792                                             mkSymCo (mkCoVarCo cv) `mkTransCo` coe
1793                               Derived {} -> newDerivedId (EqPred xi rhs_ty)
1794                    ; can_cts <- mkCanonical fl cv'
1795                    ; return $ SomeTopInt can_cts Stop }
1796            _
1797              -> panicTcS $ text "TcSMonad.matchFam returned multiple instances!"
1798        }
1799
1800
1801 -- Any other work item does not react with any top-level equations
1802 doTopReact _workItem = return NoTopInt
1803 \end{code}
1804
1805
1806 Note [FunDep and implicit parameter reactions]
1807 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1808 Currently, our story of interacting two dictionaries (or a dictionary
1809 and top-level instances) for functional dependencies, and implicit
1810 paramters, is that we simply produce new wanted equalities.  So for example
1811
1812         class D a b | a -> b where ...
1813     Inert:
1814         d1 :g D Int Bool
1815     WorkItem:
1816         d2 :w D Int alpha
1817
1818     We generate the extra work item
1819         cv :w alpha ~ Bool
1820     where 'cv' is currently unused.  However, this new item reacts with d2,
1821     discharging it in favour of a new constraint d2' thus:
1822         d2' :w D Int Bool
1823         d2 := d2' |> D Int cv
1824     Now d2' can be discharged from d1
1825
1826 We could be more aggressive and try to *immediately* solve the dictionary
1827 using those extra equalities. With the same inert set and work item we
1828 might dischard d2 directly:
1829
1830         cv :w alpha ~ Bool
1831         d2 := d1 |> D Int cv
1832
1833 But in general it's a bit painful to figure out the necessary coercion,
1834 so we just take the first approach. Here is a better example. Consider:
1835     class C a b c | a -> b
1836 And:
1837      [Given]  d1 : C T Int Char
1838      [Wanted] d2 : C T beta Int
1839 In this case, it's *not even possible* to solve the wanted immediately.
1840 So we should simply output the functional dependency and add this guy
1841 [but NOT its superclasses] back in the worklist. Even worse:
1842      [Given] d1 : C T Int beta
1843      [Wanted] d2: C T beta Int
1844 Then it is solvable, but its very hard to detect this on the spot.
1845
1846 It's exactly the same with implicit parameters, except that the
1847 "aggressive" approach would be much easier to implement.
1848
1849 Note [When improvement happens]
1850 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1851 We fire an improvement rule when
1852
1853   * Two constraints match (modulo the fundep)
1854       e.g. C t1 t2, C t1 t3    where C a b | a->b
1855     The two match because the first arg is identical
1856
1857   * At least one is not Given.  If they are both given, we don't fire
1858     the reaction because we have no way of constructing evidence for a
1859     new equality nor does it seem right to create a new wanted goal
1860     (because the goal will most likely contain untouchables, which
1861     can't be solved anyway)!
1862
1863 Note that we *do* fire the improvement if one is Given and one is Derived.
1864 The latter can be a superclass of a wanted goal. Example (tcfail138)
1865     class L a b | a -> b
1866     class (G a, L a b) => C a b
1867
1868     instance C a b' => G (Maybe a)
1869     instance C a b  => C (Maybe a) a
1870     instance L (Maybe a) a
1871
1872 When solving the superclasses of the (C (Maybe a) a) instance, we get
1873   Given:  C a b  ... and hance by superclasses, (G a, L a b)
1874   Wanted: G (Maybe a)
1875 Use the instance decl to get
1876   Wanted: C a b'
1877 The (C a b') is inert, so we generate its Derived superclasses (L a b'),
1878 and now we need improvement between that derived superclass an the Given (L a b)
1879
1880 Note [Overriding implicit parameters]
1881 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1882 Consider
1883    f :: (?x::a) -> Bool -> a
1884
1885    g v = let ?x::Int = 3
1886          in (f v, let ?x::Bool = True in f v)
1887
1888 This should probably be well typed, with
1889    g :: Bool -> (Int, Bool)
1890
1891 So the inner binding for ?x::Bool *overrides* the outer one.
1892 Hence a work-item Given overrides an inert-item Given.
1893
1894 Note [Given constraint that matches an instance declaration]
1895 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1896 What should we do when we discover that one (or more) top-level
1897 instances match a given (or solved) class constraint? We have
1898 two possibilities:
1899
1900   1. Reject the program. The reason is that there may not be a unique
1901      best strategy for the solver. Example, from the OutsideIn(X) paper:
1902        instance P x => Q [x]
1903        instance (x ~ y) => R [x] y
1904
1905        wob :: forall a b. (Q [b], R b a) => a -> Int
1906
1907        g :: forall a. Q [a] => [a] -> Int
1908        g x = wob x
1909
1910        will generate the impliation constraint:
1911             Q [a] => (Q [beta], R beta [a])
1912        If we react (Q [beta]) with its top-level axiom, we end up with a
1913        (P beta), which we have no way of discharging. On the other hand,
1914        if we react R beta [a] with the top-level we get  (beta ~ a), which
1915        is solvable and can help us rewrite (Q [beta]) to (Q [a]) which is
1916        now solvable by the given Q [a].
1917
1918      However, this option is restrictive, for instance [Example 3] from
1919      Note [Recursive dictionaries] will fail to work.
1920
1921   2. Ignore the problem, hoping that the situations where there exist indeed
1922      such multiple strategies are rare: Indeed the cause of the previous
1923      problem is that (R [x] y) yields the new work (x ~ y) which can be
1924      *spontaneously* solved, not using the givens.
1925
1926 We are choosing option 2 below but we might consider having a flag as well.
1927
1928
1929 Note [New Wanted Superclass Work]
1930 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1931 Even in the case of wanted constraints, we may add some superclasses
1932 as new given work. The reason is:
1933
1934         To allow FD-like improvement for type families. Assume that
1935         we have a class
1936              class C a b | a -> b
1937         and we have to solve the implication constraint:
1938              C a b => C a beta
1939         Then, FD improvement can help us to produce a new wanted (beta ~ b)
1940
1941         We want to have the same effect with the type family encoding of
1942         functional dependencies. Namely, consider:
1943              class (F a ~ b) => C a b
1944         Now suppose that we have:
1945                given: C a b
1946                wanted: C a beta
1947         By interacting the given we will get given (F a ~ b) which is not
1948         enough by itself to make us discharge (C a beta). However, we
1949         may create a new derived equality from the super-class of the
1950         wanted constraint (C a beta), namely derived (F a ~ beta).
1951         Now we may interact this with given (F a ~ b) to get:
1952                   derived :  beta ~ b
1953         But 'beta' is a touchable unification variable, and hence OK to
1954         unify it with 'b', replacing the derived evidence with the identity.
1955
1956         This requires trySpontaneousSolve to solve *derived*
1957         equalities that have a touchable in their RHS, *in addition*
1958         to solving wanted equalities.
1959
1960 We also need to somehow use the superclasses to quantify over a minimal,
1961 constraint see note [Minimize by Superclasses] in TcSimplify.
1962
1963
1964 Finally, here is another example where this is useful.
1965
1966 Example 1:
1967 ----------
1968    class (F a ~ b) => C a b
1969 And we are given the wanteds:
1970       w1 : C a b
1971       w2 : C a c
1972       w3 : b ~ c
1973 We surely do *not* want to quantify over (b ~ c), since if someone provides
1974 dictionaries for (C a b) and (C a c), these dictionaries can provide a proof
1975 of (b ~ c), hence no extra evidence is necessary. Here is what will happen:
1976
1977      Step 1: We will get new *given* superclass work,
1978              provisionally to our solving of w1 and w2
1979
1980                g1: F a ~ b, g2 : F a ~ c,
1981                w1 : C a b, w2 : C a c, w3 : b ~ c
1982
1983              The evidence for g1 and g2 is a superclass evidence term:
1984
1985                g1 := sc w1, g2 := sc w2
1986
1987      Step 2: The givens will solve the wanted w3, so that
1988                w3 := sym (sc w1) ; sc w2
1989
1990      Step 3: Now, one may naively assume that then w2 can be solve from w1
1991              after rewriting with the (now solved equality) (b ~ c).
1992
1993              But this rewriting is ruled out by the isGoodRectDict!
1994
1995 Conclusion, we will (correctly) end up with the unsolved goals
1996     (C a b, C a c)
1997
1998 NB: The desugarer needs be more clever to deal with equalities
1999     that participate in recursive dictionary bindings.
2000
2001 \begin{code}
2002 data LookupInstResult
2003   = NoInstance
2004   | GenInst [WantedEvVar] EvTerm
2005
2006 matchClassInst :: Class -> [Type] -> WantedLoc -> TcS LookupInstResult
2007 matchClassInst clas tys loc
2008    = do { let pred = mkClassPred clas tys
2009         ; mb_result <- matchClass clas tys
2010         ; case mb_result of
2011             MatchInstNo   -> return NoInstance
2012             MatchInstMany -> return NoInstance -- defer any reactions of a multitude until
2013                                                -- we learn more about the reagent
2014             MatchInstSingle (dfun_id, mb_inst_tys) ->
2015               do { checkWellStagedDFun pred dfun_id loc
2016
2017         -- It's possible that not all the tyvars are in
2018         -- the substitution, tenv. For example:
2019         --      instance C X a => D X where ...
2020         -- (presumably there's a functional dependency in class C)
2021         -- Hence mb_inst_tys :: Either TyVar TcType
2022
2023                  ; tys <- instDFunTypes mb_inst_tys
2024                  ; let (theta, _) = tcSplitPhiTy (applyTys (idType dfun_id) tys)
2025                  ; if null theta then
2026                        return (GenInst [] (EvDFunApp dfun_id tys []))
2027                    else do
2028                      { ev_vars <- instDFunConstraints theta
2029                      ; let wevs = [EvVarX w loc | w <- ev_vars]
2030                      ; return $ GenInst wevs (EvDFunApp dfun_id tys ev_vars) }
2031                  }
2032         }
2033 \end{code}