configure.ac

   1 dnl == autoconf source for the Glasgow FP tools ==
   2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
   3 dnl  (or some such) to see the outline of this file)
   4 dnl
   5 #
   6 # (c) The University of Glasgow 1994-2004
   7 #
   8 # Configure script template for GHC
   9 #
  10 # Process with 'autoreconf' to get a working configure script.
  11 #
  12 # For the generated configure script, do "./configure --help" to
  13 # see what flags are available. (Better yet, read the documentation!)
  14 #
  15
  16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [6.13], [glasgow-haskell-bugs@haskell.org], [ghc])
  17
  18 # Set this to YES for a released version, otherwise NO
  19 : ${RELEASE=NO}
  20
  21 # The primary version (e.g. 6.7, 6.6.1) is set in the AC_INIT line
  22 # above.  If this is not a released version, then we will append the
  23 # date to the version number (e.g. 6.7.20070204).  The date is
  24 # constructed by finding the date of the most recent patch in the
  25 # darcs repository.  If this is a source distribution (not a darcs
  26 # checkout), then we ship a file 'VERSION' containing the full version
  27 # when the source distribution was created.
  28
  29 if test ! -f mk/config.h.in; then
  30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'sh boot'?"
  31    exit 1
  32 fi
  33
  34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
  35
  36 dnl ----------------------------------------------------------
  37 dnl ** Find unixy sort and find commands,
  38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
  39
  40 dnl ** Find find command (for Win32's benefit)
  41 FP_PROG_FIND
  42
  43 dnl ** Find sort command (for the benefit of Win32 environs)
  44 FP_PROG_SORT
  45
  46 dnl ----------------------------------------------------------
  47 FP_SETUP_PROJECT_VERSION
  48
  49 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
  50 AC_SUBST([release], [1])
  51
  52 # First off, a distrib sanity check..
  53 AC_CONFIG_SRCDIR([mk/config.mk.in])
  54
  55 dnl * We require autoconf version 2.52
  56 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
  57 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
  58 AC_PREREQ([2.52])
  59
  60 # -------------------------------------------------------------------------
  61 # Prepare to generate the following header files
  62 #
  63 #
  64 AC_CONFIG_HEADER(mk/config.h)
  65
  66 # No, semi-sadly, we don't do `--srcdir'...
  67 if test x"$srcdir" != 'x.' ; then
  68     echo "This configuration does not support the \`--srcdir' option.."
  69     exit 1
  70 fi
  71
  72 dnl --------------------------------------------------------------
  73 dnl * Project specific configuration options
  74 dnl --------------------------------------------------------------
  75 dnl What follows is a bunch of options that can either be configured
  76 dnl through command line options to the configure script or by
  77 dnl supplying defns in the build tree's mk/build.mk. Having the option to
  78 dnl use either is considered a Feature.
  79
  80 dnl ** What command to use to compile compiler sources ?
  81 dnl --------------------------------------------------------------
  82
  83 AC_ARG_WITH([ghc],
  84 [AC_HELP_STRING([--with-ghc=ARG],
  85   [Use ARG as the path to GHC  [default=autodetect]])],
  86   [WithGhc="$withval"],
  87   [if test "$GHC" = ""; then
  88     AC_PATH_PROG([GHC], [ghc])
  89   fi
  90   WithGhc="$GHC"])
  91
  92 dnl ** Booting from .hc files?
  93 dnl --------------------------------------------------------------
  94 AC_ARG_ENABLE(hc-boot,
  95 [AC_HELP_STRING([--enable-hc-boot],
  96 [Boot the Glasgow Haskell Compiler from intermediate .hc files.
  97  (This option is mostly of interest to porters.) [default=no]])],
  98 [ if test x"$enableval" = x"yes"; then
  99         BootingFromHc=YES
 100   else
 101         BootingFromHc=NO
 102   fi
 103 ],
 104 [BootingFromHc=NO]
 105 )
 106 AC_SUBST(BootingFromHc)
 107
 108 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
 109 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
 110                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
 111         EnableBootstrapWithDevelSnaphost=YES,
 112         EnableBootstrapWithDevelSnaphost=NO
 113 )
 114
 115 if test "$WithGhc" != ""; then
 116   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
 117
 118   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
 119      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
 120   fi
 121
 122   AC_SUBST(GhcVersion)dnl
 123   AC_SUBST(GhcMajVersion)dnl
 124   AC_SUBST(GhcMinVersion)dnl
 125   AC_SUBST(GhcPatchLevel)dnl
 126   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
 127   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
 128   FP_COMPARE_VERSIONS($GhcVersion,[-ge],[6.10.2],
 129                       [ghc_ge_6102=YES], [ghc_ge_6102=NO])
 130   if test $GhcCanonVersion -ge 611; then ghc_ge_611=YES; else ghc_ge_611=NO; fi
 131   if test $GhcCanonVersion -ge 613; then ghc_ge_613=YES; else ghc_ge_613=NO; fi
 132   AC_SUBST(ghc_ge_6102)dnl
 133   AC_SUBST(ghc_ge_611)dnl
 134   AC_SUBST(ghc_ge_613)dnl
 135 fi
 136
 137 dnl ** Must have GHC to build GHC, unless --enable-hc-boot is on
 138 if test "$BootingFromHc" = "NO" -a -d "$srcdir/compiler"; then
 139   if test "$WithGhc" = ""; then
 140      AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 141   fi
 142   FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[6.10],
 143     [AC_MSG_ERROR([GHC version 6.10 or later is required to compile GHC.])])dnl
 144
 145   if test `expr $GhcMinVersion % 2` = "1"; then
 146      if test "$EnableBootstrapWithDevelSnaphost" = "NO"; then
 147         AC_MSG_ERROR([
 148      $WithGhc is a development snapshot of GHC, version $GhcVersion.
 149      Bootstrapping using this version of GHC is not supported, and may not
 150      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
 151      or --with-ghc to specify a different GHC to use.])
 152      fi
 153   fi
 154 fi;
 155
 156 # GHC is passed to Cabal, so we need a native path
 157 if test "${WithGhc}" != ""
 158 then
 159     ghc_host=`"${WithGhc}" +RTS --info | grep 'Host platform' | sed -e 's/.*, "//' -e 's/")//'`
 160
 161     if test "$ghc_host" = "i386-unknown-mingw32"
 162     then
 163         if test "${OSTYPE}" = "msys"
 164         then
 165             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
 166         else
 167             # Canonicalise to <drive>:/path/to/ghc
 168             WithGhc=`cygpath -m "${WithGhc}"`
 169         fi
 170         echo "GHC path canonicalised to: ${WithGhc}"
 171     fi
 172 fi
 173 AC_SUBST([WithGhc])
 174
 175 dnl ** Without optimization some INLINE trickery fails for GHCi
 176 SRC_CC_OPTS="-O"
 177
 178 dnl Allow to specify iconv options to the toplevel configure script
 179 dnl so they can be properly passed to sub-builds.
 180 dnl Note: ICONV_LIB_DIRS and ICONV_INCLUDE_DIRS are not predefined
 181 dnl to the empty string to allow them to be overridden from the
 182 dnl environment.
 183
 184 AC_ARG_WITH([iconv-includes],
 185   [AC_HELP_STRING([--with-iconv-includes],
 186     [directory containing iconv.h])],
 187     [ICONV_INCLUDE_DIRS=$withval])
 188
 189 AC_ARG_WITH([iconv-libraries],
 190   [AC_HELP_STRING([--with-iconv-libraries],
 191     [directory containing iconv library])],
 192     [ICONV_LIB_DIRS=$withval])
 193
 194 AC_SUBST(ICONV_INCLUDE_DIRS)
 195 AC_SUBST(ICONV_LIB_DIRS)
 196
 197 dnl--------------------------------------------------------------------
 198 dnl * Choose host(/target/build) platform
 199 dnl--------------------------------------------------------------------
 200 dnl We don't use the standard autoconf macros for this, but instead
 201 dnl ask the bootstrapping compiler what platform it is for
 202
 203 dnl Guess host/target/build platform(s) if necessary.
 204 m4_divert_once([HELP_CANON],
 205 [[
 206 System types:
 207   --build=BUILD     configure for building on BUILD [guessed]
 208   --host=HOST       cross-compile to build programs to run on HOST [guessed]
 209   --target=TARGET   configure for building compilers for TARGET [guessed]]])dnl
 210
 211 if test "${WithGhc}" != ""
 212 then
 213         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 214         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 215         if test "$bootstrap_host" != "$bootstrap_target"
 216         then
 217                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
 218         fi
 219 fi
 220
 221 # We have to run these unconditionally, but we may discard their
 222 # results in the following code
 223 AC_CANONICAL_BUILD
 224 AC_CANONICAL_HOST
 225 AC_CANONICAL_TARGET
 226
 227 # If no argument was given for a configuration variable, then discard
 228 # the guessed canonical system and use the configuration of the
 229 # bootstrapping ghc. If an argument was given, map it from gnu format
 230 # to ghc format.
 231 #
 232 # For why we do it this way, see: #3637, #1717, #2951
 233
 234 if test "$build_alias" = ""
 235 then
 236     if test "${WithGhc}" != ""
 237     then
 238         build=$bootstrap_target
 239         echo "Build platform inferred as: $build"
 240     else
 241         echo "Can't work out build platform"
 242         exit 1
 243     fi
 244
 245     BuildArch=`echo "$build" | sed 's/-.*//'`
 246     BuildVendor=`echo "$build" | sed -e 's/.*-\(.*\)-.*/\1/'`
 247     BuildOS=`echo "$build" | sed 's/.*-//'`
 248 else
 249     GHC_CONVERT_CPU([$build_cpu], [BuildArch])
 250     GHC_CONVERT_VENDOR([$build_vendor], [BuildVendor])
 251     GHC_CONVERT_OS([$build_os], [BuildOS])
 252 fi
 253
 254 if test "$host_alias" = ""
 255 then
 256     if test "${WithGhc}" != ""
 257     then
 258         host=$bootstrap_target
 259         echo "Host platform inferred as: $host"
 260     else
 261         echo "Can't work out host platform"
 262         exit 1
 263     fi
 264
 265     HostArch=`echo "$host" | sed 's/-.*//'`
 266     HostVendor=`echo "$host" | sed -e 's/.*-\(.*\)-.*/\1/'`
 267     HostOS=`echo "$host" | sed 's/.*-//'`
 268 else
 269     GHC_CONVERT_CPU([$host_cpu], [HostArch])
 270     GHC_CONVERT_VENDOR([$host_vendor], [HostVendor])
 271     GHC_CONVERT_OS([$host_os], [HostOS])
 272 fi
 273
 274 if test "$target_alias" = ""
 275 then
 276     if test "${WithGhc}" != ""
 277     then
 278         target=$bootstrap_target
 279         echo "Target platform inferred as: $target"
 280     else
 281         echo "Can't work out target platform"
 282         exit 1
 283     fi
 284
 285     TargetArch=`echo "$target" | sed 's/-.*//'`
 286     TargetVendor=`echo "$target" | sed -e 's/.*-\(.*\)-.*/\1/'`
 287     TargetOS=`echo "$target" | sed 's/.*-//'`
 288 else
 289     GHC_CONVERT_CPU([$target_cpu], [TargetArch])
 290     GHC_CONVERT_VENDOR([$target_vendor], [TargetVendor])
 291     GHC_CONVERT_OS([$target_os], [TargetOS])
 292 fi
 293
 294 exeext=''
 295 soext='.so'
 296 case $host in
 297 *-unknown-cygwin32)
 298     AC_MSG_WARN([GHC does not support the Cygwin target at the moment])
 299     AC_MSG_WARN([I'm assuming you wanted to build for i386-unknown-mingw32])
 300     exit 1
 301     ;;
 302 *-unknown-mingw32)
 303     exeext='.exe'
 304     soext='.dll'
 305     ;;
 306 i386-apple-darwin|powerpc-apple-darwin)
 307     soext='.dylib'
 308     CFLAGS="$CFLAGS -m32"
 309     LDFLAGS="$LDFLAGS -m32"
 310     CONF_CC_OPTS="$CONF_CC_OPTS -m32"
 311     CONF_LD_OPTS="$CONF_LD_OPTS -m32"
 312     ;;
 313 x86_64-apple-darwin)
 314     soext='.dylib'
 315     CFLAGS="$CFLAGS -m64"
 316     LDFLAGS="$LDFLAGS -m64"
 317     CONF_CC_OPTS="$CONF_CC_OPTS -m64"
 318     CONF_LD_OPTS="$CONF_LD_OPTS -m64"
 319     ;;
 320 esac
 321
 322 checkArch() {
 323     case $1 in
 324     alpha|arm|hppa|hppa1_1|i386|ia64|m68k|mips|mipseb|mipsel|powerpc|powerpc64|rs6000|s390|sparc|sparc64|vax|x86_64)
 325         ;;
 326     *)
 327         echo "Unknown arch $1"
 328         exit 1
 329         ;;
 330     esac
 331 }
 332
 333 checkVendor() {
 334     case $1 in
 335     dec|unknown|hp|apple|next|sun|sgi|ibm)
 336         ;;
 337     *)
 338         echo "Unknown vendor $1"
 339         exit 1
 340         ;;
 341     esac
 342 }
 343
 344 checkOS() {
 345     case $1 in
 346     linux|freebsd|netbsd|openbsd|dragonfly|osf1|osf3|hpux|linuxaout|kfreebsdgnu|freebsd2|solaris2|cygwin32|mingw32|darwin|gnu|nextstep2|nextstep3|sunos4|ultrix|irix|aix|haiku)
 347         ;;
 348     *)
 349         echo "Unknown OS '$1'"
 350         exit 1
 351         ;;
 352     esac
 353 }
 354
 355 BuildPlatform="$BuildArch-$BuildVendor-$BuildOS"
 356 BuildPlatform_CPP=`echo "$BuildPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 357 BuildArch_CPP=`    echo "$BuildArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 358 BuildVendor_CPP=`  echo "$BuildVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 359 BuildOS_CPP=`      echo "$BuildOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 360
 361 checkArch "$BuildArch"
 362 checkVendor "$BuildVendor"
 363 checkOS "$BuildOS"
 364
 365 HostPlatform="$HostArch-$HostVendor-$HostOS"
 366 HostPlatform_CPP=`echo "$HostPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 367 HostArch_CPP=`    echo "$HostArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 368 HostVendor_CPP=`  echo "$HostVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 369 HostOS_CPP=`      echo "$HostOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 370
 371 checkArch "$HostArch"
 372 checkVendor "$HostVendor"
 373 checkOS "$HostOS"
 374
 375 TargetPlatform="$TargetArch-$TargetVendor-$TargetOS"
 376 TargetPlatform_CPP=`echo "$TargetPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 377 TargetArch_CPP=`    echo "$TargetArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 378 TargetVendor_CPP=`  echo "$TargetVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 379 TargetOS_CPP=`      echo "$TargetOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 380
 381 checkArch "$TargetArch"
 382 checkVendor "$TargetVendor"
 383 checkOS "$TargetOS"
 384
 385 AC_SUBST(BuildPlatform)
 386 AC_SUBST(HostPlatform)
 387 AC_SUBST(TargetPlatform)
 388 AC_SUBST(HostPlatform_CPP)
 389 AC_SUBST(BuildPlatform_CPP)
 390 AC_SUBST(TargetPlatform_CPP)
 391
 392 AC_SUBST(HostArch_CPP)
 393 AC_SUBST(BuildArch_CPP)
 394 AC_SUBST(TargetArch_CPP)
 395
 396 AC_SUBST(HostOS_CPP)
 397 AC_SUBST(BuildOS_CPP)
 398 AC_SUBST(TargetOS_CPP)
 399
 400 AC_SUBST(HostVendor_CPP)
 401 AC_SUBST(BuildVendor_CPP)
 402 AC_SUBST(TargetVendor_CPP)
 403
 404 AC_SUBST(exeext)
 405 AC_SUBST(soext)
 406
 407 AC_ARG_WITH(hc,
 408 [AC_HELP_STRING([--with-hc=ARG],
 409         [Use ARG as the path to the compiler for compiling ordinary
 410          Haskell code  (default= value of --with-ghc)])],
 411 [WithHc="$withval"],
 412 [WithHc=$WithGhc]
 413 )
 414 AC_SUBST(WithHc)
 415
 416 AC_PATH_PROGS(NHC,nhc nhc98)
 417 AC_PATH_PROG(HBC,hbc)
 418
 419 # This uses GHC, so put it after the "GHC is required" check above:
 420 FP_FIND_ROOT
 421
 422 if test "$HostOS" = "mingw32"
 423 then
 424     CC="$hardtop/inplace/mingw/bin/gcc.exe"
 425     LD="$hardtop/inplace/mingw/bin/ld.exe"
 426     NM="$hardtop/inplace/mingw/bin/nm.exe"
 427     if ! test -d inplace/mingw ||
 428          test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.gz ||
 429          test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.gz ||
 430          test inplace/mingw -ot ghc-tarballs/mingw/gcc-g++*.tar.gz ||
 431          test inplace/mingw -ot ghc-tarballs/mingw/libcrypt*.tar.bz2 ||
 432          test inplace/mingw -ot ghc-tarballs/mingw/mingw-runtime*.tar.gz ||
 433          test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.gz
 434     then
 435         AC_MSG_NOTICE([Making in-tree mingw tree])
 436         rm -rf inplace/mingw
 437         mkdir inplace
 438         mkdir inplace/mingw
 439         (
 440             cd inplace/mingw &&
 441             tar -zxf ../../ghc-tarballs/mingw/binutils*.tar.gz &&
 442             tar -zxf ../../ghc-tarballs/mingw/gcc-core*.tar.gz &&
 443             tar -zxf ../../ghc-tarballs/mingw/gcc-g++*.tar.gz &&
 444             tar -jxf ../../ghc-tarballs/mingw/libcrypt*.tar.bz2 &&
 445             tar -zxf ../../ghc-tarballs/mingw/mingw-runtime*.tar.gz &&
 446             tar -zxf ../../ghc-tarballs/mingw/w32api*.tar.gz &&
 447             mv bin/gcc.exe bin/realgcc.exe
 448         )
 449         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
 450         AC_MSG_NOTICE([In-tree mingw tree created])
 451     fi
 452     if ! test -d inplace/perl ||
 453          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
 454     then
 455         AC_MSG_NOTICE([Making in-tree perl tree])
 456         rm -rf inplace/perl
 457         mkdir inplace
 458         mkdir inplace/perl
 459         (
 460             cd inplace/perl &&
 461             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
 462         )
 463         AC_MSG_NOTICE([In-tree perl tree created])
 464     fi
 465 fi
 466
 467 dnl ** Which gcc to use?
 468 dnl --------------------------------------------------------------
 469 FP_ARG_WITH_PATH_GNU_PROG([CC], [gcc])
 470 export CC
 471 WhatGccIsCalled="$CC"
 472 AC_SUBST(WhatGccIsCalled)
 473
 474 dnl ** Which ld to use?
 475 dnl --------------------------------------------------------------
 476 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld])
 477 LdCmd="$LD"
 478 AC_SUBST([LdCmd])
 479
 480 dnl ** Which nm to use?
 481 dnl --------------------------------------------------------------
 482 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm])
 483 NmCmd="$NM"
 484 AC_SUBST([NmCmd])
 485
 486 dnl ** Mac OS X: explicit deployment target
 487 dnl --------------------------------------------------------------
 488 AC_ARG_WITH([macosx-deployment-target],
 489 [AC_HELP_STRING([--with-macosx-deployment-target=VERSION],
 490         [Build for Mac OS VERSION and higher  (default= version of build host)])],
 491 [FP_MACOSX_DEPLOYMENT_TARGET="$withval"
 492  if test "x$TargetOS_CPP-$TargetVendor_CPP" != "xdarwin-apple"; then
 493    # ignore everywhere, but on Mac OS
 494    AC_MSG_WARN([--macosx-deployment-target is only available on Mac OS X])
 495    FP_MACOSX_DEPLOYMENT_TARGET=none
 496  fi],
 497 [FP_MACOSX_DEPLOYMENT_TARGET=none]
 498 )
 499 FP_CHECK_MACOSX_DEPLOYMENT_TARGET
 500 AC_SUBST(MACOSX_DEPLOYMENT_VERSION)
 501 AC_SUBST(MACOSX_DEPLOYMENT_SDK)
 502
 503 dnl --------------------------------------------------------------
 504 dnl End of configure script option section
 505 dnl --------------------------------------------------------------
 506
 507
 508 dnl --------------------------------------------------------------
 509 dnl * General configuration checks
 510 dnl --------------------------------------------------------------
 511
 512 dnl ** Can the unix package be built?
 513 dnl --------------------------------------------------------------
 514
 515 if test x"$TargetPlatform" = x"i386-unknown-mingw32"; then
 516    GhcLibsWithUnix=NO
 517 else
 518    GhcLibsWithUnix=YES
 519 fi
 520 AC_SUBST([GhcLibsWithUnix])
 521
 522 dnl ** does #! work?
 523 AC_SYS_INTERPRETER()
 524
 525 dnl ** look for `perl', but only in /bin on Windows
 526 case $HostOS_CPP in
 527 cygwin32|mingw32)
 528       AC_CHECK_PROG(PerlCmd,perl,/bin/perl,,/bin)
 529       if test -z "$PerlCmd"; then
 530          echo "You must install the version of Perl shipped with GHC"
 531          echo "(or a compatible one) in /bin."
 532          exit 1
 533       fi
 534    ;;
 535 *)
 536    AC_PATH_PROG(PerlCmd,perl)
 537    if test -z "$PerlCmd"; then
 538       echo "You must install perl before you can continue"
 539       echo "Perhaps it is already installed, but not in your PATH?"
 540       exit 1
 541    else
 542    FPTOOLS_CHECK_PERL_VERSION
 543    fi
 544    ;;
 545 esac
 546
 547 dnl ** does #! path/to/perl work? (sometimes it's too long...)
 548 FPTOOLS_SHEBANG_PERL
 549
 550 dnl ** check for Python
 551 AC_PATH_PROG(PythonCmd,python)
 552
 553 dnl ** look for GCC and find out which version
 554 dnl     Figure out which C compiler to use.  Gcc is preferred.
 555 dnl     If gcc, make sure it's at least 2.1
 556 dnl
 557 FP_HAVE_GCC
 558 FP_GCC_EXTRA_FLAGS
 559
 560 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
 561 AC_PROG_CPP
 562
 563 AC_SUBST(CONF_CC_OPTS)
 564 AC_SUBST(CONF_LD_OPTS)
 565
 566 dnl ** figure out how to do context diffs
 567 FP_PROG_CONTEXT_DIFF
 568
 569 dnl Let's make sure install-sh is executable here.  If we got it from
 570 dnl a darcs repo, it might not be (see bug #978).
 571 chmod +x install-sh
 572 dnl ** figure out how to do a BSD-ish install
 573 AC_PROG_INSTALL
 574
 575 dnl If you can run configure, you certainly have /bin/sh
 576 AC_DEFINE([HAVE_BIN_SH], [1], [Define to 1 if you have /bin/sh.])
 577
 578 dnl ** how to invoke `ar' and `ranlib'
 579 FP_PROG_AR_SUPPORTS_ATFILE
 580 FP_PROG_AR_NEEDS_RANLIB
 581 FP_PROG_AR_SUPPORTS_INPUT
 582
 583 dnl ** Check to see whether ln -s works
 584 AC_PROG_LN_S
 585
 586
 587 dnl ** Find the path to sed
 588 AC_PATH_PROGS(SedCmd,gsed sed,sed)
 589
 590
 591 dnl ** check for time command
 592 AC_PATH_PROG(TimeCmd,time)
 593
 594 dnl ** check for tar
 595 dnl   if GNU tar is named gtar, look for it first.
 596 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
 597
 598 dnl ** check for patch
 599 dnl if GNU patch is named gpatch, look for it first
 600 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
 601
 602 dnl ** check for dtrace (currently only implemented for Mac OS X)
 603 HaveDtrace=NO
 604 AC_PATH_PROG(DtraceCmd,dtrace)
 605 if test -n "$DtraceCmd"; then
 606   if test "x$TargetOS_CPP-$TargetVendor_CPP" == "xdarwin-apple"; then
 607     HaveDtrace=YES
 608   fi
 609 fi
 610 AC_SUBST(HaveDtrace)
 611
 612 AC_PATH_PROG(HSCOLOUR,HsColour)
 613 # HsColour is passed to Cabal, so we need a native path
 614 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 615    test "${OSTYPE}"      != "msys"                  && \
 616    test "${HSCOLOUR}"    != ""
 617 then
 618     # Canonicalise to <drive>:/path/to/gcc
 619     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
 620 fi
 621
 622 dnl ** check for DocBook toolchain
 623 FP_CHECK_DOCBOOK_DTD
 624 FP_DOCBOOK_XSL
 625 FP_PROG_DBLATEX
 626
 627 FP_PROG_HSTAGS
 628
 629 dnl ** check for ghc-pkg command
 630 FP_PROG_GHC_PKG
 631
 632 dnl ** check for installed happy binary + version
 633 dnl    (don't do it if we're booting from .hc files though.)
 634 if test "$BootingFromHc" = "NO"; then
 635 FPTOOLS_HAPPY
 636 fi;
 637
 638 dnl ** check for installed alex binary + version
 639 dnl    (don't do it if we're booting from .hc files though.)
 640 if test "$BootingFromHc" = "NO"; then
 641 FPTOOLS_ALEX
 642 fi;
 643
 644 dnl --------------------------------------------------
 645 dnl ### program checking section ends here ###
 646 dnl --------------------------------------------------
 647
 648 dnl --------------------------------------------------
 649 dnl * Platform header file and syscall feature tests
 650 dnl ### checking the state of the local header files and syscalls ###
 651
 652 dnl ** check for full ANSI header (.h) files
 653 AC_HEADER_STDC
 654
 655 dnl ** Enable large file support.  NB. do this before testing the type of
 656 dnl    off_t, because it will affect the result of that test.
 657 AC_SYS_LARGEFILE
 658
 659 dnl ** check for specific header (.h) files that we are interested in
 660 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
 661
 662 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
 663 AC_HEADER_TIME
 664
 665 dnl ** do we have long longs?
 666 AC_CHECK_TYPES([long long])
 667
 668 dnl ** what are the sizes of various types
 669 AC_CHECK_SIZEOF(char,               1)
 670 AC_CHECK_SIZEOF(double,             8)
 671 AC_CHECK_SIZEOF(float,              4)
 672 AC_CHECK_SIZEOF(int,                4)
 673 AC_CHECK_SIZEOF(long,               4)
 674 if test "$ac_cv_type_long_long" = yes; then
 675 AC_CHECK_SIZEOF(long long,          8)
 676 fi
 677 AC_CHECK_SIZEOF(short,              2)
 678 AC_CHECK_SIZEOF(unsigned char,      1)
 679 AC_CHECK_SIZEOF(unsigned int,       4)
 680 AC_CHECK_SIZEOF(unsigned long,      4)
 681 if test "$ac_cv_type_long_long" = yes; then
 682 AC_CHECK_SIZEOF(unsigned long long, 8)
 683 fi
 684 AC_CHECK_SIZEOF(unsigned short,     2)
 685 AC_CHECK_SIZEOF(void *,             4)
 686
 687 dnl ** what are alignment constraints on various types
 688 FP_CHECK_ALIGNMENT(char)
 689 FP_CHECK_ALIGNMENT(double)
 690 FP_CHECK_ALIGNMENT(float)
 691 FP_CHECK_ALIGNMENT(int)
 692 FP_CHECK_ALIGNMENT(long)
 693 if test "$ac_cv_type_long_long" = yes; then
 694 FP_CHECK_ALIGNMENT(long long)
 695 fi
 696 FP_CHECK_ALIGNMENT(short)
 697 FP_CHECK_ALIGNMENT(unsigned char)
 698 FP_CHECK_ALIGNMENT(unsigned int)
 699 FP_CHECK_ALIGNMENT(unsigned long)
 700 if test "$ac_cv_type_long_long" = yes; then
 701 FP_CHECK_ALIGNMENT(unsigned long long)
 702 fi
 703 FP_CHECK_ALIGNMENT(unsigned short)
 704 FP_CHECK_ALIGNMENT(void *)
 705
 706 FP_CHECK_FUNC([WinExec],
 707   [@%:@include <windows.h>], [WinExec("",0)])
 708
 709 FP_CHECK_FUNC([GetModuleFileName],
 710   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
 711
 712 dnl ** check return type of signal handlers
 713 dnl Foo: assumes we can use prototypes.
 714 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 715 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
 716 dnl [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 717 dnl #include <signal.h>
 718 dnl #ifdef signal
 719 dnl #undef signal
 720 dnl #endif
 721 dnl void (*signal (int, void (*)(int)))(int);
 722 dnl ]],
 723 dnl [[int i;]])],
 724 dnl [ac_cv_type_signal_handler=void_int],
 725 dnl [ac_cv_type_signal_handler=int_void])])
 726 dnl if test "$ac_cv_type_signal_handler" = void_int; then
 727 dnl AC_DEFINE(VOID_INT_SIGNALS)
 728 dnl fi
 729
 730 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 731 AC_TYPE_SIGNAL
 732 if test "$ac_cv_type_signal" = void; then
 733   AC_DEFINE([VOID_INT_SIGNALS], [1], [Define to 1 if signal handlers have type void (*)(int). Otherwise, they're assumed to have type int (*)(void).])
 734 fi
 735
 736 dnl ** check for more functions
 737 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
 738 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
 739
 740 AC_TRY_RUN([
 741 #include <sys/types.h>
 742 #include <sys/time.h>
 743 int main(void) {
 744   struct itimerval tval;
 745   tval.it_value.tv_sec = 1;
 746   tval.it_value.tv_usec = 0;
 747   tval.it_interval = tval.it_value;
 748   return setitimer(ITIMER_VIRTUAL, &tval, (void*)0) != 0;
 749 }
 750 ],[AC_DEFINE([HAVE_SETITIMER_VIRTUAL], [1], [Define to 1 if setitimer accepts ITIMER_VIRTUAL, 0 else.])])
 751
 752 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
 753 dnl ** _POSIX_C_SOURCE is defined
 754 AC_CHECK_DECLS([ctime_r], , ,
 755 [#define _POSIX_SOURCE 1
 756 #define _POSIX_C_SOURCE 199506L
 757 #include <time.h>])
 758
 759 dnl ** check for mingwex library
 760 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
 761 AC_SUBST(HaveLibMingwEx)
 762
 763 if test $HaveLibMingwEx = YES ; then
 764   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
 765 fi
 766
 767 dnl ** check for math library
 768 dnl    Keep that check as early as possible.
 769 dnl    as we need to know whether we need libm
 770 dnl    for math functions or not
 771 dnl    (see http://hackage.haskell.org/trac/ghc/ticket/3730)
 772 AC_SEARCH_LIBS(atan, m,
 773   [AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])])
 774
 775 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
 776 dnl    the order of these tests matters: bfd needs liberty
 777 AC_CHECK_LIB(iberty, xmalloc)
 778 AC_CHECK_LIB(bfd,    bfd_init)
 779
 780 dnl ################################################################
 781 dnl Check for libraries
 782 dnl ################################################################
 783
 784 dnl ** check whether we need -ldl to get dlopen()
 785
 786 AC_CHECK_LIB(dl, dlopen,
 787     [HaveLibDL=YES
 788      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
 789      LIBS="$LIBS -ldl"],
 790     [HaveLibDL=NO])
 791 AC_SUBST(HaveLibDL)
 792
 793 dnl --------------------------------------------------
 794 dnl * Miscellaneous feature tests
 795 dnl --------------------------------------------------
 796
 797 dnl ** can we get alloca?
 798 AC_FUNC_ALLOCA
 799
 800 dnl ** Working vfork?
 801 AC_FUNC_FORK
 802
 803 dnl ** determine whether or not const works
 804 AC_C_CONST
 805
 806 dnl ** are we big endian?
 807 AC_C_BIGENDIAN
 808 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
 809
 810 dnl ** check for leading underscores in symbol names
 811 FP_LEADING_UNDERSCORE
 812
 813 dnl ** check for ld, whether it has an -x option, and if it is GNU ld
 814 FP_PROG_LD_X
 815 FP_PROG_LD_IS_GNU
 816
 817 dnl ** check for Apple-style dead-stripping support
 818 dnl    (.subsections-via-symbols assembler directive)
 819
 820
 821 AC_MSG_CHECKING(for .subsections_via_symbols)
 822 AC_COMPILE_IFELSE(
 823     [AC_LANG_PROGRAM([], [__asm__ (".subsections_via_symbols");])],
 824     [AC_MSG_RESULT(yes)
 825      AC_DEFINE([HAVE_SUBSECTIONS_VIA_SYMBOLS],[1],
 826                [Define to 1 if Apple-style dead-stripping is supported.])
 827     ],
 828     [AC_MSG_RESULT(no)])
 829
 830 dnl *** check for GNU non-executable stack note support (ELF only)
 831 dnl     (.section .note.GNU-stack,"",@progbits)
 832
 833 AC_MSG_CHECKING(for GNU non-executable stack support)
 834 AC_COMPILE_IFELSE(
 835     [AC_LANG_PROGRAM([__asm__ (".section .note.GNU-stack,\"\",@progbits");], [0])],
 836     [AC_MSG_RESULT(yes)
 837      AC_DEFINE([HAVE_GNU_NONEXEC_STACK],[1],
 838                [Define to 1 if GNU non-executable stack notes are supported.])
 839     ],
 840     [AC_MSG_RESULT(no)])
 841
 842 dnl ** check for librt
 843 AC_CHECK_LIB(rt, clock_gettime)
 844 AC_CHECK_FUNCS(clock_gettime timer_create timer_settime)
 845 FP_CHECK_TIMER_CREATE
 846
 847 dnl ** check for Apple's "interesting" long double compatibility scheme
 848 AC_MSG_CHECKING(for printf\$LDBLStub)
 849 AC_TRY_LINK_FUNC(printf\$LDBLStub,
 850     [
 851         AC_MSG_RESULT(yes)
 852         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
 853             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 854     ],
 855     [
 856         AC_MSG_RESULT(no)
 857         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
 858             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 859     ])
 860
 861 # test for GTK+
 862 AC_PATH_PROGS([GTK_CONFIG], [pkg-config])
 863 if test -n "$GTK_CONFIG"; then
 864   if $GTK_CONFIG gtk+-2.0 --atleast-version=2.0; then
 865     GTK_CONFIG="$GTK_CONFIG gtk+-2.0"
 866   else
 867     AC_MSG_WARN([GTK+ not usable, need at least version 2.0])
 868     GTK_CONFIG=
 869   fi
 870 fi
 871 AC_SUBST([GTK_CONFIG])
 872
 873 #Checking for PAPI
 874 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
 875 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
 876 AC_SUBST(HavePapiLib)
 877 AC_SUBST(HavePapiHeader)
 878
 879 AC_CHECK_FUNCS(__mingw_vfprintf)
 880
 881 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
 882    HavePapi=YES
 883 else
 884    HavePapi=NO
 885 fi
 886 AC_SUBST(HavePapi)
 887
 888 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
 889    test "$XsltprocCmd" = ""
 890 then
 891     BUILD_DOCBOOK_HTML=NO
 892 else
 893     BUILD_DOCBOOK_HTML=YES
 894 fi
 895 AC_SUBST(BUILD_DOCBOOK_HTML)
 896
 897 if test "$DblatexCmd" = ""
 898 then
 899     BUILD_DOCBOOK_PS=NO
 900     BUILD_DOCBOOK_PDF=NO
 901 else
 902     BUILD_DOCBOOK_PS=YES
 903     BUILD_DOCBOOK_PDF=YES
 904 fi
 905 AC_SUBST(BUILD_DOCBOOK_PS)
 906 AC_SUBST(BUILD_DOCBOOK_PDF)
 907
 908 LIBRARY_VERSION(base)
 909 LIBRARY_VERSION(Cabal)
 910 LIBRARY_VERSION(ghc-prim)
 911 LIBRARY_ghc_VERSION="$ProjectVersion"
 912 AC_SUBST(LIBRARY_ghc_VERSION)
 913
 914 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
 915    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
 916 fi
 917
 918 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal ghc.spec extra-gcc-opts docs/users_guide/ug-book.xml docs/users_guide/ug-ent.xml docs/index.html libraries/prologue.txt distrib/ghc.iss distrib/configure.ac])
 919 AC_CONFIG_COMMANDS([mk/stamp-h],[echo timestamp > mk/stamp-h])
 920 AC_OUTPUT
 921
 922 # We get caught by
 923 #     http://savannah.gnu.org/bugs/index.php?1516
 924 #     $(eval ...) inside conditionals causes errors
 925 # with make 3.80, so warn the user if it looks like they're about to
 926 # try to use it.
 927 # We would use "grep -q" here, but Solaris's grep doesn't support it.
 928 checkMake380() {
 929     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
 930     then
 931         echo
 932         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
 933         echo "This version cannot be used to build GHC."
 934         echo "Please use GNU make >= 3.81."
 935     fi
 936 }
 937
 938 checkMake380 make
 939 checkMake380 gmake
 940
 941 echo ["
 942 ----------------------------------------------------------------------
 943 Configure completed successfully.
 944
 945    Building GHC version  : $ProjectVersion
 946
 947    Build platform        : $BuildPlatform
 948    Host platform         : $HostPlatform
 949    Target platform       : $TargetPlatform
 950 "]
 951
 952 if test "$BootingFromHc" = "YES"; then
 953 echo ["\
 954    Bootstrapping from HC files.
 955 "]
 956 else
 957 echo ["\
 958    Bootstrapping using   : $WithGhc
 959       which is version   : $GhcVersion
 960 "]
 961 fi
 962
 963 echo ["\
 964    Using GCC             : $WhatGccIsCalled
 965       which is version   : $GccVersion
 966
 967    ld       : $LdCmd
 968    Happy    : $HappyCmd ($HappyVersion)
 969    Alex     : $AlexCmd ($AlexVersion)
 970    Python   : $PythonCmd
 971    Perl     : $PerlCmd
 972    dblatex  : $DblatexCmd
 973    xsltproc : $XsltprocCmd"]
 974
 975 if test "$HSCOLOUR" = ""; then
 976 echo ["
 977    HsColour was not found; documentation will not contain source links
 978 "]
 979 else
 980 echo ["\
 981    HsColour : $HSCOLOUR
 982 "]
 983 fi
 984
 985 echo ["\
 986    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
 987    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
 988    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
 989
 990 echo ["----------------------------------------------------------------------
 991 "]
 992
 993 echo "\
 994 For a standard build of GHC (fully optimised with profiling), type (g)make.
 995
 996 To make changes to the default build configuration, copy the file
 997 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
 998
 999 For more information on how to configure your GHC build, see
1000    http://hackage.haskell.org/trac/ghc/wiki/Building
1001 "