compiler/typecheck/TcRnDriver.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5 \section[TcMovectle]{Typechecking a whole module}
   6
   7 \begin{code}
   8 module TcRnDriver (
   9 #ifdef GHCI
  10         tcRnStmt, tcRnExpr, tcRnType,
  11         tcRnLookupRdrName,
  12         getModuleExports,
  13 #endif
  14         tcRnLookupName,
  15         tcRnGetInfo,
  16         tcRnModule,
  17         tcTopSrcDecls,
  18         tcRnExtCore
  19     ) where
  20
  21 #ifdef GHCI
  22 import {-# SOURCE #-} TcSplice ( tcSpliceDecls )
  23 #endif
  24
  25 import DynFlags
  26 import StaticFlags
  27 import HsSyn
  28 import PrelNames
  29 import RdrName
  30 import TcHsSyn
  31 import TcExpr
  32 import TcRnMonad
  33 import Coercion
  34 import FamInst
  35 import InstEnv
  36 import FamInstEnv
  37 import TcAnnotations
  38 import TcBinds
  39 import TcType   ( tidyTopType )
  40 import TcDefaults
  41 import TcEnv
  42 import TcRules
  43 import TcForeign
  44 import TcInstDcls
  45 import TcIface
  46 import TcMType
  47 import MkIface
  48 import IfaceSyn
  49 import TcSimplify
  50 import TcTyClsDecls
  51 import LoadIface
  52 import RnNames
  53 import RnEnv
  54 import RnSource
  55 import PprCore
  56 import CoreSyn
  57 import ErrUtils
  58 import Id
  59 import VarEnv
  60 import Var
  61 import Module
  62 import UniqFM
  63 import Name
  64 import NameEnv
  65 import NameSet
  66 import TyCon
  67 import TysPrim
  68 import SrcLoc
  69 import HscTypes
  70 import ListSetOps
  71 import Outputable
  72 import DataCon
  73 import Type
  74 import Class
  75 import TcType   ( orphNamesOfDFunHead )
  76 import Inst     ( tcGetInstEnvs )
  77 import Data.List ( sortBy )
  78
  79 #ifdef GHCI
  80 import TcType   ( isUnitTy, isTauTy )
  81 import CoreUtils( mkPiTypes )
  82 import TcHsType
  83 import TcMatches
  84 import RnTypes
  85 import RnExpr
  86 import IfaceEnv
  87 import MkId
  88 import BasicTypes
  89 import TidyPgm    ( globaliseAndTidyId )
  90 import TysWiredIn ( unitTy, mkListTy )
  91 #endif
  92
  93 import FastString
  94 import Maybes
  95 import Util
  96 import Bag
  97
  98 import Control.Monad
  99
 100 #include "HsVersions.h"
 101 \end{code}
 102
 103 %************************************************************************
 104 %*                                                                      *
 105         Typecheck and rename a module
 106 %*                                                                      *
 107 %************************************************************************
 108
 109
 110 \begin{code}
 111 tcRnModule :: HscEnv
 112            -> HscSource
 113            -> Bool              -- True <=> save renamed syntax
 114            -> Located (HsModule RdrName)
 115            -> IO (Messages, Maybe TcGblEnv)
 116
 117 tcRnModule hsc_env hsc_src save_rn_syntax
 118          (L loc (HsModule maybe_mod export_ies
 119                           import_decls local_decls mod_deprec
 120                           maybe_doc_hdr))
 121  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 122
 123    let { this_pkg = thisPackage (hsc_dflags hsc_env) ;
 124          this_mod = case maybe_mod of
 125                         Nothing  -> mAIN        -- 'module M where' is omitted
 126                         Just (L _ mod) -> mkModule this_pkg mod } ;
 127                                                 -- The normal case
 128
 129    initTc hsc_env hsc_src save_rn_syntax this_mod $
 130    setSrcSpan loc $
 131    do {         -- Deal with imports;
 132         tcg_env <- tcRnImports hsc_env this_mod import_decls ;
 133         setGblEnv tcg_env               $ do {
 134
 135                 -- Load the hi-boot interface for this module, if any
 136                 -- We do this now so that the boot_names can be passed
 137                 -- to tcTyAndClassDecls, because the boot_names are
 138                 -- automatically considered to be loop breakers
 139                 --
 140                 -- Do this *after* tcRnImports, so that we know whether
 141                 -- a module that we import imports us; and hence whether to
 142                 -- look for a hi-boot file
 143         boot_iface <- tcHiBootIface hsc_src this_mod ;
 144
 145                 -- Rename and type check the declarations
 146         traceRn (text "rn1a") ;
 147         tcg_env <- if isHsBoot hsc_src then
 148                         tcRnHsBootDecls local_decls
 149                    else
 150                         tcRnSrcDecls boot_iface local_decls ;
 151         setGblEnv tcg_env               $ do {
 152
 153                 -- Report the use of any deprecated things
 154                 -- We do this *before* processsing the export list so
 155                 -- that we don't bleat about re-exporting a deprecated
 156                 -- thing (especially via 'module Foo' export item)
 157                 -- That is, only uses in the *body* of the module are complained about
 158         traceRn (text "rn3") ;
 159         failIfErrsM ;   -- finishWarnings crashes sometimes
 160                         -- as a result of typechecker repairs (e.g. unboundNames)
 161         tcg_env <- finishWarnings (hsc_dflags hsc_env) mod_deprec tcg_env ;
 162
 163                 -- Process the export list
 164         traceRn (text "rn4a: before exports");
 165         tcg_env <- rnExports (isJust maybe_mod) export_ies tcg_env ;
 166         traceRn (text "rn4b: after exportss") ;
 167
 168                 -- Check that main is exported (must be after rnExports)
 169         checkMainExported tcg_env ;
 170
 171         -- Compare the hi-boot iface (if any) with the real thing
 172         -- Must be done after processing the exports
 173         tcg_env <- checkHiBootIface tcg_env boot_iface ;
 174
 175         -- The new type env is already available to stuff slurped from
 176         -- interface files, via TcEnv.updateGlobalTypeEnv
 177         -- It's important that this includes the stuff in checkHiBootIface,
 178         -- because the latter might add new bindings for boot_dfuns,
 179         -- which may be mentioned in imported unfoldings
 180
 181                 -- Don't need to rename the Haddock documentation,
 182                 -- it's not parsed by GHC anymore.
 183         tcg_env <- return (tcg_env { tcg_doc_hdr = maybe_doc_hdr }) ;
 184
 185                 -- Report unused names
 186         reportUnusedNames export_ies tcg_env ;
 187
 188                 -- Dump output and return
 189         tcDump tcg_env ;
 190         return tcg_env
 191     }}}}
 192 \end{code}
 193
 194
 195 %************************************************************************
 196 %*                                                                      *
 197                 Import declarations
 198 %*                                                                      *
 199 %************************************************************************
 200
 201 \begin{code}
 202 tcRnImports :: HscEnv -> Module -> [LImportDecl RdrName] -> TcM TcGblEnv
 203 tcRnImports hsc_env this_mod import_decls
 204   = do  { (rn_imports, rdr_env, imports,hpc_info) <- rnImports import_decls ;
 205
 206         ; let { dep_mods :: ModuleNameEnv (ModuleName, IsBootInterface)
 207               ; dep_mods = imp_dep_mods imports
 208
 209                 -- We want instance declarations from all home-package
 210                 -- modules below this one, including boot modules, except
 211                 -- ourselves.  The 'except ourselves' is so that we don't
 212                 -- get the instances from this module's hs-boot file
 213               ; want_instances :: ModuleName -> Bool
 214               ; want_instances mod = mod `elemUFM` dep_mods
 215                                    && mod /= moduleName this_mod
 216               ; (home_insts, home_fam_insts) = hptInstances hsc_env
 217                                                             want_instances
 218               } ;
 219
 220                 -- Record boot-file info in the EPS, so that it's
 221                 -- visible to loadHiBootInterface in tcRnSrcDecls,
 222                 -- and any other incrementally-performed imports
 223         ; updateEps_ (\eps -> eps { eps_is_boot = dep_mods }) ;
 224
 225                 -- Update the gbl env
 226         ; updGblEnv ( \ gbl ->
 227             gbl {
 228               tcg_rdr_env      = plusOccEnv (tcg_rdr_env gbl) rdr_env,
 229               tcg_imports      = tcg_imports gbl `plusImportAvails` imports,
 230               tcg_rn_imports   = rn_imports,
 231               tcg_inst_env     = extendInstEnvList (tcg_inst_env gbl) home_insts,
 232               tcg_fam_inst_env = extendFamInstEnvList (tcg_fam_inst_env gbl)
 233                                                       home_fam_insts,
 234               tcg_hpc          = hpc_info
 235             }) $ do {
 236
 237         ; traceRn (text "rn1" <+> ppr (imp_dep_mods imports))
 238                 -- Fail if there are any errors so far
 239                 -- The error printing (if needed) takes advantage
 240                 -- of the tcg_env we have now set
 241 --      ; traceIf (text "rdr_env: " <+> ppr rdr_env)
 242         ; failIfErrsM
 243
 244                 -- Load any orphan-module and family instance-module
 245                 -- interfaces, so that their rules and instance decls will be
 246                 -- found.
 247         ; loadOrphanModules (imp_orphs  imports) False
 248         ; loadOrphanModules (imp_finsts imports) True
 249
 250                 -- Check type-familily consistency
 251         ; traceRn (text "rn1: checking family instance consistency")
 252         ; let { dir_imp_mods = moduleEnvKeys
 253                              . imp_mods
 254                              $ imports }
 255         ; checkFamInstConsistency (imp_finsts imports) dir_imp_mods ;
 256
 257         ; getGblEnv } }
 258 \end{code}
 259
 260
 261 %************************************************************************
 262 %*                                                                      *
 263         Type-checking external-core modules
 264 %*                                                                      *
 265 %************************************************************************
 266
 267 \begin{code}
 268 tcRnExtCore :: HscEnv
 269             -> HsExtCore RdrName
 270             -> IO (Messages, Maybe ModGuts)
 271         -- Nothing => some error occurred
 272
 273 tcRnExtCore hsc_env (HsExtCore this_mod decls src_binds)
 274         -- The decls are IfaceDecls; all names are original names
 275  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 276
 277    initTc hsc_env ExtCoreFile False this_mod $ do {
 278
 279    let { ldecls  = map noLoc decls } ;
 280
 281        -- bring the type and class decls into scope
 282        -- ToDo: check that this doesn't need to extract the val binds.
 283        --       It seems that only the type and class decls need to be in scope below because
 284        --          (a) tcTyAndClassDecls doesn't need the val binds, and
 285        --          (b) tcExtCoreBindings doesn't need anything
 286        --              (in fact, it might not even need to be in the scope of
 287        --               this tcg_env at all)
 288    avails  <- getLocalNonValBinders (mkFakeGroup ldecls) ;
 289    tc_envs <- extendGlobalRdrEnvRn avails emptyFsEnv {- no fixity decls -} ;
 290
 291    setEnvs tc_envs $ do {
 292
 293    (rn_decls, _fvs) <- checkNoErrs $ rnTyClDecls [ldecls] ;
 294
 295         -- Dump trace of renaming part
 296    rnDump (ppr rn_decls) ;
 297
 298         -- Typecheck them all together so that
 299         -- any mutually recursive types are done right
 300         -- Just discard the auxiliary bindings; they are generated
 301         -- only for Haskell source code, and should already be in Core
 302    (tcg_env, _aux_binds, _dm_ids, _) <- tcTyAndClassDecls emptyModDetails rn_decls ;
 303
 304    setGblEnv tcg_env $ do {
 305         -- Make the new type env available to stuff slurped from interface files
 306
 307         -- Now the core bindings
 308    core_binds <- initIfaceExtCore (tcExtCoreBindings src_binds) ;
 309
 310         -- Wrap up
 311    let {
 312         bndrs      = bindersOfBinds core_binds ;
 313         my_exports = map (Avail . idName) bndrs ;
 314                 -- ToDo: export the data types also?
 315
 316         final_type_env =
 317              extendTypeEnvWithIds (tcg_type_env tcg_env) bndrs ;
 318
 319         mod_guts = ModGuts {    mg_module    = this_mod,
 320                                 mg_boot      = False,
 321                                 mg_used_names = emptyNameSet, -- ToDo: compute usage
 322                                 mg_dir_imps  = emptyModuleEnv, -- ??
 323                                 mg_deps      = noDependencies,  -- ??
 324                                 mg_exports   = my_exports,
 325                                 mg_types     = final_type_env,
 326                                 mg_insts     = tcg_insts tcg_env,
 327                                 mg_fam_insts = tcg_fam_insts tcg_env,
 328                                 mg_inst_env  = tcg_inst_env tcg_env,
 329                                 mg_fam_inst_env = tcg_fam_inst_env tcg_env,
 330                                 mg_rules     = [],
 331                                 mg_vect_decls = [],
 332                                 mg_anns      = [],
 333                                 mg_binds     = core_binds,
 334
 335                                 -- Stubs
 336                                 mg_rdr_env   = emptyGlobalRdrEnv,
 337                                 mg_fix_env   = emptyFixityEnv,
 338                                 mg_warns     = NoWarnings,
 339                                 mg_foreign   = NoStubs,
 340                                 mg_hpc_info  = emptyHpcInfo False,
 341                                 mg_modBreaks = emptyModBreaks,
 342                                 mg_vect_info = noVectInfo
 343                     } } ;
 344
 345    tcCoreDump mod_guts ;
 346
 347    return mod_guts
 348    }}}}
 349
 350 mkFakeGroup :: [LTyClDecl a] -> HsGroup a
 351 mkFakeGroup decls -- Rather clumsy; lots of unused fields
 352   = emptyRdrGroup { hs_tyclds = [decls] }
 353 \end{code}
 354
 355
 356 %************************************************************************
 357 %*                                                                      *
 358         Type-checking the top level of a module
 359 %*                                                                      *
 360 %************************************************************************
 361
 362 \begin{code}
 363 tcRnSrcDecls :: ModDetails -> [LHsDecl RdrName] -> TcM TcGblEnv
 364         -- Returns the variables free in the decls
 365         -- Reason: solely to report unused imports and bindings
 366 tcRnSrcDecls boot_iface decls
 367  = do {         -- Do all the declarations
 368         (tc_envs, lie) <- captureConstraints $ tc_rn_src_decls boot_iface decls ;
 369       ; traceTc "Tc8" empty ;
 370       ; setEnvs tc_envs $
 371    do {
 372
 373              --         Finish simplifying class constraints
 374              --
 375              -- simplifyTop deals with constant or ambiguous InstIds.
 376              -- How could there be ambiguous ones?  They can only arise if a
 377              -- top-level decl falls under the monomorphism restriction
 378              -- and no subsequent decl instantiates its type.
 379              --
 380              -- We do this after checkMain, so that we use the type info
 381              -- thaat checkMain adds
 382              --
 383              -- We do it with both global and local env in scope:
 384              --  * the global env exposes the instances to simplifyTop
 385              --  * the local env exposes the local Ids to simplifyTop,
 386              --    so that we get better error messages (monomorphism restriction)
 387         new_ev_binds <- simplifyTop lie ;
 388         traceTc "Tc9" empty ;
 389
 390         failIfErrsM ;   -- Don't zonk if there have been errors
 391                         -- It's a waste of time; and we may get debug warnings
 392                         -- about strangely-typed TyCons!
 393
 394         -- Zonk the final code.  This must be done last.
 395         -- Even simplifyTop may do some unification.
 396         -- This pass also warns about missing type signatures
 397         let { (tcg_env, _) = tc_envs
 398             ; TcGblEnv { tcg_type_env  = type_env,
 399                          tcg_binds     = binds,
 400                          tcg_sigs      = sig_ns,
 401                          tcg_ev_binds  = cur_ev_binds,
 402                          tcg_imp_specs = imp_specs,
 403                          tcg_rules     = rules,
 404                          tcg_vects     = vects,
 405                          tcg_fords     = fords } = tcg_env
 406             ; all_ev_binds = cur_ev_binds `unionBags` new_ev_binds } ;
 407
 408         (bind_ids, ev_binds', binds', fords', imp_specs', rules', vects')
 409             <- zonkTopDecls all_ev_binds binds sig_ns rules vects imp_specs fords ;
 410
 411         let { final_type_env = extendTypeEnvWithIds type_env bind_ids
 412             ; tcg_env' = tcg_env { tcg_binds    = binds',
 413                                    tcg_ev_binds = ev_binds',
 414                                    tcg_imp_specs = imp_specs',
 415                                    tcg_rules    = rules',
 416                                    tcg_vects    = vects',
 417                                    tcg_fords    = fords' } } ;
 418
 419         setGlobalTypeEnv tcg_env' final_type_env
 420    } }
 421
 422 tc_rn_src_decls :: ModDetails -> [LHsDecl RdrName] -> TcM (TcGblEnv, TcLclEnv)
 423 -- Loops around dealing with each top level inter-splice group
 424 -- in turn, until it's dealt with the entire module
 425 tc_rn_src_decls boot_details ds
 426  = do { (first_group, group_tail) <- findSplice ds  ;
 427                 -- If ds is [] we get ([], Nothing)
 428
 429         -- Deal with decls up to, but not including, the first splice
 430         (tcg_env, rn_decls) <- rnTopSrcDecls first_group ;
 431                 -- rnTopSrcDecls fails if there are any errors
 432
 433         (tcg_env, tcl_env) <- setGblEnv tcg_env $
 434                               tcTopSrcDecls boot_details rn_decls ;
 435
 436         -- If there is no splice, we're nearly done
 437         setEnvs (tcg_env, tcl_env) $
 438         case group_tail of {
 439            Nothing -> do { tcg_env <- checkMain ;       -- Check for `main'
 440                            return (tcg_env, tcl_env)
 441                       } ;
 442
 443 #ifndef GHCI
 444         -- There shouldn't be a splice
 445            Just (SpliceDecl {}, _) -> do {
 446         failWithTc (text "Can't do a top-level splice; need a bootstrapped compiler")
 447 #else
 448         -- If there's a splice, we must carry on
 449            Just (SpliceDecl splice_expr _, rest_ds) -> do {
 450
 451         -- Rename the splice expression, and get its supporting decls
 452         (rn_splice_expr, splice_fvs) <- checkNoErrs (rnLExpr splice_expr) ;
 453                 -- checkNoErrs: don't typecheck if renaming failed
 454         rnDump (ppr rn_splice_expr) ;
 455
 456         -- Execute the splice
 457         spliced_decls <- tcSpliceDecls rn_splice_expr ;
 458
 459         -- Glue them on the front of the remaining decls and loop
 460         setGblEnv (tcg_env `addTcgDUs` usesOnly splice_fvs) $
 461         tc_rn_src_decls boot_details (spliced_decls ++ rest_ds)
 462 #endif /* GHCI */
 463     } } }
 464 \end{code}
 465
 466 %************************************************************************
 467 %*                                                                      *
 468         Compiling hs-boot source files, and
 469         comparing the hi-boot interface with the real thing
 470 %*                                                                      *
 471 %************************************************************************
 472
 473 \begin{code}
 474 tcRnHsBootDecls :: [LHsDecl RdrName] -> TcM TcGblEnv
 475 tcRnHsBootDecls decls
 476    = do { (first_group, group_tail) <- findSplice decls
 477
 478                 -- Rename the declarations
 479         ; (tcg_env, HsGroup {
 480                    hs_tyclds = tycl_decls,
 481                    hs_instds = inst_decls,
 482                    hs_derivds = deriv_decls,
 483                    hs_fords  = for_decls,
 484                    hs_defds  = def_decls,
 485                    hs_ruleds = rule_decls,
 486                    hs_vects  = vect_decls,
 487                    hs_annds  = _,
 488                    hs_valds  = val_binds }) <- rnTopSrcDecls first_group
 489         ; (gbl_env, lie) <- captureConstraints $ setGblEnv tcg_env $ do {
 490
 491
 492                 -- Check for illegal declarations
 493         ; case group_tail of
 494              Just (SpliceDecl d _, _) -> badBootDecl "splice" d
 495              Nothing                  -> return ()
 496         ; mapM_ (badBootDecl "foreign") for_decls
 497         ; mapM_ (badBootDecl "default") def_decls
 498         ; mapM_ (badBootDecl "rule")    rule_decls
 499         ; mapM_ (badBootDecl "vect")    vect_decls
 500
 501                 -- Typecheck type/class decls
 502         ; traceTc "Tc2" empty
 503         ; (tcg_env, aux_binds, dm_ids, _)
 504                <- tcTyAndClassDecls emptyModDetails tycl_decls
 505         ; setGblEnv tcg_env    $
 506           tcExtendIdEnv dm_ids $ do {
 507
 508                 -- Typecheck instance decls
 509                 -- Family instance declarations are rejected here
 510         ; traceTc "Tc3" empty
 511         ; (tcg_env, inst_infos, _deriv_binds)
 512             <- tcInstDecls1 (concat tycl_decls) inst_decls deriv_decls
 513
 514         ; setGblEnv tcg_env     $ do {
 515
 516                 -- Typecheck value declarations
 517         ; traceTc "Tc5" empty
 518         ; val_ids <- tcHsBootSigs val_binds
 519
 520                 -- Wrap up
 521                 -- No simplification or zonking to do
 522         ; traceTc "Tc7a" empty
 523         ; gbl_env <- getGblEnv
 524
 525                 -- Make the final type-env
 526                 -- Include the dfun_ids so that their type sigs
 527                 -- are written into the interface file.
 528                 -- And similarly the aux_ids from aux_binds
 529         ; let { type_env0 = tcg_type_env gbl_env
 530               ; type_env1 = extendTypeEnvWithIds type_env0 val_ids
 531               ; type_env2 = extendTypeEnvWithIds type_env1 dfun_ids
 532               ; type_env3 = extendTypeEnvWithIds type_env2 aux_ids
 533               ; dfun_ids = map iDFunId inst_infos
 534               ; aux_ids  = case aux_binds of
 535                              ValBindsOut _ sigs -> [id | L _ (IdSig id) <- sigs]
 536                              _                  -> panic "tcRnHsBoodDecls"
 537               }
 538
 539         ; setGlobalTypeEnv gbl_env type_env3
 540    }}}
 541    ; traceTc "boot" (ppr lie); return gbl_env }
 542
 543 badBootDecl :: String -> Located decl -> TcM ()
 544 badBootDecl what (L loc _)
 545   = addErrAt loc (char 'A' <+> text what
 546       <+> ptext (sLit "declaration is not (currently) allowed in a hs-boot file"))
 547 \end{code}
 548
 549 Once we've typechecked the body of the module, we want to compare what
 550 we've found (gathered in a TypeEnv) with the hi-boot details (if any).
 551
 552 \begin{code}
 553 checkHiBootIface :: TcGblEnv -> ModDetails -> TcM TcGblEnv
 554 -- Compare the hi-boot file for this module (if there is one)
 555 -- with the type environment we've just come up with
 556 -- In the common case where there is no hi-boot file, the list
 557 -- of boot_names is empty.
 558 --
 559 -- The bindings we return give bindings for the dfuns defined in the
 560 -- hs-boot file, such as        $fbEqT = $fEqT
 561
 562 checkHiBootIface
 563         tcg_env@(TcGblEnv { tcg_src = hs_src, tcg_binds = binds,
 564                             tcg_insts = local_insts,
 565                             tcg_type_env = local_type_env, tcg_exports = local_exports })
 566         (ModDetails { md_insts = boot_insts, md_fam_insts = boot_fam_insts,
 567                       md_types = boot_type_env, md_exports = boot_exports })
 568   | isHsBoot hs_src     -- Current module is already a hs-boot file!
 569   = return tcg_env
 570
 571   | otherwise
 572   = do  { traceTc "checkHiBootIface" $ vcat
 573              [ ppr boot_type_env, ppr boot_insts, ppr boot_exports]
 574
 575                 -- Check the exports of the boot module, one by one
 576         ; mapM_ check_export boot_exports
 577
 578                 -- Check for no family instances
 579         ; unless (null boot_fam_insts) $
 580             panic ("TcRnDriver.checkHiBootIface: Cannot handle family " ++
 581                    "instances in boot files yet...")
 582             -- FIXME: Why?  The actual comparison is not hard, but what would
 583             --        be the equivalent to the dfun bindings returned for class
 584             --        instances?  We can't easily equate tycons...
 585
 586                 -- Check instance declarations
 587         ; mb_dfun_prs <- mapM check_inst boot_insts
 588         ; let dfun_prs   = catMaybes mb_dfun_prs
 589               boot_dfuns = map fst dfun_prs
 590               dfun_binds = listToBag [ mkVarBind boot_dfun (nlHsVar dfun)
 591                                      | (boot_dfun, dfun) <- dfun_prs ]
 592               type_env'  = extendTypeEnvWithIds local_type_env boot_dfuns
 593               tcg_env'   = tcg_env { tcg_binds = binds `unionBags` dfun_binds }
 594
 595         ; failIfErrsM
 596         ; setGlobalTypeEnv tcg_env' type_env' }
 597              -- Update the global type env *including* the knot-tied one
 598              -- so that if the source module reads in an interface unfolding
 599              -- mentioning one of the dfuns from the boot module, then it
 600              -- can "see" that boot dfun.   See Trac #4003
 601   where
 602     check_export boot_avail     -- boot_avail is exported by the boot iface
 603       | name `elem` dfun_names = return ()
 604       | isWiredInName name     = return ()      -- No checking for wired-in names.  In particular,
 605                                                 -- 'error' is handled by a rather gross hack
 606                                                 -- (see comments in GHC.Err.hs-boot)
 607
 608         -- Check that the actual module exports the same thing
 609       | not (null missing_names)
 610       = addErrAt (nameSrcSpan (head missing_names))
 611                  (missingBootThing (head missing_names) "exported by")
 612
 613         -- If the boot module does not *define* the thing, we are done
 614         -- (it simply re-exports it, and names match, so nothing further to do)
 615       | isNothing mb_boot_thing = return ()
 616
 617         -- Check that the actual module also defines the thing, and
 618         -- then compare the definitions
 619       | Just real_thing <- lookupTypeEnv local_type_env name,
 620         Just boot_thing <- mb_boot_thing
 621       = when (not (checkBootDecl boot_thing real_thing))
 622             $ addErrAt (nameSrcSpan (getName boot_thing))
 623                        (let boot_decl = tyThingToIfaceDecl
 624                                                (fromJust mb_boot_thing)
 625                             real_decl = tyThingToIfaceDecl real_thing
 626                         in bootMisMatch real_thing boot_decl real_decl)
 627
 628       | otherwise
 629       = addErrTc (missingBootThing name "defined in")
 630       where
 631         name          = availName boot_avail
 632         mb_boot_thing = lookupTypeEnv boot_type_env name
 633         missing_names = case lookupNameEnv local_export_env name of
 634                           Nothing    -> [name]
 635                           Just avail -> availNames boot_avail `minusList` availNames avail
 636
 637     dfun_names = map getName boot_insts
 638
 639     local_export_env :: NameEnv AvailInfo
 640     local_export_env = availsToNameEnv local_exports
 641
 642     check_inst :: Instance -> TcM (Maybe (Id, Id))
 643         -- Returns a pair of the boot dfun in terms of the equivalent real dfun
 644     check_inst boot_inst
 645         = case [dfun | inst <- local_insts,
 646                        let dfun = instanceDFunId inst,
 647                        idType dfun `tcEqType` boot_inst_ty ] of
 648             [] -> do { traceTc "check_inst" (vcat [ text "local_insts" <+> vcat (map (ppr . idType . instanceDFunId) local_insts)
 649                                                   , text "boot_inst"   <+> ppr boot_inst
 650                                                   , text "boot_inst_ty" <+> ppr boot_inst_ty
 651                                                   ])
 652                      ; addErrTc (instMisMatch boot_inst); return Nothing }
 653             (dfun:_) -> return (Just (local_boot_dfun, dfun))
 654         where
 655           boot_dfun = instanceDFunId boot_inst
 656           boot_inst_ty = idType boot_dfun
 657           local_boot_dfun = Id.mkExportedLocalId (idName boot_dfun) boot_inst_ty
 658
 659
 660 -- This has to compare the TyThing from the .hi-boot file to the TyThing
 661 -- in the current source file.  We must be careful to allow alpha-renaming
 662 -- where appropriate, and also the boot declaration is allowed to omit
 663 -- constructors and class methods.
 664 --
 665 -- See rnfail055 for a good test of this stuff.
 666
 667 checkBootDecl :: TyThing -> TyThing -> Bool
 668
 669 checkBootDecl (AnId id1) (AnId id2)
 670   = ASSERT(id1 == id2)
 671     (idType id1 `tcEqType` idType id2)
 672
 673 checkBootDecl (ATyCon tc1) (ATyCon tc2)
 674   = checkBootTyCon tc1 tc2
 675
 676 checkBootDecl (AClass c1)  (AClass c2)
 677   = let
 678        (clas_tyvars1, clas_fds1, sc_theta1, _, ats1, op_stuff1)
 679           = classExtraBigSig c1
 680        (clas_tyvars2, clas_fds2, sc_theta2, _, ats2, op_stuff2)
 681           = classExtraBigSig c2
 682
 683        env0 = mkRnEnv2 emptyInScopeSet
 684        env = rnBndrs2 env0 clas_tyvars1 clas_tyvars2
 685
 686        eqSig (id1, def_meth1) (id2, def_meth2)
 687          = idName id1 == idName id2 &&
 688            tcEqTypeX env op_ty1 op_ty2 &&
 689            def_meth1 == def_meth2
 690          where
 691           (_, rho_ty1) = splitForAllTys (idType id1)
 692           op_ty1 = funResultTy rho_ty1
 693           (_, rho_ty2) = splitForAllTys (idType id2)
 694           op_ty2 = funResultTy rho_ty2
 695
 696        eqFD (as1,bs1) (as2,bs2) =
 697          eqListBy (tcEqTypeX env) (mkTyVarTys as1) (mkTyVarTys as2) &&
 698          eqListBy (tcEqTypeX env) (mkTyVarTys bs1) (mkTyVarTys bs2)
 699
 700        same_kind tv1 tv2 = eqKind (tyVarKind tv1) (tyVarKind tv2)
 701     in
 702        eqListBy same_kind clas_tyvars1 clas_tyvars2 &&
 703              -- Checks kind of class
 704        eqListBy eqFD clas_fds1 clas_fds2 &&
 705        (null sc_theta1 && null op_stuff1 && null ats1
 706         ||   -- Above tests for an "abstract" class
 707         eqListBy (tcEqPredX env) sc_theta1 sc_theta2 &&
 708         eqListBy eqSig op_stuff1 op_stuff2 &&
 709         eqListBy checkBootTyCon ats1 ats2)
 710
 711 checkBootDecl (ADataCon dc1) (ADataCon _)
 712   = pprPanic "checkBootDecl" (ppr dc1)
 713
 714 checkBootDecl _ _ = False -- probably shouldn't happen
 715
 716 ----------------
 717 checkBootTyCon :: TyCon -> TyCon -> Bool
 718 checkBootTyCon tc1 tc2
 719   | not (eqKind (tyConKind tc1) (tyConKind tc2))
 720   = False       -- First off, check the kind
 721
 722   | isSynTyCon tc1 && isSynTyCon tc2
 723   = ASSERT(tc1 == tc2)
 724     let tvs1 = tyConTyVars tc1; tvs2 = tyConTyVars tc2
 725         env = rnBndrs2 env0 tvs1 tvs2
 726
 727         eqSynRhs SynFamilyTyCon SynFamilyTyCon
 728             = True
 729         eqSynRhs (SynonymTyCon t1) (SynonymTyCon t2)
 730             = tcEqTypeX env t1 t2
 731         eqSynRhs _ _ = False
 732     in
 733     equalLength tvs1 tvs2 &&
 734     eqSynRhs (synTyConRhs tc1) (synTyConRhs tc2)
 735
 736   | isAlgTyCon tc1 && isAlgTyCon tc2
 737   = ASSERT(tc1 == tc2)
 738     eqKind (tyConKind tc1) (tyConKind tc2) &&
 739     eqListBy tcEqPred (tyConStupidTheta tc1) (tyConStupidTheta tc2) &&
 740     eqAlgRhs (algTyConRhs tc1) (algTyConRhs tc2)
 741
 742   | isForeignTyCon tc1 && isForeignTyCon tc2
 743   = eqKind (tyConKind tc1) (tyConKind tc2) &&
 744     tyConExtName tc1 == tyConExtName tc2
 745
 746   | otherwise = False
 747   where
 748         env0 = mkRnEnv2 emptyInScopeSet
 749
 750         eqAlgRhs AbstractTyCon _ = True
 751         eqAlgRhs DataFamilyTyCon{} DataFamilyTyCon{} = True
 752         eqAlgRhs tc1@DataTyCon{} tc2@DataTyCon{} =
 753             eqListBy eqCon (data_cons tc1) (data_cons tc2)
 754         eqAlgRhs tc1@NewTyCon{} tc2@NewTyCon{} =
 755             eqCon (data_con tc1) (data_con tc2)
 756         eqAlgRhs _ _ = False
 757
 758         eqCon c1 c2
 759           =  dataConName c1 == dataConName c2
 760           && dataConIsInfix c1 == dataConIsInfix c2
 761           && dataConStrictMarks c1 == dataConStrictMarks c2
 762           && dataConFieldLabels c1 == dataConFieldLabels c2
 763           && let tvs1 = dataConUnivTyVars c1 ++ dataConExTyVars c1
 764                  tvs2 = dataConUnivTyVars c2 ++ dataConExTyVars c2
 765                  env = rnBndrs2 env0 tvs1 tvs2
 766              in
 767               equalLength tvs1 tvs2 &&
 768               eqListBy (tcEqPredX env)
 769                         (dataConEqTheta c1 ++ dataConDictTheta c1)
 770                         (dataConEqTheta c2 ++ dataConDictTheta c2) &&
 771               eqListBy (tcEqTypeX env)
 772                         (dataConOrigArgTys c1)
 773                         (dataConOrigArgTys c2)
 774
 775 ----------------
 776 missingBootThing :: Name -> String -> SDoc
 777 missingBootThing name what
 778   = ppr name <+> ptext (sLit "is exported by the hs-boot file, but not")
 779               <+> text what <+> ptext (sLit "the module")
 780
 781 bootMisMatch :: TyThing -> IfaceDecl -> IfaceDecl -> SDoc
 782 bootMisMatch thing boot_decl real_decl
 783   = vcat [ppr thing <+> ptext (sLit "has conflicting definitions in the module and its hs-boot file"),
 784           ptext (sLit "Main module:") <+> ppr real_decl,
 785           ptext (sLit "Boot file:  ") <+> ppr boot_decl]
 786
 787 instMisMatch :: Instance -> SDoc
 788 instMisMatch inst
 789   = hang (ppr inst)
 790        2 (ptext (sLit "is defined in the hs-boot file, but not in the module itself"))
 791 \end{code}
 792
 793
 794 %************************************************************************
 795 %*                                                                      *
 796         Type-checking the top level of a module
 797 %*                                                                      *
 798 %************************************************************************
 799
 800 tcRnGroup takes a bunch of top-level source-code declarations, and
 801  * renames them
 802  * gets supporting declarations from interface files
 803  * typechecks them
 804  * zonks them
 805  * and augments the TcGblEnv with the results
 806
 807 In Template Haskell it may be called repeatedly for each group of
 808 declarations.  It expects there to be an incoming TcGblEnv in the
 809 monad; it augments it and returns the new TcGblEnv.
 810
 811 \begin{code}
 812 ------------------------------------------------
 813 rnTopSrcDecls :: HsGroup RdrName -> TcM (TcGblEnv, HsGroup Name)
 814 -- Fails if there are any errors
 815 rnTopSrcDecls group
 816  = do { -- Rename the source decls
 817         traceTc "rn12" empty ;
 818         (tcg_env, rn_decls) <- checkNoErrs $ rnSrcDecls group ;
 819         traceTc "rn13" empty ;
 820
 821         -- save the renamed syntax, if we want it
 822         let { tcg_env'
 823                 | Just grp <- tcg_rn_decls tcg_env
 824                   = tcg_env{ tcg_rn_decls = Just (appendGroups grp rn_decls) }
 825                 | otherwise
 826                    = tcg_env };
 827
 828                 -- Dump trace of renaming part
 829         rnDump (ppr rn_decls) ;
 830
 831         return (tcg_env', rn_decls)
 832    }
 833
 834 ------------------------------------------------
 835 tcTopSrcDecls :: ModDetails -> HsGroup Name -> TcM (TcGblEnv, TcLclEnv)
 836 tcTopSrcDecls boot_details
 837         (HsGroup { hs_tyclds = tycl_decls,
 838                    hs_instds = inst_decls,
 839                    hs_derivds = deriv_decls,
 840                    hs_fords  = foreign_decls,
 841                    hs_defds  = default_decls,
 842                    hs_annds  = annotation_decls,
 843                    hs_ruleds = rule_decls,
 844                    hs_vects  = vect_decls,
 845                    hs_valds  = val_binds })
 846  = do {         -- Type-check the type and class decls, and all imported decls
 847                 -- The latter come in via tycl_decls
 848         traceTc "Tc2" empty ;
 849
 850         (tcg_env, aux_binds, dm_ids, kc_decls) <- tcTyAndClassDecls boot_details tycl_decls ;
 851                 -- If there are any errors, tcTyAndClassDecls fails here
 852
 853         setGblEnv tcg_env       $
 854         tcExtendIdEnv dm_ids    $ do {
 855
 856                 -- Source-language instances, including derivings,
 857                 -- and import the supporting declarations
 858         traceTc "Tc3" empty ;
 859         (tcg_env, inst_infos, deriv_binds)
 860             <- tcInstDecls1 (concat tycl_decls) inst_decls deriv_decls;
 861         setGblEnv tcg_env       $ do {
 862
 863                 -- Foreign import declarations next.
 864         traceTc "Tc4" empty ;
 865         (fi_ids, fi_decls) <- tcForeignImports foreign_decls ;
 866         tcExtendGlobalValEnv fi_ids     $ do {
 867
 868                 -- Default declarations
 869         traceTc "Tc4a" empty ;
 870         default_tys <- tcDefaults default_decls ;
 871         updGblEnv (\gbl -> gbl { tcg_default = default_tys }) $ do {
 872
 873                 -- Now GHC-generated derived bindings, generics, and selectors
 874                 -- Do not generate warnings from compiler-generated code;
 875                 -- hence the use of discardWarnings
 876         (tc_aux_binds,   specs1, tcl_env) <- discardWarnings (tcTopBinds aux_binds) ;
 877         (tc_deriv_binds, specs2, tcl_env) <- setLclTypeEnv tcl_env $
 878                                              discardWarnings (tcTopBinds deriv_binds) ;
 879
 880                 -- Value declarations next
 881         traceTc "Tc5" empty ;
 882         (tc_val_binds, specs3, tcl_env) <- setLclTypeEnv tcl_env $
 883                                            tcTopBinds val_binds;
 884
 885         setLclTypeEnv tcl_env $ do {    -- Environment doesn't change now
 886
 887                 -- Second pass over class and instance declarations,
 888                 -- now using the kind-checked decls
 889         traceTc "Tc6" empty ;
 890         inst_binds <- tcInstDecls2 kc_decls inst_infos ;
 891
 892                 -- Foreign exports
 893         traceTc "Tc7" empty ;
 894         (foe_binds, foe_decls) <- tcForeignExports foreign_decls ;
 895
 896                 -- Annotations
 897         annotations <- tcAnnotations annotation_decls ;
 898
 899                 -- Rules
 900         rules <- tcRules rule_decls ;
 901
 902                 -- Vectorisation declarations
 903         vects <- tcVectDecls vect_decls ;
 904
 905                 -- Wrap up
 906         traceTc "Tc7a" empty ;
 907         tcg_env <- getGblEnv ;
 908         let { all_binds = tc_val_binds   `unionBags`
 909                           tc_deriv_binds `unionBags`
 910                           tc_aux_binds   `unionBags`
 911                           inst_binds     `unionBags`
 912                           foe_binds
 913
 914             ; sig_names = mkNameSet (collectHsValBinders val_binds)
 915                           `minusNameSet` getTypeSigNames val_binds
 916
 917                 -- Extend the GblEnv with the (as yet un-zonked)
 918                 -- bindings, rules, foreign decls
 919             ; tcg_env' = tcg_env { tcg_binds = tcg_binds tcg_env `unionBags` all_binds
 920                                  , tcg_imp_specs = tcg_imp_specs tcg_env ++ specs1 ++ specs2 ++
 921                                                    specs3
 922                                  , tcg_sigs  = tcg_sigs tcg_env `unionNameSets` sig_names
 923                                  , tcg_rules = tcg_rules tcg_env ++ rules
 924                                  , tcg_vects = tcg_vects tcg_env ++ vects
 925                                  , tcg_anns  = tcg_anns tcg_env ++ annotations
 926                                  , tcg_fords = tcg_fords tcg_env ++ foe_decls ++ fi_decls } } ;
 927         return (tcg_env', tcl_env)
 928     }}}}}}
 929 \end{code}
 930
 931
 932 %************************************************************************
 933 %*                                                                      *
 934         Checking for 'main'
 935 %*                                                                      *
 936 %************************************************************************
 937
 938 \begin{code}
 939 checkMain :: TcM TcGblEnv
 940 -- If we are in module Main, check that 'main' is defined.
 941 checkMain
 942   = do { tcg_env   <- getGblEnv ;
 943          dflags    <- getDOpts ;
 944          check_main dflags tcg_env
 945     }
 946
 947 check_main :: DynFlags -> TcGblEnv -> TcM TcGblEnv
 948 check_main dflags tcg_env
 949  | mod /= main_mod
 950  = traceTc "checkMain not" (ppr main_mod <+> ppr mod) >>
 951    return tcg_env
 952
 953  | otherwise
 954  = do   { mb_main <- lookupGlobalOccRn_maybe main_fn
 955                 -- Check that 'main' is in scope
 956                 -- It might be imported from another module!
 957         ; case mb_main of {
 958              Nothing -> do { traceTc "checkMain fail" (ppr main_mod <+> ppr main_fn)
 959                            ; complain_no_main
 960                            ; return tcg_env } ;
 961              Just main_name -> do
 962
 963         { traceTc "checkMain found" (ppr main_mod <+> ppr main_fn)
 964         ; let loc = srcLocSpan (getSrcLoc main_name)
 965         ; ioTyCon <- tcLookupTyCon ioTyConName
 966         ; res_ty <- newFlexiTyVarTy liftedTypeKind
 967         ; main_expr
 968                 <- addErrCtxt mainCtxt    $
 969                    tcMonoExpr (L loc (HsVar main_name)) (mkTyConApp ioTyCon [res_ty])
 970
 971                 -- See Note [Root-main Id]
 972                 -- Construct the binding
 973                 --      :Main.main :: IO res_ty = runMainIO res_ty main
 974         ; run_main_id <- tcLookupId runMainIOName
 975         ; let { root_main_name =  mkExternalName rootMainKey rOOT_MAIN
 976                                    (mkVarOccFS (fsLit "main"))
 977                                    (getSrcSpan main_name)
 978               ; root_main_id = Id.mkExportedLocalId root_main_name
 979                                                     (mkTyConApp ioTyCon [res_ty])
 980               ; co  = mkWpTyApps [res_ty]
 981               ; rhs = nlHsApp (mkLHsWrap co (nlHsVar run_main_id)) main_expr
 982               ; main_bind = mkVarBind root_main_id rhs }
 983
 984         ; return (tcg_env { tcg_main  = Just main_name,
 985                             tcg_binds = tcg_binds tcg_env
 986                                         `snocBag` main_bind,
 987                             tcg_dus   = tcg_dus tcg_env
 988                                         `plusDU` usesOnly (unitFV main_name)
 989                         -- Record the use of 'main', so that we don't
 990                         -- complain about it being defined but not used
 991                  })
 992     }}}
 993   where
 994     mod          = tcg_mod tcg_env
 995     main_mod     = mainModIs dflags
 996     main_fn      = getMainFun dflags
 997
 998     complain_no_main | ghcLink dflags == LinkInMemory = return ()
 999                      | otherwise = failWithTc noMainMsg
1000         -- In interactive mode, don't worry about the absence of 'main'
1001         -- In other modes, fail altogether, so that we don't go on
1002         -- and complain a second time when processing the export list.
1003
1004     mainCtxt  = ptext (sLit "When checking the type of the") <+> pp_main_fn
1005     noMainMsg = ptext (sLit "The") <+> pp_main_fn
1006                 <+> ptext (sLit "is not defined in module") <+> quotes (ppr main_mod)
1007     pp_main_fn = ppMainFn main_fn
1008
1009 ppMainFn :: RdrName -> SDoc
1010 ppMainFn main_fn
1011   | main_fn == main_RDR_Unqual
1012   = ptext (sLit "function") <+> quotes (ppr main_fn)
1013   | otherwise
1014   = ptext (sLit "main function") <+> quotes (ppr main_fn)
1015
1016 -- | Get the unqualified name of the function to use as the \"main\" for the main module.
1017 -- Either returns the default name or the one configured on the command line with -main-is
1018 getMainFun :: DynFlags -> RdrName
1019 getMainFun dflags = case (mainFunIs dflags) of
1020     Just fn -> mkRdrUnqual (mkVarOccFS (mkFastString fn))
1021     Nothing -> main_RDR_Unqual
1022
1023 checkMainExported :: TcGblEnv -> TcM ()
1024 checkMainExported tcg_env = do
1025   dflags    <- getDOpts
1026   case tcg_main tcg_env of
1027     Nothing -> return () -- not the main module
1028     Just main_name -> do
1029       let main_mod = mainModIs dflags
1030       checkTc (main_name `elem` concatMap availNames (tcg_exports tcg_env)) $
1031               ptext (sLit "The") <+> ppMainFn (nameRdrName main_name) <+>
1032               ptext (sLit "is not exported by module") <+> quotes (ppr main_mod)
1033 \end{code}
1034
1035 Note [Root-main Id]
1036 ~~~~~~~~~~~~~~~~~~~
1037 The function that the RTS invokes is always :Main.main, which we call
1038 root_main_id.  (Because GHC allows the user to have a module not
1039 called Main as the main module, we can't rely on the main function
1040 being called "Main.main".  That's why root_main_id has a fixed module
1041 ":Main".)
1042
1043 This is unusual: it's a LocalId whose Name has a Module from another
1044 module.  Tiresomely, we must filter it out again in MkIface, les we
1045 get two defns for 'main' in the interface file!
1046
1047
1048 %*********************************************************
1049 %*                                                       *
1050                 GHCi stuff
1051 %*                                                       *
1052 %*********************************************************
1053
1054 \begin{code}
1055 setInteractiveContext :: HscEnv -> InteractiveContext -> TcRn a -> TcRn a
1056 setInteractiveContext hsc_env icxt thing_inside
1057   = let -- Initialise the tcg_inst_env with instances from all home modules.
1058         -- This mimics the more selective call to hptInstances in tcRnModule.
1059         (home_insts, home_fam_insts) = hptInstances hsc_env (\_ -> True)
1060     in
1061     updGblEnv (\env -> env {
1062         tcg_rdr_env      = ic_rn_gbl_env icxt,
1063         tcg_inst_env     = extendInstEnvList    (tcg_inst_env env) home_insts,
1064         tcg_fam_inst_env = extendFamInstEnvList (tcg_fam_inst_env env)
1065                                                 home_fam_insts
1066       }) $
1067
1068     tcExtendGhciEnv (ic_tmp_ids icxt) $
1069         -- tcExtendGhciEnv does lots:
1070         --   - it extends the local type env (tcl_env) with the given Ids,
1071         --   - it extends the local rdr env (tcl_rdr) with the Names from
1072         --     the given Ids
1073         --   - it adds the free tyvars of the Ids to the tcl_tyvars
1074         --     set.
1075         --
1076         -- later ids in ic_tmp_ids must shadow earlier ones with the same
1077         -- OccName, and tcExtendIdEnv implements this behaviour.
1078
1079     do  { traceTc "setIC" (ppr (ic_tmp_ids icxt))
1080         ; thing_inside }
1081 \end{code}
1082
1083
1084 \begin{code}
1085 #ifdef GHCI
1086 tcRnStmt :: HscEnv
1087          -> InteractiveContext
1088          -> LStmt RdrName
1089          -> IO (Messages, Maybe ([Id], LHsExpr Id))
1090                 -- The returned [Id] is the list of new Ids bound by
1091                 -- this statement.  It can be used to extend the
1092                 -- InteractiveContext via extendInteractiveContext.
1093                 --
1094                 -- The returned TypecheckedHsExpr is of type IO [ () ],
1095                 -- a list of the bound values, coerced to ().
1096
1097 tcRnStmt hsc_env ictxt rdr_stmt
1098   = initTcPrintErrors hsc_env iNTERACTIVE $
1099     setInteractiveContext hsc_env ictxt $ do {
1100
1101     -- Rename; use CmdLineMode because tcRnStmt is only used interactively
1102     (([rn_stmt], _), fvs) <- rnStmts GhciStmt [rdr_stmt] $ \_ ->
1103                              return ((), emptyFVs) ;
1104     traceRn (text "tcRnStmt" <+> vcat [ppr rdr_stmt, ppr rn_stmt, ppr fvs]) ;
1105     failIfErrsM ;
1106     rnDump (ppr rn_stmt) ;
1107
1108     -- The real work is done here
1109     (bound_ids, tc_expr) <- mkPlan rn_stmt ;
1110     zonked_expr <- zonkTopLExpr tc_expr ;
1111     zonked_ids  <- zonkTopBndrs bound_ids ;
1112
1113         -- None of the Ids should be of unboxed type, because we
1114         -- cast them all to HValues in the end!
1115     mapM_ bad_unboxed (filter (isUnLiftedType . idType) zonked_ids) ;
1116
1117     traceTc "tcs 1" empty ;
1118     let { global_ids = map globaliseAndTidyId zonked_ids } ;
1119         -- Note [Interactively-bound Ids in GHCi]
1120
1121 {- ---------------------------------------------
1122    At one stage I removed any shadowed bindings from the type_env;
1123    they are inaccessible but might, I suppose, cause a space leak if we leave them there.
1124    However, with Template Haskell they aren't necessarily inaccessible.  Consider this
1125    GHCi session
1126          Prelude> let f n = n * 2 :: Int
1127          Prelude> fName <- runQ [| f |]
1128          Prelude> $(return $ AppE fName (LitE (IntegerL 7)))
1129          14
1130          Prelude> let f n = n * 3 :: Int
1131          Prelude> $(return $ AppE fName (LitE (IntegerL 7)))
1132    In the last line we use 'fName', which resolves to the *first* 'f'
1133    in scope. If we delete it from the type env, GHCi crashes because
1134    it doesn't expect that.
1135
1136    Hence this code is commented out
1137
1138 -------------------------------------------------- -}
1139
1140     dumpOptTcRn Opt_D_dump_tc
1141         (vcat [text "Bound Ids" <+> pprWithCommas ppr global_ids,
1142                text "Typechecked expr" <+> ppr zonked_expr]) ;
1143
1144     return (global_ids, zonked_expr)
1145     }
1146   where
1147     bad_unboxed id = addErr (sep [ptext (sLit "GHCi can't bind a variable of unlifted type:"),
1148                                   nest 2 (ppr id <+> dcolon <+> ppr (idType id))])
1149 \end{code}
1150
1151 Note [Interactively-bound Ids in GHCi]
1152 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1153 The Ids bound by previous Stmts in Template Haskell are currently
1154         a) GlobalIds
1155         b) with an Internal Name (not External)
1156         c) and a tidied type
1157
1158  (a) They must be GlobalIds (not LocalIds) otherwise when we come to
1159      compile an expression using these ids later, the byte code
1160      generator will consider the occurrences to be free rather than
1161      global.
1162
1163  (b) They retain their Internal names becuase we don't have a suitable
1164      Module to name them with.  We could revisit this choice.
1165
1166  (c) Their types are tidied.  This is important, because :info may ask
1167      to look at them, and :info expects the things it looks up to have
1168      tidy types
1169
1170
1171 --------------------------------------------------------------------------
1172                 Typechecking Stmts in GHCi
1173
1174 Here is the grand plan, implemented in tcUserStmt
1175
1176         What you type                   The IO [HValue] that hscStmt returns
1177         -------------                   ------------------------------------
1178         let pat = expr          ==>     let pat = expr in return [coerce HVal x, coerce HVal y, ...]
1179                                         bindings: [x,y,...]
1180
1181         pat <- expr             ==>     expr >>= \ pat -> return [coerce HVal x, coerce HVal y, ...]
1182                                         bindings: [x,y,...]
1183
1184         expr (of IO type)       ==>     expr >>= \ it -> return [coerce HVal it]
1185           [NB: result not printed]      bindings: [it]
1186
1187         expr (of non-IO type,   ==>     let it = expr in print it >> return [coerce HVal it]
1188           result showable)              bindings: [it]
1189
1190         expr (of non-IO type,
1191           result not showable)  ==>     error
1192
1193
1194 \begin{code}
1195 ---------------------------
1196 type PlanResult = ([Id], LHsExpr Id)
1197 type Plan = TcM PlanResult
1198
1199 runPlans :: [Plan] -> TcM PlanResult
1200 -- Try the plans in order.  If one fails (by raising an exn), try the next.
1201 -- If one succeeds, take it.
1202 runPlans []     = panic "runPlans"
1203 runPlans [p]    = p
1204 runPlans (p:ps) = tryTcLIE_ (runPlans ps) p
1205
1206 --------------------
1207 mkPlan :: LStmt Name -> TcM PlanResult
1208 mkPlan (L loc (ExprStmt expr _ _))      -- An expression typed at the prompt
1209   = do  { uniq <- newUnique             -- is treated very specially
1210         ; let fresh_it  = itName uniq
1211               the_bind  = L loc $ mkFunBind (L loc fresh_it) matches
1212               matches   = [mkMatch [] expr emptyLocalBinds]
1213               let_stmt  = L loc $ LetStmt (HsValBinds (ValBindsOut [(NonRecursive,unitBag the_bind)] []))
1214               bind_stmt = L loc $ BindStmt (nlVarPat fresh_it) expr
1215                                            (HsVar bindIOName) noSyntaxExpr
1216               print_it  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar fresh_it))
1217                                            (HsVar thenIOName) placeHolderType
1218
1219         -- The plans are:
1220         --      [it <- e; print it]     but not if it::()
1221         --      [it <- e]
1222         --      [let it = e; print it]
1223         ; runPlans [    -- Plan A
1224                     do { stuff@([it_id], _) <- tcGhciStmts [bind_stmt, print_it]
1225                        ; it_ty <- zonkTcType (idType it_id)
1226                        ; when (isUnitTy it_ty) failM
1227                        ; return stuff },
1228
1229                         -- Plan B; a naked bind statment
1230                     tcGhciStmts [bind_stmt],
1231
1232                         -- Plan C; check that the let-binding is typeable all by itself.
1233                         -- If not, fail; if so, try to print it.
1234                         -- The two-step process avoids getting two errors: one from
1235                         -- the expression itself, and one from the 'print it' part
1236                         -- This two-step story is very clunky, alas
1237                     do { _ <- checkNoErrs (tcGhciStmts [let_stmt])
1238                                 --- checkNoErrs defeats the error recovery of let-bindings
1239                        ; tcGhciStmts [let_stmt, print_it] }
1240           ]}
1241
1242 mkPlan stmt@(L loc (BindStmt {}))
1243   | [v] <- collectLStmtBinders stmt             -- One binder, for a bind stmt
1244   = do  { let print_v  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar v))
1245                                            (HsVar thenIOName) placeHolderType
1246
1247         ; print_bind_result <- doptM Opt_PrintBindResult
1248         ; let print_plan = do
1249                   { stuff@([v_id], _) <- tcGhciStmts [stmt, print_v]
1250                   ; v_ty <- zonkTcType (idType v_id)
1251                   ; when (isUnitTy v_ty || not (isTauTy v_ty)) failM
1252                   ; return stuff }
1253
1254         -- The plans are:
1255         --      [stmt; print v]         but not if v::()
1256         --      [stmt]
1257         ; runPlans ((if print_bind_result then [print_plan] else []) ++
1258                     [tcGhciStmts [stmt]])
1259         }
1260
1261 mkPlan stmt
1262   = tcGhciStmts [stmt]
1263
1264 ---------------------------
1265 tcGhciStmts :: [LStmt Name] -> TcM PlanResult
1266 tcGhciStmts stmts
1267  = do { ioTyCon <- tcLookupTyCon ioTyConName ;
1268         ret_id  <- tcLookupId returnIOName ;            -- return @ IO
1269         let {
1270             ret_ty    = mkListTy unitTy ;
1271             io_ret_ty = mkTyConApp ioTyCon [ret_ty] ;
1272             tc_io_stmts stmts = tcStmts GhciStmt tcDoStmt stmts io_ret_ty ;
1273
1274             names = collectLStmtsBinders stmts ;
1275
1276                 -- mk_return builds the expression
1277                 --      returnIO @ [()] [coerce () x, ..,  coerce () z]
1278                 --
1279                 -- Despite the inconvenience of building the type applications etc,
1280                 -- this *has* to be done in type-annotated post-typecheck form
1281                 -- because we are going to return a list of *polymorphic* values
1282                 -- coerced to type (). If we built a *source* stmt
1283                 --      return [coerce x, ..., coerce z]
1284                 -- then the type checker would instantiate x..z, and we wouldn't
1285                 -- get their *polymorphic* values.  (And we'd get ambiguity errs
1286                 -- if they were overloaded, since they aren't applied to anything.)
1287             mk_return ids = nlHsApp (nlHsTyApp ret_id [ret_ty])
1288                                     (noLoc $ ExplicitList unitTy (map mk_item ids)) ;
1289             mk_item id = nlHsApp (nlHsTyApp unsafeCoerceId [idType id, unitTy])
1290                                  (nlHsVar id)
1291          } ;
1292
1293         -- OK, we're ready to typecheck the stmts
1294         traceTc "TcRnDriver.tcGhciStmts: tc stmts" empty ;
1295         ((tc_stmts, ids), lie) <- captureConstraints $ tc_io_stmts stmts $ \ _ ->
1296                                            mapM tcLookupId names ;
1297                                         -- Look up the names right in the middle,
1298                                         -- where they will all be in scope
1299
1300         -- Simplify the context
1301         traceTc "TcRnDriver.tcGhciStmts: simplify ctxt" empty ;
1302         const_binds <- checkNoErrs (simplifyInteractive lie) ;
1303                 -- checkNoErrs ensures that the plan fails if context redn fails
1304
1305         traceTc "TcRnDriver.tcGhciStmts: done" empty ;
1306         return (ids, mkHsDictLet (EvBinds const_binds) $
1307                      noLoc (HsDo GhciStmt tc_stmts (mk_return ids) io_ret_ty))
1308     }
1309 \end{code}
1310
1311
1312 tcRnExpr just finds the type of an expression
1313
1314 \begin{code}
1315 tcRnExpr :: HscEnv
1316          -> InteractiveContext
1317          -> LHsExpr RdrName
1318          -> IO (Messages, Maybe Type)
1319 tcRnExpr hsc_env ictxt rdr_expr
1320   = initTcPrintErrors hsc_env iNTERACTIVE $
1321     setInteractiveContext hsc_env ictxt $ do {
1322
1323     (rn_expr, _fvs) <- rnLExpr rdr_expr ;
1324     failIfErrsM ;
1325
1326         -- Now typecheck the expression;
1327         -- it might have a rank-2 type (e.g. :t runST)
1328
1329     uniq <- newUnique ;
1330     let { fresh_it  = itName uniq } ;
1331     ((_tc_expr, res_ty), lie)   <- captureConstraints (tcInferRho rn_expr) ;
1332     ((qtvs, dicts, _), lie_top) <- captureConstraints $
1333                                    simplifyInfer TopLevel
1334                                                  False {- No MR for now -}
1335                                                  [(fresh_it, res_ty)]
1336                                                  lie  ;
1337
1338     _ <- simplifyInteractive lie_top ;       -- Ignore the dicionary bindings
1339
1340     let { all_expr_ty = mkForAllTys qtvs (mkPiTypes dicts res_ty) } ;
1341     zonkTcType all_expr_ty
1342     }
1343 \end{code}
1344
1345 tcRnType just finds the kind of a type
1346
1347 \begin{code}
1348 tcRnType :: HscEnv
1349          -> InteractiveContext
1350          -> LHsType RdrName
1351          -> IO (Messages, Maybe Kind)
1352 tcRnType hsc_env ictxt rdr_type
1353   = initTcPrintErrors hsc_env iNTERACTIVE $
1354     setInteractiveContext hsc_env ictxt $ do {
1355
1356     rn_type <- rnLHsType doc rdr_type ;
1357     failIfErrsM ;
1358
1359         -- Now kind-check the type
1360     (_ty', kind) <- kcLHsType rn_type ;
1361     return kind
1362     }
1363   where
1364     doc = ptext (sLit "In GHCi input")
1365
1366 #endif /* GHCi */
1367 \end{code}
1368
1369
1370 %************************************************************************
1371 %*                                                                      *
1372         More GHCi stuff, to do with browsing and getting info
1373 %*                                                                      *
1374 %************************************************************************
1375
1376 \begin{code}
1377 #ifdef GHCI
1378 -- | ASSUMES that the module is either in the 'HomePackageTable' or is
1379 -- a package module with an interface on disk.  If neither of these is
1380 -- true, then the result will be an error indicating the interface
1381 -- could not be found.
1382 getModuleExports :: HscEnv -> Module -> IO (Messages, Maybe [AvailInfo])
1383 getModuleExports hsc_env mod
1384   = let
1385       ic        = hsc_IC hsc_env
1386       checkMods = ic_toplev_scope ic ++ map fst (ic_exports ic)
1387     in
1388     initTc hsc_env HsSrcFile False iNTERACTIVE (tcGetModuleExports mod checkMods)
1389
1390 -- Get the export avail info and also load all orphan and family-instance
1391 -- modules.  Finally, check that the family instances of all modules in the
1392 -- interactive context are consistent (these modules are in the second
1393 -- argument).
1394 tcGetModuleExports :: Module -> [Module] -> TcM [AvailInfo]
1395 tcGetModuleExports mod directlyImpMods
1396   = do { let doc = ptext (sLit "context for compiling statements")
1397        ; iface <- initIfaceTcRn $ loadSysInterface doc mod
1398
1399                 -- Load any orphan-module and family instance-module
1400                 -- interfaces, so their instances are visible.
1401        ; loadOrphanModules (dep_orphs (mi_deps iface)) False
1402        ; loadOrphanModules (dep_finsts (mi_deps iface)) True
1403
1404                 -- Check that the family instances of all directly loaded
1405                 -- modules are consistent.
1406        ; checkFamInstConsistency (dep_finsts (mi_deps iface)) directlyImpMods
1407
1408        ; ifaceExportNames (mi_exports iface)
1409        }
1410
1411 tcRnLookupRdrName :: HscEnv -> RdrName -> IO (Messages, Maybe [Name])
1412 tcRnLookupRdrName hsc_env rdr_name
1413   = initTcPrintErrors hsc_env iNTERACTIVE $
1414     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1415     lookup_rdr_name rdr_name
1416
1417 lookup_rdr_name :: RdrName -> TcM [Name]
1418 lookup_rdr_name rdr_name = do {
1419         -- If the identifier is a constructor (begins with an
1420         -- upper-case letter), then we need to consider both
1421         -- constructor and type class identifiers.
1422     let { rdr_names = dataTcOccs rdr_name } ;
1423
1424         -- results :: [Either Messages Name]
1425     results <- mapM (tryTcErrs . lookupOccRn) rdr_names ;
1426
1427     traceRn (text "xx" <+> vcat [ppr rdr_names, ppr (map snd results)]);
1428         -- The successful lookups will be (Just name)
1429     let { (warns_s, good_names) = unzip [ (msgs, name)
1430                                         | (msgs, Just name) <- results] ;
1431           errs_s = [msgs | (msgs, Nothing) <- results] } ;
1432
1433         -- Fail if nothing good happened, else add warnings
1434     if null good_names then
1435                 -- No lookup succeeded, so
1436                 -- pick the first error message and report it
1437                 -- ToDo: If one of the errors is "could be Foo.X or Baz.X",
1438                 --       while the other is "X is not in scope",
1439                 --       we definitely want the former; but we might pick the latter
1440         do { addMessages (head errs_s) ; failM }
1441       else                      -- Add deprecation warnings
1442         mapM_ addMessages warns_s ;
1443
1444     return good_names
1445  }
1446 #endif
1447
1448 tcRnLookupName :: HscEnv -> Name -> IO (Messages, Maybe TyThing)
1449 tcRnLookupName hsc_env name
1450   = initTcPrintErrors hsc_env iNTERACTIVE $
1451     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1452     tcRnLookupName' name
1453
1454 -- To look up a name we have to look in the local environment (tcl_lcl)
1455 -- as well as the global environment, which is what tcLookup does.
1456 -- But we also want a TyThing, so we have to convert:
1457
1458 tcRnLookupName' :: Name -> TcRn TyThing
1459 tcRnLookupName' name = do
1460    tcthing <- tcLookup name
1461    case tcthing of
1462      AGlobal thing    -> return thing
1463      ATcId{tct_id=id} -> return (AnId id)
1464      _ -> panic "tcRnLookupName'"
1465
1466 tcRnGetInfo :: HscEnv
1467             -> Name
1468             -> IO (Messages, Maybe (TyThing, Fixity, [Instance]))
1469
1470 -- Used to implement :info in GHCi
1471 --
1472 -- Look up a RdrName and return all the TyThings it might be
1473 -- A capitalised RdrName is given to us in the DataName namespace,
1474 -- but we want to treat it as *both* a data constructor
1475 --  *and* as a type or class constructor;
1476 -- hence the call to dataTcOccs, and we return up to two results
1477 tcRnGetInfo hsc_env name
1478   = initTcPrintErrors hsc_env iNTERACTIVE $
1479     tcRnGetInfo' hsc_env name
1480
1481 tcRnGetInfo' :: HscEnv
1482              -> Name
1483              -> TcRn (TyThing, Fixity, [Instance])
1484 tcRnGetInfo' hsc_env name
1485   = let ictxt = hsc_IC hsc_env in
1486     setInteractiveContext hsc_env ictxt $ do
1487
1488         -- Load the interface for all unqualified types and classes
1489         -- That way we will find all the instance declarations
1490         -- (Packages have not orphan modules, and we assume that
1491         --  in the home package all relevant modules are loaded.)
1492     loadUnqualIfaces ictxt
1493
1494     thing  <- tcRnLookupName' name
1495     fixity <- lookupFixityRn name
1496     ispecs <- lookupInsts thing
1497     return (thing, fixity, ispecs)
1498
1499 lookupInsts :: TyThing -> TcM [Instance]
1500 lookupInsts (AClass cls)
1501   = do  { inst_envs <- tcGetInstEnvs
1502         ; return (classInstances inst_envs cls) }
1503
1504 lookupInsts (ATyCon tc)
1505   = do  { (pkg_ie, home_ie) <- tcGetInstEnvs
1506                 -- Load all instances for all classes that are
1507                 -- in the type environment (which are all the ones
1508                 -- we've seen in any interface file so far)
1509         ; return [ ispec        -- Search all
1510                  | ispec <- instEnvElts home_ie ++ instEnvElts pkg_ie
1511                  , let dfun = instanceDFunId ispec
1512                  , relevant dfun ] }
1513   where
1514     relevant df = tc_name `elemNameSet` orphNamesOfDFunHead (idType df)
1515     tc_name     = tyConName tc
1516
1517 lookupInsts _ = return []
1518
1519 loadUnqualIfaces :: InteractiveContext -> TcM ()
1520 -- Load the home module for everything that is in scope unqualified
1521 -- This is so that we can accurately report the instances for
1522 -- something
1523 loadUnqualIfaces ictxt
1524   = initIfaceTcRn $
1525     mapM_ (loadSysInterface doc) (moduleSetElts (mkModuleSet unqual_mods))
1526   where
1527     unqual_mods = [ nameModule name
1528                   | gre <- globalRdrEnvElts (ic_rn_gbl_env ictxt),
1529                     let name = gre_name gre,
1530                     not (isInternalName name),
1531                     isTcOcc (nameOccName name),  -- Types and classes only
1532                     unQualOK gre ]               -- In scope unqualified
1533     doc = ptext (sLit "Need interface for module whose export(s) are in scope unqualified")
1534 \end{code}
1535
1536 %************************************************************************
1537 %*                                                                      *
1538                 Degugging output
1539 %*                                                                      *
1540 %************************************************************************
1541
1542 \begin{code}
1543 rnDump :: SDoc -> TcRn ()
1544 -- Dump, with a banner, if -ddump-rn
1545 rnDump doc = do { dumpOptTcRn Opt_D_dump_rn (mkDumpDoc "Renamer" doc) }
1546
1547 tcDump :: TcGblEnv -> TcRn ()
1548 tcDump env
1549  = do { dflags <- getDOpts ;
1550
1551         -- Dump short output if -ddump-types or -ddump-tc
1552         when (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1553              (dumpTcRn short_dump) ;
1554
1555         -- Dump bindings if -ddump-tc
1556         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump)
1557    }
1558   where
1559     short_dump = pprTcGblEnv env
1560     full_dump  = pprLHsBinds (tcg_binds env)
1561         -- NB: foreign x-d's have undefined's in their types;
1562         --     hence can't show the tc_fords
1563
1564 tcCoreDump :: ModGuts -> TcM ()
1565 tcCoreDump mod_guts
1566  = do { dflags <- getDOpts ;
1567         when (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1568              (dumpTcRn (pprModGuts mod_guts)) ;
1569
1570         -- Dump bindings if -ddump-tc
1571         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump) }
1572   where
1573     full_dump = pprCoreBindings (mg_binds mod_guts)
1574
1575 -- It's unpleasant having both pprModGuts and pprModDetails here
1576 pprTcGblEnv :: TcGblEnv -> SDoc
1577 pprTcGblEnv (TcGblEnv { tcg_type_env  = type_env,
1578                         tcg_insts     = insts,
1579                         tcg_fam_insts = fam_insts,
1580                         tcg_rules     = rules,
1581                         tcg_vects     = vects,
1582                         tcg_imports   = imports })
1583   = vcat [ ppr_types insts type_env
1584          , ppr_tycons fam_insts type_env
1585          , ppr_insts insts
1586          , ppr_fam_insts fam_insts
1587          , vcat (map ppr rules)
1588          , vcat (map ppr vects)
1589          , ppr_gen_tycons (typeEnvTyCons type_env)
1590          , ptext (sLit "Dependent modules:") <+>
1591                 ppr (sortBy cmp_mp $ eltsUFM (imp_dep_mods imports))
1592          , ptext (sLit "Dependent packages:") <+>
1593                 ppr (sortBy stablePackageIdCmp $ imp_dep_pkgs imports)]
1594   where         -- The two uses of sortBy are just to reduce unnecessary
1595                 -- wobbling in testsuite output
1596     cmp_mp (mod_name1, is_boot1) (mod_name2, is_boot2)
1597         = (mod_name1 `stableModuleNameCmp` mod_name2)
1598                   `thenCmp`
1599           (is_boot1 `compare` is_boot2)
1600
1601 pprModGuts :: ModGuts -> SDoc
1602 pprModGuts (ModGuts { mg_types = type_env,
1603                       mg_rules = rules })
1604   = vcat [ ppr_types [] type_env,
1605            ppr_rules rules ]
1606
1607 ppr_types :: [Instance] -> TypeEnv -> SDoc
1608 ppr_types insts type_env
1609   = text "TYPE SIGNATURES" $$ nest 4 (ppr_sigs ids)
1610   where
1611     dfun_ids = map instanceDFunId insts
1612     ids = [id | id <- typeEnvIds type_env, want_sig id]
1613     want_sig id | opt_PprStyle_Debug = True
1614                 | otherwise          = isLocalId id &&
1615                                        isExternalName (idName id) &&
1616                                        not (id `elem` dfun_ids)
1617         -- isLocalId ignores data constructors, records selectors etc.
1618         -- The isExternalName ignores local dictionary and method bindings
1619         -- that the type checker has invented.  Top-level user-defined things
1620         -- have External names.
1621
1622 ppr_tycons :: [FamInst] -> TypeEnv -> SDoc
1623 ppr_tycons fam_insts type_env
1624   = text "TYPE CONSTRUCTORS" $$ nest 4 (ppr_tydecls tycons)
1625   where
1626     fi_tycons = map famInstTyCon fam_insts
1627     tycons = [tycon | tycon <- typeEnvTyCons type_env, want_tycon tycon]
1628     want_tycon tycon | opt_PprStyle_Debug = True
1629                      | otherwise          = not (isImplicitTyCon tycon) &&
1630                                             isExternalName (tyConName tycon) &&
1631                                             not (tycon `elem` fi_tycons)
1632
1633 ppr_insts :: [Instance] -> SDoc
1634 ppr_insts []     = empty
1635 ppr_insts ispecs = text "INSTANCES" $$ nest 2 (pprInstances ispecs)
1636
1637 ppr_fam_insts :: [FamInst] -> SDoc
1638 ppr_fam_insts []        = empty
1639 ppr_fam_insts fam_insts =
1640   text "FAMILY INSTANCES" $$ nest 2 (pprFamInsts fam_insts)
1641
1642 ppr_sigs :: [Var] -> SDoc
1643 ppr_sigs ids
1644         -- Print type signatures; sort by OccName
1645   = vcat (map ppr_sig (sortLe le_sig ids))
1646   where
1647     le_sig id1 id2 = getOccName id1 <= getOccName id2
1648     ppr_sig id = ppr id <+> dcolon <+> ppr (tidyTopType (idType id))
1649
1650 ppr_tydecls :: [TyCon] -> SDoc
1651 ppr_tydecls tycons
1652         -- Print type constructor info; sort by OccName
1653   = vcat (map ppr_tycon (sortLe le_sig tycons))
1654   where
1655     le_sig tycon1 tycon2 = getOccName tycon1 <= getOccName tycon2
1656     ppr_tycon tycon
1657       | isCoercionTyCon tycon
1658       = sep [ptext (sLit "coercion") <+> ppr tycon <+> ppr tvs
1659             , nest 2 (dcolon <+> pprEqPred (coercionKind (mkTyConApp tycon (mkTyVarTys tvs))))]
1660       | otherwise             = ppr (tyThingToIfaceDecl (ATyCon tycon))
1661       where
1662         tvs = take (tyConArity tycon) alphaTyVars
1663
1664 ppr_rules :: [CoreRule] -> SDoc
1665 ppr_rules [] = empty
1666 ppr_rules rs = vcat [ptext (sLit "{-# RULES"),
1667                       nest 2 (pprRules rs),
1668                       ptext (sLit "#-}")]
1669
1670 ppr_gen_tycons :: [TyCon] -> SDoc
1671 ppr_gen_tycons []  = empty
1672 ppr_gen_tycons tcs = vcat [ptext (sLit "Tycons with generics:"),
1673                            nest 2 (fsep (map ppr (filter tyConHasGenerics tcs)))]
1674 \end{code}