configure.ac

   1 dnl == autoconf source for the Glasgow FP tools ==
   2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
   3 dnl  (or some such) to see the outline of this file)
   4 dnl
   5 #
   6 # (c) The University of Glasgow 1994-2004
   7 #
   8 # Configure script template for GHC
   9 #
  10 # Process with 'autoreconf' to get a working configure script.
  11 #
  12 # For the generated configure script, do "./configure --help" to
  13 # see what flags are available. (Better yet, read the documentation!)
  14 #
  15
  16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [6.13], [glasgow-haskell-bugs@haskell.org], [ghc])
  17
  18 # Set this to YES for a released version, otherwise NO
  19 : ${RELEASE=NO}
  20
  21 # The primary version (e.g. 6.7, 6.6.1) is set in the AC_INIT line
  22 # above.  If this is not a released version, then we will append the
  23 # date to the version number (e.g. 6.7.20070204).  The date is
  24 # constructed by finding the date of the most recent patch in the
  25 # darcs repository.  If this is a source distribution (not a darcs
  26 # checkout), then we ship a file 'VERSION' containing the full version
  27 # when the source distribution was created.
  28
  29 if test ! -f mk/config.h.in; then
  30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'sh boot'?"
  31    exit 1
  32 fi
  33
  34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
  35
  36 dnl ----------------------------------------------------------
  37 dnl ** Find unixy sort and find commands,
  38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
  39
  40 dnl ** Find find command (for Win32's benefit)
  41 FP_PROG_FIND
  42
  43 dnl ** Find sort command (for the benefit of Win32 environs)
  44 FP_PROG_SORT
  45
  46 dnl ----------------------------------------------------------
  47 FP_SETUP_PROJECT_VERSION
  48
  49 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
  50 AC_SUBST([release], [1])
  51
  52 # First off, a distrib sanity check..
  53 AC_CONFIG_SRCDIR([mk/config.mk.in])
  54
  55 dnl * We require autoconf version 2.52
  56 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
  57 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
  58 AC_PREREQ([2.52])
  59
  60 # -------------------------------------------------------------------------
  61 # Prepare to generate the following header files
  62 #
  63 #
  64 AC_CONFIG_HEADER(mk/config.h)
  65
  66 # No, semi-sadly, we don't do `--srcdir'...
  67 if test x"$srcdir" != 'x.' ; then
  68     echo "This configuration does not support the \`--srcdir' option.."
  69     exit 1
  70 fi
  71
  72 dnl --------------------------------------------------------------
  73 dnl * Project specific configuration options
  74 dnl --------------------------------------------------------------
  75 dnl What follows is a bunch of options that can either be configured
  76 dnl through command line options to the configure script or by
  77 dnl supplying defns in the build tree's mk/build.mk. Having the option to
  78 dnl use either is considered a Feature.
  79
  80 dnl ** What command to use to compile compiler sources ?
  81 dnl --------------------------------------------------------------
  82
  83 AC_ARG_WITH([ghc],
  84 [AC_HELP_STRING([--with-ghc=ARG],
  85   [Use ARG as the path to GHC  [default=autodetect]])],
  86   [WithGhc="$withval"],
  87   [if test "$GHC" = ""; then
  88     AC_PATH_PROG([GHC], [ghc])
  89   fi
  90   WithGhc="$GHC"])
  91
  92 dnl ** Booting from .hc files?
  93 dnl --------------------------------------------------------------
  94 AC_ARG_ENABLE(hc-boot,
  95 [AC_HELP_STRING([--enable-hc-boot],
  96 [Boot the Glasgow Haskell Compiler from intermediate .hc files.
  97  (This option is mostly of interest to porters.) [default=no]])],
  98 [ if test x"$enableval" = x"yes"; then
  99         BootingFromHc=YES
 100   else
 101         BootingFromHc=NO
 102   fi
 103 ],
 104 [BootingFromHc=NO]
 105 )
 106 AC_SUBST(BootingFromHc)
 107
 108 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
 109 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
 110                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
 111         EnableBootstrapWithDevelSnaphost=YES,
 112         EnableBootstrapWithDevelSnaphost=NO
 113 )
 114
 115 if test "$WithGhc" != ""; then
 116   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
 117
 118   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
 119      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
 120   fi
 121
 122   AC_SUBST(GhcVersion)dnl
 123   AC_SUBST(GhcMajVersion)dnl
 124   AC_SUBST(GhcMinVersion)dnl
 125   AC_SUBST(GhcPatchLevel)dnl
 126   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
 127   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
 128   if test $GhcCanonVersion -ge 609; then ghc_ge_609=YES; else ghc_ge_609=NO; fi
 129   FP_COMPARE_VERSIONS($GhcVersion,[-ge],[6.10.2],
 130                       [ghc_ge_6102=YES], [ghc_ge_6102=NO])
 131   if test $GhcCanonVersion -ge 611; then ghc_ge_611=YES; else ghc_ge_611=NO; fi
 132   AC_SUBST(ghc_ge_609)dnl
 133   AC_SUBST(ghc_ge_6102)dnl
 134   AC_SUBST(ghc_ge_611)dnl
 135 fi
 136
 137 dnl ** Must have GHC to build GHC, unless --enable-hc-boot is on
 138 if test "$BootingFromHc" = "NO" -a -d "$srcdir/compiler"; then
 139   if test "$WithGhc" = ""; then
 140      AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 141   fi
 142   FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[6.8],
 143     [AC_MSG_ERROR([GHC version 6.8 or later is required to compile GHC.])])dnl
 144
 145   if test `expr $GhcMinVersion % 2` = "1"; then
 146      if test "$EnableBootstrapWithDevelSnaphost" = "NO"; then
 147         AC_MSG_ERROR([
 148      $WithGhc is a development snapshot of GHC, version $GhcVersion.
 149      Bootstrapping using this version of GHC is not supported, and may not
 150      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
 151      or --with-ghc to specify a different GHC to use.])
 152      fi
 153   fi
 154 fi;
 155
 156 # GHC is passed to Cabal, so we need a native path
 157 if test "${WithGhc}" != ""
 158 then
 159     ghc_host=`"${WithGhc}" +RTS --info | grep 'Host platform' | sed -e 's/.*, "//' -e 's/")//'`
 160
 161     if test "$ghc_host" = "i386-unknown-mingw32"
 162     then
 163         if test "${OSTYPE}" = "msys"
 164         then
 165             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
 166         else
 167             # Canonicalise to <drive>:/path/to/ghc
 168             WithGhc=`cygpath -m "${WithGhc}"`
 169         fi
 170         echo "GHC path canonicalised to: ${WithGhc}"
 171     fi
 172 fi
 173 AC_SUBST([WithGhc])
 174
 175 dnl ** Without optimization some INLINE trickery fails for GHCi
 176 SRC_CC_OPTS="-O"
 177
 178 dnl Allow to specify iconv options to the toplevel configure script
 179 dnl so they can be properly passed to sub-builds.
 180 dnl Note: ICONV_LIB_DIRS and ICONV_INCLUDE_DIRS are not predefined
 181 dnl to the empty string to allow them to be overridden from the
 182 dnl environment.
 183
 184 AC_ARG_WITH([iconv-includes],
 185   [AC_HELP_STRING([--with-iconv-includes],
 186     [directory containing iconv.h])],
 187     [ICONV_INCLUDE_DIRS=$withval])
 188
 189 AC_ARG_WITH([iconv-libraries],
 190   [AC_HELP_STRING([--with-iconv-libraries],
 191     [directory containing iconv library])],
 192     [ICONV_LIB_DIRS=$withval])
 193
 194 AC_SUBST(ICONV_INCLUDE_DIRS)
 195 AC_SUBST(ICONV_LIB_DIRS)
 196
 197 dnl--------------------------------------------------------------------
 198 dnl * Choose host(/target/build) platform
 199 dnl--------------------------------------------------------------------
 200 dnl We don't use the standard autoconf macros for this, but instead
 201 dnl ask the bootstrapping compiler what platform it is for
 202
 203 dnl Guess host/target/build platform(s) if necessary.
 204 m4_divert_once([HELP_CANON],
 205 [[
 206 System types:
 207   --build=BUILD     configure for building on BUILD [guessed]
 208   --host=HOST       cross-compile to build programs to run on HOST [guessed]
 209   --target=TARGET   configure for building compilers for TARGET [guessed]]])dnl
 210
 211 if test "${WithGhc}" != ""
 212 then
 213         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 214         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 215         if test "$bootstrap_host" != "$bootstrap_target"
 216         then
 217                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
 218         fi
 219 fi
 220
 221 # We have to run these unconditionally, but we may discard their
 222 # results in the following code
 223 AC_CANONICAL_BUILD
 224 AC_CANONICAL_HOST
 225 AC_CANONICAL_TARGET
 226
 227 # If no argument was given for a configuration variable, then discard
 228 # the guessed canonical system and use the configuration of the
 229 # bootstrapping ghc. If an argument was given, map it from gnu format
 230 # to ghc format.
 231 #
 232 # For why we do it this way, see: #3637, #1717, #2951
 233
 234 if test "$build_alias" = ""
 235 then
 236     if test "${WithGhc}" != ""
 237     then
 238         build=$bootstrap_target
 239         echo "Build platform inferred as: $build"
 240     else
 241         echo "Can't work out build platform"
 242         exit 1
 243     fi
 244
 245     BuildArch=`echo "$build" | sed 's/-.*//'`
 246     BuildVendor=`echo "$build" | sed -e 's/.*-\(.*\)-.*/\1/'`
 247     BuildOS=`echo "$build" | sed 's/.*-//'`
 248 else
 249     GHC_CONVERT_CPU([$build_cpu], [BuildArch])
 250     GHC_CONVERT_VENDOR([$build_vendor], [BuildVendor])
 251     GHC_CONVERT_OS([$build_os], [BuildOS])
 252 fi
 253
 254 if test "$host_alias" = ""
 255 then
 256     if test "${WithGhc}" != ""
 257     then
 258         host=$bootstrap_target
 259         echo "Host platform inferred as: $host"
 260     else
 261         echo "Can't work out host platform"
 262         exit 1
 263     fi
 264
 265     HostArch=`echo "$host" | sed 's/-.*//'`
 266     HostVendor=`echo "$host" | sed -e 's/.*-\(.*\)-.*/\1/'`
 267     HostOS=`echo "$host" | sed 's/.*-//'`
 268 else
 269     GHC_CONVERT_CPU([$host_cpu], [HostArch])
 270     GHC_CONVERT_VENDOR([$host_vendor], [HostVendor])
 271     GHC_CONVERT_OS([$host_os], [HostOS])
 272 fi
 273
 274 if test "$target_alias" = ""
 275 then
 276     if test "${WithGhc}" != ""
 277     then
 278         target=$bootstrap_target
 279         echo "Target platform inferred as: $target"
 280     else
 281         echo "Can't work out target platform"
 282         exit 1
 283     fi
 284
 285     TargetArch=`echo "$target" | sed 's/-.*//'`
 286     TargetVendor=`echo "$target" | sed -e 's/.*-\(.*\)-.*/\1/'`
 287     TargetOS=`echo "$target" | sed 's/.*-//'`
 288 else
 289     GHC_CONVERT_CPU([$target_cpu], [TargetArch])
 290     GHC_CONVERT_VENDOR([$target_vendor], [TargetVendor])
 291     GHC_CONVERT_OS([$target_os], [TargetOS])
 292 fi
 293
 294 exeext=''
 295 soext='.so'
 296 case $host in
 297 *-unknown-cygwin32)
 298     AC_MSG_WARN([GHC does not support the Cygwin target at the moment])
 299     AC_MSG_WARN([I'm assuming you wanted to build for i386-unknown-mingw32])
 300     exit 1
 301     ;;
 302 *-unknown-mingw32)
 303     exeext='.exe'
 304     soext='.dll'
 305     ;;
 306 i386-apple-darwin|powerpc-apple-darwin)
 307     soext='.dylib'
 308     CFLAGS="$CFLAGS -m32"
 309     LDFLAGS="$LDFLAGS -m32"
 310     CONF_CC_OPTS="$CONF_CC_OPTS -m32"
 311     CONF_LD_OPTS="$CONF_LD_OPTS -m32"
 312     ;;
 313 x86_64-apple-darwin)
 314     soext='.dylib'
 315     CFLAGS="$CFLAGS -m64"
 316     LDFLAGS="$LDFLAGS -m64"
 317     CONF_CC_OPTS="$CONF_CC_OPTS -m64"
 318     CONF_LD_OPTS="$CONF_LD_OPTS -m64"
 319     ;;
 320 esac
 321
 322 checkArch() {
 323     case $1 in
 324     alpha|arm|hppa|hppa1_1|i386|ia64|m68k|mips|mipseb|mipsel|powerpc|powerpc64|rs6000|s390|sparc|sparc64|vax|x86_64)
 325         ;;
 326     *)
 327         echo "Unknown arch $1"
 328         exit 1
 329         ;;
 330     esac
 331 }
 332
 333 checkVendor() {
 334     case $1 in
 335     dec|unknown|hp|apple|next|sun|sgi|ibm)
 336         ;;
 337     *)
 338         echo "Unknown vendor $1"
 339         exit 1
 340         ;;
 341     esac
 342 }
 343
 344 checkOS() {
 345     case $1 in
 346     linux|freebsd|netbsd|openbsd|dragonfly|osf1|osf3|hpux|linuxaout|kfreebsdgnu|freebsd2|solaris2|cygwin32|mingw32|darwin|gnu|nextstep2|nextstep3|sunos4|ultrix|irix|aix|haiku)
 347         ;;
 348     *)
 349         echo "Unknown OS '$1'"
 350         exit 1
 351         ;;
 352     esac
 353 }
 354
 355 BuildPlatform="$BuildArch-$BuildVendor-$BuildOS"
 356 BuildPlatform_CPP=`echo "$BuildPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 357 BuildArch_CPP=`    echo "$BuildArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 358 BuildVendor_CPP=`  echo "$BuildVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 359 BuildOS_CPP=`      echo "$BuildOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 360
 361 checkArch "$BuildArch"
 362 checkVendor "$BuildVendor"
 363 checkOS "$BuildOS"
 364
 365 HostPlatform="$HostArch-$HostVendor-$HostOS"
 366 HostPlatform_CPP=`echo "$HostPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 367 HostArch_CPP=`    echo "$HostArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 368 HostVendor_CPP=`  echo "$HostVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 369 HostOS_CPP=`      echo "$HostOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 370
 371 checkArch "$HostArch"
 372 checkVendor "$HostVendor"
 373 checkOS "$HostOS"
 374
 375 TargetPlatform="$TargetArch-$TargetVendor-$TargetOS"
 376 TargetPlatform_CPP=`echo "$TargetPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 377 TargetArch_CPP=`    echo "$TargetArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 378 TargetVendor_CPP=`  echo "$TargetVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 379 TargetOS_CPP=`      echo "$TargetOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 380
 381 checkArch "$TargetArch"
 382 checkVendor "$TargetVendor"
 383 checkOS "$TargetOS"
 384
 385 AC_SUBST(BuildPlatform)
 386 AC_SUBST(HostPlatform)
 387 AC_SUBST(TargetPlatform)
 388 AC_SUBST(HostPlatform_CPP)
 389 AC_SUBST(BuildPlatform_CPP)
 390 AC_SUBST(TargetPlatform_CPP)
 391
 392 AC_SUBST(HostArch_CPP)
 393 AC_SUBST(BuildArch_CPP)
 394 AC_SUBST(TargetArch_CPP)
 395
 396 AC_SUBST(HostOS_CPP)
 397 AC_SUBST(BuildOS_CPP)
 398 AC_SUBST(TargetOS_CPP)
 399
 400 AC_SUBST(HostVendor_CPP)
 401 AC_SUBST(BuildVendor_CPP)
 402 AC_SUBST(TargetVendor_CPP)
 403
 404 AC_SUBST(exeext)
 405 AC_SUBST(soext)
 406
 407 AC_ARG_WITH(hc,
 408 [AC_HELP_STRING([--with-hc=ARG],
 409         [Use ARG as the path to the compiler for compiling ordinary
 410          Haskell code  (default= value of --with-ghc)])],
 411 [WithHc="$withval"],
 412 [WithHc=$WithGhc]
 413 )
 414 AC_SUBST(WithHc)
 415
 416 AC_PATH_PROGS(NHC,nhc nhc98)
 417 AC_PATH_PROG(HBC,hbc)
 418
 419 # This uses GHC, so put it after the "GHC is required" check above:
 420 FP_FIND_ROOT
 421
 422 if test "$HostOS" = "mingw32"
 423 then
 424     CC="$hardtop/inplace/mingw/bin/gcc.exe"
 425     LD="$hardtop/inplace/mingw/bin/ld.exe"
 426     NM="$hardtop/inplace/mingw/bin/nm.exe"
 427     if ! test -d inplace/mingw ||
 428          test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.gz ||
 429          test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.gz ||
 430          test inplace/mingw -ot ghc-tarballs/mingw/libcrypt*.tar.bz2 ||
 431          test inplace/mingw -ot ghc-tarballs/mingw/mingw-runtime*.tar.gz ||
 432          test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.gz
 433     then
 434         AC_MSG_NOTICE([Making in-tree mingw tree])
 435         rm -rf inplace/mingw
 436         mkdir inplace
 437         mkdir inplace/mingw
 438         (
 439             cd inplace/mingw &&
 440             tar -zxf ../../ghc-tarballs/mingw/binutils*.tar.gz &&
 441             tar -zxf ../../ghc-tarballs/mingw/gcc-core*.tar.gz &&
 442             tar -jxf ../../ghc-tarballs/mingw/libcrypt*.tar.bz2 &&
 443             tar -zxf ../../ghc-tarballs/mingw/mingw-runtime*.tar.gz &&
 444             tar -zxf ../../ghc-tarballs/mingw/w32api*.tar.gz &&
 445             mv bin/gcc.exe bin/realgcc.exe
 446         )
 447         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
 448         AC_MSG_NOTICE([In-tree mingw tree created])
 449     fi
 450     if ! test -d inplace/perl ||
 451          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
 452     then
 453         AC_MSG_NOTICE([Making in-tree perl tree])
 454         rm -rf inplace/perl
 455         mkdir inplace
 456         mkdir inplace/perl
 457         (
 458             cd inplace/perl &&
 459             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
 460         )
 461         AC_MSG_NOTICE([In-tree perl tree created])
 462     fi
 463 fi
 464
 465 dnl ** Which gcc to use?
 466 dnl --------------------------------------------------------------
 467 FP_ARG_WITH_PATH_GNU_PROG([CC], [gcc])
 468 export CC
 469 WhatGccIsCalled="$CC"
 470 AC_SUBST(WhatGccIsCalled)
 471
 472 dnl ** Which ld to use?
 473 dnl --------------------------------------------------------------
 474 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld])
 475 LdCmd="$LD"
 476 AC_SUBST([LdCmd])
 477
 478 dnl ** Which nm to use?
 479 dnl --------------------------------------------------------------
 480 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm])
 481 NmCmd="$NM"
 482 AC_SUBST([NmCmd])
 483
 484 dnl ** Mac OS X: explicit deployment target
 485 dnl --------------------------------------------------------------
 486 AC_ARG_WITH([macosx-deployment-target],
 487 [AC_HELP_STRING([--with-macosx-deployment-target=VERSION],
 488         [Build for Mac OS VERSION and higher  (default= version of build host)])],
 489 [FP_MACOSX_DEPLOYMENT_TARGET="$withval"
 490  if test "x$TargetOS_CPP-$TargetVendor_CPP" != "xdarwin-apple"; then
 491    # ignore everywhere, but on Mac OS
 492    AC_MSG_WARN([--macosx-deployment-target is only available on Mac OS X])
 493    FP_MACOSX_DEPLOYMENT_TARGET=none
 494  fi],
 495 [FP_MACOSX_DEPLOYMENT_TARGET=none]
 496 )
 497 FP_CHECK_MACOSX_DEPLOYMENT_TARGET
 498 AC_SUBST(MACOSX_DEPLOYMENT_VERSION)
 499 AC_SUBST(MACOSX_DEPLOYMENT_SDK)
 500
 501 dnl --------------------------------------------------------------
 502 dnl End of configure script option section
 503 dnl --------------------------------------------------------------
 504
 505
 506 dnl --------------------------------------------------------------
 507 dnl * General configuration checks
 508 dnl --------------------------------------------------------------
 509
 510 dnl ** Can the unix package be built?
 511 dnl --------------------------------------------------------------
 512
 513 if test x"$TargetPlatform" = x"i386-unknown-mingw32"; then
 514    GhcLibsWithUnix=NO
 515 else
 516    GhcLibsWithUnix=YES
 517 fi
 518 AC_SUBST([GhcLibsWithUnix])
 519
 520 dnl ** does #! work?
 521 AC_SYS_INTERPRETER()
 522
 523 dnl ** look for `perl', but only in /bin on Windows
 524 case $HostOS_CPP in
 525 cygwin32|mingw32)
 526       AC_CHECK_PROG(PerlCmd,perl,/bin/perl,,/bin)
 527       if test -z "$PerlCmd"; then
 528          echo "You must install the version of Perl shipped with GHC"
 529          echo "(or a compatible one) in /bin."
 530          exit 1
 531       fi
 532    ;;
 533 *)
 534    AC_PATH_PROG(PerlCmd,perl)
 535    if test -z "$PerlCmd"; then
 536       echo "You must install perl before you can continue"
 537       echo "Perhaps it is already installed, but not in your PATH?"
 538       exit 1
 539    else
 540    FPTOOLS_CHECK_PERL_VERSION
 541    fi
 542    ;;
 543 esac
 544
 545 dnl ** does #! path/to/perl work? (sometimes it's too long...)
 546 FPTOOLS_SHEBANG_PERL
 547
 548 dnl ** check for Python
 549 AC_PATH_PROG(PythonCmd,python)
 550
 551 dnl ** look for GCC and find out which version
 552 dnl     Figure out which C compiler to use.  Gcc is preferred.
 553 dnl     If gcc, make sure it's at least 2.1
 554 dnl
 555 FP_HAVE_GCC
 556 FP_GCC_EXTRA_FLAGS
 557
 558 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
 559 AC_PROG_CPP
 560
 561 AC_SUBST(CONF_CC_OPTS)
 562 AC_SUBST(CONF_LD_OPTS)
 563
 564 dnl ** figure out how to do context diffs
 565 FP_PROG_CONTEXT_DIFF
 566
 567 dnl Let's make sure install-sh is executable here.  If we got it from
 568 dnl a darcs repo, it might not be (see bug #978).
 569 chmod +x install-sh
 570 dnl ** figure out how to do a BSD-ish install
 571 AC_PROG_INSTALL
 572
 573 dnl If you can run configure, you certainly have /bin/sh
 574 AC_DEFINE([HAVE_BIN_SH], [1], [Define to 1 if you have /bin/sh.])
 575
 576 dnl ** how to invoke `ar' and `ranlib'
 577 FP_PROG_AR_NEEDS_RANLIB
 578 FP_PROG_AR_SUPPORTS_INPUT
 579
 580 dnl ** Check to see whether ln -s works
 581 AC_PROG_LN_S
 582
 583
 584 dnl ** Find the path to sed
 585 AC_PATH_PROGS(SedCmd,gsed sed,sed)
 586
 587
 588 dnl ** check for time command
 589 AC_PATH_PROG(TimeCmd,time)
 590
 591 dnl ** check for tar
 592 dnl   if GNU tar is named gtar, look for it first.
 593 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
 594
 595 dnl ** check for patch
 596 dnl if GNU patch is named gpatch, look for it first
 597 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
 598
 599 dnl ** check for dtrace (currently only implemented for Mac OS X)
 600 HaveDtrace=NO
 601 AC_PATH_PROG(DtraceCmd,dtrace)
 602 if test -n "$DtraceCmd"; then
 603   if test "x$TargetOS_CPP-$TargetVendor_CPP" == "xdarwin-apple"; then
 604     HaveDtrace=YES
 605   fi
 606 fi
 607 AC_SUBST(HaveDtrace)
 608
 609 AC_PATH_PROG(HSCOLOUR,HsColour)
 610 # HsColour is passed to Cabal, so we need a native path
 611 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 612    test "${OSTYPE}"      != "msys"                  && \
 613    test "${HSCOLOUR}"    != ""
 614 then
 615     # Canonicalise to <drive>:/path/to/gcc
 616     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
 617 fi
 618
 619 dnl ** check for DocBook toolchain
 620 FP_CHECK_DOCBOOK_DTD
 621 FP_DOCBOOK_XSL
 622 FP_PROG_DBLATEX
 623
 624 FP_PROG_HSTAGS
 625
 626 dnl ** check for ghc-pkg command
 627 FP_PROG_GHC_PKG
 628
 629 dnl ** check for installed happy binary + version
 630 dnl    (don't do it if we're booting from .hc files though.)
 631 if test "$BootingFromHc" = "NO"; then
 632 FPTOOLS_HAPPY
 633 fi;
 634
 635 dnl ** check for installed alex binary + version
 636 dnl    (don't do it if we're booting from .hc files though.)
 637 if test "$BootingFromHc" = "NO"; then
 638 FPTOOLS_ALEX
 639 fi;
 640
 641 dnl --------------------------------------------------
 642 dnl ### program checking section ends here ###
 643 dnl --------------------------------------------------
 644
 645 dnl --------------------------------------------------
 646 dnl * Platform header file and syscall feature tests
 647 dnl ### checking the state of the local header files and syscalls ###
 648
 649 dnl ** check for full ANSI header (.h) files
 650 AC_HEADER_STDC
 651
 652 dnl ** Enable large file support.  NB. do this before testing the type of
 653 dnl    off_t, because it will affect the result of that test.
 654 AC_SYS_LARGEFILE
 655
 656 dnl ** check for specific header (.h) files that we are interested in
 657 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
 658
 659 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
 660 AC_HEADER_TIME
 661
 662 dnl ** do we have long longs?
 663 AC_CHECK_TYPES([long long])
 664
 665 dnl ** what are the sizes of various types
 666 AC_CHECK_SIZEOF(char,               1)
 667 AC_CHECK_SIZEOF(double,             8)
 668 AC_CHECK_SIZEOF(float,              4)
 669 AC_CHECK_SIZEOF(int,                4)
 670 AC_CHECK_SIZEOF(long,               4)
 671 if test "$ac_cv_type_long_long" = yes; then
 672 AC_CHECK_SIZEOF(long long,          8)
 673 fi
 674 AC_CHECK_SIZEOF(short,              2)
 675 AC_CHECK_SIZEOF(unsigned char,      1)
 676 AC_CHECK_SIZEOF(unsigned int,       4)
 677 AC_CHECK_SIZEOF(unsigned long,      4)
 678 if test "$ac_cv_type_long_long" = yes; then
 679 AC_CHECK_SIZEOF(unsigned long long, 8)
 680 fi
 681 AC_CHECK_SIZEOF(unsigned short,     2)
 682 AC_CHECK_SIZEOF(void *,             4)
 683
 684 dnl ** what are alignment constraints on various types
 685 FP_CHECK_ALIGNMENT(char)
 686 FP_CHECK_ALIGNMENT(double)
 687 FP_CHECK_ALIGNMENT(float)
 688 FP_CHECK_ALIGNMENT(int)
 689 FP_CHECK_ALIGNMENT(long)
 690 if test "$ac_cv_type_long_long" = yes; then
 691 FP_CHECK_ALIGNMENT(long long)
 692 fi
 693 FP_CHECK_ALIGNMENT(short)
 694 FP_CHECK_ALIGNMENT(unsigned char)
 695 FP_CHECK_ALIGNMENT(unsigned int)
 696 FP_CHECK_ALIGNMENT(unsigned long)
 697 if test "$ac_cv_type_long_long" = yes; then
 698 FP_CHECK_ALIGNMENT(unsigned long long)
 699 fi
 700 FP_CHECK_ALIGNMENT(unsigned short)
 701 FP_CHECK_ALIGNMENT(void *)
 702
 703 FP_CHECK_FUNC([WinExec],
 704   [@%:@include <windows.h>], [WinExec("",0)])
 705
 706 FP_CHECK_FUNC([GetModuleFileName],
 707   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
 708
 709 dnl ** check return type of signal handlers
 710 dnl Foo: assumes we can use prototypes.
 711 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 712 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
 713 dnl [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 714 dnl #include <signal.h>
 715 dnl #ifdef signal
 716 dnl #undef signal
 717 dnl #endif
 718 dnl void (*signal (int, void (*)(int)))(int);
 719 dnl ]],
 720 dnl [[int i;]])],
 721 dnl [ac_cv_type_signal_handler=void_int],
 722 dnl [ac_cv_type_signal_handler=int_void])])
 723 dnl if test "$ac_cv_type_signal_handler" = void_int; then
 724 dnl AC_DEFINE(VOID_INT_SIGNALS)
 725 dnl fi
 726
 727 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 728 AC_TYPE_SIGNAL
 729 if test "$ac_cv_type_signal" = void; then
 730   AC_DEFINE([VOID_INT_SIGNALS], [1], [Define to 1 if signal handlers have type void (*)(int). Otherwise, they're assumed to have type int (*)(void).])
 731 fi
 732
 733 dnl ** check for more functions
 734 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
 735 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
 736
 737 AC_TRY_RUN([
 738 #include <sys/types.h>
 739 #include <sys/time.h>
 740 int main(void) {
 741   struct itimerval tval;
 742   tval.it_value.tv_sec = 1;
 743   tval.it_value.tv_usec = 0;
 744   tval.it_interval = tval.it_value;
 745   return setitimer(ITIMER_VIRTUAL, &tval, (void*)0) != 0;
 746 }
 747 ],[AC_DEFINE([HAVE_SETITIMER_VIRTUAL], [1], [Define to 1 if setitimer accepts ITIMER_VIRTUAL, 0 else.])])
 748
 749 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
 750 dnl ** _POSIX_C_SOURCE is defined
 751 AC_CHECK_DECLS([ctime_r], , ,
 752 [#define _POSIX_SOURCE 1
 753 #define _POSIX_C_SOURCE 199506L
 754 #include <time.h>])
 755
 756 dnl ** check for mingwex library
 757 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
 758 AC_SUBST(HaveLibMingwEx)
 759
 760 if test $HaveLibMingwEx = YES ; then
 761   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
 762 fi
 763
 764 dnl ** check for math library
 765 dnl    Keep that check as early as possible.
 766 dnl    as we need to know whether we need libm
 767 dnl    for math functions or not
 768 dnl    (see http://hackage.haskell.org/trac/ghc/ticket/3730)
 769 AC_SEARCH_LIBS(atan, m,
 770   [AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])])
 771
 772 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
 773 dnl    the order of these tests matters: bfd needs liberty
 774 AC_CHECK_LIB(iberty, xmalloc)
 775 AC_CHECK_LIB(bfd,    bfd_init)
 776
 777 dnl ################################################################
 778 dnl Check for libraries
 779 dnl ################################################################
 780
 781 dnl ** check whether we need -ldl to get dlopen()
 782
 783 AC_CHECK_LIB(dl, dlopen,
 784     [HaveLibDL=YES
 785      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
 786      LIBS="$LIBS -ldl"],
 787     [HaveLibDL=NO])
 788 AC_SUBST(HaveLibDL)
 789
 790 dnl --------------------------------------------------
 791 dnl * Miscellaneous feature tests
 792 dnl --------------------------------------------------
 793
 794 dnl ** can we get alloca?
 795 AC_FUNC_ALLOCA
 796
 797 dnl ** Working vfork?
 798 AC_FUNC_FORK
 799
 800 dnl ** determine whether or not const works
 801 AC_C_CONST
 802
 803 dnl ** are we big endian?
 804 AC_C_BIGENDIAN
 805 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
 806
 807 dnl ** check for leading underscores in symbol names
 808 FP_LEADING_UNDERSCORE
 809
 810 dnl ** check for ld, whether it has an -x option, and if it is GNU ld
 811 FP_PROG_LD_X
 812 FP_PROG_LD_IS_GNU
 813
 814 dnl ** check for Apple-style dead-stripping support
 815 dnl    (.subsections-via-symbols assembler directive)
 816
 817
 818 AC_MSG_CHECKING(for .subsections_via_symbols)
 819 AC_COMPILE_IFELSE(
 820     [AC_LANG_PROGRAM([], [__asm__ (".subsections_via_symbols");])],
 821     [AC_MSG_RESULT(yes)
 822      AC_DEFINE([HAVE_SUBSECTIONS_VIA_SYMBOLS],[1],
 823                [Define to 1 if Apple-style dead-stripping is supported.])
 824     ],
 825     [AC_MSG_RESULT(no)])
 826
 827 dnl *** check for GNU non-executable stack note support (ELF only)
 828 dnl     (.section .note.GNU-stack,"",@progbits)
 829
 830 AC_MSG_CHECKING(for GNU non-executable stack support)
 831 AC_COMPILE_IFELSE(
 832     [AC_LANG_PROGRAM([__asm__ (".section .note.GNU-stack,\"\",@progbits");], [0])],
 833     [AC_MSG_RESULT(yes)
 834      AC_DEFINE([HAVE_GNU_NONEXEC_STACK],[1],
 835                [Define to 1 if GNU non-executable stack notes are supported.])
 836     ],
 837     [AC_MSG_RESULT(no)])
 838
 839 dnl ** check for librt
 840 AC_CHECK_LIB(rt, clock_gettime)
 841 AC_CHECK_FUNCS(clock_gettime timer_create timer_settime)
 842 FP_CHECK_TIMER_CREATE
 843
 844 dnl ** check for Apple's "interesting" long double compatibility scheme
 845 AC_MSG_CHECKING(for printf\$LDBLStub)
 846 AC_TRY_LINK_FUNC(printf\$LDBLStub,
 847     [
 848         AC_MSG_RESULT(yes)
 849         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
 850             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 851     ],
 852     [
 853         AC_MSG_RESULT(no)
 854         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
 855             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 856     ])
 857
 858 # test for GTK+
 859 AC_PATH_PROGS([GTK_CONFIG], [pkg-config])
 860 if test -n "$GTK_CONFIG"; then
 861   if $GTK_CONFIG gtk+-2.0 --atleast-version=2.0; then
 862     GTK_CONFIG="$GTK_CONFIG gtk+-2.0"
 863   else
 864     AC_MSG_WARN([GTK+ not usable, need at least version 2.0])
 865     GTK_CONFIG=
 866   fi
 867 fi
 868 AC_SUBST([GTK_CONFIG])
 869
 870 #Checking for PAPI
 871 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
 872 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
 873 AC_SUBST(HavePapiLib)
 874 AC_SUBST(HavePapiHeader)
 875
 876 AC_CHECK_FUNCS(__mingw_vfprintf)
 877
 878 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
 879    HavePapi=YES
 880 else
 881    HavePapi=NO
 882 fi
 883 AC_SUBST(HavePapi)
 884
 885 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
 886    test "$XsltprocCmd" = ""
 887 then
 888     BUILD_DOCBOOK_HTML=NO
 889 else
 890     BUILD_DOCBOOK_HTML=YES
 891 fi
 892 AC_SUBST(BUILD_DOCBOOK_HTML)
 893
 894 if test "$DblatexCmd" = ""
 895 then
 896     BUILD_DOCBOOK_PS=NO
 897     BUILD_DOCBOOK_PDF=NO
 898 else
 899     BUILD_DOCBOOK_PS=YES
 900     BUILD_DOCBOOK_PDF=YES
 901 fi
 902 AC_SUBST(BUILD_DOCBOOK_PS)
 903 AC_SUBST(BUILD_DOCBOOK_PDF)
 904
 905 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
 906    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
 907 fi
 908
 909 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal ghc.spec extra-gcc-opts docs/users_guide/ug-book.xml distrib/ghc.iss distrib/configure.ac])
 910 AC_CONFIG_COMMANDS([mk/stamp-h],[echo timestamp > mk/stamp-h])
 911 AC_OUTPUT
 912
 913 # We get caught by
 914 #     http://savannah.gnu.org/bugs/index.php?1516
 915 #     $(eval ...) inside conditionals causes errors
 916 # with make 3.80, so warn the user if it looks like they're about to
 917 # try to use it.
 918 # We would use "grep -q" here, but Solaris's grep doesn't support it.
 919 checkMake380() {
 920     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
 921     then
 922         echo
 923         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
 924         echo "This version cannot be used to build GHC."
 925         echo "Please use GNU make >= 3.81."
 926     fi
 927 }
 928
 929 checkMake380 make
 930 checkMake380 gmake
 931
 932 echo ["
 933 ----------------------------------------------------------------------
 934 Configure completed successfully.
 935
 936    Building GHC version  : $ProjectVersion
 937
 938    Build platform        : $BuildPlatform
 939    Host platform         : $HostPlatform
 940    Target platform       : $TargetPlatform
 941 "]
 942
 943 if test "$BootingFromHc" = "YES"; then
 944 echo ["\
 945    Bootstrapping from HC files.
 946 "]
 947 else
 948 echo ["\
 949    Bootstrapping using   : $WithGhc
 950       which is version   : $GhcVersion
 951 "]
 952 fi
 953
 954 echo ["\
 955    Using GCC             : $WhatGccIsCalled
 956       which is version   : $GccVersion
 957
 958    ld       : $LdCmd
 959    Happy    : $HappyCmd ($HappyVersion)
 960    Alex     : $AlexCmd ($AlexVersion)
 961    Python   : $PythonCmd
 962    Perl     : $PerlCmd
 963    dblatex  : $DblatexCmd
 964    xsltproc : $XsltprocCmd"]
 965
 966 if test "$HSCOLOUR" = ""; then
 967 echo ["
 968    HsColour was not found; documentation will not contain source links
 969 "]
 970 else
 971 echo ["\
 972    HsColour : $HSCOLOUR
 973 "]
 974 fi
 975
 976 echo ["\
 977    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
 978    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
 979    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
 980
 981 echo ["----------------------------------------------------------------------
 982 "]
 983
 984 echo "\
 985 For a standard build of GHC (fully optimised with profiling), type (g)make.
 986
 987 To make changes to the default build configuration, copy the file
 988 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
 989
 990 For more information on how to configure your GHC build, see
 991    http://hackage.haskell.org/trac/ghc/wiki/Building
 992 "