compiler/typecheck/TcUnify.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Type subsumption and unification
   7
   8 \begin{code}
   9 module TcUnify (
  10         -- Full-blown subsumption
  11   tcWrapResult, tcSubType, tcGen,
  12   checkConstraints, newImplication, sigCtxt,
  13
  14         -- Various unifications
  15   unifyType, unifyTypeList, unifyTheta, unifyKind,
  16
  17   --------------------------------
  18   -- Holes
  19   tcInfer,
  20   matchExpectedListTy, matchExpectedPArrTy,
  21   matchExpectedTyConApp, matchExpectedAppTy,
  22   matchExpectedFunTys, matchExpectedFunKind,
  23   wrapFunResCoercion
  24   ) where
  25
  26 #include "HsVersions.h"
  27
  28 import HsSyn
  29 import TypeRep
  30
  31 import TcErrors ( typeExtraInfoMsg, unifyCtxt )
  32 import TcMType
  33 import TcEnv
  34 import TcIface
  35 import TcRnMonad
  36 import TcType
  37 import Type
  38 import Coercion
  39 import Inst
  40 import TyCon
  41 import TysWiredIn
  42 import Var
  43 import VarSet
  44 import VarEnv
  45 import Name
  46 import ErrUtils
  47 import BasicTypes
  48 import Bag
  49
  50 import Maybes ( allMaybes )
  51 import Util
  52 import Outputable
  53 import FastString
  54
  55 import Control.Monad
  56 \end{code}
  57
  58
  59 %************************************************************************
  60 %*                                                                      *
  61              matchExpected functions
  62 %*                                                                      *
  63 %************************************************************************
  64
  65 Note [Herald for matchExpectedFunTys]
  66 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  67 The 'herald' always looks like:
  68    "The equation(s) for 'f' have"
  69    "The abstraction (\x.e) takes"
  70    "The section (+ x) expects"
  71    "The function 'f' is applied to"
  72
  73 This is used to construct a message of form
  74
  75    The abstraction `\Just 1 -> ...' takes two arguments
  76    but its type `Maybe a -> a' has only one
  77
  78    The equation(s) for `f' have two arguments
  79    but its type `Maybe a -> a' has only one
  80
  81    The section `(f 3)' requires 'f' to take two arguments
  82    but its type `Int -> Int' has only one
  83
  84    The function 'f' is applied to two arguments
  85    but its type `Int -> Int' has only one
  86
  87 Note [matchExpectedFunTys]
  88 ~~~~~~~~~~~~~~~~~~~~~~~~~~
  89 matchExpectedFunTys checks that an (Expected rho) has the form
  90 of an n-ary function.  It passes the decomposed type to the
  91 thing_inside, and returns a wrapper to coerce between the two types
  92
  93 It's used wherever a language construct must have a functional type,
  94 namely:
  95         A lambda expression
  96         A function definition
  97      An operator section
  98
  99 This is not (currently) where deep skolemisation occurs;
 100 matchExpectedFunTys does not skolmise nested foralls in the
 101 expected type, becuase it expects that to have been done already
 102
 103
 104 \begin{code}
 105 matchExpectedFunTys :: SDoc     -- See Note [Herald for matchExpectedFunTys]
 106                     -> Arity
 107                     -> TcRhoType
 108                     -> TcM (CoercionI, [TcSigmaType], TcRhoType)
 109
 110 -- If    matchExpectFunTys n ty = (co, [t1,..,tn], ty_r)
 111 -- then  co : ty ~ (t1 -> ... -> tn -> ty_r)
 112 --
 113 -- Does not allocate unnecessary meta variables: if the input already is
 114 -- a function, we just take it apart.  Not only is this efficient,
 115 -- it's important for higher rank: the argument might be of form
 116 --              (forall a. ty) -> other
 117 -- If allocated (fresh-meta-var1 -> fresh-meta-var2) and unified, we'd
 118 -- hide the forall inside a meta-variable
 119
 120 matchExpectedFunTys herald arity orig_ty
 121   = go arity orig_ty
 122   where
 123     -- If     go n ty = (co, [t1,..,tn], ty_r)
 124     -- then   co : ty ~ t1 -> .. -> tn -> ty_r
 125
 126     go n_req ty
 127       | n_req == 0 = return (IdCo ty, [], ty)
 128
 129     go n_req ty
 130       | Just ty' <- tcView ty = go n_req ty'
 131
 132     go n_req (FunTy arg_ty res_ty)
 133       | not (isPredTy arg_ty)
 134       = do { (coi, tys, ty_r) <- go (n_req-1) res_ty
 135            ; return (mkFunTyCoI (IdCo arg_ty) coi, arg_ty:tys, ty_r) }
 136
 137     go _ (TyConApp tc _)              -- A common case
 138       | not (isSynFamilyTyCon tc)
 139       = do { (env,msg) <- mk_ctxt emptyTidyEnv
 140            ; failWithTcM (env,msg) }
 141
 142     go n_req ty@(TyVarTy tv)
 143       | ASSERT( isTcTyVar tv) isMetaTyVar tv
 144       = do { cts <- readMetaTyVar tv
 145            ; case cts of
 146                Indirect ty' -> go n_req ty'
 147                Flexi        -> defer n_req ty }
 148
 149        -- In all other cases we bale out into ordinary unification
 150     go n_req ty = defer n_req ty
 151
 152     ------------
 153     defer n_req fun_ty
 154       = addErrCtxtM mk_ctxt $
 155         do { arg_tys <- newFlexiTyVarTys n_req argTypeKind
 156            ; res_ty  <- newFlexiTyVarTy openTypeKind
 157            ; coi     <- unifyType fun_ty (mkFunTys arg_tys res_ty)
 158            ; return (coi, arg_tys, res_ty) }
 159
 160     ------------
 161     mk_ctxt :: TidyEnv -> TcM (TidyEnv, Message)
 162     mk_ctxt env = do { orig_ty1 <- zonkTcType orig_ty
 163                      ; let (env', orig_ty2) = tidyOpenType env orig_ty1
 164                            (args, _) = tcSplitFunTys orig_ty2
 165                            n_actual = length args
 166                      ; return (env', mk_msg orig_ty2 n_actual) }
 167
 168     mk_msg ty n_args
 169       = herald <+> speakNOf arity (ptext (sLit "argument")) <> comma $$
 170         sep [ptext (sLit "but its type") <+> quotes (pprType ty),
 171              if n_args == 0 then ptext (sLit "has none")
 172              else ptext (sLit "has only") <+> speakN n_args]
 173 \end{code}
 174
 175
 176 \begin{code}
 177 ----------------------
 178 matchExpectedListTy :: TcRhoType -> TcM (CoercionI, TcRhoType)
 179 -- Special case for lists
 180 matchExpectedListTy exp_ty
 181  = do { (coi, [elt_ty]) <- matchExpectedTyConApp listTyCon exp_ty
 182       ; return (coi, elt_ty) }
 183
 184 ----------------------
 185 matchExpectedPArrTy :: TcRhoType -> TcM (CoercionI, TcRhoType)
 186 -- Special case for parrs
 187 matchExpectedPArrTy exp_ty
 188   = do { (coi, [elt_ty]) <- matchExpectedTyConApp parrTyCon exp_ty
 189        ; return (coi, elt_ty) }
 190
 191 ----------------------
 192 matchExpectedTyConApp :: TyCon                -- T :: k1 -> ... -> kn -> *
 193                       -> TcRhoType            -- orig_ty
 194                       -> TcM (CoercionI,      -- T a b c ~ orig_ty
 195                               [TcSigmaType])  -- Element types, a b c
 196
 197 -- It's used for wired-in tycons, so we call checkWiredInTyCon
 198 -- Precondition: never called with FunTyCon
 199 -- Precondition: input type :: *
 200
 201 matchExpectedTyConApp tc orig_ty
 202   = do  { checkWiredInTyCon tc
 203         ; go (tyConArity tc) orig_ty [] }
 204   where
 205     go :: Int -> TcRhoType -> [TcSigmaType] -> TcM (CoercionI, [TcSigmaType])
 206     -- If     go n ty tys = (co, [t1..tn] ++ tys)
 207     -- then   co : T t1..tn ~ ty
 208
 209     go n_req ty tys
 210       | Just ty' <- tcView ty = go n_req ty' tys
 211
 212     go n_req ty@(TyVarTy tv) tys
 213       | ASSERT( isTcTyVar tv) isMetaTyVar tv
 214       = do { cts <- readMetaTyVar tv
 215            ; case cts of
 216                Indirect ty -> go n_req ty tys
 217                Flexi       -> defer n_req ty tys }
 218
 219     go n_req ty@(TyConApp tycon args) tys
 220       | tc == tycon
 221       = ASSERT( n_req == length args)   -- ty::*
 222         return (IdCo ty, args ++ tys)
 223
 224     go n_req (AppTy fun arg) tys
 225       | n_req > 0
 226       = do { (coi, args) <- go (n_req - 1) fun (arg : tys)
 227            ; return (mkAppTyCoI coi (IdCo arg), args) }
 228
 229     go n_req ty tys = defer n_req ty tys
 230
 231     ----------
 232     defer n_req ty tys
 233       = do { tau_tys <- mapM newFlexiTyVarTy arg_kinds
 234            ; coi <- unifyType (mkTyConApp tc tau_tys) ty
 235            ; return (coi, tau_tys ++ tys) }
 236       where
 237         (arg_kinds, _) = splitKindFunTysN n_req (tyConKind tc)
 238
 239 ----------------------
 240 matchExpectedAppTy :: TcRhoType                         -- orig_ty
 241                    -> TcM (CoercionI,                   -- m a ~ orig_ty
 242                            (TcSigmaType, TcSigmaType))  -- Returns m, a
 243 -- If the incoming type is a mutable type variable of kind k, then
 244 -- matchExpectedAppTy returns a new type variable (m: * -> k); note the *.
 245
 246 matchExpectedAppTy orig_ty
 247   = go orig_ty
 248   where
 249     go ty
 250       | Just ty' <- tcView ty = go ty'
 251
 252       | Just (fun_ty, arg_ty) <- tcSplitAppTy_maybe ty
 253       = return (IdCo orig_ty, (fun_ty, arg_ty))
 254
 255     go (TyVarTy tv)
 256       | ASSERT( isTcTyVar tv) isMetaTyVar tv
 257       = do { cts <- readMetaTyVar tv
 258            ; case cts of
 259                Indirect ty -> go ty
 260                Flexi       -> defer }
 261
 262     go _ = defer
 263
 264     -- Defer splitting by generating an equality constraint
 265     defer = do { ty1 <- newFlexiTyVarTy kind1
 266                ; ty2 <- newFlexiTyVarTy kind2
 267                ; coi <- unifyType (mkAppTy ty1 ty2) orig_ty
 268                ; return (coi, (ty1, ty2)) }
 269
 270     orig_kind = typeKind orig_ty
 271     kind1 = mkArrowKind liftedTypeKind (defaultKind orig_kind)
 272     kind2 = liftedTypeKind    -- m :: * -> k
 273                               -- arg type :: *
 274         -- The defaultKind is a bit smelly.  If you remove it,
 275         -- try compiling        f x = do { x }
 276         -- and you'll get a kind mis-match.  It smells, but
 277         -- not enough to lose sleep over.
 278 \end{code}
 279
 280
 281 %************************************************************************
 282 %*                                                                      *
 283                 Subsumption checking
 284 %*                                                                      *
 285 %************************************************************************
 286
 287 All the tcSub calls have the form
 288
 289                 tcSub actual_ty expected_ty
 290 which checks
 291                 actual_ty <= expected_ty
 292
 293 That is, that a value of type actual_ty is acceptable in
 294 a place expecting a value of type expected_ty.
 295
 296 It returns a coercion function
 297         co_fn :: actual_ty ~ expected_ty
 298 which takes an HsExpr of type actual_ty into one of type
 299 expected_ty.
 300
 301 \begin{code}
 302 tcSubType :: CtOrigin -> SkolemInfo -> TcSigmaType -> TcSigmaType -> TcM HsWrapper
 303 -- Check that ty_actual is more polymorphic than ty_expected
 304 -- Both arguments might be polytypes, so we must instantiate and skolemise
 305 -- Returns a wrapper of shape   ty_actual ~ ty_expected
 306 tcSubType origin skol_info ty_actual ty_expected
 307   | isSigmaTy ty_actual
 308   = do { let extra_tvs = tyVarsOfType ty_actual
 309        ; (sk_wrap, inst_wrap)
 310             <- tcGen skol_info extra_tvs ty_expected $ \ _ sk_rho -> do
 311             { (in_wrap, in_rho) <- deeplyInstantiate origin ty_actual
 312             ; coi <- unifyType in_rho sk_rho
 313             ; return (coiToHsWrapper coi <.> in_wrap) }
 314        ; return (sk_wrap <.> inst_wrap) }
 315
 316   | otherwise   -- Urgh!  It seems deeply weird to have equality
 317                 -- when actual is not a polytype, and it makes a big
 318                 -- difference e.g. tcfail104
 319   = do { coi <- unifyType ty_actual ty_expected
 320        ; return (coiToHsWrapper coi) }
 321
 322 tcInfer :: (TcType -> TcM a) -> TcM (a, TcType)
 323 tcInfer tc_infer = do { ty  <- newFlexiTyVarTy openTypeKind
 324                       ; res <- tc_infer ty
 325                       ; return (res, ty) }
 326
 327 -----------------
 328 tcWrapResult :: HsExpr TcId -> TcRhoType -> TcRhoType -> TcM (HsExpr TcId)
 329 tcWrapResult expr actual_ty res_ty
 330   = do { coi <- unifyType actual_ty res_ty
 331                 -- Both types are deeply skolemised
 332        ; return (mkHsWrapCoI coi expr) }
 333
 334 -----------------------------------
 335 wrapFunResCoercion
 336         :: [TcType]     -- Type of args
 337         -> HsWrapper    -- HsExpr a -> HsExpr b
 338         -> TcM HsWrapper        -- HsExpr (arg_tys -> a) -> HsExpr (arg_tys -> b)
 339 wrapFunResCoercion arg_tys co_fn_res
 340   | isIdHsWrapper co_fn_res
 341   = return idHsWrapper
 342   | null arg_tys
 343   = return co_fn_res
 344   | otherwise
 345   = do  { arg_ids <- newSysLocalIds (fsLit "sub") arg_tys
 346         ; return (mkWpLams arg_ids <.> co_fn_res <.> mkWpEvVarApps arg_ids) }
 347 \end{code}
 348
 349
 350
 351 %************************************************************************
 352 %*                                                                      *
 353 \subsection{Generalisation}
 354 %*                                                                      *
 355 %************************************************************************
 356
 357 \begin{code}
 358 tcGen :: SkolemInfo -> TcTyVarSet -> TcType
 359       -> ([TcTyVar] -> TcRhoType -> TcM result)
 360       -> TcM (HsWrapper, result)
 361         -- The expression has type: spec_ty -> expected_ty
 362
 363 tcGen skol_info extra_tvs
 364        expected_ty thing_inside    -- We expect expected_ty to be a forall-type
 365                                    -- If not, the call is a no-op
 366   = do  { traceTc "tcGen" empty
 367         ; (wrap, tvs', given, rho') <- deeplySkolemise skol_info expected_ty
 368
 369         ; when debugIsOn $
 370               traceTc "tcGen" $ vcat [
 371                            text "expected_ty" <+> ppr expected_ty,
 372                            text "inst ty" <+> ppr tvs' <+> ppr rho' ]
 373
 374         -- In 'free_tvs' we must check that the "forall_tvs" havn't been constrained
 375         -- The interesting bit here is that we must include the free variables
 376         -- of the expected_ty.  Here's an example:
 377         --       runST (newVar True)
 378         -- Here, if we don't make a check, we'll get a type (ST s (MutVar s Bool))
 379         -- for (newVar True), with s fresh.  Then we unify with the runST's arg type
 380         -- forall s'. ST s' a. That unifies s' with s, and a with MutVar s Bool.
 381         -- So now s' isn't unconstrained because it's linked to a.
 382         -- Conclusion: pass the free vars of the expected_ty to checkConsraints
 383         ; let free_tvs = tyVarsOfType expected_ty `unionVarSet` extra_tvs
 384
 385         ; (ev_binds, result) <- checkConstraints skol_info free_tvs tvs' given $
 386                                 thing_inside tvs' rho'
 387
 388         ; return (wrap <.> mkWpLet ev_binds, result) }
 389           -- The ev_binds returned by checkConstraints is very
 390           -- often empty, in which case mkWpLet is a no-op
 391
 392 checkConstraints :: SkolemInfo
 393                  -> TcTyVarSet          -- Free variables (other than the type envt)
 394                                         -- for the skolem escape check
 395                  -> [TcTyVar]           -- Skolems
 396                  -> [EvVar]             -- Given
 397                  -> TcM result
 398                  -> TcM (TcEvBinds, result)
 399
 400 checkConstraints skol_info free_tvs skol_tvs given thing_inside
 401   | null skol_tvs && null given
 402   = do { res <- thing_inside; return (emptyTcEvBinds, res) }
 403       -- Just for efficiency.  We check every function argument with
 404       -- tcPolyExpr, which uses tcGen and hence checkConstraints.
 405
 406   | otherwise
 407   = do { (ev_binds, wanted, result) <- newImplication skol_info free_tvs
 408                                              skol_tvs given thing_inside
 409        ; emitConstraints wanted
 410        ; return (ev_binds, result) }
 411
 412 newImplication :: SkolemInfo -> TcTyVarSet -> [TcTyVar]
 413                -> [EvVar] -> TcM result
 414                -> TcM (TcEvBinds, WantedConstraints, result)
 415 newImplication skol_info _free_tvs skol_tvs given thing_inside
 416   = ASSERT2( all isTcTyVar skol_tvs, ppr skol_tvs )
 417     ASSERT2( all isSkolemTyVar skol_tvs, ppr skol_tvs )
 418     do { --   gbl_tvs  <- tcGetGlobalTyVars
 419          -- ; free_tvs <- zonkTcTyVarsAndFV free_tvs
 420          -- ; let untch = gbl_tvs `unionVarSet` free_tvs
 421
 422        ; ((result, untch), wanted) <- captureConstraints  $
 423                                       captureUntouchables $
 424                                       thing_inside
 425
 426        ; if isEmptyBag wanted && not (hasEqualities given)
 427             -- Optimisation : if there are no wanteds, and the givens
 428             -- are sufficiently simple, don't generate an implication
 429             -- at all.  Reason for the hasEqualities test:
 430             -- we don't want to lose the "inaccessible alternative"
 431             -- error check
 432          then
 433             return (emptyTcEvBinds, emptyWanteds, result)
 434          else do
 435        { ev_binds_var <- newTcEvBinds
 436        ; lcl_env <- getLclTypeEnv
 437        ; loc <- getCtLoc skol_info
 438        ; let implic = Implic { ic_untch = untch
 439                              , ic_env = lcl_env
 440                              , ic_skols = mkVarSet skol_tvs
 441                              , ic_scoped = panic "emitImplication"
 442                              , ic_given = given
 443                              , ic_wanted = wanted
 444                              , ic_binds = ev_binds_var
 445                              , ic_loc = loc }
 446
 447        ; return (TcEvBinds ev_binds_var, unitBag (WcImplic implic), result) } }
 448 \end{code}
 449
 450 %************************************************************************
 451 %*                                                                      *
 452                 Boxy unification
 453 %*                                                                      *
 454 %************************************************************************
 455
 456 The exported functions are all defined as versions of some
 457 non-exported generic functions.
 458
 459 \begin{code}
 460 ---------------
 461 unifyType :: TcTauType -> TcTauType -> TcM CoercionI
 462 -- Actual and expected types
 463 -- Returns a coercion : ty1 ~ ty2
 464 unifyType ty1 ty2 = uType [] ty1 ty2
 465
 466 ---------------
 467 unifyPred :: PredType -> PredType -> TcM CoercionI
 468 -- Actual and expected types
 469 unifyPred p1 p2 = uPred [UnifyOrigin (mkPredTy p1) (mkPredTy p2)] p1 p2
 470
 471 ---------------
 472 unifyTheta :: TcThetaType -> TcThetaType -> TcM [CoercionI]
 473 -- Actual and expected types
 474 unifyTheta theta1 theta2
 475   = do  { checkTc (equalLength theta1 theta2)
 476                   (vcat [ptext (sLit "Contexts differ in length"),
 477                          nest 2 $ parens $ ptext (sLit "Use -XRelaxedPolyRec to allow this")])
 478         ; zipWithM unifyPred theta1 theta2 }
 479 \end{code}
 480
 481 @unifyTypeList@ takes a single list of @TauType@s and unifies them
 482 all together.  It is used, for example, when typechecking explicit
 483 lists, when all the elts should be of the same type.
 484
 485 \begin{code}
 486 unifyTypeList :: [TcTauType] -> TcM ()
 487 unifyTypeList []                 = return ()
 488 unifyTypeList [_]                = return ()
 489 unifyTypeList (ty1:tys@(ty2:_)) = do { _ <- unifyType ty1 ty2
 490                                      ; unifyTypeList tys }
 491 \end{code}
 492
 493 %************************************************************************
 494 %*                                                                      *
 495                  uType and friends
 496 %*                                                                      *
 497 %************************************************************************
 498
 499 uType is the heart of the unifier.  Each arg occurs twice, because
 500 we want to report errors in terms of synomyms if possible.  The first of
 501 the pair is used in error messages only; it is always the same as the
 502 second, except that if the first is a synonym then the second may be a
 503 de-synonym'd version.  This way we get better error messages.
 504
 505 \begin{code}
 506 data SwapFlag
 507   = NotSwapped  -- Args are: actual,   expected
 508   | IsSwapped   -- Args are: expected, actual
 509
 510 instance Outputable SwapFlag where
 511   ppr IsSwapped  = ptext (sLit "Is-swapped")
 512   ppr NotSwapped = ptext (sLit "Not-swapped")
 513
 514 unSwap :: SwapFlag -> (a->a->b) -> a -> a -> b
 515 unSwap NotSwapped f a b = f a b
 516 unSwap IsSwapped  f a b = f b a
 517
 518 ------------
 519 uType, uType_np, uType_defer
 520   :: [EqOrigin]
 521   -> TcType    -- ty1 is the *actual* type
 522   -> TcType    -- ty2 is the *expected* type
 523   -> TcM CoercionI
 524
 525 --------------
 526 -- It is always safe to defer unification to the main constraint solver
 527 -- See Note [Deferred unification]
 528 uType_defer (item : origin) ty1 ty2
 529   = do { co_var <- newWantedCoVar ty1 ty2
 530        ; traceTc "utype_defer" (vcat [ppr co_var, ppr ty1, ppr ty2, ppr origin])
 531        ; loc <- getCtLoc (TypeEqOrigin item)
 532        ; wrapEqCtxt origin $
 533          emitConstraint (WcEvVar (WantedEvVar co_var loc))
 534        ; return $ ACo $ mkTyVarTy co_var }
 535 uType_defer [] _ _
 536   = panic "uType_defer"
 537
 538 --------------
 539 -- Push a new item on the origin stack (the most common case)
 540 uType origin ty1 ty2  -- Push a new item on the origin stack
 541   = uType_np (pushOrigin ty1 ty2 origin) ty1 ty2
 542
 543 --------------
 544 -- unify_np (short for "no push" on the origin stack) does the work
 545 uType_np origin orig_ty1 orig_ty2
 546   = do { traceTc "u_tys " $ vcat
 547               [ sep [ ppr orig_ty1, text "~", ppr orig_ty2]
 548               , ppr origin]
 549        ; coi <- go origin orig_ty1 orig_ty2
 550        ; case coi of
 551             ACo co -> traceTc "u_tys yields coercion:" (ppr co)
 552             IdCo _ -> traceTc "u_tys yields no coercion" empty
 553        ; return coi }
 554   where
 555     bale_out :: [EqOrigin] -> TcM a
 556     bale_out origin = failWithMisMatch origin
 557
 558     go :: [EqOrigin] -> TcType -> TcType -> TcM CoercionI
 559         -- The arguments to 'go' are always semantically identical
 560         -- to orig_ty{1,2} except for looking through type synonyms
 561
 562         -- Variables; go for uVar
 563         -- Note that we pass in *original* (before synonym expansion),
 564         -- so that type variables tend to get filled in with
 565         -- the most informative version of the type
 566     go origin (TyVarTy tyvar1) ty2 = uVar origin NotSwapped tyvar1 ty2
 567     go origin ty1 (TyVarTy tyvar2) = uVar origin IsSwapped  tyvar2 ty1
 568
 569         -- Expand synonyms:
 570         --      see Note [Unification and synonyms]
 571         -- Do this after the variable case so that we tend to unify
 572         -- variables with un-expended type synonym
 573     go origin ty1 ty2
 574       | Just ty1' <- tcView ty1 = uType origin ty1' ty2
 575       | Just ty2' <- tcView ty2 = uType origin ty1  ty2'
 576
 577         -- Predicates
 578     go origin (PredTy p1) (PredTy p2) = uPred origin p1 p2
 579
 580         -- Coercion functions: (t1a ~ t1b) => t1c  ~  (t2a ~ t2b) => t2c
 581     go origin ty1 ty2
 582       | Just (t1a,t1b,t1c) <- splitCoPredTy_maybe ty1,
 583         Just (t2a,t2b,t2c) <- splitCoPredTy_maybe ty2
 584       = do { co1 <- uType origin t1a t2a
 585            ; co2 <- uType origin t1b t2b
 586            ; co3 <- uType origin t1c t2c
 587            ; return $ mkCoPredCoI co1 co2 co3 }
 588
 589         -- Functions (or predicate functions) just check the two parts
 590     go origin (FunTy fun1 arg1) (FunTy fun2 arg2)
 591       = do { coi_l <- uType origin fun1 fun2
 592            ; coi_r <- uType origin arg1 arg2
 593            ; return $ mkFunTyCoI coi_l coi_r }
 594
 595         -- Always defer if a type synonym family (type function)
 596         -- is involved.  (Data families behave rigidly.)
 597     go origin ty1@(TyConApp tc1 _) ty2
 598       | isSynFamilyTyCon tc1 = uType_defer origin ty1 ty2
 599     go origin ty1 ty2@(TyConApp tc2 _)
 600       | isSynFamilyTyCon tc2 = uType_defer origin ty1 ty2
 601
 602     go origin (TyConApp tc1 tys1) (TyConApp tc2 tys2)
 603       | tc1 == tc2         -- See Note [TyCon app]
 604       = do { cois <- uList origin uType tys1 tys2
 605            ; return $ mkTyConAppCoI tc1 cois }
 606
 607         -- See Note [Care with type applications]
 608     go origin (AppTy s1 t1) ty2
 609       | Just (s2,t2) <- tcSplitAppTy_maybe ty2
 610       = do { coi_s <- uType_np origin s1 s2  -- See Note [Unifying AppTy]
 611            ; coi_t <- uType origin t1 t2
 612            ; return $ mkAppTyCoI coi_s coi_t }
 613
 614     go origin ty1 (AppTy s2 t2)
 615       | Just (s1,t1) <- tcSplitAppTy_maybe ty1
 616       = do { coi_s <- uType_np origin s1 s2
 617            ; coi_t <- uType origin t1 t2
 618            ; return $ mkAppTyCoI coi_s coi_t }
 619
 620     go _ ty1 ty2
 621       | tcIsForAllTy ty1 || tcIsForAllTy ty2
 622       = unifySigmaTy origin ty1 ty2
 623
 624         -- Anything else fails
 625     go origin _ _ = bale_out origin
 626
 627 unifySigmaTy :: [EqOrigin] -> TcType -> TcType -> TcM CoercionI
 628 unifySigmaTy origin ty1 ty2
 629   = do { let (tvs1, body1) = tcSplitForAllTys ty1
 630              (tvs2, body2) = tcSplitForAllTys ty2
 631        ; unless (equalLength tvs1 tvs2) (failWithMisMatch origin)
 632        ; skol_tvs <- tcInstSkolTyVars UnkSkol tvs1     -- Not a helpful SkolemInfo
 633                   -- Get location from monad, not from tvs1
 634        ; let tys      = mkTyVarTys skol_tvs
 635              in_scope = mkInScopeSet (mkVarSet skol_tvs)
 636              phi1     = substTy (mkTvSubst in_scope (zipTyEnv tvs1 tys)) body1
 637              phi2     = substTy (mkTvSubst in_scope (zipTyEnv tvs2 tys)) body2
 638 --             untch = tyVarsOfType ty1 `unionVarSet` tyVarsOfType ty2
 639
 640        ; ((coi, _untch), lie) <- captureConstraints $
 641                                  captureUntouchables $
 642                                  uType origin phi1 phi2
 643           -- Check for escape; e.g. (forall a. a->b) ~ (forall a. a->a)
 644        ; let bad_lie  = filterBag is_bad lie
 645              is_bad w = any (`elemVarSet` tyVarsOfWanted w) skol_tvs
 646        ; when (not (isEmptyBag bad_lie))
 647               (failWithMisMatch origin) -- ToDo: give details from bad_lie
 648
 649        ; emitConstraints lie
 650        ; return (foldr mkForAllTyCoI coi skol_tvs) }
 651
 652 ----------
 653 uPred :: [EqOrigin] -> PredType -> PredType -> TcM CoercionI
 654 uPred origin (IParam n1 t1) (IParam n2 t2)
 655   | n1 == n2
 656   = do { coi <- uType origin t1 t2
 657        ; return $ mkIParamPredCoI n1 coi }
 658 uPred origin (ClassP c1 tys1) (ClassP c2 tys2)
 659   | c1 == c2
 660   = do { cois <- uList origin uType tys1 tys2
 661           -- Guaranteed equal lengths because the kinds check
 662        ; return $ mkClassPPredCoI c1 cois }
 663 uPred origin (EqPred ty1a ty1b) (EqPred ty2a ty2b)
 664   = do { coia <- uType origin ty1a ty2a
 665        ; coib <- uType origin ty1b ty2b
 666        ; return $ mkEqPredCoI coia coib }
 667
 668 uPred origin _ _ = failWithMisMatch origin
 669
 670 ---------------
 671 uList :: [EqOrigin]
 672       -> ([EqOrigin] -> a -> a -> TcM b)
 673       -> [a] -> [a] -> TcM [b]
 674 -- Unify corresponding elements of two lists of types, which
 675 -- should be of equal length.  We charge down the list explicitly so that
 676 -- we can complain if their lengths differ.
 677 uList _       _     []         []        = return []
 678 uList origin unify (ty1:tys1) (ty2:tys2) = do { x  <- unify origin ty1 ty2;
 679                                               ; xs <- uList origin unify tys1 tys2
 680                                               ; return (x:xs) }
 681 uList origin _ _ _ = failWithMisMatch origin
 682        -- See Note [Mismatched type lists and application decomposition]
 683
 684 \end{code}
 685
 686 Note [Care with type applications]
 687 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 688 Note: type applications need a bit of care!
 689 They can match FunTy and TyConApp, so use splitAppTy_maybe
 690 NB: we've already dealt with type variables and Notes,
 691 so if one type is an App the other one jolly well better be too
 692
 693 Note [Unifying AppTy]
 694 ~~~~~~~~~~~~~~~~~~~~~
 695 Considerm unifying  (m Int) ~ (IO Int) where m is a unification variable
 696 that is now bound to (say) (Bool ->).  Then we want to report
 697      "Can't unify (Bool -> Int) with (IO Int)
 698 and not
 699      "Can't unify ((->) Bool) with IO"
 700 That is why we use the "_np" variant of uType, which does not alter the error
 701 message.
 702
 703 Note [TyCon app]
 704 ~~~~~~~~~~~~~~~~
 705 When we find two TyConApps, the argument lists are guaranteed equal
 706 length.  Reason: intially the kinds of the two types to be unified is
 707 the same. The only way it can become not the same is when unifying two
 708 AppTys (f1 a1)~(f2 a2).  In that case there can't be a TyConApp in
 709 the f1,f2 (because it'd absorb the app).  If we unify f1~f2 first,
 710 which we do, that ensures that f1,f2 have the same kind; and that
 711 means a1,a2 have the same kind.  And now the argument repeats.
 712
 713 Note [Mismatched type lists and application decomposition]
 714 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 715 When we find two TyConApps, you might think that the argument lists
 716 are guaranteed equal length.  But they aren't. Consider matching
 717         w (T x) ~ Foo (T x y)
 718 We do match (w ~ Foo) first, but in some circumstances we simply create
 719 a deferred constraint; and then go ahead and match (T x ~ T x y).
 720 This came up in Trac #3950.
 721
 722 So either
 723    (a) either we must check for identical argument kinds
 724        when decomposing applications,
 725
 726    (b) or we must be prepared for ill-kinded unification sub-problems
 727
 728 Currently we adopt (b) since it seems more robust -- no need to maintain
 729 a global invariant.
 730
 731 Note [Unification and synonyms]
 732 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 733 If you are tempted to make a short cut on synonyms, as in this
 734 pseudocode...
 735
 736    uTys (SynTy con1 args1 ty1) (SynTy con2 args2 ty2)
 737      = if (con1 == con2) then
 738    -- Good news!  Same synonym constructors, so we can shortcut
 739    -- by unifying their arguments and ignoring their expansions.
 740    unifyTypepeLists args1 args2
 741     else
 742    -- Never mind.  Just expand them and try again
 743    uTys ty1 ty2
 744
 745 then THINK AGAIN.  Here is the whole story, as detected and reported
 746 by Chris Okasaki:
 747
 748 Here's a test program that should detect the problem:
 749
 750         type Bogus a = Int
 751         x = (1 :: Bogus Char) :: Bogus Bool
 752
 753 The problem with [the attempted shortcut code] is that
 754
 755         con1 == con2
 756
 757 is not a sufficient condition to be able to use the shortcut!
 758 You also need to know that the type synonym actually USES all
 759 its arguments.  For example, consider the following type synonym
 760 which does not use all its arguments.
 761
 762         type Bogus a = Int
 763
 764 If you ever tried unifying, say, (Bogus Char) with )Bogus Bool), the
 765 unifier would blithely try to unify Char with Bool and would fail,
 766 even though the expanded forms (both Int) should match. Similarly,
 767 unifying (Bogus Char) with (Bogus t) would unnecessarily bind t to
 768 Char.
 769
 770 ... You could explicitly test for the problem synonyms and mark them
 771 somehow as needing expansion, perhaps also issuing a warning to the
 772 user.
 773
 774 Note [Deferred Unification]
 775 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
 776 We may encounter a unification ty1 ~ ty2 that cannot be performed syntactically,
 777 and yet its consistency is undetermined. Previously, there was no way to still
 778 make it consistent. So a mismatch error was issued.
 779
 780 Now these unfications are deferred until constraint simplification, where type
 781 family instances and given equations may (or may not) establish the consistency.
 782 Deferred unifications are of the form
 783                 F ... ~ ...
 784 or              x ~ ...
 785 where F is a type function and x is a type variable.
 786 E.g.
 787         id :: x ~ y => x -> y
 788         id e = e
 789
 790 involves the unfication x = y. It is deferred until we bring into account the
 791 context x ~ y to establish that it holds.
 792
 793 If available, we defer original types (rather than those where closed type
 794 synonyms have already been expanded via tcCoreView).  This is, as usual, to
 795 improve error messages.
 796
 797
 798 %************************************************************************
 799 %*                                                                      *
 800                  uVar and friends
 801 %*                                                                      *
 802 %************************************************************************
 803
 804 @uVar@ is called when at least one of the types being unified is a
 805 variable.  It does {\em not} assume that the variable is a fixed point
 806 of the substitution; rather, notice that @uVar@ (defined below) nips
 807 back into @uTys@ if it turns out that the variable is already bound.
 808
 809 \begin{code}
 810 uVar :: [EqOrigin] -> SwapFlag -> TcTyVar -> TcTauType -> TcM CoercionI
 811 uVar origin swapped tv1 ty2
 812   = do  { traceTc "uVar" (vcat [ ppr origin
 813                                 , ppr swapped
 814                                 , ppr tv1 <+> dcolon <+> ppr (tyVarKind tv1)
 815                                 , nest 2 (ptext (sLit " ~ "))
 816                                 , ppr ty2 <+> dcolon <+> ppr (typeKind ty2)])
 817         ; details <- lookupTcTyVar tv1
 818         ; case details of
 819             Filled ty1  -> unSwap swapped (uType_np origin) ty1 ty2
 820             Unfilled details1 -> uUnfilledVar origin swapped tv1 details1 ty2
 821         }
 822
 823 ----------------
 824 uUnfilledVar :: [EqOrigin]
 825              -> SwapFlag
 826              -> TcTyVar -> TcTyVarDetails       -- Tyvar 1
 827              -> TcTauType                       -- Type 2
 828              -> TcM CoercionI
 829 -- "Unfilled" means that the variable is definitely not a filled-in meta tyvar
 830 --            It might be a skolem, or untouchable, or meta
 831
 832 uUnfilledVar origin swapped tv1 details1 (TyVarTy tv2)
 833   | tv1 == tv2  -- Same type variable => no-op
 834   = return (IdCo (mkTyVarTy tv1))
 835
 836   | otherwise  -- Distinct type variables
 837   = do  { lookup2 <- lookupTcTyVar tv2
 838         ; case lookup2 of
 839             Filled ty2'       -> uUnfilledVar origin swapped tv1 details1 ty2'
 840             Unfilled details2 -> uUnfilledVars origin swapped tv1 details1 tv2 details2
 841         }
 842
 843 uUnfilledVar origin swapped tv1 details1 non_var_ty2  -- ty2 is not a type variable
 844   = case details1 of
 845       MetaTv TauTv ref1
 846         -> do { mb_ty2' <- checkTauTvUpdate tv1 non_var_ty2
 847               ; case mb_ty2' of
 848                   Nothing   -> do { traceTc "Occ/kind defer" (ppr tv1); defer }
 849                   Just ty2' -> updateMeta tv1 ref1 ty2'
 850               }
 851
 852       _other -> do { traceTc "Skolem defer" (ppr tv1); defer }          -- Skolems of all sorts
 853   where
 854     defer = unSwap swapped (uType_defer origin) (mkTyVarTy tv1) non_var_ty2
 855           -- Occurs check or an untouchable: just defer
 856           -- NB: occurs check isn't necessarily fatal:
 857           --     eg tv1 occured in type family parameter
 858
 859 ----------------
 860 uUnfilledVars :: [EqOrigin]
 861               -> SwapFlag
 862               -> TcTyVar -> TcTyVarDetails      -- Tyvar 1
 863               -> TcTyVar -> TcTyVarDetails      -- Tyvar 2
 864               -> TcM CoercionI
 865 -- Invarant: The type variables are distinct,
 866 --           Neither is filled in yet
 867
 868 uUnfilledVars origin swapped tv1 details1 tv2 details2
 869   = case (details1, details2) of
 870       (MetaTv i1 ref1, MetaTv i2 ref2)
 871           | k1_sub_k2 -> if k2_sub_k1 && nicer_to_update_tv1 i1 i2
 872                          then updateMeta tv1 ref1 ty2
 873                          else updateMeta tv2 ref2 ty1
 874           | k2_sub_k1 -> updateMeta tv1 ref1 ty2
 875
 876       (_, MetaTv _ ref2) | k1_sub_k2 -> updateMeta tv2 ref2 ty1
 877       (MetaTv _ ref1, _) | k2_sub_k1 -> updateMeta tv1 ref1 ty2
 878
 879       (_, _) -> unSwap swapped (uType_defer origin) ty1 ty2
 880                 -- Defer for skolems of all sorts
 881   where
 882     k1        = tyVarKind tv1
 883     k2        = tyVarKind tv2
 884     k1_sub_k2 = k1 `isSubKind` k2
 885     k2_sub_k1 = k2 `isSubKind` k1
 886     ty1       = mkTyVarTy tv1
 887     ty2       = mkTyVarTy tv2
 888
 889     nicer_to_update_tv1 _         (SigTv _) = True
 890     nicer_to_update_tv1 (SigTv _) _         = False
 891     nicer_to_update_tv1 _         _         = isSystemName (Var.varName tv1)
 892         -- Try not to update SigTvs; and try to update sys-y type
 893         -- variables in preference to ones gotten (say) by
 894         -- instantiating a polymorphic function with a user-written
 895         -- type sig
 896
 897 ----------------
 898 checkTauTvUpdate :: TcTyVar -> TcType -> TcM (Maybe TcType)
 899 --    (checkTauTvUpdate tv ty)
 900 -- We are about to update the TauTv tv with ty.
 901 -- Check (a) that tv doesn't occur in ty (occurs check)
 902 --       (b) that kind(ty) is a sub-kind of kind(tv)
 903 --       (c) that ty does not contain any type families, see Note [Type family sharing]
 904 --
 905 -- We have two possible outcomes:
 906 -- (1) Return the type to update the type variable with,
 907 --        [we know the update is ok]
 908 -- (2) Return Nothing,
 909 --        [the update might be dodgy]
 910 --
 911 -- Note that "Nothing" does not mean "definite error".  For example
 912 --   type family F a
 913 --   type instance F Int = Int
 914 -- consider
 915 --   a ~ F a
 916 -- This is perfectly reasonable, if we later get a ~ Int.  For now, though,
 917 -- we return Nothing, leaving it to the later constraint simplifier to
 918 -- sort matters out.
 919
 920 checkTauTvUpdate tv ty
 921   = do { ty' <- zonkTcType ty
 922        ; if typeKind ty' `isSubKind` tyVarKind tv then
 923            case ok ty' of
 924              Nothing -> return Nothing
 925              Just ty'' -> return (Just ty'')
 926          else return Nothing }
 927
 928   where ok :: TcType -> Maybe TcType
 929         ok (TyVarTy tv') | not (tv == tv') = Just (TyVarTy tv')
 930         ok this_ty@(TyConApp tc tys)
 931           | not (isSynFamilyTyCon tc), Just tys' <- allMaybes (map ok tys)
 932           = Just (TyConApp tc tys')
 933           | isSynTyCon tc, Just ty_expanded <- tcView this_ty
 934           = ok ty_expanded -- See Note [Type synonyms and the occur check]
 935         ok (PredTy sty) | Just sty' <- ok_pred sty = Just (PredTy sty')
 936         ok (FunTy arg res) | Just arg' <- ok arg, Just res' <- ok res
 937                            = Just (FunTy arg' res')
 938         ok (AppTy fun arg) | Just fun' <- ok fun, Just arg' <- ok arg
 939                            = Just (AppTy fun' arg')
 940         ok (ForAllTy tv1 ty1) | Just ty1' <- ok ty1 = Just (ForAllTy tv1 ty1')
 941         -- Fall-through
 942         ok _ty = Nothing
 943
 944         ok_pred (IParam nm ty) | Just ty' <- ok ty = Just (IParam nm ty')
 945         ok_pred (ClassP cl tys)
 946           | Just tys' <- allMaybes (map ok tys)
 947           = Just (ClassP cl tys')
 948         ok_pred (EqPred ty1 ty2)
 949           | Just ty1' <- ok ty1, Just ty2' <- ok ty2
 950           = Just (EqPred ty1' ty2')
 951         -- Fall-through
 952         ok_pred _pty = Nothing
 953
 954 \end{code}
 955
 956 Note [Type synonyms and the occur check]
 957 ~~~~~~~~~~~~~~~~~~~~
 958 Generally speaking we need to update a variable with type synonyms not expanded, which
 959 improves later error messages, except for when looking inside a type synonym may help resolve
 960 a spurious occurs check error. Consider:
 961           type A a = ()
 962
 963           f :: (A a -> a -> ()) -> ()
 964           f = \ _ -> ()
 965
 966           x :: ()
 967           x = f (\ x p -> p x)
 968
 969 We will eventually get a constraint of the form t ~ A t. The ok function above will
 970 properly expand the type (A t) to just (), which is ok to be unified with t. If we had
 971 unified with the original type A t, we would lead the type checker into an infinite loop.
 972
 973 Hence, if the occurs check fails for a type synonym application, then (and *only* then),
 974 the ok function expands the synonym to detect opportunities for occurs check success using
 975 the underlying definition of the type synonym.
 976
 977 The same applies later on in the constraint interaction code; see TcInteract,
 978 function @occ_check_ok@.
 979
 980
 981 Note [Type family sharing]
 982 ~~~~~~~~~~~~~~
 983 We must avoid eagerly unifying type variables to types that contain function symbols,
 984 because this may lead to loss of sharing, and in turn, in very poor performance of the
 985 constraint simplifier. Assume that we have a wanted constraint:
 986 {
 987   m1 ~ [F m2],
 988   m2 ~ [F m3],
 989   m3 ~ [F m4],
 990   D m1,
 991   D m2,
 992   D m3
 993 }
 994 where D is some type class. If we eagerly unify m1 := [F m2], m2 := [F m3], m3 := [F m2],
 995 then, after zonking, our constraint simplifier will be faced with the following wanted
 996 constraint:
 997 {
 998   D [F [F [F m4]]],
 999   D [F [F m4]],
1000   D [F m4]
1001 }
1002 which has to be flattened by the constraint solver. However, because the sharing is lost,
1003 an polynomially larger number of flatten skolems will be created and the constraint sets
1004 we are working with will be polynomially larger.
1005
1006 Instead, if we defer the unifications m1 := [F m2], etc. we will only be generating three
1007 flatten skolems, which is the maximum possible sharing arising from the original constraint.
1008
1009 \begin{code}
1010 data LookupTyVarResult  -- The result of a lookupTcTyVar call
1011   = Unfilled TcTyVarDetails     -- SkolemTv or virgin MetaTv
1012   | Filled   TcType
1013
1014 lookupTcTyVar :: TcTyVar -> TcM LookupTyVarResult
1015 lookupTcTyVar tyvar
1016   | MetaTv _ ref <- details
1017   = do { meta_details <- readMutVar ref
1018        ; case meta_details of
1019            Indirect ty -> return (Filled ty)
1020            Flexi -> do { is_untch <- isUntouchable tyvar
1021                        ; let    -- Note [Unifying untouchables]
1022                              ret_details | is_untch = SkolemTv UnkSkol
1023                                          | otherwise = details
1024                        ; return (Unfilled ret_details) } }
1025   | otherwise
1026   = return (Unfilled details)
1027   where
1028     details = ASSERT2( isTcTyVar tyvar, ppr tyvar )
1029               tcTyVarDetails tyvar
1030
1031 updateMeta :: TcTyVar -> TcRef MetaDetails -> TcType -> TcM CoercionI
1032 updateMeta tv1 ref1 ty2
1033   = do { writeMetaTyVarRef tv1 ref1 ty2
1034        ; return (IdCo ty2) }
1035 \end{code}
1036
1037 Note [Unifying untouchables]
1038 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1039 We treat an untouchable type variable as if it was a skolem.  That
1040 ensures it won't unify with anything.  It's a slight had, because
1041 we return a made-up TcTyVarDetails, but I think it works smoothly.
1042
1043
1044 %************************************************************************
1045 %*                                                                      *
1046         Errors and contexts
1047 %*                                                                      *
1048 %************************************************************************
1049
1050 \begin{code}
1051 pushOrigin :: TcType -> TcType -> [EqOrigin] -> [EqOrigin]
1052 pushOrigin ty_act ty_exp origin
1053   = UnifyOrigin { uo_actual = ty_act, uo_expected = ty_exp } : origin
1054
1055 ---------------
1056 wrapEqCtxt :: [EqOrigin] -> TcM a -> TcM a
1057 -- Build a suitable error context from the origin and do the thing inside
1058 -- The "couldn't match" error comes from the innermost item on the stack,
1059 -- and, if there is more than one item, the "Expected/inferred" part
1060 -- comes from the outermost item
1061 wrapEqCtxt []    thing_inside = thing_inside
1062 wrapEqCtxt items thing_inside = addErrCtxtM (unifyCtxt (last items)) thing_inside
1063
1064 ---------------
1065 failWithMisMatch :: [EqOrigin] -> TcM a
1066 -- Generate the message when two types fail to match,
1067 -- going to some trouble to make it helpful.
1068 -- We take the failing types from the top of the origin stack
1069 -- rather than reporting the particular ones we are looking
1070 -- at right now
1071 failWithMisMatch (item:origin)
1072   = wrapEqCtxt origin $
1073     do  { ty_act <- zonkTcType (uo_actual item)
1074         ; ty_exp <- zonkTcType (uo_expected item)
1075         ; env0 <- tcInitTidyEnv
1076         ; let (env1, pp_exp) = tidyOpenType env0 ty_exp
1077               (env2, pp_act) = tidyOpenType env1 ty_act
1078         ; failWithTcM (misMatchMsg env2 pp_act pp_exp) }
1079 failWithMisMatch []
1080   = panic "failWithMisMatch"
1081
1082 misMatchMsg :: TidyEnv -> TcType -> TcType -> (TidyEnv, SDoc)
1083 misMatchMsg env ty_act ty_exp
1084   = (env2, sep [sep [ ptext (sLit "Couldn't match expected type") <+> quotes (ppr ty_exp)
1085                     , nest 12 $   ptext (sLit "with actual type") <+> quotes (ppr ty_act)]
1086                , nest 2 (extra1 $$ extra2) ])
1087   where
1088     (env1, extra1) = typeExtraInfoMsg env  ty_exp
1089     (env2, extra2) = typeExtraInfoMsg env1 ty_act
1090 \end{code}
1091
1092
1093 -----------------------------------------
1094         UNUSED FOR NOW
1095 -----------------------------------------
1096
1097 ----------------
1098 ----------------
1099 -- If an error happens we try to figure out whether the function
1100 -- function has been given too many or too few arguments, and say so.
1101 addSubCtxt :: InstOrigin -> TcType -> TcType -> TcM a -> TcM a
1102 addSubCtxt orig actual_res_ty expected_res_ty thing_inside
1103   = addErrCtxtM mk_err thing_inside
1104   where
1105     mk_err tidy_env
1106       = do { exp_ty' <- zonkTcType expected_res_ty
1107            ; act_ty' <- zonkTcType actual_res_ty
1108            ; let (env1, exp_ty'') = tidyOpenType tidy_env exp_ty'
1109                  (env2, act_ty'') = tidyOpenType env1     act_ty'
1110                  (exp_args, _)    = tcSplitFunTys exp_ty''
1111                  (act_args, _)    = tcSplitFunTys act_ty''
1112
1113                  len_act_args     = length act_args
1114                  len_exp_args     = length exp_args
1115
1116                  message = case orig of
1117                              OccurrenceOf fun
1118                                   | len_exp_args < len_act_args -> wrongArgsCtxt "too few"  fun
1119                                   | len_exp_args > len_act_args -> wrongArgsCtxt "too many" fun
1120                              _ -> mkExpectedActualMsg act_ty'' exp_ty''
1121            ; return (env2, message) }
1122
1123
1124 %************************************************************************
1125 %*                                                                      *
1126                 Kind unification
1127 %*                                                                      *
1128 %************************************************************************
1129
1130 Unifying kinds is much, much simpler than unifying types.
1131
1132 \begin{code}
1133 matchExpectedFunKind :: TcKind -> TcM (Maybe (TcKind, TcKind))
1134 -- Like unifyFunTy, but does not fail; instead just returns Nothing
1135
1136 matchExpectedFunKind (TyVarTy kvar) = do
1137     maybe_kind <- readKindVar kvar
1138     case maybe_kind of
1139       Indirect fun_kind -> matchExpectedFunKind fun_kind
1140       Flexi ->
1141           do { arg_kind <- newKindVar
1142              ; res_kind <- newKindVar
1143              ; writeKindVar kvar (mkArrowKind arg_kind res_kind)
1144              ; return (Just (arg_kind,res_kind)) }
1145
1146 matchExpectedFunKind (FunTy arg_kind res_kind) = return (Just (arg_kind,res_kind))
1147 matchExpectedFunKind _                         = return Nothing
1148
1149 -----------------
1150 unifyKind :: TcKind                 -- Expected
1151           -> TcKind                 -- Actual
1152           -> TcM ()
1153
1154 unifyKind (TyConApp kc1 []) (TyConApp kc2 [])
1155   | isSubKindCon kc2 kc1 = return ()
1156
1157 unifyKind (FunTy a1 r1) (FunTy a2 r2)
1158   = do { unifyKind a2 a1; unifyKind r1 r2 }
1159                 -- Notice the flip in the argument,
1160                 -- so that the sub-kinding works right
1161 unifyKind (TyVarTy kv1) k2 = uKVar False kv1 k2
1162 unifyKind k1 (TyVarTy kv2) = uKVar True kv2 k1
1163 unifyKind k1 k2 = unifyKindMisMatch k1 k2
1164
1165 ----------------
1166 uKVar :: Bool -> KindVar -> TcKind -> TcM ()
1167 uKVar swapped kv1 k2
1168   = do  { mb_k1 <- readKindVar kv1
1169         ; case mb_k1 of
1170             Flexi -> uUnboundKVar swapped kv1 k2
1171             Indirect k1 | swapped   -> unifyKind k2 k1
1172                         | otherwise -> unifyKind k1 k2 }
1173
1174 ----------------
1175 uUnboundKVar :: Bool -> KindVar -> TcKind -> TcM ()
1176 uUnboundKVar swapped kv1 k2@(TyVarTy kv2)
1177   | kv1 == kv2 = return ()
1178   | otherwise   -- Distinct kind variables
1179   = do  { mb_k2 <- readKindVar kv2
1180         ; case mb_k2 of
1181             Indirect k2 -> uUnboundKVar swapped kv1 k2
1182             Flexi -> writeKindVar kv1 k2 }
1183
1184 uUnboundKVar swapped kv1 non_var_k2
1185   = do  { k2' <- zonkTcKind non_var_k2
1186         ; kindOccurCheck kv1 k2'
1187         ; k2'' <- kindSimpleKind swapped k2'
1188                 -- KindVars must be bound only to simple kinds
1189                 -- Polarities: (kindSimpleKind True ?) succeeds
1190                 -- returning *, corresponding to unifying
1191                 --      expected: ?
1192                 --      actual:   kind-ver
1193         ; writeKindVar kv1 k2'' }
1194
1195 ----------------
1196 kindOccurCheck :: TyVar -> Type -> TcM ()
1197 kindOccurCheck kv1 k2   -- k2 is zonked
1198   = checkTc (not_in k2) (kindOccurCheckErr kv1 k2)
1199   where
1200     not_in (TyVarTy kv2) = kv1 /= kv2
1201     not_in (FunTy a2 r2) = not_in a2 && not_in r2
1202     not_in _             = True
1203
1204 kindSimpleKind :: Bool -> Kind -> TcM SimpleKind
1205 -- (kindSimpleKind True k) returns a simple kind sk such that sk <: k
1206 -- If the flag is False, it requires k <: sk
1207 -- E.g.         kindSimpleKind False ?? = *
1208 -- What about (kv -> *) ~ ?? -> *
1209 kindSimpleKind orig_swapped orig_kind
1210   = go orig_swapped orig_kind
1211   where
1212     go sw (FunTy k1 k2) = do { k1' <- go (not sw) k1
1213                              ; k2' <- go sw k2
1214                              ; return (mkArrowKind k1' k2') }
1215     go True k
1216      | isOpenTypeKind k = return liftedTypeKind
1217      | isArgTypeKind k  = return liftedTypeKind
1218     go _ k
1219      | isLiftedTypeKind k   = return liftedTypeKind
1220      | isUnliftedTypeKind k = return unliftedTypeKind
1221     go _ k@(TyVarTy _) = return k -- KindVars are always simple
1222     go _ _ = failWithTc (ptext (sLit "Unexpected kind unification failure:")
1223                                   <+> ppr orig_swapped <+> ppr orig_kind)
1224         -- I think this can't actually happen
1225
1226 -- T v = MkT v           v must be a type
1227 -- T v w = MkT (v -> w)  v must not be an umboxed tuple
1228
1229 unifyKindMisMatch :: TcKind -> TcKind -> TcM ()
1230 unifyKindMisMatch ty1 ty2 = do
1231     ty1' <- zonkTcKind ty1
1232     ty2' <- zonkTcKind ty2
1233     let
1234         msg = hang (ptext (sLit "Couldn't match kind"))
1235                    2 (sep [quotes (ppr ty1'),
1236                            ptext (sLit "against"),
1237                            quotes (ppr ty2')])
1238     failWithTc msg
1239
1240 ----------------
1241 kindOccurCheckErr :: Var -> Type -> SDoc
1242 kindOccurCheckErr tyvar ty
1243   = hang (ptext (sLit "Occurs check: cannot construct the infinite kind:"))
1244        2 (sep [ppr tyvar, char '=', ppr ty])
1245 \end{code}
1246
1247 %************************************************************************
1248 %*                                                                      *
1249 \subsection{Checking signature type variables}
1250 %*                                                                      *
1251 %************************************************************************
1252
1253 @checkSigTyVars@ checks that a set of universally quantified type varaibles
1254 are not mentioned in the environment.  In particular:
1255
1256         (a) Not mentioned in the type of a variable in the envt
1257                 eg the signature for f in this:
1258
1259                         g x = ... where
1260                                         f :: a->[a]
1261                                         f y = [x,y]
1262
1263                 Here, f is forced to be monorphic by the free occurence of x.
1264
1265         (d) Not (unified with another type variable that is) in scope.
1266                 eg f x :: (r->r) = (\y->y) :: forall a. a->r
1267             when checking the expression type signature, we find that
1268             even though there is nothing in scope whose type mentions r,
1269             nevertheless the type signature for the expression isn't right.
1270
1271             Another example is in a class or instance declaration:
1272                 class C a where
1273                    op :: forall b. a -> b
1274                    op x = x
1275             Here, b gets unified with a
1276
1277 Before doing this, the substitution is applied to the signature type variable.
1278
1279 -- \begin{code}
1280 checkSigTyVars :: [TcTyVar] -> TcM ()
1281 checkSigTyVars sig_tvs = check_sig_tyvars emptyVarSet sig_tvs
1282
1283 checkSigTyVarsWrt :: TcTyVarSet -> [TcTyVar] -> TcM ()
1284 -- The extra_tvs can include boxy type variables;
1285 --      e.g. TcMatches.tcCheckExistentialPat
1286 checkSigTyVarsWrt extra_tvs sig_tvs
1287   = do  { extra_tvs' <- zonkTcTyVarsAndFV extra_tvs
1288         ; check_sig_tyvars extra_tvs' sig_tvs }
1289
1290 check_sig_tyvars
1291         :: TcTyVarSet   -- Global type variables. The universally quantified
1292                         --      tyvars should not mention any of these
1293                         --      Guaranteed already zonked.
1294         -> [TcTyVar]    -- Universally-quantified type variables in the signature
1295                         --      Guaranteed to be skolems
1296         -> TcM ()
1297 check_sig_tyvars _ []
1298   = return ()
1299 check_sig_tyvars extra_tvs sig_tvs
1300   = ASSERT( all isTcTyVar sig_tvs && all isSkolemTyVar sig_tvs )
1301     do  { gbl_tvs <- tcGetGlobalTyVars
1302         ; traceTc "check_sig_tyvars" $ vcat
1303                [ text "sig_tys" <+> ppr sig_tvs
1304                , text "gbl_tvs" <+> ppr gbl_tvs
1305                , text "extra_tvs" <+> ppr extra_tvs]
1306
1307         ; let env_tvs = gbl_tvs `unionVarSet` extra_tvs
1308         ; when (any (`elemVarSet` env_tvs) sig_tvs)
1309                (bleatEscapedTvs env_tvs sig_tvs sig_tvs)
1310         }
1311
1312 bleatEscapedTvs :: TcTyVarSet   -- The global tvs
1313                 -> [TcTyVar]    -- The possibly-escaping type variables
1314                 -> [TcTyVar]    -- The zonked versions thereof
1315                 -> TcM ()
1316 -- Complain about escaping type variables
1317 -- We pass a list of type variables, at least one of which
1318 -- escapes.  The first list contains the original signature type variable,
1319 -- while the second  contains the type variable it is unified to (usually itself)
1320 bleatEscapedTvs globals sig_tvs zonked_tvs
1321   = do  { env0 <- tcInitTidyEnv
1322         ; let (env1, tidy_tvs)        = tidyOpenTyVars env0 sig_tvs
1323               (env2, tidy_zonked_tvs) = tidyOpenTyVars env1 zonked_tvs
1324
1325         ; (env3, msgs) <- foldlM check (env2, []) (tidy_tvs `zip` tidy_zonked_tvs)
1326         ; failWithTcM (env3, main_msg $$ nest 2 (vcat msgs)) }
1327   where
1328     main_msg = ptext (sLit "Inferred type is less polymorphic than expected")
1329
1330     check (tidy_env, msgs) (sig_tv, zonked_tv)
1331       | not (zonked_tv `elemVarSet` globals) = return (tidy_env, msgs)
1332       | otherwise
1333       = do { lcl_env <- getLclTypeEnv
1334            ; (tidy_env1, globs) <- findGlobals (unitVarSet zonked_tv) lcl_env tidy_env
1335            ; return (tidy_env1, escape_msg sig_tv zonked_tv globs : msgs) }
1336
1337 -----------------------
1338 escape_msg :: Var -> Var -> [SDoc] -> SDoc
1339 escape_msg sig_tv zonked_tv globs
1340   | notNull globs
1341   = vcat [sep [msg, ptext (sLit "is mentioned in the environment:")],
1342           nest 2 (vcat globs)]
1343   | otherwise
1344   = msg <+> ptext (sLit "escapes")
1345         -- Sigh.  It's really hard to give a good error message
1346         -- all the time.   One bad case is an existential pattern match.
1347         -- We rely on the "When..." context to help.
1348   where
1349     msg = ptext (sLit "Quantified type variable") <+> quotes (ppr sig_tv) <+> is_bound_to
1350     is_bound_to
1351         | sig_tv == zonked_tv = empty
1352         | otherwise = ptext (sLit "is unified with") <+> quotes (ppr zonked_tv) <+> ptext (sLit "which")
1353 -- \end{code}
1354
1355 These two context are used with checkSigTyVars
1356
1357 \begin{code}
1358 sigCtxt :: Id -> [TcTyVar] -> TcThetaType -> TcTauType
1359         -> TidyEnv -> TcM (TidyEnv, Message)
1360 sigCtxt id sig_tvs sig_theta sig_tau tidy_env = do
1361     actual_tau <- zonkTcType sig_tau
1362     let
1363         (env1, tidy_sig_tvs)    = tidyOpenTyVars tidy_env sig_tvs
1364         (env2, tidy_sig_rho)    = tidyOpenType env1 (mkPhiTy sig_theta sig_tau)
1365         (env3, tidy_actual_tau) = tidyOpenType env2 actual_tau
1366         sub_msg = vcat [ptext (sLit "Signature type:    ") <+> pprType (mkForAllTys tidy_sig_tvs tidy_sig_rho),
1367                         ptext (sLit "Type to generalise:") <+> pprType tidy_actual_tau
1368                    ]
1369         msg = vcat [ptext (sLit "When trying to generalise the type inferred for") <+> quotes (ppr id),
1370                     nest 2 sub_msg]
1371
1372     return (env3, msg)
1373 \end{code}