compiler/typecheck/TcUnify.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section{Type subsumption and unification}
   5
   6 \begin{code}
   7 module TcUnify (
   8         -- Full-blown subsumption
   9   tcSubExp, tcFunResTy, tcGen,
  10   checkSigTyVars, checkSigTyVarsWrt, bleatEscapedTvs, sigCtxt,
  11
  12         -- Various unifications
  13   unifyType, unifyTypeList, unifyTheta,
  14   unifyKind, unifyKinds, unifyFunKind,
  15   checkExpectedKind,
  16   preSubType, boxyMatchTypes,
  17
  18   --------------------------------
  19   -- Holes
  20   tcInfer, subFunTys, unBox, stripBoxyType, withBox,
  21   boxyUnify, boxyUnifyList, zapToMonotype,
  22   boxySplitListTy, boxySplitTyConApp, boxySplitAppTy,
  23   wrapFunResCoercion
  24   ) where
  25
  26 #include "HsVersions.h"
  27
  28 import HsSyn            ( ExprCoFn(..), idCoercion, isIdCoercion, (<.>) )
  29 import TypeRep          ( Type(..), PredType(..) )
  30
  31 import TcMType          ( lookupTcTyVar, LookupTyVarResult(..),
  32                           tcInstSkolType, tcInstBoxyTyVar, newKindVar, newMetaTyVar,
  33                           newBoxyTyVar, newBoxyTyVarTys, readFilledBox,
  34                           readMetaTyVar, writeMetaTyVar, newFlexiTyVarTy,
  35                           tcInstSkolTyVars, tcInstTyVar,
  36                           zonkTcKind, zonkType, zonkTcType,  zonkTcTyVarsAndFV,
  37                           readKindVar, writeKindVar )
  38 import TcSimplify       ( tcSimplifyCheck )
  39 import TcEnv            ( tcGetGlobalTyVars, findGlobals )
  40 import TcIface          ( checkWiredInTyCon )
  41 import TcRnMonad         -- TcType, amongst others
  42 import TcType           ( TcKind, TcType, TcTyVar, BoxyTyVar, TcTauType,
  43                           BoxySigmaType, BoxyRhoType, BoxyType,
  44                           TcTyVarSet, TcThetaType, TcTyVarDetails(..), BoxInfo(..),
  45                           SkolemInfo( GenSkol, UnkSkol ), MetaDetails(..), isImmutableTyVar,
  46                           pprSkolTvBinding, isTauTy, isTauTyCon, isSigmaTy,
  47                           mkFunTy, mkFunTys, mkTyConApp, isMetaTyVar,
  48                           tcSplitForAllTys, tcSplitAppTy_maybe, tcSplitFunTys, mkTyVarTys,
  49                           tcSplitSigmaTy, tyVarsOfType, mkPhiTy, mkTyVarTy, mkPredTy,
  50                           typeKind, mkForAllTys, mkAppTy, isBoxyTyVar,
  51                           tcView, exactTyVarsOfType,
  52                           tidyOpenType, tidyOpenTyVar, tidyOpenTyVars,
  53                           pprType, tidyKind, tidySkolemTyVar, isSkolemTyVar, isSigTyVar,
  54                           TvSubst, mkTvSubst, zipTyEnv, zipOpenTvSubst, emptyTvSubst,
  55                           substTy, substTheta,
  56                           lookupTyVar, extendTvSubst )
  57 import Kind             ( Kind(..), SimpleKind, KindVar, isArgTypeKind,
  58                           openTypeKind, liftedTypeKind, unliftedTypeKind,
  59                           mkArrowKind, defaultKind,
  60                           isOpenTypeKind, argTypeKind, isLiftedTypeKind, isUnliftedTypeKind,
  61                           isSubKind, pprKind, splitKindFunTys )
  62 import TysPrim          ( alphaTy, betaTy )
  63 import Inst             ( newDicts, instToId )
  64 import TyCon            ( TyCon, tyConArity, tyConTyVars, isSynTyCon )
  65 import TysWiredIn       ( listTyCon )
  66 import Id               ( Id, mkSysLocal )
  67 import Var              ( Var, varName, tyVarKind, isTcTyVar, tcTyVarDetails )
  68 import VarSet
  69 import VarEnv
  70 import Name             ( Name, isSystemName )
  71 import ErrUtils         ( Message )
  72 import Maybes           ( expectJust, isNothing )
  73 import BasicTypes       ( Arity )
  74 import UniqSupply       ( uniqsFromSupply )
  75 import Util             ( notNull, equalLength )
  76 import Outputable
  77
  78 -- Assertion imports
  79 #ifdef DEBUG
  80 import TcType           ( isBoxyTy, isFlexi )
  81 #endif
  82 \end{code}
  83
  84 %************************************************************************
  85 %*                                                                      *
  86 \subsection{'hole' type variables}
  87 %*                                                                      *
  88 %************************************************************************
  89
  90 \begin{code}
  91 tcInfer :: (BoxyType -> TcM a) -> TcM (a, TcType)
  92 tcInfer tc_infer
  93   = do  { box <- newBoxyTyVar openTypeKind
  94         ; res <- tc_infer (mkTyVarTy box)
  95         ; res_ty <- readFilledBox box   -- Guaranteed filled-in by now
  96         ; return (res, res_ty) }
  97 \end{code}
  98
  99
 100 %************************************************************************
 101 %*                                                                      *
 102         subFunTys
 103 %*                                                                      *
 104 %************************************************************************
 105
 106 \begin{code}
 107 subFunTys :: SDoc  -- Somthing like "The function f has 3 arguments"
 108                    -- or "The abstraction (\x.e) takes 1 argument"
 109           -> Arity              -- Expected # of args
 110           -> BoxyRhoType        -- res_ty
 111           -> ([BoxySigmaType] -> BoxyRhoType -> TcM a)
 112           -> TcM (ExprCoFn, a)
 113 -- Attempt to decompse res_ty to have enough top-level arrows to
 114 -- match the number of patterns in the match group
 115 --
 116 -- If (subFunTys n_args res_ty thing_inside) = (co_fn, res)
 117 -- and the inner call to thing_inside passes args: [a1,...,an], b
 118 -- then co_fn :: (a1 -> ... -> an -> b) -> res_ty
 119 --
 120 -- Note that it takes a BoxyRho type, and guarantees to return a BoxyRhoType
 121
 122
 123 {-      Error messages from subFunTys
 124
 125    The abstraction `\Just 1 -> ...' has two arguments
 126    but its type `Maybe a -> a' has only one
 127
 128    The equation(s) for `f' have two arguments
 129    but its type `Maybe a -> a' has only one
 130
 131    The section `(f 3)' requires 'f' to take two arguments
 132    but its type `Int -> Int' has only one
 133
 134    The function 'f' is applied to two arguments
 135    but its type `Int -> Int' has only one
 136 -}
 137
 138
 139 subFunTys error_herald n_pats res_ty thing_inside
 140   = loop n_pats [] res_ty
 141   where
 142         -- In 'loop', the parameter 'arg_tys' accumulates
 143         -- the arg types so far, in *reverse order*
 144     loop n args_so_far res_ty
 145         | Just res_ty' <- tcView res_ty  = loop n args_so_far res_ty'
 146
 147     loop n args_so_far res_ty
 148         | isSigmaTy res_ty      -- Do this before checking n==0, because we
 149                                 -- guarantee to return a BoxyRhoType, not a BoxySigmaType
 150         = do { (gen_fn, (co_fn, res)) <- tcGen res_ty emptyVarSet $ \ res_ty' ->
 151                                          loop n args_so_far res_ty'
 152              ; return (gen_fn <.> co_fn, res) }
 153
 154     loop 0 args_so_far res_ty
 155         = do { res <- thing_inside (reverse args_so_far) res_ty
 156              ; return (idCoercion, res) }
 157
 158     loop n args_so_far (FunTy arg_ty res_ty)
 159         = do { (co_fn, res) <- loop (n-1) (arg_ty:args_so_far) res_ty
 160              ; co_fn' <- wrapFunResCoercion [arg_ty] co_fn
 161              ; return (co_fn', res) }
 162
 163         -- res_ty might have a type variable at the head, such as (a b c),
 164         -- in which case we must fill in with (->).  Simplest thing to do
 165         -- is to use boxyUnify, but we catch failure and generate our own
 166         -- error message on failure
 167     loop n args_so_far res_ty@(AppTy _ _)
 168         = do { [arg_ty',res_ty'] <- newBoxyTyVarTys [argTypeKind, openTypeKind]
 169              ; (_, mb_unit) <- tryTcErrs $ boxyUnify res_ty (FunTy arg_ty' res_ty')
 170              ; if isNothing mb_unit then bale_out args_so_far
 171                else loop n args_so_far (FunTy arg_ty' res_ty') }
 172
 173     loop n args_so_far (TyVarTy tv)
 174         | not (isImmutableTyVar tv)
 175         = do { cts <- readMetaTyVar tv
 176              ; case cts of
 177                  Indirect ty -> loop n args_so_far ty
 178                  Flexi -> do { (res_ty:arg_tys) <- withMetaTvs tv kinds mk_res_ty
 179                              ; res <- thing_inside (reverse args_so_far ++ arg_tys) res_ty
 180                              ; return (idCoercion, res) } }
 181         where
 182           mk_res_ty (res_ty' : arg_tys') = mkFunTys arg_tys' res_ty'
 183           mk_res_ty [] = panic "TcUnify.mk_res_ty1"
 184           kinds = openTypeKind : take n (repeat argTypeKind)
 185                 -- Note argTypeKind: the args can have an unboxed type,
 186                 -- but not an unboxed tuple.
 187
 188     loop n args_so_far res_ty = bale_out args_so_far
 189
 190     bale_out args_so_far
 191         = do { env0 <- tcInitTidyEnv
 192              ; res_ty' <- zonkTcType res_ty
 193              ; let (env1, res_ty'') = tidyOpenType env0 res_ty'
 194              ; failWithTcM (env1, mk_msg res_ty'' (length args_so_far)) }
 195
 196     mk_msg res_ty n_actual
 197       = error_herald <> comma $$
 198         sep [ptext SLIT("but its type") <+> quotes (pprType res_ty),
 199              if n_actual == 0 then ptext SLIT("has none")
 200              else ptext SLIT("has only") <+> speakN n_actual]
 201 \end{code}
 202
 203 \begin{code}
 204 ----------------------
 205 boxySplitTyConApp :: TyCon                      -- T :: k1 -> ... -> kn -> *
 206                   -> BoxyRhoType                -- Expected type (T a b c)
 207                   -> TcM [BoxySigmaType]        -- Element types, a b c
 208   -- It's used for wired-in tycons, so we call checkWiredInTyCOn
 209   -- Precondition: never called with FunTyCon
 210   -- Precondition: input type :: *
 211
 212 boxySplitTyConApp tc orig_ty
 213   = do  { checkWiredInTyCon tc
 214         ; loop (tyConArity tc) [] orig_ty }
 215   where
 216     loop n_req args_so_far ty
 217       | Just ty' <- tcView ty = loop n_req args_so_far ty'
 218
 219     loop n_req args_so_far (TyConApp tycon args)
 220       | tc == tycon
 221       = ASSERT( n_req == length args)   -- ty::*
 222         return (args ++ args_so_far)
 223
 224     loop n_req args_so_far (AppTy fun arg)
 225       = loop (n_req - 1) (arg:args_so_far) fun
 226
 227     loop n_req args_so_far (TyVarTy tv)
 228       | not (isImmutableTyVar tv)
 229       = do { cts <- readMetaTyVar tv
 230            ; case cts of
 231                Indirect ty -> loop n_req args_so_far ty
 232                Flexi       -> do { arg_tys <- withMetaTvs tv arg_kinds mk_res_ty
 233                                  ; return (arg_tys ++ args_so_far) }
 234         }
 235       where
 236         mk_res_ty arg_tys' = mkTyConApp tc arg_tys'
 237         arg_kinds = map tyVarKind (take n_req (tyConTyVars tc))
 238
 239     loop _ _ _ = boxySplitFailure (mkTyConApp tc (mkTyVarTys (tyConTyVars tc))) orig_ty
 240
 241 ----------------------
 242 boxySplitListTy :: BoxyRhoType -> TcM BoxySigmaType     -- Special case for lists
 243 boxySplitListTy exp_ty = do { [elt_ty] <- boxySplitTyConApp listTyCon exp_ty
 244                             ; return elt_ty }
 245
 246
 247 ----------------------
 248 boxySplitAppTy :: BoxyRhoType                           -- Type to split: m a
 249                -> TcM (BoxySigmaType, BoxySigmaType)    -- Returns m, a
 250 -- Assumes (m: * -> k), where k is the kind of the incoming type
 251 -- If the incoming type is boxy, then so are the result types; and vice versa
 252
 253 boxySplitAppTy orig_ty
 254   = loop orig_ty
 255   where
 256     loop ty
 257       | Just ty' <- tcView ty = loop ty'
 258
 259     loop ty
 260       | Just (fun_ty, arg_ty) <- tcSplitAppTy_maybe ty
 261       = return (fun_ty, arg_ty)
 262
 263     loop (TyVarTy tv)
 264       | not (isImmutableTyVar tv)
 265       = do { cts <- readMetaTyVar tv
 266            ; case cts of
 267                Indirect ty -> loop ty
 268                Flexi       -> do { [fun_ty,arg_ty] <- withMetaTvs tv kinds mk_res_ty
 269                                  ; return (fun_ty, arg_ty) } }
 270       where
 271         mk_res_ty [fun_ty', arg_ty'] = mkAppTy fun_ty' arg_ty'
 272         mk_res_ty other = panic "TcUnify.mk_res_ty2"
 273         tv_kind = tyVarKind tv
 274         kinds = [mkArrowKind liftedTypeKind (defaultKind tv_kind),
 275                                                 -- m :: * -> k
 276                  liftedTypeKind]                -- arg type :: *
 277         -- The defaultKind is a bit smelly.  If you remove it,
 278         -- try compiling        f x = do { x }
 279         -- and you'll get a kind mis-match.  It smells, but
 280         -- not enough to lose sleep over.
 281
 282     loop _ = boxySplitFailure (mkAppTy alphaTy betaTy) orig_ty
 283
 284 ------------------
 285 boxySplitFailure actual_ty expected_ty
 286   = unifyMisMatch False False actual_ty expected_ty
 287         -- "outer" is False, so we don't pop the context
 288         -- which is what we want since we have not pushed one!
 289 \end{code}
 290
 291
 292 --------------------------------
 293 -- withBoxes: the key utility function
 294 --------------------------------
 295
 296 \begin{code}
 297 withMetaTvs :: TcTyVar  -- An unfilled-in, non-skolem, meta type variable
 298             -> [Kind]   -- Make fresh boxes (with the same BoxTv/TauTv setting as tv)
 299             -> ([BoxySigmaType] -> BoxySigmaType)
 300                                         -- Constructs the type to assign
 301                                         -- to the original var
 302             -> TcM [BoxySigmaType]      -- Return the fresh boxes
 303
 304 -- It's entirely possible for the [kind] to be empty.
 305 -- For example, when pattern-matching on True,
 306 -- we call boxySplitTyConApp passing a boolTyCon
 307
 308 -- Invariant: tv is still Flexi
 309
 310 withMetaTvs tv kinds mk_res_ty
 311   | isBoxyTyVar tv
 312   = do  { box_tvs <- mapM (newMetaTyVar BoxTv) kinds
 313         ; let box_tys = mkTyVarTys box_tvs
 314         ; writeMetaTyVar tv (mk_res_ty box_tys)
 315         ; return box_tys }
 316
 317   | otherwise                   -- Non-boxy meta type variable
 318   = do  { tau_tys <- mapM newFlexiTyVarTy kinds
 319         ; writeMetaTyVar tv (mk_res_ty tau_tys) -- Write it *first*
 320                                                 -- Sure to be a tau-type
 321         ; return tau_tys }
 322
 323 withBox :: Kind -> (BoxySigmaType -> TcM a) -> TcM (a, TcType)
 324 -- Allocate a *boxy* tyvar
 325 withBox kind thing_inside
 326   = do  { box_tv <- newMetaTyVar BoxTv kind
 327         ; res <- thing_inside (mkTyVarTy box_tv)
 328         ; ty  <- readFilledBox box_tv
 329         ; return (res, ty) }
 330 \end{code}
 331
 332
 333 %************************************************************************
 334 %*                                                                      *
 335                 Approximate boxy matching
 336 %*                                                                      *
 337 %************************************************************************
 338
 339 \begin{code}
 340 preSubType :: [TcTyVar]         -- Quantified type variables
 341            -> TcTyVarSet        -- Subset of quantified type variables
 342                                 --   see Note [Pre-sub boxy]
 343             -> TcType           -- The rho-type part; quantified tyvars scopes over this
 344             -> BoxySigmaType    -- Matching type from the context
 345             -> TcM [TcType]     -- Types to instantiate the tyvars
 346 -- Perform pre-subsumption, and return suitable types
 347 -- to instantiate the quantified type varibles:
 348 --      info from the pre-subsumption, if there is any
 349 --      a boxy type variable otherwise
 350 --
 351 -- Note [Pre-sub boxy]
 352 --   The 'btvs' are a subset of 'qtvs'.  They are the ones we can
 353 --   instantiate to a boxy type variable, because they'll definitely be
 354 --   filled in later.  This isn't always the case; sometimes we have type
 355 --   variables mentioned in the context of the type, but not the body;
 356 --                f :: forall a b. C a b => a -> a
 357 --   Then we may land up with an unconstrained 'b', so we want to
 358 --   instantiate it to a monotype (non-boxy) type variable
 359 --
 360 -- The 'qtvs' that are *neither* fixed by the pre-subsumption, *nor* are in 'btvs',
 361 -- are instantiated to TauTv meta variables.
 362
 363 preSubType qtvs btvs qty expected_ty
 364   = do { tys <- mapM inst_tv qtvs
 365         ; traceTc (text "preSubType" <+> (ppr qtvs $$ ppr btvs $$ ppr qty $$ ppr expected_ty $$ ppr pre_subst $$ ppr tys))
 366         ; return tys }
 367   where
 368     pre_subst = boxySubMatchType (mkVarSet qtvs) qty expected_ty
 369     inst_tv tv
 370         | Just boxy_ty <- lookupTyVar pre_subst tv = return boxy_ty
 371         | tv `elemVarSet` btvs = do { tv' <- tcInstBoxyTyVar tv
 372                                     ; return (mkTyVarTy tv') }
 373         | otherwise            = do { tv' <- tcInstTyVar tv
 374                                     ; return (mkTyVarTy tv') }
 375
 376 boxySubMatchType
 377         :: TcTyVarSet -> TcType -- The "template"; the tyvars are skolems
 378         -> BoxyRhoType          -- Type to match (note a *Rho* type)
 379         -> TvSubst              -- Substitution of the [TcTyVar] to BoxySigmaTypes
 380
 381 -- boxySubMatchType implements the Pre-subsumption judgement, in Fig 5 of the paper
 382 -- "Boxy types: inference for higher rank types and impredicativity"
 383
 384 boxySubMatchType tmpl_tvs tmpl_ty boxy_ty
 385   = go tmpl_tvs tmpl_ty emptyVarSet boxy_ty
 386   where
 387     go t_tvs t_ty b_tvs b_ty
 388         | Just t_ty' <- tcView t_ty = go t_tvs t_ty' b_tvs b_ty
 389         | Just b_ty' <- tcView b_ty = go t_tvs t_ty b_tvs b_ty'
 390
 391     go t_tvs (TyVarTy _) b_tvs b_ty = emptyTvSubst      -- Rule S-ANY; no bindings
 392         -- Rule S-ANY covers (a) type variables and (b) boxy types
 393         -- in the template.  Both look like a TyVarTy.
 394         -- See Note [Sub-match] below
 395
 396     go t_tvs t_ty b_tvs b_ty
 397         | isSigmaTy t_ty, (tvs, _, t_tau) <- tcSplitSigmaTy t_ty
 398         = go (t_tvs `delVarSetList` tvs) t_tau b_tvs b_ty       -- Rule S-SPEC
 399                 -- Under a forall on the left, if there is shadowing,
 400                 -- do not bind! Hence the delVarSetList.
 401         | isSigmaTy b_ty, (tvs, _, b_tau) <- tcSplitSigmaTy b_ty
 402         = go t_tvs t_ty (extendVarSetList b_tvs tvs) b_tau      -- Rule S-SKOL
 403                 -- Add to the variables we must not bind to
 404         -- NB: it's *important* to discard the theta part. Otherwise
 405         -- consider (forall a. Eq a => a -> b) ~<~ (Int -> Int -> Bool)
 406         -- and end up with a completely bogus binding (b |-> Bool), by lining
 407         -- up the (Eq a) with the Int, whereas it should be (b |-> (Int->Bool)).
 408         -- This pre-subsumption stuff can return too few bindings, but it
 409         -- must *never* return bogus info.
 410
 411     go t_tvs (FunTy arg1 res1) b_tvs (FunTy arg2 res2)  -- Rule S-FUN
 412         = boxy_match t_tvs arg1 b_tvs arg2 (go t_tvs res1 b_tvs res2)
 413         -- Match the args, and sub-match the results
 414
 415     go t_tvs t_ty b_tvs b_ty = boxy_match t_tvs t_ty b_tvs b_ty emptyTvSubst
 416         -- Otherwise defer to boxy matching
 417         -- This covers TyConApp, AppTy, PredTy
 418 \end{code}
 419
 420 Note [Sub-match]
 421 ~~~~~~~~~~~~~~~~
 422 Consider this
 423         head :: [a] -> a
 424         |- head xs : <rhobox>
 425 We will do a boxySubMatchType between   a ~ <rhobox>
 426 But we *don't* want to match [a |-> <rhobox>] because
 427     (a) The box should be filled in with a rho-type, but
 428            but the returned substitution maps TyVars to boxy
 429            *sigma* types
 430     (b) In any case, the right final answer might be *either*
 431            instantiate 'a' with a rho-type or a sigma type
 432            head xs : Int   vs   head xs : forall b. b->b
 433 So the matcher MUST NOT make a choice here.   In general, we only
 434 bind a template type variable in boxyMatchType, not in boxySubMatchType.
 435
 436
 437 \begin{code}
 438 boxyMatchTypes
 439         :: TcTyVarSet -> [TcType] -- The "template"; the tyvars are skolems
 440         -> [BoxySigmaType]        -- Type to match
 441         -> TvSubst                -- Substitution of the [TcTyVar] to BoxySigmaTypes
 442
 443 -- boxyMatchTypes implements the Pre-matching judgement, in Fig 5 of the paper
 444 -- "Boxy types: inference for higher rank types and impredicativity"
 445
 446 -- Find a *boxy* substitution that makes the template look as much
 447 --      like the BoxySigmaType as possible.
 448 -- It's always ok to return an empty substitution;
 449 --      anything more is jam on the pudding
 450 --
 451 -- NB1: This is a pure, non-monadic function.
 452 --      It does no unification, and cannot fail
 453 --
 454 -- Precondition: the arg lengths are equal
 455 -- Precondition: none of the template type variables appear anywhere in the [BoxySigmaType]
 456 --
 457
 458 ------------
 459 boxyMatchTypes tmpl_tvs tmpl_tys boxy_tys
 460   = ASSERT( length tmpl_tys == length boxy_tys )
 461     boxy_match_s tmpl_tvs tmpl_tys emptyVarSet boxy_tys emptyTvSubst
 462         -- ToDo: add error context?
 463
 464 boxy_match_s tmpl_tvs [] boxy_tvs [] subst
 465   = subst
 466 boxy_match_s tmpl_tvs (t_ty:t_tys) boxy_tvs (b_ty:b_tys) subst
 467   = boxy_match tmpl_tvs t_ty boxy_tvs b_ty $
 468     boxy_match_s tmpl_tvs t_tys boxy_tvs b_tys subst
 469 boxy_match_s tmpl_tvs _ boxy_tvs _ subst
 470   = panic "boxy_match_s"        -- Lengths do not match
 471
 472
 473 ------------
 474 boxy_match :: TcTyVarSet -> TcType      -- Template
 475            -> TcTyVarSet                -- boxy_tvs: do not bind template tyvars to any of these
 476            -> BoxySigmaType             -- Match against this type
 477            -> TvSubst
 478            -> TvSubst
 479
 480 -- The boxy_tvs argument prevents this match:
 481 --      [a]  forall b. a  ~  forall b. b
 482 -- We don't want to bind the template variable 'a'
 483 -- to the quantified type variable 'b'!
 484
 485 boxy_match tmpl_tvs orig_tmpl_ty boxy_tvs orig_boxy_ty subst
 486   = go orig_tmpl_ty orig_boxy_ty
 487   where
 488     go t_ty b_ty
 489         | Just t_ty' <- tcView t_ty = go t_ty' b_ty
 490         | Just b_ty' <- tcView b_ty = go t_ty b_ty'
 491
 492     go ty1 ty2          -- C.f. the isSigmaTy case for boxySubMatchType
 493         | isSigmaTy ty1
 494         , (tvs1, _, tau1) <- tcSplitSigmaTy ty1
 495         , (tvs2, _, tau2) <- tcSplitSigmaTy ty2
 496         , equalLength tvs1 tvs2
 497         = boxy_match (tmpl_tvs `delVarSetList` tvs1)    tau1
 498                      (boxy_tvs `extendVarSetList` tvs2) tau2 subst
 499
 500     go (TyConApp tc1 tys1) (TyConApp tc2 tys2)
 501         | tc1 == tc2 = go_s tys1 tys2
 502
 503     go (FunTy arg1 res1) (FunTy arg2 res2)
 504         = go_s [arg1,res1] [arg2,res2]
 505
 506     go t_ty b_ty
 507         | Just (s1,t1) <- tcSplitAppTy_maybe t_ty,
 508           Just (s2,t2) <- tcSplitAppTy_maybe b_ty,
 509           typeKind t2 `isSubKind` typeKind t1   -- Maintain invariant
 510         = go_s [s1,t1] [s2,t2]
 511
 512     go (TyVarTy tv) b_ty
 513         | tv `elemVarSet` tmpl_tvs      -- Template type variable in the template
 514         , not (intersectsVarSet boxy_tvs (tyVarsOfType orig_boxy_ty))
 515         , typeKind b_ty `isSubKind` tyVarKind tv  -- See Note [Matching kinds]
 516         = extendTvSubst subst tv boxy_ty'
 517         | otherwise
 518         = subst                         -- Ignore others
 519         where
 520           boxy_ty' = case lookupTyVar subst tv of
 521                         Nothing -> orig_boxy_ty
 522                         Just ty -> ty `boxyLub` orig_boxy_ty
 523
 524     go _ _ = emptyTvSubst       -- It's important to *fail* by returning the empty substitution
 525         -- Example:  Tree a ~ Maybe Int
 526         -- We do not want to bind (a |-> Int) in pre-matching, because that can give very
 527         -- misleading error messages.  An even more confusing case is
 528         --           a -> b ~ Maybe Int
 529         -- Then we do not want to bind (b |-> Int)!  It's always safe to discard bindings
 530         -- from this pre-matching phase.
 531
 532     --------
 533     go_s tys1 tys2 = boxy_match_s tmpl_tvs tys1 boxy_tvs tys2 subst
 534
 535
 536 boxyLub :: BoxySigmaType -> BoxySigmaType -> BoxySigmaType
 537 -- Combine boxy information from the two types
 538 -- If there is a conflict, return the first
 539 boxyLub orig_ty1 orig_ty2
 540   = go orig_ty1 orig_ty2
 541   where
 542     go (AppTy f1 a1) (AppTy f2 a2) = AppTy (boxyLub f1 f2) (boxyLub a1 a2)
 543     go (FunTy f1 a1) (FunTy f2 a2) = FunTy (boxyLub f1 f2) (boxyLub a1 a2)
 544     go (TyConApp tc1 ts1) (TyConApp tc2 ts2)
 545       | tc1 == tc2, length ts1 == length ts2
 546       = TyConApp tc1 (zipWith boxyLub ts1 ts2)
 547
 548     go (TyVarTy tv1) ty2                -- This is the whole point;
 549       | isTcTyVar tv1, isBoxyTyVar tv1  -- choose ty2 if ty2 is a box
 550       = orig_ty2
 551
 552         -- Look inside type synonyms, but only if the naive version fails
 553     go ty1 ty2 | Just ty1' <- tcView ty1 = go ty1' ty2
 554                | Just ty2' <- tcView ty1 = go ty1 ty2'
 555
 556     -- For now, we don't look inside ForAlls, PredTys
 557     go ty1 ty2 = orig_ty1       -- Default
 558 \end{code}
 559
 560 Note [Matching kinds]
 561 ~~~~~~~~~~~~~~~~~~~~~
 562 The target type might legitimately not be a sub-kind of template.
 563 For example, suppose the target is simply a box with an OpenTypeKind,
 564 and the template is a type variable with LiftedTypeKind.
 565 Then it's ok (because the target type will later be refined).
 566 We simply don't bind the template type variable.
 567
 568 It might also be that the kind mis-match is an error. For example,
 569 suppose we match the template (a -> Int) against (Int# -> Int),
 570 where the template type variable 'a' has LiftedTypeKind.  This
 571 matching function does not fail; it simply doesn't bind the template.
 572 Later stuff will fail.
 573
 574 %************************************************************************
 575 %*                                                                      *
 576                 Subsumption checking
 577 %*                                                                      *
 578 %************************************************************************
 579
 580 All the tcSub calls have the form
 581
 582                 tcSub expected_ty offered_ty
 583 which checks
 584                 offered_ty <= expected_ty
 585
 586 That is, that a value of type offered_ty is acceptable in
 587 a place expecting a value of type expected_ty.
 588
 589 It returns a coercion function
 590         co_fn :: offered_ty -> expected_ty
 591 which takes an HsExpr of type offered_ty into one of type
 592 expected_ty.
 593
 594 \begin{code}
 595 -----------------
 596 tcSubExp :: BoxySigmaType -> BoxySigmaType -> TcM ExprCoFn      -- Locally used only
 597         -- (tcSub act exp) checks that
 598         --      act <= exp
 599 tcSubExp actual_ty expected_ty
 600   = -- addErrCtxtM (unifyCtxt actual_ty expected_ty) $
 601     -- Adding the error context here leads to some very confusing error
 602     -- messages, such as "can't match foarall a. a->a with forall a. a->a"
 603     -- So instead I'm adding it when moving from tc_sub to u_tys
 604     tc_sub Nothing actual_ty actual_ty False expected_ty expected_ty
 605
 606 tcFunResTy :: Name -> BoxySigmaType -> BoxySigmaType -> TcM ExprCoFn    -- Locally used only
 607 tcFunResTy fun actual_ty expected_ty
 608   = tc_sub (Just fun) actual_ty actual_ty False expected_ty expected_ty
 609
 610 -----------------
 611 tc_sub :: Maybe Name            -- Just fun => we're looking at a function result type
 612        -> BoxySigmaType         -- actual_ty, before expanding synonyms
 613        -> BoxySigmaType         --              ..and after
 614        -> InBox                 -- True <=> expected_ty is inside a box
 615        -> BoxySigmaType         -- expected_ty, before
 616        -> BoxySigmaType         --              ..and after
 617        -> TcM ExprCoFn
 618                                 -- The acual_ty is never inside a box
 619 -- IMPORTANT pre-condition: if the args contain foralls, the bound type
 620 --                          variables are visible non-monadically
 621 --                          (i.e. tha args are sufficiently zonked)
 622 -- This invariant is needed so that we can "see" the foralls, ad
 623 -- e.g. in the SPEC rule where we just use splitSigmaTy
 624
 625 tc_sub mb_fun act_sty act_ty exp_ib exp_sty exp_ty
 626   = tc_sub1 mb_fun act_sty act_ty exp_ib exp_sty exp_ty
 627         -- This indirection is just here to make
 628         -- it easy to insert a debug trace!
 629
 630 tc_sub1 mb_fun act_sty act_ty exp_ib exp_sty exp_ty
 631   | Just exp_ty' <- tcView exp_ty = tc_sub mb_fun act_sty act_ty exp_ib exp_sty exp_ty'
 632 tc_sub1 mb_fun act_sty act_ty exp_ib exp_sty exp_ty
 633   | Just act_ty' <- tcView act_ty = tc_sub mb_fun act_sty act_ty' exp_ib exp_sty exp_ty
 634
 635 -----------------------------------
 636 -- Rule SBOXY, plus other cases when act_ty is a type variable
 637 -- Just defer to boxy matching
 638 -- This rule takes precedence over SKOL!
 639 tc_sub1 mb_fun act_sty (TyVarTy tv) exp_ib exp_sty exp_ty
 640   = do  { addErrCtxtM (subCtxt mb_fun act_sty exp_sty) $
 641           uVar True False tv exp_ib exp_sty exp_ty
 642         ; return idCoercion }
 643
 644 -----------------------------------
 645 -- Skolemisation case (rule SKOL)
 646 --      actual_ty:   d:Eq b => b->b
 647 --      expected_ty: forall a. Ord a => a->a
 648 --      co_fn e      /\a. \d2:Ord a. let d = eqFromOrd d2 in e
 649
 650 -- It is essential to do this *before* the specialisation case
 651 -- Example:  f :: (Eq a => a->a) -> ...
 652 --           g :: Ord b => b->b
 653 -- Consider  f g !
 654
 655 tc_sub1 mb_fun act_sty act_ty exp_ib exp_sty exp_ty
 656   | not exp_ib,         -- SKOL does not apply if exp_ty is inside a box
 657     isSigmaTy exp_ty
 658   = do  { (gen_fn, co_fn) <- tcGen exp_ty act_tvs $ \ body_exp_ty ->
 659                              tc_sub mb_fun act_sty act_ty False body_exp_ty body_exp_ty
 660         ; return (gen_fn <.> co_fn) }
 661   where
 662     act_tvs = tyVarsOfType act_ty
 663                 -- It's really important to check for escape wrt
 664                 -- the free vars of both expected_ty *and* actual_ty
 665
 666 -----------------------------------
 667 -- Specialisation case (rule ASPEC):
 668 --      actual_ty:   forall a. Ord a => a->a
 669 --      expected_ty: Int -> Int
 670 --      co_fn e =    e Int dOrdInt
 671
 672 tc_sub1 mb_fun act_sty actual_ty exp_ib exp_sty expected_ty
 673 -- Implements the new SPEC rule in the Appendix of the paper
 674 -- "Boxy types: inference for higher rank types and impredicativity"
 675 -- (This appendix isn't in the published version.)
 676 -- The idea is to *first* do pre-subsumption, and then full subsumption
 677 -- Example:     forall a. a->a  <=  Int -> (forall b. Int)
 678 --   Pre-subsumpion finds a|->Int, and that works fine, whereas
 679 --   just running full subsumption would fail.
 680   | isSigmaTy actual_ty
 681   = do  {       -- Perform pre-subsumption, and instantiate
 682                 -- the type with info from the pre-subsumption;
 683                 -- boxy tyvars if pre-subsumption gives no info
 684           let (tyvars, theta, tau) = tcSplitSigmaTy actual_ty
 685               tau_tvs = exactTyVarsOfType tau
 686         ; inst_tys <- if exp_ib then    -- Inside a box, do not do clever stuff
 687                         do { tyvars' <- mapM tcInstBoxyTyVar tyvars
 688                            ; return (mkTyVarTys tyvars') }
 689                       else              -- Outside, do clever stuff
 690                         preSubType tyvars tau_tvs tau expected_ty
 691         ; let subst' = zipOpenTvSubst tyvars inst_tys
 692               tau'   = substTy subst' tau
 693
 694                 -- Perform a full subsumption check
 695         ; traceTc (text "tc_sub_spec" <+> vcat [ppr actual_ty,
 696                                                 ppr tyvars <+> ppr theta <+> ppr tau,
 697                                                 ppr tau'])
 698         ; co_fn <- tc_sub mb_fun tau' tau' exp_ib exp_sty expected_ty
 699
 700                 -- Deal with the dictionaries
 701         ; dicts <- newDicts InstSigOrigin (substTheta subst' theta)
 702         ; extendLIEs dicts
 703         ; let inst_fn = CoApps (CoTyApps CoHole inst_tys)
 704                                (map instToId dicts)
 705         ; return (co_fn <.> inst_fn) }
 706
 707 -----------------------------------
 708 -- Function case (rule F1)
 709 tc_sub1 mb_fun _ (FunTy act_arg act_res) exp_ib _ (FunTy exp_arg exp_res)
 710   = tc_sub_funs mb_fun act_arg act_res exp_ib exp_arg exp_res
 711
 712 -- Function case (rule F2)
 713 tc_sub1 mb_fun act_sty act_ty@(FunTy act_arg act_res) _ exp_sty (TyVarTy exp_tv)
 714   | isBoxyTyVar exp_tv
 715   = do  { cts <- readMetaTyVar exp_tv
 716         ; case cts of
 717             Indirect ty -> tc_sub mb_fun act_sty act_ty True exp_sty ty
 718             Flexi       -> do { [arg_ty,res_ty] <- withMetaTvs exp_tv fun_kinds mk_res_ty
 719                               ; tc_sub_funs mb_fun act_arg act_res True arg_ty res_ty } }
 720  where
 721     mk_res_ty [arg_ty', res_ty'] = mkFunTy arg_ty' res_ty'
 722     mk_res_ty other = panic "TcUnify.mk_res_ty3"
 723     fun_kinds = [argTypeKind, openTypeKind]
 724
 725 -- Everything else: defer to boxy matching
 726 tc_sub1 mb_fun act_sty actual_ty exp_ib exp_sty expected_ty
 727   = do  { addErrCtxtM (subCtxt mb_fun act_sty exp_sty) $
 728           u_tys True False act_sty actual_ty exp_ib exp_sty expected_ty
 729         ; return idCoercion }
 730
 731
 732 -----------------------------------
 733 tc_sub_funs mb_fun act_arg act_res exp_ib exp_arg exp_res
 734   = do  { uTys False act_arg exp_ib exp_arg
 735         ; co_fn_res <- tc_sub mb_fun act_res act_res exp_ib exp_res exp_res
 736         ; wrapFunResCoercion [exp_arg] co_fn_res }
 737
 738 -----------------------------------
 739 wrapFunResCoercion
 740         :: [TcType]     -- Type of args
 741         -> ExprCoFn     -- HsExpr a -> HsExpr b
 742         -> TcM ExprCoFn -- HsExpr (arg_tys -> a) -> HsExpr (arg_tys -> b)
 743 wrapFunResCoercion arg_tys co_fn_res
 744   | isIdCoercion co_fn_res = return idCoercion
 745   | null arg_tys           = return co_fn_res
 746   | otherwise
 747   = do  { us <- newUniqueSupply
 748         ; let arg_ids = zipWith (mkSysLocal FSLIT("sub")) (uniqsFromSupply us) arg_tys
 749         ; return (CoLams arg_ids (co_fn_res <.> (CoApps CoHole arg_ids))) }
 750 \end{code}
 751
 752
 753
 754 %************************************************************************
 755 %*                                                                      *
 756 \subsection{Generalisation}
 757 %*                                                                      *
 758 %************************************************************************
 759
 760 \begin{code}
 761 tcGen :: BoxySigmaType                          -- expected_ty
 762       -> TcTyVarSet                             -- Extra tyvars that the universally
 763                                                 --      quantified tyvars of expected_ty
 764                                                 --      must not be unified
 765       -> (BoxyRhoType -> TcM result)            -- spec_ty
 766       -> TcM (ExprCoFn, result)
 767         -- The expression has type: spec_ty -> expected_ty
 768
 769 tcGen expected_ty extra_tvs thing_inside        -- We expect expected_ty to be a forall-type
 770                                                 -- If not, the call is a no-op
 771   = do  {       -- We want the GenSkol info in the skolemised type variables to
 772                 -- mention the *instantiated* tyvar names, so that we get a
 773                 -- good error message "Rigid variable 'a' is bound by (forall a. a->a)"
 774                 -- Hence the tiresome but innocuous fixM
 775           ((forall_tvs, theta, rho_ty), skol_info) <- fixM (\ ~(_, skol_info) ->
 776                 do { (forall_tvs, theta, rho_ty) <- tcInstSkolType skol_info expected_ty
 777                    ; span <- getSrcSpanM
 778                    ; let skol_info = GenSkol forall_tvs (mkPhiTy theta rho_ty) span
 779                    ; return ((forall_tvs, theta, rho_ty), skol_info) })
 780
 781 #ifdef DEBUG
 782         ; traceTc (text "tcGen" <+> vcat [text "extra_tvs" <+> ppr extra_tvs,
 783                                     text "expected_ty" <+> ppr expected_ty,
 784                                     text "inst ty" <+> ppr forall_tvs <+> ppr theta <+> ppr rho_ty,
 785                                     text "free_tvs" <+> ppr free_tvs,
 786                                     text "forall_tvs" <+> ppr forall_tvs])
 787 #endif
 788
 789         -- Type-check the arg and unify with poly type
 790         ; (result, lie) <- getLIE (thing_inside rho_ty)
 791
 792         -- Check that the "forall_tvs" havn't been constrained
 793         -- The interesting bit here is that we must include the free variables
 794         -- of the expected_ty.  Here's an example:
 795         --       runST (newVar True)
 796         -- Here, if we don't make a check, we'll get a type (ST s (MutVar s Bool))
 797         -- for (newVar True), with s fresh.  Then we unify with the runST's arg type
 798         -- forall s'. ST s' a. That unifies s' with s, and a with MutVar s Bool.
 799         -- So now s' isn't unconstrained because it's linked to a.
 800         -- Conclusion: include the free vars of the expected_ty in the
 801         -- list of "free vars" for the signature check.
 802
 803         ; dicts <- newDicts (SigOrigin skol_info) theta
 804         ; inst_binds <- tcSimplifyCheck sig_msg forall_tvs dicts lie
 805
 806         ; checkSigTyVarsWrt free_tvs forall_tvs
 807         ; traceTc (text "tcGen:done")
 808
 809         ; let
 810             -- This HsLet binds any Insts which came out of the simplification.
 811             -- It's a bit out of place here, but using AbsBind involves inventing
 812             -- a couple of new names which seems worse.
 813                 dict_ids   = map instToId dicts
 814                 co_fn = CoTyLams forall_tvs $ CoLams dict_ids $ CoLet inst_binds CoHole
 815         ; returnM (co_fn, result) }
 816   where
 817     free_tvs = tyVarsOfType expected_ty `unionVarSet` extra_tvs
 818     sig_msg  = ptext SLIT("expected type of an expression")
 819 \end{code}
 820
 821
 822
 823 %************************************************************************
 824 %*                                                                      *
 825                 Boxy unification
 826 %*                                                                      *
 827 %************************************************************************
 828
 829 The exported functions are all defined as versions of some
 830 non-exported generic functions.
 831
 832 \begin{code}
 833 boxyUnify :: BoxyType -> BoxyType -> TcM ()
 834 -- Acutal and expected, respectively
 835 boxyUnify ty1 ty2
 836   = addErrCtxtM (unifyCtxt ty1 ty2) $
 837     uTysOuter False ty1 False ty2
 838
 839 ---------------
 840 boxyUnifyList :: [BoxyType] -> [BoxyType] -> TcM ()
 841 -- Arguments should have equal length
 842 -- Acutal and expected types
 843 boxyUnifyList tys1 tys2 = uList boxyUnify tys1 tys2
 844
 845 ---------------
 846 unifyType :: TcTauType -> TcTauType -> TcM ()
 847 -- No boxes expected inside these types
 848 -- Acutal and expected types
 849 unifyType ty1 ty2       -- ty1 expected, ty2 inferred
 850   = ASSERT2( not (isBoxyTy ty1), ppr ty1 )
 851     ASSERT2( not (isBoxyTy ty2), ppr ty2 )
 852     addErrCtxtM (unifyCtxt ty1 ty2) $
 853     uTysOuter True ty1 True ty2
 854
 855 ---------------
 856 unifyPred :: PredType -> PredType -> TcM ()
 857 -- Acutal and expected types
 858 unifyPred p1 p2 = addErrCtxtM (unifyCtxt (mkPredTy p1) (mkPredTy p2)) $
 859                   uPred True True p1 True p2
 860
 861 unifyTheta :: TcThetaType -> TcThetaType -> TcM ()
 862 -- Acutal and expected types
 863 unifyTheta theta1 theta2
 864   = do  { checkTc (equalLength theta1 theta2)
 865                   (ptext SLIT("Contexts differ in length"))
 866         ; uList unifyPred theta1 theta2 }
 867
 868 ---------------
 869 uList :: (a -> a -> TcM ())
 870        -> [a] -> [a] -> TcM ()
 871 -- Unify corresponding elements of two lists of types, which
 872 -- should be f equal length.  We charge down the list explicitly so that
 873 -- we can complain if their lengths differ.
 874 uList unify []         []         = return ()
 875 uList unify (ty1:tys1) (ty2:tys2) = do { unify ty1 ty2; uList unify tys1 tys2 }
 876 uList unify ty1s ty2s = panic "Unify.uList: mismatched type lists!"
 877 \end{code}
 878
 879 @unifyTypeList@ takes a single list of @TauType@s and unifies them
 880 all together.  It is used, for example, when typechecking explicit
 881 lists, when all the elts should be of the same type.
 882
 883 \begin{code}
 884 unifyTypeList :: [TcTauType] -> TcM ()
 885 unifyTypeList []                 = returnM ()
 886 unifyTypeList [ty]               = returnM ()
 887 unifyTypeList (ty1:tys@(ty2:_)) = do { unifyType ty1 ty2
 888                                       ; unifyTypeList tys }
 889 \end{code}
 890
 891 %************************************************************************
 892 %*                                                                      *
 893 \subsection[Unify-uTys]{@uTys@: getting down to business}
 894 %*                                                                      *
 895 %************************************************************************
 896
 897 @uTys@ is the heart of the unifier.  Each arg happens twice, because
 898 we want to report errors in terms of synomyms if poss.  The first of
 899 the pair is used in error messages only; it is always the same as the
 900 second, except that if the first is a synonym then the second may be a
 901 de-synonym'd version.  This way we get better error messages.
 902
 903 We call the first one \tr{ps_ty1}, \tr{ps_ty2} for ``possible synomym''.
 904
 905 \begin{code}
 906 type InBox = Bool       -- True  <=> we are inside a box
 907                         -- False <=> we are outside a box
 908         -- The importance of this is that if we get "filled-box meets
 909         -- filled-box", we'll look into the boxes and unify... but
 910         -- we must not allow polytypes.  But if we are in a box on
 911         -- just one side, then we can allow polytypes
 912
 913 type Outer = Bool       -- True <=> this is the outer level of a unification
 914                         --          so that the types being unified are the
 915                         --          very ones we began with, not some sub
 916                         --          component or synonym expansion
 917 -- The idea is that if Outer is true then unifyMisMatch should
 918 -- pop the context to remove the "Expected/Acutal" context
 919
 920 uTysOuter, uTys
 921      :: InBox -> TcType -- ty1 is the *expected* type
 922      -> InBox -> TcType -- ty2 is the *actual* type
 923      -> TcM ()
 924 uTysOuter nb1 ty1 nb2 ty2 = u_tys True nb1 ty1 ty1 nb2 ty2 ty2
 925 uTys      nb1 ty1 nb2 ty2 = u_tys False nb1 ty1 ty1 nb2 ty2 ty2
 926
 927
 928 --------------
 929 uTys_s :: InBox -> [TcType]     -- ty1 is the *actual* types
 930        -> InBox -> [TcType]     -- ty2 is the *expected* types
 931        -> TcM ()
 932 uTys_s nb1 []           nb2 []         = returnM ()
 933 uTys_s nb1 (ty1:tys1) nb2 (ty2:tys2) = do { uTys nb1 ty1 nb2 ty2
 934                                           ; uTys_s nb1 tys1 nb2 tys2 }
 935 uTys_s nb1 ty1s nb2 ty2s = panic "Unify.uTys_s: mismatched type lists!"
 936
 937 --------------
 938 u_tys :: Outer
 939       -> InBox -> TcType -> TcType      -- ty1 is the *actual* type
 940       -> InBox -> TcType -> TcType      -- ty2 is the *expected* type
 941       -> TcM ()
 942
 943 u_tys outer nb1 orig_ty1 ty1 nb2 orig_ty2 ty2
 944   = go outer ty1 ty2
 945   where
 946
 947         -- Always expand synonyms (see notes at end)
 948         -- (this also throws away FTVs)
 949     go outer ty1 ty2
 950       | Just ty1' <- tcView ty1 = go False ty1' ty2
 951       | Just ty2' <- tcView ty2 = go False ty1 ty2'
 952
 953         -- Variables; go for uVar
 954     go outer (TyVarTy tyvar1) ty2 = uVar outer False tyvar1 nb2 orig_ty2 ty2
 955     go outer ty1 (TyVarTy tyvar2) = uVar outer True  tyvar2 nb1 orig_ty1 ty1
 956                                 -- "True" means args swapped
 957         -- Predicates
 958     go outer (PredTy p1) (PredTy p2) = uPred outer nb1 p1 nb2 p2
 959
 960         -- Type constructors must match
 961     go _ (TyConApp con1 tys1) (TyConApp con2 tys2)
 962       | con1 == con2 = uTys_s nb1 tys1 nb2 tys2
 963         -- See Note [TyCon app]
 964
 965         -- Functions; just check the two parts
 966     go _ (FunTy fun1 arg1) (FunTy fun2 arg2)
 967       = do { uTys nb1 fun1 nb2 fun2
 968            ; uTys nb1 arg1 nb2 arg2 }
 969
 970         -- Applications need a bit of care!
 971         -- They can match FunTy and TyConApp, so use splitAppTy_maybe
 972         -- NB: we've already dealt with type variables and Notes,
 973         -- so if one type is an App the other one jolly well better be too
 974     go outer (AppTy s1 t1) ty2
 975       | Just (s2,t2) <- tcSplitAppTy_maybe ty2
 976       = do { uTys nb1 s1 nb2 s2; uTys nb1 t1 nb2 t2 }
 977
 978         -- Now the same, but the other way round
 979         -- Don't swap the types, because the error messages get worse
 980     go outer ty1 (AppTy s2 t2)
 981       | Just (s1,t1) <- tcSplitAppTy_maybe ty1
 982       = do { uTys nb1 s1 nb2 s2; uTys nb1 t1 nb2 t2 }
 983
 984     go _ ty1@(ForAllTy _ _) ty2@(ForAllTy _ _)
 985       | length tvs1 == length tvs2
 986       = do   { tvs <- tcInstSkolTyVars UnkSkol tvs1     -- Not a helpful SkolemInfo
 987              ; let tys      = mkTyVarTys tvs
 988                    in_scope = mkInScopeSet (mkVarSet tvs)
 989                    subst1   = mkTvSubst in_scope (zipTyEnv tvs1 tys)
 990                    subst2   = mkTvSubst in_scope (zipTyEnv tvs2 tys)
 991              ; uTys nb1 (substTy subst1 body1) nb2 (substTy subst2 body2)
 992
 993                 -- If both sides are inside a box, we are in a "box-meets-box"
 994                 -- situation, and we should not have a polytype at all.
 995                 -- If we get here we have two boxes, already filled with
 996                 -- the same polytype... but it should be a monotype.
 997                 -- This check comes last, because the error message is
 998                 -- extremely unhelpful.
 999              ; ifM (nb1 && nb2) (notMonoType ty1)
1000              }
1001       where
1002         (tvs1, body1) = tcSplitForAllTys ty1
1003         (tvs2, body2) = tcSplitForAllTys ty2
1004
1005         -- Anything else fails
1006     go outer _ _ = unifyMisMatch outer False orig_ty1 orig_ty2
1007
1008 ----------
1009 uPred outer nb1 (IParam n1 t1) nb2 (IParam n2 t2)
1010   | n1 == n2 = uTys nb1 t1 nb2 t2
1011 uPred outer nb1 (ClassP c1 tys1) nb2 (ClassP c2 tys2)
1012   | c1 == c2 = uTys_s nb1 tys1 nb2 tys2         -- Guaranteed equal lengths because the kinds check
1013 uPred outer _ p1 _ p2 = unifyMisMatch outer False (mkPredTy p1) (mkPredTy p2)
1014 \end{code}
1015
1016 Note [Tycon app]
1017 ~~~~~~~~~~~~~~~~
1018 When we find two TyConApps, the argument lists are guaranteed equal
1019 length.  Reason: intially the kinds of the two types to be unified is
1020 the same. The only way it can become not the same is when unifying two
1021 AppTys (f1 a1):=:(f2 a2).  In that case there can't be a TyConApp in
1022 the f1,f2 (because it'd absorb the app).  If we unify f1:=:f2 first,
1023 which we do, that ensures that f1,f2 have the same kind; and that
1024 means a1,a2 have the same kind.  And now the argument repeats.
1025
1026
1027 Notes on synonyms
1028 ~~~~~~~~~~~~~~~~~
1029 If you are tempted to make a short cut on synonyms, as in this
1030 pseudocode...
1031
1032 \begin{verbatim}
1033 -- NO   uTys (SynTy con1 args1 ty1) (SynTy con2 args2 ty2)
1034 -- NO     = if (con1 == con2) then
1035 -- NO   -- Good news!  Same synonym constructors, so we can shortcut
1036 -- NO   -- by unifying their arguments and ignoring their expansions.
1037 -- NO   unifyTypepeLists args1 args2
1038 -- NO    else
1039 -- NO   -- Never mind.  Just expand them and try again
1040 -- NO   uTys ty1 ty2
1041 \end{verbatim}
1042
1043 then THINK AGAIN.  Here is the whole story, as detected and reported
1044 by Chris Okasaki \tr{<Chris_Okasaki@loch.mess.cs.cmu.edu>}:
1045 \begin{quotation}
1046 Here's a test program that should detect the problem:
1047
1048 \begin{verbatim}
1049         type Bogus a = Int
1050         x = (1 :: Bogus Char) :: Bogus Bool
1051 \end{verbatim}
1052
1053 The problem with [the attempted shortcut code] is that
1054 \begin{verbatim}
1055         con1 == con2
1056 \end{verbatim}
1057 is not a sufficient condition to be able to use the shortcut!
1058 You also need to know that the type synonym actually USES all
1059 its arguments.  For example, consider the following type synonym
1060 which does not use all its arguments.
1061 \begin{verbatim}
1062         type Bogus a = Int
1063 \end{verbatim}
1064
1065 If you ever tried unifying, say, \tr{Bogus Char} with \tr{Bogus Bool},
1066 the unifier would blithely try to unify \tr{Char} with \tr{Bool} and
1067 would fail, even though the expanded forms (both \tr{Int}) should
1068 match.
1069
1070 Similarly, unifying \tr{Bogus Char} with \tr{Bogus t} would
1071 unnecessarily bind \tr{t} to \tr{Char}.
1072
1073 ... You could explicitly test for the problem synonyms and mark them
1074 somehow as needing expansion, perhaps also issuing a warning to the
1075 user.
1076 \end{quotation}
1077
1078
1079 %************************************************************************
1080 %*                                                                      *
1081 \subsection[Unify-uVar]{@uVar@: unifying with a type variable}
1082 %*                                                                      *
1083 %************************************************************************
1084
1085 @uVar@ is called when at least one of the types being unified is a
1086 variable.  It does {\em not} assume that the variable is a fixed point
1087 of the substitution; rather, notice that @uVar@ (defined below) nips
1088 back into @uTys@ if it turns out that the variable is already bound.
1089
1090 \begin{code}
1091 uVar :: Outer
1092      -> Bool            -- False => tyvar is the "expected"
1093                         -- True  => ty    is the "expected" thing
1094      -> TcTyVar
1095      -> InBox           -- True <=> definitely no boxes in t2
1096      -> TcTauType -> TcTauType  -- printing and real versions
1097      -> TcM ()
1098
1099 uVar outer swapped tv1 nb2 ps_ty2 ty2
1100   = do  { let expansion | showSDoc (ppr ty2) == showSDoc (ppr ps_ty2) = empty
1101                         | otherwise = brackets (equals <+> ppr ty2)
1102         ; traceTc (text "uVar" <+> ppr swapped <+>
1103                         sep [ppr tv1 <+> dcolon <+> ppr (tyVarKind tv1 ),
1104                                 nest 2 (ptext SLIT(" :=: ")),
1105                              ppr ps_ty2 <+> dcolon <+> ppr (typeKind ty2) <+> expansion])
1106         ; details <- lookupTcTyVar tv1
1107         ; case details of
1108             IndirectTv ty1
1109                 | swapped   -> u_tys outer nb2  ps_ty2 ty2 True ty1    ty1      -- Swap back
1110                 | otherwise -> u_tys outer True ty1    ty1 nb2  ps_ty2 ty2      -- Same order
1111                         -- The 'True' here says that ty1 is now inside a box
1112             DoneTv details1 -> uUnfilledVar outer swapped tv1 details1 ps_ty2 ty2
1113         }
1114
1115 ----------------
1116 uUnfilledVar :: Outer
1117              -> Bool                            -- Args are swapped
1118              -> TcTyVar -> TcTyVarDetails       -- Tyvar 1
1119              -> TcTauType -> TcTauType          -- Type 2
1120              -> TcM ()
1121 -- Invariant: tyvar 1 is not unified with anything
1122
1123 uUnfilledVar outer swapped tv1 details1 ps_ty2 ty2
1124   | Just ty2' <- tcView ty2
1125   =     -- Expand synonyms; ignore FTVs
1126     uUnfilledVar False swapped tv1 details1 ps_ty2 ty2'
1127
1128 uUnfilledVar outer swapped tv1 details1 ps_ty2 (TyVarTy tv2)
1129   | tv1 == tv2  -- Same type variable => no-op (but watch out for the boxy case)
1130   = case details1 of
1131         MetaTv BoxTv ref1  -- A boxy type variable meets itself;
1132                            -- this is box-meets-box, so fill in with a tau-type
1133               -> do { tau_tv <- tcInstTyVar tv1
1134                     ; updateMeta tv1 ref1 (mkTyVarTy tau_tv) }
1135         other -> returnM ()     -- No-op
1136
1137         -- Distinct type variables
1138   | otherwise
1139   = do  { lookup2 <- lookupTcTyVar tv2
1140         ; case lookup2 of
1141             IndirectTv ty2' -> uUnfilledVar  outer swapped tv1 details1 ty2' ty2'
1142             DoneTv details2 -> uUnfilledVars outer swapped tv1 details1 tv2 details2
1143         }
1144
1145 uUnfilledVar outer swapped tv1 details1 ps_ty2 non_var_ty2      -- ty2 is not a type variable
1146   = case details1 of
1147         MetaTv (SigTv _) ref1 -> mis_match      -- Can't update a skolem with a non-type-variable
1148         MetaTv info ref1      -> uMetaVar swapped tv1 info ref1 ps_ty2 non_var_ty2
1149         skolem_details        -> mis_match
1150   where
1151     mis_match = unifyMisMatch outer swapped (TyVarTy tv1) ps_ty2
1152
1153 ----------------
1154 uMetaVar :: Bool
1155          -> TcTyVar -> BoxInfo -> IORef MetaDetails
1156          -> TcType -> TcType
1157          -> TcM ()
1158 -- tv1 is an un-filled-in meta type variable (maybe boxy, maybe tau)
1159 -- ty2 is not a type variable
1160
1161 uMetaVar swapped tv1 BoxTv ref1 ps_ty2 non_var_ty2
1162   =     -- tv1 is a BoxTv.  So we must unbox ty2, to ensure
1163         -- that any boxes in ty2 are filled with monotypes
1164         --
1165         -- It should not be the case that tv1 occurs in ty2
1166         -- (i.e. no occurs check should be needed), but if perchance
1167         -- it does, the unbox operation will fill it, and the DEBUG
1168         -- checks for that.
1169     do  { final_ty <- unBox ps_ty2
1170 #ifdef DEBUG
1171         ; meta_details <- readMutVar ref1
1172         ; case meta_details of
1173             Indirect ty -> WARN( True, ppr tv1 <+> ppr ty )
1174                            return ()    -- This really should *not* happen
1175             Flexi       -> return ()
1176 #endif
1177         ; checkUpdateMeta swapped tv1 ref1 final_ty }
1178
1179 uMetaVar swapped tv1 info1 ref1 ps_ty2 non_var_ty2
1180   = do  { final_ty <- checkTauTvUpdate tv1 ps_ty2       -- Occurs check + monotype check
1181         ; checkUpdateMeta swapped tv1 ref1 final_ty }
1182
1183 ----------------
1184 uUnfilledVars :: Outer
1185               -> Bool                   -- Args are swapped
1186               -> TcTyVar -> TcTyVarDetails      -- Tyvar 1
1187               -> TcTyVar -> TcTyVarDetails      -- Tyvar 2
1188               -> TcM ()
1189 -- Invarant: The type variables are distinct,
1190 --           Neither is filled in yet
1191 --           They might be boxy or not
1192
1193 uUnfilledVars outer swapped tv1 (SkolemTv _) tv2 (SkolemTv _)
1194   = unifyMisMatch outer swapped (mkTyVarTy tv1) (mkTyVarTy tv2)
1195
1196 uUnfilledVars outer swapped tv1 (MetaTv info1 ref1) tv2 (SkolemTv _)
1197   = checkUpdateMeta swapped tv1 ref1 (mkTyVarTy tv2)
1198 uUnfilledVars outer swapped tv1 (SkolemTv _) tv2 (MetaTv info2 ref2)
1199   = checkUpdateMeta (not swapped) tv2 ref2 (mkTyVarTy tv1)
1200
1201 -- ToDo: this function seems too long for what it acutally does!
1202 uUnfilledVars outer swapped tv1 (MetaTv info1 ref1) tv2 (MetaTv info2 ref2)
1203   = case (info1, info2) of
1204         (BoxTv,   BoxTv)   -> box_meets_box
1205
1206         -- If a box meets a TauTv, but the fomer has the smaller kind
1207         -- then we must create a fresh TauTv with the smaller kind
1208         (_,       BoxTv)   | k1_sub_k2 -> update_tv2
1209                            | otherwise -> box_meets_box
1210         (BoxTv,   _    )   | k2_sub_k1 -> update_tv1
1211                            | otherwise -> box_meets_box
1212
1213         -- Avoid SigTvs if poss
1214         (SigTv _, _      ) | k1_sub_k2 -> update_tv2
1215         (_,       SigTv _) | k2_sub_k1 -> update_tv1
1216
1217         (_,   _) | k1_sub_k2 -> if k2_sub_k1 && nicer_to_update_tv1
1218                                 then update_tv1         -- Same kinds
1219                                 else update_tv2
1220                  | k2_sub_k1 -> update_tv1
1221                  | otherwise -> kind_err
1222
1223         -- Update the variable with least kind info
1224         -- See notes on type inference in Kind.lhs
1225         -- The "nicer to" part only applies if the two kinds are the same,
1226         -- so we can choose which to do.
1227   where
1228         -- Kinds should be guaranteed ok at this point
1229     update_tv1 = updateMeta tv1 ref1 (mkTyVarTy tv2)
1230     update_tv2 = updateMeta tv2 ref2 (mkTyVarTy tv1)
1231
1232     box_meets_box | k1_sub_k2 = if k2_sub_k1 && nicer_to_update_tv1
1233                                 then fill_from tv2
1234                                 else fill_from tv1
1235                   | k2_sub_k1 = fill_from tv2
1236                   | otherwise = kind_err
1237
1238         -- Update *both* tyvars with a TauTv whose name and kind
1239         -- are gotten from tv (avoid losing nice names is poss)
1240     fill_from tv = do { tv' <- tcInstTyVar tv
1241                       ; let tau_ty = mkTyVarTy tv'
1242                       ; updateMeta tv1 ref1 tau_ty
1243                       ; updateMeta tv2 ref2 tau_ty }
1244
1245     kind_err = addErrCtxtM (unifyKindCtxt swapped tv1 (mkTyVarTy tv2))  $
1246                unifyKindMisMatch k1 k2
1247
1248     k1 = tyVarKind tv1
1249     k2 = tyVarKind tv2
1250     k1_sub_k2 = k1 `isSubKind` k2
1251     k2_sub_k1 = k2 `isSubKind` k1
1252
1253     nicer_to_update_tv1 = isSystemName (varName tv1)
1254         -- Try to update sys-y type variables in preference to ones
1255         -- gotten (say) by instantiating a polymorphic function with
1256         -- a user-written type sig
1257
1258 ----------------
1259 checkUpdateMeta :: Bool -> TcTyVar -> IORef MetaDetails -> TcType -> TcM ()
1260 -- Update tv1, which is flexi; occurs check is alrady done
1261 -- The 'check' version does a kind check too
1262 -- We do a sub-kind check here: we might unify (a b) with (c d)
1263 --      where b::*->* and d::*; this should fail
1264
1265 checkUpdateMeta swapped tv1 ref1 ty2
1266   = do  { checkKinds swapped tv1 ty2
1267         ; updateMeta tv1 ref1 ty2 }
1268
1269 updateMeta :: TcTyVar -> IORef MetaDetails -> TcType -> TcM ()
1270 updateMeta tv1 ref1 ty2
1271   = ASSERT( isMetaTyVar tv1 )
1272     ASSERT( isBoxyTyVar tv1 || isTauTy ty2 )
1273     do  { ASSERTM2( do { details <- readMetaTyVar tv1; return (isFlexi details) }, ppr tv1 )
1274         ; traceTc (text "updateMeta" <+> ppr tv1 <+> text ":=" <+> ppr ty2)
1275         ; writeMutVar ref1 (Indirect ty2) }
1276
1277 ----------------
1278 checkKinds swapped tv1 ty2
1279 -- We're about to unify a type variable tv1 with a non-tyvar-type ty2.
1280 -- ty2 has been zonked at this stage, which ensures that
1281 -- its kind has as much boxity information visible as possible.
1282   | tk2 `isSubKind` tk1 = returnM ()
1283
1284   | otherwise
1285         -- Either the kinds aren't compatible
1286         --      (can happen if we unify (a b) with (c d))
1287         -- or we are unifying a lifted type variable with an
1288         --      unlifted type: e.g.  (id 3#) is illegal
1289   = addErrCtxtM (unifyKindCtxt swapped tv1 ty2) $
1290     unifyKindMisMatch k1 k2
1291   where
1292     (k1,k2) | swapped   = (tk2,tk1)
1293             | otherwise = (tk1,tk2)
1294     tk1 = tyVarKind tv1
1295     tk2 = typeKind ty2
1296
1297 ----------------
1298 checkTauTvUpdate :: TcTyVar -> TcType -> TcM TcType
1299 --    (checkTauTvUpdate tv ty)
1300 -- We are about to update the TauTv tv with ty.
1301 -- Check (a) that tv doesn't occur in ty (occurs check)
1302 --       (b) that ty is a monotype
1303 -- Furthermore, in the interest of (b), if you find an
1304 -- empty box (BoxTv that is Flexi), fill it in with a TauTv
1305 --
1306 -- Returns the (non-boxy) type to update the type variable with, or fails
1307
1308 checkTauTvUpdate orig_tv orig_ty
1309   = go orig_ty
1310   where
1311     go (TyConApp tc tys)
1312         | isSynTyCon tc  = go_syn tc tys
1313         | otherwise      = do { tys' <- mappM go tys; return (TyConApp tc tys') }
1314     go (NoteTy _ ty2)    = go ty2       -- Discard free-tyvar annotations
1315     go (PredTy p)        = do { p' <- go_pred p; return (PredTy p') }
1316     go (FunTy arg res)   = do { arg' <- go arg; res' <- go res; return (FunTy arg' res') }
1317     go (AppTy fun arg)   = do { fun' <- go fun; arg' <- go arg; return (mkAppTy fun' arg') }
1318                 -- NB the mkAppTy; we might have instantiated a
1319                 -- type variable to a type constructor, so we need
1320                 -- to pull the TyConApp to the top.
1321     go (ForAllTy tv ty) = notMonoType orig_ty           -- (b)
1322
1323     go (TyVarTy tv)
1324         | orig_tv == tv = occurCheck tv orig_ty         -- (a)
1325         | isTcTyVar tv  = go_tyvar tv (tcTyVarDetails tv)
1326         | otherwise     = return (TyVarTy tv)
1327                  -- Ordinary (non Tc) tyvars
1328                  -- occur inside quantified types
1329
1330     go_pred (ClassP c tys) = do { tys' <- mapM go tys; return (ClassP c tys') }
1331     go_pred (IParam n ty)  = do { ty' <- go ty;        return (IParam n ty') }
1332
1333     go_tyvar tv (SkolemTv _) = return (TyVarTy tv)
1334     go_tyvar tv (MetaTv box ref)
1335         = do { cts <- readMutVar ref
1336              ; case cts of
1337                   Indirect ty -> go ty
1338                   Flexi -> case box of
1339                                 BoxTv -> fillBoxWithTau tv ref
1340                                 other -> return (TyVarTy tv)
1341              }
1342
1343         -- go_syn is called for synonyms only
1344         -- See Note [Type synonyms and the occur check]
1345     go_syn tc tys
1346         | not (isTauTyCon tc)
1347         = notMonoType orig_ty   -- (b) again
1348         | otherwise
1349         = do { (msgs, mb_tys') <- tryTc (mapM go tys)
1350              ; case mb_tys' of
1351                 Just tys' -> return (TyConApp tc tys')
1352                                 -- Retain the synonym (the common case)
1353                 Nothing   -> go (expectJust "checkTauTvUpdate"
1354                                         (tcView (TyConApp tc tys)))
1355                                 -- Try again, expanding the synonym
1356              }
1357
1358 fillBoxWithTau :: BoxyTyVar -> IORef MetaDetails -> TcM TcType
1359 -- (fillBoxWithTau tv ref) fills ref with a freshly allocated
1360 --  tau-type meta-variable, whose print-name is the same as tv
1361 -- Choosing the same name is good: when we instantiate a function
1362 -- we allocate boxy tyvars with the same print-name as the quantified
1363 -- tyvar; and then we often fill the box with a tau-tyvar, and again
1364 -- we want to choose the same name.
1365 fillBoxWithTau tv ref
1366   = do  { tv' <- tcInstTyVar tv         -- Do not gratuitously forget
1367         ; let tau = mkTyVarTy tv'       -- name of the type variable
1368         ; writeMutVar ref (Indirect tau)
1369         ; return tau }
1370 \end{code}
1371
1372 Note [Type synonyms and the occur check]
1373 ~~~~~~~~~~~~~~~~~~~~
1374 Basically we want to update     tv1 := ps_ty2
1375 because ps_ty2 has type-synonym info, which improves later error messages
1376
1377 But consider
1378         type A a = ()
1379
1380         f :: (A a -> a -> ()) -> ()
1381         f = \ _ -> ()
1382
1383         x :: ()
1384         x = f (\ x p -> p x)
1385
1386 In the application (p x), we try to match "t" with "A t".  If we go
1387 ahead and bind t to A t (= ps_ty2), we'll lead the type checker into
1388 an infinite loop later.
1389 But we should not reject the program, because A t = ().
1390 Rather, we should bind t to () (= non_var_ty2).
1391
1392 \begin{code}
1393 stripBoxyType :: BoxyType -> TcM TcType
1394 -- Strip all boxes from the input type, returning a non-boxy type.
1395 -- It's fine for there to be a polytype inside a box (c.f. unBox)
1396 -- All of the boxes should have been filled in by now;
1397 -- hence we return a TcType
1398 stripBoxyType ty = zonkType strip_tv ty
1399   where
1400     strip_tv tv = ASSERT( not (isBoxyTyVar tv) ) return (TyVarTy tv)
1401         -- strip_tv will be called for *Flexi* meta-tyvars
1402         -- There should not be any Boxy ones; hence the ASSERT
1403
1404 zapToMonotype :: BoxySigmaType -> TcM TcTauType
1405 -- Subtle... we must zap the boxy res_ty
1406 -- to kind * before using it to instantiate a LitInst
1407 -- Calling unBox instead doesn't do the job, because the box
1408 -- often has an openTypeKind, and we don't want to instantiate
1409 -- with that type.
1410 zapToMonotype res_ty
1411   = do  { res_tau <- newFlexiTyVarTy liftedTypeKind
1412         ; boxyUnify res_tau res_ty
1413         ; return res_tau }
1414
1415 unBox :: BoxyType -> TcM TcType
1416 -- unBox implements the judgement
1417 --      |- s' ~ box(s)
1418 -- with input s', and result s
1419 --
1420 -- It removes all boxes from the input type, returning a non-boxy type.
1421 -- A filled box in the type can only contain a monotype; unBox fails if not
1422 -- The type can have empty boxes, which unBox fills with a monotype
1423 --
1424 -- Compare this wth checkTauTvUpdate
1425 --
1426 -- For once, it's safe to treat synonyms as opaque!
1427
1428 unBox (NoteTy n ty)     = do { ty' <- unBox ty; return (NoteTy n ty') }
1429 unBox (TyConApp tc tys) = do { tys' <- mapM unBox tys; return (TyConApp tc tys') }
1430 unBox (AppTy f a)       = do { f' <- unBox f; a' <- unBox a; return (mkAppTy f' a') }
1431 unBox (FunTy f a)       = do { f' <- unBox f; a' <- unBox a; return (FunTy f' a') }
1432 unBox (PredTy p)        = do { p' <- unBoxPred p; return (PredTy p') }
1433 unBox (ForAllTy tv ty)  = ASSERT( isImmutableTyVar tv )
1434                           do { ty' <- unBox ty; return (ForAllTy tv ty') }
1435 unBox (TyVarTy tv)
1436   | isTcTyVar tv                                -- It's a boxy type variable
1437   , MetaTv BoxTv ref <- tcTyVarDetails tv       -- NB: non-TcTyVars are possible
1438   = do  { cts <- readMutVar ref                 --     under nested quantifiers
1439         ; case cts of
1440             Flexi       -> fillBoxWithTau tv ref
1441             Indirect ty -> do { non_boxy_ty <- unBox ty
1442                               ; if isTauTy non_boxy_ty
1443                                 then return non_boxy_ty
1444                                 else notMonoType non_boxy_ty }
1445         }
1446   | otherwise   -- Skolems, and meta-tau-variables
1447   = return (TyVarTy tv)
1448
1449 unBoxPred (ClassP cls tys) = do { tys' <- mapM unBox tys; return (ClassP cls tys') }
1450 unBoxPred (IParam ip ty)   = do { ty' <- unBox ty; return (IParam ip ty') }
1451 \end{code}
1452
1453
1454
1455 %************************************************************************
1456 %*                                                                      *
1457 \subsection[Unify-context]{Errors and contexts}
1458 %*                                                                      *
1459 %************************************************************************
1460
1461 Errors
1462 ~~~~~~
1463
1464 \begin{code}
1465 unifyCtxt act_ty exp_ty tidy_env
1466   = do  { act_ty' <- zonkTcType act_ty
1467         ; exp_ty' <- zonkTcType exp_ty
1468         ; let (env1, exp_ty'') = tidyOpenType tidy_env exp_ty'
1469               (env2, act_ty'') = tidyOpenType env1     act_ty'
1470         ; return (env2, mkExpectedActualMsg act_ty'' exp_ty'') }
1471
1472 ----------------
1473 mkExpectedActualMsg act_ty exp_ty
1474   = nest 2 (vcat [ text "Expected type" <> colon <+> ppr exp_ty,
1475                    text "Inferred type" <> colon <+> ppr act_ty ])
1476
1477 ----------------
1478 -- If an error happens we try to figure out whether the function
1479 -- function has been given too many or too few arguments, and say so.
1480 subCtxt mb_fun actual_res_ty expected_res_ty tidy_env
1481   = do  { exp_ty' <- zonkTcType expected_res_ty
1482         ; act_ty' <- zonkTcType actual_res_ty
1483         ; let
1484               (env1, exp_ty'') = tidyOpenType tidy_env exp_ty'
1485               (env2, act_ty'') = tidyOpenType env1     act_ty'
1486               (exp_args, _)    = tcSplitFunTys exp_ty''
1487               (act_args, _)    = tcSplitFunTys act_ty''
1488
1489               len_act_args     = length act_args
1490               len_exp_args     = length exp_args
1491
1492               message = case mb_fun of
1493                           Just fun | len_exp_args < len_act_args -> wrongArgsCtxt "too few"  fun
1494                                    | len_exp_args > len_act_args -> wrongArgsCtxt "too many" fun
1495                           other -> mkExpectedActualMsg act_ty'' exp_ty''
1496         ; return (env2, message) }
1497
1498   where
1499     wrongArgsCtxt too_many_or_few fun
1500       = ptext SLIT("Probable cause:") <+> quotes (ppr fun)
1501         <+> ptext SLIT("is applied to") <+> text too_many_or_few
1502         <+> ptext SLIT("arguments")
1503
1504 ------------------
1505 unifyKindCtxt swapped tv1 ty2 tidy_env  -- not swapped => tv1 expected, ty2 inferred
1506         -- tv1 and ty2 are zonked already
1507   = returnM msg
1508   where
1509     msg = (env2, ptext SLIT("When matching the kinds of") <+>
1510                  sep [quotes pp_expected <+> ptext SLIT("and"), quotes pp_actual])
1511
1512     (pp_expected, pp_actual) | swapped   = (pp2, pp1)
1513                              | otherwise = (pp1, pp2)
1514     (env1, tv1') = tidyOpenTyVar tidy_env tv1
1515     (env2, ty2') = tidyOpenType  env1 ty2
1516     pp1 = ppr tv1' <+> dcolon <+> ppr (tyVarKind tv1)
1517     pp2 = ppr ty2' <+> dcolon <+> ppr (typeKind ty2)
1518
1519 unifyMisMatch outer swapped ty1 ty2
1520   = do  { (env, msg) <- if swapped then misMatchMsg ty1 ty2
1521                                    else misMatchMsg ty2 ty1
1522
1523         -- This is the whole point of the 'outer' stuff
1524         ; if outer then popErrCtxt (failWithTcM (env, msg))
1525                    else failWithTcM (env, msg)
1526         }
1527
1528 misMatchMsg ty1 ty2
1529   = do  { env0 <- tcInitTidyEnv
1530         ; (env1, pp1, extra1) <- ppr_ty env0 ty1
1531         ; (env2, pp2, extra2) <- ppr_ty env1 ty2
1532         ; return (env2, sep [sep [ptext SLIT("Couldn't match expected type") <+> pp1,
1533                                   nest 7 (ptext SLIT("against inferred type") <+> pp2)],
1534                              nest 2 extra1, nest 2 extra2]) }
1535
1536 ppr_ty :: TidyEnv -> TcType -> TcM (TidyEnv, SDoc, SDoc)
1537 ppr_ty env ty
1538   = do { ty' <- zonkTcType ty
1539        ; let (env1,tidy_ty) = tidyOpenType env ty'
1540              simple_result  = (env1, quotes (ppr tidy_ty), empty)
1541        ; case tidy_ty of
1542            TyVarTy tv
1543                 | isSkolemTyVar tv || isSigTyVar tv
1544                 -> return (env2, pp_rigid tv', pprSkolTvBinding tv')
1545                 | otherwise -> return simple_result
1546                 where
1547                   (env2, tv') = tidySkolemTyVar env1 tv
1548            other -> return simple_result }
1549   where
1550     pp_rigid tv = quotes (ppr tv) <+> parens (ptext SLIT("a rigid variable"))
1551
1552
1553 notMonoType ty
1554   = do  { ty' <- zonkTcType ty
1555         ; env0 <- tcInitTidyEnv
1556         ; let (env1, tidy_ty) = tidyOpenType env0 ty'
1557               msg = ptext SLIT("Cannot match a monotype with") <+> quotes (ppr tidy_ty)
1558         ; failWithTcM (env1, msg) }
1559
1560 occurCheck tyvar ty
1561   = do  { env0 <- tcInitTidyEnv
1562         ; ty'  <- zonkTcType ty
1563         ; let (env1, tidy_tyvar) = tidyOpenTyVar env0 tyvar
1564               (env2, tidy_ty)    = tidyOpenType  env1 ty'
1565               extra = sep [ppr tidy_tyvar, char '=', ppr tidy_ty]
1566         ; failWithTcM (env2, hang msg 2 extra) }
1567   where
1568     msg = ptext SLIT("Occurs check: cannot construct the infinite type:")
1569 \end{code}
1570
1571
1572 %************************************************************************
1573 %*                                                                      *
1574                 Kind unification
1575 %*                                                                      *
1576 %************************************************************************
1577
1578 Unifying kinds is much, much simpler than unifying types.
1579
1580 \begin{code}
1581 unifyKind :: TcKind                 -- Expected
1582           -> TcKind                 -- Actual
1583           -> TcM ()
1584 unifyKind LiftedTypeKind   LiftedTypeKind   = returnM ()
1585 unifyKind UnliftedTypeKind UnliftedTypeKind = returnM ()
1586
1587 unifyKind OpenTypeKind k2 | isOpenTypeKind k2 = returnM ()
1588 unifyKind ArgTypeKind  k2 | isArgTypeKind k2    = returnM ()
1589   -- Respect sub-kinding
1590
1591 unifyKind (FunKind a1 r1) (FunKind a2 r2)
1592  = do { unifyKind a2 a1; unifyKind r1 r2 }
1593                 -- Notice the flip in the argument,
1594                 -- so that the sub-kinding works right
1595
1596 unifyKind (KindVar kv1) k2 = uKVar False kv1 k2
1597 unifyKind k1 (KindVar kv2) = uKVar True kv2 k1
1598 unifyKind k1 k2 = unifyKindMisMatch k1 k2
1599
1600 unifyKinds :: [TcKind] -> [TcKind] -> TcM ()
1601 unifyKinds []       []       = returnM ()
1602 unifyKinds (k1:ks1) (k2:ks2) = unifyKind k1 k2  `thenM_`
1603                                unifyKinds ks1 ks2
1604 unifyKinds _ _               = panic "unifyKinds: length mis-match"
1605
1606 ----------------
1607 uKVar :: Bool -> KindVar -> TcKind -> TcM ()
1608 uKVar swapped kv1 k2
1609   = do  { mb_k1 <- readKindVar kv1
1610         ; case mb_k1 of
1611             Nothing -> uUnboundKVar swapped kv1 k2
1612             Just k1 | swapped   -> unifyKind k2 k1
1613                     | otherwise -> unifyKind k1 k2 }
1614
1615 ----------------
1616 uUnboundKVar :: Bool -> KindVar -> TcKind -> TcM ()
1617 uUnboundKVar swapped kv1 k2@(KindVar kv2)
1618   | kv1 == kv2 = returnM ()
1619   | otherwise   -- Distinct kind variables
1620   = do  { mb_k2 <- readKindVar kv2
1621         ; case mb_k2 of
1622             Just k2 -> uUnboundKVar swapped kv1 k2
1623             Nothing -> writeKindVar kv1 k2 }
1624
1625 uUnboundKVar swapped kv1 non_var_k2
1626   = do  { k2' <- zonkTcKind non_var_k2
1627         ; kindOccurCheck kv1 k2'
1628         ; k2'' <- kindSimpleKind swapped k2'
1629                 -- KindVars must be bound only to simple kinds
1630                 -- Polarities: (kindSimpleKind True ?) succeeds
1631                 -- returning *, corresponding to unifying
1632                 --      expected: ?
1633                 --      actual:   kind-ver
1634         ; writeKindVar kv1 k2'' }
1635
1636 ----------------
1637 kindOccurCheck kv1 k2   -- k2 is zonked
1638   = checkTc (not_in k2) (kindOccurCheckErr kv1 k2)
1639   where
1640     not_in (KindVar kv2)   = kv1 /= kv2
1641     not_in (FunKind a2 r2) = not_in a2 && not_in r2
1642     not_in other           = True
1643
1644 kindSimpleKind :: Bool -> Kind -> TcM SimpleKind
1645 -- (kindSimpleKind True k) returns a simple kind sk such that sk <: k
1646 -- If the flag is False, it requires k <: sk
1647 -- E.g.         kindSimpleKind False ?? = *
1648 -- What about (kv -> *) :=: ?? -> *
1649 kindSimpleKind orig_swapped orig_kind
1650   = go orig_swapped orig_kind
1651   where
1652     go sw (FunKind k1 k2) = do { k1' <- go (not sw) k1
1653                                ; k2' <- go sw k2
1654                                ; return (FunKind k1' k2') }
1655     go True OpenTypeKind = return liftedTypeKind
1656     go True ArgTypeKind  = return liftedTypeKind
1657     go sw LiftedTypeKind  = return liftedTypeKind
1658     go sw UnliftedTypeKind = return unliftedTypeKind
1659     go sw k@(KindVar _)   = return k    -- KindVars are always simple
1660     go swapped kind = failWithTc (ptext SLIT("Unexpected kind unification failure:")
1661                                   <+> ppr orig_swapped <+> ppr orig_kind)
1662         -- I think this can't actually happen
1663
1664 -- T v = MkT v           v must be a type
1665 -- T v w = MkT (v -> w)  v must not be an umboxed tuple
1666
1667 ----------------
1668 kindOccurCheckErr tyvar ty
1669   = hang (ptext SLIT("Occurs check: cannot construct the infinite kind:"))
1670        2 (sep [ppr tyvar, char '=', ppr ty])
1671
1672 unifyKindMisMatch ty1 ty2
1673   = zonkTcKind ty1      `thenM` \ ty1' ->
1674     zonkTcKind ty2      `thenM` \ ty2' ->
1675     let
1676         msg = hang (ptext SLIT("Couldn't match kind"))
1677                    2 (sep [quotes (ppr ty1'),
1678                            ptext SLIT("against"),
1679                            quotes (ppr ty2')])
1680     in
1681     failWithTc msg
1682 \end{code}
1683
1684 \begin{code}
1685 unifyFunKind :: TcKind -> TcM (Maybe (TcKind, TcKind))
1686 -- Like unifyFunTy, but does not fail; instead just returns Nothing
1687
1688 unifyFunKind (KindVar kvar)
1689   = readKindVar kvar    `thenM` \ maybe_kind ->
1690     case maybe_kind of
1691         Just fun_kind -> unifyFunKind fun_kind
1692         Nothing       -> do { arg_kind <- newKindVar
1693                             ; res_kind <- newKindVar
1694                             ; writeKindVar kvar (mkArrowKind arg_kind res_kind)
1695                             ; returnM (Just (arg_kind,res_kind)) }
1696
1697 unifyFunKind (FunKind arg_kind res_kind) = returnM (Just (arg_kind,res_kind))
1698 unifyFunKind other                       = returnM Nothing
1699 \end{code}
1700
1701 %************************************************************************
1702 %*                                                                      *
1703         Checking kinds
1704 %*                                                                      *
1705 %************************************************************************
1706
1707 ---------------------------
1708 -- We would like to get a decent error message from
1709 --   (a) Under-applied type constructors
1710 --              f :: (Maybe, Maybe)
1711 --   (b) Over-applied type constructors
1712 --              f :: Int x -> Int x
1713 --
1714
1715 \begin{code}
1716 checkExpectedKind :: Outputable a => a -> TcKind -> TcKind -> TcM ()
1717 -- A fancy wrapper for 'unifyKind', which tries
1718 -- to give decent error messages.
1719 checkExpectedKind ty act_kind exp_kind
1720   | act_kind `isSubKind` exp_kind -- Short cut for a very common case
1721   = returnM ()
1722   | otherwise
1723   = tryTc (unifyKind exp_kind act_kind) `thenM` \ (_errs, mb_r) ->
1724     case mb_r of {
1725         Just r  -> returnM () ; -- Unification succeeded
1726         Nothing ->
1727
1728         -- So there's definitely an error
1729         -- Now to find out what sort
1730     zonkTcKind exp_kind         `thenM` \ exp_kind ->
1731     zonkTcKind act_kind         `thenM` \ act_kind ->
1732
1733     tcInitTidyEnv               `thenM` \ env0 ->
1734     let (exp_as, _) = splitKindFunTys exp_kind
1735         (act_as, _) = splitKindFunTys act_kind
1736         n_exp_as = length exp_as
1737         n_act_as = length act_as
1738
1739         (env1, tidy_exp_kind) = tidyKind env0 exp_kind
1740         (env2, tidy_act_kind) = tidyKind env1 act_kind
1741
1742         err | n_exp_as < n_act_as       -- E.g. [Maybe]
1743             = quotes (ppr ty) <+> ptext SLIT("is not applied to enough type arguments")
1744
1745                 -- Now n_exp_as >= n_act_as. In the next two cases,
1746                 -- n_exp_as == 0, and hence so is n_act_as
1747             | isLiftedTypeKind exp_kind && isUnliftedTypeKind act_kind
1748             = ptext SLIT("Expecting a lifted type, but") <+> quotes (ppr ty)
1749                 <+> ptext SLIT("is unlifted")
1750
1751             | isUnliftedTypeKind exp_kind && isLiftedTypeKind act_kind
1752             = ptext SLIT("Expecting an unlifted type, but") <+> quotes (ppr ty)
1753                 <+> ptext SLIT("is lifted")
1754
1755             | otherwise                 -- E.g. Monad [Int]
1756             = ptext SLIT("Kind mis-match")
1757
1758         more_info = sep [ ptext SLIT("Expected kind") <+>
1759                                 quotes (pprKind tidy_exp_kind) <> comma,
1760                           ptext SLIT("but") <+> quotes (ppr ty) <+>
1761                                 ptext SLIT("has kind") <+> quotes (pprKind tidy_act_kind)]
1762    in
1763    failWithTcM (env2, err $$ more_info)
1764    }
1765 \end{code}
1766
1767 %************************************************************************
1768 %*                                                                      *
1769 \subsection{Checking signature type variables}
1770 %*                                                                      *
1771 %************************************************************************
1772
1773 @checkSigTyVars@ checks that a set of universally quantified type varaibles
1774 are not mentioned in the environment.  In particular:
1775
1776         (a) Not mentioned in the type of a variable in the envt
1777                 eg the signature for f in this:
1778
1779                         g x = ... where
1780                                         f :: a->[a]
1781                                         f y = [x,y]
1782
1783                 Here, f is forced to be monorphic by the free occurence of x.
1784
1785         (d) Not (unified with another type variable that is) in scope.
1786                 eg f x :: (r->r) = (\y->y) :: forall a. a->r
1787             when checking the expression type signature, we find that
1788             even though there is nothing in scope whose type mentions r,
1789             nevertheless the type signature for the expression isn't right.
1790
1791             Another example is in a class or instance declaration:
1792                 class C a where
1793                    op :: forall b. a -> b
1794                    op x = x
1795             Here, b gets unified with a
1796
1797 Before doing this, the substitution is applied to the signature type variable.
1798
1799 \begin{code}
1800 checkSigTyVars :: [TcTyVar] -> TcM ()
1801 checkSigTyVars sig_tvs = check_sig_tyvars emptyVarSet sig_tvs
1802
1803 checkSigTyVarsWrt :: TcTyVarSet -> [TcTyVar] -> TcM ()
1804 -- The extra_tvs can include boxy type variables;
1805 --      e.g. TcMatches.tcCheckExistentialPat
1806 checkSigTyVarsWrt extra_tvs sig_tvs
1807   = do  { extra_tvs' <- zonkTcTyVarsAndFV (varSetElems extra_tvs)
1808         ; check_sig_tyvars extra_tvs' sig_tvs }
1809
1810 check_sig_tyvars
1811         :: TcTyVarSet   -- Global type variables. The universally quantified
1812                         --      tyvars should not mention any of these
1813                         --      Guaranteed already zonked.
1814         -> [TcTyVar]    -- Universally-quantified type variables in the signature
1815                         --      Guaranteed to be skolems
1816         -> TcM ()
1817 check_sig_tyvars extra_tvs []
1818   = returnM ()
1819 check_sig_tyvars extra_tvs sig_tvs
1820   = ASSERT( all isSkolemTyVar sig_tvs )
1821     do  { gbl_tvs <- tcGetGlobalTyVars
1822         ; traceTc (text "check_sig_tyvars" <+> (vcat [text "sig_tys" <+> ppr sig_tvs,
1823                                       text "gbl_tvs" <+> ppr gbl_tvs,
1824                                       text "extra_tvs" <+> ppr extra_tvs]))
1825
1826         ; let env_tvs = gbl_tvs `unionVarSet` extra_tvs
1827         ; ifM (any (`elemVarSet` env_tvs) sig_tvs)
1828               (bleatEscapedTvs env_tvs sig_tvs sig_tvs)
1829         }
1830
1831 bleatEscapedTvs :: TcTyVarSet   -- The global tvs
1832                 -> [TcTyVar]    -- The possibly-escaping type variables
1833                 -> [TcTyVar]    -- The zonked versions thereof
1834                 -> TcM ()
1835 -- Complain about escaping type variables
1836 -- We pass a list of type variables, at least one of which
1837 -- escapes.  The first list contains the original signature type variable,
1838 -- while the second  contains the type variable it is unified to (usually itself)
1839 bleatEscapedTvs globals sig_tvs zonked_tvs
1840   = do  { env0 <- tcInitTidyEnv
1841         ; let (env1, tidy_tvs)        = tidyOpenTyVars env0 sig_tvs
1842               (env2, tidy_zonked_tvs) = tidyOpenTyVars env1 zonked_tvs
1843
1844         ; (env3, msgs) <- foldlM check (env2, []) (tidy_tvs `zip` tidy_zonked_tvs)
1845         ; failWithTcM (env3, main_msg $$ nest 2 (vcat msgs)) }
1846   where
1847     main_msg = ptext SLIT("Inferred type is less polymorphic than expected")
1848
1849     check (tidy_env, msgs) (sig_tv, zonked_tv)
1850       | not (zonked_tv `elemVarSet` globals) = return (tidy_env, msgs)
1851       | otherwise
1852       = do { (tidy_env1, globs) <- findGlobals (unitVarSet zonked_tv) tidy_env
1853            ; returnM (tidy_env1, escape_msg sig_tv zonked_tv globs : msgs) }
1854
1855 -----------------------
1856 escape_msg sig_tv zonked_tv globs
1857   | notNull globs
1858   = vcat [sep [msg, ptext SLIT("is mentioned in the environment:")],
1859           nest 2 (vcat globs)]
1860   | otherwise
1861   = msg <+> ptext SLIT("escapes")
1862         -- Sigh.  It's really hard to give a good error message
1863         -- all the time.   One bad case is an existential pattern match.
1864         -- We rely on the "When..." context to help.
1865   where
1866     msg = ptext SLIT("Quantified type variable") <+> quotes (ppr sig_tv) <+> is_bound_to
1867     is_bound_to
1868         | sig_tv == zonked_tv = empty
1869         | otherwise = ptext SLIT("is unified with") <+> quotes (ppr zonked_tv) <+> ptext SLIT("which")
1870 \end{code}
1871
1872 These two context are used with checkSigTyVars
1873
1874 \begin{code}
1875 sigCtxt :: Id -> [TcTyVar] -> TcThetaType -> TcTauType
1876         -> TidyEnv -> TcM (TidyEnv, Message)
1877 sigCtxt id sig_tvs sig_theta sig_tau tidy_env
1878   = zonkTcType sig_tau          `thenM` \ actual_tau ->
1879     let
1880         (env1, tidy_sig_tvs)    = tidyOpenTyVars tidy_env sig_tvs
1881         (env2, tidy_sig_rho)    = tidyOpenType env1 (mkPhiTy sig_theta sig_tau)
1882         (env3, tidy_actual_tau) = tidyOpenType env2 actual_tau
1883         sub_msg = vcat [ptext SLIT("Signature type:    ") <+> pprType (mkForAllTys tidy_sig_tvs tidy_sig_rho),
1884                         ptext SLIT("Type to generalise:") <+> pprType tidy_actual_tau
1885                    ]
1886         msg = vcat [ptext SLIT("When trying to generalise the type inferred for") <+> quotes (ppr id),
1887                     nest 2 sub_msg]
1888     in
1889     returnM (env3, msg)
1890 \end{code}