compiler/typecheck/TcRnDriver.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5 \section[TcModule]{Typechecking a whole module}
   6
   7 \begin{code}
   8 {-# OPTIONS -w #-}
   9 -- The above warning supression flag is a temporary kludge.
  10 -- While working on this module you are encouraged to remove it and fix
  11 -- any warnings in the module. See
  12 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  13 -- for details
  14
  15 module TcRnDriver (
  16 #ifdef GHCI
  17         tcRnStmt, tcRnExpr, tcRnType,
  18         tcRnLookupRdrName,
  19         tcRnLookupName,
  20         tcRnGetInfo,
  21         getModuleExports,
  22 #endif
  23         tcRnModule,
  24         tcTopSrcDecls,
  25         tcRnExtCore
  26     ) where
  27
  28 import IO
  29 #ifdef GHCI
  30 import {-# SOURCE #-} TcSplice ( tcSpliceDecls )
  31 #endif
  32
  33 import DynFlags
  34 import StaticFlags
  35 import HsSyn
  36 import RdrHsSyn
  37
  38 import PrelNames
  39 import RdrName
  40 import TcHsSyn
  41 import TcExpr
  42 import TcRnMonad
  43 import TcType
  44 import Inst
  45 import FamInst
  46 import InstEnv
  47 import FamInstEnv
  48 import TcBinds
  49 import TcDefaults
  50 import TcEnv
  51 import TcRules
  52 import TcForeign
  53 import TcInstDcls
  54 import TcIface
  55 import MkIface
  56 import IfaceSyn
  57 import TcSimplify
  58 import TcTyClsDecls
  59 import TcUnify  ( withBox )
  60 import LoadIface
  61 import RnNames
  62 import RnEnv
  63 import RnSource
  64 import RnHsDoc
  65 import PprCore
  66 import CoreSyn
  67 import ErrUtils
  68 import Id
  69 import VarEnv
  70 import Var
  71 import Module
  72 import LazyUniqFM
  73 import Name
  74 import NameEnv
  75 import NameSet
  76 import TyCon
  77 import TysWiredIn
  78 import SrcLoc
  79 import HscTypes
  80 import ListSetOps
  81 import Outputable
  82 import DataCon
  83 import Type
  84 import Class
  85 import Data.List ( sortBy )
  86
  87 #ifdef GHCI
  88 import Linker
  89 import TcHsType
  90 import TcMType
  91 import TcMatches
  92 import RnTypes
  93 import RnExpr
  94 import IfaceEnv
  95 import MkId
  96 import IdInfo
  97 import {- Kind parts of -} Type
  98 import BasicTypes
  99 import Foreign.Ptr( Ptr )
 100 #endif
 101
 102 import FastString
 103 import Maybes
 104 import Util
 105 import Bag
 106
 107 import Control.Monad
 108 import Data.Maybe       ( isJust )
 109
 110 #include "HsVersions.h"
 111 \end{code}
 112
 113
 114
 115 %************************************************************************
 116 %*                                                                      *
 117         Typecheck and rename a module
 118 %*                                                                      *
 119 %************************************************************************
 120
 121
 122 \begin{code}
 123 tcRnModule :: HscEnv
 124            -> HscSource
 125            -> Bool              -- True <=> save renamed syntax
 126            -> Located (HsModule RdrName)
 127            -> IO (Messages, Maybe TcGblEnv)
 128
 129 tcRnModule hsc_env hsc_src save_rn_syntax
 130          (L loc (HsModule maybe_mod export_ies
 131                           import_decls local_decls mod_deprec
 132                           module_info maybe_doc))
 133  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 134
 135    let { this_pkg = thisPackage (hsc_dflags hsc_env) ;
 136          this_mod = case maybe_mod of
 137                         Nothing  -> mAIN        -- 'module M where' is omitted
 138                         Just (L _ mod) -> mkModule this_pkg mod } ;
 139                                                 -- The normal case
 140
 141    initTc hsc_env hsc_src save_rn_syntax this_mod $
 142    setSrcSpan loc $
 143    do {         -- Deal with imports;
 144         tcg_env <- tcRnImports hsc_env this_mod import_decls ;
 145         setGblEnv tcg_env               $ do {
 146
 147                 -- Load the hi-boot interface for this module, if any
 148                 -- We do this now so that the boot_names can be passed
 149                 -- to tcTyAndClassDecls, because the boot_names are
 150                 -- automatically considered to be loop breakers
 151                 --
 152                 -- Do this *after* tcRnImports, so that we know whether
 153                 -- a module that we import imports us; and hence whether to
 154                 -- look for a hi-boot file
 155         boot_iface <- tcHiBootIface hsc_src this_mod ;
 156
 157                 -- Rename and type check the declarations
 158         traceRn (text "rn1a") ;
 159         tcg_env <- if isHsBoot hsc_src then
 160                         tcRnHsBootDecls local_decls
 161                    else
 162                         tcRnSrcDecls boot_iface local_decls ;
 163         setGblEnv tcg_env               $ do {
 164
 165                 -- Report the use of any deprecated things
 166                 -- We do this *before* processsing the export list so
 167                 -- that we don't bleat about re-exporting a deprecated
 168                 -- thing (especially via 'module Foo' export item)
 169                 -- That is, only uses in the *body* of the module are complained about
 170         traceRn (text "rn3") ;
 171         failIfErrsM ;   -- finishWarnings crashes sometimes
 172                         -- as a result of typechecker repairs (e.g. unboundNames)
 173         tcg_env <- finishWarnings (hsc_dflags hsc_env) mod_deprec tcg_env ;
 174
 175                 -- Process the export list
 176         traceRn (text "rn4a: before exports");
 177         tcg_env <- rnExports (isJust maybe_mod) export_ies tcg_env ;
 178         traceRn (text "rn4b: after exportss") ;
 179
 180         -- Compare the hi-boot iface (if any) with the real thing
 181         -- Must be done after processing the exports
 182         tcg_env <- checkHiBootIface tcg_env boot_iface ;
 183
 184         -- The new type env is already available to stuff slurped from
 185         -- interface files, via TcEnv.updateGlobalTypeEnv
 186         -- It's important that this includes the stuff in checkHiBootIface,
 187         -- because the latter might add new bindings for boot_dfuns,
 188         -- which may be mentioned in imported unfoldings
 189
 190                 -- Rename the Haddock documentation
 191         tcg_env <- rnHaddock module_info maybe_doc tcg_env ;
 192
 193                 -- Report unused names
 194         reportUnusedNames export_ies tcg_env ;
 195
 196                 -- Dump output and return
 197         tcDump tcg_env ;
 198         return tcg_env
 199     }}}}
 200 \end{code}
 201
 202
 203 %************************************************************************
 204 %*                                                                      *
 205                 Import declarations
 206 %*                                                                      *
 207 %************************************************************************
 208
 209 \begin{code}
 210 tcRnImports :: HscEnv -> Module -> [LImportDecl RdrName] -> TcM TcGblEnv
 211 tcRnImports hsc_env this_mod import_decls
 212   = do  { (rn_imports, rdr_env, imports,hpc_info) <- rnImports import_decls ;
 213
 214         ; let { dep_mods :: ModuleNameEnv (ModuleName, IsBootInterface)
 215               ; dep_mods = imp_dep_mods imports
 216
 217                 -- We want instance declarations from all home-package
 218                 -- modules below this one, including boot modules, except
 219                 -- ourselves.  The 'except ourselves' is so that we don't
 220                 -- get the instances from this module's hs-boot file
 221               ; want_instances :: ModuleName -> Bool
 222               ; want_instances mod = mod `elemUFM` dep_mods
 223                                    && mod /= moduleName this_mod
 224               ; (home_insts, home_fam_insts) = hptInstances hsc_env
 225                                                             want_instances
 226               } ;
 227
 228                 -- Record boot-file info in the EPS, so that it's
 229                 -- visible to loadHiBootInterface in tcRnSrcDecls,
 230                 -- and any other incrementally-performed imports
 231         ; updateEps_ (\eps -> eps { eps_is_boot = dep_mods }) ;
 232
 233                 -- Update the gbl env
 234         ; updGblEnv ( \ gbl ->
 235             gbl {
 236               tcg_rdr_env      = plusOccEnv (tcg_rdr_env gbl) rdr_env,
 237               tcg_imports      = tcg_imports gbl `plusImportAvails` imports,
 238               tcg_rn_imports   = fmap (const rn_imports) (tcg_rn_imports gbl),
 239               tcg_inst_env     = extendInstEnvList (tcg_inst_env gbl) home_insts,
 240               tcg_fam_inst_env = extendFamInstEnvList (tcg_fam_inst_env gbl)
 241                                                       home_fam_insts,
 242               tcg_hpc          = hpc_info
 243             }) $ do {
 244
 245         ; traceRn (text "rn1" <+> ppr (imp_dep_mods imports))
 246                 -- Fail if there are any errors so far
 247                 -- The error printing (if needed) takes advantage
 248                 -- of the tcg_env we have now set
 249 --      ; traceIf (text "rdr_env: " <+> ppr rdr_env)
 250         ; failIfErrsM
 251
 252                 -- Load any orphan-module and family instance-module
 253                 -- interfaces, so that their rules and instance decls will be
 254                 -- found.
 255         ; loadOrphanModules (imp_orphs  imports) False
 256         ; loadOrphanModules (imp_finsts imports) True
 257
 258                 -- Check type-familily consistency
 259         ; traceRn (text "rn1: checking family instance consistency")
 260         ; let { dir_imp_mods = moduleEnvKeys
 261                              . imp_mods
 262                              $ imports }
 263         ; checkFamInstConsistency (imp_finsts imports) dir_imp_mods ;
 264
 265         ; getGblEnv } }
 266 \end{code}
 267
 268
 269 %************************************************************************
 270 %*                                                                      *
 271         Type-checking external-core modules
 272 %*                                                                      *
 273 %************************************************************************
 274
 275 \begin{code}
 276 tcRnExtCore :: HscEnv
 277             -> HsExtCore RdrName
 278             -> IO (Messages, Maybe ModGuts)
 279         -- Nothing => some error occurred
 280
 281 tcRnExtCore hsc_env (HsExtCore this_mod decls src_binds)
 282         -- The decls are IfaceDecls; all names are original names
 283  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 284
 285    initTc hsc_env ExtCoreFile False this_mod $ do {
 286
 287    let { ldecls  = map noLoc decls } ;
 288
 289        -- bring the type and class decls into scope
 290        -- ToDo: check that this doesn't need to extract the val binds.
 291        --       It seems that only the type and class decls need to be in scope below because
 292        --          (a) tcTyAndClassDecls doesn't need the val binds, and
 293        --          (b) tcExtCoreBindings doesn't need anything
 294        --              (in fact, it might not even need to be in the scope of
 295        --               this tcg_env at all)
 296    avails  <- getLocalNonValBinders (mkFakeGroup ldecls) ;
 297    tc_envs <- extendGlobalRdrEnvRn avails emptyFsEnv {- no fixity decls -} ;
 298
 299    setEnvs tc_envs $ do {
 300
 301    rn_decls <- checkNoErrs $ rnTyClDecls ldecls ;
 302
 303         -- Dump trace of renaming part
 304    rnDump (ppr rn_decls) ;
 305
 306         -- Typecheck them all together so that
 307         -- any mutually recursive types are done right
 308    tcg_env <- tcTyAndClassDecls emptyModDetails rn_decls ;
 309         -- Make the new type env available to stuff slurped from interface files
 310
 311    setGblEnv tcg_env $ do {
 312
 313         -- Now the core bindings
 314    core_binds <- initIfaceExtCore (tcExtCoreBindings src_binds) ;
 315
 316         -- Wrap up
 317    let {
 318         bndrs      = bindersOfBinds core_binds ;
 319         my_exports = map (Avail . idName) bndrs ;
 320                 -- ToDo: export the data types also?
 321
 322         final_type_env = extendTypeEnvWithIds (tcg_type_env tcg_env) bndrs ;
 323
 324         mod_guts = ModGuts {    mg_module    = this_mod,
 325                                 mg_boot      = False,
 326                                 mg_used_names = emptyNameSet, -- ToDo: compute usage
 327                                 mg_dir_imps  = emptyModuleEnv, -- ??
 328                                 mg_deps      = noDependencies,  -- ??
 329                                 mg_exports   = my_exports,
 330                                 mg_types     = final_type_env,
 331                                 mg_insts     = tcg_insts tcg_env,
 332                                 mg_fam_insts = tcg_fam_insts tcg_env,
 333                                 mg_inst_env  = tcg_inst_env tcg_env,
 334                                 mg_fam_inst_env = tcg_fam_inst_env tcg_env,
 335                                 mg_rules     = [],
 336                                 mg_binds     = core_binds,
 337
 338                                 -- Stubs
 339                                 mg_rdr_env   = emptyGlobalRdrEnv,
 340                                 mg_fix_env   = emptyFixityEnv,
 341                                 mg_warns     = NoWarnings,
 342                                 mg_foreign   = NoStubs,
 343                                 mg_hpc_info  = emptyHpcInfo False,
 344                                 mg_modBreaks = emptyModBreaks,
 345                                 mg_vect_info = noVectInfo
 346                     } } ;
 347
 348    tcCoreDump mod_guts ;
 349
 350    return mod_guts
 351    }}}}
 352
 353 mkFakeGroup decls -- Rather clumsy; lots of unused fields
 354   = emptyRdrGroup { hs_tyclds = decls }
 355 \end{code}
 356
 357
 358 %************************************************************************
 359 %*                                                                      *
 360         Type-checking the top level of a module
 361 %*                                                                      *
 362 %************************************************************************
 363
 364 \begin{code}
 365 tcRnSrcDecls :: ModDetails -> [LHsDecl RdrName] -> TcM TcGblEnv
 366         -- Returns the variables free in the decls
 367         -- Reason: solely to report unused imports and bindings
 368 tcRnSrcDecls boot_iface decls
 369  = do {         -- Do all the declarations
 370         (tc_envs, lie) <- getLIE $ tc_rn_src_decls boot_iface decls ;
 371
 372              --         Finish simplifying class constraints
 373              --
 374              -- tcSimplifyTop deals with constant or ambiguous InstIds.
 375              -- How could there be ambiguous ones?  They can only arise if a
 376              -- top-level decl falls under the monomorphism restriction
 377              -- and no subsequent decl instantiates its type.
 378              --
 379              -- We do this after checkMain, so that we use the type info
 380              -- thaat checkMain adds
 381              --
 382              -- We do it with both global and local env in scope:
 383              --  * the global env exposes the instances to tcSimplifyTop
 384              --  * the local env exposes the local Ids to tcSimplifyTop,
 385              --    so that we get better error messages (monomorphism restriction)
 386         traceTc (text "Tc8") ;
 387         inst_binds <- setEnvs tc_envs (tcSimplifyTop lie) ;
 388
 389             -- Backsubstitution.  This must be done last.
 390             -- Even tcSimplifyTop may do some unification.
 391         traceTc (text "Tc9") ;
 392         let { (tcg_env, _) = tc_envs
 393             ; TcGblEnv { tcg_type_env = type_env, tcg_binds = binds,
 394                          tcg_rules = rules, tcg_fords = fords } = tcg_env
 395             ; all_binds = binds `unionBags` inst_binds } ;
 396
 397         failIfErrsM ;   -- Don't zonk if there have been errors
 398                         -- It's a waste of time; and we may get debug warnings
 399                         -- about strangely-typed TyCons!
 400
 401         (bind_ids, binds', fords', rules') <- zonkTopDecls all_binds rules fords ;
 402
 403
 404         let { final_type_env = extendTypeEnvWithIds type_env bind_ids
 405             ; tcg_env' = tcg_env { tcg_binds = binds',
 406                                    tcg_rules = rules',
 407                                    tcg_fords = fords' } } ;
 408
 409         setGlobalTypeEnv tcg_env' final_type_env
 410    }
 411
 412 tc_rn_src_decls :: ModDetails -> [LHsDecl RdrName] -> TcM (TcGblEnv, TcLclEnv)
 413 -- Loops around dealing with each top level inter-splice group
 414 -- in turn, until it's dealt with the entire module
 415 tc_rn_src_decls boot_details ds
 416  = do { let { (first_group, group_tail) = findSplice ds } ;
 417                 -- If ds is [] we get ([], Nothing)
 418
 419         -- Deal with decls up to, but not including, the first splice
 420         (tcg_env, rn_decls) <- rnTopSrcDecls first_group ;
 421                 -- rnTopSrcDecls fails if there are any errors
 422
 423         (tcg_env, tcl_env) <- setGblEnv tcg_env $
 424                               tcTopSrcDecls boot_details rn_decls ;
 425
 426         -- If there is no splice, we're nearly done
 427         setEnvs (tcg_env, tcl_env) $
 428         case group_tail of {
 429            Nothing -> do { tcg_env <- checkMain ;       -- Check for `main'
 430                            return (tcg_env, tcl_env)
 431                       } ;
 432
 433         -- If there's a splice, we must carry on
 434            Just (SpliceDecl splice_expr, rest_ds) -> do {
 435 #ifndef GHCI
 436         failWithTc (text "Can't do a top-level splice; need a bootstrapped compiler")
 437 #else
 438
 439         -- Rename the splice expression, and get its supporting decls
 440         (rn_splice_expr, splice_fvs) <- checkNoErrs (rnLExpr splice_expr) ;
 441                 -- checkNoErrs: don't typecheck if renaming failed
 442         rnDump (ppr rn_splice_expr) ;
 443
 444         -- Execute the splice
 445         spliced_decls <- tcSpliceDecls rn_splice_expr ;
 446
 447         -- Glue them on the front of the remaining decls and loop
 448         setGblEnv (tcg_env `addTcgDUs` usesOnly splice_fvs) $
 449         tc_rn_src_decls boot_details (spliced_decls ++ rest_ds)
 450 #endif /* GHCI */
 451     } } }
 452 \end{code}
 453
 454 %************************************************************************
 455 %*                                                                      *
 456         Compiling hs-boot source files, and
 457         comparing the hi-boot interface with the real thing
 458 %*                                                                      *
 459 %************************************************************************
 460
 461 \begin{code}
 462 tcRnHsBootDecls :: [LHsDecl RdrName] -> TcM TcGblEnv
 463 tcRnHsBootDecls decls
 464    = do { let { (first_group, group_tail) = findSplice decls }
 465
 466         ; case group_tail of
 467              Just stuff -> spliceInHsBootErr stuff
 468              Nothing    -> return ()
 469
 470                 -- Rename the declarations
 471         ; (tcg_env, rn_group) <- rnTopSrcDecls first_group
 472         ; setGblEnv tcg_env $ do {
 473
 474         -- Todo: check no foreign decls, no rules, no default decls
 475
 476                 -- Typecheck type/class decls
 477         ; traceTc (text "Tc2")
 478         ; let tycl_decls = hs_tyclds rn_group
 479         ; tcg_env <- tcTyAndClassDecls emptyModDetails tycl_decls
 480         ; setGblEnv tcg_env     $ do {
 481
 482                 -- Typecheck instance decls
 483         ; traceTc (text "Tc3")
 484         ; (tcg_env, inst_infos, _deriv_binds)
 485             <- tcInstDecls1 tycl_decls (hs_instds rn_group) (hs_derivds rn_group)
 486         ; setGblEnv tcg_env     $ do {
 487
 488                 -- Typecheck value declarations
 489         ; traceTc (text "Tc5")
 490         ; val_ids <- tcHsBootSigs (hs_valds rn_group)
 491
 492                 -- Wrap up
 493                 -- No simplification or zonking to do
 494         ; traceTc (text "Tc7a")
 495         ; gbl_env <- getGblEnv
 496
 497                 -- Make the final type-env
 498                 -- Include the dfun_ids so that their type sigs
 499                 -- are written into the interface file
 500         ; let { type_env0 = tcg_type_env gbl_env
 501               ; type_env1 = extendTypeEnvWithIds type_env0 val_ids
 502               ; type_env2 = extendTypeEnvWithIds type_env1 dfun_ids
 503               ; dfun_ids = map iDFunId inst_infos }
 504         ; setGlobalTypeEnv gbl_env type_env2
 505    }}}}
 506
 507 spliceInHsBootErr (SpliceDecl (L loc _), _)
 508   = addErrAt loc (ptext (sLit "Splices are not allowed in hs-boot files"))
 509 \end{code}
 510
 511 Once we've typechecked the body of the module, we want to compare what
 512 we've found (gathered in a TypeEnv) with the hi-boot details (if any).
 513
 514 \begin{code}
 515 checkHiBootIface :: TcGblEnv -> ModDetails -> TcM TcGblEnv
 516 -- Compare the hi-boot file for this module (if there is one)
 517 -- with the type environment we've just come up with
 518 -- In the common case where there is no hi-boot file, the list
 519 -- of boot_names is empty.
 520 --
 521 -- The bindings we return give bindings for the dfuns defined in the
 522 -- hs-boot file, such as        $fbEqT = $fEqT
 523
 524 checkHiBootIface
 525         tcg_env@(TcGblEnv { tcg_src = hs_src, tcg_binds = binds,
 526                             tcg_insts = local_insts, tcg_fam_insts = local_fam_insts,
 527                             tcg_type_env = local_type_env, tcg_exports = local_exports })
 528         (ModDetails { md_insts = boot_insts, md_fam_insts = boot_fam_insts,
 529                       md_types = boot_type_env, md_exports = boot_exports })
 530   | isHsBoot hs_src     -- Current module is already a hs-boot file!
 531   = return tcg_env
 532
 533   | otherwise
 534   = do  { traceTc (text "checkHiBootIface" <+> (ppr boot_type_env $$ ppr boot_insts $$
 535                                 ppr boot_exports)) ;
 536
 537                 -- Check the exports of the boot module, one by one
 538         ; mapM_ check_export boot_exports
 539
 540                 -- Check for no family instances
 541         ; unless (null boot_fam_insts) $
 542             panic ("TcRnDriver.checkHiBootIface: Cannot handle family " ++
 543                    "instances in boot files yet...")
 544             -- FIXME: Why?  The actual comparison is not hard, but what would
 545             --        be the equivalent to the dfun bindings returned for class
 546             --        instances?  We can't easily equate tycons...
 547
 548                 -- Check instance declarations
 549         ; mb_dfun_prs <- mapM check_inst boot_insts
 550         ; let tcg_env' = tcg_env { tcg_binds = binds `unionBags` dfun_binds }
 551               final_type_env = extendTypeEnvWithIds local_type_env boot_dfuns
 552               dfun_prs   = catMaybes mb_dfun_prs
 553               boot_dfuns = map fst dfun_prs
 554               dfun_binds = listToBag [ noLoc $ VarBind boot_dfun (nlHsVar dfun)
 555                                      | (boot_dfun, dfun) <- dfun_prs ]
 556
 557         ; failIfErrsM
 558         ; setGlobalTypeEnv tcg_env' final_type_env }
 559   where
 560     check_export boot_avail     -- boot_avail is exported by the boot iface
 561       | name `elem` dfun_names = return ()
 562       | isWiredInName name     = return ()      -- No checking for wired-in names.  In particular,
 563                                                 -- 'error' is handled by a rather gross hack
 564                                                 -- (see comments in GHC.Err.hs-boot)
 565
 566         -- Check that the actual module exports the same thing
 567       | not (null missing_names)
 568       = addErrAt (nameSrcSpan (head missing_names))
 569                  (missingBootThing (head missing_names) "exported by")
 570
 571         -- If the boot module does not *define* the thing, we are done
 572         -- (it simply re-exports it, and names match, so nothing further to do)
 573       | isNothing mb_boot_thing = return ()
 574
 575         -- Check that the actual module also defines the thing, and
 576         -- then compare the definitions
 577       | Just real_thing <- lookupTypeEnv local_type_env name,
 578         Just boot_thing <- mb_boot_thing
 579       = when (not (checkBootDecl boot_thing real_thing))
 580             $ addErrAt (nameSrcSpan (getName boot_thing))
 581                        (let boot_decl = tyThingToIfaceDecl
 582                                                (fromJust mb_boot_thing)
 583                             real_decl = tyThingToIfaceDecl real_thing
 584                         in bootMisMatch real_thing boot_decl real_decl)
 585
 586       | otherwise
 587       = addErrTc (missingBootThing name "defined in")
 588       where
 589         name          = availName boot_avail
 590         mb_boot_thing = lookupTypeEnv boot_type_env name
 591         missing_names = case lookupNameEnv local_export_env name of
 592                           Nothing    -> [name]
 593                           Just avail -> availNames boot_avail `minusList` availNames avail
 594
 595     dfun_names = map getName boot_insts
 596
 597     local_export_env :: NameEnv AvailInfo
 598     local_export_env = availsToNameEnv local_exports
 599
 600     check_inst :: Instance -> TcM (Maybe (Id, Id))
 601         -- Returns a pair of the boot dfun in terms of the equivalent real dfun
 602     check_inst boot_inst
 603         = case [dfun | inst <- local_insts,
 604                        let dfun = instanceDFunId inst,
 605                        idType dfun `tcEqType` boot_inst_ty ] of
 606             [] -> do { addErrTc (instMisMatch boot_inst); return Nothing }
 607             (dfun:_) -> return (Just (local_boot_dfun, dfun))
 608         where
 609           boot_dfun = instanceDFunId boot_inst
 610           boot_inst_ty = idType boot_dfun
 611           local_boot_dfun = Id.mkExportedLocalId (idName boot_dfun) boot_inst_ty
 612
 613
 614 -- This has to compare the TyThing from the .hi-boot file to the TyThing
 615 -- in the current source file.  We must be careful to allow alpha-renaming
 616 -- where appropriate, and also the boot declaration is allowed to omit
 617 -- constructors and class methods.
 618 --
 619 -- See rnfail055 for a good test of this stuff.
 620
 621 checkBootDecl :: TyThing -> TyThing -> Bool
 622
 623 checkBootDecl (AnId id1) (AnId id2)
 624   = ASSERT(id1 == id2)
 625     (idType id1 `tcEqType` idType id2)
 626
 627 checkBootDecl (ATyCon tc1) (ATyCon tc2)
 628   | isSynTyCon tc1 && isSynTyCon tc2
 629   = ASSERT(tc1 == tc2)
 630     let tvs1 = tyConTyVars tc1; tvs2 = tyConTyVars tc2
 631         env = rnBndrs2 env0 tvs1 tvs2
 632
 633         eqSynRhs (OpenSynTyCon k1 _) (OpenSynTyCon k2 _)
 634             = tcEqTypeX env k1 k2
 635         eqSynRhs (SynonymTyCon t1) (SynonymTyCon t2)
 636             = tcEqTypeX env t1 t2
 637     in
 638     equalLength tvs1 tvs2 &&
 639     eqSynRhs (synTyConRhs tc1) (synTyConRhs tc2)
 640
 641   | isAlgTyCon tc1 && isAlgTyCon tc2
 642   = ASSERT(tc1 == tc2)
 643     eqListBy tcEqPred (tyConStupidTheta tc1) (tyConStupidTheta tc2)
 644     && eqAlgRhs (algTyConRhs tc1) (algTyConRhs tc2)
 645
 646   | isForeignTyCon tc1 && isForeignTyCon tc2
 647   = tyConExtName tc1 == tyConExtName tc2
 648   where
 649         env0 = mkRnEnv2 emptyInScopeSet
 650
 651         eqAlgRhs AbstractTyCon _ = True
 652         eqAlgRhs OpenTyCon{} OpenTyCon{} = True
 653         eqAlgRhs tc1@DataTyCon{} tc2@DataTyCon{} =
 654             eqListBy eqCon (data_cons tc1) (data_cons tc2)
 655         eqAlgRhs tc1@NewTyCon{} tc2@NewTyCon{} =
 656             eqCon (data_con tc1) (data_con tc2)
 657         eqAlgRhs _ _ = False
 658
 659         eqCon c1 c2
 660           =  dataConName c1 == dataConName c2
 661           && dataConIsInfix c1 == dataConIsInfix c2
 662           && dataConStrictMarks c1 == dataConStrictMarks c2
 663           && dataConFieldLabels c1 == dataConFieldLabels c2
 664           && let tvs1 = dataConUnivTyVars c1 ++ dataConExTyVars c1
 665                  tvs2 = dataConUnivTyVars c2 ++ dataConExTyVars c2
 666                  env = rnBndrs2 env0 tvs1 tvs2
 667              in
 668               equalLength tvs1 tvs2 &&
 669               eqListBy (tcEqPredX env)
 670                         (dataConEqTheta c1 ++ dataConDictTheta c1)
 671                         (dataConEqTheta c2 ++ dataConDictTheta c2) &&
 672               eqListBy (tcEqTypeX env)
 673                         (dataConOrigArgTys c1)
 674                         (dataConOrigArgTys c2)
 675
 676 checkBootDecl (AClass c1)  (AClass c2)
 677   = let
 678        (clas_tyvars1, clas_fds1, sc_theta1, _, _, op_stuff1)
 679           = classExtraBigSig c1
 680        (clas_tyvars2, clas_fds2, sc_theta2, _, _, op_stuff2)
 681           = classExtraBigSig c2
 682
 683        env0 = mkRnEnv2 emptyInScopeSet
 684        env = rnBndrs2 env0 clas_tyvars1 clas_tyvars2
 685
 686        eqSig (id1, def_meth1) (id2, def_meth2)
 687          = idName id1 == idName id2 &&
 688            tcEqTypeX env op_ty1 op_ty2
 689          where
 690           (_, rho_ty1) = splitForAllTys (idType id1)
 691           op_ty1 = funResultTy rho_ty1
 692           (_, rho_ty2) = splitForAllTys (idType id2)
 693           op_ty2 = funResultTy rho_ty2
 694
 695        eqFD (as1,bs1) (as2,bs2) =
 696          eqListBy (tcEqTypeX env) (mkTyVarTys as1) (mkTyVarTys as2) &&
 697          eqListBy (tcEqTypeX env) (mkTyVarTys bs1) (mkTyVarTys bs2)
 698     in
 699        equalLength clas_tyvars1 clas_tyvars2 &&
 700        eqListBy eqFD clas_fds1 clas_fds2 &&
 701        (null sc_theta1 && null op_stuff1
 702         ||
 703         eqListBy (tcEqPredX env) sc_theta1 sc_theta2 &&
 704         eqListBy eqSig op_stuff1 op_stuff2)
 705
 706 checkBootDecl (ADataCon dc1) (ADataCon dc2)
 707   = pprPanic "checkBootDecl" (ppr dc1)
 708
 709 checkBootDecl _ _ = False -- probably shouldn't happen
 710
 711 ----------------
 712 missingBootThing thing what
 713   = ppr thing <+> ptext (sLit "is exported by the hs-boot file, but not")
 714               <+> text what <+> ptext (sLit "the module")
 715
 716 bootMisMatch thing boot_decl real_decl
 717   = vcat [ppr thing <+> ptext (sLit "has conflicting definitions in the module and its hs-boot file"),
 718           ptext (sLit "Main module:") <+> ppr real_decl,
 719           ptext (sLit "Boot file:  ") <+> ppr boot_decl]
 720
 721 instMisMatch inst
 722   = hang (ppr inst)
 723        2 (ptext (sLit "is defined in the hs-boot file, but not in the module itself"))
 724 \end{code}
 725
 726
 727 %************************************************************************
 728 %*                                                                      *
 729         Type-checking the top level of a module
 730 %*                                                                      *
 731 %************************************************************************
 732
 733 tcRnGroup takes a bunch of top-level source-code declarations, and
 734  * renames them
 735  * gets supporting declarations from interface files
 736  * typechecks them
 737  * zonks them
 738  * and augments the TcGblEnv with the results
 739
 740 In Template Haskell it may be called repeatedly for each group of
 741 declarations.  It expects there to be an incoming TcGblEnv in the
 742 monad; it augments it and returns the new TcGblEnv.
 743
 744 \begin{code}
 745 ------------------------------------------------
 746 rnTopSrcDecls :: HsGroup RdrName -> TcM (TcGblEnv, HsGroup Name)
 747 -- Fails if there are any errors
 748 rnTopSrcDecls group
 749  = do { -- Rename the source decls
 750         (tcg_env, rn_decls) <- checkNoErrs $ rnSrcDecls group ;
 751
 752         -- save the renamed syntax, if we want it
 753         let { tcg_env'
 754                 | Just grp <- tcg_rn_decls tcg_env
 755                   = tcg_env{ tcg_rn_decls = Just (appendGroups grp rn_decls) }
 756                 | otherwise
 757                    = tcg_env };
 758
 759                 -- Dump trace of renaming part
 760         rnDump (ppr rn_decls) ;
 761
 762         return (tcg_env', rn_decls)
 763    }
 764
 765 ------------------------------------------------
 766 tcTopSrcDecls :: ModDetails -> HsGroup Name -> TcM (TcGblEnv, TcLclEnv)
 767 tcTopSrcDecls boot_details
 768         (HsGroup { hs_tyclds = tycl_decls,
 769                    hs_instds = inst_decls,
 770                    hs_derivds = deriv_decls,
 771                    hs_fords  = foreign_decls,
 772                    hs_defds  = default_decls,
 773                    hs_ruleds = rule_decls,
 774                    hs_valds  = val_binds })
 775  = do {         -- Type-check the type and class decls, and all imported decls
 776                 -- The latter come in via tycl_decls
 777         traceTc (text "Tc2") ;
 778
 779         tcg_env <- tcTyAndClassDecls boot_details tycl_decls ;
 780                 -- If there are any errors, tcTyAndClassDecls fails here
 781
 782         setGblEnv tcg_env       $ do {
 783                 -- Source-language instances, including derivings,
 784                 -- and import the supporting declarations
 785         traceTc (text "Tc3") ;
 786         (tcg_env, inst_infos, deriv_binds)
 787             <- tcInstDecls1 tycl_decls inst_decls deriv_decls;
 788         setGblEnv tcg_env       $ do {
 789
 790                 -- Foreign import declarations next.  No zonking necessary
 791                 -- here; we can tuck them straight into the global environment.
 792         traceTc (text "Tc4") ;
 793         (fi_ids, fi_decls) <- tcForeignImports foreign_decls ;
 794         tcExtendGlobalValEnv fi_ids     $ do {
 795
 796                 -- Default declarations
 797         traceTc (text "Tc4a") ;
 798         default_tys <- tcDefaults default_decls ;
 799         updGblEnv (\gbl -> gbl { tcg_default = default_tys }) $ do {
 800
 801                 -- Value declarations next
 802                 -- We also typecheck any extra binds that came out
 803                 -- of the "deriving" process (deriv_binds)
 804         traceTc (text "Tc5") ;
 805         (tc_val_binds,   tcl_env) <- tcTopBinds val_binds ;
 806         setLclTypeEnv tcl_env   $ do {
 807
 808                 -- Now GHC-generated derived bindings and generics.
 809                 -- Do not generate warnings from compiler-generated code.
 810         (tc_deriv_binds, tcl_env) <- discardWarnings $
 811                                  tcTopBinds deriv_binds ;
 812
 813                 -- Second pass over class and instance declarations,
 814         traceTc (text "Tc6") ;
 815         (inst_binds, tcl_env)     <- setLclTypeEnv tcl_env $ tcInstDecls2 tycl_decls inst_infos ;
 816         showLIE (text "after instDecls2") ;
 817
 818                 -- Foreign exports
 819                 -- They need to be zonked, so we return them
 820         traceTc (text "Tc7") ;
 821         (foe_binds, foe_decls) <- tcForeignExports foreign_decls ;
 822
 823                 -- Rules
 824         rules <- tcRules rule_decls ;
 825
 826                 -- Wrap up
 827         traceTc (text "Tc7a") ;
 828         tcg_env <- getGblEnv ;
 829         let { all_binds = tc_val_binds   `unionBags`
 830                           tc_deriv_binds `unionBags`
 831                           inst_binds     `unionBags`
 832                           foe_binds  ;
 833
 834                 -- Extend the GblEnv with the (as yet un-zonked)
 835                 -- bindings, rules, foreign decls
 836               tcg_env' = tcg_env {  tcg_binds = tcg_binds tcg_env `unionBags` all_binds,
 837                                     tcg_rules = tcg_rules tcg_env ++ rules,
 838                                     tcg_fords = tcg_fords tcg_env ++ foe_decls ++ fi_decls } } ;
 839         return (tcg_env', tcl_env)
 840     }}}}}}
 841 \end{code}
 842
 843
 844 %************************************************************************
 845 %*                                                                      *
 846         Checking for 'main'
 847 %*                                                                      *
 848 %************************************************************************
 849
 850 \begin{code}
 851 checkMain :: TcM TcGblEnv
 852 -- If we are in module Main, check that 'main' is defined.
 853 checkMain
 854   = do { tcg_env   <- getGblEnv ;
 855          dflags    <- getDOpts ;
 856          check_main dflags tcg_env
 857     }
 858
 859 check_main dflags tcg_env
 860  | mod /= main_mod
 861  = traceTc (text "checkMain not" <+> ppr main_mod <+> ppr mod) >>
 862    return tcg_env
 863
 864  | otherwise
 865  = do   { mb_main <- lookupSrcOcc_maybe main_fn
 866                 -- Check that 'main' is in scope
 867                 -- It might be imported from another module!
 868         ; case mb_main of {
 869              Nothing -> do { traceTc (text "checkMain fail" <+> ppr main_mod <+> ppr main_fn)
 870                            ; complain_no_main
 871                            ; return tcg_env } ;
 872              Just main_name -> do
 873
 874         { traceTc (text "checkMain found" <+> ppr main_mod <+> ppr main_fn)
 875         ; let loc = srcLocSpan (getSrcLoc main_name)
 876         ; ioTyCon <- tcLookupTyCon ioTyConName
 877         ; (main_expr, res_ty)
 878                 <- addErrCtxt mainCtxt    $
 879                    withBox liftedTypeKind $ \res_ty ->
 880                    tcMonoExpr (L loc (HsVar main_name)) (mkTyConApp ioTyCon [res_ty])
 881
 882                 -- See Note [Root-main Id]
 883                 -- Construct the binding
 884                 --      :Main.main :: IO res_ty = runMainIO res_ty main
 885         ; run_main_id <- tcLookupId runMainIOName
 886         ; let { root_main_name =  mkExternalName rootMainKey rOOT_MAIN
 887                                    (mkVarOccFS (fsLit "main"))
 888                                    (getSrcSpan main_name)
 889               ; root_main_id = Id.mkExportedLocalId root_main_name
 890                                                     (mkTyConApp ioTyCon [res_ty])
 891               ; co  = mkWpTyApps [res_ty]
 892               ; rhs = nlHsApp (mkLHsWrap co (nlHsVar run_main_id)) main_expr
 893               ; main_bind = noLoc (VarBind root_main_id rhs) }
 894
 895         ; return (tcg_env { tcg_binds = tcg_binds tcg_env
 896                                         `snocBag` main_bind,
 897                             tcg_dus   = tcg_dus tcg_env
 898                                         `plusDU` usesOnly (unitFV main_name)
 899                         -- Record the use of 'main', so that we don't
 900                         -- complain about it being defined but not used
 901                  })
 902     }}}
 903   where
 904     mod          = tcg_mod tcg_env
 905     main_mod     = mainModIs dflags
 906     main_fn      = getMainFun dflags
 907
 908     complain_no_main | ghcLink dflags == LinkInMemory = return ()
 909                      | otherwise = failWithTc noMainMsg
 910         -- In interactive mode, don't worry about the absence of 'main'
 911         -- In other modes, fail altogether, so that we don't go on
 912         -- and complain a second time when processing the export list.
 913
 914     mainCtxt  = ptext (sLit "When checking the type of the") <+> pp_main_fn
 915     noMainMsg = ptext (sLit "The") <+> pp_main_fn
 916                 <+> ptext (sLit "is not defined in module") <+> quotes (ppr main_mod)
 917     pp_main_fn | main_fn == main_RDR_Unqual = ptext (sLit "function") <+> quotes (ppr main_fn)
 918                | otherwise                  = ptext (sLit "main function") <+> quotes (ppr main_fn)
 919
 920 \end{code}
 921
 922 Note [Root-main Id]
 923 ~~~~~~~~~~~~~~~~~~~
 924 The function that the RTS invokes is always :Main.main, which we call
 925 root_main_id.  (Because GHC allows the user to have a module not
 926 called Main as the main module, we can't rely on the main function
 927 being called "Main.main".  That's why root_main_id has a fixed module
 928 ":Main".)
 929
 930 This is unusual: it's a LocalId whose Name has a Module from another
 931 module.  Tiresomely, we must filter it out again in MkIface, les we
 932 get two defns for 'main' in the interface file!
 933
 934
 935 %*********************************************************
 936 %*                                                       *
 937                 GHCi stuff
 938 %*                                                       *
 939 %*********************************************************
 940
 941 \begin{code}
 942 #ifdef GHCI
 943 setInteractiveContext :: HscEnv -> InteractiveContext -> TcRn a -> TcRn a
 944 setInteractiveContext hsc_env icxt thing_inside
 945   = let -- Initialise the tcg_inst_env with instances from all home modules.
 946         -- This mimics the more selective call to hptInstances in tcRnModule.
 947         (home_insts, home_fam_insts) = hptInstances hsc_env (\mod -> True)
 948     in
 949     updGblEnv (\env -> env {
 950         tcg_rdr_env      = ic_rn_gbl_env icxt,
 951         tcg_inst_env     = extendInstEnvList    (tcg_inst_env env) home_insts,
 952         tcg_fam_inst_env = extendFamInstEnvList (tcg_fam_inst_env env)
 953                                                 home_fam_insts
 954       }) $
 955
 956     tcExtendGhciEnv (ic_tmp_ids icxt) $
 957         -- tcExtendGhciEnv does lots:
 958         --   - it extends the local type env (tcl_env) with the given Ids,
 959         --   - it extends the local rdr env (tcl_rdr) with the Names from
 960         --     the given Ids
 961         --   - it adds the free tyvars of the Ids to the tcl_tyvars
 962         --     set.
 963         --
 964         -- later ids in ic_tmp_ids must shadow earlier ones with the same
 965         -- OccName, and tcExtendIdEnv implements this behaviour.
 966
 967     do  { traceTc (text "setIC" <+> ppr (ic_tmp_ids icxt))
 968         ; thing_inside }
 969 \end{code}
 970
 971
 972 \begin{code}
 973 tcRnStmt :: HscEnv
 974          -> InteractiveContext
 975          -> LStmt RdrName
 976          -> IO (Messages, Maybe ([Id], LHsExpr Id))
 977                 -- The returned [Id] is the list of new Ids bound by
 978                 -- this statement.  It can be used to extend the
 979                 -- InteractiveContext via extendInteractiveContext.
 980                 --
 981                 -- The returned TypecheckedHsExpr is of type IO [ () ],
 982                 -- a list of the bound values, coerced to ().
 983
 984 tcRnStmt hsc_env ictxt rdr_stmt
 985   = initTcPrintErrors hsc_env iNTERACTIVE $
 986     setInteractiveContext hsc_env ictxt $ do {
 987
 988     -- Rename; use CmdLineMode because tcRnStmt is only used interactively
 989     (([rn_stmt], _), fvs) <- rnStmts DoExpr [rdr_stmt] (return ((), emptyFVs)) ;
 990     traceRn (text "tcRnStmt" <+> vcat [ppr rdr_stmt, ppr rn_stmt, ppr fvs]) ;
 991     failIfErrsM ;
 992     rnDump (ppr rn_stmt) ;
 993
 994     -- The real work is done here
 995     (bound_ids, tc_expr) <- mkPlan rn_stmt ;
 996     zonked_expr <- zonkTopLExpr tc_expr ;
 997     zonked_ids  <- zonkTopBndrs bound_ids ;
 998
 999         -- None of the Ids should be of unboxed type, because we
1000         -- cast them all to HValues in the end!
1001     mapM bad_unboxed (filter (isUnLiftedType . idType) zonked_ids) ;
1002
1003     traceTc (text "tcs 1") ;
1004     let { global_ids = map globaliseAndTidy zonked_ids } ;
1005
1006 {- ---------------------------------------------
1007    At one stage I removed any shadowed bindings from the type_env;
1008    they are inaccessible but might, I suppose, cause a space leak if we leave them there.
1009    However, with Template Haskell they aren't necessarily inaccessible.  Consider this
1010    GHCi session
1011          Prelude> let f n = n * 2 :: Int
1012          Prelude> fName <- runQ [| f |]
1013          Prelude> $(return $ AppE fName (LitE (IntegerL 7)))
1014          14
1015          Prelude> let f n = n * 3 :: Int
1016          Prelude> $(return $ AppE fName (LitE (IntegerL 7)))
1017    In the last line we use 'fName', which resolves to the *first* 'f'
1018    in scope. If we delete it from the type env, GHCi crashes because
1019    it doesn't expect that.
1020
1021    Hence this code is commented out
1022
1023 -------------------------------------------------- -}
1024
1025     dumpOptTcRn Opt_D_dump_tc
1026         (vcat [text "Bound Ids" <+> pprWithCommas ppr global_ids,
1027                text "Typechecked expr" <+> ppr zonked_expr]) ;
1028
1029     return (global_ids, zonked_expr)
1030     }
1031   where
1032     bad_unboxed id = addErr (sep [ptext (sLit "GHCi can't bind a variable of unlifted type:"),
1033                                   nest 2 (ppr id <+> dcolon <+> ppr (idType id))])
1034
1035 globaliseAndTidy :: Id -> Id
1036 globaliseAndTidy id     -- Note [Interactively-bound Ids in GHCi]
1037   = Id.setIdType (globaliseId VanillaGlobal id) tidy_type
1038   where
1039     tidy_type = tidyTopType (idType id)
1040 \end{code}
1041
1042 Note [Interactively-bound Ids in GHCi]
1043 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1044 The Ids bound by previous Stmts in Template Haskell are currently
1045         a) GlobalIds
1046         b) with an Internal Name (not External)
1047         c) and a tidied type
1048
1049  (a) They must be GlobalIds (not LocalIds) otherwise when we come to
1050      compile an expression using these ids later, the byte code
1051      generator will consider the occurrences to be free rather than
1052      global.
1053
1054  (b) They retain their Internal names becuase we don't have a suitable
1055      Module to name them with.  We could revisit this choice.
1056
1057  (c) Their types are tidied.  This is important, because :info may ask
1058      to look at them, and :info expects the things it looks up to have
1059      tidy types
1060
1061
1062 --------------------------------------------------------------------------
1063                 Typechecking Stmts in GHCi
1064
1065 Here is the grand plan, implemented in tcUserStmt
1066
1067         What you type                   The IO [HValue] that hscStmt returns
1068         -------------                   ------------------------------------
1069         let pat = expr          ==>     let pat = expr in return [coerce HVal x, coerce HVal y, ...]
1070                                         bindings: [x,y,...]
1071
1072         pat <- expr             ==>     expr >>= \ pat -> return [coerce HVal x, coerce HVal y, ...]
1073                                         bindings: [x,y,...]
1074
1075         expr (of IO type)       ==>     expr >>= \ it -> return [coerce HVal it]
1076           [NB: result not printed]      bindings: [it]
1077
1078         expr (of non-IO type,   ==>     let it = expr in print it >> return [coerce HVal it]
1079           result showable)              bindings: [it]
1080
1081         expr (of non-IO type,
1082           result not showable)  ==>     error
1083
1084
1085 \begin{code}
1086 ---------------------------
1087 type PlanResult = ([Id], LHsExpr Id)
1088 type Plan = TcM PlanResult
1089
1090 runPlans :: [Plan] -> TcM PlanResult
1091 -- Try the plans in order.  If one fails (by raising an exn), try the next.
1092 -- If one succeeds, take it.
1093 runPlans []     = panic "runPlans"
1094 runPlans [p]    = p
1095 runPlans (p:ps) = tryTcLIE_ (runPlans ps) p
1096
1097 --------------------
1098 mkPlan :: LStmt Name -> TcM PlanResult
1099 mkPlan (L loc (ExprStmt expr _ _))      -- An expression typed at the prompt
1100   = do  { uniq <- newUnique             -- is treated very specially
1101         ; let fresh_it  = itName uniq
1102               the_bind  = L loc $ mkFunBind (L loc fresh_it) matches
1103               matches   = [mkMatch [] expr emptyLocalBinds]
1104               let_stmt  = L loc $ LetStmt (HsValBinds (ValBindsOut [(NonRecursive,unitBag the_bind)] []))
1105               bind_stmt = L loc $ BindStmt (nlVarPat fresh_it) expr
1106                                            (HsVar bindIOName) noSyntaxExpr
1107               print_it  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar fresh_it))
1108                                            (HsVar thenIOName) placeHolderType
1109
1110         -- The plans are:
1111         --      [it <- e; print it]     but not if it::()
1112         --      [it <- e]
1113         --      [let it = e; print it]
1114         ; runPlans [    -- Plan A
1115                     do { stuff@([it_id], _) <- tcGhciStmts [bind_stmt, print_it]
1116                        ; it_ty <- zonkTcType (idType it_id)
1117                        ; when (isUnitTy it_ty) failM
1118                        ; return stuff },
1119
1120                         -- Plan B; a naked bind statment
1121                     tcGhciStmts [bind_stmt],
1122
1123                         -- Plan C; check that the let-binding is typeable all by itself.
1124                         -- If not, fail; if so, try to print it.
1125                         -- The two-step process avoids getting two errors: one from
1126                         -- the expression itself, and one from the 'print it' part
1127                         -- This two-step story is very clunky, alas
1128                     do { checkNoErrs (tcGhciStmts [let_stmt])
1129                                 --- checkNoErrs defeats the error recovery of let-bindings
1130                        ; tcGhciStmts [let_stmt, print_it] }
1131           ]}
1132
1133 mkPlan stmt@(L loc (BindStmt {}))
1134   | [L _ v] <- collectLStmtBinders stmt         -- One binder, for a bind stmt
1135   = do  { let print_v  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar v))
1136                                            (HsVar thenIOName) placeHolderType
1137
1138         ; print_bind_result <- doptM Opt_PrintBindResult
1139         ; let print_plan = do
1140                   { stuff@([v_id], _) <- tcGhciStmts [stmt, print_v]
1141                   ; v_ty <- zonkTcType (idType v_id)
1142                   ; when (isUnitTy v_ty || not (isTauTy v_ty)) failM
1143                   ; return stuff }
1144
1145         -- The plans are:
1146         --      [stmt; print v]         but not if v::()
1147         --      [stmt]
1148         ; runPlans ((if print_bind_result then [print_plan] else []) ++
1149                     [tcGhciStmts [stmt]])
1150         }
1151
1152 mkPlan stmt
1153   = tcGhciStmts [stmt]
1154
1155 ---------------------------
1156 tcGhciStmts :: [LStmt Name] -> TcM PlanResult
1157 tcGhciStmts stmts
1158  = do { ioTyCon <- tcLookupTyCon ioTyConName ;
1159         ret_id  <- tcLookupId returnIOName ;            -- return @ IO
1160         let {
1161             ret_ty    = mkListTy unitTy ;
1162             io_ret_ty = mkTyConApp ioTyCon [ret_ty] ;
1163             tc_io_stmts stmts = tcStmts DoExpr tcDoStmt stmts io_ret_ty ;
1164
1165             names = map unLoc (collectLStmtsBinders stmts) ;
1166
1167                 -- mk_return builds the expression
1168                 --      returnIO @ [()] [coerce () x, ..,  coerce () z]
1169                 --
1170                 -- Despite the inconvenience of building the type applications etc,
1171                 -- this *has* to be done in type-annotated post-typecheck form
1172                 -- because we are going to return a list of *polymorphic* values
1173                 -- coerced to type (). If we built a *source* stmt
1174                 --      return [coerce x, ..., coerce z]
1175                 -- then the type checker would instantiate x..z, and we wouldn't
1176                 -- get their *polymorphic* values.  (And we'd get ambiguity errs
1177                 -- if they were overloaded, since they aren't applied to anything.)
1178             mk_return ids = nlHsApp (nlHsTyApp ret_id [ret_ty])
1179                                     (noLoc $ ExplicitList unitTy (map mk_item ids)) ;
1180             mk_item id = nlHsApp (nlHsTyApp unsafeCoerceId [idType id, unitTy])
1181                                  (nlHsVar id)
1182          } ;
1183
1184         -- OK, we're ready to typecheck the stmts
1185         traceTc (text "TcRnDriver.tcGhciStmts: tc stmts") ;
1186         ((tc_stmts, ids), lie) <- getLIE $ tc_io_stmts stmts $ \ _ ->
1187                                            mapM tcLookupId names ;
1188                                         -- Look up the names right in the middle,
1189                                         -- where they will all be in scope
1190
1191         -- Simplify the context
1192         traceTc (text "TcRnDriver.tcGhciStmts: simplify ctxt") ;
1193         const_binds <- checkNoErrs (tcSimplifyInteractive lie) ;
1194                 -- checkNoErrs ensures that the plan fails if context redn fails
1195
1196         traceTc (text "TcRnDriver.tcGhciStmts: done") ;
1197         return (ids, mkHsDictLet const_binds $
1198                      noLoc (HsDo DoExpr tc_stmts (mk_return ids) io_ret_ty))
1199     }
1200 \end{code}
1201
1202
1203 tcRnExpr just finds the type of an expression
1204
1205 \begin{code}
1206 tcRnExpr :: HscEnv
1207          -> InteractiveContext
1208          -> LHsExpr RdrName
1209          -> IO (Messages, Maybe Type)
1210 tcRnExpr hsc_env ictxt rdr_expr
1211   = initTcPrintErrors hsc_env iNTERACTIVE $
1212     setInteractiveContext hsc_env ictxt $ do {
1213
1214     (rn_expr, fvs) <- rnLExpr rdr_expr ;
1215     failIfErrsM ;
1216
1217         -- Now typecheck the expression;
1218         -- it might have a rank-2 type (e.g. :t runST)
1219     ((tc_expr, res_ty), lie)       <- getLIE (tcInferRho rn_expr) ;
1220     ((qtvs, dict_insts, _), lie_top) <- getLIE (tcSimplifyInfer smpl_doc (tyVarsOfType res_ty) lie)  ;
1221     tcSimplifyInteractive lie_top ;
1222
1223     let { all_expr_ty = mkForAllTys qtvs $
1224                         mkFunTys (map (idType . instToId) dict_insts)   $
1225                         res_ty } ;
1226     zonkTcType all_expr_ty
1227     }
1228   where
1229     smpl_doc = ptext (sLit "main expression")
1230 \end{code}
1231
1232 tcRnType just finds the kind of a type
1233
1234 \begin{code}
1235 tcRnType :: HscEnv
1236          -> InteractiveContext
1237          -> LHsType RdrName
1238          -> IO (Messages, Maybe Kind)
1239 tcRnType hsc_env ictxt rdr_type
1240   = initTcPrintErrors hsc_env iNTERACTIVE $
1241     setInteractiveContext hsc_env ictxt $ do {
1242
1243     rn_type <- rnLHsType doc rdr_type ;
1244     failIfErrsM ;
1245
1246         -- Now kind-check the type
1247     (ty', kind) <- kcHsType rn_type ;
1248     return kind
1249     }
1250   where
1251     doc = ptext (sLit "In GHCi input")
1252
1253 #endif /* GHCi */
1254 \end{code}
1255
1256
1257 %************************************************************************
1258 %*                                                                      *
1259         More GHCi stuff, to do with browsing and getting info
1260 %*                                                                      *
1261 %************************************************************************
1262
1263 \begin{code}
1264 #ifdef GHCI
1265 -- | ASSUMES that the module is either in the 'HomePackageTable' or is
1266 -- a package module with an interface on disk.  If neither of these is
1267 -- true, then the result will be an error indicating the interface
1268 -- could not be found.
1269 getModuleExports :: HscEnv -> Module -> IO (Messages, Maybe [AvailInfo])
1270 getModuleExports hsc_env mod
1271   = let
1272       ic        = hsc_IC hsc_env
1273       checkMods = ic_toplev_scope ic ++ ic_exports ic
1274     in
1275     initTc hsc_env HsSrcFile False iNTERACTIVE (tcGetModuleExports mod checkMods)
1276
1277 -- Get the export avail info and also load all orphan and family-instance
1278 -- modules.  Finally, check that the family instances of all modules in the
1279 -- interactive context are consistent (these modules are in the second
1280 -- argument).
1281 tcGetModuleExports :: Module -> [Module] -> TcM [AvailInfo]
1282 tcGetModuleExports mod directlyImpMods
1283   = do { let doc = ptext (sLit "context for compiling statements")
1284        ; iface <- initIfaceTcRn $ loadSysInterface doc mod
1285
1286                 -- Load any orphan-module and family instance-module
1287                 -- interfaces, so their instances are visible.
1288        ; loadOrphanModules (dep_orphs (mi_deps iface)) False
1289        ; loadOrphanModules (dep_finsts (mi_deps iface)) True
1290
1291                 -- Check that the family instances of all directly loaded
1292                 -- modules are consistent.
1293        ; checkFamInstConsistency (dep_finsts (mi_deps iface)) directlyImpMods
1294
1295        ; ifaceExportNames (mi_exports iface)
1296        }
1297
1298 tcRnLookupRdrName :: HscEnv -> RdrName -> IO (Messages, Maybe [Name])
1299 tcRnLookupRdrName hsc_env rdr_name
1300   = initTcPrintErrors hsc_env iNTERACTIVE $
1301     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1302     lookup_rdr_name rdr_name
1303
1304 lookup_rdr_name rdr_name = do {
1305         -- If the identifier is a constructor (begins with an
1306         -- upper-case letter), then we need to consider both
1307         -- constructor and type class identifiers.
1308     let { rdr_names = dataTcOccs rdr_name } ;
1309
1310         -- results :: [Either Messages Name]
1311     results <- mapM (tryTcErrs . lookupOccRn) rdr_names ;
1312
1313     traceRn (text "xx" <+> vcat [ppr rdr_names, ppr (map snd results)]);
1314         -- The successful lookups will be (Just name)
1315     let { (warns_s, good_names) = unzip [ (msgs, name)
1316                                         | (msgs, Just name) <- results] ;
1317           errs_s = [msgs | (msgs, Nothing) <- results] } ;
1318
1319         -- Fail if nothing good happened, else add warnings
1320     if null good_names then
1321                 -- No lookup succeeded, so
1322                 -- pick the first error message and report it
1323                 -- ToDo: If one of the errors is "could be Foo.X or Baz.X",
1324                 --       while the other is "X is not in scope",
1325                 --       we definitely want the former; but we might pick the latter
1326         do { addMessages (head errs_s) ; failM }
1327       else                      -- Add deprecation warnings
1328         mapM_ addMessages warns_s ;
1329
1330     return good_names
1331  }
1332
1333 tcRnLookupName :: HscEnv -> Name -> IO (Messages, Maybe TyThing)
1334 tcRnLookupName hsc_env name
1335   = initTcPrintErrors hsc_env iNTERACTIVE $
1336     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1337     tcRnLookupName' name
1338
1339 -- To look up a name we have to look in the local environment (tcl_lcl)
1340 -- as well as the global environment, which is what tcLookup does.
1341 -- But we also want a TyThing, so we have to convert:
1342
1343 tcRnLookupName' :: Name -> TcRn TyThing
1344 tcRnLookupName' name = do
1345    tcthing <- tcLookup name
1346    case tcthing of
1347      AGlobal thing    -> return thing
1348      ATcId{tct_id=id} -> return (AnId id)
1349      _ -> panic "tcRnLookupName'"
1350
1351 tcRnGetInfo :: HscEnv
1352             -> Name
1353             -> IO (Messages, Maybe (TyThing, Fixity, [Instance]))
1354
1355 -- Used to implemnent :info in GHCi
1356 --
1357 -- Look up a RdrName and return all the TyThings it might be
1358 -- A capitalised RdrName is given to us in the DataName namespace,
1359 -- but we want to treat it as *both* a data constructor
1360 --  *and* as a type or class constructor;
1361 -- hence the call to dataTcOccs, and we return up to two results
1362 tcRnGetInfo hsc_env name
1363   = initTcPrintErrors hsc_env iNTERACTIVE $
1364     let ictxt = hsc_IC hsc_env in
1365     setInteractiveContext hsc_env ictxt $ do
1366
1367         -- Load the interface for all unqualified types and classes
1368         -- That way we will find all the instance declarations
1369         -- (Packages have not orphan modules, and we assume that
1370         --  in the home package all relevant modules are loaded.)
1371     loadUnqualIfaces ictxt
1372
1373     thing  <- tcRnLookupName' name
1374     fixity <- lookupFixityRn name
1375     ispecs <- lookupInsts thing
1376     return (thing, fixity, ispecs)
1377
1378 lookupInsts :: TyThing -> TcM [Instance]
1379 lookupInsts (AClass cls)
1380   = do  { inst_envs <- tcGetInstEnvs
1381         ; return (classInstances inst_envs cls) }
1382
1383 lookupInsts (ATyCon tc)
1384   = do  { eps <- getEps -- Load all instances for all classes that are
1385                         -- in the type environment (which are all the ones
1386                         -- we've seen in any interface file so far)
1387         ; (pkg_ie, home_ie) <- tcGetInstEnvs    -- Search all
1388         ; return [ ispec
1389                  | ispec <- instEnvElts home_ie ++ instEnvElts pkg_ie
1390                  , let dfun = instanceDFunId ispec
1391                  , relevant dfun ] }
1392   where
1393     relevant df = tc_name `elemNameSet` tyClsNamesOfDFunHead (idType df)
1394     tc_name     = tyConName tc
1395
1396 lookupInsts other = return []
1397
1398 loadUnqualIfaces :: InteractiveContext -> TcM ()
1399 -- Load the home module for everything that is in scope unqualified
1400 -- This is so that we can accurately report the instances for
1401 -- something
1402 loadUnqualIfaces ictxt
1403   = initIfaceTcRn $
1404     mapM_ (loadSysInterface doc) (moduleSetElts (mkModuleSet unqual_mods))
1405   where
1406     unqual_mods = [ nameModule name
1407                   | gre <- globalRdrEnvElts (ic_rn_gbl_env ictxt),
1408                     let name = gre_name gre,
1409                     not (isInternalName name),
1410                     isTcOcc (nameOccName name),  -- Types and classes only
1411                     unQualOK gre ]               -- In scope unqualified
1412     doc = ptext (sLit "Need interface for module whose export(s) are in scope unqualified")
1413 #endif /* GHCI */
1414 \end{code}
1415
1416 %************************************************************************
1417 %*                                                                      *
1418                 Degugging output
1419 %*                                                                      *
1420 %************************************************************************
1421
1422 \begin{code}
1423 rnDump :: SDoc -> TcRn ()
1424 -- Dump, with a banner, if -ddump-rn
1425 rnDump doc = do { dumpOptTcRn Opt_D_dump_rn (mkDumpDoc "Renamer" doc) }
1426
1427 tcDump :: TcGblEnv -> TcRn ()
1428 tcDump env
1429  = do { dflags <- getDOpts ;
1430
1431         -- Dump short output if -ddump-types or -ddump-tc
1432         when (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1433              (dumpTcRn short_dump) ;
1434
1435         -- Dump bindings if -ddump-tc
1436         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump)
1437    }
1438   where
1439     short_dump = pprTcGblEnv env
1440     full_dump  = pprLHsBinds (tcg_binds env)
1441         -- NB: foreign x-d's have undefined's in their types;
1442         --     hence can't show the tc_fords
1443
1444 tcCoreDump mod_guts
1445  = do { dflags <- getDOpts ;
1446         when (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1447              (dumpTcRn (pprModGuts mod_guts)) ;
1448
1449         -- Dump bindings if -ddump-tc
1450         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump) }
1451   where
1452     full_dump = pprCoreBindings (mg_binds mod_guts)
1453
1454 -- It's unpleasant having both pprModGuts and pprModDetails here
1455 pprTcGblEnv :: TcGblEnv -> SDoc
1456 pprTcGblEnv (TcGblEnv { tcg_type_env  = type_env,
1457                         tcg_insts     = insts,
1458                         tcg_fam_insts = fam_insts,
1459                         tcg_rules     = rules,
1460                         tcg_imports   = imports })
1461   = vcat [ ppr_types insts type_env
1462          , ppr_tycons fam_insts type_env
1463          , ppr_insts insts
1464          , ppr_fam_insts fam_insts
1465          , vcat (map ppr rules)
1466          , ppr_gen_tycons (typeEnvTyCons type_env)
1467          , ptext (sLit "Dependent modules:") <+>
1468                 ppr (sortBy cmp_mp $ eltsUFM (imp_dep_mods imports))
1469          , ptext (sLit "Dependent packages:") <+>
1470                 ppr (sortBy stablePackageIdCmp $ imp_dep_pkgs imports)]
1471   where         -- The two uses of sortBy are just to reduce unnecessary
1472                 -- wobbling in testsuite output
1473     cmp_mp (mod_name1, is_boot1) (mod_name2, is_boot2)
1474         = (mod_name1 `stableModuleNameCmp` mod_name2)
1475                   `thenCmp`
1476           (is_boot1 `compare` is_boot2)
1477
1478 pprModGuts :: ModGuts -> SDoc
1479 pprModGuts (ModGuts { mg_types = type_env,
1480                       mg_rules = rules })
1481   = vcat [ ppr_types [] type_env,
1482            ppr_rules rules ]
1483
1484 ppr_types :: [Instance] -> TypeEnv -> SDoc
1485 ppr_types insts type_env
1486   = text "TYPE SIGNATURES" $$ nest 4 (ppr_sigs ids)
1487   where
1488     dfun_ids = map instanceDFunId insts
1489     ids = [id | id <- typeEnvIds type_env, want_sig id]
1490     want_sig id | opt_PprStyle_Debug = True
1491                 | otherwise          = isLocalId id &&
1492                                        isExternalName (idName id) &&
1493                                        not (id `elem` dfun_ids)
1494         -- isLocalId ignores data constructors, records selectors etc.
1495         -- The isExternalName ignores local dictionary and method bindings
1496         -- that the type checker has invented.  Top-level user-defined things
1497         -- have External names.
1498
1499 ppr_tycons :: [FamInst] -> TypeEnv -> SDoc
1500 ppr_tycons fam_insts type_env
1501   = text "TYPE CONSTRUCTORS" $$ nest 4 (ppr_tydecls tycons)
1502   where
1503     fi_tycons = map famInstTyCon fam_insts
1504     tycons = [tycon | tycon <- typeEnvTyCons type_env, want_tycon tycon]
1505     want_tycon tycon | opt_PprStyle_Debug = True
1506                      | otherwise          = not (isImplicitTyCon tycon) &&
1507                                             isExternalName (tyConName tycon) &&
1508                                             not (tycon `elem` fi_tycons)
1509
1510 ppr_insts :: [Instance] -> SDoc
1511 ppr_insts []     = empty
1512 ppr_insts ispecs = text "INSTANCES" $$ nest 2 (pprInstances ispecs)
1513
1514 ppr_fam_insts :: [FamInst] -> SDoc
1515 ppr_fam_insts []        = empty
1516 ppr_fam_insts fam_insts =
1517   text "FAMILY INSTANCES" $$ nest 2 (pprFamInsts fam_insts)
1518
1519 ppr_sigs :: [Var] -> SDoc
1520 ppr_sigs ids
1521         -- Print type signatures; sort by OccName
1522   = vcat (map ppr_sig (sortLe le_sig ids))
1523   where
1524     le_sig id1 id2 = getOccName id1 <= getOccName id2
1525     ppr_sig id = ppr id <+> dcolon <+> ppr (tidyTopType (idType id))
1526
1527 ppr_tydecls :: [TyCon] -> SDoc
1528 ppr_tydecls tycons
1529         -- Print type constructor info; sort by OccName
1530   = vcat (map ppr_tycon (sortLe le_sig tycons))
1531   where
1532     le_sig tycon1 tycon2 = getOccName tycon1 <= getOccName tycon2
1533     ppr_tycon tycon
1534       | isCoercionTyCon tycon = ptext (sLit "coercion") <+> ppr tycon
1535       | otherwise             = ppr (tyThingToIfaceDecl (ATyCon tycon))
1536
1537 ppr_rules :: [CoreRule] -> SDoc
1538 ppr_rules [] = empty
1539 ppr_rules rs = vcat [ptext (sLit "{-# RULES"),
1540                       nest 4 (pprRules rs),
1541                       ptext (sLit "#-}")]
1542
1543 ppr_gen_tycons []  = empty
1544 ppr_gen_tycons tcs = vcat [ptext (sLit "Tycons with generics:"),
1545                            nest 2 (fsep (map ppr (filter tyConHasGenerics tcs)))]
1546 \end{code}