compiler/typecheck/TcRnTypes.lhs

   1
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP Project, Glasgow University, 1992-2002
   4 %
   5 \begin{code}
   6 module TcRnTypes(
   7         TcRnIf, TcRn, TcM, RnM, IfM, IfL, IfG, -- The monad is opaque outside this module
   8         TcRef,
   9
  10         -- The environment types
  11         Env(..),
  12         TcGblEnv(..), TcLclEnv(..),
  13         IfGblEnv(..), IfLclEnv(..),
  14
  15         -- Ranamer types
  16         ErrCtxt, RecFieldEnv(..),
  17         ImportAvails(..), emptyImportAvails, plusImportAvails,
  18         WhereFrom(..), mkModDeps,
  19
  20         -- Typechecker types
  21         TcTyThing(..), pprTcTyThingCategory, RefinementVisibility(..),
  22
  23         -- Template Haskell
  24         ThStage(..), topStage, topAnnStage, topSpliceStage,
  25         ThLevel, impLevel, outerLevel, thLevel,
  26
  27         -- Arrows
  28         ArrowCtxt(NoArrowCtxt), newArrowScope, escapeArrowScope,
  29
  30         -- Insts
  31         Inst(..), EqInstCo, InstOrigin(..), InstLoc(..),
  32         pprInstLoc, pprInstArising, instLocSpan, instLocOrigin, setInstLoc,
  33         LIE, emptyLIE, unitLIE, plusLIE, consLIE, instLoc, instSpan,
  34         plusLIEs, mkLIE, isEmptyLIE, lieToList, listToLIE,
  35
  36         -- Misc other types
  37         TcId, TcIdSet, TcDictBinds, TcTyVarBind(..), TcTyVarBinds
  38
  39   ) where
  40
  41 #include "HsVersions.h"
  42
  43 import HsSyn hiding (LIE)
  44 import HscTypes
  45 import Type
  46 import Coercion
  47 import TcType
  48 import Annotations
  49 import InstEnv
  50 import FamInstEnv
  51 import IOEnv
  52 import RdrName
  53 import Name
  54 import NameEnv
  55 import NameSet
  56 import Var
  57 import VarEnv
  58 import Module
  59 import LazyUniqFM
  60 import SrcLoc
  61 import VarSet
  62 import ErrUtils
  63 import UniqSupply
  64 import BasicTypes
  65 import Util
  66 import Bag
  67 import Outputable
  68 import ListSetOps
  69 import FastString
  70
  71 import Data.Set (Set)
  72 \end{code}
  73
  74
  75 %************************************************************************
  76 %*                                                                      *
  77                Standard monad definition for TcRn
  78     All the combinators for the monad can be found in TcRnMonad
  79 %*                                                                      *
  80 %************************************************************************
  81
  82 The monad itself has to be defined here, because it is mentioned by ErrCtxt
  83
  84 \begin{code}
  85 type TcRef a     = IORef a
  86 type TcId        = Id                   -- Type may be a TcType
  87 type TcIdSet     = IdSet
  88 type TcDictBinds = DictBinds TcId       -- Bag of dictionary bindings
  89
  90 type TcRnIf a b c = IOEnv (Env a b) c
  91 type IfM lcl a  = TcRnIf IfGblEnv lcl a         -- Iface stuff
  92
  93 type IfG a  = IfM () a                          -- Top level
  94 type IfL a  = IfM IfLclEnv a                    -- Nested
  95 type TcRn a = TcRnIf TcGblEnv TcLclEnv a
  96 type RnM  a = TcRn a            -- Historical
  97 type TcM  a = TcRn a            -- Historical
  98 \end{code}
  99
 100 Representation of type bindings to uninstantiated meta variables used during
 101 constraint solving.
 102
 103 \begin{code}
 104 data TcTyVarBind = TcTyVarBind TcTyVar TcType
 105
 106 type TcTyVarBinds = Bag TcTyVarBind
 107
 108 instance Outputable TcTyVarBind where
 109   ppr (TcTyVarBind tv ty) = ppr tv <+> text ":=" <+> ppr ty
 110 \end{code}
 111
 112
 113 %************************************************************************
 114 %*                                                                      *
 115                 The main environment types
 116 %*                                                                      *
 117 %************************************************************************
 118
 119 \begin{code}
 120 data Env gbl lcl        -- Changes as we move into an expression
 121   = Env {
 122         env_top  :: HscEnv,     -- Top-level stuff that never changes
 123                                 -- Includes all info about imported things
 124
 125         env_us   :: {-# UNPACK #-} !(IORef UniqSupply),
 126                                 -- Unique supply for local varibles
 127
 128         env_gbl  :: gbl,        -- Info about things defined at the top level
 129                                 -- of the module being compiled
 130
 131         env_lcl  :: lcl         -- Nested stuff; changes as we go into
 132     }
 133
 134 -- TcGblEnv describes the top-level of the module at the
 135 -- point at which the typechecker is finished work.
 136 -- It is this structure that is handed on to the desugarer
 137
 138 data TcGblEnv
 139   = TcGblEnv {
 140         tcg_mod     :: Module,         -- ^ Module being compiled
 141         tcg_src     :: HscSource,
 142           -- ^ What kind of module (regular Haskell, hs-boot, ext-core)
 143
 144         tcg_rdr_env :: GlobalRdrEnv,   -- ^ Top level envt; used during renaming
 145         tcg_default :: Maybe [Type],
 146           -- ^ Types used for defaulting. @Nothing@ => no @default@ decl
 147
 148         tcg_fix_env   :: FixityEnv,     -- ^ Just for things in this module
 149         tcg_field_env :: RecFieldEnv,   -- ^ Just for things in this module
 150
 151         tcg_type_env :: TypeEnv,
 152           -- ^ Global type env for the module we are compiling now.  All
 153           -- TyCons and Classes (for this module) end up in here right away,
 154           -- along with their derived constructors, selectors.
 155           --
 156           -- (Ids defined in this module start in the local envt, though they
 157           --  move to the global envt during zonking)
 158
 159         tcg_type_env_var :: TcRef TypeEnv,
 160                 -- Used only to initialise the interface-file
 161                 -- typechecker in initIfaceTcRn, so that it can see stuff
 162                 -- bound in this module when dealing with hi-boot recursions
 163                 -- Updated at intervals (e.g. after dealing with types and classes)
 164
 165         tcg_inst_env     :: InstEnv,
 166           -- ^ Instance envt for /home-package/ modules; Includes the dfuns in
 167           -- tcg_insts
 168         tcg_fam_inst_env :: FamInstEnv, -- ^ Ditto for family instances
 169
 170                 -- Now a bunch of things about this module that are simply
 171                 -- accumulated, but never consulted until the end.
 172                 -- Nevertheless, it's convenient to accumulate them along
 173                 -- with the rest of the info from this module.
 174         tcg_exports :: [AvailInfo],     -- ^ What is exported
 175         tcg_imports :: ImportAvails,
 176           -- ^ Information about what was imported from where, including
 177           -- things bound in this module.
 178
 179         tcg_dus :: DefUses,
 180           -- ^ What is defined in this module and what is used.
 181           -- The latter is used to generate
 182           --
 183           --  (a) version tracking; no need to recompile if these things have
 184           --      not changed version stamp
 185           --
 186           --  (b) unused-import info
 187
 188         tcg_keep :: TcRef NameSet,
 189           -- ^ Locally-defined top-level names to keep alive.
 190           --
 191           -- "Keep alive" means give them an Exported flag, so that the
 192           -- simplifier does not discard them as dead code, and so that they
 193           -- are exposed in the interface file (but not to export to the
 194           -- user).
 195           --
 196           -- Some things, like dict-fun Ids and default-method Ids are "born"
 197           -- with the Exported flag on, for exactly the above reason, but some
 198           -- we only discover as we go.  Specifically:
 199           --
 200           --   * The to/from functions for generic data types
 201           --
 202           --   * Top-level variables appearing free in the RHS of an orphan
 203           --     rule
 204           --
 205           --   * Top-level variables appearing free in a TH bracket
 206
 207         tcg_inst_uses :: TcRef NameSet,
 208           -- ^ Home-package Dfuns actually used.
 209           --
 210           -- Used to generate version dependencies This records usages, rather
 211           -- like tcg_dus, but it has to be a mutable variable so it can be
 212           -- augmented when we look up an instance.  These uses of dfuns are
 213           -- rather like the free variables of the program, but are implicit
 214           -- instead of explicit.
 215
 216         tcg_th_used :: TcRef Bool,
 217           -- ^ @True@ <=> Template Haskell syntax used.
 218           --
 219           -- We need this so that we can generate a dependency on the Template
 220           -- Haskell package, becuase the desugarer is going to emit loads of
 221           -- references to TH symbols.  It's rather like tcg_inst_uses; the
 222           -- reference is implicit rather than explicit, so we have to zap a
 223           -- mutable variable.
 224
 225         tcg_dfun_n  :: TcRef OccSet,
 226           -- ^ Allows us to choose unique DFun names.
 227
 228         -- The next fields accumulate the payload of the module
 229         -- The binds, rules and foreign-decl fiels are collected
 230         -- initially in un-zonked form and are finally zonked in tcRnSrcDecls
 231
 232         tcg_rn_exports :: Maybe [Located (IE Name)],
 233         tcg_rn_imports :: [LImportDecl Name],
 234                 -- Keep the renamed imports regardless.  They are not
 235                 -- voluminous and are needed if you want to report unused imports
 236         tcg_used_rdrnames :: TcRef (Set RdrName),
 237         tcg_rn_decls :: Maybe (HsGroup Name),
 238           -- ^ Renamed decls, maybe.  @Nothing@ <=> Don't retain renamed
 239           -- decls.
 240
 241         tcg_binds     :: LHsBinds Id,       -- Value bindings in this module
 242         tcg_warns     :: Warnings,          -- ...Warnings and deprecations
 243         tcg_anns      :: [Annotation],      -- ...Annotations
 244         tcg_insts     :: [Instance],        -- ...Instances
 245         tcg_fam_insts :: [FamInst],         -- ...Family instances
 246         tcg_rules     :: [LRuleDecl Id],    -- ...Rules
 247         tcg_fords     :: [LForeignDecl Id], -- ...Foreign import & exports
 248
 249         tcg_doc_hdr   :: Maybe LHsDocString, -- ^ Maybe Haddock header docs
 250         tcg_hpc       :: AnyHpcUsage,        -- ^ @True@ if any part of the
 251                                              --  prog uses hpc instrumentation.
 252
 253         tcg_main      :: Maybe Name          -- ^ The Name of the main
 254                                              -- function, if this module is
 255                                              -- the main module.
 256     }
 257
 258 data RecFieldEnv
 259   = RecFields (NameEnv [Name])  -- Maps a constructor name *in this module*
 260                                 -- to the fields for that constructor
 261               NameSet           -- Set of all fields declared *in this module*;
 262                                 -- used to suppress name-shadowing complaints
 263                                 -- when using record wild cards
 264                                 -- E.g.  let fld = e in C {..}
 265         -- This is used when dealing with ".." notation in record
 266         -- construction and pattern matching.
 267         -- The FieldEnv deals *only* with constructors defined in *this*
 268         -- module.  For imported modules, we get the same info from the
 269         -- TypeEnv
 270 \end{code}
 271
 272 %************************************************************************
 273 %*                                                                      *
 274                 The interface environments
 275               Used when dealing with IfaceDecls
 276 %*                                                                      *
 277 %************************************************************************
 278
 279 \begin{code}
 280 data IfGblEnv
 281   = IfGblEnv {
 282         -- The type environment for the module being compiled,
 283         -- in case the interface refers back to it via a reference that
 284         -- was originally a hi-boot file.
 285         -- We need the module name so we can test when it's appropriate
 286         -- to look in this env.
 287         if_rec_types :: Maybe (Module, IfG TypeEnv)
 288                 -- Allows a read effect, so it can be in a mutable
 289                 -- variable; c.f. handling the external package type env
 290                 -- Nothing => interactive stuff, no loops possible
 291     }
 292
 293 data IfLclEnv
 294   = IfLclEnv {
 295         -- The module for the current IfaceDecl
 296         -- So if we see   f = \x -> x
 297         -- it means M.f = \x -> x, where M is the if_mod
 298         if_mod :: Module,
 299
 300         -- The field is used only for error reporting
 301         -- if (say) there's a Lint error in it
 302         if_loc :: SDoc,
 303                 -- Where the interface came from:
 304                 --      .hi file, or GHCi state, or ext core
 305                 -- plus which bit is currently being examined
 306
 307         if_tv_env  :: UniqFM TyVar,     -- Nested tyvar bindings
 308         if_id_env  :: UniqFM Id         -- Nested id binding
 309     }
 310 \end{code}
 311
 312
 313 %************************************************************************
 314 %*                                                                      *
 315                 The local typechecker environment
 316 %*                                                                      *
 317 %************************************************************************
 318
 319 The Global-Env/Local-Env story
 320 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 321 During type checking, we keep in the tcg_type_env
 322         * All types and classes
 323         * All Ids derived from types and classes (constructors, selectors)
 324
 325 At the end of type checking, we zonk the local bindings,
 326 and as we do so we add to the tcg_type_env
 327         * Locally defined top-level Ids
 328
 329 Why?  Because they are now Ids not TcIds.  This final GlobalEnv is
 330         a) fed back (via the knot) to typechecking the
 331            unfoldings of interface signatures
 332         b) used in the ModDetails of this module
 333
 334 \begin{code}
 335 data TcLclEnv           -- Changes as we move inside an expression
 336                         -- Discarded after typecheck/rename; not passed on to desugarer
 337   = TcLclEnv {
 338         tcl_loc  :: SrcSpan,            -- Source span
 339         tcl_ctxt :: [ErrCtxt],          -- Error context, innermost on top
 340         tcl_errs :: TcRef Messages,     -- Place to accumulate errors
 341
 342         tcl_th_ctxt    :: ThStage,            -- Template Haskell context
 343         tcl_arrow_ctxt :: ArrowCtxt,          -- Arrow-notation context
 344
 345         tcl_rdr :: LocalRdrEnv,         -- Local name envt
 346                 -- Maintained during renaming, of course, but also during
 347                 -- type checking, solely so that when renaming a Template-Haskell
 348                 -- splice we have the right environment for the renamer.
 349                 --
 350                 --   Does *not* include global name envt; may shadow it
 351                 --   Includes both ordinary variables and type variables;
 352                 --   they are kept distinct because tyvar have a different
 353                 --   occurrence contructor (Name.TvOcc)
 354                 -- We still need the unsullied global name env so that
 355                 --   we can look up record field names
 356
 357         tcl_env  :: NameEnv TcTyThing,  -- The local type environment: Ids and
 358                                         -- TyVars defined in this module
 359
 360         tcl_tyvars :: TcRef TcTyVarSet, -- The "global tyvars"
 361                         -- Namely, the in-scope TyVars bound in tcl_env,
 362                         -- plus the tyvars mentioned in the types of Ids bound
 363                         -- in tcl_lenv.
 364                         -- Why mutable? see notes with tcGetGlobalTyVars
 365
 366         tcl_lie   :: TcRef LIE,         -- Place to accumulate type constraints
 367
 368         tcl_tybinds :: TcRef TcTyVarBinds -- Meta and coercion type variable
 369                                           -- bindings accumulated during
 370                                           -- constraint solving
 371     }
 372
 373
 374 {- Note [Given Insts]
 375    ~~~~~~~~~~~~~~~~~~
 376 Because of GADTs, we have to pass inwards the Insts provided by type signatures
 377 and existential contexts. Consider
 378         data T a where { T1 :: b -> b -> T [b] }
 379         f :: Eq a => T a -> Bool
 380         f (T1 x y) = [x]==[y]
 381
 382 The constructor T1 binds an existential variable 'b', and we need Eq [b].
 383 Well, we have it, because Eq a refines to Eq [b], but we can only spot that if we
 384 pass it inwards.
 385
 386 -}
 387
 388 ---------------------------
 389 -- Template Haskell stages and levels
 390 ---------------------------
 391
 392 data ThStage    -- See Note [Template Haskell state diagram] in TcSplice
 393   = Splice      -- Top-level splicing
 394                 -- This code will be run *at compile time*;
 395                 --   the result replaces the splice
 396                 -- Binding level = 0
 397
 398   | Comp        -- Ordinary Haskell code
 399                 -- Binding level = 1
 400
 401   | Brack                       -- Inside brackets
 402       ThStage                   --   Binding level = level(stage) + 1
 403       (TcRef [PendingSplice])   --   Accumulate pending splices here
 404       (TcRef LIE)               --     and type constraints here
 405
 406 topStage, topAnnStage, topSpliceStage :: ThStage
 407 topStage       = Comp
 408 topAnnStage    = Splice
 409 topSpliceStage = Splice
 410
 411 instance Outputable ThStage where
 412    ppr Splice        = text "Splice"
 413    ppr Comp          = text "Comp"
 414    ppr (Brack s _ _) = text "Brack" <> parens (ppr s)
 415
 416 type ThLevel = Int
 417         -- See Note [Template Haskell levels] in TcSplice
 418         -- Incremented when going inside a bracket,
 419         -- decremented when going inside a splice
 420         -- NB: ThLevel is one greater than the 'n' in Fig 2 of the
 421         --     original "Template meta-programming for Haskell" paper
 422
 423 impLevel, outerLevel :: ThLevel
 424 impLevel = 0    -- Imported things; they can be used inside a top level splice
 425 outerLevel = 1  -- Things defined outside brackets
 426 -- NB: Things at level 0 are not *necessarily* imported.
 427 --      eg  $( \b -> ... )   here b is bound at level 0
 428 --
 429 -- For example:
 430 --      f = ...
 431 --      g1 = $(map ...)         is OK
 432 --      g2 = $(f ...)           is not OK; because we havn't compiled f yet
 433
 434 thLevel :: ThStage -> ThLevel
 435 thLevel Splice        = 0
 436 thLevel Comp          = 1
 437 thLevel (Brack s _ _) = thLevel s + 1
 438
 439 ---------------------------
 440 -- Arrow-notation context
 441 ---------------------------
 442
 443 {-
 444 In arrow notation, a variable bound by a proc (or enclosed let/kappa)
 445 is not in scope to the left of an arrow tail (-<) or the head of (|..|).
 446 For example
 447
 448         proc x -> (e1 -< e2)
 449
 450 Here, x is not in scope in e1, but it is in scope in e2.  This can get
 451 a bit complicated:
 452
 453         let x = 3 in
 454         proc y -> (proc z -> e1) -< e2
 455
 456 Here, x and z are in scope in e1, but y is not.  We implement this by
 457 recording the environment when passing a proc (using newArrowScope),
 458 and returning to that (using escapeArrowScope) on the left of -< and the
 459 head of (|..|).
 460 -}
 461
 462 data ArrowCtxt
 463   = NoArrowCtxt
 464   | ArrowCtxt (Env TcGblEnv TcLclEnv)
 465
 466 -- Record the current environment (outside a proc)
 467 newArrowScope :: TcM a -> TcM a
 468 newArrowScope
 469   = updEnv $ \env ->
 470         env { env_lcl = (env_lcl env) { tcl_arrow_ctxt = ArrowCtxt env } }
 471
 472 -- Return to the stored environment (from the enclosing proc)
 473 escapeArrowScope :: TcM a -> TcM a
 474 escapeArrowScope
 475   = updEnv $ \ env -> case tcl_arrow_ctxt (env_lcl env) of
 476         NoArrowCtxt -> env
 477         ArrowCtxt env' -> env'
 478
 479 ---------------------------
 480 -- TcTyThing
 481 ---------------------------
 482
 483 data TcTyThing
 484   = AGlobal TyThing             -- Used only in the return type of a lookup
 485
 486   | ATcId   {           -- Ids defined in this module; may not be fully zonked
 487         tct_id :: TcId,
 488         tct_co :: RefinementVisibility, -- Previously: Maybe HsWrapper
 489                                         -- Nothing <=>  Do not apply a GADT type refinement
 490                                         --              I am wobbly, or have no free
 491                                         --              type variables
 492                                         -- Just co <=>  Apply any type refinement to me,
 493                                         --              and record it in the coercion
 494         tct_type  :: TcType,    -- Type of (coercion applied to id)
 495         tct_level :: ThLevel }
 496
 497   | ATyVar  Name TcType         -- The type to which the lexically scoped type vaiable
 498                                 -- is currently refined. We only need the Name
 499                                 -- for error-message purposes
 500
 501   | AThing  TcKind              -- Used temporarily, during kind checking, for the
 502                                 --      tycons and clases in this recursive group
 503
 504 data RefinementVisibility
 505   = Unrefineable                        -- Do not apply a GADT refinement
 506                                         -- I have no free variables
 507
 508   | Rigid HsWrapper                     -- Apply any refinement to me
 509                                         -- and record it in the coercion
 510
 511   | Wobbly                              -- Do not apply a GADT refinement
 512                                         -- I am wobbly
 513
 514   | WobblyInvisible                     -- Wobbly type, not available inside current
 515                                         -- GADT refinement
 516
 517 instance Outputable TcTyThing where     -- Debugging only
 518    ppr (AGlobal g)      = pprTyThing g
 519    ppr elt@(ATcId {})   = text "Identifier" <>
 520                           ifPprDebug (brackets (ppr (tct_id elt) <> dcolon <> ppr (tct_type elt) <> comma
 521                                  <+> ppr (tct_level elt) <+> ppr (tct_co elt)))
 522    ppr (ATyVar tv _)    = text "Type variable" <+> quotes (ppr tv)
 523    ppr (AThing k)       = text "AThing" <+> ppr k
 524
 525 pprTcTyThingCategory :: TcTyThing -> SDoc
 526 pprTcTyThingCategory (AGlobal thing) = pprTyThingCategory thing
 527 pprTcTyThingCategory (ATyVar {})     = ptext (sLit "Type variable")
 528 pprTcTyThingCategory (ATcId {})      = ptext (sLit "Local identifier")
 529 pprTcTyThingCategory (AThing {})     = ptext (sLit "Kinded thing")
 530
 531 instance Outputable RefinementVisibility where
 532     ppr Unrefineable          = ptext (sLit "unrefineable")
 533     ppr (Rigid co)            = ptext (sLit "rigid") <+> ppr co
 534     ppr Wobbly                = ptext (sLit "wobbly")
 535     ppr WobblyInvisible       = ptext (sLit "wobbly-invisible")
 536
 537 \end{code}
 538
 539 \begin{code}
 540 type ErrCtxt = (Bool, TidyEnv -> TcM (TidyEnv, Message))
 541         -- Monadic so that we have a chance
 542         -- to deal with bound type variables just before error
 543         -- message construction
 544
 545         -- Bool:  True <=> this is a landmark context; do not
 546         --                 discard it when trimming for display
 547 \end{code}
 548
 549
 550 %************************************************************************
 551 %*                                                                      *
 552         Operations over ImportAvails
 553 %*                                                                      *
 554 %************************************************************************
 555
 556 \begin{code}
 557 -- | 'ImportAvails' summarises what was imported from where, irrespective of
 558 -- whether the imported things are actually used or not.  It is used:
 559 --
 560 --  * when processing the export list,
 561 --
 562 --  * when constructing usage info for the interface file,
 563 --
 564 --  * to identify the list of directly imported modules for initialisation
 565 --    purposes and for optimised overlap checking of family instances,
 566 --
 567 --  * when figuring out what things are really unused
 568 --
 569 data ImportAvails
 570    = ImportAvails {
 571         imp_mods :: ModuleEnv [(ModuleName, Bool, SrcSpan)],
 572           -- ^ Domain is all directly-imported modules
 573           -- The 'ModuleName' is what the module was imported as, e.g. in
 574           -- @
 575           --     import Foo as Bar
 576           -- @
 577           -- it is @Bar@.
 578           --
 579           -- The 'Bool' means:
 580           --
 581           --  - @True@ => import was @import Foo ()@
 582           --
 583           --  - @False@ => import was some other form
 584           --
 585           -- Used
 586           --
 587           --   (a) to help construct the usage information in the interface
 588           --       file; if we import somethign we need to recompile if the
 589           --       export version changes
 590           --
 591           --   (b) to specify what child modules to initialise
 592           --
 593           -- We need a full ModuleEnv rather than a ModuleNameEnv here,
 594           -- because we might be importing modules of the same name from
 595           -- different packages. (currently not the case, but might be in the
 596           -- future).
 597
 598         imp_dep_mods :: ModuleNameEnv (ModuleName, IsBootInterface),
 599           -- ^ Home-package modules needed by the module being compiled
 600           --
 601           -- It doesn't matter whether any of these dependencies
 602           -- are actually /used/ when compiling the module; they
 603           -- are listed if they are below it at all.  For
 604           -- example, suppose M imports A which imports X.  Then
 605           -- compiling M might not need to consult X.hi, but X
 606           -- is still listed in M's dependencies.
 607
 608         imp_dep_pkgs :: [PackageId],
 609           -- ^ Packages needed by the module being compiled, whether directly,
 610           -- or via other modules in this package, or via modules imported
 611           -- from other packages.
 612
 613         imp_orphs :: [Module],
 614           -- ^ Orphan modules below us in the import tree (and maybe including
 615           -- us for imported modules)
 616
 617         imp_finsts :: [Module]
 618           -- ^ Family instance modules below us in the import tree (and maybe
 619           -- including us for imported modules)
 620       }
 621
 622 mkModDeps :: [(ModuleName, IsBootInterface)]
 623           -> ModuleNameEnv (ModuleName, IsBootInterface)
 624 mkModDeps deps = foldl add emptyUFM deps
 625                where
 626                  add env elt@(m,_) = addToUFM env m elt
 627
 628 emptyImportAvails :: ImportAvails
 629 emptyImportAvails = ImportAvails { imp_mods     = emptyModuleEnv,
 630                                    imp_dep_mods = emptyUFM,
 631                                    imp_dep_pkgs = [],
 632                                    imp_orphs    = [],
 633                                    imp_finsts   = [] }
 634
 635 plusImportAvails ::  ImportAvails ->  ImportAvails ->  ImportAvails
 636 plusImportAvails
 637   (ImportAvails { imp_mods = mods1,
 638                   imp_dep_mods = dmods1, imp_dep_pkgs = dpkgs1,
 639                   imp_orphs = orphs1, imp_finsts = finsts1 })
 640   (ImportAvails { imp_mods = mods2,
 641                   imp_dep_mods = dmods2, imp_dep_pkgs = dpkgs2,
 642                   imp_orphs = orphs2, imp_finsts = finsts2 })
 643   = ImportAvails { imp_mods     = plusModuleEnv_C (++) mods1 mods2,
 644                    imp_dep_mods = plusUFM_C plus_mod_dep dmods1 dmods2,
 645                    imp_dep_pkgs = dpkgs1 `unionLists` dpkgs2,
 646                    imp_orphs    = orphs1 `unionLists` orphs2,
 647                    imp_finsts   = finsts1 `unionLists` finsts2 }
 648   where
 649     plus_mod_dep (m1, boot1) (m2, boot2)
 650         = WARN( not (m1 == m2), (ppr m1 <+> ppr m2) $$ (ppr boot1 <+> ppr boot2) )
 651                 -- Check mod-names match
 652           (m1, boot1 && boot2)  -- If either side can "see" a non-hi-boot interface, use that
 653 \end{code}
 654
 655 %************************************************************************
 656 %*                                                                      *
 657 \subsection{Where from}
 658 %*                                                                      *
 659 %************************************************************************
 660
 661 The @WhereFrom@ type controls where the renamer looks for an interface file
 662
 663 \begin{code}
 664 data WhereFrom
 665   = ImportByUser IsBootInterface        -- Ordinary user import (perhaps {-# SOURCE #-})
 666   | ImportBySystem                      -- Non user import.
 667
 668 instance Outputable WhereFrom where
 669   ppr (ImportByUser is_boot) | is_boot     = ptext (sLit "{- SOURCE -}")
 670                              | otherwise   = empty
 671   ppr ImportBySystem                       = ptext (sLit "{- SYSTEM -}")
 672 \end{code}
 673
 674
 675 %************************************************************************
 676 %*                                                                      *
 677 \subsection[Inst-types]{@Inst@ types}
 678 %*                                                                      *
 679 v%************************************************************************
 680
 681 An @Inst@ is either a dictionary, an instance of an overloaded
 682 literal, or an instance of an overloaded value.  We call the latter a
 683 ``method'' even though it may not correspond to a class operation.
 684 For example, we might have an instance of the @double@ function at
 685 type Int, represented by
 686
 687         Method 34 doubleId [Int] origin
 688
 689 In addition to the basic Haskell variants of 'Inst's, they can now also
 690 represent implication constraints 'forall tvs. given => wanted'
 691 and equality constraints 'co :: ty1 ~ ty2'.
 692
 693 NB: Equalities occur in two flavours:
 694
 695   (1) Dict {tci_pred = EqPred ty1 ty2}
 696   (2) EqInst {tci_left = ty1, tci_right = ty2, tci_co = coe}
 697
 698 The former arises from equalities in contexts, whereas the latter is used
 699 whenever the type checker introduces an equality (e.g., during deferring
 700 unification).
 701
 702 I am not convinced that this duplication is necessary or useful! -=chak
 703
 704 \begin{code}
 705 data Inst
 706   = Dict {
 707         tci_name :: Name,
 708         tci_pred :: TcPredType,   -- Class or implicit parameter only
 709         tci_loc  :: InstLoc
 710     }
 711
 712   | ImplicInst {        -- An implication constraint
 713                         -- forall tvs. given => wanted
 714         tci_name   :: Name,
 715         tci_tyvars :: [TcTyVar],    -- Quantified type variables
 716         tci_given  :: [Inst],       -- Only Dicts and EqInsts
 717                                     --   (no Methods, LitInsts, ImplicInsts)
 718         tci_wanted :: [Inst],       -- Only Dicts, EqInst, and ImplicInsts
 719                                     --   (no Methods or LitInsts)
 720
 721         tci_loc    :: InstLoc
 722     }
 723         -- NB: the tci_given are not necessarily rigid
 724
 725   | Method {
 726         tci_id :: TcId,         -- The Id for the Inst
 727
 728         tci_oid :: TcId,        -- The overloaded function
 729                 -- This function will be a global, local, or ClassOpId;
 730                 --   inside instance decls (only) it can also be an InstId!
 731                 -- The id needn't be completely polymorphic.
 732                 -- You'll probably find its name (for documentation purposes)
 733                 --        inside the InstOrigin
 734
 735         tci_tys :: [TcType],    -- The types to which its polymorphic tyvars
 736                                 --      should be instantiated.
 737                                 -- These types must saturate the Id's foralls.
 738
 739         tci_theta :: TcThetaType,
 740                         -- The (types of the) dictionaries to which the function
 741                         -- must be applied to get the method
 742
 743         tci_loc :: InstLoc
 744     }
 745         -- INVARIANT 1: in (Method m f tys theta tau loc)
 746         --      type of m = type of (f tys dicts(from theta))
 747
 748         -- INVARIANT 2: type of m must not be of form (Pred -> Tau)
 749         --   Reason: two methods are considered equal if the
 750         --           base Id matches, and the instantiating types
 751         --           match.  The TcThetaType should then match too.
 752         --   This only bites in the call to tcInstClassOp in TcClassDcl.mkMethodBind
 753
 754   | LitInst {
 755         tci_name :: Name,
 756         tci_lit  :: HsOverLit Name,     -- The literal from the occurrence site
 757                         -- INVARIANT: never a rebindable-syntax literal
 758                         -- Reason: tcSyntaxName does unification, and we
 759                         --         don't want to deal with that during tcSimplify,
 760                         --         when resolving LitInsts
 761
 762         tci_ty :: TcType,       -- The type at which the literal is used
 763         tci_loc :: InstLoc
 764     }
 765
 766   | EqInst {                      -- delayed unification of the form
 767                                   --    co :: ty1 ~ ty2
 768         tci_left  :: TcType,      -- ty1    -- both types are...
 769         tci_right :: TcType,      -- ty2    -- ...free of boxes
 770         tci_co    :: EqInstCo,            -- co
 771         tci_loc   :: InstLoc,
 772
 773         tci_name  :: Name       -- Debugging help only: this makes it easier to
 774                                 -- follow where a constraint is used in a morass
 775                                 -- of trace messages!  Unlike other Insts, it
 776                                 -- has no semantic significance whatsoever.
 777     }
 778
 779 type EqInstCo = Either    -- Distinguish between given and wanted coercions
 780                   TcTyVar   --  - a wanted equation, with a hole, to be filled
 781                             --    with a witness for the equality; for equation
 782                             --    arising from deferring unification, 'ty1' is
 783                             --    the actual and 'ty2' the expected type
 784                   Coercion  --  - a given equation, with a coercion witnessing
 785                             --    the equality; a coercion that originates
 786                             --    from a signature or a GADT is a CoVar, but
 787                             --    after normalisation of coercions, they can
 788                             --    be arbitrary Coercions involving constructors
 789                             --    and pseudo-constructors like sym and trans.
 790 \end{code}
 791
 792 @Insts@ are ordered by their class/type info, rather than by their
 793 unique.  This allows the context-reduction mechanism to use standard finite
 794 maps to do their stuff.  It's horrible that this code is here, rather
 795 than with the Avails handling stuff in TcSimplify
 796
 797 \begin{code}
 798 instance Ord Inst where
 799    compare = cmpInst
 800         -- Used *only* for AvailEnv in TcSimplify
 801
 802 instance Eq Inst where
 803   (==) i1 i2 = case i1 `cmpInst` i2 of
 804                EQ -> True
 805                _  -> False
 806
 807 cmpInst :: Inst -> Inst -> Ordering
 808 cmpInst d1@(Dict {})    d2@(Dict {})    = tci_pred d1 `tcCmpPred` tci_pred d2
 809 cmpInst (Dict {})       _               = LT
 810
 811 cmpInst (Method {})     (Dict {})       = GT
 812 cmpInst m1@(Method {})  m2@(Method {})  = (tci_oid m1 `compare` tci_oid m2) `thenCmp`
 813                                           (tci_tys m1 `tcCmpTypes` tci_tys m2)
 814 cmpInst (Method {})     _               = LT
 815
 816 cmpInst (LitInst {})    (Dict {})       = GT
 817 cmpInst (LitInst {})    (Method {})     = GT
 818 cmpInst l1@(LitInst {}) l2@(LitInst {}) = (tci_lit l1 `compare` tci_lit l2) `thenCmp`
 819                                           (tci_ty l1 `tcCmpType` tci_ty l2)
 820 cmpInst (LitInst {})    _               = LT
 821
 822         -- Implication constraints are compared by *name*
 823         -- not by type; that is, we make no attempt to do CSE on them
 824 cmpInst (ImplicInst {})    (Dict {})          = GT
 825 cmpInst (ImplicInst {})    (Method {})        = GT
 826 cmpInst (ImplicInst {})    (LitInst {})       = GT
 827 cmpInst i1@(ImplicInst {}) i2@(ImplicInst {}) = tci_name i1 `compare` tci_name i2
 828 cmpInst (ImplicInst {})    _                  = LT
 829
 830         -- same for Equality constraints
 831 cmpInst (EqInst {})    (Dict {})       = GT
 832 cmpInst (EqInst {})    (Method {})     = GT
 833 cmpInst (EqInst {})    (LitInst {})    = GT
 834 cmpInst (EqInst {})    (ImplicInst {}) = GT
 835 cmpInst i1@(EqInst {}) i2@(EqInst {})  = (tci_left  i1 `tcCmpType` tci_left  i2) `thenCmp`
 836                                          (tci_right i1 `tcCmpType` tci_right i2)
 837 \end{code}
 838
 839
 840 %************************************************************************
 841 %*                                                                      *
 842 \subsection[Inst-collections]{LIE: a collection of Insts}
 843 %*                                                                      *
 844 %************************************************************************
 845
 846 \begin{code}
 847 -- FIXME: Rename this. It clashes with (Located (IE ...))
 848 type LIE = Bag Inst
 849
 850 isEmptyLIE :: LIE -> Bool
 851 isEmptyLIE = isEmptyBag
 852
 853 emptyLIE :: LIE
 854 emptyLIE = emptyBag
 855
 856 unitLIE :: Inst -> LIE
 857 unitLIE inst = unitBag inst
 858
 859 mkLIE :: [Inst] -> LIE
 860 mkLIE insts = listToBag insts
 861
 862 plusLIE :: LIE -> LIE -> LIE
 863 plusLIE lie1 lie2 = lie1 `unionBags` lie2
 864
 865 plusLIEs :: [LIE] -> LIE
 866 plusLIEs lies = unionManyBags lies
 867
 868 lieToList :: LIE -> [Inst]
 869 lieToList = bagToList
 870
 871 listToLIE :: [Inst] -> LIE
 872 listToLIE = listToBag
 873
 874 consLIE :: Inst -> LIE -> LIE
 875 consLIE inst lie  = lie `snocBag` inst
 876 -- Putting the new Inst at the *end* of the bag is a half-hearted attempt
 877 -- to ensure that we tend to report the *leftmost* type-constraint error
 878 -- E.g.         f :: [a]
 879 --              f = [1,2,3]
 880 -- we'd like to complain about the '1', not the '3'.
 881 --
 882 -- "Half-hearted" because the rest of the type checker makes no great
 883 -- claims for retaining order in the constraint set.  Still, this
 884 -- seems to improve matters slightly.  Exampes: mdofail001, tcfail015
 885 \end{code}
 886
 887
 888 %************************************************************************
 889 %*                                                                      *
 890 \subsection[Inst-origin]{The @InstOrigin@ type}
 891 %*                                                                      *
 892 %************************************************************************
 893
 894 The @InstOrigin@ type gives information about where a dictionary came from.
 895 This is important for decent error message reporting because dictionaries
 896 don't appear in the original source code.  Doubtless this type will evolve...
 897
 898 It appears in TcMonad because there are a couple of error-message-generation
 899 functions that deal with it.
 900
 901 \begin{code}
 902 -------------------------------------------
 903 data InstLoc = InstLoc InstOrigin SrcSpan [ErrCtxt]
 904
 905 instLoc :: Inst -> InstLoc
 906 instLoc inst = tci_loc inst
 907
 908 setInstLoc :: Inst -> InstLoc -> Inst
 909 setInstLoc inst new_loc = inst { tci_loc = new_loc }
 910
 911 instSpan :: Inst -> SrcSpan
 912 instSpan wanted = instLocSpan (instLoc wanted)
 913
 914 instLocSpan :: InstLoc -> SrcSpan
 915 instLocSpan (InstLoc _ s _) = s
 916
 917 instLocOrigin :: InstLoc -> InstOrigin
 918 instLocOrigin (InstLoc o _ _) = o
 919
 920 pprInstArising :: Inst -> SDoc
 921 pprInstArising loc = ptext (sLit "arising from") <+> pprInstLoc (tci_loc loc)
 922
 923 pprInstLoc :: InstLoc -> SDoc
 924 pprInstLoc (InstLoc orig span _) = sep [ppr orig, text "at" <+> ppr span]
 925
 926 -------------------------------------------
 927 data InstOrigin
 928   = SigOrigin SkolemInfo        -- Pattern, class decl, inst decl etc;
 929                                 -- Places that bind type variables and introduce
 930                                 -- available constraints
 931
 932   | IPBindOrigin (IPName Name)  -- Binding site of an implicit parameter
 933
 934         -------------------------------------------------------
 935         -- The rest are all occurrences: Insts that are 'wanted'
 936         -------------------------------------------------------
 937   | OccurrenceOf Name           -- Occurrence of an overloaded identifier
 938   | SpecPragOrigin Name         -- Specialisation pragma for identifier
 939
 940   | IPOccOrigin  (IPName Name)  -- Occurrence of an implicit parameter
 941
 942   | LiteralOrigin (HsOverLit Name)      -- Occurrence of a literal
 943   | NegateOrigin                        -- Occurrence of syntactic negation
 944
 945   | ArithSeqOrigin (ArithSeqInfo Name) -- [x..], [x..y] etc
 946   | PArrSeqOrigin  (ArithSeqInfo Name) -- [:x..y:] and [:x,y..z:]
 947   | TupleOrigin                        -- (..,..)
 948
 949   | InstSigOrigin       -- A dict occurrence arising from instantiating
 950                         -- a polymorphic type during a subsumption check
 951
 952   | ExprSigOrigin       -- e :: ty
 953   | RecordUpdOrigin
 954   | ViewPatOrigin
 955
 956   | InstScOrigin        -- Typechecking superclasses of an instance declaration
 957
 958   | NoScOrigin          -- A very special hack; see TcSimplify,
 959                         --   Note [Recursive instances and superclases]
 960
 961
 962   | DerivOrigin         -- Typechecking deriving
 963   | StandAloneDerivOrigin -- Typechecking stand-alone deriving
 964   | DefaultOrigin       -- Typechecking a default decl
 965   | DoOrigin            -- Arising from a do expression
 966   | ProcOrigin          -- Arising from a proc expression
 967   | ImplicOrigin SDoc   -- An implication constraint
 968   | EqOrigin            -- A type equality
 969   | AnnOrigin           -- An annotation
 970
 971 instance Outputable InstOrigin where
 972     ppr (OccurrenceOf name)   = hsep [ptext (sLit "a use of"), quotes (ppr name)]
 973     ppr (SpecPragOrigin name) = hsep [ptext (sLit "a specialisation pragma for"), quotes (ppr name)]
 974     ppr (IPOccOrigin name)    = hsep [ptext (sLit "a use of implicit parameter"), quotes (ppr name)]
 975     ppr (IPBindOrigin name)   = hsep [ptext (sLit "a binding for implicit parameter"), quotes (ppr name)]
 976     ppr RecordUpdOrigin       = ptext (sLit "a record update")
 977     ppr ExprSigOrigin         = ptext (sLit "an expression type signature")
 978     ppr ViewPatOrigin         = ptext (sLit "a view pattern")
 979     ppr (LiteralOrigin lit)   = hsep [ptext (sLit "the literal"), quotes (ppr lit)]
 980     ppr (ArithSeqOrigin seq)  = hsep [ptext (sLit "the arithmetic sequence"), quotes (ppr seq)]
 981     ppr (PArrSeqOrigin seq)   = hsep [ptext (sLit "the parallel array sequence"), quotes (ppr seq)]
 982     ppr TupleOrigin           = ptext (sLit "a tuple")
 983     ppr NegateOrigin          = ptext (sLit "a use of syntactic negation")
 984     ppr InstScOrigin          = ptext (sLit "the superclasses of an instance declaration")
 985     ppr NoScOrigin            = ptext (sLit "an instance declaration")
 986     ppr DerivOrigin           = ptext (sLit "the 'deriving' clause of a data type declaration")
 987     ppr StandAloneDerivOrigin = ptext (sLit "a 'deriving' declaration")
 988     ppr DefaultOrigin         = ptext (sLit "a 'default' declaration")
 989     ppr DoOrigin              = ptext (sLit "a do statement")
 990     ppr ProcOrigin            = ptext (sLit "a proc expression")
 991     ppr (ImplicOrigin doc)    = doc
 992     ppr (SigOrigin info)      = pprSkolInfo info
 993     ppr EqOrigin              = ptext (sLit "a type equality")
 994     ppr InstSigOrigin         = panic "ppr InstSigOrigin"
 995     ppr AnnOrigin             = ptext (sLit "an annotation")
 996 \end{code}