compiler/typecheck/TcRnDriver.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5 \section[TcModule]{Typechecking a whole module}
   6
   7 \begin{code}
   8 module TcRnDriver (
   9 #ifdef GHCI
  10         tcRnStmt, tcRnExpr, tcRnType,
  11         tcRnLookupRdrName,
  12         getModuleExports,
  13 #endif
  14         tcRnLookupName,
  15         tcRnGetInfo,
  16         tcRnModule,
  17         tcTopSrcDecls,
  18         tcRnExtCore
  19     ) where
  20
  21 #ifdef GHCI
  22 import {-# SOURCE #-} TcSplice ( tcSpliceDecls )
  23 #endif
  24
  25 import DynFlags
  26 import StaticFlags
  27 import HsSyn
  28 import PrelNames
  29 import RdrName
  30 import TcHsSyn
  31 import TcExpr
  32 import TcRnMonad
  33 import Coercion
  34 import FamInst
  35 import InstEnv
  36 import FamInstEnv
  37 import TcAnnotations
  38 import TcBinds
  39 import TcType   ( tidyTopType )
  40 import TcDefaults
  41 import TcEnv
  42 import TcRules
  43 import TcForeign
  44 import TcInstDcls
  45 import TcIface
  46 import TcMType
  47 import MkIface
  48 import IfaceSyn
  49 import TcSimplify
  50 import TcTyClsDecls
  51 import LoadIface
  52 import RnNames
  53 import RnEnv
  54 import RnSource
  55 import PprCore
  56 import CoreSyn
  57 import ErrUtils
  58 import Id
  59 import VarEnv
  60 import Var
  61 import Module
  62 import UniqFM
  63 import Name
  64 import NameEnv
  65 import NameSet
  66 import TyCon
  67 import TysPrim
  68 import SrcLoc
  69 import HscTypes
  70 import ListSetOps
  71 import Outputable
  72 import DataCon
  73 import Type
  74 import Class
  75 import TcType   ( tyClsNamesOfDFunHead )
  76 import Inst     ( tcGetInstEnvs )
  77 import Data.List ( sortBy )
  78
  79 #ifdef GHCI
  80 import TcType   ( isUnitTy, isTauTy )
  81 import CoreUtils( mkPiTypes )
  82 import TcHsType
  83 import TcMatches
  84 import RnTypes
  85 import RnExpr
  86 import IfaceEnv
  87 import MkId
  88 import BasicTypes
  89 import TidyPgm    ( globaliseAndTidyId )
  90 import TysWiredIn ( unitTy, mkListTy )
  91 #endif
  92
  93 import FastString
  94 import Maybes
  95 import Util
  96 import Bag
  97
  98 import Control.Monad
  99
 100 #include "HsVersions.h"
 101 \end{code}
 102
 103 %************************************************************************
 104 %*                                                                      *
 105         Typecheck and rename a module
 106 %*                                                                      *
 107 %************************************************************************
 108
 109
 110 \begin{code}
 111 tcRnModule :: HscEnv
 112            -> HscSource
 113            -> Bool              -- True <=> save renamed syntax
 114            -> Located (HsModule RdrName)
 115            -> IO (Messages, Maybe TcGblEnv)
 116
 117 tcRnModule hsc_env hsc_src save_rn_syntax
 118          (L loc (HsModule maybe_mod export_ies
 119                           import_decls local_decls mod_deprec
 120                           maybe_doc_hdr))
 121  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 122
 123    let { this_pkg = thisPackage (hsc_dflags hsc_env) ;
 124          this_mod = case maybe_mod of
 125                         Nothing  -> mAIN        -- 'module M where' is omitted
 126                         Just (L _ mod) -> mkModule this_pkg mod } ;
 127                                                 -- The normal case
 128
 129    initTc hsc_env hsc_src save_rn_syntax this_mod $
 130    setSrcSpan loc $
 131    do {         -- Deal with imports;
 132         tcg_env <- tcRnImports hsc_env this_mod import_decls ;
 133         setGblEnv tcg_env               $ do {
 134
 135                 -- Load the hi-boot interface for this module, if any
 136                 -- We do this now so that the boot_names can be passed
 137                 -- to tcTyAndClassDecls, because the boot_names are
 138                 -- automatically considered to be loop breakers
 139                 --
 140                 -- Do this *after* tcRnImports, so that we know whether
 141                 -- a module that we import imports us; and hence whether to
 142                 -- look for a hi-boot file
 143         boot_iface <- tcHiBootIface hsc_src this_mod ;
 144
 145                 -- Rename and type check the declarations
 146         traceRn (text "rn1a") ;
 147         tcg_env <- if isHsBoot hsc_src then
 148                         tcRnHsBootDecls local_decls
 149                    else
 150                         tcRnSrcDecls boot_iface local_decls ;
 151         setGblEnv tcg_env               $ do {
 152
 153                 -- Report the use of any deprecated things
 154                 -- We do this *before* processsing the export list so
 155                 -- that we don't bleat about re-exporting a deprecated
 156                 -- thing (especially via 'module Foo' export item)
 157                 -- That is, only uses in the *body* of the module are complained about
 158         traceRn (text "rn3") ;
 159         failIfErrsM ;   -- finishWarnings crashes sometimes
 160                         -- as a result of typechecker repairs (e.g. unboundNames)
 161         tcg_env <- finishWarnings (hsc_dflags hsc_env) mod_deprec tcg_env ;
 162
 163                 -- Process the export list
 164         traceRn (text "rn4a: before exports");
 165         tcg_env <- rnExports (isJust maybe_mod) export_ies tcg_env ;
 166         traceRn (text "rn4b: after exportss") ;
 167
 168                 -- Check that main is exported (must be after rnExports)
 169         checkMainExported tcg_env ;
 170
 171         -- Compare the hi-boot iface (if any) with the real thing
 172         -- Must be done after processing the exports
 173         tcg_env <- checkHiBootIface tcg_env boot_iface ;
 174
 175         -- The new type env is already available to stuff slurped from
 176         -- interface files, via TcEnv.updateGlobalTypeEnv
 177         -- It's important that this includes the stuff in checkHiBootIface,
 178         -- because the latter might add new bindings for boot_dfuns,
 179         -- which may be mentioned in imported unfoldings
 180
 181                 -- Don't need to rename the Haddock documentation,
 182                 -- it's not parsed by GHC anymore.
 183         tcg_env <- return (tcg_env { tcg_doc_hdr = maybe_doc_hdr }) ;
 184
 185                 -- Report unused names
 186         reportUnusedNames export_ies tcg_env ;
 187
 188                 -- Dump output and return
 189         tcDump tcg_env ;
 190         return tcg_env
 191     }}}}
 192 \end{code}
 193
 194
 195 %************************************************************************
 196 %*                                                                      *
 197                 Import declarations
 198 %*                                                                      *
 199 %************************************************************************
 200
 201 \begin{code}
 202 tcRnImports :: HscEnv -> Module -> [LImportDecl RdrName] -> TcM TcGblEnv
 203 tcRnImports hsc_env this_mod import_decls
 204   = do  { (rn_imports, rdr_env, imports,hpc_info) <- rnImports import_decls ;
 205
 206         ; let { dep_mods :: ModuleNameEnv (ModuleName, IsBootInterface)
 207               ; dep_mods = imp_dep_mods imports
 208
 209                 -- We want instance declarations from all home-package
 210                 -- modules below this one, including boot modules, except
 211                 -- ourselves.  The 'except ourselves' is so that we don't
 212                 -- get the instances from this module's hs-boot file
 213               ; want_instances :: ModuleName -> Bool
 214               ; want_instances mod = mod `elemUFM` dep_mods
 215                                    && mod /= moduleName this_mod
 216               ; (home_insts, home_fam_insts) = hptInstances hsc_env
 217                                                             want_instances
 218               } ;
 219
 220                 -- Record boot-file info in the EPS, so that it's
 221                 -- visible to loadHiBootInterface in tcRnSrcDecls,
 222                 -- and any other incrementally-performed imports
 223         ; updateEps_ (\eps -> eps { eps_is_boot = dep_mods }) ;
 224
 225                 -- Update the gbl env
 226         ; updGblEnv ( \ gbl ->
 227             gbl {
 228               tcg_rdr_env      = plusOccEnv (tcg_rdr_env gbl) rdr_env,
 229               tcg_imports      = tcg_imports gbl `plusImportAvails` imports,
 230               tcg_rn_imports   = rn_imports,
 231               tcg_inst_env     = extendInstEnvList (tcg_inst_env gbl) home_insts,
 232               tcg_fam_inst_env = extendFamInstEnvList (tcg_fam_inst_env gbl)
 233                                                       home_fam_insts,
 234               tcg_hpc          = hpc_info
 235             }) $ do {
 236
 237         ; traceRn (text "rn1" <+> ppr (imp_dep_mods imports))
 238                 -- Fail if there are any errors so far
 239                 -- The error printing (if needed) takes advantage
 240                 -- of the tcg_env we have now set
 241 --      ; traceIf (text "rdr_env: " <+> ppr rdr_env)
 242         ; failIfErrsM
 243
 244                 -- Load any orphan-module and family instance-module
 245                 -- interfaces, so that their rules and instance decls will be
 246                 -- found.
 247         ; loadOrphanModules (imp_orphs  imports) False
 248         ; loadOrphanModules (imp_finsts imports) True
 249
 250                 -- Check type-familily consistency
 251         ; traceRn (text "rn1: checking family instance consistency")
 252         ; let { dir_imp_mods = moduleEnvKeys
 253                              . imp_mods
 254                              $ imports }
 255         ; checkFamInstConsistency (imp_finsts imports) dir_imp_mods ;
 256
 257         ; getGblEnv } }
 258 \end{code}
 259
 260
 261 %************************************************************************
 262 %*                                                                      *
 263         Type-checking external-core modules
 264 %*                                                                      *
 265 %************************************************************************
 266
 267 \begin{code}
 268 tcRnExtCore :: HscEnv
 269             -> HsExtCore RdrName
 270             -> IO (Messages, Maybe ModGuts)
 271         -- Nothing => some error occurred
 272
 273 tcRnExtCore hsc_env (HsExtCore this_mod decls src_binds)
 274         -- The decls are IfaceDecls; all names are original names
 275  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 276
 277    initTc hsc_env ExtCoreFile False this_mod $ do {
 278
 279    let { ldecls  = map noLoc decls } ;
 280
 281        -- bring the type and class decls into scope
 282        -- ToDo: check that this doesn't need to extract the val binds.
 283        --       It seems that only the type and class decls need to be in scope below because
 284        --          (a) tcTyAndClassDecls doesn't need the val binds, and
 285        --          (b) tcExtCoreBindings doesn't need anything
 286        --              (in fact, it might not even need to be in the scope of
 287        --               this tcg_env at all)
 288    avails  <- getLocalNonValBinders (mkFakeGroup ldecls) ;
 289    tc_envs <- extendGlobalRdrEnvRn avails emptyFsEnv {- no fixity decls -} ;
 290
 291    setEnvs tc_envs $ do {
 292
 293    rn_decls <- checkNoErrs $ rnTyClDecls ldecls ;
 294
 295         -- Dump trace of renaming part
 296    rnDump (ppr rn_decls) ;
 297
 298         -- Typecheck them all together so that
 299         -- any mutually recursive types are done right
 300         -- Just discard the auxiliary bindings; they are generated
 301         -- only for Haskell source code, and should already be in Core
 302    (tcg_env, _aux_binds, _dm_ids) <- tcTyAndClassDecls emptyModDetails rn_decls ;
 303
 304    setGblEnv tcg_env $ do {
 305         -- Make the new type env available to stuff slurped from interface files
 306
 307         -- Now the core bindings
 308    core_binds <- initIfaceExtCore (tcExtCoreBindings src_binds) ;
 309
 310         -- Wrap up
 311    let {
 312         bndrs      = bindersOfBinds core_binds ;
 313         my_exports = map (Avail . idName) bndrs ;
 314                 -- ToDo: export the data types also?
 315
 316         final_type_env =
 317              extendTypeEnvWithIds (tcg_type_env tcg_env) bndrs ;
 318
 319         mod_guts = ModGuts {    mg_module    = this_mod,
 320                                 mg_boot      = False,
 321                                 mg_used_names = emptyNameSet, -- ToDo: compute usage
 322                                 mg_dir_imps  = emptyModuleEnv, -- ??
 323                                 mg_deps      = noDependencies,  -- ??
 324                                 mg_exports   = my_exports,
 325                                 mg_types     = final_type_env,
 326                                 mg_insts     = tcg_insts tcg_env,
 327                                 mg_fam_insts = tcg_fam_insts tcg_env,
 328                                 mg_inst_env  = tcg_inst_env tcg_env,
 329                                 mg_fam_inst_env = tcg_fam_inst_env tcg_env,
 330                                 mg_rules     = [],
 331                                 mg_anns      = [],
 332                                 mg_binds     = core_binds,
 333
 334                                 -- Stubs
 335                                 mg_rdr_env   = emptyGlobalRdrEnv,
 336                                 mg_fix_env   = emptyFixityEnv,
 337                                 mg_warns     = NoWarnings,
 338                                 mg_foreign   = NoStubs,
 339                                 mg_hpc_info  = emptyHpcInfo False,
 340                                 mg_modBreaks = emptyModBreaks,
 341                                 mg_vect_info = noVectInfo
 342                     } } ;
 343
 344    tcCoreDump mod_guts ;
 345
 346    return mod_guts
 347    }}}}
 348
 349 mkFakeGroup :: [LTyClDecl a] -> HsGroup a
 350 mkFakeGroup decls -- Rather clumsy; lots of unused fields
 351   = emptyRdrGroup { hs_tyclds = decls }
 352 \end{code}
 353
 354
 355 %************************************************************************
 356 %*                                                                      *
 357         Type-checking the top level of a module
 358 %*                                                                      *
 359 %************************************************************************
 360
 361 \begin{code}
 362 tcRnSrcDecls :: ModDetails -> [LHsDecl RdrName] -> TcM TcGblEnv
 363         -- Returns the variables free in the decls
 364         -- Reason: solely to report unused imports and bindings
 365 tcRnSrcDecls boot_iface decls
 366  = do {         -- Do all the declarations
 367         (tc_envs, lie) <- captureConstraints $ tc_rn_src_decls boot_iface decls ;
 368       ; traceTc "Tc8" empty ;
 369       ; setEnvs tc_envs $
 370    do {
 371
 372              --         Finish simplifying class constraints
 373              --
 374              -- simplifyTop deals with constant or ambiguous InstIds.
 375              -- How could there be ambiguous ones?  They can only arise if a
 376              -- top-level decl falls under the monomorphism restriction
 377              -- and no subsequent decl instantiates its type.
 378              --
 379              -- We do this after checkMain, so that we use the type info
 380              -- thaat checkMain adds
 381              --
 382              -- We do it with both global and local env in scope:
 383              --  * the global env exposes the instances to simplifyTop
 384              --  * the local env exposes the local Ids to simplifyTop,
 385              --    so that we get better error messages (monomorphism restriction)
 386         new_ev_binds <- simplifyTop lie ;
 387         traceTc "Tc9" empty ;
 388
 389         failIfErrsM ;   -- Don't zonk if there have been errors
 390                         -- It's a waste of time; and we may get debug warnings
 391                         -- about strangely-typed TyCons!
 392
 393         -- Zonk the final code.  This must be done last.
 394         -- Even simplifyTop may do some unification.
 395         -- This pass also warns about missing type signatures
 396         let { (tcg_env, _) = tc_envs
 397             ; TcGblEnv { tcg_type_env  = type_env,
 398                          tcg_binds     = binds,
 399                          tcg_sigs      = sig_ns,
 400                          tcg_ev_binds  = cur_ev_binds,
 401                          tcg_imp_specs = imp_specs,
 402                          tcg_rules     = rules,
 403                          tcg_fords     = fords } = tcg_env
 404             ; all_ev_binds = cur_ev_binds `unionBags` new_ev_binds } ;
 405
 406         (bind_ids, ev_binds', binds', fords', imp_specs', rules')
 407             <- zonkTopDecls all_ev_binds binds sig_ns rules imp_specs fords ;
 408
 409         let { final_type_env = extendTypeEnvWithIds type_env bind_ids
 410             ; tcg_env' = tcg_env { tcg_binds    = binds',
 411                                    tcg_ev_binds = ev_binds',
 412                                    tcg_imp_specs = imp_specs',
 413                                    tcg_rules    = rules',
 414                                    tcg_fords    = fords' } } ;
 415
 416         setGlobalTypeEnv tcg_env' final_type_env
 417    } }
 418
 419 tc_rn_src_decls :: ModDetails -> [LHsDecl RdrName] -> TcM (TcGblEnv, TcLclEnv)
 420 -- Loops around dealing with each top level inter-splice group
 421 -- in turn, until it's dealt with the entire module
 422 tc_rn_src_decls boot_details ds
 423  = do { (first_group, group_tail) <- findSplice ds  ;
 424                 -- If ds is [] we get ([], Nothing)
 425
 426         -- Deal with decls up to, but not including, the first splice
 427         (tcg_env, rn_decls) <- rnTopSrcDecls first_group ;
 428                 -- rnTopSrcDecls fails if there are any errors
 429
 430         (tcg_env, tcl_env) <- setGblEnv tcg_env $
 431                               tcTopSrcDecls boot_details rn_decls ;
 432
 433         -- If there is no splice, we're nearly done
 434         setEnvs (tcg_env, tcl_env) $
 435         case group_tail of {
 436            Nothing -> do { tcg_env <- checkMain ;       -- Check for `main'
 437                            return (tcg_env, tcl_env)
 438                       } ;
 439
 440 #ifndef GHCI
 441         -- There shouldn't be a splice
 442            Just (SpliceDecl {}, _) -> do {
 443         failWithTc (text "Can't do a top-level splice; need a bootstrapped compiler")
 444 #else
 445         -- If there's a splice, we must carry on
 446            Just (SpliceDecl splice_expr _, rest_ds) -> do {
 447
 448         -- Rename the splice expression, and get its supporting decls
 449         (rn_splice_expr, splice_fvs) <- checkNoErrs (rnLExpr splice_expr) ;
 450                 -- checkNoErrs: don't typecheck if renaming failed
 451         rnDump (ppr rn_splice_expr) ;
 452
 453         -- Execute the splice
 454         spliced_decls <- tcSpliceDecls rn_splice_expr ;
 455
 456         -- Glue them on the front of the remaining decls and loop
 457         setGblEnv (tcg_env `addTcgDUs` usesOnly splice_fvs) $
 458         tc_rn_src_decls boot_details (spliced_decls ++ rest_ds)
 459 #endif /* GHCI */
 460     } } }
 461 \end{code}
 462
 463 %************************************************************************
 464 %*                                                                      *
 465         Compiling hs-boot source files, and
 466         comparing the hi-boot interface with the real thing
 467 %*                                                                      *
 468 %************************************************************************
 469
 470 \begin{code}
 471 tcRnHsBootDecls :: [LHsDecl RdrName] -> TcM TcGblEnv
 472 tcRnHsBootDecls decls
 473    = do { (first_group, group_tail) <- findSplice decls
 474
 475                 -- Rename the declarations
 476         ; (tcg_env, HsGroup {
 477                    hs_tyclds = tycl_decls,
 478                    hs_instds = inst_decls,
 479                    hs_derivds = deriv_decls,
 480                    hs_fords  = for_decls,
 481                    hs_defds  = def_decls,
 482                    hs_ruleds = rule_decls,
 483                    hs_annds  = _,
 484                    hs_valds  = val_binds }) <- rnTopSrcDecls first_group
 485         ; (gbl_env, lie) <- captureConstraints $ setGblEnv tcg_env $ do {
 486
 487
 488                 -- Check for illegal declarations
 489         ; case group_tail of
 490              Just (SpliceDecl d _, _) -> badBootDecl "splice" d
 491              Nothing                  -> return ()
 492         ; mapM_ (badBootDecl "foreign") for_decls
 493         ; mapM_ (badBootDecl "default") def_decls
 494         ; mapM_ (badBootDecl "rule")    rule_decls
 495
 496                 -- Typecheck type/class decls
 497         ; traceTc "Tc2" empty
 498         ; (tcg_env, aux_binds, dm_ids)
 499                <- tcTyAndClassDecls emptyModDetails tycl_decls
 500         ; setGblEnv tcg_env    $
 501           tcExtendIdEnv dm_ids $ do {
 502
 503                 -- Typecheck instance decls
 504                 -- Family instance declarations are rejected here
 505         ; traceTc "Tc3" empty
 506         ; (tcg_env, inst_infos, _deriv_binds)
 507             <- tcInstDecls1 tycl_decls inst_decls deriv_decls
 508         ; setGblEnv tcg_env     $ do {
 509
 510                 -- Typecheck value declarations
 511         ; traceTc "Tc5" empty
 512         ; val_ids <- tcHsBootSigs val_binds
 513
 514                 -- Wrap up
 515                 -- No simplification or zonking to do
 516         ; traceTc "Tc7a" empty
 517         ; gbl_env <- getGblEnv
 518
 519                 -- Make the final type-env
 520                 -- Include the dfun_ids so that their type sigs
 521                 -- are written into the interface file.
 522                 -- And similarly the aux_ids from aux_binds
 523         ; let { type_env0 = tcg_type_env gbl_env
 524               ; type_env1 = extendTypeEnvWithIds type_env0 val_ids
 525               ; type_env2 = extendTypeEnvWithIds type_env1 dfun_ids
 526               ; type_env3 = extendTypeEnvWithIds type_env2 aux_ids
 527               ; dfun_ids = map iDFunId inst_infos
 528               ; aux_ids  = case aux_binds of
 529                              ValBindsOut _ sigs -> [id | L _ (IdSig id) <- sigs]
 530                              _                  -> panic "tcRnHsBoodDecls"
 531               }
 532
 533         ; setGlobalTypeEnv gbl_env type_env3
 534    }}}
 535    ; traceTc "boot" (ppr lie); return gbl_env }
 536
 537 badBootDecl :: String -> Located decl -> TcM ()
 538 badBootDecl what (L loc _)
 539   = addErrAt loc (char 'A' <+> text what
 540       <+> ptext (sLit "declaration is not (currently) allowed in a hs-boot file"))
 541 \end{code}
 542
 543 Once we've typechecked the body of the module, we want to compare what
 544 we've found (gathered in a TypeEnv) with the hi-boot details (if any).
 545
 546 \begin{code}
 547 checkHiBootIface :: TcGblEnv -> ModDetails -> TcM TcGblEnv
 548 -- Compare the hi-boot file for this module (if there is one)
 549 -- with the type environment we've just come up with
 550 -- In the common case where there is no hi-boot file, the list
 551 -- of boot_names is empty.
 552 --
 553 -- The bindings we return give bindings for the dfuns defined in the
 554 -- hs-boot file, such as        $fbEqT = $fEqT
 555
 556 checkHiBootIface
 557         tcg_env@(TcGblEnv { tcg_src = hs_src, tcg_binds = binds,
 558                             tcg_insts = local_insts,
 559                             tcg_type_env = local_type_env, tcg_exports = local_exports })
 560         (ModDetails { md_insts = boot_insts, md_fam_insts = boot_fam_insts,
 561                       md_types = boot_type_env, md_exports = boot_exports })
 562   | isHsBoot hs_src     -- Current module is already a hs-boot file!
 563   = return tcg_env
 564
 565   | otherwise
 566   = do  { traceTc "checkHiBootIface" $ vcat
 567              [ ppr boot_type_env, ppr boot_insts, ppr boot_exports]
 568
 569                 -- Check the exports of the boot module, one by one
 570         ; mapM_ check_export boot_exports
 571
 572                 -- Check for no family instances
 573         ; unless (null boot_fam_insts) $
 574             panic ("TcRnDriver.checkHiBootIface: Cannot handle family " ++
 575                    "instances in boot files yet...")
 576             -- FIXME: Why?  The actual comparison is not hard, but what would
 577             --        be the equivalent to the dfun bindings returned for class
 578             --        instances?  We can't easily equate tycons...
 579
 580                 -- Check instance declarations
 581         ; mb_dfun_prs <- mapM check_inst boot_insts
 582         ; let dfun_prs   = catMaybes mb_dfun_prs
 583               boot_dfuns = map fst dfun_prs
 584               dfun_binds = listToBag [ mkVarBind boot_dfun (nlHsVar dfun)
 585                                      | (boot_dfun, dfun) <- dfun_prs ]
 586               type_env'  = extendTypeEnvWithIds local_type_env boot_dfuns
 587               tcg_env'   = tcg_env { tcg_binds = binds `unionBags` dfun_binds }
 588
 589         ; failIfErrsM
 590         ; setGlobalTypeEnv tcg_env' type_env' }
 591              -- Update the global type env *including* the knot-tied one
 592              -- so that if the source module reads in an interface unfolding
 593              -- mentioning one of the dfuns from the boot module, then it
 594              -- can "see" that boot dfun.   See Trac #4003
 595   where
 596     check_export boot_avail     -- boot_avail is exported by the boot iface
 597       | name `elem` dfun_names = return ()
 598       | isWiredInName name     = return ()      -- No checking for wired-in names.  In particular,
 599                                                 -- 'error' is handled by a rather gross hack
 600                                                 -- (see comments in GHC.Err.hs-boot)
 601
 602         -- Check that the actual module exports the same thing
 603       | not (null missing_names)
 604       = addErrAt (nameSrcSpan (head missing_names))
 605                  (missingBootThing (head missing_names) "exported by")
 606
 607         -- If the boot module does not *define* the thing, we are done
 608         -- (it simply re-exports it, and names match, so nothing further to do)
 609       | isNothing mb_boot_thing = return ()
 610
 611         -- Check that the actual module also defines the thing, and
 612         -- then compare the definitions
 613       | Just real_thing <- lookupTypeEnv local_type_env name,
 614         Just boot_thing <- mb_boot_thing
 615       = when (not (checkBootDecl boot_thing real_thing))
 616             $ addErrAt (nameSrcSpan (getName boot_thing))
 617                        (let boot_decl = tyThingToIfaceDecl
 618                                                (fromJust mb_boot_thing)
 619                             real_decl = tyThingToIfaceDecl real_thing
 620                         in bootMisMatch real_thing boot_decl real_decl)
 621
 622       | otherwise
 623       = addErrTc (missingBootThing name "defined in")
 624       where
 625         name          = availName boot_avail
 626         mb_boot_thing = lookupTypeEnv boot_type_env name
 627         missing_names = case lookupNameEnv local_export_env name of
 628                           Nothing    -> [name]
 629                           Just avail -> availNames boot_avail `minusList` availNames avail
 630
 631     dfun_names = map getName boot_insts
 632
 633     local_export_env :: NameEnv AvailInfo
 634     local_export_env = availsToNameEnv local_exports
 635
 636     check_inst :: Instance -> TcM (Maybe (Id, Id))
 637         -- Returns a pair of the boot dfun in terms of the equivalent real dfun
 638     check_inst boot_inst
 639         = case [dfun | inst <- local_insts,
 640                        let dfun = instanceDFunId inst,
 641                        idType dfun `tcEqType` boot_inst_ty ] of
 642             [] -> do { addErrTc (instMisMatch boot_inst); return Nothing }
 643             (dfun:_) -> return (Just (local_boot_dfun, dfun))
 644         where
 645           boot_dfun = instanceDFunId boot_inst
 646           boot_inst_ty = idType boot_dfun
 647           local_boot_dfun = Id.mkExportedLocalId (idName boot_dfun) boot_inst_ty
 648
 649
 650 -- This has to compare the TyThing from the .hi-boot file to the TyThing
 651 -- in the current source file.  We must be careful to allow alpha-renaming
 652 -- where appropriate, and also the boot declaration is allowed to omit
 653 -- constructors and class methods.
 654 --
 655 -- See rnfail055 for a good test of this stuff.
 656
 657 checkBootDecl :: TyThing -> TyThing -> Bool
 658
 659 checkBootDecl (AnId id1) (AnId id2)
 660   = ASSERT(id1 == id2)
 661     (idType id1 `tcEqType` idType id2)
 662
 663 checkBootDecl (ATyCon tc1) (ATyCon tc2)
 664   = checkBootTyCon tc1 tc2
 665
 666 checkBootDecl (AClass c1)  (AClass c2)
 667   = let
 668        (clas_tyvars1, clas_fds1, sc_theta1, _, ats1, op_stuff1)
 669           = classExtraBigSig c1
 670        (clas_tyvars2, clas_fds2, sc_theta2, _, ats2, op_stuff2)
 671           = classExtraBigSig c2
 672
 673        env0 = mkRnEnv2 emptyInScopeSet
 674        env = rnBndrs2 env0 clas_tyvars1 clas_tyvars2
 675
 676        eqSig (id1, def_meth1) (id2, def_meth2)
 677          = idName id1 == idName id2 &&
 678            tcEqTypeX env op_ty1 op_ty2 &&
 679            def_meth1 == def_meth2
 680          where
 681           (_, rho_ty1) = splitForAllTys (idType id1)
 682           op_ty1 = funResultTy rho_ty1
 683           (_, rho_ty2) = splitForAllTys (idType id2)
 684           op_ty2 = funResultTy rho_ty2
 685
 686        eqFD (as1,bs1) (as2,bs2) =
 687          eqListBy (tcEqTypeX env) (mkTyVarTys as1) (mkTyVarTys as2) &&
 688          eqListBy (tcEqTypeX env) (mkTyVarTys bs1) (mkTyVarTys bs2)
 689
 690        same_kind tv1 tv2 = eqKind (tyVarKind tv1) (tyVarKind tv2)
 691     in
 692        eqListBy same_kind clas_tyvars1 clas_tyvars2 &&
 693              -- Checks kind of class
 694        eqListBy eqFD clas_fds1 clas_fds2 &&
 695        (null sc_theta1 && null op_stuff1 && null ats1
 696         ||   -- Above tests for an "abstract" class
 697         eqListBy (tcEqPredX env) sc_theta1 sc_theta2 &&
 698         eqListBy eqSig op_stuff1 op_stuff2 &&
 699         eqListBy checkBootTyCon ats1 ats2)
 700
 701 checkBootDecl (ADataCon dc1) (ADataCon _)
 702   = pprPanic "checkBootDecl" (ppr dc1)
 703
 704 checkBootDecl _ _ = False -- probably shouldn't happen
 705
 706 ----------------
 707 checkBootTyCon :: TyCon -> TyCon -> Bool
 708 checkBootTyCon tc1 tc2
 709   | not (eqKind (tyConKind tc1) (tyConKind tc2))
 710   = False       -- First off, check the kind
 711
 712   | isSynTyCon tc1 && isSynTyCon tc2
 713   = ASSERT(tc1 == tc2)
 714     let tvs1 = tyConTyVars tc1; tvs2 = tyConTyVars tc2
 715         env = rnBndrs2 env0 tvs1 tvs2
 716
 717         eqSynRhs SynFamilyTyCon SynFamilyTyCon
 718             = True
 719         eqSynRhs (SynonymTyCon t1) (SynonymTyCon t2)
 720             = tcEqTypeX env t1 t2
 721         eqSynRhs _ _ = False
 722     in
 723     equalLength tvs1 tvs2 &&
 724     eqSynRhs (synTyConRhs tc1) (synTyConRhs tc2)
 725
 726   | isAlgTyCon tc1 && isAlgTyCon tc2
 727   = ASSERT(tc1 == tc2)
 728     eqKind (tyConKind tc1) (tyConKind tc2) &&
 729     eqListBy tcEqPred (tyConStupidTheta tc1) (tyConStupidTheta tc2) &&
 730     eqAlgRhs (algTyConRhs tc1) (algTyConRhs tc2)
 731
 732   | isForeignTyCon tc1 && isForeignTyCon tc2
 733   = eqKind (tyConKind tc1) (tyConKind tc2) &&
 734     tyConExtName tc1 == tyConExtName tc2
 735
 736   | otherwise = False
 737   where
 738         env0 = mkRnEnv2 emptyInScopeSet
 739
 740         eqAlgRhs AbstractTyCon _ = True
 741         eqAlgRhs DataFamilyTyCon{} DataFamilyTyCon{} = True
 742         eqAlgRhs tc1@DataTyCon{} tc2@DataTyCon{} =
 743             eqListBy eqCon (data_cons tc1) (data_cons tc2)
 744         eqAlgRhs tc1@NewTyCon{} tc2@NewTyCon{} =
 745             eqCon (data_con tc1) (data_con tc2)
 746         eqAlgRhs _ _ = False
 747
 748         eqCon c1 c2
 749           =  dataConName c1 == dataConName c2
 750           && dataConIsInfix c1 == dataConIsInfix c2
 751           && dataConStrictMarks c1 == dataConStrictMarks c2
 752           && dataConFieldLabels c1 == dataConFieldLabels c2
 753           && let tvs1 = dataConUnivTyVars c1 ++ dataConExTyVars c1
 754                  tvs2 = dataConUnivTyVars c2 ++ dataConExTyVars c2
 755                  env = rnBndrs2 env0 tvs1 tvs2
 756              in
 757               equalLength tvs1 tvs2 &&
 758               eqListBy (tcEqPredX env)
 759                         (dataConEqTheta c1 ++ dataConDictTheta c1)
 760                         (dataConEqTheta c2 ++ dataConDictTheta c2) &&
 761               eqListBy (tcEqTypeX env)
 762                         (dataConOrigArgTys c1)
 763                         (dataConOrigArgTys c2)
 764
 765 ----------------
 766 missingBootThing :: Name -> String -> SDoc
 767 missingBootThing name what
 768   = ppr name <+> ptext (sLit "is exported by the hs-boot file, but not")
 769               <+> text what <+> ptext (sLit "the module")
 770
 771 bootMisMatch :: TyThing -> IfaceDecl -> IfaceDecl -> SDoc
 772 bootMisMatch thing boot_decl real_decl
 773   = vcat [ppr thing <+> ptext (sLit "has conflicting definitions in the module and its hs-boot file"),
 774           ptext (sLit "Main module:") <+> ppr real_decl,
 775           ptext (sLit "Boot file:  ") <+> ppr boot_decl]
 776
 777 instMisMatch :: Instance -> SDoc
 778 instMisMatch inst
 779   = hang (ppr inst)
 780        2 (ptext (sLit "is defined in the hs-boot file, but not in the module itself"))
 781 \end{code}
 782
 783
 784 %************************************************************************
 785 %*                                                                      *
 786         Type-checking the top level of a module
 787 %*                                                                      *
 788 %************************************************************************
 789
 790 tcRnGroup takes a bunch of top-level source-code declarations, and
 791  * renames them
 792  * gets supporting declarations from interface files
 793  * typechecks them
 794  * zonks them
 795  * and augments the TcGblEnv with the results
 796
 797 In Template Haskell it may be called repeatedly for each group of
 798 declarations.  It expects there to be an incoming TcGblEnv in the
 799 monad; it augments it and returns the new TcGblEnv.
 800
 801 \begin{code}
 802 ------------------------------------------------
 803 rnTopSrcDecls :: HsGroup RdrName -> TcM (TcGblEnv, HsGroup Name)
 804 -- Fails if there are any errors
 805 rnTopSrcDecls group
 806  = do { -- Rename the source decls
 807         traceTc "rn12" empty ;
 808         (tcg_env, rn_decls) <- checkNoErrs $ rnSrcDecls group ;
 809         traceTc "rn13" empty ;
 810
 811         -- save the renamed syntax, if we want it
 812         let { tcg_env'
 813                 | Just grp <- tcg_rn_decls tcg_env
 814                   = tcg_env{ tcg_rn_decls = Just (appendGroups grp rn_decls) }
 815                 | otherwise
 816                    = tcg_env };
 817
 818                 -- Dump trace of renaming part
 819         rnDump (ppr rn_decls) ;
 820
 821         return (tcg_env', rn_decls)
 822    }
 823
 824 ------------------------------------------------
 825 tcTopSrcDecls :: ModDetails -> HsGroup Name -> TcM (TcGblEnv, TcLclEnv)
 826 tcTopSrcDecls boot_details
 827         (HsGroup { hs_tyclds = tycl_decls,
 828                    hs_instds = inst_decls,
 829                    hs_derivds = deriv_decls,
 830                    hs_fords  = foreign_decls,
 831                    hs_defds  = default_decls,
 832                    hs_annds  = annotation_decls,
 833                    hs_ruleds = rule_decls,
 834                    hs_valds  = val_binds })
 835  = do {         -- Type-check the type and class decls, and all imported decls
 836                 -- The latter come in via tycl_decls
 837         traceTc "Tc2" empty ;
 838
 839         (tcg_env, aux_binds, dm_ids) <- tcTyAndClassDecls boot_details tycl_decls ;
 840                 -- If there are any errors, tcTyAndClassDecls fails here
 841
 842         setGblEnv tcg_env       $
 843         tcExtendIdEnv dm_ids    $ do {
 844
 845                 -- Source-language instances, including derivings,
 846                 -- and import the supporting declarations
 847         traceTc "Tc3" empty ;
 848         (tcg_env, inst_infos, deriv_binds)
 849             <- tcInstDecls1 tycl_decls inst_decls deriv_decls;
 850         setGblEnv tcg_env       $ do {
 851
 852                 -- Foreign import declarations next.
 853         traceTc "Tc4" empty ;
 854         (fi_ids, fi_decls) <- tcForeignImports foreign_decls ;
 855         tcExtendGlobalValEnv fi_ids     $ do {
 856
 857                 -- Default declarations
 858         traceTc "Tc4a" empty ;
 859         default_tys <- tcDefaults default_decls ;
 860         updGblEnv (\gbl -> gbl { tcg_default = default_tys }) $ do {
 861
 862                 -- Now GHC-generated derived bindings, generics, and selectors
 863                 -- Do not generate warnings from compiler-generated code;
 864                 -- hence the use of discardWarnings
 865         (tc_aux_binds,   specs1, tcl_env) <- discardWarnings (tcTopBinds aux_binds) ;
 866         (tc_deriv_binds, specs2, tcl_env) <- setLclTypeEnv tcl_env $
 867                                              discardWarnings (tcTopBinds deriv_binds) ;
 868
 869                 -- Value declarations next
 870         traceTc "Tc5" empty ;
 871         (tc_val_binds, specs3, tcl_env) <- setLclTypeEnv tcl_env $
 872                                            tcTopBinds val_binds;
 873
 874         setLclTypeEnv tcl_env $ do {    -- Environment doesn't change now
 875
 876                 -- Second pass over class and instance declarations,
 877         traceTc "Tc6" empty ;
 878         inst_binds <- tcInstDecls2 tycl_decls inst_infos ;
 879
 880                 -- Foreign exports
 881         traceTc "Tc7" empty ;
 882         (foe_binds, foe_decls) <- tcForeignExports foreign_decls ;
 883
 884                 -- Annotations
 885         annotations <- tcAnnotations annotation_decls ;
 886
 887                 -- Rules
 888         rules <- tcRules rule_decls ;
 889
 890                 -- Wrap up
 891         traceTc "Tc7a" empty ;
 892         tcg_env <- getGblEnv ;
 893         let { all_binds = tc_val_binds   `unionBags`
 894                           tc_deriv_binds `unionBags`
 895                           tc_aux_binds   `unionBags`
 896                           inst_binds     `unionBags`
 897                           foe_binds
 898
 899             ; sig_names = mkNameSet (collectHsValBinders val_binds)
 900                           `minusNameSet` getTypeSigNames val_binds
 901
 902                 -- Extend the GblEnv with the (as yet un-zonked)
 903                 -- bindings, rules, foreign decls
 904             ; tcg_env' = tcg_env { tcg_binds = tcg_binds tcg_env `unionBags` all_binds
 905                                  , tcg_imp_specs = tcg_imp_specs tcg_env ++ specs1 ++ specs2 ++ specs3
 906                                  , tcg_sigs  = tcg_sigs tcg_env `unionNameSets` sig_names
 907                                  , tcg_rules = tcg_rules tcg_env ++ rules
 908                                  , tcg_anns  = tcg_anns tcg_env ++ annotations
 909                                  , tcg_fords = tcg_fords tcg_env ++ foe_decls ++ fi_decls } } ;
 910         return (tcg_env', tcl_env)
 911     }}}}}}
 912 \end{code}
 913
 914
 915 %************************************************************************
 916 %*                                                                      *
 917         Checking for 'main'
 918 %*                                                                      *
 919 %************************************************************************
 920
 921 \begin{code}
 922 checkMain :: TcM TcGblEnv
 923 -- If we are in module Main, check that 'main' is defined.
 924 checkMain
 925   = do { tcg_env   <- getGblEnv ;
 926          dflags    <- getDOpts ;
 927          check_main dflags tcg_env
 928     }
 929
 930 check_main :: DynFlags -> TcGblEnv -> TcM TcGblEnv
 931 check_main dflags tcg_env
 932  | mod /= main_mod
 933  = traceTc "checkMain not" (ppr main_mod <+> ppr mod) >>
 934    return tcg_env
 935
 936  | otherwise
 937  = do   { mb_main <- lookupGlobalOccRn_maybe main_fn
 938                 -- Check that 'main' is in scope
 939                 -- It might be imported from another module!
 940         ; case mb_main of {
 941              Nothing -> do { traceTc "checkMain fail" (ppr main_mod <+> ppr main_fn)
 942                            ; complain_no_main
 943                            ; return tcg_env } ;
 944              Just main_name -> do
 945
 946         { traceTc "checkMain found" (ppr main_mod <+> ppr main_fn)
 947         ; let loc = srcLocSpan (getSrcLoc main_name)
 948         ; ioTyCon <- tcLookupTyCon ioTyConName
 949         ; res_ty <- newFlexiTyVarTy liftedTypeKind
 950         ; main_expr
 951                 <- addErrCtxt mainCtxt    $
 952                    tcMonoExpr (L loc (HsVar main_name)) (mkTyConApp ioTyCon [res_ty])
 953
 954                 -- See Note [Root-main Id]
 955                 -- Construct the binding
 956                 --      :Main.main :: IO res_ty = runMainIO res_ty main
 957         ; run_main_id <- tcLookupId runMainIOName
 958         ; let { root_main_name =  mkExternalName rootMainKey rOOT_MAIN
 959                                    (mkVarOccFS (fsLit "main"))
 960                                    (getSrcSpan main_name)
 961               ; root_main_id = Id.mkExportedLocalId root_main_name
 962                                                     (mkTyConApp ioTyCon [res_ty])
 963               ; co  = mkWpTyApps [res_ty]
 964               ; rhs = nlHsApp (mkLHsWrap co (nlHsVar run_main_id)) main_expr
 965               ; main_bind = mkVarBind root_main_id rhs }
 966
 967         ; return (tcg_env { tcg_main  = Just main_name,
 968                             tcg_binds = tcg_binds tcg_env
 969                                         `snocBag` main_bind,
 970                             tcg_dus   = tcg_dus tcg_env
 971                                         `plusDU` usesOnly (unitFV main_name)
 972                         -- Record the use of 'main', so that we don't
 973                         -- complain about it being defined but not used
 974                  })
 975     }}}
 976   where
 977     mod          = tcg_mod tcg_env
 978     main_mod     = mainModIs dflags
 979     main_fn      = getMainFun dflags
 980
 981     complain_no_main | ghcLink dflags == LinkInMemory = return ()
 982                      | otherwise = failWithTc noMainMsg
 983         -- In interactive mode, don't worry about the absence of 'main'
 984         -- In other modes, fail altogether, so that we don't go on
 985         -- and complain a second time when processing the export list.
 986
 987     mainCtxt  = ptext (sLit "When checking the type of the") <+> pp_main_fn
 988     noMainMsg = ptext (sLit "The") <+> pp_main_fn
 989                 <+> ptext (sLit "is not defined in module") <+> quotes (ppr main_mod)
 990     pp_main_fn = ppMainFn main_fn
 991
 992 ppMainFn :: RdrName -> SDoc
 993 ppMainFn main_fn
 994   | main_fn == main_RDR_Unqual
 995   = ptext (sLit "function") <+> quotes (ppr main_fn)
 996   | otherwise
 997   = ptext (sLit "main function") <+> quotes (ppr main_fn)
 998
 999 -- | Get the unqualified name of the function to use as the \"main\" for the main module.
1000 -- Either returns the default name or the one configured on the command line with -main-is
1001 getMainFun :: DynFlags -> RdrName
1002 getMainFun dflags = case (mainFunIs dflags) of
1003     Just fn -> mkRdrUnqual (mkVarOccFS (mkFastString fn))
1004     Nothing -> main_RDR_Unqual
1005
1006 checkMainExported :: TcGblEnv -> TcM ()
1007 checkMainExported tcg_env = do
1008   dflags    <- getDOpts
1009   case tcg_main tcg_env of
1010     Nothing -> return () -- not the main module
1011     Just main_name -> do
1012       let main_mod = mainModIs dflags
1013       checkTc (main_name `elem` concatMap availNames (tcg_exports tcg_env)) $
1014               ptext (sLit "The") <+> ppMainFn (nameRdrName main_name) <+>
1015               ptext (sLit "is not exported by module") <+> quotes (ppr main_mod)
1016 \end{code}
1017
1018 Note [Root-main Id]
1019 ~~~~~~~~~~~~~~~~~~~
1020 The function that the RTS invokes is always :Main.main, which we call
1021 root_main_id.  (Because GHC allows the user to have a module not
1022 called Main as the main module, we can't rely on the main function
1023 being called "Main.main".  That's why root_main_id has a fixed module
1024 ":Main".)
1025
1026 This is unusual: it's a LocalId whose Name has a Module from another
1027 module.  Tiresomely, we must filter it out again in MkIface, les we
1028 get two defns for 'main' in the interface file!
1029
1030
1031 %*********************************************************
1032 %*                                                       *
1033                 GHCi stuff
1034 %*                                                       *
1035 %*********************************************************
1036
1037 \begin{code}
1038 setInteractiveContext :: HscEnv -> InteractiveContext -> TcRn a -> TcRn a
1039 setInteractiveContext hsc_env icxt thing_inside
1040   = let -- Initialise the tcg_inst_env with instances from all home modules.
1041         -- This mimics the more selective call to hptInstances in tcRnModule.
1042         (home_insts, home_fam_insts) = hptInstances hsc_env (\_ -> True)
1043     in
1044     updGblEnv (\env -> env {
1045         tcg_rdr_env      = ic_rn_gbl_env icxt,
1046         tcg_inst_env     = extendInstEnvList    (tcg_inst_env env) home_insts,
1047         tcg_fam_inst_env = extendFamInstEnvList (tcg_fam_inst_env env)
1048                                                 home_fam_insts
1049       }) $
1050
1051     tcExtendGhciEnv (ic_tmp_ids icxt) $
1052         -- tcExtendGhciEnv does lots:
1053         --   - it extends the local type env (tcl_env) with the given Ids,
1054         --   - it extends the local rdr env (tcl_rdr) with the Names from
1055         --     the given Ids
1056         --   - it adds the free tyvars of the Ids to the tcl_tyvars
1057         --     set.
1058         --
1059         -- later ids in ic_tmp_ids must shadow earlier ones with the same
1060         -- OccName, and tcExtendIdEnv implements this behaviour.
1061
1062     do  { traceTc "setIC" (ppr (ic_tmp_ids icxt))
1063         ; thing_inside }
1064 \end{code}
1065
1066
1067 \begin{code}
1068 #ifdef GHCI
1069 tcRnStmt :: HscEnv
1070          -> InteractiveContext
1071          -> LStmt RdrName
1072          -> IO (Messages, Maybe ([Id], LHsExpr Id))
1073                 -- The returned [Id] is the list of new Ids bound by
1074                 -- this statement.  It can be used to extend the
1075                 -- InteractiveContext via extendInteractiveContext.
1076                 --
1077                 -- The returned TypecheckedHsExpr is of type IO [ () ],
1078                 -- a list of the bound values, coerced to ().
1079
1080 tcRnStmt hsc_env ictxt rdr_stmt
1081   = initTcPrintErrors hsc_env iNTERACTIVE $
1082     setInteractiveContext hsc_env ictxt $ do {
1083
1084     -- Rename; use CmdLineMode because tcRnStmt is only used interactively
1085     (([rn_stmt], _), fvs) <- rnStmts GhciStmt [rdr_stmt] $ \_ ->
1086                              return ((), emptyFVs) ;
1087     traceRn (text "tcRnStmt" <+> vcat [ppr rdr_stmt, ppr rn_stmt, ppr fvs]) ;
1088     failIfErrsM ;
1089     rnDump (ppr rn_stmt) ;
1090
1091     -- The real work is done here
1092     (bound_ids, tc_expr) <- mkPlan rn_stmt ;
1093     zonked_expr <- zonkTopLExpr tc_expr ;
1094     zonked_ids  <- zonkTopBndrs bound_ids ;
1095
1096         -- None of the Ids should be of unboxed type, because we
1097         -- cast them all to HValues in the end!
1098     mapM_ bad_unboxed (filter (isUnLiftedType . idType) zonked_ids) ;
1099
1100     traceTc "tcs 1" empty ;
1101     let { global_ids = map globaliseAndTidyId zonked_ids } ;
1102         -- Note [Interactively-bound Ids in GHCi]
1103
1104 {- ---------------------------------------------
1105    At one stage I removed any shadowed bindings from the type_env;
1106    they are inaccessible but might, I suppose, cause a space leak if we leave them there.
1107    However, with Template Haskell they aren't necessarily inaccessible.  Consider this
1108    GHCi session
1109          Prelude> let f n = n * 2 :: Int
1110          Prelude> fName <- runQ [| f |]
1111          Prelude> $(return $ AppE fName (LitE (IntegerL 7)))
1112          14
1113          Prelude> let f n = n * 3 :: Int
1114          Prelude> $(return $ AppE fName (LitE (IntegerL 7)))
1115    In the last line we use 'fName', which resolves to the *first* 'f'
1116    in scope. If we delete it from the type env, GHCi crashes because
1117    it doesn't expect that.
1118
1119    Hence this code is commented out
1120
1121 -------------------------------------------------- -}
1122
1123     dumpOptTcRn Opt_D_dump_tc
1124         (vcat [text "Bound Ids" <+> pprWithCommas ppr global_ids,
1125                text "Typechecked expr" <+> ppr zonked_expr]) ;
1126
1127     return (global_ids, zonked_expr)
1128     }
1129   where
1130     bad_unboxed id = addErr (sep [ptext (sLit "GHCi can't bind a variable of unlifted type:"),
1131                                   nest 2 (ppr id <+> dcolon <+> ppr (idType id))])
1132 \end{code}
1133
1134 Note [Interactively-bound Ids in GHCi]
1135 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1136 The Ids bound by previous Stmts in Template Haskell are currently
1137         a) GlobalIds
1138         b) with an Internal Name (not External)
1139         c) and a tidied type
1140
1141  (a) They must be GlobalIds (not LocalIds) otherwise when we come to
1142      compile an expression using these ids later, the byte code
1143      generator will consider the occurrences to be free rather than
1144      global.
1145
1146  (b) They retain their Internal names becuase we don't have a suitable
1147      Module to name them with.  We could revisit this choice.
1148
1149  (c) Their types are tidied.  This is important, because :info may ask
1150      to look at them, and :info expects the things it looks up to have
1151      tidy types
1152
1153
1154 --------------------------------------------------------------------------
1155                 Typechecking Stmts in GHCi
1156
1157 Here is the grand plan, implemented in tcUserStmt
1158
1159         What you type                   The IO [HValue] that hscStmt returns
1160         -------------                   ------------------------------------
1161         let pat = expr          ==>     let pat = expr in return [coerce HVal x, coerce HVal y, ...]
1162                                         bindings: [x,y,...]
1163
1164         pat <- expr             ==>     expr >>= \ pat -> return [coerce HVal x, coerce HVal y, ...]
1165                                         bindings: [x,y,...]
1166
1167         expr (of IO type)       ==>     expr >>= \ it -> return [coerce HVal it]
1168           [NB: result not printed]      bindings: [it]
1169
1170         expr (of non-IO type,   ==>     let it = expr in print it >> return [coerce HVal it]
1171           result showable)              bindings: [it]
1172
1173         expr (of non-IO type,
1174           result not showable)  ==>     error
1175
1176
1177 \begin{code}
1178 ---------------------------
1179 type PlanResult = ([Id], LHsExpr Id)
1180 type Plan = TcM PlanResult
1181
1182 runPlans :: [Plan] -> TcM PlanResult
1183 -- Try the plans in order.  If one fails (by raising an exn), try the next.
1184 -- If one succeeds, take it.
1185 runPlans []     = panic "runPlans"
1186 runPlans [p]    = p
1187 runPlans (p:ps) = tryTcLIE_ (runPlans ps) p
1188
1189 --------------------
1190 mkPlan :: LStmt Name -> TcM PlanResult
1191 mkPlan (L loc (ExprStmt expr _ _))      -- An expression typed at the prompt
1192   = do  { uniq <- newUnique             -- is treated very specially
1193         ; let fresh_it  = itName uniq
1194               the_bind  = L loc $ mkFunBind (L loc fresh_it) matches
1195               matches   = [mkMatch [] expr emptyLocalBinds]
1196               let_stmt  = L loc $ LetStmt (HsValBinds (ValBindsOut [(NonRecursive,unitBag the_bind)] []))
1197               bind_stmt = L loc $ BindStmt (nlVarPat fresh_it) expr
1198                                            (HsVar bindIOName) noSyntaxExpr
1199               print_it  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar fresh_it))
1200                                            (HsVar thenIOName) placeHolderType
1201
1202         -- The plans are:
1203         --      [it <- e; print it]     but not if it::()
1204         --      [it <- e]
1205         --      [let it = e; print it]
1206         ; runPlans [    -- Plan A
1207                     do { stuff@([it_id], _) <- tcGhciStmts [bind_stmt, print_it]
1208                        ; it_ty <- zonkTcType (idType it_id)
1209                        ; when (isUnitTy it_ty) failM
1210                        ; return stuff },
1211
1212                         -- Plan B; a naked bind statment
1213                     tcGhciStmts [bind_stmt],
1214
1215                         -- Plan C; check that the let-binding is typeable all by itself.
1216                         -- If not, fail; if so, try to print it.
1217                         -- The two-step process avoids getting two errors: one from
1218                         -- the expression itself, and one from the 'print it' part
1219                         -- This two-step story is very clunky, alas
1220                     do { _ <- checkNoErrs (tcGhciStmts [let_stmt])
1221                                 --- checkNoErrs defeats the error recovery of let-bindings
1222                        ; tcGhciStmts [let_stmt, print_it] }
1223           ]}
1224
1225 mkPlan stmt@(L loc (BindStmt {}))
1226   | [v] <- collectLStmtBinders stmt             -- One binder, for a bind stmt
1227   = do  { let print_v  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar v))
1228                                            (HsVar thenIOName) placeHolderType
1229
1230         ; print_bind_result <- doptM Opt_PrintBindResult
1231         ; let print_plan = do
1232                   { stuff@([v_id], _) <- tcGhciStmts [stmt, print_v]
1233                   ; v_ty <- zonkTcType (idType v_id)
1234                   ; when (isUnitTy v_ty || not (isTauTy v_ty)) failM
1235                   ; return stuff }
1236
1237         -- The plans are:
1238         --      [stmt; print v]         but not if v::()
1239         --      [stmt]
1240         ; runPlans ((if print_bind_result then [print_plan] else []) ++
1241                     [tcGhciStmts [stmt]])
1242         }
1243
1244 mkPlan stmt
1245   = tcGhciStmts [stmt]
1246
1247 ---------------------------
1248 tcGhciStmts :: [LStmt Name] -> TcM PlanResult
1249 tcGhciStmts stmts
1250  = do { ioTyCon <- tcLookupTyCon ioTyConName ;
1251         ret_id  <- tcLookupId returnIOName ;            -- return @ IO
1252         let {
1253             ret_ty    = mkListTy unitTy ;
1254             io_ret_ty = mkTyConApp ioTyCon [ret_ty] ;
1255             tc_io_stmts stmts = tcStmts GhciStmt tcDoStmt stmts io_ret_ty ;
1256
1257             names = collectLStmtsBinders stmts ;
1258
1259                 -- mk_return builds the expression
1260                 --      returnIO @ [()] [coerce () x, ..,  coerce () z]
1261                 --
1262                 -- Despite the inconvenience of building the type applications etc,
1263                 -- this *has* to be done in type-annotated post-typecheck form
1264                 -- because we are going to return a list of *polymorphic* values
1265                 -- coerced to type (). If we built a *source* stmt
1266                 --      return [coerce x, ..., coerce z]
1267                 -- then the type checker would instantiate x..z, and we wouldn't
1268                 -- get their *polymorphic* values.  (And we'd get ambiguity errs
1269                 -- if they were overloaded, since they aren't applied to anything.)
1270             mk_return ids = nlHsApp (nlHsTyApp ret_id [ret_ty])
1271                                     (noLoc $ ExplicitList unitTy (map mk_item ids)) ;
1272             mk_item id = nlHsApp (nlHsTyApp unsafeCoerceId [idType id, unitTy])
1273                                  (nlHsVar id)
1274          } ;
1275
1276         -- OK, we're ready to typecheck the stmts
1277         traceTc "TcRnDriver.tcGhciStmts: tc stmts" empty ;
1278         ((tc_stmts, ids), lie) <- captureConstraints $ tc_io_stmts stmts $ \ _ ->
1279                                            mapM tcLookupId names ;
1280                                         -- Look up the names right in the middle,
1281                                         -- where they will all be in scope
1282
1283         -- Simplify the context
1284         traceTc "TcRnDriver.tcGhciStmts: simplify ctxt" empty ;
1285         const_binds <- checkNoErrs (simplifyInteractive lie) ;
1286                 -- checkNoErrs ensures that the plan fails if context redn fails
1287
1288         traceTc "TcRnDriver.tcGhciStmts: done" empty ;
1289         return (ids, mkHsDictLet (EvBinds const_binds) $
1290                      noLoc (HsDo GhciStmt tc_stmts (mk_return ids) io_ret_ty))
1291     }
1292 \end{code}
1293
1294
1295 tcRnExpr just finds the type of an expression
1296
1297 \begin{code}
1298 tcRnExpr :: HscEnv
1299          -> InteractiveContext
1300          -> LHsExpr RdrName
1301          -> IO (Messages, Maybe Type)
1302 tcRnExpr hsc_env ictxt rdr_expr
1303   = initTcPrintErrors hsc_env iNTERACTIVE $
1304     setInteractiveContext hsc_env ictxt $ do {
1305
1306     (rn_expr, _fvs) <- rnLExpr rdr_expr ;
1307     failIfErrsM ;
1308
1309         -- Now typecheck the expression;
1310         -- it might have a rank-2 type (e.g. :t runST)
1311     ((_tc_expr, res_ty), lie)   <- captureConstraints (tcInferRho rn_expr) ;
1312     ((qtvs, dicts, _), lie_top) <- captureConstraints (simplifyInfer False {- No MR for now -}
1313                                                       (tyVarsOfType res_ty) lie)  ;
1314     _ <- simplifyInteractive lie_top ;       -- Ignore the dicionary bindings
1315
1316     let { all_expr_ty = mkForAllTys qtvs (mkPiTypes dicts res_ty) } ;
1317     zonkTcType all_expr_ty
1318     }
1319 \end{code}
1320
1321 tcRnType just finds the kind of a type
1322
1323 \begin{code}
1324 tcRnType :: HscEnv
1325          -> InteractiveContext
1326          -> LHsType RdrName
1327          -> IO (Messages, Maybe Kind)
1328 tcRnType hsc_env ictxt rdr_type
1329   = initTcPrintErrors hsc_env iNTERACTIVE $
1330     setInteractiveContext hsc_env ictxt $ do {
1331
1332     rn_type <- rnLHsType doc rdr_type ;
1333     failIfErrsM ;
1334
1335         -- Now kind-check the type
1336     (_ty', kind) <- kcLHsType rn_type ;
1337     return kind
1338     }
1339   where
1340     doc = ptext (sLit "In GHCi input")
1341
1342 #endif /* GHCi */
1343 \end{code}
1344
1345
1346 %************************************************************************
1347 %*                                                                      *
1348         More GHCi stuff, to do with browsing and getting info
1349 %*                                                                      *
1350 %************************************************************************
1351
1352 \begin{code}
1353 #ifdef GHCI
1354 -- | ASSUMES that the module is either in the 'HomePackageTable' or is
1355 -- a package module with an interface on disk.  If neither of these is
1356 -- true, then the result will be an error indicating the interface
1357 -- could not be found.
1358 getModuleExports :: HscEnv -> Module -> IO (Messages, Maybe [AvailInfo])
1359 getModuleExports hsc_env mod
1360   = let
1361       ic        = hsc_IC hsc_env
1362       checkMods = ic_toplev_scope ic ++ map fst (ic_exports ic)
1363     in
1364     initTc hsc_env HsSrcFile False iNTERACTIVE (tcGetModuleExports mod checkMods)
1365
1366 -- Get the export avail info and also load all orphan and family-instance
1367 -- modules.  Finally, check that the family instances of all modules in the
1368 -- interactive context are consistent (these modules are in the second
1369 -- argument).
1370 tcGetModuleExports :: Module -> [Module] -> TcM [AvailInfo]
1371 tcGetModuleExports mod directlyImpMods
1372   = do { let doc = ptext (sLit "context for compiling statements")
1373        ; iface <- initIfaceTcRn $ loadSysInterface doc mod
1374
1375                 -- Load any orphan-module and family instance-module
1376                 -- interfaces, so their instances are visible.
1377        ; loadOrphanModules (dep_orphs (mi_deps iface)) False
1378        ; loadOrphanModules (dep_finsts (mi_deps iface)) True
1379
1380                 -- Check that the family instances of all directly loaded
1381                 -- modules are consistent.
1382        ; checkFamInstConsistency (dep_finsts (mi_deps iface)) directlyImpMods
1383
1384        ; ifaceExportNames (mi_exports iface)
1385        }
1386
1387 tcRnLookupRdrName :: HscEnv -> RdrName -> IO (Messages, Maybe [Name])
1388 tcRnLookupRdrName hsc_env rdr_name
1389   = initTcPrintErrors hsc_env iNTERACTIVE $
1390     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1391     lookup_rdr_name rdr_name
1392
1393 lookup_rdr_name :: RdrName -> TcM [Name]
1394 lookup_rdr_name rdr_name = do {
1395         -- If the identifier is a constructor (begins with an
1396         -- upper-case letter), then we need to consider both
1397         -- constructor and type class identifiers.
1398     let { rdr_names = dataTcOccs rdr_name } ;
1399
1400         -- results :: [Either Messages Name]
1401     results <- mapM (tryTcErrs . lookupOccRn) rdr_names ;
1402
1403     traceRn (text "xx" <+> vcat [ppr rdr_names, ppr (map snd results)]);
1404         -- The successful lookups will be (Just name)
1405     let { (warns_s, good_names) = unzip [ (msgs, name)
1406                                         | (msgs, Just name) <- results] ;
1407           errs_s = [msgs | (msgs, Nothing) <- results] } ;
1408
1409         -- Fail if nothing good happened, else add warnings
1410     if null good_names then
1411                 -- No lookup succeeded, so
1412                 -- pick the first error message and report it
1413                 -- ToDo: If one of the errors is "could be Foo.X or Baz.X",
1414                 --       while the other is "X is not in scope",
1415                 --       we definitely want the former; but we might pick the latter
1416         do { addMessages (head errs_s) ; failM }
1417       else                      -- Add deprecation warnings
1418         mapM_ addMessages warns_s ;
1419
1420     return good_names
1421  }
1422 #endif
1423
1424 tcRnLookupName :: HscEnv -> Name -> IO (Messages, Maybe TyThing)
1425 tcRnLookupName hsc_env name
1426   = initTcPrintErrors hsc_env iNTERACTIVE $
1427     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1428     tcRnLookupName' name
1429
1430 -- To look up a name we have to look in the local environment (tcl_lcl)
1431 -- as well as the global environment, which is what tcLookup does.
1432 -- But we also want a TyThing, so we have to convert:
1433
1434 tcRnLookupName' :: Name -> TcRn TyThing
1435 tcRnLookupName' name = do
1436    tcthing <- tcLookup name
1437    case tcthing of
1438      AGlobal thing    -> return thing
1439      ATcId{tct_id=id} -> return (AnId id)
1440      _ -> panic "tcRnLookupName'"
1441
1442 tcRnGetInfo :: HscEnv
1443             -> Name
1444             -> IO (Messages, Maybe (TyThing, Fixity, [Instance]))
1445
1446 -- Used to implement :info in GHCi
1447 --
1448 -- Look up a RdrName and return all the TyThings it might be
1449 -- A capitalised RdrName is given to us in the DataName namespace,
1450 -- but we want to treat it as *both* a data constructor
1451 --  *and* as a type or class constructor;
1452 -- hence the call to dataTcOccs, and we return up to two results
1453 tcRnGetInfo hsc_env name
1454   = initTcPrintErrors hsc_env iNTERACTIVE $
1455     tcRnGetInfo' hsc_env name
1456
1457 tcRnGetInfo' :: HscEnv
1458              -> Name
1459              -> TcRn (TyThing, Fixity, [Instance])
1460 tcRnGetInfo' hsc_env name
1461   = let ictxt = hsc_IC hsc_env in
1462     setInteractiveContext hsc_env ictxt $ do
1463
1464         -- Load the interface for all unqualified types and classes
1465         -- That way we will find all the instance declarations
1466         -- (Packages have not orphan modules, and we assume that
1467         --  in the home package all relevant modules are loaded.)
1468     loadUnqualIfaces ictxt
1469
1470     thing  <- tcRnLookupName' name
1471     fixity <- lookupFixityRn name
1472     ispecs <- lookupInsts thing
1473     return (thing, fixity, ispecs)
1474
1475 lookupInsts :: TyThing -> TcM [Instance]
1476 lookupInsts (AClass cls)
1477   = do  { inst_envs <- tcGetInstEnvs
1478         ; return (classInstances inst_envs cls) }
1479
1480 lookupInsts (ATyCon tc)
1481   = do  { (pkg_ie, home_ie) <- tcGetInstEnvs
1482                 -- Load all instances for all classes that are
1483                 -- in the type environment (which are all the ones
1484                 -- we've seen in any interface file so far)
1485         ; return [ ispec        -- Search all
1486                  | ispec <- instEnvElts home_ie ++ instEnvElts pkg_ie
1487                  , let dfun = instanceDFunId ispec
1488                  , relevant dfun ] }
1489   where
1490     relevant df = tc_name `elemNameSet` tyClsNamesOfDFunHead (idType df)
1491     tc_name     = tyConName tc
1492
1493 lookupInsts _ = return []
1494
1495 loadUnqualIfaces :: InteractiveContext -> TcM ()
1496 -- Load the home module for everything that is in scope unqualified
1497 -- This is so that we can accurately report the instances for
1498 -- something
1499 loadUnqualIfaces ictxt
1500   = initIfaceTcRn $
1501     mapM_ (loadSysInterface doc) (moduleSetElts (mkModuleSet unqual_mods))
1502   where
1503     unqual_mods = [ nameModule name
1504                   | gre <- globalRdrEnvElts (ic_rn_gbl_env ictxt),
1505                     let name = gre_name gre,
1506                     not (isInternalName name),
1507                     isTcOcc (nameOccName name),  -- Types and classes only
1508                     unQualOK gre ]               -- In scope unqualified
1509     doc = ptext (sLit "Need interface for module whose export(s) are in scope unqualified")
1510 \end{code}
1511
1512 %************************************************************************
1513 %*                                                                      *
1514                 Degugging output
1515 %*                                                                      *
1516 %************************************************************************
1517
1518 \begin{code}
1519 rnDump :: SDoc -> TcRn ()
1520 -- Dump, with a banner, if -ddump-rn
1521 rnDump doc = do { dumpOptTcRn Opt_D_dump_rn (mkDumpDoc "Renamer" doc) }
1522
1523 tcDump :: TcGblEnv -> TcRn ()
1524 tcDump env
1525  = do { dflags <- getDOpts ;
1526
1527         -- Dump short output if -ddump-types or -ddump-tc
1528         when (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1529              (dumpTcRn short_dump) ;
1530
1531         -- Dump bindings if -ddump-tc
1532         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump)
1533    }
1534   where
1535     short_dump = pprTcGblEnv env
1536     full_dump  = pprLHsBinds (tcg_binds env)
1537         -- NB: foreign x-d's have undefined's in their types;
1538         --     hence can't show the tc_fords
1539
1540 tcCoreDump :: ModGuts -> TcM ()
1541 tcCoreDump mod_guts
1542  = do { dflags <- getDOpts ;
1543         when (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1544              (dumpTcRn (pprModGuts mod_guts)) ;
1545
1546         -- Dump bindings if -ddump-tc
1547         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump) }
1548   where
1549     full_dump = pprCoreBindings (mg_binds mod_guts)
1550
1551 -- It's unpleasant having both pprModGuts and pprModDetails here
1552 pprTcGblEnv :: TcGblEnv -> SDoc
1553 pprTcGblEnv (TcGblEnv { tcg_type_env  = type_env,
1554                         tcg_insts     = insts,
1555                         tcg_fam_insts = fam_insts,
1556                         tcg_rules     = rules,
1557                         tcg_imports   = imports })
1558   = vcat [ ppr_types insts type_env
1559          , ppr_tycons fam_insts type_env
1560          , ppr_insts insts
1561          , ppr_fam_insts fam_insts
1562          , vcat (map ppr rules)
1563          , ppr_gen_tycons (typeEnvTyCons type_env)
1564          , ptext (sLit "Dependent modules:") <+>
1565                 ppr (sortBy cmp_mp $ eltsUFM (imp_dep_mods imports))
1566          , ptext (sLit "Dependent packages:") <+>
1567                 ppr (sortBy stablePackageIdCmp $ imp_dep_pkgs imports)]
1568   where         -- The two uses of sortBy are just to reduce unnecessary
1569                 -- wobbling in testsuite output
1570     cmp_mp (mod_name1, is_boot1) (mod_name2, is_boot2)
1571         = (mod_name1 `stableModuleNameCmp` mod_name2)
1572                   `thenCmp`
1573           (is_boot1 `compare` is_boot2)
1574
1575 pprModGuts :: ModGuts -> SDoc
1576 pprModGuts (ModGuts { mg_types = type_env,
1577                       mg_rules = rules })
1578   = vcat [ ppr_types [] type_env,
1579            ppr_rules rules ]
1580
1581 ppr_types :: [Instance] -> TypeEnv -> SDoc
1582 ppr_types insts type_env
1583   = text "TYPE SIGNATURES" $$ nest 4 (ppr_sigs ids)
1584   where
1585     dfun_ids = map instanceDFunId insts
1586     ids = [id | id <- typeEnvIds type_env, want_sig id]
1587     want_sig id | opt_PprStyle_Debug = True
1588                 | otherwise          = isLocalId id &&
1589                                        isExternalName (idName id) &&
1590                                        not (id `elem` dfun_ids)
1591         -- isLocalId ignores data constructors, records selectors etc.
1592         -- The isExternalName ignores local dictionary and method bindings
1593         -- that the type checker has invented.  Top-level user-defined things
1594         -- have External names.
1595
1596 ppr_tycons :: [FamInst] -> TypeEnv -> SDoc
1597 ppr_tycons fam_insts type_env
1598   = text "TYPE CONSTRUCTORS" $$ nest 4 (ppr_tydecls tycons)
1599   where
1600     fi_tycons = map famInstTyCon fam_insts
1601     tycons = [tycon | tycon <- typeEnvTyCons type_env, want_tycon tycon]
1602     want_tycon tycon | opt_PprStyle_Debug = True
1603                      | otherwise          = not (isImplicitTyCon tycon) &&
1604                                             isExternalName (tyConName tycon) &&
1605                                             not (tycon `elem` fi_tycons)
1606
1607 ppr_insts :: [Instance] -> SDoc
1608 ppr_insts []     = empty
1609 ppr_insts ispecs = text "INSTANCES" $$ nest 2 (pprInstances ispecs)
1610
1611 ppr_fam_insts :: [FamInst] -> SDoc
1612 ppr_fam_insts []        = empty
1613 ppr_fam_insts fam_insts =
1614   text "FAMILY INSTANCES" $$ nest 2 (pprFamInsts fam_insts)
1615
1616 ppr_sigs :: [Var] -> SDoc
1617 ppr_sigs ids
1618         -- Print type signatures; sort by OccName
1619   = vcat (map ppr_sig (sortLe le_sig ids))
1620   where
1621     le_sig id1 id2 = getOccName id1 <= getOccName id2
1622     ppr_sig id = ppr id <+> dcolon <+> ppr (tidyTopType (idType id))
1623
1624 ppr_tydecls :: [TyCon] -> SDoc
1625 ppr_tydecls tycons
1626         -- Print type constructor info; sort by OccName
1627   = vcat (map ppr_tycon (sortLe le_sig tycons))
1628   where
1629     le_sig tycon1 tycon2 = getOccName tycon1 <= getOccName tycon2
1630     ppr_tycon tycon
1631       | isCoercionTyCon tycon
1632       = sep [ptext (sLit "coercion") <+> ppr tycon <+> ppr tvs
1633             , nest 2 (dcolon <+> pprEqPred (coercionKind (mkTyConApp tycon (mkTyVarTys tvs))))]
1634       | otherwise             = ppr (tyThingToIfaceDecl (ATyCon tycon))
1635       where
1636         tvs = take (tyConArity tycon) alphaTyVars
1637
1638 ppr_rules :: [CoreRule] -> SDoc
1639 ppr_rules [] = empty
1640 ppr_rules rs = vcat [ptext (sLit "{-# RULES"),
1641                       nest 2 (pprRules rs),
1642                       ptext (sLit "#-}")]
1643
1644 ppr_gen_tycons :: [TyCon] -> SDoc
1645 ppr_gen_tycons []  = empty
1646 ppr_gen_tycons tcs = vcat [ptext (sLit "Tycons with generics:"),
1647                            nest 2 (fsep (map ppr (filter tyConHasGenerics tcs)))]
1648 \end{code}