compiler/types/OptCoercion.lhs

   1 %\r
   2 % (c) The University of Glasgow 2006\r
   3 %\r
   4 \r
   5 \begin{code}\r
   6 {-# OPTIONS_GHC -w #-}\r
   7 module OptCoercion (\r
   8         optCoercion\r
   9    ) where \r
  10 \r
  11 #include "HsVersions.h"\r
  12 \r
  13 import Unify    ( tcMatchTy )\r
  14 import Coercion\r
  15 import Type\r
  16 import TypeRep\r
  17 import TyCon\r
  18 import Var\r
  19 import VarSet\r
  20 import VarEnv\r
  21 import PrelNames\r
  22 import Util\r
  23 import Outputable\r
  24 \end{code}\r
  25 \r
  26 %************************************************************************\r
  27 %*                                                                      *\r
  28                  Optimising coercions                                                                   \r
  29 %*                                                                      *\r
  30 %************************************************************************\r
  31 \r
  32 Note [Subtle shadowing in coercions]\r
  33 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~\r
  34 Supose we optimising a coercion\r
  35     optCoercion (forall (co_X5:t1~t2). ...co_B1...)\r
  36 The co_X5 is a wild-card; the bound variable of a coercion for-all\r
  37 should never appear in the body of the forall. Indeed we often\r
  38 write it like this\r
  39     optCoercion ( (t1~t2) => ...co_B1... )\r
  40 \r
  41 Just because it's a wild-card doesn't mean we are free to choose\r
  42 whatever variable we like.  For example it'd be wrong for optCoercion\r
  43 to return\r
  44    forall (co_B1:t1~t2). ...co_B1...\r
  45 because now the co_B1 (which is really free) has been captured, and\r
  46 subsequent substitutions will go wrong.  That's why we can't use\r
  47 mkCoPredTy in the ForAll case, where this note appears.  \r
  48 \r
  49 \begin{code}\r
  50 optCoercion :: TvSubst -> Coercion -> NormalCo\r
  51 -- ^ optCoercion applies a substitution to a coercion, \r
  52 --   *and* optimises it to reduce its size\r
  53 optCoercion env co = opt_co env False co\r
  54 \r
  55 type NormalCo = Coercion\r
  56   -- Invariants: \r
  57   --  * The substitution has been fully applied\r
  58   --  * For trans coercions (co1 `trans` co2)\r
  59   --       co1 is not a trans, and neither co1 nor co2 is identity\r
  60   --  * If the coercion is the identity, it has no CoVars of CoTyCons in it (just types)\r
  61 \r
  62 type NormalNonIdCo = NormalCo  -- Extra invariant: not the identity\r
  63 \r
  64 opt_co, opt_co' :: TvSubst\r
  65                 -> Bool        -- True <=> return (sym co)\r
  66                 -> Coercion\r
  67                 -> NormalCo     \r
  68 opt_co = opt_co'\r
  69 \r
  70 {-    Debuggery \r
  71 opt_co env sym co \r
  72 -- = pprTrace "opt_co {" (ppr sym <+> ppr co) $\r
  73 --              co1 `seq` \r
  74 --               pprTrace "opt_co done }" (ppr co1) \r
  75 --               WARN( not same_co_kind, ppr co  <+> dcolon <+> pprEqPred (s1,t1) \r
  76 --                                   $$ ppr co1 <+> dcolon <+> pprEqPred (s2,t2) )\r
  77  =   WARN( not (coreEqType co1 simple_result), \r
  78            (text "env=" <+> ppr env) $$\r
  79            (text "input=" <+> ppr co) $$\r
  80            (text "simple=" <+> ppr simple_result) $$\r
  81            (text "opt=" <+> ppr co1) )\r
  82      co1\r
  83  where\r
  84    co1 = opt_co' env sym co\r
  85    same_co_kind = s1 `coreEqType` s2 && t1 `coreEqType` t2\r
  86    (s,t) = coercionKind (substTy env co)\r
  87    (s1,t1) | sym = (t,s)\r
  88            | otherwise = (s,t)\r
  89    (s2,t2) = coercionKind co1\r
  90 \r
  91    simple_result | sym = mkSymCoercion (substTy env co)\r
  92                  | otherwise = substTy env co\r
  93 -}\r
  94 \r
  95 opt_co' env sym (AppTy ty1 ty2)           = mkAppTy (opt_co env sym ty1) (opt_co env sym ty2)\r
  96 opt_co' env sym (FunTy ty1 ty2)           = FunTy (opt_co env sym ty1) (opt_co env sym ty2)\r
  97 opt_co' env sym (PredTy (ClassP cls tys)) = PredTy (ClassP cls (map (opt_co env sym) tys))\r
  98 opt_co' env sym (PredTy (IParam n ty))    = PredTy (IParam n (opt_co env sym ty))\r
  99 opt_co' _   _   co@(PredTy (EqPred {}))   = pprPanic "optCoercion" (ppr co)\r
 100 \r
 101 opt_co' env sym co@(TyVarTy tv)\r
 102   | Just ty <- lookupTyVar env tv = opt_co' (zapTvSubstEnv env) sym ty\r
 103   | not (isCoVar tv)     = co   -- Identity; does not mention a CoVar\r
 104   | ty1 `coreEqType` ty2 = ty1  -- Identity; ..ditto..\r
 105   | not sym              = co\r
 106   | otherwise            = mkSymCoercion co\r
 107   where\r
 108     (ty1,ty2) = coVarKind tv\r
 109 \r
 110 opt_co' env sym (ForAllTy tv cor) \r
 111   | isTyVar tv  = case substTyVarBndr env tv of\r
 112                    (env', tv') -> ForAllTy tv' (opt_co' env' sym cor)\r
 113 \r
 114 opt_co' env sym co@(ForAllTy co_var cor) \r
 115   | isCoVar co_var \r
 116   = WARN( co_var `elemVarSet` tyVarsOfType cor, ppr co )\r
 117     ForAllTy co_var' cor'\r
 118   where\r
 119     (co1,co2) = coVarKind co_var\r
 120     co1' = opt_co' env sym co1\r
 121     co2' = opt_co' env sym co2\r
 122     cor' = opt_co' env sym cor\r
 123     co_var' = uniqAway (getTvInScope env) (mkWildCoVar (mkCoKind co1' co2'))\r
 124     -- See Note [Subtle shadowing in coercions]\r
 125 \r
 126 opt_co' env sym (TyConApp tc cos)\r
 127   | Just (arity, desc) <- isCoercionTyCon_maybe tc\r
 128   = mkAppTys (opt_co_tc_app env sym tc desc (take arity cos))\r
 129              (map (opt_co env sym) (drop arity cos))\r
 130   | otherwise\r
 131   = TyConApp tc (map (opt_co env sym) cos)\r
 132 \r
 133 --------\r
 134 opt_co_tc_app :: TvSubst -> Bool -> TyCon -> CoTyConDesc -> [Coercion] -> NormalCo\r
 135 -- Used for CoercionTyCons only\r
 136 -- Arguments are *not* already simplified/substituted\r
 137 opt_co_tc_app env sym tc desc cos\r
 138   = case desc of\r
 139       CoAxiom {} -- Do *not* push sym inside top-level axioms\r
 140                  -- e.g. if g is a top-level axiom\r
 141                  --   g a : F a ~ a\r
 142                  -- Then (sym (g ty)) /= g (sym ty) !!\r
 143         | sym       -> mkSymCoercion the_co  \r
 144         | otherwise -> the_co\r
 145         where\r
 146            the_co = TyConApp tc (map (opt_co env False) cos)\r
 147            -- Note that the_co does *not* have sym pushed into it\r
 148     \r
 149       CoTrans \r
 150         | sym       -> opt_trans opt_co2 opt_co1   -- sym (g `o` h) = sym h `o` sym g\r
 151         | otherwise -> opt_trans opt_co1 opt_co2\r
 152 \r
 153       CoUnsafe\r
 154         | sym       -> mkUnsafeCoercion ty2' ty1'\r
 155         | otherwise -> mkUnsafeCoercion ty1' ty2'\r
 156 \r
 157       CoSym   -> opt_co env (not sym) co1\r
 158       CoLeft  -> opt_lr fst\r
 159       CoRight -> opt_lr snd\r
 160       CoCsel1 -> opt_csel fstOf3\r
 161       CoCsel2 -> opt_csel sndOf3\r
 162       CoCselR -> opt_csel thirdOf3\r
 163 \r
 164       CoInst        -- See if the first arg is already a forall\r
 165                     -- ...then we can just extend the current substitution\r
 166         | Just (tv, co1_body) <- splitForAllTy_maybe co1\r
 167         -> opt_co (extendTvSubst env tv ty2') sym co1_body\r
 168 \r
 169                     -- See if is *now* a forall\r
 170         | Just (tv, opt_co1_body) <- splitForAllTy_maybe opt_co1\r
 171         -> substTyWith [tv] [ty2'] opt_co1_body -- An inefficient one-variable substitution\r
 172 \r
 173         | otherwise\r
 174         -> TyConApp tc [opt_co1, ty2']\r
 175 \r
 176   where\r
 177     (co1 : cos1) = cos\r
 178     (co2 : _)    = cos1\r
 179 \r
 180     ty1' = substTy env co1\r
 181     ty2' = substTy env co2\r
 182 \r
 183         -- These opt_cos have the sym pushed into them\r
 184     opt_co1 = opt_co env sym co1\r
 185     opt_co2 = opt_co env sym co2\r
 186 \r
 187     the_unary_opt_co = TyConApp tc [opt_co1]\r
 188 \r
 189     opt_lr   sel = case splitAppTy_maybe opt_co1 of\r
 190                      Nothing -> the_unary_opt_co \r
 191                      Just lr -> sel lr\r
 192     opt_csel sel = case splitCoPredTy_maybe opt_co1 of\r
 193                      Nothing -> the_unary_opt_co \r
 194                      Just lr -> sel lr\r
 195 \r
 196 -------------\r
 197 opt_transL :: [NormalCo] -> [NormalCo] -> [NormalCo]\r
 198 opt_transL = zipWith opt_trans\r
 199 \r
 200 opt_trans :: NormalCo -> NormalCo -> NormalCo\r
 201 opt_trans co1 co2\r
 202   | isIdNormCo co1 = co2\r
 203   | otherwise      = opt_trans1 co1 co2\r
 204 \r
 205 opt_trans1 :: NormalNonIdCo -> NormalCo -> NormalCo\r
 206 -- First arg is not the identity\r
 207 opt_trans1 co1 co2\r
 208   | isIdNormCo co2 = co1\r
 209   | otherwise      = opt_trans2 co1 co2\r
 210 \r
 211 opt_trans2 :: NormalNonIdCo -> NormalNonIdCo -> NormalCo\r
 212 -- Neither arg is the identity\r
 213 opt_trans2 (TyConApp tc [co1a,co1b]) co2\r
 214   | tc `hasKey` transCoercionTyConKey\r
 215   = opt_trans1 co1a (opt_trans2 co1b co2)\r
 216 \r
 217 opt_trans2 co1 co2 \r
 218   | Just co <- opt_trans_rule co1 co2\r
 219   = co\r
 220 \r
 221 opt_trans2 co1 (TyConApp tc [co2a,co2b])\r
 222   | tc `hasKey` transCoercionTyConKey\r
 223   , Just co1_2a <- opt_trans_rule co1 co2a\r
 224   = if isIdNormCo co1_2a\r
 225     then co2b\r
 226     else opt_trans2 co1_2a co2b\r
 227 \r
 228 opt_trans2 co1 co2\r
 229   = mkTransCoercion co1 co2\r
 230 \r
 231 ------\r
 232 opt_trans_rule :: NormalNonIdCo -> NormalNonIdCo -> Maybe NormalCo\r
 233 opt_trans_rule (TyConApp tc1 args1) (TyConApp tc2 args2)\r
 234   | tc1 == tc2\r
 235   = case isCoercionTyCon_maybe tc1 of\r
 236       Nothing \r
 237         -> Just (TyConApp tc1 (opt_transL args1 args2))\r
 238       Just (arity, desc) \r
 239         | arity == length args1\r
 240         -> opt_trans_rule_equal_tc desc args1 args2\r
 241         | otherwise\r
 242         -> case opt_trans_rule_equal_tc desc \r
 243                          (take arity args1) \r
 244                          (take arity args2) of\r
 245               Just co -> Just $ mkAppTys co $ \r
 246                          opt_transL (drop arity args1) (drop arity args2)\r
 247               Nothing -> Nothing \r
 248  \r
 249 -- Push transitivity inside apply\r
 250 opt_trans_rule co1 co2\r
 251   | Just (co1a, co1b) <- splitAppTy_maybe co1\r
 252   , Just (co2a, co2b) <- etaApp_maybe co2\r
 253   = Just (mkAppTy (opt_trans co1a co2a) (opt_trans co1b co2b))\r
 254 \r
 255   | Just (co2a, co2b) <- splitAppTy_maybe co2\r
 256   , Just (co1a, co1b) <- etaApp_maybe co1\r
 257   = Just (mkAppTy (opt_trans co1a co2a) (opt_trans co1b co2b))\r
 258 \r
 259 -- Push transitivity inside (s~t)=>r\r
 260 -- We re-use the CoVar rather than using mkCoPredTy\r
 261 -- See Note [Subtle shadowing in coercions]\r
 262 opt_trans_rule co1 co2\r
 263   | Just (cv1,r1) <- splitForAllTy_maybe co1\r
 264   , isCoVar cv1\r
 265   , Just (s1,t1) <- coVarKind_maybe cv1\r
 266   , Just (s2,t2,r2) <- etaCoPred_maybe co2\r
 267   = Just (ForAllTy (mkCoVar (coVarName cv1) (mkCoKind (opt_trans s1 s2) (opt_trans t1 t2)))\r
 268                    (opt_trans r1 r2))\r
 269 \r
 270   | Just (cv2,r2) <- splitForAllTy_maybe co2\r
 271   , isCoVar cv2\r
 272   , Just (s2,t2) <- coVarKind_maybe cv2\r
 273   , Just (s1,t1,r1) <- etaCoPred_maybe co1\r
 274   = Just (ForAllTy (mkCoVar (coVarName cv2) (mkCoKind (opt_trans s1 s2) (opt_trans t1 t2)))\r
 275                    (opt_trans r1 r2))\r
 276 \r
 277 -- Push transitivity inside forall\r
 278 opt_trans_rule co1 co2\r
 279   | Just (tv1,r1) <- splitTypeForAll_maybe co1\r
 280   , Just (tv2,r2) <- etaForAll_maybe co2\r
 281   , let r2' = substTyWith [tv2] [TyVarTy tv1] r2\r
 282   = Just (ForAllTy tv1 (opt_trans2 r1 r2'))\r
 283 \r
 284   | Just (tv2,r2) <- splitTypeForAll_maybe co2\r
 285   , Just (tv1,r1) <- etaForAll_maybe co1\r
 286   , let r1' = substTyWith [tv1] [TyVarTy tv2] r1\r
 287   = Just (ForAllTy tv1 (opt_trans2 r1' r2))\r
 288 \r
 289 opt_trans_rule co1 co2\r
 290 {-      Omitting for now, because unsound\r
 291   | Just (sym1, (ax_tc1, ax1_args, ax_tvs, ax_lhs, ax_rhs)) <- co1_is_axiom_maybe\r
 292   , Just (sym2, (ax_tc2, ax2_args, _, _, _)) <- co2_is_axiom_maybe\r
 293   , ax_tc1 == ax_tc2\r
 294   , sym1 /= sym2\r
 295   = Just $\r
 296     if sym1 \r
 297     then substTyWith ax_tvs (opt_transL (map mkSymCoercion ax1_args) ax2_args) ax_rhs\r
 298     else substTyWith ax_tvs (opt_transL ax1_args (map mkSymCoercion ax2_args)) ax_lhs\r
 299 -}\r
 300 \r
 301   | Just (sym, (ax_tc, ax_args, ax_tvs, ax_lhs, _)) <- co1_is_axiom_maybe\r
 302   , Just cos <- matchesAxiomLhs ax_tvs ax_lhs co2\r
 303   = Just $ \r
 304     if sym \r
 305     then mkSymCoercion $ TyConApp ax_tc (opt_transL (map mkSymCoercion cos) ax_args)\r
 306     else                 TyConApp ax_tc (opt_transL ax_args cos)\r
 307 \r
 308   | Just (sym, (ax_tc, ax_args, ax_tvs, ax_lhs, _)) <- isAxiom_maybe co2\r
 309   , Just cos <- matchesAxiomLhs ax_tvs ax_lhs co1\r
 310   = Just $ \r
 311     if sym \r
 312     then mkSymCoercion $ TyConApp ax_tc (opt_transL ax_args (map mkSymCoercion cos))\r
 313     else                 TyConApp ax_tc (opt_transL cos ax_args)\r
 314   where\r
 315     co1_is_axiom_maybe = isAxiom_maybe co1\r
 316     co2_is_axiom_maybe = isAxiom_maybe co2\r
 317 \r
 318 opt_trans_rule co1 co2  -- Identity rule\r
 319   | (ty1,_) <- coercionKind co1\r
 320   , (_,ty2) <- coercionKind co2\r
 321   , ty1 `coreEqType` ty2\r
 322   = Just ty2\r
 323 \r
 324 opt_trans_rule _ _ = Nothing\r
 325 \r
 326 -----------  \r
 327 isAxiom_maybe :: Coercion -> Maybe (Bool, (TyCon, [Coercion], [TyVar], Type, Type))\r
 328 isAxiom_maybe co\r
 329   | Just (tc, args) <- splitTyConApp_maybe co\r
 330   , Just (_, desc)  <- isCoercionTyCon_maybe tc\r
 331   = case desc of\r
 332       CoAxiom { co_ax_tvs = tvs, co_ax_lhs = lhs, co_ax_rhs = rhs } \r
 333             -> Just (False, (tc, args, tvs, lhs, rhs))\r
 334       CoSym | (arg1:_) <- args  \r
 335             -> case isAxiom_maybe arg1 of\r
 336                  Nothing           -> Nothing\r
 337                  Just (sym, stuff) -> Just (not sym, stuff)\r
 338       _ -> Nothing\r
 339   | otherwise\r
 340   = Nothing\r
 341 \r
 342 matchesAxiomLhs :: [TyVar] -> Type -> Type -> Maybe [Type]\r
 343 matchesAxiomLhs tvs ty_tmpl ty \r
 344   = case tcMatchTy (mkVarSet tvs) ty_tmpl ty of\r
 345       Nothing    -> Nothing\r
 346       Just subst -> Just (map (substTyVar subst) tvs)\r
 347 \r
 348 -----------  \r
 349 opt_trans_rule_equal_tc :: CoTyConDesc -> [Coercion] -> [Coercion] -> Maybe Coercion\r
 350 -- Rules for Coercion TyCons only\r
 351 \r
 352 -- Push transitivity inside instantiation\r
 353 opt_trans_rule_equal_tc desc [co1,ty1] [co2,ty2]\r
 354   | CoInst <- desc\r
 355   , ty1 `coreEqType` ty2\r
 356   , co1 `compatible_co` co2\r
 357   = Just (mkInstCoercion (opt_trans2 co1 co2) ty1) \r
 358 \r
 359 opt_trans_rule_equal_tc desc [co1] [co2]\r
 360   | CoLeft  <- desc, is_compat = Just (mkLeftCoercion res_co)\r
 361   | CoRight <- desc, is_compat = Just (mkRightCoercion res_co)\r
 362   | CoCsel1 <- desc, is_compat = Just (mkCsel1Coercion res_co)\r
 363   | CoCsel2 <- desc, is_compat = Just (mkCsel2Coercion res_co)\r
 364   | CoCselR <- desc, is_compat = Just (mkCselRCoercion res_co)\r
 365   where\r
 366     is_compat = co1 `compatible_co` co2\r
 367     res_co    = opt_trans2 co1 co2\r
 368 \r
 369 opt_trans_rule_equal_tc _ _ _ = Nothing\r
 370 \r
 371 -------------\r
 372 compatible_co :: Coercion -> Coercion -> Bool\r
 373 -- Check whether (co1 . co2) will be well-kinded\r
 374 compatible_co co1 co2\r
 375   = x1 `coreEqType` x2          \r
 376   where\r
 377     (_,x1) = coercionKind co1\r
 378     (x2,_) = coercionKind co2\r
 379 \r
 380 -------------\r
 381 etaForAll_maybe :: Coercion -> Maybe (TyVar, Coercion)\r
 382 -- Try to make the coercion be of form (forall tv. co)\r
 383 etaForAll_maybe co\r
 384   | Just (tv, r) <- splitForAllTy_maybe co\r
 385   , not (isCoVar tv)    -- Check it is a *type* forall, not a (t1~t2)=>co\r
 386   = Just (tv, r)\r
 387 \r
 388   | (ty1,ty2) <- coercionKind co\r
 389   , Just (tv1, _) <- splitTypeForAll_maybe ty1\r
 390   , Just (tv2, _) <- splitTypeForAll_maybe ty2\r
 391   , tyVarKind tv1 `eqKind` tyVarKind tv2\r
 392   = Just (tv1, mkInstCoercion co (mkTyVarTy tv1))\r
 393 \r
 394   | otherwise\r
 395   = Nothing\r
 396 \r
 397 etaCoPred_maybe :: Coercion -> Maybe (Coercion, Coercion, Coercion)\r
 398 etaCoPred_maybe co \r
 399   | Just (s,t,r) <- splitCoPredTy_maybe co\r
 400   = Just (s,t,r)\r
 401   \r
 402   --  co :: (s1~t1)=>r1 ~ (s2~t2)=>r2\r
 403   | (ty1,ty2) <- coercionKind co        -- We know ty1,ty2 have same kind\r
 404   , Just (s1,_,_) <- splitCoPredTy_maybe ty1\r
 405   , Just (s2,_,_) <- splitCoPredTy_maybe ty2\r
 406   , typeKind s1 `eqKind` typeKind s2    -- t1,t2 have same kinds\r
 407   = Just (mkCsel1Coercion co, mkCsel2Coercion co, mkCselRCoercion co)\r
 408   \r
 409   | otherwise\r
 410   = Nothing\r
 411 \r
 412 etaApp_maybe :: Coercion -> Maybe (Coercion, Coercion)\r
 413 -- Split a coercion g :: t1a t1b ~ t2a t2b\r
 414 -- into (left g, right g) if possible\r
 415 etaApp_maybe co\r
 416   | Just (co1, co2) <- splitAppTy_maybe co\r
 417   = Just (co1, co2)\r
 418 \r
 419   | (ty1,ty2) <- coercionKind co\r
 420   , Just (ty1a, _) <- splitAppTy_maybe ty1\r
 421   , Just (ty2a, _) <- splitAppTy_maybe ty2\r
 422   , typeKind ty1a `eqKind` typeKind ty2a\r
 423   = Just (mkLeftCoercion co, mkRightCoercion co)\r
 424 \r
 425   | otherwise\r
 426   = Nothing\r
 427 \r
 428 -------------\r
 429 splitTypeForAll_maybe :: Type -> Maybe (TyVar, Type)\r
 430 -- Returns Just only for a *type* forall, not a (t1~t2)=>co\r
 431 splitTypeForAll_maybe ty\r
 432   | Just (tv, rty) <- splitForAllTy_maybe ty\r
 433   , not (isCoVar tv)\r
 434   = Just (tv, rty)\r
 435 \r
 436   | otherwise\r
 437   = Nothing\r
 438 \r
 439 -------------\r
 440 isIdNormCo :: NormalCo -> Bool\r
 441 -- Cheap identity test: look for coercions with no coercion variables at all\r
 442 -- So it'll return False for (sym g `trans` g)\r
 443 isIdNormCo ty = go ty\r
 444   where\r
 445     go (TyVarTy tv)            = not (isCoVar tv)\r
 446     go (AppTy t1 t2)           = go t1 && go t2\r
 447     go (FunTy t1 t2)           = go t1 && go t2\r
 448     go (ForAllTy tv ty)        = go (tyVarKind tv) && go ty\r
 449     go (TyConApp tc tys)       = not (isCoercionTyCon tc) && all go tys\r
 450     go (PredTy (IParam _ ty))  = go ty\r
 451     go (PredTy (ClassP _ tys)) = all go tys\r
 452     go (PredTy (EqPred t1 t2)) = go t1 && go t2\r
 453 \end{code}  \r