compiler/types/Coercion.lhs

   1
   2  Module for type coercions, as in System FC.
   3
   4 Coercions are represented as types, and their kinds tell what types the
   5 coercion works on.
   6
   7 The coercion kind constructor is a special TyCon that must always be saturated
   8
   9   typeKind (symCoercion type) :: TyConApp CoercionTyCon{...} [type, type]
  10
  11 \begin{code}
  12 module Coercion (
  13         Coercion,
  14
  15         mkCoKind, mkReflCoKind, splitCoercionKind_maybe, splitCoercionKind,
  16         coercionKind, coercionKinds, coercionKindPredTy,
  17
  18         -- Equality predicates
  19         isEqPred, mkEqPred, getEqPredTys, isEqPredTy,
  20
  21         -- Coercion transformations
  22         mkSymCoercion, mkTransCoercion,
  23         mkLeftCoercion, mkRightCoercion, mkInstCoercion, mkAppCoercion,
  24         mkForAllCoercion, mkFunCoercion, mkInstsCoercion, mkUnsafeCoercion,
  25         mkNewTypeCoercion, mkAppsCoercion,
  26
  27         splitNewTypeRepCo_maybe, decomposeCo,
  28
  29         unsafeCoercionTyCon, symCoercionTyCon,
  30         transCoercionTyCon, leftCoercionTyCon,
  31         rightCoercionTyCon, instCoercionTyCon -- needed by TysWiredIn
  32        ) where
  33
  34 #include "HsVersions.h"
  35
  36 import TypeRep
  37 import Type       ( Type, Kind, PredType, substTyWith, mkAppTy, mkForAllTy,
  38                     mkFunTy, splitAppTy_maybe, splitForAllTy_maybe, coreView,
  39                     kindView, mkTyConApp, isCoercionKind, isEqPred, mkAppTys,
  40                     coreEqType, splitAppTys, isTyVarTy, splitTyConApp_maybe
  41                   )
  42 import TyCon      ( TyCon, tyConArity, mkCoercionTyCon, isNewTyCon,
  43                     newTyConRhs, newTyConCo,
  44                     isCoercionTyCon, isCoercionTyCon_maybe )
  45 import Var        ( Var, TyVar, isTyVar, tyVarKind )
  46 import Name       ( BuiltInSyntax(..), Name, mkWiredInName, tcName )
  47 import OccName    ( mkOccNameFS )
  48 import PrelNames  ( symCoercionTyConKey,
  49                     transCoercionTyConKey, leftCoercionTyConKey,
  50                     rightCoercionTyConKey, instCoercionTyConKey,
  51                     unsafeCoercionTyConKey, gHC_PRIM
  52                   )
  53 import Util       ( lengthIs, snocView )
  54 import Unique     ( hasKey )
  55 import BasicTypes ( Arity )
  56 import Outputable
  57
  58
  59
  60 ------------------------------
  61 decomposeCo :: Arity -> Coercion -> [Coercion]
  62 -- (decomposeCo 3 c) = [right (left (left c)), right (left c), right c]
  63 -- So this breaks a coercion with kind T A B C :=: T D E F into
  64 -- a list of coercions of kinds A :=: D, B :=: E and E :=: F
  65 decomposeCo n co
  66   = go n co []
  67   where
  68     go 0 co cos = cos
  69     go n co cos = go (n-1) (mkLeftCoercion co)
  70                            (mkRightCoercion co : cos)
  71
  72 ------------------------------
  73
  74 -------------------------------------------------------
  75 -- and some coercion kind stuff
  76
  77 isEqPredTy (PredTy pred) = isEqPred pred
  78 isEqPredTy other         = False
  79
  80 mkEqPred :: (Type, Type) -> PredType
  81 mkEqPred (ty1, ty2) = EqPred ty1 ty2
  82
  83 getEqPredTys :: PredType -> (Type,Type)
  84 getEqPredTys (EqPred ty1 ty2) = (ty1, ty2)
  85 getEqPredTys other            = pprPanic "getEqPredTys" (ppr other)
  86
  87 mkCoKind :: Type -> Type -> CoercionKind
  88 mkCoKind ty1 ty2 = PredTy (EqPred ty1 ty2)
  89
  90 mkReflCoKind :: Type -> CoercionKind
  91 mkReflCoKind ty = mkCoKind ty ty
  92
  93 splitCoercionKind :: CoercionKind -> (Type, Type)
  94 splitCoercionKind co | Just co' <- kindView co = splitCoercionKind co'
  95 splitCoercionKind (PredTy (EqPred ty1 ty2))    = (ty1, ty2)
  96
  97 splitCoercionKind_maybe :: Kind -> Maybe (Type, Type)
  98 splitCoercionKind_maybe co | Just co' <- kindView co = splitCoercionKind_maybe co'
  99 splitCoercionKind_maybe (PredTy (EqPred ty1 ty2)) = Just (ty1, ty2)
 100 splitCoercionKind_maybe other = Nothing
 101
 102 isCoVar :: Var -> Bool
 103 isCoVar tv = isTyVar tv && isCoercionKind (tyVarKind tv)
 104
 105 type Coercion     = Type
 106 type CoercionKind = Kind        -- A CoercionKind is always of form (ty1 :=: ty2)
 107
 108 coercionKind :: Coercion -> (Type, Type)
 109 --      c :: (t1 :=: t2)
 110 -- Then (coercionKind c) = (t1,t2)
 111 coercionKind (TyVarTy a) | isCoVar a = splitCoercionKind (tyVarKind a)
 112                          | otherwise = let t = (TyVarTy a) in (t, t)
 113 coercionKind (AppTy ty1 ty2)
 114   = let (t1, t2) = coercionKind ty1
 115         (s1, s2) = coercionKind ty2 in
 116     (mkAppTy t1 s1, mkAppTy t2 s2)
 117 coercionKind (TyConApp tc args)
 118   | Just (ar, rule) <- isCoercionTyCon_maybe tc
 119     -- CoercionTyCons carry their kinding rule, so we use it here
 120   = if length args >= ar
 121     then splitCoercionKind (rule args)
 122     else pprPanic ("arity/arguments mismatch in coercionKind:")
 123              (ppr ar $$ ppr tc <+> ppr args)
 124   | otherwise
 125   = let (lArgs, rArgs) = coercionKinds args in
 126     (TyConApp tc lArgs, TyConApp tc rArgs)
 127 coercionKind (FunTy ty1 ty2)
 128   = let (t1, t2) = coercionKind ty1
 129         (s1, s2) = coercionKind ty2 in
 130     (mkFunTy t1 s1, mkFunTy t2 s2)
 131 coercionKind (ForAllTy tv ty)
 132   = let (ty1, ty2) = coercionKind ty in
 133     (ForAllTy tv ty1, ForAllTy tv ty2)
 134 coercionKind (NoteTy _ ty) = coercionKind ty
 135 coercionKind (PredTy (EqPred c1 c2))
 136   = let k1 = coercionKindPredTy c1
 137         k2 = coercionKindPredTy c2 in
 138     (k1,k2)
 139 coercionKind (PredTy (ClassP cl args))
 140   = let (lArgs, rArgs) = coercionKinds args in
 141     (PredTy (ClassP cl lArgs), PredTy (ClassP cl rArgs))
 142 coercionKind (PredTy (IParam name ty))
 143   = let (ty1, ty2) = coercionKind ty in
 144     (PredTy (IParam name ty1), PredTy (IParam name ty2))
 145
 146 coercionKindPredTy :: Coercion -> CoercionKind
 147 coercionKindPredTy c = let (t1, t2) = coercionKind c in mkCoKind t1 t2
 148
 149 coercionKinds :: [Coercion] -> ([Type], [Type])
 150 coercionKinds tys = unzip $ map coercionKind tys
 151
 152 -------------------------------------
 153 -- Coercion kind and type mk's
 154 -- (make saturated TyConApp CoercionTyCon{...} args)
 155
 156 mkCoercion coCon args = ASSERT( tyConArity coCon == length args )
 157                         TyConApp coCon args
 158
 159 mkAppCoercion, mkFunCoercion, mkTransCoercion, mkInstCoercion :: Coercion -> Coercion -> Coercion
 160 mkSymCoercion, mkLeftCoercion, mkRightCoercion :: Coercion -> Coercion
 161
 162 mkAppCoercion    co1 co2 = mkAppTy co1 co2
 163 mkAppsCoercion   co1 tys = foldl mkAppTy co1 tys
 164 -- note that a TyVar should be used here, not a CoVar (nor a TcTyVar)
 165 mkForAllCoercion tv  co  = ASSERT ( isTyVar tv ) mkForAllTy tv co
 166 mkFunCoercion    co1 co2 = mkFunTy co1 co2
 167
 168
 169 -- This smart constructor creates a sym'ed version its argument,
 170 -- but tries to push the sym's down to the leaves.  If we come to
 171 -- sym tv or sym tycon then we can drop the sym because tv and tycon
 172 -- are reflexive coercions
 173 mkSymCoercion co
 174   | Just co2 <- splitSymCoercion_maybe co = co2
 175      -- sym (sym co) --> co
 176   | Just (co1, arg_tys) <- splitTyConApp_maybe co
 177   , not (isCoercionTyCon co1) = mkTyConApp co1 (map mkSymCoercion arg_tys)
 178      -- we can drop the sym for a TyCon
 179      -- sym (ty [t1, ..., tn]) --> ty [sym t1, ..., sym tn]
 180   | (co1, arg_tys) <- splitAppTys co
 181   , isTyVarTy co1 = mkAppTys (maybe_drop co1) (map mkSymCoercion arg_tys)
 182      -- sym (tv [t1, ..., tn]) --> tv [sym t1, ..., sym tn]
 183      --   if tv type variable
 184      -- sym (cv [t1, ..., tn]) --> (sym cv) [sym t1, ..., sym tn]
 185      --   if cv is a coercion variable
 186      -- fall through if head is a CoercionTyCon
 187   | Just (co1, co2) <- splitTransCoercion_maybe co
 188      -- sym (co1 `trans` co2) --> (sym co2) `trans (sym co2)
 189   = mkTransCoercion (mkSymCoercion co2) (mkSymCoercion co1)
 190   | Just (co, ty) <- splitInstCoercion_maybe co
 191      -- sym (co @ ty) --> (sym co) @ ty
 192   = mkInstCoercion (mkSymCoercion co) ty
 193   | Just co <- splitLeftCoercion_maybe co
 194      -- sym (left co) --> left (sym co)
 195   = mkLeftCoercion (mkSymCoercion co)
 196   | Just co <- splitRightCoercion_maybe co
 197      -- sym (right co) --> right (sym co)
 198   = mkRightCoercion (mkSymCoercion co)
 199   where
 200     maybe_drop (TyVarTy tv)
 201         | isCoVar tv = mkCoercion symCoercionTyCon [TyVarTy tv]
 202         | otherwise  = TyVarTy tv
 203     maybe_drop other = other
 204 mkSymCoercion (ForAllTy tv ty) = ForAllTy tv (mkSymCoercion ty)
 205 -- for atomic types and constructors, we can just ignore sym since these
 206 -- are reflexive coercions
 207 mkSymCoercion (TyVarTy tv)
 208   | isCoVar tv = mkCoercion symCoercionTyCon [TyVarTy tv]
 209   | otherwise  = TyVarTy tv
 210 mkSymCoercion co = mkCoercion symCoercionTyCon [co]
 211
 212 -- Smart constructors for left and right
 213 mkLeftCoercion co
 214   | Just (co', _) <- splitAppCoercion_maybe co = co'
 215   | otherwise                            = mkCoercion leftCoercionTyCon [co]
 216
 217 mkRightCoercion  co
 218   | Just (co1, co2) <- splitAppCoercion_maybe co = co2
 219   | otherwise = mkCoercion rightCoercionTyCon [co]
 220
 221 mkTransCoercion co1 co2 = mkCoercion transCoercionTyCon [co1, co2]
 222
 223 mkInstCoercion  co ty = mkCoercion instCoercionTyCon  [co, ty]
 224
 225 mkInstsCoercion co tys = foldl mkInstCoercion co tys
 226
 227 splitSymCoercion_maybe :: Coercion -> Maybe Coercion
 228 splitSymCoercion_maybe (TyConApp tc [co]) =
 229   if tc `hasKey` symCoercionTyConKey
 230   then Just co
 231   else Nothing
 232 splitSymCoercion_maybe co = Nothing
 233
 234 splitAppCoercion_maybe :: Coercion -> Maybe (Coercion, Coercion)
 235 -- Splits a coercion application, being careful *not* to split (left c), etc
 236 -- which are really sytactic constructs, not applications
 237 splitAppCoercion_maybe co  | Just co' <- coreView co = splitAppCoercion_maybe co'
 238 splitAppCoercion_maybe (FunTy ty1 ty2)   = Just (TyConApp funTyCon [ty1], ty2)
 239 splitAppCoercion_maybe (AppTy ty1 ty2)   = Just (ty1, ty2)
 240 splitAppCoercion_maybe (TyConApp tc tys)
 241    | not (isCoercionTyCon tc)
 242    = case snocView tys of
 243        Just (tys', ty') -> Just (TyConApp tc tys', ty')
 244        Nothing          -> Nothing
 245 splitAppCoercion_maybe co = Nothing
 246
 247 splitTransCoercion_maybe :: Coercion -> Maybe (Coercion, Coercion)
 248 splitTransCoercion_maybe (TyConApp tc [ty1, ty2])
 249  = if tc `hasKey` transCoercionTyConKey then
 250        Just (ty1, ty2)
 251    else
 252        Nothing
 253 splitTransCoercion_maybe other = Nothing
 254
 255 splitInstCoercion_maybe :: Coercion -> Maybe (Coercion, Type)
 256 splitInstCoercion_maybe (TyConApp tc [ty1, ty2])
 257  = if tc `hasKey` instCoercionTyConKey then
 258        Just (ty1, ty2)
 259     else
 260        Nothing
 261 splitInstCoercion_maybe other = Nothing
 262
 263 splitLeftCoercion_maybe :: Coercion -> Maybe Coercion
 264 splitLeftCoercion_maybe (TyConApp tc [co])
 265  = if tc `hasKey` leftCoercionTyConKey then
 266        Just co
 267    else
 268        Nothing
 269 splitLeftCoercion_maybe other = Nothing
 270
 271 splitRightCoercion_maybe :: Coercion -> Maybe Coercion
 272 splitRightCoercion_maybe (TyConApp tc [co])
 273  = if tc `hasKey` rightCoercionTyConKey then
 274        Just co
 275    else
 276        Nothing
 277 splitRightCoercion_maybe other = Nothing
 278
 279 -- Unsafe coercion is not safe, it is used when we know we are dealing with
 280 -- bottom, which is the one case in which it is safe.  It is also used to
 281 -- implement the unsafeCoerce# primitive.
 282 mkUnsafeCoercion :: Type -> Type -> Coercion
 283 mkUnsafeCoercion ty1 ty2
 284   = mkCoercion unsafeCoercionTyCon [ty1, ty2]
 285
 286
 287 -- See note [Newtype coercions] in TyCon
 288 mkNewTypeCoercion :: Name -> TyCon -> [TyVar] -> Type -> TyCon
 289 mkNewTypeCoercion name tycon tvs rhs_ty
 290   = ASSERT (length tvs == tyConArity tycon)
 291     mkCoercionTyCon name (tyConArity tycon) rule
 292   where
 293     rule args = mkCoKind (TyConApp tycon args) (substTyWith tvs args rhs_ty)
 294
 295 --------------------------------------
 296 -- Coercion Type Constructors...
 297
 298 -- Example.  The coercion ((sym c) (sym d) (sym e))
 299 -- will be represented by (TyConApp sym [c, sym d, sym e])
 300 -- If sym c :: p1=q1
 301 --    sym d :: p2=q2
 302 --    sym e :: p3=q3
 303 -- then ((sym c) (sym d) (sym e)) :: (p1 p2 p3)=(q1 q2 q3)
 304 --
 305 -- (mkKindingFun f) is given the args [c, sym d, sym e]
 306 mkKindingFun :: ([Type] -> (Type, Type, [Type])) -> [Type] -> Kind
 307 mkKindingFun f args =
 308   let (ty1, ty2, rest) = f args in
 309   let (argtys1, argtys2) = unzip (map coercionKind rest) in
 310   mkCoKind (mkAppTys ty1 argtys1) (mkAppTys ty2 argtys2)
 311
 312
 313 symCoercionTyCon, transCoercionTyCon, leftCoercionTyCon, rightCoercionTyCon, instCoercionTyCon :: TyCon
 314 -- Each coercion TyCon is built with the special CoercionTyCon record and
 315 -- carries its own kinding rule.  Such CoercionTyCons must be fully applied
 316 -- by any TyConApp in which they are applied, however they may also be over
 317 -- applied (see example above) and the kinding function must deal with this.
 318 symCoercionTyCon =
 319   mkCoercionTyCon symCoercionTyConName 1 (mkKindingFun flipCoercionKindOf)
 320   where
 321     flipCoercionKindOf (co:rest) = (ty2, ty1, rest)
 322         where
 323           (ty1, ty2) = coercionKind co
 324
 325 transCoercionTyCon =
 326   mkCoercionTyCon transCoercionTyConName 2 (mkKindingFun composeCoercionKindsOf)
 327   where
 328     composeCoercionKindsOf (co1:co2:rest) =
 329         WARN( not (r1 `coreEqType` a2), text "Strange! Type mismatch in trans coercion, probably a bug")
 330         (a1, r2, rest)
 331       where
 332         (a1, r1) = coercionKind co1
 333         (a2, r2) = coercionKind co2
 334
 335 leftCoercionTyCon =
 336   mkCoercionTyCon leftCoercionTyConName 1 (mkKindingFun leftProjectCoercionKindOf)
 337   where
 338     leftProjectCoercionKindOf (co:rest) = (ty1, ty2, rest)
 339       where
 340         (ty1,ty2) = fst (splitCoercionKindOf co)
 341
 342 rightCoercionTyCon =
 343   mkCoercionTyCon rightCoercionTyConName 1 (mkKindingFun rightProjectCoercionKindOf)
 344   where
 345     rightProjectCoercionKindOf (co:rest) = (ty1, ty2, rest)
 346       where
 347         (ty1,ty2) = snd (splitCoercionKindOf co)
 348
 349 splitCoercionKindOf :: Type -> ((Type,Type), (Type,Type))
 350 -- Helper for left and right.  Finds coercion kind of its input and
 351 -- returns the left and right projections of the coercion...
 352 --
 353 -- if c :: t1 s1 :=: t2 s2 then splitCoercionKindOf c = ((t1, t2), (s1, s2))
 354 splitCoercionKindOf co
 355   | Just (ty1, ty2) <- splitCoercionKind_maybe (coercionKindPredTy co)
 356   , Just (ty_fun1, ty_arg1) <- splitAppTy_maybe ty1
 357   , Just (ty_fun2, ty_arg2) <- splitAppTy_maybe ty2
 358   = ((ty_fun1, ty_fun2),(ty_arg1, ty_arg2))
 359
 360 instCoercionTyCon
 361   =  mkCoercionTyCon instCoercionTyConName 2 (mkKindingFun instCoercionKind)
 362   where
 363     instantiateCo t s =
 364       let Just (tv, ty) = splitForAllTy_maybe t in
 365       substTyWith [tv] [s] ty
 366
 367     instCoercionKind (co1:ty:rest) = (instantiateCo t1 ty, instantiateCo t2 ty, rest)
 368       where (t1, t2) = coercionKind co1
 369
 370 unsafeCoercionTyCon
 371   = mkCoercionTyCon unsafeCoercionTyConName 2 (mkKindingFun unsafeCoercionKind)
 372   where
 373    unsafeCoercionKind (ty1:ty2:rest) = (ty1,ty2,rest)
 374
 375 --------------------------------------
 376 -- ...and their names
 377
 378 mkCoConName occ key coCon = mkWiredInName gHC_PRIM (mkOccNameFS tcName occ)
 379                             key Nothing (ATyCon coCon) BuiltInSyntax
 380
 381 transCoercionTyConName = mkCoConName FSLIT("trans") transCoercionTyConKey transCoercionTyCon
 382 symCoercionTyConName   = mkCoConName FSLIT("sym") symCoercionTyConKey symCoercionTyCon
 383 leftCoercionTyConName  = mkCoConName FSLIT("left") leftCoercionTyConKey leftCoercionTyCon
 384 rightCoercionTyConName = mkCoConName FSLIT("right") rightCoercionTyConKey rightCoercionTyCon
 385 instCoercionTyConName  = mkCoConName FSLIT("inst") instCoercionTyConKey instCoercionTyCon
 386 unsafeCoercionTyConName = mkCoConName FSLIT("CoUnsafe") unsafeCoercionTyConKey unsafeCoercionTyCon
 387
 388
 389
 390 -- this is here to avoid module loops
 391 splitNewTypeRepCo_maybe :: Type -> Maybe (Type, Coercion)
 392 -- Sometimes we want to look through a newtype and get its associated coercion
 393 -- It only strips *one layer* off, so the caller will usually call itself recursively
 394 -- Only applied to types of kind *, hence the newtype is always saturated
 395 splitNewTypeRepCo_maybe ty
 396   | Just ty' <- coreView ty = splitNewTypeRepCo_maybe ty'
 397 splitNewTypeRepCo_maybe (TyConApp tc tys)
 398   | isNewTyCon tc
 399   = ASSERT( tys `lengthIs` tyConArity tc )      -- splitNewTypeRepCo_maybe only be applied
 400                                                 --      to *types* (of kind *)
 401         case newTyConRhs tc of
 402           (tvs, rep_ty) ->
 403               ASSERT( length tvs == length tys )
 404               Just (substTyWith tvs tys rep_ty, mkTyConApp co_con tys)
 405   where
 406     co_con = maybe (pprPanic "splitNewTypeRepCo_maybe" (ppr tc)) id (newTyConCo tc)
 407 splitNewTypeRepCo_maybe other = Nothing
 408 \end{code}