compiler/types/Type.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1998
   4 %
   5
   6 Type - public interface
   7
   8 \begin{code}
   9 module Type (
  10         -- re-exports from TypeRep
  11         TyThing(..), Type, PredType(..), ThetaType,
  12         funTyCon,
  13
  14         -- Kinds
  15         Kind, SimpleKind, KindVar,
  16         kindFunResult, splitKindFunTys, splitKindFunTysN,
  17
  18         liftedTypeKindTyCon, openTypeKindTyCon, unliftedTypeKindTyCon,
  19         argTypeKindTyCon, ubxTupleKindTyCon,
  20
  21         liftedTypeKind, unliftedTypeKind, openTypeKind,
  22         argTypeKind, ubxTupleKind,
  23
  24         tySuperKind, coSuperKind,
  25
  26         isLiftedTypeKind, isUnliftedTypeKind, isOpenTypeKind,
  27         isUbxTupleKind, isArgTypeKind, isKind, isTySuperKind,
  28         isCoSuperKind, isSuperKind, isCoercionKind, isEqPred,
  29         mkArrowKind, mkArrowKinds,
  30
  31         isSubArgTypeKind, isSubOpenTypeKind, isSubKind, defaultKind, eqKind,
  32         isSubKindCon,
  33
  34         -- Re-exports from TyCon
  35         PrimRep(..),
  36
  37         mkTyVarTy, mkTyVarTys, getTyVar, getTyVar_maybe, isTyVarTy,
  38
  39         mkAppTy, mkAppTys, splitAppTy, splitAppTys,
  40         splitAppTy_maybe, repSplitAppTy_maybe,
  41
  42         mkFunTy, mkFunTys, splitFunTy, splitFunTy_maybe,
  43         splitFunTys, splitFunTysN,
  44         funResultTy, funArgTy, zipFunTys, isFunTy,
  45
  46         mkTyConApp, mkTyConTy,
  47         tyConAppTyCon, tyConAppArgs,
  48         splitTyConApp_maybe, splitTyConApp,
  49         splitNewTyConApp_maybe, splitNewTyConApp,
  50
  51         repType, repType', typePrimRep, coreView, tcView, kindView,
  52
  53         mkForAllTy, mkForAllTys, splitForAllTy_maybe, splitForAllTys,
  54         applyTy, applyTys, isForAllTy, dropForAlls,
  55
  56         -- Source types
  57         predTypeRep, mkPredTy, mkPredTys,
  58         tyConOrigHead,
  59
  60         -- Newtypes
  61         splitRecNewType_maybe, newTyConInstRhs,
  62
  63         -- Lifting and boxity
  64         isUnLiftedType, isUnboxedTupleType, isAlgType, isPrimitiveType,
  65         isStrictType, isStrictPred,
  66
  67         -- Free variables
  68         tyVarsOfType, tyVarsOfTypes, tyVarsOfPred, tyVarsOfTheta,
  69         typeKind, addFreeTyVars,
  70
  71         -- Tidying up for printing
  72         tidyType,      tidyTypes,
  73         tidyOpenType,  tidyOpenTypes,
  74         tidyTyVarBndr, tidyFreeTyVars,
  75         tidyOpenTyVar, tidyOpenTyVars,
  76         tidyTopType,   tidyPred,
  77         tidyKind,
  78
  79         -- Comparison
  80         coreEqType, tcEqType, tcEqTypes, tcCmpType, tcCmpTypes,
  81         tcEqPred, tcCmpPred, tcEqTypeX,
  82
  83         -- Seq
  84         seqType, seqTypes,
  85
  86         -- Type substitutions
  87         TvSubstEnv, emptyTvSubstEnv,    -- Representation widely visible
  88         TvSubst(..), emptyTvSubst,      -- Representation visible to a few friends
  89         mkTvSubst, mkOpenTvSubst, zipOpenTvSubst, zipTopTvSubst, mkTopTvSubst, notElemTvSubst,
  90         getTvSubstEnv, setTvSubstEnv, getTvInScope, extendTvInScope,
  91         extendTvSubst, extendTvSubstList, isInScope, composeTvSubst, zipTyEnv,
  92
  93         -- Performing substitution on types
  94         substTy, substTys, substTyWith, substTheta,
  95         substPred, substTyVar, substTyVars, substTyVarBndr, deShadowTy, lookupTyVar,
  96
  97         -- Pretty-printing
  98         pprType, pprParendType, pprTyThingCategory, pprForAll,
  99         pprPred, pprTheta, pprThetaArrow, pprClassPred, pprKind, pprParendKind
 100     ) where
 101
 102 #include "HsVersions.h"
 103
 104 -- We import the representation and primitive functions from TypeRep.
 105 -- Many things are reexported, but not the representation!
 106
 107 import TypeRep
 108
 109 -- friends:
 110 import Var
 111 import VarEnv
 112 import VarSet
 113
 114 import Name
 115 import Class
 116 import PrelNames
 117 import TyCon
 118
 119 -- others
 120 import StaticFlags
 121 import Util
 122 import Outputable
 123 import UniqSet
 124
 125 import Data.Maybe       ( isJust )
 126 \end{code}
 127
 128
 129 %************************************************************************
 130 %*                                                                      *
 131                 Type representation
 132 %*                                                                      *
 133 %************************************************************************
 134
 135 In Core, we "look through" non-recursive newtypes and PredTypes.
 136
 137 \begin{code}
 138 {-# INLINE coreView #-}
 139 coreView :: Type -> Maybe Type
 140 -- Strips off the *top layer only* of a type to give
 141 -- its underlying representation type.
 142 -- Returns Nothing if there is nothing to look through.
 143 --
 144 -- In the case of newtypes, it returns
 145 --      *either* a vanilla TyConApp (recursive newtype, or non-saturated)
 146 --      *or*     the newtype representation (otherwise), meaning the
 147 --                      type written in the RHS of the newtype decl,
 148 --                      which may itself be a newtype
 149 --
 150 -- Example: newtype R = MkR S
 151 --          newtype S = MkS T
 152 --          newtype T = MkT (T -> T)
 153 --   expandNewTcApp on R gives Just S
 154 --                  on S gives Just T
 155 --                  on T gives Nothing   (no expansion)
 156
 157 -- By being non-recursive and inlined, this case analysis gets efficiently
 158 -- joined onto the case analysis that the caller is already doing
 159 coreView (NoteTy _ ty)     = Just ty
 160 coreView (PredTy p)
 161   | isEqPred p             = Nothing
 162   | otherwise              = Just (predTypeRep p)
 163 coreView (TyConApp tc tys) | Just (tenv, rhs, tys') <- coreExpandTyCon_maybe tc tys
 164                            = Just (mkAppTys (substTy (mkTopTvSubst tenv) rhs) tys')
 165                                 -- Its important to use mkAppTys, rather than (foldl AppTy),
 166                                 -- because the function part might well return a
 167                                 -- partially-applied type constructor; indeed, usually will!
 168 coreView ty                = Nothing
 169
 170
 171
 172 -----------------------------------------------
 173 {-# INLINE tcView #-}
 174 tcView :: Type -> Maybe Type
 175 -- Same, but for the type checker, which just looks through synonyms
 176 tcView (NoteTy _ ty)     = Just ty
 177 tcView (TyConApp tc tys) | Just (tenv, rhs, tys') <- tcExpandTyCon_maybe tc tys
 178                          = Just (mkAppTys (substTy (mkTopTvSubst tenv) rhs) tys')
 179 tcView ty                = Nothing
 180
 181 -----------------------------------------------
 182 {-# INLINE kindView #-}
 183 kindView :: Kind -> Maybe Kind
 184 -- C.f. coreView, tcView
 185 -- For the moment, we don't even handle synonyms in kinds
 186 kindView (NoteTy _ k) = Just k
 187 kindView other        = Nothing
 188 \end{code}
 189
 190
 191 %************************************************************************
 192 %*                                                                      *
 193 \subsection{Constructor-specific functions}
 194 %*                                                                      *
 195 %************************************************************************
 196
 197
 198 ---------------------------------------------------------------------
 199                                 TyVarTy
 200                                 ~~~~~~~
 201 \begin{code}
 202 mkTyVarTy  :: TyVar   -> Type
 203 mkTyVarTy  = TyVarTy
 204
 205 mkTyVarTys :: [TyVar] -> [Type]
 206 mkTyVarTys = map mkTyVarTy -- a common use of mkTyVarTy
 207
 208 getTyVar :: String -> Type -> TyVar
 209 getTyVar msg ty = case getTyVar_maybe ty of
 210                     Just tv -> tv
 211                     Nothing -> panic ("getTyVar: " ++ msg)
 212
 213 isTyVarTy :: Type -> Bool
 214 isTyVarTy ty = isJust (getTyVar_maybe ty)
 215
 216 getTyVar_maybe :: Type -> Maybe TyVar
 217 getTyVar_maybe ty | Just ty' <- coreView ty = getTyVar_maybe ty'
 218 getTyVar_maybe (TyVarTy tv)                 = Just tv
 219 getTyVar_maybe other                        = Nothing
 220
 221 \end{code}
 222
 223
 224 ---------------------------------------------------------------------
 225                                 AppTy
 226                                 ~~~~~
 227 We need to be pretty careful with AppTy to make sure we obey the
 228 invariant that a TyConApp is always visibly so.  mkAppTy maintains the
 229 invariant: use it.
 230
 231 \begin{code}
 232 mkAppTy orig_ty1 orig_ty2
 233   = mk_app orig_ty1
 234   where
 235     mk_app (NoteTy _ ty1)    = mk_app ty1
 236     mk_app (TyConApp tc tys) = mkTyConApp tc (tys ++ [orig_ty2])
 237     mk_app ty1               = AppTy orig_ty1 orig_ty2
 238         -- Note that the TyConApp could be an
 239         -- under-saturated type synonym.  GHC allows that; e.g.
 240         --      type Foo k = k a -> k a
 241         --      type Id x = x
 242         --      foo :: Foo Id -> Foo Id
 243         --
 244         -- Here Id is partially applied in the type sig for Foo,
 245         -- but once the type synonyms are expanded all is well
 246
 247 mkAppTys :: Type -> [Type] -> Type
 248 mkAppTys orig_ty1 []        = orig_ty1
 249         -- This check for an empty list of type arguments
 250         -- avoids the needless loss of a type synonym constructor.
 251         -- For example: mkAppTys Rational []
 252         --   returns to (Ratio Integer), which has needlessly lost
 253         --   the Rational part.
 254 mkAppTys orig_ty1 orig_tys2
 255   = mk_app orig_ty1
 256   where
 257     mk_app (NoteTy _ ty1)    = mk_app ty1
 258     mk_app (TyConApp tc tys) = mkTyConApp tc (tys ++ orig_tys2)
 259                                 -- mkTyConApp: see notes with mkAppTy
 260     mk_app ty1               = foldl AppTy orig_ty1 orig_tys2
 261
 262 -------------
 263 splitAppTy_maybe :: Type -> Maybe (Type, Type)
 264 splitAppTy_maybe ty | Just ty' <- coreView ty
 265                     = splitAppTy_maybe ty'
 266 splitAppTy_maybe ty = repSplitAppTy_maybe ty
 267
 268 -------------
 269 repSplitAppTy_maybe :: Type -> Maybe (Type,Type)
 270 -- Does the AppTy split, but assumes that any view stuff is already done
 271 repSplitAppTy_maybe (FunTy ty1 ty2)   = Just (TyConApp funTyCon [ty1], ty2)
 272 repSplitAppTy_maybe (AppTy ty1 ty2)   = Just (ty1, ty2)
 273 repSplitAppTy_maybe (TyConApp tc tys) = case snocView tys of
 274                                                 Just (tys', ty') -> Just (TyConApp tc tys', ty')
 275                                                 Nothing          -> Nothing
 276 repSplitAppTy_maybe other = Nothing
 277 -------------
 278 splitAppTy :: Type -> (Type, Type)
 279 splitAppTy ty = case splitAppTy_maybe ty of
 280                         Just pr -> pr
 281                         Nothing -> panic "splitAppTy"
 282
 283 -------------
 284 splitAppTys :: Type -> (Type, [Type])
 285 splitAppTys ty = split ty ty []
 286   where
 287     split orig_ty ty args | Just ty' <- coreView ty = split orig_ty ty' args
 288     split orig_ty (AppTy ty arg)        args = split ty ty (arg:args)
 289     split orig_ty (TyConApp tc tc_args) args = (TyConApp tc [], tc_args ++ args)
 290     split orig_ty (FunTy ty1 ty2)       args = ASSERT( null args )
 291                                                (TyConApp funTyCon [], [ty1,ty2])
 292     split orig_ty ty                    args = (orig_ty, args)
 293
 294 \end{code}
 295
 296
 297 ---------------------------------------------------------------------
 298                                 FunTy
 299                                 ~~~~~
 300
 301 \begin{code}
 302 mkFunTy :: Type -> Type -> Type
 303 mkFunTy (PredTy (EqPred ty1 ty2)) res = mkForAllTy (mkWildCoVar (PredTy (EqPred ty1 ty2))) res
 304 mkFunTy arg res = FunTy arg res
 305
 306 mkFunTys :: [Type] -> Type -> Type
 307 mkFunTys tys ty = foldr mkFunTy ty tys
 308
 309 isFunTy :: Type -> Bool
 310 isFunTy ty = isJust (splitFunTy_maybe ty)
 311
 312 splitFunTy :: Type -> (Type, Type)
 313 splitFunTy ty | Just ty' <- coreView ty = splitFunTy ty'
 314 splitFunTy (FunTy arg res)   = (arg, res)
 315 splitFunTy other             = pprPanic "splitFunTy" (ppr other)
 316
 317 splitFunTy_maybe :: Type -> Maybe (Type, Type)
 318 splitFunTy_maybe ty | Just ty' <- coreView ty = splitFunTy_maybe ty'
 319 splitFunTy_maybe (FunTy arg res)   = Just (arg, res)
 320 splitFunTy_maybe other             = Nothing
 321
 322 splitFunTys :: Type -> ([Type], Type)
 323 splitFunTys ty = split [] ty ty
 324   where
 325     split args orig_ty ty | Just ty' <- coreView ty = split args orig_ty ty'
 326     split args orig_ty (FunTy arg res)   = split (arg:args) res res
 327     split args orig_ty ty                = (reverse args, orig_ty)
 328
 329 splitFunTysN :: Int -> Type -> ([Type], Type)
 330 -- Split off exactly n arg tys
 331 splitFunTysN 0 ty = ([], ty)
 332 splitFunTysN n ty = case splitFunTy ty of { (arg, res) ->
 333                     case splitFunTysN (n-1) res of { (args, res) ->
 334                     (arg:args, res) }}
 335
 336 zipFunTys :: Outputable a => [a] -> Type -> ([(a,Type)], Type)
 337 zipFunTys orig_xs orig_ty = split [] orig_xs orig_ty orig_ty
 338   where
 339     split acc []     nty ty                = (reverse acc, nty)
 340     split acc xs     nty ty
 341           | Just ty' <- coreView ty        = split acc xs nty ty'
 342     split acc (x:xs) nty (FunTy arg res)   = split ((x,arg):acc) xs res res
 343     split acc (x:xs) nty ty                = pprPanic "zipFunTys" (ppr orig_xs <+> ppr orig_ty)
 344
 345 funResultTy :: Type -> Type
 346 funResultTy ty | Just ty' <- coreView ty = funResultTy ty'
 347 funResultTy (FunTy arg res)   = res
 348 funResultTy ty                = pprPanic "funResultTy" (ppr ty)
 349
 350 funArgTy :: Type -> Type
 351 funArgTy ty | Just ty' <- coreView ty = funArgTy ty'
 352 funArgTy (FunTy arg res)   = arg
 353 funArgTy ty                = pprPanic "funArgTy" (ppr ty)
 354 \end{code}
 355
 356
 357 ---------------------------------------------------------------------
 358                                 TyConApp
 359                                 ~~~~~~~~
 360 @mkTyConApp@ is a key function, because it builds a TyConApp, FunTy or PredTy,
 361 as apppropriate.
 362
 363 \begin{code}
 364 mkTyConApp :: TyCon -> [Type] -> Type
 365 mkTyConApp tycon tys
 366   | isFunTyCon tycon, [ty1,ty2] <- tys
 367   = FunTy ty1 ty2
 368
 369   | otherwise
 370   = TyConApp tycon tys
 371
 372 mkTyConTy :: TyCon -> Type
 373 mkTyConTy tycon = mkTyConApp tycon []
 374
 375 -- splitTyConApp "looks through" synonyms, because they don't
 376 -- mean a distinct type, but all other type-constructor applications
 377 -- including functions are returned as Just ..
 378
 379 tyConAppTyCon :: Type -> TyCon
 380 tyConAppTyCon ty = fst (splitTyConApp ty)
 381
 382 tyConAppArgs :: Type -> [Type]
 383 tyConAppArgs ty = snd (splitTyConApp ty)
 384
 385 splitTyConApp :: Type -> (TyCon, [Type])
 386 splitTyConApp ty = case splitTyConApp_maybe ty of
 387                         Just stuff -> stuff
 388                         Nothing    -> pprPanic "splitTyConApp" (ppr ty)
 389
 390 splitTyConApp_maybe :: Type -> Maybe (TyCon, [Type])
 391 splitTyConApp_maybe ty | Just ty' <- coreView ty = splitTyConApp_maybe ty'
 392 splitTyConApp_maybe (TyConApp tc tys) = Just (tc, tys)
 393 splitTyConApp_maybe (FunTy arg res)   = Just (funTyCon, [arg,res])
 394 splitTyConApp_maybe other             = Nothing
 395
 396 -- Sometimes we do NOT want to look throught a newtype.  When case matching
 397 -- on a newtype we want a convenient way to access the arguments of a newty
 398 -- constructor so as to properly form a coercion.
 399 splitNewTyConApp :: Type -> (TyCon, [Type])
 400 splitNewTyConApp ty = case splitNewTyConApp_maybe ty of
 401                         Just stuff -> stuff
 402                         Nothing    -> pprPanic "splitNewTyConApp" (ppr ty)
 403 splitNewTyConApp_maybe :: Type -> Maybe (TyCon, [Type])
 404 splitNewTyConApp_maybe ty | Just ty' <- tcView ty = splitNewTyConApp_maybe ty'
 405 splitNewTyConApp_maybe (TyConApp tc tys) = Just (tc, tys)
 406 splitNewTyConApp_maybe (FunTy arg res)   = Just (funTyCon, [arg,res])
 407 splitNewTyConApp_maybe other          = Nothing
 408
 409 -- get instantiated newtype rhs, the arguments had better saturate
 410 -- the constructor
 411 newTyConInstRhs :: TyCon -> [Type] -> Type
 412 newTyConInstRhs tycon tys =
 413     let (tvs, ty) = newTyConRhs tycon in substTyWith tvs tys ty
 414 \end{code}
 415
 416
 417 ---------------------------------------------------------------------
 418                                 SynTy
 419                                 ~~~~~
 420
 421 Notes on type synonyms
 422 ~~~~~~~~~~~~~~~~~~~~~~
 423 The various "split" functions (splitFunTy, splitRhoTy, splitForAllTy) try
 424 to return type synonyms whereever possible. Thus
 425
 426         type Foo a = a -> a
 427
 428 we want
 429         splitFunTys (a -> Foo a) = ([a], Foo a)
 430 not                                ([a], a -> a)
 431
 432 The reason is that we then get better (shorter) type signatures in
 433 interfaces.  Notably this plays a role in tcTySigs in TcBinds.lhs.
 434
 435
 436                 Representation types
 437                 ~~~~~~~~~~~~~~~~~~~~
 438 repType looks through
 439         (a) for-alls, and
 440         (b) synonyms
 441         (c) predicates
 442         (d) usage annotations
 443         (e) all newtypes, including recursive ones, but not newtype families
 444 It's useful in the back end.
 445
 446 \begin{code}
 447 repType :: Type -> Type
 448 -- Only applied to types of kind *; hence tycons are saturated
 449 repType ty | Just ty' <- coreView ty = repType ty'
 450 repType (ForAllTy _ ty)  = repType ty
 451 repType (TyConApp tc tys)
 452   | isClosedNewTyCon tc  = -- Recursive newtypes are opaque to coreView
 453                            -- but we must expand them here.  Sure to
 454                            -- be saturated because repType is only applied
 455                            -- to types of kind *
 456                            ASSERT( {- isRecursiveTyCon tc && -} tys `lengthIs` tyConArity tc )
 457                            repType (new_type_rep tc tys)
 458 repType ty = ty
 459
 460 -- repType' aims to be a more thorough version of repType
 461 -- For now it simply looks through the TyConApp args too
 462 repType' ty -- | pprTrace "repType'" (ppr ty $$ ppr (go1 ty)) False = undefined
 463             | otherwise = go1 ty
 464  where
 465         go1 = go . repType
 466         go (TyConApp tc tys) = mkTyConApp tc (map repType' tys)
 467         go ty = ty
 468
 469
 470 -- new_type_rep doesn't ask any questions:
 471 -- it just expands newtype, whether recursive or not
 472 new_type_rep new_tycon tys = ASSERT( tys `lengthIs` tyConArity new_tycon )
 473                              case newTyConRep new_tycon of
 474                                  (tvs, rep_ty) -> substTyWith tvs tys rep_ty
 475
 476 -- ToDo: this could be moved to the code generator, using splitTyConApp instead
 477 -- of inspecting the type directly.
 478 typePrimRep :: Type -> PrimRep
 479 typePrimRep ty = case repType ty of
 480                    TyConApp tc _ -> tyConPrimRep tc
 481                    FunTy _ _     -> PtrRep
 482                    AppTy _ _     -> PtrRep      -- See note below
 483                    TyVarTy _     -> PtrRep
 484                    other         -> pprPanic "typePrimRep" (ppr ty)
 485         -- Types of the form 'f a' must be of kind *, not *#, so
 486         -- we are guaranteed that they are represented by pointers.
 487         -- The reason is that f must have kind *->*, not *->*#, because
 488         -- (we claim) there is no way to constrain f's kind any other
 489         -- way.
 490
 491 \end{code}
 492
 493
 494 ---------------------------------------------------------------------
 495                                 ForAllTy
 496                                 ~~~~~~~~
 497
 498 \begin{code}
 499 mkForAllTy :: TyVar -> Type -> Type
 500 mkForAllTy tyvar ty
 501   = mkForAllTys [tyvar] ty
 502
 503 mkForAllTys :: [TyVar] -> Type -> Type
 504 mkForAllTys tyvars ty = foldr ForAllTy ty tyvars
 505
 506 isForAllTy :: Type -> Bool
 507 isForAllTy (NoteTy _ ty)  = isForAllTy ty
 508 isForAllTy (ForAllTy _ _) = True
 509 isForAllTy other_ty       = False
 510
 511 splitForAllTy_maybe :: Type -> Maybe (TyVar, Type)
 512 splitForAllTy_maybe ty = splitFAT_m ty
 513   where
 514     splitFAT_m ty | Just ty' <- coreView ty = splitFAT_m ty'
 515     splitFAT_m (ForAllTy tyvar ty)          = Just(tyvar, ty)
 516     splitFAT_m _                            = Nothing
 517
 518 splitForAllTys :: Type -> ([TyVar], Type)
 519 splitForAllTys ty = split ty ty []
 520    where
 521      split orig_ty ty tvs | Just ty' <- coreView ty = split orig_ty ty' tvs
 522      split orig_ty (ForAllTy tv ty)  tvs = split ty ty (tv:tvs)
 523      split orig_ty t                 tvs = (reverse tvs, orig_ty)
 524
 525 dropForAlls :: Type -> Type
 526 dropForAlls ty = snd (splitForAllTys ty)
 527 \end{code}
 528
 529 -- (mkPiType now in CoreUtils)
 530
 531 applyTy, applyTys
 532 ~~~~~~~~~~~~~~~~~
 533 Instantiate a for-all type with one or more type arguments.
 534 Used when we have a polymorphic function applied to type args:
 535         f t1 t2
 536 Then we use (applyTys type-of-f [t1,t2]) to compute the type of
 537 the expression.
 538
 539 \begin{code}
 540 applyTy :: Type -> Type -> Type
 541 applyTy ty arg | Just ty' <- coreView ty = applyTy ty' arg
 542 applyTy (ForAllTy tv ty) arg = substTyWith [tv] [arg] ty
 543 applyTy other            arg = panic "applyTy"
 544
 545 applyTys :: Type -> [Type] -> Type
 546 -- This function is interesting because
 547 --      a) the function may have more for-alls than there are args
 548 --      b) less obviously, it may have fewer for-alls
 549 -- For case (b) think of
 550 --      applyTys (forall a.a) [forall b.b, Int]
 551 -- This really can happen, via dressing up polymorphic types with newtype
 552 -- clothing.  Here's an example:
 553 --      newtype R = R (forall a. a->a)
 554 --      foo = case undefined :: R of
 555 --              R f -> f ()
 556
 557 applyTys orig_fun_ty []      = orig_fun_ty
 558 applyTys orig_fun_ty arg_tys
 559   | n_tvs == n_args     -- The vastly common case
 560   = substTyWith tvs arg_tys rho_ty
 561   | n_tvs > n_args      -- Too many for-alls
 562   = substTyWith (take n_args tvs) arg_tys
 563                 (mkForAllTys (drop n_args tvs) rho_ty)
 564   | otherwise           -- Too many type args
 565   = ASSERT2( n_tvs > 0, ppr orig_fun_ty )       -- Zero case gives infnite loop!
 566     applyTys (substTyWith tvs (take n_tvs arg_tys) rho_ty)
 567              (drop n_tvs arg_tys)
 568   where
 569     (tvs, rho_ty) = splitForAllTys orig_fun_ty
 570     n_tvs = length tvs
 571     n_args = length arg_tys
 572 \end{code}
 573
 574
 575 %************************************************************************
 576 %*                                                                      *
 577 \subsection{Source types}
 578 %*                                                                      *
 579 %************************************************************************
 580
 581 A "source type" is a type that is a separate type as far as the type checker is
 582 concerned, but which has low-level representation as far as the back end is concerned.
 583
 584 Source types are always lifted.
 585
 586 The key function is predTypeRep which gives the representation of a source type:
 587
 588 \begin{code}
 589 mkPredTy :: PredType -> Type
 590 mkPredTy pred = PredTy pred
 591
 592 mkPredTys :: ThetaType -> [Type]
 593 mkPredTys preds = map PredTy preds
 594
 595 predTypeRep :: PredType -> Type
 596 -- Convert a PredType to its "representation type";
 597 -- the post-type-checking type used by all the Core passes of GHC.
 598 -- Unwraps only the outermost level; for example, the result might
 599 -- be a newtype application
 600 predTypeRep (IParam _ ty)     = ty
 601 predTypeRep (ClassP clas tys) = mkTyConApp (classTyCon clas) tys
 602         -- Result might be a newtype application, but the consumer will
 603         -- look through that too if necessary
 604 predTypeRep (EqPred ty1 ty2) = pprPanic "predTypeRep" (ppr (EqPred ty1 ty2))
 605
 606 -- The original head is the tycon and its variables for a vanilla tycon and it
 607 -- is the family tycon and its type indexes for a family instance.
 608 tyConOrigHead :: TyCon -> (TyCon, [Type])
 609 tyConOrigHead tycon = case tyConFamInst_maybe tycon of
 610                         Nothing      -> (tycon, mkTyVarTys (tyConTyVars tycon))
 611                         Just famInst -> famInst
 612 \end{code}
 613
 614
 615 %************************************************************************
 616 %*                                                                      *
 617                 NewTypes
 618 %*                                                                      *
 619 %************************************************************************
 620
 621 \begin{code}
 622 splitRecNewType_maybe :: Type -> Maybe Type
 623 -- Sometimes we want to look through a recursive newtype, and that's what happens here
 624 -- It only strips *one layer* off, so the caller will usually call itself recursively
 625 -- Only applied to types of kind *, hence the newtype is always saturated
 626 splitRecNewType_maybe ty | Just ty' <- coreView ty = splitRecNewType_maybe ty'
 627 splitRecNewType_maybe (TyConApp tc tys)
 628   | isClosedNewTyCon tc
 629   = ASSERT( tys `lengthIs` tyConArity tc )      -- splitRecNewType_maybe only be applied
 630                                                 --      to *types* (of kind *)
 631     ASSERT( isRecursiveTyCon tc )               -- Guaranteed by coreView
 632     case newTyConRhs tc of
 633         (tvs, rep_ty) -> ASSERT( length tvs == length tys )
 634                          Just (substTyWith tvs tys rep_ty)
 635
 636 splitRecNewType_maybe other = Nothing
 637
 638
 639
 640 \end{code}
 641
 642
 643 %************************************************************************
 644 %*                                                                      *
 645 \subsection{Kinds and free variables}
 646 %*                                                                      *
 647 %************************************************************************
 648
 649 ---------------------------------------------------------------------
 650                 Finding the kind of a type
 651                 ~~~~~~~~~~~~~~~~~~~~~~~~~~
 652 \begin{code}
 653 typeKind :: Type -> Kind
 654 typeKind (TyConApp tycon tys) = ASSERT( not (isCoercionTyCon tycon) )
 655                                    -- We should be looking for the coercion kind,
 656                                    -- not the type kind
 657                                 foldr (\_ k -> kindFunResult k) (tyConKind tycon) tys
 658 typeKind (NoteTy _ ty)        = typeKind ty
 659 typeKind (PredTy pred)        = predKind pred
 660 typeKind (AppTy fun arg)      = kindFunResult (typeKind fun)
 661 typeKind (ForAllTy tv ty)     = typeKind ty
 662 typeKind (TyVarTy tyvar)      = tyVarKind tyvar
 663 typeKind (FunTy arg res)
 664     -- Hack alert.  The kind of (Int -> Int#) is liftedTypeKind (*),
 665     --              not unliftedTypKind (#)
 666     -- The only things that can be after a function arrow are
 667     --   (a) types (of kind openTypeKind or its sub-kinds)
 668     --   (b) kinds (of super-kind TY) (e.g. * -> (* -> *))
 669     | isTySuperKind k         = k
 670     | otherwise               = ASSERT( isSubOpenTypeKind k) liftedTypeKind
 671     where
 672       k = typeKind res
 673
 674 predKind :: PredType -> Kind
 675 predKind (EqPred {}) = coSuperKind      -- A coercion kind!
 676 predKind (ClassP {}) = liftedTypeKind   -- Class and implicitPredicates are
 677 predKind (IParam {}) = liftedTypeKind   -- always represented by lifted types
 678 \end{code}
 679
 680
 681 ---------------------------------------------------------------------
 682                 Free variables of a type
 683                 ~~~~~~~~~~~~~~~~~~~~~~~~
 684 \begin{code}
 685 tyVarsOfType :: Type -> TyVarSet
 686 -- NB: for type synonyms tyVarsOfType does *not* expand the synonym
 687 tyVarsOfType (TyVarTy tv)               = unitVarSet tv
 688 tyVarsOfType (TyConApp tycon tys)       = tyVarsOfTypes tys
 689 tyVarsOfType (NoteTy (FTVNote tvs) ty2) = tvs
 690 tyVarsOfType (PredTy sty)               = tyVarsOfPred sty
 691 tyVarsOfType (FunTy arg res)            = tyVarsOfType arg `unionVarSet` tyVarsOfType res
 692 tyVarsOfType (AppTy fun arg)            = tyVarsOfType fun `unionVarSet` tyVarsOfType arg
 693 tyVarsOfType (ForAllTy tyvar ty)        = delVarSet (tyVarsOfType ty) tyvar
 694
 695 tyVarsOfTypes :: [Type] -> TyVarSet
 696 tyVarsOfTypes tys = foldr (unionVarSet.tyVarsOfType) emptyVarSet tys
 697
 698 tyVarsOfPred :: PredType -> TyVarSet
 699 tyVarsOfPred (IParam _ ty)    = tyVarsOfType ty
 700 tyVarsOfPred (ClassP _ tys)   = tyVarsOfTypes tys
 701 tyVarsOfPred (EqPred ty1 ty2) = tyVarsOfType ty1 `unionVarSet` tyVarsOfType ty2
 702
 703 tyVarsOfTheta :: ThetaType -> TyVarSet
 704 tyVarsOfTheta = foldr (unionVarSet . tyVarsOfPred) emptyVarSet
 705
 706 -- Add a Note with the free tyvars to the top of the type
 707 addFreeTyVars :: Type -> Type
 708 addFreeTyVars ty@(NoteTy (FTVNote _) _)      = ty
 709 addFreeTyVars ty                             = NoteTy (FTVNote (tyVarsOfType ty)) ty
 710 \end{code}
 711
 712
 713 %************************************************************************
 714 %*                                                                      *
 715 \subsection{TidyType}
 716 %*                                                                      *
 717 %************************************************************************
 718
 719 tidyTy tidies up a type for printing in an error message, or in
 720 an interface file.
 721
 722 It doesn't change the uniques at all, just the print names.
 723
 724 \begin{code}
 725 tidyTyVarBndr :: TidyEnv -> TyVar -> (TidyEnv, TyVar)
 726 tidyTyVarBndr (tidy_env, subst) tyvar
 727   = case tidyOccName tidy_env (getOccName name) of
 728       (tidy', occ') ->  ((tidy', subst'), tyvar')
 729                     where
 730                         subst' = extendVarEnv subst tyvar tyvar'
 731                         tyvar' = setTyVarName tyvar name'
 732                         name'  = tidyNameOcc name occ'
 733   where
 734     name = tyVarName tyvar
 735
 736 tidyFreeTyVars :: TidyEnv -> TyVarSet -> TidyEnv
 737 -- Add the free tyvars to the env in tidy form,
 738 -- so that we can tidy the type they are free in
 739 tidyFreeTyVars env tyvars = fst (tidyOpenTyVars env (varSetElems tyvars))
 740
 741 tidyOpenTyVars :: TidyEnv -> [TyVar] -> (TidyEnv, [TyVar])
 742 tidyOpenTyVars env tyvars = mapAccumL tidyOpenTyVar env tyvars
 743
 744 tidyOpenTyVar :: TidyEnv -> TyVar -> (TidyEnv, TyVar)
 745 -- Treat a new tyvar as a binder, and give it a fresh tidy name
 746 tidyOpenTyVar env@(tidy_env, subst) tyvar
 747   = case lookupVarEnv subst tyvar of
 748         Just tyvar' -> (env, tyvar')            -- Already substituted
 749         Nothing     -> tidyTyVarBndr env tyvar  -- Treat it as a binder
 750
 751 tidyType :: TidyEnv -> Type -> Type
 752 tidyType env@(tidy_env, subst) ty
 753   = go ty
 754   where
 755     go (TyVarTy tv)         = case lookupVarEnv subst tv of
 756                                 Nothing  -> TyVarTy tv
 757                                 Just tv' -> TyVarTy tv'
 758     go (TyConApp tycon tys) = let args = map go tys
 759                               in args `seqList` TyConApp tycon args
 760     go (NoteTy note ty)     = (NoteTy $! (go_note note)) $! (go ty)
 761     go (PredTy sty)         = PredTy (tidyPred env sty)
 762     go (AppTy fun arg)      = (AppTy $! (go fun)) $! (go arg)
 763     go (FunTy fun arg)      = (FunTy $! (go fun)) $! (go arg)
 764     go (ForAllTy tv ty)     = ForAllTy tvp $! (tidyType envp ty)
 765                               where
 766                                 (envp, tvp) = tidyTyVarBndr env tv
 767
 768     go_note note@(FTVNote ftvs) = note  -- No need to tidy the free tyvars
 769
 770 tidyTypes env tys = map (tidyType env) tys
 771
 772 tidyPred :: TidyEnv -> PredType -> PredType
 773 tidyPred env (IParam n ty)     = IParam n (tidyType env ty)
 774 tidyPred env (ClassP clas tys) = ClassP clas (tidyTypes env tys)
 775 tidyPred env (EqPred ty1 ty2)  = EqPred (tidyType env ty1) (tidyType env ty2)
 776 \end{code}
 777
 778
 779 @tidyOpenType@ grabs the free type variables, tidies them
 780 and then uses @tidyType@ to work over the type itself
 781
 782 \begin{code}
 783 tidyOpenType :: TidyEnv -> Type -> (TidyEnv, Type)
 784 tidyOpenType env ty
 785   = (env', tidyType env' ty)
 786   where
 787     env' = tidyFreeTyVars env (tyVarsOfType ty)
 788
 789 tidyOpenTypes :: TidyEnv -> [Type] -> (TidyEnv, [Type])
 790 tidyOpenTypes env tys = mapAccumL tidyOpenType env tys
 791
 792 tidyTopType :: Type -> Type
 793 tidyTopType ty = tidyType emptyTidyEnv ty
 794 \end{code}
 795
 796 \begin{code}
 797
 798 tidyKind :: TidyEnv -> Kind -> (TidyEnv, Kind)
 799 tidyKind env k = tidyOpenType env k
 800
 801 \end{code}
 802
 803
 804 %************************************************************************
 805 %*                                                                      *
 806 \subsection{Liftedness}
 807 %*                                                                      *
 808 %************************************************************************
 809
 810 \begin{code}
 811 isUnLiftedType :: Type -> Bool
 812         -- isUnLiftedType returns True for forall'd unlifted types:
 813         --      x :: forall a. Int#
 814         -- I found bindings like these were getting floated to the top level.
 815         -- They are pretty bogus types, mind you.  It would be better never to
 816         -- construct them
 817
 818 isUnLiftedType ty | Just ty' <- coreView ty = isUnLiftedType ty'
 819 isUnLiftedType (ForAllTy tv ty)  = isUnLiftedType ty
 820 isUnLiftedType (TyConApp tc _)   = isUnLiftedTyCon tc
 821 isUnLiftedType other             = False
 822
 823 isUnboxedTupleType :: Type -> Bool
 824 isUnboxedTupleType ty = case splitTyConApp_maybe ty of
 825                            Just (tc, ty_args) -> isUnboxedTupleTyCon tc
 826                            other              -> False
 827
 828 -- Should only be applied to *types*; hence the assert
 829 isAlgType :: Type -> Bool
 830 isAlgType ty = case splitTyConApp_maybe ty of
 831                         Just (tc, ty_args) -> ASSERT( ty_args `lengthIs` tyConArity tc )
 832                                               isAlgTyCon tc
 833                         other              -> False
 834 \end{code}
 835
 836 @isStrictType@ computes whether an argument (or let RHS) should
 837 be computed strictly or lazily, based only on its type.
 838 Works just like isUnLiftedType, except that it has a special case
 839 for dictionaries.  Since it takes account of ClassP, you might think
 840 this function should be in TcType, but isStrictType is used by DataCon,
 841 which is below TcType in the hierarchy, so it's convenient to put it here.
 842
 843 \begin{code}
 844 isStrictType (PredTy pred)     = isStrictPred pred
 845 isStrictType ty | Just ty' <- coreView ty = isStrictType ty'
 846 isStrictType (ForAllTy tv ty)  = isStrictType ty
 847 isStrictType (TyConApp tc _)   = isUnLiftedTyCon tc
 848 isStrictType other             = False
 849
 850 isStrictPred (ClassP clas _) = opt_DictsStrict && not (isNewTyCon (classTyCon clas))
 851 isStrictPred other           = False
 852         -- We may be strict in dictionary types, but only if it
 853         -- has more than one component.
 854         -- [Being strict in a single-component dictionary risks
 855         --  poking the dictionary component, which is wrong.]
 856 \end{code}
 857
 858 \begin{code}
 859 isPrimitiveType :: Type -> Bool
 860 -- Returns types that are opaque to Haskell.
 861 -- Most of these are unlifted, but now that we interact with .NET, we
 862 -- may have primtive (foreign-imported) types that are lifted
 863 isPrimitiveType ty = case splitTyConApp_maybe ty of
 864                         Just (tc, ty_args) -> ASSERT( ty_args `lengthIs` tyConArity tc )
 865                                               isPrimTyCon tc
 866                         other              -> False
 867 \end{code}
 868
 869
 870 %************************************************************************
 871 %*                                                                      *
 872 \subsection{Sequencing on types
 873 %*                                                                      *
 874 %************************************************************************
 875
 876 \begin{code}
 877 seqType :: Type -> ()
 878 seqType (TyVarTy tv)      = tv `seq` ()
 879 seqType (AppTy t1 t2)     = seqType t1 `seq` seqType t2
 880 seqType (FunTy t1 t2)     = seqType t1 `seq` seqType t2
 881 seqType (NoteTy note t2)  = seqNote note `seq` seqType t2
 882 seqType (PredTy p)        = seqPred p
 883 seqType (TyConApp tc tys) = tc `seq` seqTypes tys
 884 seqType (ForAllTy tv ty)  = tv `seq` seqType ty
 885
 886 seqTypes :: [Type] -> ()
 887 seqTypes []       = ()
 888 seqTypes (ty:tys) = seqType ty `seq` seqTypes tys
 889
 890 seqNote :: TyNote -> ()
 891 seqNote (FTVNote set) = sizeUniqSet set `seq` ()
 892
 893 seqPred :: PredType -> ()
 894 seqPred (ClassP c tys)   = c `seq` seqTypes tys
 895 seqPred (IParam n ty)    = n `seq` seqType ty
 896 seqPred (EqPred ty1 ty2) = seqType ty1 `seq` seqType ty2
 897 \end{code}
 898
 899
 900 %************************************************************************
 901 %*                                                                      *
 902                 Equality for Core types
 903         (We don't use instances so that we know where it happens)
 904 %*                                                                      *
 905 %************************************************************************
 906
 907 Note that eqType works right even for partial applications of newtypes.
 908 See Note [Newtype eta] in TyCon.lhs
 909
 910 \begin{code}
 911 coreEqType :: Type -> Type -> Bool
 912 coreEqType t1 t2
 913   = eq rn_env t1 t2
 914   where
 915     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfType t1 `unionVarSet` tyVarsOfType t2))
 916
 917     eq env (TyVarTy tv1)       (TyVarTy tv2)     = rnOccL env tv1 == rnOccR env tv2
 918     eq env (ForAllTy tv1 t1)   (ForAllTy tv2 t2) = eq (rnBndr2 env tv1 tv2) t1 t2
 919     eq env (AppTy s1 t1)       (AppTy s2 t2)     = eq env s1 s2 && eq env t1 t2
 920     eq env (FunTy s1 t1)       (FunTy s2 t2)     = eq env s1 s2 && eq env t1 t2
 921     eq env (TyConApp tc1 tys1) (TyConApp tc2 tys2)
 922         | tc1 == tc2, all2 (eq env) tys1 tys2 = True
 923                         -- The lengths should be equal because
 924                         -- the two types have the same kind
 925         -- NB: if the type constructors differ that does not
 926         --     necessarily mean that the types aren't equal
 927         --     (synonyms, newtypes)
 928         -- Even if the type constructors are the same, but the arguments
 929         -- differ, the two types could be the same (e.g. if the arg is just
 930         -- ignored in the RHS).  In both these cases we fall through to an
 931         -- attempt to expand one side or the other.
 932
 933         -- Now deal with newtypes, synonyms, pred-tys
 934     eq env t1 t2 | Just t1' <- coreView t1 = eq env t1' t2
 935                  | Just t2' <- coreView t2 = eq env t1 t2'
 936
 937         -- Fall through case; not equal!
 938     eq env t1 t2 = False
 939 \end{code}
 940
 941
 942 %************************************************************************
 943 %*                                                                      *
 944                 Comparision for source types
 945         (We don't use instances so that we know where it happens)
 946 %*                                                                      *
 947 %************************************************************************
 948
 949 Note that
 950         tcEqType, tcCmpType
 951 do *not* look through newtypes, PredTypes
 952
 953 \begin{code}
 954 tcEqType :: Type -> Type -> Bool
 955 tcEqType t1 t2 = isEqual $ cmpType t1 t2
 956
 957 tcEqTypes :: [Type] -> [Type] -> Bool
 958 tcEqTypes tys1 tys2 = isEqual $ cmpTypes tys1 tys2
 959
 960 tcCmpType :: Type -> Type -> Ordering
 961 tcCmpType t1 t2 = cmpType t1 t2
 962
 963 tcCmpTypes :: [Type] -> [Type] -> Ordering
 964 tcCmpTypes tys1 tys2 = cmpTypes tys1 tys2
 965
 966 tcEqPred :: PredType -> PredType -> Bool
 967 tcEqPred p1 p2 = isEqual $ cmpPred p1 p2
 968
 969 tcCmpPred :: PredType -> PredType -> Ordering
 970 tcCmpPred p1 p2 = cmpPred p1 p2
 971
 972 tcEqTypeX :: RnEnv2 -> Type -> Type -> Bool
 973 tcEqTypeX env t1 t2 = isEqual $ cmpTypeX env t1 t2
 974 \end{code}
 975
 976 Now here comes the real worker
 977
 978 \begin{code}
 979 cmpType :: Type -> Type -> Ordering
 980 cmpType t1 t2 = cmpTypeX rn_env t1 t2
 981   where
 982     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfType t1 `unionVarSet` tyVarsOfType t2))
 983
 984 cmpTypes :: [Type] -> [Type] -> Ordering
 985 cmpTypes ts1 ts2 = cmpTypesX rn_env ts1 ts2
 986   where
 987     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfTypes ts1 `unionVarSet` tyVarsOfTypes ts2))
 988
 989 cmpPred :: PredType -> PredType -> Ordering
 990 cmpPred p1 p2 = cmpPredX rn_env p1 p2
 991   where
 992     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfPred p1 `unionVarSet` tyVarsOfPred p2))
 993
 994 cmpTypeX :: RnEnv2 -> Type -> Type -> Ordering  -- Main workhorse
 995 cmpTypeX env t1 t2 | Just t1' <- tcView t1 = cmpTypeX env t1' t2
 996                    | Just t2' <- tcView t2 = cmpTypeX env t1 t2'
 997
 998 cmpTypeX env (TyVarTy tv1)       (TyVarTy tv2)       = rnOccL env tv1 `compare` rnOccR env tv2
 999 cmpTypeX env (ForAllTy tv1 t1)   (ForAllTy tv2 t2)   = cmpTypeX (rnBndr2 env tv1 tv2) t1 t2
1000 cmpTypeX env (AppTy s1 t1)       (AppTy s2 t2)       = cmpTypeX env s1 s2 `thenCmp` cmpTypeX env t1 t2
1001 cmpTypeX env (FunTy s1 t1)       (FunTy s2 t2)       = cmpTypeX env s1 s2 `thenCmp` cmpTypeX env t1 t2
1002 cmpTypeX env (PredTy p1)         (PredTy p2)         = cmpPredX env p1 p2
1003 cmpTypeX env (TyConApp tc1 tys1) (TyConApp tc2 tys2) = (tc1 `compare` tc2) `thenCmp` cmpTypesX env tys1 tys2
1004 cmpTypeX env t1                 (NoteTy _ t2)        = cmpTypeX env t1 t2
1005
1006     -- Deal with the rest: TyVarTy < AppTy < FunTy < TyConApp < ForAllTy < PredTy
1007 cmpTypeX env (AppTy _ _) (TyVarTy _) = GT
1008
1009 cmpTypeX env (FunTy _ _) (TyVarTy _) = GT
1010 cmpTypeX env (FunTy _ _) (AppTy _ _) = GT
1011
1012 cmpTypeX env (TyConApp _ _) (TyVarTy _) = GT
1013 cmpTypeX env (TyConApp _ _) (AppTy _ _) = GT
1014 cmpTypeX env (TyConApp _ _) (FunTy _ _) = GT
1015
1016 cmpTypeX env (ForAllTy _ _) (TyVarTy _)    = GT
1017 cmpTypeX env (ForAllTy _ _) (AppTy _ _)    = GT
1018 cmpTypeX env (ForAllTy _ _) (FunTy _ _)    = GT
1019 cmpTypeX env (ForAllTy _ _) (TyConApp _ _) = GT
1020
1021 cmpTypeX env (PredTy _)   t2            = GT
1022
1023 cmpTypeX env _ _ = LT
1024
1025 -------------
1026 cmpTypesX :: RnEnv2 -> [Type] -> [Type] -> Ordering
1027 cmpTypesX env []        []        = EQ
1028 cmpTypesX env (t1:tys1) (t2:tys2) = cmpTypeX env t1 t2 `thenCmp` cmpTypesX env tys1 tys2
1029 cmpTypesX env []        tys       = LT
1030 cmpTypesX env ty        []        = GT
1031
1032 -------------
1033 cmpPredX :: RnEnv2 -> PredType -> PredType -> Ordering
1034 cmpPredX env (IParam n1 ty1) (IParam n2 ty2) = (n1 `compare` n2) `thenCmp` cmpTypeX env ty1 ty2
1035         -- Compare names only for implicit parameters
1036         -- This comparison is used exclusively (I believe)
1037         -- for the Avails finite map built in TcSimplify
1038         -- If the types differ we keep them distinct so that we see
1039         -- a distinct pair to run improvement on
1040 cmpPredX env (ClassP c1 tys1) (ClassP c2 tys2) = (c1 `compare` c2) `thenCmp` (cmpTypesX env tys1 tys2)
1041 cmpPredX env (EqPred ty1 ty2) (EqPred ty1' ty2') = (cmpTypeX env ty1 ty1') `thenCmp` (cmpTypeX env ty2 ty2')
1042
1043 -- Constructor order: IParam < ClassP < EqPred
1044 cmpPredX env (IParam {})     _              = LT
1045 cmpPredX env (ClassP {})    (IParam {})     = GT
1046 cmpPredX env (ClassP {})    (EqPred {})     = LT
1047 cmpPredX env (EqPred {})    _               = GT
1048 \end{code}
1049
1050 PredTypes are used as a FM key in TcSimplify,
1051 so we take the easy path and make them an instance of Ord
1052
1053 \begin{code}
1054 instance Eq  PredType where { (==)    = tcEqPred }
1055 instance Ord PredType where { compare = tcCmpPred }
1056 \end{code}
1057
1058
1059 %************************************************************************
1060 %*                                                                      *
1061                 Type substitutions
1062 %*                                                                      *
1063 %************************************************************************
1064
1065 \begin{code}
1066 data TvSubst
1067   = TvSubst InScopeSet  -- The in-scope type variables
1068             TvSubstEnv  -- The substitution itself
1069         -- See Note [Apply Once]
1070         -- and Note [Extending the TvSubstEnv]
1071
1072 {- ----------------------------------------------------------
1073
1074 Note [Apply Once]
1075 ~~~~~~~~~~~~~~~~~
1076 We use TvSubsts to instantiate things, and we might instantiate
1077         forall a b. ty
1078 \with the types
1079         [a, b], or [b, a].
1080 So the substition might go [a->b, b->a].  A similar situation arises in Core
1081 when we find a beta redex like
1082         (/\ a /\ b -> e) b a
1083 Then we also end up with a substition that permutes type variables. Other
1084 variations happen to; for example [a -> (a, b)].
1085
1086         ***************************************************
1087         *** So a TvSubst must be applied precisely once ***
1088         ***************************************************
1089
1090 A TvSubst is not idempotent, but, unlike the non-idempotent substitution
1091 we use during unifications, it must not be repeatedly applied.
1092
1093 Note [Extending the TvSubst]
1094 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1095 The following invariant should hold of a TvSubst
1096
1097         The in-scope set is needed *only* to
1098         guide the generation of fresh uniques
1099
1100         In particular, the *kind* of the type variables in
1101         the in-scope set is not relevant
1102
1103 This invariant allows a short-cut when the TvSubstEnv is empty:
1104 if the TvSubstEnv is empty --- i.e. (isEmptyTvSubt subst) holds ---
1105 then (substTy subst ty) does nothing.
1106
1107 For example, consider:
1108         (/\a. /\b:(a~Int). ...b..) Int
1109 We substitute Int for 'a'.  The Unique of 'b' does not change, but
1110 nevertheless we add 'b' to the TvSubstEnv, because b's type does change
1111
1112 This invariant has several crucial consequences:
1113
1114 * In substTyVarBndr, we need extend the TvSubstEnv
1115         - if the unique has changed
1116         - or if the kind has changed
1117
1118 * In substTyVar, we do not need to consult the in-scope set;
1119   the TvSubstEnv is enough
1120
1121 * In substTy, substTheta, we can short-circuit when the TvSubstEnv is empty
1122
1123
1124 -------------------------------------------------------------- -}
1125
1126
1127 type TvSubstEnv = TyVarEnv Type
1128         -- A TvSubstEnv is used both inside a TvSubst (with the apply-once
1129         -- invariant discussed in Note [Apply Once]), and also independently
1130         -- in the middle of matching, and unification (see Types.Unify)
1131         -- So you have to look at the context to know if it's idempotent or
1132         -- apply-once or whatever
1133 emptyTvSubstEnv :: TvSubstEnv
1134 emptyTvSubstEnv = emptyVarEnv
1135
1136 composeTvSubst :: InScopeSet -> TvSubstEnv -> TvSubstEnv -> TvSubstEnv
1137 -- (compose env1 env2)(x) is env1(env2(x)); i.e. apply env2 then env1
1138 -- It assumes that both are idempotent
1139 -- Typically, env1 is the refinement to a base substitution env2
1140 composeTvSubst in_scope env1 env2
1141   = env1 `plusVarEnv` mapVarEnv (substTy subst1) env2
1142         -- First apply env1 to the range of env2
1143         -- Then combine the two, making sure that env1 loses if
1144         -- both bind the same variable; that's why env1 is the
1145         --  *left* argument to plusVarEnv, because the right arg wins
1146   where
1147     subst1 = TvSubst in_scope env1
1148
1149 emptyTvSubst = TvSubst emptyInScopeSet emptyVarEnv
1150
1151 isEmptyTvSubst :: TvSubst -> Bool
1152          -- See Note [Extending the TvSubstEnv]
1153 isEmptyTvSubst (TvSubst _ env) = isEmptyVarEnv env
1154
1155 mkTvSubst :: InScopeSet -> TvSubstEnv -> TvSubst
1156 mkTvSubst = TvSubst
1157
1158 getTvSubstEnv :: TvSubst -> TvSubstEnv
1159 getTvSubstEnv (TvSubst _ env) = env
1160
1161 getTvInScope :: TvSubst -> InScopeSet
1162 getTvInScope (TvSubst in_scope _) = in_scope
1163
1164 isInScope :: Var -> TvSubst -> Bool
1165 isInScope v (TvSubst in_scope _) = v `elemInScopeSet` in_scope
1166
1167 notElemTvSubst :: TyVar -> TvSubst -> Bool
1168 notElemTvSubst tv (TvSubst _ env) = not (tv `elemVarEnv` env)
1169
1170 setTvSubstEnv :: TvSubst -> TvSubstEnv -> TvSubst
1171 setTvSubstEnv (TvSubst in_scope _) env = TvSubst in_scope env
1172
1173 extendTvInScope :: TvSubst -> [Var] -> TvSubst
1174 extendTvInScope (TvSubst in_scope env) vars = TvSubst (extendInScopeSetList in_scope vars) env
1175
1176 extendTvSubst :: TvSubst -> TyVar -> Type -> TvSubst
1177 extendTvSubst (TvSubst in_scope env) tv ty = TvSubst in_scope (extendVarEnv env tv ty)
1178
1179 extendTvSubstList :: TvSubst -> [TyVar] -> [Type] -> TvSubst
1180 extendTvSubstList (TvSubst in_scope env) tvs tys
1181   = TvSubst in_scope (extendVarEnvList env (tvs `zip` tys))
1182
1183 -- mkOpenTvSubst and zipOpenTvSubst generate the in-scope set from
1184 -- the types given; but it's just a thunk so with a bit of luck
1185 -- it'll never be evaluated
1186
1187 mkOpenTvSubst :: TvSubstEnv -> TvSubst
1188 mkOpenTvSubst env = TvSubst (mkInScopeSet (tyVarsOfTypes (varEnvElts env))) env
1189
1190 zipOpenTvSubst :: [TyVar] -> [Type] -> TvSubst
1191 zipOpenTvSubst tyvars tys
1192 #ifdef DEBUG
1193   | length tyvars /= length tys
1194   = pprTrace "zipOpenTvSubst" (ppr tyvars $$ ppr tys) emptyTvSubst
1195   | otherwise
1196 #endif
1197   = TvSubst (mkInScopeSet (tyVarsOfTypes tys)) (zipTyEnv tyvars tys)
1198
1199 -- mkTopTvSubst is called when doing top-level substitutions.
1200 -- Here we expect that the free vars of the range of the
1201 -- substitution will be empty.
1202 mkTopTvSubst :: [(TyVar, Type)] -> TvSubst
1203 mkTopTvSubst prs = TvSubst emptyInScopeSet (mkVarEnv prs)
1204
1205 zipTopTvSubst :: [TyVar] -> [Type] -> TvSubst
1206 zipTopTvSubst tyvars tys
1207 #ifdef DEBUG
1208   | length tyvars /= length tys
1209   = pprTrace "zipOpenTvSubst" (ppr tyvars $$ ppr tys) emptyTvSubst
1210   | otherwise
1211 #endif
1212   = TvSubst emptyInScopeSet (zipTyEnv tyvars tys)
1213
1214 zipTyEnv :: [TyVar] -> [Type] -> TvSubstEnv
1215 zipTyEnv tyvars tys
1216 #ifdef DEBUG
1217   | length tyvars /= length tys
1218   = pprTrace "mkTopTvSubst" (ppr tyvars $$ ppr tys) emptyVarEnv
1219   | otherwise
1220 #endif
1221   = zip_ty_env tyvars tys emptyVarEnv
1222
1223 -- Later substitutions in the list over-ride earlier ones,
1224 -- but there should be no loops
1225 zip_ty_env []       []       env = env
1226 zip_ty_env (tv:tvs) (ty:tys) env = zip_ty_env tvs tys (extendVarEnv env tv ty)
1227         -- There used to be a special case for when
1228         --      ty == TyVarTy tv
1229         -- (a not-uncommon case) in which case the substitution was dropped.
1230         -- But the type-tidier changes the print-name of a type variable without
1231         -- changing the unique, and that led to a bug.   Why?  Pre-tidying, we had
1232         -- a type {Foo t}, where Foo is a one-method class.  So Foo is really a newtype.
1233         -- And it happened that t was the type variable of the class.  Post-tiding,
1234         -- it got turned into {Foo t2}.  The ext-core printer expanded this using
1235         -- sourceTypeRep, but that said "Oh, t == t2" because they have the same unique,
1236         -- and so generated a rep type mentioning t not t2.
1237         --
1238         -- Simplest fix is to nuke the "optimisation"
1239 zip_ty_env tvs      tys      env   = pprTrace "Var/Type length mismatch: " (ppr tvs $$ ppr tys) env
1240 -- zip_ty_env _ _ env = env
1241
1242 instance Outputable TvSubst where
1243   ppr (TvSubst ins env)
1244     = brackets $ sep[ ptext SLIT("TvSubst"),
1245                       nest 2 (ptext SLIT("In scope:") <+> ppr ins),
1246                       nest 2 (ptext SLIT("Env:") <+> ppr env) ]
1247 \end{code}
1248
1249 %************************************************************************
1250 %*                                                                      *
1251                 Performing type substitutions
1252 %*                                                                      *
1253 %************************************************************************
1254
1255 \begin{code}
1256 substTyWith :: [TyVar] -> [Type] -> Type -> Type
1257 substTyWith tvs tys = ASSERT( length tvs == length tys )
1258                       substTy (zipOpenTvSubst tvs tys)
1259
1260 substTy :: TvSubst -> Type  -> Type
1261 substTy subst ty | isEmptyTvSubst subst = ty
1262                  | otherwise            = subst_ty subst ty
1263
1264 substTys :: TvSubst -> [Type] -> [Type]
1265 substTys subst tys | isEmptyTvSubst subst = tys
1266                    | otherwise            = map (subst_ty subst) tys
1267
1268 substTheta :: TvSubst -> ThetaType -> ThetaType
1269 substTheta subst theta
1270   | isEmptyTvSubst subst = theta
1271   | otherwise            = map (substPred subst) theta
1272
1273 substPred :: TvSubst -> PredType -> PredType
1274 substPred subst (IParam n ty)     = IParam n (subst_ty subst ty)
1275 substPred subst (ClassP clas tys) = ClassP clas (map (subst_ty subst) tys)
1276 substPred subst (EqPred ty1 ty2)  = EqPred (subst_ty subst ty1) (subst_ty subst ty2)
1277
1278 deShadowTy :: TyVarSet -> Type -> Type  -- Remove any nested binders mentioning tvs
1279 deShadowTy tvs ty
1280   = subst_ty (mkTvSubst in_scope emptyTvSubstEnv) ty
1281   where
1282     in_scope = mkInScopeSet tvs
1283
1284 subst_ty :: TvSubst -> Type -> Type
1285 -- subst_ty is the main workhorse for type substitution
1286 --
1287 -- Note that the in_scope set is poked only if we hit a forall
1288 -- so it may often never be fully computed
1289 subst_ty subst ty
1290    = go ty
1291   where
1292     go (TyVarTy tv)                = substTyVar subst tv
1293     go (TyConApp tc tys)           = let args = map go tys
1294                                      in  args `seqList` TyConApp tc args
1295
1296     go (PredTy p)                  = PredTy $! (substPred subst p)
1297
1298     go (NoteTy (FTVNote _) ty2)    = go ty2             -- Discard the free tyvar note
1299
1300     go (FunTy arg res)             = (FunTy $! (go arg)) $! (go res)
1301     go (AppTy fun arg)             = mkAppTy (go fun) $! (go arg)
1302                 -- The mkAppTy smart constructor is important
1303                 -- we might be replacing (a Int), represented with App
1304                 -- by [Int], represented with TyConApp
1305     go (ForAllTy tv ty)            = case substTyVarBndr subst tv of
1306                                         (subst', tv') -> ForAllTy tv' $! (subst_ty subst' ty)
1307
1308 substTyVar :: TvSubst -> TyVar  -> Type
1309 substTyVar subst@(TvSubst in_scope env) tv
1310   = case lookupTyVar subst tv of {
1311         Nothing -> TyVarTy tv;
1312         Just ty -> ty   -- See Note [Apply Once]
1313     }
1314
1315 substTyVars :: TvSubst -> [TyVar] -> [Type]
1316 substTyVars subst tvs = map (substTyVar subst) tvs
1317
1318 lookupTyVar :: TvSubst -> TyVar  -> Maybe Type
1319         -- See Note [Extending the TvSubst]
1320 lookupTyVar (TvSubst in_scope env) tv = lookupVarEnv env tv
1321
1322 substTyVarBndr :: TvSubst -> TyVar -> (TvSubst, TyVar)
1323 substTyVarBndr subst@(TvSubst in_scope env) old_var
1324   = (TvSubst (in_scope `extendInScopeSet` new_var) new_env, new_var)
1325   where
1326     is_co_var = isCoVar old_var
1327
1328     new_env | no_change = delVarEnv env old_var
1329             | otherwise = extendVarEnv env old_var (TyVarTy new_var)
1330
1331     no_change = new_var == old_var && not is_co_var
1332         -- no_change means that the new_var is identical in
1333         -- all respects to the old_var (same unique, same kind)
1334         -- See Note [Extending the TvSubst]
1335         --
1336         -- In that case we don't need to extend the substitution
1337         -- to map old to new.  But instead we must zap any
1338         -- current substitution for the variable. For example:
1339         --      (\x.e) with id_subst = [x |-> e']
1340         -- Here we must simply zap the substitution for x
1341
1342     new_var = uniqAway in_scope subst_old_var
1343         -- The uniqAway part makes sure the new variable is not already in scope
1344
1345     subst_old_var -- subst_old_var is old_var with the substitution applied to its kind
1346                   -- It's only worth doing the substitution for coercions,
1347                   -- becuase only they can have free type variables
1348         | is_co_var = setTyVarKind old_var (substTy subst (tyVarKind old_var))
1349         | otherwise = old_var
1350 \end{code}
1351
1352 ----------------------------------------------------
1353 -- Kind Stuff
1354
1355 Kinds
1356 ~~~~~
1357 There's a little subtyping at the kind level:
1358
1359                  ?
1360                 / \
1361                /   \
1362               ??   (#)
1363              /  \
1364             *   #
1365
1366 where   *    [LiftedTypeKind]   means boxed type
1367         #    [UnliftedTypeKind] means unboxed type
1368         (#)  [UbxTupleKind]     means unboxed tuple
1369         ??   [ArgTypeKind]      is the lub of *,#
1370         ?    [OpenTypeKind]     means any type at all
1371
1372 In particular:
1373
1374         error :: forall a:?. String -> a
1375         (->)  :: ?? -> ? -> *
1376         (\(x::t) -> ...)        Here t::?? (i.e. not unboxed tuple)
1377
1378 \begin{code}
1379 type KindVar = TyVar  -- invariant: KindVar will always be a
1380                       -- TcTyVar with details MetaTv TauTv ...
1381 -- kind var constructors and functions are in TcType
1382
1383 type SimpleKind = Kind
1384 \end{code}
1385
1386 Kind inference
1387 ~~~~~~~~~~~~~~
1388 During kind inference, a kind variable unifies only with
1389 a "simple kind", sk
1390         sk ::= * | sk1 -> sk2
1391 For example
1392         data T a = MkT a (T Int#)
1393 fails.  We give T the kind (k -> *), and the kind variable k won't unify
1394 with # (the kind of Int#).
1395
1396 Type inference
1397 ~~~~~~~~~~~~~~
1398 When creating a fresh internal type variable, we give it a kind to express
1399 constraints on it.  E.g. in (\x->e) we make up a fresh type variable for x,
1400 with kind ??.
1401
1402 During unification we only bind an internal type variable to a type
1403 whose kind is lower in the sub-kind hierarchy than the kind of the tyvar.
1404
1405 When unifying two internal type variables, we collect their kind constraints by
1406 finding the GLB of the two.  Since the partial order is a tree, they only
1407 have a glb if one is a sub-kind of the other.  In that case, we bind the
1408 less-informative one to the more informative one.  Neat, eh?
1409
1410
1411 \begin{code}
1412
1413 \end{code}
1414
1415 %************************************************************************
1416 %*                                                                      *
1417         Functions over Kinds
1418 %*                                                                      *
1419 %************************************************************************
1420
1421 \begin{code}
1422 kindFunResult :: Kind -> Kind
1423 kindFunResult k = funResultTy k
1424
1425 splitKindFunTys :: Kind -> ([Kind],Kind)
1426 splitKindFunTys k = splitFunTys k
1427
1428 splitKindFunTysN :: Int -> Kind -> ([Kind],Kind)
1429 splitKindFunTysN k = splitFunTysN k
1430
1431 isUbxTupleKind, isOpenTypeKind, isArgTypeKind, isUnliftedTypeKind :: Kind -> Bool
1432
1433 isOpenTypeKindCon tc    = tyConUnique tc == openTypeKindTyConKey
1434
1435 isOpenTypeKind (TyConApp tc _) = isOpenTypeKindCon tc
1436 isOpenTypeKind other           = False
1437
1438 isUbxTupleKindCon tc = tyConUnique tc == ubxTupleKindTyConKey
1439
1440 isUbxTupleKind (TyConApp tc _) = isUbxTupleKindCon tc
1441 isUbxTupleKind other           = False
1442
1443 isArgTypeKindCon tc = tyConUnique tc == argTypeKindTyConKey
1444
1445 isArgTypeKind (TyConApp tc _) = isArgTypeKindCon tc
1446 isArgTypeKind other = False
1447
1448 isUnliftedTypeKindCon tc = tyConUnique tc == unliftedTypeKindTyConKey
1449
1450 isUnliftedTypeKind (TyConApp tc _) = isUnliftedTypeKindCon tc
1451 isUnliftedTypeKind other           = False
1452
1453 isSubOpenTypeKind :: Kind -> Bool
1454 -- True of any sub-kind of OpenTypeKind (i.e. anything except arrow)
1455 isSubOpenTypeKind (FunTy k1 k2)    = ASSERT2 ( isKind k1, text "isSubOpenTypeKind" <+> ppr k1 <+> text "::" <+> ppr (typeKind k1) )
1456                                      ASSERT2 ( isKind k2, text "isSubOpenTypeKind" <+> ppr k2 <+> text "::" <+> ppr (typeKind k2) )
1457                                      False
1458 isSubOpenTypeKind (TyConApp kc []) = ASSERT( isKind (TyConApp kc []) ) True
1459 isSubOpenTypeKind other            = ASSERT( isKind other ) False
1460          -- This is a conservative answer
1461          -- It matters in the call to isSubKind in
1462          -- checkExpectedKind.
1463
1464 isSubArgTypeKindCon kc
1465   | isUnliftedTypeKindCon kc = True
1466   | isLiftedTypeKindCon kc   = True
1467   | isArgTypeKindCon kc      = True
1468   | otherwise                = False
1469
1470 isSubArgTypeKind :: Kind -> Bool
1471 -- True of any sub-kind of ArgTypeKind
1472 isSubArgTypeKind (TyConApp kc []) = isSubArgTypeKindCon kc
1473 isSubArgTypeKind other            = False
1474
1475 isSuperKind :: Type -> Bool
1476 isSuperKind (TyConApp (skc) []) = isSuperKindTyCon skc
1477 isSuperKind other = False
1478
1479 isKind :: Kind -> Bool
1480 isKind k = isSuperKind (typeKind k)
1481
1482
1483
1484 isSubKind :: Kind -> Kind -> Bool
1485 -- (k1 `isSubKind` k2) checks that k1 <: k2
1486 isSubKind (TyConApp kc1 []) (TyConApp kc2 []) = kc1 `isSubKindCon` kc2
1487 isSubKind (FunTy a1 r1) (FunTy a2 r2)         = (a2 `isSubKind` a1) && (r1 `isSubKind` r2)
1488 isSubKind (PredTy (EqPred ty1 ty2)) (PredTy (EqPred ty1' ty2'))
1489   = ty1 `tcEqType` ty1' && ty2 `tcEqType` ty2'
1490 isSubKind k1            k2                    = False
1491
1492 eqKind :: Kind -> Kind -> Bool
1493 eqKind = tcEqType
1494
1495 isSubKindCon :: TyCon -> TyCon -> Bool
1496 -- (kc1 `isSubKindCon` kc2) checks that kc1 <: kc2
1497 isSubKindCon kc1 kc2
1498   | isLiftedTypeKindCon kc1   && isLiftedTypeKindCon kc2   = True
1499   | isUnliftedTypeKindCon kc1 && isUnliftedTypeKindCon kc2 = True
1500   | isUbxTupleKindCon kc1     && isUbxTupleKindCon kc2     = True
1501   | isOpenTypeKindCon kc2                                  = True
1502                            -- we already know kc1 is not a fun, its a TyCon
1503   | isArgTypeKindCon kc2      && isSubArgTypeKindCon kc1   = True
1504   | otherwise                                              = False
1505
1506 defaultKind :: Kind -> Kind
1507 -- Used when generalising: default kind '?' and '??' to '*'
1508 --
1509 -- When we generalise, we make generic type variables whose kind is
1510 -- simple (* or *->* etc).  So generic type variables (other than
1511 -- built-in constants like 'error') always have simple kinds.  This is important;
1512 -- consider
1513 --      f x = True
1514 -- We want f to get type
1515 --      f :: forall (a::*). a -> Bool
1516 -- Not
1517 --      f :: forall (a::??). a -> Bool
1518 -- because that would allow a call like (f 3#) as well as (f True),
1519 --and the calling conventions differ.  This defaulting is done in TcMType.zonkTcTyVarBndr.
1520 defaultKind k
1521   | isSubOpenTypeKind k = liftedTypeKind
1522   | isSubArgTypeKind k  = liftedTypeKind
1523   | otherwise        = k
1524
1525 isEqPred :: PredType -> Bool
1526 isEqPred (EqPred _ _) = True
1527 isEqPred other        = False
1528 \end{code}