compiler/typecheck/TcType.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5 \section[TcType]{Types used in the typechecker}
   6
   7 This module provides the Type interface for front-end parts of the
   8 compiler.  These parts
   9
  10         * treat "source types" as opaque:
  11                 newtypes, and predicates are meaningful.
  12         * look through usage types
  13
  14 The "tc" prefix is for "TypeChecker", because the type checker
  15 is the principal client.
  16
  17 \begin{code}
  18 module TcType (
  19   --------------------------------
  20   -- Types
  21   TcType, TcSigmaType, TcRhoType, TcTauType, TcPredType, TcThetaType,
  22   TcTyVar, TcTyVarSet, TcKind,
  23
  24   BoxyTyVar, BoxySigmaType, BoxyRhoType, BoxyThetaType, BoxyType,
  25
  26   --------------------------------
  27   -- MetaDetails
  28   UserTypeCtxt(..), pprUserTypeCtxt,
  29   TcTyVarDetails(..), BoxInfo(..), pprTcTyVarDetails,
  30   MetaDetails(Flexi, Indirect), SkolemInfo(..), pprSkolTvBinding, pprSkolInfo,
  31   isImmutableTyVar, isSkolemTyVar, isMetaTyVar, isBoxyTyVar,
  32   isSigTyVar, isExistentialTyVar,  isTyConableTyVar,
  33   metaTvRef,
  34   isFlexi, isIndirect, isRuntimeUnk, isUnk,
  35
  36   --------------------------------
  37   -- Builders
  38   mkPhiTy, mkSigmaTy,
  39
  40   --------------------------------
  41   -- Splitters
  42   -- These are important because they do not look through newtypes
  43   tcView,
  44   tcSplitForAllTys, tcSplitPhiTy, tcSplitPredFunTy_maybe,
  45   tcSplitFunTy_maybe, tcSplitFunTys, tcFunArgTy, tcFunResultTy, tcSplitFunTysN,
  46   tcSplitTyConApp, tcSplitTyConApp_maybe, tcTyConAppTyCon, tcTyConAppArgs,
  47   tcSplitAppTy_maybe, tcSplitAppTy, tcSplitAppTys, repSplitAppTy_maybe,
  48   tcInstHeadTyNotSynonym, tcInstHeadTyAppAllTyVars,
  49   tcGetTyVar_maybe, tcGetTyVar,
  50   tcSplitSigmaTy, tcMultiSplitSigmaTy,
  51
  52   ---------------------------------
  53   -- Predicates.
  54   -- Again, newtypes are opaque
  55   tcEqType, tcEqTypes, tcEqPred, tcCmpType, tcCmpTypes, tcCmpPred, tcEqTypeX,
  56   eqKind,
  57   isSigmaTy, isOverloadedTy, isRigidTy, isBoxyTy,
  58   isDoubleTy, isFloatTy, isIntTy, isWordTy, isStringTy,
  59   isIntegerTy, isBoolTy, isUnitTy, isCharTy,
  60   isTauTy, isTauTyCon, tcIsTyVarTy, tcIsForAllTy,
  61   isOpenSynTyConApp,
  62
  63   ---------------------------------
  64   -- Misc type manipulators
  65   deNoteType,
  66   tyClsNamesOfType, tyClsNamesOfDFunHead,
  67   getDFunTyKey,
  68
  69   ---------------------------------
  70   -- Predicate types
  71   getClassPredTys_maybe, getClassPredTys,
  72   isClassPred, isTyVarClassPred, isEqPred,
  73   mkDictTy, tcSplitPredTy_maybe,
  74   isPredTy, isDictTy, tcSplitDFunTy, tcSplitDFunHead, predTyUnique,
  75   mkClassPred, isInheritablePred, isIPPred,
  76   dataConsStupidTheta, isRefineableTy, isRefineablePred,
  77
  78   ---------------------------------
  79   -- Foreign import and export
  80   isFFIArgumentTy,     -- :: DynFlags -> Safety -> Type -> Bool
  81   isFFIImportResultTy, -- :: DynFlags -> Type -> Bool
  82   isFFIExportResultTy, -- :: Type -> Bool
  83   isFFIExternalTy,     -- :: Type -> Bool
  84   isFFIDynArgumentTy,  -- :: Type -> Bool
  85   isFFIDynResultTy,    -- :: Type -> Bool
  86   isFFILabelTy,        -- :: Type -> Bool
  87   isFFIDotnetTy,       -- :: DynFlags -> Type -> Bool
  88   isFFIDotnetObjTy,    -- :: Type -> Bool
  89   isFFITy,             -- :: Type -> Bool
  90   isFunPtrTy,          -- :: Type -> Bool
  91   tcSplitIOType_maybe, -- :: Type -> Maybe Type
  92   toDNType,            -- :: Type -> DNType
  93
  94   --------------------------------
  95   -- Rexported from Type
  96   Kind,         -- Stuff to do with kinds is insensitive to pre/post Tc
  97   unliftedTypeKind, liftedTypeKind, argTypeKind,
  98   openTypeKind, mkArrowKind, mkArrowKinds,
  99   isLiftedTypeKind, isUnliftedTypeKind, isSubOpenTypeKind,
 100   isSubArgTypeKind, isSubKind, defaultKind,
 101   kindVarRef, mkKindVar,
 102
 103   Type, PredType(..), ThetaType,
 104   mkForAllTy, mkForAllTys,
 105   mkFunTy, mkFunTys, zipFunTys,
 106   mkTyConApp, mkAppTy, mkAppTys, applyTy, applyTys,
 107   mkTyVarTy, mkTyVarTys, mkTyConTy, mkPredTy, mkPredTys,
 108
 109   -- Type substitutions
 110   TvSubst(..),  -- Representation visible to a few friends
 111   TvSubstEnv, emptyTvSubst, substEqSpec,
 112   mkOpenTvSubst, zipOpenTvSubst, zipTopTvSubst, mkTopTvSubst, notElemTvSubst,
 113   getTvSubstEnv, setTvSubstEnv, getTvInScope, extendTvInScope, lookupTyVar,
 114   extendTvSubst, extendTvSubstList, isInScope, mkTvSubst, zipTyEnv,
 115   substTy, substTys, substTyWith, substTheta, substTyVar, substTyVars, substTyVarBndr,
 116
 117   isUnLiftedType,       -- Source types are always lifted
 118   isUnboxedTupleType,   -- Ditto
 119   isPrimitiveType,
 120
 121   tidyTopType, tidyType, tidyPred, tidyTypes, tidyFreeTyVars, tidyOpenType, tidyOpenTypes,
 122   tidyTyVarBndr, tidyOpenTyVar, tidyOpenTyVars, tidySkolemTyVar,
 123   typeKind, tidyKind,
 124
 125   tyVarsOfType, tyVarsOfTypes, tyVarsOfPred, tyVarsOfTheta,
 126   tcTyVarsOfType, tcTyVarsOfTypes, exactTyVarsOfType, exactTyVarsOfTypes,
 127
 128   pprKind, pprParendKind,
 129   pprType, pprParendType, pprTypeApp, pprTyThingCategory,
 130   pprPred, pprTheta, pprThetaArrow, pprClassPred
 131
 132   ) where
 133
 134 #include "HsVersions.h"
 135
 136 -- friends:
 137 import TypeRep
 138 import DataCon
 139 import Class
 140 import Var
 141 import ForeignCall
 142 import Unify
 143 import VarSet
 144 import Type
 145 import Coercion
 146 import TyCon
 147
 148 -- others:
 149 import DynFlags
 150 import Name
 151 import NameSet
 152 import VarEnv
 153 import OccName
 154 import PrelNames
 155 import TysWiredIn
 156 import BasicTypes
 157 import Util
 158 import Maybes
 159 import ListSetOps
 160 import Outputable
 161 import FastString
 162
 163 import Data.List
 164 import Data.IORef
 165 \end{code}
 166
 167 %************************************************************************
 168 %*                                                                      *
 169 \subsection{Types}
 170 %*                                                                      *
 171 %************************************************************************
 172
 173 The type checker divides the generic Type world into the
 174 following more structured beasts:
 175
 176 sigma ::= forall tyvars. phi
 177         -- A sigma type is a qualified type
 178         --
 179         -- Note that even if 'tyvars' is empty, theta
 180         -- may not be: e.g.   (?x::Int) => Int
 181
 182         -- Note that 'sigma' is in prenex form:
 183         -- all the foralls are at the front.
 184         -- A 'phi' type has no foralls to the right of
 185         -- an arrow
 186
 187 phi :: theta => rho
 188
 189 rho ::= sigma -> rho
 190      |  tau
 191
 192 -- A 'tau' type has no quantification anywhere
 193 -- Note that the args of a type constructor must be taus
 194 tau ::= tyvar
 195      |  tycon tau_1 .. tau_n
 196      |  tau_1 tau_2
 197      |  tau_1 -> tau_2
 198
 199 -- In all cases, a (saturated) type synonym application is legal,
 200 -- provided it expands to the required form.
 201
 202 \begin{code}
 203 type TcTyVar = TyVar    -- Used only during type inference
 204 type TcType = Type      -- A TcType can have mutable type variables
 205         -- Invariant on ForAllTy in TcTypes:
 206         --      forall a. T
 207         -- a cannot occur inside a MutTyVar in T; that is,
 208         -- T is "flattened" before quantifying over a
 209
 210 -- These types do not have boxy type variables in them
 211 type TcPredType     = PredType
 212 type TcThetaType    = ThetaType
 213 type TcSigmaType    = TcType
 214 type TcRhoType      = TcType
 215 type TcTauType      = TcType
 216 type TcKind         = Kind
 217 type TcTyVarSet     = TyVarSet
 218
 219 -- These types may have boxy type variables in them
 220 type BoxyTyVar      = TcTyVar
 221 type BoxyRhoType    = TcType
 222 type BoxyThetaType  = TcThetaType
 223 type BoxySigmaType  = TcType
 224 type BoxyType       = TcType
 225 \end{code}
 226
 227
 228 %************************************************************************
 229 %*                                                                      *
 230 \subsection{TyVarDetails}
 231 %*                                                                      *
 232 %************************************************************************
 233
 234 TyVarDetails gives extra info about type variables, used during type
 235 checking.  It's attached to mutable type variables only.
 236 It's knot-tied back to Var.lhs.  There is no reason in principle
 237 why Var.lhs shouldn't actually have the definition, but it "belongs" here.
 238
 239
 240 Note [Signature skolems]
 241 ~~~~~~~~~~~~~~~~~~~~~~~~
 242 Consider this
 243
 244   x :: [a]
 245   y :: b
 246   (x,y,z) = ([y,z], z, head x)
 247
 248 Here, x and y have type sigs, which go into the environment.  We used to
 249 instantiate their types with skolem constants, and push those types into
 250 the RHS, so we'd typecheck the RHS with type
 251         ( [a*], b*, c )
 252 where a*, b* are skolem constants, and c is an ordinary meta type varible.
 253
 254 The trouble is that the occurrences of z in the RHS force a* and b* to
 255 be the *same*, so we can't make them into skolem constants that don't unify
 256 with each other.  Alas.
 257
 258 One solution would be insist that in the above defn the programmer uses
 259 the same type variable in both type signatures.  But that takes explanation.
 260
 261 The alternative (currently implemented) is to have a special kind of skolem
 262 constant, SigTv, which can unify with other SigTvs.  These are *not* treated
 263 as righd for the purposes of GADTs.  And they are used *only* for pattern
 264 bindings and mutually recursive function bindings.  See the function
 265 TcBinds.tcInstSig, and its use_skols parameter.
 266
 267
 268 \begin{code}
 269 -- A TyVarDetails is inside a TyVar
 270 data TcTyVarDetails
 271   = SkolemTv SkolemInfo                 -- A skolem constant
 272
 273   | MetaTv BoxInfo (IORef MetaDetails)
 274
 275 data BoxInfo
 276    = BoxTv      -- The contents is a (non-boxy) sigma-type
 277                 -- That is, this MetaTv is a "box"
 278
 279    | TauTv      -- The contents is a (non-boxy) tau-type
 280                 -- That is, this MetaTv is an ordinary unification variable
 281
 282    | SigTv SkolemInfo   -- A variant of TauTv, except that it should not be
 283                         -- unified with a type, only with a type variable
 284                         -- SigTvs are only distinguished to improve error messages
 285                         --      see Note [Signature skolems]
 286                         --      The MetaDetails, if filled in, will
 287                         --      always be another SigTv or a SkolemTv
 288
 289 -- INVARIANTS:
 290 --      A TauTv is always filled in with a tau-type, which
 291 --      never contains any BoxTvs, nor any ForAlls
 292 --
 293 --      However, a BoxTv can contain a type that contains further BoxTvs
 294 --      Notably, when typechecking an explicit list, say [e1,e2], with
 295 --      expected type being a box b1, we fill in b1 with (List b2), where
 296 --      b2 is another (currently empty) box.
 297
 298 data MetaDetails
 299   = Flexi               -- Flexi type variables unify to become
 300                         -- Indirects.
 301
 302   | Indirect TcType     -- INVARIANT:
 303                         --   For a BoxTv, this type must be non-boxy
 304                         --   For a TauTv, this type must be a tau-type
 305
 306 -- Generally speaking, SkolemInfo should not contain location info
 307 -- that is contained in the Name of the tyvar with this SkolemInfo
 308 data SkolemInfo
 309   = SigSkol UserTypeCtxt        -- A skolem that is created by instantiating
 310                                 -- a programmer-supplied type signature
 311                                 -- Location of the binding site is on the TyVar
 312
 313         -- The rest are for non-scoped skolems
 314   | ClsSkol Class       -- Bound at a class decl
 315   | InstSkol            -- Bound at an instance decl
 316   | FamInstSkol         -- Bound at a family instance decl
 317   | PatSkol DataCon     -- An existential type variable bound by a pattern for
 318                         -- a data constructor with an existential type. E.g.
 319                         --      data T = forall a. Eq a => MkT a
 320                         --      f (MkT x) = ...
 321                         -- The pattern MkT x will allocate an existential type
 322                         -- variable for 'a'.
 323   | ArrowSkol           -- An arrow form (see TcArrows)
 324
 325   | RuleSkol RuleName   -- The LHS of a RULE
 326   | GenSkol [TcTyVar]   -- Bound when doing a subsumption check for
 327             TcType      --      (forall tvs. ty)
 328
 329   | RuntimeUnkSkol      -- a type variable used to represent an unknown
 330                         -- runtime type (used in the GHCi debugger)
 331
 332   | UnkSkol             -- Unhelpful info (until I improve it)
 333
 334 -------------------------------------
 335 -- UserTypeCtxt describes the places where a
 336 -- programmer-written type signature can occur
 337 -- Like SkolemInfo, no location info
 338 data UserTypeCtxt
 339   = FunSigCtxt Name     -- Function type signature
 340                         -- Also used for types in SPECIALISE pragmas
 341   | ExprSigCtxt         -- Expression type signature
 342   | ConArgCtxt Name     -- Data constructor argument
 343   | TySynCtxt Name      -- RHS of a type synonym decl
 344   | GenPatCtxt          -- Pattern in generic decl
 345                         --      f{| a+b |} (Inl x) = ...
 346   | LamPatSigCtxt               -- Type sig in lambda pattern
 347                         --      f (x::t) = ...
 348   | BindPatSigCtxt      -- Type sig in pattern binding pattern
 349                         --      (x::t, y) = e
 350   | ResSigCtxt          -- Result type sig
 351                         --      f x :: t = ....
 352   | ForSigCtxt Name     -- Foreign inport or export signature
 353   | DefaultDeclCtxt     -- Types in a default declaration
 354   | SpecInstCtxt        -- SPECIALISE instance pragma
 355
 356 -- Notes re TySynCtxt
 357 -- We allow type synonyms that aren't types; e.g.  type List = []
 358 --
 359 -- If the RHS mentions tyvars that aren't in scope, we'll
 360 -- quantify over them:
 361 --      e.g.    type T = a->a
 362 -- will become  type T = forall a. a->a
 363 --
 364 -- With gla-exts that's right, but for H98 we should complain.
 365
 366 ---------------------------------
 367 -- Kind variables:
 368
 369 mkKindName :: Unique -> Name
 370 mkKindName unique = mkSystemName unique kind_var_occ
 371
 372 kindVarRef :: KindVar -> IORef MetaDetails
 373 kindVarRef tc =
 374   ASSERT ( isTcTyVar tc )
 375   case tcTyVarDetails tc of
 376     MetaTv TauTv ref -> ref
 377     _                -> pprPanic "kindVarRef" (ppr tc)
 378
 379 mkKindVar :: Unique -> IORef MetaDetails -> KindVar
 380 mkKindVar u r
 381   = mkTcTyVar (mkKindName u)
 382               tySuperKind  -- not sure this is right,
 383                             -- do we need kind vars for
 384                             -- coercions?
 385               (MetaTv TauTv r)
 386
 387 kind_var_occ :: OccName -- Just one for all KindVars
 388                         -- They may be jiggled by tidying
 389 kind_var_occ = mkOccName tvName "k"
 390 \end{code}
 391
 392 %************************************************************************
 393 %*                                                                      *
 394                 Pretty-printing
 395 %*                                                                      *
 396 %************************************************************************
 397
 398 \begin{code}
 399 pprTcTyVarDetails :: TcTyVarDetails -> SDoc
 400 -- For debugging
 401 pprTcTyVarDetails (SkolemTv _)         = ptext (sLit "sk")
 402 pprTcTyVarDetails (MetaTv BoxTv _)     = ptext (sLit "box")
 403 pprTcTyVarDetails (MetaTv TauTv _)     = ptext (sLit "tau")
 404 pprTcTyVarDetails (MetaTv (SigTv _) _) = ptext (sLit "sig")
 405
 406 pprUserTypeCtxt :: UserTypeCtxt -> SDoc
 407 pprUserTypeCtxt (FunSigCtxt n)  = ptext (sLit "the type signature for") <+> quotes (ppr n)
 408 pprUserTypeCtxt ExprSigCtxt     = ptext (sLit "an expression type signature")
 409 pprUserTypeCtxt (ConArgCtxt c)  = ptext (sLit "the type of the constructor") <+> quotes (ppr c)
 410 pprUserTypeCtxt (TySynCtxt c)   = ptext (sLit "the RHS of the type synonym") <+> quotes (ppr c)
 411 pprUserTypeCtxt GenPatCtxt      = ptext (sLit "the type pattern of a generic definition")
 412 pprUserTypeCtxt LamPatSigCtxt   = ptext (sLit "a pattern type signature")
 413 pprUserTypeCtxt BindPatSigCtxt  = ptext (sLit "a pattern type signature")
 414 pprUserTypeCtxt ResSigCtxt      = ptext (sLit "a result type signature")
 415 pprUserTypeCtxt (ForSigCtxt n)  = ptext (sLit "the foreign declaration for") <+> quotes (ppr n)
 416 pprUserTypeCtxt DefaultDeclCtxt = ptext (sLit "a type in a `default' declaration")
 417 pprUserTypeCtxt SpecInstCtxt    = ptext (sLit "a SPECIALISE instance pragma")
 418
 419
 420 --------------------------------
 421 tidySkolemTyVar :: TidyEnv -> TcTyVar -> (TidyEnv, TcTyVar)
 422 -- Tidy the type inside a GenSkol, preparatory to printing it
 423 tidySkolemTyVar env tv
 424   = ASSERT( isTcTyVar tv && (isSkolemTyVar tv || isSigTyVar tv ) )
 425     (env1, mkTcTyVar (tyVarName tv) (tyVarKind tv) info1)
 426   where
 427     (env1, info1) = case tcTyVarDetails tv of
 428                         SkolemTv info -> (env1, SkolemTv info')
 429                                 where
 430                                   (env1, info') = tidy_skol_info env info
 431                         MetaTv (SigTv info) box -> (env1, MetaTv (SigTv info') box)
 432                                 where
 433                                   (env1, info') = tidy_skol_info env info
 434                         info -> (env, info)
 435
 436     tidy_skol_info env (GenSkol tvs ty) = (env2, GenSkol tvs1 ty1)
 437                             where
 438                               (env1, tvs1) = tidyOpenTyVars env tvs
 439                               (env2, ty1)  = tidyOpenType env1 ty
 440     tidy_skol_info env info = (env, info)
 441
 442 pprSkolTvBinding :: TcTyVar -> SDoc
 443 -- Print info about the binding of a skolem tyvar,
 444 -- or nothing if we don't have anything useful to say
 445 pprSkolTvBinding tv
 446   = ASSERT ( isTcTyVar tv )
 447     quotes (ppr tv) <+> ppr_details (tcTyVarDetails tv)
 448   where
 449     ppr_details (MetaTv TauTv _)        = ptext (sLit "is a meta type variable")
 450     ppr_details (MetaTv BoxTv _)        = ptext (sLit "is a boxy type variable")
 451     ppr_details (MetaTv (SigTv info) _) = ppr_skol info
 452     ppr_details (SkolemTv info)         = ppr_skol info
 453
 454     ppr_skol UnkSkol        = ptext (sLit "is an unknown type variable")        -- Unhelpful
 455     ppr_skol RuntimeUnkSkol = ptext (sLit "is an unknown runtime type")
 456     ppr_skol info           = sep [ptext (sLit "is a rigid type variable bound by"),
 457                                    sep [pprSkolInfo info,
 458                                          nest 2 (ptext (sLit "at") <+> ppr (getSrcLoc tv))]]
 459
 460 pprSkolInfo :: SkolemInfo -> SDoc
 461 pprSkolInfo (SigSkol ctxt)   = pprUserTypeCtxt ctxt
 462 pprSkolInfo (ClsSkol cls)    = ptext (sLit "the class declaration for") <+> quotes (ppr cls)
 463 pprSkolInfo InstSkol         = ptext (sLit "the instance declaration")
 464 pprSkolInfo FamInstSkol      = ptext (sLit "the family instance declaration")
 465 pprSkolInfo (RuleSkol name)  = ptext (sLit "the RULE") <+> doubleQuotes (ftext name)
 466 pprSkolInfo ArrowSkol        = ptext (sLit "the arrow form")
 467 pprSkolInfo (PatSkol dc)     = sep [ptext (sLit "the constructor") <+> quotes (ppr dc)]
 468 pprSkolInfo (GenSkol tvs ty) = sep [ptext (sLit "the polymorphic type"),
 469                                     nest 2 (quotes (ppr (mkForAllTys tvs ty)))]
 470
 471 -- UnkSkol
 472 -- For type variables the others are dealt with by pprSkolTvBinding.
 473 -- For Insts, these cases should not happen
 474 pprSkolInfo UnkSkol = panic "UnkSkol"
 475 pprSkolInfo RuntimeUnkSkol = panic "RuntimeUnkSkol"
 476
 477 instance Outputable MetaDetails where
 478   ppr Flexi         = ptext (sLit "Flexi")
 479   ppr (Indirect ty) = ptext (sLit "Indirect") <+> ppr ty
 480 \end{code}
 481
 482
 483 %************************************************************************
 484 %*                                                                      *
 485                 Predicates
 486 %*                                                                      *
 487 %************************************************************************
 488
 489 \begin{code}
 490 isImmutableTyVar :: TyVar -> Bool
 491
 492 isImmutableTyVar tv
 493   | isTcTyVar tv = isSkolemTyVar tv
 494   | otherwise    = True
 495
 496 isTyConableTyVar, isSkolemTyVar, isExistentialTyVar,
 497   isBoxyTyVar, isMetaTyVar :: TcTyVar -> Bool
 498
 499 isTyConableTyVar tv
 500         -- True of a meta-type variable that can be filled in
 501         -- with a type constructor application; in particular,
 502         -- not a SigTv
 503   = ASSERT( isTcTyVar tv)
 504     case tcTyVarDetails tv of
 505         MetaTv BoxTv      _ -> True
 506         MetaTv TauTv      _ -> True
 507         MetaTv (SigTv {}) _ -> False
 508         SkolemTv {}         -> False
 509
 510 isSkolemTyVar tv
 511   = ASSERT2( isTcTyVar tv, ppr tv )
 512     case tcTyVarDetails tv of
 513         SkolemTv _         -> True
 514         MetaTv _ _         -> False
 515
 516 isExistentialTyVar tv   -- Existential type variable, bound by a pattern
 517   = ASSERT( isTcTyVar tv )
 518     case tcTyVarDetails tv of
 519         SkolemTv (PatSkol {}) -> True
 520         _                     -> False
 521
 522 isMetaTyVar tv
 523   = ASSERT2( isTcTyVar tv, ppr tv )
 524     case tcTyVarDetails tv of
 525         MetaTv _ _ -> True
 526         _          -> False
 527
 528 isBoxyTyVar tv
 529   = ASSERT( isTcTyVar tv )
 530     case tcTyVarDetails tv of
 531         MetaTv BoxTv _ -> True
 532         _              -> False
 533
 534 isSigTyVar :: Var -> Bool
 535 isSigTyVar tv
 536   = ASSERT( isTcTyVar tv )
 537     case tcTyVarDetails tv of
 538         MetaTv (SigTv _) _ -> True
 539         _                  -> False
 540
 541 metaTvRef :: TyVar -> IORef MetaDetails
 542 metaTvRef tv
 543   = ASSERT2( isTcTyVar tv, ppr tv )
 544     case tcTyVarDetails tv of
 545         MetaTv _ ref -> ref
 546         _          -> pprPanic "metaTvRef" (ppr tv)
 547
 548 isFlexi, isIndirect :: MetaDetails -> Bool
 549 isFlexi Flexi = True
 550 isFlexi _     = False
 551
 552 isIndirect (Indirect _) = True
 553 isIndirect _            = False
 554
 555 isRuntimeUnk :: TyVar -> Bool
 556 isRuntimeUnk x | isTcTyVar x
 557                , SkolemTv RuntimeUnkSkol <- tcTyVarDetails x = True
 558                | otherwise = False
 559
 560 isUnk :: TyVar -> Bool
 561 isUnk x | isTcTyVar x
 562         , SkolemTv UnkSkol <- tcTyVarDetails x = True
 563         | otherwise = False
 564 \end{code}
 565
 566
 567 %************************************************************************
 568 %*                                                                      *
 569 \subsection{Tau, sigma and rho}
 570 %*                                                                      *
 571 %************************************************************************
 572
 573 \begin{code}
 574 mkSigmaTy :: [TyVar] -> [PredType] -> Type -> Type
 575 mkSigmaTy tyvars theta tau = mkForAllTys tyvars (mkPhiTy theta tau)
 576
 577 mkPhiTy :: [PredType] -> Type -> Type
 578 mkPhiTy theta ty = foldr (\p r -> mkFunTy (mkPredTy p) r) ty theta
 579 \end{code}
 580
 581 @isTauTy@ tests for nested for-alls.  It should not be called on a boxy type.
 582
 583 \begin{code}
 584 isTauTy :: Type -> Bool
 585 isTauTy ty | Just ty' <- tcView ty = isTauTy ty'
 586 isTauTy (TyVarTy tv)     = ASSERT( not (isTcTyVar tv && isBoxyTyVar tv) )
 587                            True
 588 isTauTy (TyConApp tc tys) = all isTauTy tys && isTauTyCon tc
 589 isTauTy (AppTy a b)       = isTauTy a && isTauTy b
 590 isTauTy (FunTy a b)       = isTauTy a && isTauTy b
 591 isTauTy (PredTy _)        = True                -- Don't look through source types
 592 isTauTy _                 = False
 593
 594
 595 isTauTyCon :: TyCon -> Bool
 596 -- Returns False for type synonyms whose expansion is a polytype
 597 isTauTyCon tc
 598   | isClosedSynTyCon tc = isTauTy (snd (synTyConDefn tc))
 599   | otherwise           = True
 600
 601 ---------------
 602 isBoxyTy :: TcType -> Bool
 603 isBoxyTy ty = any isBoxyTyVar (varSetElems (tcTyVarsOfType ty))
 604
 605 isRigidTy :: TcType -> Bool
 606 -- A type is rigid if it has no meta type variables in it
 607 isRigidTy ty = all isImmutableTyVar (varSetElems (tcTyVarsOfType ty))
 608
 609 isRefineableTy :: TcType -> (Bool,Bool)
 610 -- A type should have type refinements applied to it if it has
 611 -- free type variables, and they are all rigid
 612 isRefineableTy ty = (null tc_tvs,  all isImmutableTyVar tc_tvs)
 613                     where
 614                       tc_tvs = varSetElems (tcTyVarsOfType ty)
 615
 616 isRefineablePred :: TcPredType -> Bool
 617 isRefineablePred pred = not (null tc_tvs) && all isImmutableTyVar tc_tvs
 618                       where
 619                         tc_tvs = varSetElems (tcTyVarsOfPred pred)
 620
 621 ---------------
 622 getDFunTyKey :: Type -> OccName -- Get some string from a type, to be used to
 623                                 -- construct a dictionary function name
 624 getDFunTyKey ty | Just ty' <- tcView ty = getDFunTyKey ty'
 625 getDFunTyKey (TyVarTy tv)    = getOccName tv
 626 getDFunTyKey (TyConApp tc _) = getOccName tc
 627 getDFunTyKey (AppTy fun _)   = getDFunTyKey fun
 628 getDFunTyKey (FunTy _ _)     = getOccName funTyCon
 629 getDFunTyKey (ForAllTy _ t)  = getDFunTyKey t
 630 getDFunTyKey ty              = pprPanic "getDFunTyKey" (pprType ty)
 631 -- PredTy shouldn't happen
 632 \end{code}
 633
 634
 635 %************************************************************************
 636 %*                                                                      *
 637 \subsection{Expanding and splitting}
 638 %*                                                                      *
 639 %************************************************************************
 640
 641 These tcSplit functions are like their non-Tc analogues, but
 642         a) they do not look through newtypes
 643         b) they do not look through PredTys
 644         c) [future] they ignore usage-type annotations
 645
 646 However, they are non-monadic and do not follow through mutable type
 647 variables.  It's up to you to make sure this doesn't matter.
 648
 649 \begin{code}
 650 tcSplitForAllTys :: Type -> ([TyVar], Type)
 651 tcSplitForAllTys ty = split ty ty []
 652    where
 653      split orig_ty ty tvs | Just ty' <- tcView ty = split orig_ty ty' tvs
 654      split _ (ForAllTy tv ty) tvs
 655        | not (isCoVar tv) = split ty ty (tv:tvs)
 656      split orig_ty _ tvs = (reverse tvs, orig_ty)
 657
 658 tcIsForAllTy :: Type -> Bool
 659 tcIsForAllTy ty | Just ty' <- tcView ty = tcIsForAllTy ty'
 660 tcIsForAllTy (ForAllTy tv _) = not (isCoVar tv)
 661 tcIsForAllTy _               = False
 662
 663 tcSplitPredFunTy_maybe :: Type -> Maybe (PredType, Type)
 664 -- Split off the first predicate argument from a type
 665 tcSplitPredFunTy_maybe ty | Just ty' <- tcView ty = tcSplitPredFunTy_maybe ty'
 666 tcSplitPredFunTy_maybe (ForAllTy tv ty)
 667   | isCoVar tv = Just (coVarPred tv, ty)
 668 tcSplitPredFunTy_maybe (FunTy arg res)
 669   | Just p <- tcSplitPredTy_maybe arg = Just (p, res)
 670 tcSplitPredFunTy_maybe _
 671   = Nothing
 672
 673 tcSplitPhiTy :: Type -> (ThetaType, Type)
 674 tcSplitPhiTy ty
 675   = split ty []
 676   where
 677     split ty ts
 678       = case tcSplitPredFunTy_maybe ty of
 679           Just (pred, ty) -> split ty (pred:ts)
 680           Nothing         -> (reverse ts, ty)
 681
 682 tcSplitSigmaTy :: Type -> ([TyVar], ThetaType, Type)
 683 tcSplitSigmaTy ty = case tcSplitForAllTys ty of
 684                         (tvs, rho) -> case tcSplitPhiTy rho of
 685                                         (theta, tau) -> (tvs, theta, tau)
 686
 687 -----------------------
 688 tcMultiSplitSigmaTy
 689         :: TcSigmaType
 690         -> ( [([TyVar], ThetaType)],    -- forall as.C => forall bs.D
 691              TcSigmaType)               -- The rest of the type
 692
 693 -- We need a loop here because we are now prepared to entertain
 694 -- types like
 695 --      f:: forall a. Eq a => forall b. Baz b => tau
 696 -- We want to instantiate this to
 697 --      f2::tau         {f2 = f1 b (Baz b), f1 = f a (Eq a)}
 698
 699 tcMultiSplitSigmaTy sigma
 700   = case (tcSplitSigmaTy sigma) of
 701         ([], [], _) -> ([], sigma)
 702         (tvs, theta, ty) -> case tcMultiSplitSigmaTy ty of
 703                                 (pairs, rest) -> ((tvs,theta):pairs, rest)
 704
 705 -----------------------
 706 tcTyConAppTyCon :: Type -> TyCon
 707 tcTyConAppTyCon ty = case tcSplitTyConApp_maybe ty of
 708                         Just (tc, _) -> tc
 709                         Nothing      -> pprPanic "tcTyConAppTyCon" (pprType ty)
 710
 711 tcTyConAppArgs :: Type -> [Type]
 712 tcTyConAppArgs ty = case tcSplitTyConApp_maybe ty of
 713                         Just (_, args) -> args
 714                         Nothing        -> pprPanic "tcTyConAppArgs" (pprType ty)
 715
 716 tcSplitTyConApp :: Type -> (TyCon, [Type])
 717 tcSplitTyConApp ty = case tcSplitTyConApp_maybe ty of
 718                         Just stuff -> stuff
 719                         Nothing    -> pprPanic "tcSplitTyConApp" (pprType ty)
 720
 721 tcSplitTyConApp_maybe :: Type -> Maybe (TyCon, [Type])
 722 tcSplitTyConApp_maybe ty | Just ty' <- tcView ty = tcSplitTyConApp_maybe ty'
 723 tcSplitTyConApp_maybe (TyConApp tc tys) = Just (tc, tys)
 724 tcSplitTyConApp_maybe (FunTy arg res)   = Just (funTyCon, [arg,res])
 725         -- Newtypes are opaque, so they may be split
 726         -- However, predicates are not treated
 727         -- as tycon applications by the type checker
 728 tcSplitTyConApp_maybe _                 = Nothing
 729
 730 -----------------------
 731 tcSplitFunTys :: Type -> ([Type], Type)
 732 tcSplitFunTys ty = case tcSplitFunTy_maybe ty of
 733                         Nothing        -> ([], ty)
 734                         Just (arg,res) -> (arg:args, res')
 735                                        where
 736                                           (args,res') = tcSplitFunTys res
 737
 738 tcSplitFunTy_maybe :: Type -> Maybe (Type, Type)
 739 tcSplitFunTy_maybe ty | Just ty' <- tcView ty           = tcSplitFunTy_maybe ty'
 740 tcSplitFunTy_maybe (FunTy arg res) | not (isPredTy arg) = Just (arg, res)
 741 tcSplitFunTy_maybe _                                    = Nothing
 742         -- Note the (not (isPredTy arg)) guard
 743         -- Consider     (?x::Int) => Bool
 744         -- We don't want to treat this as a function type!
 745         -- A concrete example is test tc230:
 746         --      f :: () -> (?p :: ()) => () -> ()
 747         --
 748         --      g = f () ()
 749
 750 tcSplitFunTysN
 751         :: TcRhoType
 752         -> Arity                -- N: Number of desired args
 753         -> ([TcSigmaType],      -- Arg types (N or fewer)
 754             TcSigmaType)        -- The rest of the type
 755
 756 tcSplitFunTysN ty n_args
 757   | n_args == 0
 758   = ([], ty)
 759   | Just (arg,res) <- tcSplitFunTy_maybe ty
 760   = case tcSplitFunTysN res (n_args - 1) of
 761         (args, res) -> (arg:args, res)
 762   | otherwise
 763   = ([], ty)
 764
 765 tcSplitFunTy :: Type -> (Type, Type)
 766 tcSplitFunTy  ty = expectJust "tcSplitFunTy" (tcSplitFunTy_maybe ty)
 767
 768 tcFunArgTy :: Type -> Type
 769 tcFunArgTy    ty = fst (tcSplitFunTy ty)
 770
 771 tcFunResultTy :: Type -> Type
 772 tcFunResultTy ty = snd (tcSplitFunTy ty)
 773
 774 -----------------------
 775 tcSplitAppTy_maybe :: Type -> Maybe (Type, Type)
 776 tcSplitAppTy_maybe ty | Just ty' <- tcView ty = tcSplitAppTy_maybe ty'
 777 tcSplitAppTy_maybe ty = repSplitAppTy_maybe ty
 778
 779 tcSplitAppTy :: Type -> (Type, Type)
 780 tcSplitAppTy ty = case tcSplitAppTy_maybe ty of
 781                     Just stuff -> stuff
 782                     Nothing    -> pprPanic "tcSplitAppTy" (pprType ty)
 783
 784 tcSplitAppTys :: Type -> (Type, [Type])
 785 tcSplitAppTys ty
 786   = go ty []
 787   where
 788     go ty args = case tcSplitAppTy_maybe ty of
 789                    Just (ty', arg) -> go ty' (arg:args)
 790                    Nothing         -> (ty,args)
 791
 792 -----------------------
 793 tcGetTyVar_maybe :: Type -> Maybe TyVar
 794 tcGetTyVar_maybe ty | Just ty' <- tcView ty = tcGetTyVar_maybe ty'
 795 tcGetTyVar_maybe (TyVarTy tv)   = Just tv
 796 tcGetTyVar_maybe _              = Nothing
 797
 798 tcGetTyVar :: String -> Type -> TyVar
 799 tcGetTyVar msg ty = expectJust msg (tcGetTyVar_maybe ty)
 800
 801 tcIsTyVarTy :: Type -> Bool
 802 tcIsTyVarTy ty = maybeToBool (tcGetTyVar_maybe ty)
 803
 804 -----------------------
 805 tcSplitDFunTy :: Type -> ([TyVar], [PredType], Class, [Type])
 806 -- Split the type of a dictionary function
 807 tcSplitDFunTy ty
 808   = case tcSplitSigmaTy ty   of { (tvs, theta, tau) ->
 809     case tcSplitDFunHead tau of { (clas, tys) ->
 810     (tvs, theta, clas, tys) }}
 811
 812 tcSplitDFunHead :: Type -> (Class, [Type])
 813 tcSplitDFunHead tau
 814   = case tcSplitPredTy_maybe tau of
 815         Just (ClassP clas tys) -> (clas, tys)
 816         _ -> panic "tcSplitDFunHead"
 817
 818 tcInstHeadTyNotSynonym :: Type -> Bool
 819 -- Used in Haskell-98 mode, for the argument types of an instance head
 820 -- These must not be type synonyms, but everywhere else type synonyms
 821 -- are transparent, so we need a special function here
 822 tcInstHeadTyNotSynonym ty
 823   = case ty of
 824         TyConApp tc _ -> not (isSynTyCon tc)
 825         _ -> True
 826
 827 tcInstHeadTyAppAllTyVars :: Type -> Bool
 828 -- Used in Haskell-98 mode, for the argument types of an instance head
 829 -- These must be a constructor applied to type variable arguments
 830 tcInstHeadTyAppAllTyVars ty
 831   = case ty of
 832         TyConApp _ tys  -> ok tys
 833         FunTy arg res   -> ok [arg, res]
 834         _               -> False
 835   where
 836         -- Check that all the types are type variables,
 837         -- and that each is distinct
 838     ok tys = equalLength tvs tys && hasNoDups tvs
 839            where
 840              tvs = mapCatMaybes get_tv tys
 841
 842     get_tv (TyVarTy tv)  = Just tv      -- through synonyms
 843     get_tv _             = Nothing
 844 \end{code}
 845
 846
 847
 848 %************************************************************************
 849 %*                                                                      *
 850 \subsection{Predicate types}
 851 %*                                                                      *
 852 %************************************************************************
 853
 854 \begin{code}
 855 tcSplitPredTy_maybe :: Type -> Maybe PredType
 856    -- Returns Just for predicates only
 857 tcSplitPredTy_maybe ty | Just ty' <- tcView ty = tcSplitPredTy_maybe ty'
 858 tcSplitPredTy_maybe (PredTy p)    = Just p
 859 tcSplitPredTy_maybe _             = Nothing
 860
 861 predTyUnique :: PredType -> Unique
 862 predTyUnique (IParam n _)    = getUnique (ipNameName n)
 863 predTyUnique (ClassP clas _) = getUnique clas
 864 predTyUnique (EqPred a b)    = pprPanic "predTyUnique" (ppr (EqPred a b))
 865 \end{code}
 866
 867
 868 --------------------- Dictionary types ---------------------------------
 869
 870 \begin{code}
 871 mkClassPred :: Class -> [Type] -> PredType
 872 mkClassPred clas tys = ClassP clas tys
 873
 874 isClassPred :: PredType -> Bool
 875 isClassPred (ClassP _ _) = True
 876 isClassPred _            = False
 877
 878 isTyVarClassPred :: PredType -> Bool
 879 isTyVarClassPred (ClassP _ tys) = all tcIsTyVarTy tys
 880 isTyVarClassPred _              = False
 881
 882 getClassPredTys_maybe :: PredType -> Maybe (Class, [Type])
 883 getClassPredTys_maybe (ClassP clas tys) = Just (clas, tys)
 884 getClassPredTys_maybe _                 = Nothing
 885
 886 getClassPredTys :: PredType -> (Class, [Type])
 887 getClassPredTys (ClassP clas tys) = (clas, tys)
 888 getClassPredTys _ = panic "getClassPredTys"
 889
 890 mkDictTy :: Class -> [Type] -> Type
 891 mkDictTy clas tys = mkPredTy (ClassP clas tys)
 892
 893 isDictTy :: Type -> Bool
 894 isDictTy ty | Just ty' <- tcView ty = isDictTy ty'
 895 isDictTy (PredTy p) = isClassPred p
 896 isDictTy _          = False
 897 \end{code}
 898
 899 --------------------- Implicit parameters ---------------------------------
 900
 901 \begin{code}
 902 isIPPred :: PredType -> Bool
 903 isIPPred (IParam _ _) = True
 904 isIPPred _            = False
 905
 906 isInheritablePred :: PredType -> Bool
 907 -- Can be inherited by a context.  For example, consider
 908 --      f x = let g y = (?v, y+x)
 909 --            in (g 3 with ?v = 8,
 910 --                g 4 with ?v = 9)
 911 -- The point is that g's type must be quantifed over ?v:
 912 --      g :: (?v :: a) => a -> a
 913 -- but it doesn't need to be quantified over the Num a dictionary
 914 -- which can be free in g's rhs, and shared by both calls to g
 915 isInheritablePred (ClassP _ _) = True
 916 isInheritablePred (EqPred _ _) = True
 917 isInheritablePred _            = False
 918 \end{code}
 919
 920 --------------------- Equality predicates ---------------------------------
 921 \begin{code}
 922 substEqSpec :: TvSubst -> [(TyVar,Type)] -> [(TcType,TcType)]
 923 substEqSpec subst eq_spec = [ (substTyVar subst tv, substTy subst ty)
 924                             | (tv,ty) <- eq_spec]
 925 \end{code}
 926
 927 --------------------- The stupid theta (sigh) ---------------------------------
 928
 929 \begin{code}
 930 dataConsStupidTheta :: [DataCon] -> ThetaType
 931 -- Union the stupid thetas from all the specified constructors (non-empty)
 932 -- All the constructors should have the same result type, modulo alpha conversion
 933 -- The resulting ThetaType uses type variables from the *first* constructor in the list
 934 --
 935 -- It's here because it's used in MkId.mkRecordSelId, and in TcExpr
 936 dataConsStupidTheta (con1:cons)
 937   = nubBy tcEqPred all_preds
 938   where
 939     all_preds     = dataConStupidTheta con1 ++ other_stupids
 940     res_ty1       = dataConOrigResTy con1
 941     other_stupids = [ substPred subst pred
 942                     | con <- cons
 943                     , let (tvs, _, _, res_ty) = dataConSig con
 944                           Just subst = tcMatchTy (mkVarSet tvs) res_ty res_ty1
 945                     , pred <- dataConStupidTheta con ]
 946 dataConsStupidTheta [] = panic "dataConsStupidTheta"
 947 \end{code}
 948
 949
 950 %************************************************************************
 951 %*                                                                      *
 952 \subsection{Predicates}
 953 %*                                                                      *
 954 %************************************************************************
 955
 956 isSigmaTy returns true of any qualified type.  It doesn't *necessarily* have
 957 any foralls.  E.g.
 958         f :: (?x::Int) => Int -> Int
 959
 960 \begin{code}
 961 isSigmaTy :: Type -> Bool
 962 isSigmaTy ty | Just ty' <- tcView ty = isSigmaTy ty'
 963 isSigmaTy (ForAllTy _ _) = True
 964 isSigmaTy (FunTy a _)    = isPredTy a
 965 isSigmaTy _              = False
 966
 967 isOverloadedTy :: Type -> Bool
 968 isOverloadedTy ty | Just ty' <- tcView ty = isOverloadedTy ty'
 969 isOverloadedTy (ForAllTy _ ty) = isOverloadedTy ty
 970 isOverloadedTy (FunTy a _)     = isPredTy a
 971 isOverloadedTy _               = False
 972
 973 isPredTy :: Type -> Bool        -- Belongs in TcType because it does
 974                                 -- not look through newtypes, or predtypes (of course)
 975 isPredTy ty | Just ty' <- tcView ty = isPredTy ty'
 976 isPredTy (PredTy _) = True
 977 isPredTy _          = False
 978 \end{code}
 979
 980 \begin{code}
 981 isFloatTy, isDoubleTy, isIntegerTy, isIntTy, isWordTy, isBoolTy,
 982     isUnitTy, isCharTy :: Type -> Bool
 983 isFloatTy      = is_tc floatTyConKey
 984 isDoubleTy     = is_tc doubleTyConKey
 985 isIntegerTy    = is_tc integerTyConKey
 986 isIntTy        = is_tc intTyConKey
 987 isWordTy       = is_tc wordTyConKey
 988 isBoolTy       = is_tc boolTyConKey
 989 isUnitTy       = is_tc unitTyConKey
 990 isCharTy       = is_tc charTyConKey
 991
 992 isStringTy :: Type -> Bool
 993 isStringTy ty
 994   = case tcSplitTyConApp_maybe ty of
 995       Just (tc, [arg_ty]) -> tc == listTyCon && isCharTy arg_ty
 996       _                   -> False
 997
 998 is_tc :: Unique -> Type -> Bool
 999 -- Newtypes are opaque to this
1000 is_tc uniq ty = case tcSplitTyConApp_maybe ty of
1001                         Just (tc, _) -> uniq == getUnique tc
1002                         Nothing      -> False
1003 \end{code}
1004
1005 \begin{code}
1006 -- NB: Currently used in places where we have already expanded type synonyms;
1007 --     hence no 'coreView'.  This could, however, be changed without breaking
1008 --     any code.
1009 isOpenSynTyConApp :: TcTauType -> Bool
1010 isOpenSynTyConApp (TyConApp tc tys) = isOpenSynTyCon tc &&
1011                                       length tys == tyConArity tc
1012 isOpenSynTyConApp _other            = False
1013 \end{code}
1014
1015
1016 %************************************************************************
1017 %*                                                                      *
1018 \subsection{Misc}
1019 %*                                                                      *
1020 %************************************************************************
1021
1022 \begin{code}
1023 deNoteType :: Type -> Type
1024 -- Remove all *outermost* type synonyms and other notes
1025 deNoteType ty | Just ty' <- tcView ty = deNoteType ty'
1026 deNoteType ty = ty
1027 \end{code}
1028
1029 \begin{code}
1030 tcTyVarsOfType :: Type -> TcTyVarSet
1031 -- Just the *TcTyVars* free in the type
1032 -- (Types.tyVarsOfTypes finds all free TyVars)
1033 tcTyVarsOfType (TyVarTy tv)         = if isTcTyVar tv then unitVarSet tv
1034                                                       else emptyVarSet
1035 tcTyVarsOfType (TyConApp _ tys)     = tcTyVarsOfTypes tys
1036 tcTyVarsOfType (PredTy sty)         = tcTyVarsOfPred sty
1037 tcTyVarsOfType (FunTy arg res)      = tcTyVarsOfType arg `unionVarSet` tcTyVarsOfType res
1038 tcTyVarsOfType (AppTy fun arg)      = tcTyVarsOfType fun `unionVarSet` tcTyVarsOfType arg
1039 tcTyVarsOfType (ForAllTy tyvar ty)  = (tcTyVarsOfType ty `delVarSet` tyvar)
1040                                       `unionVarSet` tcTyVarsOfTyVar tyvar
1041         -- We do sometimes quantify over skolem TcTyVars
1042
1043 tcTyVarsOfTyVar :: TcTyVar -> TyVarSet
1044 tcTyVarsOfTyVar tv | isCoVar tv = tcTyVarsOfType (tyVarKind tv)
1045                    | otherwise  = emptyVarSet
1046
1047 tcTyVarsOfTypes :: [Type] -> TyVarSet
1048 tcTyVarsOfTypes tys = foldr (unionVarSet.tcTyVarsOfType) emptyVarSet tys
1049
1050 tcTyVarsOfPred :: PredType -> TyVarSet
1051 tcTyVarsOfPred (IParam _ ty)    = tcTyVarsOfType ty
1052 tcTyVarsOfPred (ClassP _ tys)   = tcTyVarsOfTypes tys
1053 tcTyVarsOfPred (EqPred ty1 ty2) = tcTyVarsOfType ty1 `unionVarSet` tcTyVarsOfType ty2
1054 \end{code}
1055
1056 Note [Silly type synonym]
1057 ~~~~~~~~~~~~~~~~~~~~~~~~~
1058 Consider
1059         type T a = Int
1060 What are the free tyvars of (T x)?  Empty, of course!
1061 Here's the example that Ralf Laemmel showed me:
1062         foo :: (forall a. C u a -> C u a) -> u
1063         mappend :: Monoid u => u -> u -> u
1064
1065         bar :: Monoid u => u
1066         bar = foo (\t -> t `mappend` t)
1067 We have to generalise at the arg to f, and we don't
1068 want to capture the constraint (Monad (C u a)) because
1069 it appears to mention a.  Pretty silly, but it was useful to him.
1070
1071 exactTyVarsOfType is used by the type checker to figure out exactly
1072 which type variables are mentioned in a type.  It's also used in the
1073 smart-app checking code --- see TcExpr.tcIdApp
1074
1075 On the other hand, consider a *top-level* definition
1076         f = (\x -> x) :: T a -> T a
1077 If we don't abstract over 'a' it'll get fixed to GHC.Prim.Any, and then
1078 if we have an application like (f "x") we get a confusing error message
1079 involving Any.  So the conclusion is this: when generalising
1080   - at top level use tyVarsOfType
1081   - in nested bindings use exactTyVarsOfType
1082 See Trac #1813 for example.
1083
1084 \begin{code}
1085 exactTyVarsOfType :: TcType -> TyVarSet
1086 -- Find the free type variables (of any kind)
1087 -- but *expand* type synonyms.  See Note [Silly type synonym] above.
1088 exactTyVarsOfType ty
1089   = go ty
1090   where
1091     go ty | Just ty' <- tcView ty = go ty'      -- This is the key line
1092     go (TyVarTy tv)               = unitVarSet tv
1093     go (TyConApp _ tys)           = exactTyVarsOfTypes tys
1094     go (PredTy ty)                = go_pred ty
1095     go (FunTy arg res)            = go arg `unionVarSet` go res
1096     go (AppTy fun arg)            = go fun `unionVarSet` go arg
1097     go (ForAllTy tyvar ty)        = delVarSet (go ty) tyvar
1098                                     `unionVarSet` go_tv tyvar
1099
1100     go_pred (IParam _ ty)    = go ty
1101     go_pred (ClassP _ tys)   = exactTyVarsOfTypes tys
1102     go_pred (EqPred ty1 ty2) = go ty1 `unionVarSet` go ty2
1103
1104     go_tv tyvar | isCoVar tyvar = go (tyVarKind tyvar)
1105                 | otherwise     = emptyVarSet
1106
1107 exactTyVarsOfTypes :: [TcType] -> TyVarSet
1108 exactTyVarsOfTypes tys = foldr (unionVarSet . exactTyVarsOfType) emptyVarSet tys
1109 \end{code}
1110
1111 Find the free tycons and classes of a type.  This is used in the front
1112 end of the compiler.
1113
1114 \begin{code}
1115 tyClsNamesOfType :: Type -> NameSet
1116 tyClsNamesOfType (TyVarTy _)                = emptyNameSet
1117 tyClsNamesOfType (TyConApp tycon tys)       = unitNameSet (getName tycon) `unionNameSets` tyClsNamesOfTypes tys
1118 tyClsNamesOfType (PredTy (IParam _ ty))     = tyClsNamesOfType ty
1119 tyClsNamesOfType (PredTy (ClassP cl tys))   = unitNameSet (getName cl) `unionNameSets` tyClsNamesOfTypes tys
1120 tyClsNamesOfType (PredTy (EqPred ty1 ty2))  = tyClsNamesOfType ty1 `unionNameSets` tyClsNamesOfType ty2
1121 tyClsNamesOfType (FunTy arg res)            = tyClsNamesOfType arg `unionNameSets` tyClsNamesOfType res
1122 tyClsNamesOfType (AppTy fun arg)            = tyClsNamesOfType fun `unionNameSets` tyClsNamesOfType arg
1123 tyClsNamesOfType (ForAllTy _ ty)            = tyClsNamesOfType ty
1124
1125 tyClsNamesOfTypes :: [Type] -> NameSet
1126 tyClsNamesOfTypes tys = foldr (unionNameSets . tyClsNamesOfType) emptyNameSet tys
1127
1128 tyClsNamesOfDFunHead :: Type -> NameSet
1129 -- Find the free type constructors and classes
1130 -- of the head of the dfun instance type
1131 -- The 'dfun_head_type' is because of
1132 --      instance Foo a => Baz T where ...
1133 -- The decl is an orphan if Baz and T are both not locally defined,
1134 --      even if Foo *is* locally defined
1135 tyClsNamesOfDFunHead dfun_ty
1136   = case tcSplitSigmaTy dfun_ty of
1137         (_, _, head_ty) -> tyClsNamesOfType head_ty
1138 \end{code}
1139
1140
1141 %************************************************************************
1142 %*                                                                      *
1143 \subsection[TysWiredIn-ext-type]{External types}
1144 %*                                                                      *
1145 %************************************************************************
1146
1147 The compiler's foreign function interface supports the passing of a
1148 restricted set of types as arguments and results (the restricting factor
1149 being the )
1150
1151 \begin{code}
1152 tcSplitIOType_maybe :: Type -> Maybe (TyCon, Type, CoercionI)
1153 -- (isIOType t) returns Just (IO,t',co)
1154 --                              if co : t ~ IO t'
1155 --              returns Nothing otherwise
1156 tcSplitIOType_maybe ty
1157   = case tcSplitTyConApp_maybe ty of
1158         -- This split absolutely has to be a tcSplit, because we must
1159         -- see the IO type; and it's a newtype which is transparent to splitTyConApp.
1160
1161         Just (io_tycon, [io_res_ty])
1162            |  io_tycon `hasKey` ioTyConKey
1163            -> Just (io_tycon, io_res_ty, IdCo)
1164
1165         Just (tc, tys)
1166            | not (isRecursiveTyCon tc)
1167            , Just (ty, co1) <- instNewTyCon_maybe tc tys
1168                   -- Newtypes that require a coercion are ok
1169            -> case tcSplitIOType_maybe ty of
1170                 Nothing             -> Nothing
1171                 Just (tc, ty', co2) -> Just (tc, ty', co1 `mkTransCoI` co2)
1172
1173         _ -> Nothing
1174
1175 isFFITy :: Type -> Bool
1176 -- True for any TyCon that can possibly be an arg or result of an FFI call
1177 isFFITy ty = checkRepTyCon legalFFITyCon ty
1178
1179 isFFIArgumentTy :: DynFlags -> Safety -> Type -> Bool
1180 -- Checks for valid argument type for a 'foreign import'
1181 isFFIArgumentTy dflags safety ty
1182    = checkRepTyCon (legalOutgoingTyCon dflags safety) ty
1183
1184 isFFIExternalTy :: Type -> Bool
1185 -- Types that are allowed as arguments of a 'foreign export'
1186 isFFIExternalTy ty = checkRepTyCon legalFEArgTyCon ty
1187
1188 isFFIImportResultTy :: DynFlags -> Type -> Bool
1189 isFFIImportResultTy dflags ty
1190   = checkRepTyCon (legalFIResultTyCon dflags) ty
1191
1192 isFFIExportResultTy :: Type -> Bool
1193 isFFIExportResultTy ty = checkRepTyCon legalFEResultTyCon ty
1194
1195 isFFIDynArgumentTy :: Type -> Bool
1196 -- The argument type of a foreign import dynamic must be Ptr, FunPtr, Addr,
1197 -- or a newtype of either.
1198 isFFIDynArgumentTy = checkRepTyConKey [ptrTyConKey, funPtrTyConKey]
1199
1200 isFFIDynResultTy :: Type -> Bool
1201 -- The result type of a foreign export dynamic must be Ptr, FunPtr, Addr,
1202 -- or a newtype of either.
1203 isFFIDynResultTy = checkRepTyConKey [ptrTyConKey, funPtrTyConKey]
1204
1205 isFFILabelTy :: Type -> Bool
1206 -- The type of a foreign label must be Ptr, FunPtr, Addr,
1207 -- or a newtype of either.
1208 isFFILabelTy = checkRepTyConKey [ptrTyConKey, funPtrTyConKey]
1209
1210 isFFIDotnetTy :: DynFlags -> Type -> Bool
1211 isFFIDotnetTy dflags ty
1212   = checkRepTyCon (\ tc -> (legalFIResultTyCon dflags tc ||
1213                            isFFIDotnetObjTy ty || isStringTy ty)) ty
1214         -- NB: isStringTy used to look through newtypes, but
1215         --     it no longer does so.  May need to adjust isFFIDotNetTy
1216         --     if we do want to look through newtypes.
1217
1218 isFFIDotnetObjTy :: Type -> Bool
1219 isFFIDotnetObjTy ty
1220   = checkRepTyCon check_tc t_ty
1221   where
1222    (_, t_ty) = tcSplitForAllTys ty
1223    check_tc tc = getName tc == objectTyConName
1224
1225 isFunPtrTy :: Type -> Bool
1226 isFunPtrTy = checkRepTyConKey [funPtrTyConKey]
1227
1228 toDNType :: Type -> DNType
1229 toDNType ty
1230   | isStringTy ty = DNString
1231   | isFFIDotnetObjTy ty = DNObject
1232   | Just (tc,argTys) <- tcSplitTyConApp_maybe ty
1233   =  case lookup (getUnique tc) dn_assoc of
1234        Just x  -> x
1235        Nothing
1236          | tc `hasKey` ioTyConKey -> toDNType (head argTys)
1237          | otherwise -> pprPanic ("toDNType: unsupported .NET type")
1238                           (pprType ty <+> parens (hcat (map pprType argTys)) <+> ppr tc)
1239   | otherwise = panic "toDNType"        -- Is this right?
1240     where
1241       dn_assoc :: [ (Unique, DNType) ]
1242       dn_assoc = [ (unitTyConKey,   DNUnit)
1243                  , (intTyConKey,    DNInt)
1244                  , (int8TyConKey,   DNInt8)
1245                  , (int16TyConKey,  DNInt16)
1246                  , (int32TyConKey,  DNInt32)
1247                  , (int64TyConKey,  DNInt64)
1248                  , (wordTyConKey,   DNInt)
1249                  , (word8TyConKey,  DNWord8)
1250                  , (word16TyConKey, DNWord16)
1251                  , (word32TyConKey, DNWord32)
1252                  , (word64TyConKey, DNWord64)
1253                  , (floatTyConKey,  DNFloat)
1254                  , (doubleTyConKey, DNDouble)
1255                  , (ptrTyConKey,    DNPtr)
1256                  , (funPtrTyConKey, DNPtr)
1257                  , (charTyConKey,   DNChar)
1258                  , (boolTyConKey,   DNBool)
1259                  ]
1260
1261 checkRepTyCon :: (TyCon -> Bool) -> Type -> Bool
1262         -- Look through newtypes
1263         -- Non-recursive ones are transparent to splitTyConApp,
1264         -- but recursive ones aren't.  Manuel had:
1265         --      newtype T = MkT (Ptr T)
1266         -- and wanted it to work...
1267 checkRepTyCon check_tc ty
1268   | Just (tc,_) <- splitTyConApp_maybe (repType ty) = check_tc tc
1269   | otherwise                                       = False
1270
1271 checkRepTyConKey :: [Unique] -> Type -> Bool
1272 -- Like checkRepTyCon, but just looks at the TyCon key
1273 checkRepTyConKey keys
1274   = checkRepTyCon (\tc -> tyConUnique tc `elem` keys)
1275 \end{code}
1276
1277 ----------------------------------------------
1278 These chaps do the work; they are not exported
1279 ----------------------------------------------
1280
1281 \begin{code}
1282 legalFEArgTyCon :: TyCon -> Bool
1283 legalFEArgTyCon tc
1284   -- It's illegal to make foreign exports that take unboxed
1285   -- arguments.  The RTS API currently can't invoke such things.  --SDM 7/2000
1286   = boxedMarshalableTyCon tc
1287
1288 legalFIResultTyCon :: DynFlags -> TyCon -> Bool
1289 legalFIResultTyCon dflags tc
1290   | tc == unitTyCon         = True
1291   | otherwise               = marshalableTyCon dflags tc
1292
1293 legalFEResultTyCon :: TyCon -> Bool
1294 legalFEResultTyCon tc
1295   | tc == unitTyCon         = True
1296   | otherwise               = boxedMarshalableTyCon tc
1297
1298 legalOutgoingTyCon :: DynFlags -> Safety -> TyCon -> Bool
1299 -- Checks validity of types going from Haskell -> external world
1300 legalOutgoingTyCon dflags _ tc
1301   = marshalableTyCon dflags tc
1302
1303 legalFFITyCon :: TyCon -> Bool
1304 -- True for any TyCon that can possibly be an arg or result of an FFI call
1305 legalFFITyCon tc
1306   = isUnLiftedTyCon tc || boxedMarshalableTyCon tc || tc == unitTyCon
1307
1308 marshalableTyCon :: DynFlags -> TyCon -> Bool
1309 marshalableTyCon dflags tc
1310   =  (dopt Opt_UnliftedFFITypes dflags
1311       && isUnLiftedTyCon tc
1312       && not (isUnboxedTupleTyCon tc)
1313       && case tyConPrimRep tc of        -- Note [Marshalling VoidRep]
1314            VoidRep -> False
1315            _       -> True)
1316   || boxedMarshalableTyCon tc
1317
1318 boxedMarshalableTyCon :: TyCon -> Bool
1319 boxedMarshalableTyCon tc
1320    = getUnique tc `elem` [ intTyConKey, int8TyConKey, int16TyConKey
1321                          , int32TyConKey, int64TyConKey
1322                          , wordTyConKey, word8TyConKey, word16TyConKey
1323                          , word32TyConKey, word64TyConKey
1324                          , floatTyConKey, doubleTyConKey
1325                          , ptrTyConKey, funPtrTyConKey
1326                          , charTyConKey
1327                          , stablePtrTyConKey
1328                          , boolTyConKey
1329                          ]
1330 \end{code}
1331
1332 Note [Marshalling VoidRep]
1333 ~~~~~~~~~~~~~~~~~~~~~~~~~~
1334 We don't treat State# (whose PrimRep is VoidRep) as marshalable.
1335 In turn that means you can't write
1336         foreign import foo :: Int -> State# RealWorld
1337
1338 Reason: the back end falls over with panic "primRepHint:VoidRep";
1339         and there is no compelling reason to permit it