compiler/types/Type.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1998
   4 %
   5
   6 Type - public interface
   7
   8 \begin{code}
   9 -- The above warning supression flag is a temporary kludge.
  10 -- While working on this module you are encouraged to remove it and fix
  11 -- any warnings in the module. See
  12 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  13 -- for details
  14
  15 -- | Main functions for manipulating types and type-related things
  16 module Type (
  17         -- Note some of this is just re-exports from TyCon..
  18
  19         -- * Main data types representing Types
  20         -- $type_classification
  21
  22         -- $representation_types
  23         TyThing(..), Type, PredType(..), ThetaType,
  24
  25         -- ** Constructing and deconstructing types
  26         mkTyVarTy, mkTyVarTys, getTyVar, getTyVar_maybe,
  27
  28         mkAppTy, mkAppTys, splitAppTy, splitAppTys,
  29         splitAppTy_maybe, repSplitAppTy_maybe,
  30
  31         mkFunTy, mkFunTys, splitFunTy, splitFunTy_maybe,
  32         splitFunTys, splitFunTysN,
  33         funResultTy, funArgTy, zipFunTys,
  34
  35         mkTyConApp, mkTyConTy,
  36         tyConAppTyCon, tyConAppArgs,
  37         splitTyConApp_maybe, splitTyConApp,
  38
  39         mkForAllTy, mkForAllTys, splitForAllTy_maybe, splitForAllTys,
  40         applyTy, applyTys, applyTysD, isForAllTy, dropForAlls,
  41
  42         -- (Newtypes)
  43         newTyConInstRhs, carefullySplitNewType_maybe,
  44
  45         -- (Type families)
  46         tyFamInsts, predFamInsts,
  47
  48         -- (Source types)
  49         mkPredTy, mkPredTys, mkFamilyTyConApp, isEqPred,
  50
  51         -- ** Common type constructors
  52         funTyCon,
  53
  54         -- ** Predicates on types
  55         isTyVarTy, isFunTy, isDictTy,
  56
  57         -- (Lifting and boxity)
  58         isUnLiftedType, isUnboxedTupleType, isAlgType, isClosedAlgType,
  59         isPrimitiveType, isStrictType, isStrictPred,
  60
  61         -- * Main data types representing Kinds
  62         -- $kind_subtyping
  63         Kind, SimpleKind, KindVar,
  64
  65         -- ** Common Kinds and SuperKinds
  66         liftedTypeKind, unliftedTypeKind, openTypeKind,
  67         argTypeKind, ubxTupleKind,
  68
  69         tySuperKind, coSuperKind,
  70
  71         -- ** Common Kind type constructors
  72         liftedTypeKindTyCon, openTypeKindTyCon, unliftedTypeKindTyCon,
  73         argTypeKindTyCon, ubxTupleKindTyCon,
  74
  75         -- * Type free variables
  76         tyVarsOfType, tyVarsOfTypes, tyVarsOfPred, tyVarsOfTheta,
  77         expandTypeSynonyms,
  78
  79         -- * Tidying type related things up for printing
  80         tidyType,      tidyTypes,
  81         tidyOpenType,  tidyOpenTypes,
  82         tidyTyVarBndr, tidyFreeTyVars,
  83         tidyOpenTyVar, tidyOpenTyVars,
  84         tidyTopType,   tidyPred,
  85         tidyKind,
  86
  87         -- * Type comparison
  88         coreEqType, coreEqType2,
  89         tcEqType, tcEqTypes, tcCmpType, tcCmpTypes,
  90         tcEqPred, tcEqPredX, tcCmpPred, tcEqTypeX, tcPartOfType, tcPartOfPred,
  91
  92         -- * Forcing evaluation of types
  93         seqType, seqTypes,
  94
  95         -- * Other views onto Types
  96         coreView, tcView, kindView,
  97
  98         repType,
  99
 100         -- * Type representation for the code generator
 101         PrimRep(..),
 102
 103         typePrimRep, predTypeRep,
 104
 105         -- * Main type substitution data types
 106         TvSubstEnv,     -- Representation widely visible
 107         TvSubst(..),    -- Representation visible to a few friends
 108
 109         -- ** Manipulating type substitutions
 110         emptyTvSubstEnv, emptyTvSubst,
 111
 112         mkTvSubst, mkOpenTvSubst, zipOpenTvSubst, zipTopTvSubst, mkTopTvSubst, notElemTvSubst,
 113         getTvSubstEnv, setTvSubstEnv, zapTvSubstEnv, getTvInScope,
 114         extendTvInScope, extendTvInScopeList,
 115         extendTvSubst, extendTvSubstList, isInScope, composeTvSubst, zipTyEnv,
 116         isEmptyTvSubst,
 117
 118         -- ** Performing substitution on types
 119         substTy, substTys, substTyWith, substTysWith, substTheta,
 120         substPred, substTyVar, substTyVars, substTyVarBndr, deShadowTy, lookupTyVar,
 121
 122         -- * Pretty-printing
 123         pprType, pprParendType, pprTypeApp, pprTyThingCategory, pprTyThing, pprForAll,
 124         pprPred, pprEqPred, pprTheta, pprThetaArrow, pprClassPred, pprKind, pprParendKind,
 125
 126         pprSourceTyCon
 127     ) where
 128
 129 #include "HsVersions.h"
 130
 131 -- We import the representation and primitive functions from TypeRep.
 132 -- Many things are reexported, but not the representation!
 133
 134 import TypeRep
 135
 136 -- friends:
 137 import Var
 138 import VarEnv
 139 import VarSet
 140
 141 import Name
 142 import Class
 143 import TyCon
 144
 145 -- others
 146 import StaticFlags
 147 import Util
 148 import Outputable
 149 import FastString
 150
 151 import Data.List
 152 import Data.Maybe       ( isJust )
 153
 154 infixr 3 `mkFunTy`      -- Associates to the right
 155 \end{code}
 156
 157 \begin{code}
 158 -- $type_classification
 159 -- #type_classification#
 160 --
 161 -- Types are one of:
 162 --
 163 -- [Unboxed]            Iff its representation is other than a pointer
 164 --                      Unboxed types are also unlifted.
 165 --
 166 -- [Lifted]             Iff it has bottom as an element.
 167 --                      Closures always have lifted types: i.e. any
 168 --                      let-bound identifier in Core must have a lifted
 169 --                      type. Operationally, a lifted object is one that
 170 --                      can be entered.
 171 --                      Only lifted types may be unified with a type variable.
 172 --
 173 -- [Algebraic]          Iff it is a type with one or more constructors, whether
 174 --                      declared with @data@ or @newtype@.
 175 --                      An algebraic type is one that can be deconstructed
 176 --                      with a case expression. This is /not/ the same as
 177 --                      lifted types, because we also include unboxed
 178 --                      tuples in this classification.
 179 --
 180 -- [Data]               Iff it is a type declared with @data@, or a boxed tuple.
 181 --
 182 -- [Primitive]          Iff it is a built-in type that can't be expressed in Haskell.
 183 --
 184 -- Currently, all primitive types are unlifted, but that's not necessarily
 185 -- the case: for example, @Int@ could be primitive.
 186 --
 187 -- Some primitive types are unboxed, such as @Int#@, whereas some are boxed
 188 -- but unlifted (such as @ByteArray#@).  The only primitive types that we
 189 -- classify as algebraic are the unboxed tuples.
 190 --
 191 -- Some examples of type classifications that may make this a bit clearer are:
 192 --
 193 -- @
 194 -- Type         primitive       boxed           lifted          algebraic
 195 -- -----------------------------------------------------------------------------
 196 -- Int#         Yes             No              No              No
 197 -- ByteArray#   Yes             Yes             No              No
 198 -- (\# a, b \#)   Yes             No              No              Yes
 199 -- (  a, b  )   No              Yes             Yes             Yes
 200 -- [a]          No              Yes             Yes             Yes
 201 -- @
 202
 203 -- $representation_types
 204 -- A /source type/ is a type that is a separate type as far as the type checker is
 205 -- concerned, but which has a more low-level representation as far as Core-to-Core
 206 -- passes and the rest of the back end is concerned. Notably, 'PredTy's are removed
 207 -- from the representation type while they do exist in the source types.
 208 --
 209 -- You don't normally have to worry about this, as the utility functions in
 210 -- this module will automatically convert a source into a representation type
 211 -- if they are spotted, to the best of it's abilities. If you don't want this
 212 -- to happen, use the equivalent functions from the "TcType" module.
 213 \end{code}
 214
 215 %************************************************************************
 216 %*                                                                      *
 217                 Type representation
 218 %*                                                                      *
 219 %************************************************************************
 220
 221 \begin{code}
 222 {-# INLINE coreView #-}
 223 coreView :: Type -> Maybe Type
 224 -- ^ In Core, we \"look through\" non-recursive newtypes and 'PredTypes': this
 225 -- function tries to obtain a different view of the supplied type given this
 226 --
 227 -- Strips off the /top layer only/ of a type to give
 228 -- its underlying representation type.
 229 -- Returns Nothing if there is nothing to look through.
 230 --
 231 -- In the case of @newtype@s, it returns one of:
 232 --
 233 -- 1) A vanilla 'TyConApp' (recursive newtype, or non-saturated)
 234 --
 235 -- 2) The newtype representation (otherwise), meaning the
 236 --    type written in the RHS of the newtype declaration,
 237 --    which may itself be a newtype
 238 --
 239 -- For example, with:
 240 --
 241 -- > newtype R = MkR S
 242 -- > newtype S = MkS T
 243 -- > newtype T = MkT (T -> T)
 244 --
 245 -- 'expandNewTcApp' on:
 246 --
 247 --  * @R@ gives @Just S@
 248 --  * @S@ gives @Just T@
 249 --  * @T@ gives @Nothing@ (no expansion)
 250
 251 -- By being non-recursive and inlined, this case analysis gets efficiently
 252 -- joined onto the case analysis that the caller is already doing
 253 coreView (PredTy p)
 254   | isEqPred p             = Nothing
 255   | otherwise              = Just (predTypeRep p)
 256 coreView (TyConApp tc tys) | Just (tenv, rhs, tys') <- coreExpandTyCon_maybe tc tys
 257                            = Just (mkAppTys (substTy (mkTopTvSubst tenv) rhs) tys')
 258                                 -- Its important to use mkAppTys, rather than (foldl AppTy),
 259                                 -- because the function part might well return a
 260                                 -- partially-applied type constructor; indeed, usually will!
 261 coreView _                 = Nothing
 262
 263
 264
 265 -----------------------------------------------
 266 {-# INLINE tcView #-}
 267 tcView :: Type -> Maybe Type
 268 -- ^ Similar to 'coreView', but for the type checker, which just looks through synonyms
 269 tcView (TyConApp tc tys) | Just (tenv, rhs, tys') <- tcExpandTyCon_maybe tc tys
 270                          = Just (mkAppTys (substTy (mkTopTvSubst tenv) rhs) tys')
 271 tcView _                 = Nothing
 272
 273 -----------------------------------------------
 274 expandTypeSynonyms :: Type -> Type
 275 -- ^ Expand out all type synonyms.  Actually, it'd suffice to expand out
 276 -- just the ones that discard type variables (e.g.  type Funny a = Int)
 277 -- But we don't know which those are currently, so we just expand all.
 278 expandTypeSynonyms ty
 279   = go ty
 280   where
 281     go (TyConApp tc tys)
 282       | Just (tenv, rhs, tys') <- tcExpandTyCon_maybe tc tys
 283       = go (mkAppTys (substTy (mkTopTvSubst tenv) rhs) tys')
 284       | otherwise
 285       = TyConApp tc (map go tys)
 286     go (TyVarTy tv)    = TyVarTy tv
 287     go (AppTy t1 t2)   = AppTy (go t1) (go t2)
 288     go (FunTy t1 t2)   = FunTy (go t1) (go t2)
 289     go (ForAllTy tv t) = ForAllTy tv (go t)
 290     go (PredTy p)      = PredTy (go_pred p)
 291
 292     go_pred (ClassP c ts)  = ClassP c (map go ts)
 293     go_pred (IParam ip t)  = IParam ip (go t)
 294     go_pred (EqPred t1 t2) = EqPred (go t1) (go t2)
 295
 296 -----------------------------------------------
 297 {-# INLINE kindView #-}
 298 kindView :: Kind -> Maybe Kind
 299 -- ^ Similar to 'coreView' or 'tcView', but works on 'Kind's
 300
 301 -- For the moment, we don't even handle synonyms in kinds
 302 kindView _            = Nothing
 303 \end{code}
 304
 305
 306 %************************************************************************
 307 %*                                                                      *
 308 \subsection{Constructor-specific functions}
 309 %*                                                                      *
 310 %************************************************************************
 311
 312
 313 ---------------------------------------------------------------------
 314                                 TyVarTy
 315                                 ~~~~~~~
 316 \begin{code}
 317 mkTyVarTy  :: TyVar   -> Type
 318 mkTyVarTy  = TyVarTy
 319
 320 mkTyVarTys :: [TyVar] -> [Type]
 321 mkTyVarTys = map mkTyVarTy -- a common use of mkTyVarTy
 322
 323 -- | Attempts to obtain the type variable underlying a 'Type', and panics with the
 324 -- given message if this is not a type variable type. See also 'getTyVar_maybe'
 325 getTyVar :: String -> Type -> TyVar
 326 getTyVar msg ty = case getTyVar_maybe ty of
 327                     Just tv -> tv
 328                     Nothing -> panic ("getTyVar: " ++ msg)
 329
 330 isTyVarTy :: Type -> Bool
 331 isTyVarTy ty = isJust (getTyVar_maybe ty)
 332
 333 -- | Attempts to obtain the type variable underlying a 'Type'
 334 getTyVar_maybe :: Type -> Maybe TyVar
 335 getTyVar_maybe ty | Just ty' <- coreView ty = getTyVar_maybe ty'
 336 getTyVar_maybe (TyVarTy tv)                 = Just tv
 337 getTyVar_maybe _                            = Nothing
 338
 339 \end{code}
 340
 341
 342 ---------------------------------------------------------------------
 343                                 AppTy
 344                                 ~~~~~
 345 We need to be pretty careful with AppTy to make sure we obey the
 346 invariant that a TyConApp is always visibly so.  mkAppTy maintains the
 347 invariant: use it.
 348
 349 \begin{code}
 350 -- | Applies a type to another, as in e.g. @k a@
 351 mkAppTy :: Type -> Type -> Type
 352 mkAppTy orig_ty1 orig_ty2
 353   = mk_app orig_ty1
 354   where
 355     mk_app (TyConApp tc tys) = mkTyConApp tc (tys ++ [orig_ty2])
 356     mk_app _                 = AppTy orig_ty1 orig_ty2
 357         -- Note that the TyConApp could be an
 358         -- under-saturated type synonym.  GHC allows that; e.g.
 359         --      type Foo k = k a -> k a
 360         --      type Id x = x
 361         --      foo :: Foo Id -> Foo Id
 362         --
 363         -- Here Id is partially applied in the type sig for Foo,
 364         -- but once the type synonyms are expanded all is well
 365
 366 mkAppTys :: Type -> [Type] -> Type
 367 mkAppTys orig_ty1 []        = orig_ty1
 368         -- This check for an empty list of type arguments
 369         -- avoids the needless loss of a type synonym constructor.
 370         -- For example: mkAppTys Rational []
 371         --   returns to (Ratio Integer), which has needlessly lost
 372         --   the Rational part.
 373 mkAppTys orig_ty1 orig_tys2
 374   = mk_app orig_ty1
 375   where
 376     mk_app (TyConApp tc tys) = mkTyConApp tc (tys ++ orig_tys2)
 377                                 -- mkTyConApp: see notes with mkAppTy
 378     mk_app _                 = foldl AppTy orig_ty1 orig_tys2
 379
 380 -------------
 381 splitAppTy_maybe :: Type -> Maybe (Type, Type)
 382 -- ^ Attempt to take a type application apart, whether it is a
 383 -- function, type constructor, or plain type application. Note
 384 -- that type family applications are NEVER unsaturated by this!
 385 splitAppTy_maybe ty | Just ty' <- coreView ty
 386                     = splitAppTy_maybe ty'
 387 splitAppTy_maybe ty = repSplitAppTy_maybe ty
 388
 389 -------------
 390 repSplitAppTy_maybe :: Type -> Maybe (Type,Type)
 391 -- ^ Does the AppTy split as in 'splitAppTy_maybe', but assumes that
 392 -- any Core view stuff is already done
 393 repSplitAppTy_maybe (FunTy ty1 ty2)   = Just (TyConApp funTyCon [ty1], ty2)
 394 repSplitAppTy_maybe (AppTy ty1 ty2)   = Just (ty1, ty2)
 395 repSplitAppTy_maybe (TyConApp tc tys)
 396   | isDecomposableTyCon tc || length tys > tyConArity tc
 397   = case snocView tys of       -- never create unsaturated type family apps
 398       Just (tys', ty') -> Just (TyConApp tc tys', ty')
 399       Nothing          -> Nothing
 400 repSplitAppTy_maybe _other = Nothing
 401 -------------
 402 splitAppTy :: Type -> (Type, Type)
 403 -- ^ Attempts to take a type application apart, as in 'splitAppTy_maybe',
 404 -- and panics if this is not possible
 405 splitAppTy ty = case splitAppTy_maybe ty of
 406                         Just pr -> pr
 407                         Nothing -> panic "splitAppTy"
 408
 409 -------------
 410 splitAppTys :: Type -> (Type, [Type])
 411 -- ^ Recursively splits a type as far as is possible, leaving a residual
 412 -- type being applied to and the type arguments applied to it. Never fails,
 413 -- even if that means returning an empty list of type applications.
 414 splitAppTys ty = split ty ty []
 415   where
 416     split orig_ty ty args | Just ty' <- coreView ty = split orig_ty ty' args
 417     split _       (AppTy ty arg)        args = split ty ty (arg:args)
 418     split _       (TyConApp tc tc_args) args
 419       = let -- keep type families saturated
 420             n | isDecomposableTyCon tc = 0
 421               | otherwise              = tyConArity tc
 422             (tc_args1, tc_args2) = splitAt n tc_args
 423         in
 424         (TyConApp tc tc_args1, tc_args2 ++ args)
 425     split _       (FunTy ty1 ty2)       args = ASSERT( null args )
 426                                                (TyConApp funTyCon [], [ty1,ty2])
 427     split orig_ty _                     args = (orig_ty, args)
 428
 429 \end{code}
 430
 431
 432 ---------------------------------------------------------------------
 433                                 FunTy
 434                                 ~~~~~
 435
 436 \begin{code}
 437 mkFunTy :: Type -> Type -> Type
 438 -- ^ Creates a function type from the given argument and result type
 439 mkFunTy arg@(PredTy (EqPred {})) res = ForAllTy (mkWildCoVar arg) res
 440 mkFunTy arg                      res = FunTy    arg               res
 441
 442 mkFunTys :: [Type] -> Type -> Type
 443 mkFunTys tys ty = foldr mkFunTy ty tys
 444
 445 isFunTy :: Type -> Bool
 446 isFunTy ty = isJust (splitFunTy_maybe ty)
 447
 448 splitFunTy :: Type -> (Type, Type)
 449 -- ^ Attempts to extract the argument and result types from a type, and
 450 -- panics if that is not possible. See also 'splitFunTy_maybe'
 451 splitFunTy ty | Just ty' <- coreView ty = splitFunTy ty'
 452 splitFunTy (FunTy arg res)   = (arg, res)
 453 splitFunTy other             = pprPanic "splitFunTy" (ppr other)
 454
 455 splitFunTy_maybe :: Type -> Maybe (Type, Type)
 456 -- ^ Attempts to extract the argument and result types from a type
 457 splitFunTy_maybe ty | Just ty' <- coreView ty = splitFunTy_maybe ty'
 458 splitFunTy_maybe (FunTy arg res)   = Just (arg, res)
 459 splitFunTy_maybe _                 = Nothing
 460
 461 splitFunTys :: Type -> ([Type], Type)
 462 splitFunTys ty = split [] ty ty
 463   where
 464     split args orig_ty ty | Just ty' <- coreView ty = split args orig_ty ty'
 465     split args _       (FunTy arg res)   = split (arg:args) res res
 466     split args orig_ty _                 = (reverse args, orig_ty)
 467
 468 splitFunTysN :: Int -> Type -> ([Type], Type)
 469 -- ^ Split off exactly the given number argument types, and panics if that is not possible
 470 splitFunTysN 0 ty = ([], ty)
 471 splitFunTysN n ty = case splitFunTy ty of { (arg, res) ->
 472                     case splitFunTysN (n-1) res of { (args, res) ->
 473                     (arg:args, res) }}
 474
 475 -- | Splits off argument types from the given type and associating
 476 -- them with the things in the input list from left to right. The
 477 -- final result type is returned, along with the resulting pairs of
 478 -- objects and types, albeit with the list of pairs in reverse order.
 479 -- Panics if there are not enough argument types for the input list.
 480 zipFunTys :: Outputable a => [a] -> Type -> ([(a, Type)], Type)
 481 zipFunTys orig_xs orig_ty = split [] orig_xs orig_ty orig_ty
 482   where
 483     split acc []     nty _                 = (reverse acc, nty)
 484     split acc xs     nty ty
 485           | Just ty' <- coreView ty        = split acc xs nty ty'
 486     split acc (x:xs) _   (FunTy arg res)   = split ((x,arg):acc) xs res res
 487     split _   _      _   _                 = pprPanic "zipFunTys" (ppr orig_xs <+> ppr orig_ty)
 488
 489 funResultTy :: Type -> Type
 490 -- ^ Extract the function result type and panic if that is not possible
 491 funResultTy ty | Just ty' <- coreView ty = funResultTy ty'
 492 funResultTy (FunTy _arg res)  = res
 493 funResultTy ty                = pprPanic "funResultTy" (ppr ty)
 494
 495 funArgTy :: Type -> Type
 496 -- ^ Extract the function argument type and panic if that is not possible
 497 funArgTy ty | Just ty' <- coreView ty = funArgTy ty'
 498 funArgTy (FunTy arg _res)  = arg
 499 funArgTy ty                = pprPanic "funArgTy" (ppr ty)
 500 \end{code}
 501
 502 ---------------------------------------------------------------------
 503                                 TyConApp
 504                                 ~~~~~~~~
 505
 506 \begin{code}
 507 -- | A key function: builds a 'TyConApp' or 'FunTy' as apppropriate to its arguments.
 508 -- Applies its arguments to the constructor from left to right
 509 mkTyConApp :: TyCon -> [Type] -> Type
 510 mkTyConApp tycon tys
 511   | isFunTyCon tycon, [ty1,ty2] <- tys
 512   = FunTy ty1 ty2
 513
 514   | otherwise
 515   = TyConApp tycon tys
 516
 517 -- | Create the plain type constructor type which has been applied to no type arguments at all.
 518 mkTyConTy :: TyCon -> Type
 519 mkTyConTy tycon = mkTyConApp tycon []
 520
 521 -- splitTyConApp "looks through" synonyms, because they don't
 522 -- mean a distinct type, but all other type-constructor applications
 523 -- including functions are returned as Just ..
 524
 525 -- | The same as @fst . splitTyConApp@
 526 tyConAppTyCon :: Type -> TyCon
 527 tyConAppTyCon ty = fst (splitTyConApp ty)
 528
 529 -- | The same as @snd . splitTyConApp@
 530 tyConAppArgs :: Type -> [Type]
 531 tyConAppArgs ty = snd (splitTyConApp ty)
 532
 533 -- | Attempts to tease a type apart into a type constructor and the application
 534 -- of a number of arguments to that constructor. Panics if that is not possible.
 535 -- See also 'splitTyConApp_maybe'
 536 splitTyConApp :: Type -> (TyCon, [Type])
 537 splitTyConApp ty = case splitTyConApp_maybe ty of
 538                         Just stuff -> stuff
 539                         Nothing    -> pprPanic "splitTyConApp" (ppr ty)
 540
 541 -- | Attempts to tease a type apart into a type constructor and the application
 542 -- of a number of arguments to that constructor
 543 splitTyConApp_maybe :: Type -> Maybe (TyCon, [Type])
 544 splitTyConApp_maybe ty | Just ty' <- coreView ty = splitTyConApp_maybe ty'
 545 splitTyConApp_maybe (TyConApp tc tys) = Just (tc, tys)
 546 splitTyConApp_maybe (FunTy arg res)   = Just (funTyCon, [arg,res])
 547 splitTyConApp_maybe _                 = Nothing
 548
 549 newTyConInstRhs :: TyCon -> [Type] -> Type
 550 -- ^ Unwrap one 'layer' of newtype on a type constructor and its arguments, using an
 551 -- eta-reduced version of the @newtype@ if possible
 552 newTyConInstRhs tycon tys
 553     = ASSERT2( equalLength tvs tys1, ppr tycon $$ ppr tys $$ ppr tvs )
 554       mkAppTys (substTyWith tvs tys1 ty) tys2
 555   where
 556     (tvs, ty)    = newTyConEtadRhs tycon
 557     (tys1, tys2) = splitAtList tvs tys
 558 \end{code}
 559
 560
 561 ---------------------------------------------------------------------
 562                                 SynTy
 563                                 ~~~~~
 564
 565 Notes on type synonyms
 566 ~~~~~~~~~~~~~~~~~~~~~~
 567 The various "split" functions (splitFunTy, splitRhoTy, splitForAllTy) try
 568 to return type synonyms whereever possible. Thus
 569
 570         type Foo a = a -> a
 571
 572 we want
 573         splitFunTys (a -> Foo a) = ([a], Foo a)
 574 not                                ([a], a -> a)
 575
 576 The reason is that we then get better (shorter) type signatures in
 577 interfaces.  Notably this plays a role in tcTySigs in TcBinds.lhs.
 578
 579
 580 Note [Expanding newtypes]
 581 ~~~~~~~~~~~~~~~~~~~~~~~~~
 582 When expanding a type to expose a data-type constructor, we need to be
 583 careful about newtypes, lest we fall into an infinite loop. Here are
 584 the key examples:
 585
 586   newtype Id  x = MkId x
 587   newtype Fix f = MkFix (f (Fix f))
 588   newtype T     = MkT (T -> T)
 589
 590   Type           Expansion
 591  --------------------------
 592   T              T -> T
 593   Fix Maybe      Maybe (Fix Maybe)
 594   Id (Id Int)    Int
 595   Fix Id         NO NO NO
 596
 597 Notice that we can expand T, even though it's recursive.
 598 And we can expand Id (Id Int), even though the Id shows up
 599 twice at the outer level.
 600
 601 So, when expanding, we keep track of when we've seen a recursive
 602 newtype at outermost level; and bale out if we see it again.
 603
 604
 605                 Representation types
 606                 ~~~~~~~~~~~~~~~~~~~~
 607
 608 \begin{code}
 609 -- | Looks through:
 610 --
 611 --      1. For-alls
 612 --      2. Synonyms
 613 --      3. Predicates
 614 --      4. All newtypes, including recursive ones, but not newtype families
 615 --
 616 -- It's useful in the back end of the compiler.
 617 repType :: Type -> Type
 618 -- Only applied to types of kind *; hence tycons are saturated
 619 repType ty
 620   = go [] ty
 621   where
 622     go :: [TyCon] -> Type -> Type
 623     go rec_nts ty | Just ty' <- coreView ty     -- Expand synonyms
 624         = go rec_nts ty'
 625
 626     go rec_nts (ForAllTy _ ty)                  -- Look through foralls
 627         = go rec_nts ty
 628
 629     go rec_nts (TyConApp tc tys)                -- Expand newtypes
 630       | Just (rec_nts', ty') <- carefullySplitNewType_maybe rec_nts tc tys
 631       = go rec_nts' ty'
 632
 633     go _ ty = ty
 634
 635
 636 carefullySplitNewType_maybe :: [TyCon] -> TyCon -> [Type] -> Maybe ([TyCon],Type)
 637 -- Return the representation of a newtype, unless
 638 -- we've seen it already: see Note [Expanding newtypes]
 639 carefullySplitNewType_maybe rec_nts tc tys
 640   | isNewTyCon tc
 641   , not (tc `elem` rec_nts)  = Just (rec_nts', newTyConInstRhs tc tys)
 642   | otherwise                = Nothing
 643   where
 644     rec_nts' | isRecursiveTyCon tc = tc:rec_nts
 645              | otherwise           = rec_nts
 646
 647
 648 -- ToDo: this could be moved to the code generator, using splitTyConApp instead
 649 -- of inspecting the type directly.
 650
 651 -- | Discovers the primitive representation of a more abstract 'Type'
 652 typePrimRep :: Type -> PrimRep
 653 typePrimRep ty = case repType ty of
 654                    TyConApp tc _ -> tyConPrimRep tc
 655                    FunTy _ _     -> PtrRep
 656                    AppTy _ _     -> PtrRep      -- See note below
 657                    TyVarTy _     -> PtrRep
 658                    _             -> pprPanic "typePrimRep" (ppr ty)
 659         -- Types of the form 'f a' must be of kind *, not *#, so
 660         -- we are guaranteed that they are represented by pointers.
 661         -- The reason is that f must have kind *->*, not *->*#, because
 662         -- (we claim) there is no way to constrain f's kind any other
 663         -- way.
 664 \end{code}
 665
 666
 667 ---------------------------------------------------------------------
 668                                 ForAllTy
 669                                 ~~~~~~~~
 670
 671 \begin{code}
 672 mkForAllTy :: TyVar -> Type -> Type
 673 mkForAllTy tyvar ty
 674   = ForAllTy tyvar ty
 675
 676 -- | Wraps foralls over the type using the provided 'TyVar's from left to right
 677 mkForAllTys :: [TyVar] -> Type -> Type
 678 mkForAllTys tyvars ty = foldr ForAllTy ty tyvars
 679
 680 isForAllTy :: Type -> Bool
 681 isForAllTy (ForAllTy _ _) = True
 682 isForAllTy _              = False
 683
 684 -- | Attempts to take a forall type apart, returning the bound type variable
 685 -- and the remainder of the type
 686 splitForAllTy_maybe :: Type -> Maybe (TyVar, Type)
 687 splitForAllTy_maybe ty = splitFAT_m ty
 688   where
 689     splitFAT_m ty | Just ty' <- coreView ty = splitFAT_m ty'
 690     splitFAT_m (ForAllTy tyvar ty)          = Just(tyvar, ty)
 691     splitFAT_m _                            = Nothing
 692
 693 -- | Attempts to take a forall type apart, returning all the immediate such bound
 694 -- type variables and the remainder of the type. Always suceeds, even if that means
 695 -- returning an empty list of 'TyVar's
 696 splitForAllTys :: Type -> ([TyVar], Type)
 697 splitForAllTys ty = split ty ty []
 698    where
 699      split orig_ty ty tvs | Just ty' <- coreView ty = split orig_ty ty' tvs
 700      split _       (ForAllTy tv ty)  tvs = split ty ty (tv:tvs)
 701      split orig_ty _                 tvs = (reverse tvs, orig_ty)
 702
 703 -- | Equivalent to @snd . splitForAllTys@
 704 dropForAlls :: Type -> Type
 705 dropForAlls ty = snd (splitForAllTys ty)
 706 \end{code}
 707
 708 -- (mkPiType now in CoreUtils)
 709
 710 applyTy, applyTys
 711 ~~~~~~~~~~~~~~~~~
 712
 713 \begin{code}
 714 -- | Instantiate a forall type with one or more type arguments.
 715 -- Used when we have a polymorphic function applied to type args:
 716 --
 717 -- > f t1 t2
 718 --
 719 -- We use @applyTys type-of-f [t1,t2]@ to compute the type of the expression.
 720 -- Panics if no application is possible.
 721 applyTy :: Type -> Type -> Type
 722 applyTy ty arg | Just ty' <- coreView ty = applyTy ty' arg
 723 applyTy (ForAllTy tv ty) arg = substTyWith [tv] [arg] ty
 724 applyTy _                _   = panic "applyTy"
 725
 726 applyTys :: Type -> [Type] -> Type
 727 -- ^ This function is interesting because:
 728 --
 729 --      1. The function may have more for-alls than there are args
 730 --
 731 --      2. Less obviously, it may have fewer for-alls
 732 --
 733 -- For case 2. think of:
 734 --
 735 -- > applyTys (forall a.a) [forall b.b, Int]
 736 --
 737 -- This really can happen, via dressing up polymorphic types with newtype
 738 -- clothing.  Here's an example:
 739 --
 740 -- > newtype R = R (forall a. a->a)
 741 -- > foo = case undefined :: R of
 742 -- >            R f -> f ()
 743
 744 applyTys ty args = applyTysD empty ty args
 745
 746 applyTysD :: SDoc -> Type -> [Type] -> Type     -- Debug version
 747 applyTysD _   orig_fun_ty []      = orig_fun_ty
 748 applyTysD doc orig_fun_ty arg_tys
 749   | n_tvs == n_args     -- The vastly common case
 750   = substTyWith tvs arg_tys rho_ty
 751   | n_tvs > n_args      -- Too many for-alls
 752   = substTyWith (take n_args tvs) arg_tys
 753                 (mkForAllTys (drop n_args tvs) rho_ty)
 754   | otherwise           -- Too many type args
 755   = ASSERT2( n_tvs > 0, doc $$ ppr orig_fun_ty )        -- Zero case gives infnite loop!
 756     applyTysD doc (substTyWith tvs (take n_tvs arg_tys) rho_ty)
 757                   (drop n_tvs arg_tys)
 758   where
 759     (tvs, rho_ty) = splitForAllTys orig_fun_ty
 760     n_tvs = length tvs
 761     n_args = length arg_tys
 762 \end{code}
 763
 764
 765 %************************************************************************
 766 %*                                                                      *
 767 \subsection{Source types}
 768 %*                                                                      *
 769 %************************************************************************
 770
 771 Source types are always lifted.
 772
 773 The key function is predTypeRep which gives the representation of a source type:
 774
 775 \begin{code}
 776 mkPredTy :: PredType -> Type
 777 mkPredTy pred = PredTy pred
 778
 779 mkPredTys :: ThetaType -> [Type]
 780 mkPredTys preds = map PredTy preds
 781
 782 isEqPred :: PredType -> Bool
 783 isEqPred (EqPred _ _) = True
 784 isEqPred _            = False
 785
 786 predTypeRep :: PredType -> Type
 787 -- ^ Convert a 'PredType' to its representation type. However, it unwraps
 788 -- only the outermost level; for example, the result might be a newtype application
 789 predTypeRep (IParam _ ty)     = ty
 790 predTypeRep (ClassP clas tys) = mkTyConApp (classTyCon clas) tys
 791         -- Result might be a newtype application, but the consumer will
 792         -- look through that too if necessary
 793 predTypeRep (EqPred ty1 ty2) = pprPanic "predTypeRep" (ppr (EqPred ty1 ty2))
 794
 795 mkFamilyTyConApp :: TyCon -> [Type] -> Type
 796 -- ^ Given a family instance TyCon and its arg types, return the
 797 -- corresponding family type.  E.g:
 798 --
 799 -- > data family T a
 800 -- > data instance T (Maybe b) = MkT b
 801 --
 802 -- Where the instance tycon is :RTL, so:
 803 --
 804 -- > mkFamilyTyConApp :RTL Int  =  T (Maybe Int)
 805 mkFamilyTyConApp tc tys
 806   | Just (fam_tc, fam_tys) <- tyConFamInst_maybe tc
 807   , let fam_subst = zipTopTvSubst (tyConTyVars tc) tys
 808   = mkTyConApp fam_tc (substTys fam_subst fam_tys)
 809   | otherwise
 810   = mkTyConApp tc tys
 811
 812 -- | Pretty prints a 'TyCon', using the family instance in case of a
 813 -- representation tycon.  For example:
 814 --
 815 -- > data T [a] = ...
 816 --
 817 -- In that case we want to print @T [a]@, where @T@ is the family 'TyCon'
 818 pprSourceTyCon :: TyCon -> SDoc
 819 pprSourceTyCon tycon
 820   | Just (fam_tc, tys) <- tyConFamInst_maybe tycon
 821   = ppr $ fam_tc `TyConApp` tys        -- can't be FunTyCon
 822   | otherwise
 823   = ppr tycon
 824
 825 isDictTy :: Type -> Bool
 826 isDictTy ty = case splitTyConApp_maybe ty of
 827                 Just (tc, _) -> isClassTyCon tc
 828                 Nothing      -> False
 829 \end{code}
 830
 831
 832 %************************************************************************
 833 %*                                                                      *
 834              The free variables of a type
 835 %*                                                                      *
 836 %************************************************************************
 837
 838 \begin{code}
 839 tyVarsOfType :: Type -> TyVarSet
 840 -- ^ NB: for type synonyms tyVarsOfType does /not/ expand the synonym
 841 tyVarsOfType (TyVarTy tv)               = unitVarSet tv
 842 tyVarsOfType (TyConApp _ tys)           = tyVarsOfTypes tys
 843 tyVarsOfType (PredTy sty)               = tyVarsOfPred sty
 844 tyVarsOfType (FunTy arg res)            = tyVarsOfType arg `unionVarSet` tyVarsOfType res
 845 tyVarsOfType (AppTy fun arg)            = tyVarsOfType fun `unionVarSet` tyVarsOfType arg
 846 tyVarsOfType (ForAllTy tyvar ty)        = delVarSet (tyVarsOfType ty) tyvar
 847
 848 tyVarsOfTypes :: [Type] -> TyVarSet
 849 tyVarsOfTypes tys = foldr (unionVarSet.tyVarsOfType) emptyVarSet tys
 850
 851 tyVarsOfPred :: PredType -> TyVarSet
 852 tyVarsOfPred (IParam _ ty)    = tyVarsOfType ty
 853 tyVarsOfPred (ClassP _ tys)   = tyVarsOfTypes tys
 854 tyVarsOfPred (EqPred ty1 ty2) = tyVarsOfType ty1 `unionVarSet` tyVarsOfType ty2
 855
 856 tyVarsOfTheta :: ThetaType -> TyVarSet
 857 tyVarsOfTheta = foldr (unionVarSet . tyVarsOfPred) emptyVarSet
 858 \end{code}
 859
 860
 861 %************************************************************************
 862 %*                                                                      *
 863 \subsection{Type families}
 864 %*                                                                      *
 865 %************************************************************************
 866
 867 \begin{code}
 868 -- | Finds type family instances occuring in a type after expanding synonyms.
 869 tyFamInsts :: Type -> [(TyCon, [Type])]
 870 tyFamInsts ty
 871   | Just exp_ty <- tcView ty    = tyFamInsts exp_ty
 872 tyFamInsts (TyVarTy _)          = []
 873 tyFamInsts (TyConApp tc tys)
 874   | isOpenSynTyCon tc           = [(tc, tys)]
 875   | otherwise                   = concat (map tyFamInsts tys)
 876 tyFamInsts (FunTy ty1 ty2)      = tyFamInsts ty1 ++ tyFamInsts ty2
 877 tyFamInsts (AppTy ty1 ty2)      = tyFamInsts ty1 ++ tyFamInsts ty2
 878 tyFamInsts (ForAllTy _ ty)      = tyFamInsts ty
 879 tyFamInsts (PredTy pty)         = predFamInsts pty
 880
 881 -- | Finds type family instances occuring in a predicate type after expanding
 882 -- synonyms.
 883 predFamInsts :: PredType -> [(TyCon, [Type])]
 884 predFamInsts (ClassP _cla tys) = concat (map tyFamInsts tys)
 885 predFamInsts (IParam _ ty)     = tyFamInsts ty
 886 predFamInsts (EqPred ty1 ty2)  = tyFamInsts ty1 ++ tyFamInsts ty2
 887 \end{code}
 888
 889
 890 %************************************************************************
 891 %*                                                                      *
 892 \subsection{TidyType}
 893 %*                                                                      *
 894 %************************************************************************
 895
 896 \begin{code}
 897 -- | This tidies up a type for printing in an error message, or in
 898 -- an interface file.
 899 --
 900 -- It doesn't change the uniques at all, just the print names.
 901 tidyTyVarBndr :: TidyEnv -> TyVar -> (TidyEnv, TyVar)
 902 tidyTyVarBndr env@(tidy_env, subst) tyvar
 903   = case tidyOccName tidy_env (getOccName name) of
 904       (tidy', occ') -> ((tidy', subst'), tyvar'')
 905         where
 906           subst' = extendVarEnv subst tyvar tyvar''
 907           tyvar' = setTyVarName tyvar name'
 908           name'  = tidyNameOcc name occ'
 909                 -- Don't forget to tidy the kind for coercions!
 910           tyvar'' | isCoVar tyvar = setTyVarKind tyvar' kind'
 911                   | otherwise     = tyvar'
 912           kind'  = tidyType env (tyVarKind tyvar)
 913   where
 914     name = tyVarName tyvar
 915
 916 tidyFreeTyVars :: TidyEnv -> TyVarSet -> TidyEnv
 917 -- ^ Add the free 'TyVar's to the env in tidy form,
 918 -- so that we can tidy the type they are free in
 919 tidyFreeTyVars env tyvars = fst (tidyOpenTyVars env (varSetElems tyvars))
 920
 921 tidyOpenTyVars :: TidyEnv -> [TyVar] -> (TidyEnv, [TyVar])
 922 tidyOpenTyVars env tyvars = mapAccumL tidyOpenTyVar env tyvars
 923
 924 tidyOpenTyVar :: TidyEnv -> TyVar -> (TidyEnv, TyVar)
 925 -- ^ Treat a new 'TyVar' as a binder, and give it a fresh tidy name
 926 -- using the environment if one has not already been allocated. See
 927 -- also 'tidyTyVarBndr'
 928 tidyOpenTyVar env@(_, subst) tyvar
 929   = case lookupVarEnv subst tyvar of
 930         Just tyvar' -> (env, tyvar')            -- Already substituted
 931         Nothing     -> tidyTyVarBndr env tyvar  -- Treat it as a binder
 932
 933 tidyType :: TidyEnv -> Type -> Type
 934 tidyType env@(_, subst) ty
 935   = go ty
 936   where
 937     go (TyVarTy tv)         = case lookupVarEnv subst tv of
 938                                 Nothing  -> TyVarTy tv
 939                                 Just tv' -> TyVarTy tv'
 940     go (TyConApp tycon tys) = let args = map go tys
 941                               in args `seqList` TyConApp tycon args
 942     go (PredTy sty)         = PredTy (tidyPred env sty)
 943     go (AppTy fun arg)      = (AppTy $! (go fun)) $! (go arg)
 944     go (FunTy fun arg)      = (FunTy $! (go fun)) $! (go arg)
 945     go (ForAllTy tv ty)     = ForAllTy tvp $! (tidyType envp ty)
 946                               where
 947                                 (envp, tvp) = tidyTyVarBndr env tv
 948
 949 tidyTypes :: TidyEnv -> [Type] -> [Type]
 950 tidyTypes env tys = map (tidyType env) tys
 951
 952 tidyPred :: TidyEnv -> PredType -> PredType
 953 tidyPred env (IParam n ty)     = IParam n (tidyType env ty)
 954 tidyPred env (ClassP clas tys) = ClassP clas (tidyTypes env tys)
 955 tidyPred env (EqPred ty1 ty2)  = EqPred (tidyType env ty1) (tidyType env ty2)
 956 \end{code}
 957
 958
 959 \begin{code}
 960 -- | Grabs the free type variables, tidies them
 961 -- and then uses 'tidyType' to work over the type itself
 962 tidyOpenType :: TidyEnv -> Type -> (TidyEnv, Type)
 963 tidyOpenType env ty
 964   = (env', tidyType env' ty)
 965   where
 966     env' = tidyFreeTyVars env (tyVarsOfType ty)
 967
 968 tidyOpenTypes :: TidyEnv -> [Type] -> (TidyEnv, [Type])
 969 tidyOpenTypes env tys = mapAccumL tidyOpenType env tys
 970
 971 -- | Calls 'tidyType' on a top-level type (i.e. with an empty tidying environment)
 972 tidyTopType :: Type -> Type
 973 tidyTopType ty = tidyType emptyTidyEnv ty
 974 \end{code}
 975
 976 \begin{code}
 977
 978 tidyKind :: TidyEnv -> Kind -> (TidyEnv, Kind)
 979 tidyKind env k = tidyOpenType env k
 980
 981 \end{code}
 982
 983
 984 %************************************************************************
 985 %*                                                                      *
 986 \subsection{Liftedness}
 987 %*                                                                      *
 988 %************************************************************************
 989
 990 \begin{code}
 991 -- | See "Type#type_classification" for what an unlifted type is
 992 isUnLiftedType :: Type -> Bool
 993         -- isUnLiftedType returns True for forall'd unlifted types:
 994         --      x :: forall a. Int#
 995         -- I found bindings like these were getting floated to the top level.
 996         -- They are pretty bogus types, mind you.  It would be better never to
 997         -- construct them
 998
 999 isUnLiftedType ty | Just ty' <- coreView ty = isUnLiftedType ty'
1000 isUnLiftedType (ForAllTy _ ty)   = isUnLiftedType ty
1001 isUnLiftedType (TyConApp tc _)   = isUnLiftedTyCon tc
1002 isUnLiftedType _                 = False
1003
1004 isUnboxedTupleType :: Type -> Bool
1005 isUnboxedTupleType ty = case splitTyConApp_maybe ty of
1006                            Just (tc, _ty_args) -> isUnboxedTupleTyCon tc
1007                            _                   -> False
1008
1009 -- | See "Type#type_classification" for what an algebraic type is.
1010 -- Should only be applied to /types/, as opposed to e.g. partially
1011 -- saturated type constructors
1012 isAlgType :: Type -> Bool
1013 isAlgType ty
1014   = case splitTyConApp_maybe ty of
1015       Just (tc, ty_args) -> ASSERT( ty_args `lengthIs` tyConArity tc )
1016                             isAlgTyCon tc
1017       _other             -> False
1018
1019 -- | See "Type#type_classification" for what an algebraic type is.
1020 -- Should only be applied to /types/, as opposed to e.g. partially
1021 -- saturated type constructors. Closed type constructors are those
1022 -- with a fixed right hand side, as opposed to e.g. associated types
1023 isClosedAlgType :: Type -> Bool
1024 isClosedAlgType ty
1025   = case splitTyConApp_maybe ty of
1026       Just (tc, ty_args) -> ASSERT( ty_args `lengthIs` tyConArity tc )
1027                             isAlgTyCon tc && not (isOpenTyCon tc)
1028       _other             -> False
1029 \end{code}
1030
1031 \begin{code}
1032 -- | Computes whether an argument (or let right hand side) should
1033 -- be computed strictly or lazily, based only on its type.
1034 -- Works just like 'isUnLiftedType', except that it has a special case
1035 -- for dictionaries (i.e. does not work purely on representation types)
1036
1037 -- Since it takes account of class 'PredType's, you might think
1038 -- this function should be in 'TcType', but 'isStrictType' is used by 'DataCon',
1039 -- which is below 'TcType' in the hierarchy, so it's convenient to put it here.
1040 isStrictType :: Type -> Bool
1041 isStrictType (PredTy pred)     = isStrictPred pred
1042 isStrictType ty | Just ty' <- coreView ty = isStrictType ty'
1043 isStrictType (ForAllTy _ ty)   = isStrictType ty
1044 isStrictType (TyConApp tc _)   = isUnLiftedTyCon tc
1045 isStrictType _                 = False
1046
1047 -- | We may be strict in dictionary types, but only if it
1048 -- has more than one component.
1049 --
1050 -- (Being strict in a single-component dictionary risks
1051 --  poking the dictionary component, which is wrong.)
1052 isStrictPred :: PredType -> Bool
1053 isStrictPred (ClassP clas _) = opt_DictsStrict && not (isNewTyCon (classTyCon clas))
1054 isStrictPred _               = False
1055 \end{code}
1056
1057 \begin{code}
1058 isPrimitiveType :: Type -> Bool
1059 -- ^ Returns true of types that are opaque to Haskell.
1060 -- Most of these are unlifted, but now that we interact with .NET, we
1061 -- may have primtive (foreign-imported) types that are lifted
1062 isPrimitiveType ty = case splitTyConApp_maybe ty of
1063                         Just (tc, ty_args) -> ASSERT( ty_args `lengthIs` tyConArity tc )
1064                                               isPrimTyCon tc
1065                         _                  -> False
1066 \end{code}
1067
1068
1069 %************************************************************************
1070 %*                                                                      *
1071 \subsection{Sequencing on types}
1072 %*                                                                      *
1073 %************************************************************************
1074
1075 \begin{code}
1076 seqType :: Type -> ()
1077 seqType (TyVarTy tv)      = tv `seq` ()
1078 seqType (AppTy t1 t2)     = seqType t1 `seq` seqType t2
1079 seqType (FunTy t1 t2)     = seqType t1 `seq` seqType t2
1080 seqType (PredTy p)        = seqPred p
1081 seqType (TyConApp tc tys) = tc `seq` seqTypes tys
1082 seqType (ForAllTy tv ty)  = tv `seq` seqType ty
1083
1084 seqTypes :: [Type] -> ()
1085 seqTypes []       = ()
1086 seqTypes (ty:tys) = seqType ty `seq` seqTypes tys
1087
1088 seqPred :: PredType -> ()
1089 seqPred (ClassP c tys)   = c `seq` seqTypes tys
1090 seqPred (IParam n ty)    = n `seq` seqType ty
1091 seqPred (EqPred ty1 ty2) = seqType ty1 `seq` seqType ty2
1092 \end{code}
1093
1094
1095 %************************************************************************
1096 %*                                                                      *
1097                 Equality for Core types
1098         (We don't use instances so that we know where it happens)
1099 %*                                                                      *
1100 %************************************************************************
1101
1102 Note that eqType works right even for partial applications of newtypes.
1103 See Note [Newtype eta] in TyCon.lhs
1104
1105 \begin{code}
1106 -- | Type equality test for Core types (i.e. ignores predicate-types, synonyms etc.)
1107 coreEqType :: Type -> Type -> Bool
1108 coreEqType t1 t2 = coreEqType2 rn_env t1 t2
1109   where
1110     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfType t1 `unionVarSet` tyVarsOfType t2))
1111
1112 coreEqType2 :: RnEnv2 -> Type -> Type -> Bool
1113 coreEqType2 rn_env t1 t2
1114   = eq rn_env t1 t2
1115   where
1116     eq env (TyVarTy tv1)       (TyVarTy tv2)     = rnOccL env tv1 == rnOccR env tv2
1117     eq env (ForAllTy tv1 t1)   (ForAllTy tv2 t2) = eq (rnBndr2 env tv1 tv2) t1 t2
1118     eq env (AppTy s1 t1)       (AppTy s2 t2)     = eq env s1 s2 && eq env t1 t2
1119     eq env (FunTy s1 t1)       (FunTy s2 t2)     = eq env s1 s2 && eq env t1 t2
1120     eq env (TyConApp tc1 tys1) (TyConApp tc2 tys2)
1121         | tc1 == tc2, all2 (eq env) tys1 tys2 = True
1122                         -- The lengths should be equal because
1123                         -- the two types have the same kind
1124         -- NB: if the type constructors differ that does not
1125         --     necessarily mean that the types aren't equal
1126         --     (synonyms, newtypes)
1127         -- Even if the type constructors are the same, but the arguments
1128         -- differ, the two types could be the same (e.g. if the arg is just
1129         -- ignored in the RHS).  In both these cases we fall through to an
1130         -- attempt to expand one side or the other.
1131
1132         -- Now deal with newtypes, synonyms, pred-tys
1133     eq env t1 t2 | Just t1' <- coreView t1 = eq env t1' t2
1134                  | Just t2' <- coreView t2 = eq env t1 t2'
1135
1136         -- Fall through case; not equal!
1137     eq _ _ _ = False
1138 \end{code}
1139
1140
1141 %************************************************************************
1142 %*                                                                      *
1143                 Comparision for source types
1144         (We don't use instances so that we know where it happens)
1145 %*                                                                      *
1146 %************************************************************************
1147
1148 \begin{code}
1149 tcEqType :: Type -> Type -> Bool
1150 -- ^ Type equality on source types. Does not look through @newtypes@ or
1151 -- 'PredType's, but it does look through type synonyms.
1152 tcEqType t1 t2 = isEqual $ cmpType t1 t2
1153
1154 tcEqTypes :: [Type] -> [Type] -> Bool
1155 tcEqTypes tys1 tys2 = isEqual $ cmpTypes tys1 tys2
1156
1157 tcCmpType :: Type -> Type -> Ordering
1158 -- ^ Type ordering on source types. Does not look through @newtypes@ or
1159 -- 'PredType's, but it does look through type synonyms.
1160 tcCmpType t1 t2 = cmpType t1 t2
1161
1162 tcCmpTypes :: [Type] -> [Type] -> Ordering
1163 tcCmpTypes tys1 tys2 = cmpTypes tys1 tys2
1164
1165 tcEqPred :: PredType -> PredType -> Bool
1166 tcEqPred p1 p2 = isEqual $ cmpPred p1 p2
1167
1168 tcEqPredX :: RnEnv2 -> PredType -> PredType -> Bool
1169 tcEqPredX env p1 p2 = isEqual $ cmpPredX env p1 p2
1170
1171 tcCmpPred :: PredType -> PredType -> Ordering
1172 tcCmpPred p1 p2 = cmpPred p1 p2
1173
1174 tcEqTypeX :: RnEnv2 -> Type -> Type -> Bool
1175 tcEqTypeX env t1 t2 = isEqual $ cmpTypeX env t1 t2
1176 \end{code}
1177
1178 \begin{code}
1179 -- | Checks whether the second argument is a subterm of the first.  (We don't care
1180 -- about binders, as we are only interested in syntactic subterms.)
1181 tcPartOfType :: Type -> Type -> Bool
1182 tcPartOfType t1              t2
1183   | tcEqType t1 t2              = True
1184 tcPartOfType t1              t2
1185   | Just t2' <- tcView t2       = tcPartOfType t1 t2'
1186 tcPartOfType _  (TyVarTy _)     = False
1187 tcPartOfType t1 (ForAllTy _ t2) = tcPartOfType t1 t2
1188 tcPartOfType t1 (AppTy s2 t2)   = tcPartOfType t1 s2 || tcPartOfType t1 t2
1189 tcPartOfType t1 (FunTy s2 t2)   = tcPartOfType t1 s2 || tcPartOfType t1 t2
1190 tcPartOfType t1 (PredTy p2)     = tcPartOfPred t1 p2
1191 tcPartOfType t1 (TyConApp _ ts) = any (tcPartOfType t1) ts
1192
1193 tcPartOfPred :: Type -> PredType -> Bool
1194 tcPartOfPred t1 (IParam _ t2)  = tcPartOfType t1 t2
1195 tcPartOfPred t1 (ClassP _ ts)  = any (tcPartOfType t1) ts
1196 tcPartOfPred t1 (EqPred s2 t2) = tcPartOfType t1 s2 || tcPartOfType t1 t2
1197 \end{code}
1198
1199 Now here comes the real worker
1200
1201 \begin{code}
1202 cmpType :: Type -> Type -> Ordering
1203 cmpType t1 t2 = cmpTypeX rn_env t1 t2
1204   where
1205     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfType t1 `unionVarSet` tyVarsOfType t2))
1206
1207 cmpTypes :: [Type] -> [Type] -> Ordering
1208 cmpTypes ts1 ts2 = cmpTypesX rn_env ts1 ts2
1209   where
1210     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfTypes ts1 `unionVarSet` tyVarsOfTypes ts2))
1211
1212 cmpPred :: PredType -> PredType -> Ordering
1213 cmpPred p1 p2 = cmpPredX rn_env p1 p2
1214   where
1215     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfPred p1 `unionVarSet` tyVarsOfPred p2))
1216
1217 cmpTypeX :: RnEnv2 -> Type -> Type -> Ordering  -- Main workhorse
1218 cmpTypeX env t1 t2 | Just t1' <- tcView t1 = cmpTypeX env t1' t2
1219                    | Just t2' <- tcView t2 = cmpTypeX env t1 t2'
1220
1221 cmpTypeX env (TyVarTy tv1)       (TyVarTy tv2)       = rnOccL env tv1 `compare` rnOccR env tv2
1222 cmpTypeX env (ForAllTy tv1 t1)   (ForAllTy tv2 t2)   = cmpTypeX (rnBndr2 env tv1 tv2) t1 t2
1223 cmpTypeX env (AppTy s1 t1)       (AppTy s2 t2)       = cmpTypeX env s1 s2 `thenCmp` cmpTypeX env t1 t2
1224 cmpTypeX env (FunTy s1 t1)       (FunTy s2 t2)       = cmpTypeX env s1 s2 `thenCmp` cmpTypeX env t1 t2
1225 cmpTypeX env (PredTy p1)         (PredTy p2)         = cmpPredX env p1 p2
1226 cmpTypeX env (TyConApp tc1 tys1) (TyConApp tc2 tys2) = (tc1 `compare` tc2) `thenCmp` cmpTypesX env tys1 tys2
1227
1228     -- Deal with the rest: TyVarTy < AppTy < FunTy < TyConApp < ForAllTy < PredTy
1229 cmpTypeX _ (AppTy _ _)    (TyVarTy _)    = GT
1230
1231 cmpTypeX _ (FunTy _ _)    (TyVarTy _)    = GT
1232 cmpTypeX _ (FunTy _ _)    (AppTy _ _)    = GT
1233
1234 cmpTypeX _ (TyConApp _ _) (TyVarTy _)    = GT
1235 cmpTypeX _ (TyConApp _ _) (AppTy _ _)    = GT
1236 cmpTypeX _ (TyConApp _ _) (FunTy _ _)    = GT
1237
1238 cmpTypeX _ (ForAllTy _ _) (TyVarTy _)    = GT
1239 cmpTypeX _ (ForAllTy _ _) (AppTy _ _)    = GT
1240 cmpTypeX _ (ForAllTy _ _) (FunTy _ _)    = GT
1241 cmpTypeX _ (ForAllTy _ _) (TyConApp _ _) = GT
1242
1243 cmpTypeX _ (PredTy _)     _              = GT
1244
1245 cmpTypeX _ _              _              = LT
1246
1247 -------------
1248 cmpTypesX :: RnEnv2 -> [Type] -> [Type] -> Ordering
1249 cmpTypesX _   []        []        = EQ
1250 cmpTypesX env (t1:tys1) (t2:tys2) = cmpTypeX env t1 t2 `thenCmp` cmpTypesX env tys1 tys2
1251 cmpTypesX _   []        _         = LT
1252 cmpTypesX _   _         []        = GT
1253
1254 -------------
1255 cmpPredX :: RnEnv2 -> PredType -> PredType -> Ordering
1256 cmpPredX env (IParam n1 ty1) (IParam n2 ty2) = (n1 `compare` n2) `thenCmp` cmpTypeX env ty1 ty2
1257         -- Compare names only for implicit parameters
1258         -- This comparison is used exclusively (I believe)
1259         -- for the Avails finite map built in TcSimplify
1260         -- If the types differ we keep them distinct so that we see
1261         -- a distinct pair to run improvement on
1262 cmpPredX env (ClassP c1 tys1) (ClassP c2 tys2) = (c1 `compare` c2) `thenCmp` (cmpTypesX env tys1 tys2)
1263 cmpPredX env (EqPred ty1 ty2) (EqPred ty1' ty2') = (cmpTypeX env ty1 ty1') `thenCmp` (cmpTypeX env ty2 ty2')
1264
1265 -- Constructor order: IParam < ClassP < EqPred
1266 cmpPredX _   (IParam {})     _              = LT
1267 cmpPredX _   (ClassP {})    (IParam {})     = GT
1268 cmpPredX _   (ClassP {})    (EqPred {})     = LT
1269 cmpPredX _   (EqPred {})    _               = GT
1270 \end{code}
1271
1272 PredTypes are used as a FM key in TcSimplify,
1273 so we take the easy path and make them an instance of Ord
1274
1275 \begin{code}
1276 instance Eq  PredType where { (==)    = tcEqPred }
1277 instance Ord PredType where { compare = tcCmpPred }
1278 \end{code}
1279
1280
1281 %************************************************************************
1282 %*                                                                      *
1283                 Type substitutions
1284 %*                                                                      *
1285 %************************************************************************
1286
1287 \begin{code}
1288 -- | Type substitution
1289 --
1290 -- #tvsubst_invariant#
1291 -- The following invariants must hold of a 'TvSubst':
1292 --
1293 -- 1. The in-scope set is needed /only/ to
1294 -- guide the generation of fresh uniques
1295 --
1296 -- 2. In particular, the /kind/ of the type variables in
1297 -- the in-scope set is not relevant
1298 --
1299 -- 3. The substition is only applied ONCE! This is because
1300 -- in general such application will not reached a fixed point.
1301 data TvSubst
1302   = TvSubst InScopeSet  -- The in-scope type variables
1303             TvSubstEnv  -- The substitution itself
1304         -- See Note [Apply Once]
1305         -- and Note [Extending the TvSubstEnv]
1306
1307 {- ----------------------------------------------------------
1308
1309 Note [Apply Once]
1310 ~~~~~~~~~~~~~~~~~
1311 We use TvSubsts to instantiate things, and we might instantiate
1312         forall a b. ty
1313 \with the types
1314         [a, b], or [b, a].
1315 So the substition might go [a->b, b->a].  A similar situation arises in Core
1316 when we find a beta redex like
1317         (/\ a /\ b -> e) b a
1318 Then we also end up with a substition that permutes type variables. Other
1319 variations happen to; for example [a -> (a, b)].
1320
1321         ***************************************************
1322         *** So a TvSubst must be applied precisely once ***
1323         ***************************************************
1324
1325 A TvSubst is not idempotent, but, unlike the non-idempotent substitution
1326 we use during unifications, it must not be repeatedly applied.
1327
1328 Note [Extending the TvSubst]
1329 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1330 See #tvsubst_invariant# for the invariants that must hold.
1331
1332 This invariant allows a short-cut when the TvSubstEnv is empty:
1333 if the TvSubstEnv is empty --- i.e. (isEmptyTvSubt subst) holds ---
1334 then (substTy subst ty) does nothing.
1335
1336 For example, consider:
1337         (/\a. /\b:(a~Int). ...b..) Int
1338 We substitute Int for 'a'.  The Unique of 'b' does not change, but
1339 nevertheless we add 'b' to the TvSubstEnv, because b's kind does change
1340
1341 This invariant has several crucial consequences:
1342
1343 * In substTyVarBndr, we need extend the TvSubstEnv
1344         - if the unique has changed
1345         - or if the kind has changed
1346
1347 * In substTyVar, we do not need to consult the in-scope set;
1348   the TvSubstEnv is enough
1349
1350 * In substTy, substTheta, we can short-circuit when the TvSubstEnv is empty
1351
1352
1353 -------------------------------------------------------------- -}
1354
1355 -- | A substitition of 'Type's for 'TyVar's
1356 type TvSubstEnv = TyVarEnv Type
1357         -- A TvSubstEnv is used both inside a TvSubst (with the apply-once
1358         -- invariant discussed in Note [Apply Once]), and also independently
1359         -- in the middle of matching, and unification (see Types.Unify)
1360         -- So you have to look at the context to know if it's idempotent or
1361         -- apply-once or whatever
1362
1363 emptyTvSubstEnv :: TvSubstEnv
1364 emptyTvSubstEnv = emptyVarEnv
1365
1366 composeTvSubst :: InScopeSet -> TvSubstEnv -> TvSubstEnv -> TvSubstEnv
1367 -- ^ @(compose env1 env2)(x)@ is @env1(env2(x))@; i.e. apply @env2@ then @env1@.
1368 -- It assumes that both are idempotent.
1369 -- Typically, @env1@ is the refinement to a base substitution @env2@
1370 composeTvSubst in_scope env1 env2
1371   = env1 `plusVarEnv` mapVarEnv (substTy subst1) env2
1372         -- First apply env1 to the range of env2
1373         -- Then combine the two, making sure that env1 loses if
1374         -- both bind the same variable; that's why env1 is the
1375         --  *left* argument to plusVarEnv, because the right arg wins
1376   where
1377     subst1 = TvSubst in_scope env1
1378
1379 emptyTvSubst :: TvSubst
1380 emptyTvSubst = TvSubst emptyInScopeSet emptyVarEnv
1381
1382 isEmptyTvSubst :: TvSubst -> Bool
1383          -- See Note [Extending the TvSubstEnv]
1384 isEmptyTvSubst (TvSubst _ env) = isEmptyVarEnv env
1385
1386 mkTvSubst :: InScopeSet -> TvSubstEnv -> TvSubst
1387 mkTvSubst = TvSubst
1388
1389 getTvSubstEnv :: TvSubst -> TvSubstEnv
1390 getTvSubstEnv (TvSubst _ env) = env
1391
1392 getTvInScope :: TvSubst -> InScopeSet
1393 getTvInScope (TvSubst in_scope _) = in_scope
1394
1395 isInScope :: Var -> TvSubst -> Bool
1396 isInScope v (TvSubst in_scope _) = v `elemInScopeSet` in_scope
1397
1398 notElemTvSubst :: TyVar -> TvSubst -> Bool
1399 notElemTvSubst tv (TvSubst _ env) = not (tv `elemVarEnv` env)
1400
1401 setTvSubstEnv :: TvSubst -> TvSubstEnv -> TvSubst
1402 setTvSubstEnv (TvSubst in_scope _) env = TvSubst in_scope env
1403
1404 zapTvSubstEnv :: TvSubst -> TvSubst
1405 zapTvSubstEnv (TvSubst in_scope _) = TvSubst in_scope emptyVarEnv
1406
1407 extendTvInScope :: TvSubst -> Var -> TvSubst
1408 extendTvInScope (TvSubst in_scope env) var = TvSubst (extendInScopeSet in_scope var) env
1409
1410 extendTvInScopeList :: TvSubst -> [Var] -> TvSubst
1411 extendTvInScopeList (TvSubst in_scope env) vars = TvSubst (extendInScopeSetList in_scope vars) env
1412
1413 extendTvSubst :: TvSubst -> TyVar -> Type -> TvSubst
1414 extendTvSubst (TvSubst in_scope env) tv ty = TvSubst in_scope (extendVarEnv env tv ty)
1415
1416 extendTvSubstList :: TvSubst -> [TyVar] -> [Type] -> TvSubst
1417 extendTvSubstList (TvSubst in_scope env) tvs tys
1418   = TvSubst in_scope (extendVarEnvList env (tvs `zip` tys))
1419
1420 -- mkOpenTvSubst and zipOpenTvSubst generate the in-scope set from
1421 -- the types given; but it's just a thunk so with a bit of luck
1422 -- it'll never be evaluated
1423
1424 -- Note [Generating the in-scope set for a substitution]
1425 -- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1426 -- If we want to substitute [a -> ty1, b -> ty2] I used to
1427 -- think it was enough to generate an in-scope set that includes
1428 -- fv(ty1,ty2).  But that's not enough; we really should also take the
1429 -- free vars of the type we are substituting into!  Example:
1430 --      (forall b. (a,b,x)) [a -> List b]
1431 -- Then if we use the in-scope set {b}, there is a danger we will rename
1432 -- the forall'd variable to 'x' by mistake, getting this:
1433 --      (forall x. (List b, x, x)
1434 -- Urk!  This means looking at all the calls to mkOpenTvSubst....
1435
1436
1437 -- | Generates the in-scope set for the 'TvSubst' from the types in the incoming
1438 -- environment, hence "open"
1439 mkOpenTvSubst :: TvSubstEnv -> TvSubst
1440 mkOpenTvSubst env = TvSubst (mkInScopeSet (tyVarsOfTypes (varEnvElts env))) env
1441
1442 -- | Generates the in-scope set for the 'TvSubst' from the types in the incoming
1443 -- environment, hence "open"
1444 zipOpenTvSubst :: [TyVar] -> [Type] -> TvSubst
1445 zipOpenTvSubst tyvars tys
1446   | debugIsOn && (length tyvars /= length tys)
1447   = pprTrace "zipOpenTvSubst" (ppr tyvars $$ ppr tys) emptyTvSubst
1448   | otherwise
1449   = TvSubst (mkInScopeSet (tyVarsOfTypes tys)) (zipTyEnv tyvars tys)
1450
1451 -- | Called when doing top-level substitutions. Here we expect that the
1452 -- free vars of the range of the substitution will be empty.
1453 mkTopTvSubst :: [(TyVar, Type)] -> TvSubst
1454 mkTopTvSubst prs = TvSubst emptyInScopeSet (mkVarEnv prs)
1455
1456 zipTopTvSubst :: [TyVar] -> [Type] -> TvSubst
1457 zipTopTvSubst tyvars tys
1458   | debugIsOn && (length tyvars /= length tys)
1459   = pprTrace "zipTopTvSubst" (ppr tyvars $$ ppr tys) emptyTvSubst
1460   | otherwise
1461   = TvSubst emptyInScopeSet (zipTyEnv tyvars tys)
1462
1463 zipTyEnv :: [TyVar] -> [Type] -> TvSubstEnv
1464 zipTyEnv tyvars tys
1465   | debugIsOn && (length tyvars /= length tys)
1466   = pprTrace "mkTopTvSubst" (ppr tyvars $$ ppr tys) emptyVarEnv
1467   | otherwise
1468   = zip_ty_env tyvars tys emptyVarEnv
1469
1470 -- Later substitutions in the list over-ride earlier ones,
1471 -- but there should be no loops
1472 zip_ty_env :: [TyVar] -> [Type] -> TvSubstEnv -> TvSubstEnv
1473 zip_ty_env []       []       env = env
1474 zip_ty_env (tv:tvs) (ty:tys) env = zip_ty_env tvs tys (extendVarEnv env tv ty)
1475         -- There used to be a special case for when
1476         --      ty == TyVarTy tv
1477         -- (a not-uncommon case) in which case the substitution was dropped.
1478         -- But the type-tidier changes the print-name of a type variable without
1479         -- changing the unique, and that led to a bug.   Why?  Pre-tidying, we had
1480         -- a type {Foo t}, where Foo is a one-method class.  So Foo is really a newtype.
1481         -- And it happened that t was the type variable of the class.  Post-tiding,
1482         -- it got turned into {Foo t2}.  The ext-core printer expanded this using
1483         -- sourceTypeRep, but that said "Oh, t == t2" because they have the same unique,
1484         -- and so generated a rep type mentioning t not t2.
1485         --
1486         -- Simplest fix is to nuke the "optimisation"
1487 zip_ty_env tvs      tys      env   = pprTrace "Var/Type length mismatch: " (ppr tvs $$ ppr tys) env
1488 -- zip_ty_env _ _ env = env
1489
1490 instance Outputable TvSubst where
1491   ppr (TvSubst ins env)
1492     = brackets $ sep[ ptext (sLit "TvSubst"),
1493                       nest 2 (ptext (sLit "In scope:") <+> ppr ins),
1494                       nest 2 (ptext (sLit "Env:") <+> ppr env) ]
1495 \end{code}
1496
1497 %************************************************************************
1498 %*                                                                      *
1499                 Performing type substitutions
1500 %*                                                                      *
1501 %************************************************************************
1502
1503 \begin{code}
1504 -- | Type substitution making use of an 'TvSubst' that
1505 -- is assumed to be open, see 'zipOpenTvSubst'
1506 substTyWith :: [TyVar] -> [Type] -> Type -> Type
1507 substTyWith tvs tys = ASSERT( length tvs == length tys )
1508                       substTy (zipOpenTvSubst tvs tys)
1509
1510 -- | Type substitution making use of an 'TvSubst' that
1511 -- is assumed to be open, see 'zipOpenTvSubst'
1512 substTysWith :: [TyVar] -> [Type] -> [Type] -> [Type]
1513 substTysWith tvs tys = ASSERT( length tvs == length tys )
1514                        substTys (zipOpenTvSubst tvs tys)
1515
1516 -- | Substitute within a 'Type'
1517 substTy :: TvSubst -> Type  -> Type
1518 substTy subst ty | isEmptyTvSubst subst = ty
1519                  | otherwise            = subst_ty subst ty
1520
1521 -- | Substitute within several 'Type's
1522 substTys :: TvSubst -> [Type] -> [Type]
1523 substTys subst tys | isEmptyTvSubst subst = tys
1524                    | otherwise            = map (subst_ty subst) tys
1525
1526 -- | Substitute within a 'ThetaType'
1527 substTheta :: TvSubst -> ThetaType -> ThetaType
1528 substTheta subst theta
1529   | isEmptyTvSubst subst = theta
1530   | otherwise            = map (substPred subst) theta
1531
1532 -- | Substitute within a 'PredType'
1533 substPred :: TvSubst -> PredType -> PredType
1534 substPred subst (IParam n ty)     = IParam n (subst_ty subst ty)
1535 substPred subst (ClassP clas tys) = ClassP clas (map (subst_ty subst) tys)
1536 substPred subst (EqPred ty1 ty2)  = EqPred (subst_ty subst ty1) (subst_ty subst ty2)
1537
1538 -- | Remove any nested binders mentioning the 'TyVar's in the 'TyVarSet'
1539 deShadowTy :: TyVarSet -> Type -> Type
1540 deShadowTy tvs ty
1541   = subst_ty (mkTvSubst in_scope emptyTvSubstEnv) ty
1542   where
1543     in_scope = mkInScopeSet tvs
1544
1545 subst_ty :: TvSubst -> Type -> Type
1546 -- subst_ty is the main workhorse for type substitution
1547 --
1548 -- Note that the in_scope set is poked only if we hit a forall
1549 -- so it may often never be fully computed
1550 subst_ty subst ty
1551    = go ty
1552   where
1553     go (TyVarTy tv)      = substTyVar subst tv
1554     go (TyConApp tc tys) = let args = map go tys
1555                            in  args `seqList` TyConApp tc args
1556
1557     go (PredTy p)        = PredTy $! (substPred subst p)
1558
1559     go (FunTy arg res)   = (FunTy $! (go arg)) $! (go res)
1560     go (AppTy fun arg)   = mkAppTy (go fun) $! (go arg)
1561                 -- The mkAppTy smart constructor is important
1562                 -- we might be replacing (a Int), represented with App
1563                 -- by [Int], represented with TyConApp
1564     go (ForAllTy tv ty)  = case substTyVarBndr subst tv of
1565                               (subst', tv') ->
1566                                  ForAllTy tv' $! (subst_ty subst' ty)
1567
1568 substTyVar :: TvSubst -> TyVar  -> Type
1569 substTyVar subst@(TvSubst _ _) tv
1570   = case lookupTyVar subst tv of {
1571         Nothing -> TyVarTy tv;
1572         Just ty -> ty   -- See Note [Apply Once]
1573     }
1574
1575 substTyVars :: TvSubst -> [TyVar] -> [Type]
1576 substTyVars subst tvs = map (substTyVar subst) tvs
1577
1578 lookupTyVar :: TvSubst -> TyVar  -> Maybe Type
1579         -- See Note [Extending the TvSubst]
1580 lookupTyVar (TvSubst _ env) tv = lookupVarEnv env tv
1581
1582 substTyVarBndr :: TvSubst -> TyVar -> (TvSubst, TyVar)
1583 substTyVarBndr subst@(TvSubst in_scope env) old_var
1584   = (TvSubst (in_scope `extendInScopeSet` new_var) new_env, new_var)
1585   where
1586     is_co_var = isCoVar old_var
1587
1588     new_env | no_change = delVarEnv env old_var
1589             | otherwise = extendVarEnv env old_var (TyVarTy new_var)
1590
1591     no_change = new_var == old_var && not is_co_var
1592         -- no_change means that the new_var is identical in
1593         -- all respects to the old_var (same unique, same kind)
1594         -- See Note [Extending the TvSubst]
1595         --
1596         -- In that case we don't need to extend the substitution
1597         -- to map old to new.  But instead we must zap any
1598         -- current substitution for the variable. For example:
1599         --      (\x.e) with id_subst = [x |-> e']
1600         -- Here we must simply zap the substitution for x
1601
1602     new_var = uniqAway in_scope subst_old_var
1603         -- The uniqAway part makes sure the new variable is not already in scope
1604
1605     subst_old_var -- subst_old_var is old_var with the substitution applied to its kind
1606                   -- It's only worth doing the substitution for coercions,
1607                   -- becuase only they can have free type variables
1608         | is_co_var = setTyVarKind old_var (substTy subst (tyVarKind old_var))
1609         | otherwise = old_var
1610 \end{code}
1611
1612 ----------------------------------------------------
1613 -- Kind Stuff
1614
1615 Kinds
1616 ~~~~~
1617
1618 \begin{code}
1619 -- $kind_subtyping
1620 -- #kind_subtyping#
1621 -- There's a little subtyping at the kind level:
1622 --
1623 -- @
1624 --               ?
1625 --              \/ &#92;
1626 --             \/   &#92;
1627 --            ??   (\#)
1628 --           \/  &#92;
1629 --          \*    \#
1630 -- .
1631 -- Where:        \*    [LiftedTypeKind]   means boxed type
1632 --              \#    [UnliftedTypeKind] means unboxed type
1633 --              (\#)  [UbxTupleKind]     means unboxed tuple
1634 --              ??   [ArgTypeKind]      is the lub of {\*, \#}
1635 --              ?    [OpenTypeKind]     means any type at all
1636 -- @
1637 --
1638 -- In particular:
1639 --
1640 -- > error :: forall a:?. String -> a
1641 -- > (->)  :: ?? -> ? -> \*
1642 -- > (\\(x::t) -> ...)
1643 --
1644 -- Where in the last example @t :: ??@ (i.e. is not an unboxed tuple)
1645
1646 type KindVar = TyVar  -- invariant: KindVar will always be a
1647                       -- TcTyVar with details MetaTv TauTv ...
1648 -- kind var constructors and functions are in TcType
1649
1650 type SimpleKind = Kind
1651 \end{code}
1652
1653 Kind inference
1654 ~~~~~~~~~~~~~~
1655 During kind inference, a kind variable unifies only with
1656 a "simple kind", sk
1657         sk ::= * | sk1 -> sk2
1658 For example
1659         data T a = MkT a (T Int#)
1660 fails.  We give T the kind (k -> *), and the kind variable k won't unify
1661 with # (the kind of Int#).
1662
1663 Type inference
1664 ~~~~~~~~~~~~~~
1665 When creating a fresh internal type variable, we give it a kind to express
1666 constraints on it.  E.g. in (\x->e) we make up a fresh type variable for x,
1667 with kind ??.
1668
1669 During unification we only bind an internal type variable to a type
1670 whose kind is lower in the sub-kind hierarchy than the kind of the tyvar.
1671
1672 When unifying two internal type variables, we collect their kind constraints by
1673 finding the GLB of the two.  Since the partial order is a tree, they only
1674 have a glb if one is a sub-kind of the other.  In that case, we bind the
1675 less-informative one to the more informative one.  Neat, eh?