compiler/typecheck/TcRnTypes.lhs

   1
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP Project, Glasgow University, 1992-2002
   4 %
   5 \begin{code}
   6 module TcRnTypes(
   7         TcRnIf, TcRn, TcM, RnM, IfM, IfL, IfG, -- The monad is opaque outside this module
   8         TcRef,
   9
  10         -- The environment types
  11         Env(..),
  12         TcGblEnv(..), TcLclEnv(..),
  13         IfGblEnv(..), IfLclEnv(..),
  14
  15         -- Ranamer types
  16         ErrCtxt, RecFieldEnv(..),
  17         ImportAvails(..), emptyImportAvails, plusImportAvails,
  18         WhereFrom(..), mkModDeps,
  19
  20         -- Typechecker types
  21         TcTypeEnv, TcTyThing(..), pprTcTyThingCategory,
  22
  23         -- Template Haskell
  24         ThStage(..), topStage, topAnnStage, topSpliceStage,
  25         ThLevel, impLevel, outerLevel, thLevel,
  26
  27         -- Arrows
  28         ArrowCtxt(NoArrowCtxt), newArrowScope, escapeArrowScope,
  29
  30         -- Constraints
  31         Untouchables(..), inTouchableRange, isNoUntouchables,
  32
  33         WantedConstraints(..), insolubleWC, emptyWC, isEmptyWC,
  34         andWC, addFlats, addImplics, mkFlatWC,
  35
  36         EvVarX(..), mkEvVarX, evVarOf, evVarX, evVarOfPred,
  37         WantedEvVar, wantedToFlavored,
  38         keepWanted,
  39
  40         Implication(..),
  41         CtLoc(..), ctLocSpan, ctLocOrigin, setCtLocOrigin,
  42         CtOrigin(..), EqOrigin(..),
  43         WantedLoc, GivenLoc, pushErrCtxt,
  44
  45         SkolemInfo(..),
  46
  47         CtFlavor(..), pprFlavorArising, isWanted, isGiven, isDerived,
  48         FlavoredEvVar,
  49
  50         -- Pretty printing
  51         pprEvVarTheta, pprWantedEvVar, pprWantedsWithLocs,
  52         pprEvVars, pprEvVarWithType,
  53         pprArising, pprArisingAt,
  54
  55         -- Misc other types
  56         TcId, TcIdSet, TcTyVarBind(..), TcTyVarBinds
  57
  58   ) where
  59
  60 #include "HsVersions.h"
  61
  62 import HsSyn
  63 import HscTypes
  64 import Type
  65 import Class    ( Class )
  66 import DataCon  ( DataCon, dataConUserType )
  67 import TcType
  68 import Annotations
  69 import InstEnv
  70 import FamInstEnv
  71 import IOEnv
  72 import RdrName
  73 import Name
  74 import NameEnv
  75 import NameSet
  76 import Var
  77 import VarEnv
  78 import Module
  79 import SrcLoc
  80 import VarSet
  81 import ErrUtils
  82 import UniqFM
  83 import UniqSupply
  84 import Unique
  85 import BasicTypes
  86 import Bag
  87 import Outputable
  88 import ListSetOps
  89 import FastString
  90
  91 import Data.Set (Set)
  92 \end{code}
  93
  94
  95 %************************************************************************
  96 %*                                                                      *
  97                Standard monad definition for TcRn
  98     All the combinators for the monad can be found in TcRnMonad
  99 %*                                                                      *
 100 %************************************************************************
 101
 102 The monad itself has to be defined here, because it is mentioned by ErrCtxt
 103
 104 \begin{code}
 105 type TcRef a     = IORef a
 106 type TcId        = Id                   -- Type may be a TcType  DV: WHAT??????????
 107 type TcIdSet     = IdSet
 108
 109
 110 type TcRnIf a b c = IOEnv (Env a b) c
 111 type IfM lcl a  = TcRnIf IfGblEnv lcl a         -- Iface stuff
 112
 113 type IfG a  = IfM () a                          -- Top level
 114 type IfL a  = IfM IfLclEnv a                    -- Nested
 115 type TcRn a = TcRnIf TcGblEnv TcLclEnv a
 116 type RnM  a = TcRn a            -- Historical
 117 type TcM  a = TcRn a            -- Historical
 118 \end{code}
 119
 120 Representation of type bindings to uninstantiated meta variables used during
 121 constraint solving.
 122
 123 \begin{code}
 124 data TcTyVarBind = TcTyVarBind TcTyVar TcType
 125
 126 type TcTyVarBinds = Bag TcTyVarBind
 127
 128 instance Outputable TcTyVarBind where
 129   ppr (TcTyVarBind tv ty) = ppr tv <+> text ":=" <+> ppr ty
 130 \end{code}
 131
 132
 133 %************************************************************************
 134 %*                                                                      *
 135                 The main environment types
 136 %*                                                                      *
 137 %************************************************************************
 138
 139 \begin{code}
 140 data Env gbl lcl        -- Changes as we move into an expression
 141   = Env {
 142         env_top  :: HscEnv,     -- Top-level stuff that never changes
 143                                 -- Includes all info about imported things
 144
 145         env_us   :: {-# UNPACK #-} !(IORef UniqSupply),
 146                                 -- Unique supply for local varibles
 147
 148         env_gbl  :: gbl,        -- Info about things defined at the top level
 149                                 -- of the module being compiled
 150
 151         env_lcl  :: lcl         -- Nested stuff; changes as we go into
 152     }
 153
 154 -- TcGblEnv describes the top-level of the module at the
 155 -- point at which the typechecker is finished work.
 156 -- It is this structure that is handed on to the desugarer
 157
 158 data TcGblEnv
 159   = TcGblEnv {
 160         tcg_mod     :: Module,         -- ^ Module being compiled
 161         tcg_src     :: HscSource,
 162           -- ^ What kind of module (regular Haskell, hs-boot, ext-core)
 163
 164         tcg_rdr_env :: GlobalRdrEnv,   -- ^ Top level envt; used during renaming
 165         tcg_default :: Maybe [Type],
 166           -- ^ Types used for defaulting. @Nothing@ => no @default@ decl
 167
 168         tcg_fix_env   :: FixityEnv,     -- ^ Just for things in this module
 169         tcg_field_env :: RecFieldEnv,   -- ^ Just for things in this module
 170
 171         tcg_type_env :: TypeEnv,
 172           -- ^ Global type env for the module we are compiling now.  All
 173           -- TyCons and Classes (for this module) end up in here right away,
 174           -- along with their derived constructors, selectors.
 175           --
 176           -- (Ids defined in this module start in the local envt, though they
 177           --  move to the global envt during zonking)
 178
 179         tcg_type_env_var :: TcRef TypeEnv,
 180                 -- Used only to initialise the interface-file
 181                 -- typechecker in initIfaceTcRn, so that it can see stuff
 182                 -- bound in this module when dealing with hi-boot recursions
 183                 -- Updated at intervals (e.g. after dealing with types and classes)
 184
 185         tcg_inst_env     :: InstEnv,
 186           -- ^ Instance envt for /home-package/ modules; Includes the dfuns in
 187           -- tcg_insts
 188         tcg_fam_inst_env :: FamInstEnv, -- ^ Ditto for family instances
 189
 190                 -- Now a bunch of things about this module that are simply
 191                 -- accumulated, but never consulted until the end.
 192                 -- Nevertheless, it's convenient to accumulate them along
 193                 -- with the rest of the info from this module.
 194         tcg_exports :: [AvailInfo],     -- ^ What is exported
 195         tcg_imports :: ImportAvails,
 196           -- ^ Information about what was imported from where, including
 197           -- things bound in this module.
 198
 199         tcg_dus :: DefUses,
 200           -- ^ What is defined in this module and what is used.
 201           -- The latter is used to generate
 202           --
 203           --  (a) version tracking; no need to recompile if these things have
 204           --      not changed version stamp
 205           --
 206           --  (b) unused-import info
 207
 208         tcg_keep :: TcRef NameSet,
 209           -- ^ Locally-defined top-level names to keep alive.
 210           --
 211           -- "Keep alive" means give them an Exported flag, so that the
 212           -- simplifier does not discard them as dead code, and so that they
 213           -- are exposed in the interface file (but not to export to the
 214           -- user).
 215           --
 216           -- Some things, like dict-fun Ids and default-method Ids are "born"
 217           -- with the Exported flag on, for exactly the above reason, but some
 218           -- we only discover as we go.  Specifically:
 219           --
 220           --   * The to/from functions for generic data types
 221           --
 222           --   * Top-level variables appearing free in the RHS of an orphan
 223           --     rule
 224           --
 225           --   * Top-level variables appearing free in a TH bracket
 226
 227         tcg_th_used :: TcRef Bool,
 228           -- ^ @True@ <=> Template Haskell syntax used.
 229           --
 230           -- We need this so that we can generate a dependency on the
 231           -- Template Haskell package, becuase the desugarer is going
 232           -- to emit loads of references to TH symbols.  The reference
 233           -- is implicit rather than explicit, so we have to zap a
 234           -- mutable variable.
 235
 236         tcg_dfun_n  :: TcRef OccSet,
 237           -- ^ Allows us to choose unique DFun names.
 238
 239         -- The next fields accumulate the payload of the module
 240         -- The binds, rules and foreign-decl fiels are collected
 241         -- initially in un-zonked form and are finally zonked in tcRnSrcDecls
 242
 243         tcg_rn_exports :: Maybe [Located (IE Name)],
 244         tcg_rn_imports :: [LImportDecl Name],
 245                 -- Keep the renamed imports regardless.  They are not
 246                 -- voluminous and are needed if you want to report unused imports
 247
 248         tcg_used_rdrnames :: TcRef (Set RdrName),
 249                 -- The set of used *imported* (not locally-defined) RdrNames
 250                 -- Used only to report unused import declarations
 251
 252         tcg_rn_decls :: Maybe (HsGroup Name),
 253           -- ^ Renamed decls, maybe.  @Nothing@ <=> Don't retain renamed
 254           -- decls.
 255
 256         tcg_ev_binds  :: Bag EvBind,        -- Top-level evidence bindings
 257         tcg_binds     :: LHsBinds Id,       -- Value bindings in this module
 258         tcg_sigs      :: NameSet,           -- ...Top-level names that *lack* a signature
 259         tcg_imp_specs :: [LTcSpecPrag],     -- ...SPECIALISE prags for imported Ids
 260         tcg_warns     :: Warnings,          -- ...Warnings and deprecations
 261         tcg_anns      :: [Annotation],      -- ...Annotations
 262         tcg_insts     :: [Instance],        -- ...Instances
 263         tcg_fam_insts :: [FamInst],         -- ...Family instances
 264         tcg_rules     :: [LRuleDecl Id],    -- ...Rules
 265         tcg_fords     :: [LForeignDecl Id], -- ...Foreign import & exports
 266
 267         tcg_doc_hdr   :: Maybe LHsDocString, -- ^ Maybe Haddock header docs
 268         tcg_hpc       :: AnyHpcUsage,        -- ^ @True@ if any part of the
 269                                              --  prog uses hpc instrumentation.
 270
 271         tcg_main      :: Maybe Name          -- ^ The Name of the main
 272                                              -- function, if this module is
 273                                              -- the main module.
 274     }
 275
 276 data RecFieldEnv
 277   = RecFields (NameEnv [Name])  -- Maps a constructor name *in this module*
 278                                 -- to the fields for that constructor
 279               NameSet           -- Set of all fields declared *in this module*;
 280                                 -- used to suppress name-shadowing complaints
 281                                 -- when using record wild cards
 282                                 -- E.g.  let fld = e in C {..}
 283         -- This is used when dealing with ".." notation in record
 284         -- construction and pattern matching.
 285         -- The FieldEnv deals *only* with constructors defined in *this*
 286         -- module.  For imported modules, we get the same info from the
 287         -- TypeEnv
 288 \end{code}
 289
 290 %************************************************************************
 291 %*                                                                      *
 292                 The interface environments
 293               Used when dealing with IfaceDecls
 294 %*                                                                      *
 295 %************************************************************************
 296
 297 \begin{code}
 298 data IfGblEnv
 299   = IfGblEnv {
 300         -- The type environment for the module being compiled,
 301         -- in case the interface refers back to it via a reference that
 302         -- was originally a hi-boot file.
 303         -- We need the module name so we can test when it's appropriate
 304         -- to look in this env.
 305         if_rec_types :: Maybe (Module, IfG TypeEnv)
 306                 -- Allows a read effect, so it can be in a mutable
 307                 -- variable; c.f. handling the external package type env
 308                 -- Nothing => interactive stuff, no loops possible
 309     }
 310
 311 data IfLclEnv
 312   = IfLclEnv {
 313         -- The module for the current IfaceDecl
 314         -- So if we see   f = \x -> x
 315         -- it means M.f = \x -> x, where M is the if_mod
 316         if_mod :: Module,
 317
 318         -- The field is used only for error reporting
 319         -- if (say) there's a Lint error in it
 320         if_loc :: SDoc,
 321                 -- Where the interface came from:
 322                 --      .hi file, or GHCi state, or ext core
 323                 -- plus which bit is currently being examined
 324
 325         if_tv_env  :: UniqFM TyVar,     -- Nested tyvar bindings
 326         if_id_env  :: UniqFM Id         -- Nested id binding
 327     }
 328 \end{code}
 329
 330
 331 %************************************************************************
 332 %*                                                                      *
 333                 The local typechecker environment
 334 %*                                                                      *
 335 %************************************************************************
 336
 337 The Global-Env/Local-Env story
 338 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 339 During type checking, we keep in the tcg_type_env
 340         * All types and classes
 341         * All Ids derived from types and classes (constructors, selectors)
 342
 343 At the end of type checking, we zonk the local bindings,
 344 and as we do so we add to the tcg_type_env
 345         * Locally defined top-level Ids
 346
 347 Why?  Because they are now Ids not TcIds.  This final GlobalEnv is
 348         a) fed back (via the knot) to typechecking the
 349            unfoldings of interface signatures
 350         b) used in the ModDetails of this module
 351
 352 \begin{code}
 353 data TcLclEnv           -- Changes as we move inside an expression
 354                         -- Discarded after typecheck/rename; not passed on to desugarer
 355   = TcLclEnv {
 356         tcl_loc  :: SrcSpan,            -- Source span
 357         tcl_ctxt :: [ErrCtxt],          -- Error context, innermost on top
 358         tcl_errs :: TcRef Messages,     -- Place to accumulate errors
 359
 360         tcl_th_ctxt    :: ThStage,            -- Template Haskell context
 361         tcl_arrow_ctxt :: ArrowCtxt,          -- Arrow-notation context
 362
 363         tcl_rdr :: LocalRdrEnv,         -- Local name envt
 364                 -- Maintained during renaming, of course, but also during
 365                 -- type checking, solely so that when renaming a Template-Haskell
 366                 -- splice we have the right environment for the renamer.
 367                 --
 368                 --   Does *not* include global name envt; may shadow it
 369                 --   Includes both ordinary variables and type variables;
 370                 --   they are kept distinct because tyvar have a different
 371                 --   occurrence contructor (Name.TvOcc)
 372                 -- We still need the unsullied global name env so that
 373                 --   we can look up record field names
 374
 375         tcl_hetMetLevel  :: [TyVar],    -- The current environment classifier level (list-of-names)
 376         tcl_env  :: TcTypeEnv,    -- The local type environment: Ids and
 377                                   -- TyVars defined in this module
 378
 379         tcl_tyvars :: TcRef TcTyVarSet, -- The "global tyvars"
 380                         -- Namely, the in-scope TyVars bound in tcl_env,
 381                         -- plus the tyvars mentioned in the types of Ids bound
 382                         -- in tcl_lenv.
 383                         -- Why mutable? see notes with tcGetGlobalTyVars
 384
 385         tcl_lie   :: TcRef WantedConstraints,    -- Place to accumulate type constraints
 386
 387         -- TcMetaTyVars have
 388         tcl_meta  :: TcRef Unique,  -- The next free unique for TcMetaTyVars
 389                                     -- Guaranteed to be allocated linearly
 390         tcl_untch :: Unique         -- Any TcMetaTyVar with
 391                                     --     unique >= tcl_untch is touchable
 392                                     --     unique <  tcl_untch is untouchable
 393     }
 394
 395 type TcTypeEnv = NameEnv TcTyThing
 396
 397
 398 {- Note [Given Insts]
 399    ~~~~~~~~~~~~~~~~~~
 400 Because of GADTs, we have to pass inwards the Insts provided by type signatures
 401 and existential contexts. Consider
 402         data T a where { T1 :: b -> b -> T [b] }
 403         f :: Eq a => T a -> Bool
 404         f (T1 x y) = [x]==[y]
 405
 406 The constructor T1 binds an existential variable 'b', and we need Eq [b].
 407 Well, we have it, because Eq a refines to Eq [b], but we can only spot that if we
 408 pass it inwards.
 409
 410 -}
 411
 412 ---------------------------
 413 -- Template Haskell stages and levels
 414 ---------------------------
 415
 416 data ThStage    -- See Note [Template Haskell state diagram] in TcSplice
 417   = Splice      -- Top-level splicing
 418                 -- This code will be run *at compile time*;
 419                 --   the result replaces the splice
 420                 -- Binding level = 0
 421
 422   | Comp        -- Ordinary Haskell code
 423                 -- Binding level = 1
 424
 425   | Brack                       -- Inside brackets
 426       ThStage                   --   Binding level = level(stage) + 1
 427       (TcRef [PendingSplice])   --   Accumulate pending splices here
 428       (TcRef WantedConstraints) --     and type constraints here
 429
 430 topStage, topAnnStage, topSpliceStage :: ThStage
 431 topStage       = Comp
 432 topAnnStage    = Splice
 433 topSpliceStage = Splice
 434
 435 instance Outputable ThStage where
 436    ppr Splice        = text "Splice"
 437    ppr Comp          = text "Comp"
 438    ppr (Brack s _ _) = text "Brack" <> parens (ppr s)
 439
 440 type ThLevel = Int
 441         -- See Note [Template Haskell levels] in TcSplice
 442         -- Incremented when going inside a bracket,
 443         -- decremented when going inside a splice
 444         -- NB: ThLevel is one greater than the 'n' in Fig 2 of the
 445         --     original "Template meta-programming for Haskell" paper
 446
 447 impLevel, outerLevel :: ThLevel
 448 impLevel = 0    -- Imported things; they can be used inside a top level splice
 449 outerLevel = 1  -- Things defined outside brackets
 450 -- NB: Things at level 0 are not *necessarily* imported.
 451 --      eg  $( \b -> ... )   here b is bound at level 0
 452 --
 453 -- For example:
 454 --      f = ...
 455 --      g1 = $(map ...)         is OK
 456 --      g2 = $(f ...)           is not OK; because we havn't compiled f yet
 457
 458 thLevel :: ThStage -> ThLevel
 459 thLevel Splice        = 0
 460 thLevel Comp          = 1
 461 thLevel (Brack s _ _) = thLevel s + 1
 462
 463 ---------------------------
 464 -- Arrow-notation context
 465 ---------------------------
 466
 467 {-
 468 In arrow notation, a variable bound by a proc (or enclosed let/kappa)
 469 is not in scope to the left of an arrow tail (-<) or the head of (|..|).
 470 For example
 471
 472         proc x -> (e1 -< e2)
 473
 474 Here, x is not in scope in e1, but it is in scope in e2.  This can get
 475 a bit complicated:
 476
 477         let x = 3 in
 478         proc y -> (proc z -> e1) -< e2
 479
 480 Here, x and z are in scope in e1, but y is not.  We implement this by
 481 recording the environment when passing a proc (using newArrowScope),
 482 and returning to that (using escapeArrowScope) on the left of -< and the
 483 head of (|..|).
 484 -}
 485
 486 data ArrowCtxt
 487   = NoArrowCtxt
 488   | ArrowCtxt (Env TcGblEnv TcLclEnv)
 489
 490 -- Record the current environment (outside a proc)
 491 newArrowScope :: TcM a -> TcM a
 492 newArrowScope
 493   = updEnv $ \env ->
 494         env { env_lcl = (env_lcl env) { tcl_arrow_ctxt = ArrowCtxt env } }
 495
 496 -- Return to the stored environment (from the enclosing proc)
 497 escapeArrowScope :: TcM a -> TcM a
 498 escapeArrowScope
 499   = updEnv $ \ env -> case tcl_arrow_ctxt (env_lcl env) of
 500         NoArrowCtxt -> env
 501         ArrowCtxt env' -> env'
 502
 503 ---------------------------
 504 -- TcTyThing
 505 ---------------------------
 506
 507 data TcTyThing
 508   = AGlobal TyThing             -- Used only in the return type of a lookup
 509
 510   | ATcId   {           -- Ids defined in this module; may not be fully zonked
 511         tct_id    :: TcId,
 512         tct_level :: ThLevel,
 513         tct_hetMetLevel :: [TyVar]
 514     }
 515
 516   | ATyVar  Name TcType         -- The type to which the lexically scoped type vaiable
 517                                 -- is currently refined. We only need the Name
 518                                 -- for error-message purposes; it is the corresponding
 519                                 -- Name in the domain of the envt
 520
 521   | AThing  TcKind              -- Used temporarily, during kind checking, for the
 522                                 --      tycons and clases in this recursive group
 523
 524 instance Outputable TcTyThing where     -- Debugging only
 525    ppr (AGlobal g)      = pprTyThing g
 526    ppr elt@(ATcId {})   = text "Identifier" <>
 527                           brackets (ppr (tct_id elt) <> dcolon
 528                                  <> ppr (varType (tct_id elt)) <> comma
 529                                  <+> ppr (tct_level elt)
 530                                  <+> ppr (tct_hetMetLevel elt))
 531    ppr (ATyVar tv _)    = text "Type variable" <+> quotes (ppr tv)
 532    ppr (AThing k)       = text "AThing" <+> ppr k
 533
 534 pprTcTyThingCategory :: TcTyThing -> SDoc
 535 pprTcTyThingCategory (AGlobal thing) = pprTyThingCategory thing
 536 pprTcTyThingCategory (ATyVar {})     = ptext (sLit "Type variable")
 537 pprTcTyThingCategory (ATcId {})      = ptext (sLit "Local identifier")
 538 pprTcTyThingCategory (AThing {})     = ptext (sLit "Kinded thing")
 539 \end{code}
 540
 541 \begin{code}
 542 type ErrCtxt = (Bool, TidyEnv -> TcM (TidyEnv, Message))
 543         -- Monadic so that we have a chance
 544         -- to deal with bound type variables just before error
 545         -- message construction
 546
 547         -- Bool:  True <=> this is a landmark context; do not
 548         --                 discard it when trimming for display
 549 \end{code}
 550
 551
 552 %************************************************************************
 553 %*                                                                      *
 554         Operations over ImportAvails
 555 %*                                                                      *
 556 %************************************************************************
 557
 558 \begin{code}
 559 -- | 'ImportAvails' summarises what was imported from where, irrespective of
 560 -- whether the imported things are actually used or not.  It is used:
 561 --
 562 --  * when processing the export list,
 563 --
 564 --  * when constructing usage info for the interface file,
 565 --
 566 --  * to identify the list of directly imported modules for initialisation
 567 --    purposes and for optimised overlap checking of family instances,
 568 --
 569 --  * when figuring out what things are really unused
 570 --
 571 data ImportAvails
 572    = ImportAvails {
 573         imp_mods :: ModuleEnv [(ModuleName, Bool, SrcSpan)],
 574           -- ^ Domain is all directly-imported modules
 575           -- The 'ModuleName' is what the module was imported as, e.g. in
 576           -- @
 577           --     import Foo as Bar
 578           -- @
 579           -- it is @Bar@.
 580           --
 581           -- The 'Bool' means:
 582           --
 583           --  - @True@ => import was @import Foo ()@
 584           --
 585           --  - @False@ => import was some other form
 586           --
 587           -- Used
 588           --
 589           --   (a) to help construct the usage information in the interface
 590           --       file; if we import somethign we need to recompile if the
 591           --       export version changes
 592           --
 593           --   (b) to specify what child modules to initialise
 594           --
 595           -- We need a full ModuleEnv rather than a ModuleNameEnv here,
 596           -- because we might be importing modules of the same name from
 597           -- different packages. (currently not the case, but might be in the
 598           -- future).
 599
 600         imp_dep_mods :: ModuleNameEnv (ModuleName, IsBootInterface),
 601           -- ^ Home-package modules needed by the module being compiled
 602           --
 603           -- It doesn't matter whether any of these dependencies
 604           -- are actually /used/ when compiling the module; they
 605           -- are listed if they are below it at all.  For
 606           -- example, suppose M imports A which imports X.  Then
 607           -- compiling M might not need to consult X.hi, but X
 608           -- is still listed in M's dependencies.
 609
 610         imp_dep_pkgs :: [PackageId],
 611           -- ^ Packages needed by the module being compiled, whether directly,
 612           -- or via other modules in this package, or via modules imported
 613           -- from other packages.
 614
 615         imp_orphs :: [Module],
 616           -- ^ Orphan modules below us in the import tree (and maybe including
 617           -- us for imported modules)
 618
 619         imp_finsts :: [Module]
 620           -- ^ Family instance modules below us in the import tree (and maybe
 621           -- including us for imported modules)
 622       }
 623
 624 mkModDeps :: [(ModuleName, IsBootInterface)]
 625           -> ModuleNameEnv (ModuleName, IsBootInterface)
 626 mkModDeps deps = foldl add emptyUFM deps
 627                where
 628                  add env elt@(m,_) = addToUFM env m elt
 629
 630 emptyImportAvails :: ImportAvails
 631 emptyImportAvails = ImportAvails { imp_mods     = emptyModuleEnv,
 632                                    imp_dep_mods = emptyUFM,
 633                                    imp_dep_pkgs = [],
 634                                    imp_orphs    = [],
 635                                    imp_finsts   = [] }
 636
 637 plusImportAvails ::  ImportAvails ->  ImportAvails ->  ImportAvails
 638 plusImportAvails
 639   (ImportAvails { imp_mods = mods1,
 640                   imp_dep_mods = dmods1, imp_dep_pkgs = dpkgs1,
 641                   imp_orphs = orphs1, imp_finsts = finsts1 })
 642   (ImportAvails { imp_mods = mods2,
 643                   imp_dep_mods = dmods2, imp_dep_pkgs = dpkgs2,
 644                   imp_orphs = orphs2, imp_finsts = finsts2 })
 645   = ImportAvails { imp_mods     = plusModuleEnv_C (++) mods1 mods2,
 646                    imp_dep_mods = plusUFM_C plus_mod_dep dmods1 dmods2,
 647                    imp_dep_pkgs = dpkgs1 `unionLists` dpkgs2,
 648                    imp_orphs    = orphs1 `unionLists` orphs2,
 649                    imp_finsts   = finsts1 `unionLists` finsts2 }
 650   where
 651     plus_mod_dep (m1, boot1) (m2, boot2)
 652         = WARN( not (m1 == m2), (ppr m1 <+> ppr m2) $$ (ppr boot1 <+> ppr boot2) )
 653                 -- Check mod-names match
 654           (m1, boot1 && boot2)  -- If either side can "see" a non-hi-boot interface, use that
 655 \end{code}
 656
 657 %************************************************************************
 658 %*                                                                      *
 659 \subsection{Where from}
 660 %*                                                                      *
 661 %************************************************************************
 662
 663 The @WhereFrom@ type controls where the renamer looks for an interface file
 664
 665 \begin{code}
 666 data WhereFrom
 667   = ImportByUser IsBootInterface        -- Ordinary user import (perhaps {-# SOURCE #-})
 668   | ImportBySystem                      -- Non user import.
 669
 670 instance Outputable WhereFrom where
 671   ppr (ImportByUser is_boot) | is_boot     = ptext (sLit "{- SOURCE -}")
 672                              | otherwise   = empty
 673   ppr ImportBySystem                       = ptext (sLit "{- SYSTEM -}")
 674 \end{code}
 675
 676
 677 %************************************************************************
 678 %*                                                                      *
 679                 Wanted constraints
 680
 681      These are forced to be in TcRnTypes because
 682            TcLclEnv mentions WantedConstraints
 683            WantedConstraint mentions CtLoc
 684            CtLoc mentions ErrCtxt
 685            ErrCtxt mentions TcM
 686 %*                                                                      *
 687 v%************************************************************************
 688
 689 \begin{code}
 690 data WantedConstraints
 691   = WC { wc_flat  :: Bag WantedEvVar   -- Unsolved constraints, all wanted
 692        , wc_impl  :: Bag Implication
 693        , wc_insol :: Bag FlavoredEvVar -- Insoluble constraints, can be
 694                                        -- wanted, given, or derived
 695                                        -- See Note [Insoluble constraints]
 696     }
 697
 698 emptyWC :: WantedConstraints
 699 emptyWC = WC { wc_flat = emptyBag, wc_impl = emptyBag, wc_insol = emptyBag }
 700
 701 mkFlatWC :: Bag WantedEvVar -> WantedConstraints
 702 mkFlatWC wevs = WC { wc_flat = wevs, wc_impl = emptyBag, wc_insol = emptyBag }
 703
 704 isEmptyWC :: WantedConstraints -> Bool
 705 isEmptyWC (WC { wc_flat = f, wc_impl = i, wc_insol = n })
 706   = isEmptyBag f && isEmptyBag i && isEmptyBag n
 707
 708 insolubleWC :: WantedConstraints -> Bool
 709 -- True if there are any insoluble constraints in the wanted bag
 710 insolubleWC wc = not (isEmptyBag (wc_insol wc))
 711                || anyBag ic_insol (wc_impl wc)
 712
 713 andWC :: WantedConstraints -> WantedConstraints -> WantedConstraints
 714 andWC (WC { wc_flat = f1, wc_impl = i1, wc_insol = n1 })
 715       (WC { wc_flat = f2, wc_impl = i2, wc_insol = n2 })
 716   = WC { wc_flat  = f1 `unionBags` f2
 717        , wc_impl  = i1 `unionBags` i2
 718        , wc_insol = n1 `unionBags` n2 }
 719
 720 addFlats :: WantedConstraints -> Bag WantedEvVar -> WantedConstraints
 721 addFlats wc wevs = wc { wc_flat = wevs `unionBags` wc_flat wc }
 722
 723 addImplics :: WantedConstraints -> Bag Implication -> WantedConstraints
 724 addImplics wc implic = wc { wc_impl = implic `unionBags` wc_impl wc }
 725
 726 instance Outputable WantedConstraints where
 727   ppr (WC {wc_flat = f, wc_impl = i, wc_insol = n})
 728    = ptext (sLit "WC") <+> braces (vcat
 729         [ if isEmptyBag f then empty else
 730           ptext (sLit "wc_flat =")  <+> pprBag pprWantedEvVar f
 731         , if isEmptyBag i then empty else
 732           ptext (sLit "wc_impl =")  <+> pprBag ppr i
 733         , if isEmptyBag n then empty else
 734           ptext (sLit "wc_insol =") <+> pprBag ppr n ])
 735
 736 pprBag :: (a -> SDoc) -> Bag a -> SDoc
 737 pprBag pp b = foldrBag (($$) . pp) empty b
 738 \end{code}
 739
 740
 741 \begin{code}
 742 data Untouchables = NoUntouchables
 743                   | TouchableRange
 744                           Unique  -- Low end
 745                           Unique  -- High end
 746  -- A TcMetaTyvar is *touchable* iff its unique u satisfies
 747  --   u >= low
 748  --   u < high
 749
 750 instance Outputable Untouchables where
 751   ppr NoUntouchables = ptext (sLit "No untouchables")
 752   ppr (TouchableRange low high) = ptext (sLit "Touchable range:") <+>
 753                                   ppr low <+> char '-' <+> ppr high
 754
 755 isNoUntouchables :: Untouchables -> Bool
 756 isNoUntouchables NoUntouchables      = True
 757 isNoUntouchables (TouchableRange {}) = False
 758
 759 inTouchableRange :: Untouchables -> TcTyVar -> Bool
 760 inTouchableRange NoUntouchables _ = True
 761 inTouchableRange (TouchableRange low high) tv
 762   = uniq >= low && uniq < high
 763   where
 764     uniq = varUnique tv
 765
 766 -- EvVar defined in module Var.lhs:
 767 -- Evidence variables include all *quantifiable* constraints
 768 --   dictionaries
 769 --   implicit parameters
 770 --   coercion variables
 771 \end{code}
 772
 773 %************************************************************************
 774 %*                                                                      *
 775                 Implication constraints
 776 %*                                                                      *
 777 %************************************************************************
 778
 779 \begin{code}
 780 data Implication
 781   = Implic {
 782       ic_untch :: Untouchables, -- Untouchables: unification variables
 783                                 -- free in the environment
 784       ic_env   :: TcTypeEnv,    -- The type environment
 785                                 -- Used only when generating error messages
 786           -- Generally, ic_untch is a superset of tvsof(ic_env)
 787           -- However, we don't zonk ic_env when zonking the Implication
 788           -- Instead we do that when generating a skolem-escape error message
 789
 790       ic_skols  :: TcTyVarSet,   -- Introduced skolems
 791                                  -- See Note [Skolems in an implication]
 792
 793       ic_given  :: [EvVar],      -- Given evidence variables
 794                                  --   (order does not matter)
 795       ic_loc   :: GivenLoc,      -- Binding location of the implication,
 796                                  --   which is also the location of all the
 797                                  --   given evidence variables
 798
 799       ic_wanted :: WantedConstraints,  -- The wanted
 800       ic_insol  :: Bool,               -- True iff insolubleWC ic_wanted is true
 801
 802       ic_binds  :: EvBindsVar   -- Points to the place to fill in the
 803                                 -- abstraction and bindings
 804     }
 805
 806 instance Outputable Implication where
 807   ppr (Implic { ic_untch = untch, ic_skols = skols, ic_given = given
 808               , ic_wanted = wanted
 809               , ic_binds = binds, ic_loc = loc })
 810    = ptext (sLit "Implic") <+> braces
 811      (sep [ ptext (sLit "Untouchables = ") <+> ppr untch
 812           , ptext (sLit "Skolems = ") <+> ppr skols
 813           , ptext (sLit "Given = ") <+> pprEvVars given
 814           , ptext (sLit "Wanted = ") <+> ppr wanted
 815           , ptext (sLit "Binds = ") <+> ppr binds
 816           , pprSkolInfo (ctLocOrigin loc)
 817           , ppr (ctLocSpan loc) ])
 818 \end{code}
 819
 820 Note [Skolems in an implication]
 821 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 822 The skolems in an implication are not there to perform a skolem escape
 823 check.  That happens because all the environment variables are in the
 824 untouchables, and therefore cannot be unified with anything at all,
 825 let alone the skolems.
 826
 827 Instead, ic_skols is used only when considering floating a constraint
 828 outside the implication in TcSimplify.floatEqualities or
 829 TcSimplify.approximateImplications
 830
 831 Note [Insoluble constraints]
 832 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 833 Some of the errors that we get during canonicalization are best
 834 reported when all constraints have been simplified as much as
 835 possible. For instance, assume that during simplification the
 836 following constraints arise:
 837
 838  [Wanted]   F alpha ~  uf1
 839  [Wanted]   beta ~ uf1 beta
 840
 841 When canonicalizing the wanted (beta ~ uf1 beta), if we eagerly fail
 842 we will simply see a message:
 843     'Can't construct the infinite type  beta ~ uf1 beta'
 844 and the user has no idea what the uf1 variable is.
 845
 846 Instead our plan is that we will NOT fail immediately, but:
 847     (1) Record the "frozen" error in the ic_insols field
 848     (2) Isolate the offending constraint from the rest of the inerts
 849     (3) Keep on simplifying/canonicalizing
 850
 851 At the end, we will hopefully have substituted uf1 := F alpha, and we
 852 will be able to report a more informative error:
 853     'Can't construct the infinite type beta ~ F alpha beta'
 854
 855 %************************************************************************
 856 %*                                                                      *
 857             EvVarX, WantedEvVar, FlavoredEvVar
 858 %*                                                                      *
 859 %************************************************************************
 860
 861 \begin{code}
 862 data EvVarX a = EvVarX EvVar a
 863      -- An evidence variable with accompanying info
 864
 865 type WantedEvVar   = EvVarX WantedLoc     -- The location where it arose
 866 type FlavoredEvVar = EvVarX CtFlavor
 867
 868 instance Outputable (EvVarX a) where
 869   ppr (EvVarX ev _) = pprEvVarWithType ev
 870   -- If you want to see the associated info,
 871   -- use a more specific printing function
 872
 873 mkEvVarX :: EvVar -> a -> EvVarX a
 874 mkEvVarX = EvVarX
 875
 876 evVarOf :: EvVarX a -> EvVar
 877 evVarOf (EvVarX ev _) = ev
 878
 879 evVarX :: EvVarX a -> a
 880 evVarX (EvVarX _ a) = a
 881
 882 evVarOfPred :: EvVarX a -> PredType
 883 evVarOfPred wev = evVarPred (evVarOf wev)
 884
 885 wantedToFlavored :: WantedEvVar -> FlavoredEvVar
 886 wantedToFlavored (EvVarX v wl) = EvVarX v (Wanted wl)
 887
 888 keepWanted :: Bag FlavoredEvVar -> Bag WantedEvVar
 889 keepWanted flevs
 890   = foldlBag keep_wanted emptyBag flevs
 891   where
 892     keep_wanted :: Bag WantedEvVar -> FlavoredEvVar -> Bag WantedEvVar
 893     keep_wanted r (EvVarX ev (Wanted wloc)) = consBag (EvVarX ev wloc) r
 894     keep_wanted r _ = r
 895 \end{code}
 896
 897
 898 \begin{code}
 899 pprEvVars :: [EvVar] -> SDoc    -- Print with their types
 900 pprEvVars ev_vars = vcat (map pprEvVarWithType ev_vars)
 901
 902 pprEvVarTheta :: [EvVar] -> SDoc
 903 pprEvVarTheta ev_vars = pprTheta (map evVarPred ev_vars)
 904
 905 pprEvVarWithType :: EvVar -> SDoc
 906 pprEvVarWithType v = ppr v <+> dcolon <+> pprPred (evVarPred v)
 907
 908 pprWantedsWithLocs :: WantedConstraints -> SDoc
 909 pprWantedsWithLocs wcs
 910   =  vcat [ pprBag pprWantedEvVarWithLoc (wc_flat wcs)
 911           , pprBag ppr (wc_impl wcs)
 912           , pprBag ppr (wc_insol wcs) ]
 913
 914 pprWantedEvVarWithLoc, pprWantedEvVar :: WantedEvVar -> SDoc
 915 pprWantedEvVarWithLoc (EvVarX v loc) = hang (pprEvVarWithType v)
 916                                           2 (pprArisingAt loc)
 917 pprWantedEvVar        (EvVarX v _)   = pprEvVarWithType v
 918 \end{code}
 919
 920 %************************************************************************
 921 %*                                                                      *
 922             CtLoc
 923 %*                                                                      *
 924 %************************************************************************
 925
 926 \begin{code}
 927 data CtFlavor
 928   = Given   GivenLoc  -- We have evidence for this constraint in TcEvBinds
 929   | Derived WantedLoc
 930                       -- We have evidence for this constraint in TcEvBinds;
 931                       --   *however* this evidence can contain wanteds, so
 932                       --   it's valid only provisionally to the solution of
 933                       --   these wanteds
 934   | Wanted WantedLoc  -- We have no evidence bindings for this constraint.
 935
 936 -- data DerivedOrig = DerSC | DerInst | DerSelf
 937 -- Deriveds are either superclasses of other wanteds or deriveds, or partially
 938 -- solved wanteds from instances, or 'self' dictionaries containing yet wanted
 939 -- superclasses.
 940
 941 instance Outputable CtFlavor where
 942   ppr (Given _)    = ptext (sLit "[Given]")
 943   ppr (Wanted _)   = ptext (sLit "[Wanted]")
 944   ppr (Derived {}) = ptext (sLit "[Derived]")
 945
 946 pprFlavorArising :: CtFlavor -> SDoc
 947 pprFlavorArising (Derived wl )  = pprArisingAt wl
 948 pprFlavorArising (Wanted  wl)   = pprArisingAt wl
 949 pprFlavorArising (Given gl)     = pprArisingAt gl
 950
 951 isWanted :: CtFlavor -> Bool
 952 isWanted (Wanted {}) = True
 953 isWanted _           = False
 954
 955 isGiven :: CtFlavor -> Bool
 956 isGiven (Given {}) = True
 957 isGiven _          = False
 958
 959 isDerived :: CtFlavor -> Bool
 960 isDerived (Derived {}) = True
 961 isDerived _            = False
 962 \end{code}
 963
 964 %************************************************************************
 965 %*                                                                      *
 966             CtLoc
 967 %*                                                                      *
 968 %************************************************************************
 969
 970 The 'CtLoc' gives information about where a constraint came from.
 971 This is important for decent error message reporting because
 972 dictionaries don't appear in the original source code.
 973 type will evolve...
 974
 975 \begin{code}
 976 data CtLoc orig = CtLoc orig SrcSpan [ErrCtxt]
 977
 978 type WantedLoc = CtLoc CtOrigin      -- Instantiation for wanted constraints
 979 type GivenLoc  = CtLoc SkolemInfo    -- Instantiation for given constraints
 980
 981 ctLocSpan :: CtLoc o -> SrcSpan
 982 ctLocSpan (CtLoc _ s _) = s
 983
 984 ctLocOrigin :: CtLoc o -> o
 985 ctLocOrigin (CtLoc o _ _) = o
 986
 987 setCtLocOrigin :: CtLoc o -> o' -> CtLoc o'
 988 setCtLocOrigin (CtLoc _ s c) o = CtLoc o s c
 989
 990 pushErrCtxt :: orig -> ErrCtxt -> CtLoc orig -> CtLoc orig
 991 pushErrCtxt o err (CtLoc _ s errs) = CtLoc o s (err:errs)
 992
 993 pprArising :: CtOrigin -> SDoc
 994 -- Used for the main, top-level error message
 995 -- We've done special processing for TypeEq and FunDep origins
 996 pprArising (TypeEqOrigin {}) = empty
 997 pprArising FunDepOrigin      = empty
 998 pprArising orig              = text "arising from" <+> ppr orig
 999
1000 pprArisingAt :: Outputable o => CtLoc o -> SDoc
1001 pprArisingAt (CtLoc o s _) = sep [ text "arising from" <+> ppr o
1002                                  , text "at" <+> ppr s]
1003 \end{code}
1004
1005 %************************************************************************
1006 %*                                                                      *
1007                 SkolemInfo
1008 %*                                                                      *
1009 %************************************************************************
1010
1011 \begin{code}
1012 -- SkolemInfo gives the origin of *given* constraints
1013 --   a) type variables are skolemised
1014 --   b) an implication constraint is generated
1015 data SkolemInfo
1016   = SigSkol UserTypeCtxt        -- A skolem that is created by instantiating
1017             Type                -- a programmer-supplied type signature
1018                                 -- Location of the binding site is on the TyVar
1019
1020         -- The rest are for non-scoped skolems
1021   | ClsSkol Class       -- Bound at a class decl
1022   | InstSkol            -- Bound at an instance decl
1023   | DataSkol            -- Bound at a data type declaration
1024   | FamInstSkol         -- Bound at a family instance decl
1025   | PatSkol             -- An existential type variable bound by a pattern for
1026       DataCon           -- a data constructor with an existential type.
1027       (HsMatchContext Name)
1028              -- e.g.   data T = forall a. Eq a => MkT a
1029              --        f (MkT x) = ...
1030              -- The pattern MkT x will allocate an existential type
1031              -- variable for 'a'.
1032
1033   | ArrowSkol           -- An arrow form (see TcArrows)
1034
1035   | IPSkol [IPName Name]  -- Binding site of an implicit parameter
1036
1037   | RuleSkol RuleName   -- The LHS of a RULE
1038
1039   | InferSkol [(Name,TcType)]
1040                         -- We have inferred a type for these (mutually-recursivive)
1041                         -- polymorphic Ids, and are now checking that their RHS
1042                         -- constraints are satisfied.
1043
1044   | RuntimeUnkSkol      -- a type variable used to represent an unknown
1045                         -- runtime type (used in the GHCi debugger)
1046
1047   | BracketSkol         -- Template Haskell bracket
1048
1049   | UnkSkol             -- Unhelpful info (until I improve it)
1050
1051 instance Outputable SkolemInfo where
1052   ppr = pprSkolInfo
1053
1054 pprSkolInfo :: SkolemInfo -> SDoc
1055 -- Complete the sentence "is a rigid type variable bound by..."
1056 pprSkolInfo (SigSkol (FunSigCtxt f) ty)
1057                             = hang (ptext (sLit "the type signature for"))
1058                                  2 (ppr f <+> dcolon <+> ppr ty)
1059 pprSkolInfo (SigSkol cx ty) = hang (pprUserTypeCtxt cx <> colon)
1060                                  2 (ppr ty)
1061 pprSkolInfo (IPSkol ips)    = ptext (sLit "the implicit-parameter bindings for")
1062                               <+> pprWithCommas ppr ips
1063 pprSkolInfo (ClsSkol cls)   = ptext (sLit "the class declaration for") <+> quotes (ppr cls)
1064 pprSkolInfo InstSkol        = ptext (sLit "the instance declaration")
1065 pprSkolInfo DataSkol        = ptext (sLit "the data type declaration")
1066 pprSkolInfo FamInstSkol     = ptext (sLit "the family instance declaration")
1067 pprSkolInfo BracketSkol     = ptext (sLit "a Template Haskell bracket")
1068 pprSkolInfo (RuleSkol name) = ptext (sLit "the RULE") <+> doubleQuotes (ftext name)
1069 pprSkolInfo ArrowSkol       = ptext (sLit "the arrow form")
1070 pprSkolInfo (PatSkol dc mc)  = sep [ ptext (sLit "a pattern with constructor")
1071                                    , nest 2 $ ppr dc <+> dcolon
1072                                               <+> ppr (dataConUserType dc) <> comma
1073                                   , ptext (sLit "in") <+> pprMatchContext mc ]
1074 pprSkolInfo (InferSkol ids) = sep [ ptext (sLit "the inferred type of")
1075                                   , vcat [ ppr name <+> dcolon <+> ppr ty
1076                                          | (name,ty) <- ids ]]
1077
1078 -- UnkSkol
1079 -- For type variables the others are dealt with by pprSkolTvBinding.
1080 -- For Insts, these cases should not happen
1081 pprSkolInfo UnkSkol        = WARN( True, text "pprSkolInfo: UnkSkol" ) ptext (sLit "UnkSkol")
1082 pprSkolInfo RuntimeUnkSkol = WARN( True, text "pprSkolInfo: RuntimeUnkSkol" ) ptext (sLit "RuntimeUnkSkol")
1083 \end{code}
1084
1085
1086 %************************************************************************
1087 %*                                                                      *
1088             CtOrigin
1089 %*                                                                      *
1090 %************************************************************************
1091
1092 \begin{code}
1093 -- CtOrigin gives the origin of *wanted* constraints
1094 data CtOrigin
1095   = OccurrenceOf Name           -- Occurrence of an overloaded identifier
1096   | AppOrigin                   -- An application of some kind
1097
1098   | SpecPragOrigin Name         -- Specialisation pragma for identifier
1099
1100   | TypeEqOrigin EqOrigin
1101
1102   | IPOccOrigin  (IPName Name)  -- Occurrence of an implicit parameter
1103
1104   | LiteralOrigin (HsOverLit Name)      -- Occurrence of a literal
1105   | NegateOrigin                        -- Occurrence of syntactic negation
1106
1107   | ArithSeqOrigin (ArithSeqInfo Name) -- [x..], [x..y] etc
1108   | PArrSeqOrigin  (ArithSeqInfo Name) -- [:x..y:] and [:x,y..z:]
1109   | SectionOrigin
1110   | TupleOrigin                        -- (..,..)
1111   | ExprSigOrigin       -- e :: ty
1112   | PatSigOrigin        -- p :: ty
1113   | PatOrigin           -- Instantiating a polytyped pattern at a constructor
1114   | RecordUpdOrigin
1115   | ViewPatOrigin
1116
1117   | ScOrigin            -- Typechecking superclasses of an instance declaration
1118   | DerivOrigin         -- Typechecking deriving
1119   | StandAloneDerivOrigin -- Typechecking stand-alone deriving
1120   | DefaultOrigin       -- Typechecking a default decl
1121   | DoOrigin            -- Arising from a do expression
1122   | IfOrigin            -- Arising from an if statement
1123   | ProcOrigin          -- Arising from a proc expression
1124   | AnnOrigin           -- An annotation
1125   | FunDepOrigin
1126
1127 data EqOrigin
1128   = UnifyOrigin
1129        { uo_actual   :: TcType
1130        , uo_expected :: TcType }
1131
1132 instance Outputable CtOrigin where
1133   ppr orig = pprO orig
1134
1135 pprO :: CtOrigin -> SDoc
1136 pprO (OccurrenceOf name)   = hsep [ptext (sLit "a use of"), quotes (ppr name)]
1137 pprO AppOrigin             = ptext (sLit "an application")
1138 pprO (SpecPragOrigin name) = hsep [ptext (sLit "a specialisation pragma for"), quotes (ppr name)]
1139 pprO (IPOccOrigin name)    = hsep [ptext (sLit "a use of implicit parameter"), quotes (ppr name)]
1140 pprO RecordUpdOrigin       = ptext (sLit "a record update")
1141 pprO ExprSigOrigin         = ptext (sLit "an expression type signature")
1142 pprO PatSigOrigin          = ptext (sLit "a pattern type signature")
1143 pprO PatOrigin             = ptext (sLit "a pattern")
1144 pprO ViewPatOrigin         = ptext (sLit "a view pattern")
1145 pprO IfOrigin              = ptext (sLit "an if statement")
1146 pprO (LiteralOrigin lit)   = hsep [ptext (sLit "the literal"), quotes (ppr lit)]
1147 pprO (ArithSeqOrigin seq)  = hsep [ptext (sLit "the arithmetic sequence"), quotes (ppr seq)]
1148 pprO (PArrSeqOrigin seq)   = hsep [ptext (sLit "the parallel array sequence"), quotes (ppr seq)]
1149 pprO SectionOrigin         = ptext (sLit "an operator section")
1150 pprO TupleOrigin           = ptext (sLit "a tuple")
1151 pprO NegateOrigin          = ptext (sLit "a use of syntactic negation")
1152 pprO ScOrigin              = ptext (sLit "the superclasses of an instance declaration")
1153 pprO DerivOrigin           = ptext (sLit "the 'deriving' clause of a data type declaration")
1154 pprO StandAloneDerivOrigin = ptext (sLit "a 'deriving' declaration")
1155 pprO DefaultOrigin         = ptext (sLit "a 'default' declaration")
1156 pprO DoOrigin              = ptext (sLit "a do statement")
1157 pprO ProcOrigin            = ptext (sLit "a proc expression")
1158 pprO (TypeEqOrigin eq)     = ptext (sLit "an equality") <+> ppr eq
1159 pprO AnnOrigin             = ptext (sLit "an annotation")
1160 pprO FunDepOrigin          = ptext (sLit "a functional dependency")
1161
1162 instance Outputable EqOrigin where
1163   ppr (UnifyOrigin t1 t2) = ppr t1 <+> char '~' <+> ppr t2
1164 \end{code}
1165