compiler/utils/Serialized.hs

   1 --
   2 -- (c) The University of Glasgow 2002-2006
   3 --
   4 -- Serialized values
   5
   6 {-# LANGUAGE ScopedTypeVariables #-}
   7 module Serialized (
   8     -- * Main Serialized data type
   9     Serialized,
  10     seqSerialized,
  11
  12     -- * Going into and out of 'Serialized'
  13     toSerialized, fromSerialized,
  14
  15     -- * Handy serialization functions
  16     serializeWithData, deserializeWithData,
  17   ) where
  18
  19 import Binary
  20 import Outputable
  21 import FastString
  22 import Util
  23
  24 import Data.Bits
  25 import Data.Word        ( Word8 )
  26
  27 import Data.Data
  28
  29
  30 -- | Represents a serialized value of a particular type. Attempts can be made to deserialize it at certain types
  31 data Serialized = Serialized TypeRep [Word8]
  32
  33 instance Outputable Serialized where
  34     ppr (Serialized the_type bytes) = int (length bytes) <+> ptext (sLit "of type") <+> text (show the_type)
  35
  36 instance Binary Serialized where
  37     put_ bh (Serialized the_type bytes) = do
  38         put_ bh the_type
  39         put_ bh bytes
  40     get bh = do
  41         the_type <- get bh
  42         bytes <- get bh
  43         return (Serialized the_type bytes)
  44
  45 -- | Put a Typeable value that we are able to actually turn into bytes into a 'Serialized' value ready for deserialization later
  46 toSerialized :: Typeable a => (a -> [Word8]) -> a -> Serialized
  47 toSerialized serialize what = Serialized (typeOf what) (serialize what)
  48
  49 -- | If the 'Serialized' value contains something of the given type, then use the specified deserializer to return @Just@ that.
  50 -- Otherwise return @Nothing@.
  51 fromSerialized :: forall a. Typeable a => ([Word8] -> a) -> Serialized -> Maybe a
  52 fromSerialized deserialize (Serialized the_type bytes)
  53   | the_type == typeOf (undefined :: a) = Just (deserialize bytes)
  54   | otherwise                           = Nothing
  55
  56 -- | Force the contents of the Serialized value so weknow it doesn't contain any bottoms
  57 seqSerialized :: Serialized -> ()
  58 seqSerialized (Serialized the_type bytes) = the_type `seq` bytes `seqList` ()
  59
  60
  61 -- | Use a 'Data' instance to implement a serialization scheme dual to that of 'deserializeWithData'
  62 serializeWithData :: Data a => a -> [Word8]
  63 serializeWithData what = serializeWithData' what []
  64
  65 serializeWithData' :: Data a => a -> [Word8] -> [Word8]
  66 serializeWithData' what = fst $ gfoldl (\(before, a_to_b) a -> (before . serializeWithData' a, a_to_b a))
  67                                        (\x -> (serializeConstr (constrRep (toConstr what)), x))
  68                                        what
  69
  70 -- | Use a 'Data' instance to implement a deserialization scheme dual to that of 'serializeWithData'
  71 deserializeWithData :: Data a => [Word8] -> a
  72 deserializeWithData = snd . deserializeWithData'
  73
  74 deserializeWithData' :: forall a. Data a => [Word8] -> ([Word8], a)
  75 deserializeWithData' bytes = deserializeConstr bytes $ \constr_rep bytes ->
  76                              gunfold (\(bytes, b_to_r) -> let (bytes', b) = deserializeWithData' bytes in (bytes', b_to_r b))
  77                                      (\x -> (bytes, x))
  78                                      (repConstr (dataTypeOf (undefined :: a)) constr_rep)
  79
  80
  81 serializeConstr :: ConstrRep -> [Word8] -> [Word8]
  82 serializeConstr (AlgConstr ix)   = serializeWord8 1 . serializeInt ix
  83 serializeConstr (IntConstr i)    = serializeWord8 2 . serializeInteger i
  84 serializeConstr (FloatConstr r)  = serializeWord8 3 . serializeRational r
  85 serializeConstr (CharConstr c)   = serializeWord8 4 . serializeChar c
  86
  87
  88 deserializeConstr :: [Word8] -> (ConstrRep -> [Word8] -> a) -> a
  89 deserializeConstr bytes k = deserializeWord8 bytes $ \constr_ix bytes ->
  90                             case constr_ix of
  91                                 1 -> deserializeInt      bytes $ \ix -> k (AlgConstr ix)
  92                                 2 -> deserializeInteger  bytes $ \i  -> k (IntConstr i)
  93                                 3 -> deserializeRational bytes $ \r  -> k (FloatConstr r)
  94                                 4 -> deserializeChar     bytes $ \c  -> k (CharConstr c)
  95                                 x -> error $ "deserializeConstr: unrecognised serialized constructor type " ++ show x ++ " in context " ++ show bytes
  96
  97
  98 serializeFixedWidthNum :: forall a. (Num a, Integral a, Bits a) => a -> [Word8] -> [Word8]
  99 serializeFixedWidthNum what = go (bitSize what) what
 100   where
 101     go :: Int -> a -> [Word8] -> [Word8]
 102     go size current rest
 103       | size <= 0 = rest
 104       | otherwise = fromIntegral (current .&. 255) : go (size - 8) (current `shiftR` 8) rest
 105
 106 deserializeFixedWidthNum :: forall a b. (Num a, Integral a, Bits a) => [Word8] -> (a -> [Word8] -> b) -> b
 107 deserializeFixedWidthNum bytes k = go (bitSize (undefined :: a)) bytes k
 108   where
 109     go :: Int -> [Word8] -> (a -> [Word8] -> b) -> b
 110     go size bytes k
 111       | size <= 0 = k 0 bytes
 112       | otherwise = case bytes of
 113                         (byte:bytes) -> go (size - 8) bytes (\x -> k ((x `shiftL` 8) .|. fromIntegral byte))
 114                         []           -> error "deserializeFixedWidthNum: unexpected end of stream"
 115
 116
 117 serializeEnum :: (Enum a) => a -> [Word8] -> [Word8]
 118 serializeEnum = serializeInt . fromEnum
 119
 120 deserializeEnum :: Enum a => [Word8] -> (a -> [Word8] -> b) -> b
 121 deserializeEnum bytes k = deserializeInt bytes (k . toEnum)
 122
 123
 124 serializeWord8 :: Word8 -> [Word8] -> [Word8]
 125 serializeWord8 x = (x:)
 126
 127 deserializeWord8 :: [Word8] -> (Word8 -> [Word8] -> a) -> a
 128 deserializeWord8 (byte:bytes) k = k byte bytes
 129 deserializeWord8 []           _ = error "deserializeWord8: unexpected end of stream"
 130
 131
 132 serializeInt :: Int -> [Word8] -> [Word8]
 133 serializeInt = serializeFixedWidthNum
 134
 135 deserializeInt :: [Word8] -> (Int -> [Word8] -> a) -> a
 136 deserializeInt = deserializeFixedWidthNum
 137
 138
 139 serializeRational :: (Real a) => a -> [Word8] -> [Word8]
 140 serializeRational = serializeString . show . toRational
 141
 142 deserializeRational :: (Fractional a) => [Word8] -> (a -> [Word8] -> b) -> b
 143 deserializeRational bytes k = deserializeString bytes (k . fromRational . read)
 144
 145
 146 serializeInteger :: Integer -> [Word8] -> [Word8]
 147 serializeInteger = serializeString . show
 148
 149 deserializeInteger :: [Word8] -> (Integer -> [Word8] -> a) -> a
 150 deserializeInteger bytes k = deserializeString bytes (k . read)
 151
 152
 153 serializeChar :: Char -> [Word8] -> [Word8]
 154 serializeChar = serializeString . show
 155
 156 deserializeChar :: [Word8] -> (Char -> [Word8] -> a) -> a
 157 deserializeChar bytes k = deserializeString bytes (k . read)
 158
 159
 160 serializeString :: String -> [Word8] -> [Word8]
 161 serializeString = serializeList serializeEnum
 162
 163 deserializeString :: [Word8] -> (String -> [Word8] -> a) -> a
 164 deserializeString = deserializeList deserializeEnum
 165
 166
 167 serializeList :: (a -> [Word8] -> [Word8]) -> [a] -> [Word8] -> [Word8]
 168 serializeList serialize_element xs = serializeInt (length xs) . foldr (.) id (map serialize_element xs)
 169
 170 deserializeList :: forall a b. (forall c. [Word8] -> (a -> [Word8] -> c) -> c)
 171                 -> [Word8] -> ([a] -> [Word8] -> b) -> b
 172 deserializeList deserialize_element bytes k = deserializeInt bytes $ \len bytes -> go len bytes k
 173   where
 174     go :: Int -> [Word8] -> ([a] -> [Word8] -> b) -> b
 175     go len bytes k
 176       | len <= 0  = k [] bytes
 177       | otherwise = deserialize_element bytes (\elt bytes -> go (len - 1) bytes (k . (elt:)))
 178