compiler/typecheck/TcMType.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Monadic type operations
   7
   8 This module contains monadic operations over types that contain
   9 mutable type variables
  10
  11 \begin{code}
  12 module TcMType (
  13   TcTyVar, TcKind, TcType, TcTauType, TcThetaType, TcTyVarSet,
  14
  15   --------------------------------
  16   -- Creating new mutable type variables
  17   newFlexiTyVar,
  18   newFlexiTyVarTy,              -- Kind -> TcM TcType
  19   newFlexiTyVarTys,             -- Int -> Kind -> TcM [TcType]
  20   newKindVar, newKindVars,
  21   lookupTcTyVar, LookupTyVarResult(..),
  22   newMetaTyVar, readMetaTyVar, writeMetaTyVar,
  23
  24   --------------------------------
  25   -- Boxy type variables
  26   newBoxyTyVar, newBoxyTyVars, newBoxyTyVarTys, readFilledBox,
  27
  28   --------------------------------
  29   -- Creating new coercion variables
  30   newCoVars,
  31
  32   --------------------------------
  33   -- Instantiation
  34   tcInstTyVar, tcInstType, tcInstTyVars, tcInstBoxyTyVar,
  35   tcInstSigTyVars, zonkSigTyVar,
  36   tcInstSkolTyVar, tcInstSkolTyVars, tcInstSkolType,
  37   tcSkolSigType, tcSkolSigTyVars,
  38
  39   --------------------------------
  40   -- Checking type validity
  41   Rank, UserTypeCtxt(..), checkValidType,
  42   SourceTyCtxt(..), checkValidTheta, checkFreeness,
  43   checkValidInstHead, checkValidInstance, checkAmbiguity,
  44   checkInstTermination,
  45   arityErr,
  46
  47   --------------------------------
  48   -- Zonking
  49   zonkType, zonkTcPredType,
  50   zonkTcTyVar, zonkTcTyVars, zonkTcTyVarsAndFV,
  51   zonkQuantifiedTyVar, zonkQuantifiedTyVars,
  52   zonkTcType, zonkTcTypes, zonkTcClassConstraints, zonkTcThetaType,
  53   zonkTcKindToKind, zonkTcKind, zonkTopTyVar,
  54
  55   readKindVar, writeKindVar
  56
  57   ) where
  58
  59 #include "HsVersions.h"
  60
  61 -- friends:
  62 import TypeRep
  63 import TcType
  64 import Type
  65 import Coercion
  66 import Class
  67 import TyCon
  68 import Var
  69
  70 -- others:
  71 import TcRnMonad          -- TcType, amongst others
  72 import FunDeps
  73 import Name
  74 import VarSet
  75 import ErrUtils
  76 import DynFlags
  77 import Util
  78 import Maybes
  79 import ListSetOps
  80 import UniqSupply
  81 import SrcLoc
  82 import Outputable
  83
  84 import Control.Monad    ( when, unless )
  85 import Data.List        ( (\\) )
  86 \end{code}
  87
  88
  89 %************************************************************************
  90 %*                                                                      *
  91         Instantiation in general
  92 %*                                                                      *
  93 %************************************************************************
  94
  95 \begin{code}
  96 tcInstType :: ([TyVar] -> TcM [TcTyVar])                -- How to instantiate the type variables
  97            -> TcType                                    -- Type to instantiate
  98            -> TcM ([TcTyVar], TcThetaType, TcType)      -- Result
  99 tcInstType inst_tyvars ty
 100   = case tcSplitForAllTys ty of
 101         ([],     rho) -> let    -- There may be overloading despite no type variables;
 102                                 --      (?x :: Int) => Int -> Int
 103                            (theta, tau) = tcSplitPhiTy rho
 104                          in
 105                          return ([], theta, tau)
 106
 107         (tyvars, rho) -> do { tyvars' <- inst_tyvars tyvars
 108
 109                             ; let  tenv = zipTopTvSubst tyvars (mkTyVarTys tyvars')
 110                                 -- Either the tyvars are freshly made, by inst_tyvars,
 111                                 -- or (in the call from tcSkolSigType) any nested foralls
 112                                 -- have different binders.  Either way, zipTopTvSubst is ok
 113
 114                             ; let  (theta, tau) = tcSplitPhiTy (substTy tenv rho)
 115                             ; return (tyvars', theta, tau) }
 116 \end{code}
 117
 118
 119 %************************************************************************
 120 %*                                                                      *
 121         Kind variables
 122 %*                                                                      *
 123 %************************************************************************
 124
 125 \begin{code}
 126 newCoVars :: [(TcType,TcType)] -> TcM [CoVar]
 127 newCoVars spec
 128   = do  { us <- newUniqueSupply
 129         ; return [ mkCoVar (mkSysTvName uniq FSLIT("co"))
 130                            (mkCoKind ty1 ty2)
 131                  | ((ty1,ty2), uniq) <- spec `zip` uniqsFromSupply us] }
 132
 133 newKindVar :: TcM TcKind
 134 newKindVar = do { uniq <- newUnique
 135                 ; ref <- newMutVar Flexi
 136                 ; return (mkTyVarTy (mkKindVar uniq ref)) }
 137
 138 newKindVars :: Int -> TcM [TcKind]
 139 newKindVars n = mappM (\ _ -> newKindVar) (nOfThem n ())
 140 \end{code}
 141
 142
 143 %************************************************************************
 144 %*                                                                      *
 145         SkolemTvs (immutable)
 146 %*                                                                      *
 147 %************************************************************************
 148
 149 \begin{code}
 150 mkSkolTyVar :: Name -> Kind -> SkolemInfo -> TcTyVar
 151 mkSkolTyVar name kind info = mkTcTyVar name kind (SkolemTv info)
 152
 153 tcSkolSigType :: SkolemInfo -> Type -> TcM ([TcTyVar], TcThetaType, TcType)
 154 -- Instantiate a type signature with skolem constants, but
 155 -- do *not* give them fresh names, because we want the name to
 156 -- be in the type environment -- it is lexically scoped.
 157 tcSkolSigType info ty = tcInstType (\tvs -> return (tcSkolSigTyVars info tvs)) ty
 158
 159 tcSkolSigTyVars :: SkolemInfo -> [TyVar] -> [TcTyVar]
 160 -- Make skolem constants, but do *not* give them new names, as above
 161 tcSkolSigTyVars info tyvars = [ mkSkolTyVar (tyVarName tv) (tyVarKind tv) info
 162                               | tv <- tyvars ]
 163
 164 tcInstSkolTyVar :: SkolemInfo -> Maybe SrcSpan -> TyVar -> TcM TcTyVar
 165 -- Instantiate the tyvar, using
 166 --      * the occ-name and kind of the supplied tyvar,
 167 --      * the unique from the monad,
 168 --      * the location either from the tyvar (mb_loc = Nothing)
 169 --        or from mb_loc (Just loc)
 170 tcInstSkolTyVar info mb_loc tyvar
 171   = do  { uniq <- newUnique
 172         ; let old_name = tyVarName tyvar
 173               kind     = tyVarKind tyvar
 174               loc      = mb_loc `orElse` getSrcSpan old_name
 175               new_name = mkInternalName uniq (nameOccName old_name) loc
 176         ; return (mkSkolTyVar new_name kind info) }
 177
 178 tcInstSkolTyVars :: SkolemInfo -> [TyVar] -> TcM [TcTyVar]
 179 -- Get the location from the monad
 180 tcInstSkolTyVars info tyvars
 181   = do  { span <- getSrcSpanM
 182         ; mapM (tcInstSkolTyVar info (Just span)) tyvars }
 183
 184 tcInstSkolType :: SkolemInfo -> TcType -> TcM ([TcTyVar], TcThetaType, TcType)
 185 -- Instantiate a type with fresh skolem constants
 186 -- Binding location comes from the monad
 187 tcInstSkolType info ty = tcInstType (tcInstSkolTyVars info) ty
 188 \end{code}
 189
 190
 191 %************************************************************************
 192 %*                                                                      *
 193         MetaTvs (meta type variables; mutable)
 194 %*                                                                      *
 195 %************************************************************************
 196
 197 \begin{code}
 198 newMetaTyVar :: BoxInfo -> Kind -> TcM TcTyVar
 199 -- Make a new meta tyvar out of thin air
 200 newMetaTyVar box_info kind
 201   = do  { uniq <- newUnique
 202         ; ref <- newMutVar Flexi ;
 203         ; let name = mkSysTvName uniq fs
 204               fs = case box_info of
 205                         BoxTv   -> FSLIT("t")
 206                         TauTv   -> FSLIT("t")
 207                         SigTv _ -> FSLIT("a")
 208                 -- We give BoxTv and TauTv the same string, because
 209                 -- otherwise we get user-visible differences in error
 210                 -- messages, which are confusing.  If you want to see
 211                 -- the box_info of each tyvar, use -dppr-debug
 212         ; return (mkTcTyVar name kind (MetaTv box_info ref)) }
 213
 214 instMetaTyVar :: BoxInfo -> TyVar -> TcM TcTyVar
 215 -- Make a new meta tyvar whose Name and Kind
 216 -- come from an existing TyVar
 217 instMetaTyVar box_info tyvar
 218   = do  { uniq <- newUnique
 219         ; ref <- newMutVar Flexi ;
 220         ; let name = setNameUnique (tyVarName tyvar) uniq
 221               kind = tyVarKind tyvar
 222         ; return (mkTcTyVar name kind (MetaTv box_info ref)) }
 223
 224 readMetaTyVar :: TyVar -> TcM MetaDetails
 225 readMetaTyVar tyvar = ASSERT2( isMetaTyVar tyvar, ppr tyvar )
 226                       readMutVar (metaTvRef tyvar)
 227
 228 writeMetaTyVar :: TcTyVar -> TcType -> TcM ()
 229 #ifndef DEBUG
 230 writeMetaTyVar tyvar ty = writeMutVar (metaTvRef tyvar) (Indirect ty)
 231 #else
 232 writeMetaTyVar tyvar ty
 233   | not (isMetaTyVar tyvar)
 234   = pprTrace "writeMetaTyVar" (ppr tyvar) $
 235     returnM ()
 236
 237   | otherwise
 238   = ASSERT( isMetaTyVar tyvar )
 239     ASSERT2( k2 `isSubKind` k1, (ppr tyvar <+> ppr k1) $$ (ppr ty <+> ppr k2) )
 240     do  { ASSERTM2( do { details <- readMetaTyVar tyvar; return (isFlexi details) }, ppr tyvar )
 241         ; writeMutVar (metaTvRef tyvar) (Indirect ty) }
 242   where
 243     k1 = tyVarKind tyvar
 244     k2 = typeKind ty
 245 #endif
 246 \end{code}
 247
 248
 249 %************************************************************************
 250 %*                                                                      *
 251         MetaTvs: TauTvs
 252 %*                                                                      *
 253 %************************************************************************
 254
 255 \begin{code}
 256 newFlexiTyVar :: Kind -> TcM TcTyVar
 257 newFlexiTyVar kind = newMetaTyVar TauTv kind
 258
 259 newFlexiTyVarTy  :: Kind -> TcM TcType
 260 newFlexiTyVarTy kind
 261   = newFlexiTyVar kind  `thenM` \ tc_tyvar ->
 262     returnM (TyVarTy tc_tyvar)
 263
 264 newFlexiTyVarTys :: Int -> Kind -> TcM [TcType]
 265 newFlexiTyVarTys n kind = mappM newFlexiTyVarTy (nOfThem n kind)
 266
 267 tcInstTyVar :: TyVar -> TcM TcTyVar
 268 -- Instantiate with a META type variable
 269 tcInstTyVar tyvar = instMetaTyVar TauTv tyvar
 270
 271 tcInstTyVars :: [TyVar] -> TcM ([TcTyVar], [TcType], TvSubst)
 272 -- Instantiate with META type variables
 273 tcInstTyVars tyvars
 274   = do  { tc_tvs <- mapM tcInstTyVar tyvars
 275         ; let tys = mkTyVarTys tc_tvs
 276         ; returnM (tc_tvs, tys, zipTopTvSubst tyvars tys) }
 277                 -- Since the tyvars are freshly made,
 278                 -- they cannot possibly be captured by
 279                 -- any existing for-alls.  Hence zipTopTvSubst
 280 \end{code}
 281
 282
 283 %************************************************************************
 284 %*                                                                      *
 285         MetaTvs: SigTvs
 286 %*                                                                      *
 287 %************************************************************************
 288
 289 \begin{code}
 290 tcInstSigTyVars :: Bool -> SkolemInfo -> [TyVar] -> TcM [TcTyVar]
 291 -- Instantiate with skolems or meta SigTvs; depending on use_skols
 292 -- Always take location info from the supplied tyvars
 293 tcInstSigTyVars use_skols skol_info tyvars
 294   | use_skols
 295   = mapM (tcInstSkolTyVar skol_info Nothing) tyvars
 296
 297   | otherwise
 298   = mapM (instMetaTyVar (SigTv skol_info)) tyvars
 299
 300 zonkSigTyVar :: TcTyVar -> TcM TcTyVar
 301 zonkSigTyVar sig_tv
 302   | isSkolemTyVar sig_tv
 303   = return sig_tv       -- Happens in the call in TcBinds.checkDistinctTyVars
 304   | otherwise
 305   = ASSERT( isSigTyVar sig_tv )
 306     do { ty <- zonkTcTyVar sig_tv
 307        ; return (tcGetTyVar "zonkSigTyVar" ty) }
 308         -- 'ty' is bound to be a type variable, because SigTvs
 309         -- can only be unified with type variables
 310 \end{code}
 311
 312
 313 %************************************************************************
 314 %*                                                                      *
 315         MetaTvs: BoxTvs
 316 %*                                                                      *
 317 %************************************************************************
 318
 319 \begin{code}
 320 newBoxyTyVar :: Kind -> TcM BoxyTyVar
 321 newBoxyTyVar kind = newMetaTyVar BoxTv kind
 322
 323 newBoxyTyVars :: [Kind] -> TcM [BoxyTyVar]
 324 newBoxyTyVars kinds = mapM newBoxyTyVar kinds
 325
 326 newBoxyTyVarTys :: [Kind] -> TcM [BoxyType]
 327 newBoxyTyVarTys kinds = do { tvs <- mapM newBoxyTyVar kinds; return (mkTyVarTys tvs) }
 328
 329 readFilledBox :: BoxyTyVar -> TcM TcType
 330 -- Read the contents of the box, which should be filled in by now
 331 readFilledBox box_tv = ASSERT( isBoxyTyVar box_tv )
 332                        do { cts <- readMetaTyVar box_tv
 333                           ; case cts of
 334                                 Flexi       -> pprPanic "readFilledBox" (ppr box_tv)
 335                                 Indirect ty -> return ty }
 336
 337 tcInstBoxyTyVar :: TyVar -> TcM BoxyTyVar
 338 -- Instantiate with a BOXY type variable
 339 tcInstBoxyTyVar tyvar = instMetaTyVar BoxTv tyvar
 340 \end{code}
 341
 342
 343 %************************************************************************
 344 %*                                                                      *
 345 \subsection{Putting and getting  mutable type variables}
 346 %*                                                                      *
 347 %************************************************************************
 348
 349 But it's more fun to short out indirections on the way: If this
 350 version returns a TyVar, then that TyVar is unbound.  If it returns
 351 any other type, then there might be bound TyVars embedded inside it.
 352
 353 We return Nothing iff the original box was unbound.
 354
 355 \begin{code}
 356 data LookupTyVarResult  -- The result of a lookupTcTyVar call
 357   = DoneTv TcTyVarDetails       -- SkolemTv or virgin MetaTv
 358   | IndirectTv TcType
 359
 360 lookupTcTyVar :: TcTyVar -> TcM LookupTyVarResult
 361 lookupTcTyVar tyvar
 362   = ASSERT2( isTcTyVar tyvar, ppr tyvar )
 363     case details of
 364       SkolemTv _   -> return (DoneTv details)
 365       MetaTv _ ref -> do { meta_details <- readMutVar ref
 366                          ; case meta_details of
 367                             Indirect ty -> return (IndirectTv ty)
 368                             Flexi       -> return (DoneTv details) }
 369   where
 370     details =  tcTyVarDetails tyvar
 371
 372 {-
 373 -- gaw 2004 We aren't shorting anything out anymore, at least for now
 374 getTcTyVar tyvar
 375   | not (isTcTyVar tyvar)
 376   = pprTrace "getTcTyVar" (ppr tyvar) $
 377     returnM (Just (mkTyVarTy tyvar))
 378
 379   | otherwise
 380   = ASSERT2( isTcTyVar tyvar, ppr tyvar )
 381     readMetaTyVar tyvar                         `thenM` \ maybe_ty ->
 382     case maybe_ty of
 383         Just ty -> short_out ty                         `thenM` \ ty' ->
 384                    writeMetaTyVar tyvar (Just ty')      `thenM_`
 385                    returnM (Just ty')
 386
 387         Nothing    -> returnM Nothing
 388
 389 short_out :: TcType -> TcM TcType
 390 short_out ty@(TyVarTy tyvar)
 391   | not (isTcTyVar tyvar)
 392   = returnM ty
 393
 394   | otherwise
 395   = readMetaTyVar tyvar `thenM` \ maybe_ty ->
 396     case maybe_ty of
 397         Just ty' -> short_out ty'                       `thenM` \ ty' ->
 398                     writeMetaTyVar tyvar (Just ty')     `thenM_`
 399                     returnM ty'
 400
 401         other    -> returnM ty
 402
 403 short_out other_ty = returnM other_ty
 404 -}
 405 \end{code}
 406
 407
 408 %************************************************************************
 409 %*                                                                      *
 410 \subsection{Zonking -- the exernal interfaces}
 411 %*                                                                      *
 412 %************************************************************************
 413
 414 -----------------  Type variables
 415
 416 \begin{code}
 417 zonkTcTyVars :: [TcTyVar] -> TcM [TcType]
 418 zonkTcTyVars tyvars = mappM zonkTcTyVar tyvars
 419
 420 zonkTcTyVarsAndFV :: [TcTyVar] -> TcM TcTyVarSet
 421 zonkTcTyVarsAndFV tyvars = mappM zonkTcTyVar tyvars     `thenM` \ tys ->
 422                            returnM (tyVarsOfTypes tys)
 423
 424 zonkTcTyVar :: TcTyVar -> TcM TcType
 425 zonkTcTyVar tyvar = ASSERT2( isTcTyVar tyvar, ppr tyvar)
 426                     zonk_tc_tyvar (\ tv -> returnM (TyVarTy tv)) tyvar
 427 \end{code}
 428
 429 -----------------  Types
 430
 431 \begin{code}
 432 zonkTcType :: TcType -> TcM TcType
 433 zonkTcType ty = zonkType (\ tv -> returnM (TyVarTy tv)) ty
 434
 435 zonkTcTypes :: [TcType] -> TcM [TcType]
 436 zonkTcTypes tys = mappM zonkTcType tys
 437
 438 zonkTcClassConstraints cts = mappM zonk cts
 439     where zonk (clas, tys)
 440             = zonkTcTypes tys   `thenM` \ new_tys ->
 441               returnM (clas, new_tys)
 442
 443 zonkTcThetaType :: TcThetaType -> TcM TcThetaType
 444 zonkTcThetaType theta = mappM zonkTcPredType theta
 445
 446 zonkTcPredType :: TcPredType -> TcM TcPredType
 447 zonkTcPredType (ClassP c ts)
 448   = zonkTcTypes ts      `thenM` \ new_ts ->
 449     returnM (ClassP c new_ts)
 450 zonkTcPredType (IParam n t)
 451   = zonkTcType t        `thenM` \ new_t ->
 452     returnM (IParam n new_t)
 453 zonkTcPredType (EqPred t1 t2)
 454   = zonkTcType t1       `thenM` \ new_t1 ->
 455     zonkTcType t2       `thenM` \ new_t2 ->
 456     returnM (EqPred new_t1 new_t2)
 457 \end{code}
 458
 459 -------------------  These ...ToType, ...ToKind versions
 460                      are used at the end of type checking
 461
 462 \begin{code}
 463 zonkTopTyVar :: TcTyVar -> TcM TcTyVar
 464 -- zonkTopTyVar is used, at the top level, on any un-instantiated meta type variables
 465 -- to default the kind of ? and ?? etc to *.  This is important to ensure that
 466 -- instance declarations match.  For example consider
 467 --      instance Show (a->b)
 468 --      foo x = show (\_ -> True)
 469 -- Then we'll get a constraint (Show (p ->q)) where p has argTypeKind (printed ??),
 470 -- and that won't match the typeKind (*) in the instance decl.
 471 --
 472 -- Because we are at top level, no further constraints are going to affect these
 473 -- type variables, so it's time to do it by hand.  However we aren't ready
 474 -- to default them fully to () or whatever, because the type-class defaulting
 475 -- rules have yet to run.
 476
 477 zonkTopTyVar tv
 478   | k `eqKind` default_k = return tv
 479   | otherwise
 480   = do  { tv' <- newFlexiTyVar default_k
 481         ; writeMetaTyVar tv (mkTyVarTy tv')
 482         ; return tv' }
 483   where
 484     k = tyVarKind tv
 485     default_k = defaultKind k
 486
 487 zonkQuantifiedTyVars :: [TcTyVar] -> TcM [TyVar]
 488 zonkQuantifiedTyVars = mappM zonkQuantifiedTyVar
 489
 490 zonkQuantifiedTyVar :: TcTyVar -> TcM TyVar
 491 -- zonkQuantifiedTyVar is applied to the a TcTyVar when quantifying over it.
 492 --
 493 -- The quantified type variables often include meta type variables
 494 -- we want to freeze them into ordinary type variables, and
 495 -- default their kind (e.g. from OpenTypeKind to TypeKind)
 496 --                      -- see notes with Kind.defaultKind
 497 -- The meta tyvar is updated to point to the new regular TyVar.  Now any
 498 -- bound occurences of the original type variable will get zonked to
 499 -- the immutable version.
 500 --
 501 -- We leave skolem TyVars alone; they are immutable.
 502 zonkQuantifiedTyVar tv
 503   | ASSERT( isTcTyVar tv )
 504     isSkolemTyVar tv = return tv
 505         -- It might be a skolem type variable,
 506         -- for example from a user type signature
 507
 508   | otherwise   -- It's a meta-type-variable
 509   = do  { details <- readMetaTyVar tv
 510
 511         -- Create the new, frozen, regular type variable
 512         ; let final_kind = defaultKind (tyVarKind tv)
 513               final_tv   = mkTyVar (tyVarName tv) final_kind
 514
 515         -- Bind the meta tyvar to the new tyvar
 516         ; case details of
 517             Indirect ty -> WARN( True, ppr tv $$ ppr ty )
 518                            return ()
 519                 -- [Sept 04] I don't think this should happen
 520                 -- See note [Silly Type Synonym]
 521
 522             Flexi -> writeMetaTyVar tv (mkTyVarTy final_tv)
 523
 524         -- Return the new tyvar
 525         ; return final_tv }
 526 \end{code}
 527
 528 [Silly Type Synonyms]
 529
 530 Consider this:
 531         type C u a = u  -- Note 'a' unused
 532
 533         foo :: (forall a. C u a -> C u a) -> u
 534         foo x = ...
 535
 536         bar :: Num u => u
 537         bar = foo (\t -> t + t)
 538
 539 * From the (\t -> t+t) we get type  {Num d} =>  d -> d
 540   where d is fresh.
 541
 542 * Now unify with type of foo's arg, and we get:
 543         {Num (C d a)} =>  C d a -> C d a
 544   where a is fresh.
 545
 546 * Now abstract over the 'a', but float out the Num (C d a) constraint
 547   because it does not 'really' mention a.  (see exactTyVarsOfType)
 548   The arg to foo becomes
 549         /\a -> \t -> t+t
 550
 551 * So we get a dict binding for Num (C d a), which is zonked to give
 552         a = ()
 553   [Note Sept 04: now that we are zonking quantified type variables
 554   on construction, the 'a' will be frozen as a regular tyvar on
 555   quantification, so the floated dict will still have type (C d a).
 556   Which renders this whole note moot; happily!]
 557
 558 * Then the /\a abstraction has a zonked 'a' in it.
 559
 560 All very silly.   I think its harmless to ignore the problem.  We'll end up with
 561 a /\a in the final result but all the occurrences of a will be zonked to ()
 562
 563
 564 %************************************************************************
 565 %*                                                                      *
 566 \subsection{Zonking -- the main work-horses: zonkType, zonkTyVar}
 567 %*                                                                      *
 568 %*              For internal use only!                                  *
 569 %*                                                                      *
 570 %************************************************************************
 571
 572 \begin{code}
 573 -- For unbound, mutable tyvars, zonkType uses the function given to it
 574 -- For tyvars bound at a for-all, zonkType zonks them to an immutable
 575 --      type variable and zonks the kind too
 576
 577 zonkType :: (TcTyVar -> TcM Type)       -- What to do with unbound mutable type variables
 578                                         -- see zonkTcType, and zonkTcTypeToType
 579          -> TcType
 580          -> TcM Type
 581 zonkType unbound_var_fn ty
 582   = go ty
 583   where
 584     go (NoteTy _ ty2)    = go ty2       -- Discard free-tyvar annotations
 585
 586     go (TyConApp tc tys) = mappM go tys `thenM` \ tys' ->
 587                            returnM (TyConApp tc tys')
 588
 589     go (PredTy p)        = go_pred p            `thenM` \ p' ->
 590                            returnM (PredTy p')
 591
 592     go (FunTy arg res)   = go arg               `thenM` \ arg' ->
 593                            go res               `thenM` \ res' ->
 594                            returnM (FunTy arg' res')
 595
 596     go (AppTy fun arg)   = go fun               `thenM` \ fun' ->
 597                            go arg               `thenM` \ arg' ->
 598                            returnM (mkAppTy fun' arg')
 599                 -- NB the mkAppTy; we might have instantiated a
 600                 -- type variable to a type constructor, so we need
 601                 -- to pull the TyConApp to the top.
 602
 603         -- The two interesting cases!
 604     go (TyVarTy tyvar) | isTcTyVar tyvar = zonk_tc_tyvar unbound_var_fn tyvar
 605                        | otherwise       = return (TyVarTy tyvar)
 606                 -- Ordinary (non Tc) tyvars occur inside quantified types
 607
 608     go (ForAllTy tyvar ty) = ASSERT( isImmutableTyVar tyvar )
 609                              go ty              `thenM` \ ty' ->
 610                              returnM (ForAllTy tyvar ty')
 611
 612     go_pred (ClassP c tys)   = mappM go tys     `thenM` \ tys' ->
 613                                returnM (ClassP c tys')
 614     go_pred (IParam n ty)    = go ty            `thenM` \ ty' ->
 615                                returnM (IParam n ty')
 616     go_pred (EqPred ty1 ty2) = go ty1           `thenM` \ ty1' ->
 617                                go ty2           `thenM` \ ty2' ->
 618                                returnM (EqPred ty1' ty2')
 619
 620 zonk_tc_tyvar :: (TcTyVar -> TcM Type)          -- What to do for an unbound mutable variable
 621               -> TcTyVar -> TcM TcType
 622 zonk_tc_tyvar unbound_var_fn tyvar
 623   | not (isMetaTyVar tyvar)     -- Skolems
 624   = returnM (TyVarTy tyvar)
 625
 626   | otherwise                   -- Mutables
 627   = do  { cts <- readMetaTyVar tyvar
 628         ; case cts of
 629             Flexi       -> unbound_var_fn tyvar    -- Unbound meta type variable
 630             Indirect ty -> zonkType unbound_var_fn ty  }
 631 \end{code}
 632
 633
 634
 635 %************************************************************************
 636 %*                                                                      *
 637                         Zonking kinds
 638 %*                                                                      *
 639 %************************************************************************
 640
 641 \begin{code}
 642 readKindVar  :: KindVar -> TcM (MetaDetails)
 643 writeKindVar :: KindVar -> TcKind -> TcM ()
 644 readKindVar  kv = readMutVar (kindVarRef kv)
 645 writeKindVar kv val = writeMutVar (kindVarRef kv) (Indirect val)
 646
 647 -------------
 648 zonkTcKind :: TcKind -> TcM TcKind
 649 zonkTcKind k = zonkTcType k
 650
 651 -------------
 652 zonkTcKindToKind :: TcKind -> TcM Kind
 653 -- When zonking a TcKind to a kind, we need to instantiate kind variables,
 654 -- Haskell specifies that * is to be used, so we follow that.
 655 zonkTcKindToKind k = zonkType (\ _ -> return liftedTypeKind) k
 656 \end{code}
 657
 658 %************************************************************************
 659 %*                                                                      *
 660 \subsection{Checking a user type}
 661 %*                                                                      *
 662 %************************************************************************
 663
 664 When dealing with a user-written type, we first translate it from an HsType
 665 to a Type, performing kind checking, and then check various things that should
 666 be true about it.  We don't want to perform these checks at the same time
 667 as the initial translation because (a) they are unnecessary for interface-file
 668 types and (b) when checking a mutually recursive group of type and class decls,
 669 we can't "look" at the tycons/classes yet.  Also, the checks are are rather
 670 diverse, and used to really mess up the other code.
 671
 672 One thing we check for is 'rank'.
 673
 674         Rank 0:         monotypes (no foralls)
 675         Rank 1:         foralls at the front only, Rank 0 inside
 676         Rank 2:         foralls at the front, Rank 1 on left of fn arrow,
 677
 678         basic ::= tyvar | T basic ... basic
 679
 680         r2  ::= forall tvs. cxt => r2a
 681         r2a ::= r1 -> r2a | basic
 682         r1  ::= forall tvs. cxt => r0
 683         r0  ::= r0 -> r0 | basic
 684
 685 Another thing is to check that type synonyms are saturated.
 686 This might not necessarily show up in kind checking.
 687         type A i = i
 688         data T k = MkT (k Int)
 689         f :: T A        -- BAD!
 690
 691
 692 \begin{code}
 693 checkValidType :: UserTypeCtxt -> Type -> TcM ()
 694 -- Checks that the type is valid for the given context
 695 checkValidType ctxt ty
 696   = traceTc (text "checkValidType" <+> ppr ty)  `thenM_`
 697     doptM Opt_ExpressionSignaturesUnboxedTuples `thenM` \ exp_sigs_unboxed ->
 698     doptM Opt_TypeSynonymUnboxedTuples `thenM` \ type_synonym_unboxed ->
 699     doptM Opt_Rank2Types        `thenM` \ rank2 ->
 700     doptM Opt_RankNTypes        `thenM` \ rankn ->
 701     doptM Opt_PolymorphicComponents     `thenM` \ polycomp ->
 702     let
 703         rank | rankn = Arbitrary
 704              | rank2 = Rank 2
 705              | otherwise
 706              = case ctxt of     -- Haskell 98
 707                  GenPatCtxt     -> Rank 0
 708                  LamPatSigCtxt  -> Rank 0
 709                  BindPatSigCtxt -> Rank 0
 710                  DefaultDeclCtxt-> Rank 0
 711                  ResSigCtxt     -> Rank 0
 712                  TySynCtxt _    -> Rank 0
 713                  ExprSigCtxt    -> Rank 1
 714                  FunSigCtxt _   -> Rank 1
 715                  ConArgCtxt _   -> if polycomp
 716                            then Rank 2
 717                                 -- We are given the type of the entire
 718                                 -- constructor, hence rank 1
 719                            else Rank 1
 720                  ForSigCtxt _   -> Rank 1
 721                  SpecInstCtxt   -> Rank 1
 722
 723         actual_kind = typeKind ty
 724
 725         kind_ok = case ctxt of
 726                         TySynCtxt _  -> True    -- Any kind will do
 727                         ResSigCtxt   -> isSubOpenTypeKind        actual_kind
 728                         ExprSigCtxt  -> isSubOpenTypeKind        actual_kind
 729                         GenPatCtxt   -> isLiftedTypeKind actual_kind
 730                         ForSigCtxt _ -> isLiftedTypeKind actual_kind
 731                         other        -> isSubArgTypeKind    actual_kind
 732
 733         ubx_tup = case ctxt of
 734                       TySynCtxt _ | type_synonym_unboxed -> UT_Ok
 735                       ExprSigCtxt | exp_sigs_unboxed     -> UT_Ok
 736                       _                                  -> UT_NotOk
 737     in
 738         -- Check that the thing has kind Type, and is lifted if necessary
 739     checkTc kind_ok (kindErr actual_kind)       `thenM_`
 740
 741         -- Check the internal validity of the type itself
 742     check_poly_type rank ubx_tup ty             `thenM_`
 743
 744     traceTc (text "checkValidType done" <+> ppr ty)
 745 \end{code}
 746
 747
 748 \begin{code}
 749 data Rank = Rank Int | Arbitrary
 750
 751 decRank :: Rank -> Rank
 752 decRank Arbitrary = Arbitrary
 753 decRank (Rank n)  = Rank (n-1)
 754
 755 ----------------------------------------
 756 data UbxTupFlag = UT_Ok | UT_NotOk
 757         -- The "Ok" version means "ok if -fglasgow-exts is on"
 758
 759 ----------------------------------------
 760 check_poly_type :: Rank -> UbxTupFlag -> Type -> TcM ()
 761 check_poly_type (Rank 0) ubx_tup ty
 762   = check_tau_type (Rank 0) ubx_tup ty
 763
 764 check_poly_type rank ubx_tup ty
 765   | null tvs && null theta
 766   = check_tau_type rank ubx_tup ty
 767   | otherwise
 768   = do  { check_valid_theta SigmaCtxt theta
 769         ; check_poly_type rank ubx_tup tau      -- Allow foralls to right of arrow
 770         ; checkFreeness tvs theta
 771         ; checkAmbiguity tvs theta (tyVarsOfType tau) }
 772   where
 773     (tvs, theta, tau) = tcSplitSigmaTy ty
 774
 775 ----------------------------------------
 776 check_arg_type :: Type -> TcM ()
 777 -- The sort of type that can instantiate a type variable,
 778 -- or be the argument of a type constructor.
 779 -- Not an unboxed tuple, but now *can* be a forall (since impredicativity)
 780 -- Other unboxed types are very occasionally allowed as type
 781 -- arguments depending on the kind of the type constructor
 782 --
 783 -- For example, we want to reject things like:
 784 --
 785 --      instance Ord a => Ord (forall s. T s a)
 786 -- and
 787 --      g :: T s (forall b.b)
 788 --
 789 -- NB: unboxed tuples can have polymorphic or unboxed args.
 790 --     This happens in the workers for functions returning
 791 --     product types with polymorphic components.
 792 --     But not in user code.
 793 -- Anyway, they are dealt with by a special case in check_tau_type
 794
 795 check_arg_type ty
 796   = check_poly_type Arbitrary UT_NotOk ty       `thenM_`
 797     checkTc (not (isUnLiftedType ty)) (unliftedArgErr ty)
 798
 799 ----------------------------------------
 800 check_tau_type :: Rank -> UbxTupFlag -> Type -> TcM ()
 801 -- Rank is allowed rank for function args
 802 -- No foralls otherwise
 803
 804 check_tau_type rank ubx_tup ty@(ForAllTy _ _)       = failWithTc (forAllTyErr ty)
 805 check_tau_type rank ubx_tup ty@(FunTy (PredTy _) _) = failWithTc (forAllTyErr ty)
 806         -- Reject e.g. (Maybe (?x::Int => Int)), with a decent error message
 807
 808 -- Naked PredTys don't usually show up, but they can as a result of
 809 --      {-# SPECIALISE instance Ord Char #-}
 810 -- The Right Thing would be to fix the way that SPECIALISE instance pragmas
 811 -- are handled, but the quick thing is just to permit PredTys here.
 812 check_tau_type rank ubx_tup (PredTy sty) = getDOpts             `thenM` \ dflags ->
 813                                            check_pred_ty dflags TypeCtxt sty
 814
 815 check_tau_type rank ubx_tup (TyVarTy _)       = returnM ()
 816 check_tau_type rank ubx_tup ty@(FunTy arg_ty res_ty)
 817   = check_poly_type (decRank rank) UT_NotOk arg_ty      `thenM_`
 818     check_poly_type rank           UT_Ok    res_ty
 819
 820 check_tau_type rank ubx_tup (AppTy ty1 ty2)
 821   = check_arg_type ty1 `thenM_` check_arg_type ty2
 822
 823 check_tau_type rank ubx_tup (NoteTy other_note ty)
 824   = check_tau_type rank ubx_tup ty
 825
 826 check_tau_type rank ubx_tup ty@(TyConApp tc tys)
 827   | isSynTyCon tc
 828   = do  {       -- It's OK to have an *over-applied* type synonym
 829                 --      data Tree a b = ...
 830                 --      type Foo a = Tree [a]
 831                 --      f :: Foo a b -> ...
 832         ; case tcView ty of
 833              Just ty' -> check_tau_type rank ubx_tup ty' -- Check expansion
 834              Nothing -> unless (isOpenTyCon tc           -- No expansion if open
 835                                 && tyConArity tc <= length tys) $
 836                           failWithTc arity_msg
 837
 838         ; ok <- doptM Opt_PartiallyAppliedClosedTypeSynonyms
 839         ; if ok && not (isOpenTyCon tc) then
 840         -- Don't check the type arguments of *closed* synonyms.
 841         -- This allows us to instantiate a synonym defn with a
 842         -- for-all type, or with a partially-applied type synonym.
 843         --      e.g.   type T a b = a
 844         --             type S m   = m ()
 845         --             f :: S (T Int)
 846         -- Here, T is partially applied, so it's illegal in H98.
 847         -- But if you expand S first, then T we get just
 848         --             f :: Int
 849         -- which is fine.
 850                 returnM ()
 851           else
 852                 -- For H98, do check the type args
 853                 mappM_ check_arg_type tys
 854         }
 855
 856   | isUnboxedTupleTyCon tc
 857   = doptM Opt_UnboxedTuples `thenM` \ ub_tuples_allowed ->
 858     checkTc (ubx_tup_ok ub_tuples_allowed) ubx_tup_msg  `thenM_`
 859     mappM_ (check_tau_type (Rank 0) UT_Ok) tys
 860                 -- Args are allowed to be unlifted, or
 861                 -- more unboxed tuples, so can't use check_arg_ty
 862
 863   | otherwise
 864   = mappM_ check_arg_type tys
 865
 866   where
 867     ubx_tup_ok ub_tuples_allowed = case ubx_tup of { UT_Ok -> ub_tuples_allowed; other -> False }
 868
 869     n_args    = length tys
 870     tc_arity  = tyConArity tc
 871
 872     arity_msg   = arityErr "Type synonym" (tyConName tc) tc_arity n_args
 873     ubx_tup_msg = ubxArgTyErr ty
 874
 875 ----------------------------------------
 876 forAllTyErr     ty = ptext SLIT("Illegal polymorphic or qualified type:") <+> ppr ty
 877 unliftedArgErr  ty = ptext SLIT("Illegal unlifted type argument:") <+> ppr ty
 878 ubxArgTyErr     ty = ptext SLIT("Illegal unboxed tuple type as function argument:") <+> ppr ty
 879 kindErr kind       = ptext SLIT("Expecting an ordinary type, but found a type of kind") <+> ppr kind
 880 \end{code}
 881
 882
 883
 884 %************************************************************************
 885 %*                                                                      *
 886 \subsection{Checking a theta or source type}
 887 %*                                                                      *
 888 %************************************************************************
 889
 890 \begin{code}
 891 -- Enumerate the contexts in which a "source type", <S>, can occur
 892 --      Eq a
 893 -- or   ?x::Int
 894 -- or   r <: {x::Int}
 895 -- or   (N a) where N is a newtype
 896
 897 data SourceTyCtxt
 898   = ClassSCCtxt Name    -- Superclasses of clas
 899                         --      class <S> => C a where ...
 900   | SigmaCtxt           -- Theta part of a normal for-all type
 901                         --      f :: <S> => a -> a
 902   | DataTyCtxt Name     -- Theta part of a data decl
 903                         --      data <S> => T a = MkT a
 904   | TypeCtxt            -- Source type in an ordinary type
 905                         --      f :: N a -> N a
 906   | InstThetaCtxt       -- Context of an instance decl
 907                         --      instance <S> => C [a] where ...
 908
 909 pprSourceTyCtxt (ClassSCCtxt c) = ptext SLIT("the super-classes of class") <+> quotes (ppr c)
 910 pprSourceTyCtxt SigmaCtxt       = ptext SLIT("the context of a polymorphic type")
 911 pprSourceTyCtxt (DataTyCtxt tc) = ptext SLIT("the context of the data type declaration for") <+> quotes (ppr tc)
 912 pprSourceTyCtxt InstThetaCtxt   = ptext SLIT("the context of an instance declaration")
 913 pprSourceTyCtxt TypeCtxt        = ptext SLIT("the context of a type")
 914 \end{code}
 915
 916 \begin{code}
 917 checkValidTheta :: SourceTyCtxt -> ThetaType -> TcM ()
 918 checkValidTheta ctxt theta
 919   = addErrCtxt (checkThetaCtxt ctxt theta) (check_valid_theta ctxt theta)
 920
 921 -------------------------
 922 check_valid_theta ctxt []
 923   = returnM ()
 924 check_valid_theta ctxt theta
 925   = getDOpts                                    `thenM` \ dflags ->
 926     warnTc (notNull dups) (dupPredWarn dups)    `thenM_`
 927     mappM_ (check_pred_ty dflags ctxt) theta
 928   where
 929     (_,dups) = removeDups tcCmpPred theta
 930
 931 -------------------------
 932 check_pred_ty dflags ctxt pred@(ClassP cls tys)
 933   = do {        -- Class predicates are valid in all contexts
 934        ; checkTc (arity == n_tys) arity_err
 935
 936                 -- Check the form of the argument types
 937        ; mappM_ check_arg_type tys
 938        ; checkTc (check_class_pred_tys dflags ctxt tys)
 939                  (predTyVarErr pred $$ how_to_allow)
 940        }
 941   where
 942     class_name = className cls
 943     arity      = classArity cls
 944     n_tys      = length tys
 945     arity_err  = arityErr "Class" class_name arity n_tys
 946     how_to_allow = parens (ptext SLIT("Use -XFlexibleContexts to permit this"))
 947
 948 check_pred_ty dflags ctxt pred@(EqPred ty1 ty2)
 949   = do {        -- Equational constraints are valid in all contexts if type
 950                 -- families are permitted
 951        ; checkTc (dopt Opt_TypeFamilies dflags) (eqPredTyErr pred)
 952
 953                 -- Check the form of the argument types
 954        ; check_eq_arg_type ty1
 955        ; check_eq_arg_type ty2
 956        }
 957   where
 958     check_eq_arg_type = check_poly_type (Rank 0) UT_NotOk
 959
 960 check_pred_ty dflags SigmaCtxt (IParam _ ty) = check_arg_type ty
 961         -- Implicit parameters only allowed in type
 962         -- signatures; not in instance decls, superclasses etc
 963         -- The reason for not allowing implicit params in instances is a bit
 964         -- subtle.
 965         -- If we allowed        instance (?x::Int, Eq a) => Foo [a] where ...
 966         -- then when we saw (e :: (?x::Int) => t) it would be unclear how to
 967         -- discharge all the potential usas of the ?x in e.   For example, a
 968         -- constraint Foo [Int] might come out of e,and applying the
 969         -- instance decl would show up two uses of ?x.
 970
 971 -- Catch-all
 972 check_pred_ty dflags ctxt sty = failWithTc (badPredTyErr sty)
 973
 974 -------------------------
 975 check_class_pred_tys dflags ctxt tys
 976   = case ctxt of
 977         TypeCtxt      -> True   -- {-# SPECIALISE instance Eq (T Int) #-} is fine
 978         InstThetaCtxt -> flexible_contexts || undecidable_ok || all tcIsTyVarTy tys
 979                                 -- Further checks on head and theta in
 980                                 -- checkInstTermination
 981         other         -> flexible_contexts || all tyvar_head tys
 982   where
 983     flexible_contexts = dopt Opt_FlexibleContexts dflags
 984     undecidable_ok = dopt Opt_AllowUndecidableInstances dflags
 985
 986 -------------------------
 987 tyvar_head ty                   -- Haskell 98 allows predicates of form
 988   | tcIsTyVarTy ty = True       --      C (a ty1 .. tyn)
 989   | otherwise                   -- where a is a type variable
 990   = case tcSplitAppTy_maybe ty of
 991         Just (ty, _) -> tyvar_head ty
 992         Nothing      -> False
 993 \end{code}
 994
 995 Check for ambiguity
 996 ~~~~~~~~~~~~~~~~~~~
 997           forall V. P => tau
 998 is ambiguous if P contains generic variables
 999 (i.e. one of the Vs) that are not mentioned in tau
1000
1001 However, we need to take account of functional dependencies
1002 when we speak of 'mentioned in tau'.  Example:
1003         class C a b | a -> b where ...
1004 Then the type
1005         forall x y. (C x y) => x
1006 is not ambiguous because x is mentioned and x determines y
1007
1008 NB; the ambiguity check is only used for *user* types, not for types
1009 coming from inteface files.  The latter can legitimately have
1010 ambiguous types. Example
1011
1012    class S a where s :: a -> (Int,Int)
1013    instance S Char where s _ = (1,1)
1014    f:: S a => [a] -> Int -> (Int,Int)
1015    f (_::[a]) x = (a*x,b)
1016         where (a,b) = s (undefined::a)
1017
1018 Here the worker for f gets the type
1019         fw :: forall a. S a => Int -> (# Int, Int #)
1020
1021 If the list of tv_names is empty, we have a monotype, and then we
1022 don't need to check for ambiguity either, because the test can't fail
1023 (see is_ambig).
1024
1025 \begin{code}
1026 checkAmbiguity :: [TyVar] -> ThetaType -> TyVarSet -> TcM ()
1027 checkAmbiguity forall_tyvars theta tau_tyvars
1028   = mappM_ complain (filter is_ambig theta)
1029   where
1030     complain pred     = addErrTc (ambigErr pred)
1031     extended_tau_vars = grow theta tau_tyvars
1032
1033         -- Only a *class* predicate can give rise to ambiguity
1034         -- An *implicit parameter* cannot.  For example:
1035         --      foo :: (?x :: [a]) => Int
1036         --      foo = length ?x
1037         -- is fine.  The call site will suppply a particular 'x'
1038     is_ambig pred     = isClassPred  pred &&
1039                         any ambig_var (varSetElems (tyVarsOfPred pred))
1040
1041     ambig_var ct_var  = (ct_var `elem` forall_tyvars) &&
1042                         not (ct_var `elemVarSet` extended_tau_vars)
1043
1044 ambigErr pred
1045   = sep [ptext SLIT("Ambiguous constraint") <+> quotes (pprPred pred),
1046          nest 4 (ptext SLIT("At least one of the forall'd type variables mentioned by the constraint") $$
1047                  ptext SLIT("must be reachable from the type after the '=>'"))]
1048 \end{code}
1049
1050 In addition, GHC insists that at least one type variable
1051 in each constraint is in V.  So we disallow a type like
1052         forall a. Eq b => b -> b
1053 even in a scope where b is in scope.
1054
1055 \begin{code}
1056 checkFreeness forall_tyvars theta
1057   = do  { flexible_contexts <- doptM Opt_FlexibleContexts
1058         ; unless flexible_contexts $ mappM_ complain (filter is_free theta) }
1059   where
1060     is_free pred     =  not (isIPPred pred)
1061                      && not (any bound_var (varSetElems (tyVarsOfPred pred)))
1062     bound_var ct_var = ct_var `elem` forall_tyvars
1063     complain pred    = addErrTc (freeErr pred)
1064
1065 freeErr pred
1066   = sep [ptext SLIT("All of the type variables in the constraint") <+> quotes (pprPred pred) <+>
1067                    ptext SLIT("are already in scope"),
1068          nest 4 (ptext SLIT("(at least one must be universally quantified here)"))
1069     ]
1070 \end{code}
1071
1072 \begin{code}
1073 checkThetaCtxt ctxt theta
1074   = vcat [ptext SLIT("In the context:") <+> pprTheta theta,
1075           ptext SLIT("While checking") <+> pprSourceTyCtxt ctxt ]
1076
1077 badPredTyErr sty = ptext SLIT("Illegal constraint") <+> pprPred sty
1078 eqPredTyErr  sty = ptext SLIT("Illegal equational constraint") <+> pprPred sty
1079                    $$
1080                    parens (ptext SLIT("Use -ftype-families to permit this"))
1081 predTyVarErr pred  = sep [ptext SLIT("Non type-variable argument"),
1082                           nest 2 (ptext SLIT("in the constraint:") <+> pprPred pred)]
1083 dupPredWarn dups   = ptext SLIT("Duplicate constraint(s):") <+> pprWithCommas pprPred (map head dups)
1084
1085 arityErr kind name n m
1086   = hsep [ text kind, quotes (ppr name), ptext SLIT("should have"),
1087            n_arguments <> comma, text "but has been given", int m]
1088     where
1089         n_arguments | n == 0 = ptext SLIT("no arguments")
1090                     | n == 1 = ptext SLIT("1 argument")
1091                     | True   = hsep [int n, ptext SLIT("arguments")]
1092 \end{code}
1093
1094
1095 %************************************************************************
1096 %*                                                                      *
1097 \subsection{Checking for a decent instance head type}
1098 %*                                                                      *
1099 %************************************************************************
1100
1101 @checkValidInstHead@ checks the type {\em and} its syntactic constraints:
1102 it must normally look like: @instance Foo (Tycon a b c ...) ...@
1103
1104 The exceptions to this syntactic checking: (1)~if the @GlasgowExts@
1105 flag is on, or (2)~the instance is imported (they must have been
1106 compiled elsewhere). In these cases, we let them go through anyway.
1107
1108 We can also have instances for functions: @instance Foo (a -> b) ...@.
1109
1110 \begin{code}
1111 checkValidInstHead :: Type -> TcM (Class, [TcType])
1112
1113 checkValidInstHead ty   -- Should be a source type
1114   = case tcSplitPredTy_maybe ty of {
1115         Nothing -> failWithTc (instTypeErr (ppr ty) empty) ;
1116         Just pred ->
1117
1118     case getClassPredTys_maybe pred of {
1119         Nothing -> failWithTc (instTypeErr (pprPred pred) empty) ;
1120         Just (clas,tys) ->
1121
1122     getDOpts                                    `thenM` \ dflags ->
1123     mappM_ check_arg_type tys                   `thenM_`
1124     check_inst_head dflags clas tys             `thenM_`
1125     returnM (clas, tys)
1126     }}
1127
1128 check_inst_head dflags clas tys
1129         -- If GlasgowExts then check at least one isn't a type variable
1130   = do checkTc (dopt Opt_TypeSynonymInstances dflags ||
1131                 all tcInstHeadTyNotSynonym tys)
1132                (instTypeErr (pprClassPred clas tys) head_type_synonym_msg)
1133        checkTc (dopt Opt_FlexibleInstances dflags ||
1134                 all tcInstHeadTyAppAllTyVars tys)
1135                (instTypeErr (pprClassPred clas tys) head_type_args_tyvars_msg)
1136        checkTc (dopt Opt_MultiParamTypeClasses dflags ||
1137                 isSingleton tys)
1138                (instTypeErr (pprClassPred clas tys) head_one_type_msg)
1139        mapM_ check_one tys
1140   where
1141     head_type_synonym_msg = parens (
1142                 text "All instance types must be of the form (T t1 ... tn)" $$
1143                 text "where T is not a synonym." $$
1144                 text "Use -XTypeSynonymInstances if you want to disable this.")
1145
1146     head_type_args_tyvars_msg = parens (
1147                 text "All instance types must be of the form (T a1 ... an)" $$
1148                 text "where a1 ... an are distinct type *variables*" $$
1149                 text "Use -XFlexibleInstances if you want to disable this.")
1150
1151     head_one_type_msg = parens (
1152                 text "Only one type can be given in an instance head." $$
1153                 text "Use -XMultiParamTypeClasses if you want to allow more.")
1154
1155         -- For now, I only allow tau-types (not polytypes) in
1156         -- the head of an instance decl.
1157         --      E.g.  instance C (forall a. a->a) is rejected
1158         -- One could imagine generalising that, but I'm not sure
1159         -- what all the consequences might be
1160     check_one ty = do { check_tau_type (Rank 0) UT_NotOk ty
1161                       ; checkTc (not (isUnLiftedType ty)) (unliftedArgErr ty) }
1162
1163 instTypeErr pp_ty msg
1164   = sep [ptext SLIT("Illegal instance declaration for") <+> quotes pp_ty,
1165          nest 4 msg]
1166 \end{code}
1167
1168
1169 %************************************************************************
1170 %*                                                                      *
1171 \subsection{Checking instance for termination}
1172 %*                                                                      *
1173 %************************************************************************
1174
1175
1176 \begin{code}
1177 checkValidInstance :: [TyVar] -> ThetaType -> Class -> [TcType] -> TcM ()
1178 checkValidInstance tyvars theta clas inst_tys
1179   = do  { undecidable_ok <- doptM Opt_AllowUndecidableInstances
1180
1181         ; checkValidTheta InstThetaCtxt theta
1182         ; checkAmbiguity tyvars theta (tyVarsOfTypes inst_tys)
1183
1184         -- Check that instance inference will terminate (if we care)
1185         -- For Haskell 98 this will already have been done by checkValidTheta,
1186     -- but as we may be using other extensions we need to check.
1187         ; unless undecidable_ok $
1188           mapM_ addErrTc (checkInstTermination inst_tys theta)
1189
1190         -- The Coverage Condition
1191         ; checkTc (undecidable_ok || checkInstCoverage clas inst_tys)
1192                   (instTypeErr (pprClassPred clas inst_tys) msg)
1193         }
1194   where
1195     msg  = parens (vcat [ptext SLIT("the Coverage Condition fails for one of the functional dependencies;"),
1196                          undecidableMsg])
1197 \end{code}
1198
1199 Termination test: the so-called "Paterson conditions" (see Section 5 of
1200 "Understanding functionsl dependencies via Constraint Handling Rules,
1201 JFP Jan 2007).
1202
1203 We check that each assertion in the context satisfies:
1204  (1) no variable has more occurrences in the assertion than in the head, and
1205  (2) the assertion has fewer constructors and variables (taken together
1206      and counting repetitions) than the head.
1207 This is only needed with -fglasgow-exts, as Haskell 98 restrictions
1208 (which have already been checked) guarantee termination.
1209
1210 The underlying idea is that
1211
1212     for any ground substitution, each assertion in the
1213     context has fewer type constructors than the head.
1214
1215
1216 \begin{code}
1217 checkInstTermination :: [TcType] -> ThetaType -> [Message]
1218 checkInstTermination tys theta
1219   = mapCatMaybes check theta
1220   where
1221    fvs  = fvTypes tys
1222    size = sizeTypes tys
1223    check pred
1224       | not (null (fvPred pred \\ fvs))
1225       = Just (predUndecErr pred nomoreMsg $$ parens undecidableMsg)
1226       | sizePred pred >= size
1227       = Just (predUndecErr pred smallerMsg $$ parens undecidableMsg)
1228       | otherwise
1229       = Nothing
1230
1231 predUndecErr pred msg = sep [msg,
1232                         nest 2 (ptext SLIT("in the constraint:") <+> pprPred pred)]
1233
1234 nomoreMsg = ptext SLIT("Variable occurs more often in a constraint than in the instance head")
1235 smallerMsg = ptext SLIT("Constraint is no smaller than the instance head")
1236 undecidableMsg = ptext SLIT("Use -fallow-undecidable-instances to permit this")
1237
1238 -- Free variables of a type, retaining repetitions, and expanding synonyms
1239 fvType :: Type -> [TyVar]
1240 fvType ty | Just exp_ty <- tcView ty = fvType exp_ty
1241 fvType (TyVarTy tv)        = [tv]
1242 fvType (TyConApp _ tys)    = fvTypes tys
1243 fvType (NoteTy _ ty)       = fvType ty
1244 fvType (PredTy pred)       = fvPred pred
1245 fvType (FunTy arg res)     = fvType arg ++ fvType res
1246 fvType (AppTy fun arg)     = fvType fun ++ fvType arg
1247 fvType (ForAllTy tyvar ty) = filter (/= tyvar) (fvType ty)
1248
1249 fvTypes :: [Type] -> [TyVar]
1250 fvTypes tys                = concat (map fvType tys)
1251
1252 fvPred :: PredType -> [TyVar]
1253 fvPred (ClassP _ tys')     = fvTypes tys'
1254 fvPred (IParam _ ty)       = fvType ty
1255 fvPred (EqPred ty1 ty2)    = fvType ty1 ++ fvType ty2
1256
1257 -- Size of a type: the number of variables and constructors
1258 sizeType :: Type -> Int
1259 sizeType ty | Just exp_ty <- tcView ty = sizeType exp_ty
1260 sizeType (TyVarTy _)       = 1
1261 sizeType (TyConApp _ tys)  = sizeTypes tys + 1
1262 sizeType (NoteTy _ ty)     = sizeType ty
1263 sizeType (PredTy pred)     = sizePred pred
1264 sizeType (FunTy arg res)   = sizeType arg + sizeType res + 1
1265 sizeType (AppTy fun arg)   = sizeType fun + sizeType arg
1266 sizeType (ForAllTy _ ty)   = sizeType ty
1267
1268 sizeTypes :: [Type] -> Int
1269 sizeTypes xs               = sum (map sizeType xs)
1270
1271 sizePred :: PredType -> Int
1272 sizePred (ClassP _ tys')   = sizeTypes tys'
1273 sizePred (IParam _ ty)     = sizeType ty
1274 sizePred (EqPred ty1 ty2)  = sizeType ty1 + sizeType ty2
1275 \end{code}