compiler/typecheck/TcType.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5 \section[TcType]{Types used in the typechecker}
   6
   7 This module provides the Type interface for front-end parts of the
   8 compiler.  These parts
   9
  10         * treat "source types" as opaque:
  11                 newtypes, and predicates are meaningful.
  12         * look through usage types
  13
  14 The "tc" prefix is for "TypeChecker", because the type checker
  15 is the principal client.
  16
  17 \begin{code}
  18 module TcType (
  19   --------------------------------
  20   -- Types
  21   TcType, TcSigmaType, TcRhoType, TcTauType, TcPredType, TcThetaType,
  22   TcTyVar, TcTyVarSet, TcKind, TcCoVar,
  23
  24   --------------------------------
  25   -- MetaDetails
  26   UserTypeCtxt(..), pprUserTypeCtxt,
  27   TcTyVarDetails(..), pprTcTyVarDetails,
  28   MetaDetails(Flexi, Indirect), MetaInfo(..),
  29   SkolemInfo(..), pprSkolTvBinding, pprSkolInfo,
  30   isImmutableTyVar, isSkolemTyVar, isMetaTyVar,  isMetaTyVarTy,
  31   isSigTyVar, isExistentialTyVar,  isTyConableTyVar,
  32   metaTvRef,
  33   isFlexi, isIndirect, isUnkSkol, isRuntimeUnkSkol,
  34
  35   --------------------------------
  36   -- Builders
  37   mkPhiTy, mkSigmaTy,
  38
  39   --------------------------------
  40   -- Splitters
  41   -- These are important because they do not look through newtypes
  42   tcView,
  43   tcSplitForAllTys, tcSplitPhiTy, tcSplitPredFunTy_maybe,
  44   tcSplitFunTy_maybe, tcSplitFunTys, tcFunArgTy, tcFunResultTy, tcSplitFunTysN,
  45   tcSplitTyConApp, tcSplitTyConApp_maybe, tcTyConAppTyCon, tcTyConAppArgs,
  46   tcSplitAppTy_maybe, tcSplitAppTy, tcSplitAppTys, repSplitAppTy_maybe,
  47   tcInstHeadTyNotSynonym, tcInstHeadTyAppAllTyVars,
  48   tcGetTyVar_maybe, tcGetTyVar,
  49   tcSplitSigmaTy, tcDeepSplitSigmaTy_maybe,
  50
  51   ---------------------------------
  52   -- Predicates.
  53   -- Again, newtypes are opaque
  54   tcEqType, tcEqTypes, tcEqPred, tcCmpType, tcCmpTypes, tcCmpPred, tcEqTypeX,
  55   eqKind,
  56   isSigmaTy, isOverloadedTy, isRigidTy,
  57   isDoubleTy, isFloatTy, isIntTy, isWordTy, isStringTy,
  58   isIntegerTy, isBoolTy, isUnitTy, isCharTy,
  59   isTauTy, isTauTyCon, tcIsTyVarTy, tcIsForAllTy,
  60   isSynFamilyTyConApp,
  61
  62   ---------------------------------
  63   -- Misc type manipulators
  64   deNoteType,
  65   tyClsNamesOfType, tyClsNamesOfDFunHead,
  66   getDFunTyKey,
  67
  68   ---------------------------------
  69   -- Predicate types
  70   getClassPredTys_maybe, getClassPredTys,
  71   isClassPred, isTyVarClassPred, isEqPred,
  72   mkClassPred, mkIPPred, tcSplitPredTy_maybe,
  73   mkDictTy, evVarPred,
  74   isPredTy, isDictTy, isDictLikeTy,
  75   tcSplitDFunTy, tcSplitDFunHead, predTyUnique,
  76   isIPPred,
  77   isRefineableTy, isRefineablePred,
  78
  79   -- * Tidying type related things up for printing
  80   tidyType,      tidyTypes,
  81   tidyOpenType,  tidyOpenTypes,
  82   tidyTyVarBndr, tidyFreeTyVars,
  83   tidyOpenTyVar, tidyOpenTyVars,
  84   tidyTopType,   tidyPred,
  85   tidyKind, tidySkolemTyVar,
  86
  87   ---------------------------------
  88   -- Foreign import and export
  89   isFFIArgumentTy,     -- :: DynFlags -> Safety -> Type -> Bool
  90   isFFIImportResultTy, -- :: DynFlags -> Type -> Bool
  91   isFFIExportResultTy, -- :: Type -> Bool
  92   isFFIExternalTy,     -- :: Type -> Bool
  93   isFFIDynArgumentTy,  -- :: Type -> Bool
  94   isFFIDynResultTy,    -- :: Type -> Bool
  95   isFFIPrimArgumentTy, -- :: DynFlags -> Type -> Bool
  96   isFFIPrimResultTy,   -- :: DynFlags -> Type -> Bool
  97   isFFILabelTy,        -- :: Type -> Bool
  98   isFFIDotnetTy,       -- :: DynFlags -> Type -> Bool
  99   isFFIDotnetObjTy,    -- :: Type -> Bool
 100   isFFITy,             -- :: Type -> Bool
 101   isFunPtrTy,          -- :: Type -> Bool
 102   tcSplitIOType_maybe, -- :: Type -> Maybe Type
 103
 104   --------------------------------
 105   -- Rexported from Coercion
 106   typeKind,
 107
 108   --------------------------------
 109   -- Rexported from Type
 110   Kind,         -- Stuff to do with kinds is insensitive to pre/post Tc
 111   unliftedTypeKind, liftedTypeKind, argTypeKind,
 112   openTypeKind, mkArrowKind, mkArrowKinds,
 113   isLiftedTypeKind, isUnliftedTypeKind, isSubOpenTypeKind,
 114   isSubArgTypeKind, isSubKind, splitKindFunTys, defaultKind,
 115   kindVarRef, mkKindVar,
 116
 117   Type, PredType(..), ThetaType,
 118   mkForAllTy, mkForAllTys,
 119   mkFunTy, mkFunTys, zipFunTys,
 120   mkTyConApp, mkAppTy, mkAppTys, applyTy, applyTys,
 121   mkTyVarTy, mkTyVarTys, mkTyConTy, mkPredTy, mkPredTys,
 122
 123   -- Type substitutions
 124   TvSubst(..),  -- Representation visible to a few friends
 125   TvSubstEnv, emptyTvSubst, substEqSpec,
 126   mkOpenTvSubst, zipOpenTvSubst, zipTopTvSubst,
 127   mkTopTvSubst, notElemTvSubst, unionTvSubst,
 128   getTvSubstEnv, setTvSubstEnv, getTvInScope, extendTvInScope, lookupTyVar,
 129   extendTvSubst, extendTvSubstList, isInScope, mkTvSubst, zipTyEnv,
 130   substTy, substTys, substTyWith, substTheta, substTyVar, substTyVars, substTyVarBndr,
 131
 132   isUnLiftedType,       -- Source types are always lifted
 133   isUnboxedTupleType,   -- Ditto
 134   isPrimitiveType,
 135
 136   tyVarsOfType, tyVarsOfTypes, tyVarsOfPred, tyVarsOfTheta,
 137   tcTyVarsOfType, tcTyVarsOfTypes, tcTyVarsOfPred, exactTyVarsOfType,
 138   exactTyVarsOfTypes,
 139
 140   pprKind, pprParendKind,
 141   pprType, pprParendType, pprTypeApp, pprTyThingCategory,
 142   pprPred, pprTheta, pprThetaArrow, pprClassPred
 143
 144   ) where
 145
 146 #include "HsVersions.h"
 147
 148 -- friends:
 149 import TypeRep
 150 import DataCon
 151 import Class
 152 import Var
 153 import ForeignCall
 154 import VarSet
 155 import Type
 156 import Coercion
 157 import TyCon
 158 import HsExpr( HsMatchContext )
 159
 160 -- others:
 161 import DynFlags
 162 import Name
 163 import NameSet
 164 import VarEnv
 165 import PrelNames
 166 import TysWiredIn
 167 import BasicTypes
 168 import Util
 169 import Maybes
 170 import ListSetOps
 171 import Outputable
 172 import FastString
 173
 174 import Data.List( mapAccumL )
 175 import Data.IORef
 176 \end{code}
 177
 178 %************************************************************************
 179 %*                                                                      *
 180 \subsection{Types}
 181 %*                                                                      *
 182 %************************************************************************
 183
 184 The type checker divides the generic Type world into the
 185 following more structured beasts:
 186
 187 sigma ::= forall tyvars. phi
 188         -- A sigma type is a qualified type
 189         --
 190         -- Note that even if 'tyvars' is empty, theta
 191         -- may not be: e.g.   (?x::Int) => Int
 192
 193         -- Note that 'sigma' is in prenex form:
 194         -- all the foralls are at the front.
 195         -- A 'phi' type has no foralls to the right of
 196         -- an arrow
 197
 198 phi :: theta => rho
 199
 200 rho ::= sigma -> rho
 201      |  tau
 202
 203 -- A 'tau' type has no quantification anywhere
 204 -- Note that the args of a type constructor must be taus
 205 tau ::= tyvar
 206      |  tycon tau_1 .. tau_n
 207      |  tau_1 tau_2
 208      |  tau_1 -> tau_2
 209
 210 -- In all cases, a (saturated) type synonym application is legal,
 211 -- provided it expands to the required form.
 212
 213 \begin{code}
 214 type TcTyVar = TyVar    -- Used only during type inference
 215 type TcCoVar = CoVar    -- Used only during type inference; mutable
 216 type TcType = Type      -- A TcType can have mutable type variables
 217         -- Invariant on ForAllTy in TcTypes:
 218         --      forall a. T
 219         -- a cannot occur inside a MutTyVar in T; that is,
 220         -- T is "flattened" before quantifying over a
 221
 222 -- These types do not have boxy type variables in them
 223 type TcPredType     = PredType
 224 type TcThetaType    = ThetaType
 225 type TcSigmaType    = TcType
 226 type TcRhoType      = TcType
 227 type TcTauType      = TcType
 228 type TcKind         = Kind
 229 type TcTyVarSet     = TyVarSet
 230 \end{code}
 231
 232
 233 %************************************************************************
 234 %*                                                                      *
 235 \subsection{TyVarDetails}
 236 %*                                                                      *
 237 %************************************************************************
 238
 239 TyVarDetails gives extra info about type variables, used during type
 240 checking.  It's attached to mutable type variables only.
 241 It's knot-tied back to Var.lhs.  There is no reason in principle
 242 why Var.lhs shouldn't actually have the definition, but it "belongs" here.
 243
 244
 245 Note [Signature skolems]
 246 ~~~~~~~~~~~~~~~~~~~~~~~~
 247 Consider this
 248
 249   x :: [a]
 250   y :: b
 251   (x,y,z) = ([y,z], z, head x)
 252
 253 Here, x and y have type sigs, which go into the environment.  We used to
 254 instantiate their types with skolem constants, and push those types into
 255 the RHS, so we'd typecheck the RHS with type
 256         ( [a*], b*, c )
 257 where a*, b* are skolem constants, and c is an ordinary meta type varible.
 258
 259 The trouble is that the occurrences of z in the RHS force a* and b* to
 260 be the *same*, so we can't make them into skolem constants that don't unify
 261 with each other.  Alas.
 262
 263 One solution would be insist that in the above defn the programmer uses
 264 the same type variable in both type signatures.  But that takes explanation.
 265
 266 The alternative (currently implemented) is to have a special kind of skolem
 267 constant, SigTv, which can unify with other SigTvs.  These are *not* treated
 268 as righd for the purposes of GADTs.  And they are used *only* for pattern
 269 bindings and mutually recursive function bindings.  See the function
 270 TcBinds.tcInstSig, and its use_skols parameter.
 271
 272
 273 \begin{code}
 274 -- A TyVarDetails is inside a TyVar
 275 data TcTyVarDetails
 276   = SkolemTv SkolemInfo   -- A skolem constant
 277
 278   | FlatSkol TcType
 279            -- The "skolem" obtained by flattening during
 280            -- constraint simplification
 281
 282            -- In comments we will use the notation alpha[flat = ty]
 283            -- to represent a flattening skolem variable alpha
 284            -- identified with type ty.
 285
 286   | MetaTv MetaInfo (IORef MetaDetails)
 287
 288 data MetaDetails
 289   = Flexi  -- Flexi type variables unify to become Indirects
 290   | Indirect TcType
 291
 292 data MetaInfo
 293    = TauTv         -- This MetaTv is an ordinary unification variable
 294                    -- A TauTv is always filled in with a tau-type, which
 295                    -- never contains any ForAlls
 296
 297    | SigTv Name    -- A variant of TauTv, except that it should not be
 298                    -- unified with a type, only with a type variable
 299                    -- SigTvs are only distinguished to improve error messages
 300                    --      see Note [Signature skolems]
 301                    --      The MetaDetails, if filled in, will
 302                    --      always be another SigTv or a SkolemTv
 303                    -- The Name is the name of the function from whose
 304                    -- type signature we got this skolem
 305
 306    | TcsTv         -- A MetaTv allocated by the constraint solver
 307                    -- Its particular property is that it is always "touchable"
 308                    -- Nevertheless, the constraint solver has to try to guess
 309                    -- what type to instantiate it to
 310
 311 ----------------------------------
 312 -- SkolemInfo describes a site where
 313 --   a) type variables are skolemised
 314 --   b) an implication constraint is generated
 315 data SkolemInfo
 316   = SigSkol UserTypeCtxt        -- A skolem that is created by instantiating
 317                                 -- a programmer-supplied type signature
 318                                 -- Location of the binding site is on the TyVar
 319
 320         -- The rest are for non-scoped skolems
 321   | ClsSkol Class       -- Bound at a class decl
 322   | InstSkol            -- Bound at an instance decl
 323   | FamInstSkol         -- Bound at a family instance decl
 324   | PatSkol             -- An existential type variable bound by a pattern for
 325       DataCon           -- a data constructor with an existential type.
 326       (HsMatchContext Name)
 327              -- e.g.   data T = forall a. Eq a => MkT a
 328              --        f (MkT x) = ...
 329              -- The pattern MkT x will allocate an existential type
 330              -- variable for 'a'.
 331
 332   | ArrowSkol           -- An arrow form (see TcArrows)
 333
 334   | IPSkol [IPName Name]  -- Binding site of an implicit parameter
 335
 336   | RuleSkol RuleName   -- The LHS of a RULE
 337   | GenSkol TcType      -- Bound when doing a subsumption check for ty
 338
 339   | RuntimeUnkSkol      -- a type variable used to represent an unknown
 340                         -- runtime type (used in the GHCi debugger)
 341
 342   | NoScSkol            -- Used for the "self" superclass when solving
 343                         -- superclasses; don't generate superclasses of me
 344
 345   | UnkSkol             -- Unhelpful info (until I improve it)
 346
 347 -------------------------------------
 348 -- UserTypeCtxt describes the places where a
 349 -- programmer-written type signature can occur
 350 -- Like SkolemInfo, no location info
 351 data UserTypeCtxt
 352   = FunSigCtxt Name     -- Function type signature
 353                         -- Also used for types in SPECIALISE pragmas
 354   | ExprSigCtxt         -- Expression type signature
 355   | ConArgCtxt Name     -- Data constructor argument
 356   | TySynCtxt Name      -- RHS of a type synonym decl
 357   | GenPatCtxt          -- Pattern in generic decl
 358                         --      f{| a+b |} (Inl x) = ...
 359   | LamPatSigCtxt               -- Type sig in lambda pattern
 360                         --      f (x::t) = ...
 361   | BindPatSigCtxt      -- Type sig in pattern binding pattern
 362                         --      (x::t, y) = e
 363   | ResSigCtxt          -- Result type sig
 364                         --      f x :: t = ....
 365   | ForSigCtxt Name     -- Foreign inport or export signature
 366   | DefaultDeclCtxt     -- Types in a default declaration
 367   | SpecInstCtxt        -- SPECIALISE instance pragma
 368   | ThBrackCtxt         -- Template Haskell type brackets [t| ... |]
 369
 370 -- Notes re TySynCtxt
 371 -- We allow type synonyms that aren't types; e.g.  type List = []
 372 --
 373 -- If the RHS mentions tyvars that aren't in scope, we'll
 374 -- quantify over them:
 375 --      e.g.    type T = a->a
 376 -- will become  type T = forall a. a->a
 377 --
 378 -- With gla-exts that's right, but for H98 we should complain.
 379
 380 ---------------------------------
 381 -- Kind variables:
 382
 383 mkKindName :: Unique -> Name
 384 mkKindName unique = mkSystemName unique kind_var_occ
 385
 386 kindVarRef :: KindVar -> IORef MetaDetails
 387 kindVarRef tc =
 388   ASSERT ( isTcTyVar tc )
 389   case tcTyVarDetails tc of
 390     MetaTv TauTv ref -> ref
 391     _                -> pprPanic "kindVarRef" (ppr tc)
 392
 393 mkKindVar :: Unique -> IORef MetaDetails -> KindVar
 394 mkKindVar u r
 395   = mkTcTyVar (mkKindName u)
 396               tySuperKind  -- not sure this is right,
 397                             -- do we need kind vars for
 398                             -- coercions?
 399               (MetaTv TauTv r)
 400
 401 kind_var_occ :: OccName -- Just one for all KindVars
 402                         -- They may be jiggled by tidying
 403 kind_var_occ = mkOccName tvName "k"
 404 \end{code}
 405
 406 %************************************************************************
 407 %*                                                                      *
 408                 Pretty-printing
 409 %*                                                                      *
 410 %************************************************************************
 411
 412 \begin{code}
 413 pprTcTyVarDetails :: TcTyVarDetails -> SDoc
 414 -- For debugging
 415 pprTcTyVarDetails (SkolemTv _)         = ptext (sLit "sk")
 416 pprTcTyVarDetails (FlatSkol {})        = ptext (sLit "fsk")
 417 pprTcTyVarDetails (MetaTv TauTv _)     = ptext (sLit "tau")
 418 pprTcTyVarDetails (MetaTv TcsTv _)     = ptext (sLit "tcs")
 419 pprTcTyVarDetails (MetaTv (SigTv _) _) = ptext (sLit "sig")
 420
 421 pprUserTypeCtxt :: UserTypeCtxt -> SDoc
 422 pprUserTypeCtxt (FunSigCtxt n)  = ptext (sLit "the type signature for") <+> quotes (ppr n)
 423 pprUserTypeCtxt ExprSigCtxt     = ptext (sLit "an expression type signature")
 424 pprUserTypeCtxt (ConArgCtxt c)  = ptext (sLit "the type of the constructor") <+> quotes (ppr c)
 425 pprUserTypeCtxt (TySynCtxt c)   = ptext (sLit "the RHS of the type synonym") <+> quotes (ppr c)
 426 pprUserTypeCtxt GenPatCtxt      = ptext (sLit "the type pattern of a generic definition")
 427 pprUserTypeCtxt ThBrackCtxt     = ptext (sLit "a Template Haskell quotation [t|...|]")
 428 pprUserTypeCtxt LamPatSigCtxt   = ptext (sLit "a pattern type signature")
 429 pprUserTypeCtxt BindPatSigCtxt  = ptext (sLit "a pattern type signature")
 430 pprUserTypeCtxt ResSigCtxt      = ptext (sLit "a result type signature")
 431 pprUserTypeCtxt (ForSigCtxt n)  = ptext (sLit "the foreign declaration for") <+> quotes (ppr n)
 432 pprUserTypeCtxt DefaultDeclCtxt = ptext (sLit "a type in a `default' declaration")
 433 pprUserTypeCtxt SpecInstCtxt    = ptext (sLit "a SPECIALISE instance pragma")
 434
 435 pprSkolTvBinding :: TcTyVar -> SDoc
 436 -- Print info about the binding of a skolem tyvar,
 437 -- or nothing if we don't have anything useful to say
 438 pprSkolTvBinding tv
 439   = ASSERT ( isTcTyVar tv )
 440     quotes (ppr tv) <+> ppr_details (tcTyVarDetails tv)
 441   where
 442     ppr_details (SkolemTv info)      = ppr_skol info
 443     ppr_details (FlatSkol {})        = ptext (sLit "is a flattening type variable")
 444     ppr_details (MetaTv (SigTv n) _) = ptext (sLit "is bound by the type signature for")
 445                                        <+> quotes (ppr n)
 446     ppr_details (MetaTv _ _)         = ptext (sLit "is a meta type variable")
 447
 448     ppr_skol UnkSkol        = ptext (sLit "is an unknown type variable")        -- Unhelpful
 449     ppr_skol RuntimeUnkSkol = ptext (sLit "is an unknown runtime type")
 450     ppr_skol info           = sep [ptext (sLit "is a rigid type variable bound by"),
 451                                    sep [pprSkolInfo info,
 452                                         nest 2 (ptext (sLit "at") <+> ppr (getSrcLoc tv))]]
 453
 454 pprSkolInfo :: SkolemInfo -> SDoc
 455 -- Complete the sentence "is a rigid type variable bound by..."
 456 pprSkolInfo (SigSkol ctxt)  = pprUserTypeCtxt ctxt
 457 pprSkolInfo (IPSkol ips)    = ptext (sLit "the implicit-parameter bindings for")
 458                               <+> pprWithCommas ppr ips
 459 pprSkolInfo (ClsSkol cls)   = ptext (sLit "the class declaration for") <+> quotes (ppr cls)
 460 pprSkolInfo InstSkol        = ptext (sLit "the instance declaration")
 461 pprSkolInfo NoScSkol        = ptext (sLit "the instance declaration (self)")
 462 pprSkolInfo FamInstSkol     = ptext (sLit "the family instance declaration")
 463 pprSkolInfo (RuleSkol name) = ptext (sLit "the RULE") <+> doubleQuotes (ftext name)
 464 pprSkolInfo ArrowSkol       = ptext (sLit "the arrow form")
 465 pprSkolInfo (PatSkol dc _)  = sep [ ptext (sLit "a pattern with constructor")
 466                                     , ppr dc <+> dcolon <+> ppr (dataConUserType dc) ]
 467 pprSkolInfo (GenSkol ty)    = sep [ ptext (sLit "the polymorphic type")
 468                                   , quotes (ppr ty) ]
 469
 470 -- UnkSkol
 471 -- For type variables the others are dealt with by pprSkolTvBinding.
 472 -- For Insts, these cases should not happen
 473 pprSkolInfo UnkSkol        = WARN( True, text "pprSkolInfo: UnkSkol" ) ptext (sLit "UnkSkol")
 474 pprSkolInfo RuntimeUnkSkol = WARN( True, text "pprSkolInfo: RuntimeUnkSkol" ) ptext (sLit "RuntimeUnkSkol")
 475
 476 instance Outputable MetaDetails where
 477   ppr Flexi         = ptext (sLit "Flexi")
 478   ppr (Indirect ty) = ptext (sLit "Indirect") <+> ppr ty
 479 \end{code}
 480
 481
 482 %************************************************************************
 483 %*                                                                      *
 484 \subsection{TidyType}
 485 %*                                                                      *
 486 %************************************************************************
 487
 488 \begin{code}
 489 -- | This tidies up a type for printing in an error message, or in
 490 -- an interface file.
 491 --
 492 -- It doesn't change the uniques at all, just the print names.
 493 tidyTyVarBndr :: TidyEnv -> TyVar -> (TidyEnv, TyVar)
 494 tidyTyVarBndr env@(tidy_env, subst) tyvar
 495   = case tidyOccName tidy_env (getOccName name) of
 496       (tidy', occ') -> ((tidy', subst'), tyvar'')
 497         where
 498           subst' = extendVarEnv subst tyvar tyvar''
 499           tyvar' = setTyVarName tyvar name'
 500           name'  = tidyNameOcc name occ'
 501                 -- Don't forget to tidy the kind for coercions!
 502           tyvar'' | isCoVar tyvar = setTyVarKind tyvar' kind'
 503                   | otherwise     = tyvar'
 504           kind'  = tidyType env (tyVarKind tyvar)
 505   where
 506     name = tyVarName tyvar
 507
 508 ---------------
 509 tidyFreeTyVars :: TidyEnv -> TyVarSet -> TidyEnv
 510 -- ^ Add the free 'TyVar's to the env in tidy form,
 511 -- so that we can tidy the type they are free in
 512 tidyFreeTyVars env tyvars = fst (tidyOpenTyVars env (varSetElems tyvars))
 513
 514 ---------------
 515 tidyOpenTyVars :: TidyEnv -> [TyVar] -> (TidyEnv, [TyVar])
 516 tidyOpenTyVars env tyvars = mapAccumL tidyOpenTyVar env tyvars
 517
 518 ---------------
 519 tidyOpenTyVar :: TidyEnv -> TyVar -> (TidyEnv, TyVar)
 520 -- ^ Treat a new 'TyVar' as a binder, and give it a fresh tidy name
 521 -- using the environment if one has not already been allocated. See
 522 -- also 'tidyTyVarBndr'
 523 tidyOpenTyVar env@(_, subst) tyvar
 524   = case lookupVarEnv subst tyvar of
 525         Just tyvar' -> (env, tyvar')            -- Already substituted
 526         Nothing     -> tidyTyVarBndr env tyvar  -- Treat it as a binder
 527
 528 ---------------
 529 tidyType :: TidyEnv -> Type -> Type
 530 tidyType env@(_, subst) ty
 531   = go ty
 532   where
 533     go (TyVarTy tv)         = case lookupVarEnv subst tv of
 534                                 Nothing  -> expand tv
 535                                 Just tv' -> expand tv'
 536     go (TyConApp tycon tys) = let args = map go tys
 537                               in args `seqList` TyConApp tycon args
 538     go (PredTy sty)         = PredTy (tidyPred env sty)
 539     go (AppTy fun arg)      = (AppTy $! (go fun)) $! (go arg)
 540     go (FunTy fun arg)      = (FunTy $! (go fun)) $! (go arg)
 541     go (ForAllTy tv ty)     = ForAllTy tvp $! (tidyType envp ty)
 542                               where
 543                                 (envp, tvp) = tidyTyVarBndr env tv
 544
 545     -- Expand FlatSkols, the skolems introduced by flattening process
 546     -- We don't want to show them in type error messages
 547     expand tv | isTcTyVar tv
 548               , FlatSkol ty <- tcTyVarDetails tv
 549               = go ty
 550               | otherwise
 551               = TyVarTy tv
 552
 553 ---------------
 554 tidyTypes :: TidyEnv -> [Type] -> [Type]
 555 tidyTypes env tys = map (tidyType env) tys
 556
 557 ---------------
 558 tidyPred :: TidyEnv -> PredType -> PredType
 559 tidyPred env (IParam n ty)     = IParam n (tidyType env ty)
 560 tidyPred env (ClassP clas tys) = ClassP clas (tidyTypes env tys)
 561 tidyPred env (EqPred ty1 ty2)  = EqPred (tidyType env ty1) (tidyType env ty2)
 562
 563 ---------------
 564 -- | Grabs the free type variables, tidies them
 565 -- and then uses 'tidyType' to work over the type itself
 566 tidyOpenType :: TidyEnv -> Type -> (TidyEnv, Type)
 567 tidyOpenType env ty
 568   = (env', tidyType env' ty)
 569   where
 570     env' = tidyFreeTyVars env (tyVarsOfType ty)
 571
 572 ---------------
 573 tidyOpenTypes :: TidyEnv -> [Type] -> (TidyEnv, [Type])
 574 tidyOpenTypes env tys = mapAccumL tidyOpenType env tys
 575
 576 ---------------
 577 -- | Calls 'tidyType' on a top-level type (i.e. with an empty tidying environment)
 578 tidyTopType :: Type -> Type
 579 tidyTopType ty = tidyType emptyTidyEnv ty
 580
 581 ---------------
 582 tidySkolemTyVar :: TidyEnv -> TcTyVar -> (TidyEnv, TcTyVar)
 583 -- Tidy the type inside a GenSkol, preparatory to printing it
 584 tidySkolemTyVar env tv
 585   = ASSERT( isTcTyVar tv && (isSkolemTyVar tv || isSigTyVar tv ) )
 586     (env1, mkTcTyVar (tyVarName tv) (tyVarKind tv) info1)
 587   where
 588     (env1, info1) = case tcTyVarDetails tv of
 589                         SkolemTv info -> (env1, SkolemTv info')
 590                                 where
 591                                   (env1, info') = tidy_skol_info env info
 592                         info -> (env, info)
 593
 594     tidy_skol_info env (GenSkol ty) = (env1, GenSkol ty1)
 595                             where
 596                               (env1, ty1)  = tidyOpenType env ty
 597     tidy_skol_info env info = (env, info)
 598
 599 ---------------
 600 tidyKind :: TidyEnv -> Kind -> (TidyEnv, Kind)
 601 tidyKind env k = tidyOpenType env k
 602 \end{code}
 603
 604
 605 %************************************************************************
 606 %*                                                                      *
 607                 Predicates
 608 %*                                                                      *
 609 %************************************************************************
 610
 611 \begin{code}
 612 isImmutableTyVar :: TyVar -> Bool
 613
 614 isImmutableTyVar tv
 615   | isTcTyVar tv = isSkolemTyVar tv
 616   | otherwise    = True
 617
 618 isTyConableTyVar, isSkolemTyVar, isExistentialTyVar,
 619   isMetaTyVar :: TcTyVar -> Bool
 620
 621 isTyConableTyVar tv
 622         -- True of a meta-type variable that can be filled in
 623         -- with a type constructor application; in particular,
 624         -- not a SigTv
 625   = ASSERT( isTcTyVar tv)
 626     case tcTyVarDetails tv of
 627         MetaTv (SigTv _) _ -> False
 628         _                  -> True
 629
 630 isSkolemTyVar tv
 631   = ASSERT2( isTcTyVar tv, ppr tv )
 632     case tcTyVarDetails tv of
 633         SkolemTv {} -> True
 634         FlatSkol {} -> True
 635         MetaTv {}   -> False
 636
 637 isExistentialTyVar tv   -- Existential type variable, bound by a pattern
 638   = ASSERT( isTcTyVar tv )
 639     case tcTyVarDetails tv of
 640         SkolemTv (PatSkol {}) -> True
 641         _                     -> False
 642
 643 isMetaTyVar tv
 644   = ASSERT2( isTcTyVar tv, ppr tv )
 645     case tcTyVarDetails tv of
 646         MetaTv _ _ -> True
 647         _          -> False
 648
 649 isMetaTyVarTy :: TcType -> Bool
 650 isMetaTyVarTy (TyVarTy tv) = isMetaTyVar tv
 651 isMetaTyVarTy _            = False
 652
 653 isSigTyVar :: Var -> Bool
 654 isSigTyVar tv
 655   = ASSERT( isTcTyVar tv )
 656     case tcTyVarDetails tv of
 657         MetaTv (SigTv _) _ -> True
 658         _                  -> False
 659
 660 metaTvRef :: TyVar -> IORef MetaDetails
 661 metaTvRef tv
 662   = ASSERT2( isTcTyVar tv, ppr tv )
 663     case tcTyVarDetails tv of
 664         MetaTv _ ref -> ref
 665         _          -> pprPanic "metaTvRef" (ppr tv)
 666
 667 isFlexi, isIndirect :: MetaDetails -> Bool
 668 isFlexi Flexi = True
 669 isFlexi _     = False
 670
 671 isIndirect (Indirect _) = True
 672 isIndirect _            = False
 673
 674 isRuntimeUnkSkol :: TyVar -> Bool
 675 -- Called only in TcErrors; see Note [Runtime skolems] there
 676 isRuntimeUnkSkol x
 677   | isTcTyVar x
 678   , SkolemTv info <- tcTyVarDetails x
 679   = case info of
 680        UnkSkol -> True
 681        RuntimeUnkSkol -> True
 682        _ -> False
 683   | otherwise = False
 684
 685 isUnkSkol :: TyVar -> Bool
 686 isUnkSkol x | isTcTyVar x
 687             , SkolemTv UnkSkol <- tcTyVarDetails x = True
 688             | otherwise = False
 689 \end{code}
 690
 691
 692 %************************************************************************
 693 %*                                                                      *
 694 \subsection{Tau, sigma and rho}
 695 %*                                                                      *
 696 %************************************************************************
 697
 698 \begin{code}
 699 mkSigmaTy :: [TyVar] -> [PredType] -> Type -> Type
 700 mkSigmaTy tyvars theta tau = mkForAllTys tyvars (mkPhiTy theta tau)
 701
 702 mkPhiTy :: [PredType] -> Type -> Type
 703 mkPhiTy theta ty = foldr (\p r -> mkFunTy (mkPredTy p) r) ty theta
 704 \end{code}
 705
 706 @isTauTy@ tests for nested for-alls.  It should not be called on a boxy type.
 707
 708 \begin{code}
 709 isTauTy :: Type -> Bool
 710 isTauTy ty | Just ty' <- tcView ty = isTauTy ty'
 711 isTauTy (TyVarTy _)       = True
 712 isTauTy (TyConApp tc tys) = all isTauTy tys && isTauTyCon tc
 713 isTauTy (AppTy a b)       = isTauTy a && isTauTy b
 714 isTauTy (FunTy a b)       = isTauTy a && isTauTy b
 715 isTauTy (PredTy _)        = True                -- Don't look through source types
 716 isTauTy _                 = False
 717
 718
 719 isTauTyCon :: TyCon -> Bool
 720 -- Returns False for type synonyms whose expansion is a polytype
 721 isTauTyCon tc
 722   | isClosedSynTyCon tc = isTauTy (snd (synTyConDefn tc))
 723   | otherwise           = True
 724
 725 ---------------
 726 isRigidTy :: TcType -> Bool
 727 -- A type is rigid if it has no meta type variables in it
 728 isRigidTy ty = all isImmutableTyVar (varSetElems (tcTyVarsOfType ty))
 729
 730 isRefineableTy :: TcType -> (Bool,Bool)
 731 -- A type should have type refinements applied to it if it has
 732 -- free type variables, and they are all rigid
 733 isRefineableTy ty = (null tc_tvs,  all isImmutableTyVar tc_tvs)
 734                     where
 735                       tc_tvs = varSetElems (tcTyVarsOfType ty)
 736
 737 isRefineablePred :: TcPredType -> Bool
 738 isRefineablePred pred = not (null tc_tvs) && all isImmutableTyVar tc_tvs
 739                       where
 740                         tc_tvs = varSetElems (tcTyVarsOfPred pred)
 741
 742 ---------------
 743 getDFunTyKey :: Type -> OccName -- Get some string from a type, to be used to
 744                                 -- construct a dictionary function name
 745 getDFunTyKey ty | Just ty' <- tcView ty = getDFunTyKey ty'
 746 getDFunTyKey (TyVarTy tv)    = getOccName tv
 747 getDFunTyKey (TyConApp tc _) = getOccName tc
 748 getDFunTyKey (AppTy fun _)   = getDFunTyKey fun
 749 getDFunTyKey (FunTy _ _)     = getOccName funTyCon
 750 getDFunTyKey (ForAllTy _ t)  = getDFunTyKey t
 751 getDFunTyKey ty              = pprPanic "getDFunTyKey" (pprType ty)
 752 -- PredTy shouldn't happen
 753 \end{code}
 754
 755
 756 %************************************************************************
 757 %*                                                                      *
 758 \subsection{Expanding and splitting}
 759 %*                                                                      *
 760 %************************************************************************
 761
 762 These tcSplit functions are like their non-Tc analogues, but
 763         a) they do not look through newtypes
 764         b) they do not look through PredTys
 765
 766 However, they are non-monadic and do not follow through mutable type
 767 variables.  It's up to you to make sure this doesn't matter.
 768
 769 \begin{code}
 770 tcSplitForAllTys :: Type -> ([TyVar], Type)
 771 tcSplitForAllTys ty = split ty ty []
 772    where
 773      split orig_ty ty tvs | Just ty' <- tcView ty = split orig_ty ty' tvs
 774      split _ (ForAllTy tv ty) tvs
 775        | not (isCoVar tv) = split ty ty (tv:tvs)
 776      split orig_ty _ tvs = (reverse tvs, orig_ty)
 777
 778 tcIsForAllTy :: Type -> Bool
 779 tcIsForAllTy ty | Just ty' <- tcView ty = tcIsForAllTy ty'
 780 tcIsForAllTy (ForAllTy tv _) = not (isCoVar tv)
 781 tcIsForAllTy _               = False
 782
 783 tcSplitPredFunTy_maybe :: Type -> Maybe (PredType, Type)
 784 -- Split off the first predicate argument from a type
 785 tcSplitPredFunTy_maybe ty | Just ty' <- tcView ty = tcSplitPredFunTy_maybe ty'
 786 tcSplitPredFunTy_maybe (ForAllTy tv ty)
 787   | isCoVar tv = Just (coVarPred tv, ty)
 788 tcSplitPredFunTy_maybe (FunTy arg res)
 789   | Just p <- tcSplitPredTy_maybe arg = Just (p, res)
 790 tcSplitPredFunTy_maybe _
 791   = Nothing
 792
 793 tcSplitPhiTy :: Type -> (ThetaType, Type)
 794 tcSplitPhiTy ty
 795   = split ty []
 796   where
 797     split ty ts
 798       = case tcSplitPredFunTy_maybe ty of
 799           Just (pred, ty) -> split ty (pred:ts)
 800           Nothing         -> (reverse ts, ty)
 801
 802 tcSplitSigmaTy :: Type -> ([TyVar], ThetaType, Type)
 803 tcSplitSigmaTy ty = case tcSplitForAllTys ty of
 804                         (tvs, rho) -> case tcSplitPhiTy rho of
 805                                         (theta, tau) -> (tvs, theta, tau)
 806
 807 -----------------------
 808 tcDeepSplitSigmaTy_maybe
 809   :: TcSigmaType -> Maybe ([TcType], [TyVar], ThetaType, TcSigmaType)
 810 -- Looks for a *non-trivial* quantified type, under zero or more function arrows
 811 -- By "non-trivial" we mean either tyvars or constraints are non-empty
 812
 813 tcDeepSplitSigmaTy_maybe ty
 814   | Just (arg_ty, res_ty)           <- tcSplitFunTy_maybe ty
 815   , Just (arg_tys, tvs, theta, rho) <- tcDeepSplitSigmaTy_maybe res_ty
 816   = Just (arg_ty:arg_tys, tvs, theta, rho)
 817
 818   | (tvs, theta, rho) <- tcSplitSigmaTy ty
 819   , not (null tvs && null theta)
 820   = Just ([], tvs, theta, rho)
 821
 822   | otherwise = Nothing
 823
 824 -----------------------
 825 tcTyConAppTyCon :: Type -> TyCon
 826 tcTyConAppTyCon ty = case tcSplitTyConApp_maybe ty of
 827                         Just (tc, _) -> tc
 828                         Nothing      -> pprPanic "tcTyConAppTyCon" (pprType ty)
 829
 830 tcTyConAppArgs :: Type -> [Type]
 831 tcTyConAppArgs ty = case tcSplitTyConApp_maybe ty of
 832                         Just (_, args) -> args
 833                         Nothing        -> pprPanic "tcTyConAppArgs" (pprType ty)
 834
 835 tcSplitTyConApp :: Type -> (TyCon, [Type])
 836 tcSplitTyConApp ty = case tcSplitTyConApp_maybe ty of
 837                         Just stuff -> stuff
 838                         Nothing    -> pprPanic "tcSplitTyConApp" (pprType ty)
 839
 840 tcSplitTyConApp_maybe :: Type -> Maybe (TyCon, [Type])
 841 tcSplitTyConApp_maybe ty | Just ty' <- tcView ty = tcSplitTyConApp_maybe ty'
 842 tcSplitTyConApp_maybe (TyConApp tc tys) = Just (tc, tys)
 843 tcSplitTyConApp_maybe (FunTy arg res)   = Just (funTyCon, [arg,res])
 844         -- Newtypes are opaque, so they may be split
 845         -- However, predicates are not treated
 846         -- as tycon applications by the type checker
 847 tcSplitTyConApp_maybe _                 = Nothing
 848
 849 -----------------------
 850 tcSplitFunTys :: Type -> ([Type], Type)
 851 tcSplitFunTys ty = case tcSplitFunTy_maybe ty of
 852                         Nothing        -> ([], ty)
 853                         Just (arg,res) -> (arg:args, res')
 854                                        where
 855                                           (args,res') = tcSplitFunTys res
 856
 857 tcSplitFunTy_maybe :: Type -> Maybe (Type, Type)
 858 tcSplitFunTy_maybe ty | Just ty' <- tcView ty           = tcSplitFunTy_maybe ty'
 859 tcSplitFunTy_maybe (FunTy arg res) | not (isPredTy arg) = Just (arg, res)
 860 tcSplitFunTy_maybe _                                    = Nothing
 861         -- Note the (not (isPredTy arg)) guard
 862         -- Consider     (?x::Int) => Bool
 863         -- We don't want to treat this as a function type!
 864         -- A concrete example is test tc230:
 865         --      f :: () -> (?p :: ()) => () -> ()
 866         --
 867         --      g = f () ()
 868
 869 tcSplitFunTysN
 870         :: TcRhoType
 871         -> Arity                -- N: Number of desired args
 872         -> ([TcSigmaType],      -- Arg types (N or fewer)
 873             TcSigmaType)        -- The rest of the type
 874
 875 tcSplitFunTysN ty n_args
 876   | n_args == 0
 877   = ([], ty)
 878   | Just (arg,res) <- tcSplitFunTy_maybe ty
 879   = case tcSplitFunTysN res (n_args - 1) of
 880         (args, res) -> (arg:args, res)
 881   | otherwise
 882   = ([], ty)
 883
 884 tcSplitFunTy :: Type -> (Type, Type)
 885 tcSplitFunTy  ty = expectJust "tcSplitFunTy" (tcSplitFunTy_maybe ty)
 886
 887 tcFunArgTy :: Type -> Type
 888 tcFunArgTy    ty = fst (tcSplitFunTy ty)
 889
 890 tcFunResultTy :: Type -> Type
 891 tcFunResultTy ty = snd (tcSplitFunTy ty)
 892
 893 -----------------------
 894 tcSplitAppTy_maybe :: Type -> Maybe (Type, Type)
 895 tcSplitAppTy_maybe ty | Just ty' <- tcView ty = tcSplitAppTy_maybe ty'
 896 tcSplitAppTy_maybe ty = repSplitAppTy_maybe ty
 897
 898 tcSplitAppTy :: Type -> (Type, Type)
 899 tcSplitAppTy ty = case tcSplitAppTy_maybe ty of
 900                     Just stuff -> stuff
 901                     Nothing    -> pprPanic "tcSplitAppTy" (pprType ty)
 902
 903 tcSplitAppTys :: Type -> (Type, [Type])
 904 tcSplitAppTys ty
 905   = go ty []
 906   where
 907     go ty args = case tcSplitAppTy_maybe ty of
 908                    Just (ty', arg) -> go ty' (arg:args)
 909                    Nothing         -> (ty,args)
 910
 911 -----------------------
 912 tcGetTyVar_maybe :: Type -> Maybe TyVar
 913 tcGetTyVar_maybe ty | Just ty' <- tcView ty = tcGetTyVar_maybe ty'
 914 tcGetTyVar_maybe (TyVarTy tv)   = Just tv
 915 tcGetTyVar_maybe _              = Nothing
 916
 917 tcGetTyVar :: String -> Type -> TyVar
 918 tcGetTyVar msg ty = expectJust msg (tcGetTyVar_maybe ty)
 919
 920 tcIsTyVarTy :: Type -> Bool
 921 tcIsTyVarTy ty = maybeToBool (tcGetTyVar_maybe ty)
 922
 923 -----------------------
 924 tcSplitDFunTy :: Type -> ([TyVar], Class, [Type])
 925 -- Split the type of a dictionary function
 926 -- We don't use tcSplitSigmaTy,  because a DFun may (with NDP)
 927 -- have non-Pred arguments, such as
 928 --     df :: forall m. (forall b. Eq b => Eq (m b)) -> C m
 929 tcSplitDFunTy ty
 930   = case tcSplitForAllTys ty                 of { (tvs, rho)  ->
 931     case tcSplitDFunHead (drop_pred_tys rho) of { (clas, tys) ->
 932     (tvs, clas, tys) }}
 933   where
 934     -- Discard the context of the dfun.  This can be a mix of
 935     -- coercion and class constraints; or (in the general NDP case)
 936     -- some other function argument
 937     drop_pred_tys ty | Just ty' <- tcView ty = drop_pred_tys ty'
 938     drop_pred_tys (ForAllTy tv ty) = ASSERT( isCoVar tv ) drop_pred_tys ty
 939     drop_pred_tys (FunTy _ ty)     = drop_pred_tys ty
 940     drop_pred_tys ty               = ty
 941
 942 tcSplitDFunHead :: Type -> (Class, [Type])
 943 tcSplitDFunHead tau
 944   = case tcSplitPredTy_maybe tau of
 945         Just (ClassP clas tys) -> (clas, tys)
 946         _ -> pprPanic "tcSplitDFunHead" (ppr tau)
 947
 948 tcInstHeadTyNotSynonym :: Type -> Bool
 949 -- Used in Haskell-98 mode, for the argument types of an instance head
 950 -- These must not be type synonyms, but everywhere else type synonyms
 951 -- are transparent, so we need a special function here
 952 tcInstHeadTyNotSynonym ty
 953   = case ty of
 954         TyConApp tc _ -> not (isSynTyCon tc)
 955         _ -> True
 956
 957 tcInstHeadTyAppAllTyVars :: Type -> Bool
 958 -- Used in Haskell-98 mode, for the argument types of an instance head
 959 -- These must be a constructor applied to type variable arguments
 960 tcInstHeadTyAppAllTyVars ty
 961   = case ty of
 962         TyConApp _ tys  -> ok tys
 963         FunTy arg res   -> ok [arg, res]
 964         _               -> False
 965   where
 966         -- Check that all the types are type variables,
 967         -- and that each is distinct
 968     ok tys = equalLength tvs tys && hasNoDups tvs
 969            where
 970              tvs = mapCatMaybes get_tv tys
 971
 972     get_tv (TyVarTy tv)  = Just tv      -- through synonyms
 973     get_tv _             = Nothing
 974 \end{code}
 975
 976
 977
 978 %************************************************************************
 979 %*                                                                      *
 980 \subsection{Predicate types}
 981 %*                                                                      *
 982 %************************************************************************
 983
 984 \begin{code}
 985 evVarPred :: EvVar -> PredType
 986 evVarPred var
 987   = case tcSplitPredTy_maybe (varType var) of
 988       Just pred -> pred
 989       Nothing   -> pprPanic "evVarPred" (ppr var <+> ppr (varType var))
 990
 991 tcSplitPredTy_maybe :: Type -> Maybe PredType
 992    -- Returns Just for predicates only
 993 tcSplitPredTy_maybe ty | Just ty' <- tcView ty = tcSplitPredTy_maybe ty'
 994 tcSplitPredTy_maybe (PredTy p)    = Just p
 995 tcSplitPredTy_maybe _             = Nothing
 996
 997 predTyUnique :: PredType -> Unique
 998 predTyUnique (IParam n _)    = getUnique (ipNameName n)
 999 predTyUnique (ClassP clas _) = getUnique clas
1000 predTyUnique (EqPred a b)    = pprPanic "predTyUnique" (ppr (EqPred a b))
1001 \end{code}
1002
1003
1004 --------------------- Dictionary types ---------------------------------
1005
1006 \begin{code}
1007 mkClassPred :: Class -> [Type] -> PredType
1008 mkClassPred clas tys = ClassP clas tys
1009
1010 isClassPred :: PredType -> Bool
1011 isClassPred (ClassP _ _) = True
1012 isClassPred _            = False
1013
1014 isTyVarClassPred :: PredType -> Bool
1015 isTyVarClassPred (ClassP _ tys) = all tcIsTyVarTy tys
1016 isTyVarClassPred _              = False
1017
1018 getClassPredTys_maybe :: PredType -> Maybe (Class, [Type])
1019 getClassPredTys_maybe (ClassP clas tys) = Just (clas, tys)
1020 getClassPredTys_maybe _                 = Nothing
1021
1022 getClassPredTys :: PredType -> (Class, [Type])
1023 getClassPredTys (ClassP clas tys) = (clas, tys)
1024 getClassPredTys _ = panic "getClassPredTys"
1025
1026 mkDictTy :: Class -> [Type] -> Type
1027 mkDictTy clas tys = mkPredTy (ClassP clas tys)
1028
1029
1030
1031 isDictLikeTy :: Type -> Bool
1032 -- Note [Dictionary-like types]
1033 isDictLikeTy ty | Just ty' <- tcView ty = isDictTy ty'
1034 isDictLikeTy (PredTy p) = isClassPred p
1035 isDictLikeTy (TyConApp tc tys)
1036   | isTupleTyCon tc     = all isDictLikeTy tys
1037 isDictLikeTy _          = False
1038 \end{code}
1039
1040 Note [Dictionary-like types]
1041 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1042 Being "dictionary-like" means either a dictionary type or a tuple thereof.
1043 In GHC 6.10 we build implication constraints which construct such tuples,
1044 and if we land up with a binding
1045     t :: (C [a], Eq [a])
1046     t = blah
1047 then we want to treat t as cheap under "-fdicts-cheap" for example.
1048 (Implication constraints are normally inlined, but sadly not if the
1049 occurrence is itself inside an INLINE function!  Until we revise the
1050 handling of implication constraints, that is.)  This turned out to
1051 be important in getting good arities in DPH code.  Example:
1052
1053     class C a
1054     class D a where { foo :: a -> a }
1055     instance C a => D (Maybe a) where { foo x = x }
1056
1057     bar :: (C a, C b) => a -> b -> (Maybe a, Maybe b)
1058     {-# INLINE bar #-}
1059     bar x y = (foo (Just x), foo (Just y))
1060
1061 Then 'bar' should jolly well have arity 4 (two dicts, two args), but
1062 we ended up with something like
1063    bar = __inline_me__ (\d1,d2. let t :: (D (Maybe a), D (Maybe b)) = ...
1064                                 in \x,y. <blah>)
1065
1066 This is all a bit ad-hoc; eg it relies on knowing that implication
1067 constraints build tuples.
1068
1069 --------------------- Implicit parameters ---------------------------------
1070
1071 \begin{code}
1072 mkIPPred :: IPName Name -> Type -> PredType
1073 mkIPPred ip ty = IParam ip ty
1074
1075 isIPPred :: PredType -> Bool
1076 isIPPred (IParam _ _) = True
1077 isIPPred _            = False
1078 \end{code}
1079
1080 --------------------- Equality predicates ---------------------------------
1081 \begin{code}
1082 substEqSpec :: TvSubst -> [(TyVar,Type)] -> [(TcType,TcType)]
1083 substEqSpec subst eq_spec = [ (substTyVar subst tv, substTy subst ty)
1084                             | (tv,ty) <- eq_spec]
1085 \end{code}
1086
1087
1088 %************************************************************************
1089 %*                                                                      *
1090 \subsection{Predicates}
1091 %*                                                                      *
1092 %************************************************************************
1093
1094 isSigmaTy returns true of any qualified type.  It doesn't *necessarily* have
1095 any foralls.  E.g.
1096         f :: (?x::Int) => Int -> Int
1097
1098 \begin{code}
1099 isSigmaTy :: Type -> Bool
1100 isSigmaTy ty | Just ty' <- tcView ty = isSigmaTy ty'
1101 isSigmaTy (ForAllTy _ _) = True
1102 isSigmaTy (FunTy a _)    = isPredTy a
1103 isSigmaTy _              = False
1104
1105 isOverloadedTy :: Type -> Bool
1106 -- Yes for a type of a function that might require evidence-passing
1107 -- Used only by bindLocalMethods
1108 -- NB: be sure to check for type with an equality predicate; hence isCoVar
1109 isOverloadedTy ty | Just ty' <- tcView ty = isOverloadedTy ty'
1110 isOverloadedTy (ForAllTy tv ty) = isCoVar tv || isOverloadedTy ty
1111 isOverloadedTy (FunTy a _)      = isPredTy a
1112 isOverloadedTy _                = False
1113
1114 isPredTy :: Type -> Bool        -- Belongs in TcType because it does
1115                                 -- not look through newtypes, or predtypes (of course)
1116 isPredTy ty | Just ty' <- tcView ty = isPredTy ty'
1117 isPredTy (PredTy _) = True
1118 isPredTy _          = False
1119 \end{code}
1120
1121 \begin{code}
1122 isFloatTy, isDoubleTy, isIntegerTy, isIntTy, isWordTy, isBoolTy,
1123     isUnitTy, isCharTy :: Type -> Bool
1124 isFloatTy      = is_tc floatTyConKey
1125 isDoubleTy     = is_tc doubleTyConKey
1126 isIntegerTy    = is_tc integerTyConKey
1127 isIntTy        = is_tc intTyConKey
1128 isWordTy       = is_tc wordTyConKey
1129 isBoolTy       = is_tc boolTyConKey
1130 isUnitTy       = is_tc unitTyConKey
1131 isCharTy       = is_tc charTyConKey
1132
1133 isStringTy :: Type -> Bool
1134 isStringTy ty
1135   = case tcSplitTyConApp_maybe ty of
1136       Just (tc, [arg_ty]) -> tc == listTyCon && isCharTy arg_ty
1137       _                   -> False
1138
1139 is_tc :: Unique -> Type -> Bool
1140 -- Newtypes are opaque to this
1141 is_tc uniq ty = case tcSplitTyConApp_maybe ty of
1142                         Just (tc, _) -> uniq == getUnique tc
1143                         Nothing      -> False
1144 \end{code}
1145
1146 \begin{code}
1147 -- NB: Currently used in places where we have already expanded type synonyms;
1148 --     hence no 'coreView'.  This could, however, be changed without breaking
1149 --     any code.
1150 isSynFamilyTyConApp :: TcTauType -> Bool
1151 isSynFamilyTyConApp (TyConApp tc tys) = isSynFamilyTyCon tc &&
1152                                       length tys == tyConArity tc
1153 isSynFamilyTyConApp _other            = False
1154 \end{code}
1155
1156
1157 %************************************************************************
1158 %*                                                                      *
1159 \subsection{Misc}
1160 %*                                                                      *
1161 %************************************************************************
1162
1163 \begin{code}
1164 deNoteType :: Type -> Type
1165 -- Remove all *outermost* type synonyms and other notes
1166 deNoteType ty | Just ty' <- tcView ty = deNoteType ty'
1167 deNoteType ty = ty
1168 \end{code}
1169
1170 \begin{code}
1171 tcTyVarsOfType :: Type -> TcTyVarSet
1172 -- Just the *TcTyVars* free in the type
1173 -- (Types.tyVarsOfTypes finds all free TyVars)
1174 tcTyVarsOfType (TyVarTy tv)         = if isTcTyVar tv then unitVarSet tv
1175                                                       else emptyVarSet
1176 tcTyVarsOfType (TyConApp _ tys)     = tcTyVarsOfTypes tys
1177 tcTyVarsOfType (PredTy sty)         = tcTyVarsOfPred sty
1178 tcTyVarsOfType (FunTy arg res)      = tcTyVarsOfType arg `unionVarSet` tcTyVarsOfType res
1179 tcTyVarsOfType (AppTy fun arg)      = tcTyVarsOfType fun `unionVarSet` tcTyVarsOfType arg
1180 tcTyVarsOfType (ForAllTy tyvar ty)  = (tcTyVarsOfType ty `delVarSet` tyvar)
1181                                       `unionVarSet` tcTyVarsOfTyVar tyvar
1182         -- We do sometimes quantify over skolem TcTyVars
1183
1184 tcTyVarsOfTyVar :: TcTyVar -> TyVarSet
1185 tcTyVarsOfTyVar tv | isCoVar tv = tcTyVarsOfType (tyVarKind tv)
1186                    | otherwise  = emptyVarSet
1187
1188 tcTyVarsOfTypes :: [Type] -> TyVarSet
1189 tcTyVarsOfTypes tys = foldr (unionVarSet.tcTyVarsOfType) emptyVarSet tys
1190
1191 tcTyVarsOfPred :: PredType -> TyVarSet
1192 tcTyVarsOfPred (IParam _ ty)    = tcTyVarsOfType ty
1193 tcTyVarsOfPred (ClassP _ tys)   = tcTyVarsOfTypes tys
1194 tcTyVarsOfPred (EqPred ty1 ty2) = tcTyVarsOfType ty1 `unionVarSet` tcTyVarsOfType ty2
1195 \end{code}
1196
1197 Note [Silly type synonym]
1198 ~~~~~~~~~~~~~~~~~~~~~~~~~
1199 Consider
1200         type T a = Int
1201 What are the free tyvars of (T x)?  Empty, of course!
1202 Here's the example that Ralf Laemmel showed me:
1203         foo :: (forall a. C u a -> C u a) -> u
1204         mappend :: Monoid u => u -> u -> u
1205
1206         bar :: Monoid u => u
1207         bar = foo (\t -> t `mappend` t)
1208 We have to generalise at the arg to f, and we don't
1209 want to capture the constraint (Monad (C u a)) because
1210 it appears to mention a.  Pretty silly, but it was useful to him.
1211
1212 exactTyVarsOfType is used by the type checker to figure out exactly
1213 which type variables are mentioned in a type.  It's also used in the
1214 smart-app checking code --- see TcExpr.tcIdApp
1215
1216 On the other hand, consider a *top-level* definition
1217         f = (\x -> x) :: T a -> T a
1218 If we don't abstract over 'a' it'll get fixed to GHC.Prim.Any, and then
1219 if we have an application like (f "x") we get a confusing error message
1220 involving Any.  So the conclusion is this: when generalising
1221   - at top level use tyVarsOfType
1222   - in nested bindings use exactTyVarsOfType
1223 See Trac #1813 for example.
1224
1225 \begin{code}
1226 exactTyVarsOfType :: TcType -> TyVarSet
1227 -- Find the free type variables (of any kind)
1228 -- but *expand* type synonyms.  See Note [Silly type synonym] above.
1229 exactTyVarsOfType ty
1230   = go ty
1231   where
1232     go ty | Just ty' <- tcView ty = go ty'      -- This is the key line
1233     go (TyVarTy tv)               = unitVarSet tv
1234     go (TyConApp _ tys)           = exactTyVarsOfTypes tys
1235     go (PredTy ty)                = go_pred ty
1236     go (FunTy arg res)            = go arg `unionVarSet` go res
1237     go (AppTy fun arg)            = go fun `unionVarSet` go arg
1238     go (ForAllTy tyvar ty)        = delVarSet (go ty) tyvar
1239                                     `unionVarSet` go_tv tyvar
1240
1241     go_pred (IParam _ ty)    = go ty
1242     go_pred (ClassP _ tys)   = exactTyVarsOfTypes tys
1243     go_pred (EqPred ty1 ty2) = go ty1 `unionVarSet` go ty2
1244
1245     go_tv tyvar | isCoVar tyvar = go (tyVarKind tyvar)
1246                 | otherwise     = emptyVarSet
1247
1248 exactTyVarsOfTypes :: [TcType] -> TyVarSet
1249 exactTyVarsOfTypes tys = foldr (unionVarSet . exactTyVarsOfType) emptyVarSet tys
1250 \end{code}
1251
1252 Find the free tycons and classes of a type.  This is used in the front
1253 end of the compiler.
1254
1255 \begin{code}
1256 tyClsNamesOfType :: Type -> NameSet
1257 tyClsNamesOfType (TyVarTy _)                = emptyNameSet
1258 tyClsNamesOfType (TyConApp tycon tys)       = unitNameSet (getName tycon) `unionNameSets` tyClsNamesOfTypes tys
1259 tyClsNamesOfType (PredTy (IParam _ ty))     = tyClsNamesOfType ty
1260 tyClsNamesOfType (PredTy (ClassP cl tys))   = unitNameSet (getName cl) `unionNameSets` tyClsNamesOfTypes tys
1261 tyClsNamesOfType (PredTy (EqPred ty1 ty2))  = tyClsNamesOfType ty1 `unionNameSets` tyClsNamesOfType ty2
1262 tyClsNamesOfType (FunTy arg res)            = tyClsNamesOfType arg `unionNameSets` tyClsNamesOfType res
1263 tyClsNamesOfType (AppTy fun arg)            = tyClsNamesOfType fun `unionNameSets` tyClsNamesOfType arg
1264 tyClsNamesOfType (ForAllTy _ ty)            = tyClsNamesOfType ty
1265
1266 tyClsNamesOfTypes :: [Type] -> NameSet
1267 tyClsNamesOfTypes tys = foldr (unionNameSets . tyClsNamesOfType) emptyNameSet tys
1268
1269 tyClsNamesOfDFunHead :: Type -> NameSet
1270 -- Find the free type constructors and classes
1271 -- of the head of the dfun instance type
1272 -- The 'dfun_head_type' is because of
1273 --      instance Foo a => Baz T where ...
1274 -- The decl is an orphan if Baz and T are both not locally defined,
1275 --      even if Foo *is* locally defined
1276 tyClsNamesOfDFunHead dfun_ty
1277   = case tcSplitSigmaTy dfun_ty of
1278         (_, _, head_ty) -> tyClsNamesOfType head_ty
1279 \end{code}
1280
1281
1282 %************************************************************************
1283 %*                                                                      *
1284 \subsection[TysWiredIn-ext-type]{External types}
1285 %*                                                                      *
1286 %************************************************************************
1287
1288 The compiler's foreign function interface supports the passing of a
1289 restricted set of types as arguments and results (the restricting factor
1290 being the )
1291
1292 \begin{code}
1293 tcSplitIOType_maybe :: Type -> Maybe (TyCon, Type, CoercionI)
1294 -- (isIOType t) returns Just (IO,t',co)
1295 --                              if co : t ~ IO t'
1296 --              returns Nothing otherwise
1297 tcSplitIOType_maybe ty
1298   = case tcSplitTyConApp_maybe ty of
1299         -- This split absolutely has to be a tcSplit, because we must
1300         -- see the IO type; and it's a newtype which is transparent to splitTyConApp.
1301
1302         Just (io_tycon, [io_res_ty])
1303            |  io_tycon `hasKey` ioTyConKey
1304            -> Just (io_tycon, io_res_ty, IdCo ty)
1305
1306         Just (tc, tys)
1307            | not (isRecursiveTyCon tc)
1308            , Just (ty, co1) <- instNewTyCon_maybe tc tys
1309                   -- Newtypes that require a coercion are ok
1310            -> case tcSplitIOType_maybe ty of
1311                 Nothing             -> Nothing
1312                 Just (tc, ty', co2) -> Just (tc, ty', co1 `mkTransCoI` co2)
1313
1314         _ -> Nothing
1315
1316 isFFITy :: Type -> Bool
1317 -- True for any TyCon that can possibly be an arg or result of an FFI call
1318 isFFITy ty = checkRepTyCon legalFFITyCon ty
1319
1320 isFFIArgumentTy :: DynFlags -> Safety -> Type -> Bool
1321 -- Checks for valid argument type for a 'foreign import'
1322 isFFIArgumentTy dflags safety ty
1323    = checkRepTyCon (legalOutgoingTyCon dflags safety) ty
1324
1325 isFFIExternalTy :: Type -> Bool
1326 -- Types that are allowed as arguments of a 'foreign export'
1327 isFFIExternalTy ty = checkRepTyCon legalFEArgTyCon ty
1328
1329 isFFIImportResultTy :: DynFlags -> Type -> Bool
1330 isFFIImportResultTy dflags ty
1331   = checkRepTyCon (legalFIResultTyCon dflags) ty
1332
1333 isFFIExportResultTy :: Type -> Bool
1334 isFFIExportResultTy ty = checkRepTyCon legalFEResultTyCon ty
1335
1336 isFFIDynArgumentTy :: Type -> Bool
1337 -- The argument type of a foreign import dynamic must be Ptr, FunPtr, Addr,
1338 -- or a newtype of either.
1339 isFFIDynArgumentTy = checkRepTyConKey [ptrTyConKey, funPtrTyConKey]
1340
1341 isFFIDynResultTy :: Type -> Bool
1342 -- The result type of a foreign export dynamic must be Ptr, FunPtr, Addr,
1343 -- or a newtype of either.
1344 isFFIDynResultTy = checkRepTyConKey [ptrTyConKey, funPtrTyConKey]
1345
1346 isFFILabelTy :: Type -> Bool
1347 -- The type of a foreign label must be Ptr, FunPtr, Addr,
1348 -- or a newtype of either.
1349 isFFILabelTy = checkRepTyConKey [ptrTyConKey, funPtrTyConKey]
1350
1351 isFFIPrimArgumentTy :: DynFlags -> Type -> Bool
1352 -- Checks for valid argument type for a 'foreign import prim'
1353 -- Currently they must all be simple unlifted types.
1354 isFFIPrimArgumentTy dflags ty
1355    = checkRepTyCon (legalFIPrimArgTyCon dflags) ty
1356
1357 isFFIPrimResultTy :: DynFlags -> Type -> Bool
1358 -- Checks for valid result type for a 'foreign import prim'
1359 -- Currently it must be an unlifted type, including unboxed tuples.
1360 isFFIPrimResultTy dflags ty
1361    = checkRepTyCon (legalFIPrimResultTyCon dflags) ty
1362
1363 isFFIDotnetTy :: DynFlags -> Type -> Bool
1364 isFFIDotnetTy dflags ty
1365   = checkRepTyCon (\ tc -> (legalFIResultTyCon dflags tc ||
1366                            isFFIDotnetObjTy ty || isStringTy ty)) ty
1367         -- NB: isStringTy used to look through newtypes, but
1368         --     it no longer does so.  May need to adjust isFFIDotNetTy
1369         --     if we do want to look through newtypes.
1370
1371 isFFIDotnetObjTy :: Type -> Bool
1372 isFFIDotnetObjTy ty
1373   = checkRepTyCon check_tc t_ty
1374   where
1375    (_, t_ty) = tcSplitForAllTys ty
1376    check_tc tc = getName tc == objectTyConName
1377
1378 isFunPtrTy :: Type -> Bool
1379 isFunPtrTy = checkRepTyConKey [funPtrTyConKey]
1380
1381 checkRepTyCon :: (TyCon -> Bool) -> Type -> Bool
1382 -- Look through newtypes, but *not* foralls
1383 -- Should work even for recursive newtypes
1384 -- eg Manuel had:       newtype T = MkT (Ptr T)
1385 checkRepTyCon check_tc ty
1386   = go [] ty
1387   where
1388     go rec_nts ty
1389       | Just (tc,tys) <- splitTyConApp_maybe ty
1390       = case carefullySplitNewType_maybe rec_nts tc tys of
1391            Just (rec_nts', ty') -> go rec_nts' ty'
1392            Nothing              -> check_tc tc
1393       | otherwise
1394       = False
1395
1396 checkRepTyConKey :: [Unique] -> Type -> Bool
1397 -- Like checkRepTyCon, but just looks at the TyCon key
1398 checkRepTyConKey keys
1399   = checkRepTyCon (\tc -> tyConUnique tc `elem` keys)
1400 \end{code}
1401
1402 ----------------------------------------------
1403 These chaps do the work; they are not exported
1404 ----------------------------------------------
1405
1406 \begin{code}
1407 legalFEArgTyCon :: TyCon -> Bool
1408 legalFEArgTyCon tc
1409   -- It's illegal to make foreign exports that take unboxed
1410   -- arguments.  The RTS API currently can't invoke such things.  --SDM 7/2000
1411   = boxedMarshalableTyCon tc
1412
1413 legalFIResultTyCon :: DynFlags -> TyCon -> Bool
1414 legalFIResultTyCon dflags tc
1415   | tc == unitTyCon         = True
1416   | otherwise               = marshalableTyCon dflags tc
1417
1418 legalFEResultTyCon :: TyCon -> Bool
1419 legalFEResultTyCon tc
1420   | tc == unitTyCon         = True
1421   | otherwise               = boxedMarshalableTyCon tc
1422
1423 legalOutgoingTyCon :: DynFlags -> Safety -> TyCon -> Bool
1424 -- Checks validity of types going from Haskell -> external world
1425 legalOutgoingTyCon dflags _ tc
1426   = marshalableTyCon dflags tc
1427
1428 legalFFITyCon :: TyCon -> Bool
1429 -- True for any TyCon that can possibly be an arg or result of an FFI call
1430 legalFFITyCon tc
1431   = isUnLiftedTyCon tc || boxedMarshalableTyCon tc || tc == unitTyCon
1432
1433 marshalableTyCon :: DynFlags -> TyCon -> Bool
1434 marshalableTyCon dflags tc
1435   =  (xopt Opt_UnliftedFFITypes dflags
1436       && isUnLiftedTyCon tc
1437       && not (isUnboxedTupleTyCon tc)
1438       && case tyConPrimRep tc of        -- Note [Marshalling VoidRep]
1439            VoidRep -> False
1440            _       -> True)
1441   || boxedMarshalableTyCon tc
1442
1443 boxedMarshalableTyCon :: TyCon -> Bool
1444 boxedMarshalableTyCon tc
1445    = getUnique tc `elem` [ intTyConKey, int8TyConKey, int16TyConKey
1446                          , int32TyConKey, int64TyConKey
1447                          , wordTyConKey, word8TyConKey, word16TyConKey
1448                          , word32TyConKey, word64TyConKey
1449                          , floatTyConKey, doubleTyConKey
1450                          , ptrTyConKey, funPtrTyConKey
1451                          , charTyConKey
1452                          , stablePtrTyConKey
1453                          , boolTyConKey
1454                          ]
1455
1456 legalFIPrimArgTyCon :: DynFlags -> TyCon -> Bool
1457 -- Check args of 'foreign import prim', only allow simple unlifted types.
1458 -- Strictly speaking it is unnecessary to ban unboxed tuples here since
1459 -- currently they're of the wrong kind to use in function args anyway.
1460 legalFIPrimArgTyCon dflags tc
1461   = xopt Opt_UnliftedFFITypes dflags
1462     && isUnLiftedTyCon tc
1463     && not (isUnboxedTupleTyCon tc)
1464
1465 legalFIPrimResultTyCon :: DynFlags -> TyCon -> Bool
1466 -- Check result type of 'foreign import prim'. Allow simple unlifted
1467 -- types and also unboxed tuple result types '... -> (# , , #)'
1468 legalFIPrimResultTyCon dflags tc
1469   = xopt Opt_UnliftedFFITypes dflags
1470     && isUnLiftedTyCon tc
1471     && (isUnboxedTupleTyCon tc
1472         || case tyConPrimRep tc of      -- Note [Marshalling VoidRep]
1473            VoidRep -> False
1474            _       -> True)
1475 \end{code}
1476
1477 Note [Marshalling VoidRep]
1478 ~~~~~~~~~~~~~~~~~~~~~~~~~~
1479 We don't treat State# (whose PrimRep is VoidRep) as marshalable.
1480 In turn that means you can't write
1481         foreign import foo :: Int -> State# RealWorld
1482
1483 Reason: the back end falls over with panic "primRepHint:VoidRep";
1484         and there is no compelling reason to permit it