compiler/typecheck/TcMType.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Monadic type operations
   7
   8 This module contains monadic operations over types that contain
   9 mutable type variables
  10
  11 \begin{code}
  12 module TcMType (
  13   TcTyVar, TcKind, TcType, TcTauType, TcThetaType, TcTyVarSet,
  14
  15   --------------------------------
  16   -- Creating new mutable type variables
  17   newFlexiTyVar,
  18   newFlexiTyVarTy,              -- Kind -> TcM TcType
  19   newFlexiTyVarTys,             -- Int -> Kind -> TcM [TcType]
  20   newKindVar, newKindVars,
  21   lookupTcTyVar, LookupTyVarResult(..),
  22
  23   newMetaTyVar, readMetaTyVar, writeMetaTyVar, isFilledMetaTyVar,
  24
  25   --------------------------------
  26   -- Boxy type variables
  27   newBoxyTyVar, newBoxyTyVars, newBoxyTyVarTys, readFilledBox,
  28
  29   --------------------------------
  30   -- Creating new coercion variables
  31   newCoVars, newMetaCoVar,
  32
  33   --------------------------------
  34   -- Instantiation
  35   tcInstTyVar, tcInstType, tcInstTyVars, tcInstBoxyTyVar,
  36   tcInstSigType,
  37   tcInstSkolTyVars, tcInstSkolType,
  38   tcSkolSigType, tcSkolSigTyVars, occurCheckErr,
  39
  40   --------------------------------
  41   -- Checking type validity
  42   Rank, UserTypeCtxt(..), checkValidType, checkValidMonoType,
  43   SourceTyCtxt(..), checkValidTheta, checkFreeness,
  44   checkValidInstHead, checkValidInstance,
  45   checkInstTermination, checkValidTypeInst, checkTyFamFreeness,
  46   checkUpdateMeta, updateMeta, checkTauTvUpdate, fillBoxWithTau, unifyKindCtxt,
  47   unifyKindMisMatch, validDerivPred, arityErr, notMonoType, notMonoArgs,
  48
  49   --------------------------------
  50   -- Zonking
  51   zonkType, zonkTcPredType,
  52   zonkTcTyVar, zonkTcTyVars, zonkTcTyVarsAndFV, zonkSigTyVar,
  53   zonkQuantifiedTyVar, zonkQuantifiedTyVars,
  54   zonkTcType, zonkTcTypes, zonkTcThetaType,
  55   zonkTcKindToKind, zonkTcKind, zonkTopTyVar,
  56
  57   readKindVar, writeKindVar
  58   ) where
  59
  60 #include "HsVersions.h"
  61
  62 -- friends:
  63 import TypeRep
  64 import TcType
  65 import Type
  66 import Coercion
  67 import Class
  68 import TyCon
  69 import Var
  70
  71 -- others:
  72 import TcRnMonad          -- TcType, amongst others
  73 import FunDeps
  74 import Name
  75 import VarEnv
  76 import VarSet
  77 import ErrUtils
  78 import DynFlags
  79 import Util
  80 import Maybes
  81 import ListSetOps
  82 import UniqSupply
  83 import SrcLoc
  84 import Outputable
  85 import FastString
  86
  87 import Control.Monad
  88 import Data.List        ( (\\) )
  89 \end{code}
  90
  91
  92 %************************************************************************
  93 %*                                                                      *
  94         Instantiation in general
  95 %*                                                                      *
  96 %************************************************************************
  97
  98 \begin{code}
  99 tcInstType :: ([TyVar] -> TcM [TcTyVar])                -- How to instantiate the type variables
 100            -> TcType                                    -- Type to instantiate
 101            -> TcM ([TcTyVar], TcThetaType, TcType)      -- Result
 102                 -- (type vars (excl coercion vars), preds (incl equalities), rho)
 103 tcInstType inst_tyvars ty
 104   = case tcSplitForAllTys ty of
 105         ([],     rho) -> let    -- There may be overloading despite no type variables;
 106                                 --      (?x :: Int) => Int -> Int
 107                            (theta, tau) = tcSplitPhiTy rho
 108                          in
 109                          return ([], theta, tau)
 110
 111         (tyvars, rho) -> do { tyvars' <- inst_tyvars tyvars
 112
 113                             ; let  tenv = zipTopTvSubst tyvars (mkTyVarTys tyvars')
 114                                 -- Either the tyvars are freshly made, by inst_tyvars,
 115                                 -- or (in the call from tcSkolSigType) any nested foralls
 116                                 -- have different binders.  Either way, zipTopTvSubst is ok
 117
 118                             ; let  (theta, tau) = tcSplitPhiTy (substTy tenv rho)
 119                             ; return (tyvars', theta, tau) }
 120 \end{code}
 121
 122
 123 %************************************************************************
 124 %*                                                                      *
 125         Updating tau types
 126 %*                                                                      *
 127 %************************************************************************
 128
 129 Can't be in TcUnify, as we also need it in TcTyFuns.
 130
 131 \begin{code}
 132 type SwapFlag = Bool
 133         -- False <=> the two args are (actual, expected) respectively
 134         -- True  <=> the two args are (expected, actual) respectively
 135
 136 checkUpdateMeta :: SwapFlag
 137                 -> TcTyVar -> IORef MetaDetails -> TcType -> TcM ()
 138 -- Update tv1, which is flexi; occurs check is alrady done
 139 -- The 'check' version does a kind check too
 140 -- We do a sub-kind check here: we might unify (a b) with (c d)
 141 --      where b::*->* and d::*; this should fail
 142
 143 checkUpdateMeta swapped tv1 ref1 ty2
 144   = do  { checkKinds swapped tv1 ty2
 145         ; updateMeta tv1 ref1 ty2 }
 146
 147 updateMeta :: TcTyVar -> IORef MetaDetails -> TcType -> TcM ()
 148 updateMeta tv1 ref1 ty2
 149   = ASSERT( isMetaTyVar tv1 )
 150     ASSERT( isBoxyTyVar tv1 || isTauTy ty2 )
 151     do  { ASSERTM2( do { details <- readMetaTyVar tv1; return (isFlexi details) }, ppr tv1 )
 152         ; traceTc (text "updateMeta" <+> ppr tv1 <+> text ":=" <+> ppr ty2)
 153         ; writeMutVar ref1 (Indirect ty2)
 154         }
 155
 156 ----------------
 157 checkKinds :: Bool -> TyVar -> Type -> TcM ()
 158 checkKinds swapped tv1 ty2
 159 -- We're about to unify a type variable tv1 with a non-tyvar-type ty2.
 160 -- ty2 has been zonked at this stage, which ensures that
 161 -- its kind has as much boxity information visible as possible.
 162   | tk2 `isSubKind` tk1 = return ()
 163
 164   | otherwise
 165         -- Either the kinds aren't compatible
 166         --      (can happen if we unify (a b) with (c d))
 167         -- or we are unifying a lifted type variable with an
 168         --      unlifted type: e.g.  (id 3#) is illegal
 169   = addErrCtxtM (unifyKindCtxt swapped tv1 ty2) $
 170     unifyKindMisMatch k1 k2
 171   where
 172     (k1,k2) | swapped   = (tk2,tk1)
 173             | otherwise = (tk1,tk2)
 174     tk1 = tyVarKind tv1
 175     tk2 = typeKind ty2
 176
 177 ----------------
 178 checkTauTvUpdate :: TcTyVar -> TcType -> TcM (Maybe TcType)
 179 --    (checkTauTvUpdate tv ty)
 180 -- We are about to update the TauTv tv with ty.
 181 -- Check (a) that tv doesn't occur in ty (occurs check)
 182 --       (b) that ty is a monotype
 183 -- Furthermore, in the interest of (b), if you find an
 184 -- empty box (BoxTv that is Flexi), fill it in with a TauTv
 185 --
 186 -- We have three possible outcomes:
 187 -- (1) Return the (non-boxy) type to update the type variable with,
 188 --     [we know the update is ok!]
 189 -- (2) return Nothing, or
 190 --     [we cannot tell whether the update is ok right now]
 191 -- (3) fails.
 192 --     [the update is definitely invalid]
 193 -- We return Nothing in case the tv occurs in ty *under* a type family
 194 -- application.  In this case, we must not update tv (to avoid a cyclic type
 195 -- term), but we also cannot fail claiming an infinite type.  Given
 196 --   type family F a
 197 --   type instance F Int = Int
 198 -- consider
 199 --   a ~ F a
 200 -- This is perfectly reasonable, if we later get a ~ Int.
 201
 202 checkTauTvUpdate orig_tv orig_ty
 203   = do { result <- go orig_ty
 204        ; case result of
 205            Right ty    -> return $ Just ty
 206            Left  True  -> return $ Nothing
 207            Left  False -> occurCheckErr (mkTyVarTy orig_tv) orig_ty
 208        }
 209   where
 210     go :: TcType -> TcM (Either Bool TcType)
 211     -- go returns
 212     --   Right ty    if everything is fine
 213     --   Left True   if orig_tv occurs in orig_ty, but under a type family app
 214     --   Left False  if orig_tv occurs in orig_ty (with no type family app)
 215     -- It fails if it encounters a forall type, except as an argument for a
 216     -- closed type synonym that expands to a tau type.
 217     go (TyConApp tc tys)
 218         | isSynTyCon tc  = go_syn tc tys
 219         | otherwise      = do { tys' <- mapM go tys
 220                               ; return $ occurs (TyConApp tc) tys' }
 221     go (PredTy p)             = do { p' <- go_pred p
 222                               ; return $ occurs1 PredTy p' }
 223     go (FunTy arg res)   = do { arg' <- go arg
 224                               ; res' <- go res
 225                               ; return $ occurs2 FunTy arg' res' }
 226     go (AppTy fun arg)   = do { fun' <- go fun
 227                               ; arg' <- go arg
 228                               ; return $ occurs2 mkAppTy fun' arg' }
 229                 -- NB the mkAppTy; we might have instantiated a
 230                 -- type variable to a type constructor, so we need
 231                 -- to pull the TyConApp to the top.
 232     go (ForAllTy _ _) = notMonoType orig_ty             -- (b)
 233
 234     go (TyVarTy tv)
 235         | orig_tv == tv = return $ Left False           -- (a)
 236         | isTcTyVar tv  = go_tyvar tv (tcTyVarDetails tv)
 237         | otherwise     = return $ Right (TyVarTy tv)
 238                  -- Ordinary (non Tc) tyvars
 239                  -- occur inside quantified types
 240
 241     go_pred (ClassP c tys) = do { tys' <- mapM go tys
 242                                 ; return $ occurs (ClassP c) tys' }
 243     go_pred (IParam n ty)  = do { ty' <- go ty
 244                                 ; return $ occurs1 (IParam n) ty' }
 245     go_pred (EqPred t1 t2) = do { t1' <- go t1
 246                                 ; t2' <- go t2
 247                                 ; return $ occurs2 EqPred t1' t2' }
 248
 249     go_tyvar tv (SkolemTv _) = return $ Right (TyVarTy tv)
 250     go_tyvar tv (MetaTv box ref)
 251         = do { cts <- readMutVar ref
 252              ; case cts of
 253                   Indirect ty -> go ty
 254                   Flexi -> case box of
 255                                 BoxTv -> do { ty <- fillBoxWithTau tv ref
 256                                             ; return $ Right ty }
 257                                 _     -> return $ Right (TyVarTy tv)
 258              }
 259
 260         -- go_syn is called for synonyms only
 261         -- See Note [Type synonyms and the occur check]
 262     go_syn tc tys
 263         | not (isTauTyCon tc)
 264         = notMonoType orig_ty   -- (b) again
 265         | otherwise
 266         = do { (_msgs, mb_tys') <- tryTc (mapM go tys)
 267              ; case mb_tys' of
 268
 269                 -- we had a type error => forall in type parameters
 270                 Nothing
 271                   | isOpenTyCon tc -> notMonoArgs (TyConApp tc tys)
 272                         -- Synonym families must have monotype args
 273                   | otherwise      -> go (expectJust "checkTauTvUpdate(1)"
 274                                             (tcView (TyConApp tc tys)))
 275                         -- Try again, expanding the synonym
 276
 277                 -- no type error, but need to test whether occurs check happend
 278                 Just tys' ->
 279                   case occurs id tys' of
 280                     Left _
 281                       | isOpenTyCon tc -> return $ Left True
 282                         -- Variable occured under type family application
 283                       | otherwise      -> go (expectJust "checkTauTvUpdate(2)"
 284                                                (tcView (TyConApp tc tys)))
 285                         -- Try again, expanding the synonym
 286                     Right raw_tys'     -> return $ Right (TyConApp tc raw_tys')
 287                         -- Retain the synonym (the common case)
 288              }
 289
 290     -- Left results (= occurrence of orig_ty) dominate and
 291     -- (Left False) (= fatal occurrence) dominates over (Left True)
 292     occurs :: ([a] -> b) -> [Either Bool a] -> Either Bool b
 293     occurs c = either Left (Right . c) . foldr combine (Right [])
 294       where
 295         combine (Left famInst1) (Left famInst2) = Left (famInst1 && famInst2)
 296         combine (Right _      ) (Left famInst)  = Left famInst
 297         combine (Left famInst)  (Right _)       = Left famInst
 298         combine (Right arg)     (Right args)    = Right (arg:args)
 299
 300     occurs1 c x   = occurs (\[x']     -> c x')    [x]
 301     occurs2 c x y = occurs (\[x', y'] -> c x' y') [x, y]
 302
 303 fillBoxWithTau :: BoxyTyVar -> IORef MetaDetails -> TcM TcType
 304 -- (fillBoxWithTau tv ref) fills ref with a freshly allocated
 305 --  tau-type meta-variable, whose print-name is the same as tv
 306 -- Choosing the same name is good: when we instantiate a function
 307 -- we allocate boxy tyvars with the same print-name as the quantified
 308 -- tyvar; and then we often fill the box with a tau-tyvar, and again
 309 -- we want to choose the same name.
 310 fillBoxWithTau tv ref
 311   = do  { tv' <- tcInstTyVar tv         -- Do not gratuitously forget
 312         ; let tau = mkTyVarTy tv'       -- name of the type variable
 313         ; writeMutVar ref (Indirect tau)
 314         ; return tau }
 315 \end{code}
 316
 317 Note [Type synonyms and the occur check]
 318 ~~~~~~~~~~~~~~~~~~~~
 319 Basically we want to update     tv1 := ps_ty2
 320 because ps_ty2 has type-synonym info, which improves later error messages
 321
 322 But consider
 323         type A a = ()
 324
 325         f :: (A a -> a -> ()) -> ()
 326         f = \ _ -> ()
 327
 328         x :: ()
 329         x = f (\ x p -> p x)
 330
 331 In the application (p x), we try to match "t" with "A t".  If we go
 332 ahead and bind t to A t (= ps_ty2), we'll lead the type checker into
 333 an infinite loop later.
 334 But we should not reject the program, because A t = ().
 335 Rather, we should bind t to () (= non_var_ty2).
 336
 337 --------------
 338
 339 Error mesages in case of kind mismatch.
 340
 341 \begin{code}
 342 unifyKindMisMatch :: TcKind -> TcKind -> TcM ()
 343 unifyKindMisMatch ty1 ty2 = do
 344     ty1' <- zonkTcKind ty1
 345     ty2' <- zonkTcKind ty2
 346     let
 347         msg = hang (ptext (sLit "Couldn't match kind"))
 348                    2 (sep [quotes (ppr ty1'),
 349                            ptext (sLit "against"),
 350                            quotes (ppr ty2')])
 351     failWithTc msg
 352
 353 unifyKindCtxt :: Bool -> TyVar -> Type -> TidyEnv -> TcM (TidyEnv, SDoc)
 354 unifyKindCtxt swapped tv1 ty2 tidy_env  -- not swapped => tv1 expected, ty2 inferred
 355         -- tv1 and ty2 are zonked already
 356   = return msg
 357   where
 358     msg = (env2, ptext (sLit "When matching the kinds of") <+>
 359                  sep [quotes pp_expected <+> ptext (sLit "and"), quotes pp_actual])
 360
 361     (pp_expected, pp_actual) | swapped   = (pp2, pp1)
 362                              | otherwise = (pp1, pp2)
 363     (env1, tv1') = tidyOpenTyVar tidy_env tv1
 364     (env2, ty2') = tidyOpenType  env1 ty2
 365     pp1 = ppr tv1' <+> dcolon <+> ppr (tyVarKind tv1)
 366     pp2 = ppr ty2' <+> dcolon <+> ppr (typeKind ty2)
 367 \end{code}
 368
 369 Error message for failure due to an occurs check.
 370
 371 \begin{code}
 372 occurCheckErr :: TcType -> TcType -> TcM a
 373 occurCheckErr ty containingTy
 374   = do  { env0 <- tcInitTidyEnv
 375         ; ty'           <- zonkTcType ty
 376         ; containingTy' <- zonkTcType containingTy
 377         ; let (env1, tidy_ty1) = tidyOpenType env0 ty'
 378               (env2, tidy_ty2) = tidyOpenType env1 containingTy'
 379               extra = sep [ppr tidy_ty1, char '=', ppr tidy_ty2]
 380         ; failWithTcM (env2, hang msg 2 extra) }
 381   where
 382     msg = ptext (sLit "Occurs check: cannot construct the infinite type:")
 383 \end{code}
 384
 385 %************************************************************************
 386 %*                                                                      *
 387         Kind variables
 388 %*                                                                      *
 389 %************************************************************************
 390
 391 \begin{code}
 392 newCoVars :: [(TcType,TcType)] -> TcM [CoVar]
 393 newCoVars spec
 394   = do  { us <- newUniqueSupply
 395         ; return [ mkCoVar (mkSysTvName uniq (fsLit "co"))
 396                            (mkCoKind ty1 ty2)
 397                  | ((ty1,ty2), uniq) <- spec `zip` uniqsFromSupply us] }
 398
 399 newMetaCoVar :: TcType -> TcType -> TcM TcTyVar
 400 newMetaCoVar ty1 ty2 = newMetaTyVar TauTv (mkCoKind ty1 ty2)
 401
 402 newKindVar :: TcM TcKind
 403 newKindVar = do { uniq <- newUnique
 404                 ; ref <- newMutVar Flexi
 405                 ; return (mkTyVarTy (mkKindVar uniq ref)) }
 406
 407 newKindVars :: Int -> TcM [TcKind]
 408 newKindVars n = mapM (\ _ -> newKindVar) (nOfThem n ())
 409 \end{code}
 410
 411
 412 %************************************************************************
 413 %*                                                                      *
 414         SkolemTvs (immutable)
 415 %*                                                                      *
 416 %************************************************************************
 417
 418 \begin{code}
 419 mkSkolTyVar :: Name -> Kind -> SkolemInfo -> TcTyVar
 420 mkSkolTyVar name kind info = mkTcTyVar name kind (SkolemTv info)
 421
 422 tcSkolSigType :: SkolemInfo -> Type -> TcM ([TcTyVar], TcThetaType, TcType)
 423 -- Instantiate a type signature with skolem constants, but
 424 -- do *not* give them fresh names, because we want the name to
 425 -- be in the type environment -- it is lexically scoped.
 426 tcSkolSigType info ty = tcInstType (\tvs -> return (tcSkolSigTyVars info tvs)) ty
 427
 428 tcSkolSigTyVars :: SkolemInfo -> [TyVar] -> [TcTyVar]
 429 -- Make skolem constants, but do *not* give them new names, as above
 430 tcSkolSigTyVars info tyvars = [ mkSkolTyVar (tyVarName tv) (tyVarKind tv) info
 431                               | tv <- tyvars ]
 432
 433 tcInstSkolTyVar :: SkolemInfo -> (Name -> SrcSpan) -> TyVar -> TcM TcTyVar
 434 -- Instantiate the tyvar, using
 435 --      * the occ-name and kind of the supplied tyvar,
 436 --      * the unique from the monad,
 437 --      * the location either from the tyvar (mb_loc = Nothing)
 438 --        or from mb_loc (Just loc)
 439 tcInstSkolTyVar info get_loc tyvar
 440   = do  { uniq <- newUnique
 441         ; let old_name = tyVarName tyvar
 442               kind     = tyVarKind tyvar
 443               loc      = get_loc old_name
 444               new_name = mkInternalName uniq (nameOccName old_name) loc
 445         ; return (mkSkolTyVar new_name kind info) }
 446
 447 tcInstSkolTyVars :: SkolemInfo -> [TyVar] -> TcM [TcTyVar]
 448 -- Get the location from the monad
 449 tcInstSkolTyVars info tyvars
 450   = do  { span <- getSrcSpanM
 451         ; mapM (tcInstSkolTyVar info (const span)) tyvars }
 452
 453 tcInstSkolType :: SkolemInfo -> TcType -> TcM ([TcTyVar], TcThetaType, TcType)
 454 -- Instantiate a type with fresh skolem constants
 455 -- Binding location comes from the monad
 456 tcInstSkolType info ty = tcInstType (tcInstSkolTyVars info) ty
 457
 458 tcInstSigType :: Bool -> SkolemInfo -> TcType -> TcM ([TcTyVar], TcThetaType, TcRhoType)
 459 -- Instantiate with skolems or meta SigTvs; depending on use_skols
 460 -- Always take location info from the supplied tyvars
 461 tcInstSigType use_skols skol_info ty
 462   = tcInstType (mapM inst_tyvar) ty
 463   where
 464     inst_tyvar | use_skols = tcInstSkolTyVar skol_info getSrcSpan
 465                | otherwise = instMetaTyVar (SigTv skol_info)
 466 \end{code}
 467
 468
 469 %************************************************************************
 470 %*                                                                      *
 471         MetaTvs (meta type variables; mutable)
 472 %*                                                                      *
 473 %************************************************************************
 474
 475 \begin{code}
 476 newMetaTyVar :: BoxInfo -> Kind -> TcM TcTyVar
 477 -- Make a new meta tyvar out of thin air
 478 newMetaTyVar box_info kind
 479   = do  { uniq <- newUnique
 480         ; ref <- newMutVar Flexi
 481         ; let name = mkSysTvName uniq fs
 482               fs = case box_info of
 483                         BoxTv   -> fsLit "t"
 484                         TauTv   -> fsLit "t"
 485                         SigTv _ -> fsLit "a"
 486                 -- We give BoxTv and TauTv the same string, because
 487                 -- otherwise we get user-visible differences in error
 488                 -- messages, which are confusing.  If you want to see
 489                 -- the box_info of each tyvar, use -dppr-debug
 490         ; return (mkTcTyVar name kind (MetaTv box_info ref)) }
 491
 492 instMetaTyVar :: BoxInfo -> TyVar -> TcM TcTyVar
 493 -- Make a new meta tyvar whose Name and Kind
 494 -- come from an existing TyVar
 495 instMetaTyVar box_info tyvar
 496   = do  { uniq <- newUnique
 497         ; ref <- newMutVar Flexi
 498         ; let name = setNameUnique (tyVarName tyvar) uniq
 499               kind = tyVarKind tyvar
 500         ; return (mkTcTyVar name kind (MetaTv box_info ref)) }
 501
 502 readMetaTyVar :: TyVar -> TcM MetaDetails
 503 readMetaTyVar tyvar = ASSERT2( isMetaTyVar tyvar, ppr tyvar )
 504                       readMutVar (metaTvRef tyvar)
 505
 506 isFilledMetaTyVar :: TyVar -> TcM Bool
 507 -- True of a filled-in (Indirect) meta type variable
 508 isFilledMetaTyVar tv
 509   | not (isTcTyVar tv) = return False
 510   | MetaTv _ ref <- tcTyVarDetails tv
 511   = do  { details <- readMutVar ref
 512         ; return (isIndirect details) }
 513   | otherwise = return False
 514
 515 writeMetaTyVar :: TcTyVar -> TcType -> TcM ()
 516 writeMetaTyVar tyvar ty
 517   | not debugIsOn = writeMutVar (metaTvRef tyvar) (Indirect ty)
 518 writeMetaTyVar tyvar ty
 519   | not (isMetaTyVar tyvar)
 520   = pprTrace "writeMetaTyVar" (ppr tyvar) $
 521     return ()
 522   | otherwise
 523   = ASSERT( isMetaTyVar tyvar )
 524     -- TOM: It should also work for coercions
 525     -- ASSERT2( k2 `isSubKind` k1, (ppr tyvar <+> ppr k1) $$ (ppr ty <+> ppr k2) )
 526     do  { ASSERTM2( do { details <- readMetaTyVar tyvar; return (isFlexi details) }, ppr tyvar )
 527         ; writeMutVar (metaTvRef tyvar) (Indirect ty) }
 528   where
 529     _k1 = tyVarKind tyvar
 530     _k2 = typeKind ty
 531 \end{code}
 532
 533
 534 %************************************************************************
 535 %*                                                                      *
 536         MetaTvs: TauTvs
 537 %*                                                                      *
 538 %************************************************************************
 539
 540 \begin{code}
 541 newFlexiTyVar :: Kind -> TcM TcTyVar
 542 newFlexiTyVar kind = newMetaTyVar TauTv kind
 543
 544 newFlexiTyVarTy  :: Kind -> TcM TcType
 545 newFlexiTyVarTy kind = do
 546     tc_tyvar <- newFlexiTyVar kind
 547     return (TyVarTy tc_tyvar)
 548
 549 newFlexiTyVarTys :: Int -> Kind -> TcM [TcType]
 550 newFlexiTyVarTys n kind = mapM newFlexiTyVarTy (nOfThem n kind)
 551
 552 tcInstTyVar :: TyVar -> TcM TcTyVar
 553 -- Instantiate with a META type variable
 554 tcInstTyVar tyvar = instMetaTyVar TauTv tyvar
 555
 556 tcInstTyVars :: [TyVar] -> TcM ([TcTyVar], [TcType], TvSubst)
 557 -- Instantiate with META type variables
 558 tcInstTyVars tyvars
 559   = do  { tc_tvs <- mapM tcInstTyVar tyvars
 560         ; let tys = mkTyVarTys tc_tvs
 561         ; return (tc_tvs, tys, zipTopTvSubst tyvars tys) }
 562                 -- Since the tyvars are freshly made,
 563                 -- they cannot possibly be captured by
 564                 -- any existing for-alls.  Hence zipTopTvSubst
 565 \end{code}
 566
 567
 568 %************************************************************************
 569 %*                                                                      *
 570         MetaTvs: SigTvs
 571 %*                                                                      *
 572 %************************************************************************
 573
 574 \begin{code}
 575 zonkSigTyVar :: TcTyVar -> TcM TcTyVar
 576 zonkSigTyVar sig_tv
 577   | isSkolemTyVar sig_tv
 578   = return sig_tv       -- Happens in the call in TcBinds.checkDistinctTyVars
 579   | otherwise
 580   = ASSERT( isSigTyVar sig_tv )
 581     do { ty <- zonkTcTyVar sig_tv
 582        ; return (tcGetTyVar "zonkSigTyVar" ty) }
 583         -- 'ty' is bound to be a type variable, because SigTvs
 584         -- can only be unified with type variables
 585 \end{code}
 586
 587
 588 %************************************************************************
 589 %*                                                                      *
 590         MetaTvs: BoxTvs
 591 %*                                                                      *
 592 %************************************************************************
 593
 594 \begin{code}
 595 newBoxyTyVar :: Kind -> TcM BoxyTyVar
 596 newBoxyTyVar kind = newMetaTyVar BoxTv kind
 597
 598 newBoxyTyVars :: [Kind] -> TcM [BoxyTyVar]
 599 newBoxyTyVars kinds = mapM newBoxyTyVar kinds
 600
 601 newBoxyTyVarTys :: [Kind] -> TcM [BoxyType]
 602 newBoxyTyVarTys kinds = do { tvs <- mapM newBoxyTyVar kinds; return (mkTyVarTys tvs) }
 603
 604 readFilledBox :: BoxyTyVar -> TcM TcType
 605 -- Read the contents of the box, which should be filled in by now
 606 readFilledBox box_tv = ASSERT( isBoxyTyVar box_tv )
 607                        do { cts <- readMetaTyVar box_tv
 608                           ; case cts of
 609                                 Flexi -> pprPanic "readFilledBox" (ppr box_tv)
 610                                 Indirect ty -> return ty }
 611
 612 tcInstBoxyTyVar :: TyVar -> TcM BoxyTyVar
 613 -- Instantiate with a BOXY type variable
 614 tcInstBoxyTyVar tyvar = instMetaTyVar BoxTv tyvar
 615 \end{code}
 616
 617
 618 %************************************************************************
 619 %*                                                                      *
 620 \subsection{Putting and getting  mutable type variables}
 621 %*                                                                      *
 622 %************************************************************************
 623
 624 But it's more fun to short out indirections on the way: If this
 625 version returns a TyVar, then that TyVar is unbound.  If it returns
 626 any other type, then there might be bound TyVars embedded inside it.
 627
 628 We return Nothing iff the original box was unbound.
 629
 630 \begin{code}
 631 data LookupTyVarResult  -- The result of a lookupTcTyVar call
 632   = DoneTv TcTyVarDetails       -- SkolemTv or virgin MetaTv
 633   | IndirectTv TcType
 634
 635 lookupTcTyVar :: TcTyVar -> TcM LookupTyVarResult
 636 lookupTcTyVar tyvar
 637   = ASSERT2( isTcTyVar tyvar, ppr tyvar )
 638     case details of
 639       SkolemTv _   -> return (DoneTv details)
 640       MetaTv _ ref -> do { meta_details <- readMutVar ref
 641                          ; case meta_details of
 642                             Indirect ty -> return (IndirectTv ty)
 643                             Flexi -> return (DoneTv details) }
 644   where
 645     details =  tcTyVarDetails tyvar
 646
 647 {-
 648 -- gaw 2004 We aren't shorting anything out anymore, at least for now
 649 getTcTyVar tyvar
 650   | not (isTcTyVar tyvar)
 651   = pprTrace "getTcTyVar" (ppr tyvar) $
 652     return (Just (mkTyVarTy tyvar))
 653
 654   | otherwise
 655   = ASSERT2( isTcTyVar tyvar, ppr tyvar ) do
 656     maybe_ty <- readMetaTyVar tyvar
 657     case maybe_ty of
 658         Just ty -> do ty' <- short_out ty
 659                       writeMetaTyVar tyvar (Just ty')
 660                       return (Just ty')
 661
 662         Nothing    -> return Nothing
 663
 664 short_out :: TcType -> TcM TcType
 665 short_out ty@(TyVarTy tyvar)
 666   | not (isTcTyVar tyvar)
 667   = return ty
 668
 669   | otherwise = do
 670     maybe_ty <- readMetaTyVar tyvar
 671     case maybe_ty of
 672         Just ty' -> do ty' <- short_out ty'
 673                        writeMetaTyVar tyvar (Just ty')
 674                        return ty'
 675
 676         other    -> return ty
 677
 678 short_out other_ty = return other_ty
 679 -}
 680 \end{code}
 681
 682
 683 %************************************************************************
 684 %*                                                                      *
 685 \subsection{Zonking -- the exernal interfaces}
 686 %*                                                                      *
 687 %************************************************************************
 688
 689 -----------------  Type variables
 690
 691 \begin{code}
 692 zonkTcTyVars :: [TcTyVar] -> TcM [TcType]
 693 zonkTcTyVars tyvars = mapM zonkTcTyVar tyvars
 694
 695 zonkTcTyVarsAndFV :: [TcTyVar] -> TcM TcTyVarSet
 696 zonkTcTyVarsAndFV tyvars = tyVarsOfTypes <$> mapM zonkTcTyVar tyvars
 697
 698 zonkTcTyVar :: TcTyVar -> TcM TcType
 699 zonkTcTyVar tyvar = ASSERT2( isTcTyVar tyvar, ppr tyvar)
 700                     zonk_tc_tyvar (\ tv -> return (TyVarTy tv)) tyvar
 701 \end{code}
 702
 703 -----------------  Types
 704
 705 \begin{code}
 706 zonkTcType :: TcType -> TcM TcType
 707 zonkTcType ty = zonkType (\ tv -> return (TyVarTy tv)) ty
 708
 709 zonkTcTypes :: [TcType] -> TcM [TcType]
 710 zonkTcTypes tys = mapM zonkTcType tys
 711
 712 zonkTcThetaType :: TcThetaType -> TcM TcThetaType
 713 zonkTcThetaType theta = mapM zonkTcPredType theta
 714
 715 zonkTcPredType :: TcPredType -> TcM TcPredType
 716 zonkTcPredType (ClassP c ts)  = ClassP c <$> zonkTcTypes ts
 717 zonkTcPredType (IParam n t)   = IParam n <$> zonkTcType t
 718 zonkTcPredType (EqPred t1 t2) = EqPred <$> zonkTcType t1 <*> zonkTcType t2
 719 \end{code}
 720
 721 -------------------  These ...ToType, ...ToKind versions
 722                      are used at the end of type checking
 723
 724 \begin{code}
 725 zonkTopTyVar :: TcTyVar -> TcM TcTyVar
 726 -- zonkTopTyVar is used, at the top level, on any un-instantiated meta type variables
 727 -- to default the kind of ? and ?? etc to *.  This is important to ensure that
 728 -- instance declarations match.  For example consider
 729 --      instance Show (a->b)
 730 --      foo x = show (\_ -> True)
 731 -- Then we'll get a constraint (Show (p ->q)) where p has argTypeKind (printed ??),
 732 -- and that won't match the typeKind (*) in the instance decl.
 733 --
 734 -- Because we are at top level, no further constraints are going to affect these
 735 -- type variables, so it's time to do it by hand.  However we aren't ready
 736 -- to default them fully to () or whatever, because the type-class defaulting
 737 -- rules have yet to run.
 738
 739 zonkTopTyVar tv
 740   | k `eqKind` default_k = return tv
 741   | otherwise
 742   = do  { tv' <- newFlexiTyVar default_k
 743         ; writeMetaTyVar tv (mkTyVarTy tv')
 744         ; return tv' }
 745   where
 746     k = tyVarKind tv
 747     default_k = defaultKind k
 748
 749 zonkQuantifiedTyVars :: [TcTyVar] -> TcM [TcTyVar]
 750 zonkQuantifiedTyVars = mapM zonkQuantifiedTyVar
 751
 752 zonkQuantifiedTyVar :: TcTyVar -> TcM TcTyVar
 753 -- zonkQuantifiedTyVar is applied to the a TcTyVar when quantifying over it.
 754 --
 755 -- The quantified type variables often include meta type variables
 756 -- we want to freeze them into ordinary type variables, and
 757 -- default their kind (e.g. from OpenTypeKind to TypeKind)
 758 --                      -- see notes with Kind.defaultKind
 759 -- The meta tyvar is updated to point to the new skolem TyVar.  Now any
 760 -- bound occurences of the original type variable will get zonked to
 761 -- the immutable version.
 762 --
 763 -- We leave skolem TyVars alone; they are immutable.
 764 zonkQuantifiedTyVar tv
 765   | ASSERT( isTcTyVar tv )
 766     isSkolemTyVar tv = return tv
 767         -- It might be a skolem type variable,
 768         -- for example from a user type signature
 769
 770   | otherwise   -- It's a meta-type-variable
 771   = do  { details <- readMetaTyVar tv
 772
 773         -- Create the new, frozen, skolem type variable
 774         -- We zonk to a skolem, not to a regular TcVar
 775         -- See Note [Zonking to Skolem]
 776         ; let final_kind = defaultKind (tyVarKind tv)
 777               final_tv   = mkSkolTyVar (tyVarName tv) final_kind UnkSkol
 778
 779         -- Bind the meta tyvar to the new tyvar
 780         ; case details of
 781             Indirect ty -> WARN( True, ppr tv $$ ppr ty )
 782                            return ()
 783                 -- [Sept 04] I don't think this should happen
 784                 -- See note [Silly Type Synonym]
 785
 786             Flexi -> writeMetaTyVar tv (mkTyVarTy final_tv)
 787
 788         -- Return the new tyvar
 789         ; return final_tv }
 790 \end{code}
 791
 792 Note [Silly Type Synonyms]
 793 ~~~~~~~~~~~~~~~~~~~~~~~~~~
 794 Consider this:
 795         type C u a = u  -- Note 'a' unused
 796
 797         foo :: (forall a. C u a -> C u a) -> u
 798         foo x = ...
 799
 800         bar :: Num u => u
 801         bar = foo (\t -> t + t)
 802
 803 * From the (\t -> t+t) we get type  {Num d} =>  d -> d
 804   where d is fresh.
 805
 806 * Now unify with type of foo's arg, and we get:
 807         {Num (C d a)} =>  C d a -> C d a
 808   where a is fresh.
 809
 810 * Now abstract over the 'a', but float out the Num (C d a) constraint
 811   because it does not 'really' mention a.  (see exactTyVarsOfType)
 812   The arg to foo becomes
 813         \/\a -> \t -> t+t
 814
 815 * So we get a dict binding for Num (C d a), which is zonked to give
 816         a = ()
 817   [Note Sept 04: now that we are zonking quantified type variables
 818   on construction, the 'a' will be frozen as a regular tyvar on
 819   quantification, so the floated dict will still have type (C d a).
 820   Which renders this whole note moot; happily!]
 821
 822 * Then the \/\a abstraction has a zonked 'a' in it.
 823
 824 All very silly.   I think its harmless to ignore the problem.  We'll end up with
 825 a \/\a in the final result but all the occurrences of a will be zonked to ()
 826
 827 Note [Zonking to Skolem]
 828 ~~~~~~~~~~~~~~~~~~~~~~~~
 829 We used to zonk quantified type variables to regular TyVars.  However, this
 830 leads to problems.  Consider this program from the regression test suite:
 831
 832   eval :: Int -> String -> String -> String
 833   eval 0 root actual = evalRHS 0 root actual
 834
 835   evalRHS :: Int -> a
 836   evalRHS 0 root actual = eval 0 root actual
 837
 838 It leads to the deferral of an equality
 839
 840   (String -> String -> String) ~ a
 841
 842 which is propagated up to the toplevel (see TcSimplify.tcSimplifyInferCheck).
 843 In the meantime `a' is zonked and quantified to form `evalRHS's signature.
 844 This has the *side effect* of also zonking the `a' in the deferred equality
 845 (which at this point is being handed around wrapped in an implication
 846 constraint).
 847
 848 Finally, the equality (with the zonked `a') will be handed back to the
 849 simplifier by TcRnDriver.tcRnSrcDecls calling TcSimplify.tcSimplifyTop.
 850 If we zonk `a' with a regular type variable, we will have this regular type
 851 variable now floating around in the simplifier, which in many places assumes to
 852 only see proper TcTyVars.
 853
 854 We can avoid this problem by zonking with a skolem.  The skolem is rigid
 855 (which we requirefor a quantified variable), but is still a TcTyVar that the
 856 simplifier knows how to deal with.
 857
 858
 859 %************************************************************************
 860 %*                                                                      *
 861 \subsection{Zonking -- the main work-horses: zonkType, zonkTyVar}
 862 %*                                                                      *
 863 %*              For internal use only!                                  *
 864 %*                                                                      *
 865 %************************************************************************
 866
 867 \begin{code}
 868 -- For unbound, mutable tyvars, zonkType uses the function given to it
 869 -- For tyvars bound at a for-all, zonkType zonks them to an immutable
 870 --      type variable and zonks the kind too
 871
 872 zonkType :: (TcTyVar -> TcM Type)       -- What to do with unbound mutable type variables
 873                                         -- see zonkTcType, and zonkTcTypeToType
 874          -> TcType
 875          -> TcM Type
 876 zonkType unbound_var_fn ty
 877   = go ty
 878   where
 879     go (TyConApp tc tys) = do tys' <- mapM go tys
 880                               return (TyConApp tc tys')
 881
 882     go (PredTy p)        = do p' <- go_pred p
 883                               return (PredTy p')
 884
 885     go (FunTy arg res)   = do arg' <- go arg
 886                               res' <- go res
 887                               return (FunTy arg' res')
 888
 889     go (AppTy fun arg)   = do fun' <- go fun
 890                               arg' <- go arg
 891                               return (mkAppTy fun' arg')
 892                 -- NB the mkAppTy; we might have instantiated a
 893                 -- type variable to a type constructor, so we need
 894                 -- to pull the TyConApp to the top.
 895
 896         -- The two interesting cases!
 897     go (TyVarTy tyvar) | isTcTyVar tyvar = zonk_tc_tyvar unbound_var_fn tyvar
 898                        | otherwise       = return (TyVarTy tyvar)
 899                 -- Ordinary (non Tc) tyvars occur inside quantified types
 900
 901     go (ForAllTy tyvar ty) = ASSERT( isImmutableTyVar tyvar ) do
 902                              ty' <- go ty
 903                              return (ForAllTy tyvar ty')
 904
 905     go_pred (ClassP c tys)   = do tys' <- mapM go tys
 906                                   return (ClassP c tys')
 907     go_pred (IParam n ty)    = do ty' <- go ty
 908                                   return (IParam n ty')
 909     go_pred (EqPred ty1 ty2) = do ty1' <- go ty1
 910                                   ty2' <- go ty2
 911                                   return (EqPred ty1' ty2')
 912
 913 zonk_tc_tyvar :: (TcTyVar -> TcM Type)          -- What to do for an unbound mutable variable
 914               -> TcTyVar -> TcM TcType
 915 zonk_tc_tyvar unbound_var_fn tyvar
 916   | not (isMetaTyVar tyvar)     -- Skolems
 917   = return (TyVarTy tyvar)
 918
 919   | otherwise                   -- Mutables
 920   = do  { cts <- readMetaTyVar tyvar
 921         ; case cts of
 922             Flexi       -> unbound_var_fn tyvar    -- Unbound meta type variable
 923             Indirect ty -> zonkType unbound_var_fn ty  }
 924 \end{code}
 925
 926
 927
 928 %************************************************************************
 929 %*                                                                      *
 930                         Zonking kinds
 931 %*                                                                      *
 932 %************************************************************************
 933
 934 \begin{code}
 935 readKindVar  :: KindVar -> TcM (MetaDetails)
 936 writeKindVar :: KindVar -> TcKind -> TcM ()
 937 readKindVar  kv = readMutVar (kindVarRef kv)
 938 writeKindVar kv val = writeMutVar (kindVarRef kv) (Indirect val)
 939
 940 -------------
 941 zonkTcKind :: TcKind -> TcM TcKind
 942 zonkTcKind k = zonkTcType k
 943
 944 -------------
 945 zonkTcKindToKind :: TcKind -> TcM Kind
 946 -- When zonking a TcKind to a kind, we need to instantiate kind variables,
 947 -- Haskell specifies that * is to be used, so we follow that.
 948 zonkTcKindToKind k = zonkType (\ _ -> return liftedTypeKind) k
 949 \end{code}
 950
 951 %************************************************************************
 952 %*                                                                      *
 953 \subsection{Checking a user type}
 954 %*                                                                      *
 955 %************************************************************************
 956
 957 When dealing with a user-written type, we first translate it from an HsType
 958 to a Type, performing kind checking, and then check various things that should
 959 be true about it.  We don't want to perform these checks at the same time
 960 as the initial translation because (a) they are unnecessary for interface-file
 961 types and (b) when checking a mutually recursive group of type and class decls,
 962 we can't "look" at the tycons/classes yet.  Also, the checks are are rather
 963 diverse, and used to really mess up the other code.
 964
 965 One thing we check for is 'rank'.
 966
 967         Rank 0:         monotypes (no foralls)
 968         Rank 1:         foralls at the front only, Rank 0 inside
 969         Rank 2:         foralls at the front, Rank 1 on left of fn arrow,
 970
 971         basic ::= tyvar | T basic ... basic
 972
 973         r2  ::= forall tvs. cxt => r2a
 974         r2a ::= r1 -> r2a | basic
 975         r1  ::= forall tvs. cxt => r0
 976         r0  ::= r0 -> r0 | basic
 977
 978 Another thing is to check that type synonyms are saturated.
 979 This might not necessarily show up in kind checking.
 980         type A i = i
 981         data T k = MkT (k Int)
 982         f :: T A        -- BAD!
 983
 984
 985 \begin{code}
 986 checkValidType :: UserTypeCtxt -> Type -> TcM ()
 987 -- Checks that the type is valid for the given context
 988 checkValidType ctxt ty = do
 989     traceTc (text "checkValidType" <+> ppr ty)
 990     unboxed  <- doptM Opt_UnboxedTuples
 991     rank2    <- doptM Opt_Rank2Types
 992     rankn    <- doptM Opt_RankNTypes
 993     polycomp <- doptM Opt_PolymorphicComponents
 994     let
 995         gen_rank n | rankn     = ArbitraryRank
 996                    | rank2     = Rank 2
 997                    | otherwise = Rank n
 998         rank
 999           = case ctxt of
1000                  GenPatCtxt     -> MustBeMonoType
1001                  DefaultDeclCtxt-> MustBeMonoType
1002                  ResSigCtxt     -> MustBeMonoType
1003                  LamPatSigCtxt  -> gen_rank 0
1004                  BindPatSigCtxt -> gen_rank 0
1005                  TySynCtxt _    -> gen_rank 0
1006                  ExprSigCtxt    -> gen_rank 1
1007                  FunSigCtxt _   -> gen_rank 1
1008                  ConArgCtxt _   | polycomp -> gen_rank 2
1009                                 -- We are given the type of the entire
1010                                 -- constructor, hence rank 1
1011                                 | otherwise -> gen_rank 1
1012                  ForSigCtxt _   -> gen_rank 1
1013                  SpecInstCtxt   -> gen_rank 1
1014
1015         actual_kind = typeKind ty
1016
1017         kind_ok = case ctxt of
1018                         TySynCtxt _  -> True -- Any kind will do
1019                         ResSigCtxt   -> isSubOpenTypeKind actual_kind
1020                         ExprSigCtxt  -> isSubOpenTypeKind actual_kind
1021                         GenPatCtxt   -> isLiftedTypeKind actual_kind
1022                         ForSigCtxt _ -> isLiftedTypeKind actual_kind
1023                         _            -> isSubArgTypeKind actual_kind
1024
1025         ubx_tup = case ctxt of
1026                       TySynCtxt _ | unboxed -> UT_Ok
1027                       ExprSigCtxt | unboxed -> UT_Ok
1028                       _                     -> UT_NotOk
1029
1030         -- Check that the thing has kind Type, and is lifted if necessary
1031     checkTc kind_ok (kindErr actual_kind)
1032
1033         -- Check the internal validity of the type itself
1034     check_type rank ubx_tup ty
1035
1036     traceTc (text "checkValidType done" <+> ppr ty)
1037
1038 checkValidMonoType :: Type -> TcM ()
1039 checkValidMonoType ty = check_mono_type MustBeMonoType ty
1040 \end{code}
1041
1042
1043 \begin{code}
1044 data Rank = ArbitraryRank         -- Any rank ok
1045           | MustBeMonoType        -- Monotype regardless of flags
1046           | TyConArgMonoType      -- Monotype but could be poly if -XImpredicativeTypes
1047           | Rank Int              -- Rank n, but could be more with -XRankNTypes
1048
1049 decRank :: Rank -> Rank           -- Function arguments
1050 decRank (Rank 0)   = Rank 0
1051 decRank (Rank n)   = Rank (n-1)
1052 decRank other_rank = other_rank
1053
1054 nonZeroRank :: Rank -> Bool
1055 nonZeroRank ArbitraryRank = True
1056 nonZeroRank (Rank n)      = n>0
1057 nonZeroRank _             = False
1058
1059 ----------------------------------------
1060 data UbxTupFlag = UT_Ok | UT_NotOk
1061         -- The "Ok" version means "ok if UnboxedTuples is on"
1062
1063 ----------------------------------------
1064 check_mono_type :: Rank -> Type -> TcM ()       -- No foralls anywhere
1065                                                 -- No unlifted types of any kind
1066 check_mono_type rank ty
1067    = do { check_type rank UT_NotOk ty
1068         ; checkTc (not (isUnLiftedType ty)) (unliftedArgErr ty) }
1069
1070 check_type :: Rank -> UbxTupFlag -> Type -> TcM ()
1071 -- The args say what the *type context* requires, independent
1072 -- of *flag* settings.  You test the flag settings at usage sites.
1073 --
1074 -- Rank is allowed rank for function args
1075 -- Rank 0 means no for-alls anywhere
1076
1077 check_type rank ubx_tup ty
1078   | not (null tvs && null theta)
1079   = do  { checkTc (nonZeroRank rank) (forAllTyErr rank ty)
1080                 -- Reject e.g. (Maybe (?x::Int => Int)),
1081                 -- with a decent error message
1082         ; check_valid_theta SigmaCtxt theta
1083         ; check_type rank ubx_tup tau   -- Allow foralls to right of arrow
1084         ; checkFreeness tvs theta
1085         ; checkAmbiguity tvs theta (tyVarsOfType tau) }
1086   where
1087     (tvs, theta, tau) = tcSplitSigmaTy ty
1088
1089 -- Naked PredTys don't usually show up, but they can as a result of
1090 --      {-# SPECIALISE instance Ord Char #-}
1091 -- The Right Thing would be to fix the way that SPECIALISE instance pragmas
1092 -- are handled, but the quick thing is just to permit PredTys here.
1093 check_type _ _ (PredTy sty)
1094   = do  { dflags <- getDOpts
1095         ; check_pred_ty dflags TypeCtxt sty }
1096
1097 check_type _ _ (TyVarTy _) = return ()
1098 check_type rank _ (FunTy arg_ty res_ty)
1099   = do  { check_type (decRank rank) UT_NotOk arg_ty
1100         ; check_type rank           UT_Ok    res_ty }
1101
1102 check_type rank _ (AppTy ty1 ty2)
1103   = do  { check_arg_type rank ty1
1104         ; check_arg_type rank ty2 }
1105
1106 check_type rank ubx_tup ty@(TyConApp tc tys)
1107   | isSynTyCon tc
1108   = do  {       -- Check that the synonym has enough args
1109                 -- This applies equally to open and closed synonyms
1110                 -- It's OK to have an *over-applied* type synonym
1111                 --      data Tree a b = ...
1112                 --      type Foo a = Tree [a]
1113                 --      f :: Foo a b -> ...
1114           checkTc (tyConArity tc <= length tys) arity_msg
1115
1116         -- See Note [Liberal type synonyms]
1117         ; liberal <- doptM Opt_LiberalTypeSynonyms
1118         ; if not liberal || isOpenSynTyCon tc then
1119                 -- For H98 and synonym families, do check the type args
1120                 mapM_ (check_mono_type TyConArgMonoType) tys
1121
1122           else  -- In the liberal case (only for closed syns), expand then check
1123           case tcView ty of
1124              Just ty' -> check_type rank ubx_tup ty'
1125              Nothing  -> pprPanic "check_tau_type" (ppr ty)
1126     }
1127
1128   | isUnboxedTupleTyCon tc
1129   = do  { ub_tuples_allowed <- doptM Opt_UnboxedTuples
1130         ; checkTc (ubx_tup_ok ub_tuples_allowed) ubx_tup_msg
1131
1132         ; impred <- doptM Opt_ImpredicativeTypes
1133         ; let rank' = if impred then ArbitraryRank else TyConArgMonoType
1134                 -- c.f. check_arg_type
1135                 -- However, args are allowed to be unlifted, or
1136                 -- more unboxed tuples, so can't use check_arg_ty
1137         ; mapM_ (check_type rank' UT_Ok) tys }
1138
1139   | otherwise
1140   = mapM_ (check_arg_type rank) tys
1141
1142   where
1143     ubx_tup_ok ub_tuples_allowed = case ubx_tup of
1144                                    UT_Ok -> ub_tuples_allowed
1145                                    _     -> False
1146
1147     n_args    = length tys
1148     tc_arity  = tyConArity tc
1149
1150     arity_msg   = arityErr "Type synonym" (tyConName tc) tc_arity n_args
1151     ubx_tup_msg = ubxArgTyErr ty
1152
1153 check_type _ _ ty = pprPanic "check_type" (ppr ty)
1154
1155 ----------------------------------------
1156 check_arg_type :: Rank -> Type -> TcM ()
1157 -- The sort of type that can instantiate a type variable,
1158 -- or be the argument of a type constructor.
1159 -- Not an unboxed tuple, but now *can* be a forall (since impredicativity)
1160 -- Other unboxed types are very occasionally allowed as type
1161 -- arguments depending on the kind of the type constructor
1162 --
1163 -- For example, we want to reject things like:
1164 --
1165 --      instance Ord a => Ord (forall s. T s a)
1166 -- and
1167 --      g :: T s (forall b.b)
1168 --
1169 -- NB: unboxed tuples can have polymorphic or unboxed args.
1170 --     This happens in the workers for functions returning
1171 --     product types with polymorphic components.
1172 --     But not in user code.
1173 -- Anyway, they are dealt with by a special case in check_tau_type
1174
1175 check_arg_type rank ty
1176   = do  { impred <- doptM Opt_ImpredicativeTypes
1177         ; let rank' = if impred then ArbitraryRank  -- Arg of tycon can have arby rank, regardless
1178                       else case rank of             -- Predictive => must be monotype
1179                         MustBeMonoType -> MustBeMonoType
1180                         _              -> TyConArgMonoType
1181                         -- Make sure that MustBeMonoType is propagated,
1182                         -- so that we don't suggest -XImpredicativeTypes in
1183                         --    (Ord (forall a.a)) => a -> a
1184
1185         ; check_type rank' UT_NotOk ty
1186         ; checkTc (not (isUnLiftedType ty)) (unliftedArgErr ty) }
1187
1188 ----------------------------------------
1189 forAllTyErr :: Rank -> Type -> SDoc
1190 forAllTyErr rank ty
1191    = vcat [ hang (ptext (sLit "Illegal polymorphic or qualified type:")) 2 (ppr ty)
1192           , suggestion ]
1193   where
1194     suggestion = case rank of
1195                    Rank _ -> ptext (sLit "Perhaps you intended to use -XRankNTypes or -XRank2Types")
1196                    TyConArgMonoType -> ptext (sLit "Perhaps you intended to use -XImpredicativeTypes")
1197                    _ -> empty      -- Polytype is always illegal
1198
1199 unliftedArgErr, ubxArgTyErr :: Type -> SDoc
1200 unliftedArgErr  ty = sep [ptext (sLit "Illegal unlifted type:"), ppr ty]
1201 ubxArgTyErr     ty = sep [ptext (sLit "Illegal unboxed tuple type as function argument:"), ppr ty]
1202
1203 kindErr :: Kind -> SDoc
1204 kindErr kind       = sep [ptext (sLit "Expecting an ordinary type, but found a type of kind"), ppr kind]
1205 \end{code}
1206
1207 Note [Liberal type synonyms]
1208 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1209 If -XLiberalTypeSynonyms is on, expand closed type synonyms *before*
1210 doing validity checking.  This allows us to instantiate a synonym defn
1211 with a for-all type, or with a partially-applied type synonym.
1212         e.g.   type T a b = a
1213                type S m   = m ()
1214                f :: S (T Int)
1215 Here, T is partially applied, so it's illegal in H98.  But if you
1216 expand S first, then T we get just
1217                f :: Int
1218 which is fine.
1219
1220 IMPORTANT: suppose T is a type synonym.  Then we must do validity
1221 checking on an appliation (T ty1 ty2)
1222
1223         *either* before expansion (i.e. check ty1, ty2)
1224         *or* after expansion (i.e. expand T ty1 ty2, and then check)
1225         BUT NOT BOTH
1226
1227 If we do both, we get exponential behaviour!!
1228
1229   data TIACons1 i r c = c i ::: r c
1230   type TIACons2 t x = TIACons1 t (TIACons1 t x)
1231   type TIACons3 t x = TIACons2 t (TIACons1 t x)
1232   type TIACons4 t x = TIACons2 t (TIACons2 t x)
1233   type TIACons7 t x = TIACons4 t (TIACons3 t x)
1234
1235
1236 %************************************************************************
1237 %*                                                                      *
1238 \subsection{Checking a theta or source type}
1239 %*                                                                      *
1240 %************************************************************************
1241
1242 \begin{code}
1243 -- Enumerate the contexts in which a "source type", <S>, can occur
1244 --      Eq a
1245 -- or   ?x::Int
1246 -- or   r <: {x::Int}
1247 -- or   (N a) where N is a newtype
1248
1249 data SourceTyCtxt
1250   = ClassSCCtxt Name    -- Superclasses of clas
1251                         --      class <S> => C a where ...
1252   | SigmaCtxt           -- Theta part of a normal for-all type
1253                         --      f :: <S> => a -> a
1254   | DataTyCtxt Name     -- Theta part of a data decl
1255                         --      data <S> => T a = MkT a
1256   | TypeCtxt            -- Source type in an ordinary type
1257                         --      f :: N a -> N a
1258   | InstThetaCtxt       -- Context of an instance decl
1259                         --      instance <S> => C [a] where ...
1260
1261 pprSourceTyCtxt :: SourceTyCtxt -> SDoc
1262 pprSourceTyCtxt (ClassSCCtxt c) = ptext (sLit "the super-classes of class") <+> quotes (ppr c)
1263 pprSourceTyCtxt SigmaCtxt       = ptext (sLit "the context of a polymorphic type")
1264 pprSourceTyCtxt (DataTyCtxt tc) = ptext (sLit "the context of the data type declaration for") <+> quotes (ppr tc)
1265 pprSourceTyCtxt InstThetaCtxt   = ptext (sLit "the context of an instance declaration")
1266 pprSourceTyCtxt TypeCtxt        = ptext (sLit "the context of a type")
1267 \end{code}
1268
1269 \begin{code}
1270 checkValidTheta :: SourceTyCtxt -> ThetaType -> TcM ()
1271 checkValidTheta ctxt theta
1272   = addErrCtxt (checkThetaCtxt ctxt theta) (check_valid_theta ctxt theta)
1273
1274 -------------------------
1275 check_valid_theta :: SourceTyCtxt -> [PredType] -> TcM ()
1276 check_valid_theta _ []
1277   = return ()
1278 check_valid_theta ctxt theta = do
1279     dflags <- getDOpts
1280     warnTc (notNull dups) (dupPredWarn dups)
1281     mapM_ (check_pred_ty dflags ctxt) theta
1282   where
1283     (_,dups) = removeDups tcCmpPred theta
1284
1285 -------------------------
1286 check_pred_ty :: DynFlags -> SourceTyCtxt -> PredType -> TcM ()
1287 check_pred_ty dflags ctxt pred@(ClassP cls tys)
1288   = do {        -- Class predicates are valid in all contexts
1289        ; checkTc (arity == n_tys) arity_err
1290
1291                 -- Check the form of the argument types
1292        ; mapM_ checkValidMonoType tys
1293        ; checkTc (check_class_pred_tys dflags ctxt tys)
1294                  (predTyVarErr pred $$ how_to_allow)
1295        }
1296   where
1297     class_name = className cls
1298     arity      = classArity cls
1299     n_tys      = length tys
1300     arity_err  = arityErr "Class" class_name arity n_tys
1301     how_to_allow = parens (ptext (sLit "Use -XFlexibleContexts to permit this"))
1302
1303 check_pred_ty dflags _ pred@(EqPred ty1 ty2)
1304   = do {        -- Equational constraints are valid in all contexts if type
1305                 -- families are permitted
1306        ; checkTc (dopt Opt_TypeFamilies dflags) (eqPredTyErr pred)
1307
1308                 -- Check the form of the argument types
1309        ; checkValidMonoType ty1
1310        ; checkValidMonoType ty2
1311        }
1312
1313 check_pred_ty _ SigmaCtxt (IParam _ ty) = checkValidMonoType ty
1314         -- Implicit parameters only allowed in type
1315         -- signatures; not in instance decls, superclasses etc
1316         -- The reason for not allowing implicit params in instances is a bit
1317         -- subtle.
1318         -- If we allowed        instance (?x::Int, Eq a) => Foo [a] where ...
1319         -- then when we saw (e :: (?x::Int) => t) it would be unclear how to
1320         -- discharge all the potential usas of the ?x in e.   For example, a
1321         -- constraint Foo [Int] might come out of e,and applying the
1322         -- instance decl would show up two uses of ?x.
1323
1324 -- Catch-all
1325 check_pred_ty _ _ sty = failWithTc (badPredTyErr sty)
1326
1327 -------------------------
1328 check_class_pred_tys :: DynFlags -> SourceTyCtxt -> [Type] -> Bool
1329 check_class_pred_tys dflags ctxt tys
1330   = case ctxt of
1331         TypeCtxt      -> True   -- {-# SPECIALISE instance Eq (T Int) #-} is fine
1332         InstThetaCtxt -> flexible_contexts || undecidable_ok || all tcIsTyVarTy tys
1333                                 -- Further checks on head and theta in
1334                                 -- checkInstTermination
1335         _             -> flexible_contexts || all tyvar_head tys
1336   where
1337     flexible_contexts = dopt Opt_FlexibleContexts dflags
1338     undecidable_ok = dopt Opt_UndecidableInstances dflags
1339
1340 -------------------------
1341 tyvar_head :: Type -> Bool
1342 tyvar_head ty                   -- Haskell 98 allows predicates of form
1343   | tcIsTyVarTy ty = True       --      C (a ty1 .. tyn)
1344   | otherwise                   -- where a is a type variable
1345   = case tcSplitAppTy_maybe ty of
1346         Just (ty, _) -> tyvar_head ty
1347         Nothing      -> False
1348 \end{code}
1349
1350 Check for ambiguity
1351 ~~~~~~~~~~~~~~~~~~~
1352           forall V. P => tau
1353 is ambiguous if P contains generic variables
1354 (i.e. one of the Vs) that are not mentioned in tau
1355
1356 However, we need to take account of functional dependencies
1357 when we speak of 'mentioned in tau'.  Example:
1358         class C a b | a -> b where ...
1359 Then the type
1360         forall x y. (C x y) => x
1361 is not ambiguous because x is mentioned and x determines y
1362
1363 NB; the ambiguity check is only used for *user* types, not for types
1364 coming from inteface files.  The latter can legitimately have
1365 ambiguous types. Example
1366
1367    class S a where s :: a -> (Int,Int)
1368    instance S Char where s _ = (1,1)
1369    f:: S a => [a] -> Int -> (Int,Int)
1370    f (_::[a]) x = (a*x,b)
1371         where (a,b) = s (undefined::a)
1372
1373 Here the worker for f gets the type
1374         fw :: forall a. S a => Int -> (# Int, Int #)
1375
1376 If the list of tv_names is empty, we have a monotype, and then we
1377 don't need to check for ambiguity either, because the test can't fail
1378 (see is_ambig).
1379
1380
1381 \begin{code}
1382 checkAmbiguity :: [TyVar] -> ThetaType -> TyVarSet -> TcM ()
1383 checkAmbiguity forall_tyvars theta tau_tyvars
1384   = mapM_ complain (filter is_ambig theta)
1385   where
1386     complain pred     = addErrTc (ambigErr pred)
1387     extended_tau_vars = grow theta tau_tyvars
1388
1389         -- See Note [Implicit parameters and ambiguity] in TcSimplify
1390     is_ambig pred     = isClassPred  pred &&
1391                         any ambig_var (varSetElems (tyVarsOfPred pred))
1392
1393     ambig_var ct_var  = (ct_var `elem` forall_tyvars) &&
1394                         not (ct_var `elemVarSet` extended_tau_vars)
1395
1396 ambigErr :: PredType -> SDoc
1397 ambigErr pred
1398   = sep [ptext (sLit "Ambiguous constraint") <+> quotes (pprPred pred),
1399          nest 4 (ptext (sLit "At least one of the forall'd type variables mentioned by the constraint") $$
1400                  ptext (sLit "must be reachable from the type after the '=>'"))]
1401 \end{code}
1402
1403 In addition, GHC insists that at least one type variable
1404 in each constraint is in V.  So we disallow a type like
1405         forall a. Eq b => b -> b
1406 even in a scope where b is in scope.
1407
1408 \begin{code}
1409 checkFreeness :: [Var] -> [PredType] -> TcM ()
1410 checkFreeness forall_tyvars theta
1411   = do  { flexible_contexts <- doptM Opt_FlexibleContexts
1412         ; unless flexible_contexts $ mapM_ complain (filter is_free theta) }
1413   where
1414     is_free pred     =  not (isIPPred pred)
1415                      && not (any bound_var (varSetElems (tyVarsOfPred pred)))
1416     bound_var ct_var = ct_var `elem` forall_tyvars
1417     complain pred    = addErrTc (freeErr pred)
1418
1419 freeErr :: PredType -> SDoc
1420 freeErr pred
1421   = sep [ ptext (sLit "All of the type variables in the constraint") <+>
1422           quotes (pprPred pred)
1423         , ptext (sLit "are already in scope") <+>
1424           ptext (sLit "(at least one must be universally quantified here)")
1425         , nest 4 $
1426             ptext (sLit "(Use -XFlexibleContexts to lift this restriction)")
1427         ]
1428 \end{code}
1429
1430 \begin{code}
1431 checkThetaCtxt :: SourceTyCtxt -> ThetaType -> SDoc
1432 checkThetaCtxt ctxt theta
1433   = vcat [ptext (sLit "In the context:") <+> pprTheta theta,
1434           ptext (sLit "While checking") <+> pprSourceTyCtxt ctxt ]
1435
1436 badPredTyErr, eqPredTyErr, predTyVarErr :: PredType -> SDoc
1437 badPredTyErr sty = ptext (sLit "Illegal constraint") <+> pprPred sty
1438 eqPredTyErr  sty = ptext (sLit "Illegal equational constraint") <+> pprPred sty
1439                    $$
1440                    parens (ptext (sLit "Use -XTypeFamilies to permit this"))
1441 predTyVarErr pred  = sep [ptext (sLit "Non type-variable argument"),
1442                           nest 2 (ptext (sLit "in the constraint:") <+> pprPred pred)]
1443 dupPredWarn :: [[PredType]] -> SDoc
1444 dupPredWarn dups   = ptext (sLit "Duplicate constraint(s):") <+> pprWithCommas pprPred (map head dups)
1445
1446 arityErr :: Outputable a => String -> a -> Int -> Int -> SDoc
1447 arityErr kind name n m
1448   = hsep [ text kind, quotes (ppr name), ptext (sLit "should have"),
1449            n_arguments <> comma, text "but has been given", int m]
1450     where
1451         n_arguments | n == 0 = ptext (sLit "no arguments")
1452                     | n == 1 = ptext (sLit "1 argument")
1453                     | True   = hsep [int n, ptext (sLit "arguments")]
1454
1455 -----------------
1456 notMonoType :: TcType -> TcM a
1457 notMonoType ty
1458   = do  { ty' <- zonkTcType ty
1459         ; env0 <- tcInitTidyEnv
1460         ; let (env1, tidy_ty) = tidyOpenType env0 ty'
1461               msg = ptext (sLit "Cannot match a monotype with") <+> quotes (ppr tidy_ty)
1462         ; failWithTcM (env1, msg) }
1463
1464 notMonoArgs :: TcType -> TcM a
1465 notMonoArgs ty
1466   = do  { ty' <- zonkTcType ty
1467         ; env0 <- tcInitTidyEnv
1468         ; let (env1, tidy_ty) = tidyOpenType env0 ty'
1469               msg = ptext (sLit "Arguments of type synonym families must be monotypes") <+> quotes (ppr tidy_ty)
1470         ; failWithTcM (env1, msg) }
1471 \end{code}
1472
1473
1474 %************************************************************************
1475 %*                                                                      *
1476 \subsection{Checking for a decent instance head type}
1477 %*                                                                      *
1478 %************************************************************************
1479
1480 @checkValidInstHead@ checks the type {\em and} its syntactic constraints:
1481 it must normally look like: @instance Foo (Tycon a b c ...) ...@
1482
1483 The exceptions to this syntactic checking: (1)~if the @GlasgowExts@
1484 flag is on, or (2)~the instance is imported (they must have been
1485 compiled elsewhere). In these cases, we let them go through anyway.
1486
1487 We can also have instances for functions: @instance Foo (a -> b) ...@.
1488
1489 \begin{code}
1490 checkValidInstHead :: Type -> TcM (Class, [TcType])
1491
1492 checkValidInstHead ty   -- Should be a source type
1493   = case tcSplitPredTy_maybe ty of {
1494         Nothing -> failWithTc (instTypeErr (ppr ty) empty) ;
1495         Just pred ->
1496
1497     case getClassPredTys_maybe pred of {
1498         Nothing -> failWithTc (instTypeErr (pprPred pred) empty) ;
1499         Just (clas,tys) -> do
1500
1501     dflags <- getDOpts
1502     check_inst_head dflags clas tys
1503     return (clas, tys)
1504     }}
1505
1506 check_inst_head :: DynFlags -> Class -> [Type] -> TcM ()
1507 check_inst_head dflags clas tys
1508   = do { -- If GlasgowExts then check at least one isn't a type variable
1509        ; checkTc (dopt Opt_TypeSynonymInstances dflags ||
1510                   all tcInstHeadTyNotSynonym tys)
1511                  (instTypeErr (pprClassPred clas tys) head_type_synonym_msg)
1512        ; checkTc (dopt Opt_FlexibleInstances dflags ||
1513                   all tcInstHeadTyAppAllTyVars tys)
1514                  (instTypeErr (pprClassPred clas tys) head_type_args_tyvars_msg)
1515        ; checkTc (dopt Opt_MultiParamTypeClasses dflags ||
1516                   isSingleton tys)
1517                  (instTypeErr (pprClassPred clas tys) head_one_type_msg)
1518          -- May not contain type family applications
1519        ; mapM_ checkTyFamFreeness tys
1520
1521        ; mapM_ checkValidMonoType tys
1522         -- For now, I only allow tau-types (not polytypes) in
1523         -- the head of an instance decl.
1524         --      E.g.  instance C (forall a. a->a) is rejected
1525         -- One could imagine generalising that, but I'm not sure
1526         -- what all the consequences might be
1527        }
1528
1529   where
1530     head_type_synonym_msg = parens (
1531                 text "All instance types must be of the form (T t1 ... tn)" $$
1532                 text "where T is not a synonym." $$
1533                 text "Use -XTypeSynonymInstances if you want to disable this.")
1534
1535     head_type_args_tyvars_msg = parens (vcat [
1536                 text "All instance types must be of the form (T a1 ... an)",
1537                 text "where a1 ... an are type *variables*,",
1538                 text "and each type variable appears at most once in the instance head.",
1539                 text "Use -XFlexibleInstances if you want to disable this."])
1540
1541     head_one_type_msg = parens (
1542                 text "Only one type can be given in an instance head." $$
1543                 text "Use -XMultiParamTypeClasses if you want to allow more.")
1544
1545 instTypeErr :: SDoc -> SDoc -> SDoc
1546 instTypeErr pp_ty msg
1547   = sep [ptext (sLit "Illegal instance declaration for") <+> quotes pp_ty,
1548          nest 4 msg]
1549 \end{code}
1550
1551
1552 %************************************************************************
1553 %*                                                                      *
1554 \subsection{Checking instance for termination}
1555 %*                                                                      *
1556 %************************************************************************
1557
1558
1559 \begin{code}
1560 checkValidInstance :: [TyVar] -> ThetaType -> Class -> [TcType] -> TcM ()
1561 checkValidInstance tyvars theta clas inst_tys
1562   = do  { undecidable_ok <- doptM Opt_UndecidableInstances
1563
1564         ; checkValidTheta InstThetaCtxt theta
1565         ; checkAmbiguity tyvars theta (tyVarsOfTypes inst_tys)
1566
1567         -- Check that instance inference will terminate (if we care)
1568         -- For Haskell 98 this will already have been done by checkValidTheta,
1569         -- but as we may be using other extensions we need to check.
1570         ; unless undecidable_ok $
1571           mapM_ addErrTc (checkInstTermination inst_tys theta)
1572
1573         -- The Coverage Condition
1574         ; checkTc (undecidable_ok || checkInstCoverage clas inst_tys)
1575                   (instTypeErr (pprClassPred clas inst_tys) msg)
1576         }
1577   where
1578     msg  = parens (vcat [ptext (sLit "the Coverage Condition fails for one of the functional dependencies;"),
1579                          undecidableMsg])
1580 \end{code}
1581
1582 Termination test: the so-called "Paterson conditions" (see Section 5 of
1583 "Understanding functionsl dependencies via Constraint Handling Rules,
1584 JFP Jan 2007).
1585
1586 We check that each assertion in the context satisfies:
1587  (1) no variable has more occurrences in the assertion than in the head, and
1588  (2) the assertion has fewer constructors and variables (taken together
1589      and counting repetitions) than the head.
1590 This is only needed with -fglasgow-exts, as Haskell 98 restrictions
1591 (which have already been checked) guarantee termination.
1592
1593 The underlying idea is that
1594
1595     for any ground substitution, each assertion in the
1596     context has fewer type constructors than the head.
1597
1598
1599 \begin{code}
1600 checkInstTermination :: [TcType] -> ThetaType -> [Message]
1601 checkInstTermination tys theta
1602   = mapCatMaybes check theta
1603   where
1604    fvs  = fvTypes tys
1605    size = sizeTypes tys
1606    check pred
1607       | not (null (fvPred pred \\ fvs))
1608       = Just (predUndecErr pred nomoreMsg $$ parens undecidableMsg)
1609       | sizePred pred >= size
1610       = Just (predUndecErr pred smallerMsg $$ parens undecidableMsg)
1611       | otherwise
1612       = Nothing
1613
1614 predUndecErr :: PredType -> SDoc -> SDoc
1615 predUndecErr pred msg = sep [msg,
1616                         nest 2 (ptext (sLit "in the constraint:") <+> pprPred pred)]
1617
1618 nomoreMsg, smallerMsg, undecidableMsg :: SDoc
1619 nomoreMsg = ptext (sLit "Variable occurs more often in a constraint than in the instance head")
1620 smallerMsg = ptext (sLit "Constraint is no smaller than the instance head")
1621 undecidableMsg = ptext (sLit "Use -XUndecidableInstances to permit this")
1622 \end{code}
1623
1624
1625 %************************************************************************
1626 %*                                                                      *
1627         Checking the context of a derived instance declaration
1628 %*                                                                      *
1629 %************************************************************************
1630
1631 Note [Exotic derived instance contexts]
1632 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1633 In a 'derived' instance declaration, we *infer* the context.  It's a
1634 bit unclear what rules we should apply for this; the Haskell report is
1635 silent.  Obviously, constraints like (Eq a) are fine, but what about
1636         data T f a = MkT (f a) deriving( Eq )
1637 where we'd get an Eq (f a) constraint.  That's probably fine too.
1638
1639 One could go further: consider
1640         data T a b c = MkT (Foo a b c) deriving( Eq )
1641         instance (C Int a, Eq b, Eq c) => Eq (Foo a b c)
1642
1643 Notice that this instance (just) satisfies the Paterson termination
1644 conditions.  Then we *could* derive an instance decl like this:
1645
1646         instance (C Int a, Eq b, Eq c) => Eq (T a b c)
1647
1648 even though there is no instance for (C Int a), because there just
1649 *might* be an instance for, say, (C Int Bool) at a site where we
1650 need the equality instance for T's.
1651
1652 However, this seems pretty exotic, and it's quite tricky to allow
1653 this, and yet give sensible error messages in the (much more common)
1654 case where we really want that instance decl for C.
1655
1656 So for now we simply require that the derived instance context
1657 should have only type-variable constraints.
1658
1659 Here is another example:
1660         data Fix f = In (f (Fix f)) deriving( Eq )
1661 Here, if we are prepared to allow -XUndecidableInstances we
1662 could derive the instance
1663         instance Eq (f (Fix f)) => Eq (Fix f)
1664 but this is so delicate that I don't think it should happen inside
1665 'deriving'. If you want this, write it yourself!
1666
1667 NB: if you want to lift this condition, make sure you still meet the
1668 termination conditions!  If not, the deriving mechanism generates
1669 larger and larger constraints.  Example:
1670   data Succ a = S a
1671   data Seq a = Cons a (Seq (Succ a)) | Nil deriving Show
1672
1673 Note the lack of a Show instance for Succ.  First we'll generate
1674   instance (Show (Succ a), Show a) => Show (Seq a)
1675 and then
1676   instance (Show (Succ (Succ a)), Show (Succ a), Show a) => Show (Seq a)
1677 and so on.  Instead we want to complain of no instance for (Show (Succ a)).
1678
1679 The bottom line
1680 ~~~~~~~~~~~~~~~
1681 Allow constraints which consist only of type variables, with no repeats.
1682
1683 \begin{code}
1684 validDerivPred :: PredType -> Bool
1685 validDerivPred (ClassP _ tys) = hasNoDups fvs && sizeTypes tys == length fvs
1686                               where fvs = fvTypes tys
1687 validDerivPred _              = False
1688 \end{code}
1689
1690 %************************************************************************
1691 %*                                                                      *
1692         Checking type instance well-formedness and termination
1693 %*                                                                      *
1694 %************************************************************************
1695
1696 \begin{code}
1697 -- Check that a "type instance" is well-formed (which includes decidability
1698 -- unless -XUndecidableInstances is given).
1699 --
1700 checkValidTypeInst :: [Type] -> Type -> TcM ()
1701 checkValidTypeInst typats rhs
1702   = do { -- left-hand side contains no type family applications
1703          -- (vanilla synonyms are fine, though)
1704        ; mapM_ checkTyFamFreeness typats
1705
1706          -- the right-hand side is a tau type
1707        ; checkValidMonoType rhs
1708
1709          -- we have a decidable instance unless otherwise permitted
1710        ; undecidable_ok <- doptM Opt_UndecidableInstances
1711        ; unless undecidable_ok $
1712            mapM_ addErrTc (checkFamInst typats (tyFamInsts rhs))
1713        }
1714
1715 -- Make sure that each type family instance is
1716 --   (1) strictly smaller than the lhs,
1717 --   (2) mentions no type variable more often than the lhs, and
1718 --   (3) does not contain any further type family instances.
1719 --
1720 checkFamInst :: [Type]                  -- lhs
1721              -> [(TyCon, [Type])]       -- type family instances
1722              -> [Message]
1723 checkFamInst lhsTys famInsts
1724   = mapCatMaybes check famInsts
1725   where
1726    size = sizeTypes lhsTys
1727    fvs  = fvTypes lhsTys
1728    check (tc, tys)
1729       | not (all isTyFamFree tys)
1730       = Just (famInstUndecErr famInst nestedMsg $$ parens undecidableMsg)
1731       | not (null (fvTypes tys \\ fvs))
1732       = Just (famInstUndecErr famInst nomoreVarMsg $$ parens undecidableMsg)
1733       | size <= sizeTypes tys
1734       = Just (famInstUndecErr famInst smallerAppMsg $$ parens undecidableMsg)
1735       | otherwise
1736       = Nothing
1737       where
1738         famInst = TyConApp tc tys
1739
1740 -- Ensure that no type family instances occur in a type.
1741 --
1742 checkTyFamFreeness :: Type -> TcM ()
1743 checkTyFamFreeness ty
1744   = checkTc (isTyFamFree ty) $
1745       tyFamInstIllegalErr ty
1746
1747 -- Check that a type does not contain any type family applications.
1748 --
1749 isTyFamFree :: Type -> Bool
1750 isTyFamFree = null . tyFamInsts
1751
1752 -- Error messages
1753
1754 tyFamInstIllegalErr :: Type -> SDoc
1755 tyFamInstIllegalErr ty
1756   = hang (ptext (sLit "Illegal type synonym family application in instance") <>
1757          colon) 4 $
1758       ppr ty
1759
1760 famInstUndecErr :: Type -> SDoc -> SDoc
1761 famInstUndecErr ty msg
1762   = sep [msg,
1763          nest 2 (ptext (sLit "in the type family application:") <+>
1764                  pprType ty)]
1765
1766 nestedMsg, nomoreVarMsg, smallerAppMsg :: SDoc
1767 nestedMsg     = ptext (sLit "Nested type family application")
1768 nomoreVarMsg  = ptext (sLit "Variable occurs more often than in instance head")
1769 smallerAppMsg = ptext (sLit "Application is no smaller than the instance head")
1770 \end{code}
1771
1772
1773 %************************************************************************
1774 %*                                                                      *
1775 \subsection{Auxiliary functions}
1776 %*                                                                      *
1777 %************************************************************************
1778
1779 \begin{code}
1780 -- Free variables of a type, retaining repetitions, and expanding synonyms
1781 fvType :: Type -> [TyVar]
1782 fvType ty | Just exp_ty <- tcView ty = fvType exp_ty
1783 fvType (TyVarTy tv)        = [tv]
1784 fvType (TyConApp _ tys)    = fvTypes tys
1785 fvType (PredTy pred)       = fvPred pred
1786 fvType (FunTy arg res)     = fvType arg ++ fvType res
1787 fvType (AppTy fun arg)     = fvType fun ++ fvType arg
1788 fvType (ForAllTy tyvar ty) = filter (/= tyvar) (fvType ty)
1789
1790 fvTypes :: [Type] -> [TyVar]
1791 fvTypes tys                = concat (map fvType tys)
1792
1793 fvPred :: PredType -> [TyVar]
1794 fvPred (ClassP _ tys')     = fvTypes tys'
1795 fvPred (IParam _ ty)       = fvType ty
1796 fvPred (EqPred ty1 ty2)    = fvType ty1 ++ fvType ty2
1797
1798 -- Size of a type: the number of variables and constructors
1799 sizeType :: Type -> Int
1800 sizeType ty | Just exp_ty <- tcView ty = sizeType exp_ty
1801 sizeType (TyVarTy _)       = 1
1802 sizeType (TyConApp _ tys)  = sizeTypes tys + 1
1803 sizeType (PredTy pred)     = sizePred pred
1804 sizeType (FunTy arg res)   = sizeType arg + sizeType res + 1
1805 sizeType (AppTy fun arg)   = sizeType fun + sizeType arg
1806 sizeType (ForAllTy _ ty)   = sizeType ty
1807
1808 sizeTypes :: [Type] -> Int
1809 sizeTypes xs               = sum (map sizeType xs)
1810
1811 sizePred :: PredType -> Int
1812 sizePred (ClassP _ tys')   = sizeTypes tys'
1813 sizePred (IParam _ ty)     = sizeType ty
1814 sizePred (EqPred ty1 ty2)  = sizeType ty1 + sizeType ty2
1815 \end{code}