compiler/typecheck/TcRnTypes.lhs

   1
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP Project, Glasgow University, 1992-2002
   4 %
   5 \begin{code}
   6 module TcRnTypes(
   7         TcRnIf, TcRn, TcM, RnM, IfM, IfL, IfG, -- The monad is opaque outside this module
   8         TcRef,
   9
  10         -- The environment types
  11         Env(..),
  12         TcGblEnv(..), TcLclEnv(..),
  13         IfGblEnv(..), IfLclEnv(..),
  14
  15         -- Ranamer types
  16         ErrCtxt, RecFieldEnv(..),
  17         ImportAvails(..), emptyImportAvails, plusImportAvails,
  18         WhereFrom(..), mkModDeps,
  19
  20         -- Typechecker types
  21         TcTyThing(..), pprTcTyThingCategory, RefinementVisibility(..),
  22
  23         -- Template Haskell
  24         ThStage(..), topStage, topAnnStage, topSpliceStage,
  25         ThLevel, impLevel, topLevel,
  26
  27         -- Arrows
  28         ArrowCtxt(NoArrowCtxt), newArrowScope, escapeArrowScope,
  29
  30         -- Insts
  31         Inst(..), EqInstCo, InstOrigin(..), InstLoc(..),
  32         pprInstLoc, pprInstArising, instLocSpan, instLocOrigin, setInstLoc,
  33         LIE, emptyLIE, unitLIE, plusLIE, consLIE, instLoc, instSpan,
  34         plusLIEs, mkLIE, isEmptyLIE, lieToList, listToLIE,
  35
  36         -- Misc other types
  37         TcId, TcIdSet, TcDictBinds, TcTyVarBind(..), TcTyVarBinds
  38
  39   ) where
  40
  41 #include "HsVersions.h"
  42
  43 import HsSyn hiding (LIE)
  44 import HscTypes
  45 import Type
  46 import Coercion
  47 import TcType
  48 import Annotations
  49 import InstEnv
  50 import FamInstEnv
  51 import IOEnv
  52 import RdrName
  53 import Name
  54 import NameEnv
  55 import NameSet
  56 import Var
  57 import VarEnv
  58 import Module
  59 import LazyUniqFM
  60 import SrcLoc
  61 import VarSet
  62 import ErrUtils
  63 import UniqSupply
  64 import BasicTypes
  65 import Util
  66 import Bag
  67 import Outputable
  68 import ListSetOps
  69 import FastString
  70
  71 import Data.Set (Set)
  72 \end{code}
  73
  74
  75 %************************************************************************
  76 %*                                                                      *
  77                Standard monad definition for TcRn
  78     All the combinators for the monad can be found in TcRnMonad
  79 %*                                                                      *
  80 %************************************************************************
  81
  82 The monad itself has to be defined here, because it is mentioned by ErrCtxt
  83
  84 \begin{code}
  85 type TcRef a     = IORef a
  86 type TcId        = Id                   -- Type may be a TcType
  87 type TcIdSet     = IdSet
  88 type TcDictBinds = DictBinds TcId       -- Bag of dictionary bindings
  89
  90 type TcRnIf a b c = IOEnv (Env a b) c
  91 type IfM lcl a  = TcRnIf IfGblEnv lcl a         -- Iface stuff
  92
  93 type IfG a  = IfM () a                          -- Top level
  94 type IfL a  = IfM IfLclEnv a                    -- Nested
  95 type TcRn a = TcRnIf TcGblEnv TcLclEnv a
  96 type RnM  a = TcRn a            -- Historical
  97 type TcM  a = TcRn a            -- Historical
  98 \end{code}
  99
 100 Representation of type bindings to uninstantiated meta variables used during
 101 constraint solving.
 102
 103 \begin{code}
 104 data TcTyVarBind = TcTyVarBind TcTyVar TcType
 105
 106 type TcTyVarBinds = Bag TcTyVarBind
 107
 108 instance Outputable TcTyVarBind where
 109   ppr (TcTyVarBind tv ty) = ppr tv <+> text ":=" <+> ppr ty
 110 \end{code}
 111
 112
 113 %************************************************************************
 114 %*                                                                      *
 115                 The main environment types
 116 %*                                                                      *
 117 %************************************************************************
 118
 119 \begin{code}
 120 data Env gbl lcl        -- Changes as we move into an expression
 121   = Env {
 122         env_top  :: HscEnv,     -- Top-level stuff that never changes
 123                                 -- Includes all info about imported things
 124
 125         env_us   :: {-# UNPACK #-} !(IORef UniqSupply),
 126                                 -- Unique supply for local varibles
 127
 128         env_gbl  :: gbl,        -- Info about things defined at the top level
 129                                 -- of the module being compiled
 130
 131         env_lcl  :: lcl         -- Nested stuff; changes as we go into
 132     }
 133
 134 -- TcGblEnv describes the top-level of the module at the
 135 -- point at which the typechecker is finished work.
 136 -- It is this structure that is handed on to the desugarer
 137
 138 data TcGblEnv
 139   = TcGblEnv {
 140         tcg_mod     :: Module,         -- ^ Module being compiled
 141         tcg_src     :: HscSource,
 142           -- ^ What kind of module (regular Haskell, hs-boot, ext-core)
 143
 144         tcg_rdr_env :: GlobalRdrEnv,   -- ^ Top level envt; used during renaming
 145         tcg_default :: Maybe [Type],
 146           -- ^ Types used for defaulting. @Nothing@ => no @default@ decl
 147
 148         tcg_fix_env   :: FixityEnv,     -- ^ Just for things in this module
 149         tcg_field_env :: RecFieldEnv,   -- ^ Just for things in this module
 150
 151         tcg_type_env :: TypeEnv,
 152           -- ^ Global type env for the module we are compiling now.  All
 153           -- TyCons and Classes (for this module) end up in here right away,
 154           -- along with their derived constructors, selectors.
 155           --
 156           -- (Ids defined in this module start in the local envt, though they
 157           --  move to the global envt during zonking)
 158
 159         tcg_type_env_var :: TcRef TypeEnv,
 160                 -- Used only to initialise the interface-file
 161                 -- typechecker in initIfaceTcRn, so that it can see stuff
 162                 -- bound in this module when dealing with hi-boot recursions
 163                 -- Updated at intervals (e.g. after dealing with types and classes)
 164
 165         tcg_inst_env     :: InstEnv,
 166           -- ^ Instance envt for /home-package/ modules; Includes the dfuns in
 167           -- tcg_insts
 168         tcg_fam_inst_env :: FamInstEnv, -- ^ Ditto for family instances
 169
 170                 -- Now a bunch of things about this module that are simply
 171                 -- accumulated, but never consulted until the end.
 172                 -- Nevertheless, it's convenient to accumulate them along
 173                 -- with the rest of the info from this module.
 174         tcg_exports :: [AvailInfo],     -- ^ What is exported
 175         tcg_imports :: ImportAvails,
 176           -- ^ Information about what was imported from where, including
 177           -- things bound in this module.
 178
 179         tcg_dus :: DefUses,
 180           -- ^ What is defined in this module and what is used.
 181           -- The latter is used to generate
 182           --
 183           --  (a) version tracking; no need to recompile if these things have
 184           --      not changed version stamp
 185           --
 186           --  (b) unused-import info
 187
 188         tcg_keep :: TcRef NameSet,
 189           -- ^ Locally-defined top-level names to keep alive.
 190           --
 191           -- "Keep alive" means give them an Exported flag, so that the
 192           -- simplifier does not discard them as dead code, and so that they
 193           -- are exposed in the interface file (but not to export to the
 194           -- user).
 195           --
 196           -- Some things, like dict-fun Ids and default-method Ids are "born"
 197           -- with the Exported flag on, for exactly the above reason, but some
 198           -- we only discover as we go.  Specifically:
 199           --
 200           --   * The to/from functions for generic data types
 201           --
 202           --   * Top-level variables appearing free in the RHS of an orphan
 203           --     rule
 204           --
 205           --   * Top-level variables appearing free in a TH bracket
 206
 207         tcg_inst_uses :: TcRef NameSet,
 208           -- ^ Home-package Dfuns actually used.
 209           --
 210           -- Used to generate version dependencies This records usages, rather
 211           -- like tcg_dus, but it has to be a mutable variable so it can be
 212           -- augmented when we look up an instance.  These uses of dfuns are
 213           -- rather like the free variables of the program, but are implicit
 214           -- instead of explicit.
 215
 216         tcg_th_used :: TcRef Bool,
 217           -- ^ @True@ <=> Template Haskell syntax used.
 218           --
 219           -- We need this so that we can generate a dependency on the Template
 220           -- Haskell package, becuase the desugarer is going to emit loads of
 221           -- references to TH symbols.  It's rather like tcg_inst_uses; the
 222           -- reference is implicit rather than explicit, so we have to zap a
 223           -- mutable variable.
 224
 225         tcg_dfun_n  :: TcRef OccSet,
 226           -- ^ Allows us to choose unique DFun names.
 227
 228         -- The next fields accumulate the payload of the module
 229         -- The binds, rules and foreign-decl fiels are collected
 230         -- initially in un-zonked form and are finally zonked in tcRnSrcDecls
 231
 232         tcg_rn_exports :: Maybe [Located (IE Name)],
 233         tcg_rn_imports :: [LImportDecl Name],
 234                 -- Keep the renamed imports regardless.  They are not
 235                 -- voluminous and are needed if you want to report unused imports
 236         tcg_used_rdrnames :: TcRef (Set RdrName),
 237         tcg_rn_decls :: Maybe (HsGroup Name),
 238           -- ^ Renamed decls, maybe.  @Nothing@ <=> Don't retain renamed
 239           -- decls.
 240
 241         tcg_binds     :: LHsBinds Id,       -- Value bindings in this module
 242         tcg_warns     :: Warnings,          -- ...Warnings and deprecations
 243         tcg_anns      :: [Annotation],      -- ...Annotations
 244         tcg_insts     :: [Instance],        -- ...Instances
 245         tcg_fam_insts :: [FamInst],         -- ...Family instances
 246         tcg_rules     :: [LRuleDecl Id],    -- ...Rules
 247         tcg_fords     :: [LForeignDecl Id], -- ...Foreign import & exports
 248
 249         tcg_doc :: Maybe (HsDoc Name), -- ^ Maybe Haddock documentation
 250         tcg_hmi :: HaddockModInfo Name, -- ^ Haddock module information
 251         tcg_hpc :: AnyHpcUsage -- ^ @True@ if any part of the prog uses hpc
 252                                -- instrumentation.
 253     }
 254
 255 data RecFieldEnv
 256   = RecFields (NameEnv [Name])  -- Maps a constructor name *in this module*
 257                                 -- to the fields for that constructor
 258               NameSet           -- Set of all fields declared *in this module*;
 259                                 -- used to suppress name-shadowing complaints
 260                                 -- when using record wild cards
 261                                 -- E.g.  let fld = e in C {..}
 262         -- This is used when dealing with ".." notation in record
 263         -- construction and pattern matching.
 264         -- The FieldEnv deals *only* with constructors defined in *this*
 265         -- module.  For imported modules, we get the same info from the
 266         -- TypeEnv
 267 \end{code}
 268
 269 %************************************************************************
 270 %*                                                                      *
 271                 The interface environments
 272               Used when dealing with IfaceDecls
 273 %*                                                                      *
 274 %************************************************************************
 275
 276 \begin{code}
 277 data IfGblEnv
 278   = IfGblEnv {
 279         -- The type environment for the module being compiled,
 280         -- in case the interface refers back to it via a reference that
 281         -- was originally a hi-boot file.
 282         -- We need the module name so we can test when it's appropriate
 283         -- to look in this env.
 284         if_rec_types :: Maybe (Module, IfG TypeEnv)
 285                 -- Allows a read effect, so it can be in a mutable
 286                 -- variable; c.f. handling the external package type env
 287                 -- Nothing => interactive stuff, no loops possible
 288     }
 289
 290 data IfLclEnv
 291   = IfLclEnv {
 292         -- The module for the current IfaceDecl
 293         -- So if we see   f = \x -> x
 294         -- it means M.f = \x -> x, where M is the if_mod
 295         if_mod :: Module,
 296
 297         -- The field is used only for error reporting
 298         -- if (say) there's a Lint error in it
 299         if_loc :: SDoc,
 300                 -- Where the interface came from:
 301                 --      .hi file, or GHCi state, or ext core
 302                 -- plus which bit is currently being examined
 303
 304         if_tv_env  :: UniqFM TyVar,     -- Nested tyvar bindings
 305         if_id_env  :: UniqFM Id         -- Nested id binding
 306     }
 307 \end{code}
 308
 309
 310 %************************************************************************
 311 %*                                                                      *
 312                 The local typechecker environment
 313 %*                                                                      *
 314 %************************************************************************
 315
 316 The Global-Env/Local-Env story
 317 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 318 During type checking, we keep in the tcg_type_env
 319         * All types and classes
 320         * All Ids derived from types and classes (constructors, selectors)
 321
 322 At the end of type checking, we zonk the local bindings,
 323 and as we do so we add to the tcg_type_env
 324         * Locally defined top-level Ids
 325
 326 Why?  Because they are now Ids not TcIds.  This final GlobalEnv is
 327         a) fed back (via the knot) to typechecking the
 328            unfoldings of interface signatures
 329         b) used in the ModDetails of this module
 330
 331 \begin{code}
 332 data TcLclEnv           -- Changes as we move inside an expression
 333                         -- Discarded after typecheck/rename; not passed on to desugarer
 334   = TcLclEnv {
 335         tcl_loc  :: SrcSpan,            -- Source span
 336         tcl_ctxt :: [ErrCtxt],          -- Error context, innermost on top
 337         tcl_errs :: TcRef Messages,     -- Place to accumulate errors
 338
 339         tcl_th_ctxt    :: ThStage,            -- Template Haskell context
 340         tcl_arrow_ctxt :: ArrowCtxt,          -- Arrow-notation context
 341
 342         tcl_rdr :: LocalRdrEnv,         -- Local name envt
 343                 -- Maintained during renaming, of course, but also during
 344                 -- type checking, solely so that when renaming a Template-Haskell
 345                 -- splice we have the right environment for the renamer.
 346                 --
 347                 --   Does *not* include global name envt; may shadow it
 348                 --   Includes both ordinary variables and type variables;
 349                 --   they are kept distinct because tyvar have a different
 350                 --   occurrence contructor (Name.TvOcc)
 351                 -- We still need the unsullied global name env so that
 352                 --   we can look up record field names
 353
 354         tcl_env  :: NameEnv TcTyThing,  -- The local type environment: Ids and
 355                                         -- TyVars defined in this module
 356
 357         tcl_tyvars :: TcRef TcTyVarSet, -- The "global tyvars"
 358                         -- Namely, the in-scope TyVars bound in tcl_env,
 359                         -- plus the tyvars mentioned in the types of Ids bound
 360                         -- in tcl_lenv.
 361                         -- Why mutable? see notes with tcGetGlobalTyVars
 362
 363         tcl_lie   :: TcRef LIE,         -- Place to accumulate type constraints
 364
 365         tcl_tybinds :: TcRef TcTyVarBinds -- Meta and coercion type variable
 366                                           -- bindings accumulated during
 367                                           -- constraint solving
 368     }
 369
 370
 371 {- Note [Given Insts]
 372    ~~~~~~~~~~~~~~~~~~
 373 Because of GADTs, we have to pass inwards the Insts provided by type signatures
 374 and existential contexts. Consider
 375         data T a where { T1 :: b -> b -> T [b] }
 376         f :: Eq a => T a -> Bool
 377         f (T1 x y) = [x]==[y]
 378
 379 The constructor T1 binds an existential variable 'b', and we need Eq [b].
 380 Well, we have it, because Eq a refines to Eq [b], but we can only spot that if we
 381 pass it inwards.
 382
 383 -}
 384
 385 ---------------------------
 386 -- Template Haskell levels
 387 ---------------------------
 388
 389 type ThLevel = Int
 390         -- Indicates how many levels of brackets we are inside
 391         --      (always >= 0)
 392         -- Incremented when going inside a bracket,
 393         -- decremented when going inside a splice
 394         -- NB: ThLevel is one greater than the 'n' in Fig 2 of the
 395         --     original "Template meta-programming for Haskell" paper
 396
 397 impLevel, topLevel :: ThLevel
 398 topLevel = 1    -- Things defined at top level of this module
 399 impLevel = 0    -- Imported things; they can be used inside a top level splice
 400 --
 401 -- For example:
 402 --      f = ...
 403 --      g1 = $(map ...)         is OK
 404 --      g2 = $(f ...)           is not OK; because we havn't compiled f yet
 405
 406
 407 data ThStage
 408   = Comp   ThLevel                      -- Ordinary compiling, usually at level topLevel but annotations use a lower level
 409   | Splice ThLevel                      -- Inside a splice
 410   | Brack  ThLevel                      -- Inside brackets;
 411            (TcRef [PendingSplice])      --   accumulate pending splices here
 412            (TcRef LIE)                  --   and type constraints here
 413 topStage, topAnnStage, topSpliceStage :: ThStage
 414 topStage       = Comp topLevel
 415 topAnnStage    = Comp (topLevel - 1)
 416 topSpliceStage = Splice (topLevel - 1)  -- Stage for the body of a top-level splice
 417
 418 ---------------------------
 419 -- Arrow-notation context
 420 ---------------------------
 421
 422 {-
 423 In arrow notation, a variable bound by a proc (or enclosed let/kappa)
 424 is not in scope to the left of an arrow tail (-<) or the head of (|..|).
 425 For example
 426
 427         proc x -> (e1 -< e2)
 428
 429 Here, x is not in scope in e1, but it is in scope in e2.  This can get
 430 a bit complicated:
 431
 432         let x = 3 in
 433         proc y -> (proc z -> e1) -< e2
 434
 435 Here, x and z are in scope in e1, but y is not.  We implement this by
 436 recording the environment when passing a proc (using newArrowScope),
 437 and returning to that (using escapeArrowScope) on the left of -< and the
 438 head of (|..|).
 439 -}
 440
 441 data ArrowCtxt
 442   = NoArrowCtxt
 443   | ArrowCtxt (Env TcGblEnv TcLclEnv)
 444
 445 -- Record the current environment (outside a proc)
 446 newArrowScope :: TcM a -> TcM a
 447 newArrowScope
 448   = updEnv $ \env ->
 449         env { env_lcl = (env_lcl env) { tcl_arrow_ctxt = ArrowCtxt env } }
 450
 451 -- Return to the stored environment (from the enclosing proc)
 452 escapeArrowScope :: TcM a -> TcM a
 453 escapeArrowScope
 454   = updEnv $ \ env -> case tcl_arrow_ctxt (env_lcl env) of
 455         NoArrowCtxt -> env
 456         ArrowCtxt env' -> env'
 457
 458 ---------------------------
 459 -- TcTyThing
 460 ---------------------------
 461
 462 data TcTyThing
 463   = AGlobal TyThing             -- Used only in the return type of a lookup
 464
 465   | ATcId   {           -- Ids defined in this module; may not be fully zonked
 466         tct_id :: TcId,
 467         tct_co :: RefinementVisibility, -- Previously: Maybe HsWrapper
 468                                         -- Nothing <=>  Do not apply a GADT type refinement
 469                                         --              I am wobbly, or have no free
 470                                         --              type variables
 471                                         -- Just co <=>  Apply any type refinement to me,
 472                                         --              and record it in the coercion
 473         tct_type  :: TcType,    -- Type of (coercion applied to id)
 474         tct_level :: ThLevel }
 475
 476   | ATyVar  Name TcType         -- The type to which the lexically scoped type vaiable
 477                                 -- is currently refined. We only need the Name
 478                                 -- for error-message purposes
 479
 480   | AThing  TcKind              -- Used temporarily, during kind checking, for the
 481                                 --      tycons and clases in this recursive group
 482
 483 data RefinementVisibility
 484   = Unrefineable                        -- Do not apply a GADT refinement
 485                                         -- I have no free variables
 486
 487   | Rigid HsWrapper                     -- Apply any refinement to me
 488                                         -- and record it in the coercion
 489
 490   | Wobbly                              -- Do not apply a GADT refinement
 491                                         -- I am wobbly
 492
 493   | WobblyInvisible                     -- Wobbly type, not available inside current
 494                                         -- GADT refinement
 495
 496 instance Outputable TcTyThing where     -- Debugging only
 497    ppr (AGlobal g)      = pprTyThing g
 498    ppr elt@(ATcId {})   = text "Identifier" <>
 499                           ifPprDebug (brackets (ppr (tct_id elt) <> dcolon <> ppr (tct_type elt) <> comma
 500                                  <+> ppr (tct_level elt) <+> ppr (tct_co elt)))
 501    ppr (ATyVar tv _)    = text "Type variable" <+> quotes (ppr tv)
 502    ppr (AThing k)       = text "AThing" <+> ppr k
 503
 504 pprTcTyThingCategory :: TcTyThing -> SDoc
 505 pprTcTyThingCategory (AGlobal thing) = pprTyThingCategory thing
 506 pprTcTyThingCategory (ATyVar {})     = ptext (sLit "Type variable")
 507 pprTcTyThingCategory (ATcId {})      = ptext (sLit "Local identifier")
 508 pprTcTyThingCategory (AThing {})     = ptext (sLit "Kinded thing")
 509
 510 instance Outputable RefinementVisibility where
 511     ppr Unrefineable          = ptext (sLit "unrefineable")
 512     ppr (Rigid co)            = ptext (sLit "rigid") <+> ppr co
 513     ppr Wobbly                = ptext (sLit "wobbly")
 514     ppr WobblyInvisible       = ptext (sLit "wobbly-invisible")
 515
 516 \end{code}
 517
 518 \begin{code}
 519 type ErrCtxt = (Bool, TidyEnv -> TcM (TidyEnv, Message))
 520         -- Monadic so that we have a chance
 521         -- to deal with bound type variables just before error
 522         -- message construction
 523
 524         -- Bool:  True <=> this is a landmark context; do not
 525         --                 discard it when trimming for display
 526 \end{code}
 527
 528
 529 %************************************************************************
 530 %*                                                                      *
 531         Operations over ImportAvails
 532 %*                                                                      *
 533 %************************************************************************
 534
 535 \begin{code}
 536 -- | 'ImportAvails' summarises what was imported from where, irrespective of
 537 -- whether the imported things are actually used or not.  It is used:
 538 --
 539 --  * when processing the export list,
 540 --
 541 --  * when constructing usage info for the interface file,
 542 --
 543 --  * to identify the list of directly imported modules for initialisation
 544 --    purposes and for optimised overlap checking of family instances,
 545 --
 546 --  * when figuring out what things are really unused
 547 --
 548 data ImportAvails
 549    = ImportAvails {
 550         imp_mods :: ModuleEnv [(ModuleName, Bool, SrcSpan)],
 551           -- ^ Domain is all directly-imported modules
 552           -- The 'ModuleName' is what the module was imported as, e.g. in
 553           -- @
 554           --     import Foo as Bar
 555           -- @
 556           -- it is @Bar@.
 557           --
 558           -- The 'Bool' means:
 559           --
 560           --  - @True@ => import was @import Foo ()@
 561           --
 562           --  - @False@ => import was some other form
 563           --
 564           -- Used
 565           --
 566           --   (a) to help construct the usage information in the interface
 567           --       file; if we import somethign we need to recompile if the
 568           --       export version changes
 569           --
 570           --   (b) to specify what child modules to initialise
 571           --
 572           -- We need a full ModuleEnv rather than a ModuleNameEnv here,
 573           -- because we might be importing modules of the same name from
 574           -- different packages. (currently not the case, but might be in the
 575           -- future).
 576
 577         imp_dep_mods :: ModuleNameEnv (ModuleName, IsBootInterface),
 578           -- ^ Home-package modules needed by the module being compiled
 579           --
 580           -- It doesn't matter whether any of these dependencies
 581           -- are actually /used/ when compiling the module; they
 582           -- are listed if they are below it at all.  For
 583           -- example, suppose M imports A which imports X.  Then
 584           -- compiling M might not need to consult X.hi, but X
 585           -- is still listed in M's dependencies.
 586
 587         imp_dep_pkgs :: [PackageId],
 588           -- ^ Packages needed by the module being compiled, whether directly,
 589           -- or via other modules in this package, or via modules imported
 590           -- from other packages.
 591
 592         imp_orphs :: [Module],
 593           -- ^ Orphan modules below us in the import tree (and maybe including
 594           -- us for imported modules)
 595
 596         imp_finsts :: [Module]
 597           -- ^ Family instance modules below us in the import tree (and maybe
 598           -- including us for imported modules)
 599       }
 600
 601 mkModDeps :: [(ModuleName, IsBootInterface)]
 602           -> ModuleNameEnv (ModuleName, IsBootInterface)
 603 mkModDeps deps = foldl add emptyUFM deps
 604                where
 605                  add env elt@(m,_) = addToUFM env m elt
 606
 607 emptyImportAvails :: ImportAvails
 608 emptyImportAvails = ImportAvails { imp_mods     = emptyModuleEnv,
 609                                    imp_dep_mods = emptyUFM,
 610                                    imp_dep_pkgs = [],
 611                                    imp_orphs    = [],
 612                                    imp_finsts   = [] }
 613
 614 plusImportAvails ::  ImportAvails ->  ImportAvails ->  ImportAvails
 615 plusImportAvails
 616   (ImportAvails { imp_mods = mods1,
 617                   imp_dep_mods = dmods1, imp_dep_pkgs = dpkgs1,
 618                   imp_orphs = orphs1, imp_finsts = finsts1 })
 619   (ImportAvails { imp_mods = mods2,
 620                   imp_dep_mods = dmods2, imp_dep_pkgs = dpkgs2,
 621                   imp_orphs = orphs2, imp_finsts = finsts2 })
 622   = ImportAvails { imp_mods     = plusModuleEnv_C (++) mods1 mods2,
 623                    imp_dep_mods = plusUFM_C plus_mod_dep dmods1 dmods2,
 624                    imp_dep_pkgs = dpkgs1 `unionLists` dpkgs2,
 625                    imp_orphs    = orphs1 `unionLists` orphs2,
 626                    imp_finsts   = finsts1 `unionLists` finsts2 }
 627   where
 628     plus_mod_dep (m1, boot1) (m2, boot2)
 629         = WARN( not (m1 == m2), (ppr m1 <+> ppr m2) $$ (ppr boot1 <+> ppr boot2) )
 630                 -- Check mod-names match
 631           (m1, boot1 && boot2)  -- If either side can "see" a non-hi-boot interface, use that
 632 \end{code}
 633
 634 %************************************************************************
 635 %*                                                                      *
 636 \subsection{Where from}
 637 %*                                                                      *
 638 %************************************************************************
 639
 640 The @WhereFrom@ type controls where the renamer looks for an interface file
 641
 642 \begin{code}
 643 data WhereFrom
 644   = ImportByUser IsBootInterface        -- Ordinary user import (perhaps {-# SOURCE #-})
 645   | ImportBySystem                      -- Non user import.
 646
 647 instance Outputable WhereFrom where
 648   ppr (ImportByUser is_boot) | is_boot     = ptext (sLit "{- SOURCE -}")
 649                              | otherwise   = empty
 650   ppr ImportBySystem                       = ptext (sLit "{- SYSTEM -}")
 651 \end{code}
 652
 653
 654 %************************************************************************
 655 %*                                                                      *
 656 \subsection[Inst-types]{@Inst@ types}
 657 %*                                                                      *
 658 v%************************************************************************
 659
 660 An @Inst@ is either a dictionary, an instance of an overloaded
 661 literal, or an instance of an overloaded value.  We call the latter a
 662 ``method'' even though it may not correspond to a class operation.
 663 For example, we might have an instance of the @double@ function at
 664 type Int, represented by
 665
 666         Method 34 doubleId [Int] origin
 667
 668 In addition to the basic Haskell variants of 'Inst's, they can now also
 669 represent implication constraints 'forall tvs. given => wanted'
 670 and equality constraints 'co :: ty1 ~ ty2'.
 671
 672 NB: Equalities occur in two flavours:
 673
 674   (1) Dict {tci_pred = EqPred ty1 ty2}
 675   (2) EqInst {tci_left = ty1, tci_right = ty2, tci_co = coe}
 676
 677 The former arises from equalities in contexts, whereas the latter is used
 678 whenever the type checker introduces an equality (e.g., during deferring
 679 unification).
 680
 681 I am not convinced that this duplication is necessary or useful! -=chak
 682
 683 \begin{code}
 684 data Inst
 685   = Dict {
 686         tci_name :: Name,
 687         tci_pred :: TcPredType,   -- Class or implicit parameter only
 688         tci_loc  :: InstLoc
 689     }
 690
 691   | ImplicInst {        -- An implication constraint
 692                         -- forall tvs. given => wanted
 693         tci_name   :: Name,
 694         tci_tyvars :: [TcTyVar],    -- Quantified type variables
 695         tci_given  :: [Inst],       -- Only Dicts and EqInsts
 696                                     --   (no Methods, LitInsts, ImplicInsts)
 697         tci_wanted :: [Inst],       -- Only Dicts, EqInst, and ImplicInsts
 698                                     --   (no Methods or LitInsts)
 699
 700         tci_loc    :: InstLoc
 701     }
 702         -- NB: the tci_given are not necessarily rigid
 703
 704   | Method {
 705         tci_id :: TcId,         -- The Id for the Inst
 706
 707         tci_oid :: TcId,        -- The overloaded function
 708                 -- This function will be a global, local, or ClassOpId;
 709                 --   inside instance decls (only) it can also be an InstId!
 710                 -- The id needn't be completely polymorphic.
 711                 -- You'll probably find its name (for documentation purposes)
 712                 --        inside the InstOrigin
 713
 714         tci_tys :: [TcType],    -- The types to which its polymorphic tyvars
 715                                 --      should be instantiated.
 716                                 -- These types must saturate the Id's foralls.
 717
 718         tci_theta :: TcThetaType,
 719                         -- The (types of the) dictionaries to which the function
 720                         -- must be applied to get the method
 721
 722         tci_loc :: InstLoc
 723     }
 724         -- INVARIANT 1: in (Method m f tys theta tau loc)
 725         --      type of m = type of (f tys dicts(from theta))
 726
 727         -- INVARIANT 2: type of m must not be of form (Pred -> Tau)
 728         --   Reason: two methods are considered equal if the
 729         --           base Id matches, and the instantiating types
 730         --           match.  The TcThetaType should then match too.
 731         --   This only bites in the call to tcInstClassOp in TcClassDcl.mkMethodBind
 732
 733   | LitInst {
 734         tci_name :: Name,
 735         tci_lit  :: HsOverLit Name,     -- The literal from the occurrence site
 736                         -- INVARIANT: never a rebindable-syntax literal
 737                         -- Reason: tcSyntaxName does unification, and we
 738                         --         don't want to deal with that during tcSimplify,
 739                         --         when resolving LitInsts
 740
 741         tci_ty :: TcType,       -- The type at which the literal is used
 742         tci_loc :: InstLoc
 743     }
 744
 745   | EqInst {                      -- delayed unification of the form
 746                                   --    co :: ty1 ~ ty2
 747         tci_left  :: TcType,      -- ty1    -- both types are...
 748         tci_right :: TcType,      -- ty2    -- ...free of boxes
 749         tci_co    :: EqInstCo,            -- co
 750         tci_loc   :: InstLoc,
 751
 752         tci_name  :: Name       -- Debugging help only: this makes it easier to
 753                                 -- follow where a constraint is used in a morass
 754                                 -- of trace messages!  Unlike other Insts, it
 755                                 -- has no semantic significance whatsoever.
 756     }
 757
 758 type EqInstCo = Either    -- Distinguish between given and wanted coercions
 759                   TcTyVar   --  - a wanted equation, with a hole, to be filled
 760                             --    with a witness for the equality; for equation
 761                             --    arising from deferring unification, 'ty1' is
 762                             --    the actual and 'ty2' the expected type
 763                   Coercion  --  - a given equation, with a coercion witnessing
 764                             --    the equality; a coercion that originates
 765                             --    from a signature or a GADT is a CoVar, but
 766                             --    after normalisation of coercions, they can
 767                             --    be arbitrary Coercions involving constructors
 768                             --    and pseudo-constructors like sym and trans.
 769 \end{code}
 770
 771 @Insts@ are ordered by their class/type info, rather than by their
 772 unique.  This allows the context-reduction mechanism to use standard finite
 773 maps to do their stuff.  It's horrible that this code is here, rather
 774 than with the Avails handling stuff in TcSimplify
 775
 776 \begin{code}
 777 instance Ord Inst where
 778    compare = cmpInst
 779         -- Used *only* for AvailEnv in TcSimplify
 780
 781 instance Eq Inst where
 782   (==) i1 i2 = case i1 `cmpInst` i2 of
 783                EQ -> True
 784                _  -> False
 785
 786 cmpInst :: Inst -> Inst -> Ordering
 787 cmpInst d1@(Dict {})    d2@(Dict {})    = tci_pred d1 `tcCmpPred` tci_pred d2
 788 cmpInst (Dict {})       _               = LT
 789
 790 cmpInst (Method {})     (Dict {})       = GT
 791 cmpInst m1@(Method {})  m2@(Method {})  = (tci_oid m1 `compare` tci_oid m2) `thenCmp`
 792                                           (tci_tys m1 `tcCmpTypes` tci_tys m2)
 793 cmpInst (Method {})     _               = LT
 794
 795 cmpInst (LitInst {})    (Dict {})       = GT
 796 cmpInst (LitInst {})    (Method {})     = GT
 797 cmpInst l1@(LitInst {}) l2@(LitInst {}) = (tci_lit l1 `compare` tci_lit l2) `thenCmp`
 798                                           (tci_ty l1 `tcCmpType` tci_ty l2)
 799 cmpInst (LitInst {})    _               = LT
 800
 801         -- Implication constraints are compared by *name*
 802         -- not by type; that is, we make no attempt to do CSE on them
 803 cmpInst (ImplicInst {})    (Dict {})          = GT
 804 cmpInst (ImplicInst {})    (Method {})        = GT
 805 cmpInst (ImplicInst {})    (LitInst {})       = GT
 806 cmpInst i1@(ImplicInst {}) i2@(ImplicInst {}) = tci_name i1 `compare` tci_name i2
 807 cmpInst (ImplicInst {})    _                  = LT
 808
 809         -- same for Equality constraints
 810 cmpInst (EqInst {})    (Dict {})       = GT
 811 cmpInst (EqInst {})    (Method {})     = GT
 812 cmpInst (EqInst {})    (LitInst {})    = GT
 813 cmpInst (EqInst {})    (ImplicInst {}) = GT
 814 cmpInst i1@(EqInst {}) i2@(EqInst {})  = (tci_left  i1 `tcCmpType` tci_left  i2) `thenCmp`
 815                                          (tci_right i1 `tcCmpType` tci_right i2)
 816 \end{code}
 817
 818
 819 %************************************************************************
 820 %*                                                                      *
 821 \subsection[Inst-collections]{LIE: a collection of Insts}
 822 %*                                                                      *
 823 %************************************************************************
 824
 825 \begin{code}
 826 -- FIXME: Rename this. It clashes with (Located (IE ...))
 827 type LIE = Bag Inst
 828
 829 isEmptyLIE :: LIE -> Bool
 830 isEmptyLIE = isEmptyBag
 831
 832 emptyLIE :: LIE
 833 emptyLIE = emptyBag
 834
 835 unitLIE :: Inst -> LIE
 836 unitLIE inst = unitBag inst
 837
 838 mkLIE :: [Inst] -> LIE
 839 mkLIE insts = listToBag insts
 840
 841 plusLIE :: LIE -> LIE -> LIE
 842 plusLIE lie1 lie2 = lie1 `unionBags` lie2
 843
 844 plusLIEs :: [LIE] -> LIE
 845 plusLIEs lies = unionManyBags lies
 846
 847 lieToList :: LIE -> [Inst]
 848 lieToList = bagToList
 849
 850 listToLIE :: [Inst] -> LIE
 851 listToLIE = listToBag
 852
 853 consLIE :: Inst -> LIE -> LIE
 854 consLIE inst lie  = lie `snocBag` inst
 855 -- Putting the new Inst at the *end* of the bag is a half-hearted attempt
 856 -- to ensure that we tend to report the *leftmost* type-constraint error
 857 -- E.g.         f :: [a]
 858 --              f = [1,2,3]
 859 -- we'd like to complain about the '1', not the '3'.
 860 --
 861 -- "Half-hearted" because the rest of the type checker makes no great
 862 -- claims for retaining order in the constraint set.  Still, this
 863 -- seems to improve matters slightly.  Exampes: mdofail001, tcfail015
 864 \end{code}
 865
 866
 867 %************************************************************************
 868 %*                                                                      *
 869 \subsection[Inst-origin]{The @InstOrigin@ type}
 870 %*                                                                      *
 871 %************************************************************************
 872
 873 The @InstOrigin@ type gives information about where a dictionary came from.
 874 This is important for decent error message reporting because dictionaries
 875 don't appear in the original source code.  Doubtless this type will evolve...
 876
 877 It appears in TcMonad because there are a couple of error-message-generation
 878 functions that deal with it.
 879
 880 \begin{code}
 881 -------------------------------------------
 882 data InstLoc = InstLoc InstOrigin SrcSpan [ErrCtxt]
 883
 884 instLoc :: Inst -> InstLoc
 885 instLoc inst = tci_loc inst
 886
 887 setInstLoc :: Inst -> InstLoc -> Inst
 888 setInstLoc inst new_loc = inst { tci_loc = new_loc }
 889
 890 instSpan :: Inst -> SrcSpan
 891 instSpan wanted = instLocSpan (instLoc wanted)
 892
 893 instLocSpan :: InstLoc -> SrcSpan
 894 instLocSpan (InstLoc _ s _) = s
 895
 896 instLocOrigin :: InstLoc -> InstOrigin
 897 instLocOrigin (InstLoc o _ _) = o
 898
 899 pprInstArising :: Inst -> SDoc
 900 pprInstArising loc = ptext (sLit "arising from") <+> pprInstLoc (tci_loc loc)
 901
 902 pprInstLoc :: InstLoc -> SDoc
 903 pprInstLoc (InstLoc orig span _) = sep [ppr orig, text "at" <+> ppr span]
 904
 905 -------------------------------------------
 906 data InstOrigin
 907   = SigOrigin SkolemInfo        -- Pattern, class decl, inst decl etc;
 908                                 -- Places that bind type variables and introduce
 909                                 -- available constraints
 910
 911   | IPBindOrigin (IPName Name)  -- Binding site of an implicit parameter
 912
 913         -------------------------------------------------------
 914         -- The rest are all occurrences: Insts that are 'wanted'
 915         -------------------------------------------------------
 916   | OccurrenceOf Name           -- Occurrence of an overloaded identifier
 917   | SpecPragOrigin Name         -- Specialisation pragma for identifier
 918
 919   | IPOccOrigin  (IPName Name)  -- Occurrence of an implicit parameter
 920
 921   | LiteralOrigin (HsOverLit Name)      -- Occurrence of a literal
 922   | NegateOrigin                        -- Occurrence of syntactic negation
 923
 924   | ArithSeqOrigin (ArithSeqInfo Name) -- [x..], [x..y] etc
 925   | PArrSeqOrigin  (ArithSeqInfo Name) -- [:x..y:] and [:x,y..z:]
 926   | TupleOrigin                        -- (..,..)
 927
 928   | InstSigOrigin       -- A dict occurrence arising from instantiating
 929                         -- a polymorphic type during a subsumption check
 930
 931   | ExprSigOrigin       -- e :: ty
 932   | RecordUpdOrigin
 933   | ViewPatOrigin
 934
 935   | InstScOrigin        -- Typechecking superclasses of an instance declaration
 936
 937   | NoScOrigin          -- A very special hack; see TcSimplify,
 938                         --   Note [Recursive instances and superclases]
 939
 940
 941   | DerivOrigin         -- Typechecking deriving
 942   | StandAloneDerivOrigin -- Typechecking stand-alone deriving
 943   | DefaultOrigin       -- Typechecking a default decl
 944   | DoOrigin            -- Arising from a do expression
 945   | ProcOrigin          -- Arising from a proc expression
 946   | ImplicOrigin SDoc   -- An implication constraint
 947   | EqOrigin            -- A type equality
 948   | AnnOrigin           -- An annotation
 949
 950 instance Outputable InstOrigin where
 951     ppr (OccurrenceOf name)   = hsep [ptext (sLit "a use of"), quotes (ppr name)]
 952     ppr (SpecPragOrigin name) = hsep [ptext (sLit "a specialisation pragma for"), quotes (ppr name)]
 953     ppr (IPOccOrigin name)    = hsep [ptext (sLit "a use of implicit parameter"), quotes (ppr name)]
 954     ppr (IPBindOrigin name)   = hsep [ptext (sLit "a binding for implicit parameter"), quotes (ppr name)]
 955     ppr RecordUpdOrigin       = ptext (sLit "a record update")
 956     ppr ExprSigOrigin         = ptext (sLit "an expression type signature")
 957     ppr ViewPatOrigin         = ptext (sLit "a view pattern")
 958     ppr (LiteralOrigin lit)   = hsep [ptext (sLit "the literal"), quotes (ppr lit)]
 959     ppr (ArithSeqOrigin seq)  = hsep [ptext (sLit "the arithmetic sequence"), quotes (ppr seq)]
 960     ppr (PArrSeqOrigin seq)   = hsep [ptext (sLit "the parallel array sequence"), quotes (ppr seq)]
 961     ppr TupleOrigin           = ptext (sLit "a tuple")
 962     ppr NegateOrigin          = ptext (sLit "a use of syntactic negation")
 963     ppr InstScOrigin          = ptext (sLit "the superclasses of an instance declaration")
 964     ppr NoScOrigin            = ptext (sLit "an instance declaration")
 965     ppr DerivOrigin           = ptext (sLit "the 'deriving' clause of a data type declaration")
 966     ppr StandAloneDerivOrigin = ptext (sLit "a 'deriving' declaration")
 967     ppr DefaultOrigin         = ptext (sLit "a 'default' declaration")
 968     ppr DoOrigin              = ptext (sLit "a do statement")
 969     ppr ProcOrigin            = ptext (sLit "a proc expression")
 970     ppr (ImplicOrigin doc)    = doc
 971     ppr (SigOrigin info)      = pprSkolInfo info
 972     ppr EqOrigin              = ptext (sLit "a type equality")
 973     ppr InstSigOrigin         = panic "ppr InstSigOrigin"
 974     ppr AnnOrigin             = ptext (sLit "an annotation")
 975 \end{code}