compiler/typecheck/TcMType.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Monadic type operations
   7
   8 This module contains monadic operations over types that contain
   9 mutable type variables
  10
  11 \begin{code}
  12 module TcMType (
  13   TcTyVar, TcKind, TcType, TcTauType, TcThetaType, TcTyVarSet,
  14
  15   --------------------------------
  16   -- Creating new mutable type variables
  17   newFlexiTyVar,
  18   newFlexiTyVarTy,              -- Kind -> TcM TcType
  19   newFlexiTyVarTys,             -- Int -> Kind -> TcM [TcType]
  20   newKindVar, newKindVars,
  21   lookupTcTyVar, LookupTyVarResult(..),
  22   newMetaTyVar, readMetaTyVar, writeMetaTyVar,
  23
  24   --------------------------------
  25   -- Boxy type variables
  26   newBoxyTyVar, newBoxyTyVars, newBoxyTyVarTys, readFilledBox,
  27
  28   --------------------------------
  29   -- Creating new coercion variables
  30   newCoVars,
  31
  32   --------------------------------
  33   -- Instantiation
  34   tcInstTyVar, tcInstType, tcInstTyVars, tcInstBoxyTyVar,
  35   tcInstSigTyVars, zonkSigTyVar,
  36   tcInstSkolTyVar, tcInstSkolTyVars, tcInstSkolType,
  37   tcSkolSigType, tcSkolSigTyVars,
  38
  39   --------------------------------
  40   -- Checking type validity
  41   Rank, UserTypeCtxt(..), checkValidType,
  42   SourceTyCtxt(..), checkValidTheta, checkFreeness,
  43   checkValidInstHead, checkValidInstance, checkAmbiguity,
  44   checkInstTermination,
  45   arityErr,
  46
  47   --------------------------------
  48   -- Zonking
  49   zonkType, zonkTcPredType,
  50   zonkTcTyVar, zonkTcTyVars, zonkTcTyVarsAndFV,
  51   zonkQuantifiedTyVar, zonkQuantifiedTyVars,
  52   zonkTcType, zonkTcTypes, zonkTcClassConstraints, zonkTcThetaType,
  53   zonkTcKindToKind, zonkTcKind, zonkTopTyVar,
  54
  55   readKindVar, writeKindVar
  56
  57   ) where
  58
  59 #include "HsVersions.h"
  60
  61 -- friends:
  62 import TypeRep
  63 import TcType
  64 import Type
  65 import Coercion
  66 import Class
  67 import TyCon
  68 import Var
  69
  70 -- others:
  71 import TcRnMonad          -- TcType, amongst others
  72 import FunDeps
  73 import Name
  74 import VarSet
  75 import ErrUtils
  76 import DynFlags
  77 import Util
  78 import Maybes
  79 import ListSetOps
  80 import UniqSupply
  81 import SrcLoc
  82 import Outputable
  83
  84 import Control.Monad    ( when, unless )
  85 import Data.List        ( (\\) )
  86 \end{code}
  87
  88
  89 %************************************************************************
  90 %*                                                                      *
  91         Instantiation in general
  92 %*                                                                      *
  93 %************************************************************************
  94
  95 \begin{code}
  96 tcInstType :: ([TyVar] -> TcM [TcTyVar])                -- How to instantiate the type variables
  97            -> TcType                                    -- Type to instantiate
  98            -> TcM ([TcTyVar], TcThetaType, TcType)      -- Result
  99 tcInstType inst_tyvars ty
 100   = case tcSplitForAllTys ty of
 101         ([],     rho) -> let    -- There may be overloading despite no type variables;
 102                                 --      (?x :: Int) => Int -> Int
 103                            (theta, tau) = tcSplitPhiTy rho
 104                          in
 105                          return ([], theta, tau)
 106
 107         (tyvars, rho) -> do { tyvars' <- inst_tyvars tyvars
 108
 109                             ; let  tenv = zipTopTvSubst tyvars (mkTyVarTys tyvars')
 110                                 -- Either the tyvars are freshly made, by inst_tyvars,
 111                                 -- or (in the call from tcSkolSigType) any nested foralls
 112                                 -- have different binders.  Either way, zipTopTvSubst is ok
 113
 114                             ; let  (theta, tau) = tcSplitPhiTy (substTy tenv rho)
 115                             ; return (tyvars', theta, tau) }
 116 \end{code}
 117
 118
 119 %************************************************************************
 120 %*                                                                      *
 121         Kind variables
 122 %*                                                                      *
 123 %************************************************************************
 124
 125 \begin{code}
 126 newCoVars :: [(TcType,TcType)] -> TcM [CoVar]
 127 newCoVars spec
 128   = do  { us <- newUniqueSupply
 129         ; return [ mkCoVar (mkSysTvName uniq FSLIT("co"))
 130                            (mkCoKind ty1 ty2)
 131                  | ((ty1,ty2), uniq) <- spec `zip` uniqsFromSupply us] }
 132
 133 newKindVar :: TcM TcKind
 134 newKindVar = do { uniq <- newUnique
 135                 ; ref <- newMutVar Flexi
 136                 ; return (mkTyVarTy (mkKindVar uniq ref)) }
 137
 138 newKindVars :: Int -> TcM [TcKind]
 139 newKindVars n = mappM (\ _ -> newKindVar) (nOfThem n ())
 140 \end{code}
 141
 142
 143 %************************************************************************
 144 %*                                                                      *
 145         SkolemTvs (immutable)
 146 %*                                                                      *
 147 %************************************************************************
 148
 149 \begin{code}
 150 mkSkolTyVar :: Name -> Kind -> SkolemInfo -> TcTyVar
 151 mkSkolTyVar name kind info = mkTcTyVar name kind (SkolemTv info)
 152
 153 tcSkolSigType :: SkolemInfo -> Type -> TcM ([TcTyVar], TcThetaType, TcType)
 154 -- Instantiate a type signature with skolem constants, but
 155 -- do *not* give them fresh names, because we want the name to
 156 -- be in the type environment -- it is lexically scoped.
 157 tcSkolSigType info ty = tcInstType (\tvs -> return (tcSkolSigTyVars info tvs)) ty
 158
 159 tcSkolSigTyVars :: SkolemInfo -> [TyVar] -> [TcTyVar]
 160 -- Make skolem constants, but do *not* give them new names, as above
 161 tcSkolSigTyVars info tyvars = [ mkSkolTyVar (tyVarName tv) (tyVarKind tv) info
 162                               | tv <- tyvars ]
 163
 164 tcInstSkolTyVar :: SkolemInfo -> Maybe SrcLoc -> TyVar -> TcM TcTyVar
 165 -- Instantiate the tyvar, using
 166 --      * the occ-name and kind of the supplied tyvar,
 167 --      * the unique from the monad,
 168 --      * the location either from the tyvar (mb_loc = Nothing)
 169 --        or from mb_loc (Just loc)
 170 tcInstSkolTyVar info mb_loc tyvar
 171   = do  { uniq <- newUnique
 172         ; let old_name = tyVarName tyvar
 173               kind     = tyVarKind tyvar
 174               loc      = mb_loc `orElse` getSrcLoc old_name
 175               new_name = mkInternalName uniq (nameOccName old_name) loc
 176         ; return (mkSkolTyVar new_name kind info) }
 177
 178 tcInstSkolTyVars :: SkolemInfo -> [TyVar] -> TcM [TcTyVar]
 179 -- Get the location from the monad
 180 tcInstSkolTyVars info tyvars
 181   = do  { span <- getSrcSpanM
 182         ; mapM (tcInstSkolTyVar info (Just (srcSpanStart span))) tyvars }
 183
 184 tcInstSkolType :: SkolemInfo -> TcType -> TcM ([TcTyVar], TcThetaType, TcType)
 185 -- Instantiate a type with fresh skolem constants
 186 -- Binding location comes from the monad
 187 tcInstSkolType info ty = tcInstType (tcInstSkolTyVars info) ty
 188 \end{code}
 189
 190
 191 %************************************************************************
 192 %*                                                                      *
 193         MetaTvs (meta type variables; mutable)
 194 %*                                                                      *
 195 %************************************************************************
 196
 197 \begin{code}
 198 newMetaTyVar :: BoxInfo -> Kind -> TcM TcTyVar
 199 -- Make a new meta tyvar out of thin air
 200 newMetaTyVar box_info kind
 201   = do  { uniq <- newUnique
 202         ; ref <- newMutVar Flexi ;
 203         ; let name = mkSysTvName uniq fs
 204               fs = case box_info of
 205                         BoxTv   -> FSLIT("t")
 206                         TauTv   -> FSLIT("t")
 207                         SigTv _ -> FSLIT("a")
 208                 -- We give BoxTv and TauTv the same string, because
 209                 -- otherwise we get user-visible differences in error
 210                 -- messages, which are confusing.  If you want to see
 211                 -- the box_info of each tyvar, use -dppr-debug
 212         ; return (mkTcTyVar name kind (MetaTv box_info ref)) }
 213
 214 instMetaTyVar :: BoxInfo -> TyVar -> TcM TcTyVar
 215 -- Make a new meta tyvar whose Name and Kind
 216 -- come from an existing TyVar
 217 instMetaTyVar box_info tyvar
 218   = do  { uniq <- newUnique
 219         ; ref <- newMutVar Flexi ;
 220         ; let name = setNameUnique (tyVarName tyvar) uniq
 221               kind = tyVarKind tyvar
 222         ; return (mkTcTyVar name kind (MetaTv box_info ref)) }
 223
 224 readMetaTyVar :: TyVar -> TcM MetaDetails
 225 readMetaTyVar tyvar = ASSERT2( isMetaTyVar tyvar, ppr tyvar )
 226                       readMutVar (metaTvRef tyvar)
 227
 228 writeMetaTyVar :: TcTyVar -> TcType -> TcM ()
 229 #ifndef DEBUG
 230 writeMetaTyVar tyvar ty = writeMutVar (metaTvRef tyvar) (Indirect ty)
 231 #else
 232 writeMetaTyVar tyvar ty
 233   | not (isMetaTyVar tyvar)
 234   = pprTrace "writeMetaTyVar" (ppr tyvar) $
 235     returnM ()
 236
 237   | otherwise
 238   = ASSERT( isMetaTyVar tyvar )
 239     ASSERT2( k2 `isSubKind` k1, (ppr tyvar <+> ppr k1) $$ (ppr ty <+> ppr k2) )
 240     do  { ASSERTM2( do { details <- readMetaTyVar tyvar; return (isFlexi details) }, ppr tyvar )
 241         ; writeMutVar (metaTvRef tyvar) (Indirect ty) }
 242   where
 243     k1 = tyVarKind tyvar
 244     k2 = typeKind ty
 245 #endif
 246 \end{code}
 247
 248
 249 %************************************************************************
 250 %*                                                                      *
 251         MetaTvs: TauTvs
 252 %*                                                                      *
 253 %************************************************************************
 254
 255 \begin{code}
 256 newFlexiTyVar :: Kind -> TcM TcTyVar
 257 newFlexiTyVar kind = newMetaTyVar TauTv kind
 258
 259 newFlexiTyVarTy  :: Kind -> TcM TcType
 260 newFlexiTyVarTy kind
 261   = newFlexiTyVar kind  `thenM` \ tc_tyvar ->
 262     returnM (TyVarTy tc_tyvar)
 263
 264 newFlexiTyVarTys :: Int -> Kind -> TcM [TcType]
 265 newFlexiTyVarTys n kind = mappM newFlexiTyVarTy (nOfThem n kind)
 266
 267 tcInstTyVar :: TyVar -> TcM TcTyVar
 268 -- Instantiate with a META type variable
 269 tcInstTyVar tyvar = instMetaTyVar TauTv tyvar
 270
 271 tcInstTyVars :: [TyVar] -> TcM ([TcTyVar], [TcType], TvSubst)
 272 -- Instantiate with META type variables
 273 tcInstTyVars tyvars
 274   = do  { tc_tvs <- mapM tcInstTyVar tyvars
 275         ; let tys = mkTyVarTys tc_tvs
 276         ; returnM (tc_tvs, tys, zipTopTvSubst tyvars tys) }
 277                 -- Since the tyvars are freshly made,
 278                 -- they cannot possibly be captured by
 279                 -- any existing for-alls.  Hence zipTopTvSubst
 280 \end{code}
 281
 282
 283 %************************************************************************
 284 %*                                                                      *
 285         MetaTvs: SigTvs
 286 %*                                                                      *
 287 %************************************************************************
 288
 289 \begin{code}
 290 tcInstSigTyVars :: Bool -> SkolemInfo -> [TyVar] -> TcM [TcTyVar]
 291 -- Instantiate with skolems or meta SigTvs; depending on use_skols
 292 -- Always take location info from the supplied tyvars
 293 tcInstSigTyVars use_skols skol_info tyvars
 294   | use_skols
 295   = mapM (tcInstSkolTyVar skol_info Nothing) tyvars
 296
 297   | otherwise
 298   = mapM (instMetaTyVar (SigTv skol_info)) tyvars
 299
 300 zonkSigTyVar :: TcTyVar -> TcM TcTyVar
 301 zonkSigTyVar sig_tv
 302   | isSkolemTyVar sig_tv
 303   = return sig_tv       -- Happens in the call in TcBinds.checkDistinctTyVars
 304   | otherwise
 305   = ASSERT( isSigTyVar sig_tv )
 306     do { ty <- zonkTcTyVar sig_tv
 307        ; return (tcGetTyVar "zonkSigTyVar" ty) }
 308         -- 'ty' is bound to be a type variable, because SigTvs
 309         -- can only be unified with type variables
 310 \end{code}
 311
 312
 313 %************************************************************************
 314 %*                                                                      *
 315         MetaTvs: BoxTvs
 316 %*                                                                      *
 317 %************************************************************************
 318
 319 \begin{code}
 320 newBoxyTyVar :: Kind -> TcM BoxyTyVar
 321 newBoxyTyVar kind = newMetaTyVar BoxTv kind
 322
 323 newBoxyTyVars :: [Kind] -> TcM [BoxyTyVar]
 324 newBoxyTyVars kinds = mapM newBoxyTyVar kinds
 325
 326 newBoxyTyVarTys :: [Kind] -> TcM [BoxyType]
 327 newBoxyTyVarTys kinds = do { tvs <- mapM newBoxyTyVar kinds; return (mkTyVarTys tvs) }
 328
 329 readFilledBox :: BoxyTyVar -> TcM TcType
 330 -- Read the contents of the box, which should be filled in by now
 331 readFilledBox box_tv = ASSERT( isBoxyTyVar box_tv )
 332                        do { cts <- readMetaTyVar box_tv
 333                           ; case cts of
 334                                 Flexi       -> pprPanic "readFilledBox" (ppr box_tv)
 335                                 Indirect ty -> return ty }
 336
 337 tcInstBoxyTyVar :: TyVar -> TcM BoxyTyVar
 338 -- Instantiate with a BOXY type variable
 339 tcInstBoxyTyVar tyvar = instMetaTyVar BoxTv tyvar
 340 \end{code}
 341
 342
 343 %************************************************************************
 344 %*                                                                      *
 345 \subsection{Putting and getting  mutable type variables}
 346 %*                                                                      *
 347 %************************************************************************
 348
 349 But it's more fun to short out indirections on the way: If this
 350 version returns a TyVar, then that TyVar is unbound.  If it returns
 351 any other type, then there might be bound TyVars embedded inside it.
 352
 353 We return Nothing iff the original box was unbound.
 354
 355 \begin{code}
 356 data LookupTyVarResult  -- The result of a lookupTcTyVar call
 357   = DoneTv TcTyVarDetails       -- SkolemTv or virgin MetaTv
 358   | IndirectTv TcType
 359
 360 lookupTcTyVar :: TcTyVar -> TcM LookupTyVarResult
 361 lookupTcTyVar tyvar
 362   = ASSERT2( isTcTyVar tyvar, ppr tyvar )
 363     case details of
 364       SkolemTv _   -> return (DoneTv details)
 365       MetaTv _ ref -> do { meta_details <- readMutVar ref
 366                          ; case meta_details of
 367                             Indirect ty -> return (IndirectTv ty)
 368                             Flexi       -> return (DoneTv details) }
 369   where
 370     details =  tcTyVarDetails tyvar
 371
 372 {-
 373 -- gaw 2004 We aren't shorting anything out anymore, at least for now
 374 getTcTyVar tyvar
 375   | not (isTcTyVar tyvar)
 376   = pprTrace "getTcTyVar" (ppr tyvar) $
 377     returnM (Just (mkTyVarTy tyvar))
 378
 379   | otherwise
 380   = ASSERT2( isTcTyVar tyvar, ppr tyvar )
 381     readMetaTyVar tyvar                         `thenM` \ maybe_ty ->
 382     case maybe_ty of
 383         Just ty -> short_out ty                         `thenM` \ ty' ->
 384                    writeMetaTyVar tyvar (Just ty')      `thenM_`
 385                    returnM (Just ty')
 386
 387         Nothing    -> returnM Nothing
 388
 389 short_out :: TcType -> TcM TcType
 390 short_out ty@(TyVarTy tyvar)
 391   | not (isTcTyVar tyvar)
 392   = returnM ty
 393
 394   | otherwise
 395   = readMetaTyVar tyvar `thenM` \ maybe_ty ->
 396     case maybe_ty of
 397         Just ty' -> short_out ty'                       `thenM` \ ty' ->
 398                     writeMetaTyVar tyvar (Just ty')     `thenM_`
 399                     returnM ty'
 400
 401         other    -> returnM ty
 402
 403 short_out other_ty = returnM other_ty
 404 -}
 405 \end{code}
 406
 407
 408 %************************************************************************
 409 %*                                                                      *
 410 \subsection{Zonking -- the exernal interfaces}
 411 %*                                                                      *
 412 %************************************************************************
 413
 414 -----------------  Type variables
 415
 416 \begin{code}
 417 zonkTcTyVars :: [TcTyVar] -> TcM [TcType]
 418 zonkTcTyVars tyvars = mappM zonkTcTyVar tyvars
 419
 420 zonkTcTyVarsAndFV :: [TcTyVar] -> TcM TcTyVarSet
 421 zonkTcTyVarsAndFV tyvars = mappM zonkTcTyVar tyvars     `thenM` \ tys ->
 422                            returnM (tyVarsOfTypes tys)
 423
 424 zonkTcTyVar :: TcTyVar -> TcM TcType
 425 zonkTcTyVar tyvar = ASSERT( isTcTyVar tyvar )
 426                     zonk_tc_tyvar (\ tv -> returnM (TyVarTy tv)) tyvar
 427 \end{code}
 428
 429 -----------------  Types
 430
 431 \begin{code}
 432 zonkTcType :: TcType -> TcM TcType
 433 zonkTcType ty = zonkType (\ tv -> returnM (TyVarTy tv)) ty
 434
 435 zonkTcTypes :: [TcType] -> TcM [TcType]
 436 zonkTcTypes tys = mappM zonkTcType tys
 437
 438 zonkTcClassConstraints cts = mappM zonk cts
 439     where zonk (clas, tys)
 440             = zonkTcTypes tys   `thenM` \ new_tys ->
 441               returnM (clas, new_tys)
 442
 443 zonkTcThetaType :: TcThetaType -> TcM TcThetaType
 444 zonkTcThetaType theta = mappM zonkTcPredType theta
 445
 446 zonkTcPredType :: TcPredType -> TcM TcPredType
 447 zonkTcPredType (ClassP c ts)
 448   = zonkTcTypes ts      `thenM` \ new_ts ->
 449     returnM (ClassP c new_ts)
 450 zonkTcPredType (IParam n t)
 451   = zonkTcType t        `thenM` \ new_t ->
 452     returnM (IParam n new_t)
 453 zonkTcPredType (EqPred t1 t2)
 454   = zonkTcType t1       `thenM` \ new_t1 ->
 455     zonkTcType t2       `thenM` \ new_t2 ->
 456     returnM (EqPred new_t1 new_t2)
 457 \end{code}
 458
 459 -------------------  These ...ToType, ...ToKind versions
 460                      are used at the end of type checking
 461
 462 \begin{code}
 463 zonkTopTyVar :: TcTyVar -> TcM TcTyVar
 464 -- zonkTopTyVar is used, at the top level, on any un-instantiated meta type variables
 465 -- to default the kind of ? and ?? etc to *.  This is important to ensure that
 466 -- instance declarations match.  For example consider
 467 --      instance Show (a->b)
 468 --      foo x = show (\_ -> True)
 469 -- Then we'll get a constraint (Show (p ->q)) where p has argTypeKind (printed ??),
 470 -- and that won't match the typeKind (*) in the instance decl.
 471 --
 472 -- Because we are at top level, no further constraints are going to affect these
 473 -- type variables, so it's time to do it by hand.  However we aren't ready
 474 -- to default them fully to () or whatever, because the type-class defaulting
 475 -- rules have yet to run.
 476
 477 zonkTopTyVar tv
 478   | k `eqKind` default_k = return tv
 479   | otherwise
 480   = do  { tv' <- newFlexiTyVar default_k
 481         ; writeMetaTyVar tv (mkTyVarTy tv')
 482         ; return tv' }
 483   where
 484     k = tyVarKind tv
 485     default_k = defaultKind k
 486
 487 zonkQuantifiedTyVars :: [TcTyVar] -> TcM [TyVar]
 488 zonkQuantifiedTyVars = mappM zonkQuantifiedTyVar
 489
 490 zonkQuantifiedTyVar :: TcTyVar -> TcM TyVar
 491 -- zonkQuantifiedTyVar is applied to the a TcTyVar when quantifying over it.
 492 --
 493 -- The quantified type variables often include meta type variables
 494 -- we want to freeze them into ordinary type variables, and
 495 -- default their kind (e.g. from OpenTypeKind to TypeKind)
 496 --                      -- see notes with Kind.defaultKind
 497 -- The meta tyvar is updated to point to the new regular TyVar.  Now any
 498 -- bound occurences of the original type variable will get zonked to
 499 -- the immutable version.
 500 --
 501 -- We leave skolem TyVars alone; they are immutable.
 502 zonkQuantifiedTyVar tv
 503   | ASSERT( isTcTyVar tv )
 504     isSkolemTyVar tv = return tv
 505         -- It might be a skolem type variable,
 506         -- for example from a user type signature
 507
 508   | otherwise   -- It's a meta-type-variable
 509   = do  { details <- readMetaTyVar tv
 510
 511         -- Create the new, frozen, regular type variable
 512         ; let final_kind = defaultKind (tyVarKind tv)
 513               final_tv   = mkTyVar (tyVarName tv) final_kind
 514
 515         -- Bind the meta tyvar to the new tyvar
 516         ; case details of
 517             Indirect ty -> WARN( True, ppr tv $$ ppr ty )
 518                            return ()
 519                 -- [Sept 04] I don't think this should happen
 520                 -- See note [Silly Type Synonym]
 521
 522             Flexi -> writeMetaTyVar tv (mkTyVarTy final_tv)
 523
 524         -- Return the new tyvar
 525         ; return final_tv }
 526 \end{code}
 527
 528 [Silly Type Synonyms]
 529
 530 Consider this:
 531         type C u a = u  -- Note 'a' unused
 532
 533         foo :: (forall a. C u a -> C u a) -> u
 534         foo x = ...
 535
 536         bar :: Num u => u
 537         bar = foo (\t -> t + t)
 538
 539 * From the (\t -> t+t) we get type  {Num d} =>  d -> d
 540   where d is fresh.
 541
 542 * Now unify with type of foo's arg, and we get:
 543         {Num (C d a)} =>  C d a -> C d a
 544   where a is fresh.
 545
 546 * Now abstract over the 'a', but float out the Num (C d a) constraint
 547   because it does not 'really' mention a.  (see exactTyVarsOfType)
 548   The arg to foo becomes
 549         /\a -> \t -> t+t
 550
 551 * So we get a dict binding for Num (C d a), which is zonked to give
 552         a = ()
 553   [Note Sept 04: now that we are zonking quantified type variables
 554   on construction, the 'a' will be frozen as a regular tyvar on
 555   quantification, so the floated dict will still have type (C d a).
 556   Which renders this whole note moot; happily!]
 557
 558 * Then the /\a abstraction has a zonked 'a' in it.
 559
 560 All very silly.   I think its harmless to ignore the problem.  We'll end up with
 561 a /\a in the final result but all the occurrences of a will be zonked to ()
 562
 563
 564 %************************************************************************
 565 %*                                                                      *
 566 \subsection{Zonking -- the main work-horses: zonkType, zonkTyVar}
 567 %*                                                                      *
 568 %*              For internal use only!                                  *
 569 %*                                                                      *
 570 %************************************************************************
 571
 572 \begin{code}
 573 -- For unbound, mutable tyvars, zonkType uses the function given to it
 574 -- For tyvars bound at a for-all, zonkType zonks them to an immutable
 575 --      type variable and zonks the kind too
 576
 577 zonkType :: (TcTyVar -> TcM Type)       -- What to do with unbound mutable type variables
 578                                         -- see zonkTcType, and zonkTcTypeToType
 579          -> TcType
 580          -> TcM Type
 581 zonkType unbound_var_fn ty
 582   = go ty
 583   where
 584     go (NoteTy _ ty2)    = go ty2       -- Discard free-tyvar annotations
 585
 586     go (TyConApp tc tys) = mappM go tys `thenM` \ tys' ->
 587                            returnM (TyConApp tc tys')
 588
 589     go (PredTy p)        = go_pred p            `thenM` \ p' ->
 590                            returnM (PredTy p')
 591
 592     go (FunTy arg res)   = go arg               `thenM` \ arg' ->
 593                            go res               `thenM` \ res' ->
 594                            returnM (FunTy arg' res')
 595
 596     go (AppTy fun arg)   = go fun               `thenM` \ fun' ->
 597                            go arg               `thenM` \ arg' ->
 598                            returnM (mkAppTy fun' arg')
 599                 -- NB the mkAppTy; we might have instantiated a
 600                 -- type variable to a type constructor, so we need
 601                 -- to pull the TyConApp to the top.
 602
 603         -- The two interesting cases!
 604     go (TyVarTy tyvar) | isTcTyVar tyvar = zonk_tc_tyvar unbound_var_fn tyvar
 605                        | otherwise       = return (TyVarTy tyvar)
 606                 -- Ordinary (non Tc) tyvars occur inside quantified types
 607
 608     go (ForAllTy tyvar ty) = ASSERT( isImmutableTyVar tyvar )
 609                              go ty              `thenM` \ ty' ->
 610                              returnM (ForAllTy tyvar ty')
 611
 612     go_pred (ClassP c tys)   = mappM go tys     `thenM` \ tys' ->
 613                                returnM (ClassP c tys')
 614     go_pred (IParam n ty)    = go ty            `thenM` \ ty' ->
 615                                returnM (IParam n ty')
 616     go_pred (EqPred ty1 ty2) = go ty1           `thenM` \ ty1' ->
 617                                go ty2           `thenM` \ ty2' ->
 618                                returnM (EqPred ty1' ty2')
 619
 620 zonk_tc_tyvar :: (TcTyVar -> TcM Type)          -- What to do for an unbound mutable variable
 621               -> TcTyVar -> TcM TcType
 622 zonk_tc_tyvar unbound_var_fn tyvar
 623   | not (isMetaTyVar tyvar)     -- Skolems
 624   = returnM (TyVarTy tyvar)
 625
 626   | otherwise                   -- Mutables
 627   = do  { cts <- readMetaTyVar tyvar
 628         ; case cts of
 629             Flexi       -> unbound_var_fn tyvar    -- Unbound meta type variable
 630             Indirect ty -> zonkType unbound_var_fn ty  }
 631 \end{code}
 632
 633
 634
 635 %************************************************************************
 636 %*                                                                      *
 637                         Zonking kinds
 638 %*                                                                      *
 639 %************************************************************************
 640
 641 \begin{code}
 642 readKindVar  :: KindVar -> TcM (MetaDetails)
 643 writeKindVar :: KindVar -> TcKind -> TcM ()
 644 readKindVar  kv = readMutVar (kindVarRef kv)
 645 writeKindVar kv val = writeMutVar (kindVarRef kv) (Indirect val)
 646
 647 -------------
 648 zonkTcKind :: TcKind -> TcM TcKind
 649 zonkTcKind k = zonkTcType k
 650
 651 -------------
 652 zonkTcKindToKind :: TcKind -> TcM Kind
 653 -- When zonking a TcKind to a kind, we need to instantiate kind variables,
 654 -- Haskell specifies that * is to be used, so we follow that.
 655 zonkTcKindToKind k = zonkType (\ _ -> return liftedTypeKind) k
 656 \end{code}
 657
 658 %************************************************************************
 659 %*                                                                      *
 660 \subsection{Checking a user type}
 661 %*                                                                      *
 662 %************************************************************************
 663
 664 When dealing with a user-written type, we first translate it from an HsType
 665 to a Type, performing kind checking, and then check various things that should
 666 be true about it.  We don't want to perform these checks at the same time
 667 as the initial translation because (a) they are unnecessary for interface-file
 668 types and (b) when checking a mutually recursive group of type and class decls,
 669 we can't "look" at the tycons/classes yet.  Also, the checks are are rather
 670 diverse, and used to really mess up the other code.
 671
 672 One thing we check for is 'rank'.
 673
 674         Rank 0:         monotypes (no foralls)
 675         Rank 1:         foralls at the front only, Rank 0 inside
 676         Rank 2:         foralls at the front, Rank 1 on left of fn arrow,
 677
 678         basic ::= tyvar | T basic ... basic
 679
 680         r2  ::= forall tvs. cxt => r2a
 681         r2a ::= r1 -> r2a | basic
 682         r1  ::= forall tvs. cxt => r0
 683         r0  ::= r0 -> r0 | basic
 684
 685 Another thing is to check that type synonyms are saturated.
 686 This might not necessarily show up in kind checking.
 687         type A i = i
 688         data T k = MkT (k Int)
 689         f :: T A        -- BAD!
 690
 691
 692 \begin{code}
 693 checkValidType :: UserTypeCtxt -> Type -> TcM ()
 694 -- Checks that the type is valid for the given context
 695 checkValidType ctxt ty
 696   = traceTc (text "checkValidType" <+> ppr ty)  `thenM_`
 697     doptM Opt_GlasgowExts       `thenM` \ gla_exts ->
 698     let
 699         rank | gla_exts = Arbitrary
 700              | otherwise
 701              = case ctxt of     -- Haskell 98
 702                  GenPatCtxt     -> Rank 0
 703                  LamPatSigCtxt  -> Rank 0
 704                  BindPatSigCtxt -> Rank 0
 705                  DefaultDeclCtxt-> Rank 0
 706                  ResSigCtxt     -> Rank 0
 707                  TySynCtxt _    -> Rank 0
 708                  ExprSigCtxt    -> Rank 1
 709                  FunSigCtxt _   -> Rank 1
 710                  ConArgCtxt _   -> Rank 1       -- We are given the type of the entire
 711                                                 -- constructor, hence rank 1
 712                  ForSigCtxt _   -> Rank 1
 713                  SpecInstCtxt   -> Rank 1
 714
 715         actual_kind = typeKind ty
 716
 717         kind_ok = case ctxt of
 718                         TySynCtxt _  -> True    -- Any kind will do
 719                         ResSigCtxt   -> isSubOpenTypeKind        actual_kind
 720                         ExprSigCtxt  -> isSubOpenTypeKind        actual_kind
 721                         GenPatCtxt   -> isLiftedTypeKind actual_kind
 722                         ForSigCtxt _ -> isLiftedTypeKind actual_kind
 723                         other        -> isSubArgTypeKind    actual_kind
 724
 725         ubx_tup | not gla_exts = UT_NotOk
 726                 | otherwise    = case ctxt of
 727                                    TySynCtxt _ -> UT_Ok
 728                                    ExprSigCtxt -> UT_Ok
 729                                    other       -> UT_NotOk
 730                 -- Unboxed tuples ok in function results,
 731                 -- but for type synonyms we allow them even at
 732                 -- top level
 733     in
 734         -- Check that the thing has kind Type, and is lifted if necessary
 735     checkTc kind_ok (kindErr actual_kind)       `thenM_`
 736
 737         -- Check the internal validity of the type itself
 738     check_poly_type rank ubx_tup ty             `thenM_`
 739
 740     traceTc (text "checkValidType done" <+> ppr ty)
 741 \end{code}
 742
 743
 744 \begin{code}
 745 data Rank = Rank Int | Arbitrary
 746
 747 decRank :: Rank -> Rank
 748 decRank Arbitrary = Arbitrary
 749 decRank (Rank n)  = Rank (n-1)
 750
 751 ----------------------------------------
 752 data UbxTupFlag = UT_Ok | UT_NotOk
 753         -- The "Ok" version means "ok if -fglasgow-exts is on"
 754
 755 ----------------------------------------
 756 check_poly_type :: Rank -> UbxTupFlag -> Type -> TcM ()
 757 check_poly_type (Rank 0) ubx_tup ty
 758   = check_tau_type (Rank 0) ubx_tup ty
 759
 760 check_poly_type rank ubx_tup ty
 761   | null tvs && null theta
 762   = check_tau_type rank ubx_tup ty
 763   | otherwise
 764   = do  { check_valid_theta SigmaCtxt theta
 765         ; check_poly_type rank ubx_tup tau      -- Allow foralls to right of arrow
 766         ; checkFreeness tvs theta
 767         ; checkAmbiguity tvs theta (tyVarsOfType tau) }
 768   where
 769     (tvs, theta, tau) = tcSplitSigmaTy ty
 770
 771 ----------------------------------------
 772 check_arg_type :: Type -> TcM ()
 773 -- The sort of type that can instantiate a type variable,
 774 -- or be the argument of a type constructor.
 775 -- Not an unboxed tuple, but now *can* be a forall (since impredicativity)
 776 -- Other unboxed types are very occasionally allowed as type
 777 -- arguments depending on the kind of the type constructor
 778 --
 779 -- For example, we want to reject things like:
 780 --
 781 --      instance Ord a => Ord (forall s. T s a)
 782 -- and
 783 --      g :: T s (forall b.b)
 784 --
 785 -- NB: unboxed tuples can have polymorphic or unboxed args.
 786 --     This happens in the workers for functions returning
 787 --     product types with polymorphic components.
 788 --     But not in user code.
 789 -- Anyway, they are dealt with by a special case in check_tau_type
 790
 791 check_arg_type ty
 792   = check_poly_type Arbitrary UT_NotOk ty       `thenM_`
 793     checkTc (not (isUnLiftedType ty)) (unliftedArgErr ty)
 794
 795 ----------------------------------------
 796 check_tau_type :: Rank -> UbxTupFlag -> Type -> TcM ()
 797 -- Rank is allowed rank for function args
 798 -- No foralls otherwise
 799
 800 check_tau_type rank ubx_tup ty@(ForAllTy _ _)       = failWithTc (forAllTyErr ty)
 801 check_tau_type rank ubx_tup ty@(FunTy (PredTy _) _) = failWithTc (forAllTyErr ty)
 802         -- Reject e.g. (Maybe (?x::Int => Int)), with a decent error message
 803
 804 -- Naked PredTys don't usually show up, but they can as a result of
 805 --      {-# SPECIALISE instance Ord Char #-}
 806 -- The Right Thing would be to fix the way that SPECIALISE instance pragmas
 807 -- are handled, but the quick thing is just to permit PredTys here.
 808 check_tau_type rank ubx_tup (PredTy sty) = getDOpts             `thenM` \ dflags ->
 809                                            check_pred_ty dflags TypeCtxt sty
 810
 811 check_tau_type rank ubx_tup (TyVarTy _)       = returnM ()
 812 check_tau_type rank ubx_tup ty@(FunTy arg_ty res_ty)
 813   = check_poly_type (decRank rank) UT_NotOk arg_ty      `thenM_`
 814     check_poly_type rank           UT_Ok    res_ty
 815
 816 check_tau_type rank ubx_tup (AppTy ty1 ty2)
 817   = check_arg_type ty1 `thenM_` check_arg_type ty2
 818
 819 check_tau_type rank ubx_tup (NoteTy other_note ty)
 820   = check_tau_type rank ubx_tup ty
 821
 822 check_tau_type rank ubx_tup ty@(TyConApp tc tys)
 823   | isSynTyCon tc
 824   = do  {       -- It's OK to have an *over-applied* type synonym
 825                 --      data Tree a b = ...
 826                 --      type Foo a = Tree [a]
 827                 --      f :: Foo a b -> ...
 828         ; case tcView ty of
 829              Just ty' -> check_tau_type rank ubx_tup ty' -- Check expansion
 830              Nothing -> unless (isOpenTyCon tc           -- No expansion if open
 831                                 && tyConArity tc <= length tys) $
 832                           failWithTc arity_msg
 833
 834         ; gla_exts <- doptM Opt_GlasgowExts
 835         ; if gla_exts && not (isOpenTyCon tc) then
 836         -- If -fglasgow-exts then don't check the type arguments of
 837         -- *closed* synonyms.
 838         -- This allows us to instantiate a synonym defn with a
 839         -- for-all type, or with a partially-applied type synonym.
 840         --      e.g.   type T a b = a
 841         --             type S m   = m ()
 842         --             f :: S (T Int)
 843         -- Here, T is partially applied, so it's illegal in H98.
 844         -- But if you expand S first, then T we get just
 845         --             f :: Int
 846         -- which is fine.
 847                 returnM ()
 848           else
 849                 -- For H98, do check the type args
 850                 mappM_ check_arg_type tys
 851         }
 852
 853   | isUnboxedTupleTyCon tc
 854   = doptM Opt_GlasgowExts                       `thenM` \ gla_exts ->
 855     checkTc (ubx_tup_ok gla_exts) ubx_tup_msg   `thenM_`
 856     mappM_ (check_tau_type (Rank 0) UT_Ok) tys
 857                 -- Args are allowed to be unlifted, or
 858                 -- more unboxed tuples, so can't use check_arg_ty
 859
 860   | otherwise
 861   = mappM_ check_arg_type tys
 862
 863   where
 864     ubx_tup_ok gla_exts = case ubx_tup of { UT_Ok -> gla_exts; other -> False }
 865
 866     n_args    = length tys
 867     tc_arity  = tyConArity tc
 868
 869     arity_msg   = arityErr "Type synonym" (tyConName tc) tc_arity n_args
 870     ubx_tup_msg = ubxArgTyErr ty
 871
 872 ----------------------------------------
 873 forAllTyErr     ty = ptext SLIT("Illegal polymorphic or qualified type:") <+> ppr ty
 874 unliftedArgErr  ty = ptext SLIT("Illegal unlifted type argument:") <+> ppr ty
 875 ubxArgTyErr     ty = ptext SLIT("Illegal unboxed tuple type as function argument:") <+> ppr ty
 876 kindErr kind       = ptext SLIT("Expecting an ordinary type, but found a type of kind") <+> ppr kind
 877 \end{code}
 878
 879
 880
 881 %************************************************************************
 882 %*                                                                      *
 883 \subsection{Checking a theta or source type}
 884 %*                                                                      *
 885 %************************************************************************
 886
 887 \begin{code}
 888 -- Enumerate the contexts in which a "source type", <S>, can occur
 889 --      Eq a
 890 -- or   ?x::Int
 891 -- or   r <: {x::Int}
 892 -- or   (N a) where N is a newtype
 893
 894 data SourceTyCtxt
 895   = ClassSCCtxt Name    -- Superclasses of clas
 896                         --      class <S> => C a where ...
 897   | SigmaCtxt           -- Theta part of a normal for-all type
 898                         --      f :: <S> => a -> a
 899   | DataTyCtxt Name     -- Theta part of a data decl
 900                         --      data <S> => T a = MkT a
 901   | TypeCtxt            -- Source type in an ordinary type
 902                         --      f :: N a -> N a
 903   | InstThetaCtxt       -- Context of an instance decl
 904                         --      instance <S> => C [a] where ...
 905
 906 pprSourceTyCtxt (ClassSCCtxt c) = ptext SLIT("the super-classes of class") <+> quotes (ppr c)
 907 pprSourceTyCtxt SigmaCtxt       = ptext SLIT("the context of a polymorphic type")
 908 pprSourceTyCtxt (DataTyCtxt tc) = ptext SLIT("the context of the data type declaration for") <+> quotes (ppr tc)
 909 pprSourceTyCtxt InstThetaCtxt   = ptext SLIT("the context of an instance declaration")
 910 pprSourceTyCtxt TypeCtxt        = ptext SLIT("the context of a type")
 911 \end{code}
 912
 913 \begin{code}
 914 checkValidTheta :: SourceTyCtxt -> ThetaType -> TcM ()
 915 checkValidTheta ctxt theta
 916   = addErrCtxt (checkThetaCtxt ctxt theta) (check_valid_theta ctxt theta)
 917
 918 -------------------------
 919 check_valid_theta ctxt []
 920   = returnM ()
 921 check_valid_theta ctxt theta
 922   = getDOpts                                    `thenM` \ dflags ->
 923     warnTc (notNull dups) (dupPredWarn dups)    `thenM_`
 924     mappM_ (check_pred_ty dflags ctxt) theta
 925   where
 926     (_,dups) = removeDups tcCmpPred theta
 927
 928 -------------------------
 929 check_pred_ty dflags ctxt pred@(ClassP cls tys)
 930   = do {        -- Class predicates are valid in all contexts
 931        ; checkTc (arity == n_tys) arity_err
 932
 933                 -- Check the form of the argument types
 934        ; mappM_ check_arg_type tys
 935        ; checkTc (check_class_pred_tys dflags ctxt tys)
 936                  (predTyVarErr pred $$ how_to_allow)
 937        }
 938   where
 939     class_name = className cls
 940     arity      = classArity cls
 941     n_tys      = length tys
 942     arity_err  = arityErr "Class" class_name arity n_tys
 943     how_to_allow = parens (ptext SLIT("Use -fglasgow-exts to permit this"))
 944
 945 check_pred_ty dflags ctxt pred@(EqPred ty1 ty2)
 946   = do {        -- Equational constraints are valid in all contexts if indexed
 947                 -- types are permitted
 948        ; checkTc (dopt Opt_IndexedTypes dflags) (eqPredTyErr pred)
 949
 950                 -- Check the form of the argument types
 951        ; check_eq_arg_type ty1
 952        ; check_eq_arg_type ty2
 953        }
 954   where
 955     check_eq_arg_type = check_poly_type (Rank 0) UT_NotOk
 956
 957 check_pred_ty dflags SigmaCtxt (IParam _ ty) = check_arg_type ty
 958         -- Implicit parameters only allowed in type
 959         -- signatures; not in instance decls, superclasses etc
 960         -- The reason for not allowing implicit params in instances is a bit
 961         -- subtle.
 962         -- If we allowed        instance (?x::Int, Eq a) => Foo [a] where ...
 963         -- then when we saw (e :: (?x::Int) => t) it would be unclear how to
 964         -- discharge all the potential usas of the ?x in e.   For example, a
 965         -- constraint Foo [Int] might come out of e,and applying the
 966         -- instance decl would show up two uses of ?x.
 967
 968 -- Catch-all
 969 check_pred_ty dflags ctxt sty = failWithTc (badPredTyErr sty)
 970
 971 -------------------------
 972 check_class_pred_tys dflags ctxt tys
 973   = case ctxt of
 974         TypeCtxt      -> True   -- {-# SPECIALISE instance Eq (T Int) #-} is fine
 975         InstThetaCtxt -> gla_exts || undecidable_ok || all tcIsTyVarTy tys
 976                                 -- Further checks on head and theta in
 977                                 -- checkInstTermination
 978         other         -> gla_exts || all tyvar_head tys
 979   where
 980     gla_exts       = dopt Opt_GlasgowExts dflags
 981     undecidable_ok = dopt Opt_AllowUndecidableInstances dflags
 982
 983 -------------------------
 984 tyvar_head ty                   -- Haskell 98 allows predicates of form
 985   | tcIsTyVarTy ty = True       --      C (a ty1 .. tyn)
 986   | otherwise                   -- where a is a type variable
 987   = case tcSplitAppTy_maybe ty of
 988         Just (ty, _) -> tyvar_head ty
 989         Nothing      -> False
 990 \end{code}
 991
 992 Check for ambiguity
 993 ~~~~~~~~~~~~~~~~~~~
 994           forall V. P => tau
 995 is ambiguous if P contains generic variables
 996 (i.e. one of the Vs) that are not mentioned in tau
 997
 998 However, we need to take account of functional dependencies
 999 when we speak of 'mentioned in tau'.  Example:
1000         class C a b | a -> b where ...
1001 Then the type
1002         forall x y. (C x y) => x
1003 is not ambiguous because x is mentioned and x determines y
1004
1005 NB; the ambiguity check is only used for *user* types, not for types
1006 coming from inteface files.  The latter can legitimately have
1007 ambiguous types. Example
1008
1009    class S a where s :: a -> (Int,Int)
1010    instance S Char where s _ = (1,1)
1011    f:: S a => [a] -> Int -> (Int,Int)
1012    f (_::[a]) x = (a*x,b)
1013         where (a,b) = s (undefined::a)
1014
1015 Here the worker for f gets the type
1016         fw :: forall a. S a => Int -> (# Int, Int #)
1017
1018 If the list of tv_names is empty, we have a monotype, and then we
1019 don't need to check for ambiguity either, because the test can't fail
1020 (see is_ambig).
1021
1022 \begin{code}
1023 checkAmbiguity :: [TyVar] -> ThetaType -> TyVarSet -> TcM ()
1024 checkAmbiguity forall_tyvars theta tau_tyvars
1025   = mappM_ complain (filter is_ambig theta)
1026   where
1027     complain pred     = addErrTc (ambigErr pred)
1028     extended_tau_vars = grow theta tau_tyvars
1029
1030         -- Only a *class* predicate can give rise to ambiguity
1031         -- An *implicit parameter* cannot.  For example:
1032         --      foo :: (?x :: [a]) => Int
1033         --      foo = length ?x
1034         -- is fine.  The call site will suppply a particular 'x'
1035     is_ambig pred     = isClassPred  pred &&
1036                         any ambig_var (varSetElems (tyVarsOfPred pred))
1037
1038     ambig_var ct_var  = (ct_var `elem` forall_tyvars) &&
1039                         not (ct_var `elemVarSet` extended_tau_vars)
1040
1041 ambigErr pred
1042   = sep [ptext SLIT("Ambiguous constraint") <+> quotes (pprPred pred),
1043          nest 4 (ptext SLIT("At least one of the forall'd type variables mentioned by the constraint") $$
1044                  ptext SLIT("must be reachable from the type after the '=>'"))]
1045 \end{code}
1046
1047 In addition, GHC insists that at least one type variable
1048 in each constraint is in V.  So we disallow a type like
1049         forall a. Eq b => b -> b
1050 even in a scope where b is in scope.
1051
1052 \begin{code}
1053 checkFreeness forall_tyvars theta
1054   = do  { gla_exts <- doptM Opt_GlasgowExts
1055         ; if gla_exts then return ()    -- New!  Oct06
1056           else mappM_ complain (filter is_free theta) }
1057   where
1058     is_free pred     =  not (isIPPred pred)
1059                      && not (any bound_var (varSetElems (tyVarsOfPred pred)))
1060     bound_var ct_var = ct_var `elem` forall_tyvars
1061     complain pred    = addErrTc (freeErr pred)
1062
1063 freeErr pred
1064   = sep [ptext SLIT("All of the type variables in the constraint") <+> quotes (pprPred pred) <+>
1065                    ptext SLIT("are already in scope"),
1066          nest 4 (ptext SLIT("(at least one must be universally quantified here)"))
1067     ]
1068 \end{code}
1069
1070 \begin{code}
1071 checkThetaCtxt ctxt theta
1072   = vcat [ptext SLIT("In the context:") <+> pprTheta theta,
1073           ptext SLIT("While checking") <+> pprSourceTyCtxt ctxt ]
1074
1075 badPredTyErr sty = ptext SLIT("Illegal constraint") <+> pprPred sty
1076 eqPredTyErr  sty = ptext SLIT("Illegal equational constraint") <+> pprPred sty
1077                    $$
1078                    parens (ptext SLIT("Use -findexed-types to permit this"))
1079 predTyVarErr pred  = sep [ptext SLIT("Non type-variable argument"),
1080                           nest 2 (ptext SLIT("in the constraint:") <+> pprPred pred)]
1081 dupPredWarn dups   = ptext SLIT("Duplicate constraint(s):") <+> pprWithCommas pprPred (map head dups)
1082
1083 arityErr kind name n m
1084   = hsep [ text kind, quotes (ppr name), ptext SLIT("should have"),
1085            n_arguments <> comma, text "but has been given", int m]
1086     where
1087         n_arguments | n == 0 = ptext SLIT("no arguments")
1088                     | n == 1 = ptext SLIT("1 argument")
1089                     | True   = hsep [int n, ptext SLIT("arguments")]
1090 \end{code}
1091
1092
1093 %************************************************************************
1094 %*                                                                      *
1095 \subsection{Checking for a decent instance head type}
1096 %*                                                                      *
1097 %************************************************************************
1098
1099 @checkValidInstHead@ checks the type {\em and} its syntactic constraints:
1100 it must normally look like: @instance Foo (Tycon a b c ...) ...@
1101
1102 The exceptions to this syntactic checking: (1)~if the @GlasgowExts@
1103 flag is on, or (2)~the instance is imported (they must have been
1104 compiled elsewhere). In these cases, we let them go through anyway.
1105
1106 We can also have instances for functions: @instance Foo (a -> b) ...@.
1107
1108 \begin{code}
1109 checkValidInstHead :: Type -> TcM (Class, [TcType])
1110
1111 checkValidInstHead ty   -- Should be a source type
1112   = case tcSplitPredTy_maybe ty of {
1113         Nothing -> failWithTc (instTypeErr (ppr ty) empty) ;
1114         Just pred ->
1115
1116     case getClassPredTys_maybe pred of {
1117         Nothing -> failWithTc (instTypeErr (pprPred pred) empty) ;
1118         Just (clas,tys) ->
1119
1120     getDOpts                                    `thenM` \ dflags ->
1121     mappM_ check_arg_type tys                   `thenM_`
1122     check_inst_head dflags clas tys             `thenM_`
1123     returnM (clas, tys)
1124     }}
1125
1126 check_inst_head dflags clas tys
1127         -- If GlasgowExts then check at least one isn't a type variable
1128   | dopt Opt_GlasgowExts dflags
1129   = mapM_ check_one tys
1130
1131         -- WITH HASKELL 98, MUST HAVE C (T a b c)
1132   | otherwise
1133   = checkTc (isSingleton tys && tcValidInstHeadTy first_ty)
1134             (instTypeErr (pprClassPred clas tys) head_shape_msg)
1135
1136   where
1137     (first_ty : _) = tys
1138
1139     head_shape_msg = parens (text "The instance type must be of form (T a1 ... an)" $$
1140                              text "where T is not a synonym, and a1 ... an are distinct type *variables*")
1141
1142         -- For now, I only allow tau-types (not polytypes) in
1143         -- the head of an instance decl.
1144         --      E.g.  instance C (forall a. a->a) is rejected
1145         -- One could imagine generalising that, but I'm not sure
1146         -- what all the consequences might be
1147     check_one ty = do { check_tau_type (Rank 0) UT_NotOk ty
1148                       ; checkTc (not (isUnLiftedType ty)) (unliftedArgErr ty) }
1149
1150 instTypeErr pp_ty msg
1151   = sep [ptext SLIT("Illegal instance declaration for") <+> quotes pp_ty,
1152          nest 4 msg]
1153 \end{code}
1154
1155
1156 %************************************************************************
1157 %*                                                                      *
1158 \subsection{Checking instance for termination}
1159 %*                                                                      *
1160 %************************************************************************
1161
1162
1163 \begin{code}
1164 checkValidInstance :: [TyVar] -> ThetaType -> Class -> [TcType] -> TcM ()
1165 checkValidInstance tyvars theta clas inst_tys
1166   = do  { gla_exts <- doptM Opt_GlasgowExts
1167         ; undecidable_ok <- doptM Opt_AllowUndecidableInstances
1168
1169         ; checkValidTheta InstThetaCtxt theta
1170         ; checkAmbiguity tyvars theta (tyVarsOfTypes inst_tys)
1171
1172         -- Check that instance inference will terminate (if we care)
1173         -- For Haskell 98, checkValidTheta has already done that
1174         ; when (gla_exts && not undecidable_ok) $
1175           mapM_ addErrTc (checkInstTermination inst_tys theta)
1176
1177         -- The Coverage Condition
1178         ; checkTc (undecidable_ok || checkInstCoverage clas inst_tys)
1179                   (instTypeErr (pprClassPred clas inst_tys) msg)
1180         }
1181   where
1182     msg  = parens (vcat [ptext SLIT("the Coverage Condition fails for one of the functional dependencies;"),
1183                          undecidableMsg])
1184 \end{code}
1185
1186 Termination test: each assertion in the context satisfies
1187  (1) no variable has more occurrences in the assertion than in the head, and
1188  (2) the assertion has fewer constructors and variables (taken together
1189      and counting repetitions) than the head.
1190 This is only needed with -fglasgow-exts, as Haskell 98 restrictions
1191 (which have already been checked) guarantee termination.
1192
1193 The underlying idea is that
1194
1195     for any ground substitution, each assertion in the
1196     context has fewer type constructors than the head.
1197
1198
1199 \begin{code}
1200 checkInstTermination :: [TcType] -> ThetaType -> [Message]
1201 checkInstTermination tys theta
1202   = mapCatMaybes check theta
1203   where
1204    fvs  = fvTypes tys
1205    size = sizeTypes tys
1206    check pred
1207       | not (null (fvPred pred \\ fvs))
1208       = Just (predUndecErr pred nomoreMsg $$ parens undecidableMsg)
1209       | sizePred pred >= size
1210       = Just (predUndecErr pred smallerMsg $$ parens undecidableMsg)
1211       | otherwise
1212       = Nothing
1213
1214 predUndecErr pred msg = sep [msg,
1215                         nest 2 (ptext SLIT("in the constraint:") <+> pprPred pred)]
1216
1217 nomoreMsg = ptext SLIT("Variable occurs more often in a constraint than in the instance head")
1218 smallerMsg = ptext SLIT("Constraint is no smaller than the instance head")
1219 undecidableMsg = ptext SLIT("Use -fallow-undecidable-instances to permit this")
1220
1221 -- Free variables of a type, retaining repetitions, and expanding synonyms
1222 fvType :: Type -> [TyVar]
1223 fvType ty | Just exp_ty <- tcView ty = fvType exp_ty
1224 fvType (TyVarTy tv)        = [tv]
1225 fvType (TyConApp _ tys)    = fvTypes tys
1226 fvType (NoteTy _ ty)       = fvType ty
1227 fvType (PredTy pred)       = fvPred pred
1228 fvType (FunTy arg res)     = fvType arg ++ fvType res
1229 fvType (AppTy fun arg)     = fvType fun ++ fvType arg
1230 fvType (ForAllTy tyvar ty) = filter (/= tyvar) (fvType ty)
1231
1232 fvTypes :: [Type] -> [TyVar]
1233 fvTypes tys                = concat (map fvType tys)
1234
1235 fvPred :: PredType -> [TyVar]
1236 fvPred (ClassP _ tys')     = fvTypes tys'
1237 fvPred (IParam _ ty)       = fvType ty
1238 fvPred (EqPred ty1 ty2)    = fvType ty1 ++ fvType ty2
1239
1240 -- Size of a type: the number of variables and constructors
1241 sizeType :: Type -> Int
1242 sizeType ty | Just exp_ty <- tcView ty = sizeType exp_ty
1243 sizeType (TyVarTy _)       = 1
1244 sizeType (TyConApp _ tys)  = sizeTypes tys + 1
1245 sizeType (NoteTy _ ty)     = sizeType ty
1246 sizeType (PredTy pred)     = sizePred pred
1247 sizeType (FunTy arg res)   = sizeType arg + sizeType res + 1
1248 sizeType (AppTy fun arg)   = sizeType fun + sizeType arg
1249 sizeType (ForAllTy _ ty)   = sizeType ty
1250
1251 sizeTypes :: [Type] -> Int
1252 sizeTypes xs               = sum (map sizeType xs)
1253
1254 sizePred :: PredType -> Int
1255 sizePred (ClassP _ tys')   = sizeTypes tys'
1256 sizePred (IParam _ ty)     = sizeType ty
1257 sizePred (EqPred ty1 ty2)  = sizeType ty1 + sizeType ty2
1258 \end{code}