configure.ac

   1 dnl == autoconf source for the Glasgow FP tools ==
   2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
   3 dnl  (or some such) to see the outline of this file)
   4 dnl
   5 #
   6 # (c) The University of Glasgow 1994-2004
   7 #
   8 # Configure script template for GHC
   9 #
  10 # Process with 'autoreconf' to get a working configure script.
  11 #
  12 # For the generated configure script, do "./configure --help" to
  13 # see what flags are available. (Better yet, read the documentation!)
  14 #
  15
  16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [7.1], [glasgow-haskell-bugs@haskell.org], [ghc])
  17
  18 # Set this to YES for a released version, otherwise NO
  19 : ${RELEASE=NO}
  20
  21 # The primary version (e.g. 6.7, 6.6.1) is set in the AC_INIT line
  22 # above.  If this is not a released version, then we will append the
  23 # date to the version number (e.g. 6.7.20070204).  The date is
  24 # constructed by finding the date of the most recent patch in the
  25 # darcs repository.  If this is a source distribution (not a darcs
  26 # checkout), then we ship a file 'VERSION' containing the full version
  27 # when the source distribution was created.
  28
  29 if test ! -f mk/config.h.in; then
  30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
  31    exit 1
  32 fi
  33
  34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
  35
  36 dnl ----------------------------------------------------------
  37 dnl ** Find unixy sort and find commands,
  38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
  39
  40 dnl ** Find find command (for Win32's benefit)
  41 FP_PROG_FIND
  42
  43 dnl ** Find sort command (for the benefit of Win32 environs)
  44 FP_PROG_SORT
  45
  46 dnl ----------------------------------------------------------
  47 FP_SETUP_PROJECT_VERSION
  48
  49 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
  50 AC_SUBST([release], [1])
  51
  52 # First off, a distrib sanity check..
  53 AC_CONFIG_SRCDIR([mk/config.mk.in])
  54
  55 dnl * We require autoconf version 2.52
  56 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
  57 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
  58 AC_PREREQ([2.52])
  59
  60 # -------------------------------------------------------------------------
  61 # Prepare to generate the following header files
  62 #
  63 #
  64 AC_CONFIG_HEADER(mk/config.h)
  65
  66 # No, semi-sadly, we don't do `--srcdir'...
  67 if test x"$srcdir" != 'x.' ; then
  68     echo "This configuration does not support the \`--srcdir' option.."
  69     exit 1
  70 fi
  71
  72 dnl --------------------------------------------------------------
  73 dnl * Project specific configuration options
  74 dnl --------------------------------------------------------------
  75 dnl What follows is a bunch of options that can either be configured
  76 dnl through command line options to the configure script or by
  77 dnl supplying defns in the build tree's mk/build.mk. Having the option to
  78 dnl use either is considered a Feature.
  79
  80 dnl ** What command to use to compile compiler sources ?
  81 dnl --------------------------------------------------------------
  82
  83 AC_ARG_WITH([ghc],
  84 [AC_HELP_STRING([--with-ghc=ARG],
  85   [Use ARG as the path to GHC  [default=autodetect]])],
  86   [WithGhc="$withval"],
  87   [if test "$GHC" = ""; then
  88     AC_PATH_PROG([GHC], [ghc])
  89   fi
  90   WithGhc="$GHC"])
  91
  92
  93 dnl ** Tell the make system which OS we are using
  94 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
  95 AC_SUBST(OSTYPE)
  96
  97 dnl ** Booting from .hc files?
  98 dnl --------------------------------------------------------------
  99 AC_ARG_ENABLE(hc-boot,
 100 [AC_HELP_STRING([--enable-hc-boot],
 101 [Boot the Glasgow Haskell Compiler from intermediate .hc files.
 102  (This option is mostly of interest to porters.) [default=no]])],
 103 [ if test x"$enableval" = x"yes"; then
 104         BootingFromHc=YES
 105   else
 106         BootingFromHc=NO
 107   fi
 108 ],
 109 [BootingFromHc=NO]
 110 )
 111 AC_SUBST(BootingFromHc)
 112
 113 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
 114 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
 115                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
 116         EnableBootstrapWithDevelSnaphost=YES,
 117         EnableBootstrapWithDevelSnaphost=NO
 118 )
 119
 120 if test "$WithGhc" != ""; then
 121   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
 122
 123   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
 124      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
 125   fi
 126
 127   AC_SUBST(GhcVersion)dnl
 128   AC_SUBST(GhcMajVersion)dnl
 129   AC_SUBST(GhcMinVersion)dnl
 130   AC_SUBST(GhcPatchLevel)dnl
 131   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
 132   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
 133   if test $GhcCanonVersion -ge 613; then ghc_ge_613=YES; else ghc_ge_613=NO; fi
 134   AC_SUBST(ghc_ge_613)dnl
 135 fi
 136
 137 dnl ** Must have GHC to build GHC, unless --enable-hc-boot is on
 138 if test "$BootingFromHc" = "NO" -a -d "$srcdir/compiler"; then
 139   if test "$WithGhc" = ""; then
 140      AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 141   fi
 142   FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[6.12],
 143     [AC_MSG_ERROR([GHC version 6.12 or later is required to compile GHC.])])dnl
 144
 145   if test `expr $GhcMinVersion % 2` = "1"; then
 146      if test "$EnableBootstrapWithDevelSnaphost" = "NO"; then
 147         AC_MSG_ERROR([
 148      $WithGhc is a development snapshot of GHC, version $GhcVersion.
 149      Bootstrapping using this version of GHC is not supported, and may not
 150      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
 151      or --with-ghc to specify a different GHC to use.])
 152      fi
 153   fi
 154 fi;
 155
 156 # GHC is passed to Cabal, so we need a native path
 157 if test "${WithGhc}" != ""
 158 then
 159     ghc_host=`"${WithGhc}" +RTS --info | grep 'Host platform' | sed -e 's/.*, "//' -e 's/")//'`
 160
 161     if test "$ghc_host" = "i386-unknown-mingw32"
 162     then
 163         if test "${OSTYPE}" = "msys"
 164         then
 165             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
 166         else
 167             # Canonicalise to <drive>:/path/to/ghc
 168             WithGhc=`cygpath -m "${WithGhc}"`
 169         fi
 170         echo "GHC path canonicalised to: ${WithGhc}"
 171     fi
 172 fi
 173 AC_SUBST([WithGhc])
 174
 175 dnl ** Without optimization some INLINE trickery fails for GHCi
 176 SRC_CC_OPTS="-O"
 177
 178 FP_ICONV
 179 FP_GMP
 180
 181 dnl--------------------------------------------------------------------
 182 dnl * Choose host(/target/build) platform
 183 dnl--------------------------------------------------------------------
 184 dnl If we aren't explicitly told what values to use with configure flags,
 185 dnl we ask the bootstrapping compiler what platform it is for
 186
 187 if test "${WithGhc}" != ""
 188 then
 189         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 190         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 191         if test "$bootstrap_host" != "$bootstrap_target"
 192         then
 193                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
 194         fi
 195 fi
 196
 197 # We have to run these unconditionally, but we may discard their
 198 # results in the following code
 199 AC_CANONICAL_BUILD
 200 AC_CANONICAL_HOST
 201 AC_CANONICAL_TARGET
 202
 203 # If no argument was given for a configuration variable, then discard
 204 # the guessed canonical system and use the configuration of the
 205 # bootstrapping ghc. If an argument was given, map it from gnu format
 206 # to ghc format.
 207 #
 208 # For why we do it this way, see: #3637, #1717, #2951
 209
 210 if test "$build_alias" = ""
 211 then
 212     if test "${WithGhc}" != ""
 213     then
 214         build=$bootstrap_target
 215         echo "Build platform inferred as: $build"
 216     else
 217         echo "Can't work out build platform"
 218         exit 1
 219     fi
 220
 221     BuildArch=`echo "$build" | sed 's/-.*//'`
 222     BuildVendor=`echo "$build" | sed -e 's/.*-\(.*\)-.*/\1/'`
 223     BuildOS=`echo "$build" | sed 's/.*-//'`
 224 else
 225     GHC_CONVERT_CPU([$build_cpu], [BuildArch])
 226     GHC_CONVERT_VENDOR([$build_vendor], [BuildVendor])
 227     GHC_CONVERT_OS([$build_os], [BuildOS])
 228 fi
 229
 230 if test "$host_alias" = ""
 231 then
 232     if test "${WithGhc}" != ""
 233     then
 234         host=$bootstrap_target
 235         echo "Host platform inferred as: $host"
 236     else
 237         echo "Can't work out host platform"
 238         exit 1
 239     fi
 240
 241     HostArch=`echo "$host" | sed 's/-.*//'`
 242     HostVendor=`echo "$host" | sed -e 's/.*-\(.*\)-.*/\1/'`
 243     HostOS=`echo "$host" | sed 's/.*-//'`
 244 else
 245     GHC_CONVERT_CPU([$host_cpu], [HostArch])
 246     GHC_CONVERT_VENDOR([$host_vendor], [HostVendor])
 247     GHC_CONVERT_OS([$host_os], [HostOS])
 248 fi
 249
 250 if test "$target_alias" = ""
 251 then
 252     if test "${WithGhc}" != ""
 253     then
 254         target=$bootstrap_target
 255         echo "Target platform inferred as: $target"
 256     else
 257         echo "Can't work out target platform"
 258         exit 1
 259     fi
 260
 261     TargetArch=`echo "$target" | sed 's/-.*//'`
 262     TargetVendor=`echo "$target" | sed -e 's/.*-\(.*\)-.*/\1/'`
 263     TargetOS=`echo "$target" | sed 's/.*-//'`
 264 else
 265     GHC_CONVERT_CPU([$target_cpu], [TargetArch])
 266     GHC_CONVERT_VENDOR([$target_vendor], [TargetVendor])
 267     GHC_CONVERT_OS([$target_os], [TargetOS])
 268 fi
 269
 270 exeext=''
 271 soext='.so'
 272 case $host in
 273 *-unknown-cygwin32)
 274     AC_MSG_WARN([GHC does not support the Cygwin target at the moment])
 275     AC_MSG_WARN([I'm assuming you wanted to build for i386-unknown-mingw32])
 276     exit 1
 277     ;;
 278 *-unknown-mingw32)
 279     exeext='.exe'
 280     soext='.dll'
 281     ;;
 282 i386-apple-darwin|powerpc-apple-darwin)
 283     soext='.dylib'
 284     ;;
 285 x86_64-apple-darwin)
 286     soext='.dylib'
 287     ;;
 288 esac
 289
 290 # Sync this with cTargetArch in compiler/ghc.mk
 291 checkArch() {
 292     case $1 in
 293     alpha|arm|hppa|hppa1_1|i386|ia64|m68k|mips|mipseb|mipsel|powerpc|powerpc64|rs6000|s390|sparc|sparc64|vax|x86_64)
 294         ;;
 295     *)
 296         echo "Unknown arch $1"
 297         exit 1
 298         ;;
 299     esac
 300 }
 301
 302 checkVendor() {
 303     case $1 in
 304     dec|unknown|hp|apple|next|sun|sgi|ibm)
 305         ;;
 306     *)
 307         echo "Unknown vendor $1"
 308         exit 1
 309         ;;
 310     esac
 311 }
 312
 313 checkOS() {
 314     case $1 in
 315     linux|freebsd|netbsd|openbsd|dragonfly|osf1|osf3|hpux|linuxaout|kfreebsdgnu|freebsd2|solaris2|cygwin32|mingw32|darwin|gnu|nextstep2|nextstep3|sunos4|ultrix|irix|aix|haiku)
 316         ;;
 317     *)
 318         echo "Unknown OS '$1'"
 319         exit 1
 320         ;;
 321     esac
 322 }
 323
 324 BuildPlatform="$BuildArch-$BuildVendor-$BuildOS"
 325 BuildPlatform_CPP=`echo "$BuildPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 326 BuildArch_CPP=`    echo "$BuildArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 327 BuildVendor_CPP=`  echo "$BuildVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 328 BuildOS_CPP=`      echo "$BuildOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 329
 330 checkArch "$BuildArch"
 331 checkVendor "$BuildVendor"
 332 checkOS "$BuildOS"
 333
 334 HostPlatform="$HostArch-$HostVendor-$HostOS"
 335 HostPlatform_CPP=`echo "$HostPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 336 HostArch_CPP=`    echo "$HostArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 337 HostVendor_CPP=`  echo "$HostVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 338 HostOS_CPP=`      echo "$HostOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 339
 340 checkArch "$HostArch"
 341 checkVendor "$HostVendor"
 342 checkOS "$HostOS"
 343
 344 TargetPlatform="$TargetArch-$TargetVendor-$TargetOS"
 345 TargetPlatform_CPP=`echo "$TargetPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 346 TargetArch_CPP=`    echo "$TargetArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 347 TargetVendor_CPP=`  echo "$TargetVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 348 TargetOS_CPP=`      echo "$TargetOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 349
 350 checkArch "$TargetArch"
 351 checkVendor "$TargetVendor"
 352 checkOS "$TargetOS"
 353
 354 # Verify that the installed (bootstrap) GHC is capable of generating
 355 # code for the requested build platform.
 356 if test "$build" != "$bootstrap_target"
 357 then
 358     echo "This GHC (${WithGhc}) does not generate code for the build platform"
 359     echo "   GHC target platform    : $bootstrap_target"
 360     echo "   Desired build platform : $BuildPlatform"
 361     exit 1
 362 fi
 363
 364 AC_SUBST(BuildPlatform)
 365 AC_SUBST(HostPlatform)
 366 AC_SUBST(TargetPlatform)
 367 AC_SUBST(HostPlatform_CPP)
 368 AC_SUBST(BuildPlatform_CPP)
 369 AC_SUBST(TargetPlatform_CPP)
 370
 371 AC_SUBST(HostArch_CPP)
 372 AC_SUBST(BuildArch_CPP)
 373 AC_SUBST(TargetArch_CPP)
 374
 375 AC_SUBST(HostOS_CPP)
 376 AC_SUBST(BuildOS_CPP)
 377 AC_SUBST(TargetOS_CPP)
 378
 379 AC_SUBST(HostVendor_CPP)
 380 AC_SUBST(BuildVendor_CPP)
 381 AC_SUBST(TargetVendor_CPP)
 382
 383 AC_SUBST(exeext)
 384 AC_SUBST(soext)
 385
 386 AC_ARG_WITH(hc,
 387 [AC_HELP_STRING([--with-hc=ARG],
 388         [Use ARG as the path to the compiler for compiling ordinary
 389          Haskell code  (default= value of --with-ghc)])],
 390 [WithHc="$withval"],
 391 [WithHc=$WithGhc]
 392 )
 393 AC_SUBST(WithHc)
 394
 395 # This uses GHC, so put it after the "GHC is required" check above:
 396 FP_INTREE_GHC_PWD
 397 FP_FIND_ROOT
 398
 399 if test "$HostOS" = "mingw32"
 400 then
 401     test -d inplace || mkdir inplace
 402
 403     CC="$hardtop/inplace/mingw/bin/gcc.exe"
 404     LD="$hardtop/inplace/mingw/bin/ld.exe"
 405     NM="$hardtop/inplace/mingw/bin/nm.exe"
 406     fp_prog_ar_raw="$hardtop/inplace/mingw/bin/ar.exe"
 407
 408     # NB. If you update the tarbballs to a new version of gcc, don't
 409     # forget to tweak the paths in driver/gcc/gcc.c.
 410     if ! test -d inplace/mingw ||
 411          test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.lzma  ||
 412          test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.lzma  ||
 413          test inplace/mingw -ot ghc-tarballs/mingw/gcc-c++*.tar.lzma   ||
 414          test inplace/mingw -ot ghc-tarballs/mingw/libgcc*.tar.gz      ||
 415          test inplace/mingw -ot ghc-tarballs/mingw/libgmp*.tar.gz      ||
 416          test inplace/mingw -ot ghc-tarballs/mingw/libmpc*.tar.gz      ||
 417          test inplace/mingw -ot ghc-tarballs/mingw/libmpfr*.tar.gz     ||
 418          test inplace/mingw -ot ghc-tarballs/mingw/libstdc*.tar.lzma   ||
 419          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dev.tar.gz ||
 420          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dll.tar.gz ||
 421          test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.lzma
 422     then
 423         AC_MSG_NOTICE([Making in-tree mingw tree])
 424         rm -rf inplace/mingw
 425         mkdir inplace/mingw
 426         (
 427             cd inplace/mingw &&
 428             tar --lzma -xf ../../ghc-tarballs/mingw/binutils*.tar.lzma  &&
 429             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-core*.tar.lzma  &&
 430             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-c++*.tar.lzma   &&
 431             tar --lzma -xf ../../ghc-tarballs/mingw/libgcc*.tar.lzma    &&
 432             tar --lzma -xf ../../ghc-tarballs/mingw/libgmp*.tar.lzma    &&
 433             tar --lzma -xf ../../ghc-tarballs/mingw/libmpc*.tar.lzma    &&
 434             tar --lzma -xf ../../ghc-tarballs/mingw/libmpfr*.tar.lzma   &&
 435             tar --lzma -xf ../../ghc-tarballs/mingw/libstdc*.tar.lzma   &&
 436             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dev.tar.gz &&
 437             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dll.tar.gz &&
 438             tar --lzma -xf ../../ghc-tarballs/mingw/w32api*.tar.lzma    &&
 439             mv bin/gcc.exe bin/realgcc.exe
 440         )
 441         PATH=`pwd`/inplace/mingw/bin:$PATH inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
 442         if ! test -e inplace/mingw/bin/gcc.exe
 443         then
 444             AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 445         fi
 446         AC_MSG_NOTICE([In-tree mingw tree created])
 447     fi
 448     if ! test -d inplace/perl ||
 449          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
 450     then
 451         AC_MSG_NOTICE([Making in-tree perl tree])
 452         rm -rf inplace/perl
 453         mkdir inplace
 454         mkdir inplace/perl
 455         (
 456             cd inplace/perl &&
 457             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
 458         )
 459         AC_MSG_NOTICE([In-tree perl tree created])
 460     fi
 461 fi
 462
 463 dnl ** Which gcc to use?
 464 dnl --------------------------------------------------------------
 465 FP_ARG_WITH_PATH_GNU_PROG([CC], [gcc])
 466 export CC
 467 WhatGccIsCalled="$CC"
 468 AC_SUBST(WhatGccIsCalled)
 469
 470 dnl ** Which ld to use?
 471 dnl --------------------------------------------------------------
 472 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld])
 473 LdCmd="$LD"
 474 AC_SUBST([LdCmd])
 475
 476 dnl ** Which nm to use?
 477 dnl --------------------------------------------------------------
 478 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm])
 479 NmCmd="$NM"
 480 AC_SUBST([NmCmd])
 481
 482 dnl ** Mac OS X: explicit deployment target
 483 dnl --------------------------------------------------------------
 484 AC_ARG_WITH([macosx-deployment-target],
 485 [AC_HELP_STRING([--with-macosx-deployment-target=VERSION],
 486         [Build for Mac OS VERSION and higher  (default= version of build host)])],
 487 [FP_MACOSX_DEPLOYMENT_TARGET="$withval"
 488  if test "x$TargetOS_CPP-$TargetVendor_CPP" != "xdarwin-apple"; then
 489    # ignore everywhere, but on Mac OS
 490    AC_MSG_WARN([--macosx-deployment-target is only available on Mac OS X])
 491    FP_MACOSX_DEPLOYMENT_TARGET=none
 492  fi],
 493 [FP_MACOSX_DEPLOYMENT_TARGET=none]
 494 )
 495 FP_CHECK_MACOSX_DEPLOYMENT_TARGET
 496 AC_SUBST(MACOSX_DEPLOYMENT_VERSION)
 497 AC_SUBST(MACOSX_DEPLOYMENT_SDK)
 498
 499 dnl --------------------------------------------------------------
 500 dnl End of configure script option section
 501 dnl --------------------------------------------------------------
 502
 503
 504 dnl --------------------------------------------------------------
 505 dnl * General configuration checks
 506 dnl --------------------------------------------------------------
 507
 508 dnl ** Can the unix package be built?
 509 dnl --------------------------------------------------------------
 510
 511 if test x"$TargetPlatform" = x"i386-unknown-mingw32"; then
 512    GhcLibsWithUnix=NO
 513 else
 514    GhcLibsWithUnix=YES
 515 fi
 516 AC_SUBST([GhcLibsWithUnix])
 517
 518 dnl ** does #! work?
 519 AC_SYS_INTERPRETER()
 520
 521 dnl ** look for `perl'
 522 case $HostOS_CPP in
 523 cygwin32|mingw32)
 524     PerlCmd=$hardtop/inplace/perl/perl
 525     ;;
 526 *)
 527     AC_PATH_PROG(PerlCmd,perl)
 528     if test -z "$PerlCmd"
 529     then
 530         echo "You must install perl before you can continue"
 531         echo "Perhaps it is already installed, but not in your PATH?"
 532         exit 1
 533     else
 534         FPTOOLS_CHECK_PERL_VERSION
 535     fi
 536     ;;
 537 esac
 538
 539 dnl ** does #! path/to/perl work? (sometimes it's too long...)
 540 FPTOOLS_SHEBANG_PERL
 541
 542 dnl ** check for Python
 543 AC_PATH_PROG(PythonCmd,python)
 544
 545 dnl ** look for GCC and find out which version
 546 dnl     Figure out which C compiler to use.  Gcc is preferred.
 547 dnl     If gcc, make sure it's at least 2.1
 548 dnl
 549 FP_HAVE_GCC
 550
 551 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
 552 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
 553 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
 554 # Stage 3 won't be supported by cross-compilation
 555 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
 556
 557 FP_GCC_EXTRA_FLAGS
 558
 559 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
 560 AC_PROG_CPP
 561
 562 AC_SUBST(CONF_CC_OPTS_STAGE0)
 563 AC_SUBST(CONF_CC_OPTS_STAGE1)
 564 AC_SUBST(CONF_CC_OPTS_STAGE2)
 565 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
 566 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
 567 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
 568 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
 569 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
 570 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
 571 AC_SUBST(CONF_CPP_OPTS_STAGE0)
 572 AC_SUBST(CONF_CPP_OPTS_STAGE1)
 573 AC_SUBST(CONF_CPP_OPTS_STAGE2)
 574
 575 dnl ** figure out how to do context diffs
 576 FP_PROG_CONTEXT_DIFF
 577
 578 dnl Let's make sure install-sh is executable here.  If we got it from
 579 dnl a darcs repo, it might not be (see bug #978).
 580 chmod +x install-sh
 581 dnl ** figure out how to do a BSD-ish install
 582 AC_PROG_INSTALL
 583
 584 dnl If you can run configure, you certainly have /bin/sh
 585 AC_DEFINE([HAVE_BIN_SH], [1], [Define to 1 if you have /bin/sh.])
 586
 587 dnl ** how to invoke `ar' and `ranlib'
 588 FP_PROG_AR_SUPPORTS_ATFILE
 589 FP_PROG_AR_NEEDS_RANLIB
 590 FP_PROG_AR_SUPPORTS_INPUT
 591
 592 dnl ** Check to see whether ln -s works
 593 AC_PROG_LN_S
 594
 595
 596 dnl ** Find the path to sed
 597 AC_PATH_PROGS(SedCmd,gsed sed,sed)
 598
 599
 600 dnl ** check for time command
 601 AC_PATH_PROG(TimeCmd,time)
 602
 603 dnl ** check for tar
 604 dnl   if GNU tar is named gtar, look for it first.
 605 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
 606
 607 dnl ** check for patch
 608 dnl if GNU patch is named gpatch, look for it first
 609 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
 610
 611 dnl ** check for dtrace (currently only implemented for Mac OS X)
 612 HaveDtrace=NO
 613 AC_PATH_PROG(DtraceCmd,dtrace)
 614 if test -n "$DtraceCmd"; then
 615   if test "x$TargetOS_CPP-$TargetVendor_CPP" == "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" == "xsolaris2-unknown"; then
 616     HaveDtrace=YES
 617   fi
 618 fi
 619 AC_SUBST(HaveDtrace)
 620
 621 AC_PATH_PROG(HSCOLOUR,HsColour)
 622 # HsColour is passed to Cabal, so we need a native path
 623 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 624    test "${OSTYPE}"      != "msys"                  && \
 625    test "${HSCOLOUR}"    != ""
 626 then
 627     # Canonicalise to <drive>:/path/to/gcc
 628     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
 629 fi
 630
 631 dnl ** check for DocBook toolchain
 632 FP_CHECK_DOCBOOK_DTD
 633 FP_DOCBOOK_XSL
 634 FP_PROG_DBLATEX
 635
 636 FP_PROG_HSTAGS
 637
 638 dnl ** check for ghc-pkg command
 639 FP_PROG_GHC_PKG
 640
 641 dnl ** check for installed happy binary + version
 642 dnl    (don't do it if we're booting from .hc files though.)
 643 if test "$BootingFromHc" = "NO"; then
 644 FPTOOLS_HAPPY
 645 fi;
 646
 647 dnl ** check for installed alex binary + version
 648 dnl    (don't do it if we're booting from .hc files though.)
 649 if test "$BootingFromHc" = "NO"; then
 650 FPTOOLS_ALEX
 651 fi;
 652
 653 dnl --------------------------------------------------
 654 dnl ### program checking section ends here ###
 655 dnl --------------------------------------------------
 656
 657 dnl --------------------------------------------------
 658 dnl * Platform header file and syscall feature tests
 659 dnl ### checking the state of the local header files and syscalls ###
 660
 661 dnl ** check for full ANSI header (.h) files
 662 AC_HEADER_STDC
 663
 664 dnl ** Enable large file support.  NB. do this before testing the type of
 665 dnl    off_t, because it will affect the result of that test.
 666 AC_SYS_LARGEFILE
 667
 668 dnl ** check for specific header (.h) files that we are interested in
 669 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/cpuset.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
 670
 671 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
 672 AC_HEADER_TIME
 673
 674 dnl ** do we have long longs?
 675 AC_CHECK_TYPES([long long])
 676
 677 dnl ** what are the sizes of various types
 678 AC_CHECK_SIZEOF(char,               1)
 679 AC_CHECK_SIZEOF(double,             8)
 680 AC_CHECK_SIZEOF(float,              4)
 681 AC_CHECK_SIZEOF(int,                4)
 682 AC_CHECK_SIZEOF(long,               4)
 683 if test "$ac_cv_type_long_long" = yes; then
 684 AC_CHECK_SIZEOF(long long,          8)
 685 fi
 686 AC_CHECK_SIZEOF(short,              2)
 687 AC_CHECK_SIZEOF(unsigned char,      1)
 688 AC_CHECK_SIZEOF(unsigned int,       4)
 689 AC_CHECK_SIZEOF(unsigned long,      4)
 690 if test "$ac_cv_type_long_long" = yes; then
 691 AC_CHECK_SIZEOF(unsigned long long, 8)
 692 fi
 693 AC_CHECK_SIZEOF(unsigned short,     2)
 694 AC_CHECK_SIZEOF(void *,             4)
 695
 696 dnl ** what are alignment constraints on various types
 697 FP_CHECK_ALIGNMENT(char)
 698 FP_CHECK_ALIGNMENT(double)
 699 FP_CHECK_ALIGNMENT(float)
 700 FP_CHECK_ALIGNMENT(int)
 701 FP_CHECK_ALIGNMENT(long)
 702 if test "$ac_cv_type_long_long" = yes; then
 703 FP_CHECK_ALIGNMENT(long long)
 704 fi
 705 FP_CHECK_ALIGNMENT(short)
 706 FP_CHECK_ALIGNMENT(unsigned char)
 707 FP_CHECK_ALIGNMENT(unsigned int)
 708 FP_CHECK_ALIGNMENT(unsigned long)
 709 if test "$ac_cv_type_long_long" = yes; then
 710 FP_CHECK_ALIGNMENT(unsigned long long)
 711 fi
 712 FP_CHECK_ALIGNMENT(unsigned short)
 713 FP_CHECK_ALIGNMENT(void *)
 714
 715 FP_CHECK_FUNC([WinExec],
 716   [@%:@include <windows.h>], [WinExec("",0)])
 717
 718 FP_CHECK_FUNC([GetModuleFileName],
 719   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
 720
 721 dnl ** check return type of signal handlers
 722 dnl Foo: assumes we can use prototypes.
 723 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 724 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
 725 dnl [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 726 dnl #include <signal.h>
 727 dnl #ifdef signal
 728 dnl #undef signal
 729 dnl #endif
 730 dnl void (*signal (int, void (*)(int)))(int);
 731 dnl ]],
 732 dnl [[int i;]])],
 733 dnl [ac_cv_type_signal_handler=void_int],
 734 dnl [ac_cv_type_signal_handler=int_void])])
 735 dnl if test "$ac_cv_type_signal_handler" = void_int; then
 736 dnl AC_DEFINE(VOID_INT_SIGNALS)
 737 dnl fi
 738
 739 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 740 AC_TYPE_SIGNAL
 741 if test "$ac_cv_type_signal" = void; then
 742   AC_DEFINE([VOID_INT_SIGNALS], [1], [Define to 1 if signal handlers have type void (*)(int). Otherwise, they're assumed to have type int (*)(void).])
 743 fi
 744
 745 dnl ** check for more functions
 746 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
 747 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
 748
 749 AC_TRY_RUN([
 750 #include <sys/types.h>
 751 #include <sys/time.h>
 752 int main(void) {
 753   struct itimerval tval;
 754   tval.it_value.tv_sec = 1;
 755   tval.it_value.tv_usec = 0;
 756   tval.it_interval = tval.it_value;
 757   return setitimer(ITIMER_VIRTUAL, &tval, (void*)0) != 0;
 758 }
 759 ],[AC_DEFINE([HAVE_SETITIMER_VIRTUAL], [1], [Define to 1 if setitimer accepts ITIMER_VIRTUAL, 0 else.])])
 760
 761 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
 762 dnl ** _POSIX_C_SOURCE is defined
 763 AC_CHECK_DECLS([ctime_r], , ,
 764 [#define _POSIX_SOURCE 1
 765 #define _POSIX_C_SOURCE 199506L
 766 #include <time.h>])
 767
 768 dnl ** check for mingwex library
 769 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
 770 AC_SUBST(HaveLibMingwEx)
 771
 772 if test $HaveLibMingwEx = YES ; then
 773   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
 774 fi
 775
 776 dnl ** check for math library
 777 dnl    Keep that check as early as possible.
 778 dnl    as we need to know whether we need libm
 779 dnl    for math functions or not
 780 dnl    (see http://hackage.haskell.org/trac/ghc/ticket/3730)
 781 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
 782 if test $HaveLibM = YES
 783 then
 784   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
 785 fi
 786
 787 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
 788 dnl    the order of these tests matters: bfd needs liberty
 789 AC_CHECK_LIB(iberty, xmalloc)
 790 AC_CHECK_LIB(bfd,    bfd_init)
 791
 792 dnl ################################################################
 793 dnl Check for libraries
 794 dnl ################################################################
 795
 796 dnl ** check whether we need -ldl to get dlopen()
 797
 798 AC_CHECK_LIB(dl, dlopen,
 799     [HaveLibDL=YES
 800      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
 801      LIBS="$LIBS -ldl"],
 802     [HaveLibDL=NO])
 803 AC_SUBST(HaveLibDL)
 804
 805 dnl --------------------------------------------------
 806 dnl * Miscellaneous feature tests
 807 dnl --------------------------------------------------
 808
 809 dnl ** can we get alloca?
 810 AC_FUNC_ALLOCA
 811
 812 dnl ** Working vfork?
 813 AC_FUNC_FORK
 814
 815 dnl ** determine whether or not const works
 816 AC_C_CONST
 817
 818 dnl ** are we big endian?
 819 AC_C_BIGENDIAN
 820 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
 821
 822 dnl ** check for leading underscores in symbol names
 823 FP_LEADING_UNDERSCORE
 824
 825 dnl ** check for ld, whether it has an -x option, and if it is GNU ld
 826 FP_PROG_LD_X
 827 FP_PROG_LD_IS_GNU
 828
 829 dnl ** check for Apple-style dead-stripping support
 830 dnl    (.subsections-via-symbols assembler directive)
 831
 832
 833 AC_MSG_CHECKING(for .subsections_via_symbols)
 834 AC_COMPILE_IFELSE(
 835     [AC_LANG_PROGRAM([], [__asm__ (".subsections_via_symbols");])],
 836     [AC_MSG_RESULT(yes)
 837      AC_DEFINE([HAVE_SUBSECTIONS_VIA_SYMBOLS],[1],
 838                [Define to 1 if Apple-style dead-stripping is supported.])
 839     ],
 840     [AC_MSG_RESULT(no)])
 841
 842 dnl *** check for GNU non-executable stack note support (ELF only)
 843 dnl     (.section .note.GNU-stack,"",@progbits)
 844
 845 dnl This test doesn't work with "gcc -g" in gcc 4.4 (GHC trac #3889:
 846 dnl     Error: can't resolve `.note.GNU-stack' {.note.GNU-stack section} - `.Ltext0' {.text section}
 847 dnl so we empty CFLAGS while running this test
 848 CFLAGS2="$CFLAGS"
 849 CFLAGS=
 850 AC_MSG_CHECKING(for GNU non-executable stack support)
 851 AC_COMPILE_IFELSE(
 852     [AC_LANG_PROGRAM([__asm__ (".section .note.GNU-stack,\"\",@progbits");], [0])],
 853     [AC_MSG_RESULT(yes)
 854      AC_DEFINE([HAVE_GNU_NONEXEC_STACK],[1],
 855                [Define to 1 if GNU non-executable stack notes are supported.])
 856     ],
 857     [AC_MSG_RESULT(no)])
 858 CFLAGS="$CFLAGS2"
 859
 860 FP_VISIBILITY_HIDDEN
 861
 862 dnl ** check for librt
 863 AC_CHECK_LIB(rt, clock_gettime)
 864 AC_CHECK_FUNCS(clock_gettime timer_create timer_settime)
 865 FP_CHECK_TIMER_CREATE
 866
 867 dnl ** check for Apple's "interesting" long double compatibility scheme
 868 AC_MSG_CHECKING(for printf\$LDBLStub)
 869 AC_TRY_LINK_FUNC(printf\$LDBLStub,
 870     [
 871         AC_MSG_RESULT(yes)
 872         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
 873             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 874     ],
 875     [
 876         AC_MSG_RESULT(no)
 877         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
 878             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 879     ])
 880
 881 dnl ** check for eventfd which is needed by the I/O manager
 882 AC_CHECK_HEADERS([sys/eventfd.h])
 883 AC_CHECK_FUNCS([eventfd])
 884
 885 # test for GTK+
 886 AC_PATH_PROGS([GTK_CONFIG], [pkg-config])
 887 if test -n "$GTK_CONFIG"; then
 888   if $GTK_CONFIG gtk+-2.0 --atleast-version=2.0; then
 889     GTK_CONFIG="$GTK_CONFIG gtk+-2.0"
 890   else
 891     AC_MSG_WARN([GTK+ not usable, need at least version 2.0])
 892     GTK_CONFIG=
 893   fi
 894 fi
 895 AC_SUBST([GTK_CONFIG])
 896
 897 #Checking for PAPI
 898 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
 899 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
 900 AC_SUBST(HavePapiLib)
 901 AC_SUBST(HavePapiHeader)
 902
 903 AC_CHECK_FUNCS(__mingw_vfprintf)
 904
 905 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
 906    HavePapi=YES
 907 else
 908    HavePapi=NO
 909 fi
 910 AC_SUBST(HavePapi)
 911
 912 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
 913    test "$XsltprocCmd" = ""
 914 then
 915     BUILD_DOCBOOK_HTML=NO
 916 else
 917     BUILD_DOCBOOK_HTML=YES
 918 fi
 919 AC_SUBST(BUILD_DOCBOOK_HTML)
 920
 921 if test "$DblatexCmd" = ""
 922 then
 923     BUILD_DOCBOOK_PS=NO
 924     BUILD_DOCBOOK_PDF=NO
 925 else
 926     BUILD_DOCBOOK_PS=YES
 927     BUILD_DOCBOOK_PDF=YES
 928 fi
 929 AC_SUBST(BUILD_DOCBOOK_PS)
 930 AC_SUBST(BUILD_DOCBOOK_PDF)
 931
 932 LIBRARY_VERSION(base)
 933 LIBRARY_VERSION(Cabal)
 934 LIBRARY_VERSION(ghc-prim)
 935 LIBRARY_ghc_VERSION="$ProjectVersion"
 936 AC_SUBST(LIBRARY_ghc_VERSION)
 937
 938 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
 939    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
 940 fi
 941
 942 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal ghc.spec extra-gcc-opts docs/users_guide/ug-book.xml docs/users_guide/ug-ent.xml docs/index.html libraries/prologue.txt distrib/ghc.iss distrib/configure.ac distrib/MacOS/installer-scripts/create-links distrib/MacOS/installer-scripts/Uninstaller distrib/MacOS/GHC-system.pmdoc/index.xml])
 943 AC_CONFIG_COMMANDS([mk/stamp-h],[echo timestamp > mk/stamp-h])
 944 AC_OUTPUT
 945
 946 # We get caught by
 947 #     http://savannah.gnu.org/bugs/index.php?1516
 948 #     $(eval ...) inside conditionals causes errors
 949 # with make 3.80, so warn the user if it looks like they're about to
 950 # try to use it.
 951 # We would use "grep -q" here, but Solaris's grep doesn't support it.
 952 checkMake380() {
 953     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
 954     then
 955         echo
 956         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
 957         echo "This version cannot be used to build GHC."
 958         echo "Please use GNU make >= 3.81."
 959     fi
 960 }
 961
 962 checkMake380 make
 963 checkMake380 gmake
 964
 965 echo ["
 966 ----------------------------------------------------------------------
 967 Configure completed successfully.
 968
 969    Building GHC version  : $ProjectVersion
 970
 971    Build platform        : $BuildPlatform
 972    Host platform         : $HostPlatform
 973    Target platform       : $TargetPlatform
 974 "]
 975
 976 if test "$BootingFromHc" = "YES"; then
 977 echo ["\
 978    Bootstrapping from HC files.
 979 "]
 980 else
 981 echo ["\
 982    Bootstrapping using   : $WithGhc
 983       which is version   : $GhcVersion
 984 "]
 985 fi
 986
 987 echo ["\
 988    Using GCC             : $WhatGccIsCalled
 989       which is version   : $GccVersion
 990
 991    ld       : $LdCmd
 992    Happy    : $HappyCmd ($HappyVersion)
 993    Alex     : $AlexCmd ($AlexVersion)
 994    Python   : $PythonCmd
 995    Perl     : $PerlCmd
 996    dblatex  : $DblatexCmd
 997    xsltproc : $XsltprocCmd"]
 998
 999 if test "$HSCOLOUR" = ""; then
1000 echo ["
1001    HsColour was not found; documentation will not contain source links
1002 "]
1003 else
1004 echo ["\
1005    HsColour : $HSCOLOUR
1006 "]
1007 fi
1008
1009 echo ["\
1010    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
1011    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
1012    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
1013
1014 echo ["----------------------------------------------------------------------
1015 "]
1016
1017 echo "\
1018 For a standard build of GHC (fully optimised with profiling), type (g)make.
1019
1020 To make changes to the default build configuration, copy the file
1021 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1022
1023 For more information on how to configure your GHC build, see
1024    http://hackage.haskell.org/trac/ghc/wiki/Building
1025 "