compiler/typecheck/TcTyClsDecls.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1996-1998
   3 %
   4 \section[TcTyClsDecls]{Typecheck type and class declarations}
   5
   6 \begin{code}
   7 module TcTyClsDecls (
   8         tcTyAndClassDecls, tcIdxTyInstDecl
   9     ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( TyClDecl(..),  HsConDetails(..), HsTyVarBndr(..),
  14                           ConDecl(..),   Sig(..), NewOrData(..), ResType(..),
  15                           tyClDeclTyVars, isSynDecl, isClassDecl, isIdxTyDecl,
  16                           isKindSigDecl, hsConArgs, LTyClDecl, tcdName,
  17                           hsTyVarName, LHsTyVarBndr, LHsType, HsType(..),
  18                           mkHsAppTy
  19                         )
  20 import HsTypes          ( HsBang(..), getBangStrictness, hsLTyVarNames )
  21 import BasicTypes       ( RecFlag(..), StrictnessMark(..) )
  22 import HscTypes         ( implicitTyThings, ModDetails )
  23 import BuildTyCl        ( buildClass, buildAlgTyCon, buildSynTyCon, buildDataCon,
  24                           mkDataTyConRhs, mkNewTyConRhs )
  25 import TcRnMonad
  26 import TcEnv            ( TyThing(..),
  27                           tcLookupLocated, tcLookupLocatedGlobal,
  28                           tcExtendGlobalEnv, tcExtendKindEnv,
  29                           tcExtendKindEnvTvs, newFamInstTyConName,
  30                           tcExtendRecEnv, tcLookupTyVar, InstInfo,
  31                           tcLookupLocatedTyCon )
  32 import TcTyDecls        ( calcRecFlags, calcClassCycles, calcSynCycles )
  33 import TcClassDcl       ( tcClassSigs, tcAddDeclCtxt )
  34 import TcHsType         ( kcHsTyVars, kcHsLiftedSigType, kcHsType,
  35                           kcHsContext, tcTyVarBndrs, tcHsKindedType, tcHsKindedContext,
  36                           kcHsSigType, tcHsBangType, tcLHsConResTy,
  37                           tcDataKindSig, kcCheckHsType )
  38 import TcMType          ( newKindVar, checkValidTheta, checkValidType,
  39                           -- checkFreeness,
  40                           UserTypeCtxt(..), SourceTyCtxt(..) )
  41 import TcType           ( TcKind, TcType, Type, tyVarsOfType, mkPhiTy,
  42                           mkArrowKind, liftedTypeKind, mkTyVarTys,
  43                           tcSplitSigmaTy, tcEqTypes, tcGetTyVar_maybe )
  44 import Type             ( PredType(..), splitTyConApp_maybe, mkTyVarTy,
  45                           newTyConInstRhs, isLiftedTypeKind, Kind
  46                           -- pprParendType, pprThetaArrow
  47                         )
  48 import Generics         ( validGenericMethodType, canDoGenerics )
  49 import Class            ( Class, className, classTyCon, DefMeth(..), classBigSig, classTyVars )
  50 import TyCon            ( TyCon, AlgTyConRhs( AbstractTyCon, OpenDataTyCon,
  51                                               OpenNewTyCon ),
  52                           SynTyConRhs( OpenSynTyCon, SynonymTyCon ),
  53                           tyConDataCons, mkForeignTyCon, isProductTyCon,
  54                           isRecursiveTyCon, isOpenTyCon,
  55                           tyConStupidTheta, synTyConRhs, isSynTyCon, tyConName,
  56                           isNewTyCon, isDataTyCon, tyConKind,
  57                           setTyConArgPoss )
  58 import DataCon          ( DataCon, dataConUserType, dataConName,
  59                           dataConFieldLabels, dataConTyCon, dataConAllTyVars,
  60                           dataConFieldType, dataConResTys )
  61 import Var              ( TyVar, idType, idName )
  62 import VarSet           ( elemVarSet, mkVarSet )
  63 import Name             ( Name, getSrcLoc )
  64 import Outputable
  65 import Maybe            ( isJust, fromJust, isNothing, catMaybes )
  66 import Maybes           ( expectJust )
  67 import Monad            ( unless )
  68 import Unify            ( tcMatchTys, tcMatchTyX )
  69 import Util             ( zipLazy, isSingleton, notNull, sortLe )
  70 import List             ( partition, elemIndex )
  71 import SrcLoc           ( Located(..), unLoc, getLoc, srcLocSpan,
  72                           srcSpanStart )
  73 import ListSetOps       ( equivClasses, minusList )
  74 import Digraph          ( SCC(..) )
  75 import DynFlags         ( DynFlag( Opt_GlasgowExts, Opt_Generics,
  76                                    Opt_UnboxStrictFields, Opt_IndexedTypes ) )
  77 \end{code}
  78
  79
  80 %************************************************************************
  81 %*                                                                      *
  82 \subsection{Type checking for type and class declarations}
  83 %*                                                                      *
  84 %************************************************************************
  85
  86 Dealing with a group
  87 ~~~~~~~~~~~~~~~~~~~~
  88 Consider a mutually-recursive group, binding
  89 a type constructor T and a class C.
  90
  91 Step 1:         getInitialKind
  92         Construct a KindEnv by binding T and C to a kind variable
  93
  94 Step 2:         kcTyClDecl
  95         In that environment, do a kind check
  96
  97 Step 3: Zonk the kinds
  98
  99 Step 4:         buildTyConOrClass
 100         Construct an environment binding T to a TyCon and C to a Class.
 101         a) Their kinds comes from zonking the relevant kind variable
 102         b) Their arity (for synonyms) comes direct from the decl
 103         c) The funcional dependencies come from the decl
 104         d) The rest comes a knot-tied binding of T and C, returned from Step 4
 105         e) The variances of the tycons in the group is calculated from
 106                 the knot-tied stuff
 107
 108 Step 5:         tcTyClDecl1
 109         In this environment, walk over the decls, constructing the TyCons and Classes.
 110         This uses in a strict way items (a)-(c) above, which is why they must
 111         be constructed in Step 4. Feed the results back to Step 4.
 112         For this step, pass the is-recursive flag as the wimp-out flag
 113         to tcTyClDecl1.
 114
 115
 116 Step 6:         Extend environment
 117         We extend the type environment with bindings not only for the TyCons and Classes,
 118         but also for their "implicit Ids" like data constructors and class selectors
 119
 120 Step 7:         checkValidTyCl
 121         For a recursive group only, check all the decls again, just
 122         to check all the side conditions on validity.  We could not
 123         do this before because we were in a mutually recursive knot.
 124
 125 Identification of recursive TyCons
 126 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 127 The knot-tying parameters: @rec_details_list@ is an alist mapping @Name@s to
 128 @TyThing@s.
 129
 130 Identifying a TyCon as recursive serves two purposes
 131
 132 1.  Avoid infinite types.  Non-recursive newtypes are treated as
 133 "transparent", like type synonyms, after the type checker.  If we did
 134 this for all newtypes, we'd get infinite types.  So we figure out for
 135 each newtype whether it is "recursive", and add a coercion if so.  In
 136 effect, we are trying to "cut the loops" by identifying a loop-breaker.
 137
 138 2.  Avoid infinite unboxing.  This is nothing to do with newtypes.
 139 Suppose we have
 140         data T = MkT Int T
 141         f (MkT x t) = f t
 142 Well, this function diverges, but we don't want the strictness analyser
 143 to diverge.  But the strictness analyser will diverge because it looks
 144 deeper and deeper into the structure of T.   (I believe there are
 145 examples where the function does something sane, and the strictness
 146 analyser still diverges, but I can't see one now.)
 147
 148 Now, concerning (1), the FC2 branch currently adds a coercion for ALL
 149 newtypes.  I did this as an experiment, to try to expose cases in which
 150 the coercions got in the way of optimisations.  If it turns out that we
 151 can indeed always use a coercion, then we don't risk recursive types,
 152 and don't need to figure out what the loop breakers are.
 153
 154 For newtype *families* though, we will always have a coercion, so they
 155 are always loop breakers!  So you can easily adjust the current
 156 algorithm by simply treating all newtype families as loop breakers (and
 157 indeed type families).  I think.
 158
 159 \begin{code}
 160 tcTyAndClassDecls :: ModDetails -> [LTyClDecl Name]
 161                    -> TcM TcGblEnv      -- Input env extended by types and classes
 162                                         -- and their implicit Ids,DataCons
 163 tcTyAndClassDecls boot_details allDecls
 164   = do  {       -- Omit instances of indexed types; they are handled together
 165                 -- with the *heads* of class instances
 166         ; let decls = filter (not . isIdxTyDecl . unLoc) allDecls
 167
 168                 -- First check for cyclic type synonysm or classes
 169                 -- See notes with checkCycleErrs
 170         ; checkCycleErrs decls
 171         ; mod <- getModule
 172         ; traceTc (text "tcTyAndCl" <+> ppr mod)
 173         ; (syn_tycons, alg_tyclss) <- fixM (\ ~(rec_syn_tycons, rec_alg_tyclss) ->
 174           do    { let { -- Seperate ordinary synonyms from all other type and
 175                         -- class declarations and add all associated type
 176                         -- declarations from type classes.  The latter is
 177                         -- required so that the temporary environment for the
 178                         -- knot includes all associated family declarations.
 179                       ; (syn_decls, alg_decls) = partition (isSynDecl . unLoc)
 180                                                    decls
 181                       ; alg_at_decls           = concatMap addATs alg_decls
 182                       }
 183                         -- Extend the global env with the knot-tied results
 184                         -- for data types and classes
 185                         --
 186                         -- We must populate the environment with the loop-tied
 187                         -- T's right away, because the kind checker may "fault
 188                         -- in" some type  constructors that recursively
 189                         -- mention T
 190                 ; let gbl_things = mkGlobalThings alg_at_decls rec_alg_tyclss
 191                 ; tcExtendRecEnv gbl_things $ do
 192
 193                         -- Kind-check the declarations
 194                 { (kc_syn_decls, kc_alg_decls) <- kcTyClDecls syn_decls alg_decls
 195
 196                 ; let { -- Calculate rec-flag
 197                       ; calc_rec  = calcRecFlags boot_details rec_alg_tyclss
 198                       ; tc_decl   = addLocM (tcTyClDecl calc_rec) }
 199                         -- Type-check the type synonyms, and extend the envt
 200                 ; syn_tycons <- tcSynDecls kc_syn_decls
 201                 ; tcExtendGlobalEnv syn_tycons $ do
 202
 203                         -- Type-check the data types and classes
 204                 { alg_tyclss <- mappM tc_decl kc_alg_decls
 205                 ; return (syn_tycons, concat alg_tyclss)
 206             }}})
 207         -- Finished with knot-tying now
 208         -- Extend the environment with the finished things
 209         ; tcExtendGlobalEnv (syn_tycons ++ alg_tyclss) $ do
 210
 211         -- Perform the validity check
 212         { traceTc (text "ready for validity check")
 213         ; mappM_ (addLocM checkValidTyCl) decls
 214         ; traceTc (text "done")
 215
 216         -- Add the implicit things;
 217         -- we want them in the environment because
 218         -- they may be mentioned in interface files
 219         -- NB: All associated types and their implicit things will be added a
 220         --     second time here.  This doesn't matter as the definitions are
 221         --     the same.
 222         ; let { implicit_things = concatMap implicitTyThings alg_tyclss }
 223         ; traceTc ((text "Adding" <+> ppr alg_tyclss)
 224                    $$ (text "and" <+> ppr implicit_things))
 225         ; tcExtendGlobalEnv implicit_things getGblEnv
 226     }}
 227   where
 228     -- Pull associated types out of class declarations, to tie them into the
 229     -- knot above.
 230     -- NB: We put them in the same place in the list as `tcTyClDecl' will
 231     --     eventually put the matching `TyThing's.  That's crucial; otherwise,
 232     --     the two argument lists of `mkGlobalThings' don't match up.
 233     addATs decl@(L _ (ClassDecl {tcdATs = ats})) = decl : ats
 234     addATs decl                                  = [decl]
 235
 236 mkGlobalThings :: [LTyClDecl Name]      -- The decls
 237                -> [TyThing]             -- Knot-tied, in 1-1 correspondence with the decls
 238                -> [(Name,TyThing)]
 239 -- Driven by the Decls, and treating the TyThings lazily
 240 -- make a TypeEnv for the new things
 241 mkGlobalThings decls things
 242   = map mk_thing (decls `zipLazy` things)
 243   where
 244     mk_thing (L _ (ClassDecl {tcdLName = L _ name}), ~(AClass cl))
 245          = (name, AClass cl)
 246     mk_thing (L _ decl, ~(ATyCon tc))
 247          = (tcdName decl, ATyCon tc)
 248 \end{code}
 249
 250
 251 %************************************************************************
 252 %*                                                                      *
 253 \subsection{Type checking instances of indexed types}
 254 %*                                                                      *
 255 %************************************************************************
 256
 257 Instances of indexed types are somewhat of a hybrid.  They are processed
 258 together with class instance heads, but can contain data constructors and hence
 259 they share a lot of kinding and type checking code with ordinary algebraic
 260 data types (and GADTs).
 261
 262 \begin{code}
 263 tcIdxTyInstDecl :: LTyClDecl Name
 264                 -> TcM (Maybe InstInfo, Maybe TyThing)  -- Nothing if error
 265 tcIdxTyInstDecl (L loc decl)
 266   =     -- Prime error recovery, set source location
 267     recoverM (returnM (Nothing, Nothing))       $
 268     setSrcSpan loc                              $
 269     tcAddDeclCtxt decl                          $
 270     do { -- indexed data types require -findexed-types and can't be in an
 271          -- hs-boot file
 272        ; gla_exts <- doptM Opt_IndexedTypes
 273        ; is_boot  <- tcIsHsBoot   -- Are we compiling an hs-boot file?
 274        ; checkTc gla_exts      $ badIdxTyDecl (tcdLName decl)
 275        ; checkTc (not is_boot) $ badBootTyIdxDeclErr
 276
 277          -- perform kind and type checking
 278        ; tcIdxTyInstDecl1 decl
 279        }
 280
 281 tcIdxTyInstDecl1 :: TyClDecl Name
 282                  -> TcM (Maybe InstInfo, Maybe TyThing) -- Nothing if error
 283
 284 tcIdxTyInstDecl1 (decl@TySynonym {})
 285   = kcIdxTyPats decl $ \k_tvs k_typats resKind family ->
 286     do { -- check that the family declaration is for a synonym
 287          unless (isSynTyCon family) $
 288            addErr (wrongKindOfFamily family)
 289
 290        ; -- (1) kind check the right hand side of the type equation
 291        ; k_rhs <- kcCheckHsType (tcdSynRhs decl) resKind
 292
 293          -- (2) type check type equation
 294        ; tcTyVarBndrs k_tvs $ \t_tvs -> do {  -- turn kinded into proper tyvars
 295        ; t_typats <- mappM tcHsKindedType k_typats
 296        ; t_rhs    <- tcHsKindedType k_rhs
 297
 298          -- construct type rewrite rule
 299          -- !!!of the form: forall t_tvs. (tcdLName decl) t_typats = t_rhs
 300        ; return (Nothing, Nothing) -- !!!TODO: need InstInfo for eq axioms
 301        }}
 302
 303 tcIdxTyInstDecl1 (decl@TyData {tcdND = new_or_data, tcdLName = L loc tc_name,
 304                                tcdCons = cons})
 305   = kcIdxTyPats decl $ \k_tvs k_typats resKind family ->
 306     do { -- check that the family declaration is for the right kind
 307          unless (new_or_data == NewType  && isNewTyCon  family ||
 308                  new_or_data == DataType && isDataTyCon family) $
 309            addErr (wrongKindOfFamily family)
 310
 311        ; -- (1) kind check the data declaration as usual
 312        ; k_decl <- kcDataDecl decl k_tvs
 313        ; let k_ctxt = tcdCtxt k_decl
 314              k_cons = tcdCons k_decl
 315
 316          -- result kind must be '*' (otherwise, we have too few patterns)
 317        ; checkTc (isLiftedTypeKind resKind) $ tooFewParmsErr tc_name
 318
 319          -- (2) type check indexed data type declaration
 320        ; tcTyVarBndrs k_tvs $ \t_tvs -> do {  -- turn kinded into proper tyvars
 321        ; unbox_strict <- doptM Opt_UnboxStrictFields
 322
 323          -- Check that we don't use GADT syntax for indexed types
 324        ; checkTc h98_syntax (badGadtIdxTyDecl tc_name)
 325
 326          -- Check that a newtype has exactly one constructor
 327        ; checkTc (new_or_data == DataType || isSingleton k_cons) $
 328            newtypeConError tc_name (length k_cons)
 329
 330        ; t_typats     <- mappM tcHsKindedType k_typats
 331        ; stupid_theta <- tcHsKindedContext k_ctxt
 332
 333        ; rep_tc_name <- newFamInstTyConName tc_name (srcSpanStart loc)
 334        ; tycon <- fixM (\ tycon -> do
 335              { data_cons <- mappM (addLocM (tcConDecl unbox_strict new_or_data
 336                                               tycon t_tvs))
 337                                   k_cons
 338              ; tc_rhs <-
 339                  case new_or_data of
 340                    DataType -> return (mkDataTyConRhs data_cons)
 341                    NewType  -> ASSERT( isSingleton data_cons )
 342                                mkNewTyConRhs tc_name tycon (head data_cons)
 343              ; buildAlgTyCon rep_tc_name t_tvs stupid_theta tc_rhs Recursive
 344                              False h98_syntax (Just (family, t_typats))
 345                  -- We always assume that indexed types are recursive.  Why?
 346                  -- (1) Due to their open nature, we can never be sure that a
 347                  -- further instance might not introduce a new recursive
 348                  -- dependency.  (2) They are always valid loop breakers as
 349                  -- they involve a coercion.
 350              })
 351
 352          -- construct result
 353        ; return (Nothing, Just (ATyCon tycon))
 354        }}
 355        where
 356          h98_syntax = case cons of      -- All constructors have same shape
 357                         L _ (ConDecl { con_res = ResTyGADT _ }) : _ -> False
 358                         other -> True
 359
 360 -- Kind checking of indexed types
 361 -- -
 362
 363 -- Kind check type patterns and kind annotate the embedded type variables.
 364 --
 365 -- * Here we check that a type instance matches its kind signature, but we do
 366 --   not check whether there is a pattern for each type index; the latter
 367 --   check is only required for type functions.
 368 --
 369 kcIdxTyPats :: TyClDecl Name
 370             -> ([LHsTyVarBndr Name] -> [LHsType Name] -> Kind -> TyCon -> TcM a)
 371                -- ^^kinded tvs         ^^kinded ty pats  ^^res kind
 372             -> TcM a
 373 kcIdxTyPats decl thing_inside
 374   = kcHsTyVars (tcdTyVars decl) $ \tvs ->
 375     do { family <- tcLookupLocatedTyCon (tcdLName decl)
 376        ; let { (kinds, resKind) = splitKindFunTys (tyConKind family)
 377              ; hs_typats        = fromJust $ tcdTyPats decl }
 378
 379          -- we may not have more parameters than the kind indicates
 380        ; checkTc (length kinds >= length hs_typats) $
 381            tooManyParmsErr (tcdLName decl)
 382
 383          -- type functions can have a higher-kinded result
 384        ; let resultKind = mkArrowKinds (drop (length hs_typats) kinds) resKind
 385        ; typats <- zipWithM kcCheckHsType hs_typats kinds
 386        ; thing_inside tvs typats resultKind family
 387        }
 388   where
 389 \end{code}
 390
 391
 392 %************************************************************************
 393 %*                                                                      *
 394                 Kind checking
 395 %*                                                                      *
 396 %************************************************************************
 397
 398 We need to kind check all types in the mutually recursive group
 399 before we know the kind of the type variables.  For example:
 400
 401 class C a where
 402    op :: D b => a -> b -> b
 403
 404 class D c where
 405    bop :: (Monad c) => ...
 406
 407 Here, the kind of the locally-polymorphic type variable "b"
 408 depends on *all the uses of class D*.  For example, the use of
 409 Monad c in bop's type signature means that D must have kind Type->Type.
 410
 411 However type synonyms work differently.  They can have kinds which don't
 412 just involve (->) and *:
 413         type R = Int#           -- Kind #
 414         type S a = Array# a     -- Kind * -> #
 415         type T a b = (# a,b #)  -- Kind * -> * -> (# a,b #)
 416 So we must infer their kinds from their right-hand sides *first* and then
 417 use them, whereas for the mutually recursive data types D we bring into
 418 scope kind bindings D -> k, where k is a kind variable, and do inference.
 419
 420 Indexed Types
 421 ~~~~~~~~~~~~~
 422 This treatment of type synonyms only applies to Haskell 98-style synonyms.
 423 General type functions can be recursive, and hence, appear in `alg_decls'.
 424
 425 The kind of an indexed type is solely determinded by its kind signature;
 426 hence, only kind signatures participate in the construction of the initial
 427 kind environment (as constructed by `getInitialKind').  In fact, we ignore
 428 instances of indexed types altogether in the following.  However, we need to
 429 include the kind signatures of associated types into the construction of the
 430 initial kind environment.  (This is handled by `allDecls').
 431
 432 \begin{code}
 433 kcTyClDecls syn_decls alg_decls
 434   = do  {       -- First extend the kind env with each data type, class, and
 435                 -- indexed type, mapping them to a type variable
 436           let initialKindDecls = concat [allDecls decl | L _ decl <- alg_decls]
 437         ; alg_kinds <- mappM getInitialKind initialKindDecls
 438         ; tcExtendKindEnv alg_kinds $ do
 439
 440                 -- Now kind-check the type synonyms, in dependency order
 441                 -- We do these differently to data type and classes,
 442                 -- because a type synonym can be an unboxed type
 443                 --      type Foo = Int#
 444                 -- and a kind variable can't unify with UnboxedTypeKind
 445                 -- So we infer their kinds in dependency order
 446         { (kc_syn_decls, syn_kinds) <- kcSynDecls (calcSynCycles syn_decls)
 447         ; tcExtendKindEnv syn_kinds $  do
 448
 449                 -- Now kind-check the data type, class, and kind signatures,
 450                 -- returning kind-annotated decls; we don't kind-check
 451                 -- instances of indexed types yet, but leave this to
 452                 -- `tcInstDecls1'
 453         { kc_alg_decls <- mappM (wrapLocM kcTyClDecl)
 454                             (filter (not . isIdxTyDecl . unLoc) alg_decls)
 455
 456         ; return (kc_syn_decls, kc_alg_decls) }}}
 457   where
 458     -- get all declarations relevant for determining the initial kind
 459     -- environment
 460     allDecls (decl@ClassDecl {tcdATs = ats}) = decl : [ at
 461                                                       | L _ at <- ats
 462                                                       , isKindSigDecl at]
 463     allDecls decl | isIdxTyDecl decl         = []
 464                   | otherwise                = [decl]
 465
 466 ------------------------------------------------------------------------
 467 getInitialKind :: TyClDecl Name -> TcM (Name, TcKind)
 468 -- Only for data type, class, and indexed type declarations
 469 -- Get as much info as possible from the data, class, or indexed type decl,
 470 -- so as to maximise usefulness of error messages
 471 getInitialKind decl
 472   = do  { arg_kinds <- mapM (mk_arg_kind . unLoc) (tyClDeclTyVars decl)
 473         ; res_kind  <- mk_res_kind decl
 474         ; return (tcdName decl, mkArrowKinds arg_kinds res_kind) }
 475   where
 476     mk_arg_kind (UserTyVar _)        = newKindVar
 477     mk_arg_kind (KindedTyVar _ kind) = return kind
 478
 479     mk_res_kind (TyFunction { tcdKind    = kind      }) = return kind
 480     mk_res_kind (TyData     { tcdKindSig = Just kind }) = return kind
 481         -- On GADT-style and data signature declarations we allow a kind
 482         -- signature
 483         --      data T :: *->* where { ... }
 484     mk_res_kind other = return liftedTypeKind
 485
 486
 487 ----------------
 488 kcSynDecls :: [SCC (LTyClDecl Name)]
 489            -> TcM ([LTyClDecl Name],    -- Kind-annotated decls
 490                    [(Name,TcKind)])     -- Kind bindings
 491 kcSynDecls []
 492   = return ([], [])
 493 kcSynDecls (group : groups)
 494   = do  { (decl,  nk)  <- kcSynDecl group
 495         ; (decls, nks) <- tcExtendKindEnv [nk] (kcSynDecls groups)
 496         ; return (decl:decls, nk:nks) }
 497
 498 ----------------
 499 kcSynDecl :: SCC (LTyClDecl Name)
 500            -> TcM (LTyClDecl Name,      -- Kind-annotated decls
 501                    (Name,TcKind))       -- Kind bindings
 502 kcSynDecl (AcyclicSCC ldecl@(L loc decl))
 503   = tcAddDeclCtxt decl  $
 504     kcHsTyVars (tcdTyVars decl) (\ k_tvs ->
 505     do { traceTc (text "kcd1" <+> ppr (unLoc (tcdLName decl)) <+> brackets (ppr (tcdTyVars decl))
 506                         <+> brackets (ppr k_tvs))
 507        ; (k_rhs, rhs_kind) <- kcHsType (tcdSynRhs decl)
 508        ; traceTc (text "kcd2" <+> ppr (unLoc (tcdLName decl)))
 509        ; let tc_kind = foldr (mkArrowKind . kindedTyVarKind) rhs_kind k_tvs
 510        ; return (L loc (decl { tcdTyVars = k_tvs, tcdSynRhs = k_rhs }),
 511                  (unLoc (tcdLName decl), tc_kind)) })
 512
 513 kcSynDecl (CyclicSCC decls)
 514   = do { recSynErr decls; failM }       -- Fail here to avoid error cascade
 515                                         -- of out-of-scope tycons
 516
 517 kindedTyVarKind (L _ (KindedTyVar _ k)) = k
 518
 519 ------------------------------------------------------------------------
 520 kcTyClDecl :: TyClDecl Name -> TcM (TyClDecl Name)
 521         -- Not used for type synonyms (see kcSynDecl)
 522
 523 kcTyClDecl decl@(TyData {})
 524   = ASSERT( not . isJust $ tcdTyPats decl )   -- must not be instance of idx ty
 525     kcTyClDeclBody decl $
 526       kcDataDecl decl
 527
 528 kcTyClDecl decl@(TyFunction {})
 529   = kcTyClDeclBody decl $ \ tvs' ->
 530       return (decl {tcdTyVars = tvs'})
 531
 532 kcTyClDecl decl@(ClassDecl {tcdCtxt = ctxt, tcdSigs = sigs, tcdATs = ats})
 533   = kcTyClDeclBody decl $ \ tvs' ->
 534     do  { is_boot <- tcIsHsBoot
 535         ; ctxt' <- kcHsContext ctxt
 536         ; ats'  <- mappM (wrapLocM kcTyClDecl) ats
 537         ; sigs' <- mappM (wrapLocM kc_sig    ) sigs
 538         ; return (decl {tcdTyVars = tvs', tcdCtxt = ctxt', tcdSigs = sigs',
 539                         tcdATs = ats'}) }
 540   where
 541     kc_sig (TypeSig nm op_ty) = do { op_ty' <- kcHsLiftedSigType op_ty
 542                                    ; return (TypeSig nm op_ty') }
 543     kc_sig other_sig          = return other_sig
 544
 545 kcTyClDecl decl@(ForeignType {})
 546   = return decl
 547
 548 kcTyClDeclBody :: TyClDecl Name
 549                -> ([LHsTyVarBndr Name] -> TcM a)
 550                -> TcM a
 551 -- getInitialKind has made a suitably-shaped kind for the type or class
 552 -- Unpack it, and attribute those kinds to the type variables
 553 -- Extend the env with bindings for the tyvars, taken from
 554 -- the kind of the tycon/class.  Give it to the thing inside, and
 555 -- check the result kind matches
 556 kcTyClDeclBody decl thing_inside
 557   = tcAddDeclCtxt decl          $
 558     do  { tc_ty_thing <- tcLookupLocated (tcdLName decl)
 559         ; let tc_kind    = case tc_ty_thing of { AThing k -> k }
 560               (kinds, _) = splitKindFunTys tc_kind
 561               hs_tvs     = tcdTyVars decl
 562               kinded_tvs = ASSERT( length kinds >= length hs_tvs )
 563                            [ L loc (KindedTyVar (hsTyVarName tv) k)
 564                            | (L loc tv, k) <- zip hs_tvs kinds]
 565         ; tcExtendKindEnvTvs kinded_tvs (thing_inside kinded_tvs) }
 566
 567 -- Kind check a data declaration, assuming that we already extended the
 568 -- kind environment with the type variables of the left-hand side (these
 569 -- kinded type variables are also passed as the second parameter).
 570 --
 571 kcDataDecl :: TyClDecl Name -> [LHsTyVarBndr Name] -> TcM (TyClDecl Name)
 572 kcDataDecl decl@(TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdCons = cons})
 573            tvs
 574   = do  { ctxt' <- kcHsContext ctxt
 575         ; cons' <- mappM (wrapLocM kc_con_decl) cons
 576         ; return (decl {tcdTyVars = tvs, tcdCtxt = ctxt', tcdCons = cons'}) }
 577   where
 578     kc_con_decl (ConDecl name expl ex_tvs ex_ctxt details res) = do
 579       kcHsTyVars ex_tvs $ \ex_tvs' -> do
 580         ex_ctxt' <- kcHsContext ex_ctxt
 581         details' <- kc_con_details details
 582         res'     <- case res of
 583           ResTyH98 -> return ResTyH98
 584           ResTyGADT ty -> do { ty' <- kcHsSigType ty; return (ResTyGADT ty') }
 585         return (ConDecl name expl ex_tvs' ex_ctxt' details' res')
 586
 587     kc_con_details (PrefixCon btys)
 588         = do { btys' <- mappM kc_larg_ty btys ; return (PrefixCon btys') }
 589     kc_con_details (InfixCon bty1 bty2)
 590         = do { bty1' <- kc_larg_ty bty1; bty2' <- kc_larg_ty bty2; return (InfixCon bty1' bty2') }
 591     kc_con_details (RecCon fields)
 592         = do { fields' <- mappM kc_field fields; return (RecCon fields') }
 593
 594     kc_field (fld, bty) = do { bty' <- kc_larg_ty bty ; return (fld, bty') }
 595
 596     kc_larg_ty bty = case new_or_data of
 597                         DataType -> kcHsSigType bty
 598                         NewType  -> kcHsLiftedSigType bty
 599         -- Can't allow an unlifted type for newtypes, because we're effectively
 600         -- going to remove the constructor while coercing it to a lifted type.
 601         -- And newtypes can't be bang'd
 602 \end{code}
 603
 604
 605 %************************************************************************
 606 %*                                                                      *
 607 \subsection{Type checking}
 608 %*                                                                      *
 609 %************************************************************************
 610
 611 \begin{code}
 612 tcSynDecls :: [LTyClDecl Name] -> TcM [TyThing]
 613 tcSynDecls [] = return []
 614 tcSynDecls (decl : decls)
 615   = do { syn_tc <- addLocM tcSynDecl decl
 616        ; syn_tcs <- tcExtendGlobalEnv [syn_tc] (tcSynDecls decls)
 617        ; return (syn_tc : syn_tcs) }
 618
 619 tcSynDecl
 620   (TySynonym {tcdLName = L _ tc_name, tcdTyVars = tvs, tcdSynRhs = rhs_ty})
 621   = tcTyVarBndrs tvs            $ \ tvs' -> do
 622     { traceTc (text "tcd1" <+> ppr tc_name)
 623     ; rhs_ty' <- tcHsKindedType rhs_ty
 624     ; return (ATyCon (buildSynTyCon tc_name tvs' (SynonymTyCon rhs_ty'))) }
 625
 626 --------------------
 627 tcTyClDecl :: (Name -> RecFlag) -> TyClDecl Name -> TcM [TyThing]
 628
 629 tcTyClDecl calc_isrec decl
 630   = tcAddDeclCtxt decl (tcTyClDecl1 calc_isrec decl)
 631
 632   -- kind signature for a type function
 633 tcTyClDecl1 _calc_isrec
 634   (TyFunction {tcdLName = L _ tc_name, tcdTyVars = tvs, tcdKind = kind})
 635   = tcTyVarBndrs tvs  $ \ tvs' -> do
 636   { traceTc (text "type family: " <+> ppr tc_name)
 637   ; gla_exts <- doptM Opt_IndexedTypes
 638
 639         -- Check that we don't use kind signatures without Glasgow extensions
 640   ; checkTc gla_exts $ badSigTyDecl tc_name
 641
 642   ; return [ATyCon $ buildSynTyCon tc_name tvs' (OpenSynTyCon kind)]
 643   }
 644
 645   -- kind signature for an indexed data type
 646 tcTyClDecl1 _calc_isrec
 647   (TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdTyVars = tvs,
 648            tcdLName = L _ tc_name, tcdKindSig = Just ksig, tcdCons = []})
 649   = tcTyVarBndrs tvs  $ \ tvs' -> do
 650   { traceTc (text "data/newtype family: " <+> ppr tc_name)
 651   ; extra_tvs <- tcDataKindSig (Just ksig)
 652   ; let final_tvs = tvs' ++ extra_tvs    -- we may not need these
 653
 654   ; checkTc (null . unLoc $ ctxt) $ badKindSigCtxt tc_name
 655   ; gla_exts <- doptM Opt_IndexedTypes
 656
 657         -- Check that we don't use kind signatures without Glasgow extensions
 658   ; checkTc gla_exts $ badSigTyDecl tc_name
 659
 660   ; tycon <- buildAlgTyCon tc_name final_tvs []
 661                (case new_or_data of
 662                   DataType -> OpenDataTyCon
 663                   NewType  -> OpenNewTyCon)
 664                Recursive False True Nothing
 665   ; return [ATyCon tycon]
 666   }
 667
 668 tcTyClDecl1 calc_isrec
 669   (TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdTyVars = tvs,
 670            tcdLName = L _ tc_name, tcdKindSig = mb_ksig, tcdCons = cons})
 671   = tcTyVarBndrs tvs    $ \ tvs' -> do
 672   { extra_tvs <- tcDataKindSig mb_ksig
 673   ; let final_tvs = tvs' ++ extra_tvs
 674   ; stupid_theta <- tcHsKindedContext ctxt
 675   ; want_generic <- doptM Opt_Generics
 676   ; unbox_strict <- doptM Opt_UnboxStrictFields
 677   ; gla_exts     <- doptM Opt_GlasgowExts
 678   ; is_boot      <- tcIsHsBoot  -- Are we compiling an hs-boot file?
 679
 680         -- Check that we don't use GADT syntax in H98 world
 681   ; checkTc (gla_exts || h98_syntax) (badGadtDecl tc_name)
 682
 683         -- Check that we don't use kind signatures without Glasgow extensions
 684   ; checkTc (gla_exts || isNothing mb_ksig) (badSigTyDecl tc_name)
 685
 686         -- Check that the stupid theta is empty for a GADT-style declaration
 687   ; checkTc (null stupid_theta || h98_syntax) (badStupidTheta tc_name)
 688
 689         -- Check that there's at least one condecl,
 690         -- or else we're reading an hs-boot file, or -fglasgow-exts
 691   ; checkTc (not (null cons) || gla_exts || is_boot)
 692             (emptyConDeclsErr tc_name)
 693
 694         -- Check that a newtype has exactly one constructor
 695   ; checkTc (new_or_data == DataType || isSingleton cons)
 696             (newtypeConError tc_name (length cons))
 697
 698   ; tycon <- fixM (\ tycon -> do
 699         { data_cons <- mappM (addLocM (tcConDecl unbox_strict new_or_data
 700                                                  tycon final_tvs))
 701                              cons
 702         ; tc_rhs <-
 703             if null cons && is_boot     -- In a hs-boot file, empty cons means
 704             then return AbstractTyCon   -- "don't know"; hence Abstract
 705             else case new_or_data of
 706                    DataType -> return (mkDataTyConRhs data_cons)
 707                    NewType  ->
 708                        ASSERT( isSingleton data_cons )
 709                        mkNewTyConRhs tc_name tycon (head data_cons)
 710         ; buildAlgTyCon tc_name final_tvs stupid_theta tc_rhs is_rec
 711             (want_generic && canDoGenerics data_cons) h98_syntax Nothing
 712         })
 713   ; return [ATyCon tycon]
 714   }
 715   where
 716     is_rec   = calc_isrec tc_name
 717     h98_syntax = case cons of   -- All constructors have same shape
 718                         L _ (ConDecl { con_res = ResTyGADT _ }) : _ -> False
 719                         other -> True
 720
 721 tcTyClDecl1 calc_isrec
 722   (ClassDecl {tcdLName = L _ class_name, tcdTyVars = tvs,
 723               tcdCtxt = ctxt, tcdMeths = meths,
 724               tcdFDs = fundeps, tcdSigs = sigs, tcdATs = ats} )
 725   = tcTyVarBndrs tvs            $ \ tvs' -> do
 726   { ctxt' <- tcHsKindedContext ctxt
 727   ; fds' <- mappM (addLocM tc_fundep) fundeps
 728   ; atss <- mappM (addLocM (tcTyClDecl1 (const Recursive))) ats
 729   ; let ats' = zipWith setTyThingPoss atss (map (tcdTyVars . unLoc) ats)
 730   ; sig_stuff <- tcClassSigs class_name sigs meths
 731   ; clas <- fixM (\ clas ->
 732                 let     -- This little knot is just so we can get
 733                         -- hold of the name of the class TyCon, which we
 734                         -- need to look up its recursiveness
 735                     tycon_name = tyConName (classTyCon clas)
 736                     tc_isrec = calc_isrec tycon_name
 737                 in
 738                 buildClass class_name tvs' ctxt' fds' ats'
 739                            sig_stuff tc_isrec)
 740   ; return (AClass clas : ats')
 741       -- NB: Order is important due to the call to `mkGlobalThings' when
 742       --     tying the the type and class declaration type checking knot.
 743   }
 744   where
 745     tc_fundep (tvs1, tvs2) = do { tvs1' <- mappM tcLookupTyVar tvs1 ;
 746                                 ; tvs2' <- mappM tcLookupTyVar tvs2 ;
 747                                 ; return (tvs1', tvs2') }
 748
 749     -- For each AT argument compute the position of the corresponding class
 750     -- parameter in the class head.  This will later serve as a permutation
 751     -- vector when checking the validity of instance declarations.
 752     setTyThingPoss [ATyCon tycon] atTyVars =
 753       let classTyVars = hsLTyVarNames tvs
 754           poss        =   catMaybes
 755                         . map (`elemIndex` classTyVars)
 756                         . hsLTyVarNames
 757                         $ atTyVars
 758                      -- There will be no Nothing, as we already passed renaming
 759       in
 760       ATyCon (setTyConArgPoss tycon poss)
 761     setTyThingPoss _              _ = panic "TcTyClsDecls.setTyThingPoss"
 762
 763 tcTyClDecl1 calc_isrec
 764   (ForeignType {tcdLName = L _ tc_name, tcdExtName = tc_ext_name})
 765   = returnM [ATyCon (mkForeignTyCon tc_name tc_ext_name liftedTypeKind 0)]
 766
 767 -----------------------------------
 768 tcConDecl :: Bool               -- True <=> -funbox-strict_fields
 769           -> NewOrData
 770           -> TyCon -> [TyVar]
 771           -> ConDecl Name
 772           -> TcM DataCon
 773
 774 tcConDecl unbox_strict NewType tycon tc_tvs     -- Newtypes
 775           (ConDecl name _ ex_tvs ex_ctxt details ResTyH98)
 776   = do  { let tc_datacon field_lbls arg_ty
 777                 = do { arg_ty' <- tcHsKindedType arg_ty -- No bang on newtype
 778                      ; buildDataCon (unLoc name) False {- Prefix -}
 779                                     [NotMarkedStrict]
 780                                     (map unLoc field_lbls)
 781                                     tc_tvs []  -- No existentials
 782                                     [] []      -- No equalities, predicates
 783                                     [arg_ty']
 784                                     tycon }
 785
 786                 -- Check that a newtype has no existential stuff
 787         ; checkTc (null ex_tvs && null (unLoc ex_ctxt)) (newtypeExError name)
 788
 789         ; case details of
 790             PrefixCon [arg_ty]           -> tc_datacon [] arg_ty
 791             RecCon [(field_lbl, arg_ty)] -> tc_datacon [field_lbl] arg_ty
 792             other                        ->
 793               failWithTc (newtypeFieldErr name (length (hsConArgs details)))
 794                         -- Check that the constructor has exactly one field
 795         }
 796
 797 tcConDecl unbox_strict DataType tycon tc_tvs    -- Data types
 798           (ConDecl name _ tvs ctxt details res_ty)
 799   = tcTyVarBndrs tvs            $ \ tvs' -> do
 800     { ctxt' <- tcHsKindedContext ctxt
 801     ; (univ_tvs, ex_tvs, eq_preds, data_tc) <- tcResultType tycon tc_tvs tvs' res_ty
 802     ; let
 803         tc_datacon is_infix field_lbls btys
 804           = do { let bangs = map getBangStrictness btys
 805                ; arg_tys <- mappM tcHsBangType btys
 806                ; buildDataCon (unLoc name) is_infix
 807                     (argStrictness unbox_strict tycon bangs arg_tys)
 808                     (map unLoc field_lbls)
 809                     univ_tvs ex_tvs eq_preds ctxt' arg_tys
 810                     data_tc }
 811                 -- NB:  we put data_tc, the type constructor gotten from the
 812                 --      constructor type signature into the data constructor;
 813                 --      that way checkValidDataCon can complain if it's wrong.
 814
 815     ; case details of
 816         PrefixCon btys     -> tc_datacon False [] btys
 817         InfixCon bty1 bty2 -> tc_datacon True  [] [bty1,bty2]
 818         RecCon fields      -> tc_datacon False field_names btys
 819                            where
 820                               (field_names, btys) = unzip fields
 821
 822     }
 823
 824 tcResultType :: TyCon
 825              -> [TyVar]         -- data T a b c = ...
 826              -> [TyVar]         -- where MkT :: forall a b c. ...
 827              -> ResType Name
 828              -> TcM ([TyVar],           -- Universal
 829                      [TyVar],           -- Existential
 830                      [(TyVar,Type)],    -- Equality predicates
 831                      TyCon)             -- TyCon given in the ResTy
 832         -- We don't check that the TyCon given in the ResTy is
 833         -- the same as the parent tycon, becuase we are in the middle
 834         -- of a recursive knot; so it's postponed until checkValidDataCon
 835
 836 tcResultType decl_tycon tc_tvs dc_tvs ResTyH98
 837   = return (tc_tvs, dc_tvs, [], decl_tycon)
 838         -- In H98 syntax the dc_tvs are the existential ones
 839         --      data T a b c = forall d e. MkT ...
 840         -- The {a,b,c} are tc_tvs, and {d,e} are dc_tvs
 841
 842 tcResultType _ tc_tvs dc_tvs (ResTyGADT res_ty)
 843         -- E.g.  data T a b c where
 844         --         MkT :: forall x y z. T (x,y) z z
 845         -- Then we generate
 846         --      ([a,z,c], [x,y], [a:=:(x,y), c:=:z], T)
 847
 848   = do  { (dc_tycon, res_tys) <- tcLHsConResTy res_ty
 849                 -- NB: tc_tvs and dc_tvs are distinct
 850         ; let univ_tvs = choose_univs [] tc_tvs res_tys
 851                 -- Each univ_tv is either a dc_tv or a tc_tv
 852               ex_tvs = dc_tvs `minusList` univ_tvs
 853               eq_spec = [ (tv, ty) | (tv,ty) <- univ_tvs `zip` res_tys,
 854                                       tv `elem` tc_tvs]
 855         ; return (univ_tvs, ex_tvs, eq_spec, dc_tycon) }
 856   where
 857         -- choose_univs uses the res_ty itself if it's a type variable
 858         -- and hasn't already been used; otherwise it uses one of the tc_tvs
 859     choose_univs used tc_tvs []
 860         = ASSERT( null tc_tvs ) []
 861     choose_univs used (tc_tv:tc_tvs) (res_ty:res_tys)
 862         | Just tv <- tcGetTyVar_maybe res_ty, not (tv `elem` used)
 863         = tv    : choose_univs (tv:used) tc_tvs res_tys
 864         | otherwise
 865         = tc_tv : choose_univs used tc_tvs res_tys
 866
 867 -------------------
 868 argStrictness :: Bool           -- True <=> -funbox-strict_fields
 869               -> TyCon -> [HsBang]
 870               -> [TcType] -> [StrictnessMark]
 871 argStrictness unbox_strict tycon bangs arg_tys
 872  = ASSERT( length bangs == length arg_tys )
 873    zipWith (chooseBoxingStrategy unbox_strict tycon) arg_tys bangs
 874
 875 -- We attempt to unbox/unpack a strict field when either:
 876 --   (i)  The field is marked '!!', or
 877 --   (ii) The field is marked '!', and the -funbox-strict-fields flag is on.
 878 --
 879 -- We have turned off unboxing of newtypes because coercions make unboxing
 880 -- and reboxing more complicated
 881 chooseBoxingStrategy :: Bool -> TyCon -> TcType -> HsBang -> StrictnessMark
 882 chooseBoxingStrategy unbox_strict_fields tycon arg_ty bang
 883   = case bang of
 884         HsNoBang                                    -> NotMarkedStrict
 885         HsStrict | unbox_strict_fields
 886                    && can_unbox arg_ty              -> MarkedUnboxed
 887         HsUnbox  | can_unbox arg_ty                 -> MarkedUnboxed
 888         other                                       -> MarkedStrict
 889   where
 890     -- we can unbox if the type is a chain of newtypes with a product tycon
 891     -- at the end
 892     can_unbox arg_ty = case splitTyConApp_maybe arg_ty of
 893                    Nothing                      -> False
 894                    Just (arg_tycon, tycon_args) ->
 895                        not (isRecursiveTyCon tycon) &&
 896                        isProductTyCon arg_tycon &&
 897                        (if isNewTyCon arg_tycon then
 898                             can_unbox (newTyConInstRhs arg_tycon tycon_args)
 899                         else True)
 900 \end{code}
 901
 902 %************************************************************************
 903 %*                                                                      *
 904 \subsection{Dependency analysis}
 905 %*                                                                      *
 906 %************************************************************************
 907
 908 Validity checking is done once the mutually-recursive knot has been
 909 tied, so we can look at things freely.
 910
 911 \begin{code}
 912 checkCycleErrs :: [LTyClDecl Name] -> TcM ()
 913 checkCycleErrs tyclss
 914   | null cls_cycles
 915   = return ()
 916   | otherwise
 917   = do  { mappM_ recClsErr cls_cycles
 918         ; failM }       -- Give up now, because later checkValidTyCl
 919                         -- will loop if the synonym is recursive
 920   where
 921     cls_cycles = calcClassCycles tyclss
 922
 923 checkValidTyCl :: TyClDecl Name -> TcM ()
 924 -- We do the validity check over declarations, rather than TyThings
 925 -- only so that we can add a nice context with tcAddDeclCtxt
 926 checkValidTyCl decl
 927   = tcAddDeclCtxt decl $
 928     do  { thing <- tcLookupLocatedGlobal (tcdLName decl)
 929         ; traceTc (text "Validity of" <+> ppr thing)
 930         ; case thing of
 931             ATyCon tc -> checkValidTyCon tc
 932             AClass cl -> checkValidClass cl
 933         ; traceTc (text "Done validity of" <+> ppr thing)
 934         }
 935
 936 -------------------------
 937 -- For data types declared with record syntax, we require
 938 -- that each constructor that has a field 'f'
 939 --      (a) has the same result type
 940 --      (b) has the same type for 'f'
 941 -- module alpha conversion of the quantified type variables
 942 -- of the constructor.
 943
 944 checkValidTyCon :: TyCon -> TcM ()
 945 checkValidTyCon tc
 946   | isSynTyCon tc
 947   = case synTyConRhs tc of
 948       OpenSynTyCon _  -> return ()
 949       SynonymTyCon ty -> checkValidType syn_ctxt ty
 950   | otherwise
 951   =     -- Check the context on the data decl
 952     checkValidTheta (DataTyCtxt name) (tyConStupidTheta tc)     `thenM_`
 953
 954         -- Check arg types of data constructors
 955     mappM_ (checkValidDataCon tc) data_cons                     `thenM_`
 956
 957         -- Check that fields with the same name share a type
 958     mappM_ check_fields groups
 959
 960   where
 961     syn_ctxt  = TySynCtxt name
 962     name      = tyConName tc
 963     data_cons = tyConDataCons tc
 964
 965     groups = equivClasses cmp_fld (concatMap get_fields data_cons)
 966     cmp_fld (f1,_) (f2,_) = f1 `compare` f2
 967     get_fields con = dataConFieldLabels con `zip` repeat con
 968         -- dataConFieldLabels may return the empty list, which is fine
 969
 970     -- See Note [GADT record selectors] in MkId.lhs
 971     -- We must check (a) that the named field has the same
 972     --                   type in each constructor
 973     --               (b) that those constructors have the same result type
 974     --
 975     -- However, the constructors may have differently named type variable
 976     -- and (worse) we don't know how the correspond to each other.  E.g.
 977     --     C1 :: forall a b. { f :: a, g :: b } -> T a b
 978     --     C2 :: forall d c. { f :: c, g :: c } -> T c d
 979     --
 980     -- So what we do is to ust Unify.tcMatchTys to compare the first candidate's
 981     -- result type against other candidates' types BOTH WAYS ROUND.
 982     -- If they magically agrees, take the substitution and
 983     -- apply them to the latter ones, and see if they match perfectly.
 984     check_fields fields@((label, con1) : other_fields)
 985         -- These fields all have the same name, but are from
 986         -- different constructors in the data type
 987         = recoverM (return ()) $ mapM_ checkOne other_fields
 988                 -- Check that all the fields in the group have the same type
 989                 -- NB: this check assumes that all the constructors of a given
 990                 -- data type use the same type variables
 991         where
 992         tvs1 = mkVarSet (dataConAllTyVars con1)
 993         res1 = dataConResTys con1
 994         fty1 = dataConFieldType con1 label
 995
 996         checkOne (_, con2)    -- Do it bothways to ensure they are structurally identical
 997             = do { checkFieldCompat label con1 con2 tvs1 res1 res2 fty1 fty2
 998                  ; checkFieldCompat label con2 con1 tvs2 res2 res1 fty2 fty1 }
 999             where
1000                 tvs2 = mkVarSet (dataConAllTyVars con2)
1001                 res2 = dataConResTys con2
1002                 fty2 = dataConFieldType con2 label
1003
1004 checkFieldCompat fld con1 con2 tvs1 res1 res2 fty1 fty2
1005   = do  { checkTc (isJust mb_subst1) (resultTypeMisMatch fld con1 con2)
1006         ; checkTc (isJust mb_subst2) (fieldTypeMisMatch fld con1 con2) }
1007   where
1008     mb_subst1 = tcMatchTys tvs1 res1 res2
1009     mb_subst2 = tcMatchTyX tvs1 (expectJust "checkFieldCompat" mb_subst1) fty1 fty2
1010
1011 -------------------------------
1012 checkValidDataCon :: TyCon -> DataCon -> TcM ()
1013 checkValidDataCon tc con
1014   = setSrcSpan (srcLocSpan (getSrcLoc con))     $
1015     addErrCtxt (dataConCtxt con)                $
1016     do  { checkTc (dataConTyCon con == tc) (badDataConTyCon con)
1017         ; checkValidType ctxt (dataConUserType con) }
1018   where
1019     ctxt = ConArgCtxt (dataConName con)
1020
1021 -------------------------------
1022 checkValidClass :: Class -> TcM ()
1023 checkValidClass cls
1024   = do  {       -- CHECK ARITY 1 FOR HASKELL 1.4
1025           gla_exts <- doptM Opt_GlasgowExts
1026
1027         -- Check that the class is unary, unless GlaExs
1028         ; checkTc (notNull tyvars) (nullaryClassErr cls)
1029         ; checkTc (gla_exts || unary) (classArityErr cls)
1030
1031         -- Check the super-classes
1032         ; checkValidTheta (ClassSCCtxt (className cls)) theta
1033
1034         -- Check the class operations
1035         ; mappM_ (check_op gla_exts) op_stuff
1036
1037         -- Check that if the class has generic methods, then the
1038         -- class has only one parameter.  We can't do generic
1039         -- multi-parameter type classes!
1040         ; checkTc (unary || no_generics) (genericMultiParamErr cls)
1041         }
1042   where
1043     (tyvars, theta, _, op_stuff) = classBigSig cls
1044     unary       = isSingleton tyvars
1045     no_generics = null [() | (_, GenDefMeth) <- op_stuff]
1046
1047     check_op gla_exts (sel_id, dm)
1048       = addErrCtxt (classOpCtxt sel_id tau) $ do
1049         { checkValidTheta SigmaCtxt (tail theta)
1050                 -- The 'tail' removes the initial (C a) from the
1051                 -- class itself, leaving just the method type
1052
1053         ; checkValidType (FunSigCtxt op_name) tau
1054
1055                 -- Check that the type mentions at least one of
1056                 -- the class type variables
1057         ; checkTc (any (`elemVarSet` tyVarsOfType tau) tyvars)
1058                   (noClassTyVarErr cls sel_id)
1059
1060                 -- Check that for a generic method, the type of
1061                 -- the method is sufficiently simple
1062         ; checkTc (dm /= GenDefMeth || validGenericMethodType tau)
1063                   (badGenericMethodType op_name op_ty)
1064         }
1065         where
1066           op_name = idName sel_id
1067           op_ty   = idType sel_id
1068           (_,theta1,tau1) = tcSplitSigmaTy op_ty
1069           (_,theta2,tau2)  = tcSplitSigmaTy tau1
1070           (theta,tau) | gla_exts  = (theta1 ++ theta2, tau2)
1071                       | otherwise = (theta1,           mkPhiTy (tail theta1) tau1)
1072                 -- Ugh!  The function might have a type like
1073                 --      op :: forall a. C a => forall b. (Eq b, Eq a) => tau2
1074                 -- With -fglasgow-exts, we want to allow this, even though the inner
1075                 -- forall has an (Eq a) constraint.  Whereas in general, each constraint
1076                 -- in the context of a for-all must mention at least one quantified
1077                 -- type variable.  What a mess!
1078
1079
1080 ---------------------------------------------------------------------
1081 resultTypeMisMatch field_name con1 con2
1082   = vcat [sep [ptext SLIT("Constructors") <+> ppr con1 <+> ptext SLIT("and") <+> ppr con2,
1083                 ptext SLIT("have a common field") <+> quotes (ppr field_name) <> comma],
1084           nest 2 $ ptext SLIT("but have different result types")]
1085 fieldTypeMisMatch field_name con1 con2
1086   = sep [ptext SLIT("Constructors") <+> ppr con1 <+> ptext SLIT("and") <+> ppr con2,
1087          ptext SLIT("give different types for field"), quotes (ppr field_name)]
1088
1089 dataConCtxt con = ptext SLIT("In the definition of data constructor") <+> quotes (ppr con)
1090
1091 classOpCtxt sel_id tau = sep [ptext SLIT("When checking the class method:"),
1092                               nest 2 (ppr sel_id <+> dcolon <+> ppr tau)]
1093
1094 nullaryClassErr cls
1095   = ptext SLIT("No parameters for class")  <+> quotes (ppr cls)
1096
1097 classArityErr cls
1098   = vcat [ptext SLIT("Too many parameters for class") <+> quotes (ppr cls),
1099           parens (ptext SLIT("Use -fglasgow-exts to allow multi-parameter classes"))]
1100
1101 noClassTyVarErr clas op
1102   = sep [ptext SLIT("The class method") <+> quotes (ppr op),
1103          ptext SLIT("mentions none of the type variables of the class") <+>
1104                 ppr clas <+> hsep (map ppr (classTyVars clas))]
1105
1106 genericMultiParamErr clas
1107   = ptext SLIT("The multi-parameter class") <+> quotes (ppr clas) <+>
1108     ptext SLIT("cannot have generic methods")
1109
1110 badGenericMethodType op op_ty
1111   = hang (ptext SLIT("Generic method type is too complex"))
1112        4 (vcat [ppr op <+> dcolon <+> ppr op_ty,
1113                 ptext SLIT("You can only use type variables, arrows, lists, and tuples")])
1114
1115 recSynErr syn_decls
1116   = setSrcSpan (getLoc (head sorted_decls)) $
1117     addErr (sep [ptext SLIT("Cycle in type synonym declarations:"),
1118                  nest 2 (vcat (map ppr_decl sorted_decls))])
1119   where
1120     sorted_decls = sortLocated syn_decls
1121     ppr_decl (L loc decl) = ppr loc <> colon <+> ppr decl
1122
1123 recClsErr cls_decls
1124   = setSrcSpan (getLoc (head sorted_decls)) $
1125     addErr (sep [ptext SLIT("Cycle in class declarations (via superclasses):"),
1126                  nest 2 (vcat (map ppr_decl sorted_decls))])
1127   where
1128     sorted_decls = sortLocated cls_decls
1129     ppr_decl (L loc decl) = ppr loc <> colon <+> ppr (decl { tcdSigs = [] })
1130
1131 sortLocated :: [Located a] -> [Located a]
1132 sortLocated things = sortLe le things
1133   where
1134     le (L l1 _) (L l2 _) = l1 <= l2
1135
1136 badDataConTyCon data_con
1137   = hang (ptext SLIT("Data constructor") <+> quotes (ppr data_con) <+>
1138                 ptext SLIT("returns type") <+> quotes (ppr (dataConTyCon data_con)))
1139        2 (ptext SLIT("instead of its parent type"))
1140
1141 badGadtDecl tc_name
1142   = vcat [ ptext SLIT("Illegal generalised algebraic data declaration for") <+> quotes (ppr tc_name)
1143          , nest 2 (parens $ ptext SLIT("Use -fglasgow-exts to allow GADTs")) ]
1144
1145 badStupidTheta tc_name
1146   = ptext SLIT("A data type declared in GADT style cannot have a context:") <+> quotes (ppr tc_name)
1147
1148 newtypeConError tycon n
1149   = sep [ptext SLIT("A newtype must have exactly one constructor,"),
1150          nest 2 $ ptext SLIT("but") <+> quotes (ppr tycon) <+> ptext SLIT("has") <+> speakN n ]
1151
1152 newtypeExError con
1153   = sep [ptext SLIT("A newtype constructor cannot have an existential context,"),
1154          nest 2 $ ptext SLIT("but") <+> quotes (ppr con) <+> ptext SLIT("does")]
1155
1156 newtypeFieldErr con_name n_flds
1157   = sep [ptext SLIT("The constructor of a newtype must have exactly one field"),
1158          nest 2 $ ptext SLIT("but") <+> quotes (ppr con_name) <+> ptext SLIT("has") <+> speakN n_flds]
1159
1160 badSigTyDecl tc_name
1161   = vcat [ ptext SLIT("Illegal kind signature") <+>
1162            quotes (ppr tc_name)
1163          , nest 2 (parens $ ptext SLIT("Use -fglasgow-exts to allow indexed types")) ]
1164
1165 badKindSigCtxt tc_name
1166   = vcat [ ptext SLIT("Illegal context in kind signature") <+>
1167            quotes (ppr tc_name)
1168          , nest 2 (parens $ ptext SLIT("Currently, kind signatures cannot have a context")) ]
1169
1170 badIdxTyDecl tc_name
1171   = vcat [ ptext SLIT("Illegal indexed type instance for") <+>
1172            quotes (ppr tc_name)
1173          , nest 2 (parens $ ptext SLIT("Use -fglasgow-exts to allow indexed types")) ]
1174
1175 badGadtIdxTyDecl tc_name
1176   = vcat [ ptext SLIT("Illegal generalised algebraic data declaration for") <+>
1177            quotes (ppr tc_name)
1178          , nest 2 (parens $ ptext SLIT("Indexed types cannot use GADT declarations")) ]
1179
1180 tooManyParmsErr tc_name
1181   = ptext SLIT("Indexed type instance has too many parameters:") <+>
1182     quotes (ppr tc_name)
1183
1184 tooFewParmsErr tc_name
1185   = ptext SLIT("Indexed type instance has too few parameters:") <+>
1186     quotes (ppr tc_name)
1187
1188 badBootTyIdxDeclErr =
1189   ptext SLIT("Illegal indexed type instance in hs-boot file")
1190
1191 wrongKindOfFamily family =
1192   ptext SLIT("Wrong category of type instance; declaration was for a") <+>
1193   kindOfFamily
1194   where
1195     kindOfFamily | isSynTyCon  family = ptext SLIT("type synonym")
1196                  | isDataTyCon family = ptext SLIT("data type")
1197                  | isNewTyCon  family = ptext SLIT("newtype")
1198
1199 emptyConDeclsErr tycon
1200   = sep [quotes (ppr tycon) <+> ptext SLIT("has no constructors"),
1201          nest 2 $ ptext SLIT("(-fglasgow-exts permits this)")]
1202 \end{code}