compiler/types/Type.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1998
   4 %
   5
   6 Type - public interface
   7
   8 \begin{code}
   9 module Type (
  10         -- re-exports from TypeRep
  11         TyThing(..), Type, PredType(..), ThetaType,
  12         funTyCon,
  13
  14         -- Kinds
  15         Kind, SimpleKind, KindVar,
  16         kindFunResult, splitKindFunTys, splitKindFunTysN,
  17
  18         liftedTypeKindTyCon, openTypeKindTyCon, unliftedTypeKindTyCon,
  19         argTypeKindTyCon, ubxTupleKindTyCon,
  20
  21         liftedTypeKind, unliftedTypeKind, openTypeKind,
  22         argTypeKind, ubxTupleKind,
  23
  24         tySuperKind, coSuperKind,
  25
  26         isLiftedTypeKind, isUnliftedTypeKind, isOpenTypeKind,
  27         isUbxTupleKind, isArgTypeKind, isKind, isTySuperKind,
  28         isCoSuperKind, isSuperKind, isCoercionKind, isEqPred,
  29         mkArrowKind, mkArrowKinds,
  30
  31         isSubArgTypeKind, isSubOpenTypeKind, isSubKind, defaultKind, eqKind,
  32         isSubKindCon,
  33
  34         -- Re-exports from TyCon
  35         PrimRep(..),
  36
  37         mkTyVarTy, mkTyVarTys, getTyVar, getTyVar_maybe, isTyVarTy,
  38
  39         mkAppTy, mkAppTys, splitAppTy, splitAppTys,
  40         splitAppTy_maybe, repSplitAppTy_maybe,
  41
  42         mkFunTy, mkFunTys, splitFunTy, splitFunTy_maybe,
  43         splitFunTys, splitFunTysN,
  44         funResultTy, funArgTy, zipFunTys, isFunTy,
  45
  46         mkTyConApp, mkTyConTy,
  47         tyConAppTyCon, tyConAppArgs,
  48         splitTyConApp_maybe, splitTyConApp,
  49         splitNewTyConApp_maybe, splitNewTyConApp,
  50
  51         repType, repType', typePrimRep, coreView, tcView, kindView,
  52
  53         mkForAllTy, mkForAllTys, splitForAllTy_maybe, splitForAllTys,
  54         applyTy, applyTys, isForAllTy, dropForAlls,
  55
  56         -- Source types
  57         predTypeRep, mkPredTy, mkPredTys,
  58         tyConOrigHead, pprSourceTyCon,
  59
  60         -- Newtypes
  61         splitRecNewType_maybe, newTyConInstRhs,
  62
  63         -- Lifting and boxity
  64         isUnLiftedType, isUnboxedTupleType, isAlgType, isPrimitiveType,
  65         isStrictType, isStrictPred,
  66
  67         -- Free variables
  68         tyVarsOfType, tyVarsOfTypes, tyVarsOfPred, tyVarsOfTheta,
  69         typeKind, addFreeTyVars,
  70
  71         -- Tidying up for printing
  72         tidyType,      tidyTypes,
  73         tidyOpenType,  tidyOpenTypes,
  74         tidyTyVarBndr, tidyFreeTyVars,
  75         tidyOpenTyVar, tidyOpenTyVars,
  76         tidyTopType,   tidyPred,
  77         tidyKind,
  78
  79         -- Comparison
  80         coreEqType, tcEqType, tcEqTypes, tcCmpType, tcCmpTypes,
  81         tcEqPred, tcCmpPred, tcEqTypeX,
  82
  83         -- Seq
  84         seqType, seqTypes,
  85
  86         -- Type substitutions
  87         TvSubstEnv, emptyTvSubstEnv,    -- Representation widely visible
  88         TvSubst(..), emptyTvSubst,      -- Representation visible to a few friends
  89         mkTvSubst, mkOpenTvSubst, zipOpenTvSubst, zipTopTvSubst, mkTopTvSubst, notElemTvSubst,
  90         getTvSubstEnv, setTvSubstEnv, getTvInScope, extendTvInScope,
  91         extendTvSubst, extendTvSubstList, isInScope, composeTvSubst, zipTyEnv,
  92
  93         -- Performing substitution on types
  94         substTy, substTys, substTyWith, substTheta,
  95         substPred, substTyVar, substTyVars, substTyVarBndr, deShadowTy, lookupTyVar,
  96
  97         -- Pretty-printing
  98         pprType, pprParendType, pprTypeApp, pprTyThingCategory, pprForAll,
  99         pprPred, pprTheta, pprThetaArrow, pprClassPred, pprKind, pprParendKind
 100     ) where
 101
 102 #include "HsVersions.h"
 103
 104 -- We import the representation and primitive functions from TypeRep.
 105 -- Many things are reexported, but not the representation!
 106
 107 import TypeRep
 108
 109 -- friends:
 110 import Var
 111 import VarEnv
 112 import VarSet
 113
 114 import Name
 115 import Class
 116 import PrelNames
 117 import TyCon
 118
 119 -- others
 120 import StaticFlags
 121 import Util
 122 import Outputable
 123 import UniqSet
 124
 125 import Data.Maybe       ( isJust )
 126 \end{code}
 127
 128
 129 %************************************************************************
 130 %*                                                                      *
 131                 Type representation
 132 %*                                                                      *
 133 %************************************************************************
 134
 135 In Core, we "look through" non-recursive newtypes and PredTypes.
 136
 137 \begin{code}
 138 {-# INLINE coreView #-}
 139 coreView :: Type -> Maybe Type
 140 -- Strips off the *top layer only* of a type to give
 141 -- its underlying representation type.
 142 -- Returns Nothing if there is nothing to look through.
 143 --
 144 -- In the case of newtypes, it returns
 145 --      *either* a vanilla TyConApp (recursive newtype, or non-saturated)
 146 --      *or*     the newtype representation (otherwise), meaning the
 147 --                      type written in the RHS of the newtype decl,
 148 --                      which may itself be a newtype
 149 --
 150 -- Example: newtype R = MkR S
 151 --          newtype S = MkS T
 152 --          newtype T = MkT (T -> T)
 153 --   expandNewTcApp on R gives Just S
 154 --                  on S gives Just T
 155 --                  on T gives Nothing   (no expansion)
 156
 157 -- By being non-recursive and inlined, this case analysis gets efficiently
 158 -- joined onto the case analysis that the caller is already doing
 159 coreView (NoteTy _ ty)     = Just ty
 160 coreView (PredTy p)
 161   | isEqPred p             = Nothing
 162   | otherwise              = Just (predTypeRep p)
 163 coreView (TyConApp tc tys) | Just (tenv, rhs, tys') <- coreExpandTyCon_maybe tc tys
 164                            = Just (mkAppTys (substTy (mkTopTvSubst tenv) rhs) tys')
 165                                 -- Its important to use mkAppTys, rather than (foldl AppTy),
 166                                 -- because the function part might well return a
 167                                 -- partially-applied type constructor; indeed, usually will!
 168 coreView ty                = Nothing
 169
 170
 171
 172 -----------------------------------------------
 173 {-# INLINE tcView #-}
 174 tcView :: Type -> Maybe Type
 175 -- Same, but for the type checker, which just looks through synonyms
 176 tcView (NoteTy _ ty)     = Just ty
 177 tcView (TyConApp tc tys) | Just (tenv, rhs, tys') <- tcExpandTyCon_maybe tc tys
 178                          = Just (mkAppTys (substTy (mkTopTvSubst tenv) rhs) tys')
 179 tcView ty                = Nothing
 180
 181 -----------------------------------------------
 182 {-# INLINE kindView #-}
 183 kindView :: Kind -> Maybe Kind
 184 -- C.f. coreView, tcView
 185 -- For the moment, we don't even handle synonyms in kinds
 186 kindView (NoteTy _ k) = Just k
 187 kindView other        = Nothing
 188 \end{code}
 189
 190
 191 %************************************************************************
 192 %*                                                                      *
 193 \subsection{Constructor-specific functions}
 194 %*                                                                      *
 195 %************************************************************************
 196
 197
 198 ---------------------------------------------------------------------
 199                                 TyVarTy
 200                                 ~~~~~~~
 201 \begin{code}
 202 mkTyVarTy  :: TyVar   -> Type
 203 mkTyVarTy  = TyVarTy
 204
 205 mkTyVarTys :: [TyVar] -> [Type]
 206 mkTyVarTys = map mkTyVarTy -- a common use of mkTyVarTy
 207
 208 getTyVar :: String -> Type -> TyVar
 209 getTyVar msg ty = case getTyVar_maybe ty of
 210                     Just tv -> tv
 211                     Nothing -> panic ("getTyVar: " ++ msg)
 212
 213 isTyVarTy :: Type -> Bool
 214 isTyVarTy ty = isJust (getTyVar_maybe ty)
 215
 216 getTyVar_maybe :: Type -> Maybe TyVar
 217 getTyVar_maybe ty | Just ty' <- coreView ty = getTyVar_maybe ty'
 218 getTyVar_maybe (TyVarTy tv)                 = Just tv
 219 getTyVar_maybe other                        = Nothing
 220
 221 \end{code}
 222
 223
 224 ---------------------------------------------------------------------
 225                                 AppTy
 226                                 ~~~~~
 227 We need to be pretty careful with AppTy to make sure we obey the
 228 invariant that a TyConApp is always visibly so.  mkAppTy maintains the
 229 invariant: use it.
 230
 231 \begin{code}
 232 mkAppTy orig_ty1 orig_ty2
 233   = mk_app orig_ty1
 234   where
 235     mk_app (NoteTy _ ty1)    = mk_app ty1
 236     mk_app (TyConApp tc tys) = mkTyConApp tc (tys ++ [orig_ty2])
 237     mk_app ty1               = AppTy orig_ty1 orig_ty2
 238         -- Note that the TyConApp could be an
 239         -- under-saturated type synonym.  GHC allows that; e.g.
 240         --      type Foo k = k a -> k a
 241         --      type Id x = x
 242         --      foo :: Foo Id -> Foo Id
 243         --
 244         -- Here Id is partially applied in the type sig for Foo,
 245         -- but once the type synonyms are expanded all is well
 246
 247 mkAppTys :: Type -> [Type] -> Type
 248 mkAppTys orig_ty1 []        = orig_ty1
 249         -- This check for an empty list of type arguments
 250         -- avoids the needless loss of a type synonym constructor.
 251         -- For example: mkAppTys Rational []
 252         --   returns to (Ratio Integer), which has needlessly lost
 253         --   the Rational part.
 254 mkAppTys orig_ty1 orig_tys2
 255   = mk_app orig_ty1
 256   where
 257     mk_app (NoteTy _ ty1)    = mk_app ty1
 258     mk_app (TyConApp tc tys) = mkTyConApp tc (tys ++ orig_tys2)
 259                                 -- mkTyConApp: see notes with mkAppTy
 260     mk_app ty1               = foldl AppTy orig_ty1 orig_tys2
 261
 262 -------------
 263 splitAppTy_maybe :: Type -> Maybe (Type, Type)
 264 splitAppTy_maybe ty | Just ty' <- coreView ty
 265                     = splitAppTy_maybe ty'
 266 splitAppTy_maybe ty = repSplitAppTy_maybe ty
 267
 268 -------------
 269 repSplitAppTy_maybe :: Type -> Maybe (Type,Type)
 270 -- Does the AppTy split, but assumes that any view stuff is already done
 271 repSplitAppTy_maybe (FunTy ty1 ty2)   = Just (TyConApp funTyCon [ty1], ty2)
 272 repSplitAppTy_maybe (AppTy ty1 ty2)   = Just (ty1, ty2)
 273 repSplitAppTy_maybe (TyConApp tc tys) = case snocView tys of
 274                                                 Just (tys', ty') -> Just (TyConApp tc tys', ty')
 275                                                 Nothing          -> Nothing
 276 repSplitAppTy_maybe other = Nothing
 277 -------------
 278 splitAppTy :: Type -> (Type, Type)
 279 splitAppTy ty = case splitAppTy_maybe ty of
 280                         Just pr -> pr
 281                         Nothing -> panic "splitAppTy"
 282
 283 -------------
 284 splitAppTys :: Type -> (Type, [Type])
 285 splitAppTys ty = split ty ty []
 286   where
 287     split orig_ty ty args | Just ty' <- coreView ty = split orig_ty ty' args
 288     split orig_ty (AppTy ty arg)        args = split ty ty (arg:args)
 289     split orig_ty (TyConApp tc tc_args) args = (TyConApp tc [], tc_args ++ args)
 290     split orig_ty (FunTy ty1 ty2)       args = ASSERT( null args )
 291                                                (TyConApp funTyCon [], [ty1,ty2])
 292     split orig_ty ty                    args = (orig_ty, args)
 293
 294 \end{code}
 295
 296
 297 ---------------------------------------------------------------------
 298                                 FunTy
 299                                 ~~~~~
 300
 301 \begin{code}
 302 mkFunTy :: Type -> Type -> Type
 303 mkFunTy (PredTy (EqPred ty1 ty2)) res = mkForAllTy (mkWildCoVar (PredTy (EqPred ty1 ty2))) res
 304 mkFunTy arg res = FunTy arg res
 305
 306 mkFunTys :: [Type] -> Type -> Type
 307 mkFunTys tys ty = foldr mkFunTy ty tys
 308
 309 isFunTy :: Type -> Bool
 310 isFunTy ty = isJust (splitFunTy_maybe ty)
 311
 312 splitFunTy :: Type -> (Type, Type)
 313 splitFunTy ty | Just ty' <- coreView ty = splitFunTy ty'
 314 splitFunTy (FunTy arg res)   = (arg, res)
 315 splitFunTy other             = pprPanic "splitFunTy" (ppr other)
 316
 317 splitFunTy_maybe :: Type -> Maybe (Type, Type)
 318 splitFunTy_maybe ty | Just ty' <- coreView ty = splitFunTy_maybe ty'
 319 splitFunTy_maybe (FunTy arg res)   = Just (arg, res)
 320 splitFunTy_maybe other             = Nothing
 321
 322 splitFunTys :: Type -> ([Type], Type)
 323 splitFunTys ty = split [] ty ty
 324   where
 325     split args orig_ty ty | Just ty' <- coreView ty = split args orig_ty ty'
 326     split args orig_ty (FunTy arg res)   = split (arg:args) res res
 327     split args orig_ty ty                = (reverse args, orig_ty)
 328
 329 splitFunTysN :: Int -> Type -> ([Type], Type)
 330 -- Split off exactly n arg tys
 331 splitFunTysN 0 ty = ([], ty)
 332 splitFunTysN n ty = case splitFunTy ty of { (arg, res) ->
 333                     case splitFunTysN (n-1) res of { (args, res) ->
 334                     (arg:args, res) }}
 335
 336 zipFunTys :: Outputable a => [a] -> Type -> ([(a,Type)], Type)
 337 zipFunTys orig_xs orig_ty = split [] orig_xs orig_ty orig_ty
 338   where
 339     split acc []     nty ty                = (reverse acc, nty)
 340     split acc xs     nty ty
 341           | Just ty' <- coreView ty        = split acc xs nty ty'
 342     split acc (x:xs) nty (FunTy arg res)   = split ((x,arg):acc) xs res res
 343     split acc (x:xs) nty ty                = pprPanic "zipFunTys" (ppr orig_xs <+> ppr orig_ty)
 344
 345 funResultTy :: Type -> Type
 346 funResultTy ty | Just ty' <- coreView ty = funResultTy ty'
 347 funResultTy (FunTy arg res)   = res
 348 funResultTy ty                = pprPanic "funResultTy" (ppr ty)
 349
 350 funArgTy :: Type -> Type
 351 funArgTy ty | Just ty' <- coreView ty = funArgTy ty'
 352 funArgTy (FunTy arg res)   = arg
 353 funArgTy ty                = pprPanic "funArgTy" (ppr ty)
 354 \end{code}
 355
 356
 357 ---------------------------------------------------------------------
 358                                 TyConApp
 359                                 ~~~~~~~~
 360 @mkTyConApp@ is a key function, because it builds a TyConApp, FunTy or PredTy,
 361 as apppropriate.
 362
 363 \begin{code}
 364 mkTyConApp :: TyCon -> [Type] -> Type
 365 mkTyConApp tycon tys
 366   | isFunTyCon tycon, [ty1,ty2] <- tys
 367   = FunTy ty1 ty2
 368
 369   | otherwise
 370   = TyConApp tycon tys
 371
 372 mkTyConTy :: TyCon -> Type
 373 mkTyConTy tycon = mkTyConApp tycon []
 374
 375 -- splitTyConApp "looks through" synonyms, because they don't
 376 -- mean a distinct type, but all other type-constructor applications
 377 -- including functions are returned as Just ..
 378
 379 tyConAppTyCon :: Type -> TyCon
 380 tyConAppTyCon ty = fst (splitTyConApp ty)
 381
 382 tyConAppArgs :: Type -> [Type]
 383 tyConAppArgs ty = snd (splitTyConApp ty)
 384
 385 splitTyConApp :: Type -> (TyCon, [Type])
 386 splitTyConApp ty = case splitTyConApp_maybe ty of
 387                         Just stuff -> stuff
 388                         Nothing    -> pprPanic "splitTyConApp" (ppr ty)
 389
 390 splitTyConApp_maybe :: Type -> Maybe (TyCon, [Type])
 391 splitTyConApp_maybe ty | Just ty' <- coreView ty = splitTyConApp_maybe ty'
 392 splitTyConApp_maybe (TyConApp tc tys) = Just (tc, tys)
 393 splitTyConApp_maybe (FunTy arg res)   = Just (funTyCon, [arg,res])
 394 splitTyConApp_maybe other             = Nothing
 395
 396 -- Sometimes we do NOT want to look throught a newtype.  When case matching
 397 -- on a newtype we want a convenient way to access the arguments of a newty
 398 -- constructor so as to properly form a coercion.
 399 splitNewTyConApp :: Type -> (TyCon, [Type])
 400 splitNewTyConApp ty = case splitNewTyConApp_maybe ty of
 401                         Just stuff -> stuff
 402                         Nothing    -> pprPanic "splitNewTyConApp" (ppr ty)
 403 splitNewTyConApp_maybe :: Type -> Maybe (TyCon, [Type])
 404 splitNewTyConApp_maybe ty | Just ty' <- tcView ty = splitNewTyConApp_maybe ty'
 405 splitNewTyConApp_maybe (TyConApp tc tys) = Just (tc, tys)
 406 splitNewTyConApp_maybe (FunTy arg res)   = Just (funTyCon, [arg,res])
 407 splitNewTyConApp_maybe other          = Nothing
 408
 409 -- get instantiated newtype rhs, the arguments had better saturate
 410 -- the constructor
 411 newTyConInstRhs :: TyCon -> [Type] -> Type
 412 newTyConInstRhs tycon tys =
 413     let (tvs, ty) = newTyConRhs tycon in substTyWith tvs tys ty
 414 \end{code}
 415
 416
 417 ---------------------------------------------------------------------
 418                                 SynTy
 419                                 ~~~~~
 420
 421 Notes on type synonyms
 422 ~~~~~~~~~~~~~~~~~~~~~~
 423 The various "split" functions (splitFunTy, splitRhoTy, splitForAllTy) try
 424 to return type synonyms whereever possible. Thus
 425
 426         type Foo a = a -> a
 427
 428 we want
 429         splitFunTys (a -> Foo a) = ([a], Foo a)
 430 not                                ([a], a -> a)
 431
 432 The reason is that we then get better (shorter) type signatures in
 433 interfaces.  Notably this plays a role in tcTySigs in TcBinds.lhs.
 434
 435
 436                 Representation types
 437                 ~~~~~~~~~~~~~~~~~~~~
 438 repType looks through
 439         (a) for-alls, and
 440         (b) synonyms
 441         (c) predicates
 442         (d) usage annotations
 443         (e) all newtypes, including recursive ones, but not newtype families
 444 It's useful in the back end.
 445
 446 \begin{code}
 447 repType :: Type -> Type
 448 -- Only applied to types of kind *; hence tycons are saturated
 449 repType ty | Just ty' <- coreView ty = repType ty'
 450 repType (ForAllTy _ ty)  = repType ty
 451 repType (TyConApp tc tys)
 452   | isClosedNewTyCon tc  = -- Recursive newtypes are opaque to coreView
 453                            -- but we must expand them here.  Sure to
 454                            -- be saturated because repType is only applied
 455                            -- to types of kind *
 456                            ASSERT( {- isRecursiveTyCon tc && -} tys `lengthIs` tyConArity tc )
 457                            repType (new_type_rep tc tys)
 458 repType ty = ty
 459
 460 -- repType' aims to be a more thorough version of repType
 461 -- For now it simply looks through the TyConApp args too
 462 repType' ty -- | pprTrace "repType'" (ppr ty $$ ppr (go1 ty)) False = undefined
 463             | otherwise = go1 ty
 464  where
 465         go1 = go . repType
 466         go (TyConApp tc tys) = mkTyConApp tc (map repType' tys)
 467         go ty = ty
 468
 469
 470 -- new_type_rep doesn't ask any questions:
 471 -- it just expands newtype, whether recursive or not
 472 new_type_rep new_tycon tys = ASSERT( tys `lengthIs` tyConArity new_tycon )
 473                              case newTyConRep new_tycon of
 474                                  (tvs, rep_ty) -> substTyWith tvs tys rep_ty
 475
 476 -- ToDo: this could be moved to the code generator, using splitTyConApp instead
 477 -- of inspecting the type directly.
 478 typePrimRep :: Type -> PrimRep
 479 typePrimRep ty = case repType ty of
 480                    TyConApp tc _ -> tyConPrimRep tc
 481                    FunTy _ _     -> PtrRep
 482                    AppTy _ _     -> PtrRep      -- See note below
 483                    TyVarTy _     -> PtrRep
 484                    other         -> pprPanic "typePrimRep" (ppr ty)
 485         -- Types of the form 'f a' must be of kind *, not *#, so
 486         -- we are guaranteed that they are represented by pointers.
 487         -- The reason is that f must have kind *->*, not *->*#, because
 488         -- (we claim) there is no way to constrain f's kind any other
 489         -- way.
 490
 491 \end{code}
 492
 493
 494 ---------------------------------------------------------------------
 495                                 ForAllTy
 496                                 ~~~~~~~~
 497
 498 \begin{code}
 499 mkForAllTy :: TyVar -> Type -> Type
 500 mkForAllTy tyvar ty
 501   = mkForAllTys [tyvar] ty
 502
 503 mkForAllTys :: [TyVar] -> Type -> Type
 504 mkForAllTys tyvars ty = foldr ForAllTy ty tyvars
 505
 506 isForAllTy :: Type -> Bool
 507 isForAllTy (NoteTy _ ty)  = isForAllTy ty
 508 isForAllTy (ForAllTy _ _) = True
 509 isForAllTy other_ty       = False
 510
 511 splitForAllTy_maybe :: Type -> Maybe (TyVar, Type)
 512 splitForAllTy_maybe ty = splitFAT_m ty
 513   where
 514     splitFAT_m ty | Just ty' <- coreView ty = splitFAT_m ty'
 515     splitFAT_m (ForAllTy tyvar ty)          = Just(tyvar, ty)
 516     splitFAT_m _                            = Nothing
 517
 518 splitForAllTys :: Type -> ([TyVar], Type)
 519 splitForAllTys ty = split ty ty []
 520    where
 521      split orig_ty ty tvs | Just ty' <- coreView ty = split orig_ty ty' tvs
 522      split orig_ty (ForAllTy tv ty)  tvs = split ty ty (tv:tvs)
 523      split orig_ty t                 tvs = (reverse tvs, orig_ty)
 524
 525 dropForAlls :: Type -> Type
 526 dropForAlls ty = snd (splitForAllTys ty)
 527 \end{code}
 528
 529 -- (mkPiType now in CoreUtils)
 530
 531 applyTy, applyTys
 532 ~~~~~~~~~~~~~~~~~
 533 Instantiate a for-all type with one or more type arguments.
 534 Used when we have a polymorphic function applied to type args:
 535         f t1 t2
 536 Then we use (applyTys type-of-f [t1,t2]) to compute the type of
 537 the expression.
 538
 539 \begin{code}
 540 applyTy :: Type -> Type -> Type
 541 applyTy ty arg | Just ty' <- coreView ty = applyTy ty' arg
 542 applyTy (ForAllTy tv ty) arg = substTyWith [tv] [arg] ty
 543 applyTy other            arg = panic "applyTy"
 544
 545 applyTys :: Type -> [Type] -> Type
 546 -- This function is interesting because
 547 --      a) the function may have more for-alls than there are args
 548 --      b) less obviously, it may have fewer for-alls
 549 -- For case (b) think of
 550 --      applyTys (forall a.a) [forall b.b, Int]
 551 -- This really can happen, via dressing up polymorphic types with newtype
 552 -- clothing.  Here's an example:
 553 --      newtype R = R (forall a. a->a)
 554 --      foo = case undefined :: R of
 555 --              R f -> f ()
 556
 557 applyTys orig_fun_ty []      = orig_fun_ty
 558 applyTys orig_fun_ty arg_tys
 559   | n_tvs == n_args     -- The vastly common case
 560   = substTyWith tvs arg_tys rho_ty
 561   | n_tvs > n_args      -- Too many for-alls
 562   = substTyWith (take n_args tvs) arg_tys
 563                 (mkForAllTys (drop n_args tvs) rho_ty)
 564   | otherwise           -- Too many type args
 565   = ASSERT2( n_tvs > 0, ppr orig_fun_ty )       -- Zero case gives infnite loop!
 566     applyTys (substTyWith tvs (take n_tvs arg_tys) rho_ty)
 567              (drop n_tvs arg_tys)
 568   where
 569     (tvs, rho_ty) = splitForAllTys orig_fun_ty
 570     n_tvs = length tvs
 571     n_args = length arg_tys
 572 \end{code}
 573
 574
 575 %************************************************************************
 576 %*                                                                      *
 577 \subsection{Source types}
 578 %*                                                                      *
 579 %************************************************************************
 580
 581 A "source type" is a type that is a separate type as far as the type checker is
 582 concerned, but which has low-level representation as far as the back end is concerned.
 583
 584 Source types are always lifted.
 585
 586 The key function is predTypeRep which gives the representation of a source type:
 587
 588 \begin{code}
 589 mkPredTy :: PredType -> Type
 590 mkPredTy pred = PredTy pred
 591
 592 mkPredTys :: ThetaType -> [Type]
 593 mkPredTys preds = map PredTy preds
 594
 595 predTypeRep :: PredType -> Type
 596 -- Convert a PredType to its "representation type";
 597 -- the post-type-checking type used by all the Core passes of GHC.
 598 -- Unwraps only the outermost level; for example, the result might
 599 -- be a newtype application
 600 predTypeRep (IParam _ ty)     = ty
 601 predTypeRep (ClassP clas tys) = mkTyConApp (classTyCon clas) tys
 602         -- Result might be a newtype application, but the consumer will
 603         -- look through that too if necessary
 604 predTypeRep (EqPred ty1 ty2) = pprPanic "predTypeRep" (ppr (EqPred ty1 ty2))
 605
 606 -- The original head is the tycon and its variables for a vanilla tycon and it
 607 -- is the family tycon and its type indexes for a family instance.
 608 tyConOrigHead :: TyCon -> (TyCon, [Type])
 609 tyConOrigHead tycon = case tyConFamInst_maybe tycon of
 610                         Nothing      -> (tycon, mkTyVarTys (tyConTyVars tycon))
 611                         Just famInst -> famInst
 612
 613 -- Pretty prints a tycon, using the family instance in case of a
 614 -- representation tycon.  For example
 615 --      e.g.  data T [a] = ...
 616 -- In that case we want to print `T [a]', where T is the family TyCon
 617 pprSourceTyCon tycon
 618   | Just (repTyCon, tys) <- tyConFamInst_maybe tycon
 619   = ppr $ repTyCon `TyConApp` tys              -- can't be FunTyCon
 620   | otherwise
 621   = ppr tycon
 622 \end{code}
 623
 624
 625 %************************************************************************
 626 %*                                                                      *
 627                 NewTypes
 628 %*                                                                      *
 629 %************************************************************************
 630
 631 \begin{code}
 632 splitRecNewType_maybe :: Type -> Maybe Type
 633 -- Sometimes we want to look through a recursive newtype, and that's what happens here
 634 -- It only strips *one layer* off, so the caller will usually call itself recursively
 635 -- Only applied to types of kind *, hence the newtype is always saturated
 636 splitRecNewType_maybe ty | Just ty' <- coreView ty = splitRecNewType_maybe ty'
 637 splitRecNewType_maybe (TyConApp tc tys)
 638   | isClosedNewTyCon tc
 639   = ASSERT( tys `lengthIs` tyConArity tc )      -- splitRecNewType_maybe only be applied
 640                                                 --      to *types* (of kind *)
 641     ASSERT( isRecursiveTyCon tc )               -- Guaranteed by coreView
 642     case newTyConRhs tc of
 643         (tvs, rep_ty) -> ASSERT( length tvs == length tys )
 644                          Just (substTyWith tvs tys rep_ty)
 645
 646 splitRecNewType_maybe other = Nothing
 647
 648
 649
 650 \end{code}
 651
 652
 653 %************************************************************************
 654 %*                                                                      *
 655 \subsection{Kinds and free variables}
 656 %*                                                                      *
 657 %************************************************************************
 658
 659 ---------------------------------------------------------------------
 660                 Finding the kind of a type
 661                 ~~~~~~~~~~~~~~~~~~~~~~~~~~
 662 \begin{code}
 663 typeKind :: Type -> Kind
 664 typeKind (TyConApp tycon tys) = ASSERT( not (isCoercionTyCon tycon) )
 665                                    -- We should be looking for the coercion kind,
 666                                    -- not the type kind
 667                                 foldr (\_ k -> kindFunResult k) (tyConKind tycon) tys
 668 typeKind (NoteTy _ ty)        = typeKind ty
 669 typeKind (PredTy pred)        = predKind pred
 670 typeKind (AppTy fun arg)      = kindFunResult (typeKind fun)
 671 typeKind (ForAllTy tv ty)     = typeKind ty
 672 typeKind (TyVarTy tyvar)      = tyVarKind tyvar
 673 typeKind (FunTy arg res)
 674     -- Hack alert.  The kind of (Int -> Int#) is liftedTypeKind (*),
 675     --              not unliftedTypKind (#)
 676     -- The only things that can be after a function arrow are
 677     --   (a) types (of kind openTypeKind or its sub-kinds)
 678     --   (b) kinds (of super-kind TY) (e.g. * -> (* -> *))
 679     | isTySuperKind k         = k
 680     | otherwise               = ASSERT( isSubOpenTypeKind k) liftedTypeKind
 681     where
 682       k = typeKind res
 683
 684 predKind :: PredType -> Kind
 685 predKind (EqPred {}) = coSuperKind      -- A coercion kind!
 686 predKind (ClassP {}) = liftedTypeKind   -- Class and implicitPredicates are
 687 predKind (IParam {}) = liftedTypeKind   -- always represented by lifted types
 688 \end{code}
 689
 690
 691 ---------------------------------------------------------------------
 692                 Free variables of a type
 693                 ~~~~~~~~~~~~~~~~~~~~~~~~
 694 \begin{code}
 695 tyVarsOfType :: Type -> TyVarSet
 696 -- NB: for type synonyms tyVarsOfType does *not* expand the synonym
 697 tyVarsOfType (TyVarTy tv)               = unitVarSet tv
 698 tyVarsOfType (TyConApp tycon tys)       = tyVarsOfTypes tys
 699 tyVarsOfType (NoteTy (FTVNote tvs) ty2) = tvs
 700 tyVarsOfType (PredTy sty)               = tyVarsOfPred sty
 701 tyVarsOfType (FunTy arg res)            = tyVarsOfType arg `unionVarSet` tyVarsOfType res
 702 tyVarsOfType (AppTy fun arg)            = tyVarsOfType fun `unionVarSet` tyVarsOfType arg
 703 tyVarsOfType (ForAllTy tyvar ty)        = delVarSet (tyVarsOfType ty) tyvar
 704
 705 tyVarsOfTypes :: [Type] -> TyVarSet
 706 tyVarsOfTypes tys = foldr (unionVarSet.tyVarsOfType) emptyVarSet tys
 707
 708 tyVarsOfPred :: PredType -> TyVarSet
 709 tyVarsOfPred (IParam _ ty)    = tyVarsOfType ty
 710 tyVarsOfPred (ClassP _ tys)   = tyVarsOfTypes tys
 711 tyVarsOfPred (EqPred ty1 ty2) = tyVarsOfType ty1 `unionVarSet` tyVarsOfType ty2
 712
 713 tyVarsOfTheta :: ThetaType -> TyVarSet
 714 tyVarsOfTheta = foldr (unionVarSet . tyVarsOfPred) emptyVarSet
 715
 716 -- Add a Note with the free tyvars to the top of the type
 717 addFreeTyVars :: Type -> Type
 718 addFreeTyVars ty@(NoteTy (FTVNote _) _)      = ty
 719 addFreeTyVars ty                             = NoteTy (FTVNote (tyVarsOfType ty)) ty
 720 \end{code}
 721
 722
 723 %************************************************************************
 724 %*                                                                      *
 725 \subsection{TidyType}
 726 %*                                                                      *
 727 %************************************************************************
 728
 729 tidyTy tidies up a type for printing in an error message, or in
 730 an interface file.
 731
 732 It doesn't change the uniques at all, just the print names.
 733
 734 \begin{code}
 735 tidyTyVarBndr :: TidyEnv -> TyVar -> (TidyEnv, TyVar)
 736 tidyTyVarBndr (tidy_env, subst) tyvar
 737   = case tidyOccName tidy_env (getOccName name) of
 738       (tidy', occ') ->  ((tidy', subst'), tyvar')
 739                     where
 740                         subst' = extendVarEnv subst tyvar tyvar'
 741                         tyvar' = setTyVarName tyvar name'
 742                         name'  = tidyNameOcc name occ'
 743   where
 744     name = tyVarName tyvar
 745
 746 tidyFreeTyVars :: TidyEnv -> TyVarSet -> TidyEnv
 747 -- Add the free tyvars to the env in tidy form,
 748 -- so that we can tidy the type they are free in
 749 tidyFreeTyVars env tyvars = fst (tidyOpenTyVars env (varSetElems tyvars))
 750
 751 tidyOpenTyVars :: TidyEnv -> [TyVar] -> (TidyEnv, [TyVar])
 752 tidyOpenTyVars env tyvars = mapAccumL tidyOpenTyVar env tyvars
 753
 754 tidyOpenTyVar :: TidyEnv -> TyVar -> (TidyEnv, TyVar)
 755 -- Treat a new tyvar as a binder, and give it a fresh tidy name
 756 tidyOpenTyVar env@(tidy_env, subst) tyvar
 757   = case lookupVarEnv subst tyvar of
 758         Just tyvar' -> (env, tyvar')            -- Already substituted
 759         Nothing     -> tidyTyVarBndr env tyvar  -- Treat it as a binder
 760
 761 tidyType :: TidyEnv -> Type -> Type
 762 tidyType env@(tidy_env, subst) ty
 763   = go ty
 764   where
 765     go (TyVarTy tv)         = case lookupVarEnv subst tv of
 766                                 Nothing  -> TyVarTy tv
 767                                 Just tv' -> TyVarTy tv'
 768     go (TyConApp tycon tys) = let args = map go tys
 769                               in args `seqList` TyConApp tycon args
 770     go (NoteTy note ty)     = (NoteTy $! (go_note note)) $! (go ty)
 771     go (PredTy sty)         = PredTy (tidyPred env sty)
 772     go (AppTy fun arg)      = (AppTy $! (go fun)) $! (go arg)
 773     go (FunTy fun arg)      = (FunTy $! (go fun)) $! (go arg)
 774     go (ForAllTy tv ty)     = ForAllTy tvp $! (tidyType envp ty)
 775                               where
 776                                 (envp, tvp) = tidyTyVarBndr env tv
 777
 778     go_note note@(FTVNote ftvs) = note  -- No need to tidy the free tyvars
 779
 780 tidyTypes env tys = map (tidyType env) tys
 781
 782 tidyPred :: TidyEnv -> PredType -> PredType
 783 tidyPred env (IParam n ty)     = IParam n (tidyType env ty)
 784 tidyPred env (ClassP clas tys) = ClassP clas (tidyTypes env tys)
 785 tidyPred env (EqPred ty1 ty2)  = EqPred (tidyType env ty1) (tidyType env ty2)
 786 \end{code}
 787
 788
 789 @tidyOpenType@ grabs the free type variables, tidies them
 790 and then uses @tidyType@ to work over the type itself
 791
 792 \begin{code}
 793 tidyOpenType :: TidyEnv -> Type -> (TidyEnv, Type)
 794 tidyOpenType env ty
 795   = (env', tidyType env' ty)
 796   where
 797     env' = tidyFreeTyVars env (tyVarsOfType ty)
 798
 799 tidyOpenTypes :: TidyEnv -> [Type] -> (TidyEnv, [Type])
 800 tidyOpenTypes env tys = mapAccumL tidyOpenType env tys
 801
 802 tidyTopType :: Type -> Type
 803 tidyTopType ty = tidyType emptyTidyEnv ty
 804 \end{code}
 805
 806 \begin{code}
 807
 808 tidyKind :: TidyEnv -> Kind -> (TidyEnv, Kind)
 809 tidyKind env k = tidyOpenType env k
 810
 811 \end{code}
 812
 813
 814 %************************************************************************
 815 %*                                                                      *
 816 \subsection{Liftedness}
 817 %*                                                                      *
 818 %************************************************************************
 819
 820 \begin{code}
 821 isUnLiftedType :: Type -> Bool
 822         -- isUnLiftedType returns True for forall'd unlifted types:
 823         --      x :: forall a. Int#
 824         -- I found bindings like these were getting floated to the top level.
 825         -- They are pretty bogus types, mind you.  It would be better never to
 826         -- construct them
 827
 828 isUnLiftedType ty | Just ty' <- coreView ty = isUnLiftedType ty'
 829 isUnLiftedType (ForAllTy tv ty)  = isUnLiftedType ty
 830 isUnLiftedType (TyConApp tc _)   = isUnLiftedTyCon tc
 831 isUnLiftedType other             = False
 832
 833 isUnboxedTupleType :: Type -> Bool
 834 isUnboxedTupleType ty = case splitTyConApp_maybe ty of
 835                            Just (tc, ty_args) -> isUnboxedTupleTyCon tc
 836                            other              -> False
 837
 838 -- Should only be applied to *types*; hence the assert
 839 isAlgType :: Type -> Bool
 840 isAlgType ty = case splitTyConApp_maybe ty of
 841                         Just (tc, ty_args) -> ASSERT( ty_args `lengthIs` tyConArity tc )
 842                                               isAlgTyCon tc
 843                         other              -> False
 844 \end{code}
 845
 846 @isStrictType@ computes whether an argument (or let RHS) should
 847 be computed strictly or lazily, based only on its type.
 848 Works just like isUnLiftedType, except that it has a special case
 849 for dictionaries.  Since it takes account of ClassP, you might think
 850 this function should be in TcType, but isStrictType is used by DataCon,
 851 which is below TcType in the hierarchy, so it's convenient to put it here.
 852
 853 \begin{code}
 854 isStrictType (PredTy pred)     = isStrictPred pred
 855 isStrictType ty | Just ty' <- coreView ty = isStrictType ty'
 856 isStrictType (ForAllTy tv ty)  = isStrictType ty
 857 isStrictType (TyConApp tc _)   = isUnLiftedTyCon tc
 858 isStrictType other             = False
 859
 860 isStrictPred (ClassP clas _) = opt_DictsStrict && not (isNewTyCon (classTyCon clas))
 861 isStrictPred other           = False
 862         -- We may be strict in dictionary types, but only if it
 863         -- has more than one component.
 864         -- [Being strict in a single-component dictionary risks
 865         --  poking the dictionary component, which is wrong.]
 866 \end{code}
 867
 868 \begin{code}
 869 isPrimitiveType :: Type -> Bool
 870 -- Returns types that are opaque to Haskell.
 871 -- Most of these are unlifted, but now that we interact with .NET, we
 872 -- may have primtive (foreign-imported) types that are lifted
 873 isPrimitiveType ty = case splitTyConApp_maybe ty of
 874                         Just (tc, ty_args) -> ASSERT( ty_args `lengthIs` tyConArity tc )
 875                                               isPrimTyCon tc
 876                         other              -> False
 877 \end{code}
 878
 879
 880 %************************************************************************
 881 %*                                                                      *
 882 \subsection{Sequencing on types
 883 %*                                                                      *
 884 %************************************************************************
 885
 886 \begin{code}
 887 seqType :: Type -> ()
 888 seqType (TyVarTy tv)      = tv `seq` ()
 889 seqType (AppTy t1 t2)     = seqType t1 `seq` seqType t2
 890 seqType (FunTy t1 t2)     = seqType t1 `seq` seqType t2
 891 seqType (NoteTy note t2)  = seqNote note `seq` seqType t2
 892 seqType (PredTy p)        = seqPred p
 893 seqType (TyConApp tc tys) = tc `seq` seqTypes tys
 894 seqType (ForAllTy tv ty)  = tv `seq` seqType ty
 895
 896 seqTypes :: [Type] -> ()
 897 seqTypes []       = ()
 898 seqTypes (ty:tys) = seqType ty `seq` seqTypes tys
 899
 900 seqNote :: TyNote -> ()
 901 seqNote (FTVNote set) = sizeUniqSet set `seq` ()
 902
 903 seqPred :: PredType -> ()
 904 seqPred (ClassP c tys)   = c `seq` seqTypes tys
 905 seqPred (IParam n ty)    = n `seq` seqType ty
 906 seqPred (EqPred ty1 ty2) = seqType ty1 `seq` seqType ty2
 907 \end{code}
 908
 909
 910 %************************************************************************
 911 %*                                                                      *
 912                 Equality for Core types
 913         (We don't use instances so that we know where it happens)
 914 %*                                                                      *
 915 %************************************************************************
 916
 917 Note that eqType works right even for partial applications of newtypes.
 918 See Note [Newtype eta] in TyCon.lhs
 919
 920 \begin{code}
 921 coreEqType :: Type -> Type -> Bool
 922 coreEqType t1 t2
 923   = eq rn_env t1 t2
 924   where
 925     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfType t1 `unionVarSet` tyVarsOfType t2))
 926
 927     eq env (TyVarTy tv1)       (TyVarTy tv2)     = rnOccL env tv1 == rnOccR env tv2
 928     eq env (ForAllTy tv1 t1)   (ForAllTy tv2 t2) = eq (rnBndr2 env tv1 tv2) t1 t2
 929     eq env (AppTy s1 t1)       (AppTy s2 t2)     = eq env s1 s2 && eq env t1 t2
 930     eq env (FunTy s1 t1)       (FunTy s2 t2)     = eq env s1 s2 && eq env t1 t2
 931     eq env (TyConApp tc1 tys1) (TyConApp tc2 tys2)
 932         | tc1 == tc2, all2 (eq env) tys1 tys2 = True
 933                         -- The lengths should be equal because
 934                         -- the two types have the same kind
 935         -- NB: if the type constructors differ that does not
 936         --     necessarily mean that the types aren't equal
 937         --     (synonyms, newtypes)
 938         -- Even if the type constructors are the same, but the arguments
 939         -- differ, the two types could be the same (e.g. if the arg is just
 940         -- ignored in the RHS).  In both these cases we fall through to an
 941         -- attempt to expand one side or the other.
 942
 943         -- Now deal with newtypes, synonyms, pred-tys
 944     eq env t1 t2 | Just t1' <- coreView t1 = eq env t1' t2
 945                  | Just t2' <- coreView t2 = eq env t1 t2'
 946
 947         -- Fall through case; not equal!
 948     eq env t1 t2 = False
 949 \end{code}
 950
 951
 952 %************************************************************************
 953 %*                                                                      *
 954                 Comparision for source types
 955         (We don't use instances so that we know where it happens)
 956 %*                                                                      *
 957 %************************************************************************
 958
 959 Note that
 960         tcEqType, tcCmpType
 961 do *not* look through newtypes, PredTypes
 962
 963 \begin{code}
 964 tcEqType :: Type -> Type -> Bool
 965 tcEqType t1 t2 = isEqual $ cmpType t1 t2
 966
 967 tcEqTypes :: [Type] -> [Type] -> Bool
 968 tcEqTypes tys1 tys2 = isEqual $ cmpTypes tys1 tys2
 969
 970 tcCmpType :: Type -> Type -> Ordering
 971 tcCmpType t1 t2 = cmpType t1 t2
 972
 973 tcCmpTypes :: [Type] -> [Type] -> Ordering
 974 tcCmpTypes tys1 tys2 = cmpTypes tys1 tys2
 975
 976 tcEqPred :: PredType -> PredType -> Bool
 977 tcEqPred p1 p2 = isEqual $ cmpPred p1 p2
 978
 979 tcCmpPred :: PredType -> PredType -> Ordering
 980 tcCmpPred p1 p2 = cmpPred p1 p2
 981
 982 tcEqTypeX :: RnEnv2 -> Type -> Type -> Bool
 983 tcEqTypeX env t1 t2 = isEqual $ cmpTypeX env t1 t2
 984 \end{code}
 985
 986 Now here comes the real worker
 987
 988 \begin{code}
 989 cmpType :: Type -> Type -> Ordering
 990 cmpType t1 t2 = cmpTypeX rn_env t1 t2
 991   where
 992     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfType t1 `unionVarSet` tyVarsOfType t2))
 993
 994 cmpTypes :: [Type] -> [Type] -> Ordering
 995 cmpTypes ts1 ts2 = cmpTypesX rn_env ts1 ts2
 996   where
 997     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfTypes ts1 `unionVarSet` tyVarsOfTypes ts2))
 998
 999 cmpPred :: PredType -> PredType -> Ordering
1000 cmpPred p1 p2 = cmpPredX rn_env p1 p2
1001   where
1002     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfPred p1 `unionVarSet` tyVarsOfPred p2))
1003
1004 cmpTypeX :: RnEnv2 -> Type -> Type -> Ordering  -- Main workhorse
1005 cmpTypeX env t1 t2 | Just t1' <- tcView t1 = cmpTypeX env t1' t2
1006                    | Just t2' <- tcView t2 = cmpTypeX env t1 t2'
1007
1008 cmpTypeX env (TyVarTy tv1)       (TyVarTy tv2)       = rnOccL env tv1 `compare` rnOccR env tv2
1009 cmpTypeX env (ForAllTy tv1 t1)   (ForAllTy tv2 t2)   = cmpTypeX (rnBndr2 env tv1 tv2) t1 t2
1010 cmpTypeX env (AppTy s1 t1)       (AppTy s2 t2)       = cmpTypeX env s1 s2 `thenCmp` cmpTypeX env t1 t2
1011 cmpTypeX env (FunTy s1 t1)       (FunTy s2 t2)       = cmpTypeX env s1 s2 `thenCmp` cmpTypeX env t1 t2
1012 cmpTypeX env (PredTy p1)         (PredTy p2)         = cmpPredX env p1 p2
1013 cmpTypeX env (TyConApp tc1 tys1) (TyConApp tc2 tys2) = (tc1 `compare` tc2) `thenCmp` cmpTypesX env tys1 tys2
1014 cmpTypeX env t1                 (NoteTy _ t2)        = cmpTypeX env t1 t2
1015
1016     -- Deal with the rest: TyVarTy < AppTy < FunTy < TyConApp < ForAllTy < PredTy
1017 cmpTypeX env (AppTy _ _) (TyVarTy _) = GT
1018
1019 cmpTypeX env (FunTy _ _) (TyVarTy _) = GT
1020 cmpTypeX env (FunTy _ _) (AppTy _ _) = GT
1021
1022 cmpTypeX env (TyConApp _ _) (TyVarTy _) = GT
1023 cmpTypeX env (TyConApp _ _) (AppTy _ _) = GT
1024 cmpTypeX env (TyConApp _ _) (FunTy _ _) = GT
1025
1026 cmpTypeX env (ForAllTy _ _) (TyVarTy _)    = GT
1027 cmpTypeX env (ForAllTy _ _) (AppTy _ _)    = GT
1028 cmpTypeX env (ForAllTy _ _) (FunTy _ _)    = GT
1029 cmpTypeX env (ForAllTy _ _) (TyConApp _ _) = GT
1030
1031 cmpTypeX env (PredTy _)   t2            = GT
1032
1033 cmpTypeX env _ _ = LT
1034
1035 -------------
1036 cmpTypesX :: RnEnv2 -> [Type] -> [Type] -> Ordering
1037 cmpTypesX env []        []        = EQ
1038 cmpTypesX env (t1:tys1) (t2:tys2) = cmpTypeX env t1 t2 `thenCmp` cmpTypesX env tys1 tys2
1039 cmpTypesX env []        tys       = LT
1040 cmpTypesX env ty        []        = GT
1041
1042 -------------
1043 cmpPredX :: RnEnv2 -> PredType -> PredType -> Ordering
1044 cmpPredX env (IParam n1 ty1) (IParam n2 ty2) = (n1 `compare` n2) `thenCmp` cmpTypeX env ty1 ty2
1045         -- Compare names only for implicit parameters
1046         -- This comparison is used exclusively (I believe)
1047         -- for the Avails finite map built in TcSimplify
1048         -- If the types differ we keep them distinct so that we see
1049         -- a distinct pair to run improvement on
1050 cmpPredX env (ClassP c1 tys1) (ClassP c2 tys2) = (c1 `compare` c2) `thenCmp` (cmpTypesX env tys1 tys2)
1051 cmpPredX env (EqPred ty1 ty2) (EqPred ty1' ty2') = (cmpTypeX env ty1 ty1') `thenCmp` (cmpTypeX env ty2 ty2')
1052
1053 -- Constructor order: IParam < ClassP < EqPred
1054 cmpPredX env (IParam {})     _              = LT
1055 cmpPredX env (ClassP {})    (IParam {})     = GT
1056 cmpPredX env (ClassP {})    (EqPred {})     = LT
1057 cmpPredX env (EqPred {})    _               = GT
1058 \end{code}
1059
1060 PredTypes are used as a FM key in TcSimplify,
1061 so we take the easy path and make them an instance of Ord
1062
1063 \begin{code}
1064 instance Eq  PredType where { (==)    = tcEqPred }
1065 instance Ord PredType where { compare = tcCmpPred }
1066 \end{code}
1067
1068
1069 %************************************************************************
1070 %*                                                                      *
1071                 Type substitutions
1072 %*                                                                      *
1073 %************************************************************************
1074
1075 \begin{code}
1076 data TvSubst
1077   = TvSubst InScopeSet  -- The in-scope type variables
1078             TvSubstEnv  -- The substitution itself
1079         -- See Note [Apply Once]
1080         -- and Note [Extending the TvSubstEnv]
1081
1082 {- ----------------------------------------------------------
1083
1084 Note [Apply Once]
1085 ~~~~~~~~~~~~~~~~~
1086 We use TvSubsts to instantiate things, and we might instantiate
1087         forall a b. ty
1088 \with the types
1089         [a, b], or [b, a].
1090 So the substition might go [a->b, b->a].  A similar situation arises in Core
1091 when we find a beta redex like
1092         (/\ a /\ b -> e) b a
1093 Then we also end up with a substition that permutes type variables. Other
1094 variations happen to; for example [a -> (a, b)].
1095
1096         ***************************************************
1097         *** So a TvSubst must be applied precisely once ***
1098         ***************************************************
1099
1100 A TvSubst is not idempotent, but, unlike the non-idempotent substitution
1101 we use during unifications, it must not be repeatedly applied.
1102
1103 Note [Extending the TvSubst]
1104 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1105 The following invariant should hold of a TvSubst
1106
1107         The in-scope set is needed *only* to
1108         guide the generation of fresh uniques
1109
1110         In particular, the *kind* of the type variables in
1111         the in-scope set is not relevant
1112
1113 This invariant allows a short-cut when the TvSubstEnv is empty:
1114 if the TvSubstEnv is empty --- i.e. (isEmptyTvSubt subst) holds ---
1115 then (substTy subst ty) does nothing.
1116
1117 For example, consider:
1118         (/\a. /\b:(a~Int). ...b..) Int
1119 We substitute Int for 'a'.  The Unique of 'b' does not change, but
1120 nevertheless we add 'b' to the TvSubstEnv, because b's type does change
1121
1122 This invariant has several crucial consequences:
1123
1124 * In substTyVarBndr, we need extend the TvSubstEnv
1125         - if the unique has changed
1126         - or if the kind has changed
1127
1128 * In substTyVar, we do not need to consult the in-scope set;
1129   the TvSubstEnv is enough
1130
1131 * In substTy, substTheta, we can short-circuit when the TvSubstEnv is empty
1132
1133
1134 -------------------------------------------------------------- -}
1135
1136
1137 type TvSubstEnv = TyVarEnv Type
1138         -- A TvSubstEnv is used both inside a TvSubst (with the apply-once
1139         -- invariant discussed in Note [Apply Once]), and also independently
1140         -- in the middle of matching, and unification (see Types.Unify)
1141         -- So you have to look at the context to know if it's idempotent or
1142         -- apply-once or whatever
1143 emptyTvSubstEnv :: TvSubstEnv
1144 emptyTvSubstEnv = emptyVarEnv
1145
1146 composeTvSubst :: InScopeSet -> TvSubstEnv -> TvSubstEnv -> TvSubstEnv
1147 -- (compose env1 env2)(x) is env1(env2(x)); i.e. apply env2 then env1
1148 -- It assumes that both are idempotent
1149 -- Typically, env1 is the refinement to a base substitution env2
1150 composeTvSubst in_scope env1 env2
1151   = env1 `plusVarEnv` mapVarEnv (substTy subst1) env2
1152         -- First apply env1 to the range of env2
1153         -- Then combine the two, making sure that env1 loses if
1154         -- both bind the same variable; that's why env1 is the
1155         --  *left* argument to plusVarEnv, because the right arg wins
1156   where
1157     subst1 = TvSubst in_scope env1
1158
1159 emptyTvSubst = TvSubst emptyInScopeSet emptyVarEnv
1160
1161 isEmptyTvSubst :: TvSubst -> Bool
1162          -- See Note [Extending the TvSubstEnv]
1163 isEmptyTvSubst (TvSubst _ env) = isEmptyVarEnv env
1164
1165 mkTvSubst :: InScopeSet -> TvSubstEnv -> TvSubst
1166 mkTvSubst = TvSubst
1167
1168 getTvSubstEnv :: TvSubst -> TvSubstEnv
1169 getTvSubstEnv (TvSubst _ env) = env
1170
1171 getTvInScope :: TvSubst -> InScopeSet
1172 getTvInScope (TvSubst in_scope _) = in_scope
1173
1174 isInScope :: Var -> TvSubst -> Bool
1175 isInScope v (TvSubst in_scope _) = v `elemInScopeSet` in_scope
1176
1177 notElemTvSubst :: TyVar -> TvSubst -> Bool
1178 notElemTvSubst tv (TvSubst _ env) = not (tv `elemVarEnv` env)
1179
1180 setTvSubstEnv :: TvSubst -> TvSubstEnv -> TvSubst
1181 setTvSubstEnv (TvSubst in_scope _) env = TvSubst in_scope env
1182
1183 extendTvInScope :: TvSubst -> [Var] -> TvSubst
1184 extendTvInScope (TvSubst in_scope env) vars = TvSubst (extendInScopeSetList in_scope vars) env
1185
1186 extendTvSubst :: TvSubst -> TyVar -> Type -> TvSubst
1187 extendTvSubst (TvSubst in_scope env) tv ty = TvSubst in_scope (extendVarEnv env tv ty)
1188
1189 extendTvSubstList :: TvSubst -> [TyVar] -> [Type] -> TvSubst
1190 extendTvSubstList (TvSubst in_scope env) tvs tys
1191   = TvSubst in_scope (extendVarEnvList env (tvs `zip` tys))
1192
1193 -- mkOpenTvSubst and zipOpenTvSubst generate the in-scope set from
1194 -- the types given; but it's just a thunk so with a bit of luck
1195 -- it'll never be evaluated
1196
1197 mkOpenTvSubst :: TvSubstEnv -> TvSubst
1198 mkOpenTvSubst env = TvSubst (mkInScopeSet (tyVarsOfTypes (varEnvElts env))) env
1199
1200 zipOpenTvSubst :: [TyVar] -> [Type] -> TvSubst
1201 zipOpenTvSubst tyvars tys
1202 #ifdef DEBUG
1203   | length tyvars /= length tys
1204   = pprTrace "zipOpenTvSubst" (ppr tyvars $$ ppr tys) emptyTvSubst
1205   | otherwise
1206 #endif
1207   = TvSubst (mkInScopeSet (tyVarsOfTypes tys)) (zipTyEnv tyvars tys)
1208
1209 -- mkTopTvSubst is called when doing top-level substitutions.
1210 -- Here we expect that the free vars of the range of the
1211 -- substitution will be empty.
1212 mkTopTvSubst :: [(TyVar, Type)] -> TvSubst
1213 mkTopTvSubst prs = TvSubst emptyInScopeSet (mkVarEnv prs)
1214
1215 zipTopTvSubst :: [TyVar] -> [Type] -> TvSubst
1216 zipTopTvSubst tyvars tys
1217 #ifdef DEBUG
1218   | length tyvars /= length tys
1219   = pprTrace "zipOpenTvSubst" (ppr tyvars $$ ppr tys) emptyTvSubst
1220   | otherwise
1221 #endif
1222   = TvSubst emptyInScopeSet (zipTyEnv tyvars tys)
1223
1224 zipTyEnv :: [TyVar] -> [Type] -> TvSubstEnv
1225 zipTyEnv tyvars tys
1226 #ifdef DEBUG
1227   | length tyvars /= length tys
1228   = pprTrace "mkTopTvSubst" (ppr tyvars $$ ppr tys) emptyVarEnv
1229   | otherwise
1230 #endif
1231   = zip_ty_env tyvars tys emptyVarEnv
1232
1233 -- Later substitutions in the list over-ride earlier ones,
1234 -- but there should be no loops
1235 zip_ty_env []       []       env = env
1236 zip_ty_env (tv:tvs) (ty:tys) env = zip_ty_env tvs tys (extendVarEnv env tv ty)
1237         -- There used to be a special case for when
1238         --      ty == TyVarTy tv
1239         -- (a not-uncommon case) in which case the substitution was dropped.
1240         -- But the type-tidier changes the print-name of a type variable without
1241         -- changing the unique, and that led to a bug.   Why?  Pre-tidying, we had
1242         -- a type {Foo t}, where Foo is a one-method class.  So Foo is really a newtype.
1243         -- And it happened that t was the type variable of the class.  Post-tiding,
1244         -- it got turned into {Foo t2}.  The ext-core printer expanded this using
1245         -- sourceTypeRep, but that said "Oh, t == t2" because they have the same unique,
1246         -- and so generated a rep type mentioning t not t2.
1247         --
1248         -- Simplest fix is to nuke the "optimisation"
1249 zip_ty_env tvs      tys      env   = pprTrace "Var/Type length mismatch: " (ppr tvs $$ ppr tys) env
1250 -- zip_ty_env _ _ env = env
1251
1252 instance Outputable TvSubst where
1253   ppr (TvSubst ins env)
1254     = brackets $ sep[ ptext SLIT("TvSubst"),
1255                       nest 2 (ptext SLIT("In scope:") <+> ppr ins),
1256                       nest 2 (ptext SLIT("Env:") <+> ppr env) ]
1257 \end{code}
1258
1259 %************************************************************************
1260 %*                                                                      *
1261                 Performing type substitutions
1262 %*                                                                      *
1263 %************************************************************************
1264
1265 \begin{code}
1266 substTyWith :: [TyVar] -> [Type] -> Type -> Type
1267 substTyWith tvs tys = ASSERT( length tvs == length tys )
1268                       substTy (zipOpenTvSubst tvs tys)
1269
1270 substTy :: TvSubst -> Type  -> Type
1271 substTy subst ty | isEmptyTvSubst subst = ty
1272                  | otherwise            = subst_ty subst ty
1273
1274 substTys :: TvSubst -> [Type] -> [Type]
1275 substTys subst tys | isEmptyTvSubst subst = tys
1276                    | otherwise            = map (subst_ty subst) tys
1277
1278 substTheta :: TvSubst -> ThetaType -> ThetaType
1279 substTheta subst theta
1280   | isEmptyTvSubst subst = theta
1281   | otherwise            = map (substPred subst) theta
1282
1283 substPred :: TvSubst -> PredType -> PredType
1284 substPred subst (IParam n ty)     = IParam n (subst_ty subst ty)
1285 substPred subst (ClassP clas tys) = ClassP clas (map (subst_ty subst) tys)
1286 substPred subst (EqPred ty1 ty2)  = EqPred (subst_ty subst ty1) (subst_ty subst ty2)
1287
1288 deShadowTy :: TyVarSet -> Type -> Type  -- Remove any nested binders mentioning tvs
1289 deShadowTy tvs ty
1290   = subst_ty (mkTvSubst in_scope emptyTvSubstEnv) ty
1291   where
1292     in_scope = mkInScopeSet tvs
1293
1294 subst_ty :: TvSubst -> Type -> Type
1295 -- subst_ty is the main workhorse for type substitution
1296 --
1297 -- Note that the in_scope set is poked only if we hit a forall
1298 -- so it may often never be fully computed
1299 subst_ty subst ty
1300    = go ty
1301   where
1302     go (TyVarTy tv)                = substTyVar subst tv
1303     go (TyConApp tc tys)           = let args = map go tys
1304                                      in  args `seqList` TyConApp tc args
1305
1306     go (PredTy p)                  = PredTy $! (substPred subst p)
1307
1308     go (NoteTy (FTVNote _) ty2)    = go ty2             -- Discard the free tyvar note
1309
1310     go (FunTy arg res)             = (FunTy $! (go arg)) $! (go res)
1311     go (AppTy fun arg)             = mkAppTy (go fun) $! (go arg)
1312                 -- The mkAppTy smart constructor is important
1313                 -- we might be replacing (a Int), represented with App
1314                 -- by [Int], represented with TyConApp
1315     go (ForAllTy tv ty)            = case substTyVarBndr subst tv of
1316                                         (subst', tv') -> ForAllTy tv' $! (subst_ty subst' ty)
1317
1318 substTyVar :: TvSubst -> TyVar  -> Type
1319 substTyVar subst@(TvSubst in_scope env) tv
1320   = case lookupTyVar subst tv of {
1321         Nothing -> TyVarTy tv;
1322         Just ty -> ty   -- See Note [Apply Once]
1323     }
1324
1325 substTyVars :: TvSubst -> [TyVar] -> [Type]
1326 substTyVars subst tvs = map (substTyVar subst) tvs
1327
1328 lookupTyVar :: TvSubst -> TyVar  -> Maybe Type
1329         -- See Note [Extending the TvSubst]
1330 lookupTyVar (TvSubst in_scope env) tv = lookupVarEnv env tv
1331
1332 substTyVarBndr :: TvSubst -> TyVar -> (TvSubst, TyVar)
1333 substTyVarBndr subst@(TvSubst in_scope env) old_var
1334   = (TvSubst (in_scope `extendInScopeSet` new_var) new_env, new_var)
1335   where
1336     is_co_var = isCoVar old_var
1337
1338     new_env | no_change = delVarEnv env old_var
1339             | otherwise = extendVarEnv env old_var (TyVarTy new_var)
1340
1341     no_change = new_var == old_var && not is_co_var
1342         -- no_change means that the new_var is identical in
1343         -- all respects to the old_var (same unique, same kind)
1344         -- See Note [Extending the TvSubst]
1345         --
1346         -- In that case we don't need to extend the substitution
1347         -- to map old to new.  But instead we must zap any
1348         -- current substitution for the variable. For example:
1349         --      (\x.e) with id_subst = [x |-> e']
1350         -- Here we must simply zap the substitution for x
1351
1352     new_var = uniqAway in_scope subst_old_var
1353         -- The uniqAway part makes sure the new variable is not already in scope
1354
1355     subst_old_var -- subst_old_var is old_var with the substitution applied to its kind
1356                   -- It's only worth doing the substitution for coercions,
1357                   -- becuase only they can have free type variables
1358         | is_co_var = setTyVarKind old_var (substTy subst (tyVarKind old_var))
1359         | otherwise = old_var
1360 \end{code}
1361
1362 ----------------------------------------------------
1363 -- Kind Stuff
1364
1365 Kinds
1366 ~~~~~
1367 There's a little subtyping at the kind level:
1368
1369                  ?
1370                 / \
1371                /   \
1372               ??   (#)
1373              /  \
1374             *   #
1375
1376 where   *    [LiftedTypeKind]   means boxed type
1377         #    [UnliftedTypeKind] means unboxed type
1378         (#)  [UbxTupleKind]     means unboxed tuple
1379         ??   [ArgTypeKind]      is the lub of *,#
1380         ?    [OpenTypeKind]     means any type at all
1381
1382 In particular:
1383
1384         error :: forall a:?. String -> a
1385         (->)  :: ?? -> ? -> *
1386         (\(x::t) -> ...)        Here t::?? (i.e. not unboxed tuple)
1387
1388 \begin{code}
1389 type KindVar = TyVar  -- invariant: KindVar will always be a
1390                       -- TcTyVar with details MetaTv TauTv ...
1391 -- kind var constructors and functions are in TcType
1392
1393 type SimpleKind = Kind
1394 \end{code}
1395
1396 Kind inference
1397 ~~~~~~~~~~~~~~
1398 During kind inference, a kind variable unifies only with
1399 a "simple kind", sk
1400         sk ::= * | sk1 -> sk2
1401 For example
1402         data T a = MkT a (T Int#)
1403 fails.  We give T the kind (k -> *), and the kind variable k won't unify
1404 with # (the kind of Int#).
1405
1406 Type inference
1407 ~~~~~~~~~~~~~~
1408 When creating a fresh internal type variable, we give it a kind to express
1409 constraints on it.  E.g. in (\x->e) we make up a fresh type variable for x,
1410 with kind ??.
1411
1412 During unification we only bind an internal type variable to a type
1413 whose kind is lower in the sub-kind hierarchy than the kind of the tyvar.
1414
1415 When unifying two internal type variables, we collect their kind constraints by
1416 finding the GLB of the two.  Since the partial order is a tree, they only
1417 have a glb if one is a sub-kind of the other.  In that case, we bind the
1418 less-informative one to the more informative one.  Neat, eh?
1419
1420
1421 \begin{code}
1422
1423 \end{code}
1424
1425 %************************************************************************
1426 %*                                                                      *
1427         Functions over Kinds
1428 %*                                                                      *
1429 %************************************************************************
1430
1431 \begin{code}
1432 kindFunResult :: Kind -> Kind
1433 kindFunResult k = funResultTy k
1434
1435 splitKindFunTys :: Kind -> ([Kind],Kind)
1436 splitKindFunTys k = splitFunTys k
1437
1438 splitKindFunTysN :: Int -> Kind -> ([Kind],Kind)
1439 splitKindFunTysN k = splitFunTysN k
1440
1441 isUbxTupleKind, isOpenTypeKind, isArgTypeKind, isUnliftedTypeKind :: Kind -> Bool
1442
1443 isOpenTypeKindCon tc    = tyConUnique tc == openTypeKindTyConKey
1444
1445 isOpenTypeKind (TyConApp tc _) = isOpenTypeKindCon tc
1446 isOpenTypeKind other           = False
1447
1448 isUbxTupleKindCon tc = tyConUnique tc == ubxTupleKindTyConKey
1449
1450 isUbxTupleKind (TyConApp tc _) = isUbxTupleKindCon tc
1451 isUbxTupleKind other           = False
1452
1453 isArgTypeKindCon tc = tyConUnique tc == argTypeKindTyConKey
1454
1455 isArgTypeKind (TyConApp tc _) = isArgTypeKindCon tc
1456 isArgTypeKind other = False
1457
1458 isUnliftedTypeKindCon tc = tyConUnique tc == unliftedTypeKindTyConKey
1459
1460 isUnliftedTypeKind (TyConApp tc _) = isUnliftedTypeKindCon tc
1461 isUnliftedTypeKind other           = False
1462
1463 isSubOpenTypeKind :: Kind -> Bool
1464 -- True of any sub-kind of OpenTypeKind (i.e. anything except arrow)
1465 isSubOpenTypeKind (FunTy k1 k2)    = ASSERT2 ( isKind k1, text "isSubOpenTypeKind" <+> ppr k1 <+> text "::" <+> ppr (typeKind k1) )
1466                                      ASSERT2 ( isKind k2, text "isSubOpenTypeKind" <+> ppr k2 <+> text "::" <+> ppr (typeKind k2) )
1467                                      False
1468 isSubOpenTypeKind (TyConApp kc []) = ASSERT( isKind (TyConApp kc []) ) True
1469 isSubOpenTypeKind other            = ASSERT( isKind other ) False
1470          -- This is a conservative answer
1471          -- It matters in the call to isSubKind in
1472          -- checkExpectedKind.
1473
1474 isSubArgTypeKindCon kc
1475   | isUnliftedTypeKindCon kc = True
1476   | isLiftedTypeKindCon kc   = True
1477   | isArgTypeKindCon kc      = True
1478   | otherwise                = False
1479
1480 isSubArgTypeKind :: Kind -> Bool
1481 -- True of any sub-kind of ArgTypeKind
1482 isSubArgTypeKind (TyConApp kc []) = isSubArgTypeKindCon kc
1483 isSubArgTypeKind other            = False
1484
1485 isSuperKind :: Type -> Bool
1486 isSuperKind (TyConApp (skc) []) = isSuperKindTyCon skc
1487 isSuperKind other = False
1488
1489 isKind :: Kind -> Bool
1490 isKind k = isSuperKind (typeKind k)
1491
1492
1493
1494 isSubKind :: Kind -> Kind -> Bool
1495 -- (k1 `isSubKind` k2) checks that k1 <: k2
1496 isSubKind (TyConApp kc1 []) (TyConApp kc2 []) = kc1 `isSubKindCon` kc2
1497 isSubKind (FunTy a1 r1) (FunTy a2 r2)         = (a2 `isSubKind` a1) && (r1 `isSubKind` r2)
1498 isSubKind (PredTy (EqPred ty1 ty2)) (PredTy (EqPred ty1' ty2'))
1499   = ty1 `tcEqType` ty1' && ty2 `tcEqType` ty2'
1500 isSubKind k1            k2                    = False
1501
1502 eqKind :: Kind -> Kind -> Bool
1503 eqKind = tcEqType
1504
1505 isSubKindCon :: TyCon -> TyCon -> Bool
1506 -- (kc1 `isSubKindCon` kc2) checks that kc1 <: kc2
1507 isSubKindCon kc1 kc2
1508   | isLiftedTypeKindCon kc1   && isLiftedTypeKindCon kc2   = True
1509   | isUnliftedTypeKindCon kc1 && isUnliftedTypeKindCon kc2 = True
1510   | isUbxTupleKindCon kc1     && isUbxTupleKindCon kc2     = True
1511   | isOpenTypeKindCon kc2                                  = True
1512                            -- we already know kc1 is not a fun, its a TyCon
1513   | isArgTypeKindCon kc2      && isSubArgTypeKindCon kc1   = True
1514   | otherwise                                              = False
1515
1516 defaultKind :: Kind -> Kind
1517 -- Used when generalising: default kind '?' and '??' to '*'
1518 --
1519 -- When we generalise, we make generic type variables whose kind is
1520 -- simple (* or *->* etc).  So generic type variables (other than
1521 -- built-in constants like 'error') always have simple kinds.  This is important;
1522 -- consider
1523 --      f x = True
1524 -- We want f to get type
1525 --      f :: forall (a::*). a -> Bool
1526 -- Not
1527 --      f :: forall (a::??). a -> Bool
1528 -- because that would allow a call like (f 3#) as well as (f True),
1529 --and the calling conventions differ.  This defaulting is done in TcMType.zonkTcTyVarBndr.
1530 defaultKind k
1531   | isSubOpenTypeKind k = liftedTypeKind
1532   | isSubArgTypeKind k  = liftedTypeKind
1533   | otherwise        = k
1534
1535 isEqPred :: PredType -> Bool
1536 isEqPred (EqPred _ _) = True
1537 isEqPred other        = False
1538 \end{code}