compiler/types/Type.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1998
   4 %
   5
   6 Type - public interface
   7
   8 \begin{code}
   9 module Type (
  10         -- re-exports from TypeRep
  11         TyThing(..), Type, PredType(..), ThetaType,
  12         funTyCon,
  13
  14         -- Kinds
  15         Kind, SimpleKind, KindVar,
  16         kindFunResult, splitKindFunTys, splitKindFunTysN,
  17
  18         liftedTypeKindTyCon, openTypeKindTyCon, unliftedTypeKindTyCon,
  19         argTypeKindTyCon, ubxTupleKindTyCon,
  20
  21         liftedTypeKind, unliftedTypeKind, openTypeKind,
  22         argTypeKind, ubxTupleKind,
  23
  24         tySuperKind, coSuperKind,
  25
  26         isLiftedTypeKind, isUnliftedTypeKind, isOpenTypeKind,
  27         isUbxTupleKind, isArgTypeKind, isKind, isTySuperKind,
  28         isCoSuperKind, isSuperKind, isCoercionKind, isEqPred,
  29         mkArrowKind, mkArrowKinds,
  30
  31         isSubArgTypeKind, isSubOpenTypeKind, isSubKind, defaultKind, eqKind,
  32         isSubKindCon,
  33
  34         -- Re-exports from TyCon
  35         PrimRep(..),
  36
  37         mkTyVarTy, mkTyVarTys, getTyVar, getTyVar_maybe, isTyVarTy,
  38
  39         mkAppTy, mkAppTys, splitAppTy, splitAppTys,
  40         splitAppTy_maybe, repSplitAppTy_maybe,
  41
  42         mkFunTy, mkFunTys, splitFunTy, splitFunTy_maybe,
  43         splitFunTys, splitFunTysN,
  44         funResultTy, funArgTy, zipFunTys, isFunTy,
  45
  46         mkTyConApp, mkTyConTy,
  47         tyConAppTyCon, tyConAppArgs,
  48         splitTyConApp_maybe, splitTyConApp,
  49         splitNewTyConApp_maybe, splitNewTyConApp,
  50
  51         repType, repType', typePrimRep, coreView, tcView, kindView,
  52
  53         mkForAllTy, mkForAllTys, splitForAllTy_maybe, splitForAllTys,
  54         applyTy, applyTys, isForAllTy, dropForAlls,
  55
  56         -- Source types
  57         predTypeRep, mkPredTy, mkPredTys,
  58         tyConOrigHead,
  59
  60         -- Newtypes
  61         splitRecNewType_maybe, newTyConInstRhs,
  62
  63         -- Lifting and boxity
  64         isUnLiftedType, isUnboxedTupleType, isAlgType, isPrimitiveType,
  65         isStrictType, isStrictPred,
  66
  67         -- Free variables
  68         tyVarsOfType, tyVarsOfTypes, tyVarsOfPred, tyVarsOfTheta,
  69         typeKind, addFreeTyVars,
  70
  71         -- Tidying up for printing
  72         tidyType,      tidyTypes,
  73         tidyOpenType,  tidyOpenTypes,
  74         tidyTyVarBndr, tidyFreeTyVars,
  75         tidyOpenTyVar, tidyOpenTyVars,
  76         tidyTopType,   tidyPred,
  77         tidyKind,
  78
  79         -- Comparison
  80         coreEqType, tcEqType, tcEqTypes, tcCmpType, tcCmpTypes,
  81         tcEqPred, tcCmpPred, tcEqTypeX,
  82
  83         -- Seq
  84         seqType, seqTypes,
  85
  86         -- Type substitutions
  87         TvSubstEnv, emptyTvSubstEnv,    -- Representation widely visible
  88         TvSubst(..), emptyTvSubst,      -- Representation visible to a few friends
  89         mkTvSubst, mkOpenTvSubst, zipOpenTvSubst, zipTopTvSubst, mkTopTvSubst, notElemTvSubst,
  90         getTvSubstEnv, setTvSubstEnv, getTvInScope, extendTvInScope,
  91         extendTvSubst, extendTvSubstList, isInScope, composeTvSubst, zipTyEnv,
  92
  93         -- Performing substitution on types
  94         substTy, substTys, substTyWith, substTheta,
  95         substPred, substTyVar, substTyVarBndr, deShadowTy, lookupTyVar,
  96
  97         -- Pretty-printing
  98         pprType, pprParendType, pprTyThingCategory, pprForAll,
  99         pprPred, pprTheta, pprThetaArrow, pprClassPred, pprKind, pprParendKind
 100     ) where
 101
 102 #include "HsVersions.h"
 103
 104 -- We import the representation and primitive functions from TypeRep.
 105 -- Many things are reexported, but not the representation!
 106
 107 import TypeRep
 108
 109 -- friends:
 110 import Var
 111 import VarEnv
 112 import VarSet
 113
 114 import Name
 115 import Class
 116 import PrelNames
 117 import TyCon
 118
 119 -- others
 120 import StaticFlags
 121 import Util
 122 import Outputable
 123 import UniqSet
 124
 125 import Data.Maybe       ( isJust )
 126 \end{code}
 127
 128
 129 %************************************************************************
 130 %*                                                                      *
 131                 Type representation
 132 %*                                                                      *
 133 %************************************************************************
 134
 135 In Core, we "look through" non-recursive newtypes and PredTypes.
 136
 137 \begin{code}
 138 {-# INLINE coreView #-}
 139 coreView :: Type -> Maybe Type
 140 -- Strips off the *top layer only* of a type to give
 141 -- its underlying representation type.
 142 -- Returns Nothing if there is nothing to look through.
 143 --
 144 -- In the case of newtypes, it returns
 145 --      *either* a vanilla TyConApp (recursive newtype, or non-saturated)
 146 --      *or*     the newtype representation (otherwise), meaning the
 147 --                      type written in the RHS of the newtype decl,
 148 --                      which may itself be a newtype
 149 --
 150 -- Example: newtype R = MkR S
 151 --          newtype S = MkS T
 152 --          newtype T = MkT (T -> T)
 153 --   expandNewTcApp on R gives Just S
 154 --                  on S gives Just T
 155 --                  on T gives Nothing   (no expansion)
 156
 157 -- By being non-recursive and inlined, this case analysis gets efficiently
 158 -- joined onto the case analysis that the caller is already doing
 159 coreView (NoteTy _ ty)     = Just ty
 160 coreView (PredTy p)
 161   | isEqPred p             = Nothing
 162   | otherwise              = Just (predTypeRep p)
 163 coreView (TyConApp tc tys) | Just (tenv, rhs, tys') <- coreExpandTyCon_maybe tc tys
 164                            = Just (mkAppTys (substTy (mkTopTvSubst tenv) rhs) tys')
 165                                 -- Its important to use mkAppTys, rather than (foldl AppTy),
 166                                 -- because the function part might well return a
 167                                 -- partially-applied type constructor; indeed, usually will!
 168 coreView ty                = Nothing
 169
 170
 171
 172 -----------------------------------------------
 173 {-# INLINE tcView #-}
 174 tcView :: Type -> Maybe Type
 175 -- Same, but for the type checker, which just looks through synonyms
 176 tcView (NoteTy _ ty)     = Just ty
 177 tcView (TyConApp tc tys) | Just (tenv, rhs, tys') <- tcExpandTyCon_maybe tc tys
 178                          = Just (mkAppTys (substTy (mkTopTvSubst tenv) rhs) tys')
 179 tcView ty                = Nothing
 180
 181 -----------------------------------------------
 182 {-# INLINE kindView #-}
 183 kindView :: Kind -> Maybe Kind
 184 -- C.f. coreView, tcView
 185 -- For the moment, we don't even handle synonyms in kinds
 186 kindView (NoteTy _ k) = Just k
 187 kindView other        = Nothing
 188 \end{code}
 189
 190
 191 %************************************************************************
 192 %*                                                                      *
 193 \subsection{Constructor-specific functions}
 194 %*                                                                      *
 195 %************************************************************************
 196
 197
 198 ---------------------------------------------------------------------
 199                                 TyVarTy
 200                                 ~~~~~~~
 201 \begin{code}
 202 mkTyVarTy  :: TyVar   -> Type
 203 mkTyVarTy  = TyVarTy
 204
 205 mkTyVarTys :: [TyVar] -> [Type]
 206 mkTyVarTys = map mkTyVarTy -- a common use of mkTyVarTy
 207
 208 getTyVar :: String -> Type -> TyVar
 209 getTyVar msg ty = case getTyVar_maybe ty of
 210                     Just tv -> tv
 211                     Nothing -> panic ("getTyVar: " ++ msg)
 212
 213 isTyVarTy :: Type -> Bool
 214 isTyVarTy ty = isJust (getTyVar_maybe ty)
 215
 216 getTyVar_maybe :: Type -> Maybe TyVar
 217 getTyVar_maybe ty | Just ty' <- coreView ty = getTyVar_maybe ty'
 218 getTyVar_maybe (TyVarTy tv)                 = Just tv
 219 getTyVar_maybe other                        = Nothing
 220
 221 \end{code}
 222
 223
 224 ---------------------------------------------------------------------
 225                                 AppTy
 226                                 ~~~~~
 227 We need to be pretty careful with AppTy to make sure we obey the
 228 invariant that a TyConApp is always visibly so.  mkAppTy maintains the
 229 invariant: use it.
 230
 231 \begin{code}
 232 mkAppTy orig_ty1 orig_ty2
 233   = mk_app orig_ty1
 234   where
 235     mk_app (NoteTy _ ty1)    = mk_app ty1
 236     mk_app (TyConApp tc tys) = mkTyConApp tc (tys ++ [orig_ty2])
 237     mk_app ty1               = AppTy orig_ty1 orig_ty2
 238         -- Note that the TyConApp could be an
 239         -- under-saturated type synonym.  GHC allows that; e.g.
 240         --      type Foo k = k a -> k a
 241         --      type Id x = x
 242         --      foo :: Foo Id -> Foo Id
 243         --
 244         -- Here Id is partially applied in the type sig for Foo,
 245         -- but once the type synonyms are expanded all is well
 246
 247 mkAppTys :: Type -> [Type] -> Type
 248 mkAppTys orig_ty1 []        = orig_ty1
 249         -- This check for an empty list of type arguments
 250         -- avoids the needless loss of a type synonym constructor.
 251         -- For example: mkAppTys Rational []
 252         --   returns to (Ratio Integer), which has needlessly lost
 253         --   the Rational part.
 254 mkAppTys orig_ty1 orig_tys2
 255   = mk_app orig_ty1
 256   where
 257     mk_app (NoteTy _ ty1)    = mk_app ty1
 258     mk_app (TyConApp tc tys) = mkTyConApp tc (tys ++ orig_tys2)
 259                                 -- mkTyConApp: see notes with mkAppTy
 260     mk_app ty1               = foldl AppTy orig_ty1 orig_tys2
 261
 262 -------------
 263 splitAppTy_maybe :: Type -> Maybe (Type, Type)
 264 splitAppTy_maybe ty | Just ty' <- coreView ty
 265                     = splitAppTy_maybe ty'
 266 splitAppTy_maybe ty = repSplitAppTy_maybe ty
 267
 268 -------------
 269 repSplitAppTy_maybe :: Type -> Maybe (Type,Type)
 270 -- Does the AppTy split, but assumes that any view stuff is already done
 271 repSplitAppTy_maybe (FunTy ty1 ty2)   = Just (TyConApp funTyCon [ty1], ty2)
 272 repSplitAppTy_maybe (AppTy ty1 ty2)   = Just (ty1, ty2)
 273 repSplitAppTy_maybe (TyConApp tc tys) = case snocView tys of
 274                                                 Just (tys', ty') -> Just (TyConApp tc tys', ty')
 275                                                 Nothing          -> Nothing
 276 repSplitAppTy_maybe other = Nothing
 277 -------------
 278 splitAppTy :: Type -> (Type, Type)
 279 splitAppTy ty = case splitAppTy_maybe ty of
 280                         Just pr -> pr
 281                         Nothing -> panic "splitAppTy"
 282
 283 -------------
 284 splitAppTys :: Type -> (Type, [Type])
 285 splitAppTys ty = split ty ty []
 286   where
 287     split orig_ty ty args | Just ty' <- coreView ty = split orig_ty ty' args
 288     split orig_ty (AppTy ty arg)        args = split ty ty (arg:args)
 289     split orig_ty (TyConApp tc tc_args) args = (TyConApp tc [], tc_args ++ args)
 290     split orig_ty (FunTy ty1 ty2)       args = ASSERT( null args )
 291                                                (TyConApp funTyCon [], [ty1,ty2])
 292     split orig_ty ty                    args = (orig_ty, args)
 293
 294 \end{code}
 295
 296
 297 ---------------------------------------------------------------------
 298                                 FunTy
 299                                 ~~~~~
 300
 301 \begin{code}
 302 mkFunTy :: Type -> Type -> Type
 303 mkFunTy (PredTy (EqPred ty1 ty2)) res = mkForAllTy (mkWildCoVar (PredTy (EqPred ty1 ty2))) res
 304 mkFunTy arg res = FunTy arg res
 305
 306 mkFunTys :: [Type] -> Type -> Type
 307 mkFunTys tys ty = foldr mkFunTy ty tys
 308
 309 isFunTy :: Type -> Bool
 310 isFunTy ty = isJust (splitFunTy_maybe ty)
 311
 312 splitFunTy :: Type -> (Type, Type)
 313 splitFunTy ty | Just ty' <- coreView ty = splitFunTy ty'
 314 splitFunTy (FunTy arg res)   = (arg, res)
 315 splitFunTy other             = pprPanic "splitFunTy" (ppr other)
 316
 317 splitFunTy_maybe :: Type -> Maybe (Type, Type)
 318 splitFunTy_maybe ty | Just ty' <- coreView ty = splitFunTy_maybe ty'
 319 splitFunTy_maybe (FunTy arg res)   = Just (arg, res)
 320 splitFunTy_maybe other             = Nothing
 321
 322 splitFunTys :: Type -> ([Type], Type)
 323 splitFunTys ty = split [] ty ty
 324   where
 325     split args orig_ty ty | Just ty' <- coreView ty = split args orig_ty ty'
 326     split args orig_ty (FunTy arg res)   = split (arg:args) res res
 327     split args orig_ty ty                = (reverse args, orig_ty)
 328
 329 splitFunTysN :: Int -> Type -> ([Type], Type)
 330 -- Split off exactly n arg tys
 331 splitFunTysN 0 ty = ([], ty)
 332 splitFunTysN n ty = case splitFunTy ty of { (arg, res) ->
 333                     case splitFunTysN (n-1) res of { (args, res) ->
 334                     (arg:args, res) }}
 335
 336 zipFunTys :: Outputable a => [a] -> Type -> ([(a,Type)], Type)
 337 zipFunTys orig_xs orig_ty = split [] orig_xs orig_ty orig_ty
 338   where
 339     split acc []     nty ty                = (reverse acc, nty)
 340     split acc xs     nty ty
 341           | Just ty' <- coreView ty        = split acc xs nty ty'
 342     split acc (x:xs) nty (FunTy arg res)   = split ((x,arg):acc) xs res res
 343     split acc (x:xs) nty ty                = pprPanic "zipFunTys" (ppr orig_xs <+> ppr orig_ty)
 344
 345 funResultTy :: Type -> Type
 346 funResultTy ty | Just ty' <- coreView ty = funResultTy ty'
 347 funResultTy (FunTy arg res)   = res
 348 funResultTy ty                = pprPanic "funResultTy" (ppr ty)
 349
 350 funArgTy :: Type -> Type
 351 funArgTy ty | Just ty' <- coreView ty = funArgTy ty'
 352 funArgTy (FunTy arg res)   = arg
 353 funArgTy ty                = pprPanic "funArgTy" (ppr ty)
 354 \end{code}
 355
 356
 357 ---------------------------------------------------------------------
 358                                 TyConApp
 359                                 ~~~~~~~~
 360 @mkTyConApp@ is a key function, because it builds a TyConApp, FunTy or PredTy,
 361 as apppropriate.
 362
 363 \begin{code}
 364 mkTyConApp :: TyCon -> [Type] -> Type
 365 mkTyConApp tycon tys
 366   | isFunTyCon tycon, [ty1,ty2] <- tys
 367   = FunTy ty1 ty2
 368
 369   | otherwise
 370   = TyConApp tycon tys
 371
 372 mkTyConTy :: TyCon -> Type
 373 mkTyConTy tycon = mkTyConApp tycon []
 374
 375 -- splitTyConApp "looks through" synonyms, because they don't
 376 -- mean a distinct type, but all other type-constructor applications
 377 -- including functions are returned as Just ..
 378
 379 tyConAppTyCon :: Type -> TyCon
 380 tyConAppTyCon ty = fst (splitTyConApp ty)
 381
 382 tyConAppArgs :: Type -> [Type]
 383 tyConAppArgs ty = snd (splitTyConApp ty)
 384
 385 splitTyConApp :: Type -> (TyCon, [Type])
 386 splitTyConApp ty = case splitTyConApp_maybe ty of
 387                         Just stuff -> stuff
 388                         Nothing    -> pprPanic "splitTyConApp" (ppr ty)
 389
 390 splitTyConApp_maybe :: Type -> Maybe (TyCon, [Type])
 391 splitTyConApp_maybe ty | Just ty' <- coreView ty = splitTyConApp_maybe ty'
 392 splitTyConApp_maybe (TyConApp tc tys) = Just (tc, tys)
 393 splitTyConApp_maybe (FunTy arg res)   = Just (funTyCon, [arg,res])
 394 splitTyConApp_maybe other             = Nothing
 395
 396 -- Sometimes we do NOT want to look throught a newtype.  When case matching
 397 -- on a newtype we want a convenient way to access the arguments of a newty
 398 -- constructor so as to properly form a coercion.
 399 splitNewTyConApp :: Type -> (TyCon, [Type])
 400 splitNewTyConApp ty = case splitNewTyConApp_maybe ty of
 401                         Just stuff -> stuff
 402                         Nothing    -> pprPanic "splitNewTyConApp" (ppr ty)
 403 splitNewTyConApp_maybe :: Type -> Maybe (TyCon, [Type])
 404 splitNewTyConApp_maybe ty | Just ty' <- tcView ty = splitNewTyConApp_maybe ty'
 405 splitNewTyConApp_maybe (TyConApp tc tys) = Just (tc, tys)
 406 splitNewTyConApp_maybe (FunTy arg res)   = Just (funTyCon, [arg,res])
 407 splitNewTyConApp_maybe other          = Nothing
 408
 409 -- get instantiated newtype rhs, the arguments had better saturate
 410 -- the constructor
 411 newTyConInstRhs :: TyCon -> [Type] -> Type
 412 newTyConInstRhs tycon tys =
 413     let (tvs, ty) = newTyConRhs tycon in substTyWith tvs tys ty
 414
 415 \end{code}
 416
 417
 418 ---------------------------------------------------------------------
 419                                 SynTy
 420                                 ~~~~~
 421
 422 Notes on type synonyms
 423 ~~~~~~~~~~~~~~~~~~~~~~
 424 The various "split" functions (splitFunTy, splitRhoTy, splitForAllTy) try
 425 to return type synonyms whereever possible. Thus
 426
 427         type Foo a = a -> a
 428
 429 we want
 430         splitFunTys (a -> Foo a) = ([a], Foo a)
 431 not                                ([a], a -> a)
 432
 433 The reason is that we then get better (shorter) type signatures in
 434 interfaces.  Notably this plays a role in tcTySigs in TcBinds.lhs.
 435
 436
 437                 Representation types
 438                 ~~~~~~~~~~~~~~~~~~~~
 439 repType looks through
 440         (a) for-alls, and
 441         (b) synonyms
 442         (c) predicates
 443         (d) usage annotations
 444         (e) all newtypes, including recursive ones, but not newtype families
 445 It's useful in the back end.
 446
 447 \begin{code}
 448 repType :: Type -> Type
 449 -- Only applied to types of kind *; hence tycons are saturated
 450 repType ty | Just ty' <- coreView ty = repType ty'
 451 repType (ForAllTy _ ty)  = repType ty
 452 repType (TyConApp tc tys)
 453   | isClosedNewTyCon tc  = -- Recursive newtypes are opaque to coreView
 454                            -- but we must expand them here.  Sure to
 455                            -- be saturated because repType is only applied
 456                            -- to types of kind *
 457                            ASSERT( {- isRecursiveTyCon tc && -} tys `lengthIs` tyConArity tc )
 458                            repType (new_type_rep tc tys)
 459 repType ty = ty
 460
 461 -- repType' aims to be a more thorough version of repType
 462 -- For now it simply looks through the TyConApp args too
 463 repType' ty -- | pprTrace "repType'" (ppr ty $$ ppr (go1 ty)) False = undefined
 464             | otherwise = go1 ty
 465  where
 466         go1 = go . repType
 467         go (TyConApp tc tys) = mkTyConApp tc (map repType' tys)
 468         go ty = ty
 469
 470
 471 -- new_type_rep doesn't ask any questions:
 472 -- it just expands newtype, whether recursive or not
 473 new_type_rep new_tycon tys = ASSERT( tys `lengthIs` tyConArity new_tycon )
 474                              case newTyConRep new_tycon of
 475                                  (tvs, rep_ty) -> substTyWith tvs tys rep_ty
 476
 477 -- ToDo: this could be moved to the code generator, using splitTyConApp instead
 478 -- of inspecting the type directly.
 479 typePrimRep :: Type -> PrimRep
 480 typePrimRep ty = case repType ty of
 481                    TyConApp tc _ -> tyConPrimRep tc
 482                    FunTy _ _     -> PtrRep
 483                    AppTy _ _     -> PtrRep      -- See note below
 484                    TyVarTy _     -> PtrRep
 485                    other         -> pprPanic "typePrimRep" (ppr ty)
 486         -- Types of the form 'f a' must be of kind *, not *#, so
 487         -- we are guaranteed that they are represented by pointers.
 488         -- The reason is that f must have kind *->*, not *->*#, because
 489         -- (we claim) there is no way to constrain f's kind any other
 490         -- way.
 491
 492 \end{code}
 493
 494
 495 ---------------------------------------------------------------------
 496                                 ForAllTy
 497                                 ~~~~~~~~
 498
 499 \begin{code}
 500 mkForAllTy :: TyVar -> Type -> Type
 501 mkForAllTy tyvar ty
 502   = mkForAllTys [tyvar] ty
 503
 504 mkForAllTys :: [TyVar] -> Type -> Type
 505 mkForAllTys tyvars ty = foldr ForAllTy ty tyvars
 506
 507 isForAllTy :: Type -> Bool
 508 isForAllTy (NoteTy _ ty)  = isForAllTy ty
 509 isForAllTy (ForAllTy _ _) = True
 510 isForAllTy other_ty       = False
 511
 512 splitForAllTy_maybe :: Type -> Maybe (TyVar, Type)
 513 splitForAllTy_maybe ty = splitFAT_m ty
 514   where
 515     splitFAT_m ty | Just ty' <- coreView ty = splitFAT_m ty'
 516     splitFAT_m (ForAllTy tyvar ty)          = Just(tyvar, ty)
 517     splitFAT_m _                            = Nothing
 518
 519 splitForAllTys :: Type -> ([TyVar], Type)
 520 splitForAllTys ty = split ty ty []
 521    where
 522      split orig_ty ty tvs | Just ty' <- coreView ty = split orig_ty ty' tvs
 523      split orig_ty (ForAllTy tv ty)  tvs = split ty ty (tv:tvs)
 524      split orig_ty t                 tvs = (reverse tvs, orig_ty)
 525
 526 dropForAlls :: Type -> Type
 527 dropForAlls ty = snd (splitForAllTys ty)
 528 \end{code}
 529
 530 -- (mkPiType now in CoreUtils)
 531
 532 applyTy, applyTys
 533 ~~~~~~~~~~~~~~~~~
 534 Instantiate a for-all type with one or more type arguments.
 535 Used when we have a polymorphic function applied to type args:
 536         f t1 t2
 537 Then we use (applyTys type-of-f [t1,t2]) to compute the type of
 538 the expression.
 539
 540 \begin{code}
 541 applyTy :: Type -> Type -> Type
 542 applyTy ty arg | Just ty' <- coreView ty = applyTy ty' arg
 543 applyTy (ForAllTy tv ty) arg = substTyWith [tv] [arg] ty
 544 applyTy other            arg = panic "applyTy"
 545
 546 applyTys :: Type -> [Type] -> Type
 547 -- This function is interesting because
 548 --      a) the function may have more for-alls than there are args
 549 --      b) less obviously, it may have fewer for-alls
 550 -- For case (b) think of
 551 --      applyTys (forall a.a) [forall b.b, Int]
 552 -- This really can happen, via dressing up polymorphic types with newtype
 553 -- clothing.  Here's an example:
 554 --      newtype R = R (forall a. a->a)
 555 --      foo = case undefined :: R of
 556 --              R f -> f ()
 557
 558 applyTys orig_fun_ty []      = orig_fun_ty
 559 applyTys orig_fun_ty arg_tys
 560   | n_tvs == n_args     -- The vastly common case
 561   = substTyWith tvs arg_tys rho_ty
 562   | n_tvs > n_args      -- Too many for-alls
 563   = substTyWith (take n_args tvs) arg_tys
 564                 (mkForAllTys (drop n_args tvs) rho_ty)
 565   | otherwise           -- Too many type args
 566   = ASSERT2( n_tvs > 0, ppr orig_fun_ty )       -- Zero case gives infnite loop!
 567     applyTys (substTyWith tvs (take n_tvs arg_tys) rho_ty)
 568              (drop n_tvs arg_tys)
 569   where
 570     (tvs, rho_ty) = splitForAllTys orig_fun_ty
 571     n_tvs = length tvs
 572     n_args = length arg_tys
 573 \end{code}
 574
 575
 576 %************************************************************************
 577 %*                                                                      *
 578 \subsection{Source types}
 579 %*                                                                      *
 580 %************************************************************************
 581
 582 A "source type" is a type that is a separate type as far as the type checker is
 583 concerned, but which has low-level representation as far as the back end is concerned.
 584
 585 Source types are always lifted.
 586
 587 The key function is predTypeRep which gives the representation of a source type:
 588
 589 \begin{code}
 590 mkPredTy :: PredType -> Type
 591 mkPredTy pred = PredTy pred
 592
 593 mkPredTys :: ThetaType -> [Type]
 594 mkPredTys preds = map PredTy preds
 595
 596 predTypeRep :: PredType -> Type
 597 -- Convert a PredType to its "representation type";
 598 -- the post-type-checking type used by all the Core passes of GHC.
 599 -- Unwraps only the outermost level; for example, the result might
 600 -- be a newtype application
 601 predTypeRep (IParam _ ty)     = ty
 602 predTypeRep (ClassP clas tys) = mkTyConApp (classTyCon clas) tys
 603         -- Result might be a newtype application, but the consumer will
 604         -- look through that too if necessary
 605 predTypeRep (EqPred ty1 ty2) = pprPanic "predTypeRep" (ppr (EqPred ty1 ty2))
 606
 607 -- The original head is the tycon and its variables for a vanilla tycon and it
 608 -- is the family tycon and its type indexes for a family instance.
 609 tyConOrigHead :: TyCon -> (TyCon, [Type])
 610 tyConOrigHead tycon = case tyConFamInst_maybe tycon of
 611                         Nothing      -> (tycon, mkTyVarTys (tyConTyVars tycon))
 612                         Just famInst -> famInst
 613 \end{code}
 614
 615
 616 %************************************************************************
 617 %*                                                                      *
 618                 NewTypes
 619 %*                                                                      *
 620 %************************************************************************
 621
 622 \begin{code}
 623 splitRecNewType_maybe :: Type -> Maybe Type
 624 -- Sometimes we want to look through a recursive newtype, and that's what happens here
 625 -- It only strips *one layer* off, so the caller will usually call itself recursively
 626 -- Only applied to types of kind *, hence the newtype is always saturated
 627 splitRecNewType_maybe ty | Just ty' <- coreView ty = splitRecNewType_maybe ty'
 628 splitRecNewType_maybe (TyConApp tc tys)
 629   | isClosedNewTyCon tc
 630   = ASSERT( tys `lengthIs` tyConArity tc )      -- splitRecNewType_maybe only be applied
 631                                                 --      to *types* (of kind *)
 632     ASSERT( isRecursiveTyCon tc )               -- Guaranteed by coreView
 633     case newTyConRhs tc of
 634         (tvs, rep_ty) -> ASSERT( length tvs == length tys )
 635                          Just (substTyWith tvs tys rep_ty)
 636
 637 splitRecNewType_maybe other = Nothing
 638
 639
 640
 641 \end{code}
 642
 643
 644 %************************************************************************
 645 %*                                                                      *
 646 \subsection{Kinds and free variables}
 647 %*                                                                      *
 648 %************************************************************************
 649
 650 ---------------------------------------------------------------------
 651                 Finding the kind of a type
 652                 ~~~~~~~~~~~~~~~~~~~~~~~~~~
 653 \begin{code}
 654 typeKind :: Type -> Kind
 655 typeKind (TyConApp tycon tys) = ASSERT( not (isCoercionTyCon tycon) )
 656                                    -- We should be looking for the coercion kind,
 657                                    -- not the type kind
 658                                 foldr (\_ k -> kindFunResult k) (tyConKind tycon) tys
 659 typeKind (NoteTy _ ty)        = typeKind ty
 660 typeKind (PredTy pred)        = predKind pred
 661 typeKind (AppTy fun arg)      = kindFunResult (typeKind fun)
 662 typeKind (ForAllTy tv ty)     = typeKind ty
 663 typeKind (TyVarTy tyvar)      = tyVarKind tyvar
 664 typeKind (FunTy arg res)
 665     -- Hack alert.  The kind of (Int -> Int#) is liftedTypeKind (*),
 666     --              not unliftedTypKind (#)
 667     -- The only things that can be after a function arrow are
 668     --   (a) types (of kind openTypeKind or its sub-kinds)
 669     --   (b) kinds (of super-kind TY) (e.g. * -> (* -> *))
 670     | isTySuperKind k         = k
 671     | otherwise               = ASSERT( isSubOpenTypeKind k) liftedTypeKind
 672     where
 673       k = typeKind res
 674
 675 predKind :: PredType -> Kind
 676 predKind (EqPred {}) = coSuperKind      -- A coercion kind!
 677 predKind (ClassP {}) = liftedTypeKind   -- Class and implicitPredicates are
 678 predKind (IParam {}) = liftedTypeKind   -- always represented by lifted types
 679 \end{code}
 680
 681
 682 ---------------------------------------------------------------------
 683                 Free variables of a type
 684                 ~~~~~~~~~~~~~~~~~~~~~~~~
 685 \begin{code}
 686 tyVarsOfType :: Type -> TyVarSet
 687 -- NB: for type synonyms tyVarsOfType does *not* expand the synonym
 688 tyVarsOfType (TyVarTy tv)               = unitVarSet tv
 689 tyVarsOfType (TyConApp tycon tys)       = tyVarsOfTypes tys
 690 tyVarsOfType (NoteTy (FTVNote tvs) ty2) = tvs
 691 tyVarsOfType (PredTy sty)               = tyVarsOfPred sty
 692 tyVarsOfType (FunTy arg res)            = tyVarsOfType arg `unionVarSet` tyVarsOfType res
 693 tyVarsOfType (AppTy fun arg)            = tyVarsOfType fun `unionVarSet` tyVarsOfType arg
 694 tyVarsOfType (ForAllTy tyvar ty)        = delVarSet (tyVarsOfType ty) tyvar
 695
 696 tyVarsOfTypes :: [Type] -> TyVarSet
 697 tyVarsOfTypes tys = foldr (unionVarSet.tyVarsOfType) emptyVarSet tys
 698
 699 tyVarsOfPred :: PredType -> TyVarSet
 700 tyVarsOfPred (IParam _ ty)    = tyVarsOfType ty
 701 tyVarsOfPred (ClassP _ tys)   = tyVarsOfTypes tys
 702 tyVarsOfPred (EqPred ty1 ty2) = tyVarsOfType ty1 `unionVarSet` tyVarsOfType ty2
 703
 704 tyVarsOfTheta :: ThetaType -> TyVarSet
 705 tyVarsOfTheta = foldr (unionVarSet . tyVarsOfPred) emptyVarSet
 706
 707 -- Add a Note with the free tyvars to the top of the type
 708 addFreeTyVars :: Type -> Type
 709 addFreeTyVars ty@(NoteTy (FTVNote _) _)      = ty
 710 addFreeTyVars ty                             = NoteTy (FTVNote (tyVarsOfType ty)) ty
 711 \end{code}
 712
 713
 714 %************************************************************************
 715 %*                                                                      *
 716 \subsection{TidyType}
 717 %*                                                                      *
 718 %************************************************************************
 719
 720 tidyTy tidies up a type for printing in an error message, or in
 721 an interface file.
 722
 723 It doesn't change the uniques at all, just the print names.
 724
 725 \begin{code}
 726 tidyTyVarBndr :: TidyEnv -> TyVar -> (TidyEnv, TyVar)
 727 tidyTyVarBndr (tidy_env, subst) tyvar
 728   = case tidyOccName tidy_env (getOccName name) of
 729       (tidy', occ') ->  ((tidy', subst'), tyvar')
 730                     where
 731                         subst' = extendVarEnv subst tyvar tyvar'
 732                         tyvar' = setTyVarName tyvar name'
 733                         name'  = tidyNameOcc name occ'
 734   where
 735     name = tyVarName tyvar
 736
 737 tidyFreeTyVars :: TidyEnv -> TyVarSet -> TidyEnv
 738 -- Add the free tyvars to the env in tidy form,
 739 -- so that we can tidy the type they are free in
 740 tidyFreeTyVars env tyvars = fst (tidyOpenTyVars env (varSetElems tyvars))
 741
 742 tidyOpenTyVars :: TidyEnv -> [TyVar] -> (TidyEnv, [TyVar])
 743 tidyOpenTyVars env tyvars = mapAccumL tidyOpenTyVar env tyvars
 744
 745 tidyOpenTyVar :: TidyEnv -> TyVar -> (TidyEnv, TyVar)
 746 -- Treat a new tyvar as a binder, and give it a fresh tidy name
 747 tidyOpenTyVar env@(tidy_env, subst) tyvar
 748   = case lookupVarEnv subst tyvar of
 749         Just tyvar' -> (env, tyvar')            -- Already substituted
 750         Nothing     -> tidyTyVarBndr env tyvar  -- Treat it as a binder
 751
 752 tidyType :: TidyEnv -> Type -> Type
 753 tidyType env@(tidy_env, subst) ty
 754   = go ty
 755   where
 756     go (TyVarTy tv)         = case lookupVarEnv subst tv of
 757                                 Nothing  -> TyVarTy tv
 758                                 Just tv' -> TyVarTy tv'
 759     go (TyConApp tycon tys) = let args = map go tys
 760                               in args `seqList` TyConApp tycon args
 761     go (NoteTy note ty)     = (NoteTy $! (go_note note)) $! (go ty)
 762     go (PredTy sty)         = PredTy (tidyPred env sty)
 763     go (AppTy fun arg)      = (AppTy $! (go fun)) $! (go arg)
 764     go (FunTy fun arg)      = (FunTy $! (go fun)) $! (go arg)
 765     go (ForAllTy tv ty)     = ForAllTy tvp $! (tidyType envp ty)
 766                               where
 767                                 (envp, tvp) = tidyTyVarBndr env tv
 768
 769     go_note note@(FTVNote ftvs) = note  -- No need to tidy the free tyvars
 770
 771 tidyTypes env tys = map (tidyType env) tys
 772
 773 tidyPred :: TidyEnv -> PredType -> PredType
 774 tidyPred env (IParam n ty)     = IParam n (tidyType env ty)
 775 tidyPred env (ClassP clas tys) = ClassP clas (tidyTypes env tys)
 776 tidyPred env (EqPred ty1 ty2)  = EqPred (tidyType env ty1) (tidyType env ty2)
 777 \end{code}
 778
 779
 780 @tidyOpenType@ grabs the free type variables, tidies them
 781 and then uses @tidyType@ to work over the type itself
 782
 783 \begin{code}
 784 tidyOpenType :: TidyEnv -> Type -> (TidyEnv, Type)
 785 tidyOpenType env ty
 786   = (env', tidyType env' ty)
 787   where
 788     env' = tidyFreeTyVars env (tyVarsOfType ty)
 789
 790 tidyOpenTypes :: TidyEnv -> [Type] -> (TidyEnv, [Type])
 791 tidyOpenTypes env tys = mapAccumL tidyOpenType env tys
 792
 793 tidyTopType :: Type -> Type
 794 tidyTopType ty = tidyType emptyTidyEnv ty
 795 \end{code}
 796
 797 \begin{code}
 798
 799 tidyKind :: TidyEnv -> Kind -> (TidyEnv, Kind)
 800 tidyKind env k = tidyOpenType env k
 801
 802 \end{code}
 803
 804
 805 %************************************************************************
 806 %*                                                                      *
 807 \subsection{Liftedness}
 808 %*                                                                      *
 809 %************************************************************************
 810
 811 \begin{code}
 812 isUnLiftedType :: Type -> Bool
 813         -- isUnLiftedType returns True for forall'd unlifted types:
 814         --      x :: forall a. Int#
 815         -- I found bindings like these were getting floated to the top level.
 816         -- They are pretty bogus types, mind you.  It would be better never to
 817         -- construct them
 818
 819 isUnLiftedType ty | Just ty' <- coreView ty = isUnLiftedType ty'
 820 isUnLiftedType (ForAllTy tv ty)  = isUnLiftedType ty
 821 isUnLiftedType (TyConApp tc _)   = isUnLiftedTyCon tc
 822 isUnLiftedType other             = False
 823
 824 isUnboxedTupleType :: Type -> Bool
 825 isUnboxedTupleType ty = case splitTyConApp_maybe ty of
 826                            Just (tc, ty_args) -> isUnboxedTupleTyCon tc
 827                            other              -> False
 828
 829 -- Should only be applied to *types*; hence the assert
 830 isAlgType :: Type -> Bool
 831 isAlgType ty = case splitTyConApp_maybe ty of
 832                         Just (tc, ty_args) -> ASSERT( ty_args `lengthIs` tyConArity tc )
 833                                               isAlgTyCon tc
 834                         other              -> False
 835 \end{code}
 836
 837 @isStrictType@ computes whether an argument (or let RHS) should
 838 be computed strictly or lazily, based only on its type.
 839 Works just like isUnLiftedType, except that it has a special case
 840 for dictionaries.  Since it takes account of ClassP, you might think
 841 this function should be in TcType, but isStrictType is used by DataCon,
 842 which is below TcType in the hierarchy, so it's convenient to put it here.
 843
 844 \begin{code}
 845 isStrictType (PredTy pred)     = isStrictPred pred
 846 isStrictType ty | Just ty' <- coreView ty = isStrictType ty'
 847 isStrictType (ForAllTy tv ty)  = isStrictType ty
 848 isStrictType (TyConApp tc _)   = isUnLiftedTyCon tc
 849 isStrictType other             = False
 850
 851 isStrictPred (ClassP clas _) = opt_DictsStrict && not (isNewTyCon (classTyCon clas))
 852 isStrictPred other           = False
 853         -- We may be strict in dictionary types, but only if it
 854         -- has more than one component.
 855         -- [Being strict in a single-component dictionary risks
 856         --  poking the dictionary component, which is wrong.]
 857 \end{code}
 858
 859 \begin{code}
 860 isPrimitiveType :: Type -> Bool
 861 -- Returns types that are opaque to Haskell.
 862 -- Most of these are unlifted, but now that we interact with .NET, we
 863 -- may have primtive (foreign-imported) types that are lifted
 864 isPrimitiveType ty = case splitTyConApp_maybe ty of
 865                         Just (tc, ty_args) -> ASSERT( ty_args `lengthIs` tyConArity tc )
 866                                               isPrimTyCon tc
 867                         other              -> False
 868 \end{code}
 869
 870
 871 %************************************************************************
 872 %*                                                                      *
 873 \subsection{Sequencing on types
 874 %*                                                                      *
 875 %************************************************************************
 876
 877 \begin{code}
 878 seqType :: Type -> ()
 879 seqType (TyVarTy tv)      = tv `seq` ()
 880 seqType (AppTy t1 t2)     = seqType t1 `seq` seqType t2
 881 seqType (FunTy t1 t2)     = seqType t1 `seq` seqType t2
 882 seqType (NoteTy note t2)  = seqNote note `seq` seqType t2
 883 seqType (PredTy p)        = seqPred p
 884 seqType (TyConApp tc tys) = tc `seq` seqTypes tys
 885 seqType (ForAllTy tv ty)  = tv `seq` seqType ty
 886
 887 seqTypes :: [Type] -> ()
 888 seqTypes []       = ()
 889 seqTypes (ty:tys) = seqType ty `seq` seqTypes tys
 890
 891 seqNote :: TyNote -> ()
 892 seqNote (FTVNote set) = sizeUniqSet set `seq` ()
 893
 894 seqPred :: PredType -> ()
 895 seqPred (ClassP c tys)   = c `seq` seqTypes tys
 896 seqPred (IParam n ty)    = n `seq` seqType ty
 897 seqPred (EqPred ty1 ty2) = seqType ty1 `seq` seqType ty2
 898 \end{code}
 899
 900
 901 %************************************************************************
 902 %*                                                                      *
 903                 Equality for Core types
 904         (We don't use instances so that we know where it happens)
 905 %*                                                                      *
 906 %************************************************************************
 907
 908 Note that eqType works right even for partial applications of newtypes.
 909 See Note [Newtype eta] in TyCon.lhs
 910
 911 \begin{code}
 912 coreEqType :: Type -> Type -> Bool
 913 coreEqType t1 t2
 914   = eq rn_env t1 t2
 915   where
 916     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfType t1 `unionVarSet` tyVarsOfType t2))
 917
 918     eq env (TyVarTy tv1)       (TyVarTy tv2)     = rnOccL env tv1 == rnOccR env tv2
 919     eq env (ForAllTy tv1 t1)   (ForAllTy tv2 t2) = eq (rnBndr2 env tv1 tv2) t1 t2
 920     eq env (AppTy s1 t1)       (AppTy s2 t2)     = eq env s1 s2 && eq env t1 t2
 921     eq env (FunTy s1 t1)       (FunTy s2 t2)     = eq env s1 s2 && eq env t1 t2
 922     eq env (TyConApp tc1 tys1) (TyConApp tc2 tys2)
 923         | tc1 == tc2, all2 (eq env) tys1 tys2 = True
 924                         -- The lengths should be equal because
 925                         -- the two types have the same kind
 926         -- NB: if the type constructors differ that does not
 927         --     necessarily mean that the types aren't equal
 928         --     (synonyms, newtypes)
 929         -- Even if the type constructors are the same, but the arguments
 930         -- differ, the two types could be the same (e.g. if the arg is just
 931         -- ignored in the RHS).  In both these cases we fall through to an
 932         -- attempt to expand one side or the other.
 933
 934         -- Now deal with newtypes, synonyms, pred-tys
 935     eq env t1 t2 | Just t1' <- coreView t1 = eq env t1' t2
 936                  | Just t2' <- coreView t2 = eq env t1 t2'
 937
 938         -- Fall through case; not equal!
 939     eq env t1 t2 = False
 940 \end{code}
 941
 942
 943 %************************************************************************
 944 %*                                                                      *
 945                 Comparision for source types
 946         (We don't use instances so that we know where it happens)
 947 %*                                                                      *
 948 %************************************************************************
 949
 950 Note that
 951         tcEqType, tcCmpType
 952 do *not* look through newtypes, PredTypes
 953
 954 \begin{code}
 955 tcEqType :: Type -> Type -> Bool
 956 tcEqType t1 t2 = isEqual $ cmpType t1 t2
 957
 958 tcEqTypes :: [Type] -> [Type] -> Bool
 959 tcEqTypes tys1 tys2 = isEqual $ cmpTypes tys1 tys2
 960
 961 tcCmpType :: Type -> Type -> Ordering
 962 tcCmpType t1 t2 = cmpType t1 t2
 963
 964 tcCmpTypes :: [Type] -> [Type] -> Ordering
 965 tcCmpTypes tys1 tys2 = cmpTypes tys1 tys2
 966
 967 tcEqPred :: PredType -> PredType -> Bool
 968 tcEqPred p1 p2 = isEqual $ cmpPred p1 p2
 969
 970 tcCmpPred :: PredType -> PredType -> Ordering
 971 tcCmpPred p1 p2 = cmpPred p1 p2
 972
 973 tcEqTypeX :: RnEnv2 -> Type -> Type -> Bool
 974 tcEqTypeX env t1 t2 = isEqual $ cmpTypeX env t1 t2
 975 \end{code}
 976
 977 Now here comes the real worker
 978
 979 \begin{code}
 980 cmpType :: Type -> Type -> Ordering
 981 cmpType t1 t2 = cmpTypeX rn_env t1 t2
 982   where
 983     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfType t1 `unionVarSet` tyVarsOfType t2))
 984
 985 cmpTypes :: [Type] -> [Type] -> Ordering
 986 cmpTypes ts1 ts2 = cmpTypesX rn_env ts1 ts2
 987   where
 988     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfTypes ts1 `unionVarSet` tyVarsOfTypes ts2))
 989
 990 cmpPred :: PredType -> PredType -> Ordering
 991 cmpPred p1 p2 = cmpPredX rn_env p1 p2
 992   where
 993     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfPred p1 `unionVarSet` tyVarsOfPred p2))
 994
 995 cmpTypeX :: RnEnv2 -> Type -> Type -> Ordering  -- Main workhorse
 996 cmpTypeX env t1 t2 | Just t1' <- tcView t1 = cmpTypeX env t1' t2
 997                    | Just t2' <- tcView t2 = cmpTypeX env t1 t2'
 998
 999 cmpTypeX env (TyVarTy tv1)       (TyVarTy tv2)       = rnOccL env tv1 `compare` rnOccR env tv2
1000 cmpTypeX env (ForAllTy tv1 t1)   (ForAllTy tv2 t2)   = cmpTypeX (rnBndr2 env tv1 tv2) t1 t2
1001 cmpTypeX env (AppTy s1 t1)       (AppTy s2 t2)       = cmpTypeX env s1 s2 `thenCmp` cmpTypeX env t1 t2
1002 cmpTypeX env (FunTy s1 t1)       (FunTy s2 t2)       = cmpTypeX env s1 s2 `thenCmp` cmpTypeX env t1 t2
1003 cmpTypeX env (PredTy p1)         (PredTy p2)         = cmpPredX env p1 p2
1004 cmpTypeX env (TyConApp tc1 tys1) (TyConApp tc2 tys2) = (tc1 `compare` tc2) `thenCmp` cmpTypesX env tys1 tys2
1005 cmpTypeX env t1                 (NoteTy _ t2)        = cmpTypeX env t1 t2
1006
1007     -- Deal with the rest: TyVarTy < AppTy < FunTy < TyConApp < ForAllTy < PredTy
1008 cmpTypeX env (AppTy _ _) (TyVarTy _) = GT
1009
1010 cmpTypeX env (FunTy _ _) (TyVarTy _) = GT
1011 cmpTypeX env (FunTy _ _) (AppTy _ _) = GT
1012
1013 cmpTypeX env (TyConApp _ _) (TyVarTy _) = GT
1014 cmpTypeX env (TyConApp _ _) (AppTy _ _) = GT
1015 cmpTypeX env (TyConApp _ _) (FunTy _ _) = GT
1016
1017 cmpTypeX env (ForAllTy _ _) (TyVarTy _)    = GT
1018 cmpTypeX env (ForAllTy _ _) (AppTy _ _)    = GT
1019 cmpTypeX env (ForAllTy _ _) (FunTy _ _)    = GT
1020 cmpTypeX env (ForAllTy _ _) (TyConApp _ _) = GT
1021
1022 cmpTypeX env (PredTy _)   t2            = GT
1023
1024 cmpTypeX env _ _ = LT
1025
1026 -------------
1027 cmpTypesX :: RnEnv2 -> [Type] -> [Type] -> Ordering
1028 cmpTypesX env []        []        = EQ
1029 cmpTypesX env (t1:tys1) (t2:tys2) = cmpTypeX env t1 t2 `thenCmp` cmpTypesX env tys1 tys2
1030 cmpTypesX env []        tys       = LT
1031 cmpTypesX env ty        []        = GT
1032
1033 -------------
1034 cmpPredX :: RnEnv2 -> PredType -> PredType -> Ordering
1035 cmpPredX env (IParam n1 ty1) (IParam n2 ty2) = (n1 `compare` n2) `thenCmp` cmpTypeX env ty1 ty2
1036         -- Compare names only for implicit parameters
1037         -- This comparison is used exclusively (I believe)
1038         -- for the Avails finite map built in TcSimplify
1039         -- If the types differ we keep them distinct so that we see
1040         -- a distinct pair to run improvement on
1041 cmpPredX env (ClassP c1 tys1) (ClassP c2 tys2) = (c1 `compare` c2) `thenCmp` (cmpTypesX env tys1 tys2)
1042 cmpPredX env (EqPred ty1 ty2) (EqPred ty1' ty2') = (cmpTypeX env ty1 ty1') `thenCmp` (cmpTypeX env ty2 ty2')
1043
1044 -- Constructor order: IParam < ClassP < EqPred
1045 cmpPredX env (IParam {})     _              = LT
1046 cmpPredX env (ClassP {})    (IParam {})     = GT
1047 cmpPredX env (ClassP {})    (EqPred {})     = LT
1048 cmpPredX env (EqPred {})    _               = GT
1049 \end{code}
1050
1051 PredTypes are used as a FM key in TcSimplify,
1052 so we take the easy path and make them an instance of Ord
1053
1054 \begin{code}
1055 instance Eq  PredType where { (==)    = tcEqPred }
1056 instance Ord PredType where { compare = tcCmpPred }
1057 \end{code}
1058
1059
1060 %************************************************************************
1061 %*                                                                      *
1062                 Type substitutions
1063 %*                                                                      *
1064 %************************************************************************
1065
1066 \begin{code}
1067 data TvSubst
1068   = TvSubst InScopeSet  -- The in-scope type variables
1069             TvSubstEnv  -- The substitution itself
1070         -- See Note [Apply Once]
1071         -- and Note [Extending the TvSubstEnv]
1072
1073 {- ----------------------------------------------------------
1074
1075 Note [Apply Once]
1076 ~~~~~~~~~~~~~~~~~
1077 We use TvSubsts to instantiate things, and we might instantiate
1078         forall a b. ty
1079 \with the types
1080         [a, b], or [b, a].
1081 So the substition might go [a->b, b->a].  A similar situation arises in Core
1082 when we find a beta redex like
1083         (/\ a /\ b -> e) b a
1084 Then we also end up with a substition that permutes type variables. Other
1085 variations happen to; for example [a -> (a, b)].
1086
1087         ***************************************************
1088         *** So a TvSubst must be applied precisely once ***
1089         ***************************************************
1090
1091 A TvSubst is not idempotent, but, unlike the non-idempotent substitution
1092 we use during unifications, it must not be repeatedly applied.
1093
1094 Note [Extending the TvSubst]
1095 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1096 The following invariant should hold of a TvSubst
1097
1098         The in-scope set is needed *only* to
1099         guide the generation of fresh uniques
1100
1101         In particular, the *kind* of the type variables in
1102         the in-scope set is not relevant
1103
1104 This invariant allows a short-cut when the TvSubstEnv is empty:
1105 if the TvSubstEnv is empty --- i.e. (isEmptyTvSubt subst) holds ---
1106 then (substTy subst ty) does nothing.
1107
1108 For example, consider:
1109         (/\a. /\b:(a~Int). ...b..) Int
1110 We substitute Int for 'a'.  The Unique of 'b' does not change, but
1111 nevertheless we add 'b' to the TvSubstEnv, because b's type does change
1112
1113 This invariant has several crucial consequences:
1114
1115 * In substTyVarBndr, we need extend the TvSubstEnv
1116         - if the unique has changed
1117         - or if the kind has changed
1118
1119 * In substTyVar, we do not need to consult the in-scope set;
1120   the TvSubstEnv is enough
1121
1122 * In substTy, substTheta, we can short-circuit when the TvSubstEnv is empty
1123
1124
1125 -------------------------------------------------------------- -}
1126
1127
1128 type TvSubstEnv = TyVarEnv Type
1129         -- A TvSubstEnv is used both inside a TvSubst (with the apply-once
1130         -- invariant discussed in Note [Apply Once]), and also independently
1131         -- in the middle of matching, and unification (see Types.Unify)
1132         -- So you have to look at the context to know if it's idempotent or
1133         -- apply-once or whatever
1134 emptyTvSubstEnv :: TvSubstEnv
1135 emptyTvSubstEnv = emptyVarEnv
1136
1137 composeTvSubst :: InScopeSet -> TvSubstEnv -> TvSubstEnv -> TvSubstEnv
1138 -- (compose env1 env2)(x) is env1(env2(x)); i.e. apply env2 then env1
1139 -- It assumes that both are idempotent
1140 -- Typically, env1 is the refinement to a base substitution env2
1141 composeTvSubst in_scope env1 env2
1142   = env1 `plusVarEnv` mapVarEnv (substTy subst1) env2
1143         -- First apply env1 to the range of env2
1144         -- Then combine the two, making sure that env1 loses if
1145         -- both bind the same variable; that's why env1 is the
1146         --  *left* argument to plusVarEnv, because the right arg wins
1147   where
1148     subst1 = TvSubst in_scope env1
1149
1150 emptyTvSubst = TvSubst emptyInScopeSet emptyVarEnv
1151
1152 isEmptyTvSubst :: TvSubst -> Bool
1153          -- See Note [Extending the TvSubstEnv]
1154 isEmptyTvSubst (TvSubst _ env) = isEmptyVarEnv env
1155
1156 mkTvSubst :: InScopeSet -> TvSubstEnv -> TvSubst
1157 mkTvSubst = TvSubst
1158
1159 getTvSubstEnv :: TvSubst -> TvSubstEnv
1160 getTvSubstEnv (TvSubst _ env) = env
1161
1162 getTvInScope :: TvSubst -> InScopeSet
1163 getTvInScope (TvSubst in_scope _) = in_scope
1164
1165 isInScope :: Var -> TvSubst -> Bool
1166 isInScope v (TvSubst in_scope _) = v `elemInScopeSet` in_scope
1167
1168 notElemTvSubst :: TyVar -> TvSubst -> Bool
1169 notElemTvSubst tv (TvSubst _ env) = not (tv `elemVarEnv` env)
1170
1171 setTvSubstEnv :: TvSubst -> TvSubstEnv -> TvSubst
1172 setTvSubstEnv (TvSubst in_scope _) env = TvSubst in_scope env
1173
1174 extendTvInScope :: TvSubst -> [Var] -> TvSubst
1175 extendTvInScope (TvSubst in_scope env) vars = TvSubst (extendInScopeSetList in_scope vars) env
1176
1177 extendTvSubst :: TvSubst -> TyVar -> Type -> TvSubst
1178 extendTvSubst (TvSubst in_scope env) tv ty = TvSubst in_scope (extendVarEnv env tv ty)
1179
1180 extendTvSubstList :: TvSubst -> [TyVar] -> [Type] -> TvSubst
1181 extendTvSubstList (TvSubst in_scope env) tvs tys
1182   = TvSubst in_scope (extendVarEnvList env (tvs `zip` tys))
1183
1184 -- mkOpenTvSubst and zipOpenTvSubst generate the in-scope set from
1185 -- the types given; but it's just a thunk so with a bit of luck
1186 -- it'll never be evaluated
1187
1188 mkOpenTvSubst :: TvSubstEnv -> TvSubst
1189 mkOpenTvSubst env = TvSubst (mkInScopeSet (tyVarsOfTypes (varEnvElts env))) env
1190
1191 zipOpenTvSubst :: [TyVar] -> [Type] -> TvSubst
1192 zipOpenTvSubst tyvars tys
1193 #ifdef DEBUG
1194   | length tyvars /= length tys
1195   = pprTrace "zipOpenTvSubst" (ppr tyvars $$ ppr tys) emptyTvSubst
1196   | otherwise
1197 #endif
1198   = TvSubst (mkInScopeSet (tyVarsOfTypes tys)) (zipTyEnv tyvars tys)
1199
1200 -- mkTopTvSubst is called when doing top-level substitutions.
1201 -- Here we expect that the free vars of the range of the
1202 -- substitution will be empty.
1203 mkTopTvSubst :: [(TyVar, Type)] -> TvSubst
1204 mkTopTvSubst prs = TvSubst emptyInScopeSet (mkVarEnv prs)
1205
1206 zipTopTvSubst :: [TyVar] -> [Type] -> TvSubst
1207 zipTopTvSubst tyvars tys
1208 #ifdef DEBUG
1209   | length tyvars /= length tys
1210   = pprTrace "zipOpenTvSubst" (ppr tyvars $$ ppr tys) emptyTvSubst
1211   | otherwise
1212 #endif
1213   = TvSubst emptyInScopeSet (zipTyEnv tyvars tys)
1214
1215 zipTyEnv :: [TyVar] -> [Type] -> TvSubstEnv
1216 zipTyEnv tyvars tys
1217 #ifdef DEBUG
1218   | length tyvars /= length tys
1219   = pprTrace "mkTopTvSubst" (ppr tyvars $$ ppr tys) emptyVarEnv
1220   | otherwise
1221 #endif
1222   = zip_ty_env tyvars tys emptyVarEnv
1223
1224 -- Later substitutions in the list over-ride earlier ones,
1225 -- but there should be no loops
1226 zip_ty_env []       []       env = env
1227 zip_ty_env (tv:tvs) (ty:tys) env = zip_ty_env tvs tys (extendVarEnv env tv ty)
1228         -- There used to be a special case for when
1229         --      ty == TyVarTy tv
1230         -- (a not-uncommon case) in which case the substitution was dropped.
1231         -- But the type-tidier changes the print-name of a type variable without
1232         -- changing the unique, and that led to a bug.   Why?  Pre-tidying, we had
1233         -- a type {Foo t}, where Foo is a one-method class.  So Foo is really a newtype.
1234         -- And it happened that t was the type variable of the class.  Post-tiding,
1235         -- it got turned into {Foo t2}.  The ext-core printer expanded this using
1236         -- sourceTypeRep, but that said "Oh, t == t2" because they have the same unique,
1237         -- and so generated a rep type mentioning t not t2.
1238         --
1239         -- Simplest fix is to nuke the "optimisation"
1240 zip_ty_env tvs      tys      env   = pprTrace "Var/Type length mismatch: " (ppr tvs $$ ppr tys) env
1241 -- zip_ty_env _ _ env = env
1242
1243 instance Outputable TvSubst where
1244   ppr (TvSubst ins env)
1245     = brackets $ sep[ ptext SLIT("TvSubst"),
1246                       nest 2 (ptext SLIT("In scope:") <+> ppr ins),
1247                       nest 2 (ptext SLIT("Env:") <+> ppr env) ]
1248 \end{code}
1249
1250 %************************************************************************
1251 %*                                                                      *
1252                 Performing type substitutions
1253 %*                                                                      *
1254 %************************************************************************
1255
1256 \begin{code}
1257 substTyWith :: [TyVar] -> [Type] -> Type -> Type
1258 substTyWith tvs tys = ASSERT( length tvs == length tys )
1259                       substTy (zipOpenTvSubst tvs tys)
1260
1261 substTy :: TvSubst -> Type  -> Type
1262 substTy subst ty | isEmptyTvSubst subst = ty
1263                  | otherwise            = subst_ty subst ty
1264
1265 substTys :: TvSubst -> [Type] -> [Type]
1266 substTys subst tys | isEmptyTvSubst subst = tys
1267                    | otherwise            = map (subst_ty subst) tys
1268
1269 substTheta :: TvSubst -> ThetaType -> ThetaType
1270 substTheta subst theta
1271   | isEmptyTvSubst subst = theta
1272   | otherwise            = map (substPred subst) theta
1273
1274 substPred :: TvSubst -> PredType -> PredType
1275 substPred subst (IParam n ty)     = IParam n (subst_ty subst ty)
1276 substPred subst (ClassP clas tys) = ClassP clas (map (subst_ty subst) tys)
1277 substPred subst (EqPred ty1 ty2)  = EqPred (subst_ty subst ty1) (subst_ty subst ty2)
1278
1279 deShadowTy :: TyVarSet -> Type -> Type  -- Remove any nested binders mentioning tvs
1280 deShadowTy tvs ty
1281   = subst_ty (mkTvSubst in_scope emptyTvSubstEnv) ty
1282   where
1283     in_scope = mkInScopeSet tvs
1284
1285 subst_ty :: TvSubst -> Type -> Type
1286 -- subst_ty is the main workhorse for type substitution
1287 --
1288 -- Note that the in_scope set is poked only if we hit a forall
1289 -- so it may often never be fully computed
1290 subst_ty subst ty
1291    = go ty
1292   where
1293     go (TyVarTy tv)                = substTyVar subst tv
1294     go (TyConApp tc tys)           = let args = map go tys
1295                                      in  args `seqList` TyConApp tc args
1296
1297     go (PredTy p)                  = PredTy $! (substPred subst p)
1298
1299     go (NoteTy (FTVNote _) ty2)    = go ty2             -- Discard the free tyvar note
1300
1301     go (FunTy arg res)             = (FunTy $! (go arg)) $! (go res)
1302     go (AppTy fun arg)             = mkAppTy (go fun) $! (go arg)
1303                 -- The mkAppTy smart constructor is important
1304                 -- we might be replacing (a Int), represented with App
1305                 -- by [Int], represented with TyConApp
1306     go (ForAllTy tv ty)            = case substTyVarBndr subst tv of
1307                                         (subst', tv') -> ForAllTy tv' $! (subst_ty subst' ty)
1308
1309 substTyVar :: TvSubst -> TyVar  -> Type
1310 substTyVar subst@(TvSubst in_scope env) tv
1311   = case lookupTyVar subst tv of {
1312         Nothing -> TyVarTy tv;
1313         Just ty -> ty   -- See Note [Apply Once]
1314     }
1315
1316 lookupTyVar :: TvSubst -> TyVar  -> Maybe Type
1317         -- See Note [Extending the TvSubst]
1318 lookupTyVar (TvSubst in_scope env) tv = lookupVarEnv env tv
1319
1320 substTyVarBndr :: TvSubst -> TyVar -> (TvSubst, TyVar)
1321 substTyVarBndr subst@(TvSubst in_scope env) old_var
1322   = (TvSubst (in_scope `extendInScopeSet` new_var) new_env, new_var)
1323   where
1324     is_co_var = isCoVar old_var
1325
1326     new_env | no_change = delVarEnv env old_var
1327             | otherwise = extendVarEnv env old_var (TyVarTy new_var)
1328
1329     no_change = new_var == old_var && not is_co_var
1330         -- no_change means that the new_var is identical in
1331         -- all respects to the old_var (same unique, same kind)
1332         -- See Note [Extending the TvSubst]
1333         --
1334         -- In that case we don't need to extend the substitution
1335         -- to map old to new.  But instead we must zap any
1336         -- current substitution for the variable. For example:
1337         --      (\x.e) with id_subst = [x |-> e']
1338         -- Here we must simply zap the substitution for x
1339
1340     new_var = uniqAway in_scope subst_old_var
1341         -- The uniqAway part makes sure the new variable is not already in scope
1342
1343     subst_old_var -- subst_old_var is old_var with the substitution applied to its kind
1344                   -- It's only worth doing the substitution for coercions,
1345                   -- becuase only they can have free type variables
1346         | is_co_var = setTyVarKind old_var (substTy subst (tyVarKind old_var))
1347         | otherwise = old_var
1348 \end{code}
1349
1350 ----------------------------------------------------
1351 -- Kind Stuff
1352
1353 Kinds
1354 ~~~~~
1355 There's a little subtyping at the kind level:
1356
1357                  ?
1358                 / \
1359                /   \
1360               ??   (#)
1361              /  \
1362             *   #
1363
1364 where   *    [LiftedTypeKind]   means boxed type
1365         #    [UnliftedTypeKind] means unboxed type
1366         (#)  [UbxTupleKind]     means unboxed tuple
1367         ??   [ArgTypeKind]      is the lub of *,#
1368         ?    [OpenTypeKind]     means any type at all
1369
1370 In particular:
1371
1372         error :: forall a:?. String -> a
1373         (->)  :: ?? -> ? -> *
1374         (\(x::t) -> ...)        Here t::?? (i.e. not unboxed tuple)
1375
1376 \begin{code}
1377 type KindVar = TyVar  -- invariant: KindVar will always be a
1378                       -- TcTyVar with details MetaTv TauTv ...
1379 -- kind var constructors and functions are in TcType
1380
1381 type SimpleKind = Kind
1382 \end{code}
1383
1384 Kind inference
1385 ~~~~~~~~~~~~~~
1386 During kind inference, a kind variable unifies only with
1387 a "simple kind", sk
1388         sk ::= * | sk1 -> sk2
1389 For example
1390         data T a = MkT a (T Int#)
1391 fails.  We give T the kind (k -> *), and the kind variable k won't unify
1392 with # (the kind of Int#).
1393
1394 Type inference
1395 ~~~~~~~~~~~~~~
1396 When creating a fresh internal type variable, we give it a kind to express
1397 constraints on it.  E.g. in (\x->e) we make up a fresh type variable for x,
1398 with kind ??.
1399
1400 During unification we only bind an internal type variable to a type
1401 whose kind is lower in the sub-kind hierarchy than the kind of the tyvar.
1402
1403 When unifying two internal type variables, we collect their kind constraints by
1404 finding the GLB of the two.  Since the partial order is a tree, they only
1405 have a glb if one is a sub-kind of the other.  In that case, we bind the
1406 less-informative one to the more informative one.  Neat, eh?
1407
1408
1409 \begin{code}
1410
1411 \end{code}
1412
1413 %************************************************************************
1414 %*                                                                      *
1415         Functions over Kinds
1416 %*                                                                      *
1417 %************************************************************************
1418
1419 \begin{code}
1420 kindFunResult :: Kind -> Kind
1421 kindFunResult k = funResultTy k
1422
1423 splitKindFunTys :: Kind -> ([Kind],Kind)
1424 splitKindFunTys k = splitFunTys k
1425
1426 splitKindFunTysN :: Int -> Kind -> ([Kind],Kind)
1427 splitKindFunTysN k = splitFunTysN k
1428
1429 isUbxTupleKind, isOpenTypeKind, isArgTypeKind, isUnliftedTypeKind :: Kind -> Bool
1430
1431 isOpenTypeKindCon tc    = tyConUnique tc == openTypeKindTyConKey
1432
1433 isOpenTypeKind (TyConApp tc _) = isOpenTypeKindCon tc
1434 isOpenTypeKind other           = False
1435
1436 isUbxTupleKindCon tc = tyConUnique tc == ubxTupleKindTyConKey
1437
1438 isUbxTupleKind (TyConApp tc _) = isUbxTupleKindCon tc
1439 isUbxTupleKind other           = False
1440
1441 isArgTypeKindCon tc = tyConUnique tc == argTypeKindTyConKey
1442
1443 isArgTypeKind (TyConApp tc _) = isArgTypeKindCon tc
1444 isArgTypeKind other = False
1445
1446 isUnliftedTypeKindCon tc = tyConUnique tc == unliftedTypeKindTyConKey
1447
1448 isUnliftedTypeKind (TyConApp tc _) = isUnliftedTypeKindCon tc
1449 isUnliftedTypeKind other           = False
1450
1451 isSubOpenTypeKind :: Kind -> Bool
1452 -- True of any sub-kind of OpenTypeKind (i.e. anything except arrow)
1453 isSubOpenTypeKind (FunTy k1 k2)    = ASSERT2 ( isKind k1, text "isSubOpenTypeKind" <+> ppr k1 <+> text "::" <+> ppr (typeKind k1) )
1454                                      ASSERT2 ( isKind k2, text "isSubOpenTypeKind" <+> ppr k2 <+> text "::" <+> ppr (typeKind k2) )
1455                                      False
1456 isSubOpenTypeKind (TyConApp kc []) = ASSERT( isKind (TyConApp kc []) ) True
1457 isSubOpenTypeKind other            = ASSERT( isKind other ) False
1458          -- This is a conservative answer
1459          -- It matters in the call to isSubKind in
1460          -- checkExpectedKind.
1461
1462 isSubArgTypeKindCon kc
1463   | isUnliftedTypeKindCon kc = True
1464   | isLiftedTypeKindCon kc   = True
1465   | isArgTypeKindCon kc      = True
1466   | otherwise                = False
1467
1468 isSubArgTypeKind :: Kind -> Bool
1469 -- True of any sub-kind of ArgTypeKind
1470 isSubArgTypeKind (TyConApp kc []) = isSubArgTypeKindCon kc
1471 isSubArgTypeKind other            = False
1472
1473 isSuperKind :: Type -> Bool
1474 isSuperKind (TyConApp (skc) []) = isSuperKindTyCon skc
1475 isSuperKind other = False
1476
1477 isKind :: Kind -> Bool
1478 isKind k = isSuperKind (typeKind k)
1479
1480
1481
1482 isSubKind :: Kind -> Kind -> Bool
1483 -- (k1 `isSubKind` k2) checks that k1 <: k2
1484 isSubKind (TyConApp kc1 []) (TyConApp kc2 []) = kc1 `isSubKindCon` kc2
1485 isSubKind (FunTy a1 r1) (FunTy a2 r2)         = (a2 `isSubKind` a1) && (r1 `isSubKind` r2)
1486 isSubKind (PredTy (EqPred ty1 ty2)) (PredTy (EqPred ty1' ty2'))
1487   = ty1 `tcEqType` ty1' && ty2 `tcEqType` ty2'
1488 isSubKind k1            k2                    = False
1489
1490 eqKind :: Kind -> Kind -> Bool
1491 eqKind = tcEqType
1492
1493 isSubKindCon :: TyCon -> TyCon -> Bool
1494 -- (kc1 `isSubKindCon` kc2) checks that kc1 <: kc2
1495 isSubKindCon kc1 kc2
1496   | isLiftedTypeKindCon kc1   && isLiftedTypeKindCon kc2   = True
1497   | isUnliftedTypeKindCon kc1 && isUnliftedTypeKindCon kc2 = True
1498   | isUbxTupleKindCon kc1     && isUbxTupleKindCon kc2     = True
1499   | isOpenTypeKindCon kc2                                  = True
1500                            -- we already know kc1 is not a fun, its a TyCon
1501   | isArgTypeKindCon kc2      && isSubArgTypeKindCon kc1   = True
1502   | otherwise                                              = False
1503
1504 defaultKind :: Kind -> Kind
1505 -- Used when generalising: default kind '?' and '??' to '*'
1506 --
1507 -- When we generalise, we make generic type variables whose kind is
1508 -- simple (* or *->* etc).  So generic type variables (other than
1509 -- built-in constants like 'error') always have simple kinds.  This is important;
1510 -- consider
1511 --      f x = True
1512 -- We want f to get type
1513 --      f :: forall (a::*). a -> Bool
1514 -- Not
1515 --      f :: forall (a::??). a -> Bool
1516 -- because that would allow a call like (f 3#) as well as (f True),
1517 --and the calling conventions differ.  This defaulting is done in TcMType.zonkTcTyVarBndr.
1518 defaultKind k
1519   | isSubOpenTypeKind k = liftedTypeKind
1520   | isSubArgTypeKind k  = liftedTypeKind
1521   | otherwise        = k
1522
1523 isEqPred :: PredType -> Bool
1524 isEqPred (EqPred _ _) = True
1525 isEqPred other        = False
1526 \end{code}