compiler/typecheck/TcRnDriver.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5 \section[TcModule]{Typechecking a whole module}
   6
   7 \begin{code}
   8 module TcRnDriver (
   9 #ifdef GHCI
  10         tcRnStmt, tcRnExpr, tcRnType,
  11         tcRnLookupRdrName,
  12         tcRnLookupName,
  13         tcRnGetInfo,
  14         getModuleExports,
  15 #endif
  16         tcRnModule,
  17         tcTopSrcDecls,
  18         tcRnExtCore
  19     ) where
  20
  21 #ifdef GHCI
  22 import {-# SOURCE #-} TcSplice ( tcSpliceDecls )
  23 #endif
  24
  25 import DynFlags
  26 import StaticFlags
  27 import HsSyn
  28 import PrelNames
  29 import RdrName
  30 import TcHsSyn
  31 import TcExpr
  32 import TcRnMonad
  33 import Coercion
  34 import Inst
  35 import FamInst
  36 import InstEnv
  37 import FamInstEnv
  38 import TcAnnotations
  39 import TcBinds
  40 import TcDefaults
  41 import TcEnv
  42 import TcRules
  43 import TcForeign
  44 import TcInstDcls
  45 import TcIface
  46 import MkIface
  47 import IfaceSyn
  48 import TcSimplify
  49 import TcTyClsDecls
  50 import TcUnify  ( withBox )
  51 import LoadIface
  52 import RnNames
  53 import RnEnv
  54 import RnSource
  55 import PprCore
  56 import CoreSyn
  57 import ErrUtils
  58 import Id
  59 import VarEnv
  60 import Var
  61 import Module
  62 import UniqFM
  63 import Name
  64 import NameEnv
  65 import NameSet
  66 import TyCon
  67 import TysPrim
  68 import SrcLoc
  69 import HscTypes
  70 import ListSetOps
  71 import Outputable
  72 import DataCon
  73 import Type
  74 import Class
  75 import Data.List ( sortBy )
  76
  77 #ifdef GHCI
  78 import TcHsType
  79 import TcMType
  80 import TcMatches
  81 import RnTypes
  82 import RnExpr
  83 import IfaceEnv
  84 import MkId
  85 import BasicTypes
  86 import TidyPgm    ( globaliseAndTidyId )
  87 import TcType     ( isUnitTy, isTauTy, tyClsNamesOfDFunHead )
  88 import TysWiredIn ( unitTy, mkListTy )
  89 #endif
  90
  91 import FastString
  92 import Maybes
  93 import Util
  94 import Bag
  95
  96 import Control.Monad
  97
  98 #include "HsVersions.h"
  99 \end{code}
 100
 101 %************************************************************************
 102 %*                                                                      *
 103         Typecheck and rename a module
 104 %*                                                                      *
 105 %************************************************************************
 106
 107
 108 \begin{code}
 109 tcRnModule :: HscEnv
 110            -> HscSource
 111            -> Bool              -- True <=> save renamed syntax
 112            -> Located (HsModule RdrName)
 113            -> IO (Messages, Maybe TcGblEnv)
 114
 115 tcRnModule hsc_env hsc_src save_rn_syntax
 116          (L loc (HsModule maybe_mod export_ies
 117                           import_decls local_decls mod_deprec
 118                           maybe_doc_hdr))
 119  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 120
 121    let { this_pkg = thisPackage (hsc_dflags hsc_env) ;
 122          this_mod = case maybe_mod of
 123                         Nothing  -> mAIN        -- 'module M where' is omitted
 124                         Just (L _ mod) -> mkModule this_pkg mod } ;
 125                                                 -- The normal case
 126
 127    initTc hsc_env hsc_src save_rn_syntax this_mod $
 128    setSrcSpan loc $
 129    do {         -- Deal with imports;
 130         tcg_env <- tcRnImports hsc_env this_mod import_decls ;
 131         setGblEnv tcg_env               $ do {
 132
 133                 -- Load the hi-boot interface for this module, if any
 134                 -- We do this now so that the boot_names can be passed
 135                 -- to tcTyAndClassDecls, because the boot_names are
 136                 -- automatically considered to be loop breakers
 137                 --
 138                 -- Do this *after* tcRnImports, so that we know whether
 139                 -- a module that we import imports us; and hence whether to
 140                 -- look for a hi-boot file
 141         boot_iface <- tcHiBootIface hsc_src this_mod ;
 142
 143                 -- Rename and type check the declarations
 144         traceRn (text "rn1a") ;
 145         tcg_env <- if isHsBoot hsc_src then
 146                         tcRnHsBootDecls local_decls
 147                    else
 148                         tcRnSrcDecls boot_iface local_decls ;
 149         setGblEnv tcg_env               $ do {
 150
 151                 -- Report the use of any deprecated things
 152                 -- We do this *before* processsing the export list so
 153                 -- that we don't bleat about re-exporting a deprecated
 154                 -- thing (especially via 'module Foo' export item)
 155                 -- That is, only uses in the *body* of the module are complained about
 156         traceRn (text "rn3") ;
 157         failIfErrsM ;   -- finishWarnings crashes sometimes
 158                         -- as a result of typechecker repairs (e.g. unboundNames)
 159         tcg_env <- finishWarnings (hsc_dflags hsc_env) mod_deprec tcg_env ;
 160
 161                 -- Process the export list
 162         traceRn (text "rn4a: before exports");
 163         tcg_env <- rnExports (isJust maybe_mod) export_ies tcg_env ;
 164         traceRn (text "rn4b: after exportss") ;
 165
 166                 -- Check that main is exported (must be after rnExports)
 167         checkMainExported tcg_env ;
 168
 169         -- Compare the hi-boot iface (if any) with the real thing
 170         -- Must be done after processing the exports
 171         tcg_env <- checkHiBootIface tcg_env boot_iface ;
 172
 173         -- The new type env is already available to stuff slurped from
 174         -- interface files, via TcEnv.updateGlobalTypeEnv
 175         -- It's important that this includes the stuff in checkHiBootIface,
 176         -- because the latter might add new bindings for boot_dfuns,
 177         -- which may be mentioned in imported unfoldings
 178
 179                 -- Don't need to rename the Haddock documentation,
 180                 -- it's not parsed by GHC anymore.
 181         tcg_env <- return (tcg_env { tcg_doc_hdr = maybe_doc_hdr }) ;
 182
 183                 -- Report unused names
 184         reportUnusedNames export_ies tcg_env ;
 185
 186                 -- Dump output and return
 187         tcDump tcg_env ;
 188         return tcg_env
 189     }}}}
 190 \end{code}
 191
 192
 193 %************************************************************************
 194 %*                                                                      *
 195                 Import declarations
 196 %*                                                                      *
 197 %************************************************************************
 198
 199 \begin{code}
 200 tcRnImports :: HscEnv -> Module -> [LImportDecl RdrName] -> TcM TcGblEnv
 201 tcRnImports hsc_env this_mod import_decls
 202   = do  { (rn_imports, rdr_env, imports,hpc_info) <- rnImports import_decls ;
 203
 204         ; let { dep_mods :: ModuleNameEnv (ModuleName, IsBootInterface)
 205               ; dep_mods = imp_dep_mods imports
 206
 207                 -- We want instance declarations from all home-package
 208                 -- modules below this one, including boot modules, except
 209                 -- ourselves.  The 'except ourselves' is so that we don't
 210                 -- get the instances from this module's hs-boot file
 211               ; want_instances :: ModuleName -> Bool
 212               ; want_instances mod = mod `elemUFM` dep_mods
 213                                    && mod /= moduleName this_mod
 214               ; (home_insts, home_fam_insts) = hptInstances hsc_env
 215                                                             want_instances
 216               } ;
 217
 218                 -- Record boot-file info in the EPS, so that it's
 219                 -- visible to loadHiBootInterface in tcRnSrcDecls,
 220                 -- and any other incrementally-performed imports
 221         ; updateEps_ (\eps -> eps { eps_is_boot = dep_mods }) ;
 222
 223                 -- Update the gbl env
 224         ; updGblEnv ( \ gbl ->
 225             gbl {
 226               tcg_rdr_env      = plusOccEnv (tcg_rdr_env gbl) rdr_env,
 227               tcg_imports      = tcg_imports gbl `plusImportAvails` imports,
 228               tcg_rn_imports   = rn_imports,
 229               tcg_inst_env     = extendInstEnvList (tcg_inst_env gbl) home_insts,
 230               tcg_fam_inst_env = extendFamInstEnvList (tcg_fam_inst_env gbl)
 231                                                       home_fam_insts,
 232               tcg_hpc          = hpc_info
 233             }) $ do {
 234
 235         ; traceRn (text "rn1" <+> ppr (imp_dep_mods imports))
 236                 -- Fail if there are any errors so far
 237                 -- The error printing (if needed) takes advantage
 238                 -- of the tcg_env we have now set
 239 --      ; traceIf (text "rdr_env: " <+> ppr rdr_env)
 240         ; failIfErrsM
 241
 242                 -- Load any orphan-module and family instance-module
 243                 -- interfaces, so that their rules and instance decls will be
 244                 -- found.
 245         ; loadOrphanModules (imp_orphs  imports) False
 246         ; loadOrphanModules (imp_finsts imports) True
 247
 248                 -- Check type-familily consistency
 249         ; traceRn (text "rn1: checking family instance consistency")
 250         ; let { dir_imp_mods = moduleEnvKeys
 251                              . imp_mods
 252                              $ imports }
 253         ; checkFamInstConsistency (imp_finsts imports) dir_imp_mods ;
 254
 255         ; getGblEnv } }
 256 \end{code}
 257
 258
 259 %************************************************************************
 260 %*                                                                      *
 261         Type-checking external-core modules
 262 %*                                                                      *
 263 %************************************************************************
 264
 265 \begin{code}
 266 tcRnExtCore :: HscEnv
 267             -> HsExtCore RdrName
 268             -> IO (Messages, Maybe ModGuts)
 269         -- Nothing => some error occurred
 270
 271 tcRnExtCore hsc_env (HsExtCore this_mod decls src_binds)
 272         -- The decls are IfaceDecls; all names are original names
 273  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 274
 275    initTc hsc_env ExtCoreFile False this_mod $ do {
 276
 277    let { ldecls  = map noLoc decls } ;
 278
 279        -- bring the type and class decls into scope
 280        -- ToDo: check that this doesn't need to extract the val binds.
 281        --       It seems that only the type and class decls need to be in scope below because
 282        --          (a) tcTyAndClassDecls doesn't need the val binds, and
 283        --          (b) tcExtCoreBindings doesn't need anything
 284        --              (in fact, it might not even need to be in the scope of
 285        --               this tcg_env at all)
 286    avails  <- getLocalNonValBinders (mkFakeGroup ldecls) ;
 287    tc_envs <- extendGlobalRdrEnvRn avails emptyFsEnv {- no fixity decls -} ;
 288
 289    setEnvs tc_envs $ do {
 290
 291    rn_decls <- checkNoErrs $ rnTyClDecls ldecls ;
 292
 293         -- Dump trace of renaming part
 294    rnDump (ppr rn_decls) ;
 295
 296         -- Typecheck them all together so that
 297         -- any mutually recursive types are done right
 298         -- Just discard the auxiliary bindings; they are generated
 299         -- only for Haskell source code, and should already be in Core
 300    (tcg_env, _aux_binds) <- tcTyAndClassDecls emptyModDetails rn_decls ;
 301
 302    setGblEnv tcg_env $ do {
 303         -- Make the new type env available to stuff slurped from interface files
 304
 305         -- Now the core bindings
 306    core_binds <- initIfaceExtCore (tcExtCoreBindings src_binds) ;
 307
 308         -- Wrap up
 309    let {
 310         bndrs      = bindersOfBinds core_binds ;
 311         my_exports = map (Avail . idName) bndrs ;
 312                 -- ToDo: export the data types also?
 313
 314         final_type_env =
 315              extendTypeEnvWithIds (tcg_type_env tcg_env) bndrs ;
 316
 317         mod_guts = ModGuts {    mg_module    = this_mod,
 318                                 mg_boot      = False,
 319                                 mg_used_names = emptyNameSet, -- ToDo: compute usage
 320                                 mg_dir_imps  = emptyModuleEnv, -- ??
 321                                 mg_deps      = noDependencies,  -- ??
 322                                 mg_exports   = my_exports,
 323                                 mg_types     = final_type_env,
 324                                 mg_insts     = tcg_insts tcg_env,
 325                                 mg_fam_insts = tcg_fam_insts tcg_env,
 326                                 mg_inst_env  = tcg_inst_env tcg_env,
 327                                 mg_fam_inst_env = tcg_fam_inst_env tcg_env,
 328                                 mg_rules     = [],
 329                                 mg_anns      = [],
 330                                 mg_binds     = core_binds,
 331
 332                                 -- Stubs
 333                                 mg_rdr_env   = emptyGlobalRdrEnv,
 334                                 mg_fix_env   = emptyFixityEnv,
 335                                 mg_warns     = NoWarnings,
 336                                 mg_foreign   = NoStubs,
 337                                 mg_hpc_info  = emptyHpcInfo False,
 338                                 mg_modBreaks = emptyModBreaks,
 339                                 mg_vect_info = noVectInfo
 340                     } } ;
 341
 342    tcCoreDump mod_guts ;
 343
 344    return mod_guts
 345    }}}}
 346
 347 mkFakeGroup :: [LTyClDecl a] -> HsGroup a
 348 mkFakeGroup decls -- Rather clumsy; lots of unused fields
 349   = emptyRdrGroup { hs_tyclds = decls }
 350 \end{code}
 351
 352
 353 %************************************************************************
 354 %*                                                                      *
 355         Type-checking the top level of a module
 356 %*                                                                      *
 357 %************************************************************************
 358
 359 \begin{code}
 360 tcRnSrcDecls :: ModDetails -> [LHsDecl RdrName] -> TcM TcGblEnv
 361         -- Returns the variables free in the decls
 362         -- Reason: solely to report unused imports and bindings
 363 tcRnSrcDecls boot_iface decls
 364  = do {         -- Do all the declarations
 365         (tc_envs, lie) <- getLIE $ tc_rn_src_decls boot_iface decls ;
 366
 367              --         Finish simplifying class constraints
 368              --
 369              -- tcSimplifyTop deals with constant or ambiguous InstIds.
 370              -- How could there be ambiguous ones?  They can only arise if a
 371              -- top-level decl falls under the monomorphism restriction
 372              -- and no subsequent decl instantiates its type.
 373              --
 374              -- We do this after checkMain, so that we use the type info
 375              -- thaat checkMain adds
 376              --
 377              -- We do it with both global and local env in scope:
 378              --  * the global env exposes the instances to tcSimplifyTop
 379              --  * the local env exposes the local Ids to tcSimplifyTop,
 380              --    so that we get better error messages (monomorphism restriction)
 381         traceTc (text "Tc8") ;
 382         inst_binds <- setEnvs tc_envs (tcSimplifyTop lie) ;
 383
 384             -- Backsubstitution.  This must be done last.
 385             -- Even tcSimplifyTop may do some unification.
 386         traceTc (text "Tc9") ;
 387         let { (tcg_env, _) = tc_envs
 388             ; TcGblEnv { tcg_type_env = type_env,
 389                          tcg_binds = binds,
 390                          tcg_rules = rules,
 391                          tcg_fords = fords } = tcg_env
 392             ; all_binds = binds `unionBags` inst_binds } ;
 393
 394         failIfErrsM ;   -- Don't zonk if there have been errors
 395                         -- It's a waste of time; and we may get debug warnings
 396                         -- about strangely-typed TyCons!
 397
 398         (bind_ids, binds', fords', rules') <- zonkTopDecls all_binds rules fords ;
 399
 400
 401         let { final_type_env = extendTypeEnvWithIds type_env bind_ids
 402             ; tcg_env' = tcg_env { tcg_binds = binds',
 403                                    tcg_rules = rules',
 404                                    tcg_fords = fords' } } ;
 405
 406         setGlobalTypeEnv tcg_env' final_type_env
 407    }
 408
 409 tc_rn_src_decls :: ModDetails -> [LHsDecl RdrName] -> TcM (TcGblEnv, TcLclEnv)
 410 -- Loops around dealing with each top level inter-splice group
 411 -- in turn, until it's dealt with the entire module
 412 tc_rn_src_decls boot_details ds
 413  = do { (first_group, group_tail) <- findSplice ds  ;
 414                 -- If ds is [] we get ([], Nothing)
 415
 416         -- Deal with decls up to, but not including, the first splice
 417         (tcg_env, rn_decls) <- rnTopSrcDecls first_group ;
 418                 -- rnTopSrcDecls fails if there are any errors
 419
 420         (tcg_env, tcl_env) <- setGblEnv tcg_env $
 421                               tcTopSrcDecls boot_details rn_decls ;
 422
 423         -- If there is no splice, we're nearly done
 424         setEnvs (tcg_env, tcl_env) $
 425         case group_tail of {
 426            Nothing -> do { tcg_env <- checkMain ;       -- Check for `main'
 427                            return (tcg_env, tcl_env)
 428                       } ;
 429
 430 #ifndef GHCI
 431         -- There shouldn't be a splice
 432            Just (SpliceDecl {}, _) -> do {
 433         failWithTc (text "Can't do a top-level splice; need a bootstrapped compiler")
 434 #else
 435         -- If there's a splice, we must carry on
 436            Just (SpliceDecl splice_expr _, rest_ds) -> do {
 437
 438         -- Rename the splice expression, and get its supporting decls
 439         (rn_splice_expr, splice_fvs) <- checkNoErrs (rnLExpr splice_expr) ;
 440                 -- checkNoErrs: don't typecheck if renaming failed
 441         rnDump (ppr rn_splice_expr) ;
 442
 443         -- Execute the splice
 444         spliced_decls <- tcSpliceDecls rn_splice_expr ;
 445
 446         -- Glue them on the front of the remaining decls and loop
 447         setGblEnv (tcg_env `addTcgDUs` usesOnly splice_fvs) $
 448         tc_rn_src_decls boot_details (spliced_decls ++ rest_ds)
 449 #endif /* GHCI */
 450     } } }
 451 \end{code}
 452
 453 %************************************************************************
 454 %*                                                                      *
 455         Compiling hs-boot source files, and
 456         comparing the hi-boot interface with the real thing
 457 %*                                                                      *
 458 %************************************************************************
 459
 460 \begin{code}
 461 tcRnHsBootDecls :: [LHsDecl RdrName] -> TcM TcGblEnv
 462 tcRnHsBootDecls decls
 463    = do { (first_group, group_tail) <- findSplice decls
 464
 465                 -- Rename the declarations
 466         ; (tcg_env, HsGroup {
 467                    hs_tyclds = tycl_decls,
 468                    hs_instds = inst_decls,
 469                    hs_derivds = deriv_decls,
 470                    hs_fords  = for_decls,
 471                    hs_defds  = def_decls,
 472                    hs_ruleds = rule_decls,
 473                    hs_annds  = _,
 474                    hs_valds  = val_binds }) <- rnTopSrcDecls first_group
 475         ; setGblEnv tcg_env $ do {
 476
 477
 478                 -- Check for illegal declarations
 479         ; case group_tail of
 480              Just (SpliceDecl d _, _) -> badBootDecl "splice" d
 481              Nothing                  -> return ()
 482         ; mapM_ (badBootDecl "foreign") for_decls
 483         ; mapM_ (badBootDecl "default") def_decls
 484         ; mapM_ (badBootDecl "rule")    rule_decls
 485
 486                 -- Typecheck type/class decls
 487         ; traceTc (text "Tc2")
 488         ; (tcg_env, aux_binds) <- tcTyAndClassDecls emptyModDetails tycl_decls
 489         ; setGblEnv tcg_env     $ do {
 490
 491                 -- Typecheck instance decls
 492                 -- Family instance declarations are rejected here
 493         ; traceTc (text "Tc3")
 494         ; (tcg_env, inst_infos, _deriv_binds)
 495             <- tcInstDecls1 tycl_decls inst_decls deriv_decls
 496         ; setGblEnv tcg_env     $ do {
 497
 498                 -- Typecheck value declarations
 499         ; traceTc (text "Tc5")
 500         ; val_ids <- tcHsBootSigs val_binds
 501
 502                 -- Wrap up
 503                 -- No simplification or zonking to do
 504         ; traceTc (text "Tc7a")
 505         ; gbl_env <- getGblEnv
 506
 507                 -- Make the final type-env
 508                 -- Include the dfun_ids so that their type sigs
 509                 -- are written into the interface file.
 510                 -- And similarly the aux_ids from aux_binds
 511         ; let { type_env0 = tcg_type_env gbl_env
 512               ; type_env1 = extendTypeEnvWithIds type_env0 val_ids
 513               ; type_env2 = extendTypeEnvWithIds type_env1 dfun_ids
 514               ; type_env3 = extendTypeEnvWithIds type_env2 aux_ids
 515               ; dfun_ids = map iDFunId inst_infos
 516               ; aux_ids  = case aux_binds of
 517                              ValBindsOut _ sigs -> [id | L _ (IdSig id) <- sigs]
 518                              _                  -> panic "tcRnHsBoodDecls"
 519               }
 520
 521         ; setGlobalTypeEnv gbl_env type_env3
 522    }}}}
 523
 524 badBootDecl :: String -> Located decl -> TcM ()
 525 badBootDecl what (L loc _)
 526   = addErrAt loc (char 'A' <+> text what
 527       <+> ptext (sLit "declaration is not (currently) allowed in a hs-boot file"))
 528 \end{code}
 529
 530 Once we've typechecked the body of the module, we want to compare what
 531 we've found (gathered in a TypeEnv) with the hi-boot details (if any).
 532
 533 \begin{code}
 534 checkHiBootIface :: TcGblEnv -> ModDetails -> TcM TcGblEnv
 535 -- Compare the hi-boot file for this module (if there is one)
 536 -- with the type environment we've just come up with
 537 -- In the common case where there is no hi-boot file, the list
 538 -- of boot_names is empty.
 539 --
 540 -- The bindings we return give bindings for the dfuns defined in the
 541 -- hs-boot file, such as        $fbEqT = $fEqT
 542
 543 checkHiBootIface
 544         tcg_env@(TcGblEnv { tcg_src = hs_src, tcg_binds = binds,
 545                             tcg_insts = local_insts,
 546                             tcg_type_env = local_type_env, tcg_exports = local_exports })
 547         (ModDetails { md_insts = boot_insts, md_fam_insts = boot_fam_insts,
 548                       md_types = boot_type_env, md_exports = boot_exports })
 549   | isHsBoot hs_src     -- Current module is already a hs-boot file!
 550   = return tcg_env
 551
 552   | otherwise
 553   = do  { traceTc (text "checkHiBootIface" <+> (ppr boot_type_env $$ ppr boot_insts $$
 554                                 ppr boot_exports)) ;
 555
 556                 -- Check the exports of the boot module, one by one
 557         ; mapM_ check_export boot_exports
 558
 559                 -- Check for no family instances
 560         ; unless (null boot_fam_insts) $
 561             panic ("TcRnDriver.checkHiBootIface: Cannot handle family " ++
 562                    "instances in boot files yet...")
 563             -- FIXME: Why?  The actual comparison is not hard, but what would
 564             --        be the equivalent to the dfun bindings returned for class
 565             --        instances?  We can't easily equate tycons...
 566
 567                 -- Check instance declarations
 568         ; mb_dfun_prs <- mapM check_inst boot_insts
 569         ; let dfun_prs   = catMaybes mb_dfun_prs
 570               boot_dfuns = map fst dfun_prs
 571               dfun_binds = listToBag [ mkVarBind boot_dfun (nlHsVar dfun)
 572                                      | (boot_dfun, dfun) <- dfun_prs ]
 573               type_env'  = extendTypeEnvWithIds local_type_env boot_dfuns
 574               tcg_env'   = tcg_env { tcg_binds = binds `unionBags` dfun_binds }
 575
 576         ; failIfErrsM
 577         ; setGlobalTypeEnv tcg_env' type_env' }
 578              -- Update the global type env *including* the knot-tied one
 579              -- so that if the source module reads in an interface unfolding
 580              -- mentioning one of the dfuns from the boot module, then it
 581              -- can "see" that boot dfun.   See Trac #4003
 582   where
 583     check_export boot_avail     -- boot_avail is exported by the boot iface
 584       | name `elem` dfun_names = return ()
 585       | isWiredInName name     = return ()      -- No checking for wired-in names.  In particular,
 586                                                 -- 'error' is handled by a rather gross hack
 587                                                 -- (see comments in GHC.Err.hs-boot)
 588
 589         -- Check that the actual module exports the same thing
 590       | not (null missing_names)
 591       = addErrAt (nameSrcSpan (head missing_names))
 592                  (missingBootThing (head missing_names) "exported by")
 593
 594         -- If the boot module does not *define* the thing, we are done
 595         -- (it simply re-exports it, and names match, so nothing further to do)
 596       | isNothing mb_boot_thing = return ()
 597
 598         -- Check that the actual module also defines the thing, and
 599         -- then compare the definitions
 600       | Just real_thing <- lookupTypeEnv local_type_env name,
 601         Just boot_thing <- mb_boot_thing
 602       = when (not (checkBootDecl boot_thing real_thing))
 603             $ addErrAt (nameSrcSpan (getName boot_thing))
 604                        (let boot_decl = tyThingToIfaceDecl
 605                                                (fromJust mb_boot_thing)
 606                             real_decl = tyThingToIfaceDecl real_thing
 607                         in bootMisMatch real_thing boot_decl real_decl)
 608
 609       | otherwise
 610       = addErrTc (missingBootThing name "defined in")
 611       where
 612         name          = availName boot_avail
 613         mb_boot_thing = lookupTypeEnv boot_type_env name
 614         missing_names = case lookupNameEnv local_export_env name of
 615                           Nothing    -> [name]
 616                           Just avail -> availNames boot_avail `minusList` availNames avail
 617
 618     dfun_names = map getName boot_insts
 619
 620     local_export_env :: NameEnv AvailInfo
 621     local_export_env = availsToNameEnv local_exports
 622
 623     check_inst :: Instance -> TcM (Maybe (Id, Id))
 624         -- Returns a pair of the boot dfun in terms of the equivalent real dfun
 625     check_inst boot_inst
 626         = case [dfun | inst <- local_insts,
 627                        let dfun = instanceDFunId inst,
 628                        idType dfun `tcEqType` boot_inst_ty ] of
 629             [] -> do { addErrTc (instMisMatch boot_inst); return Nothing }
 630             (dfun:_) -> return (Just (local_boot_dfun, dfun))
 631         where
 632           boot_dfun = instanceDFunId boot_inst
 633           boot_inst_ty = idType boot_dfun
 634           local_boot_dfun = Id.mkExportedLocalId (idName boot_dfun) boot_inst_ty
 635
 636
 637 -- This has to compare the TyThing from the .hi-boot file to the TyThing
 638 -- in the current source file.  We must be careful to allow alpha-renaming
 639 -- where appropriate, and also the boot declaration is allowed to omit
 640 -- constructors and class methods.
 641 --
 642 -- See rnfail055 for a good test of this stuff.
 643
 644 checkBootDecl :: TyThing -> TyThing -> Bool
 645
 646 checkBootDecl (AnId id1) (AnId id2)
 647   = ASSERT(id1 == id2)
 648     (idType id1 `tcEqType` idType id2)
 649
 650 checkBootDecl (ATyCon tc1) (ATyCon tc2)
 651   = checkBootTyCon tc1 tc2
 652
 653 checkBootDecl (AClass c1)  (AClass c2)
 654   = let
 655        (clas_tyvars1, clas_fds1, sc_theta1, _, ats1, op_stuff1)
 656           = classExtraBigSig c1
 657        (clas_tyvars2, clas_fds2, sc_theta2, _, ats2, op_stuff2)
 658           = classExtraBigSig c2
 659
 660        env0 = mkRnEnv2 emptyInScopeSet
 661        env = rnBndrs2 env0 clas_tyvars1 clas_tyvars2
 662
 663        eqSig (id1, def_meth1) (id2, def_meth2)
 664          = idName id1 == idName id2 &&
 665            tcEqTypeX env op_ty1 op_ty2 &&
 666            def_meth1 == def_meth2
 667          where
 668           (_, rho_ty1) = splitForAllTys (idType id1)
 669           op_ty1 = funResultTy rho_ty1
 670           (_, rho_ty2) = splitForAllTys (idType id2)
 671           op_ty2 = funResultTy rho_ty2
 672
 673        eqFD (as1,bs1) (as2,bs2) =
 674          eqListBy (tcEqTypeX env) (mkTyVarTys as1) (mkTyVarTys as2) &&
 675          eqListBy (tcEqTypeX env) (mkTyVarTys bs1) (mkTyVarTys bs2)
 676
 677        same_kind tv1 tv2 = eqKind (tyVarKind tv1) (tyVarKind tv2)
 678     in
 679        eqListBy same_kind clas_tyvars1 clas_tyvars2 &&
 680              -- Checks kind of class
 681        eqListBy eqFD clas_fds1 clas_fds2 &&
 682        (null sc_theta1 && null op_stuff1 && null ats1
 683         ||   -- Above tests for an "abstract" class
 684         eqListBy (tcEqPredX env) sc_theta1 sc_theta2 &&
 685         eqListBy eqSig op_stuff1 op_stuff2 &&
 686         eqListBy checkBootTyCon ats1 ats2)
 687
 688 checkBootDecl (ADataCon dc1) (ADataCon _)
 689   = pprPanic "checkBootDecl" (ppr dc1)
 690
 691 checkBootDecl _ _ = False -- probably shouldn't happen
 692
 693 ----------------
 694 checkBootTyCon :: TyCon -> TyCon -> Bool
 695 checkBootTyCon tc1 tc2
 696   | not (eqKind (tyConKind tc1) (tyConKind tc2))
 697   = False       -- First off, check the kind
 698
 699   | isSynTyCon tc1 && isSynTyCon tc2
 700   = ASSERT(tc1 == tc2)
 701     let tvs1 = tyConTyVars tc1; tvs2 = tyConTyVars tc2
 702         env = rnBndrs2 env0 tvs1 tvs2
 703
 704         eqSynRhs (OpenSynTyCon k1 _) (OpenSynTyCon k2 _)
 705             = tcEqTypeX env k1 k2
 706         eqSynRhs (SynonymTyCon t1) (SynonymTyCon t2)
 707             = tcEqTypeX env t1 t2
 708         eqSynRhs _ _ = False
 709     in
 710     equalLength tvs1 tvs2 &&
 711     eqSynRhs (synTyConRhs tc1) (synTyConRhs tc2)
 712
 713   | isAlgTyCon tc1 && isAlgTyCon tc2
 714   = ASSERT(tc1 == tc2)
 715     eqKind (tyConKind tc1) (tyConKind tc2) &&
 716     eqListBy tcEqPred (tyConStupidTheta tc1) (tyConStupidTheta tc2) &&
 717     eqAlgRhs (algTyConRhs tc1) (algTyConRhs tc2)
 718
 719   | isForeignTyCon tc1 && isForeignTyCon tc2
 720   = eqKind (tyConKind tc1) (tyConKind tc2) &&
 721     tyConExtName tc1 == tyConExtName tc2
 722
 723   | otherwise = False
 724   where
 725         env0 = mkRnEnv2 emptyInScopeSet
 726
 727         eqAlgRhs AbstractTyCon _ = True
 728         eqAlgRhs OpenTyCon{} OpenTyCon{} = True
 729         eqAlgRhs tc1@DataTyCon{} tc2@DataTyCon{} =
 730             eqListBy eqCon (data_cons tc1) (data_cons tc2)
 731         eqAlgRhs tc1@NewTyCon{} tc2@NewTyCon{} =
 732             eqCon (data_con tc1) (data_con tc2)
 733         eqAlgRhs _ _ = False
 734
 735         eqCon c1 c2
 736           =  dataConName c1 == dataConName c2
 737           && dataConIsInfix c1 == dataConIsInfix c2
 738           && dataConStrictMarks c1 == dataConStrictMarks c2
 739           && dataConFieldLabels c1 == dataConFieldLabels c2
 740           && let tvs1 = dataConUnivTyVars c1 ++ dataConExTyVars c1
 741                  tvs2 = dataConUnivTyVars c2 ++ dataConExTyVars c2
 742                  env = rnBndrs2 env0 tvs1 tvs2
 743              in
 744               equalLength tvs1 tvs2 &&
 745               eqListBy (tcEqPredX env)
 746                         (dataConEqTheta c1 ++ dataConDictTheta c1)
 747                         (dataConEqTheta c2 ++ dataConDictTheta c2) &&
 748               eqListBy (tcEqTypeX env)
 749                         (dataConOrigArgTys c1)
 750                         (dataConOrigArgTys c2)
 751
 752 ----------------
 753 missingBootThing :: Name -> String -> SDoc
 754 missingBootThing name what
 755   = ppr name <+> ptext (sLit "is exported by the hs-boot file, but not")
 756               <+> text what <+> ptext (sLit "the module")
 757
 758 bootMisMatch :: TyThing -> IfaceDecl -> IfaceDecl -> SDoc
 759 bootMisMatch thing boot_decl real_decl
 760   = vcat [ppr thing <+> ptext (sLit "has conflicting definitions in the module and its hs-boot file"),
 761           ptext (sLit "Main module:") <+> ppr real_decl,
 762           ptext (sLit "Boot file:  ") <+> ppr boot_decl]
 763
 764 instMisMatch :: Instance -> SDoc
 765 instMisMatch inst
 766   = hang (ppr inst)
 767        2 (ptext (sLit "is defined in the hs-boot file, but not in the module itself"))
 768 \end{code}
 769
 770
 771 %************************************************************************
 772 %*                                                                      *
 773         Type-checking the top level of a module
 774 %*                                                                      *
 775 %************************************************************************
 776
 777 tcRnGroup takes a bunch of top-level source-code declarations, and
 778  * renames them
 779  * gets supporting declarations from interface files
 780  * typechecks them
 781  * zonks them
 782  * and augments the TcGblEnv with the results
 783
 784 In Template Haskell it may be called repeatedly for each group of
 785 declarations.  It expects there to be an incoming TcGblEnv in the
 786 monad; it augments it and returns the new TcGblEnv.
 787
 788 \begin{code}
 789 ------------------------------------------------
 790 rnTopSrcDecls :: HsGroup RdrName -> TcM (TcGblEnv, HsGroup Name)
 791 -- Fails if there are any errors
 792 rnTopSrcDecls group
 793  = do { -- Rename the source decls
 794         (tcg_env, rn_decls) <- checkNoErrs $ rnSrcDecls group ;
 795
 796         -- save the renamed syntax, if we want it
 797         let { tcg_env'
 798                 | Just grp <- tcg_rn_decls tcg_env
 799                   = tcg_env{ tcg_rn_decls = Just (appendGroups grp rn_decls) }
 800                 | otherwise
 801                    = tcg_env };
 802
 803                 -- Dump trace of renaming part
 804         rnDump (ppr rn_decls) ;
 805
 806         return (tcg_env', rn_decls)
 807    }
 808
 809 ------------------------------------------------
 810 tcTopSrcDecls :: ModDetails -> HsGroup Name -> TcM (TcGblEnv, TcLclEnv)
 811 tcTopSrcDecls boot_details
 812         (HsGroup { hs_tyclds = tycl_decls,
 813                    hs_instds = inst_decls,
 814                    hs_derivds = deriv_decls,
 815                    hs_fords  = foreign_decls,
 816                    hs_defds  = default_decls,
 817                    hs_annds  = annotation_decls,
 818                    hs_ruleds = rule_decls,
 819                    hs_valds  = val_binds })
 820  = do {         -- Type-check the type and class decls, and all imported decls
 821                 -- The latter come in via tycl_decls
 822         traceTc (text "Tc2") ;
 823
 824         (tcg_env, aux_binds) <- tcTyAndClassDecls boot_details tycl_decls ;
 825                 -- If there are any errors, tcTyAndClassDecls fails here
 826
 827         setGblEnv tcg_env       $ do {
 828                 -- Source-language instances, including derivings,
 829                 -- and import the supporting declarations
 830         traceTc (text "Tc3") ;
 831         (tcg_env, inst_infos, deriv_binds)
 832             <- tcInstDecls1 tycl_decls inst_decls deriv_decls;
 833         setGblEnv tcg_env       $ do {
 834
 835                 -- Foreign import declarations next.
 836         traceTc (text "Tc4") ;
 837         (fi_ids, fi_decls) <- tcForeignImports foreign_decls ;
 838         tcExtendGlobalValEnv fi_ids     $ do {
 839
 840                 -- Default declarations
 841         traceTc (text "Tc4a") ;
 842         default_tys <- tcDefaults default_decls ;
 843         updGblEnv (\gbl -> gbl { tcg_default = default_tys }) $ do {
 844
 845                 -- Now GHC-generated derived bindings, generics, and selectors
 846                 -- Do not generate warnings from compiler-generated code;
 847                 -- hence the use of discardWarnings
 848         (tc_aux_binds,   tcl_env) <- discardWarnings (tcTopBinds aux_binds) ;
 849         (tc_deriv_binds, tcl_env) <- setLclTypeEnv tcl_env $
 850                                      discardWarnings (tcTopBinds deriv_binds) ;
 851
 852                 -- Value declarations next
 853         traceTc (text "Tc5") ;
 854         (tc_val_binds, tcl_env) <- setLclTypeEnv tcl_env $
 855                                    tcTopBinds val_binds;
 856
 857                 -- Second pass over class and instance declarations,
 858         traceTc (text "Tc6") ;
 859         (inst_binds, tcl_env) <- setLclTypeEnv tcl_env $
 860                                  tcInstDecls2 tycl_decls inst_infos ;
 861                                         showLIE (text "after instDecls2") ;
 862
 863         setLclTypeEnv tcl_env $ do {    -- Environment doesn't change now
 864
 865                 -- Foreign exports
 866         traceTc (text "Tc7") ;
 867         (foe_binds, foe_decls) <- tcForeignExports foreign_decls ;
 868
 869                 -- Annotations
 870         annotations <- tcAnnotations annotation_decls ;
 871
 872                 -- Rules
 873         rules <- tcRules rule_decls ;
 874
 875                 -- Wrap up
 876         traceTc (text "Tc7a") ;
 877         tcg_env <- getGblEnv ;
 878         let { all_binds = tc_val_binds   `unionBags`
 879                           tc_deriv_binds `unionBags`
 880                           tc_aux_binds   `unionBags`
 881                           inst_binds     `unionBags`
 882                           foe_binds;
 883
 884                 -- Extend the GblEnv with the (as yet un-zonked)
 885                 -- bindings, rules, foreign decls
 886               tcg_env' = tcg_env {  tcg_binds = tcg_binds tcg_env `unionBags` all_binds,
 887                                     tcg_rules = tcg_rules tcg_env ++ rules,
 888                                     tcg_anns  = tcg_anns tcg_env ++ annotations,
 889                                     tcg_fords = tcg_fords tcg_env ++ foe_decls ++ fi_decls } } ;
 890         return (tcg_env', tcl_env)
 891     }}}}}}
 892 \end{code}
 893
 894
 895 %************************************************************************
 896 %*                                                                      *
 897         Checking for 'main'
 898 %*                                                                      *
 899 %************************************************************************
 900
 901 \begin{code}
 902 checkMain :: TcM TcGblEnv
 903 -- If we are in module Main, check that 'main' is defined.
 904 checkMain
 905   = do { tcg_env   <- getGblEnv ;
 906          dflags    <- getDOpts ;
 907          check_main dflags tcg_env
 908     }
 909
 910 check_main :: DynFlags -> TcGblEnv -> TcM TcGblEnv
 911 check_main dflags tcg_env
 912  | mod /= main_mod
 913  = traceTc (text "checkMain not" <+> ppr main_mod <+> ppr mod) >>
 914    return tcg_env
 915
 916  | otherwise
 917  = do   { mb_main <- lookupGlobalOccRn_maybe main_fn
 918                 -- Check that 'main' is in scope
 919                 -- It might be imported from another module!
 920         ; case mb_main of {
 921              Nothing -> do { traceTc (text "checkMain fail" <+> ppr main_mod <+> ppr main_fn)
 922                            ; complain_no_main
 923                            ; return tcg_env } ;
 924              Just main_name -> do
 925
 926         { traceTc (text "checkMain found" <+> ppr main_mod <+> ppr main_fn)
 927         ; let loc = srcLocSpan (getSrcLoc main_name)
 928         ; ioTyCon <- tcLookupTyCon ioTyConName
 929         ; (main_expr, res_ty)
 930                 <- addErrCtxt mainCtxt    $
 931                    withBox liftedTypeKind $ \res_ty ->
 932                    tcMonoExpr (L loc (HsVar main_name)) (mkTyConApp ioTyCon [res_ty])
 933
 934                 -- See Note [Root-main Id]
 935                 -- Construct the binding
 936                 --      :Main.main :: IO res_ty = runMainIO res_ty main
 937         ; run_main_id <- tcLookupId runMainIOName
 938         ; let { root_main_name =  mkExternalName rootMainKey rOOT_MAIN
 939                                    (mkVarOccFS (fsLit "main"))
 940                                    (getSrcSpan main_name)
 941               ; root_main_id = Id.mkExportedLocalId root_main_name
 942                                                     (mkTyConApp ioTyCon [res_ty])
 943               ; co  = mkWpTyApps [res_ty]
 944               ; rhs = nlHsApp (mkLHsWrap co (nlHsVar run_main_id)) main_expr
 945               ; main_bind = mkVarBind root_main_id rhs }
 946
 947         ; return (tcg_env { tcg_main  = Just main_name,
 948                             tcg_binds = tcg_binds tcg_env
 949                                         `snocBag` main_bind,
 950                             tcg_dus   = tcg_dus tcg_env
 951                                         `plusDU` usesOnly (unitFV main_name)
 952                         -- Record the use of 'main', so that we don't
 953                         -- complain about it being defined but not used
 954                  })
 955     }}}
 956   where
 957     mod          = tcg_mod tcg_env
 958     main_mod     = mainModIs dflags
 959     main_fn      = getMainFun dflags
 960
 961     complain_no_main | ghcLink dflags == LinkInMemory = return ()
 962                      | otherwise = failWithTc noMainMsg
 963         -- In interactive mode, don't worry about the absence of 'main'
 964         -- In other modes, fail altogether, so that we don't go on
 965         -- and complain a second time when processing the export list.
 966
 967     mainCtxt  = ptext (sLit "When checking the type of the") <+> pp_main_fn
 968     noMainMsg = ptext (sLit "The") <+> pp_main_fn
 969                 <+> ptext (sLit "is not defined in module") <+> quotes (ppr main_mod)
 970     pp_main_fn = ppMainFn main_fn
 971
 972 ppMainFn :: RdrName -> SDoc
 973 ppMainFn main_fn
 974   | main_fn == main_RDR_Unqual
 975   = ptext (sLit "function") <+> quotes (ppr main_fn)
 976   | otherwise
 977   = ptext (sLit "main function") <+> quotes (ppr main_fn)
 978
 979 -- | Get the unqualified name of the function to use as the \"main\" for the main module.
 980 -- Either returns the default name or the one configured on the command line with -main-is
 981 getMainFun :: DynFlags -> RdrName
 982 getMainFun dflags = case (mainFunIs dflags) of
 983     Just fn -> mkRdrUnqual (mkVarOccFS (mkFastString fn))
 984     Nothing -> main_RDR_Unqual
 985
 986 checkMainExported :: TcGblEnv -> TcM ()
 987 checkMainExported tcg_env = do
 988   dflags    <- getDOpts
 989   case tcg_main tcg_env of
 990     Nothing -> return () -- not the main module
 991     Just main_name -> do
 992       let main_mod = mainModIs dflags
 993       checkTc (main_name `elem` concatMap availNames (tcg_exports tcg_env)) $
 994               ptext (sLit "The") <+> ppMainFn (nameRdrName main_name) <+>
 995               ptext (sLit "is not exported by module") <+> quotes (ppr main_mod)
 996 \end{code}
 997
 998 Note [Root-main Id]
 999 ~~~~~~~~~~~~~~~~~~~
1000 The function that the RTS invokes is always :Main.main, which we call
1001 root_main_id.  (Because GHC allows the user to have a module not
1002 called Main as the main module, we can't rely on the main function
1003 being called "Main.main".  That's why root_main_id has a fixed module
1004 ":Main".)
1005
1006 This is unusual: it's a LocalId whose Name has a Module from another
1007 module.  Tiresomely, we must filter it out again in MkIface, les we
1008 get two defns for 'main' in the interface file!
1009
1010
1011 %*********************************************************
1012 %*                                                       *
1013                 GHCi stuff
1014 %*                                                       *
1015 %*********************************************************
1016
1017 \begin{code}
1018 #ifdef GHCI
1019 setInteractiveContext :: HscEnv -> InteractiveContext -> TcRn a -> TcRn a
1020 setInteractiveContext hsc_env icxt thing_inside
1021   = let -- Initialise the tcg_inst_env with instances from all home modules.
1022         -- This mimics the more selective call to hptInstances in tcRnModule.
1023         (home_insts, home_fam_insts) = hptInstances hsc_env (\_ -> True)
1024     in
1025     updGblEnv (\env -> env {
1026         tcg_rdr_env      = ic_rn_gbl_env icxt,
1027         tcg_inst_env     = extendInstEnvList    (tcg_inst_env env) home_insts,
1028         tcg_fam_inst_env = extendFamInstEnvList (tcg_fam_inst_env env)
1029                                                 home_fam_insts
1030       }) $
1031
1032     tcExtendGhciEnv (ic_tmp_ids icxt) $
1033         -- tcExtendGhciEnv does lots:
1034         --   - it extends the local type env (tcl_env) with the given Ids,
1035         --   - it extends the local rdr env (tcl_rdr) with the Names from
1036         --     the given Ids
1037         --   - it adds the free tyvars of the Ids to the tcl_tyvars
1038         --     set.
1039         --
1040         -- later ids in ic_tmp_ids must shadow earlier ones with the same
1041         -- OccName, and tcExtendIdEnv implements this behaviour.
1042
1043     do  { traceTc (text "setIC" <+> ppr (ic_tmp_ids icxt))
1044         ; thing_inside }
1045 \end{code}
1046
1047
1048 \begin{code}
1049 tcRnStmt :: HscEnv
1050          -> InteractiveContext
1051          -> LStmt RdrName
1052          -> IO (Messages, Maybe ([Id], LHsExpr Id))
1053                 -- The returned [Id] is the list of new Ids bound by
1054                 -- this statement.  It can be used to extend the
1055                 -- InteractiveContext via extendInteractiveContext.
1056                 --
1057                 -- The returned TypecheckedHsExpr is of type IO [ () ],
1058                 -- a list of the bound values, coerced to ().
1059
1060 tcRnStmt hsc_env ictxt rdr_stmt
1061   = initTcPrintErrors hsc_env iNTERACTIVE $
1062     setInteractiveContext hsc_env ictxt $ do {
1063
1064     -- Rename; use CmdLineMode because tcRnStmt is only used interactively
1065     (([rn_stmt], _), fvs) <- rnStmts GhciStmt [rdr_stmt] (return ((), emptyFVs)) ;
1066     traceRn (text "tcRnStmt" <+> vcat [ppr rdr_stmt, ppr rn_stmt, ppr fvs]) ;
1067     failIfErrsM ;
1068     rnDump (ppr rn_stmt) ;
1069
1070     -- The real work is done here
1071     (bound_ids, tc_expr) <- mkPlan rn_stmt ;
1072     zonked_expr <- zonkTopLExpr tc_expr ;
1073     zonked_ids  <- zonkTopBndrs bound_ids ;
1074
1075         -- None of the Ids should be of unboxed type, because we
1076         -- cast them all to HValues in the end!
1077     mapM_ bad_unboxed (filter (isUnLiftedType . idType) zonked_ids) ;
1078
1079     traceTc (text "tcs 1") ;
1080     let { global_ids = map globaliseAndTidyId zonked_ids } ;
1081         -- Note [Interactively-bound Ids in GHCi]
1082
1083 {- ---------------------------------------------
1084    At one stage I removed any shadowed bindings from the type_env;
1085    they are inaccessible but might, I suppose, cause a space leak if we leave them there.
1086    However, with Template Haskell they aren't necessarily inaccessible.  Consider this
1087    GHCi session
1088          Prelude> let f n = n * 2 :: Int
1089          Prelude> fName <- runQ [| f |]
1090          Prelude> $(return $ AppE fName (LitE (IntegerL 7)))
1091          14
1092          Prelude> let f n = n * 3 :: Int
1093          Prelude> $(return $ AppE fName (LitE (IntegerL 7)))
1094    In the last line we use 'fName', which resolves to the *first* 'f'
1095    in scope. If we delete it from the type env, GHCi crashes because
1096    it doesn't expect that.
1097
1098    Hence this code is commented out
1099
1100 -------------------------------------------------- -}
1101
1102     dumpOptTcRn Opt_D_dump_tc
1103         (vcat [text "Bound Ids" <+> pprWithCommas ppr global_ids,
1104                text "Typechecked expr" <+> ppr zonked_expr]) ;
1105
1106     return (global_ids, zonked_expr)
1107     }
1108   where
1109     bad_unboxed id = addErr (sep [ptext (sLit "GHCi can't bind a variable of unlifted type:"),
1110                                   nest 2 (ppr id <+> dcolon <+> ppr (idType id))])
1111 \end{code}
1112
1113 Note [Interactively-bound Ids in GHCi]
1114 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1115 The Ids bound by previous Stmts in Template Haskell are currently
1116         a) GlobalIds
1117         b) with an Internal Name (not External)
1118         c) and a tidied type
1119
1120  (a) They must be GlobalIds (not LocalIds) otherwise when we come to
1121      compile an expression using these ids later, the byte code
1122      generator will consider the occurrences to be free rather than
1123      global.
1124
1125  (b) They retain their Internal names becuase we don't have a suitable
1126      Module to name them with.  We could revisit this choice.
1127
1128  (c) Their types are tidied.  This is important, because :info may ask
1129      to look at them, and :info expects the things it looks up to have
1130      tidy types
1131
1132
1133 --------------------------------------------------------------------------
1134                 Typechecking Stmts in GHCi
1135
1136 Here is the grand plan, implemented in tcUserStmt
1137
1138         What you type                   The IO [HValue] that hscStmt returns
1139         -------------                   ------------------------------------
1140         let pat = expr          ==>     let pat = expr in return [coerce HVal x, coerce HVal y, ...]
1141                                         bindings: [x,y,...]
1142
1143         pat <- expr             ==>     expr >>= \ pat -> return [coerce HVal x, coerce HVal y, ...]
1144                                         bindings: [x,y,...]
1145
1146         expr (of IO type)       ==>     expr >>= \ it -> return [coerce HVal it]
1147           [NB: result not printed]      bindings: [it]
1148
1149         expr (of non-IO type,   ==>     let it = expr in print it >> return [coerce HVal it]
1150           result showable)              bindings: [it]
1151
1152         expr (of non-IO type,
1153           result not showable)  ==>     error
1154
1155
1156 \begin{code}
1157 ---------------------------
1158 type PlanResult = ([Id], LHsExpr Id)
1159 type Plan = TcM PlanResult
1160
1161 runPlans :: [Plan] -> TcM PlanResult
1162 -- Try the plans in order.  If one fails (by raising an exn), try the next.
1163 -- If one succeeds, take it.
1164 runPlans []     = panic "runPlans"
1165 runPlans [p]    = p
1166 runPlans (p:ps) = tryTcLIE_ (runPlans ps) p
1167
1168 --------------------
1169 mkPlan :: LStmt Name -> TcM PlanResult
1170 mkPlan (L loc (ExprStmt expr _ _))      -- An expression typed at the prompt
1171   = do  { uniq <- newUnique             -- is treated very specially
1172         ; let fresh_it  = itName uniq
1173               the_bind  = L loc $ mkFunBind (L loc fresh_it) matches
1174               matches   = [mkMatch [] expr emptyLocalBinds]
1175               let_stmt  = L loc $ LetStmt (HsValBinds (ValBindsOut [(NonRecursive,unitBag the_bind)] []))
1176               bind_stmt = L loc $ BindStmt (nlVarPat fresh_it) expr
1177                                            (HsVar bindIOName) noSyntaxExpr
1178               print_it  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar fresh_it))
1179                                            (HsVar thenIOName) placeHolderType
1180
1181         -- The plans are:
1182         --      [it <- e; print it]     but not if it::()
1183         --      [it <- e]
1184         --      [let it = e; print it]
1185         ; runPlans [    -- Plan A
1186                     do { stuff@([it_id], _) <- tcGhciStmts [bind_stmt, print_it]
1187                        ; it_ty <- zonkTcType (idType it_id)
1188                        ; when (isUnitTy it_ty) failM
1189                        ; return stuff },
1190
1191                         -- Plan B; a naked bind statment
1192                     tcGhciStmts [bind_stmt],
1193
1194                         -- Plan C; check that the let-binding is typeable all by itself.
1195                         -- If not, fail; if so, try to print it.
1196                         -- The two-step process avoids getting two errors: one from
1197                         -- the expression itself, and one from the 'print it' part
1198                         -- This two-step story is very clunky, alas
1199                     do { _ <- checkNoErrs (tcGhciStmts [let_stmt])
1200                                 --- checkNoErrs defeats the error recovery of let-bindings
1201                        ; tcGhciStmts [let_stmt, print_it] }
1202           ]}
1203
1204 mkPlan stmt@(L loc (BindStmt {}))
1205   | [v] <- collectLStmtBinders stmt             -- One binder, for a bind stmt
1206   = do  { let print_v  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar v))
1207                                            (HsVar thenIOName) placeHolderType
1208
1209         ; print_bind_result <- doptM Opt_PrintBindResult
1210         ; let print_plan = do
1211                   { stuff@([v_id], _) <- tcGhciStmts [stmt, print_v]
1212                   ; v_ty <- zonkTcType (idType v_id)
1213                   ; when (isUnitTy v_ty || not (isTauTy v_ty)) failM
1214                   ; return stuff }
1215
1216         -- The plans are:
1217         --      [stmt; print v]         but not if v::()
1218         --      [stmt]
1219         ; runPlans ((if print_bind_result then [print_plan] else []) ++
1220                     [tcGhciStmts [stmt]])
1221         }
1222
1223 mkPlan stmt
1224   = tcGhciStmts [stmt]
1225
1226 ---------------------------
1227 tcGhciStmts :: [LStmt Name] -> TcM PlanResult
1228 tcGhciStmts stmts
1229  = do { ioTyCon <- tcLookupTyCon ioTyConName ;
1230         ret_id  <- tcLookupId returnIOName ;            -- return @ IO
1231         let {
1232             ret_ty    = mkListTy unitTy ;
1233             io_ret_ty = mkTyConApp ioTyCon [ret_ty] ;
1234             tc_io_stmts stmts = tcStmts GhciStmt tcDoStmt stmts io_ret_ty ;
1235
1236             names = collectLStmtsBinders stmts ;
1237
1238                 -- mk_return builds the expression
1239                 --      returnIO @ [()] [coerce () x, ..,  coerce () z]
1240                 --
1241                 -- Despite the inconvenience of building the type applications etc,
1242                 -- this *has* to be done in type-annotated post-typecheck form
1243                 -- because we are going to return a list of *polymorphic* values
1244                 -- coerced to type (). If we built a *source* stmt
1245                 --      return [coerce x, ..., coerce z]
1246                 -- then the type checker would instantiate x..z, and we wouldn't
1247                 -- get their *polymorphic* values.  (And we'd get ambiguity errs
1248                 -- if they were overloaded, since they aren't applied to anything.)
1249             mk_return ids = nlHsApp (nlHsTyApp ret_id [ret_ty])
1250                                     (noLoc $ ExplicitList unitTy (map mk_item ids)) ;
1251             mk_item id = nlHsApp (nlHsTyApp unsafeCoerceId [idType id, unitTy])
1252                                  (nlHsVar id)
1253          } ;
1254
1255         -- OK, we're ready to typecheck the stmts
1256         traceTc (text "TcRnDriver.tcGhciStmts: tc stmts") ;
1257         ((tc_stmts, ids), lie) <- getLIE $ tc_io_stmts stmts $ \ _ ->
1258                                            mapM tcLookupId names ;
1259                                         -- Look up the names right in the middle,
1260                                         -- where they will all be in scope
1261
1262         -- Simplify the context
1263         traceTc (text "TcRnDriver.tcGhciStmts: simplify ctxt") ;
1264         const_binds <- checkNoErrs (tcSimplifyInteractive lie) ;
1265                 -- checkNoErrs ensures that the plan fails if context redn fails
1266
1267         traceTc (text "TcRnDriver.tcGhciStmts: done") ;
1268         return (ids, mkHsDictLet const_binds $
1269                      noLoc (HsDo GhciStmt tc_stmts (mk_return ids) io_ret_ty))
1270     }
1271 \end{code}
1272
1273
1274 tcRnExpr just finds the type of an expression
1275
1276 \begin{code}
1277 tcRnExpr :: HscEnv
1278          -> InteractiveContext
1279          -> LHsExpr RdrName
1280          -> IO (Messages, Maybe Type)
1281 tcRnExpr hsc_env ictxt rdr_expr
1282   = initTcPrintErrors hsc_env iNTERACTIVE $
1283     setInteractiveContext hsc_env ictxt $ do {
1284
1285     (rn_expr, _fvs) <- rnLExpr rdr_expr ;
1286     failIfErrsM ;
1287
1288         -- Now typecheck the expression;
1289         -- it might have a rank-2 type (e.g. :t runST)
1290     ((_tc_expr, res_ty), lie)        <- getLIE (tcInferRho rn_expr) ;
1291     ((qtvs, dict_insts, _), lie_top) <- getLIE (tcSimplifyInfer smpl_doc (tyVarsOfType res_ty) lie)  ;
1292     _ <- tcSimplifyInteractive lie_top ;       -- Ignore the dicionary bindings
1293
1294     let { all_expr_ty = mkForAllTys qtvs $
1295                         mkFunTys (map (idType . instToId) dict_insts)   $
1296                         res_ty } ;
1297     zonkTcType all_expr_ty
1298     }
1299   where
1300     smpl_doc = ptext (sLit "main expression")
1301 \end{code}
1302
1303 tcRnType just finds the kind of a type
1304
1305 \begin{code}
1306 tcRnType :: HscEnv
1307          -> InteractiveContext
1308          -> LHsType RdrName
1309          -> IO (Messages, Maybe Kind)
1310 tcRnType hsc_env ictxt rdr_type
1311   = initTcPrintErrors hsc_env iNTERACTIVE $
1312     setInteractiveContext hsc_env ictxt $ do {
1313
1314     rn_type <- rnLHsType doc rdr_type ;
1315     failIfErrsM ;
1316
1317         -- Now kind-check the type
1318     (_ty', kind) <- kcLHsType rn_type ;
1319     return kind
1320     }
1321   where
1322     doc = ptext (sLit "In GHCi input")
1323
1324 #endif /* GHCi */
1325 \end{code}
1326
1327
1328 %************************************************************************
1329 %*                                                                      *
1330         More GHCi stuff, to do with browsing and getting info
1331 %*                                                                      *
1332 %************************************************************************
1333
1334 \begin{code}
1335 #ifdef GHCI
1336 -- | ASSUMES that the module is either in the 'HomePackageTable' or is
1337 -- a package module with an interface on disk.  If neither of these is
1338 -- true, then the result will be an error indicating the interface
1339 -- could not be found.
1340 getModuleExports :: HscEnv -> Module -> IO (Messages, Maybe [AvailInfo])
1341 getModuleExports hsc_env mod
1342   = let
1343       ic        = hsc_IC hsc_env
1344       checkMods = ic_toplev_scope ic ++ map fst (ic_exports ic)
1345     in
1346     initTc hsc_env HsSrcFile False iNTERACTIVE (tcGetModuleExports mod checkMods)
1347
1348 -- Get the export avail info and also load all orphan and family-instance
1349 -- modules.  Finally, check that the family instances of all modules in the
1350 -- interactive context are consistent (these modules are in the second
1351 -- argument).
1352 tcGetModuleExports :: Module -> [Module] -> TcM [AvailInfo]
1353 tcGetModuleExports mod directlyImpMods
1354   = do { let doc = ptext (sLit "context for compiling statements")
1355        ; iface <- initIfaceTcRn $ loadSysInterface doc mod
1356
1357                 -- Load any orphan-module and family instance-module
1358                 -- interfaces, so their instances are visible.
1359        ; loadOrphanModules (dep_orphs (mi_deps iface)) False
1360        ; loadOrphanModules (dep_finsts (mi_deps iface)) True
1361
1362                 -- Check that the family instances of all directly loaded
1363                 -- modules are consistent.
1364        ; checkFamInstConsistency (dep_finsts (mi_deps iface)) directlyImpMods
1365
1366        ; ifaceExportNames (mi_exports iface)
1367        }
1368
1369 tcRnLookupRdrName :: HscEnv -> RdrName -> IO (Messages, Maybe [Name])
1370 tcRnLookupRdrName hsc_env rdr_name
1371   = initTcPrintErrors hsc_env iNTERACTIVE $
1372     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1373     lookup_rdr_name rdr_name
1374
1375 lookup_rdr_name :: RdrName -> TcM [Name]
1376 lookup_rdr_name rdr_name = do {
1377         -- If the identifier is a constructor (begins with an
1378         -- upper-case letter), then we need to consider both
1379         -- constructor and type class identifiers.
1380     let { rdr_names = dataTcOccs rdr_name } ;
1381
1382         -- results :: [Either Messages Name]
1383     results <- mapM (tryTcErrs . lookupOccRn) rdr_names ;
1384
1385     traceRn (text "xx" <+> vcat [ppr rdr_names, ppr (map snd results)]);
1386         -- The successful lookups will be (Just name)
1387     let { (warns_s, good_names) = unzip [ (msgs, name)
1388                                         | (msgs, Just name) <- results] ;
1389           errs_s = [msgs | (msgs, Nothing) <- results] } ;
1390
1391         -- Fail if nothing good happened, else add warnings
1392     if null good_names then
1393                 -- No lookup succeeded, so
1394                 -- pick the first error message and report it
1395                 -- ToDo: If one of the errors is "could be Foo.X or Baz.X",
1396                 --       while the other is "X is not in scope",
1397                 --       we definitely want the former; but we might pick the latter
1398         do { addMessages (head errs_s) ; failM }
1399       else                      -- Add deprecation warnings
1400         mapM_ addMessages warns_s ;
1401
1402     return good_names
1403  }
1404
1405 tcRnLookupName :: HscEnv -> Name -> IO (Messages, Maybe TyThing)
1406 tcRnLookupName hsc_env name
1407   = initTcPrintErrors hsc_env iNTERACTIVE $
1408     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1409     tcRnLookupName' name
1410
1411 -- To look up a name we have to look in the local environment (tcl_lcl)
1412 -- as well as the global environment, which is what tcLookup does.
1413 -- But we also want a TyThing, so we have to convert:
1414
1415 tcRnLookupName' :: Name -> TcRn TyThing
1416 tcRnLookupName' name = do
1417    tcthing <- tcLookup name
1418    case tcthing of
1419      AGlobal thing    -> return thing
1420      ATcId{tct_id=id} -> return (AnId id)
1421      _ -> panic "tcRnLookupName'"
1422
1423 tcRnGetInfo :: HscEnv
1424             -> Name
1425             -> IO (Messages, Maybe (TyThing, Fixity, [Instance]))
1426
1427 -- Used to implement :info in GHCi
1428 --
1429 -- Look up a RdrName and return all the TyThings it might be
1430 -- A capitalised RdrName is given to us in the DataName namespace,
1431 -- but we want to treat it as *both* a data constructor
1432 --  *and* as a type or class constructor;
1433 -- hence the call to dataTcOccs, and we return up to two results
1434 tcRnGetInfo hsc_env name
1435   = initTcPrintErrors hsc_env iNTERACTIVE $
1436     let ictxt = hsc_IC hsc_env in
1437     setInteractiveContext hsc_env ictxt $ do
1438
1439         -- Load the interface for all unqualified types and classes
1440         -- That way we will find all the instance declarations
1441         -- (Packages have not orphan modules, and we assume that
1442         --  in the home package all relevant modules are loaded.)
1443     loadUnqualIfaces ictxt
1444
1445     thing  <- tcRnLookupName' name
1446     fixity <- lookupFixityRn name
1447     ispecs <- lookupInsts thing
1448     return (thing, fixity, ispecs)
1449
1450 lookupInsts :: TyThing -> TcM [Instance]
1451 lookupInsts (AClass cls)
1452   = do  { inst_envs <- tcGetInstEnvs
1453         ; return (classInstances inst_envs cls) }
1454
1455 lookupInsts (ATyCon tc)
1456   = do  { (pkg_ie, home_ie) <- tcGetInstEnvs
1457                 -- Load all instances for all classes that are
1458                 -- in the type environment (which are all the ones
1459                 -- we've seen in any interface file so far)
1460         ; return [ ispec        -- Search all
1461                  | ispec <- instEnvElts home_ie ++ instEnvElts pkg_ie
1462                  , let dfun = instanceDFunId ispec
1463                  , relevant dfun ] }
1464   where
1465     relevant df = tc_name `elemNameSet` tyClsNamesOfDFunHead (idType df)
1466     tc_name     = tyConName tc
1467
1468 lookupInsts _ = return []
1469
1470 loadUnqualIfaces :: InteractiveContext -> TcM ()
1471 -- Load the home module for everything that is in scope unqualified
1472 -- This is so that we can accurately report the instances for
1473 -- something
1474 loadUnqualIfaces ictxt
1475   = initIfaceTcRn $
1476     mapM_ (loadSysInterface doc) (moduleSetElts (mkModuleSet unqual_mods))
1477   where
1478     unqual_mods = [ nameModule name
1479                   | gre <- globalRdrEnvElts (ic_rn_gbl_env ictxt),
1480                     let name = gre_name gre,
1481                     not (isInternalName name),
1482                     isTcOcc (nameOccName name),  -- Types and classes only
1483                     unQualOK gre ]               -- In scope unqualified
1484     doc = ptext (sLit "Need interface for module whose export(s) are in scope unqualified")
1485 #endif /* GHCI */
1486 \end{code}
1487
1488 %************************************************************************
1489 %*                                                                      *
1490                 Degugging output
1491 %*                                                                      *
1492 %************************************************************************
1493
1494 \begin{code}
1495 rnDump :: SDoc -> TcRn ()
1496 -- Dump, with a banner, if -ddump-rn
1497 rnDump doc = do { dumpOptTcRn Opt_D_dump_rn (mkDumpDoc "Renamer" doc) }
1498
1499 tcDump :: TcGblEnv -> TcRn ()
1500 tcDump env
1501  = do { dflags <- getDOpts ;
1502
1503         -- Dump short output if -ddump-types or -ddump-tc
1504         when (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1505              (dumpTcRn short_dump) ;
1506
1507         -- Dump bindings if -ddump-tc
1508         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump)
1509    }
1510   where
1511     short_dump = pprTcGblEnv env
1512     full_dump  = pprLHsBinds (tcg_binds env)
1513         -- NB: foreign x-d's have undefined's in their types;
1514         --     hence can't show the tc_fords
1515
1516 tcCoreDump :: ModGuts -> TcM ()
1517 tcCoreDump mod_guts
1518  = do { dflags <- getDOpts ;
1519         when (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1520              (dumpTcRn (pprModGuts mod_guts)) ;
1521
1522         -- Dump bindings if -ddump-tc
1523         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump) }
1524   where
1525     full_dump = pprCoreBindings (mg_binds mod_guts)
1526
1527 -- It's unpleasant having both pprModGuts and pprModDetails here
1528 pprTcGblEnv :: TcGblEnv -> SDoc
1529 pprTcGblEnv (TcGblEnv { tcg_type_env  = type_env,
1530                         tcg_insts     = insts,
1531                         tcg_fam_insts = fam_insts,
1532                         tcg_rules     = rules,
1533                         tcg_imports   = imports })
1534   = vcat [ ppr_types insts type_env
1535          , ppr_tycons fam_insts type_env
1536          , ppr_insts insts
1537          , ppr_fam_insts fam_insts
1538          , vcat (map ppr rules)
1539          , ppr_gen_tycons (typeEnvTyCons type_env)
1540          , ptext (sLit "Dependent modules:") <+>
1541                 ppr (sortBy cmp_mp $ eltsUFM (imp_dep_mods imports))
1542          , ptext (sLit "Dependent packages:") <+>
1543                 ppr (sortBy stablePackageIdCmp $ imp_dep_pkgs imports)]
1544   where         -- The two uses of sortBy are just to reduce unnecessary
1545                 -- wobbling in testsuite output
1546     cmp_mp (mod_name1, is_boot1) (mod_name2, is_boot2)
1547         = (mod_name1 `stableModuleNameCmp` mod_name2)
1548                   `thenCmp`
1549           (is_boot1 `compare` is_boot2)
1550
1551 pprModGuts :: ModGuts -> SDoc
1552 pprModGuts (ModGuts { mg_types = type_env,
1553                       mg_rules = rules })
1554   = vcat [ ppr_types [] type_env,
1555            ppr_rules rules ]
1556
1557 ppr_types :: [Instance] -> TypeEnv -> SDoc
1558 ppr_types insts type_env
1559   = text "TYPE SIGNATURES" $$ nest 4 (ppr_sigs ids)
1560   where
1561     dfun_ids = map instanceDFunId insts
1562     ids = [id | id <- typeEnvIds type_env, want_sig id]
1563     want_sig id | opt_PprStyle_Debug = True
1564                 | otherwise          = isLocalId id &&
1565                                        isExternalName (idName id) &&
1566                                        not (id `elem` dfun_ids)
1567         -- isLocalId ignores data constructors, records selectors etc.
1568         -- The isExternalName ignores local dictionary and method bindings
1569         -- that the type checker has invented.  Top-level user-defined things
1570         -- have External names.
1571
1572 ppr_tycons :: [FamInst] -> TypeEnv -> SDoc
1573 ppr_tycons fam_insts type_env
1574   = text "TYPE CONSTRUCTORS" $$ nest 4 (ppr_tydecls tycons)
1575   where
1576     fi_tycons = map famInstTyCon fam_insts
1577     tycons = [tycon | tycon <- typeEnvTyCons type_env, want_tycon tycon]
1578     want_tycon tycon | opt_PprStyle_Debug = True
1579                      | otherwise          = not (isImplicitTyCon tycon) &&
1580                                             isExternalName (tyConName tycon) &&
1581                                             not (tycon `elem` fi_tycons)
1582
1583 ppr_insts :: [Instance] -> SDoc
1584 ppr_insts []     = empty
1585 ppr_insts ispecs = text "INSTANCES" $$ nest 2 (pprInstances ispecs)
1586
1587 ppr_fam_insts :: [FamInst] -> SDoc
1588 ppr_fam_insts []        = empty
1589 ppr_fam_insts fam_insts =
1590   text "FAMILY INSTANCES" $$ nest 2 (pprFamInsts fam_insts)
1591
1592 ppr_sigs :: [Var] -> SDoc
1593 ppr_sigs ids
1594         -- Print type signatures; sort by OccName
1595   = vcat (map ppr_sig (sortLe le_sig ids))
1596   where
1597     le_sig id1 id2 = getOccName id1 <= getOccName id2
1598     ppr_sig id = ppr id <+> dcolon <+> ppr (tidyTopType (idType id))
1599
1600 ppr_tydecls :: [TyCon] -> SDoc
1601 ppr_tydecls tycons
1602         -- Print type constructor info; sort by OccName
1603   = vcat (map ppr_tycon (sortLe le_sig tycons))
1604   where
1605     le_sig tycon1 tycon2 = getOccName tycon1 <= getOccName tycon2
1606     ppr_tycon tycon
1607       | isCoercionTyCon tycon
1608       = sep [ptext (sLit "coercion") <+> ppr tycon <+> ppr tvs
1609             , nest 2 (dcolon <+> pprEqPred (coercionKind (mkTyConApp tycon (mkTyVarTys tvs))))]
1610       | otherwise             = ppr (tyThingToIfaceDecl (ATyCon tycon))
1611       where
1612         tvs = take (tyConArity tycon) alphaTyVars
1613
1614 ppr_rules :: [CoreRule] -> SDoc
1615 ppr_rules [] = empty
1616 ppr_rules rs = vcat [ptext (sLit "{-# RULES"),
1617                       nest 4 (pprRules rs),
1618                       ptext (sLit "#-}")]
1619
1620 ppr_gen_tycons :: [TyCon] -> SDoc
1621 ppr_gen_tycons []  = empty
1622 ppr_gen_tycons tcs = vcat [ptext (sLit "Tycons with generics:"),
1623                            nest 2 (fsep (map ppr (filter tyConHasGenerics tcs)))]
1624 \end{code}