compiler/typecheck/TcRnDriver.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5 \section[TcModule]{Typechecking a whole module}
   6
   7 \begin{code}
   8 {-# OPTIONS -w #-}
   9 -- The above warning supression flag is a temporary kludge.
  10 -- While working on this module you are encouraged to remove it and fix
  11 -- any warnings in the module. See
  12 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  13 -- for details
  14
  15 module TcRnDriver (
  16 #ifdef GHCI
  17         tcRnStmt, tcRnExpr, tcRnType,
  18         tcRnLookupRdrName,
  19         tcRnLookupName,
  20         tcRnGetInfo,
  21         getModuleExports,
  22 #endif
  23         tcRnModule,
  24         tcTopSrcDecls,
  25         tcRnExtCore
  26     ) where
  27
  28 #include "HsVersions.h"
  29
  30 import IO
  31 #ifdef GHCI
  32 import {-# SOURCE #-} TcSplice ( tcSpliceDecls )
  33 #endif
  34
  35 import DynFlags
  36 import StaticFlags
  37 import HsSyn
  38 import RdrHsSyn
  39
  40 import PrelNames
  41 import RdrName
  42 import TcHsSyn
  43 import TcExpr
  44 import TcRnMonad
  45 import TcType
  46 import Inst
  47 import FamInst
  48 import InstEnv
  49 import FamInstEnv
  50 import TcBinds
  51 import TcDefaults
  52 import TcEnv
  53 import TcRules
  54 import TcForeign
  55 import TcInstDcls
  56 import TcIface
  57 import MkIface
  58 import IfaceSyn
  59 import TcSimplify
  60 import TcTyClsDecls
  61 import LoadIface
  62 import RnNames
  63 import RnEnv
  64 import RnSource
  65 import RnHsDoc
  66 import PprCore
  67 import CoreSyn
  68 import ErrUtils
  69 import Id
  70 import Var
  71 import Module
  72 import UniqFM
  73 import Name
  74 import NameEnv
  75 import NameSet
  76 import TyCon
  77 import SrcLoc
  78 import HscTypes
  79 import ListSetOps
  80 import Outputable
  81
  82 #ifdef GHCI
  83 import Linker
  84 import DataCon
  85 import TcHsType
  86 import TcMType
  87 import TcMatches
  88 import TcGadt
  89 import RnTypes
  90 import RnExpr
  91 import IfaceEnv
  92 import MkId
  93 import TysWiredIn
  94 import IdInfo
  95 import {- Kind parts of -} Type
  96 import BasicTypes
  97 import Foreign.Ptr( Ptr )
  98 #endif
  99
 100 import FastString
 101 import Maybes
 102 import Util
 103 import Bag
 104
 105 import Control.Monad    ( unless )
 106 import Data.Maybe       ( isJust )
 107
 108 \end{code}
 109
 110
 111
 112 %************************************************************************
 113 %*                                                                      *
 114         Typecheck and rename a module
 115 %*                                                                      *
 116 %************************************************************************
 117
 118
 119 \begin{code}
 120 tcRnModule :: HscEnv
 121            -> HscSource
 122            -> Bool              -- True <=> save renamed syntax
 123            -> Located (HsModule RdrName)
 124            -> IO (Messages, Maybe TcGblEnv)
 125
 126 tcRnModule hsc_env hsc_src save_rn_syntax
 127          (L loc (HsModule maybe_mod export_ies
 128                           import_decls local_decls mod_deprec _
 129                           module_info maybe_doc))
 130  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 131
 132    let { this_pkg = thisPackage (hsc_dflags hsc_env) ;
 133          this_mod = case maybe_mod of
 134                         Nothing  -> mAIN        -- 'module M where' is omitted
 135                         Just (L _ mod) -> mkModule this_pkg mod } ;
 136                                                 -- The normal case
 137
 138    initTc hsc_env hsc_src save_rn_syntax this_mod $
 139    setSrcSpan loc $
 140    do {         -- Deal with imports;
 141         tcg_env <- tcRnImports hsc_env this_mod import_decls ;
 142         setGblEnv tcg_env               $ do {
 143
 144                 -- Load the hi-boot interface for this module, if any
 145                 -- We do this now so that the boot_names can be passed
 146                 -- to tcTyAndClassDecls, because the boot_names are
 147                 -- automatically considered to be loop breakers
 148                 --
 149                 -- Do this *after* tcRnImports, so that we know whether
 150                 -- a module that we import imports us; and hence whether to
 151                 -- look for a hi-boot file
 152         boot_iface <- tcHiBootIface hsc_src this_mod ;
 153
 154                 -- Rename and type check the declarations
 155         traceRn (text "rn1a") ;
 156         tcg_env <- if isHsBoot hsc_src then
 157                         tcRnHsBootDecls local_decls
 158                    else
 159                         tcRnSrcDecls boot_iface local_decls ;
 160         setGblEnv tcg_env               $ do {
 161
 162                 -- Report the use of any deprecated things
 163                 -- We do this *before* processsing the export list so
 164                 -- that we don't bleat about re-exporting a deprecated
 165                 -- thing (especially via 'module Foo' export item)
 166                 -- That is, only uses in the *body* of the module are complained about
 167         traceRn (text "rn3") ;
 168         failIfErrsM ;   -- finishDeprecations crashes sometimes
 169                         -- as a result of typechecker repairs (e.g. unboundNames)
 170         tcg_env <- finishDeprecations (hsc_dflags hsc_env) mod_deprec tcg_env ;
 171
 172                 -- Process the export list
 173        traceRn (text "rn4a: before exports");
 174         tcg_env <- rnExports (isJust maybe_mod) export_ies tcg_env ;
 175         traceRn (text "rn4b: after exportss") ;
 176
 177         -- Compare the hi-boot iface (if any) with the real thing
 178         -- Must be done after processing the exports
 179         tcg_env <- checkHiBootIface tcg_env boot_iface ;
 180
 181         -- Make the new type env available to stuff slurped from interface files
 182         -- Must do this after checkHiBootIface, because the latter might add new
 183         -- bindings for boot_dfuns, which may be mentioned in imported unfoldings
 184         writeMutVar (tcg_type_env_var tcg_env) (tcg_type_env tcg_env) ;
 185
 186                 -- Rename the Haddock documentation
 187         tcg_env <- rnHaddock module_info maybe_doc tcg_env ;
 188
 189                 -- Report unused names
 190         reportUnusedNames export_ies tcg_env ;
 191
 192                 -- Dump output and return
 193         tcDump tcg_env ;
 194         return tcg_env
 195     }}}}
 196 \end{code}
 197
 198
 199 %************************************************************************
 200 %*                                                                      *
 201                 Import declarations
 202 %*                                                                      *
 203 %************************************************************************
 204
 205 \begin{code}
 206 tcRnImports :: HscEnv -> Module -> [LImportDecl RdrName] -> TcM TcGblEnv
 207 tcRnImports hsc_env this_mod import_decls
 208   = do  { (rn_imports, rdr_env, imports,hpc_info) <- rnImports import_decls ;
 209
 210         ; let { dep_mods :: ModuleNameEnv (ModuleName, IsBootInterface)
 211               ; dep_mods = imp_dep_mods imports
 212
 213                 -- We want instance declarations from all home-package
 214                 -- modules below this one, including boot modules, except
 215                 -- ourselves.  The 'except ourselves' is so that we don't
 216                 -- get the instances from this module's hs-boot file
 217               ; want_instances :: ModuleName -> Bool
 218               ; want_instances mod = mod `elemUFM` dep_mods
 219                                    && mod /= moduleName this_mod
 220               ; (home_insts, home_fam_insts) = hptInstances hsc_env
 221                                                             want_instances
 222               } ;
 223
 224                 -- Record boot-file info in the EPS, so that it's
 225                 -- visible to loadHiBootInterface in tcRnSrcDecls,
 226                 -- and any other incrementally-performed imports
 227         ; updateEps_ (\eps -> eps { eps_is_boot = dep_mods }) ;
 228
 229                 -- Update the gbl env
 230         ; updGblEnv ( \ gbl ->
 231             gbl {
 232               tcg_rdr_env      = plusOccEnv (tcg_rdr_env gbl) rdr_env,
 233               tcg_imports      = tcg_imports gbl `plusImportAvails` imports,
 234               tcg_rn_imports   = fmap (const rn_imports) (tcg_rn_imports gbl),
 235               tcg_inst_env     = extendInstEnvList (tcg_inst_env gbl) home_insts,
 236               tcg_fam_inst_env = extendFamInstEnvList (tcg_fam_inst_env gbl)
 237                                                       home_fam_insts,
 238               tcg_hpc          = hpc_info
 239             }) $ do {
 240
 241         ; traceRn (text "rn1" <+> ppr (imp_dep_mods imports))
 242                 -- Fail if there are any errors so far
 243                 -- The error printing (if needed) takes advantage
 244                 -- of the tcg_env we have now set
 245 --      ; traceIf (text "rdr_env: " <+> ppr rdr_env)
 246         ; failIfErrsM
 247
 248                 -- Load any orphan-module and family instance-module
 249                 -- interfaces, so that their rules and instance decls will be
 250                 -- found.
 251         ; loadOrphanModules (imp_orphs  imports) False
 252         ; loadOrphanModules (imp_finsts imports) True
 253
 254                 -- Check type-familily consistency
 255         ; traceRn (text "rn1: checking family instance consistency")
 256         ; let { dir_imp_mods = map (\ (mod, _) -> mod)
 257                              . moduleEnvElts
 258                              . imp_mods
 259                              $ imports }
 260         ; checkFamInstConsistency (imp_finsts imports) dir_imp_mods ;
 261
 262         ; getGblEnv } }
 263 \end{code}
 264
 265
 266 %************************************************************************
 267 %*                                                                      *
 268         Type-checking external-core modules
 269 %*                                                                      *
 270 %************************************************************************
 271
 272 \begin{code}
 273 tcRnExtCore :: HscEnv
 274             -> HsExtCore RdrName
 275             -> IO (Messages, Maybe ModGuts)
 276         -- Nothing => some error occurred
 277
 278 tcRnExtCore hsc_env (HsExtCore this_mod decls src_binds)
 279         -- The decls are IfaceDecls; all names are original names
 280  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 281
 282    initTc hsc_env ExtCoreFile False this_mod $ do {
 283
 284    let { ldecls  = map noLoc decls } ;
 285
 286        -- bring the type and class decls into scope
 287        -- ToDo: check that this doesn't need to extract the val binds.
 288        --       It seems that only the type and class decls need to be in scope below because
 289        --          (a) tcTyAndClassDecls doesn't need the val binds, and
 290        --          (b) tcExtCoreBindings doesn't need anything
 291        --              (in fact, it might not even need to be in the scope of
 292        --               this tcg_env at all)
 293    tcg_env  <- importsFromLocalDecls False (mkFakeGroup ldecls)
 294                emptyUFM {- no fixity decls -} ;
 295
 296    setGblEnv tcg_env $ do {
 297
 298    rn_decls <- rnTyClDecls ldecls ;
 299    failIfErrsM ;
 300
 301         -- Dump trace of renaming part
 302    rnDump (ppr rn_decls) ;
 303
 304         -- Typecheck them all together so that
 305         -- any mutually recursive types are done right
 306    tcg_env <- checkNoErrs (tcTyAndClassDecls emptyModDetails rn_decls) ;
 307         -- Make the new type env available to stuff slurped from interface files
 308
 309    setGblEnv tcg_env $ do {
 310
 311         -- Now the core bindings
 312    core_binds <- initIfaceExtCore (tcExtCoreBindings src_binds) ;
 313
 314         -- Wrap up
 315    let {
 316         bndrs      = bindersOfBinds core_binds ;
 317         my_exports = map (Avail . idName) bndrs ;
 318                 -- ToDo: export the data types also?
 319
 320         final_type_env = extendTypeEnvWithIds (tcg_type_env tcg_env) bndrs ;
 321
 322         mod_guts = ModGuts {    mg_module    = this_mod,
 323                                 mg_boot      = False,
 324                                 mg_usages    = [],              -- ToDo: compute usage
 325                                 mg_dir_imps  = [],              -- ??
 326                                 mg_deps      = noDependencies,  -- ??
 327                                 mg_exports   = my_exports,
 328                                 mg_types     = final_type_env,
 329                                 mg_insts     = tcg_insts tcg_env,
 330                                 mg_fam_insts = tcg_fam_insts tcg_env,
 331                                 mg_inst_env  = tcg_inst_env tcg_env,
 332                                 mg_fam_inst_env = tcg_fam_inst_env tcg_env,
 333                                 mg_rules     = [],
 334                                 mg_binds     = core_binds,
 335
 336                                 -- Stubs
 337                                 mg_rdr_env   = emptyGlobalRdrEnv,
 338                                 mg_fix_env   = emptyFixityEnv,
 339                                 mg_deprecs   = NoDeprecs,
 340                                 mg_foreign   = NoStubs,
 341                                 mg_hpc_info  = emptyHpcInfo False,
 342                                 mg_modBreaks = emptyModBreaks,
 343                                 mg_vect_info = noVectInfo
 344                     } } ;
 345
 346    tcCoreDump mod_guts ;
 347
 348    return mod_guts
 349    }}}}
 350
 351 mkFakeGroup decls -- Rather clumsy; lots of unused fields
 352   = emptyRdrGroup { hs_tyclds = decls }
 353 \end{code}
 354
 355
 356 %************************************************************************
 357 %*                                                                      *
 358         Type-checking the top level of a module
 359 %*                                                                      *
 360 %************************************************************************
 361
 362 \begin{code}
 363 tcRnSrcDecls :: ModDetails -> [LHsDecl RdrName] -> TcM TcGblEnv
 364         -- Returns the variables free in the decls
 365         -- Reason: solely to report unused imports and bindings
 366 tcRnSrcDecls boot_iface decls
 367  = do {         -- Do all the declarations
 368         (tc_envs, lie) <- getLIE $ tc_rn_src_decls boot_iface decls ;
 369
 370              --         Finish simplifying class constraints
 371              --
 372              -- tcSimplifyTop deals with constant or ambiguous InstIds.
 373              -- How could there be ambiguous ones?  They can only arise if a
 374              -- top-level decl falls under the monomorphism restriction
 375              -- and no subsequent decl instantiates its type.
 376              --
 377              -- We do this after checkMain, so that we use the type info
 378              -- thaat checkMain adds
 379              --
 380              -- We do it with both global and local env in scope:
 381              --  * the global env exposes the instances to tcSimplifyTop
 382              --  * the local env exposes the local Ids to tcSimplifyTop,
 383              --    so that we get better error messages (monomorphism restriction)
 384         traceTc (text "Tc8") ;
 385         inst_binds <- setEnvs tc_envs (tcSimplifyTop lie) ;
 386
 387             -- Backsubstitution.  This must be done last.
 388             -- Even tcSimplifyTop may do some unification.
 389         traceTc (text "Tc9") ;
 390         let { (tcg_env, _) = tc_envs
 391             ; TcGblEnv { tcg_type_env = type_env, tcg_binds = binds,
 392                          tcg_rules = rules, tcg_fords = fords } = tcg_env
 393             ; all_binds = binds `unionBags` inst_binds } ;
 394
 395         (bind_ids, binds', fords', rules') <- zonkTopDecls all_binds rules fords ;
 396
 397         let { final_type_env = extendTypeEnvWithIds type_env bind_ids
 398             ; tcg_env' = tcg_env { tcg_type_env = final_type_env,
 399                                    tcg_binds = binds',
 400                                    tcg_rules = rules',
 401                                    tcg_fords = fords' } } ;
 402
 403         return (tcg_env' { tcg_binds = tcg_binds tcg_env' })
 404    }
 405
 406 tc_rn_src_decls :: ModDetails -> [LHsDecl RdrName] -> TcM (TcGblEnv, TcLclEnv)
 407 -- Loops around dealing with each top level inter-splice group
 408 -- in turn, until it's dealt with the entire module
 409 tc_rn_src_decls boot_details ds
 410  = do { let { (first_group, group_tail) = findSplice ds } ;
 411                 -- If ds is [] we get ([], Nothing)
 412
 413         -- Deal with decls up to, but not including, the first splice
 414         (tcg_env, rn_decls) <- checkNoErrs $ rnTopSrcDecls first_group ;
 415                 -- checkNoErrs: stop if renaming fails
 416
 417         (tcg_env, tcl_env) <- setGblEnv tcg_env $
 418                               tcTopSrcDecls boot_details rn_decls ;
 419
 420         -- If there is no splice, we're nearly done
 421         setEnvs (tcg_env, tcl_env) $
 422         case group_tail of {
 423            Nothing -> do { tcg_env <- checkMain ;       -- Check for `main'
 424                            return (tcg_env, tcl_env)
 425                       } ;
 426
 427         -- If there's a splice, we must carry on
 428            Just (SpliceDecl splice_expr, rest_ds) -> do {
 429 #ifndef GHCI
 430         failWithTc (text "Can't do a top-level splice; need a bootstrapped compiler")
 431 #else
 432
 433         -- Rename the splice expression, and get its supporting decls
 434         (rn_splice_expr, splice_fvs) <- checkNoErrs (rnLExpr splice_expr) ;
 435                 -- checkNoErrs: don't typecheck if renaming failed
 436         rnDump (ppr rn_splice_expr) ;
 437
 438         -- Execute the splice
 439         spliced_decls <- tcSpliceDecls rn_splice_expr ;
 440
 441         -- Glue them on the front of the remaining decls and loop
 442         setGblEnv (tcg_env `addTcgDUs` usesOnly splice_fvs) $
 443         tc_rn_src_decls boot_details (spliced_decls ++ rest_ds)
 444 #endif /* GHCI */
 445     } } }
 446 \end{code}
 447
 448 %************************************************************************
 449 %*                                                                      *
 450         Compiling hs-boot source files, and
 451         comparing the hi-boot interface with the real thing
 452 %*                                                                      *
 453 %************************************************************************
 454
 455 \begin{code}
 456 tcRnHsBootDecls :: [LHsDecl RdrName] -> TcM TcGblEnv
 457 tcRnHsBootDecls decls
 458    = do { let { (first_group, group_tail) = findSplice decls }
 459
 460         ; case group_tail of
 461              Just stuff -> spliceInHsBootErr stuff
 462              Nothing    -> return ()
 463
 464                 -- Rename the declarations
 465         ; (tcg_env, rn_group) <- rnTopSrcDecls first_group
 466         ; setGblEnv tcg_env $ do {
 467
 468         -- Todo: check no foreign decls, no rules, no default decls
 469
 470                 -- Typecheck type/class decls
 471         ; traceTc (text "Tc2")
 472         ; let tycl_decls = hs_tyclds rn_group
 473         ; tcg_env <- checkNoErrs (tcTyAndClassDecls emptyModDetails tycl_decls)
 474         ; setGblEnv tcg_env     $ do {
 475
 476                 -- Typecheck instance decls
 477         ; traceTc (text "Tc3")
 478         ; (tcg_env, inst_infos, _deriv_binds)
 479             <- tcInstDecls1 tycl_decls (hs_instds rn_group) (hs_derivds rn_group)
 480         ; setGblEnv tcg_env     $ do {
 481
 482                 -- Typecheck value declarations
 483         ; traceTc (text "Tc5")
 484         ; val_ids <- tcHsBootSigs (hs_valds rn_group)
 485
 486                 -- Wrap up
 487                 -- No simplification or zonking to do
 488         ; traceTc (text "Tc7a")
 489         ; gbl_env <- getGblEnv
 490
 491                 -- Make the final type-env
 492                 -- Include the dfun_ids so that their type sigs
 493                 -- are written into the interface file
 494         ; let { type_env0 = tcg_type_env gbl_env
 495               ; type_env1 = extendTypeEnvWithIds type_env0 val_ids
 496               ; type_env2 = extendTypeEnvWithIds type_env1 dfun_ids
 497               ; dfun_ids = map iDFunId inst_infos }
 498         ; return (gbl_env { tcg_type_env = type_env2 })
 499    }}}}
 500
 501 spliceInHsBootErr (SpliceDecl (L loc _), _)
 502   = addErrAt loc (ptext SLIT("Splices are not allowed in hs-boot files"))
 503 \end{code}
 504
 505 Once we've typechecked the body of the module, we want to compare what
 506 we've found (gathered in a TypeEnv) with the hi-boot details (if any).
 507
 508 \begin{code}
 509 checkHiBootIface :: TcGblEnv -> ModDetails -> TcM TcGblEnv
 510 -- Compare the hi-boot file for this module (if there is one)
 511 -- with the type environment we've just come up with
 512 -- In the common case where there is no hi-boot file, the list
 513 -- of boot_names is empty.
 514 --
 515 -- The bindings we return give bindings for the dfuns defined in the
 516 -- hs-boot file, such as        $fbEqT = $fEqT
 517
 518 checkHiBootIface
 519         tcg_env@(TcGblEnv { tcg_src = hs_src, tcg_binds = binds,
 520                             tcg_insts = local_insts, tcg_fam_insts = local_fam_insts,
 521                             tcg_type_env = local_type_env, tcg_exports = local_exports })
 522         (ModDetails { md_insts = boot_insts, md_fam_insts = boot_fam_insts,
 523                       md_types = boot_type_env, md_exports = boot_exports })
 524   | isHsBoot hs_src     -- Current module is already a hs-boot file!
 525   = return tcg_env
 526
 527   | otherwise
 528   = do  { traceTc (text "checkHiBootIface" <+> (ppr boot_type_env $$ ppr boot_insts $$
 529                                 ppr boot_exports)) ;
 530
 531                 -- Check the exports of the boot module, one by one
 532         ; mapM_ check_export boot_exports
 533
 534                 -- Check instance declarations
 535         ; mb_dfun_prs <- mapM check_inst boot_insts
 536         ; let tcg_env' = tcg_env { tcg_binds    = binds `unionBags` dfun_binds,
 537                                    tcg_type_env = extendTypeEnvWithIds local_type_env boot_dfuns }
 538               dfun_prs   = catMaybes mb_dfun_prs
 539               boot_dfuns = map fst dfun_prs
 540               dfun_binds = listToBag [ noLoc $ VarBind boot_dfun (nlHsVar dfun)
 541                                      | (boot_dfun, dfun) <- dfun_prs ]
 542
 543                 -- Check for no family instances
 544         ; unless (null boot_fam_insts) $
 545             panic ("TcRnDriver.checkHiBootIface: Cannot handle family " ++
 546                    "instances in boot files yet...")
 547             -- FIXME: Why?  The actual comparison is not hard, but what would
 548             --        be the equivalent to the dfun bindings returned for class
 549             --        instances?  We can't easily equate tycons...
 550
 551         ; return tcg_env' }
 552   where
 553     check_export boot_avail     -- boot_avail is exported by the boot iface
 554       | name `elem` dfun_names = return ()
 555       | isWiredInName name     = return ()      -- No checking for wired-in names.  In particular,
 556                                                 -- 'error' is handled by a rather gross hack
 557                                                 -- (see comments in GHC.Err.hs-boot)
 558
 559         -- Check that the actual module exports the same thing
 560       | not (null missing_names)
 561       = addErrTc (missingBootThing (head missing_names) "exported by")
 562
 563         -- If the boot module does not *define* the thing, we are done
 564         -- (it simply re-exports it, and names match, so nothing further to do)
 565       | isNothing mb_boot_thing = return ()
 566
 567         -- Check that the actual module also defines the thing, and
 568         -- then compare the definitions
 569       | Just real_thing <- lookupTypeEnv local_type_env name
 570       = do { let boot_decl = tyThingToIfaceDecl (fromJust mb_boot_thing)
 571                  real_decl = tyThingToIfaceDecl real_thing
 572            ; checkTc (checkBootDecl boot_decl real_decl)
 573                      (bootMisMatch real_thing boot_decl real_decl) }
 574                 -- The easiest way to check compatibility is to convert to
 575                 -- iface syntax, where we already have good comparison functions
 576
 577       | otherwise
 578       = addErrTc (missingBootThing name "defined in")
 579       where
 580         name          = availName boot_avail
 581         mb_boot_thing = lookupTypeEnv boot_type_env name
 582         missing_names = case lookupNameEnv local_export_env name of
 583                           Nothing    -> [name]
 584                           Just avail -> availNames boot_avail `minusList` availNames avail
 585
 586     dfun_names = map getName boot_insts
 587
 588     local_export_env :: NameEnv AvailInfo
 589     local_export_env = availsToNameEnv local_exports
 590
 591     check_inst :: Instance -> TcM (Maybe (Id, Id))
 592         -- Returns a pair of the boot dfun in terms of the equivalent real dfun
 593     check_inst boot_inst
 594         = case [dfun | inst <- local_insts,
 595                        let dfun = instanceDFunId inst,
 596                        idType dfun `tcEqType` boot_inst_ty ] of
 597             [] -> do { addErrTc (instMisMatch boot_inst); return Nothing }
 598             (dfun:_) -> return (Just (local_boot_dfun, dfun))
 599         where
 600           boot_dfun = instanceDFunId boot_inst
 601           boot_inst_ty = idType boot_dfun
 602           local_boot_dfun = Id.mkExportedLocalId (idName boot_dfun) boot_inst_ty
 603
 604
 605 ----------------
 606 missingBootThing thing what
 607   = ppr thing <+> ptext SLIT("is exported by the hs-boot file, but not")
 608               <+> text what <+> ptext SLIT("the module")
 609
 610 bootMisMatch thing boot_decl real_decl
 611   = vcat [ppr thing <+> ptext SLIT("has conflicting definitions in the module and its hs-boot file"),
 612           ptext SLIT("Main module:") <+> ppr real_decl,
 613           ptext SLIT("Boot file:  ") <+> ppr boot_decl]
 614
 615 instMisMatch inst
 616   = hang (ppr inst)
 617        2 (ptext SLIT("is defined in the hs-boot file, but not in the module itself"))
 618 \end{code}
 619
 620
 621 %************************************************************************
 622 %*                                                                      *
 623         Type-checking the top level of a module
 624 %*                                                                      *
 625 %************************************************************************
 626
 627 tcRnGroup takes a bunch of top-level source-code declarations, and
 628  * renames them
 629  * gets supporting declarations from interface files
 630  * typechecks them
 631  * zonks them
 632  * and augments the TcGblEnv with the results
 633
 634 In Template Haskell it may be called repeatedly for each group of
 635 declarations.  It expects there to be an incoming TcGblEnv in the
 636 monad; it augments it and returns the new TcGblEnv.
 637
 638 \begin{code}
 639 ------------------------------------------------
 640 rnTopSrcDecls :: HsGroup RdrName -> TcM (TcGblEnv, HsGroup Name)
 641 rnTopSrcDecls group
 642  = do { -- Rename the source decls (with no shadowing; error on duplicates)
 643         (tcg_env, rn_decls) <- rnSrcDecls False group ;
 644         failIfErrsM ;
 645
 646         -- save the renamed syntax, if we want it
 647         let { tcg_env'
 648                 | Just grp <- tcg_rn_decls tcg_env
 649                   = tcg_env{ tcg_rn_decls = Just (appendGroups grp rn_decls) }
 650                 | otherwise
 651                    = tcg_env };
 652
 653                 -- Dump trace of renaming part
 654         rnDump (ppr rn_decls) ;
 655
 656         return (tcg_env', rn_decls)
 657    }
 658
 659 ------------------------------------------------
 660 tcTopSrcDecls :: ModDetails -> HsGroup Name -> TcM (TcGblEnv, TcLclEnv)
 661 tcTopSrcDecls boot_details
 662         (HsGroup { hs_tyclds = tycl_decls,
 663                    hs_instds = inst_decls,
 664                    hs_derivds = deriv_decls,
 665                    hs_fords  = foreign_decls,
 666                    hs_defds  = default_decls,
 667                    hs_ruleds = rule_decls,
 668                    hs_valds  = val_binds })
 669  = do {         -- Type-check the type and class decls, and all imported decls
 670                 -- The latter come in via tycl_decls
 671         traceTc (text "Tc2") ;
 672
 673         tcg_env <- checkNoErrs (tcTyAndClassDecls boot_details tycl_decls) ;
 674         -- tcTyAndClassDecls recovers internally, but if anything gave rise to
 675         -- an error we'd better stop now, to avoid a cascade
 676
 677         -- Make these type and class decls available to stuff slurped from interface files
 678         writeMutVar (tcg_type_env_var tcg_env) (tcg_type_env tcg_env) ;
 679
 680
 681         setGblEnv tcg_env       $ do {
 682                 -- Source-language instances, including derivings,
 683                 -- and import the supporting declarations
 684         traceTc (text "Tc3") ;
 685         (tcg_env, inst_infos, deriv_binds)
 686             <- tcInstDecls1 tycl_decls inst_decls deriv_decls;
 687         setGblEnv tcg_env       $ do {
 688
 689                 -- Foreign import declarations next.  No zonking necessary
 690                 -- here; we can tuck them straight into the global environment.
 691         traceTc (text "Tc4") ;
 692         (fi_ids, fi_decls) <- tcForeignImports foreign_decls ;
 693         tcExtendGlobalValEnv fi_ids     $ do {
 694
 695                 -- Default declarations
 696         traceTc (text "Tc4a") ;
 697         default_tys <- tcDefaults default_decls ;
 698         updGblEnv (\gbl -> gbl { tcg_default = default_tys }) $ do {
 699
 700                 -- Value declarations next
 701                 -- We also typecheck any extra binds that came out
 702                 -- of the "deriving" process (deriv_binds)
 703         traceTc (text "Tc5") ;
 704         (tc_val_binds,   tcl_env) <- tcTopBinds val_binds ;
 705         setLclTypeEnv tcl_env   $ do {
 706
 707                 -- Now GHC-generated derived bindings and generics.
 708                 -- Do not generate warnings from compiler-generated code.
 709         (tc_deriv_binds, tcl_env) <- discardWarnings $
 710                                  tcTopBinds deriv_binds ;
 711
 712                 -- Second pass over class and instance declarations,
 713         traceTc (text "Tc6") ;
 714         (inst_binds, tcl_env)     <- setLclTypeEnv tcl_env $ tcInstDecls2 tycl_decls inst_infos ;
 715         showLIE (text "after instDecls2") ;
 716
 717                 -- Foreign exports
 718                 -- They need to be zonked, so we return them
 719         traceTc (text "Tc7") ;
 720         (foe_binds, foe_decls) <- tcForeignExports foreign_decls ;
 721
 722                 -- Rules
 723         rules <- tcRules rule_decls ;
 724
 725                 -- Wrap up
 726         traceTc (text "Tc7a") ;
 727         tcg_env <- getGblEnv ;
 728         let { all_binds = tc_val_binds   `unionBags`
 729                           tc_deriv_binds `unionBags`
 730                           inst_binds     `unionBags`
 731                           foe_binds  ;
 732
 733                 -- Extend the GblEnv with the (as yet un-zonked)
 734                 -- bindings, rules, foreign decls
 735               tcg_env' = tcg_env {  tcg_binds = tcg_binds tcg_env `unionBags` all_binds,
 736                                     tcg_rules = tcg_rules tcg_env ++ rules,
 737                                     tcg_fords = tcg_fords tcg_env ++ foe_decls ++ fi_decls } } ;
 738         return (tcg_env', tcl_env)
 739     }}}}}}
 740 \end{code}
 741
 742
 743 %************************************************************************
 744 %*                                                                      *
 745         Checking for 'main'
 746 %*                                                                      *
 747 %************************************************************************
 748
 749 \begin{code}
 750 checkMain :: TcM TcGblEnv
 751 -- If we are in module Main, check that 'main' is defined.
 752 checkMain
 753   = do { tcg_env   <- getGblEnv ;
 754          dflags    <- getDOpts ;
 755          check_main dflags tcg_env
 756     }
 757
 758 check_main dflags tcg_env
 759  | mod /= main_mod
 760  = traceTc (text "checkMain not" <+> ppr main_mod <+> ppr mod) >>
 761    return tcg_env
 762
 763  | otherwise
 764  = do   { mb_main <- lookupSrcOcc_maybe main_fn
 765                 -- Check that 'main' is in scope
 766                 -- It might be imported from another module!
 767         ; case mb_main of {
 768              Nothing -> do { traceTc (text "checkMain fail" <+> ppr main_mod <+> ppr main_fn)
 769                            ; complain_no_main
 770                            ; return tcg_env } ;
 771              Just main_name -> do
 772
 773         { traceTc (text "checkMain found" <+> ppr main_mod <+> ppr main_fn)
 774         ; let { rhs = nlHsApp (nlHsVar runMainIOName) (nlHsVar main_name) }
 775                         -- :Main.main :: IO () = runMainIO main
 776
 777         ; (main_expr, ty) <- addErrCtxt mainCtxt                        $
 778                              setSrcSpan (srcLocSpan (getSrcLoc main_name)) $
 779                              tcInferRho rhs
 780
 781                 -- See Note [Root-main Id]
 782         ; let { root_main_name =  mkExternalName rootMainKey rOOT_MAIN
 783                                    (mkVarOccFS FSLIT("main"))
 784                                    (getSrcSpan main_name)
 785               ; root_main_id = Id.mkExportedLocalId root_main_name ty
 786               ; main_bind    = noLoc (VarBind root_main_id main_expr) }
 787
 788         ; return (tcg_env { tcg_binds = tcg_binds tcg_env
 789                                         `snocBag` main_bind,
 790                             tcg_dus   = tcg_dus tcg_env
 791                                         `plusDU` usesOnly (unitFV main_name)
 792                         -- Record the use of 'main', so that we don't
 793                         -- complain about it being defined but not used
 794                  })
 795     }}}
 796   where
 797     mod          = tcg_mod tcg_env
 798     main_mod     = mainModIs dflags
 799     main_is_flag = mainFunIs dflags
 800
 801     main_fn  = case main_is_flag of
 802                   Just fn -> mkRdrUnqual (mkVarOccFS (mkFastString fn))
 803                   Nothing -> main_RDR_Unqual
 804
 805     complain_no_main | ghcLink dflags == LinkInMemory = return ()
 806                      | otherwise = failWithTc noMainMsg
 807         -- In interactive mode, don't worry about the absence of 'main'
 808         -- In other modes, fail altogether, so that we don't go on
 809         -- and complain a second time when processing the export list.
 810
 811     mainCtxt  = ptext SLIT("When checking the type of the") <+> pp_main_fn
 812     noMainMsg = ptext SLIT("The") <+> pp_main_fn
 813                 <+> ptext SLIT("is not defined in module") <+> quotes (ppr main_mod)
 814     pp_main_fn | isJust main_is_flag = ptext SLIT("main function") <+> quotes (ppr main_fn)
 815                | otherwise           = ptext SLIT("function") <+> quotes (ppr main_fn)
 816 \end{code}
 817
 818 Note [Root-main Id]
 819 ~~~~~~~~~~~~~~~~~~~
 820 The function that the RTS invokes is always :Main.main, which we call
 821 root_main_id.  (Because GHC allows the user to have a module not
 822 called Main as the main module, we can't rely on the main function
 823 being called "Main.main".  That's why root_main_id has a fixed module
 824 ":Main".)
 825
 826 This is unusual: it's a LocalId whose Name has a Module from another
 827 module.  Tiresomely, we must filter it out again in MkIface, les we
 828 get two defns for 'main' in the interface file!
 829
 830
 831 %*********************************************************
 832 %*                                                       *
 833                 GHCi stuff
 834 %*                                                       *
 835 %*********************************************************
 836
 837 \begin{code}
 838 #ifdef GHCI
 839 setInteractiveContext :: HscEnv -> InteractiveContext -> TcRn a -> TcRn a
 840 setInteractiveContext hsc_env icxt thing_inside
 841   = let -- Initialise the tcg_inst_env with instances from all home modules.
 842         -- This mimics the more selective call to hptInstances in tcRnModule.
 843         (home_insts, home_fam_insts) = hptInstances hsc_env (\mod -> True)
 844     in
 845     updGblEnv (\env -> env {
 846         tcg_rdr_env      = ic_rn_gbl_env icxt,
 847         tcg_inst_env     = extendInstEnvList    (tcg_inst_env env) home_insts,
 848         tcg_fam_inst_env = extendFamInstEnvList (tcg_fam_inst_env env)
 849                                                 home_fam_insts
 850       }) $
 851
 852     tcExtendGhciEnv (ic_tmp_ids icxt) $
 853         -- tcExtendGhciEnv does lots:
 854         --   - it extends the local type env (tcl_env) with the given Ids,
 855         --   - it extends the local rdr env (tcl_rdr) with the Names from
 856         --     the given Ids
 857         --   - it adds the free tyvars of the Ids to the tcl_tyvars
 858         --     set.
 859         --
 860         -- later ids in ic_tmp_ids must shadow earlier ones with the same
 861         -- OccName, and tcExtendIdEnv implements this behaviour.
 862
 863     do  { traceTc (text "setIC" <+> ppr (ic_tmp_ids icxt))
 864         ; thing_inside }
 865 \end{code}
 866
 867
 868 \begin{code}
 869 tcRnStmt :: HscEnv
 870          -> InteractiveContext
 871          -> LStmt RdrName
 872          -> IO (Maybe ([Id], LHsExpr Id))
 873                 -- The returned [Id] is the list of new Ids bound by
 874                 -- this statement.  It can be used to extend the
 875                 -- InteractiveContext via extendInteractiveContext.
 876                 --
 877                 -- The returned TypecheckedHsExpr is of type IO [ () ],
 878                 -- a list of the bound values, coerced to ().
 879
 880 tcRnStmt hsc_env ictxt rdr_stmt
 881   = initTcPrintErrors hsc_env iNTERACTIVE $
 882     setInteractiveContext hsc_env ictxt $ do {
 883
 884     -- Rename; use CmdLineMode because tcRnStmt is only used interactively
 885     (([rn_stmt], _), fvs) <- rnStmts DoExpr [rdr_stmt] (return ((), emptyFVs)) ;
 886     traceRn (text "tcRnStmt" <+> vcat [ppr rdr_stmt, ppr rn_stmt, ppr fvs]) ;
 887     failIfErrsM ;
 888     rnDump (ppr rn_stmt) ;
 889
 890     -- The real work is done here
 891     (bound_ids, tc_expr) <- mkPlan rn_stmt ;
 892     zonked_expr <- zonkTopLExpr tc_expr ;
 893     zonked_ids  <- zonkTopBndrs bound_ids ;
 894
 895         -- None of the Ids should be of unboxed type, because we
 896         -- cast them all to HValues in the end!
 897     mappM bad_unboxed (filter (isUnLiftedType . idType) zonked_ids) ;
 898
 899     traceTc (text "tcs 1") ;
 900     let {       -- (a) Make all the bound ids "global" ids, now that
 901                 --     they're notionally top-level bindings.  This is
 902                 --     important: otherwise when we come to compile an expression
 903                 --     using these ids later, the byte code generator will consider
 904                 --     the occurrences to be free rather than global.
 905                 --
 906                 -- (b) Tidy their types; this is important, because :info may
 907                 --     ask to look at them, and :info expects the things it looks
 908                 --     up to have tidy types
 909         global_ids = map globaliseAndTidy zonked_ids ;
 910
 911 {- ---------------------------------------------
 912    At one stage I removed any shadowed bindings from the type_env;
 913    they are inaccessible but might, I suppose, cause a space leak if we leave them there.
 914    However, with Template Haskell they aren't necessarily inaccessible.  Consider this
 915    GHCi session
 916          Prelude> let f n = n * 2 :: Int
 917          Prelude> fName <- runQ [| f |]
 918          Prelude> $(return $ AppE fName (LitE (IntegerL 7)))
 919          14
 920          Prelude> let f n = n * 3 :: Int
 921          Prelude> $(return $ AppE fName (LitE (IntegerL 7)))
 922    In the last line we use 'fName', which resolves to the *first* 'f'
 923    in scope. If we delete it from the type env, GHCi crashes because
 924    it doesn't expect that.
 925
 926    Hence this code is commented out
 927
 928 -------------------------------------------------- -}
 929     } ;
 930
 931     dumpOptTcRn Opt_D_dump_tc
 932         (vcat [text "Bound Ids" <+> pprWithCommas ppr global_ids,
 933                text "Typechecked expr" <+> ppr zonked_expr]) ;
 934
 935     returnM (global_ids, zonked_expr)
 936     }
 937   where
 938     bad_unboxed id = addErr (sep [ptext SLIT("GHCi can't bind a variable of unlifted type:"),
 939                                   nest 2 (ppr id <+> dcolon <+> ppr (idType id))])
 940
 941 globaliseAndTidy :: Id -> Id
 942 globaliseAndTidy id
 943 -- Give the Id a Global Name, and tidy its type
 944   = Id.setIdType (globaliseId VanillaGlobal id) tidy_type
 945   where
 946     tidy_type = tidyTopType (idType id)
 947 \end{code}
 948
 949 Here is the grand plan, implemented in tcUserStmt
 950
 951         What you type                   The IO [HValue] that hscStmt returns
 952         -------------                   ------------------------------------
 953         let pat = expr          ==>     let pat = expr in return [coerce HVal x, coerce HVal y, ...]
 954                                         bindings: [x,y,...]
 955
 956         pat <- expr             ==>     expr >>= \ pat -> return [coerce HVal x, coerce HVal y, ...]
 957                                         bindings: [x,y,...]
 958
 959         expr (of IO type)       ==>     expr >>= \ it -> return [coerce HVal it]
 960           [NB: result not printed]      bindings: [it]
 961
 962         expr (of non-IO type,   ==>     let it = expr in print it >> return [coerce HVal it]
 963           result showable)              bindings: [it]
 964
 965         expr (of non-IO type,
 966           result not showable)  ==>     error
 967
 968
 969 \begin{code}
 970 ---------------------------
 971 type PlanResult = ([Id], LHsExpr Id)
 972 type Plan = TcM PlanResult
 973
 974 runPlans :: [Plan] -> TcM PlanResult
 975 -- Try the plans in order.  If one fails (by raising an exn), try the next.
 976 -- If one succeeds, take it.
 977 runPlans []     = panic "runPlans"
 978 runPlans [p]    = p
 979 runPlans (p:ps) = tryTcLIE_ (runPlans ps) p
 980
 981 --------------------
 982 mkPlan :: LStmt Name -> TcM PlanResult
 983 mkPlan (L loc (ExprStmt expr _ _))      -- An expression typed at the prompt
 984   = do  { uniq <- newUnique             -- is treated very specially
 985         ; let fresh_it  = itName uniq
 986               the_bind  = L loc $ mkFunBind (L loc fresh_it) matches
 987               matches   = [mkMatch [] expr emptyLocalBinds]
 988               let_stmt  = L loc $ LetStmt (HsValBinds (ValBindsOut [(NonRecursive,unitBag the_bind)] []))
 989               bind_stmt = L loc $ BindStmt (nlVarPat fresh_it) expr
 990                                            (HsVar bindIOName) noSyntaxExpr
 991               print_it  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar fresh_it))
 992                                            (HsVar thenIOName) placeHolderType
 993
 994         -- The plans are:
 995         --      [it <- e; print it]     but not if it::()
 996         --      [it <- e]
 997         --      [let it = e; print it]
 998         ; runPlans [    -- Plan A
 999                     do { stuff@([it_id], _) <- tcGhciStmts [bind_stmt, print_it]
1000                        ; it_ty <- zonkTcType (idType it_id)
1001                        ; ifM (isUnitTy it_ty) failM
1002                        ; return stuff },
1003
1004                         -- Plan B; a naked bind statment
1005                     tcGhciStmts [bind_stmt],
1006
1007                         -- Plan C; check that the let-binding is typeable all by itself.
1008                         -- If not, fail; if so, try to print it.
1009                         -- The two-step process avoids getting two errors: one from
1010                         -- the expression itself, and one from the 'print it' part
1011                         -- This two-step story is very clunky, alas
1012                     do { checkNoErrs (tcGhciStmts [let_stmt])
1013                                 --- checkNoErrs defeats the error recovery of let-bindings
1014                        ; tcGhciStmts [let_stmt, print_it] }
1015           ]}
1016
1017 mkPlan stmt@(L loc (BindStmt {}))
1018   | [L _ v] <- collectLStmtBinders stmt         -- One binder, for a bind stmt
1019   = do  { let print_v  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar v))
1020                                            (HsVar thenIOName) placeHolderType
1021
1022         ; print_bind_result <- doptM Opt_PrintBindResult
1023         ; let print_plan = do
1024                   { stuff@([v_id], _) <- tcGhciStmts [stmt, print_v]
1025                   ; v_ty <- zonkTcType (idType v_id)
1026                   ; ifM (isUnitTy v_ty || not (isTauTy v_ty)) failM
1027                   ; return stuff }
1028
1029         -- The plans are:
1030         --      [stmt; print v]         but not if v::()
1031         --      [stmt]
1032         ; runPlans ((if print_bind_result then [print_plan] else []) ++
1033                     [tcGhciStmts [stmt]])
1034         }
1035
1036 mkPlan stmt
1037   = tcGhciStmts [stmt]
1038
1039 ---------------------------
1040 tcGhciStmts :: [LStmt Name] -> TcM PlanResult
1041 tcGhciStmts stmts
1042  = do { ioTyCon <- tcLookupTyCon ioTyConName ;
1043         ret_id  <- tcLookupId returnIOName ;            -- return @ IO
1044         let {
1045             io_ty     = mkTyConApp ioTyCon [] ;
1046             ret_ty    = mkListTy unitTy ;
1047             io_ret_ty = mkTyConApp ioTyCon [ret_ty] ;
1048             tc_io_stmts stmts = tcStmts DoExpr (tcDoStmt io_ty) stmts
1049                                         (emptyRefinement, io_ret_ty) ;
1050
1051             names = map unLoc (collectLStmtsBinders stmts) ;
1052
1053                 -- mk_return builds the expression
1054                 --      returnIO @ [()] [coerce () x, ..,  coerce () z]
1055                 --
1056                 -- Despite the inconvenience of building the type applications etc,
1057                 -- this *has* to be done in type-annotated post-typecheck form
1058                 -- because we are going to return a list of *polymorphic* values
1059                 -- coerced to type (). If we built a *source* stmt
1060                 --      return [coerce x, ..., coerce z]
1061                 -- then the type checker would instantiate x..z, and we wouldn't
1062                 -- get their *polymorphic* values.  (And we'd get ambiguity errs
1063                 -- if they were overloaded, since they aren't applied to anything.)
1064             mk_return ids = nlHsApp (nlHsTyApp ret_id [ret_ty])
1065                                     (noLoc $ ExplicitList unitTy (map mk_item ids)) ;
1066             mk_item id = nlHsApp (nlHsTyApp unsafeCoerceId [idType id, unitTy])
1067                                  (nlHsVar id)
1068          } ;
1069
1070         -- OK, we're ready to typecheck the stmts
1071         traceTc (text "TcRnDriver.tcGhciStmts: tc stmts") ;
1072         ((tc_stmts, ids), lie) <- getLIE $ tc_io_stmts stmts $ \ _ ->
1073                                            mappM tcLookupId names ;
1074                                         -- Look up the names right in the middle,
1075                                         -- where they will all be in scope
1076
1077         -- Simplify the context
1078         traceTc (text "TcRnDriver.tcGhciStmts: simplify ctxt") ;
1079         const_binds <- checkNoErrs (tcSimplifyInteractive lie) ;
1080                 -- checkNoErrs ensures that the plan fails if context redn fails
1081
1082         traceTc (text "TcRnDriver.tcGhciStmts: done") ;
1083         return (ids, mkHsDictLet const_binds $
1084                      noLoc (HsDo DoExpr tc_stmts (mk_return ids) io_ret_ty))
1085     }
1086 \end{code}
1087
1088
1089 tcRnExpr just finds the type of an expression
1090
1091 \begin{code}
1092 tcRnExpr :: HscEnv
1093          -> InteractiveContext
1094          -> LHsExpr RdrName
1095          -> IO (Maybe Type)
1096 tcRnExpr hsc_env ictxt rdr_expr
1097   = initTcPrintErrors hsc_env iNTERACTIVE $
1098     setInteractiveContext hsc_env ictxt $ do {
1099
1100     (rn_expr, fvs) <- rnLExpr rdr_expr ;
1101     failIfErrsM ;
1102
1103         -- Now typecheck the expression;
1104         -- it might have a rank-2 type (e.g. :t runST)
1105     ((tc_expr, res_ty), lie)       <- getLIE (tcInferRho rn_expr) ;
1106     ((qtvs, dict_insts, _), lie_top) <- getLIE (tcSimplifyInfer smpl_doc (tyVarsOfType res_ty) lie)  ;
1107     tcSimplifyInteractive lie_top ;
1108
1109     let { all_expr_ty = mkForAllTys qtvs $
1110                         mkFunTys (map (idType . instToId) dict_insts)   $
1111                         res_ty } ;
1112     zonkTcType all_expr_ty
1113     }
1114   where
1115     smpl_doc = ptext SLIT("main expression")
1116 \end{code}
1117
1118 tcRnType just finds the kind of a type
1119
1120 \begin{code}
1121 tcRnType :: HscEnv
1122          -> InteractiveContext
1123          -> LHsType RdrName
1124          -> IO (Maybe Kind)
1125 tcRnType hsc_env ictxt rdr_type
1126   = initTcPrintErrors hsc_env iNTERACTIVE $
1127     setInteractiveContext hsc_env ictxt $ do {
1128
1129     rn_type <- rnLHsType doc rdr_type ;
1130     failIfErrsM ;
1131
1132         -- Now kind-check the type
1133     (ty', kind) <- kcHsType rn_type ;
1134     return kind
1135     }
1136   where
1137     doc = ptext SLIT("In GHCi input")
1138
1139 #endif /* GHCi */
1140 \end{code}
1141
1142
1143 %************************************************************************
1144 %*                                                                      *
1145         More GHCi stuff, to do with browsing and getting info
1146 %*                                                                      *
1147 %************************************************************************
1148
1149 \begin{code}
1150 #ifdef GHCI
1151 -- ASSUMES that the module is either in the HomePackageTable or is
1152 -- a package module with an interface on disk.  If neither of these is
1153 -- true, then the result will be an error indicating the interface
1154 -- could not be found.
1155 getModuleExports :: HscEnv -> Module -> IO (Messages, Maybe [AvailInfo])
1156 getModuleExports hsc_env mod
1157   = let
1158       ic        = hsc_IC hsc_env
1159       checkMods = ic_toplev_scope ic ++ ic_exports ic
1160     in
1161     initTc hsc_env HsSrcFile False iNTERACTIVE (tcGetModuleExports mod checkMods)
1162
1163 -- Get the export avail info and also load all orphan and family-instance
1164 -- modules.  Finally, check that the family instances of all modules in the
1165 -- interactive context are consistent (these modules are in the second
1166 -- argument).
1167 tcGetModuleExports :: Module -> [Module] -> TcM [AvailInfo]
1168 tcGetModuleExports mod directlyImpMods
1169   = do { let doc = ptext SLIT("context for compiling statements")
1170        ; iface <- initIfaceTcRn $ loadSysInterface doc mod
1171
1172                 -- Load any orphan-module and family instance-module
1173                 -- interfaces, so their instances are visible.
1174        ; loadOrphanModules (dep_orphs (mi_deps iface)) False
1175        ; loadOrphanModules (dep_finsts (mi_deps iface)) True
1176
1177                 -- Check that the family instances of all directly loaded
1178                 -- modules are consistent.
1179        ; checkFamInstConsistency (dep_finsts (mi_deps iface)) directlyImpMods
1180
1181        ; ifaceExportNames (mi_exports iface)
1182        }
1183
1184 tcRnLookupRdrName :: HscEnv -> RdrName -> IO (Maybe [Name])
1185 tcRnLookupRdrName hsc_env rdr_name
1186   = initTcPrintErrors hsc_env iNTERACTIVE $
1187     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1188     lookup_rdr_name rdr_name
1189
1190 lookup_rdr_name rdr_name = do {
1191         -- If the identifier is a constructor (begins with an
1192         -- upper-case letter), then we need to consider both
1193         -- constructor and type class identifiers.
1194     let { rdr_names = dataTcOccs rdr_name } ;
1195
1196         -- results :: [Either Messages Name]
1197     results <- mapM (tryTcErrs . lookupOccRn) rdr_names ;
1198
1199     traceRn (text "xx" <+> vcat [ppr rdr_names, ppr (map snd results)]);
1200         -- The successful lookups will be (Just name)
1201     let { (warns_s, good_names) = unzip [ (msgs, name)
1202                                         | (msgs, Just name) <- results] ;
1203           errs_s = [msgs | (msgs, Nothing) <- results] } ;
1204
1205         -- Fail if nothing good happened, else add warnings
1206     if null good_names then
1207                 -- No lookup succeeded, so
1208                 -- pick the first error message and report it
1209                 -- ToDo: If one of the errors is "could be Foo.X or Baz.X",
1210                 --       while the other is "X is not in scope",
1211                 --       we definitely want the former; but we might pick the latter
1212         do { addMessages (head errs_s) ; failM }
1213       else                      -- Add deprecation warnings
1214         mapM_ addMessages warns_s ;
1215
1216     return good_names
1217  }
1218
1219 tcRnLookupName :: HscEnv -> Name -> IO (Maybe TyThing)
1220 tcRnLookupName hsc_env name
1221   = initTcPrintErrors hsc_env iNTERACTIVE $
1222     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1223     tcRnLookupName' name
1224
1225 -- To look up a name we have to look in the local environment (tcl_lcl)
1226 -- as well as the global environment, which is what tcLookup does.
1227 -- But we also want a TyThing, so we have to convert:
1228
1229 tcRnLookupName' :: Name -> TcRn TyThing
1230 tcRnLookupName' name = do
1231    tcthing <- tcLookup name
1232    case tcthing of
1233      AGlobal thing    -> return thing
1234      ATcId{tct_id=id} -> return (AnId id)
1235      _ -> panic "tcRnLookupName'"
1236
1237 tcRnGetInfo :: HscEnv
1238             -> Name
1239             -> IO (Maybe (TyThing, Fixity, [Instance]))
1240
1241 -- Used to implemnent :info in GHCi
1242 --
1243 -- Look up a RdrName and return all the TyThings it might be
1244 -- A capitalised RdrName is given to us in the DataName namespace,
1245 -- but we want to treat it as *both* a data constructor
1246 --  *and* as a type or class constructor;
1247 -- hence the call to dataTcOccs, and we return up to two results
1248 tcRnGetInfo hsc_env name
1249   = initTcPrintErrors hsc_env iNTERACTIVE $
1250     let ictxt = hsc_IC hsc_env in
1251     setInteractiveContext hsc_env ictxt $ do
1252
1253         -- Load the interface for all unqualified types and classes
1254         -- That way we will find all the instance declarations
1255         -- (Packages have not orphan modules, and we assume that
1256         --  in the home package all relevant modules are loaded.)
1257     loadUnqualIfaces ictxt
1258
1259     thing  <- tcRnLookupName' name
1260     fixity <- lookupFixityRn name
1261     ispecs <- lookupInsts thing
1262     return (thing, fixity, ispecs)
1263
1264 lookupInsts :: TyThing -> TcM [Instance]
1265 lookupInsts (AClass cls)
1266   = do  { inst_envs <- tcGetInstEnvs
1267         ; return (classInstances inst_envs cls) }
1268
1269 lookupInsts (ATyCon tc)
1270   = do  { eps <- getEps -- Load all instances for all classes that are
1271                         -- in the type environment (which are all the ones
1272                         -- we've seen in any interface file so far)
1273         ; (pkg_ie, home_ie) <- tcGetInstEnvs    -- Search all
1274         ; return [ ispec
1275                  | ispec <- instEnvElts home_ie ++ instEnvElts pkg_ie
1276                  , let dfun = instanceDFunId ispec
1277                  , relevant dfun ] }
1278   where
1279     relevant df = tc_name `elemNameSet` tyClsNamesOfDFunHead (idType df)
1280     tc_name     = tyConName tc
1281
1282 lookupInsts other = return []
1283
1284 loadUnqualIfaces :: InteractiveContext -> TcM ()
1285 -- Load the home module for everything that is in scope unqualified
1286 -- This is so that we can accurately report the instances for
1287 -- something
1288 loadUnqualIfaces ictxt
1289   = initIfaceTcRn $
1290     mapM_ (loadSysInterface doc) (moduleSetElts (mkModuleSet unqual_mods))
1291   where
1292     unqual_mods = [ nameModule name
1293                   | gre <- globalRdrEnvElts (ic_rn_gbl_env ictxt),
1294                     let name = gre_name gre,
1295                     not (isInternalName name),
1296                     isTcOcc (nameOccName name),  -- Types and classes only
1297                     unQualOK gre ]               -- In scope unqualified
1298     doc = ptext SLIT("Need interface for module whose export(s) are in scope unqualified")
1299 #endif /* GHCI */
1300 \end{code}
1301
1302 %************************************************************************
1303 %*                                                                      *
1304                 Degugging output
1305 %*                                                                      *
1306 %************************************************************************
1307
1308 \begin{code}
1309 rnDump :: SDoc -> TcRn ()
1310 -- Dump, with a banner, if -ddump-rn
1311 rnDump doc = do { dumpOptTcRn Opt_D_dump_rn (mkDumpDoc "Renamer" doc) }
1312
1313 tcDump :: TcGblEnv -> TcRn ()
1314 tcDump env
1315  = do { dflags <- getDOpts ;
1316
1317         -- Dump short output if -ddump-types or -ddump-tc
1318         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1319             (dumpTcRn short_dump) ;
1320
1321         -- Dump bindings if -ddump-tc
1322         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump)
1323    }
1324   where
1325     short_dump = pprTcGblEnv env
1326     full_dump  = pprLHsBinds (tcg_binds env)
1327         -- NB: foreign x-d's have undefined's in their types;
1328         --     hence can't show the tc_fords
1329
1330 tcCoreDump mod_guts
1331  = do { dflags <- getDOpts ;
1332         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1333             (dumpTcRn (pprModGuts mod_guts)) ;
1334
1335         -- Dump bindings if -ddump-tc
1336         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump) }
1337   where
1338     full_dump = pprCoreBindings (mg_binds mod_guts)
1339
1340 -- It's unpleasant having both pprModGuts and pprModDetails here
1341 pprTcGblEnv :: TcGblEnv -> SDoc
1342 pprTcGblEnv (TcGblEnv { tcg_type_env  = type_env,
1343                         tcg_insts     = insts,
1344                         tcg_fam_insts = fam_insts,
1345                         tcg_rules     = rules,
1346                         tcg_imports   = imports })
1347   = vcat [ ppr_types insts type_env
1348          , ppr_tycons fam_insts type_env
1349          , ppr_insts insts
1350          , ppr_fam_insts fam_insts
1351          , vcat (map ppr rules)
1352          , ppr_gen_tycons (typeEnvTyCons type_env)
1353          , ptext SLIT("Dependent modules:") <+> ppr (eltsUFM (imp_dep_mods imports))
1354          , ptext SLIT("Dependent packages:") <+> ppr (imp_dep_pkgs imports)]
1355
1356 pprModGuts :: ModGuts -> SDoc
1357 pprModGuts (ModGuts { mg_types = type_env,
1358                       mg_rules = rules })
1359   = vcat [ ppr_types [] type_env,
1360            ppr_rules rules ]
1361
1362 ppr_types :: [Instance] -> TypeEnv -> SDoc
1363 ppr_types insts type_env
1364   = text "TYPE SIGNATURES" $$ nest 4 (ppr_sigs ids)
1365   where
1366     dfun_ids = map instanceDFunId insts
1367     ids = [id | id <- typeEnvIds type_env, want_sig id]
1368     want_sig id | opt_PprStyle_Debug = True
1369                 | otherwise          = isLocalId id &&
1370                                        isExternalName (idName id) &&
1371                                        not (id `elem` dfun_ids)
1372         -- isLocalId ignores data constructors, records selectors etc.
1373         -- The isExternalName ignores local dictionary and method bindings
1374         -- that the type checker has invented.  Top-level user-defined things
1375         -- have External names.
1376
1377 ppr_tycons :: [FamInst] -> TypeEnv -> SDoc
1378 ppr_tycons fam_insts type_env
1379   = text "TYPE CONSTRUCTORS" $$ nest 4 (ppr_tydecls tycons)
1380   where
1381     fi_tycons = map famInstTyCon fam_insts
1382     tycons = [tycon | tycon <- typeEnvTyCons type_env, want_tycon tycon]
1383     want_tycon tycon | opt_PprStyle_Debug = True
1384                      | otherwise          = not (isImplicitTyCon tycon) &&
1385                                             isExternalName (tyConName tycon) &&
1386                                             not (tycon `elem` fi_tycons)
1387
1388 ppr_insts :: [Instance] -> SDoc
1389 ppr_insts []     = empty
1390 ppr_insts ispecs = text "INSTANCES" $$ nest 2 (pprInstances ispecs)
1391
1392 ppr_fam_insts :: [FamInst] -> SDoc
1393 ppr_fam_insts []        = empty
1394 ppr_fam_insts fam_insts =
1395   text "FAMILY INSTANCES" $$ nest 2 (pprFamInsts fam_insts)
1396
1397 ppr_sigs :: [Var] -> SDoc
1398 ppr_sigs ids
1399         -- Print type signatures; sort by OccName
1400   = vcat (map ppr_sig (sortLe le_sig ids))
1401   where
1402     le_sig id1 id2 = getOccName id1 <= getOccName id2
1403     ppr_sig id = ppr id <+> dcolon <+> ppr (tidyTopType (idType id))
1404
1405 ppr_tydecls :: [TyCon] -> SDoc
1406 ppr_tydecls tycons
1407         -- Print type constructor info; sort by OccName
1408   = vcat (map ppr_tycon (sortLe le_sig tycons))
1409   where
1410     le_sig tycon1 tycon2 = getOccName tycon1 <= getOccName tycon2
1411     ppr_tycon tycon
1412       | isCoercionTyCon tycon = ptext SLIT("coercion") <+> ppr tycon
1413       | otherwise             = ppr (tyThingToIfaceDecl (ATyCon tycon))
1414
1415 ppr_rules :: [CoreRule] -> SDoc
1416 ppr_rules [] = empty
1417 ppr_rules rs = vcat [ptext SLIT("{-# RULES"),
1418                       nest 4 (pprRules rs),
1419                       ptext SLIT("#-}")]
1420
1421 ppr_gen_tycons []  = empty
1422 ppr_gen_tycons tcs = vcat [ptext SLIT("Tycons with generics:"),
1423                            nest 2 (fsep (map ppr (filter tyConHasGenerics tcs)))]
1424 \end{code}