compiler/typecheck/TcTyClsDecls.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The AQUA Project, Glasgow University, 1996-1998
   4 %
   5
   6 TcTyClsDecls: Typecheck type and class declarations
   7
   8 \begin{code}
   9 module TcTyClsDecls (
  10         tcTyAndClassDecls, tcFamInstDecl
  11     ) where
  12
  13 #include "HsVersions.h"
  14
  15 import HsSyn
  16 import HsTypes
  17 import BasicTypes
  18 import HscTypes
  19 import BuildTyCl
  20 import TcUnify
  21 import TcRnMonad
  22 import TcEnv
  23 import TcTyDecls
  24 import TcClassDcl
  25 import TcHsType
  26 import TcMType
  27 import TcType
  28 import FunDeps
  29 import Type
  30 import Generics
  31 import Class
  32 import TyCon
  33 import DataCon
  34 import Var
  35 import VarSet
  36 import Name
  37 import OccName
  38 import Outputable
  39 import Maybes
  40 import Monad
  41 import Unify
  42 import Util
  43 import SrcLoc
  44 import ListSetOps
  45 import Digraph
  46 import DynFlags
  47
  48 import Data.List
  49 import Control.Monad    ( mplus )
  50 \end{code}
  51
  52
  53 %************************************************************************
  54 %*                                                                      *
  55 \subsection{Type checking for type and class declarations}
  56 %*                                                                      *
  57 %************************************************************************
  58
  59 Dealing with a group
  60 ~~~~~~~~~~~~~~~~~~~~
  61 Consider a mutually-recursive group, binding
  62 a type constructor T and a class C.
  63
  64 Step 1:         getInitialKind
  65         Construct a KindEnv by binding T and C to a kind variable
  66
  67 Step 2:         kcTyClDecl
  68         In that environment, do a kind check
  69
  70 Step 3: Zonk the kinds
  71
  72 Step 4:         buildTyConOrClass
  73         Construct an environment binding T to a TyCon and C to a Class.
  74         a) Their kinds comes from zonking the relevant kind variable
  75         b) Their arity (for synonyms) comes direct from the decl
  76         c) The funcional dependencies come from the decl
  77         d) The rest comes a knot-tied binding of T and C, returned from Step 4
  78         e) The variances of the tycons in the group is calculated from
  79                 the knot-tied stuff
  80
  81 Step 5:         tcTyClDecl1
  82         In this environment, walk over the decls, constructing the TyCons and Classes.
  83         This uses in a strict way items (a)-(c) above, which is why they must
  84         be constructed in Step 4. Feed the results back to Step 4.
  85         For this step, pass the is-recursive flag as the wimp-out flag
  86         to tcTyClDecl1.
  87
  88
  89 Step 6:         Extend environment
  90         We extend the type environment with bindings not only for the TyCons and Classes,
  91         but also for their "implicit Ids" like data constructors and class selectors
  92
  93 Step 7:         checkValidTyCl
  94         For a recursive group only, check all the decls again, just
  95         to check all the side conditions on validity.  We could not
  96         do this before because we were in a mutually recursive knot.
  97
  98 Identification of recursive TyCons
  99 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 100 The knot-tying parameters: @rec_details_list@ is an alist mapping @Name@s to
 101 @TyThing@s.
 102
 103 Identifying a TyCon as recursive serves two purposes
 104
 105 1.  Avoid infinite types.  Non-recursive newtypes are treated as
 106 "transparent", like type synonyms, after the type checker.  If we did
 107 this for all newtypes, we'd get infinite types.  So we figure out for
 108 each newtype whether it is "recursive", and add a coercion if so.  In
 109 effect, we are trying to "cut the loops" by identifying a loop-breaker.
 110
 111 2.  Avoid infinite unboxing.  This is nothing to do with newtypes.
 112 Suppose we have
 113         data T = MkT Int T
 114         f (MkT x t) = f t
 115 Well, this function diverges, but we don't want the strictness analyser
 116 to diverge.  But the strictness analyser will diverge because it looks
 117 deeper and deeper into the structure of T.   (I believe there are
 118 examples where the function does something sane, and the strictness
 119 analyser still diverges, but I can't see one now.)
 120
 121 Now, concerning (1), the FC2 branch currently adds a coercion for ALL
 122 newtypes.  I did this as an experiment, to try to expose cases in which
 123 the coercions got in the way of optimisations.  If it turns out that we
 124 can indeed always use a coercion, then we don't risk recursive types,
 125 and don't need to figure out what the loop breakers are.
 126
 127 For newtype *families* though, we will always have a coercion, so they
 128 are always loop breakers!  So you can easily adjust the current
 129 algorithm by simply treating all newtype families as loop breakers (and
 130 indeed type families).  I think.
 131
 132 \begin{code}
 133 tcTyAndClassDecls :: ModDetails -> [LTyClDecl Name]
 134                    -> TcM TcGblEnv      -- Input env extended by types and classes
 135                                         -- and their implicit Ids,DataCons
 136 tcTyAndClassDecls boot_details allDecls
 137   = do  {       -- Omit instances of type families; they are handled together
 138                 -- with the *heads* of class instances
 139         ; let decls = filter (not . isFamInstDecl . unLoc) allDecls
 140
 141                 -- First check for cyclic type synonysm or classes
 142                 -- See notes with checkCycleErrs
 143         ; checkCycleErrs decls
 144         ; mod <- getModule
 145         ; traceTc (text "tcTyAndCl" <+> ppr mod)
 146         ; (syn_tycons, alg_tyclss) <- fixM (\ ~(rec_syn_tycons, rec_alg_tyclss) ->
 147           do    { let { -- Seperate ordinary synonyms from all other type and
 148                         -- class declarations and add all associated type
 149                         -- declarations from type classes.  The latter is
 150                         -- required so that the temporary environment for the
 151                         -- knot includes all associated family declarations.
 152                       ; (syn_decls, alg_decls) = partition (isSynDecl . unLoc)
 153                                                    decls
 154                       ; alg_at_decls           = concatMap addATs alg_decls
 155                       }
 156                         -- Extend the global env with the knot-tied results
 157                         -- for data types and classes
 158                         --
 159                         -- We must populate the environment with the loop-tied
 160                         -- T's right away, because the kind checker may "fault
 161                         -- in" some type  constructors that recursively
 162                         -- mention T
 163                 ; let gbl_things = mkGlobalThings alg_at_decls rec_alg_tyclss
 164                 ; tcExtendRecEnv gbl_things $ do
 165
 166                         -- Kind-check the declarations
 167                 { (kc_syn_decls, kc_alg_decls) <- kcTyClDecls syn_decls alg_decls
 168
 169                 ; let { -- Calculate rec-flag
 170                       ; calc_rec  = calcRecFlags boot_details rec_alg_tyclss
 171                       ; tc_decl   = addLocM (tcTyClDecl calc_rec) }
 172
 173                         -- Type-check the type synonyms, and extend the envt
 174                 ; syn_tycons <- tcSynDecls kc_syn_decls
 175                 ; tcExtendGlobalEnv syn_tycons $ do
 176
 177                         -- Type-check the data types and classes
 178                 { alg_tyclss <- mappM tc_decl kc_alg_decls
 179                 ; return (syn_tycons, concat alg_tyclss)
 180             }}})
 181         -- Finished with knot-tying now
 182         -- Extend the environment with the finished things
 183         ; tcExtendGlobalEnv (syn_tycons ++ alg_tyclss) $ do
 184
 185         -- Perform the validity check
 186         { traceTc (text "ready for validity check")
 187         ; mappM_ (addLocM checkValidTyCl) decls
 188         ; traceTc (text "done")
 189
 190         -- Add the implicit things;
 191         -- we want them in the environment because
 192         -- they may be mentioned in interface files
 193         -- NB: All associated types and their implicit things will be added a
 194         --     second time here.  This doesn't matter as the definitions are
 195         --     the same.
 196         ; let { implicit_things = concatMap implicitTyThings alg_tyclss }
 197         ; traceTc ((text "Adding" <+> ppr alg_tyclss)
 198                    $$ (text "and" <+> ppr implicit_things))
 199         ; tcExtendGlobalEnv implicit_things getGblEnv
 200     }}
 201   where
 202     -- Pull associated types out of class declarations, to tie them into the
 203     -- knot above.
 204     -- NB: We put them in the same place in the list as `tcTyClDecl' will
 205     --     eventually put the matching `TyThing's.  That's crucial; otherwise,
 206     --     the two argument lists of `mkGlobalThings' don't match up.
 207     addATs decl@(L _ (ClassDecl {tcdATs = ats})) = decl : ats
 208     addATs decl                                  = [decl]
 209
 210 mkGlobalThings :: [LTyClDecl Name]      -- The decls
 211                -> [TyThing]             -- Knot-tied, in 1-1 correspondence with the decls
 212                -> [(Name,TyThing)]
 213 -- Driven by the Decls, and treating the TyThings lazily
 214 -- make a TypeEnv for the new things
 215 mkGlobalThings decls things
 216   = map mk_thing (decls `zipLazy` things)
 217   where
 218     mk_thing (L _ (ClassDecl {tcdLName = L _ name}), ~(AClass cl))
 219          = (name, AClass cl)
 220     mk_thing (L _ decl, ~(ATyCon tc))
 221          = (tcdName decl, ATyCon tc)
 222 \end{code}
 223
 224
 225 %************************************************************************
 226 %*                                                                      *
 227 \subsection{Type checking family instances}
 228 %*                                                                      *
 229 %************************************************************************
 230
 231 Family instances are somewhat of a hybrid.  They are processed together with
 232 class instance heads, but can contain data constructors and hence they share a
 233 lot of kinding and type checking code with ordinary algebraic data types (and
 234 GADTs).
 235
 236 \begin{code}
 237 tcFamInstDecl :: LTyClDecl Name -> TcM (Maybe TyThing)   -- Nothing if error
 238 tcFamInstDecl (L loc decl)
 239   =     -- Prime error recovery, set source location
 240     recoverM (returnM Nothing)                  $
 241     setSrcSpan loc                              $
 242     tcAddDeclCtxt decl                          $
 243     do { -- type families require -ftype-families and can't be in an
 244          -- hs-boot file
 245        ; type_families <- doptM Opt_TypeFamilies
 246        ; is_boot  <- tcIsHsBoot   -- Are we compiling an hs-boot file?
 247        ; checkTc type_families $ badFamInstDecl (tcdLName decl)
 248        ; checkTc (not is_boot) $ badBootFamInstDeclErr
 249
 250          -- perform kind and type checking
 251        ; tcFamInstDecl1 decl
 252        }
 253
 254 tcFamInstDecl1 :: TyClDecl Name -> TcM (Maybe TyThing)   -- Nothing if error
 255
 256   -- "type instance"
 257 tcFamInstDecl1 (decl@TySynonym {tcdLName = L loc tc_name})
 258   = kcIdxTyPats decl $ \k_tvs k_typats resKind family ->
 259     do { -- check that the family declaration is for a synonym
 260          unless (isSynTyCon family) $
 261            addErr (wrongKindOfFamily family)
 262
 263        ; -- (1) kind check the right-hand side of the type equation
 264        ; k_rhs <- kcCheckHsType (tcdSynRhs decl) resKind
 265
 266          -- (2) type check type equation
 267        ; tcTyVarBndrs k_tvs $ \t_tvs -> do {  -- turn kinded into proper tyvars
 268        ; t_typats <- mappM tcHsKindedType k_typats
 269        ; t_rhs    <- tcHsKindedType k_rhs
 270
 271          -- (3) check that
 272          --     - left-hand side contains no type family applications
 273          --       (vanilla synonyms are fine, though)
 274        ; mappM_ checkTyFamFreeness t_typats
 275
 276          --     - the right-hand side is a tau type
 277        ; unless (isTauTy t_rhs) $
 278            addErr (polyTyErr t_rhs)
 279
 280          -- (4) construct representation tycon
 281        ; rep_tc_name <- newFamInstTyConName tc_name loc
 282        ; tycon <- buildSynTyCon rep_tc_name t_tvs (SynonymTyCon t_rhs)
 283                                 (Just (family, t_typats))
 284
 285        ; return $ Just (ATyCon tycon)
 286        }}
 287
 288   -- "newtype instance" and "data instance"
 289 tcFamInstDecl1 (decl@TyData {tcdND = new_or_data, tcdLName = L loc tc_name,
 290                              tcdCons = cons})
 291   = kcIdxTyPats decl $ \k_tvs k_typats resKind family ->
 292     do { -- check that the family declaration is for the right kind
 293          unless (isAlgTyCon family) $
 294            addErr (wrongKindOfFamily family)
 295
 296        ; -- (1) kind check the data declaration as usual
 297        ; k_decl <- kcDataDecl decl k_tvs
 298        ; let k_ctxt = tcdCtxt k_decl
 299              k_cons = tcdCons k_decl
 300
 301          -- result kind must be '*' (otherwise, we have too few patterns)
 302        ; checkTc (isLiftedTypeKind resKind) $ tooFewParmsErr tc_name
 303
 304          -- (2) type check indexed data type declaration
 305        ; tcTyVarBndrs k_tvs $ \t_tvs -> do {  -- turn kinded into proper tyvars
 306        ; unbox_strict <- doptM Opt_UnboxStrictFields
 307
 308          -- kind check the type indexes and the context
 309        ; t_typats     <- mappM tcHsKindedType k_typats
 310        ; stupid_theta <- tcHsKindedContext k_ctxt
 311
 312          -- (3) Check that
 313          --     - left-hand side contains no type family applications
 314          --       (vanilla synonyms are fine, though)
 315        ; mappM_ checkTyFamFreeness t_typats
 316
 317          --     - we don't use GADT syntax for indexed types
 318        ; checkTc h98_syntax (badGadtIdxTyDecl tc_name)
 319
 320          --     - a newtype has exactly one constructor
 321        ; checkTc (new_or_data == DataType || isSingleton k_cons) $
 322            newtypeConError tc_name (length k_cons)
 323
 324          -- (4) construct representation tycon
 325        ; rep_tc_name <- newFamInstTyConName tc_name loc
 326        ; tycon <- fixM (\ tycon -> do
 327              { data_cons <- mappM (addLocM (tcConDecl unbox_strict tycon t_tvs))
 328                                   k_cons
 329              ; tc_rhs <-
 330                  case new_or_data of
 331                    DataType -> return (mkDataTyConRhs data_cons)
 332                    NewType  -> ASSERT( isSingleton data_cons )
 333                                mkNewTyConRhs rep_tc_name tycon (head data_cons)
 334              ; buildAlgTyCon rep_tc_name t_tvs stupid_theta tc_rhs Recursive
 335                              False h98_syntax (Just (family, t_typats))
 336                  -- We always assume that indexed types are recursive.  Why?
 337                  -- (1) Due to their open nature, we can never be sure that a
 338                  -- further instance might not introduce a new recursive
 339                  -- dependency.  (2) They are always valid loop breakers as
 340                  -- they involve a coercion.
 341              })
 342
 343          -- construct result
 344        ; return $ Just (ATyCon tycon)
 345        }}
 346        where
 347          h98_syntax = case cons of      -- All constructors have same shape
 348                         L _ (ConDecl { con_res = ResTyGADT _ }) : _ -> False
 349                         other -> True
 350
 351 -- Check that a type index does not contain any type family applications
 352 --
 353 -- * Earlier phases have already checked that there are no foralls in the
 354 --   type; we also cannot have PredTys and NoteTys are being skipped by using
 355 --   the core view.
 356 --
 357 checkTyFamFreeness :: Type -> TcM ()
 358 checkTyFamFreeness ty | Just (tycon, tys) <- splitTyConApp_maybe ty
 359                       = if isSynTyCon tycon
 360                         then addErr $ tyFamAppInIndexErr ty
 361                         else mappM_ checkTyFamFreeness tys
 362                           -- splitTyConApp_maybe uses the core view; hence,
 363                           -- any synonym tycon must be a family tycon
 364
 365                       | Just (ty1, ty2) <- splitAppTy_maybe ty
 366                       = checkTyFamFreeness ty1 >> checkTyFamFreeness ty2
 367
 368                       | otherwise          -- only vars remaining
 369                       = return ()
 370
 371
 372 -- Kind checking of indexed types
 373 -- -
 374
 375 -- Kind check type patterns and kind annotate the embedded type variables.
 376 --
 377 -- * Here we check that a type instance matches its kind signature, but we do
 378 --   not check whether there is a pattern for each type index; the latter
 379 --   check is only required for type synonym instances.
 380 --
 381 kcIdxTyPats :: TyClDecl Name
 382             -> ([LHsTyVarBndr Name] -> [LHsType Name] -> Kind -> TyCon -> TcM a)
 383                -- ^^kinded tvs         ^^kinded ty pats  ^^res kind
 384             -> TcM a
 385 kcIdxTyPats decl thing_inside
 386   = kcHsTyVars (tcdTyVars decl) $ \tvs ->
 387     do { family <- tcLookupLocatedTyCon (tcdLName decl)
 388        ; let { (kinds, resKind) = splitKindFunTys (tyConKind family)
 389              ; hs_typats        = fromJust $ tcdTyPats decl }
 390
 391          -- we may not have more parameters than the kind indicates
 392        ; checkTc (length kinds >= length hs_typats) $
 393            tooManyParmsErr (tcdLName decl)
 394
 395          -- type functions can have a higher-kinded result
 396        ; let resultKind = mkArrowKinds (drop (length hs_typats) kinds) resKind
 397        ; typats <- TcRnMonad.zipWithM kcCheckHsType hs_typats kinds
 398        ; thing_inside tvs typats resultKind family
 399        }
 400   where
 401 \end{code}
 402
 403
 404 %************************************************************************
 405 %*                                                                      *
 406                 Kind checking
 407 %*                                                                      *
 408 %************************************************************************
 409
 410 We need to kind check all types in the mutually recursive group
 411 before we know the kind of the type variables.  For example:
 412
 413 class C a where
 414    op :: D b => a -> b -> b
 415
 416 class D c where
 417    bop :: (Monad c) => ...
 418
 419 Here, the kind of the locally-polymorphic type variable "b"
 420 depends on *all the uses of class D*.  For example, the use of
 421 Monad c in bop's type signature means that D must have kind Type->Type.
 422
 423 However type synonyms work differently.  They can have kinds which don't
 424 just involve (->) and *:
 425         type R = Int#           -- Kind #
 426         type S a = Array# a     -- Kind * -> #
 427         type T a b = (# a,b #)  -- Kind * -> * -> (# a,b #)
 428 So we must infer their kinds from their right-hand sides *first* and then
 429 use them, whereas for the mutually recursive data types D we bring into
 430 scope kind bindings D -> k, where k is a kind variable, and do inference.
 431
 432 Type families
 433 ~~~~~~~~~~~~~
 434 This treatment of type synonyms only applies to Haskell 98-style synonyms.
 435 General type functions can be recursive, and hence, appear in `alg_decls'.
 436
 437 The kind of a type family is solely determinded by its kind signature;
 438 hence, only kind signatures participate in the construction of the initial
 439 kind environment (as constructed by `getInitialKind').  In fact, we ignore
 440 instances of families altogether in the following.  However, we need to
 441 include the kinds of associated families into the construction of the
 442 initial kind environment.  (This is handled by `allDecls').
 443
 444 \begin{code}
 445 kcTyClDecls syn_decls alg_decls
 446   = do  {       -- First extend the kind env with each data type, class, and
 447                 -- indexed type, mapping them to a type variable
 448           let initialKindDecls = concat [allDecls decl | L _ decl <- alg_decls]
 449         ; alg_kinds <- mappM getInitialKind initialKindDecls
 450         ; tcExtendKindEnv alg_kinds $ do
 451
 452                 -- Now kind-check the type synonyms, in dependency order
 453                 -- We do these differently to data type and classes,
 454                 -- because a type synonym can be an unboxed type
 455                 --      type Foo = Int#
 456                 -- and a kind variable can't unify with UnboxedTypeKind
 457                 -- So we infer their kinds in dependency order
 458         { (kc_syn_decls, syn_kinds) <- kcSynDecls (calcSynCycles syn_decls)
 459         ; tcExtendKindEnv syn_kinds $  do
 460
 461                 -- Now kind-check the data type, class, and kind signatures,
 462                 -- returning kind-annotated decls; we don't kind-check
 463                 -- instances of indexed types yet, but leave this to
 464                 -- `tcInstDecls1'
 465         { kc_alg_decls <- mappM (wrapLocM kcTyClDecl)
 466                             (filter (not . isFamInstDecl . unLoc) alg_decls)
 467
 468         ; return (kc_syn_decls, kc_alg_decls) }}}
 469   where
 470     -- get all declarations relevant for determining the initial kind
 471     -- environment
 472     allDecls (decl@ClassDecl {tcdATs = ats}) = decl : [ at
 473                                                       | L _ at <- ats
 474                                                       , isFamilyDecl at]
 475     allDecls decl | isFamInstDecl decl = []
 476                   | otherwise          = [decl]
 477
 478 ------------------------------------------------------------------------
 479 getInitialKind :: TyClDecl Name -> TcM (Name, TcKind)
 480 -- Only for data type, class, and indexed type declarations
 481 -- Get as much info as possible from the data, class, or indexed type decl,
 482 -- so as to maximise usefulness of error messages
 483 getInitialKind decl
 484   = do  { arg_kinds <- mapM (mk_arg_kind . unLoc) (tyClDeclTyVars decl)
 485         ; res_kind  <- mk_res_kind decl
 486         ; return (tcdName decl, mkArrowKinds arg_kinds res_kind) }
 487   where
 488     mk_arg_kind (UserTyVar _)        = newKindVar
 489     mk_arg_kind (KindedTyVar _ kind) = return kind
 490
 491     mk_res_kind (TyFamily { tcdKind    = Just kind }) = return kind
 492     mk_res_kind (TyData   { tcdKindSig = Just kind }) = return kind
 493         -- On GADT-style declarations we allow a kind signature
 494         --      data T :: *->* where { ... }
 495     mk_res_kind other = return liftedTypeKind
 496
 497
 498 ----------------
 499 kcSynDecls :: [SCC (LTyClDecl Name)]
 500            -> TcM ([LTyClDecl Name],    -- Kind-annotated decls
 501                    [(Name,TcKind)])     -- Kind bindings
 502 kcSynDecls []
 503   = return ([], [])
 504 kcSynDecls (group : groups)
 505   = do  { (decl,  nk)  <- kcSynDecl group
 506         ; (decls, nks) <- tcExtendKindEnv [nk] (kcSynDecls groups)
 507         ; return (decl:decls, nk:nks) }
 508
 509 ----------------
 510 kcSynDecl :: SCC (LTyClDecl Name)
 511            -> TcM (LTyClDecl Name,      -- Kind-annotated decls
 512                    (Name,TcKind))       -- Kind bindings
 513 kcSynDecl (AcyclicSCC ldecl@(L loc decl))
 514   = tcAddDeclCtxt decl  $
 515     kcHsTyVars (tcdTyVars decl) (\ k_tvs ->
 516     do { traceTc (text "kcd1" <+> ppr (unLoc (tcdLName decl)) <+> brackets (ppr (tcdTyVars decl))
 517                         <+> brackets (ppr k_tvs))
 518        ; (k_rhs, rhs_kind) <- kcHsType (tcdSynRhs decl)
 519        ; traceTc (text "kcd2" <+> ppr (unLoc (tcdLName decl)))
 520        ; let tc_kind = foldr (mkArrowKind . kindedTyVarKind) rhs_kind k_tvs
 521        ; return (L loc (decl { tcdTyVars = k_tvs, tcdSynRhs = k_rhs }),
 522                  (unLoc (tcdLName decl), tc_kind)) })
 523
 524 kcSynDecl (CyclicSCC decls)
 525   = do { recSynErr decls; failM }       -- Fail here to avoid error cascade
 526                                         -- of out-of-scope tycons
 527
 528 kindedTyVarKind (L _ (KindedTyVar _ k)) = k
 529
 530 ------------------------------------------------------------------------
 531 kcTyClDecl :: TyClDecl Name -> TcM (TyClDecl Name)
 532         -- Not used for type synonyms (see kcSynDecl)
 533
 534 kcTyClDecl decl@(TyData {})
 535   = ASSERT( not . isFamInstDecl $ decl )   -- must not be a family instance
 536     kcTyClDeclBody decl $
 537       kcDataDecl decl
 538
 539 kcTyClDecl decl@(TyFamily {})
 540   = kcFamilyDecl [] decl      -- the empty list signals a toplevel decl
 541
 542 kcTyClDecl decl@(ClassDecl {tcdCtxt = ctxt, tcdSigs = sigs, tcdATs = ats})
 543   = kcTyClDeclBody decl $ \ tvs' ->
 544     do  { is_boot <- tcIsHsBoot
 545         ; ctxt' <- kcHsContext ctxt
 546         ; ats'  <- mappM (wrapLocM (kcFamilyDecl tvs')) ats
 547         ; sigs' <- mappM (wrapLocM kc_sig) sigs
 548         ; return (decl {tcdTyVars = tvs', tcdCtxt = ctxt', tcdSigs = sigs',
 549                         tcdATs = ats'}) }
 550   where
 551     kc_sig (TypeSig nm op_ty) = do { op_ty' <- kcHsLiftedSigType op_ty
 552                                    ; return (TypeSig nm op_ty') }
 553     kc_sig other_sig          = return other_sig
 554
 555 kcTyClDecl decl@(ForeignType {})
 556   = return decl
 557
 558 kcTyClDeclBody :: TyClDecl Name
 559                -> ([LHsTyVarBndr Name] -> TcM a)
 560                -> TcM a
 561 -- getInitialKind has made a suitably-shaped kind for the type or class
 562 -- Unpack it, and attribute those kinds to the type variables
 563 -- Extend the env with bindings for the tyvars, taken from
 564 -- the kind of the tycon/class.  Give it to the thing inside, and
 565 -- check the result kind matches
 566 kcTyClDeclBody decl thing_inside
 567   = tcAddDeclCtxt decl          $
 568     do  { tc_ty_thing <- tcLookupLocated (tcdLName decl)
 569         ; let tc_kind    = case tc_ty_thing of { AThing k -> k }
 570               (kinds, _) = splitKindFunTys tc_kind
 571               hs_tvs     = tcdTyVars decl
 572               kinded_tvs = ASSERT( length kinds >= length hs_tvs )
 573                            [ L loc (KindedTyVar (hsTyVarName tv) k)
 574                            | (L loc tv, k) <- zip hs_tvs kinds]
 575         ; tcExtendKindEnvTvs kinded_tvs (thing_inside kinded_tvs) }
 576
 577 -- Kind check a data declaration, assuming that we already extended the
 578 -- kind environment with the type variables of the left-hand side (these
 579 -- kinded type variables are also passed as the second parameter).
 580 --
 581 kcDataDecl :: TyClDecl Name -> [LHsTyVarBndr Name] -> TcM (TyClDecl Name)
 582 kcDataDecl decl@(TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdCons = cons})
 583            tvs
 584   = do  { ctxt' <- kcHsContext ctxt
 585         ; cons' <- mappM (wrapLocM kc_con_decl) cons
 586         ; return (decl {tcdTyVars = tvs, tcdCtxt = ctxt', tcdCons = cons'}) }
 587   where
 588     -- doc comments are typechecked to Nothing here
 589     kc_con_decl (ConDecl name expl ex_tvs ex_ctxt details res _) = do
 590       kcHsTyVars ex_tvs $ \ex_tvs' -> do
 591         ex_ctxt' <- kcHsContext ex_ctxt
 592         details' <- kc_con_details details
 593         res'     <- case res of
 594           ResTyH98 -> return ResTyH98
 595           ResTyGADT ty -> do { ty' <- kcHsSigType ty; return (ResTyGADT ty') }
 596         return (ConDecl name expl ex_tvs' ex_ctxt' details' res' Nothing)
 597
 598     kc_con_details (PrefixCon btys)
 599         = do { btys' <- mappM kc_larg_ty btys
 600              ; return (PrefixCon btys') }
 601     kc_con_details (InfixCon bty1 bty2)
 602         = do { bty1' <- kc_larg_ty bty1
 603              ; bty2' <- kc_larg_ty bty2
 604              ; return (InfixCon bty1' bty2') }
 605     kc_con_details (RecCon fields)
 606         = do { fields' <- mappM kc_field fields
 607              ; return (RecCon fields') }
 608
 609     kc_field (ConDeclField fld bty d) = do { bty' <- kc_larg_ty bty
 610                                            ; return (ConDeclField fld bty' d) }
 611
 612     kc_larg_ty bty = case new_or_data of
 613                         DataType -> kcHsSigType bty
 614                         NewType  -> kcHsLiftedSigType bty
 615         -- Can't allow an unlifted type for newtypes, because we're effectively
 616         -- going to remove the constructor while coercing it to a lifted type.
 617         -- And newtypes can't be bang'd
 618
 619 -- Kind check a family declaration or type family default declaration.
 620 --
 621 kcFamilyDecl :: [LHsTyVarBndr Name]  -- tyvars of enclosing class decl if any
 622              -> TyClDecl Name -> TcM (TyClDecl Name)
 623 kcFamilyDecl classTvs decl@(TyFamily {tcdKind = kind})
 624   = kcTyClDeclBody decl $ \tvs' ->
 625     do { mapM_ unifyClassParmKinds tvs'
 626        ; return (decl {tcdTyVars = tvs',
 627                        tcdKind = kind `mplus` Just liftedTypeKind})
 628                        -- default result kind is '*'
 629        }
 630   where
 631     unifyClassParmKinds (L _ (KindedTyVar n k))
 632       | Just classParmKind <- lookup n classTyKinds = unifyKind k classParmKind
 633       | otherwise                                   = return ()
 634     classTyKinds = [(n, k) | L _ (KindedTyVar n k) <- classTvs]
 635 kcFamilyDecl _ decl@(TySynonym {})              -- type family defaults
 636   = panic "TcTyClsDecls.kcFamilyDecl: not implemented yet"
 637 \end{code}
 638
 639
 640 %************************************************************************
 641 %*                                                                      *
 642 \subsection{Type checking}
 643 %*                                                                      *
 644 %************************************************************************
 645
 646 \begin{code}
 647 tcSynDecls :: [LTyClDecl Name] -> TcM [TyThing]
 648 tcSynDecls [] = return []
 649 tcSynDecls (decl : decls)
 650   = do { syn_tc <- addLocM tcSynDecl decl
 651        ; syn_tcs <- tcExtendGlobalEnv [syn_tc] (tcSynDecls decls)
 652        ; return (syn_tc : syn_tcs) }
 653
 654   -- "type"
 655 tcSynDecl
 656   (TySynonym {tcdLName = L _ tc_name, tcdTyVars = tvs, tcdSynRhs = rhs_ty})
 657   = tcTyVarBndrs tvs            $ \ tvs' -> do
 658     { traceTc (text "tcd1" <+> ppr tc_name)
 659     ; rhs_ty' <- tcHsKindedType rhs_ty
 660     ; tycon <- buildSynTyCon tc_name tvs' (SynonymTyCon rhs_ty') Nothing
 661     ; return (ATyCon tycon)
 662     }
 663
 664 --------------------
 665 tcTyClDecl :: (Name -> RecFlag) -> TyClDecl Name -> TcM [TyThing]
 666
 667 tcTyClDecl calc_isrec decl
 668   = tcAddDeclCtxt decl (tcTyClDecl1 calc_isrec decl)
 669
 670   -- "type family" declarations
 671 tcTyClDecl1 _calc_isrec
 672   (TyFamily {tcdFlavour = TypeFamily,
 673              tcdLName = L _ tc_name, tcdTyVars = tvs, tcdKind = Just kind})
 674                                                       -- NB: kind at latest
 675                                                       --     added during
 676                                                       --     kind checking
 677   = tcTyVarBndrs tvs  $ \ tvs' -> do
 678   { traceTc (text "type family: " <+> ppr tc_name)
 679   ; idx_tys <- doptM Opt_TypeFamilies
 680
 681         -- Check that we don't use families without -ftype-families
 682   ; checkTc idx_tys $ badFamInstDecl tc_name
 683
 684   ; tycon <- buildSynTyCon tc_name tvs' (OpenSynTyCon kind Nothing) Nothing
 685   ; return [ATyCon tycon]
 686   }
 687
 688   -- "newtype family" or "data family" declaration
 689 tcTyClDecl1 _calc_isrec
 690   (TyFamily {tcdFlavour = DataFamily,
 691              tcdLName = L _ tc_name, tcdTyVars = tvs, tcdKind = mb_kind})
 692   = tcTyVarBndrs tvs  $ \ tvs' -> do
 693   { traceTc (text "data family: " <+> ppr tc_name)
 694   ; extra_tvs <- tcDataKindSig mb_kind
 695   ; let final_tvs = tvs' ++ extra_tvs    -- we may not need these
 696
 697   ; idx_tys <- doptM Opt_TypeFamilies
 698
 699         -- Check that we don't use families without -ftype-families
 700   ; checkTc idx_tys $ badFamInstDecl tc_name
 701
 702   ; tycon <- buildAlgTyCon tc_name final_tvs []
 703                mkOpenDataTyConRhs Recursive False True Nothing
 704   ; return [ATyCon tycon]
 705   }
 706
 707   -- "newtype" and "data"
 708 tcTyClDecl1 calc_isrec
 709   (TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdTyVars = tvs,
 710            tcdLName = L _ tc_name, tcdKindSig = mb_ksig, tcdCons = cons})
 711   = tcTyVarBndrs tvs    $ \ tvs' -> do
 712   { extra_tvs <- tcDataKindSig mb_ksig
 713   ; let final_tvs = tvs' ++ extra_tvs
 714   ; stupid_theta <- tcHsKindedContext ctxt
 715   ; want_generic <- doptM Opt_Generics
 716   ; unbox_strict <- doptM Opt_UnboxStrictFields
 717   ; empty_data_decls <- doptM Opt_EmptyDataDecls
 718   ; kind_signatures <- doptM Opt_KindSignatures
 719   ; gadt_ok      <- doptM Opt_GADTs
 720   ; is_boot      <- tcIsHsBoot  -- Are we compiling an hs-boot file?
 721
 722         -- Check that we don't use GADT syntax in H98 world
 723   ; checkTc (gadt_ok || h98_syntax) (badGadtDecl tc_name)
 724
 725         -- Check that we don't use kind signatures without Glasgow extensions
 726   ; checkTc (kind_signatures || isNothing mb_ksig) (badSigTyDecl tc_name)
 727
 728         -- Check that the stupid theta is empty for a GADT-style declaration
 729   ; checkTc (null stupid_theta || h98_syntax) (badStupidTheta tc_name)
 730
 731         -- Check that there's at least one condecl,
 732         -- or else we're reading an hs-boot file, or -XEmptyDataDecls
 733   ; checkTc (not (null cons) || empty_data_decls || is_boot)
 734             (emptyConDeclsErr tc_name)
 735
 736         -- Check that a newtype has exactly one constructor
 737   ; checkTc (new_or_data == DataType || isSingleton cons)
 738             (newtypeConError tc_name (length cons))
 739
 740   ; tycon <- fixM (\ tycon -> do
 741         { data_cons <- mappM (addLocM (tcConDecl unbox_strict tycon final_tvs))
 742                              cons
 743         ; tc_rhs <-
 744             if null cons && is_boot     -- In a hs-boot file, empty cons means
 745             then return AbstractTyCon   -- "don't know"; hence Abstract
 746             else case new_or_data of
 747                    DataType -> return (mkDataTyConRhs data_cons)
 748                    NewType  ->
 749                        ASSERT( isSingleton data_cons )
 750                        mkNewTyConRhs tc_name tycon (head data_cons)
 751         ; buildAlgTyCon tc_name final_tvs stupid_theta tc_rhs is_rec
 752             (want_generic && canDoGenerics data_cons) h98_syntax Nothing
 753         })
 754   ; return [ATyCon tycon]
 755   }
 756   where
 757     is_rec   = calc_isrec tc_name
 758     h98_syntax = case cons of   -- All constructors have same shape
 759                         L _ (ConDecl { con_res = ResTyGADT _ }) : _ -> False
 760                         other -> True
 761
 762 tcTyClDecl1 calc_isrec
 763   (ClassDecl {tcdLName = L _ class_name, tcdTyVars = tvs,
 764               tcdCtxt = ctxt, tcdMeths = meths,
 765               tcdFDs = fundeps, tcdSigs = sigs, tcdATs = ats} )
 766   = tcTyVarBndrs tvs            $ \ tvs' -> do
 767   { ctxt' <- tcHsKindedContext ctxt
 768   ; fds' <- mappM (addLocM tc_fundep) fundeps
 769   ; atss <- mappM (addLocM (tcTyClDecl1 (const Recursive))) ats
 770   ; let ats' = zipWith setTyThingPoss atss (map (tcdTyVars . unLoc) ats)
 771   ; sig_stuff <- tcClassSigs class_name sigs meths
 772   ; clas <- fixM (\ clas ->
 773                 let     -- This little knot is just so we can get
 774                         -- hold of the name of the class TyCon, which we
 775                         -- need to look up its recursiveness
 776                     tycon_name = tyConName (classTyCon clas)
 777                     tc_isrec = calc_isrec tycon_name
 778                 in
 779                 buildClass class_name tvs' ctxt' fds' ats'
 780                            sig_stuff tc_isrec)
 781   ; return (AClass clas : ats')
 782       -- NB: Order is important due to the call to `mkGlobalThings' when
 783       --     tying the the type and class declaration type checking knot.
 784   }
 785   where
 786     tc_fundep (tvs1, tvs2) = do { tvs1' <- mappM tcLookupTyVar tvs1 ;
 787                                 ; tvs2' <- mappM tcLookupTyVar tvs2 ;
 788                                 ; return (tvs1', tvs2') }
 789
 790     -- For each AT argument compute the position of the corresponding class
 791     -- parameter in the class head.  This will later serve as a permutation
 792     -- vector when checking the validity of instance declarations.
 793     setTyThingPoss [ATyCon tycon] atTyVars =
 794       let classTyVars = hsLTyVarNames tvs
 795           poss        =   catMaybes
 796                         . map (`elemIndex` classTyVars)
 797                         . hsLTyVarNames
 798                         $ atTyVars
 799                      -- There will be no Nothing, as we already passed renaming
 800       in
 801       ATyCon (setTyConArgPoss tycon poss)
 802     setTyThingPoss _              _ = panic "TcTyClsDecls.setTyThingPoss"
 803
 804 tcTyClDecl1 calc_isrec
 805   (ForeignType {tcdLName = L _ tc_name, tcdExtName = tc_ext_name})
 806   = returnM [ATyCon (mkForeignTyCon tc_name tc_ext_name liftedTypeKind 0)]
 807
 808 -----------------------------------
 809 tcConDecl :: Bool               -- True <=> -funbox-strict_fields
 810           -> TyCon -> [TyVar]
 811           -> ConDecl Name
 812           -> TcM DataCon
 813
 814 tcConDecl unbox_strict tycon tc_tvs     -- Data types
 815           (ConDecl name _ tvs ctxt details res_ty _)
 816   = tcTyVarBndrs tvs            $ \ tvs' -> do
 817     { ctxt' <- tcHsKindedContext ctxt
 818     ; (univ_tvs, ex_tvs, eq_preds, data_tc) <- tcResultType tycon tc_tvs tvs' res_ty
 819     ; let
 820         -- Tiresome: tidy the tyvar binders, since tc_tvs and tvs' may have the same OccNames
 821         tc_datacon is_infix field_lbls btys
 822           = do { let bangs = map getBangStrictness btys
 823                ; arg_tys <- mappM tcHsBangType btys
 824                ; buildDataCon (unLoc name) is_infix
 825                     (argStrictness unbox_strict bangs arg_tys)
 826                     (map unLoc field_lbls)
 827                     univ_tvs ex_tvs eq_preds ctxt' arg_tys
 828                     data_tc }
 829                 -- NB:  we put data_tc, the type constructor gotten from the
 830                 --      constructor type signature into the data constructor;
 831                 --      that way checkValidDataCon can complain if it's wrong.
 832
 833     ; case details of
 834         PrefixCon btys     -> tc_datacon False [] btys
 835         InfixCon bty1 bty2 -> tc_datacon True  [] [bty1,bty2]
 836         RecCon fields      -> tc_datacon False field_names btys
 837                            where
 838                               field_names = map cd_fld_name fields
 839                               btys        = map cd_fld_type fields
 840     }
 841
 842 tcResultType :: TyCon
 843              -> [TyVar]         -- data T a b c = ...
 844              -> [TyVar]         -- where MkT :: forall a b c. ...
 845              -> ResType Name
 846              -> TcM ([TyVar],           -- Universal
 847                      [TyVar],           -- Existential (distinct OccNames from univs)
 848                      [(TyVar,Type)],    -- Equality predicates
 849                      TyCon)             -- TyCon given in the ResTy
 850         -- We don't check that the TyCon given in the ResTy is
 851         -- the same as the parent tycon, becuase we are in the middle
 852         -- of a recursive knot; so it's postponed until checkValidDataCon
 853
 854 tcResultType decl_tycon tc_tvs dc_tvs ResTyH98
 855   = return (tc_tvs, dc_tvs, [], decl_tycon)
 856         -- In H98 syntax the dc_tvs are the existential ones
 857         --      data T a b c = forall d e. MkT ...
 858         -- The {a,b,c} are tc_tvs, and {d,e} are dc_tvs
 859
 860 tcResultType _ tc_tvs dc_tvs (ResTyGADT res_ty)
 861         -- E.g.  data T a b c where
 862         --         MkT :: forall x y z. T (x,y) z z
 863         -- Then we generate
 864         --      ([a,z,c], [x,y], [a:=:(x,y), c:=:z], T)
 865
 866   = do  { (dc_tycon, res_tys) <- tcLHsConResTy res_ty
 867
 868         ; let univ_tvs = choose_univs [] tidy_tc_tvs res_tys
 869                 -- Each univ_tv is either a dc_tv or a tc_tv
 870               ex_tvs = dc_tvs `minusList` univ_tvs
 871               eq_spec = [ (tv, ty) | (tv,ty) <- univ_tvs `zip` res_tys,
 872                                       tv `elem` tc_tvs]
 873         ; return (univ_tvs, ex_tvs, eq_spec, dc_tycon) }
 874   where
 875         -- choose_univs uses the res_ty itself if it's a type variable
 876         -- and hasn't already been used; otherwise it uses one of the tc_tvs
 877     choose_univs used tc_tvs []
 878         = ASSERT( null tc_tvs ) []
 879     choose_univs used (tc_tv:tc_tvs) (res_ty:res_tys)
 880         | Just tv <- tcGetTyVar_maybe res_ty, not (tv `elem` used)
 881         = tv    : choose_univs (tv:used) tc_tvs res_tys
 882         | otherwise
 883         = tc_tv : choose_univs used tc_tvs res_tys
 884
 885         -- NB: tc_tvs and dc_tvs are distinct, but
 886         -- we want them to be *visibly* distinct, both for
 887         -- interface files and general confusion.  So rename
 888         -- the tc_tvs, since they are not used yet (no
 889         -- consequential renaming needed)
 890     init_occ_env     = initTidyOccEnv (map getOccName dc_tvs)
 891     (_, tidy_tc_tvs) = mapAccumL tidy_one init_occ_env tc_tvs
 892     tidy_one env tv  = (env', setTyVarName tv (tidyNameOcc name occ'))
 893               where
 894                  name = tyVarName tv
 895                  (env', occ') = tidyOccName env (getOccName name)
 896
 897               -------------------
 898 argStrictness :: Bool           -- True <=> -funbox-strict_fields
 899               -> [HsBang]
 900               -> [TcType] -> [StrictnessMark]
 901 argStrictness unbox_strict bangs arg_tys
 902  = ASSERT( length bangs == length arg_tys )
 903    zipWith (chooseBoxingStrategy unbox_strict) arg_tys bangs
 904
 905 -- We attempt to unbox/unpack a strict field when either:
 906 --   (i)  The field is marked '!!', or
 907 --   (ii) The field is marked '!', and the -funbox-strict-fields flag is on.
 908 --
 909 -- We have turned off unboxing of newtypes because coercions make unboxing
 910 -- and reboxing more complicated
 911 chooseBoxingStrategy :: Bool -> TcType -> HsBang -> StrictnessMark
 912 chooseBoxingStrategy unbox_strict_fields arg_ty bang
 913   = case bang of
 914         HsNoBang                                    -> NotMarkedStrict
 915         HsStrict | unbox_strict_fields
 916                    && can_unbox arg_ty              -> MarkedUnboxed
 917         HsUnbox  | can_unbox arg_ty                 -> MarkedUnboxed
 918         other                                       -> MarkedStrict
 919   where
 920     -- we can unbox if the type is a chain of newtypes with a product tycon
 921     -- at the end
 922     can_unbox arg_ty = case splitTyConApp_maybe arg_ty of
 923                    Nothing                      -> False
 924                    Just (arg_tycon, tycon_args) ->
 925                        not (isRecursiveTyCon arg_tycon) &&      -- Note [Recusive unboxing]
 926                        isProductTyCon arg_tycon &&
 927                        (if isNewTyCon arg_tycon then
 928                             can_unbox (newTyConInstRhs arg_tycon tycon_args)
 929                         else True)
 930 \end{code}
 931
 932 Note [Recursive unboxing]
 933 ~~~~~~~~~~~~~~~~~~~~~~~~~
 934 Be careful not to try to unbox this!
 935         data T = MkT !T Int
 936 But it's the *argument* type that matters. This is fine:
 937         data S = MkS S !Int
 938 because Int is non-recursive.
 939
 940 %************************************************************************
 941 %*                                                                      *
 942 \subsection{Dependency analysis}
 943 %*                                                                      *
 944 %************************************************************************
 945
 946 Validity checking is done once the mutually-recursive knot has been
 947 tied, so we can look at things freely.
 948
 949 \begin{code}
 950 checkCycleErrs :: [LTyClDecl Name] -> TcM ()
 951 checkCycleErrs tyclss
 952   | null cls_cycles
 953   = return ()
 954   | otherwise
 955   = do  { mappM_ recClsErr cls_cycles
 956         ; failM }       -- Give up now, because later checkValidTyCl
 957                         -- will loop if the synonym is recursive
 958   where
 959     cls_cycles = calcClassCycles tyclss
 960
 961 checkValidTyCl :: TyClDecl Name -> TcM ()
 962 -- We do the validity check over declarations, rather than TyThings
 963 -- only so that we can add a nice context with tcAddDeclCtxt
 964 checkValidTyCl decl
 965   = tcAddDeclCtxt decl $
 966     do  { thing <- tcLookupLocatedGlobal (tcdLName decl)
 967         ; traceTc (text "Validity of" <+> ppr thing)
 968         ; case thing of
 969             ATyCon tc -> checkValidTyCon tc
 970             AClass cl -> checkValidClass cl
 971         ; traceTc (text "Done validity of" <+> ppr thing)
 972         }
 973
 974 -------------------------
 975 -- For data types declared with record syntax, we require
 976 -- that each constructor that has a field 'f'
 977 --      (a) has the same result type
 978 --      (b) has the same type for 'f'
 979 -- module alpha conversion of the quantified type variables
 980 -- of the constructor.
 981
 982 checkValidTyCon :: TyCon -> TcM ()
 983 checkValidTyCon tc
 984   | isSynTyCon tc
 985   = case synTyConRhs tc of
 986       OpenSynTyCon _ _ -> return ()
 987       SynonymTyCon ty  -> checkValidType syn_ctxt ty
 988   | otherwise
 989   =     -- Check the context on the data decl
 990     checkValidTheta (DataTyCtxt name) (tyConStupidTheta tc)     `thenM_`
 991
 992         -- Check arg types of data constructors
 993     mappM_ (checkValidDataCon tc) data_cons                     `thenM_`
 994
 995         -- Check that fields with the same name share a type
 996     mappM_ check_fields groups
 997
 998   where
 999     syn_ctxt  = TySynCtxt name
1000     name      = tyConName tc
1001     data_cons = tyConDataCons tc
1002
1003     groups = equivClasses cmp_fld (concatMap get_fields data_cons)
1004     cmp_fld (f1,_) (f2,_) = f1 `compare` f2
1005     get_fields con = dataConFieldLabels con `zip` repeat con
1006         -- dataConFieldLabels may return the empty list, which is fine
1007
1008     -- See Note [GADT record selectors] in MkId.lhs
1009     -- We must check (a) that the named field has the same
1010     --                   type in each constructor
1011     --               (b) that those constructors have the same result type
1012     --
1013     -- However, the constructors may have differently named type variable
1014     -- and (worse) we don't know how the correspond to each other.  E.g.
1015     --     C1 :: forall a b. { f :: a, g :: b } -> T a b
1016     --     C2 :: forall d c. { f :: c, g :: c } -> T c d
1017     --
1018     -- So what we do is to ust Unify.tcMatchTys to compare the first candidate's
1019     -- result type against other candidates' types BOTH WAYS ROUND.
1020     -- If they magically agrees, take the substitution and
1021     -- apply them to the latter ones, and see if they match perfectly.
1022     check_fields fields@((label, con1) : other_fields)
1023         -- These fields all have the same name, but are from
1024         -- different constructors in the data type
1025         = recoverM (return ()) $ mapM_ checkOne other_fields
1026                 -- Check that all the fields in the group have the same type
1027                 -- NB: this check assumes that all the constructors of a given
1028                 -- data type use the same type variables
1029         where
1030         (tvs1, _, _, res1) = dataConSig con1
1031         ts1 = mkVarSet tvs1
1032         fty1 = dataConFieldType con1 label
1033
1034         checkOne (_, con2)    -- Do it bothways to ensure they are structurally identical
1035             = do { checkFieldCompat label con1 con2 ts1 res1 res2 fty1 fty2
1036                  ; checkFieldCompat label con2 con1 ts2 res2 res1 fty2 fty1 }
1037             where
1038                 (tvs2, _, _, res2) = dataConSig con2
1039                 ts2 = mkVarSet tvs2
1040                 fty2 = dataConFieldType con2 label
1041
1042 checkFieldCompat fld con1 con2 tvs1 res1 res2 fty1 fty2
1043   = do  { checkTc (isJust mb_subst1) (resultTypeMisMatch fld con1 con2)
1044         ; checkTc (isJust mb_subst2) (fieldTypeMisMatch fld con1 con2) }
1045   where
1046     mb_subst1 = tcMatchTy tvs1 res1 res2
1047     mb_subst2 = tcMatchTyX tvs1 (expectJust "checkFieldCompat" mb_subst1) fty1 fty2
1048
1049 -------------------------------
1050 checkValidDataCon :: TyCon -> DataCon -> TcM ()
1051 checkValidDataCon tc con
1052   = setSrcSpan (srcLocSpan (getSrcLoc con))     $
1053     addErrCtxt (dataConCtxt con)                $
1054     do  { checkTc (dataConTyCon con == tc) (badDataConTyCon con)
1055         ; checkValidType ctxt (dataConUserType con)
1056         ; ifM (isNewTyCon tc) (checkNewDataCon con)
1057     }
1058   where
1059     ctxt = ConArgCtxt (dataConName con)
1060
1061 -------------------------------
1062 checkNewDataCon :: DataCon -> TcM ()
1063 -- Checks for the data constructor of a newtype
1064 checkNewDataCon con
1065   = do  { checkTc (isSingleton arg_tys) (newtypeFieldErr con (length arg_tys))
1066                 -- One argument
1067         ; checkTc (null eq_spec) (newtypePredError con)
1068                 -- Return type is (T a b c)
1069         ; checkTc (null ex_tvs && null theta) (newtypeExError con)
1070                 -- No existentials
1071         ; checkTc (not (any isMarkedStrict (dataConStrictMarks con)))
1072                   (newtypeStrictError con)
1073                 -- No strictness
1074     }
1075   where
1076     (_univ_tvs, ex_tvs, eq_spec, theta, arg_tys, _res_ty) = dataConFullSig con
1077
1078 -------------------------------
1079 checkValidClass :: Class -> TcM ()
1080 checkValidClass cls
1081   = do  { constrained_class_methods <- doptM Opt_ConstrainedClassMethods
1082         ; multi_param_type_classes <- doptM Opt_MultiParamTypeClasses
1083         ; fundep_classes <- doptM Opt_FunctionalDependencies
1084
1085         -- Check that the class is unary, unless GlaExs
1086         ; checkTc (notNull tyvars) (nullaryClassErr cls)
1087         ; checkTc (multi_param_type_classes || unary) (classArityErr cls)
1088         ; checkTc (fundep_classes || null fundeps) (classFunDepsErr cls)
1089
1090         -- Check the super-classes
1091         ; checkValidTheta (ClassSCCtxt (className cls)) theta
1092
1093         -- Check the class operations
1094         ; mappM_ (check_op constrained_class_methods) op_stuff
1095
1096         -- Check that if the class has generic methods, then the
1097         -- class has only one parameter.  We can't do generic
1098         -- multi-parameter type classes!
1099         ; checkTc (unary || no_generics) (genericMultiParamErr cls)
1100         }
1101   where
1102     (tyvars, fundeps, theta, _, _, op_stuff) = classExtraBigSig cls
1103     unary       = isSingleton tyvars
1104     no_generics = null [() | (_, GenDefMeth) <- op_stuff]
1105
1106     check_op constrained_class_methods (sel_id, dm)
1107       = addErrCtxt (classOpCtxt sel_id tau) $ do
1108         { checkValidTheta SigmaCtxt (tail theta)
1109                 -- The 'tail' removes the initial (C a) from the
1110                 -- class itself, leaving just the method type
1111
1112         ; checkValidType (FunSigCtxt op_name) tau
1113
1114                 -- Check that the type mentions at least one of
1115                 -- the class type variables...or at least one reachable
1116                 -- from one of the class variables.  Example: tc223
1117                 --   class Error e => Game b mv e | b -> mv e where
1118                 --      newBoard :: MonadState b m => m ()
1119                 -- Here, MonadState has a fundep m->b, so newBoard is fine
1120         ; let grown_tyvars = grow theta (mkVarSet tyvars)
1121         ; checkTc (tyVarsOfType tau `intersectsVarSet` grown_tyvars)
1122                   (noClassTyVarErr cls sel_id)
1123
1124                 -- Check that for a generic method, the type of
1125                 -- the method is sufficiently simple
1126         ; checkTc (dm /= GenDefMeth || validGenericMethodType tau)
1127                   (badGenericMethodType op_name op_ty)
1128         }
1129         where
1130           op_name = idName sel_id
1131           op_ty   = idType sel_id
1132           (_,theta1,tau1) = tcSplitSigmaTy op_ty
1133           (_,theta2,tau2)  = tcSplitSigmaTy tau1
1134           (theta,tau) | constrained_class_methods = (theta1 ++ theta2, tau2)
1135                       | otherwise = (theta1, mkPhiTy (tail theta1) tau1)
1136                 -- Ugh!  The function might have a type like
1137                 --      op :: forall a. C a => forall b. (Eq b, Eq a) => tau2
1138                 -- With -XConstrainedClassMethods, we want to allow this, even though the inner
1139                 -- forall has an (Eq a) constraint.  Whereas in general, each constraint
1140                 -- in the context of a for-all must mention at least one quantified
1141                 -- type variable.  What a mess!
1142
1143
1144 ---------------------------------------------------------------------
1145 resultTypeMisMatch field_name con1 con2
1146   = vcat [sep [ptext SLIT("Constructors") <+> ppr con1 <+> ptext SLIT("and") <+> ppr con2,
1147                 ptext SLIT("have a common field") <+> quotes (ppr field_name) <> comma],
1148           nest 2 $ ptext SLIT("but have different result types")]
1149 fieldTypeMisMatch field_name con1 con2
1150   = sep [ptext SLIT("Constructors") <+> ppr con1 <+> ptext SLIT("and") <+> ppr con2,
1151          ptext SLIT("give different types for field"), quotes (ppr field_name)]
1152
1153 dataConCtxt con = ptext SLIT("In the definition of data constructor") <+> quotes (ppr con)
1154
1155 classOpCtxt sel_id tau = sep [ptext SLIT("When checking the class method:"),
1156                               nest 2 (ppr sel_id <+> dcolon <+> ppr tau)]
1157
1158 nullaryClassErr cls
1159   = ptext SLIT("No parameters for class")  <+> quotes (ppr cls)
1160
1161 classArityErr cls
1162   = vcat [ptext SLIT("Too many parameters for class") <+> quotes (ppr cls),
1163           parens (ptext SLIT("Use -XMultiParamTypeClasses to allow multi-parameter classes"))]
1164
1165 classFunDepsErr cls
1166   = vcat [ptext SLIT("Fundeps in class") <+> quotes (ppr cls),
1167           parens (ptext SLIT("Use -XFunctionalDependencies to allow fundeps"))]
1168
1169 noClassTyVarErr clas op
1170   = sep [ptext SLIT("The class method") <+> quotes (ppr op),
1171          ptext SLIT("mentions none of the type variables of the class") <+>
1172                 ppr clas <+> hsep (map ppr (classTyVars clas))]
1173
1174 genericMultiParamErr clas
1175   = ptext SLIT("The multi-parameter class") <+> quotes (ppr clas) <+>
1176     ptext SLIT("cannot have generic methods")
1177
1178 badGenericMethodType op op_ty
1179   = hang (ptext SLIT("Generic method type is too complex"))
1180        4 (vcat [ppr op <+> dcolon <+> ppr op_ty,
1181                 ptext SLIT("You can only use type variables, arrows, lists, and tuples")])
1182
1183 recSynErr syn_decls
1184   = setSrcSpan (getLoc (head sorted_decls)) $
1185     addErr (sep [ptext SLIT("Cycle in type synonym declarations:"),
1186                  nest 2 (vcat (map ppr_decl sorted_decls))])
1187   where
1188     sorted_decls = sortLocated syn_decls
1189     ppr_decl (L loc decl) = ppr loc <> colon <+> ppr decl
1190
1191 recClsErr cls_decls
1192   = setSrcSpan (getLoc (head sorted_decls)) $
1193     addErr (sep [ptext SLIT("Cycle in class declarations (via superclasses):"),
1194                  nest 2 (vcat (map ppr_decl sorted_decls))])
1195   where
1196     sorted_decls = sortLocated cls_decls
1197     ppr_decl (L loc decl) = ppr loc <> colon <+> ppr (decl { tcdSigs = [] })
1198
1199 sortLocated :: [Located a] -> [Located a]
1200 sortLocated things = sortLe le things
1201   where
1202     le (L l1 _) (L l2 _) = l1 <= l2
1203
1204 badDataConTyCon data_con
1205   = hang (ptext SLIT("Data constructor") <+> quotes (ppr data_con) <+>
1206                 ptext SLIT("returns type") <+> quotes (ppr (dataConTyCon data_con)))
1207        2 (ptext SLIT("instead of its parent type"))
1208
1209 badGadtDecl tc_name
1210   = vcat [ ptext SLIT("Illegal generalised algebraic data declaration for") <+> quotes (ppr tc_name)
1211          , nest 2 (parens $ ptext SLIT("Use -XGADTs to allow GADTs")) ]
1212
1213 badStupidTheta tc_name
1214   = ptext SLIT("A data type declared in GADT style cannot have a context:") <+> quotes (ppr tc_name)
1215
1216 newtypeConError tycon n
1217   = sep [ptext SLIT("A newtype must have exactly one constructor,"),
1218          nest 2 $ ptext SLIT("but") <+> quotes (ppr tycon) <+> ptext SLIT("has") <+> speakN n ]
1219
1220 newtypeExError con
1221   = sep [ptext SLIT("A newtype constructor cannot have an existential context,"),
1222          nest 2 $ ptext SLIT("but") <+> quotes (ppr con) <+> ptext SLIT("does")]
1223
1224 newtypeStrictError con
1225   = sep [ptext SLIT("A newtype constructor cannot have a strictness annotation,"),
1226          nest 2 $ ptext SLIT("but") <+> quotes (ppr con) <+> ptext SLIT("does")]
1227
1228 newtypePredError con
1229   = sep [ptext SLIT("A newtype constructor must have a return type of form T a1 ... an"),
1230          nest 2 $ ptext SLIT("but") <+> quotes (ppr con) <+> ptext SLIT("does not")]
1231
1232 newtypeFieldErr con_name n_flds
1233   = sep [ptext SLIT("The constructor of a newtype must have exactly one field"),
1234          nest 2 $ ptext SLIT("but") <+> quotes (ppr con_name) <+> ptext SLIT("has") <+> speakN n_flds]
1235
1236 badSigTyDecl tc_name
1237   = vcat [ ptext SLIT("Illegal kind signature") <+>
1238            quotes (ppr tc_name)
1239          , nest 2 (parens $ ptext SLIT("Use -XKindSignatures to allow kind signatures")) ]
1240
1241 badFamInstDecl tc_name
1242   = vcat [ ptext SLIT("Illegal family instance for") <+>
1243            quotes (ppr tc_name)
1244          , nest 2 (parens $ ptext SLIT("Use -XTypeFamilies to allow indexed type families")) ]
1245
1246 badGadtIdxTyDecl tc_name
1247   = vcat [ ptext SLIT("Illegal generalised algebraic data declaration for") <+>
1248            quotes (ppr tc_name)
1249          , nest 2 (parens $ ptext SLIT("Family instances can not yet use GADT declarations")) ]
1250
1251 tooManyParmsErr tc_name
1252   = ptext SLIT("Family instance has too many parameters:") <+>
1253     quotes (ppr tc_name)
1254
1255 tooFewParmsErr tc_name
1256   = ptext SLIT("Family instance has too few parameters:") <+>
1257     quotes (ppr tc_name)
1258
1259 badBootFamInstDeclErr =
1260   ptext SLIT("Illegal family instance in hs-boot file")
1261
1262 wrongKindOfFamily family =
1263   ptext SLIT("Wrong category of family instance; declaration was for a") <+>
1264   kindOfFamily
1265   where
1266     kindOfFamily | isSynTyCon family = ptext SLIT("type synonym")
1267                  | isAlgTyCon family = ptext SLIT("data type")
1268                  | otherwise = pprPanic "wrongKindOfFamily" (ppr family)
1269
1270 polyTyErr ty
1271   = hang (ptext SLIT("Illegal polymorphic type in type instance") <> colon) 4 $
1272       ppr ty
1273
1274 tyFamAppInIndexErr ty
1275   = hang (ptext SLIT("Illegal type family application in type instance") <>
1276          colon) 4 $
1277       ppr ty
1278
1279 emptyConDeclsErr tycon
1280   = sep [quotes (ppr tycon) <+> ptext SLIT("has no constructors"),
1281          nest 2 $ ptext SLIT("(-XEmptyDataDecls permits this)")]
1282 \end{code}