compiler/typecheck/TcRnDriver.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcModule]{Typechecking a whole module}
   5
   6 \begin{code}
   7 module TcRnDriver (
   8 #ifdef GHCI
   9         tcRnStmt, tcRnExpr, tcRnType,
  10         tcRnLookupRdrName,
  11         tcRnLookupName,
  12         tcRnGetInfo,
  13         getModuleExports,
  14 #endif
  15         tcRnModule,
  16         tcTopSrcDecls,
  17         tcRnExtCore
  18     ) where
  19
  20 #include "HsVersions.h"
  21
  22 import IO
  23 #ifdef GHCI
  24 import {-# SOURCE #-} TcSplice ( tcSpliceDecls )
  25 #endif
  26
  27 import DynFlags         ( DynFlag(..), DynFlags(..), dopt, GhcMode(..) )
  28 import StaticFlags      ( opt_PprStyle_Debug )
  29 import HsSyn            ( HsModule(..), HsExtCore(..), HsGroup(..), LHsDecl,
  30                           SpliceDecl(..), HsBind(..), LHsBinds,
  31                           emptyRdrGroup, emptyRnGroup, appendGroups, plusHsValBinds,
  32                           nlHsApp, nlHsVar, pprLHsBinds )
  33 import RdrHsSyn         ( findSplice )
  34
  35 import PrelNames        ( runMainIOName, rootMainKey, rOOT_MAIN, mAIN,
  36                           main_RDR_Unqual )
  37 import RdrName          ( RdrName, mkRdrUnqual, emptyGlobalRdrEnv )
  38 import TyCon            ( isOpenTyCon )
  39 import TcHsSyn          ( zonkTopDecls )
  40 import TcExpr           ( tcInferRho )
  41 import TcRnMonad
  42 import TcType           ( tidyTopType, tcEqType )
  43 import Inst             ( showLIE )
  44 import InstEnv          ( extendInstEnvList, Instance, pprInstances, instanceDFunId )
  45 import TcBinds          ( tcTopBinds, tcHsBootSigs )
  46 import TcDefaults       ( tcDefaults )
  47 import TcEnv            ( tcExtendGlobalValEnv, iDFunId )
  48 import TcRules          ( tcRules )
  49 import TcForeign        ( tcForeignImports, tcForeignExports )
  50 import TcInstDcls       ( tcInstDecls1, tcInstDecls2 )
  51 import TcIface          ( tcExtCoreBindings, tcHiBootIface )
  52 import MkIface          ( tyThingToIfaceDecl )
  53 import IfaceSyn         ( checkBootDecl, IfaceExtName(..) )
  54 import TcSimplify       ( tcSimplifyTop )
  55 import TcTyClsDecls     ( tcTyAndClassDecls )
  56 import LoadIface        ( loadOrphanModules )
  57 import RnNames          ( importsFromLocalDecls, rnImports, rnExports,
  58                           mkRdrEnvAndImports, mkExportNameSet,
  59                           reportUnusedNames, reportDeprecations )
  60 import RnEnv            ( lookupSrcOcc_maybe )
  61 import RnSource         ( rnSrcDecls, rnTyClDecls, checkModDeprec )
  62 import PprCore          ( pprRules, pprCoreBindings )
  63 import CoreSyn          ( CoreRule, bindersOfBinds )
  64 import ErrUtils         ( Messages, mkDumpDoc, showPass )
  65 import Id               ( Id, mkExportedLocalId, isLocalId, idName, idType )
  66 import Var              ( Var )
  67 import Module
  68 import UniqFM           ( elemUFM, eltsUFM )
  69 import OccName          ( mkVarOccFS, plusOccEnv )
  70 import Name             ( Name, NamedThing(..), isExternalName, getSrcLoc, isWiredInName,
  71                           nameModule, nameOccName, isImplicitName, mkExternalName )
  72 import NameSet
  73 import TyCon            ( tyConHasGenerics )
  74 import SrcLoc           ( srcLocSpan, Located(..), noLoc )
  75 import DriverPhases     ( HscSource(..), isHsBoot )
  76 import HscTypes         ( ModGuts(..), ModDetails(..), emptyModDetails,
  77                           HscEnv(..), ExternalPackageState(..),
  78                           IsBootInterface, noDependencies,
  79                           Deprecs( NoDeprecs ), plusDeprecs,
  80                           ForeignStubs(NoStubs),
  81                           TypeEnv, lookupTypeEnv, hptInstances,
  82                           extendTypeEnvWithIds, typeEnvIds, typeEnvTyCons, typeEnvElts,
  83                           emptyFixityEnv
  84                         )
  85 import Outputable
  86
  87 #ifdef GHCI
  88 import HsSyn            ( HsStmtContext(..), Stmt(..), HsExpr(..),
  89                           HsLocalBinds(..), HsValBinds(..),
  90                           LStmt, LHsExpr, LHsType, mkMatch, emptyLocalBinds,
  91                           collectLStmtsBinders, collectLStmtBinders, nlVarPat,
  92                           mkFunBind, placeHolderType, noSyntaxExpr, nlHsTyApp )
  93 import RdrName          ( GlobalRdrElt(..), globalRdrEnvElts,
  94                           unQualOK, lookupLocalRdrEnv, extendLocalRdrEnv )
  95 import RnSource         ( addTcgDUs )
  96 import TcHsSyn          ( mkHsDictLet, zonkTopLExpr, zonkTopBndrs )
  97 import TcHsType         ( kcHsType )
  98 import TcMType          ( zonkTcType, zonkQuantifiedTyVar )
  99 import TcMatches        ( tcStmts, tcDoStmt )
 100 import TcSimplify       ( tcSimplifyInteractive, tcSimplifyInfer )
 101 import TcGadt           ( emptyRefinement )
 102 import TcType           ( Type, mkForAllTys, mkFunTys, mkTyConApp, tyVarsOfType, isTauTy,
 103                           isUnLiftedType, tyClsNamesOfDFunHead, tyClsNamesOfType, isUnitTy )
 104 import TcEnv            ( tcLookupTyCon, tcLookupId, tcLookupGlobal )
 105 import TypeRep          ( TyThing(..) )
 106 import RnTypes          ( rnLHsType )
 107 import Inst             ( tcGetInstEnvs )
 108 import InstEnv          ( classInstances, instEnvElts )
 109 import RnExpr           ( rnStmts, rnLExpr )
 110 import LoadIface        ( loadSysInterface )
 111 import IfaceEnv         ( ifaceExportNames )
 112 import RnEnv            ( lookupOccRn, dataTcOccs, lookupFixityRn )
 113 import Id               ( setIdType )
 114 import MkId             ( unsafeCoerceId )
 115 import TyCon            ( tyConName )
 116 import TysWiredIn       ( mkListTy, unitTy )
 117 import IdInfo           ( GlobalIdDetails(..) )
 118 import {- Kind parts of -} Type         ( Kind )
 119 import Var              ( globaliseId )
 120 import Name             ( isBuiltInSyntax, isInternalName )
 121 import OccName          ( isTcOcc )
 122 import NameEnv          ( delListFromNameEnv )
 123 import PrelNames        ( iNTERACTIVE, ioTyConName, printName, itName,
 124                           bindIOName, thenIOName, returnIOName )
 125 import HscTypes         ( InteractiveContext(..),
 126                           ModIface(..), icPrintUnqual,
 127                           Dependencies(..) )
 128 import BasicTypes       ( Fixity, RecFlag(..) )
 129 import SrcLoc           ( unLoc )
 130 import Data.Maybe       ( isNothing )
 131 #endif
 132
 133 import FastString       ( mkFastString )
 134 import Util             ( sortLe )
 135 import Bag              ( unionBags, snocBag, emptyBag, unitBag, unionManyBags )
 136
 137 import Data.Maybe       ( isJust )
 138 \end{code}
 139
 140
 141
 142 %************************************************************************
 143 %*                                                                      *
 144         Typecheck and rename a module
 145 %*                                                                      *
 146 %************************************************************************
 147
 148
 149 \begin{code}
 150 tcRnModule :: HscEnv
 151            -> HscSource
 152            -> Bool              -- True <=> save renamed syntax
 153            -> Located (HsModule RdrName)
 154            -> IO (Messages, Maybe TcGblEnv)
 155
 156 tcRnModule hsc_env hsc_src save_rn_syntax
 157          (L loc (HsModule maybe_mod export_ies
 158                           import_decls local_decls mod_deprec))
 159  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 160
 161    let { this_pkg = thisPackage (hsc_dflags hsc_env) ;
 162          this_mod = case maybe_mod of
 163                         Nothing  -> mAIN        -- 'module M where' is omitted
 164                         Just (L _ mod) -> mkModule this_pkg mod } ;
 165                                                 -- The normal case
 166
 167    initTc hsc_env hsc_src this_mod $
 168    setSrcSpan loc $
 169    do {
 170                 -- Deal with imports;
 171         rn_imports <- rnImports import_decls ;
 172         (rdr_env, imports) <- mkRdrEnvAndImports rn_imports ;
 173
 174         let { dep_mods :: ModuleNameEnv (ModuleName, IsBootInterface)
 175             ; dep_mods = imp_dep_mods imports
 176
 177                 -- We want instance declarations from all home-package
 178                 -- modules below this one, including boot modules, except
 179                 -- ourselves.  The 'except ourselves' is so that we don't
 180                 -- get the instances from this module's hs-boot file
 181             ; want_instances :: ModuleName -> Bool
 182             ; want_instances mod = mod `elemUFM` dep_mods
 183                                    && mod /= moduleName this_mod
 184             ; home_insts = hptInstances hsc_env want_instances
 185             } ;
 186
 187                 -- Record boot-file info in the EPS, so that it's
 188                 -- visible to loadHiBootInterface in tcRnSrcDecls,
 189                 -- and any other incrementally-performed imports
 190         updateEps_ (\eps -> eps { eps_is_boot = dep_mods }) ;
 191
 192                 -- Update the gbl env
 193         updGblEnv ( \ gbl ->
 194                 gbl { tcg_rdr_env  = plusOccEnv (tcg_rdr_env gbl) rdr_env,
 195                       tcg_inst_env = extendInstEnvList (tcg_inst_env gbl) home_insts,
 196                       tcg_imports  = tcg_imports gbl `plusImportAvails` imports,
 197                       tcg_rn_imports = if save_rn_syntax then
 198                                          Just rn_imports
 199                                        else
 200                                          Nothing,
 201                       tcg_rn_decls = if save_rn_syntax then
 202                                         Just emptyRnGroup
 203                                      else
 204                                         Nothing })
 205                 $ do {
 206
 207         traceRn (text "rn1" <+> ppr (imp_dep_mods imports)) ;
 208                 -- Fail if there are any errors so far
 209                 -- The error printing (if needed) takes advantage
 210                 -- of the tcg_env we have now set
 211         failIfErrsM ;
 212
 213                 -- Load any orphan-module interfaces, so that
 214                 -- their rules and instance decls will be found
 215         loadOrphanModules (imp_orphs imports) ;
 216
 217         traceRn (text "rn1a") ;
 218                 -- Rename and type check the declarations
 219         tcg_env <- if isHsBoot hsc_src then
 220                         tcRnHsBootDecls local_decls
 221                    else
 222                         tcRnSrcDecls local_decls ;
 223         setGblEnv tcg_env               $ do {
 224
 225         traceRn (text "rn3") ;
 226
 227                 -- Report the use of any deprecated things
 228                 -- We do this before processsing the export list so
 229                 -- that we don't bleat about re-exporting a deprecated
 230                 -- thing (especially via 'module Foo' export item)
 231                 -- Only uses in the body of the module are complained about
 232         reportDeprecations (hsc_dflags hsc_env) tcg_env ;
 233
 234                 -- Process the export list
 235         rn_exports <- rnExports export_ies;
 236         let { liftM2' fn a b = do a' <- a; b' <- b; return (fn a' b') } ;
 237         exports <- mkExportNameSet (isJust maybe_mod)
 238                                    (liftM2' (,) rn_exports export_ies) ;
 239
 240                 -- Check whether the entire module is deprecated
 241                 -- This happens only once per module
 242         let { mod_deprecs = checkModDeprec mod_deprec } ;
 243
 244                 -- Add exports and deprecations to envt
 245         let { final_env  = tcg_env { tcg_exports = exports,
 246                                      tcg_rn_exports = if save_rn_syntax then
 247                                                          rn_exports
 248                                                       else Nothing,
 249                                      tcg_dus = tcg_dus tcg_env `plusDU` usesOnly exports,
 250                                      tcg_deprecs = tcg_deprecs tcg_env `plusDeprecs`
 251                                                    mod_deprecs }
 252                 -- A module deprecation over-rides the earlier ones
 253              } ;
 254
 255                 -- Report unused names
 256         reportUnusedNames export_ies final_env ;
 257
 258                 -- Dump output and return
 259         tcDump final_env ;
 260         return final_env
 261     }}}}
 262 \end{code}
 263
 264
 265 %************************************************************************
 266 %*                                                                      *
 267         Type-checking external-core modules
 268 %*                                                                      *
 269 %************************************************************************
 270
 271 \begin{code}
 272 tcRnExtCore :: HscEnv
 273             -> HsExtCore RdrName
 274             -> IO (Messages, Maybe ModGuts)
 275         -- Nothing => some error occurred
 276
 277 tcRnExtCore hsc_env (HsExtCore this_mod decls src_binds)
 278         -- The decls are IfaceDecls; all names are original names
 279  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 280
 281    initTc hsc_env ExtCoreFile this_mod $ do {
 282
 283    let { ldecls  = map noLoc decls } ;
 284
 285         -- Deal with the type declarations; first bring their stuff
 286         -- into scope, then rname them, then type check them
 287    tcg_env  <- importsFromLocalDecls (mkFakeGroup ldecls) ;
 288
 289    setGblEnv tcg_env $ do {
 290
 291    rn_decls <- rnTyClDecls ldecls ;
 292    failIfErrsM ;
 293
 294         -- Dump trace of renaming part
 295    rnDump (ppr rn_decls) ;
 296
 297         -- Typecheck them all together so that
 298         -- any mutually recursive types are done right
 299    tcg_env <- checkNoErrs (tcTyAndClassDecls emptyModDetails rn_decls) ;
 300         -- Make the new type env available to stuff slurped from interface files
 301
 302    setGblEnv tcg_env $ do {
 303
 304         -- Now the core bindings
 305    core_binds <- initIfaceExtCore (tcExtCoreBindings src_binds) ;
 306
 307         -- Wrap up
 308    let {
 309         bndrs      = bindersOfBinds core_binds ;
 310         my_exports = mkNameSet (map idName bndrs) ;
 311                 -- ToDo: export the data types also?
 312
 313         final_type_env = extendTypeEnvWithIds (tcg_type_env tcg_env) bndrs ;
 314
 315         mod_guts = ModGuts {    mg_module   = this_mod,
 316                                 mg_boot     = False,
 317                                 mg_usages   = [],               -- ToDo: compute usage
 318                                 mg_dir_imps = [],               -- ??
 319                                 mg_deps     = noDependencies,   -- ??
 320                                 mg_exports  = my_exports,
 321                                 mg_types    = final_type_env,
 322                                 mg_insts    = tcg_insts tcg_env,
 323                                 mg_rules    = [],
 324                                 mg_binds    = core_binds,
 325
 326                                 -- Stubs
 327                                 mg_rdr_env  = emptyGlobalRdrEnv,
 328                                 mg_fix_env  = emptyFixityEnv,
 329                                 mg_deprecs  = NoDeprecs,
 330                                 mg_foreign  = NoStubs
 331                     } } ;
 332
 333    tcCoreDump mod_guts ;
 334
 335    return mod_guts
 336    }}}}
 337
 338 mkFakeGroup decls -- Rather clumsy; lots of unused fields
 339   = emptyRdrGroup { hs_tyclds = decls }
 340 \end{code}
 341
 342
 343 %************************************************************************
 344 %*                                                                      *
 345         Type-checking the top level of a module
 346 %*                                                                      *
 347 %************************************************************************
 348
 349 \begin{code}
 350 tcRnSrcDecls :: [LHsDecl RdrName] -> TcM TcGblEnv
 351         -- Returns the variables free in the decls
 352         -- Reason: solely to report unused imports and bindings
 353 tcRnSrcDecls decls
 354  = do {         -- Load the hi-boot interface for this module, if any
 355                 -- We do this now so that the boot_names can be passed
 356                 -- to tcTyAndClassDecls, because the boot_names are
 357                 -- automatically considered to be loop breakers
 358         mod <- getModule ;
 359         boot_iface <- tcHiBootIface mod ;
 360
 361                 -- Do all the declarations
 362         (tc_envs, lie) <- getLIE (tc_rn_src_decls boot_iface decls) ;
 363
 364              -- tcSimplifyTop deals with constant or ambiguous InstIds.
 365              -- How could there be ambiguous ones?  They can only arise if a
 366              -- top-level decl falls under the monomorphism
 367              -- restriction, and no subsequent decl instantiates its
 368              -- type.  (Usually, ambiguous type variables are resolved
 369              -- during the generalisation step.)
 370         traceTc (text "Tc8") ;
 371         inst_binds <- setEnvs tc_envs (tcSimplifyTop lie) ;
 372                 -- Setting the global env exposes the instances to tcSimplifyTop
 373                 -- Setting the local env exposes the local Ids to tcSimplifyTop,
 374                 -- so that we get better error messages (monomorphism restriction)
 375
 376             -- Backsubstitution.  This must be done last.
 377             -- Even tcSimplifyTop may do some unification.
 378         traceTc (text "Tc9") ;
 379         let { (tcg_env, _) = tc_envs ;
 380               TcGblEnv { tcg_type_env = type_env, tcg_binds = binds,
 381                          tcg_rules = rules, tcg_fords = fords } = tcg_env } ;
 382
 383         tcDump tcg_env ;
 384         (bind_ids, binds', fords', rules') <- zonkTopDecls (binds `unionBags` inst_binds)
 385                                                            rules fords ;
 386
 387         let { final_type_env = extendTypeEnvWithIds type_env bind_ids
 388             ; tcg_env' = tcg_env { tcg_type_env = final_type_env,
 389                                    tcg_binds = binds',
 390                                    tcg_rules = rules',
 391                                    tcg_fords = fords' } } ;
 392
 393         -- Make the new type env available to stuff slurped from interface files
 394         writeMutVar (tcg_type_env_var tcg_env) final_type_env ;
 395
 396         -- Compare the hi-boot iface (if any) with the real thing
 397         dfun_binds <- checkHiBootIface tcg_env' boot_iface ;
 398
 399         return (tcg_env' { tcg_binds = tcg_binds tcg_env' `unionBags` dfun_binds })
 400    }
 401
 402 tc_rn_src_decls :: ModDetails -> [LHsDecl RdrName] -> TcM (TcGblEnv, TcLclEnv)
 403 -- Loops around dealing with each top level inter-splice group
 404 -- in turn, until it's dealt with the entire module
 405 tc_rn_src_decls boot_details ds
 406  = do { let { (first_group, group_tail) = findSplice ds } ;
 407                 -- If ds is [] we get ([], Nothing)
 408
 409         -- Type check the decls up to, but not including, the first splice
 410         tc_envs@(tcg_env,tcl_env) <- tcRnGroup boot_details first_group ;
 411
 412         -- Bale out if errors; for example, error recovery when checking
 413         -- the RHS of 'main' can mean that 'main' is not in the envt for
 414         -- the subsequent checkMain test
 415         failIfErrsM ;
 416
 417         setEnvs tc_envs $
 418
 419         -- If there is no splice, we're nearly done
 420         case group_tail of {
 421            Nothing -> do {      -- Last thing: check for `main'
 422                            tcg_env <- checkMain ;
 423                            return (tcg_env, tcl_env)
 424                       } ;
 425
 426         -- If there's a splice, we must carry on
 427            Just (SpliceDecl splice_expr, rest_ds) -> do {
 428 #ifndef GHCI
 429         failWithTc (text "Can't do a top-level splice; need a bootstrapped compiler")
 430 #else
 431
 432         -- Rename the splice expression, and get its supporting decls
 433         (rn_splice_expr, splice_fvs) <- rnLExpr splice_expr ;
 434         failIfErrsM ;   -- Don't typecheck if renaming failed
 435         rnDump (ppr rn_splice_expr) ;
 436
 437         -- Execute the splice
 438         spliced_decls <- tcSpliceDecls rn_splice_expr ;
 439
 440         -- Glue them on the front of the remaining decls and loop
 441         setGblEnv (tcg_env `addTcgDUs` usesOnly splice_fvs) $
 442         tc_rn_src_decls boot_details (spliced_decls ++ rest_ds)
 443 #endif /* GHCI */
 444     }}}
 445 \end{code}
 446
 447 %************************************************************************
 448 %*                                                                      *
 449         Compiling hs-boot source files, and
 450         comparing the hi-boot interface with the real thing
 451 %*                                                                      *
 452 %************************************************************************
 453
 454 \begin{code}
 455 tcRnHsBootDecls :: [LHsDecl RdrName] -> TcM TcGblEnv
 456 tcRnHsBootDecls decls
 457    = do { let { (first_group, group_tail) = findSplice decls }
 458
 459         ; case group_tail of
 460              Just stuff -> spliceInHsBootErr stuff
 461              Nothing    -> return ()
 462
 463                 -- Rename the declarations
 464         ; (tcg_env, rn_group) <- rnTopSrcDecls first_group
 465         ; setGblEnv tcg_env $ do {
 466
 467         -- Todo: check no foreign decls, no rules, no default decls
 468
 469                 -- Typecheck type/class decls
 470         ; traceTc (text "Tc2")
 471         ; let tycl_decls = hs_tyclds rn_group
 472         ; tcg_env <- checkNoErrs (tcTyAndClassDecls emptyModDetails tycl_decls)
 473         ; setGblEnv tcg_env     $ do {
 474
 475                 -- Typecheck instance decls
 476         ; traceTc (text "Tc3")
 477         ; (tcg_env, inst_infos, _binds) <- tcInstDecls1 tycl_decls (hs_instds rn_group)
 478         ; setGblEnv tcg_env     $ do {
 479
 480                 -- Typecheck value declarations
 481         ; traceTc (text "Tc5")
 482         ; val_ids <- tcHsBootSigs (hs_valds rn_group)
 483
 484                 -- Wrap up
 485                 -- No simplification or zonking to do
 486         ; traceTc (text "Tc7a")
 487         ; gbl_env <- getGblEnv
 488
 489                 -- Make the final type-env
 490                 -- Include the dfun_ids so that their type sigs get
 491                 -- are written into the interface file
 492         ; let { type_env0 = tcg_type_env gbl_env
 493               ; type_env1 = extendTypeEnvWithIds type_env0 val_ids
 494               ; type_env2 = extendTypeEnvWithIds type_env1 dfun_ids
 495               ; dfun_ids = map iDFunId inst_infos }
 496         ; return (gbl_env { tcg_type_env = type_env2 })
 497    }}}}
 498
 499 spliceInHsBootErr (SpliceDecl (L loc _), _)
 500   = addErrAt loc (ptext SLIT("Splices are not allowed in hs-boot files"))
 501 \end{code}
 502
 503 Once we've typechecked the body of the module, we want to compare what
 504 we've found (gathered in a TypeEnv) with the hi-boot details (if any).
 505
 506 \begin{code}
 507 checkHiBootIface :: TcGblEnv -> ModDetails -> TcM (LHsBinds Id)
 508 -- Compare the hi-boot file for this module (if there is one)
 509 -- with the type environment we've just come up with
 510 -- In the common case where there is no hi-boot file, the list
 511 -- of boot_names is empty.
 512 --
 513 -- The bindings we return give bindings for the dfuns defined in the
 514 -- hs-boot file, such as        $fbEqT = $fEqT
 515
 516 checkHiBootIface
 517         (TcGblEnv { tcg_insts = local_insts, tcg_type_env = local_type_env })
 518         (ModDetails { md_insts = boot_insts, md_types = boot_type_env })
 519   = do  { traceTc (text "checkHiBootIface" <+> (ppr boot_type_env $$ ppr boot_insts)) ;
 520         ; mapM_ check_one (typeEnvElts boot_type_env)
 521         ; dfun_binds <- mapM check_inst boot_insts
 522         ; return (unionManyBags dfun_binds) }
 523   where
 524     check_one boot_thing
 525       | no_check name
 526       = return ()
 527       | Just real_thing <- lookupTypeEnv local_type_env name
 528       = do { let boot_decl = tyThingToIfaceDecl ext_nm boot_thing
 529                  real_decl = tyThingToIfaceDecl ext_nm real_thing
 530            ; checkTc (checkBootDecl boot_decl real_decl)
 531                      (bootMisMatch boot_thing boot_decl real_decl) }
 532                 -- The easiest way to check compatibility is to convert to
 533                 -- iface syntax, where we already have good comparison functions
 534       | otherwise
 535       = addErrTc (missingBootThing boot_thing)
 536       where
 537         name = getName boot_thing
 538
 539     ext_nm name = ExtPkg (nameModule name) (nameOccName name)
 540         -- Just enough to compare; no versions etc needed
 541
 542     no_check name = isWiredInName name  -- No checking for wired-in names.  In particular,
 543                                         -- 'error' is handled by a rather gross hack
 544                                         -- (see comments in GHC.Err.hs-boot)
 545                   || name `elem` dfun_names
 546                   || isImplicitName name        -- Has a parent, which we'll check
 547
 548     dfun_names = map getName boot_insts
 549
 550     check_inst boot_inst
 551         = case [dfun | inst <- local_insts,
 552                        let dfun = instanceDFunId inst,
 553                        idType dfun `tcEqType` boot_inst_ty ] of
 554             [] -> do { addErrTc (instMisMatch boot_inst); return emptyBag }
 555             (dfun:_) -> return (unitBag $ noLoc $ VarBind local_boot_dfun (nlHsVar dfun))
 556         where
 557           boot_dfun = instanceDFunId boot_inst
 558           boot_inst_ty = idType boot_dfun
 559           local_boot_dfun = mkExportedLocalId (idName boot_dfun) boot_inst_ty
 560
 561 ----------------
 562 missingBootThing thing
 563   = ppr thing <+> ptext SLIT("is defined in the hs-boot file, but not in the module")
 564 bootMisMatch thing boot_decl real_decl
 565   = ppr thing <+> ptext SLIT("has conflicting definitions in the module and its hs-boot file")
 566     $+$ (ppr boot_decl) $+$ (ppr real_decl)
 567 instMisMatch inst
 568   = hang (ppr inst)
 569        2 (ptext SLIT("is defined in the hs-boot file, but not in the module"))
 570 \end{code}
 571
 572
 573 %************************************************************************
 574 %*                                                                      *
 575         Type-checking the top level of a module
 576 %*                                                                      *
 577 %************************************************************************
 578
 579 tcRnGroup takes a bunch of top-level source-code declarations, and
 580  * renames them
 581  * gets supporting declarations from interface files
 582  * typechecks them
 583  * zonks them
 584  * and augments the TcGblEnv with the results
 585
 586 In Template Haskell it may be called repeatedly for each group of
 587 declarations.  It expects there to be an incoming TcGblEnv in the
 588 monad; it augments it and returns the new TcGblEnv.
 589
 590 \begin{code}
 591 tcRnGroup :: ModDetails -> HsGroup RdrName -> TcM (TcGblEnv, TcLclEnv)
 592         -- Returns the variables free in the decls, for unused-binding reporting
 593 tcRnGroup boot_details decls
 594  = do {         -- Rename the declarations
 595         (tcg_env, rn_decls) <- rnTopSrcDecls decls ;
 596         setGblEnv tcg_env $ do {
 597
 598                 -- Typecheck the declarations
 599         tcTopSrcDecls boot_details rn_decls
 600   }}
 601
 602 ------------------------------------------------
 603 rnTopSrcDecls :: HsGroup RdrName -> TcM (TcGblEnv, HsGroup Name)
 604 rnTopSrcDecls group
 605  = do {         -- Bring top level binders into scope
 606         tcg_env <- importsFromLocalDecls group ;
 607         setGblEnv tcg_env $ do {
 608
 609         failIfErrsM ;   -- No point in continuing if (say) we have duplicate declarations
 610
 611                 -- Rename the source decls
 612         (tcg_env, rn_decls) <- rnSrcDecls group ;
 613         failIfErrsM ;
 614
 615                 -- save the renamed syntax, if we want it
 616         let { tcg_env'
 617                 | Just grp <- tcg_rn_decls tcg_env
 618                   = tcg_env{ tcg_rn_decls = Just (appendGroups grp rn_decls) }
 619                 | otherwise
 620                    = tcg_env };
 621
 622                 -- Dump trace of renaming part
 623         rnDump (ppr rn_decls) ;
 624
 625         return (tcg_env', rn_decls)
 626    }}
 627
 628 ------------------------------------------------
 629 tcTopSrcDecls :: ModDetails -> HsGroup Name -> TcM (TcGblEnv, TcLclEnv)
 630 tcTopSrcDecls boot_details
 631         (HsGroup { hs_tyclds = tycl_decls,
 632                    hs_instds = inst_decls,
 633                    hs_fords  = foreign_decls,
 634                    hs_defds  = default_decls,
 635                    hs_ruleds = rule_decls,
 636                    hs_valds  = val_binds })
 637  = do {         -- Type-check the type and class decls, and all imported decls
 638                 -- The latter come in via tycl_decls
 639         traceTc (text "Tc2") ;
 640
 641         tcg_env <- checkNoErrs (tcTyAndClassDecls boot_details tycl_decls) ;
 642         -- tcTyAndClassDecls recovers internally, but if anything gave rise to
 643         -- an error we'd better stop now, to avoid a cascade
 644
 645         -- Make these type and class decls available to stuff slurped from interface files
 646         writeMutVar (tcg_type_env_var tcg_env) (tcg_type_env tcg_env) ;
 647
 648
 649         setGblEnv tcg_env       $ do {
 650                 -- Source-language instances, including derivings,
 651                 -- and import the supporting declarations
 652         traceTc (text "Tc3") ;
 653         (tcg_env, inst_infos, deriv_binds) <- tcInstDecls1 tycl_decls inst_decls ;
 654         setGblEnv tcg_env       $ do {
 655
 656                 -- Foreign import declarations next.  No zonking necessary
 657                 -- here; we can tuck them straight into the global environment.
 658         traceTc (text "Tc4") ;
 659         (fi_ids, fi_decls) <- tcForeignImports foreign_decls ;
 660         tcExtendGlobalValEnv fi_ids     $ do {
 661
 662                 -- Default declarations
 663         traceTc (text "Tc4a") ;
 664         default_tys <- tcDefaults default_decls ;
 665         updGblEnv (\gbl -> gbl { tcg_default = default_tys }) $ do {
 666
 667                 -- Value declarations next
 668                 -- We also typecheck any extra binds that came out
 669                 -- of the "deriving" process (deriv_binds)
 670         traceTc (text "Tc5") ;
 671         (tc_val_binds, tcl_env) <- tcTopBinds (val_binds `plusHsValBinds` deriv_binds) ;
 672         setLclTypeEnv tcl_env   $ do {
 673
 674                 -- Second pass over class and instance declarations,
 675         traceTc (text "Tc6") ;
 676         (inst_binds, tcl_env) <- tcInstDecls2 tycl_decls inst_infos ;
 677         showLIE (text "after instDecls2") ;
 678
 679                 -- Foreign exports
 680                 -- They need to be zonked, so we return them
 681         traceTc (text "Tc7") ;
 682         (foe_binds, foe_decls) <- tcForeignExports foreign_decls ;
 683
 684                 -- Rules
 685         rules <- tcRules rule_decls ;
 686
 687                 -- Wrap up
 688         traceTc (text "Tc7a") ;
 689         tcg_env <- getGblEnv ;
 690         let { all_binds = tc_val_binds   `unionBags`
 691                           inst_binds     `unionBags`
 692                           foe_binds  ;
 693
 694                 -- Extend the GblEnv with the (as yet un-zonked)
 695                 -- bindings, rules, foreign decls
 696               tcg_env' = tcg_env {  tcg_binds = tcg_binds tcg_env `unionBags` all_binds,
 697                                     tcg_rules = tcg_rules tcg_env ++ rules,
 698                                     tcg_fords = tcg_fords tcg_env ++ foe_decls ++ fi_decls } } ;
 699         return (tcg_env', tcl_env)
 700     }}}}}}
 701 \end{code}
 702
 703
 704 %************************************************************************
 705 %*                                                                      *
 706         Checking for 'main'
 707 %*                                                                      *
 708 %************************************************************************
 709
 710 \begin{code}
 711 checkMain :: TcM TcGblEnv
 712 -- If we are in module Main, check that 'main' is defined.
 713 checkMain
 714   = do { ghc_mode <- getGhcMode ;
 715          tcg_env   <- getGblEnv ;
 716          dflags    <- getDOpts ;
 717          let { main_mod = mainModIs dflags ;
 718                main_fn  = case mainFunIs dflags of {
 719                                 Just fn -> mkRdrUnqual (mkVarOccFS (mkFastString fn)) ;
 720                                 Nothing -> main_RDR_Unqual } } ;
 721
 722          check_main ghc_mode tcg_env main_mod main_fn
 723     }
 724
 725
 726 check_main ghc_mode tcg_env main_mod main_fn
 727  | mod /= main_mod
 728  = traceTc (text "checkMain not" <+> ppr main_mod <+> ppr mod) >>
 729    return tcg_env
 730
 731  | otherwise
 732  = addErrCtxt mainCtxt                  $
 733    do   { mb_main <- lookupSrcOcc_maybe main_fn
 734                 -- Check that 'main' is in scope
 735                 -- It might be imported from another module!
 736         ; case mb_main of {
 737              Nothing -> do { traceTc (text "checkMain fail" <+> ppr main_mod <+> ppr main_fn)
 738                            ; complain_no_main
 739                            ; return tcg_env } ;
 740              Just main_name -> do
 741         { traceTc (text "checkMain found" <+> ppr main_mod <+> ppr main_fn)
 742         ; let { rhs = nlHsApp (nlHsVar runMainIOName) (nlHsVar main_name) }
 743                         -- :Main.main :: IO () = runMainIO main
 744
 745         ; (main_expr, ty) <- setSrcSpan (srcLocSpan (getSrcLoc main_name)) $
 746                              tcInferRho rhs
 747
 748         -- The function that the RTS invokes is always :Main.main,
 749         -- which we call root_main_id.
 750         -- (Because GHC allows the user to have a module not called
 751         -- Main as the main module, we can't rely on the main function
 752         -- being called "Main.main".  That's why root_main_id has a fixed
 753         -- module ":Main".)
 754         -- We also make root_main_id an implicit Id, by making main_name
 755         -- its parent (hence (Just main_name)).  That has the effect
 756         -- of preventing its type and unfolding from getting out into
 757         -- the interface file. Otherwise we can end up with two defns
 758         -- for 'main' in the interface file!
 759
 760         ; let { root_main_name =  mkExternalName rootMainKey rOOT_MAIN
 761                                    (mkVarOccFS FSLIT("main"))
 762                                    (Just main_name) (getSrcLoc main_name)
 763               ; root_main_id = mkExportedLocalId root_main_name ty
 764               ; main_bind    = noLoc (VarBind root_main_id main_expr) }
 765
 766         ; return (tcg_env { tcg_binds = tcg_binds tcg_env
 767                                         `snocBag` main_bind,
 768                             tcg_dus   = tcg_dus tcg_env
 769                                         `plusDU` usesOnly (unitFV main_name)
 770                         -- Record the use of 'main', so that we don't
 771                         -- complain about it being defined but not used
 772                  })
 773     }}}
 774   where
 775     mod = tcg_mod tcg_env
 776
 777     complain_no_main | ghc_mode == Interactive = return ()
 778                      | otherwise                = failWithTc noMainMsg
 779         -- In interactive mode, don't worry about the absence of 'main'
 780         -- In other modes, fail altogether, so that we don't go on
 781         -- and complain a second time when processing the export list.
 782
 783     mainCtxt  = ptext SLIT("When checking the type of the main function") <+> quotes (ppr main_fn)
 784     noMainMsg = ptext SLIT("The main function") <+> quotes (ppr main_fn)
 785                 <+> ptext SLIT("is not defined in module") <+> quotes (ppr main_mod)
 786 \end{code}
 787
 788 %*********************************************************
 789 %*                                                       *
 790                 GHCi stuff
 791 %*                                                       *
 792 %*********************************************************
 793
 794 \begin{code}
 795 #ifdef GHCI
 796 setInteractiveContext :: HscEnv -> InteractiveContext -> TcRn a -> TcRn a
 797 setInteractiveContext hsc_env icxt thing_inside
 798   = let
 799         -- Initialise the tcg_inst_env with instances
 800         -- from all home modules.  This mimics the more selective
 801         -- call to hptInstances in tcRnModule
 802         dfuns = hptInstances hsc_env (\mod -> True)
 803     in
 804     updGblEnv (\env -> env {
 805         tcg_rdr_env  = ic_rn_gbl_env icxt,
 806         tcg_type_env = ic_type_env   icxt,
 807         tcg_inst_env = extendInstEnvList (tcg_inst_env env) dfuns }) $
 808
 809     updLclEnv (\env -> env { tcl_rdr = ic_rn_local_env icxt })  $
 810
 811     do  { traceTc (text "setIC" <+> ppr (ic_type_env icxt))
 812         ; thing_inside }
 813 \end{code}
 814
 815
 816 \begin{code}
 817 tcRnStmt :: HscEnv
 818          -> InteractiveContext
 819          -> LStmt RdrName
 820          -> IO (Maybe (InteractiveContext, [Name], LHsExpr Id))
 821                 -- The returned [Name] is the same as the input except for
 822                 -- ExprStmt, in which case the returned [Name] is [itName]
 823                 --
 824                 -- The returned TypecheckedHsExpr is of type IO [ () ],
 825                 -- a list of the bound values, coerced to ().
 826
 827 tcRnStmt hsc_env ictxt rdr_stmt
 828   = initTcPrintErrors hsc_env iNTERACTIVE $
 829     setInteractiveContext hsc_env ictxt $ do {
 830
 831     -- Rename; use CmdLineMode because tcRnStmt is only used interactively
 832     (([rn_stmt], _), fvs) <- rnStmts DoExpr [rdr_stmt] (return ((), emptyFVs)) ;
 833     traceRn (text "tcRnStmt" <+> vcat [ppr rdr_stmt, ppr rn_stmt, ppr fvs]) ;
 834     failIfErrsM ;
 835
 836     -- The real work is done here
 837     (bound_ids, tc_expr) <- mkPlan rn_stmt ;
 838     zonked_expr <- zonkTopLExpr tc_expr ;
 839     zonked_ids  <- zonkTopBndrs bound_ids ;
 840
 841         -- None of the Ids should be of unboxed type, because we
 842         -- cast them all to HValues in the end!
 843     mappM bad_unboxed (filter (isUnLiftedType . idType) zonked_ids) ;
 844
 845     traceTc (text "tcs 1") ;
 846     let {       -- (a) Make all the bound ids "global" ids, now that
 847                 --     they're notionally top-level bindings.  This is
 848                 --     important: otherwise when we come to compile an expression
 849                 --     using these ids later, the byte code generator will consider
 850                 --     the occurrences to be free rather than global.
 851                 --
 852                 -- (b) Tidy their types; this is important, because :info may
 853                 --     ask to look at them, and :info expects the things it looks
 854                 --     up to have tidy types
 855         global_ids = map globaliseAndTidy zonked_ids ;
 856
 857                 -- Update the interactive context
 858         rn_env   = ic_rn_local_env ictxt ;
 859         type_env = ic_type_env ictxt ;
 860
 861         bound_names = map idName global_ids ;
 862         new_rn_env  = extendLocalRdrEnv rn_env bound_names ;
 863
 864                 -- Remove any shadowed bindings from the type_env;
 865                 -- they are inaccessible but might, I suppose, cause
 866                 -- a space leak if we leave them there
 867         shadowed = [ n | name <- bound_names,
 868                          let rdr_name = mkRdrUnqual (nameOccName name),
 869                          Just n <- [lookupLocalRdrEnv rn_env rdr_name] ] ;
 870
 871         filtered_type_env = delListFromNameEnv type_env shadowed ;
 872         new_type_env = extendTypeEnvWithIds filtered_type_env global_ids ;
 873
 874         new_ic = ictxt { ic_rn_local_env = new_rn_env,
 875                          ic_type_env     = new_type_env }
 876     } ;
 877
 878     dumpOptTcRn Opt_D_dump_tc
 879         (vcat [text "Bound Ids" <+> pprWithCommas ppr global_ids,
 880                text "Typechecked expr" <+> ppr zonked_expr]) ;
 881
 882     returnM (new_ic, bound_names, zonked_expr)
 883     }
 884   where
 885     bad_unboxed id = addErr (sep [ptext SLIT("GHCi can't bind a variable of unlifted type:"),
 886                                   nest 2 (ppr id <+> dcolon <+> ppr (idType id))])
 887
 888 globaliseAndTidy :: Id -> Id
 889 globaliseAndTidy id
 890 -- Give the Id a Global Name, and tidy its type
 891   = setIdType (globaliseId VanillaGlobal id) tidy_type
 892   where
 893     tidy_type = tidyTopType (idType id)
 894 \end{code}
 895
 896 Here is the grand plan, implemented in tcUserStmt
 897
 898         What you type                   The IO [HValue] that hscStmt returns
 899         -------------                   ------------------------------------
 900         let pat = expr          ==>     let pat = expr in return [coerce HVal x, coerce HVal y, ...]
 901                                         bindings: [x,y,...]
 902
 903         pat <- expr             ==>     expr >>= \ pat -> return [coerce HVal x, coerce HVal y, ...]
 904                                         bindings: [x,y,...]
 905
 906         expr (of IO type)       ==>     expr >>= \ it -> return [coerce HVal it]
 907           [NB: result not printed]      bindings: [it]
 908
 909         expr (of non-IO type,   ==>     let it = expr in print it >> return [coerce HVal it]
 910           result showable)              bindings: [it]
 911
 912         expr (of non-IO type,
 913           result not showable)  ==>     error
 914
 915
 916 \begin{code}
 917 ---------------------------
 918 type PlanResult = ([Id], LHsExpr Id)
 919 type Plan = TcM PlanResult
 920
 921 runPlans :: [Plan] -> TcM PlanResult
 922 -- Try the plans in order.  If one fails (by raising an exn), try the next.
 923 -- If one succeeds, take it.
 924 runPlans []     = panic "runPlans"
 925 runPlans [p]    = p
 926 runPlans (p:ps) = tryTcLIE_ (runPlans ps) p
 927
 928 --------------------
 929 mkPlan :: LStmt Name -> TcM PlanResult
 930 mkPlan (L loc (ExprStmt expr _ _))      -- An expression typed at the prompt
 931   = do  { uniq <- newUnique             -- is treated very specially
 932         ; let fresh_it  = itName uniq
 933               the_bind  = L loc $ mkFunBind (L loc fresh_it) matches
 934               matches   = [mkMatch [] expr emptyLocalBinds]
 935               let_stmt  = L loc $ LetStmt (HsValBinds (ValBindsOut [(NonRecursive,unitBag the_bind)] []))
 936               bind_stmt = L loc $ BindStmt (nlVarPat fresh_it) expr
 937                                            (HsVar bindIOName) noSyntaxExpr
 938               print_it  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar fresh_it))
 939                                            (HsVar thenIOName) placeHolderType
 940
 941         -- The plans are:
 942         --      [it <- e; print it]     but not if it::()
 943         --      [it <- e]
 944         --      [let it = e; print it]
 945         ; runPlans [    -- Plan A
 946                     do { stuff@([it_id], _) <- tcGhciStmts [bind_stmt, print_it]
 947                        ; it_ty <- zonkTcType (idType it_id)
 948                        ; ifM (isUnitTy it_ty) failM
 949                        ; return stuff },
 950
 951                         -- Plan B; a naked bind statment
 952                     tcGhciStmts [bind_stmt],
 953
 954                         -- Plan C; check that the let-binding is typeable all by itself.
 955                         -- If not, fail; if so, try to print it.
 956                         -- The two-step process avoids getting two errors: one from
 957                         -- the expression itself, and one from the 'print it' part
 958                         -- This two-step story is very clunky, alas
 959                     do { checkNoErrs (tcGhciStmts [let_stmt])
 960                                 --- checkNoErrs defeats the error recovery of let-bindings
 961                        ; tcGhciStmts [let_stmt, print_it] }
 962           ]}
 963
 964 mkPlan stmt@(L loc (BindStmt {}))
 965   | [L _ v] <- collectLStmtBinders stmt         -- One binder, for a bind stmt
 966   = do  { let print_v  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar v))
 967                                            (HsVar thenIOName) placeHolderType
 968         -- The plans are:
 969         --      [stmt; print v]         but not if v::()
 970         --      [stmt]
 971         ; runPlans [do { stuff@([v_id], _) <- tcGhciStmts [stmt, print_v]
 972                        ; v_ty <- zonkTcType (idType v_id)
 973                        ; ifM (isUnitTy v_ty || not (isTauTy v_ty)) failM
 974                        ; return stuff },
 975                     tcGhciStmts [stmt]
 976           ]}
 977
 978 mkPlan stmt
 979   = tcGhciStmts [stmt]
 980
 981 ---------------------------
 982 tcGhciStmts :: [LStmt Name] -> TcM PlanResult
 983 tcGhciStmts stmts
 984  = do { ioTyCon <- tcLookupTyCon ioTyConName ;
 985         ret_id  <- tcLookupId returnIOName ;            -- return @ IO
 986         let {
 987             io_ty     = mkTyConApp ioTyCon [] ;
 988             ret_ty    = mkListTy unitTy ;
 989             io_ret_ty = mkTyConApp ioTyCon [ret_ty] ;
 990             tc_io_stmts stmts = tcStmts DoExpr (tcDoStmt io_ty) stmts
 991                                         (emptyRefinement, io_ret_ty) ;
 992
 993             names = map unLoc (collectLStmtsBinders stmts) ;
 994
 995                 -- mk_return builds the expression
 996                 --      returnIO @ [()] [coerce () x, ..,  coerce () z]
 997                 --
 998                 -- Despite the inconvenience of building the type applications etc,
 999                 -- this *has* to be done in type-annotated post-typecheck form
1000                 -- because we are going to return a list of *polymorphic* values
1001                 -- coerced to type (). If we built a *source* stmt
1002                 --      return [coerce x, ..., coerce z]
1003                 -- then the type checker would instantiate x..z, and we wouldn't
1004                 -- get their *polymorphic* values.  (And we'd get ambiguity errs
1005                 -- if they were overloaded, since they aren't applied to anything.)
1006             mk_return ids = nlHsApp (nlHsTyApp ret_id [ret_ty])
1007                                     (noLoc $ ExplicitList unitTy (map mk_item ids)) ;
1008             mk_item id = nlHsApp (nlHsTyApp unsafeCoerceId [idType id, unitTy])
1009                                  (nlHsVar id)
1010          } ;
1011
1012         -- OK, we're ready to typecheck the stmts
1013         traceTc (text "tcs 2") ;
1014         ((tc_stmts, ids), lie) <- getLIE $ tc_io_stmts stmts $ \ _ ->
1015                                            mappM tcLookupId names ;
1016                                         -- Look up the names right in the middle,
1017                                         -- where they will all be in scope
1018
1019         -- Simplify the context
1020         const_binds <- checkNoErrs (tcSimplifyInteractive lie) ;
1021                 -- checkNoErrs ensures that the plan fails if context redn fails
1022
1023         return (ids, mkHsDictLet const_binds $
1024                      noLoc (HsDo DoExpr tc_stmts (mk_return ids) io_ret_ty))
1025     }
1026 \end{code}
1027
1028
1029 tcRnExpr just finds the type of an expression
1030
1031 \begin{code}
1032 tcRnExpr :: HscEnv
1033          -> InteractiveContext
1034          -> LHsExpr RdrName
1035          -> IO (Maybe Type)
1036 tcRnExpr hsc_env ictxt rdr_expr
1037   = initTcPrintErrors hsc_env iNTERACTIVE $
1038     setInteractiveContext hsc_env ictxt $ do {
1039
1040     (rn_expr, fvs) <- rnLExpr rdr_expr ;
1041     failIfErrsM ;
1042
1043         -- Now typecheck the expression;
1044         -- it might have a rank-2 type (e.g. :t runST)
1045     ((tc_expr, res_ty), lie)       <- getLIE (tcInferRho rn_expr) ;
1046     ((qtvs, _, dict_ids), lie_top) <- getLIE (tcSimplifyInfer smpl_doc (tyVarsOfType res_ty) lie)  ;
1047     tcSimplifyInteractive lie_top ;
1048     qtvs' <- mappM zonkQuantifiedTyVar qtvs ;
1049
1050     let { all_expr_ty = mkForAllTys qtvs' $
1051                         mkFunTys (map idType dict_ids)  $
1052                         res_ty } ;
1053     zonkTcType all_expr_ty
1054     }
1055   where
1056     smpl_doc = ptext SLIT("main expression")
1057 \end{code}
1058
1059 tcRnType just finds the kind of a type
1060
1061 \begin{code}
1062 tcRnType :: HscEnv
1063          -> InteractiveContext
1064          -> LHsType RdrName
1065          -> IO (Maybe Kind)
1066 tcRnType hsc_env ictxt rdr_type
1067   = initTcPrintErrors hsc_env iNTERACTIVE $
1068     setInteractiveContext hsc_env ictxt $ do {
1069
1070     rn_type <- rnLHsType doc rdr_type ;
1071     failIfErrsM ;
1072
1073         -- Now kind-check the type
1074     (ty', kind) <- kcHsType rn_type ;
1075     return kind
1076     }
1077   where
1078     doc = ptext SLIT("In GHCi input")
1079
1080 #endif /* GHCi */
1081 \end{code}
1082
1083
1084 %************************************************************************
1085 %*                                                                      *
1086         More GHCi stuff, to do with browsing and getting info
1087 %*                                                                      *
1088 %************************************************************************
1089
1090 \begin{code}
1091 #ifdef GHCI
1092 -- ASSUMES that the module is either in the HomePackageTable or is
1093 -- a package module with an interface on disk.  If neither of these is
1094 -- true, then the result will be an error indicating the interface
1095 -- could not be found.
1096 getModuleExports :: HscEnv -> Module -> IO (Messages, Maybe NameSet)
1097 getModuleExports hsc_env mod
1098   = initTc hsc_env HsSrcFile iNTERACTIVE (tcGetModuleExports mod)
1099
1100 tcGetModuleExports :: Module -> TcM NameSet
1101 tcGetModuleExports mod = do
1102   let doc = ptext SLIT("context for compiling statements")
1103   iface <- initIfaceTcRn $ loadSysInterface doc mod
1104   loadOrphanModules (dep_orphs (mi_deps iface))
1105                 -- Load any orphan-module interfaces,
1106                 -- so their instances are visible
1107   ifaceExportNames (mi_exports iface)
1108
1109 tcRnLookupRdrName :: HscEnv -> RdrName -> IO (Maybe [Name])
1110 tcRnLookupRdrName hsc_env rdr_name
1111   = initTcPrintErrors hsc_env iNTERACTIVE $
1112     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1113     lookup_rdr_name rdr_name
1114
1115 lookup_rdr_name rdr_name = do {
1116         -- If the identifier is a constructor (begins with an
1117         -- upper-case letter), then we need to consider both
1118         -- constructor and type class identifiers.
1119     let { rdr_names = dataTcOccs rdr_name } ;
1120
1121         -- results :: [Either Messages Name]
1122     results <- mapM (tryTcErrs . lookupOccRn) rdr_names ;
1123
1124     traceRn (text "xx" <+> vcat [ppr rdr_names, ppr (map snd results)]);
1125         -- The successful lookups will be (Just name)
1126     let { (warns_s, good_names) = unzip [ (msgs, name)
1127                                         | (msgs, Just name) <- results] ;
1128           errs_s = [msgs | (msgs, Nothing) <- results] } ;
1129
1130         -- Fail if nothing good happened, else add warnings
1131     if null good_names then
1132                 -- No lookup succeeded, so
1133                 -- pick the first error message and report it
1134                 -- ToDo: If one of the errors is "could be Foo.X or Baz.X",
1135                 --       while the other is "X is not in scope",
1136                 --       we definitely want the former; but we might pick the latter
1137         do { addMessages (head errs_s) ; failM }
1138       else                      -- Add deprecation warnings
1139         mapM_ addMessages warns_s ;
1140
1141     return good_names
1142  }
1143
1144
1145 tcRnLookupName :: HscEnv -> Name -> IO (Maybe TyThing)
1146 tcRnLookupName hsc_env name
1147   = initTcPrintErrors hsc_env iNTERACTIVE $
1148     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1149     tcLookupGlobal name
1150
1151
1152 tcRnGetInfo :: HscEnv
1153             -> Name
1154             -> IO (Maybe (TyThing, Fixity, [Instance]))
1155
1156 -- Used to implemnent :info in GHCi
1157 --
1158 -- Look up a RdrName and return all the TyThings it might be
1159 -- A capitalised RdrName is given to us in the DataName namespace,
1160 -- but we want to treat it as *both* a data constructor
1161 --  *and* as a type or class constructor;
1162 -- hence the call to dataTcOccs, and we return up to two results
1163 tcRnGetInfo hsc_env name
1164   = initTcPrintErrors hsc_env iNTERACTIVE $
1165     let ictxt = hsc_IC hsc_env in
1166     setInteractiveContext hsc_env ictxt $ do
1167
1168         -- Load the interface for all unqualified types and classes
1169         -- That way we will find all the instance declarations
1170         -- (Packages have not orphan modules, and we assume that
1171         --  in the home package all relevant modules are loaded.)
1172     loadUnqualIfaces ictxt
1173
1174     thing  <- tcLookupGlobal name
1175     fixity <- lookupFixityRn name
1176     ispecs <- lookupInsts (icPrintUnqual ictxt) thing
1177     return (thing, fixity, ispecs)
1178
1179
1180 lookupInsts :: PrintUnqualified -> TyThing -> TcM [Instance]
1181 -- Filter the instances by the ones whose tycons (or clases resp)
1182 -- are in scope unqualified.  Otherwise we list a whole lot too many!
1183 lookupInsts print_unqual (AClass cls)
1184   = do  { inst_envs <- tcGetInstEnvs
1185         ; return [ ispec
1186                  | ispec <- classInstances inst_envs cls
1187                  , plausibleDFun print_unqual (instanceDFunId ispec) ] }
1188
1189 lookupInsts print_unqual (ATyCon tc)
1190   = do  { eps <- getEps -- Load all instances for all classes that are
1191                         -- in the type environment (which are all the ones
1192                         -- we've seen in any interface file so far)
1193         ; (pkg_ie, home_ie) <- tcGetInstEnvs    -- Search all
1194         ; return [ ispec
1195                  | ispec <- instEnvElts home_ie ++ instEnvElts pkg_ie
1196                  , let dfun = instanceDFunId ispec
1197                  , relevant dfun
1198                  , plausibleDFun print_unqual dfun ] }
1199   where
1200     relevant df = tc_name `elemNameSet` tyClsNamesOfDFunHead (idType df)
1201     tc_name     = tyConName tc
1202
1203 lookupInsts print_unqual other = return []
1204
1205 plausibleDFun print_unqual dfun -- Dfun involving only names that print unqualified
1206   = all ok (nameSetToList (tyClsNamesOfType (idType dfun)))
1207   where
1208     ok name | isBuiltInSyntax name = True
1209             | isExternalName name  =
1210                 isNothing $ fst print_unqual (nameModule name)
1211                                              (nameOccName name)
1212             | otherwise            = True
1213
1214 loadUnqualIfaces :: InteractiveContext -> TcM ()
1215 -- Load the home module for everything that is in scope unqualified
1216 -- This is so that we can accurately report the instances for
1217 -- something
1218 loadUnqualIfaces ictxt
1219   = initIfaceTcRn $
1220     mapM_ (loadSysInterface doc) (moduleSetElts (mkModuleSet unqual_mods))
1221   where
1222     unqual_mods = [ nameModule name
1223                   | gre <- globalRdrEnvElts (ic_rn_gbl_env ictxt),
1224                     let name = gre_name gre,
1225                     not (isInternalName name),
1226                     isTcOcc (nameOccName name),  -- Types and classes only
1227                     unQualOK gre ]               -- In scope unqualified
1228     doc = ptext SLIT("Need interface for module whose export(s) are in scope unqualified")
1229 #endif /* GHCI */
1230 \end{code}
1231
1232 %************************************************************************
1233 %*                                                                      *
1234                 Degugging output
1235 %*                                                                      *
1236 %************************************************************************
1237
1238 \begin{code}
1239 rnDump :: SDoc -> TcRn ()
1240 -- Dump, with a banner, if -ddump-rn
1241 rnDump doc = do { dumpOptTcRn Opt_D_dump_rn (mkDumpDoc "Renamer" doc) }
1242
1243 tcDump :: TcGblEnv -> TcRn ()
1244 tcDump env
1245  = do { dflags <- getDOpts ;
1246
1247         -- Dump short output if -ddump-types or -ddump-tc
1248         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1249             (dumpTcRn short_dump) ;
1250
1251         -- Dump bindings if -ddump-tc
1252         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump)
1253    }
1254   where
1255     short_dump = pprTcGblEnv env
1256     full_dump  = pprLHsBinds (tcg_binds env)
1257         -- NB: foreign x-d's have undefined's in their types;
1258         --     hence can't show the tc_fords
1259
1260 tcCoreDump mod_guts
1261  = do { dflags <- getDOpts ;
1262         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1263             (dumpTcRn (pprModGuts mod_guts)) ;
1264
1265         -- Dump bindings if -ddump-tc
1266         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump) }
1267   where
1268     full_dump = pprCoreBindings (mg_binds mod_guts)
1269
1270 -- It's unpleasant having both pprModGuts and pprModDetails here
1271 pprTcGblEnv :: TcGblEnv -> SDoc
1272 pprTcGblEnv (TcGblEnv { tcg_type_env = type_env,
1273                         tcg_insts    = dfun_ids,
1274                         tcg_rules    = rules,
1275                         tcg_imports  = imports })
1276   = vcat [ ppr_types dfun_ids type_env
1277          , ppr_insts dfun_ids
1278          , vcat (map ppr rules)
1279          , ppr_gen_tycons (typeEnvTyCons type_env)
1280          , ptext SLIT("Dependent modules:") <+> ppr (eltsUFM (imp_dep_mods imports))
1281          , ptext SLIT("Dependent packages:") <+> ppr (imp_dep_pkgs imports)]
1282
1283 pprModGuts :: ModGuts -> SDoc
1284 pprModGuts (ModGuts { mg_types = type_env,
1285                       mg_rules = rules })
1286   = vcat [ ppr_types [] type_env,
1287            ppr_rules rules ]
1288
1289
1290 ppr_types :: [Instance] -> TypeEnv -> SDoc
1291 ppr_types ispecs type_env
1292   = text "TYPE SIGNATURES" $$ nest 4 (ppr_sigs ids)
1293   where
1294     dfun_ids = map instanceDFunId ispecs
1295     ids = [id | id <- typeEnvIds type_env, want_sig id]
1296     want_sig id | opt_PprStyle_Debug = True
1297                 | otherwise          = isLocalId id &&
1298                                        isExternalName (idName id) &&
1299                                        not (id `elem` dfun_ids)
1300         -- isLocalId ignores data constructors, records selectors etc.
1301         -- The isExternalName ignores local dictionary and method bindings
1302         -- that the type checker has invented.  Top-level user-defined things
1303         -- have External names.
1304
1305 ppr_insts :: [Instance] -> SDoc
1306 ppr_insts []     = empty
1307 ppr_insts ispecs = text "INSTANCES" $$ nest 2 (pprInstances ispecs)
1308
1309 ppr_sigs :: [Var] -> SDoc
1310 ppr_sigs ids
1311         -- Print type signatures; sort by OccName
1312   = vcat (map ppr_sig (sortLe le_sig ids))
1313   where
1314     le_sig id1 id2 = getOccName id1 <= getOccName id2
1315     ppr_sig id = ppr id <+> dcolon <+> ppr (tidyTopType (idType id))
1316
1317 ppr_rules :: [CoreRule] -> SDoc
1318 ppr_rules [] = empty
1319 ppr_rules rs = vcat [ptext SLIT("{-# RULES"),
1320                       nest 4 (pprRules rs),
1321                       ptext SLIT("#-}")]
1322
1323 ppr_gen_tycons []  = empty
1324 ppr_gen_tycons tcs = vcat [ptext SLIT("Tycons with generics:"),
1325                            nest 2 (fsep (map ppr (filter tyConHasGenerics tcs)))]
1326 \end{code}