compiler/vectorise/VectType.hs

   1 module VectType ( vectTyCon, vectType, vectTypeEnv,
   2                    PAInstance, buildPADict )
   3 where
   4
   5 #include "HsVersions.h"
   6
   7 import VectMonad
   8 import VectUtils
   9 import VectCore
  10
  11 import HscTypes          ( TypeEnv, extendTypeEnvList, typeEnvTyCons )
  12 import CoreSyn
  13 import CoreUtils
  14 import BuildTyCl
  15 import DataCon
  16 import TyCon
  17 import Type
  18 import TypeRep
  19 import Coercion
  20 import FamInstEnv        ( FamInst, mkLocalFamInst )
  21 import InstEnv           ( Instance, mkLocalInstance, instanceDFunId )
  22 import OccName
  23 import MkId
  24 import BasicTypes        ( StrictnessMark(..), OverlapFlag(..), boolToRecFlag )
  25 import Var               ( Var )
  26 import Id                ( mkWildId )
  27 import Name              ( Name, getOccName )
  28 import NameEnv
  29 import TysWiredIn        ( unitTy, intTy, intDataCon )
  30 import TysPrim           ( intPrimTy )
  31
  32 import Unique
  33 import UniqFM
  34 import UniqSet
  35 import Digraph           ( SCC(..), stronglyConnComp )
  36
  37 import Outputable
  38
  39 import Control.Monad  ( liftM, liftM2, zipWithM, zipWithM_ )
  40 import Data.List      ( inits, tails, zipWith4, zipWith5 )
  41
  42 -- ----------------------------------------------------------------------------
  43 -- Types
  44
  45 vectTyCon :: TyCon -> VM TyCon
  46 vectTyCon tc
  47   | isFunTyCon tc        = builtin closureTyCon
  48   | isBoxedTupleTyCon tc = return tc
  49   | isUnLiftedTyCon tc   = return tc
  50   | otherwise = do
  51                   r <- lookupTyCon tc
  52                   case r of
  53                     Just tc' -> return tc'
  54
  55                     -- FIXME: just for now
  56                     Nothing  -> pprTrace "ccTyCon:" (ppr tc) $ return tc
  57
  58 vectType :: Type -> VM Type
  59 vectType ty | Just ty' <- coreView ty = vectType ty'
  60 vectType (TyVarTy tv) = return $ TyVarTy tv
  61 vectType (AppTy ty1 ty2) = liftM2 AppTy (vectType ty1) (vectType ty2)
  62 vectType (TyConApp tc tys) = liftM2 TyConApp (vectTyCon tc) (mapM vectType tys)
  63 vectType (FunTy ty1 ty2)   = liftM2 TyConApp (builtin closureTyCon)
  64                                              (mapM vectType [ty1,ty2])
  65 vectType ty@(ForAllTy _ _)
  66   = do
  67       mdicts   <- mapM paDictArgType tyvars
  68       mono_ty' <- vectType mono_ty
  69       return $ tyvars `mkForAllTys` ([dict | Just dict <- mdicts] `mkFunTys` mono_ty')
  70   where
  71     (tyvars, mono_ty) = splitForAllTys ty
  72
  73 vectType ty = pprPanic "vectType:" (ppr ty)
  74
  75 -- ----------------------------------------------------------------------------
  76 -- Type definitions
  77
  78 type TyConGroup = ([TyCon], UniqSet TyCon)
  79
  80 data PAInstance = PAInstance {
  81                     painstDFun      :: Var
  82                   , painstOrigTyCon :: TyCon
  83                   , painstVectTyCon :: TyCon
  84                   , painstArrTyCon  :: TyCon
  85                   }
  86
  87 vectTypeEnv :: TypeEnv -> VM (TypeEnv, [FamInst], [(Var, CoreExpr)])
  88 vectTypeEnv env
  89   = do
  90       cs <- readGEnv $ mk_map . global_tycons
  91       let (conv_tcs, keep_tcs) = classifyTyCons cs groups
  92           keep_dcs             = concatMap tyConDataCons keep_tcs
  93       zipWithM_ defTyCon   keep_tcs keep_tcs
  94       zipWithM_ defDataCon keep_dcs keep_dcs
  95       new_tcs <- vectTyConDecls conv_tcs
  96
  97       let orig_tcs = keep_tcs ++ conv_tcs
  98           vect_tcs  = keep_tcs ++ new_tcs
  99
 100       repr_tcs <- zipWithM buildPReprTyCon   orig_tcs vect_tcs
 101       parr_tcs <- zipWithM buildPArrayTyCon orig_tcs vect_tcs
 102       dfuns    <- mapM mkPADFun vect_tcs
 103       defTyConPAs (zip vect_tcs dfuns)
 104       binds    <- sequence (zipWith5 buildTyConBindings orig_tcs
 105                                                         vect_tcs
 106                                                         repr_tcs
 107                                                         parr_tcs
 108                                                         dfuns)
 109
 110       let all_new_tcs = new_tcs ++ repr_tcs ++ parr_tcs
 111
 112       let new_env = extendTypeEnvList env
 113                        (map ATyCon all_new_tcs
 114                         ++ [ADataCon dc | tc <- all_new_tcs
 115                                         , dc <- tyConDataCons tc])
 116
 117       return (new_env, map mkLocalFamInst (repr_tcs ++ parr_tcs), concat binds)
 118   where
 119     tycons = typeEnvTyCons env
 120     groups = tyConGroups tycons
 121
 122     mk_map env = listToUFM_Directly [(u, getUnique n /= u) | (u,n) <- nameEnvUniqueElts env]
 123
 124     keep_tc tc = let dcs = tyConDataCons tc
 125                  in
 126                  defTyCon tc tc >> zipWithM_ defDataCon dcs dcs
 127
 128
 129 vectTyConDecls :: [TyCon] -> VM [TyCon]
 130 vectTyConDecls tcs = fixV $ \tcs' ->
 131   do
 132     mapM_ (uncurry defTyCon) (lazy_zip tcs tcs')
 133     mapM vectTyConDecl tcs
 134   where
 135     lazy_zip [] _ = []
 136     lazy_zip (x:xs) ~(y:ys) = (x,y) : lazy_zip xs ys
 137
 138 vectTyConDecl :: TyCon -> VM TyCon
 139 vectTyConDecl tc
 140   = do
 141       name' <- cloneName mkVectTyConOcc name
 142       rhs'  <- vectAlgTyConRhs (algTyConRhs tc)
 143
 144       liftDs $ buildAlgTyCon name'
 145                              tyvars
 146                              []           -- no stupid theta
 147                              rhs'
 148                              rec_flag     -- FIXME: is this ok?
 149                              False        -- FIXME: no generics
 150                              False        -- not GADT syntax
 151                              Nothing      -- not a family instance
 152   where
 153     name   = tyConName tc
 154     tyvars = tyConTyVars tc
 155     rec_flag = boolToRecFlag (isRecursiveTyCon tc)
 156
 157 vectAlgTyConRhs :: AlgTyConRhs -> VM AlgTyConRhs
 158 vectAlgTyConRhs (DataTyCon { data_cons = data_cons
 159                            , is_enum   = is_enum
 160                            })
 161   = do
 162       data_cons' <- mapM vectDataCon data_cons
 163       zipWithM_ defDataCon data_cons data_cons'
 164       return $ DataTyCon { data_cons = data_cons'
 165                          , is_enum   = is_enum
 166                          }
 167
 168 vectDataCon :: DataCon -> VM DataCon
 169 vectDataCon dc
 170   | not . null $ dataConExTyVars dc = pprPanic "vectDataCon: existentials" (ppr dc)
 171   | not . null $ dataConEqSpec   dc = pprPanic "vectDataCon: eq spec" (ppr dc)
 172   | otherwise
 173   = do
 174       name'    <- cloneName mkVectDataConOcc name
 175       tycon'   <- vectTyCon tycon
 176       arg_tys  <- mapM vectType rep_arg_tys
 177
 178       liftDs $ buildDataCon name'
 179                             False           -- not infix
 180                             (map (const NotMarkedStrict) arg_tys)
 181                             []              -- no labelled fields
 182                             univ_tvs
 183                             []              -- no existential tvs for now
 184                             []              -- no eq spec for now
 185                             []              -- no context
 186                             arg_tys
 187                             tycon'
 188   where
 189     name        = dataConName dc
 190     univ_tvs    = dataConUnivTyVars dc
 191     rep_arg_tys = dataConRepArgTys dc
 192     tycon       = dataConTyCon dc
 193
 194 mk_fam_inst :: TyCon -> TyCon -> (TyCon, [Type])
 195 mk_fam_inst fam_tc arg_tc
 196   = (fam_tc, [mkTyConApp arg_tc . mkTyVarTys $ tyConTyVars arg_tc])
 197
 198 buildPReprTyCon :: TyCon -> TyCon -> VM TyCon
 199 buildPReprTyCon orig_tc vect_tc
 200   = do
 201       name     <- cloneName mkPReprTyConOcc (tyConName orig_tc)
 202       rhs_ty   <- buildPReprType vect_tc
 203       prepr_tc <- builtin preprTyCon
 204       liftDs $ buildSynTyCon name
 205                              tyvars
 206                              (SynonymTyCon rhs_ty)
 207                              (Just $ mk_fam_inst prepr_tc vect_tc)
 208   where
 209     tyvars = tyConTyVars vect_tc
 210
 211 buildPReprType :: TyCon -> VM Type
 212 buildPReprType = mkPRepr . map dataConRepArgTys . tyConDataCons
 213
 214 buildToPRepr :: Shape -> TyCon -> TyCon -> TyCon -> VM CoreExpr
 215 buildToPRepr _ vect_tc prepr_tc _
 216   = do
 217       arg <- newLocalVar FSLIT("x") arg_ty
 218       bndrss <- mapM (mapM (newLocalVar FSLIT("x"))) rep_tys
 219       (alt_bodies, res_ty) <- mkToPRepr $ map (map Var) bndrss
 220
 221       return . Lam arg
 222              . wrapFamInstBody prepr_tc var_tys
 223              . Case (Var arg) (mkWildId arg_ty) res_ty
 224              $ zipWith3 mk_alt data_cons bndrss alt_bodies
 225   where
 226     var_tys   = mkTyVarTys $ tyConTyVars vect_tc
 227     arg_ty    = mkTyConApp vect_tc var_tys
 228     data_cons = tyConDataCons vect_tc
 229     rep_tys   = map dataConRepArgTys data_cons
 230
 231     mk_alt data_con bndrs body = (DataAlt data_con, bndrs, body)
 232
 233 buildFromPRepr :: Shape -> TyCon -> TyCon -> TyCon -> VM CoreExpr
 234 buildFromPRepr _ vect_tc prepr_tc _
 235   = do
 236       arg_ty <- mkPReprType res_ty
 237       arg <- newLocalVar FSLIT("x") arg_ty
 238       alts <- mapM mk_alt data_cons
 239       body <- mkFromPRepr (unwrapFamInstScrut prepr_tc var_tys (Var arg))
 240                           res_ty alts
 241       return $ Lam arg body
 242   where
 243     var_tys   = mkTyVarTys $ tyConTyVars vect_tc
 244     res_ty    = mkTyConApp vect_tc var_tys
 245     data_cons = tyConDataCons vect_tc
 246
 247     mk_alt dc = do
 248                   bndrs <- mapM (newLocalVar FSLIT("x")) $ dataConRepArgTys dc
 249                   return (bndrs, mkConApp dc (map Type var_tys ++ map Var bndrs))
 250
 251 buildPArrayTyCon :: TyCon -> TyCon -> VM TyCon
 252 buildPArrayTyCon orig_tc vect_tc = fixV $ \repr_tc ->
 253   do
 254     name'  <- cloneName mkPArrayTyConOcc orig_name
 255     rhs    <- buildPArrayTyConRhs orig_name vect_tc repr_tc
 256     parray <- builtin parrayTyCon
 257
 258     liftDs $ buildAlgTyCon name'
 259                            tyvars
 260                            []          -- no stupid theta
 261                            rhs
 262                            rec_flag    -- FIXME: is this ok?
 263                            False       -- FIXME: no generics
 264                            False       -- not GADT syntax
 265                            (Just $ mk_fam_inst parray vect_tc)
 266   where
 267     orig_name = tyConName orig_tc
 268     tyvars = tyConTyVars vect_tc
 269     rec_flag = boolToRecFlag (isRecursiveTyCon vect_tc)
 270
 271
 272 buildPArrayTyConRhs :: Name -> TyCon -> TyCon -> VM AlgTyConRhs
 273 buildPArrayTyConRhs orig_name vect_tc repr_tc
 274   = do
 275       data_con <- buildPArrayDataCon orig_name vect_tc repr_tc
 276       return $ DataTyCon { data_cons = [data_con], is_enum = False }
 277
 278 buildPArrayDataCon :: Name -> TyCon -> TyCon -> VM DataCon
 279 buildPArrayDataCon orig_name vect_tc repr_tc
 280   = do
 281       dc_name  <- cloneName mkPArrayDataConOcc orig_name
 282       shape    <- tyConShape vect_tc
 283       repr_tys <- mapM mkPArrayType types
 284
 285       liftDs $ buildDataCon dc_name
 286                             False                  -- not infix
 287                             (shapeStrictness shape ++ map (const NotMarkedStrict) repr_tys)
 288                             []                     -- no field labels
 289                             (tyConTyVars vect_tc)
 290                             []                     -- no existentials
 291                             []                     -- no eq spec
 292                             []                     -- no context
 293                             (shapeReprTys shape ++ repr_tys)
 294                             repr_tc
 295   where
 296     types = [ty | dc <- tyConDataCons vect_tc
 297                 , ty <- dataConRepArgTys dc]
 298
 299 mkPADFun :: TyCon -> VM Var
 300 mkPADFun vect_tc
 301   = newExportedVar (mkPADFunOcc $ getOccName vect_tc) =<< paDFunType vect_tc
 302
 303 data Shape = Shape {
 304                shapeReprTys    :: [Type]
 305              , shapeStrictness :: [StrictnessMark]
 306              , shapeLength     :: [CoreExpr] -> VM CoreExpr
 307              , shapeReplicate  :: CoreExpr -> CoreExpr -> VM [CoreExpr]
 308              }
 309
 310 tyConShape :: TyCon -> VM Shape
 311 tyConShape vect_tc
 312   | isProductTyCon vect_tc
 313   = return $ Shape {
 314                 shapeReprTys    = [intPrimTy]
 315               , shapeStrictness = [NotMarkedStrict]
 316               , shapeLength     = \[len] -> return len
 317               , shapeReplicate  = \len _ -> return [len]
 318               }
 319
 320   | otherwise
 321   = do
 322       repr_ty <- mkPArrayType intTy   -- FIXME: we want to unbox this
 323       return $ Shape {
 324                  shapeReprTys    = [repr_ty]
 325                , shapeStrictness = [MarkedStrict]
 326                , shapeLength     = \[sel] -> lengthPA sel
 327                , shapeReplicate  = \len n -> do
 328                                                e <- replicatePA len n
 329                                                return [e]
 330                }
 331
 332 buildTyConBindings :: TyCon -> TyCon -> TyCon -> TyCon -> Var
 333                    -> VM [(Var, CoreExpr)]
 334 buildTyConBindings orig_tc vect_tc prepr_tc arr_tc dfun
 335   = do
 336       shape <- tyConShape vect_tc
 337       sequence_ (zipWith4 (vectDataConWorker shape vect_tc arr_tc arr_dc)
 338                           orig_dcs
 339                           vect_dcs
 340                           (inits repr_tys)
 341                           (tails repr_tys))
 342       dict <- buildPADict shape vect_tc prepr_tc arr_tc dfun
 343       binds <- takeHoisted
 344       return $ (dfun, dict) : binds
 345   where
 346     orig_dcs = tyConDataCons orig_tc
 347     vect_dcs = tyConDataCons vect_tc
 348     [arr_dc] = tyConDataCons arr_tc
 349
 350     repr_tys = map dataConRepArgTys vect_dcs
 351
 352 vectDataConWorker :: Shape -> TyCon -> TyCon -> DataCon
 353                   -> DataCon -> DataCon -> [[Type]] -> [[Type]]
 354                   -> VM ()
 355 vectDataConWorker shape vect_tc arr_tc arr_dc orig_dc vect_dc pre (dc_tys : post)
 356   = do
 357       clo <- closedV
 358            . inBind orig_worker
 359            . polyAbstract tvs $ \abstract ->
 360              liftM (abstract . vectorised)
 361            $ buildClosures tvs [] dc_tys res_ty (liftM2 (,) mk_vect mk_lift)
 362
 363       worker <- cloneId mkVectOcc orig_worker (exprType clo)
 364       hoistBinding worker clo
 365       defGlobalVar orig_worker worker
 366       return ()
 367   where
 368     tvs     = tyConTyVars vect_tc
 369     arg_tys = mkTyVarTys tvs
 370     res_ty  = mkTyConApp vect_tc arg_tys
 371
 372     orig_worker = dataConWorkId orig_dc
 373
 374     mk_vect = return . mkConApp vect_dc $ map Type arg_tys
 375     mk_lift = do
 376                 len     <- newLocalVar FSLIT("n") intPrimTy
 377                 arr_tys <- mapM mkPArrayType dc_tys
 378                 args    <- mapM (newLocalVar FSLIT("xs")) arr_tys
 379                 shapes  <- shapeReplicate shape
 380                                           (Var len)
 381                                           (mkDataConTag vect_dc)
 382
 383                 empty_pre  <- mapM emptyPA (concat pre)
 384                 empty_post <- mapM emptyPA (concat post)
 385
 386                 return . mkLams (len : args)
 387                        . wrapFamInstBody arr_tc arg_tys
 388                        . mkConApp arr_dc
 389                        $ map Type arg_tys ++ shapes
 390                                           ++ empty_pre
 391                                           ++ map Var args
 392                                           ++ empty_post
 393
 394 buildPADict :: Shape -> TyCon -> TyCon -> TyCon -> Var -> VM CoreExpr
 395 buildPADict shape vect_tc prepr_tc arr_tc dfun
 396   = polyAbstract tvs $ \abstract ->
 397     do
 398       meth_binds <- mapM (mk_method shape) paMethods
 399       let meth_exprs = map (Var . fst) meth_binds
 400
 401       pa_dc <- builtin paDataCon
 402       let dict = mkConApp pa_dc (Type (mkTyConApp vect_tc arg_tys) : meth_exprs)
 403           body = Let (Rec meth_binds) dict
 404       return . mkInlineMe $ abstract body
 405   where
 406     tvs = tyConTyVars arr_tc
 407     arg_tys = mkTyVarTys tvs
 408
 409     mk_method shape (name, build)
 410       = localV
 411       $ do
 412           body <- build shape vect_tc prepr_tc arr_tc
 413           var  <- newLocalVar name (exprType body)
 414           return (var, mkInlineMe body)
 415
 416 paMethods = [(FSLIT("lengthPA"),    buildLengthPA),
 417              (FSLIT("replicatePA"), buildReplicatePA),
 418              (FSLIT("toPRepr"),     buildToPRepr),
 419              (FSLIT("fromPRepr"),   buildFromPRepr)]
 420
 421 buildLengthPA :: Shape -> TyCon -> TyCon -> TyCon -> VM CoreExpr
 422 buildLengthPA shape vect_tc _ arr_tc
 423   = do
 424       parr_ty <- mkPArrayType (mkTyConApp vect_tc arg_tys)
 425       arg    <- newLocalVar FSLIT("xs") parr_ty
 426       shapes <- mapM (newLocalVar FSLIT("sh")) shape_tys
 427       wilds  <- mapM newDummyVar repr_tys
 428       let scrut    = unwrapFamInstScrut arr_tc arg_tys (Var arg)
 429           scrut_ty = exprType scrut
 430
 431       body <- shapeLength shape (map Var shapes)
 432
 433       return . Lam arg
 434              $ Case scrut (mkWildId scrut_ty) intPrimTy
 435                     [(DataAlt repr_dc, shapes ++ wilds, body)]
 436   where
 437     arg_tys = mkTyVarTys $ tyConTyVars arr_tc
 438     [repr_dc] = tyConDataCons arr_tc
 439
 440     shape_tys = shapeReprTys shape
 441     repr_tys  = drop (length shape_tys) (dataConRepArgTys repr_dc)
 442
 443 -- data T = C0 t1 ... tm
 444 --          ...
 445 --          Ck u1 ... un
 446 --
 447 -- data [:T:] = A ![:Int:] [:t1:] ... [:un:]
 448 --
 449 -- replicatePA :: Int# -> T -> [:T:]
 450 -- replicatePA n# t
 451 --   = let c = case t of
 452 --               C0 _ ... _ -> 0
 453 --               ...
 454 --               Ck _ ... _ -> k
 455 --
 456 --         xs1 = case t of
 457 --                 C0 x1 _ ... _ -> replicatePA @t1 n# x1
 458 --                 _             -> emptyPA @t1
 459 --
 460 --         ...
 461 --
 462 --         ysn = case t of
 463 --                 Ck _ ... _ yn -> replicatePA @un n# yn
 464 --                 _             -> emptyPA @un
 465 --     in
 466 --     A (replicatePA @Int n# c) xs1 ... ysn
 467 --
 468 --
 469
 470 buildReplicatePA :: Shape -> TyCon -> TyCon -> TyCon -> VM CoreExpr
 471 buildReplicatePA shape vect_tc _ arr_tc
 472   = do
 473       len_var <- newLocalVar FSLIT("n") intPrimTy
 474       val_var <- newLocalVar FSLIT("x") val_ty
 475
 476       let len = Var len_var
 477           val = Var val_var
 478
 479       shape_reprs <- shapeReplicate shape len (ctr_num val)
 480       reprs <- liftM concat $ mapM (mk_comp_arrs len val) vect_dcs
 481
 482       return . mkLams [len_var, val_var]
 483              . wrapFamInstBody arr_tc arg_tys
 484              $ mkConApp arr_dc (map Type arg_tys ++ shape_reprs ++ reprs)
 485   where
 486     arg_tys = mkTyVarTys (tyConTyVars arr_tc)
 487     val_ty  = mkTyConApp vect_tc arg_tys
 488     wild    = mkWildId val_ty
 489     vect_dcs = tyConDataCons vect_tc
 490     [arr_dc] = tyConDataCons arr_tc
 491
 492     ctr_num val = Case val wild intTy (zipWith ctr_num_alt vect_dcs [0..])
 493     ctr_num_alt dc i = (DataAlt dc, map mkWildId (dataConRepArgTys dc),
 494                                     mkConApp intDataCon [mkIntLitInt i])
 495
 496
 497     mk_comp_arrs len val dc = let tys = dataConRepArgTys dc
 498                                   wilds = map mkWildId tys
 499                               in
 500                               sequence (zipWith3 (mk_comp_arr len val dc)
 501                                        tys (inits wilds) (tails wilds))
 502
 503     mk_comp_arr len val dc ty pre (_:post)
 504       = do
 505           var   <- newLocalVar FSLIT("x") ty
 506           rep   <- replicatePA len (Var var)
 507           empty <- emptyPA ty
 508           arr_ty <- mkPArrayType ty
 509
 510           return $ Case val wild arr_ty
 511                      [(DEFAULT, [], empty), (DataAlt dc, pre ++ (var : post), rep)]
 512
 513 -- | Split the given tycons into two sets depending on whether they have to be
 514 -- converted (first list) or not (second list). The first argument contains
 515 -- information about the conversion status of external tycons:
 516 --
 517 --   * tycons which have converted versions are mapped to True
 518 --   * tycons which are not changed by vectorisation are mapped to False
 519 --   * tycons which can't be converted are not elements of the map
 520 --
 521 classifyTyCons :: UniqFM Bool -> [TyConGroup] -> ([TyCon], [TyCon])
 522 classifyTyCons = classify [] []
 523   where
 524     classify conv keep cs [] = (conv, keep)
 525     classify conv keep cs ((tcs, ds) : rs)
 526       | can_convert && must_convert
 527         = classify (tcs ++ conv) keep (cs `addListToUFM` [(tc,True) | tc <- tcs]) rs
 528       | can_convert
 529         = classify conv (tcs ++ keep) (cs `addListToUFM` [(tc,False) | tc <- tcs]) rs
 530       | otherwise
 531         = classify conv keep cs rs
 532       where
 533         refs = ds `delListFromUniqSet` tcs
 534
 535         can_convert  = isNullUFM (refs `minusUFM` cs) && all convertable tcs
 536         must_convert = foldUFM (||) False (intersectUFM_C const cs refs)
 537
 538         convertable tc = isDataTyCon tc && all isVanillaDataCon (tyConDataCons tc)
 539
 540 -- | Compute mutually recursive groups of tycons in topological order
 541 --
 542 tyConGroups :: [TyCon] -> [TyConGroup]
 543 tyConGroups tcs = map mk_grp (stronglyConnComp edges)
 544   where
 545     edges = [((tc, ds), tc, uniqSetToList ds) | tc <- tcs
 546                                 , let ds = tyConsOfTyCon tc]
 547
 548     mk_grp (AcyclicSCC (tc, ds)) = ([tc], ds)
 549     mk_grp (CyclicSCC els)       = (tcs, unionManyUniqSets dss)
 550       where
 551         (tcs, dss) = unzip els
 552
 553 tyConsOfTyCon :: TyCon -> UniqSet TyCon
 554 tyConsOfTyCon
 555   = tyConsOfTypes . concatMap dataConRepArgTys . tyConDataCons
 556
 557 tyConsOfType :: Type -> UniqSet TyCon
 558 tyConsOfType ty
 559   | Just ty' <- coreView ty    = tyConsOfType ty'
 560 tyConsOfType (TyVarTy v)       = emptyUniqSet
 561 tyConsOfType (TyConApp tc tys) = extend (tyConsOfTypes tys)
 562   where
 563     extend | isUnLiftedTyCon tc
 564            || isTupleTyCon   tc = id
 565
 566            | otherwise          = (`addOneToUniqSet` tc)
 567
 568 tyConsOfType (AppTy a b)       = tyConsOfType a `unionUniqSets` tyConsOfType b
 569 tyConsOfType (FunTy a b)       = (tyConsOfType a `unionUniqSets` tyConsOfType b)
 570                                  `addOneToUniqSet` funTyCon
 571 tyConsOfType (ForAllTy _ ty)   = tyConsOfType ty
 572 tyConsOfType other             = pprPanic "ClosureConv.tyConsOfType" $ ppr other
 573
 574 tyConsOfTypes :: [Type] -> UniqSet TyCon
 575 tyConsOfTypes = unionManyUniqSets . map tyConsOfType
 576