compiler/typecheck/TcSplice.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 TcSplice: Template Haskell splices
   7
   8
   9 \begin{code}
  10 {-# OPTIONS -fno-warn-unused-imports -fno-warn-unused-binds #-}
  11 -- The above warning supression flag is a temporary kludge.
  12 -- While working on this module you are encouraged to remove it and fix
  13 -- any warnings in the module. See
  14 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  15 -- for details
  16
  17 module TcSplice( kcSpliceType, tcSpliceExpr, tcSpliceDecls, tcBracket,
  18                  lookupThName_maybe,
  19                  runQuasiQuoteExpr, runQuasiQuotePat, runAnnotation ) where
  20
  21 #include "HsVersions.h"
  22
  23 import HscMain
  24 import TcRnDriver
  25         -- These imports are the reason that TcSplice
  26         -- is very high up the module hierarchy
  27
  28 import HsSyn
  29 import Convert
  30 import RnExpr
  31 import RnEnv
  32 import RdrName
  33 import RnTypes
  34 import TcExpr
  35 import TcHsSyn
  36 import TcSimplify
  37 import TcUnify
  38 import TcType
  39 import TcEnv
  40 import TcMType
  41 import TcHsType
  42 import TcIface
  43 import TypeRep
  44 import Name
  45 import NameEnv
  46 import PrelNames
  47 import HscTypes
  48 import OccName
  49 import Var
  50 import Module
  51 import Annotations
  52 import TcRnMonad
  53 import Class
  54 import Inst
  55 import TyCon
  56 import DataCon
  57 import Id
  58 import IdInfo
  59 import TysWiredIn
  60 import DsMeta
  61 import DsExpr
  62 import DsMonad hiding (Splice)
  63 import Serialized
  64 import ErrUtils
  65 import SrcLoc
  66 import Outputable
  67 import Unique
  68 import Data.Maybe
  69 import BasicTypes
  70 import Panic
  71 import FastString
  72 import Exception
  73
  74 import qualified Language.Haskell.TH as TH
  75 -- THSyntax gives access to internal functions and data types
  76 import qualified Language.Haskell.TH.Syntax as TH
  77
  78 #ifdef GHCI
  79 -- Because GHC.Desugar might not be in the base library of the bootstrapping compiler
  80 import GHC.Desugar      ( AnnotationWrapper(..) )
  81 #endif
  82
  83 import GHC.Exts         ( unsafeCoerce#, Int#, Int(..) )
  84 import System.IO.Error
  85 \end{code}
  86
  87 Note [How top-level splices are handled]
  88 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  89 Top-level splices (those not inside a [| .. |] quotation bracket) are handled
  90 very straightforwardly:
  91
  92   1. tcTopSpliceExpr: typecheck the body e of the splice $(e)
  93
  94   2. runMetaT: desugar, compile, run it, and convert result back to
  95      HsSyn RdrName (of the appropriate flavour, eg HsType RdrName,
  96      HsExpr RdrName etc)
  97
  98   3. treat the result as if that's what you saw in the first place
  99      e.g for HsType, rename and kind-check
 100          for HsExpr, rename and type-check
 101
 102      (The last step is different for decls, becuase they can *only* be
 103       top-level: we return the result of step 2.)
 104
 105 Note [How brackets and nested splices are handled]
 106 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 107 Nested splices (those inside a [| .. |] quotation bracket), are treated
 108 quite differently.
 109
 110   * After typechecking, the bracket [| |] carries
 111
 112      a) A mutable list of PendingSplice
 113           type PendingSplice = (Name, LHsExpr Id)
 114
 115      b) The quoted expression e, *renamed*: (HsExpr Name)
 116           The expression e has been typechecked, but the result of
 117           that typechecking is discarded.
 118
 119   * The brakcet is desugared by DsMeta.dsBracket.  It
 120
 121       a) Extends the ds_meta environment with the PendingSplices
 122          attached to the bracket
 123
 124       b) Converts the quoted (HsExpr Name) to a CoreExpr that, when
 125          run, will produce a suitable TH expression/type/decl.  This
 126          is why we leave the *renamed* expression attached to the bracket:
 127          the quoted expression should not be decorated with all the goop
 128          added by the type checker
 129
 130   * Each splice carries a unique Name, called a "splice point", thus
 131     ${n}(e).  The name is initialised to an (Unqual "splice") when the
 132     splice is created; the renamer gives it a unique.
 133
 134   * When the type checker type-checks a nested splice ${n}(e), it
 135         - typechecks e
 136         - adds the typechecked expression (of type (HsExpr Id))
 137           as a pending splice to the enclosing bracket
 138         - returns something non-committal
 139     Eg for [| f ${n}(g x) |], the typechecker
 140         - attaches the typechecked term (g x) to the pending splices for n
 141           in the outer bracket
 142         - returns a non-committal type \alpha.
 143         Remember that the bracket discards the typechecked term altogether
 144
 145   * When DsMeta (used to desugar the body of the bracket) comes across
 146     a splice, it looks up the splice's Name, n, in the ds_meta envt,
 147     to find an (HsExpr Id) that should be substituted for the splice;
 148     it just desugars it to get a CoreExpr (DsMeta.repSplice).
 149
 150 Example:
 151     Source:       f = [| Just $(g 3) |]
 152       The [| |] part is a HsBracket
 153
 154     Typechecked:  f = [| Just ${s7}(g 3) |]{s7 = g Int 3}
 155       The [| |] part is a HsBracketOut, containing *renamed*
 156         (not typechecked) expression
 157       The "s7" is the "splice point"; the (g Int 3) part
 158         is a typechecked expression
 159
 160     Desugared:    f = do { s7 <- g Int 3
 161                          ; return (ConE "Data.Maybe.Just" s7) }
 162
 163
 164 Note [Template Haskell state diagram]
 165 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 166 Here are the ThStages, s, their corresponding level numbers
 167 (the result of (thLevel s)), and their state transitions.
 168
 169       -----------     $      ------------   $
 170       |  Comp   | ---------> |  Splice  | -----|
 171       |   1     |            |    0     | <----|
 172       -----------            ------------
 173         ^     |                ^      |
 174       $ |     | [||]         $ |      | [||]
 175         |     v                |      v
 176    --------------          ----------------
 177    | Brack Comp |          | Brack Splice |
 178    |     2      |          |      1       |
 179    --------------          ----------------
 180
 181 * Normal top-level declarations start in state Comp
 182        (which has level 1).
 183   Annotations start in state Splice, since they are
 184        treated very like a splice (only without a '$')
 185
 186 * Code compiled in state Splice (and only such code)
 187   will be *run at compile time*, with the result replacing
 188   the splice
 189
 190 * The original paper used level -1 instead of 0, etc.
 191
 192 * The original paper did not allow a splice within a
 193   splice, but there is no reason not to. This is the
 194   $ transition in the top right.
 195
 196 Note [Template Haskell levels]
 197 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 198 * Imported things are impLevel (= 0)
 199
 200 * In GHCi, variables bound by a previous command are treated
 201   as impLevel, because we have bytecode for them.
 202
 203 * Variables are bound at the "current level"
 204
 205 * The current level starts off at outerLevel (= 1)
 206
 207 * The level is decremented by splicing $(..)
 208                incremented by brackets [| |]
 209                incremented by name-quoting 'f
 210
 211 When a variable is used, we compare
 212         bind:  binding level, and
 213         use:   current level at usage site
 214
 215   Generally
 216         bind > use      Always error (bound later than used)
 217                         [| \x -> $(f x) |]
 218
 219         bind = use      Always OK (bound same stage as used)
 220                         [| \x -> $(f [| x |]) |]
 221
 222         bind < use      Inside brackets, it depends
 223                         Inside splice, OK
 224                         Inside neither, OK
 225
 226   For (bind < use) inside brackets, there are three cases:
 227     - Imported things   OK      f = [| map |]
 228     - Top-level things  OK      g = [| f |]
 229     - Non-top-level     Only if there is a liftable instance
 230                                 h = \(x:Int) -> [| x |]
 231
 232 See Note [What is a top-level Id?]
 233
 234 Note [Quoting names]
 235 ~~~~~~~~~~~~~~~~~~~~
 236 A quoted name 'n is a bit like a quoted expression [| n |], except that we
 237 have no cross-stage lifting (c.f. TcExpr.thBrackId).  So, after incrementing
 238 the use-level to account for the brackets, the cases are:
 239
 240         bind > use                      Error
 241         bind = use                      OK
 242         bind < use
 243                 Imported things         OK
 244                 Top-level things        OK
 245                 Non-top-level           Error
 246
 247 See Note [What is a top-level Id?] in TcEnv.  Examples:
 248
 249   f 'map        -- OK; also for top-level defns of this module
 250
 251   \x. f 'x      -- Not ok (whereas \x. f [| x |] might have been ok, by
 252                 --                               cross-stage lifting
 253
 254   \y. [| \x. $(f 'y) |] -- Not ok (same reason)
 255
 256   [| \x. $(f 'x) |]     -- OK
 257
 258
 259 Note [What is a top-level Id?]
 260 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 261 In the level-control criteria above, we need to know what a "top level Id" is.
 262 There are three kinds:
 263   * Imported from another module                (GlobalId, ExternalName)
 264   * Bound at the top level of this module       (ExternalName)
 265   * In GHCi, bound by a previous stmt           (GlobalId)
 266 It's strange that there is no one criterion tht picks out all three, but that's
 267 how it is right now.  (The obvious thing is to give an ExternalName to GHCi Ids
 268 bound in an earlier Stmt, but what module would you choose?  See
 269 Note [Interactively-bound Ids in GHCi] in TcRnDriver.)
 270
 271 The predicate we use is TcEnv.thTopLevelId.
 272
 273
 274 %************************************************************************
 275 %*                                                                      *
 276 \subsection{Main interface + stubs for the non-GHCI case
 277 %*                                                                      *
 278 %************************************************************************
 279
 280 \begin{code}
 281 tcBracket     :: HsBracket Name -> BoxyRhoType -> TcM (LHsExpr TcId)
 282 tcSpliceDecls :: LHsExpr Name -> TcM [LHsDecl RdrName]
 283 tcSpliceExpr  :: HsSplice Name -> BoxyRhoType -> TcM (HsExpr TcId)
 284 kcSpliceType  :: HsSplice Name -> TcM (HsType Name, TcKind)
 285         -- None of these functions add constraints to the LIE
 286
 287 lookupThName_maybe :: TH.Name -> TcM (Maybe Name)
 288
 289 runQuasiQuoteExpr :: HsQuasiQuote Name -> TcM (LHsExpr RdrName)
 290 runQuasiQuotePat  :: HsQuasiQuote Name -> TcM (LPat RdrName)
 291 runAnnotation     :: CoreAnnTarget -> LHsExpr Name -> TcM Annotation
 292
 293 #ifndef GHCI
 294 tcBracket     x _ = pprPanic "Cant do tcBracket without GHCi"     (ppr x)
 295 tcSpliceExpr  e   = pprPanic "Cant do tcSpliceExpr without GHCi"  (ppr e)
 296 tcSpliceDecls x   = pprPanic "Cant do tcSpliceDecls without GHCi" (ppr x)
 297 kcSpliceType  x   = pprPanic "Cant do kcSpliceType without GHCi"  (ppr x)
 298
 299 lookupThName_maybe n = pprPanic "Cant do lookupThName_maybe without GHCi" (ppr n)
 300
 301 runQuasiQuoteExpr q = pprPanic "Cant do runQuasiQuoteExpr without GHCi" (ppr q)
 302 runQuasiQuotePat  q = pprPanic "Cant do runQuasiQuotePat without GHCi" (ppr q)
 303 runAnnotation   _ q = pprPanic "Cant do runAnnotation without GHCi" (ppr q)
 304 #else
 305 \end{code}
 306
 307 %************************************************************************
 308 %*                                                                      *
 309 \subsection{Quoting an expression}
 310 %*                                                                      *
 311 %************************************************************************
 312
 313
 314 \begin{code}
 315 -- See Note [How brackets and nested splices are handled]
 316 tcBracket brack res_ty
 317   = addErrCtxt (hang (ptext (sLit "In the Template Haskell quotation"))
 318                    2 (ppr brack)) $
 319     do {        -- Check for nested brackets
 320          cur_stage <- getStage
 321        ; checkTc (not (isBrackStage cur_stage)) illegalBracket
 322
 323         -- Brackets are desugared to code that mentions the TH package
 324        ; recordThUse
 325
 326         -- Typecheck expr to make sure it is valid,
 327         -- but throw away the results.  We'll type check
 328         -- it again when we actually use it.
 329        ; pending_splices <- newMutVar []
 330        ; lie_var <- getLIEVar
 331
 332        ; (meta_ty, lie) <- setStage (Brack cur_stage pending_splices lie_var)
 333                                     (getLIE (tc_bracket cur_stage brack))
 334        ; tcSimplifyBracket lie
 335
 336         -- Make the expected type have the right shape
 337        ; _ <- boxyUnify meta_ty res_ty
 338
 339         -- Return the original expression, not the type-decorated one
 340        ; pendings <- readMutVar pending_splices
 341        ; return (noLoc (HsBracketOut brack pendings)) }
 342
 343 tc_bracket :: ThStage -> HsBracket Name -> TcM TcType
 344 tc_bracket outer_stage (VarBr name)     -- Note [Quoting names]
 345   = do  { thing <- tcLookup name
 346         ; case thing of
 347             AGlobal _ -> return ()
 348             ATcId { tct_level = bind_lvl, tct_id = id }
 349                 | thTopLevelId id       -- C.f TcExpr.checkCrossStageLifting
 350                 -> keepAliveTc id
 351                 | otherwise
 352                 -> do { checkTc (thLevel outer_stage + 1 == bind_lvl)
 353                                 (quotedNameStageErr name) }
 354             _ -> pprPanic "th_bracket" (ppr name)
 355
 356         ; tcMetaTy nameTyConName        -- Result type is Var (not Q-monadic)
 357         }
 358
 359 tc_bracket _ (ExpBr expr)
 360   = do  { any_ty <- newFlexiTyVarTy liftedTypeKind
 361         ; _ <- tcMonoExprNC expr any_ty  -- NC for no context; tcBracket does that
 362         ; tcMetaTy expQTyConName }
 363         -- Result type is Expr (= Q Exp)
 364
 365 tc_bracket _ (TypBr typ)
 366   = do  { _ <- tcHsSigTypeNC ThBrackCtxt typ
 367         ; tcMetaTy typeQTyConName }
 368         -- Result type is Type (= Q Typ)
 369
 370 tc_bracket _ (DecBr decls)
 371   = do  { _ <- tcTopSrcDecls emptyModDetails decls
 372         -- Typecheck the declarations, dicarding the result
 373         -- We'll get all that stuff later, when we splice it in
 374
 375         ; decl_ty <- tcMetaTy decTyConName
 376         ; q_ty    <- tcMetaTy qTyConName
 377         ; return (mkAppTy q_ty (mkListTy decl_ty))
 378         -- Result type is Q [Dec]
 379     }
 380
 381 tc_bracket _ (PatBr _)
 382   = failWithTc (ptext (sLit "Tempate Haskell pattern brackets are not supported yet"))
 383
 384 quotedNameStageErr :: Name -> SDoc
 385 quotedNameStageErr v
 386   = sep [ ptext (sLit "Stage error: the non-top-level quoted name") <+> ppr (VarBr v)
 387         , ptext (sLit "must be used at the same stage at which is is bound")]
 388 \end{code}
 389
 390
 391 %************************************************************************
 392 %*                                                                      *
 393 \subsection{Splicing an expression}
 394 %*                                                                      *
 395 %************************************************************************
 396
 397 \begin{code}
 398 tcSpliceExpr (HsSplice name expr) res_ty
 399   = setSrcSpan (getLoc expr)    $ do
 400     { stage <- getStage
 401     ; case stage of {
 402         Splice -> tcTopSplice expr res_ty ;
 403         Comp   -> tcTopSplice expr res_ty ;
 404
 405         Brack pop_stage ps_var lie_var -> do
 406
 407         -- See Note [How brackets and nested splices are handled]
 408         -- A splice inside brackets
 409         -- NB: ignore res_ty, apart from zapping it to a mono-type
 410         -- e.g.   [| reverse $(h 4) |]
 411         -- Here (h 4) :: Q Exp
 412         -- but $(h 4) :: forall a.a     i.e. anything!
 413
 414      { _ <- unBox res_ty
 415      ; meta_exp_ty <- tcMetaTy expQTyConName
 416      ; expr' <- setStage pop_stage $
 417                 setLIEVar lie_var    $
 418                 tcMonoExpr expr meta_exp_ty
 419
 420         -- Write the pending splice into the bucket
 421      ; ps <- readMutVar ps_var
 422      ; writeMutVar ps_var ((name,expr') : ps)
 423
 424      ; return (panic "tcSpliceExpr")    -- The returned expression is ignored
 425      }}}
 426
 427 tcTopSplice :: LHsExpr Name -> BoxyRhoType -> TcM (HsExpr Id)
 428 -- Note [How top-level splices are handled]
 429 tcTopSplice expr res_ty
 430   = do { meta_exp_ty <- tcMetaTy expQTyConName
 431
 432         -- Typecheck the expression
 433        ; zonked_q_expr <- tcTopSpliceExpr (tcMonoExpr expr meta_exp_ty)
 434
 435         -- Run the expression
 436        ; expr2 <- runMetaE zonked_q_expr
 437        ; showSplice "expression" expr (ppr expr2)
 438
 439         -- Rename it, but bale out if there are errors
 440         -- otherwise the type checker just gives more spurious errors
 441        ; (exp3, _fvs) <- checkNoErrs (rnLExpr expr2)
 442
 443        ; exp4 <- tcMonoExpr exp3 res_ty
 444        ; return (unLoc exp4) }
 445
 446 -------------------
 447 tcTopSpliceExpr :: TcM (LHsExpr Id) -> TcM (LHsExpr Id)
 448 -- Note [How top-level splices are handled]
 449 -- Type check an expression that is the body of a top-level splice
 450 --   (the caller will compile and run it)
 451 -- Note that set the level to Splice, regardless of the original level,
 452 -- before typechecking the expression.  For example:
 453 --      f x = $( ...$(g 3) ... )
 454 -- The recursive call to tcMonoExpr will simply expand the
 455 -- inner escape before dealing with the outer one
 456
 457 tcTopSpliceExpr tc_action
 458   = checkNoErrs $  -- checkNoErrs: must not try to run the thing
 459                    -- if the type checker fails!
 460     setStage Splice $
 461     do {    -- Typecheck the expression
 462          (expr', lie) <- getLIE tc_action
 463
 464         -- Solve the constraints
 465         ; const_binds <- tcSimplifyTop lie
 466
 467           -- Zonk it and tie the knot of dictionary bindings
 468        ; zonkTopLExpr (mkHsDictLet const_binds expr') }
 469 \end{code}
 470
 471
 472 %************************************************************************
 473 %*                                                                      *
 474                 Splicing a type
 475 %*                                                                      *
 476 %************************************************************************
 477
 478 Very like splicing an expression, but we don't yet share code.
 479
 480 \begin{code}
 481 kcSpliceType (HsSplice name hs_expr)
 482   = setSrcSpan (getLoc hs_expr) $ do
 483     { stage <- getStage
 484     ; case stage of {
 485         Splice -> kcTopSpliceType hs_expr ;
 486         Comp   -> kcTopSpliceType hs_expr ;
 487
 488         Brack pop_level ps_var lie_var -> do
 489            -- See Note [How brackets and nested splices are handled]
 490            -- A splice inside brackets
 491     { meta_ty <- tcMetaTy typeQTyConName
 492     ; expr' <- setStage pop_level $
 493                setLIEVar lie_var $
 494                tcMonoExpr hs_expr meta_ty
 495
 496         -- Write the pending splice into the bucket
 497     ; ps <- readMutVar ps_var
 498     ; writeMutVar ps_var ((name,expr') : ps)
 499
 500     -- e.g.   [| f (g :: Int -> $(h 4)) |]
 501     -- Here (h 4) :: Q Type
 502     -- but $(h 4) :: a  i.e. any type, of any kind
 503
 504     -- We return a HsSpliceTyOut, which serves to convey the kind to
 505     -- the ensuing TcHsType.dsHsType, which makes up a non-committal
 506     -- type variable of a suitable kind
 507     ; kind <- newKindVar
 508     ; return (HsSpliceTyOut kind, kind)
 509     }}}
 510
 511 kcTopSpliceType :: LHsExpr Name -> TcM (HsType Name, TcKind)
 512 -- Note [How top-level splices are handled]
 513 kcTopSpliceType expr
 514   = do  { meta_ty <- tcMetaTy typeQTyConName
 515
 516         -- Typecheck the expression
 517         ; zonked_q_expr <- tcTopSpliceExpr (tcMonoExpr expr meta_ty)
 518
 519         -- Run the expression
 520         ; hs_ty2 <- runMetaT zonked_q_expr
 521         ; showSplice "type" expr (ppr hs_ty2)
 522
 523         -- Rename it, but bale out if there are errors
 524         -- otherwise the type checker just gives more spurious errors
 525         ; let doc = ptext (sLit "In the spliced type") <+> ppr hs_ty2
 526         ; hs_ty3 <- checkNoErrs (rnLHsType doc hs_ty2)
 527
 528         ; (ty4, kind) <- kcLHsType hs_ty3
 529         ; return (unLoc ty4, kind) }
 530 \end{code}
 531
 532 %************************************************************************
 533 %*                                                                      *
 534 \subsection{Splicing an expression}
 535 %*                                                                      *
 536 %************************************************************************
 537
 538 \begin{code}
 539 -- Note [How top-level splices are handled]
 540 -- Always at top level
 541 -- Type sig at top of file:
 542 --      tcSpliceDecls :: LHsExpr Name -> TcM [LHsDecl RdrName]
 543 tcSpliceDecls expr
 544   = do  { meta_dec_ty <- tcMetaTy decTyConName
 545         ; meta_q_ty <- tcMetaTy qTyConName
 546         ; let list_q = mkAppTy meta_q_ty (mkListTy meta_dec_ty)
 547         ; zonked_q_expr <- tcTopSpliceExpr (tcMonoExpr expr list_q)
 548
 549                 -- Run the expression
 550         ; decls <- runMetaD zonked_q_expr
 551         ; showSplice "declarations" expr
 552                      (ppr (getLoc expr) $$ (vcat (map ppr decls)))
 553
 554         ; return decls }
 555 \end{code}
 556
 557
 558 %************************************************************************
 559 %*                                                                      *
 560         Annotations
 561 %*                                                                      *
 562 %************************************************************************
 563
 564 \begin{code}
 565 runAnnotation target expr = do
 566     -- Find the classes we want instances for in order to call toAnnotationWrapper
 567     loc <- getSrcSpanM
 568     data_class <- tcLookupClass dataClassName
 569     to_annotation_wrapper_id <- tcLookupId toAnnotationWrapperName
 570
 571     -- Check the instances we require live in another module (we want to execute it..)
 572     -- and check identifiers live in other modules using TH stage checks. tcSimplifyStagedExpr
 573     -- also resolves the LIE constraints to detect e.g. instance ambiguity
 574     zonked_wrapped_expr' <- tcTopSpliceExpr $
 575            do { (expr', expr_ty) <- tcInferRhoNC expr
 576                 -- We manually wrap the typechecked expression in a call to toAnnotationWrapper
 577                 -- By instantiating the call >here< it gets registered in the
 578                 -- LIE consulted by tcTopSpliceExpr
 579                 -- and hence ensures the appropriate dictionary is bound by const_binds
 580               ; wrapper <- instCall AnnOrigin [expr_ty] [mkClassPred data_class [expr_ty]]
 581               ; let specialised_to_annotation_wrapper_expr
 582                       = L loc (HsWrap wrapper (HsVar to_annotation_wrapper_id))
 583               ; return (L loc (HsApp specialised_to_annotation_wrapper_expr expr')) }
 584
 585     -- Run the appropriately wrapped expression to get the value of
 586     -- the annotation and its dictionaries. The return value is of
 587     -- type AnnotationWrapper by construction, so this conversion is
 588     -- safe
 589     flip runMetaAW zonked_wrapped_expr' $ \annotation_wrapper ->
 590         case annotation_wrapper of
 591             AnnotationWrapper value | let serialized = toSerialized serializeWithData value ->
 592                 -- Got the value and dictionaries: build the serialized value and
 593                 -- call it a day. We ensure that we seq the entire serialized value
 594                 -- in order that any errors in the user-written code for the
 595                 -- annotation are exposed at this point.  This is also why we are
 596                 -- doing all this stuff inside the context of runMeta: it has the
 597                 -- facilities to deal with user error in a meta-level expression
 598                 seqSerialized serialized `seq` Annotation {
 599                     ann_target = target,
 600                     ann_value = serialized
 601                 }
 602 \end{code}
 603
 604
 605 %************************************************************************
 606 %*                                                                      *
 607         Quasi-quoting
 608 %*                                                                      *
 609 %************************************************************************
 610
 611 Note [Quasi-quote overview]
 612 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
 613 The GHC "quasi-quote" extension is described by Geoff Mainland's paper
 614 "Why it's nice to be quoted: quasiquoting for Haskell" (Haskell
 615 Workshop 2007).
 616
 617 Briefly, one writes
 618         [:p| stuff |]
 619 and the arbitrary string "stuff" gets parsed by the parser 'p', whose
 620 type should be Language.Haskell.TH.Quote.QuasiQuoter.  'p' must be
 621 defined in another module, because we are going to run it here.  It's
 622 a bit like a TH splice:
 623         $(p "stuff")
 624
 625 However, you can do this in patterns as well as terms.  Becuase of this,
 626 the splice is run by the *renamer* rather than the type checker.
 627
 628 \begin{code}
 629 runQuasiQuote :: Outputable hs_syn
 630               => HsQuasiQuote Name      -- Contains term of type QuasiQuoter, and the String
 631               -> Name                   -- Of type QuasiQuoter -> String -> Q th_syn
 632               -> Name                   -- Name of th_syn type
 633               -> MetaOps th_syn hs_syn
 634               -> TcM hs_syn
 635 runQuasiQuote (HsQuasiQuote _name quoter q_span quote) quote_selector meta_ty meta_ops
 636   = do  { -- Check that the quoter is not locally defined, otherwise the TH
 637           -- machinery will not be able to run the quasiquote.
 638         ; this_mod <- getModule
 639         ; let is_local = case nameModule_maybe quoter of
 640                            Just mod | mod == this_mod -> True
 641                                     | otherwise       -> False
 642                            Nothing -> True
 643         ; traceTc (text "runQQ" <+> ppr quoter <+> ppr is_local)
 644         ; checkTc (not is_local) (quoteStageError quoter)
 645
 646           -- Build the expression
 647         ; let quoterExpr = L q_span $! HsVar $! quoter
 648         ; let quoteExpr = L q_span $! HsLit $! HsString quote
 649         ; let expr = L q_span $
 650                      HsApp (L q_span $
 651                             HsApp (L q_span (HsVar quote_selector)) quoterExpr) quoteExpr
 652         ; meta_exp_ty <- tcMetaTy meta_ty
 653
 654         -- Typecheck the expression
 655         ; zonked_q_expr <- tcTopSpliceExpr (tcMonoExpr expr meta_exp_ty)
 656
 657         -- Run the expression
 658         ; result <- runMetaQ meta_ops zonked_q_expr
 659         ; showSplice (mt_desc meta_ops) quoteExpr (ppr result)
 660
 661         ; return result }
 662
 663 runQuasiQuoteExpr quasiquote = runQuasiQuote quasiquote quoteExpName expQTyConName exprMetaOps
 664 runQuasiQuotePat  quasiquote = runQuasiQuote quasiquote quotePatName patQTyConName patMetaOps
 665
 666 quoteStageError :: Name -> SDoc
 667 quoteStageError quoter
 668   = sep [ptext (sLit "GHC stage restriction:") <+> ppr quoter,
 669          nest 2 (ptext (sLit "is used in a quasiquote, and must be imported, not defined locally"))]
 670 \end{code}
 671
 672
 673 %************************************************************************
 674 %*                                                                      *
 675 \subsection{Running an expression}
 676 %*                                                                      *
 677 %************************************************************************
 678
 679 \begin{code}
 680 data MetaOps th_syn hs_syn
 681   = MT { mt_desc :: String             -- Type of beast (expression, type etc)
 682        , mt_show :: th_syn -> String   -- How to show the th_syn thing
 683        , mt_cvt  :: SrcSpan -> th_syn -> Either Message hs_syn
 684                                        -- How to convert to hs_syn
 685     }
 686
 687 exprMetaOps :: MetaOps TH.Exp (LHsExpr RdrName)
 688 exprMetaOps = MT { mt_desc = "expression", mt_show = TH.pprint, mt_cvt = convertToHsExpr }
 689
 690 patMetaOps :: MetaOps TH.Pat (LPat RdrName)
 691 patMetaOps = MT { mt_desc = "pattern", mt_show = TH.pprint, mt_cvt = convertToPat }
 692
 693 typeMetaOps :: MetaOps TH.Type (LHsType RdrName)
 694 typeMetaOps = MT { mt_desc = "type", mt_show = TH.pprint, mt_cvt = convertToHsType }
 695
 696 declMetaOps :: MetaOps [TH.Dec] [LHsDecl RdrName]
 697 declMetaOps = MT { mt_desc = "declarations", mt_show = TH.pprint, mt_cvt = convertToHsDecls }
 698
 699 ----------------
 700 runMetaAW :: Outputable output
 701           => (AnnotationWrapper -> output)
 702           -> LHsExpr Id         -- Of type AnnotationWrapper
 703           -> TcM output
 704 runMetaAW k = runMeta False (\_ -> return . Right . k)
 705     -- We turn off showing the code in meta-level exceptions because doing so exposes
 706     -- the toAnnotationWrapper function that we slap around the users code
 707
 708 -----------------
 709 runMetaQ :: Outputable hs_syn
 710          => MetaOps th_syn hs_syn
 711          -> LHsExpr Id
 712          -> TcM hs_syn
 713 runMetaQ (MT { mt_show = show_th, mt_cvt = cvt }) expr
 714   = runMeta True run_and_cvt expr
 715   where
 716     run_and_cvt expr_span hval
 717        = do { th_result <- TH.runQ hval
 718             ; traceTc (text "Got TH result:" <+> text (show_th th_result))
 719             ; return (cvt expr_span th_result) }
 720
 721 runMetaE :: LHsExpr Id          -- Of type (Q Exp)
 722          -> TcM (LHsExpr RdrName)
 723 runMetaE = runMetaQ exprMetaOps
 724
 725 runMetaT :: LHsExpr Id          -- Of type (Q Type)
 726          -> TcM (LHsType RdrName)
 727 runMetaT = runMetaQ typeMetaOps
 728
 729 runMetaD :: LHsExpr Id          -- Of type Q [Dec]
 730          -> TcM [LHsDecl RdrName]
 731 runMetaD = runMetaQ declMetaOps
 732
 733 ---------------
 734 runMeta :: (Outputable hs_syn)
 735         => Bool                 -- Whether code should be printed in the exception message
 736         -> (SrcSpan -> x -> TcM (Either Message hs_syn))        -- How to run x
 737         -> LHsExpr Id           -- Of type x; typically x = Q TH.Exp, or something like that
 738         -> TcM hs_syn           -- Of type t
 739 runMeta show_code run_and_convert expr
 740   = do  { traceTc (text "About to run" <+> ppr expr)
 741
 742         -- Desugar
 743         ; ds_expr <- initDsTc (dsLExpr expr)
 744         -- Compile and link it; might fail if linking fails
 745         ; hsc_env <- getTopEnv
 746         ; src_span <- getSrcSpanM
 747         ; either_hval <- tryM $ liftIO $
 748                          HscMain.compileExpr hsc_env src_span ds_expr
 749         ; case either_hval of {
 750             Left exn   -> failWithTc (mk_msg "compile and link" exn) ;
 751             Right hval -> do
 752
 753         {       -- Coerce it to Q t, and run it
 754
 755                 -- Running might fail if it throws an exception of any kind (hence tryAllM)
 756                 -- including, say, a pattern-match exception in the code we are running
 757                 --
 758                 -- We also do the TH -> HS syntax conversion inside the same
 759                 -- exception-cacthing thing so that if there are any lurking
 760                 -- exceptions in the data structure returned by hval, we'll
 761                 -- encounter them inside the try
 762                 --
 763                 -- See Note [Exceptions in TH]
 764           let expr_span = getLoc expr
 765         ; either_tval <- tryAllM $
 766                          setSrcSpan expr_span $ -- Set the span so that qLocation can
 767                                                 -- see where this splice is
 768              do { mb_result <- run_and_convert expr_span (unsafeCoerce# hval)
 769                 ; case mb_result of
 770                     Left err     -> failWithTc err
 771                     Right result -> do { traceTc (ptext (sLit "Got HsSyn result:") <+> ppr result)
 772                                        ; return $! result } }
 773
 774         ; case either_tval of
 775             Right v -> return v
 776             Left se -> case fromException se of
 777                          Just IOEnvFailure -> failM -- Error already in Tc monad
 778                          _ -> failWithTc (mk_msg "run" se)      -- Exception
 779         }}}
 780   where
 781     mk_msg s exn = vcat [text "Exception when trying to" <+> text s <+> text "compile-time code:",
 782                          nest 2 (text (Panic.showException exn)),
 783                          if show_code then nest 2 (text "Code:" <+> ppr expr) else empty]
 784 \end{code}
 785
 786 Note [Exceptions in TH]
 787 ~~~~~~~~~~~~~~~~~~~~~~~
 788 Supppose we have something like this
 789         $( f 4 )
 790 where
 791         f :: Int -> Q [Dec]
 792         f n | n>3       = fail "Too many declarations"
 793             | otherwise = ...
 794
 795 The 'fail' is a user-generated failure, and should be displayed as a
 796 perfectly ordinary compiler error message, not a panic or anything
 797 like that.  Here's how it's processed:
 798
 799   * 'fail' is the monad fail.  The monad instance for Q in TH.Syntax
 800     effectively transforms (fail s) to
 801         qReport True s >> fail
 802     where 'qReport' comes from the Quasi class and fail from its monad
 803     superclass.
 804
 805   * The TcM monad is an instance of Quasi (see TcSplice), and it implements
 806     (qReport True s) by using addErr to add an error message to the bag of errors.
 807     The 'fail' in TcM raises an IOEnvFailure exception
 808
 809   * So, when running a splice, we catch all exceptions; then for
 810         - an IOEnvFailure exception, we assume the error is already
 811                 in the error-bag (above)
 812         - other errors, we add an error to the bag
 813     and then fail
 814
 815
 816 To call runQ in the Tc monad, we need to make TcM an instance of Quasi:
 817
 818 \begin{code}
 819 instance TH.Quasi (IOEnv (Env TcGblEnv TcLclEnv)) where
 820   qNewName s = do { u <- newUnique
 821                   ; let i = getKey u
 822                   ; return (TH.mkNameU s i) }
 823
 824   qReport True msg  = addErr (text msg)
 825   qReport False msg = addReport (text msg) empty
 826
 827   qLocation = do { m <- getModule
 828                  ; l <- getSrcSpanM
 829                  ; return (TH.Loc { TH.loc_filename = unpackFS (srcSpanFile l)
 830                                   , TH.loc_module   = moduleNameString (moduleName m)
 831                                   , TH.loc_package  = packageIdString (modulePackageId m)
 832                                   , TH.loc_start = (srcSpanStartLine l, srcSpanStartCol l)
 833                                   , TH.loc_end = (srcSpanEndLine   l, srcSpanEndCol   l) }) }
 834
 835   qReify v = reify v
 836
 837         -- For qRecover, discard error messages if
 838         -- the recovery action is chosen.  Otherwise
 839         -- we'll only fail higher up.  c.f. tryTcLIE_
 840   qRecover recover main = do { (msgs, mb_res) <- tryTcErrs main
 841                              ; case mb_res of
 842                                  Just val -> do { addMessages msgs      -- There might be warnings
 843                                                 ; return val }
 844                                  Nothing  -> recover                    -- Discard all msgs
 845                           }
 846
 847   qRunIO io = liftIO io
 848 \end{code}
 849
 850
 851 %************************************************************************
 852 %*                                                                      *
 853 \subsection{Errors and contexts}
 854 %*                                                                      *
 855 %************************************************************************
 856
 857 \begin{code}
 858 showSplice :: String -> LHsExpr Name -> SDoc -> TcM ()
 859 -- Note that 'before' is *renamed* but not *typechecked*
 860 -- Reason (a) less typechecking crap
 861 --        (b) data constructors after type checking have been
 862 --            changed to their *wrappers*, and that makes them
 863 --            print always fully qualified
 864 showSplice what before after
 865   = do { loc <- getSrcSpanM
 866        ; traceSplice (vcat [ppr loc <> colon <+> text "Splicing" <+> text what,
 867                             nest 2 (sep [nest 2 (ppr before),
 868                                          text "======>",
 869                                          nest 2 after])]) }
 870
 871 illegalBracket :: SDoc
 872 illegalBracket = ptext (sLit "Template Haskell brackets cannot be nested (without intervening splices)")
 873 #endif  /* GHCI */
 874 \end{code}
 875
 876
 877 %************************************************************************
 878 %*                                                                      *
 879                         Reification
 880 %*                                                                      *
 881 %************************************************************************
 882
 883
 884 \begin{code}
 885 reify :: TH.Name -> TcM TH.Info
 886 reify th_name
 887   = do  { name <- lookupThName th_name
 888         ; thing <- tcLookupTh name
 889                 -- ToDo: this tcLookup could fail, which would give a
 890                 --       rather unhelpful error message
 891         ; traceIf (text "reify" <+> text (show th_name) <+> brackets (ppr_ns th_name) <+> ppr name)
 892         ; reifyThing thing
 893     }
 894   where
 895     ppr_ns (TH.Name _ (TH.NameG TH.DataName _pkg _mod)) = text "data"
 896     ppr_ns (TH.Name _ (TH.NameG TH.TcClsName _pkg _mod)) = text "tc"
 897     ppr_ns (TH.Name _ (TH.NameG TH.VarName _pkg _mod)) = text "var"
 898     ppr_ns _ = panic "reify/ppr_ns"
 899
 900 lookupThName :: TH.Name -> TcM Name
 901 lookupThName th_name = do
 902     mb_name <- lookupThName_maybe th_name
 903     case mb_name of
 904         Nothing   -> failWithTc (notInScope th_name)
 905         Just name -> return name
 906
 907 lookupThName_maybe th_name
 908   =  do { names <- mapMaybeM lookup (thRdrNameGuesses th_name)
 909           -- Pick the first that works
 910           -- E.g. reify (mkName "A") will pick the class A in preference to the data constructor A
 911         ; return (listToMaybe names) }
 912   where
 913     lookup rdr_name
 914         = do {  -- Repeat much of lookupOccRn, becase we want
 915                 -- to report errors in a TH-relevant way
 916              ; rdr_env <- getLocalRdrEnv
 917              ; case lookupLocalRdrEnv rdr_env rdr_name of
 918                  Just name -> return (Just name)
 919                  Nothing   -> lookupGlobalOccRn_maybe rdr_name }
 920
 921 tcLookupTh :: Name -> TcM TcTyThing
 922 -- This is a specialised version of TcEnv.tcLookup; specialised mainly in that
 923 -- it gives a reify-related error message on failure, whereas in the normal
 924 -- tcLookup, failure is a bug.
 925 tcLookupTh name
 926   = do  { (gbl_env, lcl_env) <- getEnvs
 927         ; case lookupNameEnv (tcl_env lcl_env) name of {
 928                 Just thing -> return thing;
 929                 Nothing    -> do
 930         { if nameIsLocalOrFrom (tcg_mod gbl_env) name
 931           then  -- It's defined in this module
 932               case lookupNameEnv (tcg_type_env gbl_env) name of
 933                 Just thing -> return (AGlobal thing)
 934                 Nothing    -> failWithTc (notInEnv name)
 935
 936           else do               -- It's imported
 937         { (eps,hpt) <- getEpsAndHpt
 938         ; dflags <- getDOpts
 939         ; case lookupType dflags hpt (eps_PTE eps) name of
 940             Just thing -> return (AGlobal thing)
 941             Nothing    -> do { thing <- tcImportDecl name
 942                              ; return (AGlobal thing) }
 943                 -- Imported names should always be findable;
 944                 -- if not, we fail hard in tcImportDecl
 945     }}}}
 946
 947 notInScope :: TH.Name -> SDoc
 948 notInScope th_name = quotes (text (TH.pprint th_name)) <+>
 949                      ptext (sLit "is not in scope at a reify")
 950         -- Ugh! Rather an indirect way to display the name
 951
 952 notInEnv :: Name -> SDoc
 953 notInEnv name = quotes (ppr name) <+>
 954                      ptext (sLit "is not in the type environment at a reify")
 955
 956 ------------------------------
 957 reifyThing :: TcTyThing -> TcM TH.Info
 958 -- The only reason this is monadic is for error reporting,
 959 -- which in turn is mainly for the case when TH can't express
 960 -- some random GHC extension
 961
 962 reifyThing (AGlobal (AnId id))
 963   = do  { ty <- reifyType (idType id)
 964         ; fix <- reifyFixity (idName id)
 965         ; let v = reifyName id
 966         ; case idDetails id of
 967             ClassOpId cls    -> return (TH.ClassOpI v ty (reifyName cls) fix)
 968             _                -> return (TH.VarI     v ty Nothing fix)
 969     }
 970
 971 reifyThing (AGlobal (ATyCon tc))  = reifyTyCon tc
 972 reifyThing (AGlobal (AClass cls)) = reifyClass cls
 973 reifyThing (AGlobal (ADataCon dc))
 974   = do  { let name = dataConName dc
 975         ; ty <- reifyType (idType (dataConWrapId dc))
 976         ; fix <- reifyFixity name
 977         ; return (TH.DataConI (reifyName name) ty
 978                               (reifyName (dataConOrigTyCon dc)) fix)
 979         }
 980
 981 reifyThing (ATcId {tct_id = id, tct_type = ty})
 982   = do  { ty1 <- zonkTcType ty  -- Make use of all the info we have, even
 983                                 -- though it may be incomplete
 984         ; ty2 <- reifyType ty1
 985         ; fix <- reifyFixity (idName id)
 986         ; return (TH.VarI (reifyName id) ty2 Nothing fix) }
 987
 988 reifyThing (ATyVar tv ty)
 989   = do  { ty1 <- zonkTcType ty
 990         ; ty2 <- reifyType ty1
 991         ; return (TH.TyVarI (reifyName tv) ty2) }
 992
 993 reifyThing (AThing {}) = panic "reifyThing AThing"
 994
 995 ------------------------------
 996 reifyTyCon :: TyCon -> TcM TH.Info
 997 reifyTyCon tc
 998   | isFunTyCon tc
 999   = return (TH.PrimTyConI (reifyName tc) 2                False)
1000   | isPrimTyCon tc
1001   = return (TH.PrimTyConI (reifyName tc) (tyConArity tc) (isUnLiftedTyCon tc))
1002   | isOpenTyCon tc
1003   = let flavour = reifyFamFlavour tc
1004         tvs     = tyConTyVars tc
1005         kind    = tyConKind tc
1006         kind'
1007           | isLiftedTypeKind kind = Nothing
1008           | otherwise             = Just $ reifyKind kind
1009     in
1010     return (TH.TyConI $
1011               TH.FamilyD flavour (reifyName tc) (reifyTyVars tvs) kind')
1012   | isSynTyCon tc
1013   = do { let (tvs, rhs) = synTyConDefn tc
1014        ; rhs' <- reifyType rhs
1015        ; return (TH.TyConI $
1016                    TH.TySynD (reifyName tc) (reifyTyVars tvs) rhs')
1017        }
1018
1019 reifyTyCon tc
1020   = do  { cxt <- reifyCxt (tyConStupidTheta tc)
1021         ; let tvs = tyConTyVars tc
1022         ; cons <- mapM (reifyDataCon (mkTyVarTys tvs)) (tyConDataCons tc)
1023         ; let name = reifyName tc
1024               r_tvs  = reifyTyVars tvs
1025               deriv = []        -- Don't know about deriving
1026               decl | isNewTyCon tc = TH.NewtypeD cxt name r_tvs (head cons) deriv
1027                    | otherwise     = TH.DataD    cxt name r_tvs cons        deriv
1028         ; return (TH.TyConI decl) }
1029
1030 reifyDataCon :: [Type] -> DataCon -> TcM TH.Con
1031 reifyDataCon tys dc
1032   | isVanillaDataCon dc
1033   = do  { arg_tys <- reifyTypes (dataConInstOrigArgTys dc tys)
1034         ; let stricts = map reifyStrict (dataConStrictMarks dc)
1035               fields  = dataConFieldLabels dc
1036               name    = reifyName dc
1037               [a1,a2] = arg_tys
1038               [s1,s2] = stricts
1039         ; ASSERT( length arg_tys == length stricts )
1040           if not (null fields) then
1041              return (TH.RecC name (zip3 (map reifyName fields) stricts arg_tys))
1042           else
1043           if dataConIsInfix dc then
1044              ASSERT( length arg_tys == 2 )
1045              return (TH.InfixC (s1,a1) name (s2,a2))
1046           else
1047              return (TH.NormalC name (stricts `zip` arg_tys)) }
1048   | otherwise
1049   = failWithTc (ptext (sLit "Can't reify a GADT data constructor:")
1050                 <+> quotes (ppr dc))
1051
1052 ------------------------------
1053 reifyClass :: Class -> TcM TH.Info
1054 reifyClass cls
1055   = do  { cxt <- reifyCxt theta
1056         ; ops <- mapM reify_op op_stuff
1057         ; return (TH.ClassI $ TH.ClassD cxt (reifyName cls) (reifyTyVars tvs) fds' ops) }
1058   where
1059     (tvs, fds, theta, _, _, op_stuff) = classExtraBigSig cls
1060     fds' = map reifyFunDep fds
1061     reify_op (op, _) = do { ty <- reifyType (idType op)
1062                           ; return (TH.SigD (reifyName op) ty) }
1063
1064 ------------------------------
1065 reifyType :: TypeRep.Type -> TcM TH.Type
1066 reifyType (TyVarTy tv)      = return (TH.VarT (reifyName tv))
1067 reifyType (TyConApp tc tys) = reify_tc_app (reifyName tc) tys
1068 reifyType (AppTy t1 t2)     = do { [r1,r2] <- reifyTypes [t1,t2] ; return (r1 `TH.AppT` r2) }
1069 reifyType (FunTy t1 t2)     = do { [r1,r2] <- reifyTypes [t1,t2] ; return (TH.ArrowT `TH.AppT` r1 `TH.AppT` r2) }
1070 reifyType ty@(ForAllTy _ _) = do { cxt' <- reifyCxt cxt;
1071                                  ; tau' <- reifyType tau
1072                                  ; return (TH.ForallT (reifyTyVars tvs) cxt' tau') }
1073                             where
1074                                 (tvs, cxt, tau) = tcSplitSigmaTy ty
1075 reifyType (PredTy {}) = panic "reifyType PredTy"
1076
1077 reifyTypes :: [Type] -> TcM [TH.Type]
1078 reifyTypes = mapM reifyType
1079
1080 reifyKind :: Kind -> TH.Kind
1081 reifyKind  ki
1082   = let (kis, ki') = splitKindFunTys ki
1083         kis_rep    = map reifyKind kis
1084         ki'_rep    = reifyNonArrowKind ki'
1085     in
1086     foldl TH.ArrowK ki'_rep kis_rep
1087   where
1088     reifyNonArrowKind k | isLiftedTypeKind k = TH.StarK
1089                         | otherwise          = pprPanic "Exotic form of kind"
1090                                                         (ppr k)
1091
1092 reifyCxt :: [PredType] -> TcM [TH.Pred]
1093 reifyCxt   = mapM reifyPred
1094
1095 reifyFunDep :: ([TyVar], [TyVar]) -> TH.FunDep
1096 reifyFunDep (xs, ys) = TH.FunDep (map reifyName xs) (map reifyName ys)
1097
1098 reifyFamFlavour :: TyCon -> TH.FamFlavour
1099 reifyFamFlavour tc | isOpenSynTyCon tc = TH.TypeFam
1100                    | isOpenTyCon    tc = TH.DataFam
1101                    | otherwise
1102                    = panic "TcSplice.reifyFamFlavour: not a type family"
1103
1104 reifyTyVars :: [TyVar] -> [TH.TyVarBndr]
1105 reifyTyVars = map reifyTyVar
1106   where
1107     reifyTyVar tv | isLiftedTypeKind kind = TH.PlainTV  name
1108                   | otherwise             = TH.KindedTV name (reifyKind kind)
1109       where
1110         kind = tyVarKind tv
1111         name = reifyName tv
1112
1113 reify_tc_app :: TH.Name -> [TypeRep.Type] -> TcM TH.Type
1114 reify_tc_app tc tys = do { tys' <- reifyTypes tys
1115                          ; return (foldl TH.AppT (TH.ConT tc) tys') }
1116
1117 reifyPred :: TypeRep.PredType -> TcM TH.Pred
1118 reifyPred (ClassP cls tys)
1119   = do { tys' <- reifyTypes tys
1120        ; return $ TH.ClassP (reifyName cls) tys'
1121        }
1122 reifyPred p@(IParam _ _)   = noTH (sLit "implicit parameters") (ppr p)
1123 reifyPred (EqPred ty1 ty2)
1124   = do { ty1' <- reifyType ty1
1125        ; ty2' <- reifyType ty2
1126        ; return $ TH.EqualP ty1' ty2'
1127        }
1128
1129
1130 ------------------------------
1131 reifyName :: NamedThing n => n -> TH.Name
1132 reifyName thing
1133   | isExternalName name = mk_varg pkg_str mod_str occ_str
1134   | otherwise           = TH.mkNameU occ_str (getKey (getUnique name))
1135         -- Many of the things we reify have local bindings, and
1136         -- NameL's aren't supposed to appear in binding positions, so
1137         -- we use NameU.  When/if we start to reify nested things, that
1138         -- have free variables, we may need to generate NameL's for them.
1139   where
1140     name    = getName thing
1141     mod     = ASSERT( isExternalName name ) nameModule name
1142     pkg_str = packageIdString (modulePackageId mod)
1143     mod_str = moduleNameString (moduleName mod)
1144     occ_str = occNameString occ
1145     occ     = nameOccName name
1146     mk_varg | OccName.isDataOcc occ = TH.mkNameG_d
1147             | OccName.isVarOcc  occ = TH.mkNameG_v
1148             | OccName.isTcOcc   occ = TH.mkNameG_tc
1149             | otherwise             = pprPanic "reifyName" (ppr name)
1150
1151 ------------------------------
1152 reifyFixity :: Name -> TcM TH.Fixity
1153 reifyFixity name
1154   = do  { fix <- lookupFixityRn name
1155         ; return (conv_fix fix) }
1156     where
1157       conv_fix (BasicTypes.Fixity i d) = TH.Fixity i (conv_dir d)
1158       conv_dir BasicTypes.InfixR = TH.InfixR
1159       conv_dir BasicTypes.InfixL = TH.InfixL
1160       conv_dir BasicTypes.InfixN = TH.InfixN
1161
1162 reifyStrict :: BasicTypes.StrictnessMark -> TH.Strict
1163 reifyStrict MarkedStrict    = TH.IsStrict
1164 reifyStrict MarkedUnboxed   = TH.IsStrict
1165 reifyStrict NotMarkedStrict = TH.NotStrict
1166
1167 ------------------------------
1168 noTH :: LitString -> SDoc -> TcM a
1169 noTH s d = failWithTc (hsep [ptext (sLit "Can't represent") <+> ptext s <+>
1170                                 ptext (sLit "in Template Haskell:"),
1171                              nest 2 d])
1172 \end{code}