compiler/typecheck/TcUnify.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Type subsumption and unification
   7
   8 \begin{code}
   9 module TcUnify (
  10         -- Full-blown subsumption
  11   tcSubExp, tcFunResTy, tcGen,
  12   checkSigTyVars, checkSigTyVarsWrt, bleatEscapedTvs, sigCtxt,
  13
  14         -- Various unifications
  15   unifyType, unifyTypeList, unifyTheta,
  16   unifyKind, unifyKinds, unifyFunKind,
  17   checkExpectedKind,
  18   preSubType, boxyMatchTypes,
  19
  20   --------------------------------
  21   -- Holes
  22   tcInfer, subFunTys, unBox, refineBox, refineBoxToTau, withBox,
  23   boxyUnify, boxyUnifyList, zapToMonotype,
  24   boxySplitListTy, boxySplitTyConApp, boxySplitAppTy,
  25   wrapFunResCoercion
  26   ) where
  27
  28 #include "HsVersions.h"
  29
  30 import HsSyn
  31 import TypeRep
  32
  33 import TcMType
  34 import TcSimplify
  35 import TcEnv
  36 import TcIface
  37 import TcRnMonad         -- TcType, amongst others
  38 import TcType
  39 import Type
  40 import TysPrim
  41 import Inst
  42 import TyCon
  43 import TysWiredIn
  44 import Var
  45 import VarSet
  46 import VarEnv
  47 import Name
  48 import ErrUtils
  49 import Maybes
  50 import BasicTypes
  51 import Util
  52 import Outputable
  53 \end{code}
  54
  55 %************************************************************************
  56 %*                                                                      *
  57 \subsection{'hole' type variables}
  58 %*                                                                      *
  59 %************************************************************************
  60
  61 \begin{code}
  62 tcInfer :: (BoxyType -> TcM a) -> TcM (a, TcType)
  63 tcInfer tc_infer
  64   = do  { box <- newBoxyTyVar openTypeKind
  65         ; res <- tc_infer (mkTyVarTy box)
  66         ; res_ty <- readFilledBox box   -- Guaranteed filled-in by now
  67         ; return (res, res_ty) }
  68 \end{code}
  69
  70
  71 %************************************************************************
  72 %*                                                                      *
  73         subFunTys
  74 %*                                                                      *
  75 %************************************************************************
  76
  77 \begin{code}
  78 subFunTys :: SDoc  -- Somthing like "The function f has 3 arguments"
  79                    -- or "The abstraction (\x.e) takes 1 argument"
  80           -> Arity              -- Expected # of args
  81           -> BoxyRhoType        -- res_ty
  82           -> ([BoxySigmaType] -> BoxyRhoType -> TcM a)
  83           -> TcM (HsWrapper, a)
  84 -- Attempt to decompse res_ty to have enough top-level arrows to
  85 -- match the number of patterns in the match group
  86 --
  87 -- If (subFunTys n_args res_ty thing_inside) = (co_fn, res)
  88 -- and the inner call to thing_inside passes args: [a1,...,an], b
  89 -- then co_fn :: (a1 -> ... -> an -> b) -> res_ty
  90 --
  91 -- Note that it takes a BoxyRho type, and guarantees to return a BoxyRhoType
  92
  93
  94 {-      Error messages from subFunTys
  95
  96    The abstraction `\Just 1 -> ...' has two arguments
  97    but its type `Maybe a -> a' has only one
  98
  99    The equation(s) for `f' have two arguments
 100    but its type `Maybe a -> a' has only one
 101
 102    The section `(f 3)' requires 'f' to take two arguments
 103    but its type `Int -> Int' has only one
 104
 105    The function 'f' is applied to two arguments
 106    but its type `Int -> Int' has only one
 107 -}
 108
 109
 110 subFunTys error_herald n_pats res_ty thing_inside
 111   = loop n_pats [] res_ty
 112   where
 113         -- In 'loop', the parameter 'arg_tys' accumulates
 114         -- the arg types so far, in *reverse order*
 115     loop n args_so_far res_ty
 116         | Just res_ty' <- tcView res_ty  = loop n args_so_far res_ty'
 117
 118     loop n args_so_far res_ty
 119         | isSigmaTy res_ty      -- Do this before checking n==0, because we
 120                                 -- guarantee to return a BoxyRhoType, not a BoxySigmaType
 121         = do { (gen_fn, (co_fn, res)) <- tcGen res_ty emptyVarSet $ \ _ res_ty' ->
 122                                          loop n args_so_far res_ty'
 123              ; return (gen_fn <.> co_fn, res) }
 124
 125     loop 0 args_so_far res_ty
 126         = do { res <- thing_inside (reverse args_so_far) res_ty
 127              ; return (idHsWrapper, res) }
 128
 129     loop n args_so_far (FunTy arg_ty res_ty)
 130         = do { (co_fn, res) <- loop (n-1) (arg_ty:args_so_far) res_ty
 131              ; co_fn' <- wrapFunResCoercion [arg_ty] co_fn
 132              ; return (co_fn', res) }
 133
 134         -- res_ty might have a type variable at the head, such as (a b c),
 135         -- in which case we must fill in with (->).  Simplest thing to do
 136         -- is to use boxyUnify, but we catch failure and generate our own
 137         -- error message on failure
 138     loop n args_so_far res_ty@(AppTy _ _)
 139         = do { [arg_ty',res_ty'] <- newBoxyTyVarTys [argTypeKind, openTypeKind]
 140              ; (_, mb_unit) <- tryTcErrs $ boxyUnify res_ty (FunTy arg_ty' res_ty')
 141              ; if isNothing mb_unit then bale_out args_so_far
 142                else loop n args_so_far (FunTy arg_ty' res_ty') }
 143
 144     loop n args_so_far (TyVarTy tv)
 145         | not (isImmutableTyVar tv)
 146         = do { cts <- readMetaTyVar tv
 147              ; case cts of
 148                  Indirect ty -> loop n args_so_far ty
 149                  Flexi -> do { (res_ty:arg_tys) <- withMetaTvs tv kinds mk_res_ty
 150                              ; res <- thing_inside (reverse args_so_far ++ arg_tys) res_ty
 151                              ; return (idHsWrapper, res) } }
 152         where
 153           mk_res_ty (res_ty' : arg_tys') = mkFunTys arg_tys' res_ty'
 154           mk_res_ty [] = panic "TcUnify.mk_res_ty1"
 155           kinds = openTypeKind : take n (repeat argTypeKind)
 156                 -- Note argTypeKind: the args can have an unboxed type,
 157                 -- but not an unboxed tuple.
 158
 159     loop n args_so_far res_ty = bale_out args_so_far
 160
 161     bale_out args_so_far
 162         = do { env0 <- tcInitTidyEnv
 163              ; res_ty' <- zonkTcType res_ty
 164              ; let (env1, res_ty'') = tidyOpenType env0 res_ty'
 165              ; failWithTcM (env1, mk_msg res_ty'' (length args_so_far)) }
 166
 167     mk_msg res_ty n_actual
 168       = error_herald <> comma $$
 169         sep [ptext SLIT("but its type") <+> quotes (pprType res_ty),
 170              if n_actual == 0 then ptext SLIT("has none")
 171              else ptext SLIT("has only") <+> speakN n_actual]
 172 \end{code}
 173
 174 \begin{code}
 175 ----------------------
 176 boxySplitTyConApp :: TyCon                      -- T :: k1 -> ... -> kn -> *
 177                   -> BoxyRhoType                -- Expected type (T a b c)
 178                   -> TcM [BoxySigmaType]        -- Element types, a b c
 179   -- It's used for wired-in tycons, so we call checkWiredInTyCOn
 180   -- Precondition: never called with FunTyCon
 181   -- Precondition: input type :: *
 182
 183 boxySplitTyConApp tc orig_ty
 184   = do  { checkWiredInTyCon tc
 185         ; loop (tyConArity tc) [] orig_ty }
 186   where
 187     loop n_req args_so_far ty
 188       | Just ty' <- tcView ty = loop n_req args_so_far ty'
 189
 190     loop n_req args_so_far (TyConApp tycon args)
 191       | tc == tycon
 192       = ASSERT( n_req == length args)   -- ty::*
 193         return (args ++ args_so_far)
 194
 195     loop n_req args_so_far (AppTy fun arg)
 196       = loop (n_req - 1) (arg:args_so_far) fun
 197
 198     loop n_req args_so_far (TyVarTy tv)
 199       | not (isImmutableTyVar tv)
 200       = do { cts <- readMetaTyVar tv
 201            ; case cts of
 202                Indirect ty -> loop n_req args_so_far ty
 203                Flexi       -> do { arg_tys <- withMetaTvs tv arg_kinds mk_res_ty
 204                                  ; return (arg_tys ++ args_so_far) }
 205         }
 206       where
 207         mk_res_ty arg_tys' = mkTyConApp tc arg_tys'
 208         arg_kinds = map tyVarKind (take n_req (tyConTyVars tc))
 209
 210     loop _ _ _ = boxySplitFailure (mkTyConApp tc (mkTyVarTys (tyConTyVars tc))) orig_ty
 211
 212 ----------------------
 213 boxySplitListTy :: BoxyRhoType -> TcM BoxySigmaType     -- Special case for lists
 214 boxySplitListTy exp_ty = do { [elt_ty] <- boxySplitTyConApp listTyCon exp_ty
 215                             ; return elt_ty }
 216
 217
 218 ----------------------
 219 boxySplitAppTy :: BoxyRhoType                           -- Type to split: m a
 220                -> TcM (BoxySigmaType, BoxySigmaType)    -- Returns m, a
 221 -- Assumes (m: * -> k), where k is the kind of the incoming type
 222 -- If the incoming type is boxy, then so are the result types; and vice versa
 223
 224 boxySplitAppTy orig_ty
 225   = loop orig_ty
 226   where
 227     loop ty
 228       | Just ty' <- tcView ty = loop ty'
 229
 230     loop ty
 231       | Just (fun_ty, arg_ty) <- tcSplitAppTy_maybe ty
 232       = return (fun_ty, arg_ty)
 233
 234     loop (TyVarTy tv)
 235       | not (isImmutableTyVar tv)
 236       = do { cts <- readMetaTyVar tv
 237            ; case cts of
 238                Indirect ty -> loop ty
 239                Flexi       -> do { [fun_ty,arg_ty] <- withMetaTvs tv kinds mk_res_ty
 240                                  ; return (fun_ty, arg_ty) } }
 241       where
 242         mk_res_ty [fun_ty', arg_ty'] = mkAppTy fun_ty' arg_ty'
 243         mk_res_ty other = panic "TcUnify.mk_res_ty2"
 244         tv_kind = tyVarKind tv
 245         kinds = [mkArrowKind liftedTypeKind (defaultKind tv_kind),
 246                                                 -- m :: * -> k
 247                  liftedTypeKind]                -- arg type :: *
 248         -- The defaultKind is a bit smelly.  If you remove it,
 249         -- try compiling        f x = do { x }
 250         -- and you'll get a kind mis-match.  It smells, but
 251         -- not enough to lose sleep over.
 252
 253     loop _ = boxySplitFailure (mkAppTy alphaTy betaTy) orig_ty
 254
 255 ------------------
 256 boxySplitFailure actual_ty expected_ty
 257   = unifyMisMatch False False actual_ty expected_ty
 258         -- "outer" is False, so we don't pop the context
 259         -- which is what we want since we have not pushed one!
 260 \end{code}
 261
 262
 263 --------------------------------
 264 -- withBoxes: the key utility function
 265 --------------------------------
 266
 267 \begin{code}
 268 withMetaTvs :: TcTyVar  -- An unfilled-in, non-skolem, meta type variable
 269             -> [Kind]   -- Make fresh boxes (with the same BoxTv/TauTv setting as tv)
 270             -> ([BoxySigmaType] -> BoxySigmaType)
 271                                         -- Constructs the type to assign
 272                                         -- to the original var
 273             -> TcM [BoxySigmaType]      -- Return the fresh boxes
 274
 275 -- It's entirely possible for the [kind] to be empty.
 276 -- For example, when pattern-matching on True,
 277 -- we call boxySplitTyConApp passing a boolTyCon
 278
 279 -- Invariant: tv is still Flexi
 280
 281 withMetaTvs tv kinds mk_res_ty
 282   | isBoxyTyVar tv
 283   = do  { box_tvs <- mapM (newMetaTyVar BoxTv) kinds
 284         ; let box_tys = mkTyVarTys box_tvs
 285         ; writeMetaTyVar tv (mk_res_ty box_tys)
 286         ; return box_tys }
 287
 288   | otherwise                   -- Non-boxy meta type variable
 289   = do  { tau_tys <- mapM newFlexiTyVarTy kinds
 290         ; writeMetaTyVar tv (mk_res_ty tau_tys) -- Write it *first*
 291                                                 -- Sure to be a tau-type
 292         ; return tau_tys }
 293
 294 withBox :: Kind -> (BoxySigmaType -> TcM a) -> TcM (a, TcType)
 295 -- Allocate a *boxy* tyvar
 296 withBox kind thing_inside
 297   = do  { box_tv <- newMetaTyVar BoxTv kind
 298         ; res <- thing_inside (mkTyVarTy box_tv)
 299         ; ty  <- readFilledBox box_tv
 300         ; return (res, ty) }
 301 \end{code}
 302
 303
 304 %************************************************************************
 305 %*                                                                      *
 306                 Approximate boxy matching
 307 %*                                                                      *
 308 %************************************************************************
 309
 310 \begin{code}
 311 preSubType :: [TcTyVar]         -- Quantified type variables
 312            -> TcTyVarSet        -- Subset of quantified type variables
 313                                 --   see Note [Pre-sub boxy]
 314             -> TcType           -- The rho-type part; quantified tyvars scopes over this
 315             -> BoxySigmaType    -- Matching type from the context
 316             -> TcM [TcType]     -- Types to instantiate the tyvars
 317 -- Perform pre-subsumption, and return suitable types
 318 -- to instantiate the quantified type varibles:
 319 --      info from the pre-subsumption, if there is any
 320 --      a boxy type variable otherwise
 321 --
 322 -- Note [Pre-sub boxy]
 323 --   The 'btvs' are a subset of 'qtvs'.  They are the ones we can
 324 --   instantiate to a boxy type variable, because they'll definitely be
 325 --   filled in later.  This isn't always the case; sometimes we have type
 326 --   variables mentioned in the context of the type, but not the body;
 327 --                f :: forall a b. C a b => a -> a
 328 --   Then we may land up with an unconstrained 'b', so we want to
 329 --   instantiate it to a monotype (non-boxy) type variable
 330 --
 331 -- The 'qtvs' that are *neither* fixed by the pre-subsumption, *nor* are in 'btvs',
 332 -- are instantiated to TauTv meta variables.
 333
 334 preSubType qtvs btvs qty expected_ty
 335   = do { tys <- mapM inst_tv qtvs
 336         ; traceTc (text "preSubType" <+> (ppr qtvs $$ ppr btvs $$ ppr qty $$ ppr expected_ty $$ ppr pre_subst $$ ppr tys))
 337         ; return tys }
 338   where
 339     pre_subst = boxySubMatchType (mkVarSet qtvs) qty expected_ty
 340     inst_tv tv
 341         | Just boxy_ty <- lookupTyVar pre_subst tv = return boxy_ty
 342         | tv `elemVarSet` btvs = do { tv' <- tcInstBoxyTyVar tv
 343                                     ; return (mkTyVarTy tv') }
 344         | otherwise            = do { tv' <- tcInstTyVar tv
 345                                     ; return (mkTyVarTy tv') }
 346
 347 boxySubMatchType
 348         :: TcTyVarSet -> TcType -- The "template"; the tyvars are skolems
 349         -> BoxyRhoType          -- Type to match (note a *Rho* type)
 350         -> TvSubst              -- Substitution of the [TcTyVar] to BoxySigmaTypes
 351
 352 -- boxySubMatchType implements the Pre-subsumption judgement, in Fig 5 of the paper
 353 -- "Boxy types: inference for higher rank types and impredicativity"
 354
 355 boxySubMatchType tmpl_tvs tmpl_ty boxy_ty
 356   = go tmpl_tvs tmpl_ty emptyVarSet boxy_ty
 357   where
 358     go t_tvs t_ty b_tvs b_ty
 359         | Just t_ty' <- tcView t_ty = go t_tvs t_ty' b_tvs b_ty
 360         | Just b_ty' <- tcView b_ty = go t_tvs t_ty b_tvs b_ty'
 361
 362     go t_tvs (TyVarTy _) b_tvs b_ty = emptyTvSubst      -- Rule S-ANY; no bindings
 363         -- Rule S-ANY covers (a) type variables and (b) boxy types
 364         -- in the template.  Both look like a TyVarTy.
 365         -- See Note [Sub-match] below
 366
 367     go t_tvs t_ty b_tvs b_ty
 368         | isSigmaTy t_ty, (tvs, _, t_tau) <- tcSplitSigmaTy t_ty
 369         = go (t_tvs `delVarSetList` tvs) t_tau b_tvs b_ty       -- Rule S-SPEC
 370                 -- Under a forall on the left, if there is shadowing,
 371                 -- do not bind! Hence the delVarSetList.
 372         | isSigmaTy b_ty, (tvs, _, b_tau) <- tcSplitSigmaTy b_ty
 373         = go t_tvs t_ty (extendVarSetList b_tvs tvs) b_tau      -- Rule S-SKOL
 374                 -- Add to the variables we must not bind to
 375         -- NB: it's *important* to discard the theta part. Otherwise
 376         -- consider (forall a. Eq a => a -> b) ~<~ (Int -> Int -> Bool)
 377         -- and end up with a completely bogus binding (b |-> Bool), by lining
 378         -- up the (Eq a) with the Int, whereas it should be (b |-> (Int->Bool)).
 379         -- This pre-subsumption stuff can return too few bindings, but it
 380         -- must *never* return bogus info.
 381
 382     go t_tvs (FunTy arg1 res1) b_tvs (FunTy arg2 res2)  -- Rule S-FUN
 383         = boxy_match t_tvs arg1 b_tvs arg2 (go t_tvs res1 b_tvs res2)
 384         -- Match the args, and sub-match the results
 385
 386     go t_tvs t_ty b_tvs b_ty = boxy_match t_tvs t_ty b_tvs b_ty emptyTvSubst
 387         -- Otherwise defer to boxy matching
 388         -- This covers TyConApp, AppTy, PredTy
 389 \end{code}
 390
 391 Note [Sub-match]
 392 ~~~~~~~~~~~~~~~~
 393 Consider this
 394         head :: [a] -> a
 395         |- head xs : <rhobox>
 396 We will do a boxySubMatchType between   a ~ <rhobox>
 397 But we *don't* want to match [a |-> <rhobox>] because
 398     (a) The box should be filled in with a rho-type, but
 399            but the returned substitution maps TyVars to boxy
 400            *sigma* types
 401     (b) In any case, the right final answer might be *either*
 402            instantiate 'a' with a rho-type or a sigma type
 403            head xs : Int   vs   head xs : forall b. b->b
 404 So the matcher MUST NOT make a choice here.   In general, we only
 405 bind a template type variable in boxyMatchType, not in boxySubMatchType.
 406
 407
 408 \begin{code}
 409 boxyMatchTypes
 410         :: TcTyVarSet -> [TcType] -- The "template"; the tyvars are skolems
 411         -> [BoxySigmaType]        -- Type to match
 412         -> TvSubst                -- Substitution of the [TcTyVar] to BoxySigmaTypes
 413
 414 -- boxyMatchTypes implements the Pre-matching judgement, in Fig 5 of the paper
 415 -- "Boxy types: inference for higher rank types and impredicativity"
 416
 417 -- Find a *boxy* substitution that makes the template look as much
 418 --      like the BoxySigmaType as possible.
 419 -- It's always ok to return an empty substitution;
 420 --      anything more is jam on the pudding
 421 --
 422 -- NB1: This is a pure, non-monadic function.
 423 --      It does no unification, and cannot fail
 424 --
 425 -- Precondition: the arg lengths are equal
 426 -- Precondition: none of the template type variables appear anywhere in the [BoxySigmaType]
 427 --
 428
 429 ------------
 430 boxyMatchTypes tmpl_tvs tmpl_tys boxy_tys
 431   = ASSERT( length tmpl_tys == length boxy_tys )
 432     boxy_match_s tmpl_tvs tmpl_tys emptyVarSet boxy_tys emptyTvSubst
 433         -- ToDo: add error context?
 434
 435 boxy_match_s tmpl_tvs [] boxy_tvs [] subst
 436   = subst
 437 boxy_match_s tmpl_tvs (t_ty:t_tys) boxy_tvs (b_ty:b_tys) subst
 438   = boxy_match tmpl_tvs t_ty boxy_tvs b_ty $
 439     boxy_match_s tmpl_tvs t_tys boxy_tvs b_tys subst
 440 boxy_match_s tmpl_tvs _ boxy_tvs _ subst
 441   = panic "boxy_match_s"        -- Lengths do not match
 442
 443
 444 ------------
 445 boxy_match :: TcTyVarSet -> TcType      -- Template
 446            -> TcTyVarSet                -- boxy_tvs: do not bind template tyvars to any of these
 447            -> BoxySigmaType             -- Match against this type
 448            -> TvSubst
 449            -> TvSubst
 450
 451 -- The boxy_tvs argument prevents this match:
 452 --      [a]  forall b. a  ~  forall b. b
 453 -- We don't want to bind the template variable 'a'
 454 -- to the quantified type variable 'b'!
 455
 456 boxy_match tmpl_tvs orig_tmpl_ty boxy_tvs orig_boxy_ty subst
 457   = go orig_tmpl_ty orig_boxy_ty
 458   where
 459     go t_ty b_ty
 460         | Just t_ty' <- tcView t_ty = go t_ty' b_ty
 461         | Just b_ty' <- tcView b_ty = go t_ty b_ty'
 462
 463     go ty1 ty2          -- C.f. the isSigmaTy case for boxySubMatchType
 464         | isSigmaTy ty1
 465         , (tvs1, _, tau1) <- tcSplitSigmaTy ty1
 466         , (tvs2, _, tau2) <- tcSplitSigmaTy ty2
 467         , equalLength tvs1 tvs2
 468         = boxy_match (tmpl_tvs `delVarSetList` tvs1)    tau1
 469                      (boxy_tvs `extendVarSetList` tvs2) tau2 subst
 470
 471     go (TyConApp tc1 tys1) (TyConApp tc2 tys2)
 472         | tc1 == tc2 = go_s tys1 tys2
 473
 474     go (FunTy arg1 res1) (FunTy arg2 res2)
 475         = go_s [arg1,res1] [arg2,res2]
 476
 477     go t_ty b_ty
 478         | Just (s1,t1) <- tcSplitAppTy_maybe t_ty,
 479           Just (s2,t2) <- tcSplitAppTy_maybe b_ty,
 480           typeKind t2 `isSubKind` typeKind t1   -- Maintain invariant
 481         = go_s [s1,t1] [s2,t2]
 482
 483     go (TyVarTy tv) b_ty
 484         | tv `elemVarSet` tmpl_tvs      -- Template type variable in the template
 485         , boxy_tvs `disjointVarSet` tyVarsOfType orig_boxy_ty
 486         , typeKind b_ty `isSubKind` tyVarKind tv  -- See Note [Matching kinds]
 487         = extendTvSubst subst tv boxy_ty'
 488         | otherwise
 489         = subst                         -- Ignore others
 490         where
 491           boxy_ty' = case lookupTyVar subst tv of
 492                         Nothing -> orig_boxy_ty
 493                         Just ty -> ty `boxyLub` orig_boxy_ty
 494
 495     go _ _ = emptyTvSubst       -- It's important to *fail* by returning the empty substitution
 496         -- Example:  Tree a ~ Maybe Int
 497         -- We do not want to bind (a |-> Int) in pre-matching, because that can give very
 498         -- misleading error messages.  An even more confusing case is
 499         --           a -> b ~ Maybe Int
 500         -- Then we do not want to bind (b |-> Int)!  It's always safe to discard bindings
 501         -- from this pre-matching phase.
 502
 503     --------
 504     go_s tys1 tys2 = boxy_match_s tmpl_tvs tys1 boxy_tvs tys2 subst
 505
 506
 507 boxyLub :: BoxySigmaType -> BoxySigmaType -> BoxySigmaType
 508 -- Combine boxy information from the two types
 509 -- If there is a conflict, return the first
 510 boxyLub orig_ty1 orig_ty2
 511   = go orig_ty1 orig_ty2
 512   where
 513     go (AppTy f1 a1) (AppTy f2 a2) = AppTy (boxyLub f1 f2) (boxyLub a1 a2)
 514     go (FunTy f1 a1) (FunTy f2 a2) = FunTy (boxyLub f1 f2) (boxyLub a1 a2)
 515     go (TyConApp tc1 ts1) (TyConApp tc2 ts2)
 516       | tc1 == tc2, length ts1 == length ts2
 517       = TyConApp tc1 (zipWith boxyLub ts1 ts2)
 518
 519     go (TyVarTy tv1) ty2                -- This is the whole point;
 520       | isTcTyVar tv1, isBoxyTyVar tv1  -- choose ty2 if ty2 is a box
 521       = orig_ty2
 522
 523         -- Look inside type synonyms, but only if the naive version fails
 524     go ty1 ty2 | Just ty1' <- tcView ty1 = go ty1' ty2
 525                | Just ty2' <- tcView ty1 = go ty1 ty2'
 526
 527     -- For now, we don't look inside ForAlls, PredTys
 528     go ty1 ty2 = orig_ty1       -- Default
 529 \end{code}
 530
 531 Note [Matching kinds]
 532 ~~~~~~~~~~~~~~~~~~~~~
 533 The target type might legitimately not be a sub-kind of template.
 534 For example, suppose the target is simply a box with an OpenTypeKind,
 535 and the template is a type variable with LiftedTypeKind.
 536 Then it's ok (because the target type will later be refined).
 537 We simply don't bind the template type variable.
 538
 539 It might also be that the kind mis-match is an error. For example,
 540 suppose we match the template (a -> Int) against (Int# -> Int),
 541 where the template type variable 'a' has LiftedTypeKind.  This
 542 matching function does not fail; it simply doesn't bind the template.
 543 Later stuff will fail.
 544
 545 %************************************************************************
 546 %*                                                                      *
 547                 Subsumption checking
 548 %*                                                                      *
 549 %************************************************************************
 550
 551 All the tcSub calls have the form
 552
 553                 tcSub expected_ty offered_ty
 554 which checks
 555                 offered_ty <= expected_ty
 556
 557 That is, that a value of type offered_ty is acceptable in
 558 a place expecting a value of type expected_ty.
 559
 560 It returns a coercion function
 561         co_fn :: offered_ty -> expected_ty
 562 which takes an HsExpr of type offered_ty into one of type
 563 expected_ty.
 564
 565 \begin{code}
 566 -----------------
 567 tcSubExp :: BoxySigmaType -> BoxySigmaType -> TcM HsWrapper     -- Locally used only
 568         -- (tcSub act exp) checks that
 569         --      act <= exp
 570 tcSubExp actual_ty expected_ty
 571   = -- addErrCtxtM (unifyCtxt actual_ty expected_ty) $
 572     -- Adding the error context here leads to some very confusing error
 573     -- messages, such as "can't match forall a. a->a with forall a. a->a"
 574     -- Example is tcfail165:
 575     --      do var <- newEmptyMVar :: IO (MVar (forall a. Show a => a -> String))
 576     --         putMVar var (show :: forall a. Show a => a -> String)
 577     -- Here the info does not flow from the 'var' arg of putMVar to its 'show' arg
 578     -- but after zonking it looks as if it does!
 579     --
 580     -- So instead I'm adding the error context when moving from tc_sub to u_tys
 581
 582     traceTc (text "tcSubExp" <+> ppr actual_ty <+> ppr expected_ty) >>
 583     tc_sub SubOther actual_ty actual_ty False expected_ty expected_ty
 584
 585 tcFunResTy :: Name -> BoxySigmaType -> BoxySigmaType -> TcM HsWrapper   -- Locally used only
 586 tcFunResTy fun actual_ty expected_ty
 587   = traceTc (text "tcFunResTy" <+> ppr actual_ty <+> ppr expected_ty) >>
 588     tc_sub (SubFun fun) actual_ty actual_ty False expected_ty expected_ty
 589
 590 -----------------
 591 data SubCtxt = SubDone          -- Error-context already pushed
 592              | SubFun Name      -- Context is tcFunResTy
 593              | SubOther         -- Context is something else
 594
 595 tc_sub :: SubCtxt               -- How to add an error-context
 596        -> BoxySigmaType         -- actual_ty, before expanding synonyms
 597        -> BoxySigmaType         --              ..and after
 598        -> InBox                 -- True <=> expected_ty is inside a box
 599        -> BoxySigmaType         -- expected_ty, before
 600        -> BoxySigmaType         --              ..and after
 601        -> TcM HsWrapper
 602                                 -- The acual_ty is never inside a box
 603 -- IMPORTANT pre-condition: if the args contain foralls, the bound type
 604 --                          variables are visible non-monadically
 605 --                          (i.e. tha args are sufficiently zonked)
 606 -- This invariant is needed so that we can "see" the foralls, ad
 607 -- e.g. in the SPEC rule where we just use splitSigmaTy
 608
 609 tc_sub sub_ctxt act_sty act_ty exp_ib exp_sty exp_ty
 610   = traceTc (text "tc_sub" <+> ppr act_ty $$ ppr exp_ty) >>
 611     tc_sub1 sub_ctxt act_sty act_ty exp_ib exp_sty exp_ty
 612         -- This indirection is just here to make
 613         -- it easy to insert a debug trace!
 614
 615 tc_sub1 sub_ctxt act_sty act_ty exp_ib exp_sty exp_ty
 616   | Just exp_ty' <- tcView exp_ty = tc_sub sub_ctxt act_sty act_ty exp_ib exp_sty exp_ty'
 617 tc_sub1 sub_ctxt act_sty act_ty exp_ib exp_sty exp_ty
 618   | Just act_ty' <- tcView act_ty = tc_sub sub_ctxt act_sty act_ty' exp_ib exp_sty exp_ty
 619
 620 -----------------------------------
 621 -- Rule SBOXY, plus other cases when act_ty is a type variable
 622 -- Just defer to boxy matching
 623 -- This rule takes precedence over SKOL!
 624 tc_sub1 sub_ctxt act_sty (TyVarTy tv) exp_ib exp_sty exp_ty
 625   = do  { addSubCtxt sub_ctxt act_sty exp_sty $
 626           uVar True False tv exp_ib exp_sty exp_ty
 627         ; return idHsWrapper }
 628
 629 -----------------------------------
 630 -- Skolemisation case (rule SKOL)
 631 --      actual_ty:   d:Eq b => b->b
 632 --      expected_ty: forall a. Ord a => a->a
 633 --      co_fn e      /\a. \d2:Ord a. let d = eqFromOrd d2 in e
 634
 635 -- It is essential to do this *before* the specialisation case
 636 -- Example:  f :: (Eq a => a->a) -> ...
 637 --           g :: Ord b => b->b
 638 -- Consider  f g !
 639
 640 tc_sub1 sub_ctxt act_sty act_ty exp_ib exp_sty exp_ty
 641   | isSigmaTy exp_ty
 642   = if exp_ib then      -- SKOL does not apply if exp_ty is inside a box
 643         defer_to_boxy_matching sub_ctxt act_sty act_ty exp_ib exp_sty exp_ty
 644     else do
 645         { (gen_fn, co_fn) <- tcGen exp_ty act_tvs $ \ _ body_exp_ty ->
 646                              tc_sub sub_ctxt act_sty act_ty False body_exp_ty body_exp_ty
 647         ; return (gen_fn <.> co_fn) }
 648   where
 649     act_tvs = tyVarsOfType act_ty
 650                 -- It's really important to check for escape wrt
 651                 -- the free vars of both expected_ty *and* actual_ty
 652
 653 -----------------------------------
 654 -- Specialisation case (rule ASPEC):
 655 --      actual_ty:   forall a. Ord a => a->a
 656 --      expected_ty: Int -> Int
 657 --      co_fn e =    e Int dOrdInt
 658
 659 tc_sub1 sub_ctxt act_sty actual_ty exp_ib exp_sty expected_ty
 660 -- Implements the new SPEC rule in the Appendix of the paper
 661 -- "Boxy types: inference for higher rank types and impredicativity"
 662 -- (This appendix isn't in the published version.)
 663 -- The idea is to *first* do pre-subsumption, and then full subsumption
 664 -- Example:     forall a. a->a  <=  Int -> (forall b. Int)
 665 --   Pre-subsumpion finds a|->Int, and that works fine, whereas
 666 --   just running full subsumption would fail.
 667   | isSigmaTy actual_ty
 668   = do  {       -- Perform pre-subsumption, and instantiate
 669                 -- the type with info from the pre-subsumption;
 670                 -- boxy tyvars if pre-subsumption gives no info
 671           let (tyvars, theta, tau) = tcSplitSigmaTy actual_ty
 672               tau_tvs = exactTyVarsOfType tau
 673         ; inst_tys <- if exp_ib then    -- Inside a box, do not do clever stuff
 674                         do { tyvars' <- mapM tcInstBoxyTyVar tyvars
 675                            ; return (mkTyVarTys tyvars') }
 676                       else              -- Outside, do clever stuff
 677                         preSubType tyvars tau_tvs tau expected_ty
 678         ; let subst' = zipOpenTvSubst tyvars inst_tys
 679               tau'   = substTy subst' tau
 680
 681                 -- Perform a full subsumption check
 682         ; traceTc (text "tc_sub_spec" <+> vcat [ppr actual_ty,
 683                                                 ppr tyvars <+> ppr theta <+> ppr tau,
 684                                                 ppr tau'])
 685         ; co_fn2 <- tc_sub sub_ctxt tau' tau' exp_ib exp_sty expected_ty
 686
 687                 -- Deal with the dictionaries
 688                 -- The origin gives a helpful origin when we have
 689                 -- a function with type f :: Int -> forall a. Num a => ...
 690                 -- This way the (Num a) dictionary gets an OccurrenceOf f origin
 691         ; let orig = case sub_ctxt of
 692                         SubFun n -> OccurrenceOf n
 693                         other    -> InstSigOrigin       -- Unhelpful
 694         ; co_fn1 <- instCall orig inst_tys (substTheta subst' theta)
 695         ; return (co_fn2 <.> co_fn1) }
 696
 697 -----------------------------------
 698 -- Function case (rule F1)
 699 tc_sub1 sub_ctxt act_sty (FunTy act_arg act_res) exp_ib exp_sty (FunTy exp_arg exp_res)
 700   = addSubCtxt sub_ctxt act_sty exp_sty $
 701     tc_sub_funs act_arg act_res exp_ib exp_arg exp_res
 702
 703 -- Function case (rule F2)
 704 tc_sub1 sub_ctxt act_sty act_ty@(FunTy act_arg act_res) _ exp_sty (TyVarTy exp_tv)
 705   | isBoxyTyVar exp_tv
 706   = addSubCtxt sub_ctxt act_sty exp_sty $
 707     do  { cts <- readMetaTyVar exp_tv
 708         ; case cts of
 709             Indirect ty -> tc_sub SubDone act_sty act_ty True exp_sty ty
 710             Flexi       -> do { [arg_ty,res_ty] <- withMetaTvs exp_tv fun_kinds mk_res_ty
 711                               ; tc_sub_funs act_arg act_res True arg_ty res_ty } }
 712  where
 713     mk_res_ty [arg_ty', res_ty'] = mkFunTy arg_ty' res_ty'
 714     mk_res_ty other = panic "TcUnify.mk_res_ty3"
 715     fun_kinds = [argTypeKind, openTypeKind]
 716
 717 -- Everything else: defer to boxy matching
 718 tc_sub1 sub_ctxt act_sty actual_ty exp_ib exp_sty expected_ty
 719   = defer_to_boxy_matching sub_ctxt act_sty actual_ty exp_ib exp_sty expected_ty
 720
 721 -----------------------------------
 722 defer_to_boxy_matching sub_ctxt act_sty actual_ty exp_ib exp_sty expected_ty
 723   = do  { addSubCtxt sub_ctxt act_sty exp_sty $
 724           u_tys True False act_sty actual_ty exp_ib exp_sty expected_ty
 725         ; return idHsWrapper }
 726
 727 -----------------------------------
 728 tc_sub_funs act_arg act_res exp_ib exp_arg exp_res
 729   = do  { uTys False act_arg exp_ib exp_arg
 730         ; co_fn_res <- tc_sub SubDone act_res act_res exp_ib exp_res exp_res
 731         ; wrapFunResCoercion [exp_arg] co_fn_res }
 732
 733 -----------------------------------
 734 wrapFunResCoercion
 735         :: [TcType]     -- Type of args
 736         -> HsWrapper    -- HsExpr a -> HsExpr b
 737         -> TcM HsWrapper        -- HsExpr (arg_tys -> a) -> HsExpr (arg_tys -> b)
 738 wrapFunResCoercion arg_tys co_fn_res
 739   | isIdHsWrapper co_fn_res = return idHsWrapper
 740   | null arg_tys           = return co_fn_res
 741   | otherwise
 742   = do  { arg_ids <- newSysLocalIds FSLIT("sub") arg_tys
 743         ; return (mkWpLams arg_ids <.> co_fn_res <.> mkWpApps arg_ids) }
 744 \end{code}
 745
 746
 747
 748 %************************************************************************
 749 %*                                                                      *
 750 \subsection{Generalisation}
 751 %*                                                                      *
 752 %************************************************************************
 753
 754 \begin{code}
 755 tcGen :: BoxySigmaType                          -- expected_ty
 756       -> TcTyVarSet                             -- Extra tyvars that the universally
 757                                                 --      quantified tyvars of expected_ty
 758                                                 --      must not be unified
 759       -> ([TcTyVar] -> BoxyRhoType -> TcM result)
 760       -> TcM (HsWrapper, result)
 761         -- The expression has type: spec_ty -> expected_ty
 762
 763 tcGen expected_ty extra_tvs thing_inside        -- We expect expected_ty to be a forall-type
 764                                                 -- If not, the call is a no-op
 765   = do  {       -- We want the GenSkol info in the skolemised type variables to
 766                 -- mention the *instantiated* tyvar names, so that we get a
 767                 -- good error message "Rigid variable 'a' is bound by (forall a. a->a)"
 768                 -- Hence the tiresome but innocuous fixM
 769           ((tvs', theta', rho'), skol_info) <- fixM (\ ~(_, skol_info) ->
 770                 do { (forall_tvs, theta, rho_ty) <- tcInstSkolType skol_info expected_ty
 771                         -- Get loation from monad, not from expected_ty
 772                    ; let skol_info = GenSkol forall_tvs (mkPhiTy theta rho_ty)
 773                    ; return ((forall_tvs, theta, rho_ty), skol_info) })
 774
 775 #ifdef DEBUG
 776         ; traceTc (text "tcGen" <+> vcat [text "extra_tvs" <+> ppr extra_tvs,
 777                                     text "expected_ty" <+> ppr expected_ty,
 778                                     text "inst ty" <+> ppr tvs' <+> ppr theta' <+> ppr rho',
 779                                     text "free_tvs" <+> ppr free_tvs])
 780 #endif
 781
 782         -- Type-check the arg and unify with poly type
 783         ; (result, lie) <- getLIE (thing_inside tvs' rho')
 784
 785         -- Check that the "forall_tvs" havn't been constrained
 786         -- The interesting bit here is that we must include the free variables
 787         -- of the expected_ty.  Here's an example:
 788         --       runST (newVar True)
 789         -- Here, if we don't make a check, we'll get a type (ST s (MutVar s Bool))
 790         -- for (newVar True), with s fresh.  Then we unify with the runST's arg type
 791         -- forall s'. ST s' a. That unifies s' with s, and a with MutVar s Bool.
 792         -- So now s' isn't unconstrained because it's linked to a.
 793         -- Conclusion: include the free vars of the expected_ty in the
 794         -- list of "free vars" for the signature check.
 795
 796         ; loc <- getInstLoc (SigOrigin skol_info)
 797         ; dicts <- newDictBndrs loc theta'
 798         ; inst_binds <- tcSimplifyCheck loc tvs' dicts lie
 799
 800         ; checkSigTyVarsWrt free_tvs tvs'
 801         ; traceTc (text "tcGen:done")
 802
 803         ; let
 804             -- The WpLet binds any Insts which came out of the simplification.
 805                 dict_ids = map instToId dicts
 806                 co_fn = mkWpTyLams tvs' <.> mkWpLams dict_ids <.> WpLet inst_binds
 807         ; returnM (co_fn, result) }
 808   where
 809     free_tvs = tyVarsOfType expected_ty `unionVarSet` extra_tvs
 810 \end{code}
 811
 812
 813
 814 %************************************************************************
 815 %*                                                                      *
 816                 Boxy unification
 817 %*                                                                      *
 818 %************************************************************************
 819
 820 The exported functions are all defined as versions of some
 821 non-exported generic functions.
 822
 823 \begin{code}
 824 boxyUnify :: BoxyType -> BoxyType -> TcM ()
 825 -- Acutal and expected, respectively
 826 boxyUnify ty1 ty2
 827   = addErrCtxtM (unifyCtxt ty1 ty2) $
 828     uTysOuter False ty1 False ty2
 829
 830 ---------------
 831 boxyUnifyList :: [BoxyType] -> [BoxyType] -> TcM ()
 832 -- Arguments should have equal length
 833 -- Acutal and expected types
 834 boxyUnifyList tys1 tys2 = uList boxyUnify tys1 tys2
 835
 836 ---------------
 837 unifyType :: TcTauType -> TcTauType -> TcM ()
 838 -- No boxes expected inside these types
 839 -- Acutal and expected types
 840 unifyType ty1 ty2       -- ty1 expected, ty2 inferred
 841   = ASSERT2( not (isBoxyTy ty1), ppr ty1 )
 842     ASSERT2( not (isBoxyTy ty2), ppr ty2 )
 843     addErrCtxtM (unifyCtxt ty1 ty2) $
 844     uTysOuter True ty1 True ty2
 845
 846 ---------------
 847 unifyPred :: PredType -> PredType -> TcM ()
 848 -- Acutal and expected types
 849 unifyPred p1 p2 = addErrCtxtM (unifyCtxt (mkPredTy p1) (mkPredTy p2)) $
 850                   uPred True True p1 True p2
 851
 852 unifyTheta :: TcThetaType -> TcThetaType -> TcM ()
 853 -- Acutal and expected types
 854 unifyTheta theta1 theta2
 855   = do  { checkTc (equalLength theta1 theta2)
 856                   (vcat [ptext SLIT("Contexts differ in length"),
 857                          nest 2 $ parens $ ptext SLIT("Use -fglasgow-exts to allow this")])
 858         ; uList unifyPred theta1 theta2 }
 859
 860 ---------------
 861 uList :: (a -> a -> TcM ())
 862        -> [a] -> [a] -> TcM ()
 863 -- Unify corresponding elements of two lists of types, which
 864 -- should be f equal length.  We charge down the list explicitly so that
 865 -- we can complain if their lengths differ.
 866 uList unify []         []         = return ()
 867 uList unify (ty1:tys1) (ty2:tys2) = do { unify ty1 ty2; uList unify tys1 tys2 }
 868 uList unify ty1s ty2s = panic "Unify.uList: mismatched type lists!"
 869 \end{code}
 870
 871 @unifyTypeList@ takes a single list of @TauType@s and unifies them
 872 all together.  It is used, for example, when typechecking explicit
 873 lists, when all the elts should be of the same type.
 874
 875 \begin{code}
 876 unifyTypeList :: [TcTauType] -> TcM ()
 877 unifyTypeList []                 = returnM ()
 878 unifyTypeList [ty]               = returnM ()
 879 unifyTypeList (ty1:tys@(ty2:_)) = do { unifyType ty1 ty2
 880                                       ; unifyTypeList tys }
 881 \end{code}
 882
 883 %************************************************************************
 884 %*                                                                      *
 885 \subsection[Unify-uTys]{@uTys@: getting down to business}
 886 %*                                                                      *
 887 %************************************************************************
 888
 889 @uTys@ is the heart of the unifier.  Each arg happens twice, because
 890 we want to report errors in terms of synomyms if poss.  The first of
 891 the pair is used in error messages only; it is always the same as the
 892 second, except that if the first is a synonym then the second may be a
 893 de-synonym'd version.  This way we get better error messages.
 894
 895 We call the first one \tr{ps_ty1}, \tr{ps_ty2} for ``possible synomym''.
 896
 897 \begin{code}
 898 type InBox = Bool       -- True  <=> we are inside a box
 899                         -- False <=> we are outside a box
 900         -- The importance of this is that if we get "filled-box meets
 901         -- filled-box", we'll look into the boxes and unify... but
 902         -- we must not allow polytypes.  But if we are in a box on
 903         -- just one side, then we can allow polytypes
 904
 905 type Outer = Bool       -- True <=> this is the outer level of a unification
 906                         --          so that the types being unified are the
 907                         --          very ones we began with, not some sub
 908                         --          component or synonym expansion
 909 -- The idea is that if Outer is true then unifyMisMatch should
 910 -- pop the context to remove the "Expected/Acutal" context
 911
 912 uTysOuter, uTys
 913      :: InBox -> TcType -- ty1 is the *expected* type
 914      -> InBox -> TcType -- ty2 is the *actual* type
 915      -> TcM ()
 916 uTysOuter nb1 ty1 nb2 ty2 = do { traceTc (text "uTysOuter" <+> ppr ty1 <+> ppr ty2)
 917                                ; u_tys True nb1 ty1 ty1 nb2 ty2 ty2 }
 918 uTys      nb1 ty1 nb2 ty2 = do { traceTc (text "uTys" <+> ppr ty1 <+> ppr ty2)
 919                                ; u_tys False nb1 ty1 ty1 nb2 ty2 ty2 }
 920
 921
 922 --------------
 923 uTys_s :: InBox -> [TcType]     -- ty1 is the *actual* types
 924        -> InBox -> [TcType]     -- ty2 is the *expected* types
 925        -> TcM ()
 926 uTys_s nb1 []           nb2 []         = returnM ()
 927 uTys_s nb1 (ty1:tys1) nb2 (ty2:tys2) = do { uTys nb1 ty1 nb2 ty2
 928                                           ; uTys_s nb1 tys1 nb2 tys2 }
 929 uTys_s nb1 ty1s nb2 ty2s = panic "Unify.uTys_s: mismatched type lists!"
 930
 931 --------------
 932 u_tys :: Outer
 933       -> InBox -> TcType -> TcType      -- ty1 is the *actual* type
 934       -> InBox -> TcType -> TcType      -- ty2 is the *expected* type
 935       -> TcM ()
 936
 937 u_tys outer nb1 orig_ty1 ty1 nb2 orig_ty2 ty2
 938   = go outer ty1 ty2
 939   where
 940
 941         -- Always expand synonyms (see notes at end)
 942         -- (this also throws away FTVs)
 943     go outer ty1 ty2
 944       | Just ty1' <- tcView ty1 = go False ty1' ty2
 945       | Just ty2' <- tcView ty2 = go False ty1 ty2'
 946
 947         -- Variables; go for uVar
 948     go outer (TyVarTy tyvar1) ty2 = uVar outer False tyvar1 nb2 orig_ty2 ty2
 949     go outer ty1 (TyVarTy tyvar2) = uVar outer True  tyvar2 nb1 orig_ty1 ty1
 950                                 -- "True" means args swapped
 951
 952         -- The case for sigma-types must *follow* the variable cases
 953         -- because a boxy variable can be filed with a polytype;
 954         -- but must precede FunTy, because ((?x::Int) => ty) look
 955         -- like a FunTy; there isn't necy a forall at the top
 956     go _ ty1 ty2
 957       | isSigmaTy ty1 || isSigmaTy ty2
 958       = do   { checkM (equalLength tvs1 tvs2)
 959                       (unifyMisMatch outer False orig_ty1 orig_ty2)
 960
 961              ; tvs <- tcInstSkolTyVars UnkSkol tvs1     -- Not a helpful SkolemInfo
 962                         -- Get location from monad, not from tvs1
 963              ; let tys      = mkTyVarTys tvs
 964                    in_scope = mkInScopeSet (mkVarSet tvs)
 965                    phi1   = substTy (mkTvSubst in_scope (zipTyEnv tvs1 tys)) body1
 966                    phi2   = substTy (mkTvSubst in_scope (zipTyEnv tvs2 tys)) body2
 967                    (theta1,tau1) = tcSplitPhiTy phi1
 968                    (theta2,tau2) = tcSplitPhiTy phi2
 969
 970              ; addErrCtxtM (unifyForAllCtxt tvs phi1 phi2) $ do
 971              { checkM (equalLength theta1 theta2)
 972                       (unifyMisMatch outer False orig_ty1 orig_ty2)
 973
 974              ; uPreds False nb1 theta1 nb2 theta2
 975              ; uTys nb1 tau1 nb2 tau2
 976
 977                 -- Check for escape; e.g. (forall a. a->b) ~ (forall a. a->a)
 978              ; free_tvs <- zonkTcTyVarsAndFV (varSetElems (tyVarsOfType ty1 `unionVarSet` tyVarsOfType ty2))
 979              ; ifM (any (`elemVarSet` free_tvs) tvs)
 980                    (bleatEscapedTvs free_tvs tvs tvs)
 981
 982                 -- If both sides are inside a box, we are in a "box-meets-box"
 983                 -- situation, and we should not have a polytype at all.
 984                 -- If we get here we have two boxes, already filled with
 985                 -- the same polytype... but it should be a monotype.
 986                 -- This check comes last, because the error message is
 987                 -- extremely unhelpful.
 988              ; ifM (nb1 && nb2) (notMonoType ty1)
 989              }}
 990       where
 991         (tvs1, body1) = tcSplitForAllTys ty1
 992         (tvs2, body2) = tcSplitForAllTys ty2
 993
 994         -- Predicates
 995     go outer (PredTy p1) (PredTy p2) = uPred False nb1 p1 nb2 p2
 996
 997         -- Type constructors must match
 998     go _ (TyConApp con1 tys1) (TyConApp con2 tys2)
 999       | con1 == con2 = uTys_s nb1 tys1 nb2 tys2
1000         -- See Note [TyCon app]
1001
1002         -- Functions; just check the two parts
1003     go _ (FunTy fun1 arg1) (FunTy fun2 arg2)
1004       = do { uTys nb1 fun1 nb2 fun2
1005            ; uTys nb1 arg1 nb2 arg2 }
1006
1007         -- Applications need a bit of care!
1008         -- They can match FunTy and TyConApp, so use splitAppTy_maybe
1009         -- NB: we've already dealt with type variables and Notes,
1010         -- so if one type is an App the other one jolly well better be too
1011     go outer (AppTy s1 t1) ty2
1012       | Just (s2,t2) <- tcSplitAppTy_maybe ty2
1013       = do { uTys nb1 s1 nb2 s2; uTys nb1 t1 nb2 t2 }
1014
1015         -- Now the same, but the other way round
1016         -- Don't swap the types, because the error messages get worse
1017     go outer ty1 (AppTy s2 t2)
1018       | Just (s1,t1) <- tcSplitAppTy_maybe ty1
1019       = do { uTys nb1 s1 nb2 s2; uTys nb1 t1 nb2 t2 }
1020
1021
1022         -- Anything else fails
1023     go outer _ _ = unifyMisMatch outer False orig_ty1 orig_ty2
1024
1025 ----------
1026 uPred outer nb1 (IParam n1 t1) nb2 (IParam n2 t2)
1027   | n1 == n2 = uTys nb1 t1 nb2 t2
1028 uPred outer nb1 (ClassP c1 tys1) nb2 (ClassP c2 tys2)
1029   | c1 == c2 = uTys_s nb1 tys1 nb2 tys2         -- Guaranteed equal lengths because the kinds check
1030 uPred outer _ p1 _ p2 = unifyMisMatch outer False (mkPredTy p1) (mkPredTy p2)
1031
1032 uPreds outer nb1 []       nb2 []       = return ()
1033 uPreds outer nb1 (p1:ps1) nb2 (p2:ps2) = uPred outer nb1 p1 nb2 p2 >> uPreds outer nb1 ps1 nb2 ps2
1034 uPreds outer nb1 ps1      nb2 ps2      = panic "uPreds"
1035 \end{code}
1036
1037 Note [Tycon app]
1038 ~~~~~~~~~~~~~~~~
1039 When we find two TyConApps, the argument lists are guaranteed equal
1040 length.  Reason: intially the kinds of the two types to be unified is
1041 the same. The only way it can become not the same is when unifying two
1042 AppTys (f1 a1):=:(f2 a2).  In that case there can't be a TyConApp in
1043 the f1,f2 (because it'd absorb the app).  If we unify f1:=:f2 first,
1044 which we do, that ensures that f1,f2 have the same kind; and that
1045 means a1,a2 have the same kind.  And now the argument repeats.
1046
1047
1048 Notes on synonyms
1049 ~~~~~~~~~~~~~~~~~
1050 If you are tempted to make a short cut on synonyms, as in this
1051 pseudocode...
1052
1053 \begin{verbatim}
1054 -- NO   uTys (SynTy con1 args1 ty1) (SynTy con2 args2 ty2)
1055 -- NO     = if (con1 == con2) then
1056 -- NO   -- Good news!  Same synonym constructors, so we can shortcut
1057 -- NO   -- by unifying their arguments and ignoring their expansions.
1058 -- NO   unifyTypepeLists args1 args2
1059 -- NO    else
1060 -- NO   -- Never mind.  Just expand them and try again
1061 -- NO   uTys ty1 ty2
1062 \end{verbatim}
1063
1064 then THINK AGAIN.  Here is the whole story, as detected and reported
1065 by Chris Okasaki \tr{<Chris_Okasaki@loch.mess.cs.cmu.edu>}:
1066 \begin{quotation}
1067 Here's a test program that should detect the problem:
1068
1069 \begin{verbatim}
1070         type Bogus a = Int
1071         x = (1 :: Bogus Char) :: Bogus Bool
1072 \end{verbatim}
1073
1074 The problem with [the attempted shortcut code] is that
1075 \begin{verbatim}
1076         con1 == con2
1077 \end{verbatim}
1078 is not a sufficient condition to be able to use the shortcut!
1079 You also need to know that the type synonym actually USES all
1080 its arguments.  For example, consider the following type synonym
1081 which does not use all its arguments.
1082 \begin{verbatim}
1083         type Bogus a = Int
1084 \end{verbatim}
1085
1086 If you ever tried unifying, say, \tr{Bogus Char} with \tr{Bogus Bool},
1087 the unifier would blithely try to unify \tr{Char} with \tr{Bool} and
1088 would fail, even though the expanded forms (both \tr{Int}) should
1089 match.
1090
1091 Similarly, unifying \tr{Bogus Char} with \tr{Bogus t} would
1092 unnecessarily bind \tr{t} to \tr{Char}.
1093
1094 ... You could explicitly test for the problem synonyms and mark them
1095 somehow as needing expansion, perhaps also issuing a warning to the
1096 user.
1097 \end{quotation}
1098
1099
1100 %************************************************************************
1101 %*                                                                      *
1102 \subsection[Unify-uVar]{@uVar@: unifying with a type variable}
1103 %*                                                                      *
1104 %************************************************************************
1105
1106 @uVar@ is called when at least one of the types being unified is a
1107 variable.  It does {\em not} assume that the variable is a fixed point
1108 of the substitution; rather, notice that @uVar@ (defined below) nips
1109 back into @uTys@ if it turns out that the variable is already bound.
1110
1111 \begin{code}
1112 uVar :: Outer
1113      -> Bool            -- False => tyvar is the "expected"
1114                         -- True  => ty    is the "expected" thing
1115      -> TcTyVar
1116      -> InBox           -- True <=> definitely no boxes in t2
1117      -> TcTauType -> TcTauType  -- printing and real versions
1118      -> TcM ()
1119
1120 uVar outer swapped tv1 nb2 ps_ty2 ty2
1121   = do  { let expansion | showSDoc (ppr ty2) == showSDoc (ppr ps_ty2) = empty
1122                         | otherwise = brackets (equals <+> ppr ty2)
1123         ; traceTc (text "uVar" <+> ppr swapped <+>
1124                         sep [ppr tv1 <+> dcolon <+> ppr (tyVarKind tv1 ),
1125                                 nest 2 (ptext SLIT(" <-> ")),
1126                              ppr ps_ty2 <+> dcolon <+> ppr (typeKind ty2) <+> expansion])
1127         ; details <- lookupTcTyVar tv1
1128         ; case details of
1129             IndirectTv ty1
1130                 | swapped   -> u_tys outer nb2  ps_ty2 ty2 True ty1    ty1      -- Swap back
1131                 | otherwise -> u_tys outer True ty1    ty1 nb2  ps_ty2 ty2      -- Same order
1132                         -- The 'True' here says that ty1 is now inside a box
1133             DoneTv details1 -> uUnfilledVar outer swapped tv1 details1 ps_ty2 ty2
1134         }
1135
1136 ----------------
1137 uUnfilledVar :: Outer
1138              -> Bool                            -- Args are swapped
1139              -> TcTyVar -> TcTyVarDetails       -- Tyvar 1
1140              -> TcTauType -> TcTauType          -- Type 2
1141              -> TcM ()
1142 -- Invariant: tyvar 1 is not unified with anything
1143
1144 uUnfilledVar outer swapped tv1 details1 ps_ty2 ty2
1145   | Just ty2' <- tcView ty2
1146   =     -- Expand synonyms; ignore FTVs
1147     uUnfilledVar False swapped tv1 details1 ps_ty2 ty2'
1148
1149 uUnfilledVar outer swapped tv1 details1 ps_ty2 (TyVarTy tv2)
1150   | tv1 == tv2  -- Same type variable => no-op (but watch out for the boxy case)
1151   = case details1 of
1152         MetaTv BoxTv ref1  -- A boxy type variable meets itself;
1153                            -- this is box-meets-box, so fill in with a tau-type
1154               -> do { tau_tv <- tcInstTyVar tv1
1155                     ; updateMeta tv1 ref1 (mkTyVarTy tau_tv) }
1156         other -> returnM ()     -- No-op
1157
1158         -- Distinct type variables
1159   | otherwise
1160   = do  { lookup2 <- lookupTcTyVar tv2
1161         ; case lookup2 of
1162             IndirectTv ty2' -> uUnfilledVar  outer swapped tv1 details1 ty2' ty2'
1163             DoneTv details2 -> uUnfilledVars outer swapped tv1 details1 tv2 details2
1164         }
1165
1166 uUnfilledVar outer swapped tv1 details1 ps_ty2 non_var_ty2      -- ty2 is not a type variable
1167   = case details1 of
1168         MetaTv (SigTv _) ref1 -> mis_match      -- Can't update a skolem with a non-type-variable
1169         MetaTv info ref1      -> uMetaVar swapped tv1 info ref1 ps_ty2 non_var_ty2
1170         skolem_details        -> mis_match
1171   where
1172     mis_match = unifyMisMatch outer swapped (TyVarTy tv1) ps_ty2
1173
1174 ----------------
1175 uMetaVar :: Bool
1176          -> TcTyVar -> BoxInfo -> IORef MetaDetails
1177          -> TcType -> TcType
1178          -> TcM ()
1179 -- tv1 is an un-filled-in meta type variable (maybe boxy, maybe tau)
1180 -- ty2 is not a type variable
1181
1182 uMetaVar swapped tv1 BoxTv ref1 ps_ty2 non_var_ty2
1183   =     -- tv1 is a BoxTv.  So we must unbox ty2, to ensure
1184         -- that any boxes in ty2 are filled with monotypes
1185         --
1186         -- It should not be the case that tv1 occurs in ty2
1187         -- (i.e. no occurs check should be needed), but if perchance
1188         -- it does, the unbox operation will fill it, and the DEBUG
1189         -- checks for that.
1190     do  { final_ty <- unBox ps_ty2
1191 #ifdef DEBUG
1192         ; meta_details <- readMutVar ref1
1193         ; case meta_details of
1194             Indirect ty -> WARN( True, ppr tv1 <+> ppr ty )
1195                            return ()    -- This really should *not* happen
1196             Flexi       -> return ()
1197 #endif
1198         ; checkUpdateMeta swapped tv1 ref1 final_ty }
1199
1200 uMetaVar swapped tv1 info1 ref1 ps_ty2 non_var_ty2
1201   = do  { final_ty <- checkTauTvUpdate tv1 ps_ty2       -- Occurs check + monotype check
1202         ; checkUpdateMeta swapped tv1 ref1 final_ty }
1203
1204 ----------------
1205 uUnfilledVars :: Outer
1206               -> Bool                   -- Args are swapped
1207               -> TcTyVar -> TcTyVarDetails      -- Tyvar 1
1208               -> TcTyVar -> TcTyVarDetails      -- Tyvar 2
1209               -> TcM ()
1210 -- Invarant: The type variables are distinct,
1211 --           Neither is filled in yet
1212 --           They might be boxy or not
1213
1214 uUnfilledVars outer swapped tv1 (SkolemTv _) tv2 (SkolemTv _)
1215   = unifyMisMatch outer swapped (mkTyVarTy tv1) (mkTyVarTy tv2)
1216
1217 uUnfilledVars outer swapped tv1 (MetaTv info1 ref1) tv2 (SkolemTv _)
1218   = checkUpdateMeta swapped tv1 ref1 (mkTyVarTy tv2)
1219 uUnfilledVars outer swapped tv1 (SkolemTv _) tv2 (MetaTv info2 ref2)
1220   = checkUpdateMeta (not swapped) tv2 ref2 (mkTyVarTy tv1)
1221
1222 -- ToDo: this function seems too long for what it acutally does!
1223 uUnfilledVars outer swapped tv1 (MetaTv info1 ref1) tv2 (MetaTv info2 ref2)
1224   = case (info1, info2) of
1225         (BoxTv,   BoxTv)   -> box_meets_box
1226
1227         -- If a box meets a TauTv, but the fomer has the smaller kind
1228         -- then we must create a fresh TauTv with the smaller kind
1229         (_,       BoxTv)   | k1_sub_k2 -> update_tv2
1230                            | otherwise -> box_meets_box
1231         (BoxTv,   _    )   | k2_sub_k1 -> update_tv1
1232                            | otherwise -> box_meets_box
1233
1234         -- Avoid SigTvs if poss
1235         (SigTv _, _      ) | k1_sub_k2 -> update_tv2
1236         (_,       SigTv _) | k2_sub_k1 -> update_tv1
1237
1238         (_,   _) | k1_sub_k2 -> if k2_sub_k1 && nicer_to_update_tv1
1239                                 then update_tv1         -- Same kinds
1240                                 else update_tv2
1241                  | k2_sub_k1 -> update_tv1
1242                  | otherwise -> kind_err
1243
1244         -- Update the variable with least kind info
1245         -- See notes on type inference in Kind.lhs
1246         -- The "nicer to" part only applies if the two kinds are the same,
1247         -- so we can choose which to do.
1248   where
1249         -- Kinds should be guaranteed ok at this point
1250     update_tv1 = updateMeta tv1 ref1 (mkTyVarTy tv2)
1251     update_tv2 = updateMeta tv2 ref2 (mkTyVarTy tv1)
1252
1253     box_meets_box | k1_sub_k2 = if k2_sub_k1 && nicer_to_update_tv1
1254                                 then fill_from tv2
1255                                 else fill_from tv1
1256                   | k2_sub_k1 = fill_from tv2
1257                   | otherwise = kind_err
1258
1259         -- Update *both* tyvars with a TauTv whose name and kind
1260         -- are gotten from tv (avoid losing nice names is poss)
1261     fill_from tv = do { tv' <- tcInstTyVar tv
1262                       ; let tau_ty = mkTyVarTy tv'
1263                       ; updateMeta tv1 ref1 tau_ty
1264                       ; updateMeta tv2 ref2 tau_ty }
1265
1266     kind_err = addErrCtxtM (unifyKindCtxt swapped tv1 (mkTyVarTy tv2))  $
1267                unifyKindMisMatch k1 k2
1268
1269     k1 = tyVarKind tv1
1270     k2 = tyVarKind tv2
1271     k1_sub_k2 = k1 `isSubKind` k2
1272     k2_sub_k1 = k2 `isSubKind` k1
1273
1274     nicer_to_update_tv1 = isSystemName (Var.varName tv1)
1275         -- Try to update sys-y type variables in preference to ones
1276         -- gotten (say) by instantiating a polymorphic function with
1277         -- a user-written type sig
1278
1279 ----------------
1280 checkUpdateMeta :: Bool -> TcTyVar -> IORef MetaDetails -> TcType -> TcM ()
1281 -- Update tv1, which is flexi; occurs check is alrady done
1282 -- The 'check' version does a kind check too
1283 -- We do a sub-kind check here: we might unify (a b) with (c d)
1284 --      where b::*->* and d::*; this should fail
1285
1286 checkUpdateMeta swapped tv1 ref1 ty2
1287   = do  { checkKinds swapped tv1 ty2
1288         ; updateMeta tv1 ref1 ty2 }
1289
1290 updateMeta :: TcTyVar -> IORef MetaDetails -> TcType -> TcM ()
1291 updateMeta tv1 ref1 ty2
1292   = ASSERT( isMetaTyVar tv1 )
1293     ASSERT( isBoxyTyVar tv1 || isTauTy ty2 )
1294     do  { ASSERTM2( do { details <- readMetaTyVar tv1; return (isFlexi details) }, ppr tv1 )
1295         ; traceTc (text "updateMeta" <+> ppr tv1 <+> text ":=" <+> ppr ty2)
1296         ; writeMutVar ref1 (Indirect ty2) }
1297
1298 ----------------
1299 checkKinds swapped tv1 ty2
1300 -- We're about to unify a type variable tv1 with a non-tyvar-type ty2.
1301 -- ty2 has been zonked at this stage, which ensures that
1302 -- its kind has as much boxity information visible as possible.
1303   | tk2 `isSubKind` tk1 = returnM ()
1304
1305   | otherwise
1306         -- Either the kinds aren't compatible
1307         --      (can happen if we unify (a b) with (c d))
1308         -- or we are unifying a lifted type variable with an
1309         --      unlifted type: e.g.  (id 3#) is illegal
1310   = addErrCtxtM (unifyKindCtxt swapped tv1 ty2) $
1311     unifyKindMisMatch k1 k2
1312   where
1313     (k1,k2) | swapped   = (tk2,tk1)
1314             | otherwise = (tk1,tk2)
1315     tk1 = tyVarKind tv1
1316     tk2 = typeKind ty2
1317
1318 ----------------
1319 checkTauTvUpdate :: TcTyVar -> TcType -> TcM TcType
1320 --    (checkTauTvUpdate tv ty)
1321 -- We are about to update the TauTv tv with ty.
1322 -- Check (a) that tv doesn't occur in ty (occurs check)
1323 --       (b) that ty is a monotype
1324 -- Furthermore, in the interest of (b), if you find an
1325 -- empty box (BoxTv that is Flexi), fill it in with a TauTv
1326 --
1327 -- Returns the (non-boxy) type to update the type variable with, or fails
1328
1329 checkTauTvUpdate orig_tv orig_ty
1330   = go orig_ty
1331   where
1332     go (TyConApp tc tys)
1333         | isSynTyCon tc  = go_syn tc tys
1334         | otherwise      = do { tys' <- mappM go tys; return (TyConApp tc tys') }
1335     go (NoteTy _ ty2)    = go ty2       -- Discard free-tyvar annotations
1336     go (PredTy p)        = do { p' <- go_pred p; return (PredTy p') }
1337     go (FunTy arg res)   = do { arg' <- go arg; res' <- go res; return (FunTy arg' res') }
1338     go (AppTy fun arg)   = do { fun' <- go fun; arg' <- go arg; return (mkAppTy fun' arg') }
1339                 -- NB the mkAppTy; we might have instantiated a
1340                 -- type variable to a type constructor, so we need
1341                 -- to pull the TyConApp to the top.
1342     go (ForAllTy tv ty) = notMonoType orig_ty           -- (b)
1343
1344     go (TyVarTy tv)
1345         | orig_tv == tv = occurCheck tv orig_ty         -- (a)
1346         | isTcTyVar tv  = go_tyvar tv (tcTyVarDetails tv)
1347         | otherwise     = return (TyVarTy tv)
1348                  -- Ordinary (non Tc) tyvars
1349                  -- occur inside quantified types
1350
1351     go_pred (ClassP c tys) = do { tys' <- mapM go tys; return (ClassP c tys') }
1352     go_pred (IParam n ty)  = do { ty' <- go ty;        return (IParam n ty') }
1353     go_pred (EqPred t1 t2) = do { t1' <- go t1; t2' <- go t2; return (EqPred t1' t2') }
1354
1355     go_tyvar tv (SkolemTv _) = return (TyVarTy tv)
1356     go_tyvar tv (MetaTv box ref)
1357         = do { cts <- readMutVar ref
1358              ; case cts of
1359                   Indirect ty -> go ty
1360                   Flexi -> case box of
1361                                 BoxTv -> fillBoxWithTau tv ref
1362                                 other -> return (TyVarTy tv)
1363              }
1364
1365         -- go_syn is called for synonyms only
1366         -- See Note [Type synonyms and the occur check]
1367     go_syn tc tys
1368         | not (isTauTyCon tc)
1369         = notMonoType orig_ty   -- (b) again
1370         | otherwise
1371         = do { (msgs, mb_tys') <- tryTc (mapM go tys)
1372              ; case mb_tys' of
1373                 Just tys' -> return (TyConApp tc tys')
1374                                 -- Retain the synonym (the common case)
1375                 Nothing | isOpenTyCon tc
1376                           -> notMonoArgs (TyConApp tc tys)
1377                                 -- Synonym families must have monotype args
1378                         | otherwise
1379                           -> go (expectJust "checkTauTvUpdate"
1380                                         (tcView (TyConApp tc tys)))
1381                                 -- Try again, expanding the synonym
1382              }
1383
1384 fillBoxWithTau :: BoxyTyVar -> IORef MetaDetails -> TcM TcType
1385 -- (fillBoxWithTau tv ref) fills ref with a freshly allocated
1386 --  tau-type meta-variable, whose print-name is the same as tv
1387 -- Choosing the same name is good: when we instantiate a function
1388 -- we allocate boxy tyvars with the same print-name as the quantified
1389 -- tyvar; and then we often fill the box with a tau-tyvar, and again
1390 -- we want to choose the same name.
1391 fillBoxWithTau tv ref
1392   = do  { tv' <- tcInstTyVar tv         -- Do not gratuitously forget
1393         ; let tau = mkTyVarTy tv'       -- name of the type variable
1394         ; writeMutVar ref (Indirect tau)
1395         ; return tau }
1396 \end{code}
1397
1398 Note [Type synonyms and the occur check]
1399 ~~~~~~~~~~~~~~~~~~~~
1400 Basically we want to update     tv1 := ps_ty2
1401 because ps_ty2 has type-synonym info, which improves later error messages
1402
1403 But consider
1404         type A a = ()
1405
1406         f :: (A a -> a -> ()) -> ()
1407         f = \ _ -> ()
1408
1409         x :: ()
1410         x = f (\ x p -> p x)
1411
1412 In the application (p x), we try to match "t" with "A t".  If we go
1413 ahead and bind t to A t (= ps_ty2), we'll lead the type checker into
1414 an infinite loop later.
1415 But we should not reject the program, because A t = ().
1416 Rather, we should bind t to () (= non_var_ty2).
1417
1418 \begin{code}
1419 refineBox :: TcType -> TcM TcType
1420 -- Unbox the outer box of a boxy type (if any)
1421 refineBox ty@(TyVarTy box_tv)
1422   | isMetaTyVar box_tv
1423   = do  { cts <- readMetaTyVar box_tv
1424         ; case cts of
1425                 Flexi       -> return ty
1426                 Indirect ty -> return ty }
1427 refineBox other_ty = return other_ty
1428
1429 refineBoxToTau :: TcType -> TcM TcType
1430 -- Unbox the outer box of a boxy type, filling with a monotype if it is empty
1431 -- Like refineBox except for the "fill with monotype" part.
1432 refineBoxToTau ty@(TyVarTy box_tv)
1433   | isMetaTyVar box_tv
1434   , MetaTv BoxTv ref <- tcTyVarDetails box_tv
1435   = do  { cts <- readMutVar ref
1436         ; case cts of
1437                 Flexi       -> fillBoxWithTau box_tv ref
1438                 Indirect ty -> return ty }
1439 refineBoxToTau other_ty = return other_ty
1440
1441 zapToMonotype :: BoxySigmaType -> TcM TcTauType
1442 -- Subtle... we must zap the boxy res_ty
1443 -- to kind * before using it to instantiate a LitInst
1444 -- Calling unBox instead doesn't do the job, because the box
1445 -- often has an openTypeKind, and we don't want to instantiate
1446 -- with that type.
1447 zapToMonotype res_ty
1448   = do  { res_tau <- newFlexiTyVarTy liftedTypeKind
1449         ; boxyUnify res_tau res_ty
1450         ; return res_tau }
1451
1452 unBox :: BoxyType -> TcM TcType
1453 -- unBox implements the judgement
1454 --      |- s' ~ box(s)
1455 -- with input s', and result s
1456 --
1457 -- It removes all boxes from the input type, returning a non-boxy type.
1458 -- A filled box in the type can only contain a monotype; unBox fails if not
1459 -- The type can have empty boxes, which unBox fills with a monotype
1460 --
1461 -- Compare this wth checkTauTvUpdate
1462 --
1463 -- For once, it's safe to treat synonyms as opaque!
1464
1465 unBox (NoteTy n ty)     = do { ty' <- unBox ty; return (NoteTy n ty') }
1466 unBox (TyConApp tc tys) = do { tys' <- mapM unBox tys; return (TyConApp tc tys') }
1467 unBox (AppTy f a)       = do { f' <- unBox f; a' <- unBox a; return (mkAppTy f' a') }
1468 unBox (FunTy f a)       = do { f' <- unBox f; a' <- unBox a; return (FunTy f' a') }
1469 unBox (PredTy p)        = do { p' <- unBoxPred p; return (PredTy p') }
1470 unBox (ForAllTy tv ty)  = ASSERT( isImmutableTyVar tv )
1471                           do { ty' <- unBox ty; return (ForAllTy tv ty') }
1472 unBox (TyVarTy tv)
1473   | isTcTyVar tv                                -- It's a boxy type variable
1474   , MetaTv BoxTv ref <- tcTyVarDetails tv       -- NB: non-TcTyVars are possible
1475   = do  { cts <- readMutVar ref                 --     under nested quantifiers
1476         ; case cts of
1477             Flexi       -> fillBoxWithTau tv ref
1478             Indirect ty -> do { non_boxy_ty <- unBox ty
1479                               ; if isTauTy non_boxy_ty
1480                                 then return non_boxy_ty
1481                                 else notMonoType non_boxy_ty }
1482         }
1483   | otherwise   -- Skolems, and meta-tau-variables
1484   = return (TyVarTy tv)
1485
1486 unBoxPred (ClassP cls tys) = do { tys' <- mapM unBox tys; return (ClassP cls tys') }
1487 unBoxPred (IParam ip ty)   = do { ty' <- unBox ty; return (IParam ip ty') }
1488 unBoxPred (EqPred ty1 ty2) = do { ty1' <- unBox ty1; ty2' <- unBox ty2; return (EqPred ty1' ty2') }
1489 \end{code}
1490
1491
1492
1493 %************************************************************************
1494 %*                                                                      *
1495 \subsection[Unify-context]{Errors and contexts}
1496 %*                                                                      *
1497 %************************************************************************
1498
1499 Errors
1500 ~~~~~~
1501
1502 \begin{code}
1503 unifyCtxt act_ty exp_ty tidy_env
1504   = do  { act_ty' <- zonkTcType act_ty
1505         ; exp_ty' <- zonkTcType exp_ty
1506         ; let (env1, exp_ty'') = tidyOpenType tidy_env exp_ty'
1507               (env2, act_ty'') = tidyOpenType env1     act_ty'
1508         ; return (env2, mkExpectedActualMsg act_ty'' exp_ty'') }
1509
1510 ----------------
1511 mkExpectedActualMsg act_ty exp_ty
1512   = nest 2 (vcat [ text "Expected type" <> colon <+> ppr exp_ty,
1513                    text "Inferred type" <> colon <+> ppr act_ty ])
1514
1515 ----------------
1516 -- If an error happens we try to figure out whether the function
1517 -- function has been given too many or too few arguments, and say so.
1518 addSubCtxt SubDone actual_res_ty expected_res_ty thing_inside
1519   = thing_inside
1520 addSubCtxt sub_ctxt actual_res_ty expected_res_ty thing_inside
1521   = addErrCtxtM mk_err thing_inside
1522   where
1523     mk_err tidy_env
1524       = do { exp_ty' <- zonkTcType expected_res_ty
1525            ; act_ty' <- zonkTcType actual_res_ty
1526            ; let (env1, exp_ty'') = tidyOpenType tidy_env exp_ty'
1527                  (env2, act_ty'') = tidyOpenType env1     act_ty'
1528                  (exp_args, _)    = tcSplitFunTys exp_ty''
1529                  (act_args, _)    = tcSplitFunTys act_ty''
1530
1531                  len_act_args     = length act_args
1532                  len_exp_args     = length exp_args
1533
1534                  message = case sub_ctxt of
1535                           SubFun fun | len_exp_args < len_act_args -> wrongArgsCtxt "too few"  fun
1536                                      | len_exp_args > len_act_args -> wrongArgsCtxt "too many" fun
1537                           other -> mkExpectedActualMsg act_ty'' exp_ty''
1538            ; return (env2, message) }
1539
1540     wrongArgsCtxt too_many_or_few fun
1541       = ptext SLIT("Probable cause:") <+> quotes (ppr fun)
1542         <+> ptext SLIT("is applied to") <+> text too_many_or_few
1543         <+> ptext SLIT("arguments")
1544
1545 ------------------
1546 unifyForAllCtxt tvs phi1 phi2 env
1547   = returnM (env2, msg)
1548   where
1549     (env', tvs') = tidyOpenTyVars env tvs       -- NB: not tidyTyVarBndrs
1550     (env1, phi1') = tidyOpenType env' phi1
1551     (env2, phi2') = tidyOpenType env1 phi2
1552     msg = vcat [ptext SLIT("When matching") <+> quotes (ppr (mkForAllTys tvs' phi1')),
1553                 ptext SLIT("          and") <+> quotes (ppr (mkForAllTys tvs' phi2'))]
1554
1555 ------------------
1556 unifyKindCtxt swapped tv1 ty2 tidy_env  -- not swapped => tv1 expected, ty2 inferred
1557         -- tv1 and ty2 are zonked already
1558   = returnM msg
1559   where
1560     msg = (env2, ptext SLIT("When matching the kinds of") <+>
1561                  sep [quotes pp_expected <+> ptext SLIT("and"), quotes pp_actual])
1562
1563     (pp_expected, pp_actual) | swapped   = (pp2, pp1)
1564                              | otherwise = (pp1, pp2)
1565     (env1, tv1') = tidyOpenTyVar tidy_env tv1
1566     (env2, ty2') = tidyOpenType  env1 ty2
1567     pp1 = ppr tv1' <+> dcolon <+> ppr (tyVarKind tv1)
1568     pp2 = ppr ty2' <+> dcolon <+> ppr (typeKind ty2)
1569
1570 unifyMisMatch outer swapped ty1 ty2
1571   = do  { (env, msg) <- if swapped then misMatchMsg ty1 ty2
1572                                    else misMatchMsg ty2 ty1
1573
1574         -- This is the whole point of the 'outer' stuff
1575         ; if outer then popErrCtxt (failWithTcM (env, msg))
1576                    else failWithTcM (env, msg)
1577         }
1578
1579 misMatchMsg ty1 ty2
1580   = do  { env0 <- tcInitTidyEnv
1581         ; (env1, pp1, extra1) <- ppr_ty env0 ty1
1582         ; (env2, pp2, extra2) <- ppr_ty env1 ty2
1583         ; return (env2, sep [sep [ptext SLIT("Couldn't match expected type") <+> pp1,
1584                                   nest 7 (ptext SLIT("against inferred type") <+> pp2)],
1585                              nest 2 extra1, nest 2 extra2]) }
1586
1587 ppr_ty :: TidyEnv -> TcType -> TcM (TidyEnv, SDoc, SDoc)
1588 ppr_ty env ty
1589   = do { ty' <- zonkTcType ty
1590        ; let (env1,tidy_ty) = tidyOpenType env ty'
1591              simple_result  = (env1, quotes (ppr tidy_ty), empty)
1592        ; case tidy_ty of
1593            TyVarTy tv
1594                 | isSkolemTyVar tv || isSigTyVar tv
1595                 -> return (env2, pp_rigid tv', pprSkolTvBinding tv')
1596                 | otherwise -> return simple_result
1597                 where
1598                   (env2, tv') = tidySkolemTyVar env1 tv
1599            other -> return simple_result }
1600   where
1601     pp_rigid tv = quotes (ppr tv) <+> parens (ptext SLIT("a rigid variable"))
1602
1603
1604 notMonoType ty
1605   = do  { ty' <- zonkTcType ty
1606         ; env0 <- tcInitTidyEnv
1607         ; let (env1, tidy_ty) = tidyOpenType env0 ty'
1608               msg = ptext SLIT("Cannot match a monotype with") <+> quotes (ppr tidy_ty)
1609         ; failWithTcM (env1, msg) }
1610
1611 notMonoArgs ty
1612   = do  { ty' <- zonkTcType ty
1613         ; env0 <- tcInitTidyEnv
1614         ; let (env1, tidy_ty) = tidyOpenType env0 ty'
1615               msg = ptext SLIT("Arguments of synonym family must be monotypes") <+> quotes (ppr tidy_ty)
1616         ; failWithTcM (env1, msg) }
1617
1618 occurCheck tyvar ty
1619   = do  { env0 <- tcInitTidyEnv
1620         ; ty'  <- zonkTcType ty
1621         ; let (env1, tidy_tyvar) = tidyOpenTyVar env0 tyvar
1622               (env2, tidy_ty)    = tidyOpenType  env1 ty'
1623               extra = sep [ppr tidy_tyvar, char '=', ppr tidy_ty]
1624         ; failWithTcM (env2, hang msg 2 extra) }
1625   where
1626     msg = ptext SLIT("Occurs check: cannot construct the infinite type:")
1627 \end{code}
1628
1629
1630 %************************************************************************
1631 %*                                                                      *
1632                 Kind unification
1633 %*                                                                      *
1634 %************************************************************************
1635
1636 Unifying kinds is much, much simpler than unifying types.
1637
1638 \begin{code}
1639 unifyKind :: TcKind                 -- Expected
1640           -> TcKind                 -- Actual
1641           -> TcM ()
1642 unifyKind (TyConApp kc1 []) (TyConApp kc2 [])
1643   | isSubKindCon kc2 kc1 = returnM ()
1644
1645 unifyKind (FunTy a1 r1) (FunTy a2 r2)
1646   = do { unifyKind a2 a1; unifyKind r1 r2 }
1647                 -- Notice the flip in the argument,
1648                 -- so that the sub-kinding works right
1649 unifyKind (TyVarTy kv1) k2 = uKVar False kv1 k2
1650 unifyKind k1 (TyVarTy kv2) = uKVar True kv2 k1
1651 unifyKind k1 k2 = unifyKindMisMatch k1 k2
1652
1653 unifyKinds :: [TcKind] -> [TcKind] -> TcM ()
1654 unifyKinds []       []       = returnM ()
1655 unifyKinds (k1:ks1) (k2:ks2) = unifyKind k1 k2  `thenM_`
1656                                unifyKinds ks1 ks2
1657 unifyKinds _ _               = panic "unifyKinds: length mis-match"
1658
1659 ----------------
1660 uKVar :: Bool -> KindVar -> TcKind -> TcM ()
1661 uKVar swapped kv1 k2
1662   = do  { mb_k1 <- readKindVar kv1
1663         ; case mb_k1 of
1664             Flexi -> uUnboundKVar swapped kv1 k2
1665             Indirect k1 | swapped   -> unifyKind k2 k1
1666                         | otherwise -> unifyKind k1 k2 }
1667
1668 ----------------
1669 uUnboundKVar :: Bool -> KindVar -> TcKind -> TcM ()
1670 uUnboundKVar swapped kv1 k2@(TyVarTy kv2)
1671   | kv1 == kv2 = returnM ()
1672   | otherwise   -- Distinct kind variables
1673   = do  { mb_k2 <- readKindVar kv2
1674         ; case mb_k2 of
1675             Indirect k2 -> uUnboundKVar swapped kv1 k2
1676             Flexi       -> writeKindVar kv1 k2 }
1677
1678 uUnboundKVar swapped kv1 non_var_k2
1679   = do  { k2' <- zonkTcKind non_var_k2
1680         ; kindOccurCheck kv1 k2'
1681         ; k2'' <- kindSimpleKind swapped k2'
1682                 -- KindVars must be bound only to simple kinds
1683                 -- Polarities: (kindSimpleKind True ?) succeeds
1684                 -- returning *, corresponding to unifying
1685                 --      expected: ?
1686                 --      actual:   kind-ver
1687         ; writeKindVar kv1 k2'' }
1688
1689 ----------------
1690 kindOccurCheck kv1 k2   -- k2 is zonked
1691   = checkTc (not_in k2) (kindOccurCheckErr kv1 k2)
1692   where
1693     not_in (TyVarTy kv2)   = kv1 /= kv2
1694     not_in (FunTy a2 r2) = not_in a2 && not_in r2
1695     not_in other         = True
1696
1697 kindSimpleKind :: Bool -> Kind -> TcM SimpleKind
1698 -- (kindSimpleKind True k) returns a simple kind sk such that sk <: k
1699 -- If the flag is False, it requires k <: sk
1700 -- E.g.         kindSimpleKind False ?? = *
1701 -- What about (kv -> *) :=: ?? -> *
1702 kindSimpleKind orig_swapped orig_kind
1703   = go orig_swapped orig_kind
1704   where
1705     go sw (FunTy k1 k2) = do { k1' <- go (not sw) k1
1706                              ; k2' <- go sw k2
1707                              ; return (mkArrowKind k1' k2') }
1708     go True k
1709      | isOpenTypeKind k = return liftedTypeKind
1710      | isArgTypeKind k  = return liftedTypeKind
1711     go sw k
1712      | isLiftedTypeKind k   = return liftedTypeKind
1713      | isUnliftedTypeKind k = return unliftedTypeKind
1714     go sw k@(TyVarTy _)   = return k    -- KindVars are always simple
1715     go swapped kind = failWithTc (ptext SLIT("Unexpected kind unification failure:")
1716                                   <+> ppr orig_swapped <+> ppr orig_kind)
1717         -- I think this can't actually happen
1718
1719 -- T v = MkT v           v must be a type
1720 -- T v w = MkT (v -> w)  v must not be an umboxed tuple
1721
1722 ----------------
1723 kindOccurCheckErr tyvar ty
1724   = hang (ptext SLIT("Occurs check: cannot construct the infinite kind:"))
1725        2 (sep [ppr tyvar, char '=', ppr ty])
1726
1727 unifyKindMisMatch ty1 ty2
1728   = zonkTcKind ty1      `thenM` \ ty1' ->
1729     zonkTcKind ty2      `thenM` \ ty2' ->
1730     let
1731         msg = hang (ptext SLIT("Couldn't match kind"))
1732                    2 (sep [quotes (ppr ty1'),
1733                            ptext SLIT("against"),
1734                            quotes (ppr ty2')])
1735     in
1736     failWithTc msg
1737 \end{code}
1738
1739 \begin{code}
1740 unifyFunKind :: TcKind -> TcM (Maybe (TcKind, TcKind))
1741 -- Like unifyFunTy, but does not fail; instead just returns Nothing
1742
1743 unifyFunKind (TyVarTy kvar)
1744   = readKindVar kvar `thenM` \ maybe_kind ->
1745     case maybe_kind of
1746       Indirect fun_kind -> unifyFunKind fun_kind
1747       Flexi             ->
1748           do { arg_kind <- newKindVar
1749              ; res_kind <- newKindVar
1750              ; writeKindVar kvar (mkArrowKind arg_kind res_kind)
1751              ; returnM (Just (arg_kind,res_kind)) }
1752
1753 unifyFunKind (FunTy arg_kind res_kind) = returnM (Just (arg_kind,res_kind))
1754 unifyFunKind other                     = returnM Nothing
1755 \end{code}
1756
1757 %************************************************************************
1758 %*                                                                      *
1759         Checking kinds
1760 %*                                                                      *
1761 %************************************************************************
1762
1763 ---------------------------
1764 -- We would like to get a decent error message from
1765 --   (a) Under-applied type constructors
1766 --              f :: (Maybe, Maybe)
1767 --   (b) Over-applied type constructors
1768 --              f :: Int x -> Int x
1769 --
1770
1771 \begin{code}
1772 checkExpectedKind :: Outputable a => a -> TcKind -> TcKind -> TcM ()
1773 -- A fancy wrapper for 'unifyKind', which tries
1774 -- to give decent error messages.
1775 checkExpectedKind ty act_kind exp_kind
1776   | act_kind `isSubKind` exp_kind -- Short cut for a very common case
1777   = returnM ()
1778   | otherwise
1779   = tryTc (unifyKind exp_kind act_kind) `thenM` \ (_errs, mb_r) ->
1780     case mb_r of {
1781         Just r  -> returnM () ; -- Unification succeeded
1782         Nothing ->
1783
1784         -- So there's definitely an error
1785         -- Now to find out what sort
1786     zonkTcKind exp_kind         `thenM` \ exp_kind ->
1787     zonkTcKind act_kind         `thenM` \ act_kind ->
1788
1789     tcInitTidyEnv               `thenM` \ env0 ->
1790     let (exp_as, _) = splitKindFunTys exp_kind
1791         (act_as, _) = splitKindFunTys act_kind
1792         n_exp_as = length exp_as
1793         n_act_as = length act_as
1794
1795         (env1, tidy_exp_kind) = tidyKind env0 exp_kind
1796         (env2, tidy_act_kind) = tidyKind env1 act_kind
1797
1798         err | n_exp_as < n_act_as       -- E.g. [Maybe]
1799             = quotes (ppr ty) <+> ptext SLIT("is not applied to enough type arguments")
1800
1801                 -- Now n_exp_as >= n_act_as. In the next two cases,
1802                 -- n_exp_as == 0, and hence so is n_act_as
1803             | isLiftedTypeKind exp_kind && isUnliftedTypeKind act_kind
1804             = ptext SLIT("Expecting a lifted type, but") <+> quotes (ppr ty)
1805                 <+> ptext SLIT("is unlifted")
1806
1807             | isUnliftedTypeKind exp_kind && isLiftedTypeKind act_kind
1808             = ptext SLIT("Expecting an unlifted type, but") <+> quotes (ppr ty)
1809                 <+> ptext SLIT("is lifted")
1810
1811             | otherwise                 -- E.g. Monad [Int]
1812             = ptext SLIT("Kind mis-match")
1813
1814         more_info = sep [ ptext SLIT("Expected kind") <+>
1815                                 quotes (pprKind tidy_exp_kind) <> comma,
1816                           ptext SLIT("but") <+> quotes (ppr ty) <+>
1817                                 ptext SLIT("has kind") <+> quotes (pprKind tidy_act_kind)]
1818    in
1819    failWithTcM (env2, err $$ more_info)
1820    }
1821 \end{code}
1822
1823 %************************************************************************
1824 %*                                                                      *
1825 \subsection{Checking signature type variables}
1826 %*                                                                      *
1827 %************************************************************************
1828
1829 @checkSigTyVars@ checks that a set of universally quantified type varaibles
1830 are not mentioned in the environment.  In particular:
1831
1832         (a) Not mentioned in the type of a variable in the envt
1833                 eg the signature for f in this:
1834
1835                         g x = ... where
1836                                         f :: a->[a]
1837                                         f y = [x,y]
1838
1839                 Here, f is forced to be monorphic by the free occurence of x.
1840
1841         (d) Not (unified with another type variable that is) in scope.
1842                 eg f x :: (r->r) = (\y->y) :: forall a. a->r
1843             when checking the expression type signature, we find that
1844             even though there is nothing in scope whose type mentions r,
1845             nevertheless the type signature for the expression isn't right.
1846
1847             Another example is in a class or instance declaration:
1848                 class C a where
1849                    op :: forall b. a -> b
1850                    op x = x
1851             Here, b gets unified with a
1852
1853 Before doing this, the substitution is applied to the signature type variable.
1854
1855 \begin{code}
1856 checkSigTyVars :: [TcTyVar] -> TcM ()
1857 checkSigTyVars sig_tvs = check_sig_tyvars emptyVarSet sig_tvs
1858
1859 checkSigTyVarsWrt :: TcTyVarSet -> [TcTyVar] -> TcM ()
1860 -- The extra_tvs can include boxy type variables;
1861 --      e.g. TcMatches.tcCheckExistentialPat
1862 checkSigTyVarsWrt extra_tvs sig_tvs
1863   = do  { extra_tvs' <- zonkTcTyVarsAndFV (varSetElems extra_tvs)
1864         ; check_sig_tyvars extra_tvs' sig_tvs }
1865
1866 check_sig_tyvars
1867         :: TcTyVarSet   -- Global type variables. The universally quantified
1868                         --      tyvars should not mention any of these
1869                         --      Guaranteed already zonked.
1870         -> [TcTyVar]    -- Universally-quantified type variables in the signature
1871                         --      Guaranteed to be skolems
1872         -> TcM ()
1873 check_sig_tyvars extra_tvs []
1874   = returnM ()
1875 check_sig_tyvars extra_tvs sig_tvs
1876   = ASSERT( all isSkolemTyVar sig_tvs )
1877     do  { gbl_tvs <- tcGetGlobalTyVars
1878         ; traceTc (text "check_sig_tyvars" <+> (vcat [text "sig_tys" <+> ppr sig_tvs,
1879                                       text "gbl_tvs" <+> ppr gbl_tvs,
1880                                       text "extra_tvs" <+> ppr extra_tvs]))
1881
1882         ; let env_tvs = gbl_tvs `unionVarSet` extra_tvs
1883         ; ifM (any (`elemVarSet` env_tvs) sig_tvs)
1884               (bleatEscapedTvs env_tvs sig_tvs sig_tvs)
1885         }
1886
1887 bleatEscapedTvs :: TcTyVarSet   -- The global tvs
1888                 -> [TcTyVar]    -- The possibly-escaping type variables
1889                 -> [TcTyVar]    -- The zonked versions thereof
1890                 -> TcM ()
1891 -- Complain about escaping type variables
1892 -- We pass a list of type variables, at least one of which
1893 -- escapes.  The first list contains the original signature type variable,
1894 -- while the second  contains the type variable it is unified to (usually itself)
1895 bleatEscapedTvs globals sig_tvs zonked_tvs
1896   = do  { env0 <- tcInitTidyEnv
1897         ; let (env1, tidy_tvs)        = tidyOpenTyVars env0 sig_tvs
1898               (env2, tidy_zonked_tvs) = tidyOpenTyVars env1 zonked_tvs
1899
1900         ; (env3, msgs) <- foldlM check (env2, []) (tidy_tvs `zip` tidy_zonked_tvs)
1901         ; failWithTcM (env3, main_msg $$ nest 2 (vcat msgs)) }
1902   where
1903     main_msg = ptext SLIT("Inferred type is less polymorphic than expected")
1904
1905     check (tidy_env, msgs) (sig_tv, zonked_tv)
1906       | not (zonked_tv `elemVarSet` globals) = return (tidy_env, msgs)
1907       | otherwise
1908       = do { (tidy_env1, globs) <- findGlobals (unitVarSet zonked_tv) tidy_env
1909            ; returnM (tidy_env1, escape_msg sig_tv zonked_tv globs : msgs) }
1910
1911 -----------------------
1912 escape_msg sig_tv zonked_tv globs
1913   | notNull globs
1914   = vcat [sep [msg, ptext SLIT("is mentioned in the environment:")],
1915           nest 2 (vcat globs)]
1916   | otherwise
1917   = msg <+> ptext SLIT("escapes")
1918         -- Sigh.  It's really hard to give a good error message
1919         -- all the time.   One bad case is an existential pattern match.
1920         -- We rely on the "When..." context to help.
1921   where
1922     msg = ptext SLIT("Quantified type variable") <+> quotes (ppr sig_tv) <+> is_bound_to
1923     is_bound_to
1924         | sig_tv == zonked_tv = empty
1925         | otherwise = ptext SLIT("is unified with") <+> quotes (ppr zonked_tv) <+> ptext SLIT("which")
1926 \end{code}
1927
1928 These two context are used with checkSigTyVars
1929
1930 \begin{code}
1931 sigCtxt :: Id -> [TcTyVar] -> TcThetaType -> TcTauType
1932         -> TidyEnv -> TcM (TidyEnv, Message)
1933 sigCtxt id sig_tvs sig_theta sig_tau tidy_env
1934   = zonkTcType sig_tau          `thenM` \ actual_tau ->
1935     let
1936         (env1, tidy_sig_tvs)    = tidyOpenTyVars tidy_env sig_tvs
1937         (env2, tidy_sig_rho)    = tidyOpenType env1 (mkPhiTy sig_theta sig_tau)
1938         (env3, tidy_actual_tau) = tidyOpenType env2 actual_tau
1939         sub_msg = vcat [ptext SLIT("Signature type:    ") <+> pprType (mkForAllTys tidy_sig_tvs tidy_sig_rho),
1940                         ptext SLIT("Type to generalise:") <+> pprType tidy_actual_tau
1941                    ]
1942         msg = vcat [ptext SLIT("When trying to generalise the type inferred for") <+> quotes (ppr id),
1943                     nest 2 sub_msg]
1944     in
1945     returnM (env3, msg)
1946 \end{code}