compiler/typecheck/TcTyClsDecls.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The AQUA Project, Glasgow University, 1996-1998
   4 %
   5
   6 TcTyClsDecls: Typecheck type and class declarations
   7
   8 \begin{code}
   9 module TcTyClsDecls (
  10         tcTyAndClassDecls, tcFamInstDecl
  11     ) where
  12
  13 #include "HsVersions.h"
  14
  15 import HsSyn
  16 import HsTypes
  17 import BasicTypes
  18 import HscTypes
  19 import BuildTyCl
  20 import TcRnMonad
  21 import TcEnv
  22 import TcTyDecls
  23 import TcClassDcl
  24 import TcHsType
  25 import TcMType
  26 import TcType
  27 import FunDeps
  28 import Type
  29 import Generics
  30 import Class
  31 import TyCon
  32 import DataCon
  33 import Var
  34 import VarSet
  35 import Name
  36 import OccName
  37 import Outputable
  38 import Maybes
  39 import Monad
  40 import Unify
  41 import Util
  42 import SrcLoc
  43 import ListSetOps
  44 import Digraph
  45 import DynFlags
  46
  47 import Data.List        ( partition, elemIndex )
  48 import Control.Monad    ( mplus )
  49 \end{code}
  50
  51
  52 %************************************************************************
  53 %*                                                                      *
  54 \subsection{Type checking for type and class declarations}
  55 %*                                                                      *
  56 %************************************************************************
  57
  58 Dealing with a group
  59 ~~~~~~~~~~~~~~~~~~~~
  60 Consider a mutually-recursive group, binding
  61 a type constructor T and a class C.
  62
  63 Step 1:         getInitialKind
  64         Construct a KindEnv by binding T and C to a kind variable
  65
  66 Step 2:         kcTyClDecl
  67         In that environment, do a kind check
  68
  69 Step 3: Zonk the kinds
  70
  71 Step 4:         buildTyConOrClass
  72         Construct an environment binding T to a TyCon and C to a Class.
  73         a) Their kinds comes from zonking the relevant kind variable
  74         b) Their arity (for synonyms) comes direct from the decl
  75         c) The funcional dependencies come from the decl
  76         d) The rest comes a knot-tied binding of T and C, returned from Step 4
  77         e) The variances of the tycons in the group is calculated from
  78                 the knot-tied stuff
  79
  80 Step 5:         tcTyClDecl1
  81         In this environment, walk over the decls, constructing the TyCons and Classes.
  82         This uses in a strict way items (a)-(c) above, which is why they must
  83         be constructed in Step 4. Feed the results back to Step 4.
  84         For this step, pass the is-recursive flag as the wimp-out flag
  85         to tcTyClDecl1.
  86
  87
  88 Step 6:         Extend environment
  89         We extend the type environment with bindings not only for the TyCons and Classes,
  90         but also for their "implicit Ids" like data constructors and class selectors
  91
  92 Step 7:         checkValidTyCl
  93         For a recursive group only, check all the decls again, just
  94         to check all the side conditions on validity.  We could not
  95         do this before because we were in a mutually recursive knot.
  96
  97 Identification of recursive TyCons
  98 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  99 The knot-tying parameters: @rec_details_list@ is an alist mapping @Name@s to
 100 @TyThing@s.
 101
 102 Identifying a TyCon as recursive serves two purposes
 103
 104 1.  Avoid infinite types.  Non-recursive newtypes are treated as
 105 "transparent", like type synonyms, after the type checker.  If we did
 106 this for all newtypes, we'd get infinite types.  So we figure out for
 107 each newtype whether it is "recursive", and add a coercion if so.  In
 108 effect, we are trying to "cut the loops" by identifying a loop-breaker.
 109
 110 2.  Avoid infinite unboxing.  This is nothing to do with newtypes.
 111 Suppose we have
 112         data T = MkT Int T
 113         f (MkT x t) = f t
 114 Well, this function diverges, but we don't want the strictness analyser
 115 to diverge.  But the strictness analyser will diverge because it looks
 116 deeper and deeper into the structure of T.   (I believe there are
 117 examples where the function does something sane, and the strictness
 118 analyser still diverges, but I can't see one now.)
 119
 120 Now, concerning (1), the FC2 branch currently adds a coercion for ALL
 121 newtypes.  I did this as an experiment, to try to expose cases in which
 122 the coercions got in the way of optimisations.  If it turns out that we
 123 can indeed always use a coercion, then we don't risk recursive types,
 124 and don't need to figure out what the loop breakers are.
 125
 126 For newtype *families* though, we will always have a coercion, so they
 127 are always loop breakers!  So you can easily adjust the current
 128 algorithm by simply treating all newtype families as loop breakers (and
 129 indeed type families).  I think.
 130
 131 \begin{code}
 132 tcTyAndClassDecls :: ModDetails -> [LTyClDecl Name]
 133                    -> TcM TcGblEnv      -- Input env extended by types and classes
 134                                         -- and their implicit Ids,DataCons
 135 tcTyAndClassDecls boot_details allDecls
 136   = do  {       -- Omit instances of indexed types; they are handled together
 137                 -- with the *heads* of class instances
 138         ; let decls = filter (not . isFamInstDecl . unLoc) allDecls
 139
 140                 -- First check for cyclic type synonysm or classes
 141                 -- See notes with checkCycleErrs
 142         ; checkCycleErrs decls
 143         ; mod <- getModule
 144         ; traceTc (text "tcTyAndCl" <+> ppr mod)
 145         ; (syn_tycons, alg_tyclss) <- fixM (\ ~(rec_syn_tycons, rec_alg_tyclss) ->
 146           do    { let { -- Seperate ordinary synonyms from all other type and
 147                         -- class declarations and add all associated type
 148                         -- declarations from type classes.  The latter is
 149                         -- required so that the temporary environment for the
 150                         -- knot includes all associated family declarations.
 151                       ; (syn_decls, alg_decls) = partition (isSynDecl . unLoc)
 152                                                    decls
 153                       ; alg_at_decls           = concatMap addATs alg_decls
 154                       }
 155                         -- Extend the global env with the knot-tied results
 156                         -- for data types and classes
 157                         --
 158                         -- We must populate the environment with the loop-tied
 159                         -- T's right away, because the kind checker may "fault
 160                         -- in" some type  constructors that recursively
 161                         -- mention T
 162                 ; let gbl_things = mkGlobalThings alg_at_decls rec_alg_tyclss
 163                 ; tcExtendRecEnv gbl_things $ do
 164
 165                         -- Kind-check the declarations
 166                 { (kc_syn_decls, kc_alg_decls) <- kcTyClDecls syn_decls alg_decls
 167
 168                 ; let { -- Calculate rec-flag
 169                       ; calc_rec  = calcRecFlags boot_details rec_alg_tyclss
 170                       ; tc_decl   = addLocM (tcTyClDecl calc_rec) }
 171
 172                         -- Type-check the type synonyms, and extend the envt
 173                 ; syn_tycons <- tcSynDecls kc_syn_decls
 174                 ; tcExtendGlobalEnv syn_tycons $ do
 175
 176                         -- Type-check the data types and classes
 177                 { alg_tyclss <- mappM tc_decl kc_alg_decls
 178                 ; return (syn_tycons, concat alg_tyclss)
 179             }}})
 180         -- Finished with knot-tying now
 181         -- Extend the environment with the finished things
 182         ; tcExtendGlobalEnv (syn_tycons ++ alg_tyclss) $ do
 183
 184         -- Perform the validity check
 185         { traceTc (text "ready for validity check")
 186         ; mappM_ (addLocM checkValidTyCl) decls
 187         ; traceTc (text "done")
 188
 189         -- Add the implicit things;
 190         -- we want them in the environment because
 191         -- they may be mentioned in interface files
 192         -- NB: All associated types and their implicit things will be added a
 193         --     second time here.  This doesn't matter as the definitions are
 194         --     the same.
 195         ; let { implicit_things = concatMap implicitTyThings alg_tyclss }
 196         ; traceTc ((text "Adding" <+> ppr alg_tyclss)
 197                    $$ (text "and" <+> ppr implicit_things))
 198         ; tcExtendGlobalEnv implicit_things getGblEnv
 199     }}
 200   where
 201     -- Pull associated types out of class declarations, to tie them into the
 202     -- knot above.
 203     -- NB: We put them in the same place in the list as `tcTyClDecl' will
 204     --     eventually put the matching `TyThing's.  That's crucial; otherwise,
 205     --     the two argument lists of `mkGlobalThings' don't match up.
 206     addATs decl@(L _ (ClassDecl {tcdATs = ats})) = decl : ats
 207     addATs decl                                  = [decl]
 208
 209 mkGlobalThings :: [LTyClDecl Name]      -- The decls
 210                -> [TyThing]             -- Knot-tied, in 1-1 correspondence with the decls
 211                -> [(Name,TyThing)]
 212 -- Driven by the Decls, and treating the TyThings lazily
 213 -- make a TypeEnv for the new things
 214 mkGlobalThings decls things
 215   = map mk_thing (decls `zipLazy` things)
 216   where
 217     mk_thing (L _ (ClassDecl {tcdLName = L _ name}), ~(AClass cl))
 218          = (name, AClass cl)
 219     mk_thing (L _ decl, ~(ATyCon tc))
 220          = (tcdName decl, ATyCon tc)
 221 \end{code}
 222
 223
 224 %************************************************************************
 225 %*                                                                      *
 226 \subsection{Type checking family instances}
 227 %*                                                                      *
 228 %************************************************************************
 229
 230 Family instances are somewhat of a hybrid.  They are processed together with
 231 class instance heads, but can contain data constructors and hence they share a
 232 lot of kinding and type checking code with ordinary algebraic data types (and
 233 GADTs).
 234
 235 \begin{code}
 236 tcFamInstDecl :: LTyClDecl Name -> TcM (Maybe TyThing)   -- Nothing if error
 237 tcFamInstDecl (L loc decl)
 238   =     -- Prime error recovery, set source location
 239     recoverM (returnM Nothing)                  $
 240     setSrcSpan loc                              $
 241     tcAddDeclCtxt decl                          $
 242     do { -- type families require -findexed-types and can't be in an
 243          -- hs-boot file
 244        ; gla_exts <- doptM Opt_IndexedTypes
 245        ; is_boot  <- tcIsHsBoot   -- Are we compiling an hs-boot file?
 246        ; checkTc gla_exts      $ badFamInstDecl (tcdLName decl)
 247        ; checkTc (not is_boot) $ badBootFamInstDeclErr
 248
 249          -- perform kind and type checking
 250        ; tcFamInstDecl1 decl
 251        }
 252
 253 tcFamInstDecl1 :: TyClDecl Name -> TcM (Maybe TyThing)   -- Nothing if error
 254
 255 tcFamInstDecl1 (decl@TySynonym {})
 256   = kcIdxTyPats decl $ \k_tvs k_typats resKind family ->
 257     do { -- check that the family declaration is for a synonym
 258          unless (isSynTyCon family) $
 259            addErr (wrongKindOfFamily family)
 260
 261        ; -- (1) kind check the right hand side of the type equation
 262        ; k_rhs <- kcCheckHsType (tcdSynRhs decl) resKind
 263
 264          -- (2) type check type equation
 265        ; tcTyVarBndrs k_tvs $ \t_tvs -> do {  -- turn kinded into proper tyvars
 266        ; t_typats <- mappM tcHsKindedType k_typats
 267        ; t_rhs    <- tcHsKindedType k_rhs
 268
 269          -- !!!of the form: forall t_tvs. (tcdLName decl) t_typats = t_rhs
 270        ; return Nothing     -- !!!TODO: need TyThing for indexed synonym
 271        }}
 272
 273 tcFamInstDecl1 (decl@TyData {tcdND = new_or_data, tcdLName = L loc tc_name,
 274                              tcdCons = cons})
 275   = kcIdxTyPats decl $ \k_tvs k_typats resKind family ->
 276     do { -- check that the family declaration is for the right kind
 277          unless (new_or_data == NewType  && isNewTyCon  family ||
 278                  new_or_data == DataType && isDataTyCon family) $
 279            addErr (wrongKindOfFamily family)
 280
 281        ; -- (1) kind check the data declaration as usual
 282        ; k_decl <- kcDataDecl decl k_tvs
 283        ; let k_ctxt = tcdCtxt k_decl
 284              k_cons = tcdCons k_decl
 285
 286          -- result kind must be '*' (otherwise, we have too few patterns)
 287        ; checkTc (isLiftedTypeKind resKind) $ tooFewParmsErr tc_name
 288
 289          -- (2) type check indexed data type declaration
 290        ; tcTyVarBndrs k_tvs $ \t_tvs -> do {  -- turn kinded into proper tyvars
 291        ; unbox_strict <- doptM Opt_UnboxStrictFields
 292
 293          -- Check that we don't use GADT syntax for indexed types
 294        ; checkTc h98_syntax (badGadtIdxTyDecl tc_name)
 295
 296          -- Check that a newtype has exactly one constructor
 297        ; checkTc (new_or_data == DataType || isSingleton k_cons) $
 298            newtypeConError tc_name (length k_cons)
 299
 300        ; t_typats     <- mappM tcHsKindedType k_typats
 301        ; stupid_theta <- tcHsKindedContext k_ctxt
 302
 303        ; rep_tc_name <- newFamInstTyConName tc_name (srcSpanStart loc)
 304        ; tycon <- fixM (\ tycon -> do
 305              { data_cons <- mappM (addLocM (tcConDecl unbox_strict new_or_data
 306                                               tycon t_tvs))
 307                                   k_cons
 308              ; tc_rhs <-
 309                  case new_or_data of
 310                    DataType -> return (mkDataTyConRhs data_cons)
 311                    NewType  -> ASSERT( isSingleton data_cons )
 312                                mkNewTyConRhs tc_name tycon (head data_cons)
 313              ; buildAlgTyCon rep_tc_name t_tvs stupid_theta tc_rhs Recursive
 314                              False h98_syntax (Just (family, t_typats))
 315                  -- We always assume that indexed types are recursive.  Why?
 316                  -- (1) Due to their open nature, we can never be sure that a
 317                  -- further instance might not introduce a new recursive
 318                  -- dependency.  (2) They are always valid loop breakers as
 319                  -- they involve a coercion.
 320              })
 321
 322          -- construct result
 323        ; return $ Just (ATyCon tycon)
 324        }}
 325        where
 326          h98_syntax = case cons of      -- All constructors have same shape
 327                         L _ (ConDecl { con_res = ResTyGADT _ }) : _ -> False
 328                         other -> True
 329
 330 -- Kind checking of indexed types
 331 -- -
 332
 333 -- Kind check type patterns and kind annotate the embedded type variables.
 334 --
 335 -- * Here we check that a type instance matches its kind signature, but we do
 336 --   not check whether there is a pattern for each type index; the latter
 337 --   check is only required for type functions.
 338 --
 339 kcIdxTyPats :: TyClDecl Name
 340             -> ([LHsTyVarBndr Name] -> [LHsType Name] -> Kind -> TyCon -> TcM a)
 341                -- ^^kinded tvs         ^^kinded ty pats  ^^res kind
 342             -> TcM a
 343 kcIdxTyPats decl thing_inside
 344   = kcHsTyVars (tcdTyVars decl) $ \tvs ->
 345     do { family <- tcLookupLocatedTyCon (tcdLName decl)
 346        ; let { (kinds, resKind) = splitKindFunTys (tyConKind family)
 347              ; hs_typats        = fromJust $ tcdTyPats decl }
 348
 349          -- we may not have more parameters than the kind indicates
 350        ; checkTc (length kinds >= length hs_typats) $
 351            tooManyParmsErr (tcdLName decl)
 352
 353          -- type functions can have a higher-kinded result
 354        ; let resultKind = mkArrowKinds (drop (length hs_typats) kinds) resKind
 355        ; typats <- TcRnMonad.zipWithM kcCheckHsType hs_typats kinds
 356        ; thing_inside tvs typats resultKind family
 357        }
 358   where
 359 \end{code}
 360
 361
 362 %************************************************************************
 363 %*                                                                      *
 364                 Kind checking
 365 %*                                                                      *
 366 %************************************************************************
 367
 368 We need to kind check all types in the mutually recursive group
 369 before we know the kind of the type variables.  For example:
 370
 371 class C a where
 372    op :: D b => a -> b -> b
 373
 374 class D c where
 375    bop :: (Monad c) => ...
 376
 377 Here, the kind of the locally-polymorphic type variable "b"
 378 depends on *all the uses of class D*.  For example, the use of
 379 Monad c in bop's type signature means that D must have kind Type->Type.
 380
 381 However type synonyms work differently.  They can have kinds which don't
 382 just involve (->) and *:
 383         type R = Int#           -- Kind #
 384         type S a = Array# a     -- Kind * -> #
 385         type T a b = (# a,b #)  -- Kind * -> * -> (# a,b #)
 386 So we must infer their kinds from their right-hand sides *first* and then
 387 use them, whereas for the mutually recursive data types D we bring into
 388 scope kind bindings D -> k, where k is a kind variable, and do inference.
 389
 390 Indexed Types
 391 ~~~~~~~~~~~~~
 392 This treatment of type synonyms only applies to Haskell 98-style synonyms.
 393 General type functions can be recursive, and hence, appear in `alg_decls'.
 394
 395 The kind of a type family is solely determinded by its kind signature;
 396 hence, only kind signatures participate in the construction of the initial
 397 kind environment (as constructed by `getInitialKind').  In fact, we ignore
 398 instances of families altogether in the following.  However, we need to
 399 include the kinds of associated families into the construction of the
 400 initial kind environment.  (This is handled by `allDecls').
 401
 402 \begin{code}
 403 kcTyClDecls syn_decls alg_decls
 404   = do  {       -- First extend the kind env with each data type, class, and
 405                 -- indexed type, mapping them to a type variable
 406           let initialKindDecls = concat [allDecls decl | L _ decl <- alg_decls]
 407         ; alg_kinds <- mappM getInitialKind initialKindDecls
 408         ; tcExtendKindEnv alg_kinds $ do
 409
 410                 -- Now kind-check the type synonyms, in dependency order
 411                 -- We do these differently to data type and classes,
 412                 -- because a type synonym can be an unboxed type
 413                 --      type Foo = Int#
 414                 -- and a kind variable can't unify with UnboxedTypeKind
 415                 -- So we infer their kinds in dependency order
 416         { (kc_syn_decls, syn_kinds) <- kcSynDecls (calcSynCycles syn_decls)
 417         ; tcExtendKindEnv syn_kinds $  do
 418
 419                 -- Now kind-check the data type, class, and kind signatures,
 420                 -- returning kind-annotated decls; we don't kind-check
 421                 -- instances of indexed types yet, but leave this to
 422                 -- `tcInstDecls1'
 423         { kc_alg_decls <- mappM (wrapLocM kcTyClDecl)
 424                             (filter (not . isFamInstDecl . unLoc) alg_decls)
 425
 426         ; return (kc_syn_decls, kc_alg_decls) }}}
 427   where
 428     -- get all declarations relevant for determining the initial kind
 429     -- environment
 430     allDecls (decl@ClassDecl {tcdATs = ats}) = decl : [ at
 431                                                       | L _ at <- ats
 432                                                       , isFamilyDecl at]
 433     allDecls decl | isFamInstDecl decl = []
 434                   | otherwise          = [decl]
 435
 436 ------------------------------------------------------------------------
 437 getInitialKind :: TyClDecl Name -> TcM (Name, TcKind)
 438 -- Only for data type, class, and indexed type declarations
 439 -- Get as much info as possible from the data, class, or indexed type decl,
 440 -- so as to maximise usefulness of error messages
 441 getInitialKind decl
 442   = do  { arg_kinds <- mapM (mk_arg_kind . unLoc) (tyClDeclTyVars decl)
 443         ; res_kind  <- mk_res_kind decl
 444         ; return (tcdName decl, mkArrowKinds arg_kinds res_kind) }
 445   where
 446     mk_arg_kind (UserTyVar _)        = newKindVar
 447     mk_arg_kind (KindedTyVar _ kind) = return kind
 448
 449     mk_res_kind (TyFamily { tcdKind    = Just kind }) = return kind
 450     mk_res_kind (TyData   { tcdKindSig = Just kind }) = return kind
 451         -- On GADT-style declarations we allow a kind signature
 452         --      data T :: *->* where { ... }
 453     mk_res_kind other = return liftedTypeKind
 454
 455
 456 ----------------
 457 kcSynDecls :: [SCC (LTyClDecl Name)]
 458            -> TcM ([LTyClDecl Name],    -- Kind-annotated decls
 459                    [(Name,TcKind)])     -- Kind bindings
 460 kcSynDecls []
 461   = return ([], [])
 462 kcSynDecls (group : groups)
 463   = do  { (decl,  nk)  <- kcSynDecl group
 464         ; (decls, nks) <- tcExtendKindEnv [nk] (kcSynDecls groups)
 465         ; return (decl:decls, nk:nks) }
 466
 467 ----------------
 468 kcSynDecl :: SCC (LTyClDecl Name)
 469            -> TcM (LTyClDecl Name,      -- Kind-annotated decls
 470                    (Name,TcKind))       -- Kind bindings
 471 kcSynDecl (AcyclicSCC ldecl@(L loc decl))
 472   = tcAddDeclCtxt decl  $
 473     kcHsTyVars (tcdTyVars decl) (\ k_tvs ->
 474     do { traceTc (text "kcd1" <+> ppr (unLoc (tcdLName decl)) <+> brackets (ppr (tcdTyVars decl))
 475                         <+> brackets (ppr k_tvs))
 476        ; (k_rhs, rhs_kind) <- kcHsType (tcdSynRhs decl)
 477        ; traceTc (text "kcd2" <+> ppr (unLoc (tcdLName decl)))
 478        ; let tc_kind = foldr (mkArrowKind . kindedTyVarKind) rhs_kind k_tvs
 479        ; return (L loc (decl { tcdTyVars = k_tvs, tcdSynRhs = k_rhs }),
 480                  (unLoc (tcdLName decl), tc_kind)) })
 481
 482 kcSynDecl (CyclicSCC decls)
 483   = do { recSynErr decls; failM }       -- Fail here to avoid error cascade
 484                                         -- of out-of-scope tycons
 485
 486 kindedTyVarKind (L _ (KindedTyVar _ k)) = k
 487
 488 ------------------------------------------------------------------------
 489 kcTyClDecl :: TyClDecl Name -> TcM (TyClDecl Name)
 490         -- Not used for type synonyms (see kcSynDecl)
 491
 492 kcTyClDecl decl@(TyData {})
 493   = ASSERT( not . isFamInstDecl $ decl )   -- must not be a family instance
 494     kcTyClDeclBody decl $
 495       kcDataDecl decl
 496
 497 kcTyClDecl decl@(TyFamily {tcdKind = kind})
 498   = kcTyClDeclBody decl $ \ tvs' ->
 499       return (decl {tcdTyVars = tvs',
 500                     tcdKind = kind `mplus` Just liftedTypeKind})
 501                     -- default result kind is '*'
 502
 503 kcTyClDecl decl@(ClassDecl {tcdCtxt = ctxt, tcdSigs = sigs, tcdATs = ats})
 504   = kcTyClDeclBody decl $ \ tvs' ->
 505     do  { is_boot <- tcIsHsBoot
 506         ; ctxt' <- kcHsContext ctxt
 507         ; ats'  <- mappM (wrapLocM kcTyClDecl) ats
 508         ; sigs' <- mappM (wrapLocM kc_sig    ) sigs
 509         ; return (decl {tcdTyVars = tvs', tcdCtxt = ctxt', tcdSigs = sigs',
 510                         tcdATs = ats'}) }
 511   where
 512     kc_sig (TypeSig nm op_ty) = do { op_ty' <- kcHsLiftedSigType op_ty
 513                                    ; return (TypeSig nm op_ty') }
 514     kc_sig other_sig          = return other_sig
 515
 516 kcTyClDecl decl@(ForeignType {})
 517   = return decl
 518
 519 kcTyClDeclBody :: TyClDecl Name
 520                -> ([LHsTyVarBndr Name] -> TcM a)
 521                -> TcM a
 522 -- getInitialKind has made a suitably-shaped kind for the type or class
 523 -- Unpack it, and attribute those kinds to the type variables
 524 -- Extend the env with bindings for the tyvars, taken from
 525 -- the kind of the tycon/class.  Give it to the thing inside, and
 526 -- check the result kind matches
 527 kcTyClDeclBody decl thing_inside
 528   = tcAddDeclCtxt decl          $
 529     do  { tc_ty_thing <- tcLookupLocated (tcdLName decl)
 530         ; let tc_kind    = case tc_ty_thing of { AThing k -> k }
 531               (kinds, _) = splitKindFunTys tc_kind
 532               hs_tvs     = tcdTyVars decl
 533               kinded_tvs = ASSERT( length kinds >= length hs_tvs )
 534                            [ L loc (KindedTyVar (hsTyVarName tv) k)
 535                            | (L loc tv, k) <- zip hs_tvs kinds]
 536         ; tcExtendKindEnvTvs kinded_tvs (thing_inside kinded_tvs) }
 537
 538 -- Kind check a data declaration, assuming that we already extended the
 539 -- kind environment with the type variables of the left-hand side (these
 540 -- kinded type variables are also passed as the second parameter).
 541 --
 542 kcDataDecl :: TyClDecl Name -> [LHsTyVarBndr Name] -> TcM (TyClDecl Name)
 543 kcDataDecl decl@(TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdCons = cons})
 544            tvs
 545   = do  { ctxt' <- kcHsContext ctxt
 546         ; cons' <- mappM (wrapLocM kc_con_decl) cons
 547         ; return (decl {tcdTyVars = tvs, tcdCtxt = ctxt', tcdCons = cons'}) }
 548   where
 549     -- doc comments are typechecked to Nothing here
 550     kc_con_decl (ConDecl name expl ex_tvs ex_ctxt details res _) = do
 551       kcHsTyVars ex_tvs $ \ex_tvs' -> do
 552         ex_ctxt' <- kcHsContext ex_ctxt
 553         details' <- kc_con_details details
 554         res'     <- case res of
 555           ResTyH98 -> return ResTyH98
 556           ResTyGADT ty -> do { ty' <- kcHsSigType ty; return (ResTyGADT ty') }
 557         return (ConDecl name expl ex_tvs' ex_ctxt' details' res' Nothing)
 558
 559     kc_con_details (PrefixCon btys)
 560         = do { btys' <- mappM kc_larg_ty btys ; return (PrefixCon btys') }
 561     kc_con_details (InfixCon bty1 bty2)
 562         = do { bty1' <- kc_larg_ty bty1; bty2' <- kc_larg_ty bty2; return (InfixCon bty1' bty2') }
 563     kc_con_details (RecCon fields)
 564         = do { fields' <- mappM kc_field fields; return (RecCon fields') }
 565
 566     kc_field (HsRecField fld bty d) = do { bty' <- kc_larg_ty bty ; return (HsRecField fld bty' d) }
 567
 568     kc_larg_ty bty = case new_or_data of
 569                         DataType -> kcHsSigType bty
 570                         NewType  -> kcHsLiftedSigType bty
 571         -- Can't allow an unlifted type for newtypes, because we're effectively
 572         -- going to remove the constructor while coercing it to a lifted type.
 573         -- And newtypes can't be bang'd
 574 \end{code}
 575
 576
 577 %************************************************************************
 578 %*                                                                      *
 579 \subsection{Type checking}
 580 %*                                                                      *
 581 %************************************************************************
 582
 583 \begin{code}
 584 tcSynDecls :: [LTyClDecl Name] -> TcM [TyThing]
 585 tcSynDecls [] = return []
 586 tcSynDecls (decl : decls)
 587   = do { syn_tc <- addLocM tcSynDecl decl
 588        ; syn_tcs <- tcExtendGlobalEnv [syn_tc] (tcSynDecls decls)
 589        ; return (syn_tc : syn_tcs) }
 590
 591 tcSynDecl
 592   (TySynonym {tcdLName = L _ tc_name, tcdTyVars = tvs, tcdSynRhs = rhs_ty})
 593   = tcTyVarBndrs tvs            $ \ tvs' -> do
 594     { traceTc (text "tcd1" <+> ppr tc_name)
 595     ; rhs_ty' <- tcHsKindedType rhs_ty
 596     ; return (ATyCon (buildSynTyCon tc_name tvs' (SynonymTyCon rhs_ty'))) }
 597
 598 --------------------
 599 tcTyClDecl :: (Name -> RecFlag) -> TyClDecl Name -> TcM [TyThing]
 600
 601 tcTyClDecl calc_isrec decl
 602   = tcAddDeclCtxt decl (tcTyClDecl1 calc_isrec decl)
 603
 604   -- "type family" declarations
 605 tcTyClDecl1 _calc_isrec
 606   (TyFamily {tcdFlavour = TypeFamily,
 607              tcdLName = L _ tc_name, tcdTyVars = tvs, tcdKind = Just kind})
 608                                                       -- NB: kind at latest
 609                                                       --     added during
 610                                                       --     kind checking
 611   = tcTyVarBndrs tvs  $ \ tvs' -> do
 612   { traceTc (text "type family: " <+> ppr tc_name)
 613   ; idx_tys <- doptM Opt_IndexedTypes
 614
 615         -- Check that we don't use families without -findexed-types
 616   ; checkTc idx_tys $ badFamInstDecl tc_name
 617
 618   ; return [ATyCon $ buildSynTyCon tc_name tvs' (OpenSynTyCon kind)]
 619   }
 620
 621   -- "newtype family" or "data family" declaration
 622 tcTyClDecl1 _calc_isrec
 623   (TyFamily {tcdFlavour = DataFamily new_or_data,
 624              tcdLName = L _ tc_name, tcdTyVars = tvs, tcdKind = mb_kind})
 625   = tcTyVarBndrs tvs  $ \ tvs' -> do
 626   { traceTc (text "data/newtype family: " <+> ppr tc_name)
 627   ; extra_tvs <- tcDataKindSig mb_kind
 628   ; let final_tvs = tvs' ++ extra_tvs    -- we may not need these
 629
 630   ; idx_tys <- doptM Opt_IndexedTypes
 631
 632         -- Check that we don't use families without -findexed-types
 633   ; checkTc idx_tys $ badFamInstDecl tc_name
 634
 635   ; tycon <- buildAlgTyCon tc_name final_tvs []
 636                (case new_or_data of
 637                   DataType -> OpenDataTyCon
 638                   NewType  -> OpenNewTyCon)
 639                Recursive False True Nothing
 640   ; return [ATyCon tycon]
 641   }
 642
 643   -- "newtype", "data", "newtype instance", "data instance"
 644 tcTyClDecl1 calc_isrec
 645   (TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdTyVars = tvs,
 646            tcdLName = L _ tc_name, tcdKindSig = mb_ksig, tcdCons = cons})
 647   = tcTyVarBndrs tvs    $ \ tvs' -> do
 648   { extra_tvs <- tcDataKindSig mb_ksig
 649   ; let final_tvs = tvs' ++ extra_tvs
 650   ; stupid_theta <- tcHsKindedContext ctxt
 651   ; want_generic <- doptM Opt_Generics
 652   ; unbox_strict <- doptM Opt_UnboxStrictFields
 653   ; gla_exts     <- doptM Opt_GlasgowExts
 654   ; is_boot      <- tcIsHsBoot  -- Are we compiling an hs-boot file?
 655
 656         -- Check that we don't use GADT syntax in H98 world
 657   ; checkTc (gla_exts || h98_syntax) (badGadtDecl tc_name)
 658
 659         -- Check that we don't use kind signatures without Glasgow extensions
 660   ; checkTc (gla_exts || isNothing mb_ksig) (badSigTyDecl tc_name)
 661
 662         -- Check that the stupid theta is empty for a GADT-style declaration
 663   ; checkTc (null stupid_theta || h98_syntax) (badStupidTheta tc_name)
 664
 665         -- Check that there's at least one condecl,
 666         -- or else we're reading an hs-boot file, or -fglasgow-exts
 667   ; checkTc (not (null cons) || gla_exts || is_boot)
 668             (emptyConDeclsErr tc_name)
 669
 670         -- Check that a newtype has exactly one constructor
 671   ; checkTc (new_or_data == DataType || isSingleton cons)
 672             (newtypeConError tc_name (length cons))
 673
 674   ; tycon <- fixM (\ tycon -> do
 675         { data_cons <- mappM (addLocM (tcConDecl unbox_strict new_or_data
 676                                                  tycon final_tvs))
 677                              cons
 678         ; tc_rhs <-
 679             if null cons && is_boot     -- In a hs-boot file, empty cons means
 680             then return AbstractTyCon   -- "don't know"; hence Abstract
 681             else case new_or_data of
 682                    DataType -> return (mkDataTyConRhs data_cons)
 683                    NewType  ->
 684                        ASSERT( isSingleton data_cons )
 685                        mkNewTyConRhs tc_name tycon (head data_cons)
 686         ; buildAlgTyCon tc_name final_tvs stupid_theta tc_rhs is_rec
 687             (want_generic && canDoGenerics data_cons) h98_syntax Nothing
 688         })
 689   ; return [ATyCon tycon]
 690   }
 691   where
 692     is_rec   = calc_isrec tc_name
 693     h98_syntax = case cons of   -- All constructors have same shape
 694                         L _ (ConDecl { con_res = ResTyGADT _ }) : _ -> False
 695                         other -> True
 696
 697 tcTyClDecl1 calc_isrec
 698   (ClassDecl {tcdLName = L _ class_name, tcdTyVars = tvs,
 699               tcdCtxt = ctxt, tcdMeths = meths,
 700               tcdFDs = fundeps, tcdSigs = sigs, tcdATs = ats} )
 701   = tcTyVarBndrs tvs            $ \ tvs' -> do
 702   { ctxt' <- tcHsKindedContext ctxt
 703   ; fds' <- mappM (addLocM tc_fundep) fundeps
 704   ; atss <- mappM (addLocM (tcTyClDecl1 (const Recursive))) ats
 705   ; let ats' = zipWith setTyThingPoss atss (map (tcdTyVars . unLoc) ats)
 706   ; sig_stuff <- tcClassSigs class_name sigs meths
 707   ; clas <- fixM (\ clas ->
 708                 let     -- This little knot is just so we can get
 709                         -- hold of the name of the class TyCon, which we
 710                         -- need to look up its recursiveness
 711                     tycon_name = tyConName (classTyCon clas)
 712                     tc_isrec = calc_isrec tycon_name
 713                 in
 714                 buildClass class_name tvs' ctxt' fds' ats'
 715                            sig_stuff tc_isrec)
 716   ; return (AClass clas : ats')
 717       -- NB: Order is important due to the call to `mkGlobalThings' when
 718       --     tying the the type and class declaration type checking knot.
 719   }
 720   where
 721     tc_fundep (tvs1, tvs2) = do { tvs1' <- mappM tcLookupTyVar tvs1 ;
 722                                 ; tvs2' <- mappM tcLookupTyVar tvs2 ;
 723                                 ; return (tvs1', tvs2') }
 724
 725     -- For each AT argument compute the position of the corresponding class
 726     -- parameter in the class head.  This will later serve as a permutation
 727     -- vector when checking the validity of instance declarations.
 728     setTyThingPoss [ATyCon tycon] atTyVars =
 729       let classTyVars = hsLTyVarNames tvs
 730           poss        =   catMaybes
 731                         . map (`elemIndex` classTyVars)
 732                         . hsLTyVarNames
 733                         $ atTyVars
 734                      -- There will be no Nothing, as we already passed renaming
 735       in
 736       ATyCon (setTyConArgPoss tycon poss)
 737     setTyThingPoss _              _ = panic "TcTyClsDecls.setTyThingPoss"
 738
 739 tcTyClDecl1 calc_isrec
 740   (ForeignType {tcdLName = L _ tc_name, tcdExtName = tc_ext_name})
 741   = returnM [ATyCon (mkForeignTyCon tc_name tc_ext_name liftedTypeKind 0)]
 742
 743 -----------------------------------
 744 tcConDecl :: Bool               -- True <=> -funbox-strict_fields
 745           -> NewOrData
 746           -> TyCon -> [TyVar]
 747           -> ConDecl Name
 748           -> TcM DataCon
 749
 750 tcConDecl unbox_strict NewType tycon tc_tvs     -- Newtypes
 751           (ConDecl name _ ex_tvs ex_ctxt details ResTyH98 _)
 752   = do  { let tc_datacon field_lbls arg_ty
 753                 = do { arg_ty' <- tcHsKindedType arg_ty -- No bang on newtype
 754                      ; buildDataCon (unLoc name) False {- Prefix -}
 755                                     [NotMarkedStrict]
 756                                     (map unLoc field_lbls)
 757                                     tc_tvs []  -- No existentials
 758                                     [] []      -- No equalities, predicates
 759                                     [arg_ty']
 760                                     tycon }
 761
 762                 -- Check that a newtype has no existential stuff
 763         ; checkTc (null ex_tvs && null (unLoc ex_ctxt)) (newtypeExError name)
 764
 765         ; case details of
 766             PrefixCon [arg_ty]           -> tc_datacon [] arg_ty
 767             RecCon [HsRecField field_lbl arg_ty _] -> tc_datacon [field_lbl] arg_ty
 768             other                        ->
 769               failWithTc (newtypeFieldErr name (length (hsConArgs details)))
 770                         -- Check that the constructor has exactly one field
 771         }
 772
 773 tcConDecl unbox_strict DataType tycon tc_tvs    -- Data types
 774           (ConDecl name _ tvs ctxt details res_ty _)
 775   = tcTyVarBndrs tvs            $ \ tvs' -> do
 776     { ctxt' <- tcHsKindedContext ctxt
 777     ; (univ_tvs, ex_tvs, eq_preds, data_tc) <- tcResultType tycon tc_tvs tvs' res_ty
 778     ; let
 779         -- Tiresome: tidy the tyvar binders, since tc_tvs and tvs' may have the same OccNames
 780         tc_datacon is_infix field_lbls btys
 781           = do { let bangs = map getBangStrictness btys
 782                ; arg_tys <- mappM tcHsBangType btys
 783                ; buildDataCon (unLoc name) is_infix
 784                     (argStrictness unbox_strict bangs arg_tys)
 785                     (map unLoc field_lbls)
 786                     univ_tvs ex_tvs eq_preds ctxt' arg_tys
 787                     data_tc }
 788                 -- NB:  we put data_tc, the type constructor gotten from the
 789                 --      constructor type signature into the data constructor;
 790                 --      that way checkValidDataCon can complain if it's wrong.
 791
 792     ; case details of
 793         PrefixCon btys     -> tc_datacon False [] btys
 794         InfixCon bty1 bty2 -> tc_datacon True  [] [bty1,bty2]
 795         RecCon fields      -> tc_datacon False field_names btys
 796                            where
 797                               (field_names, btys) = unzip [ (n, t) | HsRecField n t _ <- fields ]
 798
 799     }
 800
 801 tcResultType :: TyCon
 802              -> [TyVar]         -- data T a b c = ...
 803              -> [TyVar]         -- where MkT :: forall a b c. ...
 804              -> ResType Name
 805              -> TcM ([TyVar],           -- Universal
 806                      [TyVar],           -- Existential (distinct OccNames from univs)
 807                      [(TyVar,Type)],    -- Equality predicates
 808                      TyCon)             -- TyCon given in the ResTy
 809         -- We don't check that the TyCon given in the ResTy is
 810         -- the same as the parent tycon, becuase we are in the middle
 811         -- of a recursive knot; so it's postponed until checkValidDataCon
 812
 813 tcResultType decl_tycon tc_tvs dc_tvs ResTyH98
 814   = return (tc_tvs, dc_tvs, [], decl_tycon)
 815         -- In H98 syntax the dc_tvs are the existential ones
 816         --      data T a b c = forall d e. MkT ...
 817         -- The {a,b,c} are tc_tvs, and {d,e} are dc_tvs
 818
 819 tcResultType _ tc_tvs dc_tvs (ResTyGADT res_ty)
 820         -- E.g.  data T a b c where
 821         --         MkT :: forall x y z. T (x,y) z z
 822         -- Then we generate
 823         --      ([a,z,c], [x,y], [a:=:(x,y), c:=:z], T)
 824
 825   = do  { (dc_tycon, res_tys) <- tcLHsConResTy res_ty
 826
 827         ; let univ_tvs = choose_univs [] tidy_tc_tvs res_tys
 828                 -- Each univ_tv is either a dc_tv or a tc_tv
 829               ex_tvs = dc_tvs `minusList` univ_tvs
 830               eq_spec = [ (tv, ty) | (tv,ty) <- univ_tvs `zip` res_tys,
 831                                       tv `elem` tc_tvs]
 832         ; return (univ_tvs, ex_tvs, eq_spec, dc_tycon) }
 833   where
 834         -- choose_univs uses the res_ty itself if it's a type variable
 835         -- and hasn't already been used; otherwise it uses one of the tc_tvs
 836     choose_univs used tc_tvs []
 837         = ASSERT( null tc_tvs ) []
 838     choose_univs used (tc_tv:tc_tvs) (res_ty:res_tys)
 839         | Just tv <- tcGetTyVar_maybe res_ty, not (tv `elem` used)
 840         = tv    : choose_univs (tv:used) tc_tvs res_tys
 841         | otherwise
 842         = tc_tv : choose_univs used tc_tvs res_tys
 843
 844         -- NB: tc_tvs and dc_tvs are distinct, but
 845         -- we want them to be *visibly* distinct, both for
 846         -- interface files and general confusion.  So rename
 847         -- the tc_tvs, since they are not used yet (no
 848         -- consequential renaming needed)
 849     init_occ_env     = initTidyOccEnv (map getOccName dc_tvs)
 850     (_, tidy_tc_tvs) = mapAccumL tidy_one init_occ_env tc_tvs
 851     tidy_one env tv  = (env', setTyVarName tv (tidyNameOcc name occ'))
 852               where
 853                  name = tyVarName tv
 854                  (env', occ') = tidyOccName env (getOccName name)
 855
 856               -------------------
 857 argStrictness :: Bool           -- True <=> -funbox-strict_fields
 858               -> [HsBang]
 859               -> [TcType] -> [StrictnessMark]
 860 argStrictness unbox_strict bangs arg_tys
 861  = ASSERT( length bangs == length arg_tys )
 862    zipWith (chooseBoxingStrategy unbox_strict) arg_tys bangs
 863
 864 -- We attempt to unbox/unpack a strict field when either:
 865 --   (i)  The field is marked '!!', or
 866 --   (ii) The field is marked '!', and the -funbox-strict-fields flag is on.
 867 --
 868 -- We have turned off unboxing of newtypes because coercions make unboxing
 869 -- and reboxing more complicated
 870 chooseBoxingStrategy :: Bool -> TcType -> HsBang -> StrictnessMark
 871 chooseBoxingStrategy unbox_strict_fields arg_ty bang
 872   = case bang of
 873         HsNoBang                                    -> NotMarkedStrict
 874         HsStrict | unbox_strict_fields
 875                    && can_unbox arg_ty              -> MarkedUnboxed
 876         HsUnbox  | can_unbox arg_ty                 -> MarkedUnboxed
 877         other                                       -> MarkedStrict
 878   where
 879     -- we can unbox if the type is a chain of newtypes with a product tycon
 880     -- at the end
 881     can_unbox arg_ty = case splitTyConApp_maybe arg_ty of
 882                    Nothing                      -> False
 883                    Just (arg_tycon, tycon_args) ->
 884                        not (isRecursiveTyCon arg_tycon) &&      -- Note [Recusive unboxing]
 885                        isProductTyCon arg_tycon &&
 886                        (if isNewTyCon arg_tycon then
 887                             can_unbox (newTyConInstRhs arg_tycon tycon_args)
 888                         else True)
 889 \end{code}
 890
 891 Note [Recursive unboxing]
 892 ~~~~~~~~~~~~~~~~~~~~~~~~~
 893 Be careful not to try to unbox this!
 894         data T = MkT !T Int
 895 But it's the *argument* type that matters. This is fine:
 896         data S = MkS S !Int
 897 because Int is non-recursive.
 898
 899 %************************************************************************
 900 %*                                                                      *
 901 \subsection{Dependency analysis}
 902 %*                                                                      *
 903 %************************************************************************
 904
 905 Validity checking is done once the mutually-recursive knot has been
 906 tied, so we can look at things freely.
 907
 908 \begin{code}
 909 checkCycleErrs :: [LTyClDecl Name] -> TcM ()
 910 checkCycleErrs tyclss
 911   | null cls_cycles
 912   = return ()
 913   | otherwise
 914   = do  { mappM_ recClsErr cls_cycles
 915         ; failM }       -- Give up now, because later checkValidTyCl
 916                         -- will loop if the synonym is recursive
 917   where
 918     cls_cycles = calcClassCycles tyclss
 919
 920 checkValidTyCl :: TyClDecl Name -> TcM ()
 921 -- We do the validity check over declarations, rather than TyThings
 922 -- only so that we can add a nice context with tcAddDeclCtxt
 923 checkValidTyCl decl
 924   = tcAddDeclCtxt decl $
 925     do  { thing <- tcLookupLocatedGlobal (tcdLName decl)
 926         ; traceTc (text "Validity of" <+> ppr thing)
 927         ; case thing of
 928             ATyCon tc -> checkValidTyCon tc
 929             AClass cl -> checkValidClass cl
 930         ; traceTc (text "Done validity of" <+> ppr thing)
 931         }
 932
 933 -------------------------
 934 -- For data types declared with record syntax, we require
 935 -- that each constructor that has a field 'f'
 936 --      (a) has the same result type
 937 --      (b) has the same type for 'f'
 938 -- module alpha conversion of the quantified type variables
 939 -- of the constructor.
 940
 941 checkValidTyCon :: TyCon -> TcM ()
 942 checkValidTyCon tc
 943   | isSynTyCon tc
 944   = case synTyConRhs tc of
 945       OpenSynTyCon _  -> return ()
 946       SynonymTyCon ty -> checkValidType syn_ctxt ty
 947   | otherwise
 948   =     -- Check the context on the data decl
 949     checkValidTheta (DataTyCtxt name) (tyConStupidTheta tc)     `thenM_`
 950
 951         -- Check arg types of data constructors
 952     mappM_ (checkValidDataCon tc) data_cons                     `thenM_`
 953
 954         -- Check that fields with the same name share a type
 955     mappM_ check_fields groups
 956
 957   where
 958     syn_ctxt  = TySynCtxt name
 959     name      = tyConName tc
 960     data_cons = tyConDataCons tc
 961
 962     groups = equivClasses cmp_fld (concatMap get_fields data_cons)
 963     cmp_fld (f1,_) (f2,_) = f1 `compare` f2
 964     get_fields con = dataConFieldLabels con `zip` repeat con
 965         -- dataConFieldLabels may return the empty list, which is fine
 966
 967     -- See Note [GADT record selectors] in MkId.lhs
 968     -- We must check (a) that the named field has the same
 969     --                   type in each constructor
 970     --               (b) that those constructors have the same result type
 971     --
 972     -- However, the constructors may have differently named type variable
 973     -- and (worse) we don't know how the correspond to each other.  E.g.
 974     --     C1 :: forall a b. { f :: a, g :: b } -> T a b
 975     --     C2 :: forall d c. { f :: c, g :: c } -> T c d
 976     --
 977     -- So what we do is to ust Unify.tcMatchTys to compare the first candidate's
 978     -- result type against other candidates' types BOTH WAYS ROUND.
 979     -- If they magically agrees, take the substitution and
 980     -- apply them to the latter ones, and see if they match perfectly.
 981     check_fields fields@((label, con1) : other_fields)
 982         -- These fields all have the same name, but are from
 983         -- different constructors in the data type
 984         = recoverM (return ()) $ mapM_ checkOne other_fields
 985                 -- Check that all the fields in the group have the same type
 986                 -- NB: this check assumes that all the constructors of a given
 987                 -- data type use the same type variables
 988         where
 989         tvs1 = mkVarSet (dataConAllTyVars con1)
 990         res1 = dataConResTys con1
 991         fty1 = dataConFieldType con1 label
 992
 993         checkOne (_, con2)    -- Do it bothways to ensure they are structurally identical
 994             = do { checkFieldCompat label con1 con2 tvs1 res1 res2 fty1 fty2
 995                  ; checkFieldCompat label con2 con1 tvs2 res2 res1 fty2 fty1 }
 996             where
 997                 tvs2 = mkVarSet (dataConAllTyVars con2)
 998                 res2 = dataConResTys con2
 999                 fty2 = dataConFieldType con2 label
1000
1001 checkFieldCompat fld con1 con2 tvs1 res1 res2 fty1 fty2
1002   = do  { checkTc (isJust mb_subst1) (resultTypeMisMatch fld con1 con2)
1003         ; checkTc (isJust mb_subst2) (fieldTypeMisMatch fld con1 con2) }
1004   where
1005     mb_subst1 = tcMatchTys tvs1 res1 res2
1006     mb_subst2 = tcMatchTyX tvs1 (expectJust "checkFieldCompat" mb_subst1) fty1 fty2
1007
1008 -------------------------------
1009 checkValidDataCon :: TyCon -> DataCon -> TcM ()
1010 checkValidDataCon tc con
1011   = setSrcSpan (srcLocSpan (getSrcLoc con))     $
1012     addErrCtxt (dataConCtxt con)                $
1013     do  { checkTc (dataConTyCon con == tc) (badDataConTyCon con)
1014         ; checkValidType ctxt (dataConUserType con) }
1015   where
1016     ctxt = ConArgCtxt (dataConName con)
1017
1018 -------------------------------
1019 checkValidClass :: Class -> TcM ()
1020 checkValidClass cls
1021   = do  {       -- CHECK ARITY 1 FOR HASKELL 1.4
1022           gla_exts <- doptM Opt_GlasgowExts
1023
1024         -- Check that the class is unary, unless GlaExs
1025         ; checkTc (notNull tyvars) (nullaryClassErr cls)
1026         ; checkTc (gla_exts || unary) (classArityErr cls)
1027
1028         -- Check the super-classes
1029         ; checkValidTheta (ClassSCCtxt (className cls)) theta
1030
1031         -- Check the class operations
1032         ; mappM_ (check_op gla_exts) op_stuff
1033
1034         -- Check that if the class has generic methods, then the
1035         -- class has only one parameter.  We can't do generic
1036         -- multi-parameter type classes!
1037         ; checkTc (unary || no_generics) (genericMultiParamErr cls)
1038         }
1039   where
1040     (tyvars, theta, _, op_stuff) = classBigSig cls
1041     unary       = isSingleton tyvars
1042     no_generics = null [() | (_, GenDefMeth) <- op_stuff]
1043
1044     check_op gla_exts (sel_id, dm)
1045       = addErrCtxt (classOpCtxt sel_id tau) $ do
1046         { checkValidTheta SigmaCtxt (tail theta)
1047                 -- The 'tail' removes the initial (C a) from the
1048                 -- class itself, leaving just the method type
1049
1050         ; checkValidType (FunSigCtxt op_name) tau
1051
1052                 -- Check that the type mentions at least one of
1053                 -- the class type variables...or at least one reachable
1054                 -- from one of the class variables.  Example: tc223
1055                 --   class Error e => Game b mv e | b -> mv e where
1056                 --      newBoard :: MonadState b m => m ()
1057                 -- Here, MonadState has a fundep m->b, so newBoard is fine
1058         ; let grown_tyvars = grow theta (mkVarSet tyvars)
1059         ; checkTc (tyVarsOfType tau `intersectsVarSet` grown_tyvars)
1060                   (noClassTyVarErr cls sel_id)
1061
1062                 -- Check that for a generic method, the type of
1063                 -- the method is sufficiently simple
1064         ; checkTc (dm /= GenDefMeth || validGenericMethodType tau)
1065                   (badGenericMethodType op_name op_ty)
1066         }
1067         where
1068           op_name = idName sel_id
1069           op_ty   = idType sel_id
1070           (_,theta1,tau1) = tcSplitSigmaTy op_ty
1071           (_,theta2,tau2)  = tcSplitSigmaTy tau1
1072           (theta,tau) | gla_exts  = (theta1 ++ theta2, tau2)
1073                       | otherwise = (theta1,           mkPhiTy (tail theta1) tau1)
1074                 -- Ugh!  The function might have a type like
1075                 --      op :: forall a. C a => forall b. (Eq b, Eq a) => tau2
1076                 -- With -fglasgow-exts, we want to allow this, even though the inner
1077                 -- forall has an (Eq a) constraint.  Whereas in general, each constraint
1078                 -- in the context of a for-all must mention at least one quantified
1079                 -- type variable.  What a mess!
1080
1081
1082 ---------------------------------------------------------------------
1083 resultTypeMisMatch field_name con1 con2
1084   = vcat [sep [ptext SLIT("Constructors") <+> ppr con1 <+> ptext SLIT("and") <+> ppr con2,
1085                 ptext SLIT("have a common field") <+> quotes (ppr field_name) <> comma],
1086           nest 2 $ ptext SLIT("but have different result types")]
1087 fieldTypeMisMatch field_name con1 con2
1088   = sep [ptext SLIT("Constructors") <+> ppr con1 <+> ptext SLIT("and") <+> ppr con2,
1089          ptext SLIT("give different types for field"), quotes (ppr field_name)]
1090
1091 dataConCtxt con = ptext SLIT("In the definition of data constructor") <+> quotes (ppr con)
1092
1093 classOpCtxt sel_id tau = sep [ptext SLIT("When checking the class method:"),
1094                               nest 2 (ppr sel_id <+> dcolon <+> ppr tau)]
1095
1096 nullaryClassErr cls
1097   = ptext SLIT("No parameters for class")  <+> quotes (ppr cls)
1098
1099 classArityErr cls
1100   = vcat [ptext SLIT("Too many parameters for class") <+> quotes (ppr cls),
1101           parens (ptext SLIT("Use -fglasgow-exts to allow multi-parameter classes"))]
1102
1103 noClassTyVarErr clas op
1104   = sep [ptext SLIT("The class method") <+> quotes (ppr op),
1105          ptext SLIT("mentions none of the type variables of the class") <+>
1106                 ppr clas <+> hsep (map ppr (classTyVars clas))]
1107
1108 genericMultiParamErr clas
1109   = ptext SLIT("The multi-parameter class") <+> quotes (ppr clas) <+>
1110     ptext SLIT("cannot have generic methods")
1111
1112 badGenericMethodType op op_ty
1113   = hang (ptext SLIT("Generic method type is too complex"))
1114        4 (vcat [ppr op <+> dcolon <+> ppr op_ty,
1115                 ptext SLIT("You can only use type variables, arrows, lists, and tuples")])
1116
1117 recSynErr syn_decls
1118   = setSrcSpan (getLoc (head sorted_decls)) $
1119     addErr (sep [ptext SLIT("Cycle in type synonym declarations:"),
1120                  nest 2 (vcat (map ppr_decl sorted_decls))])
1121   where
1122     sorted_decls = sortLocated syn_decls
1123     ppr_decl (L loc decl) = ppr loc <> colon <+> ppr decl
1124
1125 recClsErr cls_decls
1126   = setSrcSpan (getLoc (head sorted_decls)) $
1127     addErr (sep [ptext SLIT("Cycle in class declarations (via superclasses):"),
1128                  nest 2 (vcat (map ppr_decl sorted_decls))])
1129   where
1130     sorted_decls = sortLocated cls_decls
1131     ppr_decl (L loc decl) = ppr loc <> colon <+> ppr (decl { tcdSigs = [] })
1132
1133 sortLocated :: [Located a] -> [Located a]
1134 sortLocated things = sortLe le things
1135   where
1136     le (L l1 _) (L l2 _) = l1 <= l2
1137
1138 badDataConTyCon data_con
1139   = hang (ptext SLIT("Data constructor") <+> quotes (ppr data_con) <+>
1140                 ptext SLIT("returns type") <+> quotes (ppr (dataConTyCon data_con)))
1141        2 (ptext SLIT("instead of its parent type"))
1142
1143 badGadtDecl tc_name
1144   = vcat [ ptext SLIT("Illegal generalised algebraic data declaration for") <+> quotes (ppr tc_name)
1145          , nest 2 (parens $ ptext SLIT("Use -fglasgow-exts to allow GADTs")) ]
1146
1147 badStupidTheta tc_name
1148   = ptext SLIT("A data type declared in GADT style cannot have a context:") <+> quotes (ppr tc_name)
1149
1150 newtypeConError tycon n
1151   = sep [ptext SLIT("A newtype must have exactly one constructor,"),
1152          nest 2 $ ptext SLIT("but") <+> quotes (ppr tycon) <+> ptext SLIT("has") <+> speakN n ]
1153
1154 newtypeExError con
1155   = sep [ptext SLIT("A newtype constructor cannot have an existential context,"),
1156          nest 2 $ ptext SLIT("but") <+> quotes (ppr con) <+> ptext SLIT("does")]
1157
1158 newtypeFieldErr con_name n_flds
1159   = sep [ptext SLIT("The constructor of a newtype must have exactly one field"),
1160          nest 2 $ ptext SLIT("but") <+> quotes (ppr con_name) <+> ptext SLIT("has") <+> speakN n_flds]
1161
1162 badSigTyDecl tc_name
1163   = vcat [ ptext SLIT("Illegal kind signature") <+>
1164            quotes (ppr tc_name)
1165          , nest 2 (parens $ ptext SLIT("Use -fglasgow-exts to allow kind signatures")) ]
1166
1167 badFamInstDecl tc_name
1168   = vcat [ ptext SLIT("Illegal family instance for") <+>
1169            quotes (ppr tc_name)
1170          , nest 2 (parens $ ptext SLIT("Use -findexed-types to allow indexed type families")) ]
1171
1172 badGadtIdxTyDecl tc_name
1173   = vcat [ ptext SLIT("Illegal generalised algebraic data declaration for") <+>
1174            quotes (ppr tc_name)
1175          , nest 2 (parens $ ptext SLIT("Family instances can not yet use GADT declarations")) ]
1176
1177 tooManyParmsErr tc_name
1178   = ptext SLIT("Family instance has too many parameters:") <+>
1179     quotes (ppr tc_name)
1180
1181 tooFewParmsErr tc_name
1182   = ptext SLIT("Family instance has too few parameters:") <+>
1183     quotes (ppr tc_name)
1184
1185 badBootFamInstDeclErr =
1186   ptext SLIT("Illegal family instance in hs-boot file")
1187
1188 wrongKindOfFamily family =
1189   ptext SLIT("Wrong category of family instance; declaration was for a") <+>
1190   kindOfFamily
1191   where
1192     kindOfFamily | isSynTyCon  family = ptext SLIT("type synonym")
1193                  | isDataTyCon family = ptext SLIT("data type")
1194                  | isNewTyCon  family = ptext SLIT("newtype")
1195
1196 emptyConDeclsErr tycon
1197   = sep [quotes (ppr tycon) <+> ptext SLIT("has no constructors"),
1198          nest 2 $ ptext SLIT("(-fglasgow-exts permits this)")]
1199 \end{code}