compiler/typecheck/TcTyClsDecls.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The AQUA Project, Glasgow University, 1996-1998
   4 %
   5
   6 TcTyClsDecls: Typecheck type and class declarations
   7
   8 \begin{code}
   9 module TcTyClsDecls (
  10         tcTyAndClassDecls, tcFamInstDecl
  11     ) where
  12
  13 #include "HsVersions.h"
  14
  15 import HsSyn
  16 import HsTypes
  17 import BasicTypes
  18 import HscTypes
  19 import BuildTyCl
  20 import TcRnMonad
  21 import TcEnv
  22 import TcTyDecls
  23 import TcClassDcl
  24 import TcHsType
  25 import TcMType
  26 import TcType
  27 import FunDeps
  28 import Type
  29 import Generics
  30 import Class
  31 import TyCon
  32 import DataCon
  33 import Var
  34 import VarSet
  35 import Name
  36 import OccName
  37 import Outputable
  38 import Maybes
  39 import Monad
  40 import Unify
  41 import Util
  42 import SrcLoc
  43 import ListSetOps
  44 import Digraph
  45 import DynFlags
  46
  47 import Data.List        ( partition, elemIndex )
  48 import Control.Monad    ( mplus )
  49 \end{code}
  50
  51
  52 %************************************************************************
  53 %*                                                                      *
  54 \subsection{Type checking for type and class declarations}
  55 %*                                                                      *
  56 %************************************************************************
  57
  58 Dealing with a group
  59 ~~~~~~~~~~~~~~~~~~~~
  60 Consider a mutually-recursive group, binding
  61 a type constructor T and a class C.
  62
  63 Step 1:         getInitialKind
  64         Construct a KindEnv by binding T and C to a kind variable
  65
  66 Step 2:         kcTyClDecl
  67         In that environment, do a kind check
  68
  69 Step 3: Zonk the kinds
  70
  71 Step 4:         buildTyConOrClass
  72         Construct an environment binding T to a TyCon and C to a Class.
  73         a) Their kinds comes from zonking the relevant kind variable
  74         b) Their arity (for synonyms) comes direct from the decl
  75         c) The funcional dependencies come from the decl
  76         d) The rest comes a knot-tied binding of T and C, returned from Step 4
  77         e) The variances of the tycons in the group is calculated from
  78                 the knot-tied stuff
  79
  80 Step 5:         tcTyClDecl1
  81         In this environment, walk over the decls, constructing the TyCons and Classes.
  82         This uses in a strict way items (a)-(c) above, which is why they must
  83         be constructed in Step 4. Feed the results back to Step 4.
  84         For this step, pass the is-recursive flag as the wimp-out flag
  85         to tcTyClDecl1.
  86
  87
  88 Step 6:         Extend environment
  89         We extend the type environment with bindings not only for the TyCons and Classes,
  90         but also for their "implicit Ids" like data constructors and class selectors
  91
  92 Step 7:         checkValidTyCl
  93         For a recursive group only, check all the decls again, just
  94         to check all the side conditions on validity.  We could not
  95         do this before because we were in a mutually recursive knot.
  96
  97 Identification of recursive TyCons
  98 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  99 The knot-tying parameters: @rec_details_list@ is an alist mapping @Name@s to
 100 @TyThing@s.
 101
 102 Identifying a TyCon as recursive serves two purposes
 103
 104 1.  Avoid infinite types.  Non-recursive newtypes are treated as
 105 "transparent", like type synonyms, after the type checker.  If we did
 106 this for all newtypes, we'd get infinite types.  So we figure out for
 107 each newtype whether it is "recursive", and add a coercion if so.  In
 108 effect, we are trying to "cut the loops" by identifying a loop-breaker.
 109
 110 2.  Avoid infinite unboxing.  This is nothing to do with newtypes.
 111 Suppose we have
 112         data T = MkT Int T
 113         f (MkT x t) = f t
 114 Well, this function diverges, but we don't want the strictness analyser
 115 to diverge.  But the strictness analyser will diverge because it looks
 116 deeper and deeper into the structure of T.   (I believe there are
 117 examples where the function does something sane, and the strictness
 118 analyser still diverges, but I can't see one now.)
 119
 120 Now, concerning (1), the FC2 branch currently adds a coercion for ALL
 121 newtypes.  I did this as an experiment, to try to expose cases in which
 122 the coercions got in the way of optimisations.  If it turns out that we
 123 can indeed always use a coercion, then we don't risk recursive types,
 124 and don't need to figure out what the loop breakers are.
 125
 126 For newtype *families* though, we will always have a coercion, so they
 127 are always loop breakers!  So you can easily adjust the current
 128 algorithm by simply treating all newtype families as loop breakers (and
 129 indeed type families).  I think.
 130
 131 \begin{code}
 132 tcTyAndClassDecls :: ModDetails -> [LTyClDecl Name]
 133                    -> TcM TcGblEnv      -- Input env extended by types and classes
 134                                         -- and their implicit Ids,DataCons
 135 tcTyAndClassDecls boot_details allDecls
 136   = do  {       -- Omit instances of indexed types; they are handled together
 137                 -- with the *heads* of class instances
 138         ; let decls = filter (not . isFamInstDecl . unLoc) allDecls
 139
 140                 -- First check for cyclic type synonysm or classes
 141                 -- See notes with checkCycleErrs
 142         ; checkCycleErrs decls
 143         ; mod <- getModule
 144         ; traceTc (text "tcTyAndCl" <+> ppr mod)
 145         ; (syn_tycons, alg_tyclss) <- fixM (\ ~(rec_syn_tycons, rec_alg_tyclss) ->
 146           do    { let { -- Seperate ordinary synonyms from all other type and
 147                         -- class declarations and add all associated type
 148                         -- declarations from type classes.  The latter is
 149                         -- required so that the temporary environment for the
 150                         -- knot includes all associated family declarations.
 151                       ; (syn_decls, alg_decls) = partition (isSynDecl . unLoc)
 152                                                    decls
 153                       ; alg_at_decls           = concatMap addATs alg_decls
 154                       }
 155                         -- Extend the global env with the knot-tied results
 156                         -- for data types and classes
 157                         --
 158                         -- We must populate the environment with the loop-tied
 159                         -- T's right away, because the kind checker may "fault
 160                         -- in" some type  constructors that recursively
 161                         -- mention T
 162                 ; let gbl_things = mkGlobalThings alg_at_decls rec_alg_tyclss
 163                 ; tcExtendRecEnv gbl_things $ do
 164
 165                         -- Kind-check the declarations
 166                 { (kc_syn_decls, kc_alg_decls) <- kcTyClDecls syn_decls alg_decls
 167
 168                 ; let { -- Calculate rec-flag
 169                       ; calc_rec  = calcRecFlags boot_details rec_alg_tyclss
 170                       ; tc_decl   = addLocM (tcTyClDecl calc_rec) }
 171
 172                         -- Type-check the type synonyms, and extend the envt
 173                 ; syn_tycons <- tcSynDecls kc_syn_decls
 174                 ; tcExtendGlobalEnv syn_tycons $ do
 175
 176                         -- Type-check the data types and classes
 177                 { alg_tyclss <- mappM tc_decl kc_alg_decls
 178                 ; return (syn_tycons, concat alg_tyclss)
 179             }}})
 180         -- Finished with knot-tying now
 181         -- Extend the environment with the finished things
 182         ; tcExtendGlobalEnv (syn_tycons ++ alg_tyclss) $ do
 183
 184         -- Perform the validity check
 185         { traceTc (text "ready for validity check")
 186         ; mappM_ (addLocM checkValidTyCl) decls
 187         ; traceTc (text "done")
 188
 189         -- Add the implicit things;
 190         -- we want them in the environment because
 191         -- they may be mentioned in interface files
 192         -- NB: All associated types and their implicit things will be added a
 193         --     second time here.  This doesn't matter as the definitions are
 194         --     the same.
 195         ; let { implicit_things = concatMap implicitTyThings alg_tyclss }
 196         ; traceTc ((text "Adding" <+> ppr alg_tyclss)
 197                    $$ (text "and" <+> ppr implicit_things))
 198         ; tcExtendGlobalEnv implicit_things getGblEnv
 199     }}
 200   where
 201     -- Pull associated types out of class declarations, to tie them into the
 202     -- knot above.
 203     -- NB: We put them in the same place in the list as `tcTyClDecl' will
 204     --     eventually put the matching `TyThing's.  That's crucial; otherwise,
 205     --     the two argument lists of `mkGlobalThings' don't match up.
 206     addATs decl@(L _ (ClassDecl {tcdATs = ats})) = decl : ats
 207     addATs decl                                  = [decl]
 208
 209 mkGlobalThings :: [LTyClDecl Name]      -- The decls
 210                -> [TyThing]             -- Knot-tied, in 1-1 correspondence with the decls
 211                -> [(Name,TyThing)]
 212 -- Driven by the Decls, and treating the TyThings lazily
 213 -- make a TypeEnv for the new things
 214 mkGlobalThings decls things
 215   = map mk_thing (decls `zipLazy` things)
 216   where
 217     mk_thing (L _ (ClassDecl {tcdLName = L _ name}), ~(AClass cl))
 218          = (name, AClass cl)
 219     mk_thing (L _ decl, ~(ATyCon tc))
 220          = (tcdName decl, ATyCon tc)
 221 \end{code}
 222
 223
 224 %************************************************************************
 225 %*                                                                      *
 226 \subsection{Type checking family instances}
 227 %*                                                                      *
 228 %************************************************************************
 229
 230 Family instances are somewhat of a hybrid.  They are processed together with
 231 class instance heads, but can contain data constructors and hence they share a
 232 lot of kinding and type checking code with ordinary algebraic data types (and
 233 GADTs).
 234
 235 \begin{code}
 236 tcFamInstDecl :: LTyClDecl Name -> TcM (Maybe TyThing)   -- Nothing if error
 237 tcFamInstDecl (L loc decl)
 238   =     -- Prime error recovery, set source location
 239     recoverM (returnM Nothing)                  $
 240     setSrcSpan loc                              $
 241     tcAddDeclCtxt decl                          $
 242     do { -- type families require -findexed-types and can't be in an
 243          -- hs-boot file
 244        ; gla_exts <- doptM Opt_IndexedTypes
 245        ; is_boot  <- tcIsHsBoot   -- Are we compiling an hs-boot file?
 246        ; checkTc gla_exts      $ badFamInstDecl (tcdLName decl)
 247        ; checkTc (not is_boot) $ badBootFamInstDeclErr
 248
 249          -- perform kind and type checking
 250        ; tcFamInstDecl1 decl
 251        }
 252
 253 tcFamInstDecl1 :: TyClDecl Name -> TcM (Maybe TyThing)   -- Nothing if error
 254
 255   -- "type instance"
 256 tcFamInstDecl1 (decl@TySynonym {tcdLName = L loc tc_name})
 257   = kcIdxTyPats decl $ \k_tvs k_typats resKind family ->
 258     do { -- check that the family declaration is for a synonym
 259          unless (isSynTyCon family) $
 260            addErr (wrongKindOfFamily family)
 261
 262        ; -- (1) kind check the right hand side of the type equation
 263        ; k_rhs <- kcCheckHsType (tcdSynRhs decl) resKind
 264
 265          -- (2) type check type equation
 266        ; tcTyVarBndrs k_tvs $ \t_tvs -> do {  -- turn kinded into proper tyvars
 267        ; t_typats <- mappM tcHsKindedType k_typats
 268        ; t_rhs    <- tcHsKindedType k_rhs
 269
 270          -- (3) construct representation tycon
 271        ; rep_tc_name <- newFamInstTyConName tc_name loc
 272        ; tycon <- buildSynTyCon rep_tc_name t_tvs (SynonymTyCon t_rhs)
 273                                 (Just (family, t_typats))
 274
 275        ; return $ Just (ATyCon tycon)
 276        }}
 277
 278   -- "newtype instance" and "data instance"
 279 tcFamInstDecl1 (decl@TyData {tcdND = new_or_data, tcdLName = L loc tc_name,
 280                              tcdCons = cons})
 281   = kcIdxTyPats decl $ \k_tvs k_typats resKind family ->
 282     do { -- check that the family declaration is for the right kind
 283          unless (isAlgTyCon family) $
 284            addErr (wrongKindOfFamily family)
 285
 286        ; -- (1) kind check the data declaration as usual
 287        ; k_decl <- kcDataDecl decl k_tvs
 288        ; let k_ctxt = tcdCtxt k_decl
 289              k_cons = tcdCons k_decl
 290
 291          -- result kind must be '*' (otherwise, we have too few patterns)
 292        ; checkTc (isLiftedTypeKind resKind) $ tooFewParmsErr tc_name
 293
 294          -- (2) type check indexed data type declaration
 295        ; tcTyVarBndrs k_tvs $ \t_tvs -> do {  -- turn kinded into proper tyvars
 296        ; unbox_strict <- doptM Opt_UnboxStrictFields
 297
 298          -- Check that we don't use GADT syntax for indexed types
 299        ; checkTc h98_syntax (badGadtIdxTyDecl tc_name)
 300
 301          -- Check that a newtype has exactly one constructor
 302        ; checkTc (new_or_data == DataType || isSingleton k_cons) $
 303            newtypeConError tc_name (length k_cons)
 304
 305        ; t_typats     <- mappM tcHsKindedType k_typats
 306        ; stupid_theta <- tcHsKindedContext k_ctxt
 307
 308          -- (3) construct representation tycon
 309        ; rep_tc_name <- newFamInstTyConName tc_name loc
 310        ; tycon <- fixM (\ tycon -> do
 311              { data_cons <- mappM (addLocM (tcConDecl unbox_strict tycon t_tvs))
 312                                   k_cons
 313              ; tc_rhs <-
 314                  case new_or_data of
 315                    DataType -> return (mkDataTyConRhs data_cons)
 316                    NewType  -> ASSERT( isSingleton data_cons )
 317                                mkNewTyConRhs tc_name tycon (head data_cons)
 318              ; buildAlgTyCon rep_tc_name t_tvs stupid_theta tc_rhs Recursive
 319                              False h98_syntax (Just (family, t_typats))
 320                  -- We always assume that indexed types are recursive.  Why?
 321                  -- (1) Due to their open nature, we can never be sure that a
 322                  -- further instance might not introduce a new recursive
 323                  -- dependency.  (2) They are always valid loop breakers as
 324                  -- they involve a coercion.
 325              })
 326
 327          -- construct result
 328        ; return $ Just (ATyCon tycon)
 329        }}
 330        where
 331          h98_syntax = case cons of      -- All constructors have same shape
 332                         L _ (ConDecl { con_res = ResTyGADT _ }) : _ -> False
 333                         other -> True
 334
 335 -- Kind checking of indexed types
 336 -- -
 337
 338 -- Kind check type patterns and kind annotate the embedded type variables.
 339 --
 340 -- * Here we check that a type instance matches its kind signature, but we do
 341 --   not check whether there is a pattern for each type index; the latter
 342 --   check is only required for type functions.
 343 --
 344 kcIdxTyPats :: TyClDecl Name
 345             -> ([LHsTyVarBndr Name] -> [LHsType Name] -> Kind -> TyCon -> TcM a)
 346                -- ^^kinded tvs         ^^kinded ty pats  ^^res kind
 347             -> TcM a
 348 kcIdxTyPats decl thing_inside
 349   = kcHsTyVars (tcdTyVars decl) $ \tvs ->
 350     do { family <- tcLookupLocatedTyCon (tcdLName decl)
 351        ; let { (kinds, resKind) = splitKindFunTys (tyConKind family)
 352              ; hs_typats        = fromJust $ tcdTyPats decl }
 353
 354          -- we may not have more parameters than the kind indicates
 355        ; checkTc (length kinds >= length hs_typats) $
 356            tooManyParmsErr (tcdLName decl)
 357
 358          -- type functions can have a higher-kinded result
 359        ; let resultKind = mkArrowKinds (drop (length hs_typats) kinds) resKind
 360        ; typats <- TcRnMonad.zipWithM kcCheckHsType hs_typats kinds
 361        ; thing_inside tvs typats resultKind family
 362        }
 363   where
 364 \end{code}
 365
 366
 367 %************************************************************************
 368 %*                                                                      *
 369                 Kind checking
 370 %*                                                                      *
 371 %************************************************************************
 372
 373 We need to kind check all types in the mutually recursive group
 374 before we know the kind of the type variables.  For example:
 375
 376 class C a where
 377    op :: D b => a -> b -> b
 378
 379 class D c where
 380    bop :: (Monad c) => ...
 381
 382 Here, the kind of the locally-polymorphic type variable "b"
 383 depends on *all the uses of class D*.  For example, the use of
 384 Monad c in bop's type signature means that D must have kind Type->Type.
 385
 386 However type synonyms work differently.  They can have kinds which don't
 387 just involve (->) and *:
 388         type R = Int#           -- Kind #
 389         type S a = Array# a     -- Kind * -> #
 390         type T a b = (# a,b #)  -- Kind * -> * -> (# a,b #)
 391 So we must infer their kinds from their right-hand sides *first* and then
 392 use them, whereas for the mutually recursive data types D we bring into
 393 scope kind bindings D -> k, where k is a kind variable, and do inference.
 394
 395 Indexed Types
 396 ~~~~~~~~~~~~~
 397 This treatment of type synonyms only applies to Haskell 98-style synonyms.
 398 General type functions can be recursive, and hence, appear in `alg_decls'.
 399
 400 The kind of a type family is solely determinded by its kind signature;
 401 hence, only kind signatures participate in the construction of the initial
 402 kind environment (as constructed by `getInitialKind').  In fact, we ignore
 403 instances of families altogether in the following.  However, we need to
 404 include the kinds of associated families into the construction of the
 405 initial kind environment.  (This is handled by `allDecls').
 406
 407 \begin{code}
 408 kcTyClDecls syn_decls alg_decls
 409   = do  {       -- First extend the kind env with each data type, class, and
 410                 -- indexed type, mapping them to a type variable
 411           let initialKindDecls = concat [allDecls decl | L _ decl <- alg_decls]
 412         ; alg_kinds <- mappM getInitialKind initialKindDecls
 413         ; tcExtendKindEnv alg_kinds $ do
 414
 415                 -- Now kind-check the type synonyms, in dependency order
 416                 -- We do these differently to data type and classes,
 417                 -- because a type synonym can be an unboxed type
 418                 --      type Foo = Int#
 419                 -- and a kind variable can't unify with UnboxedTypeKind
 420                 -- So we infer their kinds in dependency order
 421         { (kc_syn_decls, syn_kinds) <- kcSynDecls (calcSynCycles syn_decls)
 422         ; tcExtendKindEnv syn_kinds $  do
 423
 424                 -- Now kind-check the data type, class, and kind signatures,
 425                 -- returning kind-annotated decls; we don't kind-check
 426                 -- instances of indexed types yet, but leave this to
 427                 -- `tcInstDecls1'
 428         { kc_alg_decls <- mappM (wrapLocM kcTyClDecl)
 429                             (filter (not . isFamInstDecl . unLoc) alg_decls)
 430
 431         ; return (kc_syn_decls, kc_alg_decls) }}}
 432   where
 433     -- get all declarations relevant for determining the initial kind
 434     -- environment
 435     allDecls (decl@ClassDecl {tcdATs = ats}) = decl : [ at
 436                                                       | L _ at <- ats
 437                                                       , isFamilyDecl at]
 438     allDecls decl | isFamInstDecl decl = []
 439                   | otherwise          = [decl]
 440
 441 ------------------------------------------------------------------------
 442 getInitialKind :: TyClDecl Name -> TcM (Name, TcKind)
 443 -- Only for data type, class, and indexed type declarations
 444 -- Get as much info as possible from the data, class, or indexed type decl,
 445 -- so as to maximise usefulness of error messages
 446 getInitialKind decl
 447   = do  { arg_kinds <- mapM (mk_arg_kind . unLoc) (tyClDeclTyVars decl)
 448         ; res_kind  <- mk_res_kind decl
 449         ; return (tcdName decl, mkArrowKinds arg_kinds res_kind) }
 450   where
 451     mk_arg_kind (UserTyVar _)        = newKindVar
 452     mk_arg_kind (KindedTyVar _ kind) = return kind
 453
 454     mk_res_kind (TyFamily { tcdKind    = Just kind }) = return kind
 455     mk_res_kind (TyData   { tcdKindSig = Just kind }) = return kind
 456         -- On GADT-style declarations we allow a kind signature
 457         --      data T :: *->* where { ... }
 458     mk_res_kind other = return liftedTypeKind
 459
 460
 461 ----------------
 462 kcSynDecls :: [SCC (LTyClDecl Name)]
 463            -> TcM ([LTyClDecl Name],    -- Kind-annotated decls
 464                    [(Name,TcKind)])     -- Kind bindings
 465 kcSynDecls []
 466   = return ([], [])
 467 kcSynDecls (group : groups)
 468   = do  { (decl,  nk)  <- kcSynDecl group
 469         ; (decls, nks) <- tcExtendKindEnv [nk] (kcSynDecls groups)
 470         ; return (decl:decls, nk:nks) }
 471
 472 ----------------
 473 kcSynDecl :: SCC (LTyClDecl Name)
 474            -> TcM (LTyClDecl Name,      -- Kind-annotated decls
 475                    (Name,TcKind))       -- Kind bindings
 476 kcSynDecl (AcyclicSCC ldecl@(L loc decl))
 477   = tcAddDeclCtxt decl  $
 478     kcHsTyVars (tcdTyVars decl) (\ k_tvs ->
 479     do { traceTc (text "kcd1" <+> ppr (unLoc (tcdLName decl)) <+> brackets (ppr (tcdTyVars decl))
 480                         <+> brackets (ppr k_tvs))
 481        ; (k_rhs, rhs_kind) <- kcHsType (tcdSynRhs decl)
 482        ; traceTc (text "kcd2" <+> ppr (unLoc (tcdLName decl)))
 483        ; let tc_kind = foldr (mkArrowKind . kindedTyVarKind) rhs_kind k_tvs
 484        ; return (L loc (decl { tcdTyVars = k_tvs, tcdSynRhs = k_rhs }),
 485                  (unLoc (tcdLName decl), tc_kind)) })
 486
 487 kcSynDecl (CyclicSCC decls)
 488   = do { recSynErr decls; failM }       -- Fail here to avoid error cascade
 489                                         -- of out-of-scope tycons
 490
 491 kindedTyVarKind (L _ (KindedTyVar _ k)) = k
 492
 493 ------------------------------------------------------------------------
 494 kcTyClDecl :: TyClDecl Name -> TcM (TyClDecl Name)
 495         -- Not used for type synonyms (see kcSynDecl)
 496
 497 kcTyClDecl decl@(TyData {})
 498   = ASSERT( not . isFamInstDecl $ decl )   -- must not be a family instance
 499     kcTyClDeclBody decl $
 500       kcDataDecl decl
 501
 502 kcTyClDecl decl@(TyFamily {tcdKind = kind})
 503   = kcTyClDeclBody decl $ \ tvs' ->
 504       return (decl {tcdTyVars = tvs',
 505                     tcdKind = kind `mplus` Just liftedTypeKind})
 506                     -- default result kind is '*'
 507
 508 kcTyClDecl decl@(ClassDecl {tcdCtxt = ctxt, tcdSigs = sigs, tcdATs = ats})
 509   = kcTyClDeclBody decl $ \ tvs' ->
 510     do  { is_boot <- tcIsHsBoot
 511         ; ctxt' <- kcHsContext ctxt
 512         ; ats'  <- mappM (wrapLocM kcTyClDecl) ats
 513         ; sigs' <- mappM (wrapLocM kc_sig    ) sigs
 514         ; return (decl {tcdTyVars = tvs', tcdCtxt = ctxt', tcdSigs = sigs',
 515                         tcdATs = ats'}) }
 516   where
 517     kc_sig (TypeSig nm op_ty) = do { op_ty' <- kcHsLiftedSigType op_ty
 518                                    ; return (TypeSig nm op_ty') }
 519     kc_sig other_sig          = return other_sig
 520
 521 kcTyClDecl decl@(ForeignType {})
 522   = return decl
 523
 524 kcTyClDeclBody :: TyClDecl Name
 525                -> ([LHsTyVarBndr Name] -> TcM a)
 526                -> TcM a
 527 -- getInitialKind has made a suitably-shaped kind for the type or class
 528 -- Unpack it, and attribute those kinds to the type variables
 529 -- Extend the env with bindings for the tyvars, taken from
 530 -- the kind of the tycon/class.  Give it to the thing inside, and
 531 -- check the result kind matches
 532 kcTyClDeclBody decl thing_inside
 533   = tcAddDeclCtxt decl          $
 534     do  { tc_ty_thing <- tcLookupLocated (tcdLName decl)
 535         ; let tc_kind    = case tc_ty_thing of { AThing k -> k }
 536               (kinds, _) = splitKindFunTys tc_kind
 537               hs_tvs     = tcdTyVars decl
 538               kinded_tvs = ASSERT( length kinds >= length hs_tvs )
 539                            [ L loc (KindedTyVar (hsTyVarName tv) k)
 540                            | (L loc tv, k) <- zip hs_tvs kinds]
 541         ; tcExtendKindEnvTvs kinded_tvs (thing_inside kinded_tvs) }
 542
 543 -- Kind check a data declaration, assuming that we already extended the
 544 -- kind environment with the type variables of the left-hand side (these
 545 -- kinded type variables are also passed as the second parameter).
 546 --
 547 kcDataDecl :: TyClDecl Name -> [LHsTyVarBndr Name] -> TcM (TyClDecl Name)
 548 kcDataDecl decl@(TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdCons = cons})
 549            tvs
 550   = do  { ctxt' <- kcHsContext ctxt
 551         ; cons' <- mappM (wrapLocM kc_con_decl) cons
 552         ; return (decl {tcdTyVars = tvs, tcdCtxt = ctxt', tcdCons = cons'}) }
 553   where
 554     -- doc comments are typechecked to Nothing here
 555     kc_con_decl (ConDecl name expl ex_tvs ex_ctxt details res _) = do
 556       kcHsTyVars ex_tvs $ \ex_tvs' -> do
 557         ex_ctxt' <- kcHsContext ex_ctxt
 558         details' <- kc_con_details details
 559         res'     <- case res of
 560           ResTyH98 -> return ResTyH98
 561           ResTyGADT ty -> do { ty' <- kcHsSigType ty; return (ResTyGADT ty') }
 562         return (ConDecl name expl ex_tvs' ex_ctxt' details' res' Nothing)
 563
 564     kc_con_details (PrefixCon btys)
 565         = do { btys' <- mappM kc_larg_ty btys ; return (PrefixCon btys') }
 566     kc_con_details (InfixCon bty1 bty2)
 567         = do { bty1' <- kc_larg_ty bty1; bty2' <- kc_larg_ty bty2; return (InfixCon bty1' bty2') }
 568     kc_con_details (RecCon fields)
 569         = do { fields' <- mappM kc_field fields; return (RecCon fields') }
 570
 571     kc_field (HsRecField fld bty d) = do { bty' <- kc_larg_ty bty ; return (HsRecField fld bty' d) }
 572
 573     kc_larg_ty bty = case new_or_data of
 574                         DataType -> kcHsSigType bty
 575                         NewType  -> kcHsLiftedSigType bty
 576         -- Can't allow an unlifted type for newtypes, because we're effectively
 577         -- going to remove the constructor while coercing it to a lifted type.
 578         -- And newtypes can't be bang'd
 579 \end{code}
 580
 581
 582 %************************************************************************
 583 %*                                                                      *
 584 \subsection{Type checking}
 585 %*                                                                      *
 586 %************************************************************************
 587
 588 \begin{code}
 589 tcSynDecls :: [LTyClDecl Name] -> TcM [TyThing]
 590 tcSynDecls [] = return []
 591 tcSynDecls (decl : decls)
 592   = do { syn_tc <- addLocM tcSynDecl decl
 593        ; syn_tcs <- tcExtendGlobalEnv [syn_tc] (tcSynDecls decls)
 594        ; return (syn_tc : syn_tcs) }
 595
 596   -- "type"
 597 tcSynDecl
 598   (TySynonym {tcdLName = L _ tc_name, tcdTyVars = tvs, tcdSynRhs = rhs_ty})
 599   = tcTyVarBndrs tvs            $ \ tvs' -> do
 600     { traceTc (text "tcd1" <+> ppr tc_name)
 601     ; rhs_ty' <- tcHsKindedType rhs_ty
 602     ; tycon <- buildSynTyCon tc_name tvs' (SynonymTyCon rhs_ty') Nothing
 603     ; return (ATyCon tycon)
 604     }
 605
 606 --------------------
 607 tcTyClDecl :: (Name -> RecFlag) -> TyClDecl Name -> TcM [TyThing]
 608
 609 tcTyClDecl calc_isrec decl
 610   = tcAddDeclCtxt decl (tcTyClDecl1 calc_isrec decl)
 611
 612   -- "type family" declarations
 613 tcTyClDecl1 _calc_isrec
 614   (TyFamily {tcdFlavour = TypeFamily,
 615              tcdLName = L _ tc_name, tcdTyVars = tvs, tcdKind = Just kind})
 616                                                       -- NB: kind at latest
 617                                                       --     added during
 618                                                       --     kind checking
 619   = tcTyVarBndrs tvs  $ \ tvs' -> do
 620   { traceTc (text "type family: " <+> ppr tc_name)
 621   ; idx_tys <- doptM Opt_IndexedTypes
 622
 623         -- Check that we don't use families without -findexed-types
 624   ; checkTc idx_tys $ badFamInstDecl tc_name
 625
 626   ; tycon <- buildSynTyCon tc_name tvs' (OpenSynTyCon kind Nothing) Nothing
 627   ; return [ATyCon tycon]
 628   }
 629
 630   -- "newtype family" or "data family" declaration
 631 tcTyClDecl1 _calc_isrec
 632   (TyFamily {tcdFlavour = DataFamily,
 633              tcdLName = L _ tc_name, tcdTyVars = tvs, tcdKind = mb_kind})
 634   = tcTyVarBndrs tvs  $ \ tvs' -> do
 635   { traceTc (text "data family: " <+> ppr tc_name)
 636   ; extra_tvs <- tcDataKindSig mb_kind
 637   ; let final_tvs = tvs' ++ extra_tvs    -- we may not need these
 638
 639   ; idx_tys <- doptM Opt_IndexedTypes
 640
 641         -- Check that we don't use families without -findexed-types
 642   ; checkTc idx_tys $ badFamInstDecl tc_name
 643
 644   ; tycon <- buildAlgTyCon tc_name final_tvs []
 645                mkOpenDataTyConRhs Recursive False True Nothing
 646   ; return [ATyCon tycon]
 647   }
 648
 649   -- "newtype" and "data"
 650 tcTyClDecl1 calc_isrec
 651   (TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdTyVars = tvs,
 652            tcdLName = L _ tc_name, tcdKindSig = mb_ksig, tcdCons = cons})
 653   = tcTyVarBndrs tvs    $ \ tvs' -> do
 654   { extra_tvs <- tcDataKindSig mb_ksig
 655   ; let final_tvs = tvs' ++ extra_tvs
 656   ; stupid_theta <- tcHsKindedContext ctxt
 657   ; want_generic <- doptM Opt_Generics
 658   ; unbox_strict <- doptM Opt_UnboxStrictFields
 659   ; gla_exts     <- doptM Opt_GlasgowExts
 660   ; is_boot      <- tcIsHsBoot  -- Are we compiling an hs-boot file?
 661
 662         -- Check that we don't use GADT syntax in H98 world
 663   ; checkTc (gla_exts || h98_syntax) (badGadtDecl tc_name)
 664
 665         -- Check that we don't use kind signatures without Glasgow extensions
 666   ; checkTc (gla_exts || isNothing mb_ksig) (badSigTyDecl tc_name)
 667
 668         -- Check that the stupid theta is empty for a GADT-style declaration
 669   ; checkTc (null stupid_theta || h98_syntax) (badStupidTheta tc_name)
 670
 671         -- Check that there's at least one condecl,
 672         -- or else we're reading an hs-boot file, or -fglasgow-exts
 673   ; checkTc (not (null cons) || gla_exts || is_boot)
 674             (emptyConDeclsErr tc_name)
 675
 676         -- Check that a newtype has exactly one constructor
 677   ; checkTc (new_or_data == DataType || isSingleton cons)
 678             (newtypeConError tc_name (length cons))
 679
 680   ; tycon <- fixM (\ tycon -> do
 681         { data_cons <- mappM (addLocM (tcConDecl unbox_strict tycon final_tvs))
 682                              cons
 683         ; tc_rhs <-
 684             if null cons && is_boot     -- In a hs-boot file, empty cons means
 685             then return AbstractTyCon   -- "don't know"; hence Abstract
 686             else case new_or_data of
 687                    DataType -> return (mkDataTyConRhs data_cons)
 688                    NewType  ->
 689                        ASSERT( isSingleton data_cons )
 690                        mkNewTyConRhs tc_name tycon (head data_cons)
 691         ; buildAlgTyCon tc_name final_tvs stupid_theta tc_rhs is_rec
 692             (want_generic && canDoGenerics data_cons) h98_syntax Nothing
 693         })
 694   ; return [ATyCon tycon]
 695   }
 696   where
 697     is_rec   = calc_isrec tc_name
 698     h98_syntax = case cons of   -- All constructors have same shape
 699                         L _ (ConDecl { con_res = ResTyGADT _ }) : _ -> False
 700                         other -> True
 701
 702 tcTyClDecl1 calc_isrec
 703   (ClassDecl {tcdLName = L _ class_name, tcdTyVars = tvs,
 704               tcdCtxt = ctxt, tcdMeths = meths,
 705               tcdFDs = fundeps, tcdSigs = sigs, tcdATs = ats} )
 706   = tcTyVarBndrs tvs            $ \ tvs' -> do
 707   { ctxt' <- tcHsKindedContext ctxt
 708   ; fds' <- mappM (addLocM tc_fundep) fundeps
 709   ; atss <- mappM (addLocM (tcTyClDecl1 (const Recursive))) ats
 710   ; let ats' = zipWith setTyThingPoss atss (map (tcdTyVars . unLoc) ats)
 711   ; sig_stuff <- tcClassSigs class_name sigs meths
 712   ; clas <- fixM (\ clas ->
 713                 let     -- This little knot is just so we can get
 714                         -- hold of the name of the class TyCon, which we
 715                         -- need to look up its recursiveness
 716                     tycon_name = tyConName (classTyCon clas)
 717                     tc_isrec = calc_isrec tycon_name
 718                 in
 719                 buildClass class_name tvs' ctxt' fds' ats'
 720                            sig_stuff tc_isrec)
 721   ; return (AClass clas : ats')
 722       -- NB: Order is important due to the call to `mkGlobalThings' when
 723       --     tying the the type and class declaration type checking knot.
 724   }
 725   where
 726     tc_fundep (tvs1, tvs2) = do { tvs1' <- mappM tcLookupTyVar tvs1 ;
 727                                 ; tvs2' <- mappM tcLookupTyVar tvs2 ;
 728                                 ; return (tvs1', tvs2') }
 729
 730     -- For each AT argument compute the position of the corresponding class
 731     -- parameter in the class head.  This will later serve as a permutation
 732     -- vector when checking the validity of instance declarations.
 733     setTyThingPoss [ATyCon tycon] atTyVars =
 734       let classTyVars = hsLTyVarNames tvs
 735           poss        =   catMaybes
 736                         . map (`elemIndex` classTyVars)
 737                         . hsLTyVarNames
 738                         $ atTyVars
 739                      -- There will be no Nothing, as we already passed renaming
 740       in
 741       ATyCon (setTyConArgPoss tycon poss)
 742     setTyThingPoss _              _ = panic "TcTyClsDecls.setTyThingPoss"
 743
 744 tcTyClDecl1 calc_isrec
 745   (ForeignType {tcdLName = L _ tc_name, tcdExtName = tc_ext_name})
 746   = returnM [ATyCon (mkForeignTyCon tc_name tc_ext_name liftedTypeKind 0)]
 747
 748 -----------------------------------
 749 tcConDecl :: Bool               -- True <=> -funbox-strict_fields
 750           -> TyCon -> [TyVar]
 751           -> ConDecl Name
 752           -> TcM DataCon
 753
 754 tcConDecl unbox_strict tycon tc_tvs     -- Data types
 755           (ConDecl name _ tvs ctxt details res_ty _)
 756   = tcTyVarBndrs tvs            $ \ tvs' -> do
 757     { ctxt' <- tcHsKindedContext ctxt
 758     ; (univ_tvs, ex_tvs, eq_preds, data_tc) <- tcResultType tycon tc_tvs tvs' res_ty
 759     ; let
 760         -- Tiresome: tidy the tyvar binders, since tc_tvs and tvs' may have the same OccNames
 761         tc_datacon is_infix field_lbls btys
 762           = do { let bangs = map getBangStrictness btys
 763                ; arg_tys <- mappM tcHsBangType btys
 764                ; buildDataCon (unLoc name) is_infix
 765                     (argStrictness unbox_strict bangs arg_tys)
 766                     (map unLoc field_lbls)
 767                     univ_tvs ex_tvs eq_preds ctxt' arg_tys
 768                     data_tc }
 769                 -- NB:  we put data_tc, the type constructor gotten from the
 770                 --      constructor type signature into the data constructor;
 771                 --      that way checkValidDataCon can complain if it's wrong.
 772
 773     ; case details of
 774         PrefixCon btys     -> tc_datacon False [] btys
 775         InfixCon bty1 bty2 -> tc_datacon True  [] [bty1,bty2]
 776         RecCon fields      -> tc_datacon False field_names btys
 777                            where
 778                               (field_names, btys) = unzip [ (n, t) | HsRecField n t _ <- fields ]
 779
 780     }
 781
 782 tcResultType :: TyCon
 783              -> [TyVar]         -- data T a b c = ...
 784              -> [TyVar]         -- where MkT :: forall a b c. ...
 785              -> ResType Name
 786              -> TcM ([TyVar],           -- Universal
 787                      [TyVar],           -- Existential (distinct OccNames from univs)
 788                      [(TyVar,Type)],    -- Equality predicates
 789                      TyCon)             -- TyCon given in the ResTy
 790         -- We don't check that the TyCon given in the ResTy is
 791         -- the same as the parent tycon, becuase we are in the middle
 792         -- of a recursive knot; so it's postponed until checkValidDataCon
 793
 794 tcResultType decl_tycon tc_tvs dc_tvs ResTyH98
 795   = return (tc_tvs, dc_tvs, [], decl_tycon)
 796         -- In H98 syntax the dc_tvs are the existential ones
 797         --      data T a b c = forall d e. MkT ...
 798         -- The {a,b,c} are tc_tvs, and {d,e} are dc_tvs
 799
 800 tcResultType _ tc_tvs dc_tvs (ResTyGADT res_ty)
 801         -- E.g.  data T a b c where
 802         --         MkT :: forall x y z. T (x,y) z z
 803         -- Then we generate
 804         --      ([a,z,c], [x,y], [a:=:(x,y), c:=:z], T)
 805
 806   = do  { (dc_tycon, res_tys) <- tcLHsConResTy res_ty
 807
 808         ; let univ_tvs = choose_univs [] tidy_tc_tvs res_tys
 809                 -- Each univ_tv is either a dc_tv or a tc_tv
 810               ex_tvs = dc_tvs `minusList` univ_tvs
 811               eq_spec = [ (tv, ty) | (tv,ty) <- univ_tvs `zip` res_tys,
 812                                       tv `elem` tc_tvs]
 813         ; return (univ_tvs, ex_tvs, eq_spec, dc_tycon) }
 814   where
 815         -- choose_univs uses the res_ty itself if it's a type variable
 816         -- and hasn't already been used; otherwise it uses one of the tc_tvs
 817     choose_univs used tc_tvs []
 818         = ASSERT( null tc_tvs ) []
 819     choose_univs used (tc_tv:tc_tvs) (res_ty:res_tys)
 820         | Just tv <- tcGetTyVar_maybe res_ty, not (tv `elem` used)
 821         = tv    : choose_univs (tv:used) tc_tvs res_tys
 822         | otherwise
 823         = tc_tv : choose_univs used tc_tvs res_tys
 824
 825         -- NB: tc_tvs and dc_tvs are distinct, but
 826         -- we want them to be *visibly* distinct, both for
 827         -- interface files and general confusion.  So rename
 828         -- the tc_tvs, since they are not used yet (no
 829         -- consequential renaming needed)
 830     init_occ_env     = initTidyOccEnv (map getOccName dc_tvs)
 831     (_, tidy_tc_tvs) = mapAccumL tidy_one init_occ_env tc_tvs
 832     tidy_one env tv  = (env', setTyVarName tv (tidyNameOcc name occ'))
 833               where
 834                  name = tyVarName tv
 835                  (env', occ') = tidyOccName env (getOccName name)
 836
 837               -------------------
 838 argStrictness :: Bool           -- True <=> -funbox-strict_fields
 839               -> [HsBang]
 840               -> [TcType] -> [StrictnessMark]
 841 argStrictness unbox_strict bangs arg_tys
 842  = ASSERT( length bangs == length arg_tys )
 843    zipWith (chooseBoxingStrategy unbox_strict) arg_tys bangs
 844
 845 -- We attempt to unbox/unpack a strict field when either:
 846 --   (i)  The field is marked '!!', or
 847 --   (ii) The field is marked '!', and the -funbox-strict-fields flag is on.
 848 --
 849 -- We have turned off unboxing of newtypes because coercions make unboxing
 850 -- and reboxing more complicated
 851 chooseBoxingStrategy :: Bool -> TcType -> HsBang -> StrictnessMark
 852 chooseBoxingStrategy unbox_strict_fields arg_ty bang
 853   = case bang of
 854         HsNoBang                                    -> NotMarkedStrict
 855         HsStrict | unbox_strict_fields
 856                    && can_unbox arg_ty              -> MarkedUnboxed
 857         HsUnbox  | can_unbox arg_ty                 -> MarkedUnboxed
 858         other                                       -> MarkedStrict
 859   where
 860     -- we can unbox if the type is a chain of newtypes with a product tycon
 861     -- at the end
 862     can_unbox arg_ty = case splitTyConApp_maybe arg_ty of
 863                    Nothing                      -> False
 864                    Just (arg_tycon, tycon_args) ->
 865                        not (isRecursiveTyCon arg_tycon) &&      -- Note [Recusive unboxing]
 866                        isProductTyCon arg_tycon &&
 867                        (if isNewTyCon arg_tycon then
 868                             can_unbox (newTyConInstRhs arg_tycon tycon_args)
 869                         else True)
 870 \end{code}
 871
 872 Note [Recursive unboxing]
 873 ~~~~~~~~~~~~~~~~~~~~~~~~~
 874 Be careful not to try to unbox this!
 875         data T = MkT !T Int
 876 But it's the *argument* type that matters. This is fine:
 877         data S = MkS S !Int
 878 because Int is non-recursive.
 879
 880 %************************************************************************
 881 %*                                                                      *
 882 \subsection{Dependency analysis}
 883 %*                                                                      *
 884 %************************************************************************
 885
 886 Validity checking is done once the mutually-recursive knot has been
 887 tied, so we can look at things freely.
 888
 889 \begin{code}
 890 checkCycleErrs :: [LTyClDecl Name] -> TcM ()
 891 checkCycleErrs tyclss
 892   | null cls_cycles
 893   = return ()
 894   | otherwise
 895   = do  { mappM_ recClsErr cls_cycles
 896         ; failM }       -- Give up now, because later checkValidTyCl
 897                         -- will loop if the synonym is recursive
 898   where
 899     cls_cycles = calcClassCycles tyclss
 900
 901 checkValidTyCl :: TyClDecl Name -> TcM ()
 902 -- We do the validity check over declarations, rather than TyThings
 903 -- only so that we can add a nice context with tcAddDeclCtxt
 904 checkValidTyCl decl
 905   = tcAddDeclCtxt decl $
 906     do  { thing <- tcLookupLocatedGlobal (tcdLName decl)
 907         ; traceTc (text "Validity of" <+> ppr thing)
 908         ; case thing of
 909             ATyCon tc -> checkValidTyCon tc
 910             AClass cl -> checkValidClass cl
 911         ; traceTc (text "Done validity of" <+> ppr thing)
 912         }
 913
 914 -------------------------
 915 -- For data types declared with record syntax, we require
 916 -- that each constructor that has a field 'f'
 917 --      (a) has the same result type
 918 --      (b) has the same type for 'f'
 919 -- module alpha conversion of the quantified type variables
 920 -- of the constructor.
 921
 922 checkValidTyCon :: TyCon -> TcM ()
 923 checkValidTyCon tc
 924   | isSynTyCon tc
 925   = case synTyConRhs tc of
 926       OpenSynTyCon _ _ -> return ()
 927       SynonymTyCon ty  -> checkValidType syn_ctxt ty
 928   | otherwise
 929   =     -- Check the context on the data decl
 930     checkValidTheta (DataTyCtxt name) (tyConStupidTheta tc)     `thenM_`
 931
 932         -- Check arg types of data constructors
 933     mappM_ (checkValidDataCon tc) data_cons                     `thenM_`
 934
 935         -- Check that fields with the same name share a type
 936     mappM_ check_fields groups
 937
 938   where
 939     syn_ctxt  = TySynCtxt name
 940     name      = tyConName tc
 941     data_cons = tyConDataCons tc
 942
 943     groups = equivClasses cmp_fld (concatMap get_fields data_cons)
 944     cmp_fld (f1,_) (f2,_) = f1 `compare` f2
 945     get_fields con = dataConFieldLabels con `zip` repeat con
 946         -- dataConFieldLabels may return the empty list, which is fine
 947
 948     -- See Note [GADT record selectors] in MkId.lhs
 949     -- We must check (a) that the named field has the same
 950     --                   type in each constructor
 951     --               (b) that those constructors have the same result type
 952     --
 953     -- However, the constructors may have differently named type variable
 954     -- and (worse) we don't know how the correspond to each other.  E.g.
 955     --     C1 :: forall a b. { f :: a, g :: b } -> T a b
 956     --     C2 :: forall d c. { f :: c, g :: c } -> T c d
 957     --
 958     -- So what we do is to ust Unify.tcMatchTys to compare the first candidate's
 959     -- result type against other candidates' types BOTH WAYS ROUND.
 960     -- If they magically agrees, take the substitution and
 961     -- apply them to the latter ones, and see if they match perfectly.
 962     check_fields fields@((label, con1) : other_fields)
 963         -- These fields all have the same name, but are from
 964         -- different constructors in the data type
 965         = recoverM (return ()) $ mapM_ checkOne other_fields
 966                 -- Check that all the fields in the group have the same type
 967                 -- NB: this check assumes that all the constructors of a given
 968                 -- data type use the same type variables
 969         where
 970         (tvs1, _, _, res1) = dataConSig con1
 971         ts1 = mkVarSet tvs1
 972         fty1 = dataConFieldType con1 label
 973
 974         checkOne (_, con2)    -- Do it bothways to ensure they are structurally identical
 975             = do { checkFieldCompat label con1 con2 ts1 res1 res2 fty1 fty2
 976                  ; checkFieldCompat label con2 con1 ts2 res2 res1 fty2 fty1 }
 977             where
 978                 (tvs2, _, _, res2) = dataConSig con2
 979                 ts2 = mkVarSet tvs2
 980                 fty2 = dataConFieldType con2 label
 981
 982 checkFieldCompat fld con1 con2 tvs1 res1 res2 fty1 fty2
 983   = do  { checkTc (isJust mb_subst1) (resultTypeMisMatch fld con1 con2)
 984         ; checkTc (isJust mb_subst2) (fieldTypeMisMatch fld con1 con2) }
 985   where
 986     mb_subst1 = tcMatchTy tvs1 res1 res2
 987     mb_subst2 = tcMatchTyX tvs1 (expectJust "checkFieldCompat" mb_subst1) fty1 fty2
 988
 989 -------------------------------
 990 checkValidDataCon :: TyCon -> DataCon -> TcM ()
 991 checkValidDataCon tc con
 992   = setSrcSpan (srcLocSpan (getSrcLoc con))     $
 993     addErrCtxt (dataConCtxt con)                $
 994     do  { checkTc (dataConTyCon con == tc) (badDataConTyCon con)
 995         ; checkValidType ctxt (dataConUserType con)
 996         ; ifM (isNewTyCon tc) (checkNewDataCon con)
 997     }
 998   where
 999     ctxt = ConArgCtxt (dataConName con)
1000
1001 -------------------------------
1002 checkNewDataCon :: DataCon -> TcM ()
1003 -- Checks for the data constructor of a newtype
1004 checkNewDataCon con
1005   = do  { checkTc (isSingleton arg_tys) (newtypeFieldErr con (length arg_tys))
1006                 -- One argument
1007         ; checkTc (null eq_spec) (newtypePredError con)
1008                 -- Return type is (T a b c)
1009         ; checkTc (null ex_tvs && null theta) (newtypeExError con)
1010                 -- No existentials
1011     }
1012   where
1013     (_univ_tvs, ex_tvs, eq_spec, theta, arg_tys, _res_ty) = dataConFullSig con
1014
1015 -------------------------------
1016 checkValidClass :: Class -> TcM ()
1017 checkValidClass cls
1018   = do  {       -- CHECK ARITY 1 FOR HASKELL 1.4
1019           gla_exts <- doptM Opt_GlasgowExts
1020
1021         -- Check that the class is unary, unless GlaExs
1022         ; checkTc (notNull tyvars) (nullaryClassErr cls)
1023         ; checkTc (gla_exts || unary) (classArityErr cls)
1024
1025         -- Check the super-classes
1026         ; checkValidTheta (ClassSCCtxt (className cls)) theta
1027
1028         -- Check the class operations
1029         ; mappM_ (check_op gla_exts) op_stuff
1030
1031         -- Check that if the class has generic methods, then the
1032         -- class has only one parameter.  We can't do generic
1033         -- multi-parameter type classes!
1034         ; checkTc (unary || no_generics) (genericMultiParamErr cls)
1035         }
1036   where
1037     (tyvars, theta, _, op_stuff) = classBigSig cls
1038     unary       = isSingleton tyvars
1039     no_generics = null [() | (_, GenDefMeth) <- op_stuff]
1040
1041     check_op gla_exts (sel_id, dm)
1042       = addErrCtxt (classOpCtxt sel_id tau) $ do
1043         { checkValidTheta SigmaCtxt (tail theta)
1044                 -- The 'tail' removes the initial (C a) from the
1045                 -- class itself, leaving just the method type
1046
1047         ; checkValidType (FunSigCtxt op_name) tau
1048
1049                 -- Check that the type mentions at least one of
1050                 -- the class type variables...or at least one reachable
1051                 -- from one of the class variables.  Example: tc223
1052                 --   class Error e => Game b mv e | b -> mv e where
1053                 --      newBoard :: MonadState b m => m ()
1054                 -- Here, MonadState has a fundep m->b, so newBoard is fine
1055         ; let grown_tyvars = grow theta (mkVarSet tyvars)
1056         ; checkTc (tyVarsOfType tau `intersectsVarSet` grown_tyvars)
1057                   (noClassTyVarErr cls sel_id)
1058
1059                 -- Check that for a generic method, the type of
1060                 -- the method is sufficiently simple
1061         ; checkTc (dm /= GenDefMeth || validGenericMethodType tau)
1062                   (badGenericMethodType op_name op_ty)
1063         }
1064         where
1065           op_name = idName sel_id
1066           op_ty   = idType sel_id
1067           (_,theta1,tau1) = tcSplitSigmaTy op_ty
1068           (_,theta2,tau2)  = tcSplitSigmaTy tau1
1069           (theta,tau) | gla_exts  = (theta1 ++ theta2, tau2)
1070                       | otherwise = (theta1,           mkPhiTy (tail theta1) tau1)
1071                 -- Ugh!  The function might have a type like
1072                 --      op :: forall a. C a => forall b. (Eq b, Eq a) => tau2
1073                 -- With -fglasgow-exts, we want to allow this, even though the inner
1074                 -- forall has an (Eq a) constraint.  Whereas in general, each constraint
1075                 -- in the context of a for-all must mention at least one quantified
1076                 -- type variable.  What a mess!
1077
1078
1079 ---------------------------------------------------------------------
1080 resultTypeMisMatch field_name con1 con2
1081   = vcat [sep [ptext SLIT("Constructors") <+> ppr con1 <+> ptext SLIT("and") <+> ppr con2,
1082                 ptext SLIT("have a common field") <+> quotes (ppr field_name) <> comma],
1083           nest 2 $ ptext SLIT("but have different result types")]
1084 fieldTypeMisMatch field_name con1 con2
1085   = sep [ptext SLIT("Constructors") <+> ppr con1 <+> ptext SLIT("and") <+> ppr con2,
1086          ptext SLIT("give different types for field"), quotes (ppr field_name)]
1087
1088 dataConCtxt con = ptext SLIT("In the definition of data constructor") <+> quotes (ppr con)
1089
1090 classOpCtxt sel_id tau = sep [ptext SLIT("When checking the class method:"),
1091                               nest 2 (ppr sel_id <+> dcolon <+> ppr tau)]
1092
1093 nullaryClassErr cls
1094   = ptext SLIT("No parameters for class")  <+> quotes (ppr cls)
1095
1096 classArityErr cls
1097   = vcat [ptext SLIT("Too many parameters for class") <+> quotes (ppr cls),
1098           parens (ptext SLIT("Use -fglasgow-exts to allow multi-parameter classes"))]
1099
1100 noClassTyVarErr clas op
1101   = sep [ptext SLIT("The class method") <+> quotes (ppr op),
1102          ptext SLIT("mentions none of the type variables of the class") <+>
1103                 ppr clas <+> hsep (map ppr (classTyVars clas))]
1104
1105 genericMultiParamErr clas
1106   = ptext SLIT("The multi-parameter class") <+> quotes (ppr clas) <+>
1107     ptext SLIT("cannot have generic methods")
1108
1109 badGenericMethodType op op_ty
1110   = hang (ptext SLIT("Generic method type is too complex"))
1111        4 (vcat [ppr op <+> dcolon <+> ppr op_ty,
1112                 ptext SLIT("You can only use type variables, arrows, lists, and tuples")])
1113
1114 recSynErr syn_decls
1115   = setSrcSpan (getLoc (head sorted_decls)) $
1116     addErr (sep [ptext SLIT("Cycle in type synonym declarations:"),
1117                  nest 2 (vcat (map ppr_decl sorted_decls))])
1118   where
1119     sorted_decls = sortLocated syn_decls
1120     ppr_decl (L loc decl) = ppr loc <> colon <+> ppr decl
1121
1122 recClsErr cls_decls
1123   = setSrcSpan (getLoc (head sorted_decls)) $
1124     addErr (sep [ptext SLIT("Cycle in class declarations (via superclasses):"),
1125                  nest 2 (vcat (map ppr_decl sorted_decls))])
1126   where
1127     sorted_decls = sortLocated cls_decls
1128     ppr_decl (L loc decl) = ppr loc <> colon <+> ppr (decl { tcdSigs = [] })
1129
1130 sortLocated :: [Located a] -> [Located a]
1131 sortLocated things = sortLe le things
1132   where
1133     le (L l1 _) (L l2 _) = l1 <= l2
1134
1135 badDataConTyCon data_con
1136   = hang (ptext SLIT("Data constructor") <+> quotes (ppr data_con) <+>
1137                 ptext SLIT("returns type") <+> quotes (ppr (dataConTyCon data_con)))
1138        2 (ptext SLIT("instead of its parent type"))
1139
1140 badGadtDecl tc_name
1141   = vcat [ ptext SLIT("Illegal generalised algebraic data declaration for") <+> quotes (ppr tc_name)
1142          , nest 2 (parens $ ptext SLIT("Use -fglasgow-exts to allow GADTs")) ]
1143
1144 badStupidTheta tc_name
1145   = ptext SLIT("A data type declared in GADT style cannot have a context:") <+> quotes (ppr tc_name)
1146
1147 newtypeConError tycon n
1148   = sep [ptext SLIT("A newtype must have exactly one constructor,"),
1149          nest 2 $ ptext SLIT("but") <+> quotes (ppr tycon) <+> ptext SLIT("has") <+> speakN n ]
1150
1151 newtypeExError con
1152   = sep [ptext SLIT("A newtype constructor cannot have an existential context,"),
1153          nest 2 $ ptext SLIT("but") <+> quotes (ppr con) <+> ptext SLIT("does")]
1154
1155 newtypePredError con
1156   = sep [ptext SLIT("A newtype constructor must have a return type of form T a1 ... an"),
1157          nest 2 $ ptext SLIT("but") <+> quotes (ppr con) <+> ptext SLIT("does not")]
1158
1159 newtypeFieldErr con_name n_flds
1160   = sep [ptext SLIT("The constructor of a newtype must have exactly one field"),
1161          nest 2 $ ptext SLIT("but") <+> quotes (ppr con_name) <+> ptext SLIT("has") <+> speakN n_flds]
1162
1163 badSigTyDecl tc_name
1164   = vcat [ ptext SLIT("Illegal kind signature") <+>
1165            quotes (ppr tc_name)
1166          , nest 2 (parens $ ptext SLIT("Use -fglasgow-exts to allow kind signatures")) ]
1167
1168 badFamInstDecl tc_name
1169   = vcat [ ptext SLIT("Illegal family instance for") <+>
1170            quotes (ppr tc_name)
1171          , nest 2 (parens $ ptext SLIT("Use -findexed-types to allow indexed type families")) ]
1172
1173 badGadtIdxTyDecl tc_name
1174   = vcat [ ptext SLIT("Illegal generalised algebraic data declaration for") <+>
1175            quotes (ppr tc_name)
1176          , nest 2 (parens $ ptext SLIT("Family instances can not yet use GADT declarations")) ]
1177
1178 tooManyParmsErr tc_name
1179   = ptext SLIT("Family instance has too many parameters:") <+>
1180     quotes (ppr tc_name)
1181
1182 tooFewParmsErr tc_name
1183   = ptext SLIT("Family instance has too few parameters:") <+>
1184     quotes (ppr tc_name)
1185
1186 badBootFamInstDeclErr =
1187   ptext SLIT("Illegal family instance in hs-boot file")
1188
1189 wrongKindOfFamily family =
1190   ptext SLIT("Wrong category of family instance; declaration was for a") <+>
1191   kindOfFamily
1192   where
1193     kindOfFamily | isSynTyCon family = ptext SLIT("type synonym")
1194                  | isAlgTyCon family = ptext SLIT("data type")
1195                  | otherwise = pprPanic "wrongKindOfFamily" (ppr family)
1196
1197 emptyConDeclsErr tycon
1198   = sep [quotes (ppr tycon) <+> ptext SLIT("has no constructors"),
1199          nest 2 $ ptext SLIT("(-fglasgow-exts permits this)")]
1200 \end{code}