compiler/typecheck/TcRnTypes.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP Project, Glasgow University, 1992-2002
   4 %
   5 \begin{code}
   6 module TcRnTypes(
   7         TcRnIf, TcRn, TcM, RnM, IfM, IfL, IfG, -- The monad is opaque outside this module
   8         TcRef,
   9
  10         -- The environment types
  11         Env(..),
  12         TcGblEnv(..), TcLclEnv(..),
  13         IfGblEnv(..), IfLclEnv(..),
  14
  15         -- Ranamer types
  16         ErrCtxt,
  17         ImportAvails(..), emptyImportAvails, plusImportAvails,
  18         plusAvail, pruneAvails,
  19         AvailEnv, emptyAvailEnv, unitAvailEnv, plusAvailEnv,
  20         mkAvailEnv, lookupAvailEnv, lookupAvailEnv_maybe, availEnvElts, addAvail,
  21         WhereFrom(..), mkModDeps,
  22
  23         -- Typechecker types
  24         TcTyThing(..), pprTcTyThingCategory,
  25
  26         -- Template Haskell
  27         ThStage(..), topStage, topSpliceStage,
  28         ThLevel, impLevel, topLevel,
  29
  30         -- Arrows
  31         ArrowCtxt(NoArrowCtxt), newArrowScope, escapeArrowScope,
  32
  33         -- Insts
  34         Inst(..), InstOrigin(..), InstLoc(..), pprInstLoc,
  35         instLocSrcLoc, instLocSrcSpan,
  36         LIE, emptyLIE, unitLIE, plusLIE, consLIE,
  37         plusLIEs, mkLIE, isEmptyLIE, lieToList, listToLIE,
  38
  39         -- Misc other types
  40         TcId, TcIdSet, TcDictBinds
  41   ) where
  42
  43 #include "HsVersions.h"
  44
  45 import HsSyn hiding (LIE)
  46 import HscTypes
  47 import Packages
  48 import Type
  49 import TcType
  50 import InstEnv
  51 import FamInstEnv
  52 import IOEnv
  53 import RdrName
  54 import Name
  55 import NameEnv
  56 import NameSet
  57 import Var
  58 import VarEnv
  59 import Module
  60 import UniqFM
  61 import SrcLoc
  62 import VarSet
  63 import ErrUtils
  64 import UniqSupply
  65 import BasicTypes
  66 import Util
  67 import Bag
  68 import Outputable
  69 import ListSetOps
  70
  71 import Data.Maybe
  72 import Data.List
  73 \end{code}
  74
  75
  76 %************************************************************************
  77 %*                                                                      *
  78                Standard monad definition for TcRn
  79     All the combinators for the monad can be found in TcRnMonad
  80 %*                                                                      *
  81 %************************************************************************
  82
  83 The monad itself has to be defined here, because it is mentioned by ErrCtxt
  84
  85 \begin{code}
  86 type TcRef a     = IORef a
  87 type TcId        = Id                   -- Type may be a TcType
  88 type TcIdSet     = IdSet
  89 type TcDictBinds = DictBinds TcId       -- Bag of dictionary bindings
  90
  91 type TcRnIf a b c = IOEnv (Env a b) c
  92 type IfM lcl a  = TcRnIf IfGblEnv lcl a         -- Iface stuff
  93
  94 type IfG a  = IfM () a                          -- Top level
  95 type IfL a  = IfM IfLclEnv a                    -- Nested
  96 type TcRn a = TcRnIf TcGblEnv TcLclEnv a
  97 type RnM  a = TcRn a            -- Historical
  98 type TcM  a = TcRn a            -- Historical
  99 \end{code}
 100
 101
 102 %************************************************************************
 103 %*                                                                      *
 104                 The main environment types
 105 %*                                                                      *
 106 %************************************************************************
 107
 108 \begin{code}
 109 data Env gbl lcl        -- Changes as we move into an expression
 110   = Env {
 111         env_top  :: HscEnv,     -- Top-level stuff that never changes
 112                                 -- Includes all info about imported things
 113
 114         env_us   :: {-# UNPACK #-} !(IORef UniqSupply),
 115                                 -- Unique supply for local varibles
 116
 117         env_gbl  :: gbl,        -- Info about things defined at the top level
 118                                 -- of the module being compiled
 119
 120         env_lcl  :: lcl         -- Nested stuff; changes as we go into
 121                                 -- an expression
 122     }
 123
 124 -- TcGblEnv describes the top-level of the module at the
 125 -- point at which the typechecker is finished work.
 126 -- It is this structure that is handed on to the desugarer
 127
 128 data TcGblEnv
 129   = TcGblEnv {
 130         tcg_mod     :: Module,          -- Module being compiled
 131         tcg_src     :: HscSource,       -- What kind of module
 132                                         -- (regular Haskell, hs-boot, ext-core)
 133
 134         tcg_rdr_env :: GlobalRdrEnv,    -- Top level envt; used during renaming
 135         tcg_default :: Maybe [Type],    -- Types used for defaulting
 136                                         -- Nothing => no 'default' decl
 137
 138         tcg_fix_env  :: FixityEnv,      -- Just for things in this module
 139
 140         tcg_type_env :: TypeEnv,        -- Global type env for the module we are compiling now
 141                 -- All TyCons and Classes (for this module) end up in here right away,
 142                 -- along with their derived constructors, selectors.
 143                 --
 144                 -- (Ids defined in this module start in the local envt,
 145                 --  though they move to the global envt during zonking)
 146
 147         tcg_type_env_var :: TcRef TypeEnv,
 148                 -- Used only to initialise the interface-file
 149                 -- typechecker in initIfaceTcRn, so that it can see stuff
 150                 -- bound in this module when dealing with hi-boot recursions
 151                 -- Updated at intervals (e.g. after dealing with types and classes)
 152
 153         tcg_inst_env     :: InstEnv,    -- Instance envt for *home-package*
 154                                         -- modules; Includes the dfuns in
 155                                         -- tcg_insts
 156         tcg_fam_inst_env :: FamInstEnv, -- Ditto for family instances
 157
 158                 -- Now a bunch of things about this module that are simply
 159                 -- accumulated, but never consulted until the end.
 160                 -- Nevertheless, it's convenient to accumulate them along
 161                 -- with the rest of the info from this module.
 162         tcg_exports :: [AvailInfo],     -- What is exported
 163         tcg_imports :: ImportAvails,    -- Information about what was imported
 164                                         --    from where, including things bound
 165                                         --    in this module
 166
 167         tcg_dus :: DefUses,     -- What is defined in this module and what is used.
 168                                 -- The latter is used to generate
 169                                 --      (a) version tracking; no need to recompile if these
 170                                 --              things have not changed version stamp
 171                                 --      (b) unused-import info
 172
 173         tcg_keep :: TcRef NameSet,      -- Locally-defined top-level names to keep alive
 174                 -- "Keep alive" means give them an Exported flag, so
 175                 -- that the simplifier does not discard them as dead
 176                 -- code, and so that they are exposed in the interface file
 177                 -- (but not to export to the user).
 178                 --
 179                 -- Some things, like dict-fun Ids and default-method Ids are
 180                 -- "born" with the Exported flag on, for exactly the above reason,
 181                 -- but some we only discover as we go.  Specifically:
 182                 --      * The to/from functions for generic data types
 183                 --      * Top-level variables appearing free in the RHS of an orphan rule
 184                 --      * Top-level variables appearing free in a TH bracket
 185
 186         tcg_inst_uses :: TcRef NameSet, -- Home-package Dfuns actually used
 187                 -- Used to generate version dependencies
 188                 -- This records usages, rather like tcg_dus, but it has to
 189                 -- be a mutable variable so it can be augmented
 190                 -- when we look up an instance.  These uses of dfuns are
 191                 -- rather like the free variables of the program, but
 192                 -- are implicit instead of explicit.
 193
 194         tcg_th_used :: TcRef Bool,      -- True <=> Template Haskell syntax used
 195                 -- We need this so that we can generate a dependency on the
 196                 -- Template Haskell package, becuase the desugarer is going to
 197                 -- emit loads of references to TH symbols.  It's rather like
 198                 -- tcg_inst_uses; the reference is implicit rather than explicit,
 199                 -- so we have to zap a mutable variable.
 200
 201         tcg_dfun_n  :: TcRef Int,       -- Allows us to number off the names of DFuns
 202                 -- It's convenient to allocate an External Name for a DFun, with
 203                 -- a permanently-fixed unique, just like other top-level functions
 204                 -- defined in this module.  But that means we need a canonical
 205                 -- occurrence name, distinct from all other dfuns in this module,
 206                 -- and this name supply serves that purpose (df1, df2, etc).
 207
 208                 -- The next fields accumulate the payload of the module
 209                 -- The binds, rules and foreign-decl fiels are collected
 210                 -- initially in un-zonked form and are finally zonked in tcRnSrcDecls
 211
 212                 -- The next fields accumulate the payload of the
 213                 -- module The binds, rules and foreign-decl fiels are
 214                 -- collected initially in un-zonked form and are
 215                 -- finally zonked in tcRnSrcDecls
 216
 217         tcg_rn_imports :: Maybe [LImportDecl Name],
 218         tcg_rn_exports :: Maybe [Located (IE Name)],
 219         tcg_rn_decls :: Maybe (HsGroup Name),   -- renamed decls, maybe
 220                 -- Nothing <=> Don't retain renamed decls
 221
 222         tcg_binds     :: LHsBinds Id,       -- Value bindings in this module
 223         tcg_deprecs   :: Deprecations,      -- ...Deprecations
 224         tcg_insts     :: [Instance],        -- ...Instances
 225         tcg_fam_insts :: [FamInst],         -- ...Family instances
 226         tcg_rules     :: [LRuleDecl Id],    -- ...Rules
 227         tcg_fords     :: [LForeignDecl Id], -- ...Foreign import & exports
 228
 229         tcg_doc :: Maybe (HsDoc Name), -- Maybe Haddock documentation
 230         tcg_hmi :: HaddockModInfo Name -- Haddock module information
 231     }
 232 \end{code}
 233
 234 %************************************************************************
 235 %*                                                                      *
 236                 The interface environments
 237               Used when dealing with IfaceDecls
 238 %*                                                                      *
 239 %************************************************************************
 240
 241 \begin{code}
 242 data IfGblEnv
 243   = IfGblEnv {
 244         -- The type environment for the module being compiled,
 245         -- in case the interface refers back to it via a reference that
 246         -- was originally a hi-boot file.
 247         -- We need the module name so we can test when it's appropriate
 248         -- to look in this env.
 249         if_rec_types :: Maybe (Module, IfG TypeEnv)
 250                 -- Allows a read effect, so it can be in a mutable
 251                 -- variable; c.f. handling the external package type env
 252                 -- Nothing => interactive stuff, no loops possible
 253     }
 254
 255 data IfLclEnv
 256   = IfLclEnv {
 257         -- The module for the current IfaceDecl
 258         -- So if we see   f = \x -> x
 259         -- it means M.f = \x -> x, where M is the if_mod
 260         if_mod :: Module,
 261
 262         -- The field is used only for error reporting
 263         -- if (say) there's a Lint error in it
 264         if_loc :: SDoc,
 265                 -- Where the interface came from:
 266                 --      .hi file, or GHCi state, or ext core
 267                 -- plus which bit is currently being examined
 268
 269         if_tv_env  :: UniqFM TyVar,     -- Nested tyvar bindings
 270         if_id_env  :: UniqFM Id         -- Nested id binding
 271     }
 272 \end{code}
 273
 274
 275 %************************************************************************
 276 %*                                                                      *
 277                 The local typechecker environment
 278 %*                                                                      *
 279 %************************************************************************
 280
 281 The Global-Env/Local-Env story
 282 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 283 During type checking, we keep in the tcg_type_env
 284         * All types and classes
 285         * All Ids derived from types and classes (constructors, selectors)
 286
 287 At the end of type checking, we zonk the local bindings,
 288 and as we do so we add to the tcg_type_env
 289         * Locally defined top-level Ids
 290
 291 Why?  Because they are now Ids not TcIds.  This final GlobalEnv is
 292         a) fed back (via the knot) to typechecking the
 293            unfoldings of interface signatures
 294         b) used in the ModDetails of this module
 295
 296 \begin{code}
 297 data TcLclEnv           -- Changes as we move inside an expression
 298                         -- Discarded after typecheck/rename; not passed on to desugarer
 299   = TcLclEnv {
 300         tcl_loc  :: SrcSpan,            -- Source span
 301         tcl_ctxt :: ErrCtxt,            -- Error context
 302         tcl_errs :: TcRef Messages,     -- Place to accumulate errors
 303
 304         tcl_th_ctxt    :: ThStage,      -- Template Haskell context
 305         tcl_arrow_ctxt :: ArrowCtxt,    -- Arrow-notation context
 306
 307         tcl_rdr :: LocalRdrEnv,         -- Local name envt
 308                 -- Maintained during renaming, of course, but also during
 309                 -- type checking, solely so that when renaming a Template-Haskell
 310                 -- splice we have the right environment for the renamer.
 311                 --
 312                 --   Does *not* include global name envt; may shadow it
 313                 --   Includes both ordinary variables and type variables;
 314                 --   they are kept distinct because tyvar have a different
 315                 --   occurrence contructor (Name.TvOcc)
 316                 -- We still need the unsullied global name env so that
 317                 --   we can look up record field names
 318
 319         tcl_env  :: NameEnv TcTyThing,  -- The local type environment: Ids and TyVars
 320                                         -- defined in this module
 321
 322         tcl_tyvars :: TcRef TcTyVarSet, -- The "global tyvars"
 323                         -- Namely, the in-scope TyVars bound in tcl_env,
 324                         -- plus the tyvars mentioned in the types of Ids bound in tcl_lenv
 325                         -- Why mutable? see notes with tcGetGlobalTyVars
 326
 327         tcl_lie   :: TcRef LIE          -- Place to accumulate type constraints
 328     }
 329
 330
 331 {- Note [Given Insts]
 332    ~~~~~~~~~~~~~~~~~~
 333 Because of GADTs, we have to pass inwards the Insts provided by type signatures
 334 and existential contexts. Consider
 335         data T a where { T1 :: b -> b -> T [b] }
 336         f :: Eq a => T a -> Bool
 337         f (T1 x y) = [x]==[y]
 338
 339 The constructor T1 binds an existential variable 'b', and we need Eq [b].
 340 Well, we have it, because Eq a refines to Eq [b], but we can only spot that if we
 341 pass it inwards.
 342
 343 -}
 344
 345 ---------------------------
 346 -- Template Haskell levels
 347 ---------------------------
 348
 349 type ThLevel = Int
 350         -- Indicates how many levels of brackets we are inside
 351         --      (always >= 0)
 352         -- Incremented when going inside a bracket,
 353         -- decremented when going inside a splice
 354         -- NB: ThLevel is one greater than the 'n' in Fig 2 of the
 355         --     original "Template meta-programmign for Haskell" paper
 356
 357 impLevel, topLevel :: ThLevel
 358 topLevel = 1    -- Things defined at top level of this module
 359 impLevel = 0    -- Imported things; they can be used inside a top level splice
 360 --
 361 -- For example:
 362 --      f = ...
 363 --      g1 = $(map ...)         is OK
 364 --      g2 = $(f ...)           is not OK; because we havn't compiled f yet
 365
 366
 367 data ThStage
 368   = Comp                                -- Ordinary compiling, at level topLevel
 369   | Splice ThLevel                      -- Inside a splice
 370   | Brack  ThLevel                      -- Inside brackets;
 371            (TcRef [PendingSplice])      --   accumulate pending splices here
 372            (TcRef LIE)                  --   and type constraints here
 373 topStage, topSpliceStage :: ThStage
 374 topStage       = Comp
 375 topSpliceStage = Splice (topLevel - 1)  -- Stage for the body of a top-level splice
 376
 377 ---------------------------
 378 -- Arrow-notation context
 379 ---------------------------
 380
 381 {-
 382 In arrow notation, a variable bound by a proc (or enclosed let/kappa)
 383 is not in scope to the left of an arrow tail (-<) or the head of (|..|).
 384 For example
 385
 386         proc x -> (e1 -< e2)
 387
 388 Here, x is not in scope in e1, but it is in scope in e2.  This can get
 389 a bit complicated:
 390
 391         let x = 3 in
 392         proc y -> (proc z -> e1) -< e2
 393
 394 Here, x and z are in scope in e1, but y is not.  We implement this by
 395 recording the environment when passing a proc (using newArrowScope),
 396 and returning to that (using escapeArrowScope) on the left of -< and the
 397 head of (|..|).
 398 -}
 399
 400 data ArrowCtxt
 401   = NoArrowCtxt
 402   | ArrowCtxt (Env TcGblEnv TcLclEnv)
 403
 404 -- Record the current environment (outside a proc)
 405 newArrowScope :: TcM a -> TcM a
 406 newArrowScope
 407   = updEnv $ \env ->
 408         env { env_lcl = (env_lcl env) { tcl_arrow_ctxt = ArrowCtxt env } }
 409
 410 -- Return to the stored environment (from the enclosing proc)
 411 escapeArrowScope :: TcM a -> TcM a
 412 escapeArrowScope
 413   = updEnv $ \ env -> case tcl_arrow_ctxt (env_lcl env) of
 414         NoArrowCtxt -> env
 415         ArrowCtxt env' -> env'
 416
 417 ---------------------------
 418 -- TcTyThing
 419 ---------------------------
 420
 421 data TcTyThing
 422   = AGlobal TyThing             -- Used only in the return type of a lookup
 423
 424   | ATcId   {           -- Ids defined in this module; may not be fully zonked
 425         tct_id :: TcId,
 426         tct_co :: Maybe HsWrapper,      -- Nothing <=>  Do not apply a GADT type refinement
 427                                         --              I am wobbly, or have no free
 428                                         --              type variables
 429                                         -- Just co <=>  Apply any type refinement to me,
 430                                         --              and record it in the coercion
 431         tct_type  :: TcType,    -- Type of (coercion applied to id)
 432         tct_level :: ThLevel }
 433
 434   | ATyVar  Name TcType         -- The type to which the lexically scoped type vaiable
 435                                 -- is currently refined. We only need the Name
 436                                 -- for error-message purposes
 437
 438   | AThing  TcKind              -- Used temporarily, during kind checking, for the
 439                                 --      tycons and clases in this recursive group
 440
 441 instance Outputable TcTyThing where     -- Debugging only
 442    ppr (AGlobal g)      = ppr g
 443    ppr elt@(ATcId {})   = text "Identifier" <>
 444                           ifPprDebug (brackets (ppr (tct_id elt) <> dcolon <> ppr (tct_type elt) <> comma
 445                                  <+> ppr (tct_level elt) <+> ppr (tct_co elt)))
 446    ppr (ATyVar tv _)    = text "Type variable" <+> quotes (ppr tv)
 447    ppr (AThing k)       = text "AThing" <+> ppr k
 448
 449 pprTcTyThingCategory :: TcTyThing -> SDoc
 450 pprTcTyThingCategory (AGlobal thing) = pprTyThingCategory thing
 451 pprTcTyThingCategory (ATyVar {})     = ptext SLIT("Type variable")
 452 pprTcTyThingCategory (ATcId {})      = ptext SLIT("Local identifier")
 453 pprTcTyThingCategory (AThing {})     = ptext SLIT("Kinded thing")
 454 \end{code}
 455
 456 \begin{code}
 457 type ErrCtxt = [TidyEnv -> TcM (TidyEnv, Message)]
 458                         -- Innermost first.  Monadic so that we have a chance
 459                         -- to deal with bound type variables just before error
 460                         -- message construction
 461 \end{code}
 462
 463
 464 %************************************************************************
 465 %*                                                                      *
 466         Operations over ImportAvails
 467 %*                                                                      *
 468 %************************************************************************
 469
 470 ImportAvails summarises what was imported from where, irrespective
 471 of whether the imported things are actually used or not
 472 It is used      * when processing the export list
 473                 * when constructing usage info for the inteface file
 474                 * to identify the list of directly imported modules
 475                         for initialisation purposes
 476                 * when figuring out what things are really unused
 477
 478 \begin{code}
 479 data ImportAvails
 480    = ImportAvails {
 481         imp_env :: ModuleNameEnv [AvailInfo],
 482                 -- All the things imported *unqualified*, classified by
 483                 -- the *module qualifier* for its import
 484                 --   e.g.        import List as Foo
 485                 -- would add a binding Foo |-> ...stuff from List...
 486                 -- to imp_env.
 487                 --
 488                 -- This is exactly the list of things that will be exported
 489                 -- by a 'module M' specifier in the export list.
 490                 -- (see Haskell 98 Report Section 5.2).
 491                 --
 492                 -- Warning: there may be duplciates in this list,
 493                 -- duplicates are removed at the use site (rnExports).
 494                 -- We might consider turning this into a NameEnv at
 495                 -- some point.
 496
 497         imp_mods :: ModuleEnv (Module, Bool, SrcSpan),
 498                 -- Domain is all directly-imported modules
 499                 -- Bool means:
 500                 --   True => import was "import Foo ()"
 501                 --   False  => import was some other form
 502                 --
 503                 -- We need the Module in the range because we can't get
 504                 --      the keys of a ModuleEnv
 505                 -- Used
 506                 --   (a) to help construct the usage information in
 507                 --       the interface file; if we import somethign we
 508                 --       need to recompile if the export version changes
 509                 --   (b) to specify what child modules to initialise
 510                 --
 511                 -- We need a full ModuleEnv rather than a ModuleNameEnv
 512                 -- here, because we might be importing modules of the
 513                 -- same name from different packages. (currently not the case,
 514                 -- but might be in the future).
 515
 516         imp_dep_mods :: ModuleNameEnv (ModuleName, IsBootInterface),
 517                 -- Home-package modules needed by the module being compiled
 518                 --
 519                 -- It doesn't matter whether any of these dependencies
 520                 -- are actually *used* when compiling the module; they
 521                 -- are listed if they are below it at all.  For
 522                 -- example, suppose M imports A which imports X.  Then
 523                 -- compiling M might not need to consult X.hi, but X
 524                 -- is still listed in M's dependencies.
 525
 526         imp_dep_pkgs :: [PackageId],
 527                 -- Packages needed by the module being compiled, whether
 528                 -- directly, or via other modules in this package, or via
 529                 -- modules imported from other packages.
 530
 531         imp_orphs :: [Module],
 532                 -- Orphan modules below us in the import tree
 533
 534         imp_parent :: NameEnv AvailInfo
 535                 -- for the names in scope in this module, tells us
 536                 -- the relationship between parents and children
 537                 -- (eg. a TyCon is the parent of its DataCons, a
 538                 -- class is the parent of its methods, etc.).
 539       }
 540
 541 mkModDeps :: [(ModuleName, IsBootInterface)]
 542           -> ModuleNameEnv (ModuleName, IsBootInterface)
 543 mkModDeps deps = foldl add emptyUFM deps
 544                where
 545                  add env elt@(m,_) = addToUFM env m elt
 546
 547 emptyImportAvails :: ImportAvails
 548 emptyImportAvails = ImportAvails { imp_env      = emptyUFM,
 549                                    imp_mods     = emptyModuleEnv,
 550                                    imp_dep_mods = emptyUFM,
 551                                    imp_dep_pkgs = [],
 552                                    imp_orphs    = [],
 553                                    imp_parent   = emptyNameEnv }
 554
 555 plusImportAvails ::  ImportAvails ->  ImportAvails ->  ImportAvails
 556 plusImportAvails
 557   (ImportAvails { imp_env = env1, imp_mods = mods1,
 558                   imp_dep_mods = dmods1, imp_dep_pkgs = dpkgs1,
 559                   imp_orphs = orphs1, imp_parent = parent1 })
 560   (ImportAvails { imp_env = env2, imp_mods = mods2,
 561                   imp_dep_mods = dmods2, imp_dep_pkgs = dpkgs2,
 562                   imp_orphs = orphs2, imp_parent = parent2  })
 563   = ImportAvails { imp_env      = plusUFM_C (++) env1 env2,
 564                    imp_mods     = mods1  `plusModuleEnv` mods2,
 565                    imp_dep_mods = plusUFM_C plus_mod_dep dmods1 dmods2,
 566                    imp_dep_pkgs = dpkgs1 `unionLists` dpkgs2,
 567                    imp_orphs    = orphs1 `unionLists` orphs2,
 568                    imp_parent   = plusNameEnv_C plus_avails parent1 parent2 }
 569   where
 570     plus_avails (AvailTC tc subs1) (AvailTC _ subs2)
 571                 = AvailTC tc (nub (subs1 ++ subs2))
 572     plus_avails avail _ = avail
 573
 574     plus_mod_dep (m1, boot1) (m2, boot2)
 575         = WARN( not (m1 == m2), (ppr m1 <+> ppr m2) $$ (ppr boot1 <+> ppr boot2) )
 576                 -- Check mod-names match
 577           (m1, boot1 && boot2)  -- If either side can "see" a non-hi-boot interface, use that
 578 \end{code}
 579
 580 %************************************************************************
 581 %*                                                                      *
 582         Avails, AvailEnv, etc
 583 %*                                                                      *
 584 v%************************************************************************
 585
 586 \begin{code}
 587 plusAvail (Avail n1)       (Avail n2)       = Avail n1
 588 plusAvail (AvailTC n1 ns1) (AvailTC n2 ns2) = AvailTC n2 (ns1 `unionLists` ns2)
 589 -- Added SOF 4/97
 590 #ifdef DEBUG
 591 plusAvail a1 a2 = pprPanic "RnEnv.plusAvail" (hsep [ppr a1,ppr a2])
 592 #endif
 593
 594 -------------------------
 595 pruneAvails :: (Name -> Bool)   -- Keep if this is True
 596             -> [AvailInfo]
 597             -> [AvailInfo]
 598 pruneAvails keep avails
 599   = mapMaybe del avails
 600   where
 601     del :: AvailInfo -> Maybe AvailInfo -- Nothing => nothing left!
 602     del (Avail n) | keep n    = Just (Avail n)
 603                   | otherwise = Nothing
 604     del (AvailTC n ns) | null ns'  = Nothing
 605                        | otherwise = Just (AvailTC n ns')
 606                        where
 607                          ns' = filter keep ns
 608 \end{code}
 609
 610 ---------------------------------------
 611         AvailEnv and friends
 612 ---------------------------------------
 613
 614 \begin{code}
 615 type AvailEnv = NameEnv AvailInfo       -- Maps a Name to the AvailInfo that contains it
 616
 617 emptyAvailEnv :: AvailEnv
 618 emptyAvailEnv = emptyNameEnv
 619
 620 unitAvailEnv :: AvailInfo -> AvailEnv
 621 unitAvailEnv a = unitNameEnv (availName a) a
 622
 623 plusAvailEnv :: AvailEnv -> AvailEnv -> AvailEnv
 624 plusAvailEnv = plusNameEnv_C plusAvail
 625
 626 lookupAvailEnv_maybe :: AvailEnv -> Name -> Maybe AvailInfo
 627 lookupAvailEnv_maybe = lookupNameEnv
 628
 629 lookupAvailEnv :: AvailEnv -> Name -> AvailInfo
 630 lookupAvailEnv env n = case lookupNameEnv env n of
 631                          Just avail -> avail
 632                          Nothing    -> pprPanic "lookupAvailEnv" (ppr n)
 633
 634 availEnvElts = nameEnvElts
 635
 636 addAvail :: AvailEnv -> AvailInfo -> AvailEnv
 637 addAvail avails avail = extendNameEnv_C plusAvail avails (availName avail) avail
 638
 639 mkAvailEnv :: [AvailInfo] -> AvailEnv
 640         -- 'avails' may have several items with the same availName
 641         -- E.g  import Ix( Ix(..), index )
 642         -- will give Ix(Ix,index,range) and Ix(index)
 643         -- We want to combine these; addAvail does that
 644 mkAvailEnv avails = foldl addAvail emptyAvailEnv avails
 645 \end{code}
 646
 647 %************************************************************************
 648 %*                                                                      *
 649 \subsection{Where from}
 650 %*                                                                      *
 651 %************************************************************************
 652
 653 The @WhereFrom@ type controls where the renamer looks for an interface file
 654
 655 \begin{code}
 656 data WhereFrom
 657   = ImportByUser IsBootInterface        -- Ordinary user import (perhaps {-# SOURCE #-})
 658   | ImportBySystem                      -- Non user import.
 659
 660 instance Outputable WhereFrom where
 661   ppr (ImportByUser is_boot) | is_boot     = ptext SLIT("{- SOURCE -}")
 662                              | otherwise   = empty
 663   ppr ImportBySystem                       = ptext SLIT("{- SYSTEM -}")
 664 \end{code}
 665
 666
 667 %************************************************************************
 668 %*                                                                      *
 669 \subsection[Inst-types]{@Inst@ types}
 670 %*                                                                      *
 671 v%************************************************************************
 672
 673 An @Inst@ is either a dictionary, an instance of an overloaded
 674 literal, or an instance of an overloaded value.  We call the latter a
 675 ``method'' even though it may not correspond to a class operation.
 676 For example, we might have an instance of the @double@ function at
 677 type Int, represented by
 678
 679         Method 34 doubleId [Int] origin
 680
 681 \begin{code}
 682 data Inst
 683   = Dict
 684         Name
 685         TcPredType
 686         InstLoc
 687
 688   | Method
 689         Id
 690
 691         TcId    -- The overloaded function
 692                         -- This function will be a global, local, or ClassOpId;
 693                         --   inside instance decls (only) it can also be an InstId!
 694                         -- The id needn't be completely polymorphic.
 695                         -- You'll probably find its name (for documentation purposes)
 696                         --        inside the InstOrigin
 697
 698         [TcType]        -- The types to which its polymorphic tyvars
 699                         --      should be instantiated.
 700                         -- These types must saturate the Id's foralls.
 701
 702         TcThetaType     -- The (types of the) dictionaries to which the function
 703                         -- must be applied to get the method
 704
 705         InstLoc
 706
 707         -- INVARIANT 1: in (Method u f tys theta tau loc)
 708         --      type of (f tys dicts(from theta)) = tau
 709
 710         -- INVARIANT 2: tau must not be of form (Pred -> Tau)
 711         --   Reason: two methods are considered equal if the
 712         --           base Id matches, and the instantiating types
 713         --           match.  The TcThetaType should then match too.
 714         --   This only bites in the call to tcInstClassOp in TcClassDcl.mkMethodBind
 715
 716   | LitInst
 717         Name
 718         (HsOverLit Name)        -- The literal from the occurrence site
 719                                 -- INVARIANT: never a rebindable-syntax literal
 720                                 -- Reason: tcSyntaxName does unification, and we
 721                                 --         don't want to deal with that during tcSimplify,
 722                                 --         when resolving LitInsts
 723         TcType          -- The type at which the literal is used
 724         InstLoc
 725 \end{code}
 726
 727 @Insts@ are ordered by their class/type info, rather than by their
 728 unique.  This allows the context-reduction mechanism to use standard finite
 729 maps to do their stuff.
 730
 731 \begin{code}
 732 instance Ord Inst where
 733   compare = cmpInst
 734
 735 instance Eq Inst where
 736   (==) i1 i2 = case i1 `cmpInst` i2 of
 737                  EQ    -> True
 738                  other -> False
 739
 740 cmpInst (Dict _ pred1 _)        (Dict _ pred2 _)        = pred1 `tcCmpPred` pred2
 741 cmpInst (Dict _ _ _)            other                   = LT
 742
 743 cmpInst (Method _ _ _ _ _)      (Dict _ _ _)            = GT
 744 cmpInst (Method _ id1 tys1 _ _) (Method _ id2 tys2 _ _) = (id1 `compare` id2) `thenCmp` (tys1 `tcCmpTypes` tys2)
 745 cmpInst (Method _ _ _ _ _)      other                   = LT
 746
 747 cmpInst (LitInst _ _ _ _)       (Dict _ _ _)            = GT
 748 cmpInst (LitInst _ _ _ _)       (Method _ _ _ _ _)      = GT
 749 cmpInst (LitInst _ lit1 ty1 _)  (LitInst _ lit2 ty2 _)  = (lit1 `compare` lit2) `thenCmp` (ty1 `tcCmpType` ty2)
 750 \end{code}
 751
 752
 753 %************************************************************************
 754 %*                                                                      *
 755 \subsection[Inst-collections]{LIE: a collection of Insts}
 756 %*                                                                      *
 757 %************************************************************************
 758
 759 \begin{code}
 760 -- FIXME: Rename this. It clashes with (Located (IE ...))
 761 type LIE = Bag Inst
 762
 763 isEmptyLIE        = isEmptyBag
 764 emptyLIE          = emptyBag
 765 unitLIE inst      = unitBag inst
 766 mkLIE insts       = listToBag insts
 767 plusLIE lie1 lie2 = lie1 `unionBags` lie2
 768 consLIE inst lie  = inst `consBag` lie
 769 plusLIEs lies     = unionManyBags lies
 770 lieToList         = bagToList
 771 listToLIE         = listToBag
 772 \end{code}
 773
 774
 775 %************************************************************************
 776 %*                                                                      *
 777 \subsection[Inst-origin]{The @InstOrigin@ type}
 778 %*                                                                      *
 779 %************************************************************************
 780
 781 The @InstOrigin@ type gives information about where a dictionary came from.
 782 This is important for decent error message reporting because dictionaries
 783 don't appear in the original source code.  Doubtless this type will evolve...
 784
 785 It appears in TcMonad because there are a couple of error-message-generation
 786 functions that deal with it.
 787
 788 \begin{code}
 789 data InstLoc = InstLoc InstOrigin SrcSpan ErrCtxt
 790
 791 instLocSrcLoc :: InstLoc -> SrcLoc
 792 instLocSrcLoc (InstLoc _ src_span _) = srcSpanStart src_span
 793
 794 instLocSrcSpan :: InstLoc -> SrcSpan
 795 instLocSrcSpan (InstLoc _ src_span _) = src_span
 796
 797 data InstOrigin
 798   = SigOrigin SkolemInfo        -- Pattern, class decl, inst decl etc;
 799                                 -- Places that bind type variables and introduce
 800                                 -- available constraints
 801
 802   | IPBindOrigin (IPName Name)  -- Binding site of an implicit parameter
 803
 804         -------------------------------------------------------
 805         -- The rest are all occurrences: Insts that are 'wanted'
 806         -------------------------------------------------------
 807   | OccurrenceOf Name           -- Occurrence of an overloaded identifier
 808
 809   | IPOccOrigin  (IPName Name)  -- Occurrence of an implicit parameter
 810
 811   | LiteralOrigin (HsOverLit Name)      -- Occurrence of a literal
 812
 813   | ArithSeqOrigin (ArithSeqInfo Name) -- [x..], [x..y] etc
 814   | PArrSeqOrigin  (ArithSeqInfo Name) -- [:x..y:] and [:x,y..z:]
 815
 816   | InstSigOrigin       -- A dict occurrence arising from instantiating
 817                         -- a polymorphic type during a subsumption check
 818
 819   | RecordUpdOrigin
 820   | InstScOrigin        -- Typechecking superclasses of an instance declaration
 821   | DerivOrigin         -- Typechecking deriving
 822   | StandAloneDerivOrigin -- Typechecking stand-alone deriving
 823   | DefaultOrigin       -- Typechecking a default decl
 824   | DoOrigin            -- Arising from a do expression
 825   | ProcOrigin          -- Arising from a proc expression
 826 \end{code}
 827
 828 \begin{code}
 829 pprInstLoc :: InstLoc -> SDoc
 830 pprInstLoc (InstLoc orig locn _)
 831   = sep [text "arising from" <+> pp_orig orig,
 832          text "at" <+> ppr locn]
 833   where
 834     pp_orig (OccurrenceOf name)  = hsep [ptext SLIT("use of"), quotes (ppr name)]
 835     pp_orig (IPOccOrigin name)   = hsep [ptext SLIT("use of implicit parameter"), quotes (ppr name)]
 836     pp_orig (IPBindOrigin name)  = hsep [ptext SLIT("binding for implicit parameter"), quotes (ppr name)]
 837     pp_orig RecordUpdOrigin      = ptext SLIT("a record update")
 838     pp_orig (LiteralOrigin lit)  = hsep [ptext SLIT("the literal"), quotes (ppr lit)]
 839     pp_orig (ArithSeqOrigin seq) = hsep [ptext SLIT("the arithmetic sequence"), quotes (ppr seq)]
 840     pp_orig (PArrSeqOrigin seq)  = hsep [ptext SLIT("the parallel array sequence"), quotes (ppr seq)]
 841     pp_orig InstSigOrigin        = ptext SLIT("instantiating a type signature")
 842     pp_orig InstScOrigin         = ptext SLIT("the superclasses of an instance declaration")
 843     pp_orig DerivOrigin          = ptext SLIT("the 'deriving' clause of a data type declaration")
 844     pp_orig StandAloneDerivOrigin = ptext SLIT("a 'deriving' declaration")
 845     pp_orig DefaultOrigin        = ptext SLIT("a 'default' declaration")
 846     pp_orig DoOrigin             = ptext SLIT("a do statement")
 847     pp_orig ProcOrigin           = ptext SLIT("a proc expression")
 848     pp_orig (SigOrigin info)     = pprSkolInfo info
 849 \end{code}