compiler/types/Type.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1998
   4 %
   5
   6 Type - public interface
   7
   8 \begin{code}
   9 module Type (
  10         -- re-exports from TypeRep
  11         TyThing(..), Type, PredType(..), ThetaType,
  12         funTyCon,
  13
  14         -- Kinds
  15         Kind, SimpleKind, KindVar,
  16         kindFunResult, splitKindFunTys, splitKindFunTysN,
  17
  18         liftedTypeKindTyCon, openTypeKindTyCon, unliftedTypeKindTyCon,
  19         argTypeKindTyCon, ubxTupleKindTyCon,
  20
  21         liftedTypeKind, unliftedTypeKind, openTypeKind,
  22         argTypeKind, ubxTupleKind,
  23
  24         tySuperKind, coSuperKind,
  25
  26         isLiftedTypeKind, isUnliftedTypeKind, isOpenTypeKind,
  27         isUbxTupleKind, isArgTypeKind, isKind, isTySuperKind,
  28         isCoSuperKind, isSuperKind, isCoercionKind, isEqPred,
  29         mkArrowKind, mkArrowKinds,
  30
  31         isSubArgTypeKind, isSubOpenTypeKind, isSubKind, defaultKind, eqKind,
  32         isSubKindCon,
  33
  34         -- Re-exports from TyCon
  35         PrimRep(..),
  36
  37         mkTyVarTy, mkTyVarTys, getTyVar, getTyVar_maybe, isTyVarTy,
  38
  39         mkAppTy, mkAppTys, splitAppTy, splitAppTys,
  40         splitAppTy_maybe, repSplitAppTy_maybe,
  41
  42         mkFunTy, mkFunTys, splitFunTy, splitFunTy_maybe,
  43         splitFunTys, splitFunTysN,
  44         funResultTy, funArgTy, zipFunTys, isFunTy,
  45
  46         mkTyConApp, mkTyConTy,
  47         tyConAppTyCon, tyConAppArgs,
  48         splitTyConApp_maybe, splitTyConApp,
  49         splitNewTyConApp_maybe, splitNewTyConApp,
  50
  51         repType, repType', typePrimRep, coreView, tcView, kindView,
  52
  53         mkForAllTy, mkForAllTys, splitForAllTy_maybe, splitForAllTys,
  54         applyTy, applyTys, isForAllTy, dropForAlls,
  55
  56         -- Source types
  57         predTypeRep, mkPredTy, mkPredTys, pprSourceTyCon, mkFamilyTyConApp,
  58
  59         -- Newtypes
  60         newTyConInstRhs,
  61
  62         -- Lifting and boxity
  63         isUnLiftedType, isUnboxedTupleType, isAlgType, isPrimitiveType,
  64         isStrictType, isStrictPred,
  65
  66         -- Free variables
  67         tyVarsOfType, tyVarsOfTypes, tyVarsOfPred, tyVarsOfTheta,
  68         typeKind, addFreeTyVars,
  69
  70         -- Tidying up for printing
  71         tidyType,      tidyTypes,
  72         tidyOpenType,  tidyOpenTypes,
  73         tidyTyVarBndr, tidyFreeTyVars,
  74         tidyOpenTyVar, tidyOpenTyVars,
  75         tidyTopType,   tidyPred,
  76         tidyKind,
  77
  78         -- Comparison
  79         coreEqType, tcEqType, tcEqTypes, tcCmpType, tcCmpTypes,
  80         tcEqPred, tcCmpPred, tcEqTypeX,
  81
  82         -- Seq
  83         seqType, seqTypes,
  84
  85         -- Type substitutions
  86         TvSubstEnv, emptyTvSubstEnv,    -- Representation widely visible
  87         TvSubst(..), emptyTvSubst,      -- Representation visible to a few friends
  88         mkTvSubst, mkOpenTvSubst, zipOpenTvSubst, zipTopTvSubst, mkTopTvSubst, notElemTvSubst,
  89         getTvSubstEnv, setTvSubstEnv, getTvInScope, extendTvInScope,
  90         extendTvSubst, extendTvSubstList, isInScope, composeTvSubst, zipTyEnv,
  91         isEmptyTvSubst,
  92
  93         -- Performing substitution on types
  94         substTy, substTys, substTyWith, substTheta,
  95         substPred, substTyVar, substTyVars, substTyVarBndr, deShadowTy, lookupTyVar,
  96
  97         -- Pretty-printing
  98         pprType, pprParendType, pprTypeApp, pprTyThingCategory, pprForAll,
  99         pprPred, pprTheta, pprThetaArrow, pprClassPred, pprKind, pprParendKind
 100     ) where
 101
 102 #include "HsVersions.h"
 103
 104 -- We import the representation and primitive functions from TypeRep.
 105 -- Many things are reexported, but not the representation!
 106
 107 import TypeRep
 108
 109 -- friends:
 110 import Var
 111 import VarEnv
 112 import VarSet
 113
 114 import Name
 115 import Class
 116 import PrelNames
 117 import TyCon
 118
 119 -- others
 120 import StaticFlags
 121 import Util
 122 import Outputable
 123 import UniqSet
 124
 125 import Data.List
 126 import Data.Maybe       ( isJust )
 127 \end{code}
 128
 129
 130 %************************************************************************
 131 %*                                                                      *
 132                 Type representation
 133 %*                                                                      *
 134 %************************************************************************
 135
 136 In Core, we "look through" non-recursive newtypes and PredTypes.
 137
 138 \begin{code}
 139 {-# INLINE coreView #-}
 140 coreView :: Type -> Maybe Type
 141 -- Strips off the *top layer only* of a type to give
 142 -- its underlying representation type.
 143 -- Returns Nothing if there is nothing to look through.
 144 --
 145 -- In the case of newtypes, it returns
 146 --      *either* a vanilla TyConApp (recursive newtype, or non-saturated)
 147 --      *or*     the newtype representation (otherwise), meaning the
 148 --                      type written in the RHS of the newtype decl,
 149 --                      which may itself be a newtype
 150 --
 151 -- Example: newtype R = MkR S
 152 --          newtype S = MkS T
 153 --          newtype T = MkT (T -> T)
 154 --   expandNewTcApp on R gives Just S
 155 --                  on S gives Just T
 156 --                  on T gives Nothing   (no expansion)
 157
 158 -- By being non-recursive and inlined, this case analysis gets efficiently
 159 -- joined onto the case analysis that the caller is already doing
 160 coreView (NoteTy _ ty)     = Just ty
 161 coreView (PredTy p)
 162   | isEqPred p             = Nothing
 163   | otherwise              = Just (predTypeRep p)
 164 coreView (TyConApp tc tys) | Just (tenv, rhs, tys') <- coreExpandTyCon_maybe tc tys
 165                            = Just (mkAppTys (substTy (mkTopTvSubst tenv) rhs) tys')
 166                                 -- Its important to use mkAppTys, rather than (foldl AppTy),
 167                                 -- because the function part might well return a
 168                                 -- partially-applied type constructor; indeed, usually will!
 169 coreView ty                = Nothing
 170
 171
 172
 173 -----------------------------------------------
 174 {-# INLINE tcView #-}
 175 tcView :: Type -> Maybe Type
 176 -- Same, but for the type checker, which just looks through synonyms
 177 tcView (NoteTy _ ty)     = Just ty
 178 tcView (TyConApp tc tys) | Just (tenv, rhs, tys') <- tcExpandTyCon_maybe tc tys
 179                          = Just (mkAppTys (substTy (mkTopTvSubst tenv) rhs) tys')
 180 tcView ty                = Nothing
 181
 182 -----------------------------------------------
 183 {-# INLINE kindView #-}
 184 kindView :: Kind -> Maybe Kind
 185 -- C.f. coreView, tcView
 186 -- For the moment, we don't even handle synonyms in kinds
 187 kindView (NoteTy _ k) = Just k
 188 kindView other        = Nothing
 189 \end{code}
 190
 191
 192 %************************************************************************
 193 %*                                                                      *
 194 \subsection{Constructor-specific functions}
 195 %*                                                                      *
 196 %************************************************************************
 197
 198
 199 ---------------------------------------------------------------------
 200                                 TyVarTy
 201                                 ~~~~~~~
 202 \begin{code}
 203 mkTyVarTy  :: TyVar   -> Type
 204 mkTyVarTy  = TyVarTy
 205
 206 mkTyVarTys :: [TyVar] -> [Type]
 207 mkTyVarTys = map mkTyVarTy -- a common use of mkTyVarTy
 208
 209 getTyVar :: String -> Type -> TyVar
 210 getTyVar msg ty = case getTyVar_maybe ty of
 211                     Just tv -> tv
 212                     Nothing -> panic ("getTyVar: " ++ msg)
 213
 214 isTyVarTy :: Type -> Bool
 215 isTyVarTy ty = isJust (getTyVar_maybe ty)
 216
 217 getTyVar_maybe :: Type -> Maybe TyVar
 218 getTyVar_maybe ty | Just ty' <- coreView ty = getTyVar_maybe ty'
 219 getTyVar_maybe (TyVarTy tv)                 = Just tv
 220 getTyVar_maybe other                        = Nothing
 221
 222 \end{code}
 223
 224
 225 ---------------------------------------------------------------------
 226                                 AppTy
 227                                 ~~~~~
 228 We need to be pretty careful with AppTy to make sure we obey the
 229 invariant that a TyConApp is always visibly so.  mkAppTy maintains the
 230 invariant: use it.
 231
 232 \begin{code}
 233 mkAppTy orig_ty1 orig_ty2
 234   = mk_app orig_ty1
 235   where
 236     mk_app (NoteTy _ ty1)    = mk_app ty1
 237     mk_app (TyConApp tc tys) = mkTyConApp tc (tys ++ [orig_ty2])
 238     mk_app ty1               = AppTy orig_ty1 orig_ty2
 239         -- Note that the TyConApp could be an
 240         -- under-saturated type synonym.  GHC allows that; e.g.
 241         --      type Foo k = k a -> k a
 242         --      type Id x = x
 243         --      foo :: Foo Id -> Foo Id
 244         --
 245         -- Here Id is partially applied in the type sig for Foo,
 246         -- but once the type synonyms are expanded all is well
 247
 248 mkAppTys :: Type -> [Type] -> Type
 249 mkAppTys orig_ty1 []        = orig_ty1
 250         -- This check for an empty list of type arguments
 251         -- avoids the needless loss of a type synonym constructor.
 252         -- For example: mkAppTys Rational []
 253         --   returns to (Ratio Integer), which has needlessly lost
 254         --   the Rational part.
 255 mkAppTys orig_ty1 orig_tys2
 256   = mk_app orig_ty1
 257   where
 258     mk_app (NoteTy _ ty1)    = mk_app ty1
 259     mk_app (TyConApp tc tys) = mkTyConApp tc (tys ++ orig_tys2)
 260                                 -- mkTyConApp: see notes with mkAppTy
 261     mk_app ty1               = foldl AppTy orig_ty1 orig_tys2
 262
 263 -------------
 264 splitAppTy_maybe :: Type -> Maybe (Type, Type)
 265 splitAppTy_maybe ty | Just ty' <- coreView ty
 266                     = splitAppTy_maybe ty'
 267 splitAppTy_maybe ty = repSplitAppTy_maybe ty
 268
 269 -------------
 270 repSplitAppTy_maybe :: Type -> Maybe (Type,Type)
 271 -- Does the AppTy split, but assumes that any view stuff is already done
 272 repSplitAppTy_maybe (FunTy ty1 ty2)   = Just (TyConApp funTyCon [ty1], ty2)
 273 repSplitAppTy_maybe (AppTy ty1 ty2)   = Just (ty1, ty2)
 274 repSplitAppTy_maybe (TyConApp tc tys) = case snocView tys of
 275                                                 Just (tys', ty') -> Just (TyConApp tc tys', ty')
 276                                                 Nothing          -> Nothing
 277 repSplitAppTy_maybe other = Nothing
 278 -------------
 279 splitAppTy :: Type -> (Type, Type)
 280 splitAppTy ty = case splitAppTy_maybe ty of
 281                         Just pr -> pr
 282                         Nothing -> panic "splitAppTy"
 283
 284 -------------
 285 splitAppTys :: Type -> (Type, [Type])
 286 splitAppTys ty = split ty ty []
 287   where
 288     split orig_ty ty args | Just ty' <- coreView ty = split orig_ty ty' args
 289     split orig_ty (AppTy ty arg)        args = split ty ty (arg:args)
 290     split orig_ty (TyConApp tc tc_args) args = (TyConApp tc [], tc_args ++ args)
 291     split orig_ty (FunTy ty1 ty2)       args = ASSERT( null args )
 292                                                (TyConApp funTyCon [], [ty1,ty2])
 293     split orig_ty ty                    args = (orig_ty, args)
 294
 295 \end{code}
 296
 297
 298 ---------------------------------------------------------------------
 299                                 FunTy
 300                                 ~~~~~
 301
 302 \begin{code}
 303 mkFunTy :: Type -> Type -> Type
 304 mkFunTy (PredTy (EqPred ty1 ty2)) res = mkForAllTy (mkWildCoVar (PredTy (EqPred ty1 ty2))) res
 305 mkFunTy arg res = FunTy arg res
 306
 307 mkFunTys :: [Type] -> Type -> Type
 308 mkFunTys tys ty = foldr mkFunTy ty tys
 309
 310 isFunTy :: Type -> Bool
 311 isFunTy ty = isJust (splitFunTy_maybe ty)
 312
 313 splitFunTy :: Type -> (Type, Type)
 314 splitFunTy ty | Just ty' <- coreView ty = splitFunTy ty'
 315 splitFunTy (FunTy arg res)   = (arg, res)
 316 splitFunTy other             = pprPanic "splitFunTy" (ppr other)
 317
 318 splitFunTy_maybe :: Type -> Maybe (Type, Type)
 319 splitFunTy_maybe ty | Just ty' <- coreView ty = splitFunTy_maybe ty'
 320 splitFunTy_maybe (FunTy arg res)   = Just (arg, res)
 321 splitFunTy_maybe other             = Nothing
 322
 323 splitFunTys :: Type -> ([Type], Type)
 324 splitFunTys ty = split [] ty ty
 325   where
 326     split args orig_ty ty | Just ty' <- coreView ty = split args orig_ty ty'
 327     split args orig_ty (FunTy arg res)   = split (arg:args) res res
 328     split args orig_ty ty                = (reverse args, orig_ty)
 329
 330 splitFunTysN :: Int -> Type -> ([Type], Type)
 331 -- Split off exactly n arg tys
 332 splitFunTysN 0 ty = ([], ty)
 333 splitFunTysN n ty = case splitFunTy ty of { (arg, res) ->
 334                     case splitFunTysN (n-1) res of { (args, res) ->
 335                     (arg:args, res) }}
 336
 337 zipFunTys :: Outputable a => [a] -> Type -> ([(a,Type)], Type)
 338 zipFunTys orig_xs orig_ty = split [] orig_xs orig_ty orig_ty
 339   where
 340     split acc []     nty ty                = (reverse acc, nty)
 341     split acc xs     nty ty
 342           | Just ty' <- coreView ty        = split acc xs nty ty'
 343     split acc (x:xs) nty (FunTy arg res)   = split ((x,arg):acc) xs res res
 344     split acc (x:xs) nty ty                = pprPanic "zipFunTys" (ppr orig_xs <+> ppr orig_ty)
 345
 346 funResultTy :: Type -> Type
 347 funResultTy ty | Just ty' <- coreView ty = funResultTy ty'
 348 funResultTy (FunTy arg res)   = res
 349 funResultTy ty                = pprPanic "funResultTy" (ppr ty)
 350
 351 funArgTy :: Type -> Type
 352 funArgTy ty | Just ty' <- coreView ty = funArgTy ty'
 353 funArgTy (FunTy arg res)   = arg
 354 funArgTy ty                = pprPanic "funArgTy" (ppr ty)
 355 \end{code}
 356
 357
 358 ---------------------------------------------------------------------
 359                                 TyConApp
 360                                 ~~~~~~~~
 361 @mkTyConApp@ is a key function, because it builds a TyConApp, FunTy or PredTy,
 362 as apppropriate.
 363
 364 \begin{code}
 365 mkTyConApp :: TyCon -> [Type] -> Type
 366 mkTyConApp tycon tys
 367   | isFunTyCon tycon, [ty1,ty2] <- tys
 368   = FunTy ty1 ty2
 369
 370   | otherwise
 371   = TyConApp tycon tys
 372
 373 mkTyConTy :: TyCon -> Type
 374 mkTyConTy tycon = mkTyConApp tycon []
 375
 376 -- splitTyConApp "looks through" synonyms, because they don't
 377 -- mean a distinct type, but all other type-constructor applications
 378 -- including functions are returned as Just ..
 379
 380 tyConAppTyCon :: Type -> TyCon
 381 tyConAppTyCon ty = fst (splitTyConApp ty)
 382
 383 tyConAppArgs :: Type -> [Type]
 384 tyConAppArgs ty = snd (splitTyConApp ty)
 385
 386 splitTyConApp :: Type -> (TyCon, [Type])
 387 splitTyConApp ty = case splitTyConApp_maybe ty of
 388                         Just stuff -> stuff
 389                         Nothing    -> pprPanic "splitTyConApp" (ppr ty)
 390
 391 splitTyConApp_maybe :: Type -> Maybe (TyCon, [Type])
 392 splitTyConApp_maybe ty | Just ty' <- coreView ty = splitTyConApp_maybe ty'
 393 splitTyConApp_maybe (TyConApp tc tys) = Just (tc, tys)
 394 splitTyConApp_maybe (FunTy arg res)   = Just (funTyCon, [arg,res])
 395 splitTyConApp_maybe other             = Nothing
 396
 397 -- Sometimes we do NOT want to look throught a newtype.  When case matching
 398 -- on a newtype we want a convenient way to access the arguments of a newty
 399 -- constructor so as to properly form a coercion.
 400 splitNewTyConApp :: Type -> (TyCon, [Type])
 401 splitNewTyConApp ty = case splitNewTyConApp_maybe ty of
 402                         Just stuff -> stuff
 403                         Nothing    -> pprPanic "splitNewTyConApp" (ppr ty)
 404 splitNewTyConApp_maybe :: Type -> Maybe (TyCon, [Type])
 405 splitNewTyConApp_maybe ty | Just ty' <- tcView ty = splitNewTyConApp_maybe ty'
 406 splitNewTyConApp_maybe (TyConApp tc tys) = Just (tc, tys)
 407 splitNewTyConApp_maybe (FunTy arg res)   = Just (funTyCon, [arg,res])
 408 splitNewTyConApp_maybe other          = Nothing
 409
 410 -- get instantiated newtype rhs, the arguments had better saturate
 411 -- the constructor
 412 newTyConInstRhs :: TyCon -> [Type] -> Type
 413 newTyConInstRhs tycon tys =
 414     let (tvs, ty) = newTyConRhs tycon in substTyWith tvs tys ty
 415 \end{code}
 416
 417
 418 ---------------------------------------------------------------------
 419                                 SynTy
 420                                 ~~~~~
 421
 422 Notes on type synonyms
 423 ~~~~~~~~~~~~~~~~~~~~~~
 424 The various "split" functions (splitFunTy, splitRhoTy, splitForAllTy) try
 425 to return type synonyms whereever possible. Thus
 426
 427         type Foo a = a -> a
 428
 429 we want
 430         splitFunTys (a -> Foo a) = ([a], Foo a)
 431 not                                ([a], a -> a)
 432
 433 The reason is that we then get better (shorter) type signatures in
 434 interfaces.  Notably this plays a role in tcTySigs in TcBinds.lhs.
 435
 436
 437                 Representation types
 438                 ~~~~~~~~~~~~~~~~~~~~
 439 repType looks through
 440         (a) for-alls, and
 441         (b) synonyms
 442         (c) predicates
 443         (d) usage annotations
 444         (e) all newtypes, including recursive ones, but not newtype families
 445 It's useful in the back end.
 446
 447 \begin{code}
 448 repType :: Type -> Type
 449 -- Only applied to types of kind *; hence tycons are saturated
 450 repType ty | Just ty' <- coreView ty = repType ty'
 451 repType (ForAllTy _ ty)  = repType ty
 452 repType (TyConApp tc tys)
 453   | isClosedNewTyCon tc  = -- Recursive newtypes are opaque to coreView
 454                            -- but we must expand them here.  Sure to
 455                            -- be saturated because repType is only applied
 456                            -- to types of kind *
 457                            ASSERT( {- isRecursiveTyCon tc && -} tys `lengthIs` tyConArity tc )
 458                            repType (new_type_rep tc tys)
 459 repType ty = ty
 460
 461 -- repType' aims to be a more thorough version of repType
 462 -- For now it simply looks through the TyConApp args too
 463 repType' ty -- | pprTrace "repType'" (ppr ty $$ ppr (go1 ty)) False = undefined
 464             | otherwise = go1 ty
 465  where
 466         go1 = go . repType
 467         go (TyConApp tc tys) = mkTyConApp tc (map repType' tys)
 468         go ty = ty
 469
 470
 471 -- new_type_rep doesn't ask any questions:
 472 -- it just expands newtype, whether recursive or not
 473 new_type_rep new_tycon tys = ASSERT( tys `lengthIs` tyConArity new_tycon )
 474                              case newTyConRep new_tycon of
 475                                  (tvs, rep_ty) -> substTyWith tvs tys rep_ty
 476
 477 -- ToDo: this could be moved to the code generator, using splitTyConApp instead
 478 -- of inspecting the type directly.
 479 typePrimRep :: Type -> PrimRep
 480 typePrimRep ty = case repType ty of
 481                    TyConApp tc _ -> tyConPrimRep tc
 482                    FunTy _ _     -> PtrRep
 483                    AppTy _ _     -> PtrRep      -- See note below
 484                    TyVarTy _     -> PtrRep
 485                    other         -> pprPanic "typePrimRep" (ppr ty)
 486         -- Types of the form 'f a' must be of kind *, not *#, so
 487         -- we are guaranteed that they are represented by pointers.
 488         -- The reason is that f must have kind *->*, not *->*#, because
 489         -- (we claim) there is no way to constrain f's kind any other
 490         -- way.
 491
 492 \end{code}
 493
 494
 495 ---------------------------------------------------------------------
 496                                 ForAllTy
 497                                 ~~~~~~~~
 498
 499 \begin{code}
 500 mkForAllTy :: TyVar -> Type -> Type
 501 mkForAllTy tyvar ty
 502   = mkForAllTys [tyvar] ty
 503
 504 mkForAllTys :: [TyVar] -> Type -> Type
 505 mkForAllTys tyvars ty = foldr ForAllTy ty tyvars
 506
 507 isForAllTy :: Type -> Bool
 508 isForAllTy (NoteTy _ ty)  = isForAllTy ty
 509 isForAllTy (ForAllTy _ _) = True
 510 isForAllTy other_ty       = False
 511
 512 splitForAllTy_maybe :: Type -> Maybe (TyVar, Type)
 513 splitForAllTy_maybe ty = splitFAT_m ty
 514   where
 515     splitFAT_m ty | Just ty' <- coreView ty = splitFAT_m ty'
 516     splitFAT_m (ForAllTy tyvar ty)          = Just(tyvar, ty)
 517     splitFAT_m _                            = Nothing
 518
 519 splitForAllTys :: Type -> ([TyVar], Type)
 520 splitForAllTys ty = split ty ty []
 521    where
 522      split orig_ty ty tvs | Just ty' <- coreView ty = split orig_ty ty' tvs
 523      split orig_ty (ForAllTy tv ty)  tvs = split ty ty (tv:tvs)
 524      split orig_ty t                 tvs = (reverse tvs, orig_ty)
 525
 526 dropForAlls :: Type -> Type
 527 dropForAlls ty = snd (splitForAllTys ty)
 528 \end{code}
 529
 530 -- (mkPiType now in CoreUtils)
 531
 532 applyTy, applyTys
 533 ~~~~~~~~~~~~~~~~~
 534 Instantiate a for-all type with one or more type arguments.
 535 Used when we have a polymorphic function applied to type args:
 536         f t1 t2
 537 Then we use (applyTys type-of-f [t1,t2]) to compute the type of
 538 the expression.
 539
 540 \begin{code}
 541 applyTy :: Type -> Type -> Type
 542 applyTy ty arg | Just ty' <- coreView ty = applyTy ty' arg
 543 applyTy (ForAllTy tv ty) arg = substTyWith [tv] [arg] ty
 544 applyTy other            arg = panic "applyTy"
 545
 546 applyTys :: Type -> [Type] -> Type
 547 -- This function is interesting because
 548 --      a) the function may have more for-alls than there are args
 549 --      b) less obviously, it may have fewer for-alls
 550 -- For case (b) think of
 551 --      applyTys (forall a.a) [forall b.b, Int]
 552 -- This really can happen, via dressing up polymorphic types with newtype
 553 -- clothing.  Here's an example:
 554 --      newtype R = R (forall a. a->a)
 555 --      foo = case undefined :: R of
 556 --              R f -> f ()
 557
 558 applyTys orig_fun_ty []      = orig_fun_ty
 559 applyTys orig_fun_ty arg_tys
 560   | n_tvs == n_args     -- The vastly common case
 561   = substTyWith tvs arg_tys rho_ty
 562   | n_tvs > n_args      -- Too many for-alls
 563   = substTyWith (take n_args tvs) arg_tys
 564                 (mkForAllTys (drop n_args tvs) rho_ty)
 565   | otherwise           -- Too many type args
 566   = ASSERT2( n_tvs > 0, ppr orig_fun_ty )       -- Zero case gives infnite loop!
 567     applyTys (substTyWith tvs (take n_tvs arg_tys) rho_ty)
 568              (drop n_tvs arg_tys)
 569   where
 570     (tvs, rho_ty) = splitForAllTys orig_fun_ty
 571     n_tvs = length tvs
 572     n_args = length arg_tys
 573 \end{code}
 574
 575
 576 %************************************************************************
 577 %*                                                                      *
 578 \subsection{Source types}
 579 %*                                                                      *
 580 %************************************************************************
 581
 582 A "source type" is a type that is a separate type as far as the type checker is
 583 concerned, but which has low-level representation as far as the back end is concerned.
 584
 585 Source types are always lifted.
 586
 587 The key function is predTypeRep which gives the representation of a source type:
 588
 589 \begin{code}
 590 mkPredTy :: PredType -> Type
 591 mkPredTy pred = PredTy pred
 592
 593 mkPredTys :: ThetaType -> [Type]
 594 mkPredTys preds = map PredTy preds
 595
 596 predTypeRep :: PredType -> Type
 597 -- Convert a PredType to its "representation type";
 598 -- the post-type-checking type used by all the Core passes of GHC.
 599 -- Unwraps only the outermost level; for example, the result might
 600 -- be a newtype application
 601 predTypeRep (IParam _ ty)     = ty
 602 predTypeRep (ClassP clas tys) = mkTyConApp (classTyCon clas) tys
 603         -- Result might be a newtype application, but the consumer will
 604         -- look through that too if necessary
 605 predTypeRep (EqPred ty1 ty2) = pprPanic "predTypeRep" (ppr (EqPred ty1 ty2))
 606
 607 mkFamilyTyConApp :: TyCon -> [Type] -> Type
 608 -- Given a family instance TyCon and its arg types, return the
 609 -- corresponding family type.  E.g.
 610 --      data family T a
 611 --      data instance T (Maybe b) = MkT b       -- Instance tycon :RTL
 612 -- Then
 613 --      mkFamilyTyConApp :RTL Int  =  T (Maybe Int)
 614 mkFamilyTyConApp tc tys
 615   | Just (fam_tc, fam_tys) <- tyConFamInst_maybe tc
 616   , let fam_subst = zipTopTvSubst (tyConTyVars tc) tys
 617   = mkTyConApp fam_tc (substTys fam_subst fam_tys)
 618   | otherwise
 619   = mkTyConApp tc tys
 620
 621 -- Pretty prints a tycon, using the family instance in case of a
 622 -- representation tycon.  For example
 623 --      e.g.  data T [a] = ...
 624 -- In that case we want to print `T [a]', where T is the family TyCon
 625 pprSourceTyCon tycon
 626   | Just (fam_tc, tys) <- tyConFamInst_maybe tycon
 627   = ppr $ fam_tc `TyConApp` tys        -- can't be FunTyCon
 628   | otherwise
 629   = ppr tycon
 630 \end{code}
 631
 632
 633 %************************************************************************
 634 %*                                                                      *
 635 \subsection{Kinds and free variables}
 636 %*                                                                      *
 637 %************************************************************************
 638
 639 ---------------------------------------------------------------------
 640                 Finding the kind of a type
 641                 ~~~~~~~~~~~~~~~~~~~~~~~~~~
 642 \begin{code}
 643 typeKind :: Type -> Kind
 644 typeKind (TyConApp tycon tys) = ASSERT( not (isCoercionTyCon tycon) )
 645                                    -- We should be looking for the coercion kind,
 646                                    -- not the type kind
 647                                 foldr (\_ k -> kindFunResult k) (tyConKind tycon) tys
 648 typeKind (NoteTy _ ty)        = typeKind ty
 649 typeKind (PredTy pred)        = predKind pred
 650 typeKind (AppTy fun arg)      = kindFunResult (typeKind fun)
 651 typeKind (ForAllTy tv ty)     = typeKind ty
 652 typeKind (TyVarTy tyvar)      = tyVarKind tyvar
 653 typeKind (FunTy arg res)
 654     -- Hack alert.  The kind of (Int -> Int#) is liftedTypeKind (*),
 655     --              not unliftedTypKind (#)
 656     -- The only things that can be after a function arrow are
 657     --   (a) types (of kind openTypeKind or its sub-kinds)
 658     --   (b) kinds (of super-kind TY) (e.g. * -> (* -> *))
 659     | isTySuperKind k         = k
 660     | otherwise               = ASSERT( isSubOpenTypeKind k) liftedTypeKind
 661     where
 662       k = typeKind res
 663
 664 predKind :: PredType -> Kind
 665 predKind (EqPred {}) = coSuperKind      -- A coercion kind!
 666 predKind (ClassP {}) = liftedTypeKind   -- Class and implicitPredicates are
 667 predKind (IParam {}) = liftedTypeKind   -- always represented by lifted types
 668 \end{code}
 669
 670
 671 ---------------------------------------------------------------------
 672                 Free variables of a type
 673                 ~~~~~~~~~~~~~~~~~~~~~~~~
 674 \begin{code}
 675 tyVarsOfType :: Type -> TyVarSet
 676 -- NB: for type synonyms tyVarsOfType does *not* expand the synonym
 677 tyVarsOfType (TyVarTy tv)               = unitVarSet tv
 678 tyVarsOfType (TyConApp tycon tys)       = tyVarsOfTypes tys
 679 tyVarsOfType (NoteTy (FTVNote tvs) ty2) = tvs
 680 tyVarsOfType (PredTy sty)               = tyVarsOfPred sty
 681 tyVarsOfType (FunTy arg res)            = tyVarsOfType arg `unionVarSet` tyVarsOfType res
 682 tyVarsOfType (AppTy fun arg)            = tyVarsOfType fun `unionVarSet` tyVarsOfType arg
 683 tyVarsOfType (ForAllTy tyvar ty)        = delVarSet (tyVarsOfType ty) tyvar
 684
 685 tyVarsOfTypes :: [Type] -> TyVarSet
 686 tyVarsOfTypes tys = foldr (unionVarSet.tyVarsOfType) emptyVarSet tys
 687
 688 tyVarsOfPred :: PredType -> TyVarSet
 689 tyVarsOfPred (IParam _ ty)    = tyVarsOfType ty
 690 tyVarsOfPred (ClassP _ tys)   = tyVarsOfTypes tys
 691 tyVarsOfPred (EqPred ty1 ty2) = tyVarsOfType ty1 `unionVarSet` tyVarsOfType ty2
 692
 693 tyVarsOfTheta :: ThetaType -> TyVarSet
 694 tyVarsOfTheta = foldr (unionVarSet . tyVarsOfPred) emptyVarSet
 695
 696 -- Add a Note with the free tyvars to the top of the type
 697 addFreeTyVars :: Type -> Type
 698 addFreeTyVars ty@(NoteTy (FTVNote _) _)      = ty
 699 addFreeTyVars ty                             = NoteTy (FTVNote (tyVarsOfType ty)) ty
 700 \end{code}
 701
 702
 703 %************************************************************************
 704 %*                                                                      *
 705 \subsection{TidyType}
 706 %*                                                                      *
 707 %************************************************************************
 708
 709 tidyTy tidies up a type for printing in an error message, or in
 710 an interface file.
 711
 712 It doesn't change the uniques at all, just the print names.
 713
 714 \begin{code}
 715 tidyTyVarBndr :: TidyEnv -> TyVar -> (TidyEnv, TyVar)
 716 tidyTyVarBndr env@(tidy_env, subst) tyvar
 717   = case tidyOccName tidy_env (getOccName name) of
 718       (tidy', occ') -> ((tidy', subst'), tyvar'')
 719         where
 720           subst' = extendVarEnv subst tyvar tyvar''
 721           tyvar' = setTyVarName tyvar name'
 722           name'  = tidyNameOcc name occ'
 723                 -- Don't forget to tidy the kind for coercions!
 724           tyvar'' | isCoVar tyvar = setTyVarKind tyvar' kind'
 725                   | otherwise     = tyvar'
 726           kind'  = tidyType env (tyVarKind tyvar)
 727   where
 728     name = tyVarName tyvar
 729
 730 tidyFreeTyVars :: TidyEnv -> TyVarSet -> TidyEnv
 731 -- Add the free tyvars to the env in tidy form,
 732 -- so that we can tidy the type they are free in
 733 tidyFreeTyVars env tyvars = fst (tidyOpenTyVars env (varSetElems tyvars))
 734
 735 tidyOpenTyVars :: TidyEnv -> [TyVar] -> (TidyEnv, [TyVar])
 736 tidyOpenTyVars env tyvars = mapAccumL tidyOpenTyVar env tyvars
 737
 738 tidyOpenTyVar :: TidyEnv -> TyVar -> (TidyEnv, TyVar)
 739 -- Treat a new tyvar as a binder, and give it a fresh tidy name
 740 tidyOpenTyVar env@(tidy_env, subst) tyvar
 741   = case lookupVarEnv subst tyvar of
 742         Just tyvar' -> (env, tyvar')            -- Already substituted
 743         Nothing     -> tidyTyVarBndr env tyvar  -- Treat it as a binder
 744
 745 tidyType :: TidyEnv -> Type -> Type
 746 tidyType env@(tidy_env, subst) ty
 747   = go ty
 748   where
 749     go (TyVarTy tv)         = case lookupVarEnv subst tv of
 750                                 Nothing  -> TyVarTy tv
 751                                 Just tv' -> TyVarTy tv'
 752     go (TyConApp tycon tys) = let args = map go tys
 753                               in args `seqList` TyConApp tycon args
 754     go (NoteTy note ty)     = (NoteTy $! (go_note note)) $! (go ty)
 755     go (PredTy sty)         = PredTy (tidyPred env sty)
 756     go (AppTy fun arg)      = (AppTy $! (go fun)) $! (go arg)
 757     go (FunTy fun arg)      = (FunTy $! (go fun)) $! (go arg)
 758     go (ForAllTy tv ty)     = ForAllTy tvp $! (tidyType envp ty)
 759                               where
 760                                 (envp, tvp) = tidyTyVarBndr env tv
 761
 762     go_note note@(FTVNote ftvs) = note  -- No need to tidy the free tyvars
 763
 764 tidyTypes env tys = map (tidyType env) tys
 765
 766 tidyPred :: TidyEnv -> PredType -> PredType
 767 tidyPred env (IParam n ty)     = IParam n (tidyType env ty)
 768 tidyPred env (ClassP clas tys) = ClassP clas (tidyTypes env tys)
 769 tidyPred env (EqPred ty1 ty2)  = EqPred (tidyType env ty1) (tidyType env ty2)
 770 \end{code}
 771
 772
 773 @tidyOpenType@ grabs the free type variables, tidies them
 774 and then uses @tidyType@ to work over the type itself
 775
 776 \begin{code}
 777 tidyOpenType :: TidyEnv -> Type -> (TidyEnv, Type)
 778 tidyOpenType env ty
 779   = (env', tidyType env' ty)
 780   where
 781     env' = tidyFreeTyVars env (tyVarsOfType ty)
 782
 783 tidyOpenTypes :: TidyEnv -> [Type] -> (TidyEnv, [Type])
 784 tidyOpenTypes env tys = mapAccumL tidyOpenType env tys
 785
 786 tidyTopType :: Type -> Type
 787 tidyTopType ty = tidyType emptyTidyEnv ty
 788 \end{code}
 789
 790 \begin{code}
 791
 792 tidyKind :: TidyEnv -> Kind -> (TidyEnv, Kind)
 793 tidyKind env k = tidyOpenType env k
 794
 795 \end{code}
 796
 797
 798 %************************************************************************
 799 %*                                                                      *
 800 \subsection{Liftedness}
 801 %*                                                                      *
 802 %************************************************************************
 803
 804 \begin{code}
 805 isUnLiftedType :: Type -> Bool
 806         -- isUnLiftedType returns True for forall'd unlifted types:
 807         --      x :: forall a. Int#
 808         -- I found bindings like these were getting floated to the top level.
 809         -- They are pretty bogus types, mind you.  It would be better never to
 810         -- construct them
 811
 812 isUnLiftedType ty | Just ty' <- coreView ty = isUnLiftedType ty'
 813 isUnLiftedType (ForAllTy tv ty)  = isUnLiftedType ty
 814 isUnLiftedType (TyConApp tc _)   = isUnLiftedTyCon tc
 815 isUnLiftedType other             = False
 816
 817 isUnboxedTupleType :: Type -> Bool
 818 isUnboxedTupleType ty = case splitTyConApp_maybe ty of
 819                            Just (tc, ty_args) -> isUnboxedTupleTyCon tc
 820                            other              -> False
 821
 822 -- Should only be applied to *types*; hence the assert
 823 isAlgType :: Type -> Bool
 824 isAlgType ty = case splitTyConApp_maybe ty of
 825                         Just (tc, ty_args) -> ASSERT( ty_args `lengthIs` tyConArity tc )
 826                                               isAlgTyCon tc
 827                         other              -> False
 828 \end{code}
 829
 830 @isStrictType@ computes whether an argument (or let RHS) should
 831 be computed strictly or lazily, based only on its type.
 832 Works just like isUnLiftedType, except that it has a special case
 833 for dictionaries.  Since it takes account of ClassP, you might think
 834 this function should be in TcType, but isStrictType is used by DataCon,
 835 which is below TcType in the hierarchy, so it's convenient to put it here.
 836
 837 \begin{code}
 838 isStrictType (PredTy pred)     = isStrictPred pred
 839 isStrictType ty | Just ty' <- coreView ty = isStrictType ty'
 840 isStrictType (ForAllTy tv ty)  = isStrictType ty
 841 isStrictType (TyConApp tc _)   = isUnLiftedTyCon tc
 842 isStrictType other             = False
 843
 844 isStrictPred (ClassP clas _) = opt_DictsStrict && not (isNewTyCon (classTyCon clas))
 845 isStrictPred other           = False
 846         -- We may be strict in dictionary types, but only if it
 847         -- has more than one component.
 848         -- [Being strict in a single-component dictionary risks
 849         --  poking the dictionary component, which is wrong.]
 850 \end{code}
 851
 852 \begin{code}
 853 isPrimitiveType :: Type -> Bool
 854 -- Returns types that are opaque to Haskell.
 855 -- Most of these are unlifted, but now that we interact with .NET, we
 856 -- may have primtive (foreign-imported) types that are lifted
 857 isPrimitiveType ty = case splitTyConApp_maybe ty of
 858                         Just (tc, ty_args) -> ASSERT( ty_args `lengthIs` tyConArity tc )
 859                                               isPrimTyCon tc
 860                         other              -> False
 861 \end{code}
 862
 863
 864 %************************************************************************
 865 %*                                                                      *
 866 \subsection{Sequencing on types
 867 %*                                                                      *
 868 %************************************************************************
 869
 870 \begin{code}
 871 seqType :: Type -> ()
 872 seqType (TyVarTy tv)      = tv `seq` ()
 873 seqType (AppTy t1 t2)     = seqType t1 `seq` seqType t2
 874 seqType (FunTy t1 t2)     = seqType t1 `seq` seqType t2
 875 seqType (NoteTy note t2)  = seqNote note `seq` seqType t2
 876 seqType (PredTy p)        = seqPred p
 877 seqType (TyConApp tc tys) = tc `seq` seqTypes tys
 878 seqType (ForAllTy tv ty)  = tv `seq` seqType ty
 879
 880 seqTypes :: [Type] -> ()
 881 seqTypes []       = ()
 882 seqTypes (ty:tys) = seqType ty `seq` seqTypes tys
 883
 884 seqNote :: TyNote -> ()
 885 seqNote (FTVNote set) = sizeUniqSet set `seq` ()
 886
 887 seqPred :: PredType -> ()
 888 seqPred (ClassP c tys)   = c `seq` seqTypes tys
 889 seqPred (IParam n ty)    = n `seq` seqType ty
 890 seqPred (EqPred ty1 ty2) = seqType ty1 `seq` seqType ty2
 891 \end{code}
 892
 893
 894 %************************************************************************
 895 %*                                                                      *
 896                 Equality for Core types
 897         (We don't use instances so that we know where it happens)
 898 %*                                                                      *
 899 %************************************************************************
 900
 901 Note that eqType works right even for partial applications of newtypes.
 902 See Note [Newtype eta] in TyCon.lhs
 903
 904 \begin{code}
 905 coreEqType :: Type -> Type -> Bool
 906 coreEqType t1 t2
 907   = eq rn_env t1 t2
 908   where
 909     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfType t1 `unionVarSet` tyVarsOfType t2))
 910
 911     eq env (TyVarTy tv1)       (TyVarTy tv2)     = rnOccL env tv1 == rnOccR env tv2
 912     eq env (ForAllTy tv1 t1)   (ForAllTy tv2 t2) = eq (rnBndr2 env tv1 tv2) t1 t2
 913     eq env (AppTy s1 t1)       (AppTy s2 t2)     = eq env s1 s2 && eq env t1 t2
 914     eq env (FunTy s1 t1)       (FunTy s2 t2)     = eq env s1 s2 && eq env t1 t2
 915     eq env (TyConApp tc1 tys1) (TyConApp tc2 tys2)
 916         | tc1 == tc2, all2 (eq env) tys1 tys2 = True
 917                         -- The lengths should be equal because
 918                         -- the two types have the same kind
 919         -- NB: if the type constructors differ that does not
 920         --     necessarily mean that the types aren't equal
 921         --     (synonyms, newtypes)
 922         -- Even if the type constructors are the same, but the arguments
 923         -- differ, the two types could be the same (e.g. if the arg is just
 924         -- ignored in the RHS).  In both these cases we fall through to an
 925         -- attempt to expand one side or the other.
 926
 927         -- Now deal with newtypes, synonyms, pred-tys
 928     eq env t1 t2 | Just t1' <- coreView t1 = eq env t1' t2
 929                  | Just t2' <- coreView t2 = eq env t1 t2'
 930
 931         -- Fall through case; not equal!
 932     eq env t1 t2 = False
 933 \end{code}
 934
 935
 936 %************************************************************************
 937 %*                                                                      *
 938                 Comparision for source types
 939         (We don't use instances so that we know where it happens)
 940 %*                                                                      *
 941 %************************************************************************
 942
 943 Note that
 944         tcEqType, tcCmpType
 945 do *not* look through newtypes, PredTypes
 946
 947 \begin{code}
 948 tcEqType :: Type -> Type -> Bool
 949 tcEqType t1 t2 = isEqual $ cmpType t1 t2
 950
 951 tcEqTypes :: [Type] -> [Type] -> Bool
 952 tcEqTypes tys1 tys2 = isEqual $ cmpTypes tys1 tys2
 953
 954 tcCmpType :: Type -> Type -> Ordering
 955 tcCmpType t1 t2 = cmpType t1 t2
 956
 957 tcCmpTypes :: [Type] -> [Type] -> Ordering
 958 tcCmpTypes tys1 tys2 = cmpTypes tys1 tys2
 959
 960 tcEqPred :: PredType -> PredType -> Bool
 961 tcEqPred p1 p2 = isEqual $ cmpPred p1 p2
 962
 963 tcCmpPred :: PredType -> PredType -> Ordering
 964 tcCmpPred p1 p2 = cmpPred p1 p2
 965
 966 tcEqTypeX :: RnEnv2 -> Type -> Type -> Bool
 967 tcEqTypeX env t1 t2 = isEqual $ cmpTypeX env t1 t2
 968 \end{code}
 969
 970 Now here comes the real worker
 971
 972 \begin{code}
 973 cmpType :: Type -> Type -> Ordering
 974 cmpType t1 t2 = cmpTypeX rn_env t1 t2
 975   where
 976     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfType t1 `unionVarSet` tyVarsOfType t2))
 977
 978 cmpTypes :: [Type] -> [Type] -> Ordering
 979 cmpTypes ts1 ts2 = cmpTypesX rn_env ts1 ts2
 980   where
 981     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfTypes ts1 `unionVarSet` tyVarsOfTypes ts2))
 982
 983 cmpPred :: PredType -> PredType -> Ordering
 984 cmpPred p1 p2 = cmpPredX rn_env p1 p2
 985   where
 986     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfPred p1 `unionVarSet` tyVarsOfPred p2))
 987
 988 cmpTypeX :: RnEnv2 -> Type -> Type -> Ordering  -- Main workhorse
 989 cmpTypeX env t1 t2 | Just t1' <- tcView t1 = cmpTypeX env t1' t2
 990                    | Just t2' <- tcView t2 = cmpTypeX env t1 t2'
 991
 992 cmpTypeX env (TyVarTy tv1)       (TyVarTy tv2)       = rnOccL env tv1 `compare` rnOccR env tv2
 993 cmpTypeX env (ForAllTy tv1 t1)   (ForAllTy tv2 t2)   = cmpTypeX (rnBndr2 env tv1 tv2) t1 t2
 994 cmpTypeX env (AppTy s1 t1)       (AppTy s2 t2)       = cmpTypeX env s1 s2 `thenCmp` cmpTypeX env t1 t2
 995 cmpTypeX env (FunTy s1 t1)       (FunTy s2 t2)       = cmpTypeX env s1 s2 `thenCmp` cmpTypeX env t1 t2
 996 cmpTypeX env (PredTy p1)         (PredTy p2)         = cmpPredX env p1 p2
 997 cmpTypeX env (TyConApp tc1 tys1) (TyConApp tc2 tys2) = (tc1 `compare` tc2) `thenCmp` cmpTypesX env tys1 tys2
 998 cmpTypeX env t1                 (NoteTy _ t2)        = cmpTypeX env t1 t2
 999
1000     -- Deal with the rest: TyVarTy < AppTy < FunTy < TyConApp < ForAllTy < PredTy
1001 cmpTypeX env (AppTy _ _) (TyVarTy _) = GT
1002
1003 cmpTypeX env (FunTy _ _) (TyVarTy _) = GT
1004 cmpTypeX env (FunTy _ _) (AppTy _ _) = GT
1005
1006 cmpTypeX env (TyConApp _ _) (TyVarTy _) = GT
1007 cmpTypeX env (TyConApp _ _) (AppTy _ _) = GT
1008 cmpTypeX env (TyConApp _ _) (FunTy _ _) = GT
1009
1010 cmpTypeX env (ForAllTy _ _) (TyVarTy _)    = GT
1011 cmpTypeX env (ForAllTy _ _) (AppTy _ _)    = GT
1012 cmpTypeX env (ForAllTy _ _) (FunTy _ _)    = GT
1013 cmpTypeX env (ForAllTy _ _) (TyConApp _ _) = GT
1014
1015 cmpTypeX env (PredTy _)   t2            = GT
1016
1017 cmpTypeX env _ _ = LT
1018
1019 -------------
1020 cmpTypesX :: RnEnv2 -> [Type] -> [Type] -> Ordering
1021 cmpTypesX env []        []        = EQ
1022 cmpTypesX env (t1:tys1) (t2:tys2) = cmpTypeX env t1 t2 `thenCmp` cmpTypesX env tys1 tys2
1023 cmpTypesX env []        tys       = LT
1024 cmpTypesX env ty        []        = GT
1025
1026 -------------
1027 cmpPredX :: RnEnv2 -> PredType -> PredType -> Ordering
1028 cmpPredX env (IParam n1 ty1) (IParam n2 ty2) = (n1 `compare` n2) `thenCmp` cmpTypeX env ty1 ty2
1029         -- Compare names only for implicit parameters
1030         -- This comparison is used exclusively (I believe)
1031         -- for the Avails finite map built in TcSimplify
1032         -- If the types differ we keep them distinct so that we see
1033         -- a distinct pair to run improvement on
1034 cmpPredX env (ClassP c1 tys1) (ClassP c2 tys2) = (c1 `compare` c2) `thenCmp` (cmpTypesX env tys1 tys2)
1035 cmpPredX env (EqPred ty1 ty2) (EqPred ty1' ty2') = (cmpTypeX env ty1 ty1') `thenCmp` (cmpTypeX env ty2 ty2')
1036
1037 -- Constructor order: IParam < ClassP < EqPred
1038 cmpPredX env (IParam {})     _              = LT
1039 cmpPredX env (ClassP {})    (IParam {})     = GT
1040 cmpPredX env (ClassP {})    (EqPred {})     = LT
1041 cmpPredX env (EqPred {})    _               = GT
1042 \end{code}
1043
1044 PredTypes are used as a FM key in TcSimplify,
1045 so we take the easy path and make them an instance of Ord
1046
1047 \begin{code}
1048 instance Eq  PredType where { (==)    = tcEqPred }
1049 instance Ord PredType where { compare = tcCmpPred }
1050 \end{code}
1051
1052
1053 %************************************************************************
1054 %*                                                                      *
1055                 Type substitutions
1056 %*                                                                      *
1057 %************************************************************************
1058
1059 \begin{code}
1060 data TvSubst
1061   = TvSubst InScopeSet  -- The in-scope type variables
1062             TvSubstEnv  -- The substitution itself
1063         -- See Note [Apply Once]
1064         -- and Note [Extending the TvSubstEnv]
1065
1066 {- ----------------------------------------------------------
1067
1068 Note [Apply Once]
1069 ~~~~~~~~~~~~~~~~~
1070 We use TvSubsts to instantiate things, and we might instantiate
1071         forall a b. ty
1072 \with the types
1073         [a, b], or [b, a].
1074 So the substition might go [a->b, b->a].  A similar situation arises in Core
1075 when we find a beta redex like
1076         (/\ a /\ b -> e) b a
1077 Then we also end up with a substition that permutes type variables. Other
1078 variations happen to; for example [a -> (a, b)].
1079
1080         ***************************************************
1081         *** So a TvSubst must be applied precisely once ***
1082         ***************************************************
1083
1084 A TvSubst is not idempotent, but, unlike the non-idempotent substitution
1085 we use during unifications, it must not be repeatedly applied.
1086
1087 Note [Extending the TvSubst]
1088 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1089 The following invariant should hold of a TvSubst
1090
1091         The in-scope set is needed *only* to
1092         guide the generation of fresh uniques
1093
1094         In particular, the *kind* of the type variables in
1095         the in-scope set is not relevant
1096
1097 This invariant allows a short-cut when the TvSubstEnv is empty:
1098 if the TvSubstEnv is empty --- i.e. (isEmptyTvSubt subst) holds ---
1099 then (substTy subst ty) does nothing.
1100
1101 For example, consider:
1102         (/\a. /\b:(a~Int). ...b..) Int
1103 We substitute Int for 'a'.  The Unique of 'b' does not change, but
1104 nevertheless we add 'b' to the TvSubstEnv, because b's type does change
1105
1106 This invariant has several crucial consequences:
1107
1108 * In substTyVarBndr, we need extend the TvSubstEnv
1109         - if the unique has changed
1110         - or if the kind has changed
1111
1112 * In substTyVar, we do not need to consult the in-scope set;
1113   the TvSubstEnv is enough
1114
1115 * In substTy, substTheta, we can short-circuit when the TvSubstEnv is empty
1116
1117
1118 -------------------------------------------------------------- -}
1119
1120
1121 type TvSubstEnv = TyVarEnv Type
1122         -- A TvSubstEnv is used both inside a TvSubst (with the apply-once
1123         -- invariant discussed in Note [Apply Once]), and also independently
1124         -- in the middle of matching, and unification (see Types.Unify)
1125         -- So you have to look at the context to know if it's idempotent or
1126         -- apply-once or whatever
1127 emptyTvSubstEnv :: TvSubstEnv
1128 emptyTvSubstEnv = emptyVarEnv
1129
1130 composeTvSubst :: InScopeSet -> TvSubstEnv -> TvSubstEnv -> TvSubstEnv
1131 -- (compose env1 env2)(x) is env1(env2(x)); i.e. apply env2 then env1
1132 -- It assumes that both are idempotent
1133 -- Typically, env1 is the refinement to a base substitution env2
1134 composeTvSubst in_scope env1 env2
1135   = env1 `plusVarEnv` mapVarEnv (substTy subst1) env2
1136         -- First apply env1 to the range of env2
1137         -- Then combine the two, making sure that env1 loses if
1138         -- both bind the same variable; that's why env1 is the
1139         --  *left* argument to plusVarEnv, because the right arg wins
1140   where
1141     subst1 = TvSubst in_scope env1
1142
1143 emptyTvSubst = TvSubst emptyInScopeSet emptyVarEnv
1144
1145 isEmptyTvSubst :: TvSubst -> Bool
1146          -- See Note [Extending the TvSubstEnv]
1147 isEmptyTvSubst (TvSubst _ env) = isEmptyVarEnv env
1148
1149 mkTvSubst :: InScopeSet -> TvSubstEnv -> TvSubst
1150 mkTvSubst = TvSubst
1151
1152 getTvSubstEnv :: TvSubst -> TvSubstEnv
1153 getTvSubstEnv (TvSubst _ env) = env
1154
1155 getTvInScope :: TvSubst -> InScopeSet
1156 getTvInScope (TvSubst in_scope _) = in_scope
1157
1158 isInScope :: Var -> TvSubst -> Bool
1159 isInScope v (TvSubst in_scope _) = v `elemInScopeSet` in_scope
1160
1161 notElemTvSubst :: TyVar -> TvSubst -> Bool
1162 notElemTvSubst tv (TvSubst _ env) = not (tv `elemVarEnv` env)
1163
1164 setTvSubstEnv :: TvSubst -> TvSubstEnv -> TvSubst
1165 setTvSubstEnv (TvSubst in_scope _) env = TvSubst in_scope env
1166
1167 extendTvInScope :: TvSubst -> [Var] -> TvSubst
1168 extendTvInScope (TvSubst in_scope env) vars = TvSubst (extendInScopeSetList in_scope vars) env
1169
1170 extendTvSubst :: TvSubst -> TyVar -> Type -> TvSubst
1171 extendTvSubst (TvSubst in_scope env) tv ty = TvSubst in_scope (extendVarEnv env tv ty)
1172
1173 extendTvSubstList :: TvSubst -> [TyVar] -> [Type] -> TvSubst
1174 extendTvSubstList (TvSubst in_scope env) tvs tys
1175   = TvSubst in_scope (extendVarEnvList env (tvs `zip` tys))
1176
1177 -- mkOpenTvSubst and zipOpenTvSubst generate the in-scope set from
1178 -- the types given; but it's just a thunk so with a bit of luck
1179 -- it'll never be evaluated
1180
1181 mkOpenTvSubst :: TvSubstEnv -> TvSubst
1182 mkOpenTvSubst env = TvSubst (mkInScopeSet (tyVarsOfTypes (varEnvElts env))) env
1183
1184 zipOpenTvSubst :: [TyVar] -> [Type] -> TvSubst
1185 zipOpenTvSubst tyvars tys
1186 #ifdef DEBUG
1187   | length tyvars /= length tys
1188   = pprTrace "zipOpenTvSubst" (ppr tyvars $$ ppr tys) emptyTvSubst
1189   | otherwise
1190 #endif
1191   = TvSubst (mkInScopeSet (tyVarsOfTypes tys)) (zipTyEnv tyvars tys)
1192
1193 -- mkTopTvSubst is called when doing top-level substitutions.
1194 -- Here we expect that the free vars of the range of the
1195 -- substitution will be empty.
1196 mkTopTvSubst :: [(TyVar, Type)] -> TvSubst
1197 mkTopTvSubst prs = TvSubst emptyInScopeSet (mkVarEnv prs)
1198
1199 zipTopTvSubst :: [TyVar] -> [Type] -> TvSubst
1200 zipTopTvSubst tyvars tys
1201 #ifdef DEBUG
1202   | length tyvars /= length tys
1203   = pprTrace "zipTopTvSubst" (ppr tyvars $$ ppr tys) emptyTvSubst
1204   | otherwise
1205 #endif
1206   = TvSubst emptyInScopeSet (zipTyEnv tyvars tys)
1207
1208 zipTyEnv :: [TyVar] -> [Type] -> TvSubstEnv
1209 zipTyEnv tyvars tys
1210 #ifdef DEBUG
1211   | length tyvars /= length tys
1212   = pprTrace "mkTopTvSubst" (ppr tyvars $$ ppr tys) emptyVarEnv
1213   | otherwise
1214 #endif
1215   = zip_ty_env tyvars tys emptyVarEnv
1216
1217 -- Later substitutions in the list over-ride earlier ones,
1218 -- but there should be no loops
1219 zip_ty_env []       []       env = env
1220 zip_ty_env (tv:tvs) (ty:tys) env = zip_ty_env tvs tys (extendVarEnv env tv ty)
1221         -- There used to be a special case for when
1222         --      ty == TyVarTy tv
1223         -- (a not-uncommon case) in which case the substitution was dropped.
1224         -- But the type-tidier changes the print-name of a type variable without
1225         -- changing the unique, and that led to a bug.   Why?  Pre-tidying, we had
1226         -- a type {Foo t}, where Foo is a one-method class.  So Foo is really a newtype.
1227         -- And it happened that t was the type variable of the class.  Post-tiding,
1228         -- it got turned into {Foo t2}.  The ext-core printer expanded this using
1229         -- sourceTypeRep, but that said "Oh, t == t2" because they have the same unique,
1230         -- and so generated a rep type mentioning t not t2.
1231         --
1232         -- Simplest fix is to nuke the "optimisation"
1233 zip_ty_env tvs      tys      env   = pprTrace "Var/Type length mismatch: " (ppr tvs $$ ppr tys) env
1234 -- zip_ty_env _ _ env = env
1235
1236 instance Outputable TvSubst where
1237   ppr (TvSubst ins env)
1238     = brackets $ sep[ ptext SLIT("TvSubst"),
1239                       nest 2 (ptext SLIT("In scope:") <+> ppr ins),
1240                       nest 2 (ptext SLIT("Env:") <+> ppr env) ]
1241 \end{code}
1242
1243 %************************************************************************
1244 %*                                                                      *
1245                 Performing type substitutions
1246 %*                                                                      *
1247 %************************************************************************
1248
1249 \begin{code}
1250 substTyWith :: [TyVar] -> [Type] -> Type -> Type
1251 substTyWith tvs tys = ASSERT( length tvs == length tys )
1252                       substTy (zipOpenTvSubst tvs tys)
1253
1254 substTy :: TvSubst -> Type  -> Type
1255 substTy subst ty | isEmptyTvSubst subst = ty
1256                  | otherwise            = subst_ty subst ty
1257
1258 substTys :: TvSubst -> [Type] -> [Type]
1259 substTys subst tys | isEmptyTvSubst subst = tys
1260                    | otherwise            = map (subst_ty subst) tys
1261
1262 substTheta :: TvSubst -> ThetaType -> ThetaType
1263 substTheta subst theta
1264   | isEmptyTvSubst subst = theta
1265   | otherwise            = map (substPred subst) theta
1266
1267 substPred :: TvSubst -> PredType -> PredType
1268 substPred subst (IParam n ty)     = IParam n (subst_ty subst ty)
1269 substPred subst (ClassP clas tys) = ClassP clas (map (subst_ty subst) tys)
1270 substPred subst (EqPred ty1 ty2)  = EqPred (subst_ty subst ty1) (subst_ty subst ty2)
1271
1272 deShadowTy :: TyVarSet -> Type -> Type  -- Remove any nested binders mentioning tvs
1273 deShadowTy tvs ty
1274   = subst_ty (mkTvSubst in_scope emptyTvSubstEnv) ty
1275   where
1276     in_scope = mkInScopeSet tvs
1277
1278 subst_ty :: TvSubst -> Type -> Type
1279 -- subst_ty is the main workhorse for type substitution
1280 --
1281 -- Note that the in_scope set is poked only if we hit a forall
1282 -- so it may often never be fully computed
1283 subst_ty subst ty
1284    = go ty
1285   where
1286     go (TyVarTy tv)                = substTyVar subst tv
1287     go (TyConApp tc tys)           = let args = map go tys
1288                                      in  args `seqList` TyConApp tc args
1289
1290     go (PredTy p)                  = PredTy $! (substPred subst p)
1291
1292     go (NoteTy (FTVNote _) ty2)    = go ty2             -- Discard the free tyvar note
1293
1294     go (FunTy arg res)             = (FunTy $! (go arg)) $! (go res)
1295     go (AppTy fun arg)             = mkAppTy (go fun) $! (go arg)
1296                 -- The mkAppTy smart constructor is important
1297                 -- we might be replacing (a Int), represented with App
1298                 -- by [Int], represented with TyConApp
1299     go (ForAllTy tv ty)            = case substTyVarBndr subst tv of
1300                                         (subst', tv') -> ForAllTy tv' $! (subst_ty subst' ty)
1301
1302 substTyVar :: TvSubst -> TyVar  -> Type
1303 substTyVar subst@(TvSubst in_scope env) tv
1304   = case lookupTyVar subst tv of {
1305         Nothing -> TyVarTy tv;
1306         Just ty -> ty   -- See Note [Apply Once]
1307     }
1308
1309 substTyVars :: TvSubst -> [TyVar] -> [Type]
1310 substTyVars subst tvs = map (substTyVar subst) tvs
1311
1312 lookupTyVar :: TvSubst -> TyVar  -> Maybe Type
1313         -- See Note [Extending the TvSubst]
1314 lookupTyVar (TvSubst in_scope env) tv = lookupVarEnv env tv
1315
1316 substTyVarBndr :: TvSubst -> TyVar -> (TvSubst, TyVar)
1317 substTyVarBndr subst@(TvSubst in_scope env) old_var
1318   = (TvSubst (in_scope `extendInScopeSet` new_var) new_env, new_var)
1319   where
1320     is_co_var = isCoVar old_var
1321
1322     new_env | no_change = delVarEnv env old_var
1323             | otherwise = extendVarEnv env old_var (TyVarTy new_var)
1324
1325     no_change = new_var == old_var && not is_co_var
1326         -- no_change means that the new_var is identical in
1327         -- all respects to the old_var (same unique, same kind)
1328         -- See Note [Extending the TvSubst]
1329         --
1330         -- In that case we don't need to extend the substitution
1331         -- to map old to new.  But instead we must zap any
1332         -- current substitution for the variable. For example:
1333         --      (\x.e) with id_subst = [x |-> e']
1334         -- Here we must simply zap the substitution for x
1335
1336     new_var = uniqAway in_scope subst_old_var
1337         -- The uniqAway part makes sure the new variable is not already in scope
1338
1339     subst_old_var -- subst_old_var is old_var with the substitution applied to its kind
1340                   -- It's only worth doing the substitution for coercions,
1341                   -- becuase only they can have free type variables
1342         | is_co_var = setTyVarKind old_var (substTy subst (tyVarKind old_var))
1343         | otherwise = old_var
1344 \end{code}
1345
1346 ----------------------------------------------------
1347 -- Kind Stuff
1348
1349 Kinds
1350 ~~~~~
1351 There's a little subtyping at the kind level:
1352
1353                  ?
1354                 / \
1355                /   \
1356               ??   (#)
1357              /  \
1358             *   #
1359
1360 where   *    [LiftedTypeKind]   means boxed type
1361         #    [UnliftedTypeKind] means unboxed type
1362         (#)  [UbxTupleKind]     means unboxed tuple
1363         ??   [ArgTypeKind]      is the lub of *,#
1364         ?    [OpenTypeKind]     means any type at all
1365
1366 In particular:
1367
1368         error :: forall a:?. String -> a
1369         (->)  :: ?? -> ? -> *
1370         (\(x::t) -> ...)        Here t::?? (i.e. not unboxed tuple)
1371
1372 \begin{code}
1373 type KindVar = TyVar  -- invariant: KindVar will always be a
1374                       -- TcTyVar with details MetaTv TauTv ...
1375 -- kind var constructors and functions are in TcType
1376
1377 type SimpleKind = Kind
1378 \end{code}
1379
1380 Kind inference
1381 ~~~~~~~~~~~~~~
1382 During kind inference, a kind variable unifies only with
1383 a "simple kind", sk
1384         sk ::= * | sk1 -> sk2
1385 For example
1386         data T a = MkT a (T Int#)
1387 fails.  We give T the kind (k -> *), and the kind variable k won't unify
1388 with # (the kind of Int#).
1389
1390 Type inference
1391 ~~~~~~~~~~~~~~
1392 When creating a fresh internal type variable, we give it a kind to express
1393 constraints on it.  E.g. in (\x->e) we make up a fresh type variable for x,
1394 with kind ??.
1395
1396 During unification we only bind an internal type variable to a type
1397 whose kind is lower in the sub-kind hierarchy than the kind of the tyvar.
1398
1399 When unifying two internal type variables, we collect their kind constraints by
1400 finding the GLB of the two.  Since the partial order is a tree, they only
1401 have a glb if one is a sub-kind of the other.  In that case, we bind the
1402 less-informative one to the more informative one.  Neat, eh?
1403
1404
1405 \begin{code}
1406
1407 \end{code}
1408
1409 %************************************************************************
1410 %*                                                                      *
1411         Functions over Kinds
1412 %*                                                                      *
1413 %************************************************************************
1414
1415 \begin{code}
1416 kindFunResult :: Kind -> Kind
1417 kindFunResult k = funResultTy k
1418
1419 splitKindFunTys :: Kind -> ([Kind],Kind)
1420 splitKindFunTys k = splitFunTys k
1421
1422 splitKindFunTysN :: Int -> Kind -> ([Kind],Kind)
1423 splitKindFunTysN k = splitFunTysN k
1424
1425 isUbxTupleKind, isOpenTypeKind, isArgTypeKind, isUnliftedTypeKind :: Kind -> Bool
1426
1427 isOpenTypeKindCon tc    = tyConUnique tc == openTypeKindTyConKey
1428
1429 isOpenTypeKind (TyConApp tc _) = isOpenTypeKindCon tc
1430 isOpenTypeKind other           = False
1431
1432 isUbxTupleKindCon tc = tyConUnique tc == ubxTupleKindTyConKey
1433
1434 isUbxTupleKind (TyConApp tc _) = isUbxTupleKindCon tc
1435 isUbxTupleKind other           = False
1436
1437 isArgTypeKindCon tc = tyConUnique tc == argTypeKindTyConKey
1438
1439 isArgTypeKind (TyConApp tc _) = isArgTypeKindCon tc
1440 isArgTypeKind other = False
1441
1442 isUnliftedTypeKindCon tc = tyConUnique tc == unliftedTypeKindTyConKey
1443
1444 isUnliftedTypeKind (TyConApp tc _) = isUnliftedTypeKindCon tc
1445 isUnliftedTypeKind other           = False
1446
1447 isSubOpenTypeKind :: Kind -> Bool
1448 -- True of any sub-kind of OpenTypeKind (i.e. anything except arrow)
1449 isSubOpenTypeKind (FunTy k1 k2)    = ASSERT2 ( isKind k1, text "isSubOpenTypeKind" <+> ppr k1 <+> text "::" <+> ppr (typeKind k1) )
1450                                      ASSERT2 ( isKind k2, text "isSubOpenTypeKind" <+> ppr k2 <+> text "::" <+> ppr (typeKind k2) )
1451                                      False
1452 isSubOpenTypeKind (TyConApp kc []) = ASSERT( isKind (TyConApp kc []) ) True
1453 isSubOpenTypeKind other            = ASSERT( isKind other ) False
1454          -- This is a conservative answer
1455          -- It matters in the call to isSubKind in
1456          -- checkExpectedKind.
1457
1458 isSubArgTypeKindCon kc
1459   | isUnliftedTypeKindCon kc = True
1460   | isLiftedTypeKindCon kc   = True
1461   | isArgTypeKindCon kc      = True
1462   | otherwise                = False
1463
1464 isSubArgTypeKind :: Kind -> Bool
1465 -- True of any sub-kind of ArgTypeKind
1466 isSubArgTypeKind (TyConApp kc []) = isSubArgTypeKindCon kc
1467 isSubArgTypeKind other            = False
1468
1469 isSuperKind :: Type -> Bool
1470 isSuperKind (TyConApp (skc) []) = isSuperKindTyCon skc
1471 isSuperKind other = False
1472
1473 isKind :: Kind -> Bool
1474 isKind k = isSuperKind (typeKind k)
1475
1476
1477
1478 isSubKind :: Kind -> Kind -> Bool
1479 -- (k1 `isSubKind` k2) checks that k1 <: k2
1480 isSubKind (TyConApp kc1 []) (TyConApp kc2 []) = kc1 `isSubKindCon` kc2
1481 isSubKind (FunTy a1 r1) (FunTy a2 r2)         = (a2 `isSubKind` a1) && (r1 `isSubKind` r2)
1482 isSubKind (PredTy (EqPred ty1 ty2)) (PredTy (EqPred ty1' ty2'))
1483   = ty1 `tcEqType` ty1' && ty2 `tcEqType` ty2'
1484 isSubKind k1            k2                    = False
1485
1486 eqKind :: Kind -> Kind -> Bool
1487 eqKind = tcEqType
1488
1489 isSubKindCon :: TyCon -> TyCon -> Bool
1490 -- (kc1 `isSubKindCon` kc2) checks that kc1 <: kc2
1491 isSubKindCon kc1 kc2
1492   | isLiftedTypeKindCon kc1   && isLiftedTypeKindCon kc2   = True
1493   | isUnliftedTypeKindCon kc1 && isUnliftedTypeKindCon kc2 = True
1494   | isUbxTupleKindCon kc1     && isUbxTupleKindCon kc2     = True
1495   | isOpenTypeKindCon kc2                                  = True
1496                            -- we already know kc1 is not a fun, its a TyCon
1497   | isArgTypeKindCon kc2      && isSubArgTypeKindCon kc1   = True
1498   | otherwise                                              = False
1499
1500 defaultKind :: Kind -> Kind
1501 -- Used when generalising: default kind '?' and '??' to '*'
1502 --
1503 -- When we generalise, we make generic type variables whose kind is
1504 -- simple (* or *->* etc).  So generic type variables (other than
1505 -- built-in constants like 'error') always have simple kinds.  This is important;
1506 -- consider
1507 --      f x = True
1508 -- We want f to get type
1509 --      f :: forall (a::*). a -> Bool
1510 -- Not
1511 --      f :: forall (a::??). a -> Bool
1512 -- because that would allow a call like (f 3#) as well as (f True),
1513 --and the calling conventions differ.  This defaulting is done in TcMType.zonkTcTyVarBndr.
1514 defaultKind k
1515   | isSubOpenTypeKind k = liftedTypeKind
1516   | isSubArgTypeKind k  = liftedTypeKind
1517   | otherwise        = k
1518
1519 isEqPred :: PredType -> Bool
1520 isEqPred (EqPred _ _) = True
1521 isEqPred other        = False
1522 \end{code}