compiler/typecheck/TcTyClsDecls.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1996-1998
   3 %
   4 \section[TcTyClsDecls]{Typecheck type and class declarations}
   5
   6 \begin{code}
   7 module TcTyClsDecls (
   8         tcTyAndClassDecls, tcIdxTyInstDecl
   9     ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( TyClDecl(..),  HsConDetails(..), HsTyVarBndr(..),
  14                           ConDecl(..),   Sig(..), NewOrData(..), ResType(..),
  15                           tyClDeclTyVars, isSynDecl, isClassDecl, isIdxTyDecl,
  16                           isKindSigDecl, hsConArgs, LTyClDecl, tcdName,
  17                           hsTyVarName, LHsTyVarBndr, LHsType
  18                         )
  19 import HsTypes          ( HsBang(..), getBangStrictness )
  20 import BasicTypes       ( RecFlag(..), StrictnessMark(..) )
  21 import HscTypes         ( implicitTyThings, ModDetails )
  22 import BuildTyCl        ( buildClass, buildAlgTyCon, buildSynTyCon, buildDataCon,
  23                           mkDataTyConRhs, mkNewTyConRhs )
  24 import TcRnMonad
  25 import TcEnv            ( TyThing(..),
  26                           tcLookupLocated, tcLookupLocatedGlobal,
  27                           tcExtendGlobalEnv, tcExtendKindEnv, tcExtendKindEnvTvs,
  28                           tcExtendRecEnv, tcLookupTyVar, InstInfo )
  29 import TcTyDecls        ( calcRecFlags, calcClassCycles, calcSynCycles )
  30 import TcClassDcl       ( tcClassSigs, tcAddDeclCtxt )
  31 import TcHsType         ( kcHsTyVars, kcHsLiftedSigType, kcHsType,
  32                           kcHsContext, tcTyVarBndrs, tcHsKindedType, tcHsKindedContext,
  33                           kcHsSigType, tcHsBangType, tcLHsConResTy,
  34                           tcDataKindSig, kcCheckHsType )
  35 import TcMType          ( newKindVar, checkValidTheta, checkValidType,
  36                           -- checkFreeness,
  37                           UserTypeCtxt(..), SourceTyCtxt(..) )
  38 import TcType           ( TcKind, TcType, Type, tyVarsOfType, mkPhiTy,
  39                           mkArrowKind, liftedTypeKind, mkTyVarTys,
  40                           tcSplitSigmaTy, tcEqTypes, tcGetTyVar_maybe )
  41 import Type             ( PredType(..), splitTyConApp_maybe, mkTyVarTy,
  42                           newTyConInstRhs, isLiftedTypeKind, Kind
  43                           -- pprParendType, pprThetaArrow
  44                         )
  45 import Generics         ( validGenericMethodType, canDoGenerics )
  46 import Class            ( Class, className, classTyCon, DefMeth(..), classBigSig, classTyVars )
  47 import TyCon            ( TyCon, AlgTyConRhs( AbstractTyCon, OpenDataTyCon,
  48                                               OpenNewTyCon ),
  49                           SynTyConRhs( OpenSynTyCon, SynonymTyCon ),
  50                           tyConDataCons, mkForeignTyCon, isProductTyCon,
  51                           isRecursiveTyCon, isOpenTyCon,
  52                           tyConStupidTheta, synTyConRhs, isSynTyCon, tyConName,
  53                           isNewTyCon )
  54 import DataCon          ( DataCon, dataConUserType, dataConName,
  55                           dataConFieldLabels, dataConTyCon, dataConAllTyVars,
  56                           dataConFieldType, dataConResTys )
  57 import Var              ( TyVar, idType, idName )
  58 import VarSet           ( elemVarSet, mkVarSet )
  59 import Name             ( Name, getSrcLoc )
  60 import Outputable
  61 import Maybe            ( isJust, fromJust, isNothing )
  62 import Maybes           ( expectJust )
  63 import Unify            ( tcMatchTys, tcMatchTyX )
  64 import Util             ( zipLazy, isSingleton, notNull, sortLe )
  65 import List             ( partition )
  66 import SrcLoc           ( Located(..), unLoc, getLoc, srcLocSpan )
  67 import ListSetOps       ( equivClasses, minusList )
  68 import List             ( delete )
  69 import Digraph          ( SCC(..) )
  70 import DynFlags         ( DynFlag( Opt_GlasgowExts, Opt_Generics,
  71                                         Opt_UnboxStrictFields ) )
  72 \end{code}
  73
  74
  75 %************************************************************************
  76 %*                                                                      *
  77 \subsection{Type checking for type and class declarations}
  78 %*                                                                      *
  79 %************************************************************************
  80
  81 Dealing with a group
  82 ~~~~~~~~~~~~~~~~~~~~
  83 Consider a mutually-recursive group, binding
  84 a type constructor T and a class C.
  85
  86 Step 1:         getInitialKind
  87         Construct a KindEnv by binding T and C to a kind variable
  88
  89 Step 2:         kcTyClDecl
  90         In that environment, do a kind check
  91
  92 Step 3: Zonk the kinds
  93
  94 Step 4:         buildTyConOrClass
  95         Construct an environment binding T to a TyCon and C to a Class.
  96         a) Their kinds comes from zonking the relevant kind variable
  97         b) Their arity (for synonyms) comes direct from the decl
  98         c) The funcional dependencies come from the decl
  99         d) The rest comes a knot-tied binding of T and C, returned from Step 4
 100         e) The variances of the tycons in the group is calculated from
 101                 the knot-tied stuff
 102
 103 Step 5:         tcTyClDecl1
 104         In this environment, walk over the decls, constructing the TyCons and Classes.
 105         This uses in a strict way items (a)-(c) above, which is why they must
 106         be constructed in Step 4. Feed the results back to Step 4.
 107         For this step, pass the is-recursive flag as the wimp-out flag
 108         to tcTyClDecl1.
 109
 110
 111 Step 6:         Extend environment
 112         We extend the type environment with bindings not only for the TyCons and Classes,
 113         but also for their "implicit Ids" like data constructors and class selectors
 114
 115 Step 7:         checkValidTyCl
 116         For a recursive group only, check all the decls again, just
 117         to check all the side conditions on validity.  We could not
 118         do this before because we were in a mutually recursive knot.
 119
 120 Identification of recursive TyCons
 121 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 122 The knot-tying parameters: @rec_details_list@ is an alist mapping @Name@s to
 123 @TyThing@s.
 124
 125 Identifying a TyCon as recursive serves two purposes
 126
 127 1.  Avoid infinite types.  Non-recursive newtypes are treated as
 128 "transparent", like type synonyms, after the type checker.  If we did
 129 this for all newtypes, we'd get infinite types.  So we figure out for
 130 each newtype whether it is "recursive", and add a coercion if so.  In
 131 effect, we are trying to "cut the loops" by identifying a loop-breaker.
 132
 133 2.  Avoid infinite unboxing.  This is nothing to do with newtypes.
 134 Suppose we have
 135         data T = MkT Int T
 136         f (MkT x t) = f t
 137 Well, this function diverges, but we don't want the strictness analyser
 138 to diverge.  But the strictness analyser will diverge because it looks
 139 deeper and deeper into the structure of T.   (I believe there are
 140 examples where the function does something sane, and the strictness
 141 analyser still diverges, but I can't see one now.)
 142
 143 Now, concerning (1), the FC2 branch currently adds a coercion for ALL
 144 newtypes.  I did this as an experiment, to try to expose cases in which
 145 the coercions got in the way of optimisations.  If it turns out that we
 146 can indeed always use a coercion, then we don't risk recursive types,
 147 and don't need to figure out what the loop breakers are.
 148
 149 For newtype *families* though, we will always have a coercion, so they
 150 are always loop breakers!  So you can easily adjust the current
 151 algorithm by simply treating all newtype families as loop breakers (and
 152 indeed type families).  I think.
 153
 154 \begin{code}
 155 tcTyAndClassDecls :: ModDetails -> [LTyClDecl Name]
 156                    -> TcM TcGblEnv      -- Input env extended by types and classes
 157                                         -- and their implicit Ids,DataCons
 158 tcTyAndClassDecls boot_details allDecls
 159   = do  {       -- Omit instances of indexed types; they are handled together
 160                 -- with the *heads* of class instances
 161         ; let decls = filter (not . isIdxTyDecl . unLoc) allDecls
 162
 163                 -- First check for cyclic type synonysm or classes
 164                 -- See notes with checkCycleErrs
 165         ; checkCycleErrs decls
 166         ; mod <- getModule
 167         ; traceTc (text "tcTyAndCl" <+> ppr mod)
 168         ; (syn_tycons, alg_tyclss) <- fixM (\ ~(rec_syn_tycons, rec_alg_tyclss) ->
 169           do    { let { -- Calculate variances and rec-flag
 170                       ; (syn_decls, alg_decls) = partition (isSynDecl . unLoc)
 171                                                    decls }
 172                         -- Extend the global env with the knot-tied results
 173                         -- for data types and classes
 174                         --
 175                         -- We must populate the environment with the loop-tied T's right
 176                         -- away, because the kind checker may "fault in" some type
 177                         -- constructors that recursively mention T
 178                 ; let { gbl_things = mkGlobalThings alg_decls rec_alg_tyclss }
 179                 ; tcExtendRecEnv gbl_things $ do
 180
 181                         -- Kind-check the declarations
 182                 { (kc_syn_decls, kc_alg_decls) <- kcTyClDecls syn_decls alg_decls
 183
 184                 ; let { calc_rec  = calcRecFlags boot_details rec_alg_tyclss
 185                       ; tc_decl   = addLocM (tcTyClDecl calc_rec) }
 186                         -- Type-check the type synonyms, and extend the envt
 187                 ; syn_tycons <- tcSynDecls kc_syn_decls
 188                 ; tcExtendGlobalEnv syn_tycons $ do
 189
 190                         -- Type-check the data types and classes
 191                 { alg_tyclss <- mappM tc_decl kc_alg_decls
 192                 ; return (syn_tycons, alg_tyclss)
 193             }}})
 194         -- Finished with knot-tying now
 195         -- Extend the environment with the finished things
 196         ; tcExtendGlobalEnv (syn_tycons ++ alg_tyclss) $ do
 197
 198         -- Perform the validity check
 199         { traceTc (text "ready for validity check")
 200         ; mappM_ (addLocM checkValidTyCl) decls
 201         ; traceTc (text "done")
 202
 203         -- Add the implicit things;
 204         -- we want them in the environment because
 205         -- they may be mentioned in interface files
 206         ; let { implicit_things = concatMap implicitTyThings alg_tyclss }
 207         ; traceTc ((text "Adding" <+> ppr alg_tyclss) $$ (text "and" <+> ppr implicit_things))
 208         ; tcExtendGlobalEnv implicit_things getGblEnv
 209     }}
 210
 211 mkGlobalThings :: [LTyClDecl Name]      -- The decls
 212                -> [TyThing]             -- Knot-tied, in 1-1 correspondence with the decls
 213                -> [(Name,TyThing)]
 214 -- Driven by the Decls, and treating the TyThings lazily
 215 -- make a TypeEnv for the new things
 216 mkGlobalThings decls things
 217   = map mk_thing (decls `zipLazy` things)
 218   where
 219     mk_thing (L _ (ClassDecl {tcdLName = L _ name}), ~(AClass cl))
 220          = (name, AClass cl)
 221     mk_thing (L _ decl, ~(ATyCon tc))
 222          = (tcdName decl, ATyCon tc)
 223 \end{code}
 224
 225
 226 %************************************************************************
 227 %*                                                                      *
 228 \subsection{Type checking instances of indexed types}
 229 %*                                                                      *
 230 %************************************************************************
 231
 232 Instances of indexed types are somewhat of a hybrid.  They are processed
 233 together with class instance heads, but can contain data constructors and hence
 234 they share a lot of kinding and type checking code with ordinary algebraic
 235 data types (and GADTs).
 236
 237 \begin{code}
 238 tcIdxTyInstDecl :: LTyClDecl Name -> TcM (Maybe InstInfo)  -- Nothing if error
 239 tcIdxTyInstDecl (L loc decl)
 240   =     -- Prime error recovery, set source location
 241     recoverM (returnM Nothing)  $
 242     setSrcSpan loc              $
 243     tcAddDeclCtxt decl          $
 244     do { -- indexed data types require -fglasgow-exts and can't be in an
 245          -- hs-boot file
 246        ; gla_exts <- doptM Opt_GlasgowExts
 247        ; is_boot  <- tcIsHsBoot   -- Are we compiling an hs-boot file?
 248        ; checkTc gla_exts      $ badIdxTyDecl (tcdLName decl)
 249        ; checkTc (not is_boot) $ badBootTyIdxDeclErr
 250
 251          -- perform kind and type checking
 252        ; tcIdxTyInstDecl1 decl
 253        }
 254
 255 tcIdxTyInstDecl1 :: TyClDecl Name -> TcM (Maybe InstInfo)  -- Nothing if error
 256
 257 tcIdxTyInstDecl1 (decl@TySynonym {})
 258   = kcIdxTyPats decl $ \k_tvs k_typats resKind ->
 259     do { -- kind check the right hand side of the type equation
 260        ; k_rhs <- kcCheckHsType (tcdSynRhs decl) resKind
 261
 262          -- type check type equation
 263        ; tcTyVarBndrs k_tvs $ \t_tvs -> do {
 264        ; t_typats <- mappM tcHsKindedType k_typats
 265        ; t_rhs    <- tcHsKindedType k_rhs
 266
 267          -- construct type rewrite rule
 268          -- !!!of the form: forall t_tvs. (tcdLName decl) t_typats = t_rhs
 269        ; return Nothing -- !!!TODO: need InstInfo for indexed types
 270        }}
 271
 272 tcIdxTyInstDecl1 (decl@TyData {tcdND = new_or_data, tcdLName = L _ tc_name,
 273                                tcdCons = cons})
 274   = kcIdxTyPats decl $ \k_tvs k_typats resKind ->
 275     do { -- kind check the data declaration as usual
 276        ; k_decl <- kcDataDecl decl k_tvs
 277        ; k_typats <- mappM tcHsKindedType k_typats
 278        ; let k_ctxt = tcdCtxt decl
 279              k_cons = tcdCons decl
 280
 281          -- result kind must be '*' (otherwise, we have too few patterns)
 282        ; checkTc (isLiftedTypeKind resKind) $ tooFewParmsErr tc_name
 283
 284          -- type check indexed data type declaration
 285        ; tcTyVarBndrs k_tvs $ \t_tvs -> do {
 286        ; unbox_strict <- doptM Opt_UnboxStrictFields
 287
 288          -- Check that we don't use GADT syntax for indexed types
 289        ; checkTc h98_syntax (badGadtIdxTyDecl tc_name)
 290
 291          -- Check that a newtype has exactly one constructor
 292        ; checkTc (new_or_data == DataType || isSingleton cons) $
 293            newtypeConError tc_name (length cons)
 294
 295        ; stupid_theta <- tcHsKindedContext k_ctxt
 296        ; tycon <- fixM (\ tycon -> do
 297              { data_cons <- mappM (addLocM (tcConDecl unbox_strict new_or_data
 298                                                       tycon t_tvs))
 299                                   k_cons
 300              ; tc_rhs <-
 301                  case new_or_data of
 302                    DataType -> return (mkDataTyConRhs data_cons)
 303                    NewType  ->
 304                             ASSERT( isSingleton data_cons )
 305                             mkNewTyConRhs tc_name tycon (head data_cons)
 306                            --vvvvvvv !!! need a new derived tc_name here
 307              ; buildAlgTyCon tc_name t_tvs stupid_theta tc_rhs Recursive
 308                              False h98_syntax
 309                  -- We always assume that indexed types are recursive.  Why?
 310                  -- (1) Due to their open nature, we can never be sure that a
 311                  -- further instance might not introduce a new recursive
 312                  -- dependency.  (2) They are always valid loop breakers as
 313                  -- they involve a coercion.
 314              })
 315
 316          -- construct result
 317          -- !!!twofold: (1) (ATyCon tycon) and (2) an equality axiom
 318        ; return Nothing -- !!!TODO: need InstInfo for indexed types
 319        }}
 320        where
 321          h98_syntax = case cons of      -- All constructors have same shape
 322                         L _ (ConDecl { con_res = ResTyGADT _ }) : _ -> False
 323                         other -> True
 324
 325 -- Kind checking of indexed types
 326 -- -
 327
 328 -- Kind check type patterns and kind annotate the embedded type variables.
 329 --
 330 -- * Here we check that a type instance matches its kind signature, but we do
 331 --   not check whether there is a pattern for each type index; the latter
 332 --   check is only required for type functions.
 333 --
 334 kcIdxTyPats :: TyClDecl Name
 335             -> ([LHsTyVarBndr Name] -> [LHsType Name] -> Kind -> TcM a)
 336                -- ^^kinded tvs         ^^kinded ty pats  ^^res kind
 337             -> TcM a
 338 kcIdxTyPats decl thing_inside
 339   = kcHsTyVars (tcdTyVars decl) $ \tvs ->
 340     do { tc_ty_thing <- tcLookupLocated (tcdLName decl)
 341        ; let tc_kind          = case tc_ty_thing of { AThing k -> k }
 342              (kinds, resKind) = splitKindFunTys tc_kind
 343              hs_typats        = fromJust $ tcdTyPats decl
 344
 345          -- we may not have more parameters than the kind indicates
 346        ; checkTc (length kinds >= length hs_typats) $
 347            tooManyParmsErr (tcdLName decl)
 348
 349          -- type functions can have a higher-kinded result
 350        ; let resultKind = mkArrowKinds (drop (length hs_typats) kinds) resKind
 351        ; typats <- zipWithM kcCheckHsType hs_typats kinds
 352        ; thing_inside tvs typats resultKind
 353        }
 354 \end{code}
 355
 356
 357 %************************************************************************
 358 %*                                                                      *
 359                 Kind checking
 360 %*                                                                      *
 361 %************************************************************************
 362
 363 We need to kind check all types in the mutually recursive group
 364 before we know the kind of the type variables.  For example:
 365
 366 class C a where
 367    op :: D b => a -> b -> b
 368
 369 class D c where
 370    bop :: (Monad c) => ...
 371
 372 Here, the kind of the locally-polymorphic type variable "b"
 373 depends on *all the uses of class D*.  For example, the use of
 374 Monad c in bop's type signature means that D must have kind Type->Type.
 375
 376 However type synonyms work differently.  They can have kinds which don't
 377 just involve (->) and *:
 378         type R = Int#           -- Kind #
 379         type S a = Array# a     -- Kind * -> #
 380         type T a b = (# a,b #)  -- Kind * -> * -> (# a,b #)
 381 So we must infer their kinds from their right-hand sides *first* and then
 382 use them, whereas for the mutually recursive data types D we bring into
 383 scope kind bindings D -> k, where k is a kind variable, and do inference.
 384
 385 Indexed Types
 386 ~~~~~~~~~~~~~
 387 This treatment of type synonyms only applies to Haskell 98-style synonyms.
 388 General type functions can be recursive, and hence, appear in `alg_decls'.
 389
 390 The kind of an indexed type is solely determinded by its kind signature;
 391 hence, only kind signatures participate in the construction of the initial
 392 kind environment (as constructed by `getInitialKind').  In fact, we ignore
 393 instances of indexed types altogether in the following.  However, we need to
 394 include the kind signatures of associated types into the construction of the
 395 initial kind environment.  (This is handled by `allDecls').
 396
 397 \begin{code}
 398 kcTyClDecls syn_decls alg_decls
 399   = do  {       -- First extend the kind env with each data type, class, and
 400                 -- indexed type, mapping them to a type variable
 401           let initialKindDecls = concat [allDecls decl | L _ decl <- alg_decls]
 402         ; alg_kinds <- mappM getInitialKind initialKindDecls
 403         ; tcExtendKindEnv alg_kinds $ do
 404
 405                 -- Now kind-check the type synonyms, in dependency order
 406                 -- We do these differently to data type and classes,
 407                 -- because a type synonym can be an unboxed type
 408                 --      type Foo = Int#
 409                 -- and a kind variable can't unify with UnboxedTypeKind
 410                 -- So we infer their kinds in dependency order
 411         { (kc_syn_decls, syn_kinds) <- kcSynDecls (calcSynCycles syn_decls)
 412         ; tcExtendKindEnv syn_kinds $  do
 413
 414                 -- Now kind-check the data type, class, and kind signatures,
 415                 -- returning kind-annotated decls; we don't kind-check
 416                 -- instances of indexed types yet, but leave this to
 417                 -- `tcInstDecls1'
 418         { kc_alg_decls <- mappM (wrapLocM kcTyClDecl)
 419                             (filter (not . isIdxTyDecl . unLoc) alg_decls)
 420
 421         ; return (kc_syn_decls, kc_alg_decls) }}}
 422   where
 423     -- get all declarations relevant for determining the initial kind
 424     -- environment
 425     allDecls (decl@ClassDecl {tcdATs = ats}) = decl : [ at
 426                                                       | L _ at <- ats
 427                                                       , isKindSigDecl at]
 428     allDecls decl | isIdxTyDecl decl         = []
 429                   | otherwise                = [decl]
 430
 431 ------------------------------------------------------------------------
 432 getInitialKind :: TyClDecl Name -> TcM (Name, TcKind)
 433 -- Only for data type, class, and indexed type declarations
 434 -- Get as much info as possible from the data, class, or indexed type decl,
 435 -- so as to maximise usefulness of error messages
 436 getInitialKind decl
 437   = do  { arg_kinds <- mapM (mk_arg_kind . unLoc) (tyClDeclTyVars decl)
 438         ; res_kind  <- mk_res_kind decl
 439         ; return (tcdName decl, mkArrowKinds arg_kinds res_kind) }
 440   where
 441     mk_arg_kind (UserTyVar _)        = newKindVar
 442     mk_arg_kind (KindedTyVar _ kind) = return kind
 443
 444     mk_res_kind (TyFunction { tcdKind    = kind      }) = return kind
 445     mk_res_kind (TyData     { tcdKindSig = Just kind }) = return kind
 446         -- On GADT-style and data signature declarations we allow a kind
 447         -- signature
 448         --      data T :: *->* where { ... }
 449     mk_res_kind other = return liftedTypeKind
 450
 451
 452 ----------------
 453 kcSynDecls :: [SCC (LTyClDecl Name)]
 454            -> TcM ([LTyClDecl Name],    -- Kind-annotated decls
 455                    [(Name,TcKind)])     -- Kind bindings
 456 kcSynDecls []
 457   = return ([], [])
 458 kcSynDecls (group : groups)
 459   = do  { (decl,  nk)  <- kcSynDecl group
 460         ; (decls, nks) <- tcExtendKindEnv [nk] (kcSynDecls groups)
 461         ; return (decl:decls, nk:nks) }
 462
 463 ----------------
 464 kcSynDecl :: SCC (LTyClDecl Name)
 465            -> TcM (LTyClDecl Name,      -- Kind-annotated decls
 466                    (Name,TcKind))       -- Kind bindings
 467 kcSynDecl (AcyclicSCC ldecl@(L loc decl))
 468   = tcAddDeclCtxt decl  $
 469     kcHsTyVars (tcdTyVars decl) (\ k_tvs ->
 470     do { traceTc (text "kcd1" <+> ppr (unLoc (tcdLName decl)) <+> brackets (ppr (tcdTyVars decl))
 471                         <+> brackets (ppr k_tvs))
 472        ; (k_rhs, rhs_kind) <- kcHsType (tcdSynRhs decl)
 473        ; traceTc (text "kcd2" <+> ppr (unLoc (tcdLName decl)))
 474        ; let tc_kind = foldr (mkArrowKind . kindedTyVarKind) rhs_kind k_tvs
 475        ; return (L loc (decl { tcdTyVars = k_tvs, tcdSynRhs = k_rhs }),
 476                  (unLoc (tcdLName decl), tc_kind)) })
 477
 478 kcSynDecl (CyclicSCC decls)
 479   = do { recSynErr decls; failM }       -- Fail here to avoid error cascade
 480                                         -- of out-of-scope tycons
 481
 482 kindedTyVarKind (L _ (KindedTyVar _ k)) = k
 483
 484 ------------------------------------------------------------------------
 485 kcTyClDecl :: TyClDecl Name -> TcM (TyClDecl Name)
 486         -- Not used for type synonyms (see kcSynDecl)
 487
 488 kcTyClDecl decl@(TyData {})
 489   = ASSERT( not . isJust $ tcdTyPats decl )   -- must not be instance of idx ty
 490     kcTyClDeclBody decl $
 491       kcDataDecl decl
 492
 493 kcTyClDecl decl@(TyFunction {})
 494   = kcTyClDeclBody decl $ \ tvs' ->
 495       return (decl {tcdTyVars = tvs'})
 496
 497 kcTyClDecl decl@(ClassDecl {tcdCtxt = ctxt, tcdSigs = sigs, tcdATs = ats})
 498   = kcTyClDeclBody decl $ \ tvs' ->
 499     do  { is_boot <- tcIsHsBoot
 500         ; ctxt' <- kcHsContext ctxt
 501         ; ats'  <- mappM (wrapLocM kcTyClDecl) ats
 502         ; sigs' <- mappM (wrapLocM kc_sig    ) sigs
 503         ; return (decl {tcdTyVars = tvs', tcdCtxt = ctxt', tcdSigs = sigs',
 504                         tcdATs = ats'}) }
 505   where
 506     kc_sig (TypeSig nm op_ty) = do { op_ty' <- kcHsLiftedSigType op_ty
 507                                    ; return (TypeSig nm op_ty') }
 508     kc_sig other_sig          = return other_sig
 509
 510 kcTyClDecl decl@(ForeignType {})
 511   = return decl
 512
 513 kcTyClDeclBody :: TyClDecl Name
 514                -> ([LHsTyVarBndr Name] -> TcM a)
 515                -> TcM a
 516 -- getInitialKind has made a suitably-shaped kind for the type or class
 517 -- Unpack it, and attribute those kinds to the type variables
 518 -- Extend the env with bindings for the tyvars, taken from
 519 -- the kind of the tycon/class.  Give it to the thing inside, and
 520 -- check the result kind matches
 521 kcTyClDeclBody decl thing_inside
 522   = tcAddDeclCtxt decl          $
 523     do  { tc_ty_thing <- tcLookupLocated (tcdLName decl)
 524         ; let tc_kind    = case tc_ty_thing of { AThing k -> k }
 525               (kinds, _) = splitKindFunTys tc_kind
 526               hs_tvs     = tcdTyVars decl
 527               kinded_tvs = ASSERT( length kinds >= length hs_tvs )
 528                            [ L loc (KindedTyVar (hsTyVarName tv) k)
 529                            | (L loc tv, k) <- zip hs_tvs kinds]
 530         ; tcExtendKindEnvTvs kinded_tvs (thing_inside kinded_tvs) }
 531
 532 -- Kind check a data declaration, assuming that we already extended the
 533 -- kind environment with the type variables of the left-hand side (these
 534 -- kinded type variables are also passed as the second parameter).
 535 --
 536 kcDataDecl :: TyClDecl Name -> [LHsTyVarBndr Name] -> TcM (TyClDecl Name)
 537 kcDataDecl decl@(TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdCons = cons})
 538            tvs
 539   = do  { ctxt' <- kcHsContext ctxt
 540         ; cons' <- mappM (wrapLocM kc_con_decl) cons
 541         ; return (decl {tcdTyVars = tvs, tcdCtxt = ctxt', tcdCons = cons'}) }
 542   where
 543     kc_con_decl (ConDecl name expl ex_tvs ex_ctxt details res) = do
 544       kcHsTyVars ex_tvs $ \ex_tvs' -> do
 545         ex_ctxt' <- kcHsContext ex_ctxt
 546         details' <- kc_con_details details
 547         res'     <- case res of
 548           ResTyH98 -> return ResTyH98
 549           ResTyGADT ty -> do { ty' <- kcHsSigType ty; return (ResTyGADT ty') }
 550         return (ConDecl name expl ex_tvs' ex_ctxt' details' res')
 551
 552     kc_con_details (PrefixCon btys)
 553         = do { btys' <- mappM kc_larg_ty btys ; return (PrefixCon btys') }
 554     kc_con_details (InfixCon bty1 bty2)
 555         = do { bty1' <- kc_larg_ty bty1; bty2' <- kc_larg_ty bty2; return (InfixCon bty1' bty2') }
 556     kc_con_details (RecCon fields)
 557         = do { fields' <- mappM kc_field fields; return (RecCon fields') }
 558
 559     kc_field (fld, bty) = do { bty' <- kc_larg_ty bty ; return (fld, bty') }
 560
 561     kc_larg_ty bty = case new_or_data of
 562                         DataType -> kcHsSigType bty
 563                         NewType  -> kcHsLiftedSigType bty
 564         -- Can't allow an unlifted type for newtypes, because we're effectively
 565         -- going to remove the constructor while coercing it to a lifted type.
 566         -- And newtypes can't be bang'd
 567 \end{code}
 568
 569
 570 %************************************************************************
 571 %*                                                                      *
 572 \subsection{Type checking}
 573 %*                                                                      *
 574 %************************************************************************
 575
 576 \begin{code}
 577 tcSynDecls :: [LTyClDecl Name] -> TcM [TyThing]
 578 tcSynDecls [] = return []
 579 tcSynDecls (decl : decls)
 580   = do { syn_tc <- addLocM tcSynDecl decl
 581        ; syn_tcs <- tcExtendGlobalEnv [syn_tc] (tcSynDecls decls)
 582        ; return (syn_tc : syn_tcs) }
 583
 584 tcSynDecl
 585   (TySynonym {tcdLName = L _ tc_name, tcdTyVars = tvs, tcdSynRhs = rhs_ty})
 586   = tcTyVarBndrs tvs            $ \ tvs' -> do
 587     { traceTc (text "tcd1" <+> ppr tc_name)
 588     ; rhs_ty' <- tcHsKindedType rhs_ty
 589     ; return (ATyCon (buildSynTyCon tc_name tvs' (SynonymTyCon rhs_ty'))) }
 590
 591 --------------------
 592 tcTyClDecl :: (Name -> RecFlag) -> TyClDecl Name -> TcM TyThing
 593
 594 tcTyClDecl calc_isrec decl
 595   = tcAddDeclCtxt decl (tcTyClDecl1 calc_isrec decl)
 596
 597   -- kind signature for a type function
 598 tcTyClDecl1 _calc_isrec
 599   (TyFunction {tcdLName = L _ tc_name, tcdTyVars = tvs, tcdKind = kind})
 600   = tcTyVarBndrs tvs  $ \ tvs' -> do
 601   { gla_exts <- doptM Opt_GlasgowExts
 602
 603         -- Check that we don't use kind signatures without Glasgow extensions
 604   ; checkTc gla_exts $ badSigTyDecl tc_name
 605
 606   ; return (ATyCon (buildSynTyCon tc_name tvs' (OpenSynTyCon kind)))
 607   }
 608
 609   -- kind signature for an indexed data type
 610 tcTyClDecl1 _calc_isrec
 611   (TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdTyVars = tvs,
 612            tcdLName = L _ tc_name, tcdKindSig = mb_ksig, tcdCons = []})
 613   = tcTyVarBndrs tvs  $ \ tvs' -> do
 614   { extra_tvs <- tcDataKindSig mb_ksig
 615   ; let final_tvs = tvs' ++ extra_tvs    -- we may not need these
 616
 617   ; checkTc (null . unLoc $ ctxt) $ badKindSigCtxt tc_name
 618   ; gla_exts <- doptM Opt_GlasgowExts
 619
 620         -- Check that we don't use kind signatures without Glasgow extensions
 621   ; checkTc gla_exts $ badSigTyDecl tc_name
 622
 623   ; tycon <- buildAlgTyCon tc_name final_tvs []
 624                (case new_or_data of
 625                   DataType -> OpenDataTyCon
 626                   NewType  -> OpenNewTyCon)
 627                Recursive False True
 628   ; return (ATyCon tycon)
 629   }
 630
 631 tcTyClDecl1 calc_isrec
 632   (TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdTyVars = tvs,
 633            tcdLName = L _ tc_name, tcdKindSig = mb_ksig, tcdCons = cons})
 634   = tcTyVarBndrs tvs    $ \ tvs' -> do
 635   { extra_tvs <- tcDataKindSig mb_ksig
 636   ; let final_tvs = tvs' ++ extra_tvs
 637   ; stupid_theta <- tcHsKindedContext ctxt
 638   ; want_generic <- doptM Opt_Generics
 639   ; unbox_strict <- doptM Opt_UnboxStrictFields
 640   ; gla_exts     <- doptM Opt_GlasgowExts
 641   ; is_boot      <- tcIsHsBoot  -- Are we compiling an hs-boot file?
 642
 643         -- Check that we don't use GADT syntax in H98 world
 644   ; checkTc (gla_exts || h98_syntax) (badGadtDecl tc_name)
 645
 646         -- Check that we don't use kind signatures without Glasgow extensions
 647   ; checkTc (gla_exts || isNothing mb_ksig) (badSigTyDecl tc_name)
 648
 649         -- Check that the stupid theta is empty for a GADT-style declaration
 650   ; checkTc (null stupid_theta || h98_syntax) (badStupidTheta tc_name)
 651
 652         -- Check that there's at least one condecl,
 653         -- or else we're reading an hs-boot file, or -fglasgow-exts
 654   ; checkTc (not (null cons) || gla_exts || is_boot)
 655             (emptyConDeclsErr tc_name)
 656
 657         -- Check that a newtype has exactly one constructor
 658   ; checkTc (new_or_data == DataType || isSingleton cons)
 659             (newtypeConError tc_name (length cons))
 660
 661   ; tycon <- fixM (\ tycon -> do
 662         { data_cons <- mappM (addLocM (tcConDecl unbox_strict new_or_data
 663                                                  tycon final_tvs))
 664                              cons
 665         ; tc_rhs <-
 666             if null cons && is_boot     -- In a hs-boot file, empty cons means
 667             then return AbstractTyCon   -- "don't know"; hence Abstract
 668             else case new_or_data of
 669                    DataType -> return (mkDataTyConRhs data_cons)
 670                    NewType  ->
 671                        ASSERT( isSingleton data_cons )
 672                        mkNewTyConRhs tc_name tycon (head data_cons)
 673         ; buildAlgTyCon tc_name final_tvs stupid_theta tc_rhs is_rec
 674                         (want_generic && canDoGenerics data_cons) h98_syntax
 675         })
 676   ; return (ATyCon tycon)
 677   }
 678   where
 679     is_rec   = calc_isrec tc_name
 680     h98_syntax = case cons of   -- All constructors have same shape
 681                         L _ (ConDecl { con_res = ResTyGADT _ }) : _ -> False
 682                         other -> True
 683
 684 tcTyClDecl1 calc_isrec
 685   (ClassDecl {tcdLName = L _ class_name, tcdTyVars = tvs,
 686               tcdCtxt = ctxt, tcdMeths = meths,
 687               tcdFDs = fundeps, tcdSigs = sigs, tcdATs = ats} )
 688   = tcTyVarBndrs tvs            $ \ tvs' -> do
 689   { ctxt' <- tcHsKindedContext ctxt
 690   ; fds' <- mappM (addLocM tc_fundep) fundeps
 691   ; ats' <- mappM (addLocM (tcTyClDecl1 (const Recursive))) ats
 692  -- ^^^^ !!!TODO: what to do with this?  Need to generate FC tyfun decls.
 693   ; sig_stuff <- tcClassSigs class_name sigs meths
 694   ; clas <- fixM (\ clas ->
 695                 let     -- This little knot is just so we can get
 696                         -- hold of the name of the class TyCon, which we
 697                         -- need to look up its recursiveness
 698                     tycon_name = tyConName (classTyCon clas)
 699                     tc_isrec = calc_isrec tycon_name
 700                 in
 701                 buildClass class_name tvs' ctxt' fds'
 702                            sig_stuff tc_isrec)
 703   ; return (AClass clas) }
 704   where
 705     tc_fundep (tvs1, tvs2) = do { tvs1' <- mappM tcLookupTyVar tvs1 ;
 706                                 ; tvs2' <- mappM tcLookupTyVar tvs2 ;
 707                                 ; return (tvs1', tvs2') }
 708
 709
 710 tcTyClDecl1 calc_isrec
 711   (ForeignType {tcdLName = L _ tc_name, tcdExtName = tc_ext_name})
 712   = returnM (ATyCon (mkForeignTyCon tc_name tc_ext_name liftedTypeKind 0))
 713
 714 -----------------------------------
 715 tcConDecl :: Bool               -- True <=> -funbox-strict_fields
 716           -> NewOrData -> TyCon -> [TyVar]
 717           -> ConDecl Name -> TcM DataCon
 718
 719 tcConDecl unbox_strict NewType tycon tc_tvs     -- Newtypes
 720           (ConDecl name _ ex_tvs ex_ctxt details ResTyH98)
 721   = do  { let tc_datacon field_lbls arg_ty
 722                 = do { arg_ty' <- tcHsKindedType arg_ty -- No bang on newtype
 723                      ; buildDataCon (unLoc name) False {- Prefix -}
 724                                     [NotMarkedStrict]
 725                                     (map unLoc field_lbls)
 726                                     tc_tvs []  -- No existentials
 727                                     [] []      -- No equalities, predicates
 728                                     [arg_ty']
 729                                     tycon }
 730
 731                 -- Check that a newtype has no existential stuff
 732         ; checkTc (null ex_tvs && null (unLoc ex_ctxt)) (newtypeExError name)
 733
 734         ; case details of
 735             PrefixCon [arg_ty] -> tc_datacon [] arg_ty
 736             RecCon [(field_lbl, arg_ty)] -> tc_datacon [field_lbl] arg_ty
 737             other -> failWithTc (newtypeFieldErr name (length (hsConArgs details)))
 738                         -- Check that the constructor has exactly one field
 739         }
 740
 741 tcConDecl unbox_strict DataType tycon tc_tvs    -- Data types
 742           (ConDecl name _ tvs ctxt details res_ty)
 743   = tcTyVarBndrs tvs            $ \ tvs' -> do
 744     { ctxt' <- tcHsKindedContext ctxt
 745     ; (univ_tvs, ex_tvs, eq_preds, data_tc) <- tcResultType tycon tc_tvs tvs' res_ty
 746     ; let
 747         tc_datacon is_infix field_lbls btys
 748           = do { let bangs = map getBangStrictness btys
 749                ; arg_tys <- mappM tcHsBangType btys
 750                ; buildDataCon (unLoc name) is_infix
 751                     (argStrictness unbox_strict tycon bangs arg_tys)
 752                     (map unLoc field_lbls)
 753                     univ_tvs ex_tvs eq_preds ctxt' arg_tys
 754                     data_tc }
 755                 -- NB:  we put data_tc, the type constructor gotten from the constructor
 756                 --      type signature into the data constructor; that way
 757                 --      checkValidDataCon can complain if it's wrong.
 758
 759     ; case details of
 760         PrefixCon btys     -> tc_datacon False [] btys
 761         InfixCon bty1 bty2 -> tc_datacon True  [] [bty1,bty2]
 762         RecCon fields      -> tc_datacon False field_names btys
 763                            where
 764                               (field_names, btys) = unzip fields
 765
 766     }
 767
 768 tcResultType :: TyCon
 769              -> [TyVar]         -- data T a b c = ...
 770              -> [TyVar]         -- where MkT :: forall a b c. ...
 771              -> ResType Name
 772              -> TcM ([TyVar],           -- Universal
 773                      [TyVar],           -- Existential
 774                      [(TyVar,Type)],    -- Equality predicates
 775                      TyCon)             -- TyCon given in the ResTy
 776         -- We don't check that the TyCon given in the ResTy is
 777         -- the same as the parent tycon, becuase we are in the middle
 778         -- of a recursive knot; so it's postponed until checkValidDataCon
 779
 780 tcResultType decl_tycon tc_tvs dc_tvs ResTyH98
 781   = return (tc_tvs, dc_tvs, [], decl_tycon)
 782         -- In H98 syntax the dc_tvs are the existential ones
 783         --      data T a b c = forall d e. MkT ...
 784         -- The {a,b,c} are tc_tvs, and {d,e} are dc_tvs
 785
 786 tcResultType _ tc_tvs dc_tvs (ResTyGADT res_ty)
 787         -- E.g.  data T a b c where
 788         --         MkT :: forall x y z. T (x,y) z z
 789         -- Then we generate
 790         --      ([a,z,c], [x,y], [a:=:(x,y), c:=:z], T)
 791
 792   = do  { (dc_tycon, res_tys) <- tcLHsConResTy res_ty
 793                 -- NB: tc_tvs and dc_tvs are distinct
 794         ; let univ_tvs = choose_univs [] tc_tvs res_tys
 795                 -- Each univ_tv is either a dc_tv or a tc_tv
 796               ex_tvs = dc_tvs `minusList` univ_tvs
 797               eq_spec = [ (tv, ty) | (tv,ty) <- univ_tvs `zip` res_tys,
 798                                       tv `elem` tc_tvs]
 799         ; return (univ_tvs, ex_tvs, eq_spec, dc_tycon) }
 800   where
 801         -- choose_univs uses the res_ty itself if it's a type variable
 802         -- and hasn't already been used; otherwise it uses one of the tc_tvs
 803     choose_univs used tc_tvs []
 804         = ASSERT( null tc_tvs ) []
 805     choose_univs used (tc_tv:tc_tvs) (res_ty:res_tys)
 806         | Just tv <- tcGetTyVar_maybe res_ty, not (tv `elem` used)
 807         = tv    : choose_univs (tv:used) tc_tvs res_tys
 808         | otherwise
 809         = tc_tv : choose_univs used tc_tvs res_tys
 810
 811 -------------------
 812 argStrictness :: Bool           -- True <=> -funbox-strict_fields
 813               -> TyCon -> [HsBang]
 814               -> [TcType] -> [StrictnessMark]
 815 argStrictness unbox_strict tycon bangs arg_tys
 816  = ASSERT( length bangs == length arg_tys )
 817    zipWith (chooseBoxingStrategy unbox_strict tycon) arg_tys bangs
 818
 819 -- We attempt to unbox/unpack a strict field when either:
 820 --   (i)  The field is marked '!!', or
 821 --   (ii) The field is marked '!', and the -funbox-strict-fields flag is on.
 822 --
 823 -- We have turned off unboxing of newtypes because coercions make unboxing
 824 -- and reboxing more complicated
 825 chooseBoxingStrategy :: Bool -> TyCon -> TcType -> HsBang -> StrictnessMark
 826 chooseBoxingStrategy unbox_strict_fields tycon arg_ty bang
 827   = case bang of
 828         HsNoBang                                    -> NotMarkedStrict
 829         HsStrict | unbox_strict_fields
 830                    && can_unbox arg_ty              -> MarkedUnboxed
 831         HsUnbox  | can_unbox arg_ty                 -> MarkedUnboxed
 832         other                                       -> MarkedStrict
 833   where
 834     -- we can unbox if the type is a chain of newtypes with a product tycon
 835     -- at the end
 836     can_unbox arg_ty = case splitTyConApp_maybe arg_ty of
 837                    Nothing                      -> False
 838                    Just (arg_tycon, tycon_args) ->
 839                        not (isRecursiveTyCon tycon) &&
 840                        isProductTyCon arg_tycon &&
 841                        (if isNewTyCon arg_tycon then
 842                             can_unbox (newTyConInstRhs arg_tycon tycon_args)
 843                         else True)
 844 \end{code}
 845
 846 %************************************************************************
 847 %*                                                                      *
 848 \subsection{Dependency analysis}
 849 %*                                                                      *
 850 %************************************************************************
 851
 852 Validity checking is done once the mutually-recursive knot has been
 853 tied, so we can look at things freely.
 854
 855 \begin{code}
 856 checkCycleErrs :: [LTyClDecl Name] -> TcM ()
 857 checkCycleErrs tyclss
 858   | null cls_cycles
 859   = return ()
 860   | otherwise
 861   = do  { mappM_ recClsErr cls_cycles
 862         ; failM }       -- Give up now, because later checkValidTyCl
 863                         -- will loop if the synonym is recursive
 864   where
 865     cls_cycles = calcClassCycles tyclss
 866
 867 checkValidTyCl :: TyClDecl Name -> TcM ()
 868 -- We do the validity check over declarations, rather than TyThings
 869 -- only so that we can add a nice context with tcAddDeclCtxt
 870 checkValidTyCl decl
 871   = tcAddDeclCtxt decl $
 872     do  { thing <- tcLookupLocatedGlobal (tcdLName decl)
 873         ; traceTc (text "Validity of" <+> ppr thing)
 874         ; case thing of
 875             ATyCon tc -> checkValidTyCon tc
 876             AClass cl -> checkValidClass cl
 877         ; traceTc (text "Done validity of" <+> ppr thing)
 878         }
 879
 880 -------------------------
 881 -- For data types declared with record syntax, we require
 882 -- that each constructor that has a field 'f'
 883 --      (a) has the same result type
 884 --      (b) has the same type for 'f'
 885 -- module alpha conversion of the quantified type variables
 886 -- of the constructor.
 887
 888 checkValidTyCon :: TyCon -> TcM ()
 889 checkValidTyCon tc
 890   | isSynTyCon tc
 891   = case synTyConRhs tc of
 892       OpenSynTyCon _  -> return ()
 893       SynonymTyCon ty -> checkValidType syn_ctxt ty
 894   | otherwise
 895   =     -- Check the context on the data decl
 896     checkValidTheta (DataTyCtxt name) (tyConStupidTheta tc)     `thenM_`
 897
 898         -- Check arg types of data constructors
 899     mappM_ (checkValidDataCon tc) data_cons                     `thenM_`
 900
 901         -- Check that fields with the same name share a type
 902     mappM_ check_fields groups
 903
 904   where
 905     syn_ctxt  = TySynCtxt name
 906     name      = tyConName tc
 907     data_cons = tyConDataCons tc
 908
 909     groups = equivClasses cmp_fld (concatMap get_fields data_cons)
 910     cmp_fld (f1,_) (f2,_) = f1 `compare` f2
 911     get_fields con = dataConFieldLabels con `zip` repeat con
 912         -- dataConFieldLabels may return the empty list, which is fine
 913
 914     -- See Note [GADT record selectors] in MkId.lhs
 915     -- We must check (a) that the named field has the same
 916     --                   type in each constructor
 917     --               (b) that those constructors have the same result type
 918     --
 919     -- However, the constructors may have differently named type variable
 920     -- and (worse) we don't know how the correspond to each other.  E.g.
 921     --     C1 :: forall a b. { f :: a, g :: b } -> T a b
 922     --     C2 :: forall d c. { f :: c, g :: c } -> T c d
 923     --
 924     -- So what we do is to ust Unify.tcMatchTys to compare the first candidate's
 925     -- result type against other candidates' types BOTH WAYS ROUND.
 926     -- If they magically agrees, take the substitution and
 927     -- apply them to the latter ones, and see if they match perfectly.
 928     check_fields fields@((label, con1) : other_fields)
 929         -- These fields all have the same name, but are from
 930         -- different constructors in the data type
 931         = recoverM (return ()) $ mapM_ checkOne other_fields
 932                 -- Check that all the fields in the group have the same type
 933                 -- NB: this check assumes that all the constructors of a given
 934                 -- data type use the same type variables
 935         where
 936         tvs1 = mkVarSet (dataConAllTyVars con1)
 937         res1 = dataConResTys con1
 938         fty1 = dataConFieldType con1 label
 939
 940         checkOne (_, con2)    -- Do it bothways to ensure they are structurally identical
 941             = do { checkFieldCompat label con1 con2 tvs1 res1 res2 fty1 fty2
 942                  ; checkFieldCompat label con2 con1 tvs2 res2 res1 fty2 fty1 }
 943             where
 944                 tvs2 = mkVarSet (dataConAllTyVars con2)
 945                 res2 = dataConResTys con2
 946                 fty2 = dataConFieldType con2 label
 947
 948 checkFieldCompat fld con1 con2 tvs1 res1 res2 fty1 fty2
 949   = do  { checkTc (isJust mb_subst1) (resultTypeMisMatch fld con1 con2)
 950         ; checkTc (isJust mb_subst2) (fieldTypeMisMatch fld con1 con2) }
 951   where
 952     mb_subst1 = tcMatchTys tvs1 res1 res2
 953     mb_subst2 = tcMatchTyX tvs1 (expectJust "checkFieldCompat" mb_subst1) fty1 fty2
 954
 955 -------------------------------
 956 checkValidDataCon :: TyCon -> DataCon -> TcM ()
 957 checkValidDataCon tc con
 958   = setSrcSpan (srcLocSpan (getSrcLoc con))     $
 959     addErrCtxt (dataConCtxt con)                $
 960     do  { checkTc (dataConTyCon con == tc) (badDataConTyCon con)
 961         ; checkValidType ctxt (dataConUserType con) }
 962   where
 963     ctxt = ConArgCtxt (dataConName con)
 964
 965 -------------------------------
 966 checkValidClass :: Class -> TcM ()
 967 checkValidClass cls
 968   = do  {       -- CHECK ARITY 1 FOR HASKELL 1.4
 969           gla_exts <- doptM Opt_GlasgowExts
 970
 971         -- Check that the class is unary, unless GlaExs
 972         ; checkTc (notNull tyvars) (nullaryClassErr cls)
 973         ; checkTc (gla_exts || unary) (classArityErr cls)
 974
 975         -- Check the super-classes
 976         ; checkValidTheta (ClassSCCtxt (className cls)) theta
 977
 978         -- Check the class operations
 979         ; mappM_ (check_op gla_exts) op_stuff
 980
 981         -- Check that if the class has generic methods, then the
 982         -- class has only one parameter.  We can't do generic
 983         -- multi-parameter type classes!
 984         ; checkTc (unary || no_generics) (genericMultiParamErr cls)
 985         }
 986   where
 987     (tyvars, theta, _, op_stuff) = classBigSig cls
 988     unary       = isSingleton tyvars
 989     no_generics = null [() | (_, GenDefMeth) <- op_stuff]
 990
 991     check_op gla_exts (sel_id, dm)
 992       = addErrCtxt (classOpCtxt sel_id tau) $ do
 993         { checkValidTheta SigmaCtxt (tail theta)
 994                 -- The 'tail' removes the initial (C a) from the
 995                 -- class itself, leaving just the method type
 996
 997         ; checkValidType (FunSigCtxt op_name) tau
 998
 999                 -- Check that the type mentions at least one of
1000                 -- the class type variables
1001         ; checkTc (any (`elemVarSet` tyVarsOfType tau) tyvars)
1002                   (noClassTyVarErr cls sel_id)
1003
1004                 -- Check that for a generic method, the type of
1005                 -- the method is sufficiently simple
1006         ; checkTc (dm /= GenDefMeth || validGenericMethodType tau)
1007                   (badGenericMethodType op_name op_ty)
1008         }
1009         where
1010           op_name = idName sel_id
1011           op_ty   = idType sel_id
1012           (_,theta1,tau1) = tcSplitSigmaTy op_ty
1013           (_,theta2,tau2)  = tcSplitSigmaTy tau1
1014           (theta,tau) | gla_exts  = (theta1 ++ theta2, tau2)
1015                       | otherwise = (theta1,           mkPhiTy (tail theta1) tau1)
1016                 -- Ugh!  The function might have a type like
1017                 --      op :: forall a. C a => forall b. (Eq b, Eq a) => tau2
1018                 -- With -fglasgow-exts, we want to allow this, even though the inner
1019                 -- forall has an (Eq a) constraint.  Whereas in general, each constraint
1020                 -- in the context of a for-all must mention at least one quantified
1021                 -- type variable.  What a mess!
1022
1023
1024 ---------------------------------------------------------------------
1025 resultTypeMisMatch field_name con1 con2
1026   = vcat [sep [ptext SLIT("Constructors") <+> ppr con1 <+> ptext SLIT("and") <+> ppr con2,
1027                 ptext SLIT("have a common field") <+> quotes (ppr field_name) <> comma],
1028           nest 2 $ ptext SLIT("but have different result types")]
1029 fieldTypeMisMatch field_name con1 con2
1030   = sep [ptext SLIT("Constructors") <+> ppr con1 <+> ptext SLIT("and") <+> ppr con2,
1031          ptext SLIT("give different types for field"), quotes (ppr field_name)]
1032
1033 dataConCtxt con = ptext SLIT("In the definition of data constructor") <+> quotes (ppr con)
1034
1035 classOpCtxt sel_id tau = sep [ptext SLIT("When checking the class method:"),
1036                               nest 2 (ppr sel_id <+> dcolon <+> ppr tau)]
1037
1038 nullaryClassErr cls
1039   = ptext SLIT("No parameters for class")  <+> quotes (ppr cls)
1040
1041 classArityErr cls
1042   = vcat [ptext SLIT("Too many parameters for class") <+> quotes (ppr cls),
1043           parens (ptext SLIT("Use -fglasgow-exts to allow multi-parameter classes"))]
1044
1045 noClassTyVarErr clas op
1046   = sep [ptext SLIT("The class method") <+> quotes (ppr op),
1047          ptext SLIT("mentions none of the type variables of the class") <+>
1048                 ppr clas <+> hsep (map ppr (classTyVars clas))]
1049
1050 genericMultiParamErr clas
1051   = ptext SLIT("The multi-parameter class") <+> quotes (ppr clas) <+>
1052     ptext SLIT("cannot have generic methods")
1053
1054 badGenericMethodType op op_ty
1055   = hang (ptext SLIT("Generic method type is too complex"))
1056        4 (vcat [ppr op <+> dcolon <+> ppr op_ty,
1057                 ptext SLIT("You can only use type variables, arrows, lists, and tuples")])
1058
1059 recSynErr syn_decls
1060   = setSrcSpan (getLoc (head sorted_decls)) $
1061     addErr (sep [ptext SLIT("Cycle in type synonym declarations:"),
1062                  nest 2 (vcat (map ppr_decl sorted_decls))])
1063   where
1064     sorted_decls = sortLocated syn_decls
1065     ppr_decl (L loc decl) = ppr loc <> colon <+> ppr decl
1066
1067 recClsErr cls_decls
1068   = setSrcSpan (getLoc (head sorted_decls)) $
1069     addErr (sep [ptext SLIT("Cycle in class declarations (via superclasses):"),
1070                  nest 2 (vcat (map ppr_decl sorted_decls))])
1071   where
1072     sorted_decls = sortLocated cls_decls
1073     ppr_decl (L loc decl) = ppr loc <> colon <+> ppr (decl { tcdSigs = [] })
1074
1075 sortLocated :: [Located a] -> [Located a]
1076 sortLocated things = sortLe le things
1077   where
1078     le (L l1 _) (L l2 _) = l1 <= l2
1079
1080 badDataConTyCon data_con
1081   = hang (ptext SLIT("Data constructor") <+> quotes (ppr data_con) <+>
1082                 ptext SLIT("returns type") <+> quotes (ppr (dataConTyCon data_con)))
1083        2 (ptext SLIT("instead of its parent type"))
1084
1085 badGadtDecl tc_name
1086   = vcat [ ptext SLIT("Illegal generalised algebraic data declaration for") <+> quotes (ppr tc_name)
1087          , nest 2 (parens $ ptext SLIT("Use -fglasgow-exts to allow GADTs")) ]
1088
1089 badStupidTheta tc_name
1090   = ptext SLIT("A data type declared in GADT style cannot have a context:") <+> quotes (ppr tc_name)
1091
1092 newtypeConError tycon n
1093   = sep [ptext SLIT("A newtype must have exactly one constructor,"),
1094          nest 2 $ ptext SLIT("but") <+> quotes (ppr tycon) <+> ptext SLIT("has") <+> speakN n ]
1095
1096 newtypeExError con
1097   = sep [ptext SLIT("A newtype constructor cannot have an existential context,"),
1098          nest 2 $ ptext SLIT("but") <+> quotes (ppr con) <+> ptext SLIT("does")]
1099
1100 newtypeFieldErr con_name n_flds
1101   = sep [ptext SLIT("The constructor of a newtype must have exactly one field"),
1102          nest 2 $ ptext SLIT("but") <+> quotes (ppr con_name) <+> ptext SLIT("has") <+> speakN n_flds]
1103
1104 badSigTyDecl tc_name
1105   = vcat [ ptext SLIT("Illegal kind signature") <+>
1106            quotes (ppr tc_name)
1107          , nest 2 (parens $ ptext SLIT("Use -fglasgow-exts to allow indexed types")) ]
1108
1109 badKindSigCtxt tc_name
1110   = vcat [ ptext SLIT("Illegal context in kind signature") <+>
1111            quotes (ppr tc_name)
1112          , nest 2 (parens $ ptext SLIT("Currently, kind signatures cannot have a context")) ]
1113
1114 badIdxTyDecl tc_name
1115   = vcat [ ptext SLIT("Illegal indexed type instance for") <+>
1116            quotes (ppr tc_name)
1117          , nest 2 (parens $ ptext SLIT("Use -fglasgow-exts to allow indexed types")) ]
1118
1119 badGadtIdxTyDecl tc_name
1120   = vcat [ ptext SLIT("Illegal generalised algebraic data declaration for") <+>
1121            quotes (ppr tc_name)
1122          , nest 2 (parens $ ptext SLIT("Indexed types cannot use GADT declarations")) ]
1123
1124 tooManyParmsErr tc_name
1125   = ptext SLIT("Indexed type instance has too many parameters:") <+>
1126     quotes (ppr tc_name)
1127
1128 tooFewParmsErr tc_name
1129   = ptext SLIT("Indexed type instance has too few parameters:") <+>
1130     quotes (ppr tc_name)
1131
1132 badBootTyIdxDeclErr = ptext SLIT("Illegal indexed type instance in hs-boot file")
1133
1134 emptyConDeclsErr tycon
1135   = sep [quotes (ppr tycon) <+> ptext SLIT("has no constructors"),
1136          nest 2 $ ptext SLIT("(-fglasgow-exts permits this)")]
1137 \end{code}