compiler/typecheck/TcMType.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Monadic type operations
   7
   8 This module contains monadic operations over types that contain
   9 mutable type variables
  10
  11 \begin{code}
  12 module TcMType (
  13   TcTyVar, TcKind, TcType, TcTauType, TcThetaType, TcTyVarSet,
  14
  15   --------------------------------
  16   -- Creating new mutable type variables
  17   newFlexiTyVar,
  18   newFlexiTyVarTy,              -- Kind -> TcM TcType
  19   newFlexiTyVarTys,             -- Int -> Kind -> TcM [TcType]
  20   newKindVar, newKindVars,
  21   lookupTcTyVar, LookupTyVarResult(..),
  22
  23   newMetaTyVar, readMetaTyVar, writeMetaTyVar, isFilledMetaTyVar,
  24
  25   --------------------------------
  26   -- Boxy type variables
  27   newBoxyTyVar, newBoxyTyVars, newBoxyTyVarTys, readFilledBox,
  28
  29   --------------------------------
  30   -- Creating new coercion variables
  31   newCoVars, newMetaCoVar,
  32
  33   --------------------------------
  34   -- Instantiation
  35   tcInstTyVar, tcInstType, tcInstTyVars, tcInstBoxyTyVar,
  36   tcInstSigTyVars,
  37   tcInstSkolTyVar, tcInstSkolTyVars, tcInstSkolType,
  38   tcSkolSigType, tcSkolSigTyVars, occurCheckErr,
  39
  40   --------------------------------
  41   -- Checking type validity
  42   Rank, UserTypeCtxt(..), checkValidType, checkValidMonoType,
  43   SourceTyCtxt(..), checkValidTheta, checkFreeness,
  44   checkValidInstHead, checkValidInstance,
  45   checkInstTermination, checkValidTypeInst, checkTyFamFreeness,
  46   checkUpdateMeta, updateMeta, checkTauTvUpdate, fillBoxWithTau, unifyKindCtxt,
  47   unifyKindMisMatch, validDerivPred, arityErr, notMonoType, notMonoArgs,
  48
  49   --------------------------------
  50   -- Zonking
  51   zonkType, zonkTcPredType,
  52   zonkTcTyVar, zonkTcTyVars, zonkTcTyVarsAndFV, zonkSigTyVar,
  53   zonkQuantifiedTyVar, zonkQuantifiedTyVars,
  54   zonkTcType, zonkTcTypes, zonkTcThetaType,
  55   zonkTcKindToKind, zonkTcKind, zonkTopTyVar,
  56
  57   readKindVar, writeKindVar
  58   ) where
  59
  60 #include "HsVersions.h"
  61
  62 -- friends:
  63 import TypeRep
  64 import TcType
  65 import Type
  66 import Coercion
  67 import Class
  68 import TyCon
  69 import Var
  70
  71 -- others:
  72 import TcRnMonad          -- TcType, amongst others
  73 import FunDeps
  74 import Name
  75 import VarEnv
  76 import VarSet
  77 import ErrUtils
  78 import DynFlags
  79 import Util
  80 import Maybes
  81 import ListSetOps
  82 import UniqSupply
  83 import SrcLoc
  84 import Outputable
  85 import FastString
  86
  87 import Control.Monad
  88 import Data.List        ( (\\) )
  89 \end{code}
  90
  91
  92 %************************************************************************
  93 %*                                                                      *
  94         Instantiation in general
  95 %*                                                                      *
  96 %************************************************************************
  97
  98 \begin{code}
  99 tcInstType :: ([TyVar] -> TcM [TcTyVar])                -- How to instantiate the type variables
 100            -> TcType                                    -- Type to instantiate
 101            -> TcM ([TcTyVar], TcThetaType, TcType)      -- Result
 102                 -- (type vars (excl coercion vars), preds (incl equalities), rho)
 103 tcInstType inst_tyvars ty
 104   = case tcSplitForAllTys ty of
 105         ([],     rho) -> let    -- There may be overloading despite no type variables;
 106                                 --      (?x :: Int) => Int -> Int
 107                            (theta, tau) = tcSplitPhiTy rho
 108                          in
 109                          return ([], theta, tau)
 110
 111         (tyvars, rho) -> do { tyvars' <- inst_tyvars tyvars
 112
 113                             ; let  tenv = zipTopTvSubst tyvars (mkTyVarTys tyvars')
 114                                 -- Either the tyvars are freshly made, by inst_tyvars,
 115                                 -- or (in the call from tcSkolSigType) any nested foralls
 116                                 -- have different binders.  Either way, zipTopTvSubst is ok
 117
 118                             ; let  (theta, tau) = tcSplitPhiTy (substTy tenv rho)
 119                             ; return (tyvars', theta, tau) }
 120 \end{code}
 121
 122
 123 %************************************************************************
 124 %*                                                                      *
 125         Updating tau types
 126 %*                                                                      *
 127 %************************************************************************
 128
 129 Can't be in TcUnify, as we also need it in TcTyFuns.
 130
 131 \begin{code}
 132 type SwapFlag = Bool
 133         -- False <=> the two args are (actual, expected) respectively
 134         -- True  <=> the two args are (expected, actual) respectively
 135
 136 checkUpdateMeta :: SwapFlag
 137                 -> TcTyVar -> IORef MetaDetails -> TcType -> TcM ()
 138 -- Update tv1, which is flexi; occurs check is alrady done
 139 -- The 'check' version does a kind check too
 140 -- We do a sub-kind check here: we might unify (a b) with (c d)
 141 --      where b::*->* and d::*; this should fail
 142
 143 checkUpdateMeta swapped tv1 ref1 ty2
 144   = do  { checkKinds swapped tv1 ty2
 145         ; updateMeta tv1 ref1 ty2 }
 146
 147 updateMeta :: TcTyVar -> IORef MetaDetails -> TcType -> TcM ()
 148 updateMeta tv1 ref1 ty2
 149   = ASSERT( isMetaTyVar tv1 )
 150     ASSERT( isBoxyTyVar tv1 || isTauTy ty2 )
 151     do  { ASSERTM2( do { details <- readMetaTyVar tv1; return (isFlexi details) }, ppr tv1 )
 152         ; traceTc (text "updateMeta" <+> ppr tv1 <+> text ":=" <+> ppr ty2)
 153         ; writeMutVar ref1 (Indirect ty2)
 154         }
 155
 156 ----------------
 157 checkKinds :: Bool -> TyVar -> Type -> TcM ()
 158 checkKinds swapped tv1 ty2
 159 -- We're about to unify a type variable tv1 with a non-tyvar-type ty2.
 160 -- ty2 has been zonked at this stage, which ensures that
 161 -- its kind has as much boxity information visible as possible.
 162   | tk2 `isSubKind` tk1 = return ()
 163
 164   | otherwise
 165         -- Either the kinds aren't compatible
 166         --      (can happen if we unify (a b) with (c d))
 167         -- or we are unifying a lifted type variable with an
 168         --      unlifted type: e.g.  (id 3#) is illegal
 169   = addErrCtxtM (unifyKindCtxt swapped tv1 ty2) $
 170     unifyKindMisMatch k1 k2
 171   where
 172     (k1,k2) | swapped   = (tk2,tk1)
 173             | otherwise = (tk1,tk2)
 174     tk1 = tyVarKind tv1
 175     tk2 = typeKind ty2
 176
 177 ----------------
 178 checkTauTvUpdate :: TcTyVar -> TcType -> TcM (Maybe TcType)
 179 --    (checkTauTvUpdate tv ty)
 180 -- We are about to update the TauTv tv with ty.
 181 -- Check (a) that tv doesn't occur in ty (occurs check)
 182 --       (b) that ty is a monotype
 183 -- Furthermore, in the interest of (b), if you find an
 184 -- empty box (BoxTv that is Flexi), fill it in with a TauTv
 185 --
 186 -- We have three possible outcomes:
 187 -- (1) Return the (non-boxy) type to update the type variable with,
 188 --     [we know the update is ok!]
 189 -- (2) return Nothing, or
 190 --     [we cannot tell whether the update is ok right now]
 191 -- (3) fails.
 192 --     [the update is definitely invalid]
 193 -- We return Nothing in case the tv occurs in ty *under* a type family
 194 -- application.  In this case, we must not update tv (to avoid a cyclic type
 195 -- term), but we also cannot fail claiming an infinite type.  Given
 196 --   type family F a
 197 --   type instance F Int = Int
 198 -- consider
 199 --   a ~ F a
 200 -- This is perfectly reasonable, if we later get a ~ Int.
 201
 202 checkTauTvUpdate orig_tv orig_ty
 203   = do { result <- go orig_ty
 204        ; case result of
 205            Right ty    -> return $ Just ty
 206            Left  True  -> return $ Nothing
 207            Left  False -> occurCheckErr (mkTyVarTy orig_tv) orig_ty
 208        }
 209   where
 210     go :: TcType -> TcM (Either Bool TcType)
 211     -- go returns
 212     --   Right ty    if everything is fine
 213     --   Left True   if orig_tv occurs in orig_ty, but under a type family app
 214     --   Left False  if orig_tv occurs in orig_ty (with no type family app)
 215     -- It fails if it encounters a forall type, except as an argument for a
 216     -- closed type synonym that expands to a tau type.
 217     go (TyConApp tc tys)
 218         | isSynTyCon tc  = go_syn tc tys
 219         | otherwise      = do { tys' <- mapM go tys
 220                               ; return $ occurs (TyConApp tc) tys' }
 221     go (PredTy p)             = do { p' <- go_pred p
 222                               ; return $ occurs1 PredTy p' }
 223     go (FunTy arg res)   = do { arg' <- go arg
 224                               ; res' <- go res
 225                               ; return $ occurs2 FunTy arg' res' }
 226     go (AppTy fun arg)   = do { fun' <- go fun
 227                               ; arg' <- go arg
 228                               ; return $ occurs2 mkAppTy fun' arg' }
 229                 -- NB the mkAppTy; we might have instantiated a
 230                 -- type variable to a type constructor, so we need
 231                 -- to pull the TyConApp to the top.
 232     go (ForAllTy _ _) = notMonoType orig_ty             -- (b)
 233
 234     go (TyVarTy tv)
 235         | orig_tv == tv = return $ Left False           -- (a)
 236         | isTcTyVar tv  = go_tyvar tv (tcTyVarDetails tv)
 237         | otherwise     = return $ Right (TyVarTy tv)
 238                  -- Ordinary (non Tc) tyvars
 239                  -- occur inside quantified types
 240
 241     go_pred (ClassP c tys) = do { tys' <- mapM go tys
 242                                 ; return $ occurs (ClassP c) tys' }
 243     go_pred (IParam n ty)  = do { ty' <- go ty
 244                                 ; return $ occurs1 (IParam n) ty' }
 245     go_pred (EqPred t1 t2) = do { t1' <- go t1
 246                                 ; t2' <- go t2
 247                                 ; return $ occurs2 EqPred t1' t2' }
 248
 249     go_tyvar tv (SkolemTv _) = return $ Right (TyVarTy tv)
 250     go_tyvar tv (MetaTv box ref)
 251         = do { cts <- readMutVar ref
 252              ; case cts of
 253                   Indirect ty -> go ty
 254                   Flexi -> case box of
 255                                 BoxTv -> do { ty <- fillBoxWithTau tv ref
 256                                             ; return $ Right ty }
 257                                 _     -> return $ Right (TyVarTy tv)
 258              }
 259
 260         -- go_syn is called for synonyms only
 261         -- See Note [Type synonyms and the occur check]
 262     go_syn tc tys
 263         | not (isTauTyCon tc)
 264         = notMonoType orig_ty   -- (b) again
 265         | otherwise
 266         = do { (_msgs, mb_tys') <- tryTc (mapM go tys)
 267              ; case mb_tys' of
 268
 269                 -- we had a type error => forall in type parameters
 270                 Nothing
 271                   | isOpenTyCon tc -> notMonoArgs (TyConApp tc tys)
 272                         -- Synonym families must have monotype args
 273                   | otherwise      -> go (expectJust "checkTauTvUpdate(1)"
 274                                             (tcView (TyConApp tc tys)))
 275                         -- Try again, expanding the synonym
 276
 277                 -- no type error, but need to test whether occurs check happend
 278                 Just tys' ->
 279                   case occurs id tys' of
 280                     Left _
 281                       | isOpenTyCon tc -> return $ Left True
 282                         -- Variable occured under type family application
 283                       | otherwise      -> go (expectJust "checkTauTvUpdate(2)"
 284                                                (tcView (TyConApp tc tys)))
 285                         -- Try again, expanding the synonym
 286                     Right raw_tys'     -> return $ Right (TyConApp tc raw_tys')
 287                         -- Retain the synonym (the common case)
 288              }
 289
 290     -- Left results (= occurrence of orig_ty) dominate and
 291     -- (Left False) (= fatal occurrence) dominates over (Left True)
 292     occurs :: ([a] -> b) -> [Either Bool a] -> Either Bool b
 293     occurs c = either Left (Right . c) . foldr combine (Right [])
 294       where
 295         combine (Left famInst1) (Left famInst2) = Left (famInst1 && famInst2)
 296         combine (Right _      ) (Left famInst)  = Left famInst
 297         combine (Left famInst)  (Right _)       = Left famInst
 298         combine (Right arg)     (Right args)    = Right (arg:args)
 299
 300     occurs1 c x   = occurs (\[x']     -> c x')    [x]
 301     occurs2 c x y = occurs (\[x', y'] -> c x' y') [x, y]
 302
 303 fillBoxWithTau :: BoxyTyVar -> IORef MetaDetails -> TcM TcType
 304 -- (fillBoxWithTau tv ref) fills ref with a freshly allocated
 305 --  tau-type meta-variable, whose print-name is the same as tv
 306 -- Choosing the same name is good: when we instantiate a function
 307 -- we allocate boxy tyvars with the same print-name as the quantified
 308 -- tyvar; and then we often fill the box with a tau-tyvar, and again
 309 -- we want to choose the same name.
 310 fillBoxWithTau tv ref
 311   = do  { tv' <- tcInstTyVar tv         -- Do not gratuitously forget
 312         ; let tau = mkTyVarTy tv'       -- name of the type variable
 313         ; writeMutVar ref (Indirect tau)
 314         ; return tau }
 315 \end{code}
 316
 317 Note [Type synonyms and the occur check]
 318 ~~~~~~~~~~~~~~~~~~~~
 319 Basically we want to update     tv1 := ps_ty2
 320 because ps_ty2 has type-synonym info, which improves later error messages
 321
 322 But consider
 323         type A a = ()
 324
 325         f :: (A a -> a -> ()) -> ()
 326         f = \ _ -> ()
 327
 328         x :: ()
 329         x = f (\ x p -> p x)
 330
 331 In the application (p x), we try to match "t" with "A t".  If we go
 332 ahead and bind t to A t (= ps_ty2), we'll lead the type checker into
 333 an infinite loop later.
 334 But we should not reject the program, because A t = ().
 335 Rather, we should bind t to () (= non_var_ty2).
 336
 337 --------------
 338
 339 Error mesages in case of kind mismatch.
 340
 341 \begin{code}
 342 unifyKindMisMatch :: TcKind -> TcKind -> TcM ()
 343 unifyKindMisMatch ty1 ty2 = do
 344     ty1' <- zonkTcKind ty1
 345     ty2' <- zonkTcKind ty2
 346     let
 347         msg = hang (ptext (sLit "Couldn't match kind"))
 348                    2 (sep [quotes (ppr ty1'),
 349                            ptext (sLit "against"),
 350                            quotes (ppr ty2')])
 351     failWithTc msg
 352
 353 unifyKindCtxt :: Bool -> TyVar -> Type -> TidyEnv -> TcM (TidyEnv, SDoc)
 354 unifyKindCtxt swapped tv1 ty2 tidy_env  -- not swapped => tv1 expected, ty2 inferred
 355         -- tv1 and ty2 are zonked already
 356   = return msg
 357   where
 358     msg = (env2, ptext (sLit "When matching the kinds of") <+>
 359                  sep [quotes pp_expected <+> ptext (sLit "and"), quotes pp_actual])
 360
 361     (pp_expected, pp_actual) | swapped   = (pp2, pp1)
 362                              | otherwise = (pp1, pp2)
 363     (env1, tv1') = tidyOpenTyVar tidy_env tv1
 364     (env2, ty2') = tidyOpenType  env1 ty2
 365     pp1 = ppr tv1' <+> dcolon <+> ppr (tyVarKind tv1)
 366     pp2 = ppr ty2' <+> dcolon <+> ppr (typeKind ty2)
 367 \end{code}
 368
 369 Error message for failure due to an occurs check.
 370
 371 \begin{code}
 372 occurCheckErr :: TcType -> TcType -> TcM a
 373 occurCheckErr ty containingTy
 374   = do  { env0 <- tcInitTidyEnv
 375         ; ty'           <- zonkTcType ty
 376         ; containingTy' <- zonkTcType containingTy
 377         ; let (env1, tidy_ty1) = tidyOpenType env0 ty'
 378               (env2, tidy_ty2) = tidyOpenType env1 containingTy'
 379               extra = sep [ppr tidy_ty1, char '=', ppr tidy_ty2]
 380         ; failWithTcM (env2, hang msg 2 extra) }
 381   where
 382     msg = ptext (sLit "Occurs check: cannot construct the infinite type:")
 383 \end{code}
 384
 385 %************************************************************************
 386 %*                                                                      *
 387         Kind variables
 388 %*                                                                      *
 389 %************************************************************************
 390
 391 \begin{code}
 392 newCoVars :: [(TcType,TcType)] -> TcM [CoVar]
 393 newCoVars spec
 394   = do  { us <- newUniqueSupply
 395         ; return [ mkCoVar (mkSysTvName uniq (fsLit "co"))
 396                            (mkCoKind ty1 ty2)
 397                  | ((ty1,ty2), uniq) <- spec `zip` uniqsFromSupply us] }
 398
 399 newMetaCoVar :: TcType -> TcType -> TcM TcTyVar
 400 newMetaCoVar ty1 ty2 = newMetaTyVar TauTv (mkCoKind ty1 ty2)
 401
 402 newKindVar :: TcM TcKind
 403 newKindVar = do { uniq <- newUnique
 404                 ; ref <- newMutVar Flexi
 405                 ; return (mkTyVarTy (mkKindVar uniq ref)) }
 406
 407 newKindVars :: Int -> TcM [TcKind]
 408 newKindVars n = mapM (\ _ -> newKindVar) (nOfThem n ())
 409 \end{code}
 410
 411
 412 %************************************************************************
 413 %*                                                                      *
 414         SkolemTvs (immutable)
 415 %*                                                                      *
 416 %************************************************************************
 417
 418 \begin{code}
 419 mkSkolTyVar :: Name -> Kind -> SkolemInfo -> TcTyVar
 420 mkSkolTyVar name kind info = mkTcTyVar name kind (SkolemTv info)
 421
 422 tcSkolSigType :: SkolemInfo -> Type -> TcM ([TcTyVar], TcThetaType, TcType)
 423 -- Instantiate a type signature with skolem constants, but
 424 -- do *not* give them fresh names, because we want the name to
 425 -- be in the type environment -- it is lexically scoped.
 426 tcSkolSigType info ty = tcInstType (\tvs -> return (tcSkolSigTyVars info tvs)) ty
 427
 428 tcSkolSigTyVars :: SkolemInfo -> [TyVar] -> [TcTyVar]
 429 -- Make skolem constants, but do *not* give them new names, as above
 430 tcSkolSigTyVars info tyvars = [ mkSkolTyVar (tyVarName tv) (tyVarKind tv) info
 431                               | tv <- tyvars ]
 432
 433 tcInstSkolTyVar :: SkolemInfo -> Maybe SrcSpan -> TyVar -> TcM TcTyVar
 434 -- Instantiate the tyvar, using
 435 --      * the occ-name and kind of the supplied tyvar,
 436 --      * the unique from the monad,
 437 --      * the location either from the tyvar (mb_loc = Nothing)
 438 --        or from mb_loc (Just loc)
 439 tcInstSkolTyVar info mb_loc tyvar
 440   = do  { uniq <- newUnique
 441         ; let old_name = tyVarName tyvar
 442               kind     = tyVarKind tyvar
 443               loc      = mb_loc `orElse` getSrcSpan old_name
 444               new_name = mkInternalName uniq (nameOccName old_name) loc
 445         ; return (mkSkolTyVar new_name kind info) }
 446
 447 tcInstSkolTyVars :: SkolemInfo -> [TyVar] -> TcM [TcTyVar]
 448 -- Get the location from the monad
 449 tcInstSkolTyVars info tyvars
 450   = do  { span <- getSrcSpanM
 451         ; mapM (tcInstSkolTyVar info (Just span)) tyvars }
 452
 453 tcInstSkolType :: SkolemInfo -> TcType -> TcM ([TcTyVar], TcThetaType, TcType)
 454 -- Instantiate a type with fresh skolem constants
 455 -- Binding location comes from the monad
 456 tcInstSkolType info ty = tcInstType (tcInstSkolTyVars info) ty
 457 \end{code}
 458
 459
 460 %************************************************************************
 461 %*                                                                      *
 462         MetaTvs (meta type variables; mutable)
 463 %*                                                                      *
 464 %************************************************************************
 465
 466 \begin{code}
 467 newMetaTyVar :: BoxInfo -> Kind -> TcM TcTyVar
 468 -- Make a new meta tyvar out of thin air
 469 newMetaTyVar box_info kind
 470   = do  { uniq <- newUnique
 471         ; ref <- newMutVar Flexi
 472         ; let name = mkSysTvName uniq fs
 473               fs = case box_info of
 474                         BoxTv   -> fsLit "t"
 475                         TauTv   -> fsLit "t"
 476                         SigTv _ -> fsLit "a"
 477                 -- We give BoxTv and TauTv the same string, because
 478                 -- otherwise we get user-visible differences in error
 479                 -- messages, which are confusing.  If you want to see
 480                 -- the box_info of each tyvar, use -dppr-debug
 481         ; return (mkTcTyVar name kind (MetaTv box_info ref)) }
 482
 483 instMetaTyVar :: BoxInfo -> TyVar -> TcM TcTyVar
 484 -- Make a new meta tyvar whose Name and Kind
 485 -- come from an existing TyVar
 486 instMetaTyVar box_info tyvar
 487   = do  { uniq <- newUnique
 488         ; ref <- newMutVar Flexi
 489         ; let name = setNameUnique (tyVarName tyvar) uniq
 490               kind = tyVarKind tyvar
 491         ; return (mkTcTyVar name kind (MetaTv box_info ref)) }
 492
 493 readMetaTyVar :: TyVar -> TcM MetaDetails
 494 readMetaTyVar tyvar = ASSERT2( isMetaTyVar tyvar, ppr tyvar )
 495                       readMutVar (metaTvRef tyvar)
 496
 497 isFilledMetaTyVar :: TyVar -> TcM Bool
 498 -- True of a filled-in (Indirect) meta type variable
 499 isFilledMetaTyVar tv
 500   | not (isTcTyVar tv) = return False
 501   | MetaTv _ ref <- tcTyVarDetails tv
 502   = do  { details <- readMutVar ref
 503         ; return (isIndirect details) }
 504   | otherwise = return False
 505
 506 writeMetaTyVar :: TcTyVar -> TcType -> TcM ()
 507 writeMetaTyVar tyvar ty
 508   | not debugIsOn = writeMutVar (metaTvRef tyvar) (Indirect ty)
 509 writeMetaTyVar tyvar ty
 510   | not (isMetaTyVar tyvar)
 511   = pprTrace "writeMetaTyVar" (ppr tyvar) $
 512     return ()
 513   | otherwise
 514   = ASSERT( isMetaTyVar tyvar )
 515     -- TOM: It should also work for coercions
 516     -- ASSERT2( k2 `isSubKind` k1, (ppr tyvar <+> ppr k1) $$ (ppr ty <+> ppr k2) )
 517     do  { ASSERTM2( do { details <- readMetaTyVar tyvar; return (isFlexi details) }, ppr tyvar )
 518         ; writeMutVar (metaTvRef tyvar) (Indirect ty) }
 519   where
 520     _k1 = tyVarKind tyvar
 521     _k2 = typeKind ty
 522 \end{code}
 523
 524
 525 %************************************************************************
 526 %*                                                                      *
 527         MetaTvs: TauTvs
 528 %*                                                                      *
 529 %************************************************************************
 530
 531 \begin{code}
 532 newFlexiTyVar :: Kind -> TcM TcTyVar
 533 newFlexiTyVar kind = newMetaTyVar TauTv kind
 534
 535 newFlexiTyVarTy  :: Kind -> TcM TcType
 536 newFlexiTyVarTy kind = do
 537     tc_tyvar <- newFlexiTyVar kind
 538     return (TyVarTy tc_tyvar)
 539
 540 newFlexiTyVarTys :: Int -> Kind -> TcM [TcType]
 541 newFlexiTyVarTys n kind = mapM newFlexiTyVarTy (nOfThem n kind)
 542
 543 tcInstTyVar :: TyVar -> TcM TcTyVar
 544 -- Instantiate with a META type variable
 545 tcInstTyVar tyvar = instMetaTyVar TauTv tyvar
 546
 547 tcInstTyVars :: [TyVar] -> TcM ([TcTyVar], [TcType], TvSubst)
 548 -- Instantiate with META type variables
 549 tcInstTyVars tyvars
 550   = do  { tc_tvs <- mapM tcInstTyVar tyvars
 551         ; let tys = mkTyVarTys tc_tvs
 552         ; return (tc_tvs, tys, zipTopTvSubst tyvars tys) }
 553                 -- Since the tyvars are freshly made,
 554                 -- they cannot possibly be captured by
 555                 -- any existing for-alls.  Hence zipTopTvSubst
 556 \end{code}
 557
 558
 559 %************************************************************************
 560 %*                                                                      *
 561         MetaTvs: SigTvs
 562 %*                                                                      *
 563 %************************************************************************
 564
 565 \begin{code}
 566 tcInstSigTyVars :: Bool -> SkolemInfo -> [TyVar] -> TcM [TcTyVar]
 567 -- Instantiate with skolems or meta SigTvs; depending on use_skols
 568 -- Always take location info from the supplied tyvars
 569 tcInstSigTyVars use_skols skol_info tyvars
 570   | use_skols
 571   = mapM (tcInstSkolTyVar skol_info Nothing) tyvars
 572
 573   | otherwise
 574   = mapM (instMetaTyVar (SigTv skol_info)) tyvars
 575
 576 zonkSigTyVar :: TcTyVar -> TcM TcTyVar
 577 zonkSigTyVar sig_tv
 578   | isSkolemTyVar sig_tv
 579   = return sig_tv       -- Happens in the call in TcBinds.checkDistinctTyVars
 580   | otherwise
 581   = ASSERT( isSigTyVar sig_tv )
 582     do { ty <- zonkTcTyVar sig_tv
 583        ; return (tcGetTyVar "zonkSigTyVar" ty) }
 584         -- 'ty' is bound to be a type variable, because SigTvs
 585         -- can only be unified with type variables
 586 \end{code}
 587
 588
 589 %************************************************************************
 590 %*                                                                      *
 591         MetaTvs: BoxTvs
 592 %*                                                                      *
 593 %************************************************************************
 594
 595 \begin{code}
 596 newBoxyTyVar :: Kind -> TcM BoxyTyVar
 597 newBoxyTyVar kind = newMetaTyVar BoxTv kind
 598
 599 newBoxyTyVars :: [Kind] -> TcM [BoxyTyVar]
 600 newBoxyTyVars kinds = mapM newBoxyTyVar kinds
 601
 602 newBoxyTyVarTys :: [Kind] -> TcM [BoxyType]
 603 newBoxyTyVarTys kinds = do { tvs <- mapM newBoxyTyVar kinds; return (mkTyVarTys tvs) }
 604
 605 readFilledBox :: BoxyTyVar -> TcM TcType
 606 -- Read the contents of the box, which should be filled in by now
 607 readFilledBox box_tv = ASSERT( isBoxyTyVar box_tv )
 608                        do { cts <- readMetaTyVar box_tv
 609                           ; case cts of
 610                                 Flexi -> pprPanic "readFilledBox" (ppr box_tv)
 611                                 Indirect ty -> return ty }
 612
 613 tcInstBoxyTyVar :: TyVar -> TcM BoxyTyVar
 614 -- Instantiate with a BOXY type variable
 615 tcInstBoxyTyVar tyvar = instMetaTyVar BoxTv tyvar
 616 \end{code}
 617
 618
 619 %************************************************************************
 620 %*                                                                      *
 621 \subsection{Putting and getting  mutable type variables}
 622 %*                                                                      *
 623 %************************************************************************
 624
 625 But it's more fun to short out indirections on the way: If this
 626 version returns a TyVar, then that TyVar is unbound.  If it returns
 627 any other type, then there might be bound TyVars embedded inside it.
 628
 629 We return Nothing iff the original box was unbound.
 630
 631 \begin{code}
 632 data LookupTyVarResult  -- The result of a lookupTcTyVar call
 633   = DoneTv TcTyVarDetails       -- SkolemTv or virgin MetaTv
 634   | IndirectTv TcType
 635
 636 lookupTcTyVar :: TcTyVar -> TcM LookupTyVarResult
 637 lookupTcTyVar tyvar
 638   = ASSERT2( isTcTyVar tyvar, ppr tyvar )
 639     case details of
 640       SkolemTv _   -> return (DoneTv details)
 641       MetaTv _ ref -> do { meta_details <- readMutVar ref
 642                          ; case meta_details of
 643                             Indirect ty -> return (IndirectTv ty)
 644                             Flexi -> return (DoneTv details) }
 645   where
 646     details =  tcTyVarDetails tyvar
 647
 648 {-
 649 -- gaw 2004 We aren't shorting anything out anymore, at least for now
 650 getTcTyVar tyvar
 651   | not (isTcTyVar tyvar)
 652   = pprTrace "getTcTyVar" (ppr tyvar) $
 653     return (Just (mkTyVarTy tyvar))
 654
 655   | otherwise
 656   = ASSERT2( isTcTyVar tyvar, ppr tyvar ) do
 657     maybe_ty <- readMetaTyVar tyvar
 658     case maybe_ty of
 659         Just ty -> do ty' <- short_out ty
 660                       writeMetaTyVar tyvar (Just ty')
 661                       return (Just ty')
 662
 663         Nothing    -> return Nothing
 664
 665 short_out :: TcType -> TcM TcType
 666 short_out ty@(TyVarTy tyvar)
 667   | not (isTcTyVar tyvar)
 668   = return ty
 669
 670   | otherwise = do
 671     maybe_ty <- readMetaTyVar tyvar
 672     case maybe_ty of
 673         Just ty' -> do ty' <- short_out ty'
 674                        writeMetaTyVar tyvar (Just ty')
 675                        return ty'
 676
 677         other    -> return ty
 678
 679 short_out other_ty = return other_ty
 680 -}
 681 \end{code}
 682
 683
 684 %************************************************************************
 685 %*                                                                      *
 686 \subsection{Zonking -- the exernal interfaces}
 687 %*                                                                      *
 688 %************************************************************************
 689
 690 -----------------  Type variables
 691
 692 \begin{code}
 693 zonkTcTyVars :: [TcTyVar] -> TcM [TcType]
 694 zonkTcTyVars tyvars = mapM zonkTcTyVar tyvars
 695
 696 zonkTcTyVarsAndFV :: [TcTyVar] -> TcM TcTyVarSet
 697 zonkTcTyVarsAndFV tyvars = tyVarsOfTypes <$> mapM zonkTcTyVar tyvars
 698
 699 zonkTcTyVar :: TcTyVar -> TcM TcType
 700 zonkTcTyVar tyvar = ASSERT2( isTcTyVar tyvar, ppr tyvar)
 701                     zonk_tc_tyvar (\ tv -> return (TyVarTy tv)) tyvar
 702 \end{code}
 703
 704 -----------------  Types
 705
 706 \begin{code}
 707 zonkTcType :: TcType -> TcM TcType
 708 zonkTcType ty = zonkType (\ tv -> return (TyVarTy tv)) ty
 709
 710 zonkTcTypes :: [TcType] -> TcM [TcType]
 711 zonkTcTypes tys = mapM zonkTcType tys
 712
 713 zonkTcThetaType :: TcThetaType -> TcM TcThetaType
 714 zonkTcThetaType theta = mapM zonkTcPredType theta
 715
 716 zonkTcPredType :: TcPredType -> TcM TcPredType
 717 zonkTcPredType (ClassP c ts)  = ClassP c <$> zonkTcTypes ts
 718 zonkTcPredType (IParam n t)   = IParam n <$> zonkTcType t
 719 zonkTcPredType (EqPred t1 t2) = EqPred <$> zonkTcType t1 <*> zonkTcType t2
 720 \end{code}
 721
 722 -------------------  These ...ToType, ...ToKind versions
 723                      are used at the end of type checking
 724
 725 \begin{code}
 726 zonkTopTyVar :: TcTyVar -> TcM TcTyVar
 727 -- zonkTopTyVar is used, at the top level, on any un-instantiated meta type variables
 728 -- to default the kind of ? and ?? etc to *.  This is important to ensure that
 729 -- instance declarations match.  For example consider
 730 --      instance Show (a->b)
 731 --      foo x = show (\_ -> True)
 732 -- Then we'll get a constraint (Show (p ->q)) where p has argTypeKind (printed ??),
 733 -- and that won't match the typeKind (*) in the instance decl.
 734 --
 735 -- Because we are at top level, no further constraints are going to affect these
 736 -- type variables, so it's time to do it by hand.  However we aren't ready
 737 -- to default them fully to () or whatever, because the type-class defaulting
 738 -- rules have yet to run.
 739
 740 zonkTopTyVar tv
 741   | k `eqKind` default_k = return tv
 742   | otherwise
 743   = do  { tv' <- newFlexiTyVar default_k
 744         ; writeMetaTyVar tv (mkTyVarTy tv')
 745         ; return tv' }
 746   where
 747     k = tyVarKind tv
 748     default_k = defaultKind k
 749
 750 zonkQuantifiedTyVars :: [TcTyVar] -> TcM [TcTyVar]
 751 zonkQuantifiedTyVars = mapM zonkQuantifiedTyVar
 752
 753 zonkQuantifiedTyVar :: TcTyVar -> TcM TcTyVar
 754 -- zonkQuantifiedTyVar is applied to the a TcTyVar when quantifying over it.
 755 --
 756 -- The quantified type variables often include meta type variables
 757 -- we want to freeze them into ordinary type variables, and
 758 -- default their kind (e.g. from OpenTypeKind to TypeKind)
 759 --                      -- see notes with Kind.defaultKind
 760 -- The meta tyvar is updated to point to the new skolem TyVar.  Now any
 761 -- bound occurences of the original type variable will get zonked to
 762 -- the immutable version.
 763 --
 764 -- We leave skolem TyVars alone; they are immutable.
 765 zonkQuantifiedTyVar tv
 766   | ASSERT( isTcTyVar tv )
 767     isSkolemTyVar tv = return tv
 768         -- It might be a skolem type variable,
 769         -- for example from a user type signature
 770
 771   | otherwise   -- It's a meta-type-variable
 772   = do  { details <- readMetaTyVar tv
 773
 774         -- Create the new, frozen, skolem type variable
 775         -- We zonk to a skolem, not to a regular TcVar
 776         -- See Note [Zonking to Skolem]
 777         ; let final_kind = defaultKind (tyVarKind tv)
 778               final_tv   = mkSkolTyVar (tyVarName tv) final_kind UnkSkol
 779
 780         -- Bind the meta tyvar to the new tyvar
 781         ; case details of
 782             Indirect ty -> WARN( True, ppr tv $$ ppr ty )
 783                            return ()
 784                 -- [Sept 04] I don't think this should happen
 785                 -- See note [Silly Type Synonym]
 786
 787             Flexi -> writeMetaTyVar tv (mkTyVarTy final_tv)
 788
 789         -- Return the new tyvar
 790         ; return final_tv }
 791 \end{code}
 792
 793 Note [Silly Type Synonyms]
 794 ~~~~~~~~~~~~~~~~~~~~~~~~~~
 795 Consider this:
 796         type C u a = u  -- Note 'a' unused
 797
 798         foo :: (forall a. C u a -> C u a) -> u
 799         foo x = ...
 800
 801         bar :: Num u => u
 802         bar = foo (\t -> t + t)
 803
 804 * From the (\t -> t+t) we get type  {Num d} =>  d -> d
 805   where d is fresh.
 806
 807 * Now unify with type of foo's arg, and we get:
 808         {Num (C d a)} =>  C d a -> C d a
 809   where a is fresh.
 810
 811 * Now abstract over the 'a', but float out the Num (C d a) constraint
 812   because it does not 'really' mention a.  (see exactTyVarsOfType)
 813   The arg to foo becomes
 814         \/\a -> \t -> t+t
 815
 816 * So we get a dict binding for Num (C d a), which is zonked to give
 817         a = ()
 818   [Note Sept 04: now that we are zonking quantified type variables
 819   on construction, the 'a' will be frozen as a regular tyvar on
 820   quantification, so the floated dict will still have type (C d a).
 821   Which renders this whole note moot; happily!]
 822
 823 * Then the \/\a abstraction has a zonked 'a' in it.
 824
 825 All very silly.   I think its harmless to ignore the problem.  We'll end up with
 826 a \/\a in the final result but all the occurrences of a will be zonked to ()
 827
 828 Note [Zonking to Skolem]
 829 ~~~~~~~~~~~~~~~~~~~~~~~~
 830 We used to zonk quantified type variables to regular TyVars.  However, this
 831 leads to problems.  Consider this program from the regression test suite:
 832
 833   eval :: Int -> String -> String -> String
 834   eval 0 root actual = evalRHS 0 root actual
 835
 836   evalRHS :: Int -> a
 837   evalRHS 0 root actual = eval 0 root actual
 838
 839 It leads to the deferral of an equality
 840
 841   (String -> String -> String) ~ a
 842
 843 which is propagated up to the toplevel (see TcSimplify.tcSimplifyInferCheck).
 844 In the meantime `a' is zonked and quantified to form `evalRHS's signature.
 845 This has the *side effect* of also zonking the `a' in the deferred equality
 846 (which at this point is being handed around wrapped in an implication
 847 constraint).
 848
 849 Finally, the equality (with the zonked `a') will be handed back to the
 850 simplifier by TcRnDriver.tcRnSrcDecls calling TcSimplify.tcSimplifyTop.
 851 If we zonk `a' with a regular type variable, we will have this regular type
 852 variable now floating around in the simplifier, which in many places assumes to
 853 only see proper TcTyVars.
 854
 855 We can avoid this problem by zonking with a skolem.  The skolem is rigid
 856 (which we requirefor a quantified variable), but is still a TcTyVar that the
 857 simplifier knows how to deal with.
 858
 859
 860 %************************************************************************
 861 %*                                                                      *
 862 \subsection{Zonking -- the main work-horses: zonkType, zonkTyVar}
 863 %*                                                                      *
 864 %*              For internal use only!                                  *
 865 %*                                                                      *
 866 %************************************************************************
 867
 868 \begin{code}
 869 -- For unbound, mutable tyvars, zonkType uses the function given to it
 870 -- For tyvars bound at a for-all, zonkType zonks them to an immutable
 871 --      type variable and zonks the kind too
 872
 873 zonkType :: (TcTyVar -> TcM Type)       -- What to do with unbound mutable type variables
 874                                         -- see zonkTcType, and zonkTcTypeToType
 875          -> TcType
 876          -> TcM Type
 877 zonkType unbound_var_fn ty
 878   = go ty
 879   where
 880     go (TyConApp tc tys) = do tys' <- mapM go tys
 881                               return (TyConApp tc tys')
 882
 883     go (PredTy p)        = do p' <- go_pred p
 884                               return (PredTy p')
 885
 886     go (FunTy arg res)   = do arg' <- go arg
 887                               res' <- go res
 888                               return (FunTy arg' res')
 889
 890     go (AppTy fun arg)   = do fun' <- go fun
 891                               arg' <- go arg
 892                               return (mkAppTy fun' arg')
 893                 -- NB the mkAppTy; we might have instantiated a
 894                 -- type variable to a type constructor, so we need
 895                 -- to pull the TyConApp to the top.
 896
 897         -- The two interesting cases!
 898     go (TyVarTy tyvar) | isTcTyVar tyvar = zonk_tc_tyvar unbound_var_fn tyvar
 899                        | otherwise       = return (TyVarTy tyvar)
 900                 -- Ordinary (non Tc) tyvars occur inside quantified types
 901
 902     go (ForAllTy tyvar ty) = ASSERT( isImmutableTyVar tyvar ) do
 903                              ty' <- go ty
 904                              return (ForAllTy tyvar ty')
 905
 906     go_pred (ClassP c tys)   = do tys' <- mapM go tys
 907                                   return (ClassP c tys')
 908     go_pred (IParam n ty)    = do ty' <- go ty
 909                                   return (IParam n ty')
 910     go_pred (EqPred ty1 ty2) = do ty1' <- go ty1
 911                                   ty2' <- go ty2
 912                                   return (EqPred ty1' ty2')
 913
 914 zonk_tc_tyvar :: (TcTyVar -> TcM Type)          -- What to do for an unbound mutable variable
 915               -> TcTyVar -> TcM TcType
 916 zonk_tc_tyvar unbound_var_fn tyvar
 917   | not (isMetaTyVar tyvar)     -- Skolems
 918   = return (TyVarTy tyvar)
 919
 920   | otherwise                   -- Mutables
 921   = do  { cts <- readMetaTyVar tyvar
 922         ; case cts of
 923             Flexi       -> unbound_var_fn tyvar    -- Unbound meta type variable
 924             Indirect ty -> zonkType unbound_var_fn ty  }
 925 \end{code}
 926
 927
 928
 929 %************************************************************************
 930 %*                                                                      *
 931                         Zonking kinds
 932 %*                                                                      *
 933 %************************************************************************
 934
 935 \begin{code}
 936 readKindVar  :: KindVar -> TcM (MetaDetails)
 937 writeKindVar :: KindVar -> TcKind -> TcM ()
 938 readKindVar  kv = readMutVar (kindVarRef kv)
 939 writeKindVar kv val = writeMutVar (kindVarRef kv) (Indirect val)
 940
 941 -------------
 942 zonkTcKind :: TcKind -> TcM TcKind
 943 zonkTcKind k = zonkTcType k
 944
 945 -------------
 946 zonkTcKindToKind :: TcKind -> TcM Kind
 947 -- When zonking a TcKind to a kind, we need to instantiate kind variables,
 948 -- Haskell specifies that * is to be used, so we follow that.
 949 zonkTcKindToKind k = zonkType (\ _ -> return liftedTypeKind) k
 950 \end{code}
 951
 952 %************************************************************************
 953 %*                                                                      *
 954 \subsection{Checking a user type}
 955 %*                                                                      *
 956 %************************************************************************
 957
 958 When dealing with a user-written type, we first translate it from an HsType
 959 to a Type, performing kind checking, and then check various things that should
 960 be true about it.  We don't want to perform these checks at the same time
 961 as the initial translation because (a) they are unnecessary for interface-file
 962 types and (b) when checking a mutually recursive group of type and class decls,
 963 we can't "look" at the tycons/classes yet.  Also, the checks are are rather
 964 diverse, and used to really mess up the other code.
 965
 966 One thing we check for is 'rank'.
 967
 968         Rank 0:         monotypes (no foralls)
 969         Rank 1:         foralls at the front only, Rank 0 inside
 970         Rank 2:         foralls at the front, Rank 1 on left of fn arrow,
 971
 972         basic ::= tyvar | T basic ... basic
 973
 974         r2  ::= forall tvs. cxt => r2a
 975         r2a ::= r1 -> r2a | basic
 976         r1  ::= forall tvs. cxt => r0
 977         r0  ::= r0 -> r0 | basic
 978
 979 Another thing is to check that type synonyms are saturated.
 980 This might not necessarily show up in kind checking.
 981         type A i = i
 982         data T k = MkT (k Int)
 983         f :: T A        -- BAD!
 984
 985
 986 \begin{code}
 987 checkValidType :: UserTypeCtxt -> Type -> TcM ()
 988 -- Checks that the type is valid for the given context
 989 checkValidType ctxt ty = do
 990     traceTc (text "checkValidType" <+> ppr ty)
 991     unboxed  <- doptM Opt_UnboxedTuples
 992     rank2    <- doptM Opt_Rank2Types
 993     rankn    <- doptM Opt_RankNTypes
 994     polycomp <- doptM Opt_PolymorphicComponents
 995     let
 996         gen_rank n | rankn     = ArbitraryRank
 997                    | rank2     = Rank 2
 998                    | otherwise = Rank n
 999         rank
1000           = case ctxt of
1001                  GenPatCtxt     -> MustBeMonoType
1002                  DefaultDeclCtxt-> MustBeMonoType
1003                  ResSigCtxt     -> MustBeMonoType
1004                  LamPatSigCtxt  -> gen_rank 0
1005                  BindPatSigCtxt -> gen_rank 0
1006                  TySynCtxt _    -> gen_rank 0
1007                  ExprSigCtxt    -> gen_rank 1
1008                  FunSigCtxt _   -> gen_rank 1
1009                  ConArgCtxt _   | polycomp -> gen_rank 2
1010                                 -- We are given the type of the entire
1011                                 -- constructor, hence rank 1
1012                                 | otherwise -> gen_rank 1
1013                  ForSigCtxt _   -> gen_rank 1
1014                  SpecInstCtxt   -> gen_rank 1
1015
1016         actual_kind = typeKind ty
1017
1018         kind_ok = case ctxt of
1019                         TySynCtxt _  -> True -- Any kind will do
1020                         ResSigCtxt   -> isSubOpenTypeKind actual_kind
1021                         ExprSigCtxt  -> isSubOpenTypeKind actual_kind
1022                         GenPatCtxt   -> isLiftedTypeKind actual_kind
1023                         ForSigCtxt _ -> isLiftedTypeKind actual_kind
1024                         _            -> isSubArgTypeKind actual_kind
1025
1026         ubx_tup = case ctxt of
1027                       TySynCtxt _ | unboxed -> UT_Ok
1028                       ExprSigCtxt | unboxed -> UT_Ok
1029                       _                     -> UT_NotOk
1030
1031         -- Check that the thing has kind Type, and is lifted if necessary
1032     checkTc kind_ok (kindErr actual_kind)
1033
1034         -- Check the internal validity of the type itself
1035     check_type rank ubx_tup ty
1036
1037     traceTc (text "checkValidType done" <+> ppr ty)
1038
1039 checkValidMonoType :: Type -> TcM ()
1040 checkValidMonoType ty = check_mono_type MustBeMonoType ty
1041 \end{code}
1042
1043
1044 \begin{code}
1045 data Rank = ArbitraryRank         -- Any rank ok
1046           | MustBeMonoType        -- Monotype regardless of flags
1047           | TyConArgMonoType      -- Monotype but could be poly if -XImpredicativeTypes
1048           | Rank Int              -- Rank n, but could be more with -XRankNTypes
1049
1050 decRank :: Rank -> Rank           -- Function arguments
1051 decRank (Rank 0)   = Rank 0
1052 decRank (Rank n)   = Rank (n-1)
1053 decRank other_rank = other_rank
1054
1055 nonZeroRank :: Rank -> Bool
1056 nonZeroRank ArbitraryRank = True
1057 nonZeroRank (Rank n)      = n>0
1058 nonZeroRank _             = False
1059
1060 ----------------------------------------
1061 data UbxTupFlag = UT_Ok | UT_NotOk
1062         -- The "Ok" version means "ok if UnboxedTuples is on"
1063
1064 ----------------------------------------
1065 check_mono_type :: Rank -> Type -> TcM ()       -- No foralls anywhere
1066                                                 -- No unlifted types of any kind
1067 check_mono_type rank ty
1068    = do { check_type rank UT_NotOk ty
1069         ; checkTc (not (isUnLiftedType ty)) (unliftedArgErr ty) }
1070
1071 check_type :: Rank -> UbxTupFlag -> Type -> TcM ()
1072 -- The args say what the *type context* requires, independent
1073 -- of *flag* settings.  You test the flag settings at usage sites.
1074 --
1075 -- Rank is allowed rank for function args
1076 -- Rank 0 means no for-alls anywhere
1077
1078 check_type rank ubx_tup ty
1079   | not (null tvs && null theta)
1080   = do  { checkTc (nonZeroRank rank) (forAllTyErr rank ty)
1081                 -- Reject e.g. (Maybe (?x::Int => Int)),
1082                 -- with a decent error message
1083         ; check_valid_theta SigmaCtxt theta
1084         ; check_type rank ubx_tup tau   -- Allow foralls to right of arrow
1085         ; checkFreeness tvs theta
1086         ; checkAmbiguity tvs theta (tyVarsOfType tau) }
1087   where
1088     (tvs, theta, tau) = tcSplitSigmaTy ty
1089
1090 -- Naked PredTys don't usually show up, but they can as a result of
1091 --      {-# SPECIALISE instance Ord Char #-}
1092 -- The Right Thing would be to fix the way that SPECIALISE instance pragmas
1093 -- are handled, but the quick thing is just to permit PredTys here.
1094 check_type _ _ (PredTy sty)
1095   = do  { dflags <- getDOpts
1096         ; check_pred_ty dflags TypeCtxt sty }
1097
1098 check_type _ _ (TyVarTy _) = return ()
1099 check_type rank _ (FunTy arg_ty res_ty)
1100   = do  { check_type (decRank rank) UT_NotOk arg_ty
1101         ; check_type rank           UT_Ok    res_ty }
1102
1103 check_type rank _ (AppTy ty1 ty2)
1104   = do  { check_arg_type rank ty1
1105         ; check_arg_type rank ty2 }
1106
1107 check_type rank ubx_tup ty@(TyConApp tc tys)
1108   | isSynTyCon tc
1109   = do  {       -- Check that the synonym has enough args
1110                 -- This applies equally to open and closed synonyms
1111                 -- It's OK to have an *over-applied* type synonym
1112                 --      data Tree a b = ...
1113                 --      type Foo a = Tree [a]
1114                 --      f :: Foo a b -> ...
1115           checkTc (tyConArity tc <= length tys) arity_msg
1116
1117         -- See Note [Liberal type synonyms]
1118         ; liberal <- doptM Opt_LiberalTypeSynonyms
1119         ; if not liberal || isOpenSynTyCon tc then
1120                 -- For H98 and synonym families, do check the type args
1121                 mapM_ (check_mono_type TyConArgMonoType) tys
1122
1123           else  -- In the liberal case (only for closed syns), expand then check
1124           case tcView ty of
1125              Just ty' -> check_type rank ubx_tup ty'
1126              Nothing  -> pprPanic "check_tau_type" (ppr ty)
1127     }
1128
1129   | isUnboxedTupleTyCon tc
1130   = do  { ub_tuples_allowed <- doptM Opt_UnboxedTuples
1131         ; checkTc (ubx_tup_ok ub_tuples_allowed) ubx_tup_msg
1132
1133         ; impred <- doptM Opt_ImpredicativeTypes
1134         ; let rank' = if impred then ArbitraryRank else TyConArgMonoType
1135                 -- c.f. check_arg_type
1136                 -- However, args are allowed to be unlifted, or
1137                 -- more unboxed tuples, so can't use check_arg_ty
1138         ; mapM_ (check_type rank' UT_Ok) tys }
1139
1140   | otherwise
1141   = mapM_ (check_arg_type rank) tys
1142
1143   where
1144     ubx_tup_ok ub_tuples_allowed = case ubx_tup of
1145                                    UT_Ok -> ub_tuples_allowed
1146                                    _     -> False
1147
1148     n_args    = length tys
1149     tc_arity  = tyConArity tc
1150
1151     arity_msg   = arityErr "Type synonym" (tyConName tc) tc_arity n_args
1152     ubx_tup_msg = ubxArgTyErr ty
1153
1154 check_type _ _ ty = pprPanic "check_type" (ppr ty)
1155
1156 ----------------------------------------
1157 check_arg_type :: Rank -> Type -> TcM ()
1158 -- The sort of type that can instantiate a type variable,
1159 -- or be the argument of a type constructor.
1160 -- Not an unboxed tuple, but now *can* be a forall (since impredicativity)
1161 -- Other unboxed types are very occasionally allowed as type
1162 -- arguments depending on the kind of the type constructor
1163 --
1164 -- For example, we want to reject things like:
1165 --
1166 --      instance Ord a => Ord (forall s. T s a)
1167 -- and
1168 --      g :: T s (forall b.b)
1169 --
1170 -- NB: unboxed tuples can have polymorphic or unboxed args.
1171 --     This happens in the workers for functions returning
1172 --     product types with polymorphic components.
1173 --     But not in user code.
1174 -- Anyway, they are dealt with by a special case in check_tau_type
1175
1176 check_arg_type rank ty
1177   = do  { impred <- doptM Opt_ImpredicativeTypes
1178         ; let rank' = if impred then ArbitraryRank  -- Arg of tycon can have arby rank, regardless
1179                       else case rank of             -- Predictive => must be monotype
1180                         MustBeMonoType -> MustBeMonoType
1181                         _              -> TyConArgMonoType
1182                         -- Make sure that MustBeMonoType is propagated,
1183                         -- so that we don't suggest -XImpredicativeTypes in
1184                         --    (Ord (forall a.a)) => a -> a
1185
1186         ; check_type rank' UT_NotOk ty
1187         ; checkTc (not (isUnLiftedType ty)) (unliftedArgErr ty) }
1188
1189 ----------------------------------------
1190 forAllTyErr :: Rank -> Type -> SDoc
1191 forAllTyErr rank ty
1192    = vcat [ hang (ptext (sLit "Illegal polymorphic or qualified type:")) 2 (ppr ty)
1193           , suggestion ]
1194   where
1195     suggestion = case rank of
1196                    Rank _ -> ptext (sLit "Perhaps you intended to use -XRankNTypes or -XRank2Types")
1197                    TyConArgMonoType -> ptext (sLit "Perhaps you intended to use -XImpredicativeTypes")
1198                    _ -> empty      -- Polytype is always illegal
1199
1200 unliftedArgErr, ubxArgTyErr :: Type -> SDoc
1201 unliftedArgErr  ty = sep [ptext (sLit "Illegal unlifted type:"), ppr ty]
1202 ubxArgTyErr     ty = sep [ptext (sLit "Illegal unboxed tuple type as function argument:"), ppr ty]
1203
1204 kindErr :: Kind -> SDoc
1205 kindErr kind       = sep [ptext (sLit "Expecting an ordinary type, but found a type of kind"), ppr kind]
1206 \end{code}
1207
1208 Note [Liberal type synonyms]
1209 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1210 If -XLiberalTypeSynonyms is on, expand closed type synonyms *before*
1211 doing validity checking.  This allows us to instantiate a synonym defn
1212 with a for-all type, or with a partially-applied type synonym.
1213         e.g.   type T a b = a
1214                type S m   = m ()
1215                f :: S (T Int)
1216 Here, T is partially applied, so it's illegal in H98.  But if you
1217 expand S first, then T we get just
1218                f :: Int
1219 which is fine.
1220
1221 IMPORTANT: suppose T is a type synonym.  Then we must do validity
1222 checking on an appliation (T ty1 ty2)
1223
1224         *either* before expansion (i.e. check ty1, ty2)
1225         *or* after expansion (i.e. expand T ty1 ty2, and then check)
1226         BUT NOT BOTH
1227
1228 If we do both, we get exponential behaviour!!
1229
1230   data TIACons1 i r c = c i ::: r c
1231   type TIACons2 t x = TIACons1 t (TIACons1 t x)
1232   type TIACons3 t x = TIACons2 t (TIACons1 t x)
1233   type TIACons4 t x = TIACons2 t (TIACons2 t x)
1234   type TIACons7 t x = TIACons4 t (TIACons3 t x)
1235
1236
1237 %************************************************************************
1238 %*                                                                      *
1239 \subsection{Checking a theta or source type}
1240 %*                                                                      *
1241 %************************************************************************
1242
1243 \begin{code}
1244 -- Enumerate the contexts in which a "source type", <S>, can occur
1245 --      Eq a
1246 -- or   ?x::Int
1247 -- or   r <: {x::Int}
1248 -- or   (N a) where N is a newtype
1249
1250 data SourceTyCtxt
1251   = ClassSCCtxt Name    -- Superclasses of clas
1252                         --      class <S> => C a where ...
1253   | SigmaCtxt           -- Theta part of a normal for-all type
1254                         --      f :: <S> => a -> a
1255   | DataTyCtxt Name     -- Theta part of a data decl
1256                         --      data <S> => T a = MkT a
1257   | TypeCtxt            -- Source type in an ordinary type
1258                         --      f :: N a -> N a
1259   | InstThetaCtxt       -- Context of an instance decl
1260                         --      instance <S> => C [a] where ...
1261
1262 pprSourceTyCtxt :: SourceTyCtxt -> SDoc
1263 pprSourceTyCtxt (ClassSCCtxt c) = ptext (sLit "the super-classes of class") <+> quotes (ppr c)
1264 pprSourceTyCtxt SigmaCtxt       = ptext (sLit "the context of a polymorphic type")
1265 pprSourceTyCtxt (DataTyCtxt tc) = ptext (sLit "the context of the data type declaration for") <+> quotes (ppr tc)
1266 pprSourceTyCtxt InstThetaCtxt   = ptext (sLit "the context of an instance declaration")
1267 pprSourceTyCtxt TypeCtxt        = ptext (sLit "the context of a type")
1268 \end{code}
1269
1270 \begin{code}
1271 checkValidTheta :: SourceTyCtxt -> ThetaType -> TcM ()
1272 checkValidTheta ctxt theta
1273   = addErrCtxt (checkThetaCtxt ctxt theta) (check_valid_theta ctxt theta)
1274
1275 -------------------------
1276 check_valid_theta :: SourceTyCtxt -> [PredType] -> TcM ()
1277 check_valid_theta _ []
1278   = return ()
1279 check_valid_theta ctxt theta = do
1280     dflags <- getDOpts
1281     warnTc (notNull dups) (dupPredWarn dups)
1282     mapM_ (check_pred_ty dflags ctxt) theta
1283   where
1284     (_,dups) = removeDups tcCmpPred theta
1285
1286 -------------------------
1287 check_pred_ty :: DynFlags -> SourceTyCtxt -> PredType -> TcM ()
1288 check_pred_ty dflags ctxt pred@(ClassP cls tys)
1289   = do {        -- Class predicates are valid in all contexts
1290        ; checkTc (arity == n_tys) arity_err
1291
1292                 -- Check the form of the argument types
1293        ; mapM_ checkValidMonoType tys
1294        ; checkTc (check_class_pred_tys dflags ctxt tys)
1295                  (predTyVarErr pred $$ how_to_allow)
1296        }
1297   where
1298     class_name = className cls
1299     arity      = classArity cls
1300     n_tys      = length tys
1301     arity_err  = arityErr "Class" class_name arity n_tys
1302     how_to_allow = parens (ptext (sLit "Use -XFlexibleContexts to permit this"))
1303
1304 check_pred_ty dflags _ pred@(EqPred ty1 ty2)
1305   = do {        -- Equational constraints are valid in all contexts if type
1306                 -- families are permitted
1307        ; checkTc (dopt Opt_TypeFamilies dflags) (eqPredTyErr pred)
1308
1309                 -- Check the form of the argument types
1310        ; checkValidMonoType ty1
1311        ; checkValidMonoType ty2
1312        }
1313
1314 check_pred_ty _ SigmaCtxt (IParam _ ty) = checkValidMonoType ty
1315         -- Implicit parameters only allowed in type
1316         -- signatures; not in instance decls, superclasses etc
1317         -- The reason for not allowing implicit params in instances is a bit
1318         -- subtle.
1319         -- If we allowed        instance (?x::Int, Eq a) => Foo [a] where ...
1320         -- then when we saw (e :: (?x::Int) => t) it would be unclear how to
1321         -- discharge all the potential usas of the ?x in e.   For example, a
1322         -- constraint Foo [Int] might come out of e,and applying the
1323         -- instance decl would show up two uses of ?x.
1324
1325 -- Catch-all
1326 check_pred_ty _ _ sty = failWithTc (badPredTyErr sty)
1327
1328 -------------------------
1329 check_class_pred_tys :: DynFlags -> SourceTyCtxt -> [Type] -> Bool
1330 check_class_pred_tys dflags ctxt tys
1331   = case ctxt of
1332         TypeCtxt      -> True   -- {-# SPECIALISE instance Eq (T Int) #-} is fine
1333         InstThetaCtxt -> flexible_contexts || undecidable_ok || all tcIsTyVarTy tys
1334                                 -- Further checks on head and theta in
1335                                 -- checkInstTermination
1336         _             -> flexible_contexts || all tyvar_head tys
1337   where
1338     flexible_contexts = dopt Opt_FlexibleContexts dflags
1339     undecidable_ok = dopt Opt_UndecidableInstances dflags
1340
1341 -------------------------
1342 tyvar_head :: Type -> Bool
1343 tyvar_head ty                   -- Haskell 98 allows predicates of form
1344   | tcIsTyVarTy ty = True       --      C (a ty1 .. tyn)
1345   | otherwise                   -- where a is a type variable
1346   = case tcSplitAppTy_maybe ty of
1347         Just (ty, _) -> tyvar_head ty
1348         Nothing      -> False
1349 \end{code}
1350
1351 Check for ambiguity
1352 ~~~~~~~~~~~~~~~~~~~
1353           forall V. P => tau
1354 is ambiguous if P contains generic variables
1355 (i.e. one of the Vs) that are not mentioned in tau
1356
1357 However, we need to take account of functional dependencies
1358 when we speak of 'mentioned in tau'.  Example:
1359         class C a b | a -> b where ...
1360 Then the type
1361         forall x y. (C x y) => x
1362 is not ambiguous because x is mentioned and x determines y
1363
1364 NB; the ambiguity check is only used for *user* types, not for types
1365 coming from inteface files.  The latter can legitimately have
1366 ambiguous types. Example
1367
1368    class S a where s :: a -> (Int,Int)
1369    instance S Char where s _ = (1,1)
1370    f:: S a => [a] -> Int -> (Int,Int)
1371    f (_::[a]) x = (a*x,b)
1372         where (a,b) = s (undefined::a)
1373
1374 Here the worker for f gets the type
1375         fw :: forall a. S a => Int -> (# Int, Int #)
1376
1377 If the list of tv_names is empty, we have a monotype, and then we
1378 don't need to check for ambiguity either, because the test can't fail
1379 (see is_ambig).
1380
1381
1382 \begin{code}
1383 checkAmbiguity :: [TyVar] -> ThetaType -> TyVarSet -> TcM ()
1384 checkAmbiguity forall_tyvars theta tau_tyvars
1385   = mapM_ complain (filter is_ambig theta)
1386   where
1387     complain pred     = addErrTc (ambigErr pred)
1388     extended_tau_vars = grow theta tau_tyvars
1389
1390         -- See Note [Implicit parameters and ambiguity] in TcSimplify
1391     is_ambig pred     = isClassPred  pred &&
1392                         any ambig_var (varSetElems (tyVarsOfPred pred))
1393
1394     ambig_var ct_var  = (ct_var `elem` forall_tyvars) &&
1395                         not (ct_var `elemVarSet` extended_tau_vars)
1396
1397 ambigErr :: PredType -> SDoc
1398 ambigErr pred
1399   = sep [ptext (sLit "Ambiguous constraint") <+> quotes (pprPred pred),
1400          nest 4 (ptext (sLit "At least one of the forall'd type variables mentioned by the constraint") $$
1401                  ptext (sLit "must be reachable from the type after the '=>'"))]
1402 \end{code}
1403
1404 In addition, GHC insists that at least one type variable
1405 in each constraint is in V.  So we disallow a type like
1406         forall a. Eq b => b -> b
1407 even in a scope where b is in scope.
1408
1409 \begin{code}
1410 checkFreeness :: [Var] -> [PredType] -> TcM ()
1411 checkFreeness forall_tyvars theta
1412   = do  { flexible_contexts <- doptM Opt_FlexibleContexts
1413         ; unless flexible_contexts $ mapM_ complain (filter is_free theta) }
1414   where
1415     is_free pred     =  not (isIPPred pred)
1416                      && not (any bound_var (varSetElems (tyVarsOfPred pred)))
1417     bound_var ct_var = ct_var `elem` forall_tyvars
1418     complain pred    = addErrTc (freeErr pred)
1419
1420 freeErr :: PredType -> SDoc
1421 freeErr pred
1422   = sep [ ptext (sLit "All of the type variables in the constraint") <+>
1423           quotes (pprPred pred)
1424         , ptext (sLit "are already in scope") <+>
1425           ptext (sLit "(at least one must be universally quantified here)")
1426         , nest 4 $
1427             ptext (sLit "(Use -XFlexibleContexts to lift this restriction)")
1428         ]
1429 \end{code}
1430
1431 \begin{code}
1432 checkThetaCtxt :: SourceTyCtxt -> ThetaType -> SDoc
1433 checkThetaCtxt ctxt theta
1434   = vcat [ptext (sLit "In the context:") <+> pprTheta theta,
1435           ptext (sLit "While checking") <+> pprSourceTyCtxt ctxt ]
1436
1437 badPredTyErr, eqPredTyErr, predTyVarErr :: PredType -> SDoc
1438 badPredTyErr sty = ptext (sLit "Illegal constraint") <+> pprPred sty
1439 eqPredTyErr  sty = ptext (sLit "Illegal equational constraint") <+> pprPred sty
1440                    $$
1441                    parens (ptext (sLit "Use -XTypeFamilies to permit this"))
1442 predTyVarErr pred  = sep [ptext (sLit "Non type-variable argument"),
1443                           nest 2 (ptext (sLit "in the constraint:") <+> pprPred pred)]
1444 dupPredWarn :: [[PredType]] -> SDoc
1445 dupPredWarn dups   = ptext (sLit "Duplicate constraint(s):") <+> pprWithCommas pprPred (map head dups)
1446
1447 arityErr :: Outputable a => String -> a -> Int -> Int -> SDoc
1448 arityErr kind name n m
1449   = hsep [ text kind, quotes (ppr name), ptext (sLit "should have"),
1450            n_arguments <> comma, text "but has been given", int m]
1451     where
1452         n_arguments | n == 0 = ptext (sLit "no arguments")
1453                     | n == 1 = ptext (sLit "1 argument")
1454                     | True   = hsep [int n, ptext (sLit "arguments")]
1455
1456 -----------------
1457 notMonoType :: TcType -> TcM a
1458 notMonoType ty
1459   = do  { ty' <- zonkTcType ty
1460         ; env0 <- tcInitTidyEnv
1461         ; let (env1, tidy_ty) = tidyOpenType env0 ty'
1462               msg = ptext (sLit "Cannot match a monotype with") <+> quotes (ppr tidy_ty)
1463         ; failWithTcM (env1, msg) }
1464
1465 notMonoArgs :: TcType -> TcM a
1466 notMonoArgs ty
1467   = do  { ty' <- zonkTcType ty
1468         ; env0 <- tcInitTidyEnv
1469         ; let (env1, tidy_ty) = tidyOpenType env0 ty'
1470               msg = ptext (sLit "Arguments of type synonym families must be monotypes") <+> quotes (ppr tidy_ty)
1471         ; failWithTcM (env1, msg) }
1472 \end{code}
1473
1474
1475 %************************************************************************
1476 %*                                                                      *
1477 \subsection{Checking for a decent instance head type}
1478 %*                                                                      *
1479 %************************************************************************
1480
1481 @checkValidInstHead@ checks the type {\em and} its syntactic constraints:
1482 it must normally look like: @instance Foo (Tycon a b c ...) ...@
1483
1484 The exceptions to this syntactic checking: (1)~if the @GlasgowExts@
1485 flag is on, or (2)~the instance is imported (they must have been
1486 compiled elsewhere). In these cases, we let them go through anyway.
1487
1488 We can also have instances for functions: @instance Foo (a -> b) ...@.
1489
1490 \begin{code}
1491 checkValidInstHead :: Type -> TcM (Class, [TcType])
1492
1493 checkValidInstHead ty   -- Should be a source type
1494   = case tcSplitPredTy_maybe ty of {
1495         Nothing -> failWithTc (instTypeErr (ppr ty) empty) ;
1496         Just pred ->
1497
1498     case getClassPredTys_maybe pred of {
1499         Nothing -> failWithTc (instTypeErr (pprPred pred) empty) ;
1500         Just (clas,tys) -> do
1501
1502     dflags <- getDOpts
1503     check_inst_head dflags clas tys
1504     return (clas, tys)
1505     }}
1506
1507 check_inst_head :: DynFlags -> Class -> [Type] -> TcM ()
1508 check_inst_head dflags clas tys
1509   = do { -- If GlasgowExts then check at least one isn't a type variable
1510        ; checkTc (dopt Opt_TypeSynonymInstances dflags ||
1511                   all tcInstHeadTyNotSynonym tys)
1512                  (instTypeErr (pprClassPred clas tys) head_type_synonym_msg)
1513        ; checkTc (dopt Opt_FlexibleInstances dflags ||
1514                   all tcInstHeadTyAppAllTyVars tys)
1515                  (instTypeErr (pprClassPred clas tys) head_type_args_tyvars_msg)
1516        ; checkTc (dopt Opt_MultiParamTypeClasses dflags ||
1517                   isSingleton tys)
1518                  (instTypeErr (pprClassPred clas tys) head_one_type_msg)
1519          -- May not contain type family applications
1520        ; mapM_ checkTyFamFreeness tys
1521
1522        ; mapM_ checkValidMonoType tys
1523         -- For now, I only allow tau-types (not polytypes) in
1524         -- the head of an instance decl.
1525         --      E.g.  instance C (forall a. a->a) is rejected
1526         -- One could imagine generalising that, but I'm not sure
1527         -- what all the consequences might be
1528        }
1529
1530   where
1531     head_type_synonym_msg = parens (
1532                 text "All instance types must be of the form (T t1 ... tn)" $$
1533                 text "where T is not a synonym." $$
1534                 text "Use -XTypeSynonymInstances if you want to disable this.")
1535
1536     head_type_args_tyvars_msg = parens (vcat [
1537                 text "All instance types must be of the form (T a1 ... an)",
1538                 text "where a1 ... an are type *variables*,",
1539                 text "and each type variable appears at most once in the instance head.",
1540                 text "Use -XFlexibleInstances if you want to disable this."])
1541
1542     head_one_type_msg = parens (
1543                 text "Only one type can be given in an instance head." $$
1544                 text "Use -XMultiParamTypeClasses if you want to allow more.")
1545
1546 instTypeErr :: SDoc -> SDoc -> SDoc
1547 instTypeErr pp_ty msg
1548   = sep [ptext (sLit "Illegal instance declaration for") <+> quotes pp_ty,
1549          nest 4 msg]
1550 \end{code}
1551
1552
1553 %************************************************************************
1554 %*                                                                      *
1555 \subsection{Checking instance for termination}
1556 %*                                                                      *
1557 %************************************************************************
1558
1559
1560 \begin{code}
1561 checkValidInstance :: [TyVar] -> ThetaType -> Class -> [TcType] -> TcM ()
1562 checkValidInstance tyvars theta clas inst_tys
1563   = do  { undecidable_ok <- doptM Opt_UndecidableInstances
1564
1565         ; checkValidTheta InstThetaCtxt theta
1566         ; checkAmbiguity tyvars theta (tyVarsOfTypes inst_tys)
1567
1568         -- Check that instance inference will terminate (if we care)
1569         -- For Haskell 98 this will already have been done by checkValidTheta,
1570         -- but as we may be using other extensions we need to check.
1571         ; unless undecidable_ok $
1572           mapM_ addErrTc (checkInstTermination inst_tys theta)
1573
1574         -- The Coverage Condition
1575         ; checkTc (undecidable_ok || checkInstCoverage clas inst_tys)
1576                   (instTypeErr (pprClassPred clas inst_tys) msg)
1577         }
1578   where
1579     msg  = parens (vcat [ptext (sLit "the Coverage Condition fails for one of the functional dependencies;"),
1580                          undecidableMsg])
1581 \end{code}
1582
1583 Termination test: the so-called "Paterson conditions" (see Section 5 of
1584 "Understanding functionsl dependencies via Constraint Handling Rules,
1585 JFP Jan 2007).
1586
1587 We check that each assertion in the context satisfies:
1588  (1) no variable has more occurrences in the assertion than in the head, and
1589  (2) the assertion has fewer constructors and variables (taken together
1590      and counting repetitions) than the head.
1591 This is only needed with -fglasgow-exts, as Haskell 98 restrictions
1592 (which have already been checked) guarantee termination.
1593
1594 The underlying idea is that
1595
1596     for any ground substitution, each assertion in the
1597     context has fewer type constructors than the head.
1598
1599
1600 \begin{code}
1601 checkInstTermination :: [TcType] -> ThetaType -> [Message]
1602 checkInstTermination tys theta
1603   = mapCatMaybes check theta
1604   where
1605    fvs  = fvTypes tys
1606    size = sizeTypes tys
1607    check pred
1608       | not (null (fvPred pred \\ fvs))
1609       = Just (predUndecErr pred nomoreMsg $$ parens undecidableMsg)
1610       | sizePred pred >= size
1611       = Just (predUndecErr pred smallerMsg $$ parens undecidableMsg)
1612       | otherwise
1613       = Nothing
1614
1615 predUndecErr :: PredType -> SDoc -> SDoc
1616 predUndecErr pred msg = sep [msg,
1617                         nest 2 (ptext (sLit "in the constraint:") <+> pprPred pred)]
1618
1619 nomoreMsg, smallerMsg, undecidableMsg :: SDoc
1620 nomoreMsg = ptext (sLit "Variable occurs more often in a constraint than in the instance head")
1621 smallerMsg = ptext (sLit "Constraint is no smaller than the instance head")
1622 undecidableMsg = ptext (sLit "Use -XUndecidableInstances to permit this")
1623 \end{code}
1624
1625
1626 %************************************************************************
1627 %*                                                                      *
1628         Checking the context of a derived instance declaration
1629 %*                                                                      *
1630 %************************************************************************
1631
1632 Note [Exotic derived instance contexts]
1633 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1634 In a 'derived' instance declaration, we *infer* the context.  It's a
1635 bit unclear what rules we should apply for this; the Haskell report is
1636 silent.  Obviously, constraints like (Eq a) are fine, but what about
1637         data T f a = MkT (f a) deriving( Eq )
1638 where we'd get an Eq (f a) constraint.  That's probably fine too.
1639
1640 One could go further: consider
1641         data T a b c = MkT (Foo a b c) deriving( Eq )
1642         instance (C Int a, Eq b, Eq c) => Eq (Foo a b c)
1643
1644 Notice that this instance (just) satisfies the Paterson termination
1645 conditions.  Then we *could* derive an instance decl like this:
1646
1647         instance (C Int a, Eq b, Eq c) => Eq (T a b c)
1648
1649 even though there is no instance for (C Int a), because there just
1650 *might* be an instance for, say, (C Int Bool) at a site where we
1651 need the equality instance for T's.
1652
1653 However, this seems pretty exotic, and it's quite tricky to allow
1654 this, and yet give sensible error messages in the (much more common)
1655 case where we really want that instance decl for C.
1656
1657 So for now we simply require that the derived instance context
1658 should have only type-variable constraints.
1659
1660 Here is another example:
1661         data Fix f = In (f (Fix f)) deriving( Eq )
1662 Here, if we are prepared to allow -XUndecidableInstances we
1663 could derive the instance
1664         instance Eq (f (Fix f)) => Eq (Fix f)
1665 but this is so delicate that I don't think it should happen inside
1666 'deriving'. If you want this, write it yourself!
1667
1668 NB: if you want to lift this condition, make sure you still meet the
1669 termination conditions!  If not, the deriving mechanism generates
1670 larger and larger constraints.  Example:
1671   data Succ a = S a
1672   data Seq a = Cons a (Seq (Succ a)) | Nil deriving Show
1673
1674 Note the lack of a Show instance for Succ.  First we'll generate
1675   instance (Show (Succ a), Show a) => Show (Seq a)
1676 and then
1677   instance (Show (Succ (Succ a)), Show (Succ a), Show a) => Show (Seq a)
1678 and so on.  Instead we want to complain of no instance for (Show (Succ a)).
1679
1680 The bottom line
1681 ~~~~~~~~~~~~~~~
1682 Allow constraints which consist only of type variables, with no repeats.
1683
1684 \begin{code}
1685 validDerivPred :: PredType -> Bool
1686 validDerivPred (ClassP _ tys) = hasNoDups fvs && sizeTypes tys == length fvs
1687                               where fvs = fvTypes tys
1688 validDerivPred _              = False
1689 \end{code}
1690
1691 %************************************************************************
1692 %*                                                                      *
1693         Checking type instance well-formedness and termination
1694 %*                                                                      *
1695 %************************************************************************
1696
1697 \begin{code}
1698 -- Check that a "type instance" is well-formed (which includes decidability
1699 -- unless -XUndecidableInstances is given).
1700 --
1701 checkValidTypeInst :: [Type] -> Type -> TcM ()
1702 checkValidTypeInst typats rhs
1703   = do { -- left-hand side contains no type family applications
1704          -- (vanilla synonyms are fine, though)
1705        ; mapM_ checkTyFamFreeness typats
1706
1707          -- the right-hand side is a tau type
1708        ; checkValidMonoType rhs
1709
1710          -- we have a decidable instance unless otherwise permitted
1711        ; undecidable_ok <- doptM Opt_UndecidableInstances
1712        ; unless undecidable_ok $
1713            mapM_ addErrTc (checkFamInst typats (tyFamInsts rhs))
1714        }
1715
1716 -- Make sure that each type family instance is
1717 --   (1) strictly smaller than the lhs,
1718 --   (2) mentions no type variable more often than the lhs, and
1719 --   (3) does not contain any further type family instances.
1720 --
1721 checkFamInst :: [Type]                  -- lhs
1722              -> [(TyCon, [Type])]       -- type family instances
1723              -> [Message]
1724 checkFamInst lhsTys famInsts
1725   = mapCatMaybes check famInsts
1726   where
1727    size = sizeTypes lhsTys
1728    fvs  = fvTypes lhsTys
1729    check (tc, tys)
1730       | not (all isTyFamFree tys)
1731       = Just (famInstUndecErr famInst nestedMsg $$ parens undecidableMsg)
1732       | not (null (fvTypes tys \\ fvs))
1733       = Just (famInstUndecErr famInst nomoreVarMsg $$ parens undecidableMsg)
1734       | size <= sizeTypes tys
1735       = Just (famInstUndecErr famInst smallerAppMsg $$ parens undecidableMsg)
1736       | otherwise
1737       = Nothing
1738       where
1739         famInst = TyConApp tc tys
1740
1741 -- Ensure that no type family instances occur in a type.
1742 --
1743 checkTyFamFreeness :: Type -> TcM ()
1744 checkTyFamFreeness ty
1745   = checkTc (isTyFamFree ty) $
1746       tyFamInstIllegalErr ty
1747
1748 -- Check that a type does not contain any type family applications.
1749 --
1750 isTyFamFree :: Type -> Bool
1751 isTyFamFree = null . tyFamInsts
1752
1753 -- Error messages
1754
1755 tyFamInstIllegalErr :: Type -> SDoc
1756 tyFamInstIllegalErr ty
1757   = hang (ptext (sLit "Illegal type synonym family application in instance") <>
1758          colon) 4 $
1759       ppr ty
1760
1761 famInstUndecErr :: Type -> SDoc -> SDoc
1762 famInstUndecErr ty msg
1763   = sep [msg,
1764          nest 2 (ptext (sLit "in the type family application:") <+>
1765                  pprType ty)]
1766
1767 nestedMsg, nomoreVarMsg, smallerAppMsg :: SDoc
1768 nestedMsg     = ptext (sLit "Nested type family application")
1769 nomoreVarMsg  = ptext (sLit "Variable occurs more often than in instance head")
1770 smallerAppMsg = ptext (sLit "Application is no smaller than the instance head")
1771 \end{code}
1772
1773
1774 %************************************************************************
1775 %*                                                                      *
1776 \subsection{Auxiliary functions}
1777 %*                                                                      *
1778 %************************************************************************
1779
1780 \begin{code}
1781 -- Free variables of a type, retaining repetitions, and expanding synonyms
1782 fvType :: Type -> [TyVar]
1783 fvType ty | Just exp_ty <- tcView ty = fvType exp_ty
1784 fvType (TyVarTy tv)        = [tv]
1785 fvType (TyConApp _ tys)    = fvTypes tys
1786 fvType (PredTy pred)       = fvPred pred
1787 fvType (FunTy arg res)     = fvType arg ++ fvType res
1788 fvType (AppTy fun arg)     = fvType fun ++ fvType arg
1789 fvType (ForAllTy tyvar ty) = filter (/= tyvar) (fvType ty)
1790
1791 fvTypes :: [Type] -> [TyVar]
1792 fvTypes tys                = concat (map fvType tys)
1793
1794 fvPred :: PredType -> [TyVar]
1795 fvPred (ClassP _ tys')     = fvTypes tys'
1796 fvPred (IParam _ ty)       = fvType ty
1797 fvPred (EqPred ty1 ty2)    = fvType ty1 ++ fvType ty2
1798
1799 -- Size of a type: the number of variables and constructors
1800 sizeType :: Type -> Int
1801 sizeType ty | Just exp_ty <- tcView ty = sizeType exp_ty
1802 sizeType (TyVarTy _)       = 1
1803 sizeType (TyConApp _ tys)  = sizeTypes tys + 1
1804 sizeType (PredTy pred)     = sizePred pred
1805 sizeType (FunTy arg res)   = sizeType arg + sizeType res + 1
1806 sizeType (AppTy fun arg)   = sizeType fun + sizeType arg
1807 sizeType (ForAllTy _ ty)   = sizeType ty
1808
1809 sizeTypes :: [Type] -> Int
1810 sizeTypes xs               = sum (map sizeType xs)
1811
1812 sizePred :: PredType -> Int
1813 sizePred (ClassP _ tys')   = sizeTypes tys'
1814 sizePred (IParam _ ty)     = sizeType ty
1815 sizePred (EqPred ty1 ty2)  = sizeType ty1 + sizeType ty2
1816 \end{code}