compiler/types/Unify.lhs

   1 \begin{code}
   2 module Unify (
   3         -- Matching and unification
   4         tcMatchTys, tcMatchTyX, ruleMatchTyX, tcMatchPreds, MatchEnv(..),
   5
   6         tcUnifyTys,
   7
   8         gadtRefineTys, BindFlag(..),
   9
  10         coreRefineTys, TypeRefinement,
  11
  12         -- Re-export
  13         MaybeErr(..)
  14    ) where
  15
  16 #include "HsVersions.h"
  17
  18 import Var              ( Var, TyVar, tyVarKind )
  19 import VarEnv
  20 import VarSet
  21 import Kind             ( isSubKind )
  22 import Type             ( typeKind, tyVarsOfType, tyVarsOfTypes, tyVarsOfTheta, mkTyVarTys,
  23                           TvSubstEnv, emptyTvSubstEnv, TvSubst(..), substTy, tcEqTypeX,
  24                           mkOpenTvSubst, tcView )
  25 import TypeRep          ( Type(..), PredType(..), funTyCon )
  26 import DataCon          ( DataCon, dataConInstResTy )
  27 import Util             ( snocView )
  28 import ErrUtils         ( Message )
  29 import Outputable
  30 import Maybes
  31 \end{code}
  32
  33
  34 %************************************************************************
  35 %*                                                                      *
  36                 Matching
  37 %*                                                                      *
  38 %************************************************************************
  39
  40
  41 Matching is much tricker than you might think.
  42
  43 1. The substitution we generate binds the *template type variables*
  44    which are given to us explicitly.
  45
  46 2. We want to match in the presence of foralls;
  47         e.g     (forall a. t1) ~ (forall b. t2)
  48
  49    That is what the RnEnv2 is for; it does the alpha-renaming
  50    that makes it as if a and b were the same variable.
  51    Initialising the RnEnv2, so that it can generate a fresh
  52    binder when necessary, entails knowing the free variables of
  53    both types.
  54
  55 3. We must be careful not to bind a template type variable to a
  56    locally bound variable.  E.g.
  57         (forall a. x) ~ (forall b. b)
  58    where x is the template type variable.  Then we do not want to
  59    bind x to a/b!  This is a kind of occurs check.
  60    The necessary locals accumulate in the RnEnv2.
  61
  62
  63 \begin{code}
  64 data MatchEnv
  65   = ME  { me_tmpls :: VarSet    -- Template tyvars
  66         , me_env   :: RnEnv2    -- Renaming envt for nested foralls
  67         }                       --   In-scope set includes template tyvars
  68
  69 tcMatchTys :: TyVarSet          -- Template tyvars
  70          -> [Type]              -- Template
  71          -> [Type]              -- Target
  72          -> Maybe TvSubst       -- One-shot; in principle the template
  73                                 -- variables could be free in the target
  74
  75 tcMatchTys tmpls tys1 tys2
  76   = case match_tys menv emptyTvSubstEnv tys1 tys2 of
  77         Just subst_env -> Just (TvSubst in_scope subst_env)
  78         Nothing        -> Nothing
  79   where
  80     menv     = ME { me_tmpls = tmpls, me_env = mkRnEnv2 in_scope }
  81     in_scope = mkInScopeSet (tmpls `unionVarSet` tyVarsOfTypes tys2)
  82         -- We're assuming that all the interesting
  83         -- tyvars in tys1 are in tmpls
  84
  85 -- This is similar, but extends a substitution
  86 tcMatchTyX :: TyVarSet          -- Template tyvars
  87            -> TvSubst           -- Substitution to extend
  88            -> Type              -- Template
  89            -> Type              -- Target
  90            -> Maybe TvSubst
  91 tcMatchTyX tmpls (TvSubst in_scope subst_env) ty1 ty2
  92   = case match menv subst_env ty1 ty2 of
  93         Just subst_env -> Just (TvSubst in_scope subst_env)
  94         Nothing        -> Nothing
  95   where
  96     menv = ME {me_tmpls = tmpls, me_env = mkRnEnv2 in_scope}
  97
  98 tcMatchPreds
  99         :: [TyVar]                      -- Bind these
 100         -> [PredType] -> [PredType]
 101         -> Maybe TvSubstEnv
 102 tcMatchPreds tmpls ps1 ps2
 103   = match_list (match_pred menv) emptyTvSubstEnv ps1 ps2
 104   where
 105     menv = ME { me_tmpls = mkVarSet tmpls, me_env = mkRnEnv2 in_scope_tyvars }
 106     in_scope_tyvars = mkInScopeSet (tyVarsOfTheta ps1 `unionVarSet` tyVarsOfTheta ps2)
 107
 108 -- This one is called from the expression matcher, which already has a MatchEnv in hand
 109 ruleMatchTyX :: MatchEnv
 110          -> TvSubstEnv          -- Substitution to extend
 111          -> Type                -- Template
 112          -> Type                -- Target
 113          -> Maybe TvSubstEnv
 114
 115 ruleMatchTyX menv subst ty1 ty2 = match menv subst ty1 ty2      -- Rename for export
 116 \end{code}
 117
 118 Now the internals of matching
 119
 120 \begin{code}
 121 match :: MatchEnv       -- For the most part this is pushed downwards
 122       -> TvSubstEnv     -- Substitution so far:
 123                         --   Domain is subset of template tyvars
 124                         --   Free vars of range is subset of
 125                         --      in-scope set of the RnEnv2
 126       -> Type -> Type   -- Template and target respectively
 127       -> Maybe TvSubstEnv
 128 -- This matcher works on source types; that is,
 129 -- it respects NewTypes and PredType
 130
 131 match menv subst ty1 ty2 | Just ty1' <- tcView ty1 = match menv subst ty1' ty2
 132 match menv subst ty1 ty2 | Just ty2' <- tcView ty2 = match menv subst ty1 ty2'
 133
 134 match menv subst (TyVarTy tv1) ty2
 135   | tv1 `elemVarSet` me_tmpls menv
 136   = case lookupVarEnv subst tv1' of
 137         Nothing | any (inRnEnvR rn_env) (varSetElems (tyVarsOfType ty2))
 138                 -> Nothing      -- Occurs check
 139                 | not (typeKind ty2 `isSubKind` tyVarKind tv1)
 140                 -> Nothing      -- Kind mis-match
 141                 | otherwise
 142                 -> Just (extendVarEnv subst tv1 ty2)
 143
 144         Just ty1' | tcEqTypeX (nukeRnEnvL rn_env) ty1' ty2
 145                 -- ty1 has no locally-bound variables, hence nukeRnEnvL
 146                 -- Note tcEqType...we are doing source-type matching here
 147                   -> Just subst
 148
 149         other -> Nothing
 150
 151    | otherwise  -- tv1 is not a template tyvar
 152    = case ty2 of
 153         TyVarTy tv2 | tv1' == rnOccR rn_env tv2 -> Just subst
 154         other                                   -> Nothing
 155   where
 156     rn_env = me_env menv
 157     tv1' = rnOccL rn_env tv1
 158
 159 match menv subst (ForAllTy tv1 ty1) (ForAllTy tv2 ty2)
 160   = match menv' subst ty1 ty2
 161   where         -- Use the magic of rnBndr2 to go under the binders
 162     menv' = menv { me_env = rnBndr2 (me_env menv) tv1 tv2 }
 163
 164 match menv subst (PredTy p1) (PredTy p2)
 165   = match_pred menv subst p1 p2
 166 match menv subst (TyConApp tc1 tys1) (TyConApp tc2 tys2)
 167   | tc1 == tc2 = match_tys menv subst tys1 tys2
 168 match menv subst (FunTy ty1a ty1b) (FunTy ty2a ty2b)
 169   = do { subst' <- match menv subst ty1a ty2a
 170        ; match menv subst' ty1b ty2b }
 171 match menv subst (AppTy ty1a ty1b) ty2
 172   | Just (ty2a, ty2b) <- repSplitAppTy_maybe ty2
 173   = do { subst' <- match menv subst ty1a ty2a
 174        ; match menv subst' ty1b ty2b }
 175
 176 match menv subst ty1 ty2
 177   = Nothing
 178
 179 --------------
 180 match_tys menv subst tys1 tys2 = match_list (match menv) subst tys1 tys2
 181
 182 --------------
 183 match_list :: (TvSubstEnv -> a -> a -> Maybe TvSubstEnv)
 184            -> TvSubstEnv -> [a] -> [a] -> Maybe TvSubstEnv
 185 match_list fn subst []         []         = Just subst
 186 match_list fn subst (ty1:tys1) (ty2:tys2) = do  { subst' <- fn subst ty1 ty2
 187                                                 ; match_list fn subst' tys1 tys2 }
 188 match_list fn subst tys1       tys2       = Nothing
 189
 190 --------------
 191 match_pred menv subst (ClassP c1 tys1) (ClassP c2 tys2)
 192   | c1 == c2 = match_tys menv subst tys1 tys2
 193 match_pred menv subst (IParam n1 t1) (IParam n2 t2)
 194   | n1 == n2 = match menv subst t1 t2
 195 match_pred menv subst p1 p2 = Nothing
 196 \end{code}
 197
 198
 199 %************************************************************************
 200 %*                                                                      *
 201                 Unification
 202 %*                                                                      *
 203 %************************************************************************
 204
 205 \begin{code}
 206 tcUnifyTys :: (TyVar -> BindFlag)
 207            -> [Type] -> [Type]
 208            -> Maybe TvSubst     -- A regular one-shot substitution
 209 -- The two types may have common type variables, and indeed do so in the
 210 -- second call to tcUnifyTys in FunDeps.checkClsFD
 211 tcUnifyTys bind_fn tys1 tys2
 212   = maybeErrToMaybe $ initUM bind_fn $
 213     do { subst_env <- unify_tys emptyTvSubstEnv tys1 tys2
 214
 215         -- Find the fixed point of the resulting non-idempotent substitution
 216         ; let in_scope        = mkInScopeSet (tvs1 `unionVarSet` tvs2)
 217               subst           = TvSubst in_scope subst_env_fixpt
 218               subst_env_fixpt = mapVarEnv (substTy subst) subst_env
 219         ; return subst }
 220   where
 221     tvs1 = tyVarsOfTypes tys1
 222     tvs2 = tyVarsOfTypes tys2
 223
 224 ----------------------------
 225 coreRefineTys :: DataCon -> [TyVar]     -- Case pattern (con tv1 .. tvn ...)
 226               -> Type                   -- Type of scrutinee
 227               -> Maybe TypeRefinement
 228
 229 type TypeRefinement = (TvSubstEnv, Bool)
 230         -- The Bool is True iff all the bindings in the
 231         -- env are for the pattern type variables
 232         -- In this case, there is no type refinement
 233         -- for already-in-scope type variables
 234
 235 -- Used by Core Lint and the simplifier.
 236 coreRefineTys con tvs scrut_ty
 237   = maybeErrToMaybe $ initUM (tryToBind tv_set) $
 238     do  {       -- Run the unifier, starting with an empty env
 239         ; subst_env <- unify emptyTvSubstEnv pat_res_ty scrut_ty
 240
 241         -- Find the fixed point of the resulting non-idempotent substitution
 242         ; let subst           = mkOpenTvSubst subst_env_fixpt
 243               subst_env_fixpt = mapVarEnv (substTy subst) subst_env
 244
 245         ; return (subst_env_fixpt, all_bound_here subst_env) }
 246   where
 247     pat_res_ty = dataConInstResTy con (mkTyVarTys tvs)
 248
 249         -- 'tvs' are the tyvars bound by the pattern
 250     tv_set             = mkVarSet tvs
 251     all_bound_here env = all bound_here (varEnvKeys env)
 252     bound_here uniq    = elemVarSetByKey uniq tv_set
 253
 254 -- This version is used by the type checker
 255 gadtRefineTys :: TvSubst
 256               -> DataCon -> [TyVar]
 257               -> [Type] -> [Type]
 258               -> MaybeErr Message (TvSubst, Bool)
 259 -- The bool is True <=> the only *new* bindings are for pat_tvs
 260
 261 gadtRefineTys (TvSubst in_scope env1) con pat_tvs pat_tys ctxt_tys
 262   = initUM (tryToBind tv_set) $
 263     do  {       -- Run the unifier, starting with an empty env
 264         ; env2 <- unify_tys env1 pat_tys ctxt_tys
 265
 266         -- Find the fixed point of the resulting non-idempotent substitution
 267         ; let subst2          = TvSubst in_scope subst_env_fixpt
 268               subst_env_fixpt = mapVarEnv (substTy subst2) env2
 269
 270         ; return (subst2, all_bound_here env2) }
 271   where
 272         -- 'tvs' are the tyvars bound by the pattern
 273     tv_set             = mkVarSet pat_tvs
 274     all_bound_here env = all bound_here (varEnvKeys env)
 275     bound_here uniq    = elemVarEnvByKey uniq env1 || elemVarSetByKey uniq tv_set
 276         -- The bool is True <=> the only *new* bindings are for pat_tvs
 277
 278 ----------------------------
 279 tryToBind :: TyVarSet -> TyVar -> BindFlag
 280 tryToBind tv_set tv | tv `elemVarSet` tv_set = BindMe
 281                     | otherwise              = AvoidMe
 282 \end{code}
 283
 284
 285 %************************************************************************
 286 %*                                                                      *
 287                 The workhorse
 288 %*                                                                      *
 289 %************************************************************************
 290
 291 \begin{code}
 292 unify :: TvSubstEnv             -- An existing substitution to extend
 293       -> Type -> Type           -- Types to be unified
 294       -> UM TvSubstEnv          -- Just the extended substitution,
 295                                 -- Nothing if unification failed
 296 -- We do not require the incoming substitution to be idempotent,
 297 -- nor guarantee that the outgoing one is.  That's fixed up by
 298 -- the wrappers.
 299
 300 -- Respects newtypes, PredTypes
 301
 302 unify subst ty1 ty2 = -- pprTrace "unify" (ppr subst <+> pprParendType ty1 <+> pprParendType ty2) $
 303                       unify_ subst ty1 ty2
 304
 305 -- in unify_, any NewTcApps/Preds should be taken at face value
 306 unify_ subst (TyVarTy tv1) ty2  = uVar False subst tv1 ty2
 307 unify_ subst ty1 (TyVarTy tv2)  = uVar True  subst tv2 ty1
 308
 309 unify_ subst ty1 ty2 | Just ty1' <- tcView ty1 = unify subst ty1' ty2
 310 unify_ subst ty1 ty2 | Just ty2' <- tcView ty2 = unify subst ty1 ty2'
 311
 312 unify_ subst (PredTy p1) (PredTy p2) = unify_pred subst p1 p2
 313
 314 unify_ subst t1@(TyConApp tyc1 tys1) t2@(TyConApp tyc2 tys2)
 315   | tyc1 == tyc2 = unify_tys subst tys1 tys2
 316
 317 unify_ subst (FunTy ty1a ty1b) (FunTy ty2a ty2b)
 318   = do { subst' <- unify subst ty1a ty2a
 319        ; unify subst' ty1b ty2b }
 320
 321         -- Applications need a bit of care!
 322         -- They can match FunTy and TyConApp, so use splitAppTy_maybe
 323         -- NB: we've already dealt with type variables and Notes,
 324         -- so if one type is an App the other one jolly well better be too
 325 unify_ subst (AppTy ty1a ty1b) ty2
 326   | Just (ty2a, ty2b) <- repSplitAppTy_maybe ty2
 327   = do  { subst' <- unify subst ty1a ty2a
 328         ; unify subst' ty1b ty2b }
 329
 330 unify_ subst ty1 (AppTy ty2a ty2b)
 331   | Just (ty1a, ty1b) <- repSplitAppTy_maybe ty1
 332   = do  { subst' <- unify subst ty1a ty2a
 333         ; unify subst' ty1b ty2b }
 334
 335 unify_ subst ty1 ty2 = failWith (misMatch ty1 ty2)
 336
 337 ------------------------------
 338 unify_pred subst (ClassP c1 tys1) (ClassP c2 tys2)
 339   | c1 == c2 = unify_tys subst tys1 tys2
 340 unify_pred subst (IParam n1 t1) (IParam n2 t2)
 341   | n1 == n2 = unify subst t1 t2
 342 unify_pred subst p1 p2 = failWith (misMatch (PredTy p1) (PredTy p2))
 343
 344 ------------------------------
 345 unify_tys = unifyList unify
 346
 347 unifyList :: Outputable a
 348           => (TvSubstEnv -> a -> a -> UM TvSubstEnv)
 349           -> TvSubstEnv -> [a] -> [a] -> UM TvSubstEnv
 350 unifyList unifier subst orig_xs orig_ys
 351   = go subst orig_xs orig_ys
 352   where
 353     go subst []     []     = return subst
 354     go subst (x:xs) (y:ys) = do { subst' <- unifier subst x y
 355                                 ; go subst' xs ys }
 356     go subst _      _      = failWith (lengthMisMatch orig_xs orig_ys)
 357
 358 ------------------------------
 359 uVar :: Bool            -- Swapped
 360      -> TvSubstEnv      -- An existing substitution to extend
 361      -> TyVar           -- Type variable to be unified
 362      -> Type            -- with this type
 363      -> UM TvSubstEnv
 364
 365 uVar swap subst tv1 ty
 366  = -- Check to see whether tv1 is refined by the substitution
 367    case (lookupVarEnv subst tv1) of
 368      -- Yes, call back into unify'
 369      Just ty' | swap      -> unify subst ty ty'
 370               | otherwise -> unify subst ty' ty
 371      -- No, continue
 372      Nothing          -> uUnrefined subst tv1 ty ty
 373
 374
 375 uUnrefined :: TvSubstEnv          -- An existing substitution to extend
 376            -> TyVar               -- Type variable to be unified
 377            -> Type                -- with this type
 378            -> Type                -- (de-noted version)
 379            -> UM TvSubstEnv
 380
 381 -- We know that tv1 isn't refined
 382
 383 uUnrefined subst tv1 ty2 ty2'
 384   | Just ty2'' <- tcView ty2'
 385   = uUnrefined subst tv1 ty2 ty2''      -- Unwrap synonyms
 386                 -- This is essential, in case we have
 387                 --      type Foo a = a
 388                 -- and then unify a :=: Foo a
 389
 390 uUnrefined subst tv1 ty2 (TyVarTy tv2)
 391   | tv1 == tv2          -- Same type variable
 392   = return subst
 393
 394     -- Check to see whether tv2 is refined
 395   | Just ty' <- lookupVarEnv subst tv2
 396   = uUnrefined subst tv1 ty' ty'
 397
 398   -- So both are unrefined; next, see if the kinds force the direction
 399   | k1 == k2    -- Can update either; so check the bind-flags
 400   = do  { b1 <- tvBindFlag tv1
 401         ; b2 <- tvBindFlag tv2
 402         ; case (b1,b2) of
 403             (BindMe, _)          -> bind tv1 ty2
 404
 405             (AvoidMe, BindMe)    -> bind tv2 ty1
 406             (AvoidMe, _)         -> bind tv1 ty2
 407
 408             (WildCard, WildCard) -> return subst
 409             (WildCard, Skolem)   -> return subst
 410             (WildCard, _)        -> bind tv2 ty1
 411
 412             (Skolem, WildCard)   -> return subst
 413             (Skolem, Skolem)     -> failWith (misMatch ty1 ty2)
 414             (Skolem, _)          -> bind tv2 ty1
 415         }
 416
 417   | k1 `isSubKind` k2 = bindTv subst tv2 ty1    -- Must update tv2
 418   | k2 `isSubKind` k1 = bindTv subst tv1 ty2    -- Must update tv1
 419
 420   | otherwise = failWith (kindMisMatch tv1 ty2)
 421   where
 422     ty1 = TyVarTy tv1
 423     k1 = tyVarKind tv1
 424     k2 = tyVarKind tv2
 425     bind tv ty = return (extendVarEnv subst tv ty)
 426
 427 uUnrefined subst tv1 ty2 ty2'   -- ty2 is not a type variable
 428   | tv1 `elemVarSet` substTvSet subst (tyVarsOfType ty2')
 429   = failWith (occursCheck tv1 ty2)      -- Occurs check
 430   | not (k2 `isSubKind` k1)
 431   = failWith (kindMisMatch tv1 ty2)     -- Kind check
 432   | otherwise
 433   = bindTv subst tv1 ty2                -- Bind tyvar to the synonym if poss
 434   where
 435     k1 = tyVarKind tv1
 436     k2 = typeKind ty2'
 437
 438 substTvSet :: TvSubstEnv -> TyVarSet -> TyVarSet
 439 -- Apply the non-idempotent substitution to a set of type variables,
 440 -- remembering that the substitution isn't necessarily idempotent
 441 substTvSet subst tvs
 442   = foldVarSet (unionVarSet . get) emptyVarSet tvs
 443   where
 444     get tv = case lookupVarEnv subst tv of
 445                 Nothing -> unitVarSet tv
 446                 Just ty -> substTvSet subst (tyVarsOfType ty)
 447
 448 bindTv subst tv ty      -- ty is not a type variable
 449   = do  { b <- tvBindFlag tv
 450         ; case b of
 451             Skolem   -> failWith (misMatch (TyVarTy tv) ty)
 452             WildCard -> return subst
 453             other    -> return (extendVarEnv subst tv ty)
 454         }
 455 \end{code}
 456
 457 %************************************************************************
 458 %*                                                                      *
 459                 Unification monad
 460 %*                                                                      *
 461 %************************************************************************
 462
 463 \begin{code}
 464 data BindFlag
 465   = BindMe      -- A regular type variable
 466   | AvoidMe     -- Like BindMe but, given the choice, avoid binding it
 467
 468   | Skolem      -- This type variable is a skolem constant
 469                 -- Don't bind it; it only matches itself
 470
 471   | WildCard    -- This type variable matches anything,
 472                 -- and does not affect the substitution
 473
 474 newtype UM a = UM { unUM :: (TyVar -> BindFlag)
 475                          -> MaybeErr Message a }
 476
 477 instance Monad UM where
 478   return a = UM (\tvs -> Succeeded a)
 479   fail s   = UM (\tvs -> Failed (text s))
 480   m >>= k  = UM (\tvs -> case unUM m tvs of
 481                            Failed err -> Failed err
 482                            Succeeded v  -> unUM (k v) tvs)
 483
 484 initUM :: (TyVar -> BindFlag) -> UM a -> MaybeErr Message a
 485 initUM badtvs um = unUM um badtvs
 486
 487 tvBindFlag :: TyVar -> UM BindFlag
 488 tvBindFlag tv = UM (\tv_fn -> Succeeded (tv_fn tv))
 489
 490 failWith :: Message -> UM a
 491 failWith msg = UM (\tv_fn -> Failed msg)
 492
 493 maybeErrToMaybe :: MaybeErr fail succ -> Maybe succ
 494 maybeErrToMaybe (Succeeded a) = Just a
 495 maybeErrToMaybe (Failed m)    = Nothing
 496
 497 ------------------------------
 498 repSplitAppTy_maybe :: Type -> Maybe (Type,Type)
 499 -- Like Type.splitAppTy_maybe, but any coreView stuff is already done
 500 repSplitAppTy_maybe (FunTy ty1 ty2)   = Just (TyConApp funTyCon [ty1], ty2)
 501 repSplitAppTy_maybe (AppTy ty1 ty2)   = Just (ty1, ty2)
 502 repSplitAppTy_maybe (TyConApp tc tys) = case snocView tys of
 503                                                 Just (tys', ty') -> Just (TyConApp tc tys', ty')
 504                                                 Nothing          -> Nothing
 505 repSplitAppTy_maybe other = Nothing
 506 \end{code}
 507
 508
 509 %************************************************************************
 510 %*                                                                      *
 511                 Error reporting
 512         We go to a lot more trouble to tidy the types
 513         in TcUnify.  Maybe we'll end up having to do that
 514         here too, but I'll leave it for now.
 515 %*                                                                      *
 516 %************************************************************************
 517
 518 \begin{code}
 519 misMatch t1 t2
 520   = ptext SLIT("Can't match types") <+> quotes (ppr t1) <+>
 521     ptext SLIT("and") <+> quotes (ppr t2)
 522
 523 lengthMisMatch tys1 tys2
 524   = sep [ptext SLIT("Can't match unequal length lists"),
 525          nest 2 (ppr tys1), nest 2 (ppr tys2) ]
 526
 527 kindMisMatch tv1 t2
 528   = vcat [ptext SLIT("Can't match kinds") <+> quotes (ppr (tyVarKind tv1)) <+>
 529             ptext SLIT("and") <+> quotes (ppr (typeKind t2)),
 530           ptext SLIT("when matching") <+> quotes (ppr tv1) <+>
 531                 ptext SLIT("with") <+> quotes (ppr t2)]
 532
 533 occursCheck tv ty
 534   = hang (ptext SLIT("Can't construct the infinite type"))
 535        2 (ppr tv <+> equals <+> ppr ty)
 536 \end{code}