configure.ac

   1 dnl == autoconf source for the Glasgow FP tools ==
   2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
   3 dnl  (or some such) to see the outline of this file)
   4 dnl
   5 #
   6 # (c) The University of Glasgow 1994-2004
   7 #
   8 # Configure script template for GHC
   9 #
  10 # Process with 'autoreconf' to get a working configure script.
  11 #
  12 # For the generated configure script, do "./configure --help" to
  13 # see what flags are available. (Better yet, read the documentation!)
  14 #
  15
  16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [7.1], [glasgow-haskell-bugs@haskell.org], [ghc])
  17
  18 # Set this to YES for a released version, otherwise NO
  19 : ${RELEASE=NO}
  20
  21 # The primary version (e.g. 6.7, 6.6.1) is set in the AC_INIT line
  22 # above.  If this is not a released version, then we will append the
  23 # date to the version number (e.g. 6.7.20070204).  The date is
  24 # constructed by finding the date of the most recent patch in the
  25 # darcs repository.  If this is a source distribution (not a darcs
  26 # checkout), then we ship a file 'VERSION' containing the full version
  27 # when the source distribution was created.
  28
  29 if test ! -f mk/config.h.in; then
  30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
  31    exit 1
  32 fi
  33
  34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
  35
  36 dnl ----------------------------------------------------------
  37 dnl ** Find unixy sort and find commands,
  38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
  39
  40 dnl ** Find find command (for Win32's benefit)
  41 FP_PROG_FIND
  42
  43 dnl ** Find sort command (for the benefit of Win32 environs)
  44 FP_PROG_SORT
  45
  46 dnl ----------------------------------------------------------
  47 FP_SETUP_PROJECT_VERSION
  48
  49 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
  50 AC_SUBST([release], [1])
  51
  52 # First off, a distrib sanity check..
  53 AC_CONFIG_SRCDIR([mk/config.mk.in])
  54
  55 dnl * We require autoconf version 2.52
  56 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
  57 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
  58 AC_PREREQ([2.52])
  59
  60 # -------------------------------------------------------------------------
  61 # Prepare to generate the following header files
  62 #
  63 #
  64 AC_CONFIG_HEADER(mk/config.h)
  65
  66 # No, semi-sadly, we don't do `--srcdir'...
  67 if test x"$srcdir" != 'x.' ; then
  68     echo "This configuration does not support the \`--srcdir' option.."
  69     exit 1
  70 fi
  71
  72 dnl --------------------------------------------------------------
  73 dnl * Project specific configuration options
  74 dnl --------------------------------------------------------------
  75 dnl What follows is a bunch of options that can either be configured
  76 dnl through command line options to the configure script or by
  77 dnl supplying defns in the build tree's mk/build.mk. Having the option to
  78 dnl use either is considered a Feature.
  79
  80 dnl ** What command to use to compile compiler sources ?
  81 dnl --------------------------------------------------------------
  82
  83 AC_ARG_WITH([ghc],
  84 [AC_HELP_STRING([--with-ghc=ARG],
  85   [Use ARG as the path to GHC  [default=autodetect]])],
  86   [WithGhc="$withval"],
  87   [if test "$GHC" = ""; then
  88     AC_PATH_PROG([GHC], [ghc])
  89   fi
  90   WithGhc="$GHC"])
  91
  92
  93 dnl ** Tell the make system which OS we are using
  94 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
  95 AC_SUBST(OSTYPE)
  96
  97 dnl ** Booting from .hc files?
  98 dnl --------------------------------------------------------------
  99 AC_ARG_ENABLE(hc-boot,
 100 [AC_HELP_STRING([--enable-hc-boot],
 101 [Boot the Glasgow Haskell Compiler from intermediate .hc files.
 102  (This option is mostly of interest to porters.) [default=no]])],
 103 [ if test x"$enableval" = x"yes"; then
 104         BootingFromHc=YES
 105   else
 106         BootingFromHc=NO
 107   fi
 108 ],
 109 [BootingFromHc=NO]
 110 )
 111 AC_SUBST(BootingFromHc)
 112
 113 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
 114 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
 115                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
 116         EnableBootstrapWithDevelSnaphost=YES,
 117         EnableBootstrapWithDevelSnaphost=NO
 118 )
 119
 120 if test "$WithGhc" != ""; then
 121   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
 122
 123   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
 124      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
 125   fi
 126
 127   AC_SUBST(GhcVersion)dnl
 128   AC_SUBST(GhcMajVersion)dnl
 129   AC_SUBST(GhcMinVersion)dnl
 130   AC_SUBST(GhcPatchLevel)dnl
 131   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
 132   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
 133   if test $GhcCanonVersion -ge 613; then ghc_ge_613=YES; else ghc_ge_613=NO; fi
 134   AC_SUBST(ghc_ge_613)dnl
 135
 136   BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command],['$(CC)'])
 137 fi
 138
 139 dnl ** Must have GHC to build GHC, unless --enable-hc-boot is on
 140 if test "$BootingFromHc" = "NO"; then
 141   if test "$WithGhc" = ""; then
 142      AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 143   fi
 144   FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[6.12],
 145     [AC_MSG_ERROR([GHC version 6.12 or later is required to compile GHC.])])dnl
 146
 147   if test `expr $GhcMinVersion % 2` = "1"; then
 148      if test "$EnableBootstrapWithDevelSnaphost" = "NO"; then
 149         AC_MSG_ERROR([
 150      $WithGhc is a development snapshot of GHC, version $GhcVersion.
 151      Bootstrapping using this version of GHC is not supported, and may not
 152      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
 153      or --with-ghc to specify a different GHC to use.])
 154      fi
 155   fi
 156 fi;
 157
 158 # GHC is passed to Cabal, so we need a native path
 159 if test "${WithGhc}" != ""
 160 then
 161     ghc_host=`"${WithGhc}" +RTS --info | grep 'Host platform' | sed -e 's/.*, "//' -e 's/")//'`
 162
 163     if test "$ghc_host" = "i386-unknown-mingw32"
 164     then
 165         if test "${OSTYPE}" = "msys"
 166         then
 167             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
 168         else
 169             # Canonicalise to <drive>:/path/to/ghc
 170             WithGhc=`cygpath -m "${WithGhc}"`
 171         fi
 172         echo "GHC path canonicalised to: ${WithGhc}"
 173     fi
 174 fi
 175 AC_SUBST([WithGhc])
 176
 177 dnl ** Without optimization some INLINE trickery fails for GHCi
 178 SRC_CC_OPTS="-O"
 179
 180 FP_ICONV
 181 FP_GMP
 182
 183 dnl--------------------------------------------------------------------
 184 dnl * Choose host(/target/build) platform
 185 dnl--------------------------------------------------------------------
 186 dnl If we aren't explicitly told what values to use with configure flags,
 187 dnl we ask the bootstrapping compiler what platform it is for
 188
 189 if test "${WithGhc}" != ""
 190 then
 191         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 192         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 193         if test "$bootstrap_host" != "$bootstrap_target"
 194         then
 195                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
 196         fi
 197 fi
 198
 199 # We have to run these unconditionally, but we may discard their
 200 # results in the following code
 201 AC_CANONICAL_BUILD
 202 AC_CANONICAL_HOST
 203 AC_CANONICAL_TARGET
 204
 205 FPTOOLS_SET_PLATFORM_VARS
 206
 207 exeext=''
 208 soext='.so'
 209 case $host in
 210 *-unknown-cygwin32)
 211     AC_MSG_WARN([GHC does not support the Cygwin target at the moment])
 212     AC_MSG_WARN([I'm assuming you wanted to build for i386-unknown-mingw32])
 213     exit 1
 214     ;;
 215 *-unknown-mingw32)
 216     exeext='.exe'
 217     soext='.dll'
 218     ;;
 219 i386-apple-darwin|powerpc-apple-darwin)
 220     soext='.dylib'
 221     ;;
 222 x86_64-apple-darwin)
 223     soext='.dylib'
 224     ;;
 225 esac
 226
 227 # Testing if we shall enable shared libs support on Solaris.
 228 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
 229
 230 SOLARIS_BROKEN_SHLD=NO
 231
 232 case $host in
 233      i386-*-solaris2)
 234      # here we go with the test
 235      MINOR=`uname -r|cut -d '.' -f 2-`
 236      if test "$MINOR" -lt "11"; then
 237         SOLARIS_BROKEN_SHLD=YES
 238      fi
 239      ;;
 240 esac
 241
 242 # Sync this with cTargetArch in compiler/ghc.mk
 243 checkArch() {
 244     case $1 in
 245     alpha|arm|hppa|hppa1_1|i386|ia64|m68k|mips|mipseb|mipsel|powerpc|powerpc64|rs6000|s390|sparc|sparc64|vax|x86_64)
 246         ;;
 247     *)
 248         echo "Unknown arch $1"
 249         exit 1
 250         ;;
 251     esac
 252 }
 253
 254 checkVendor() {
 255     case $1 in
 256     dec|unknown|hp|apple|next|sun|sgi|ibm)
 257         ;;
 258     *)
 259         echo "Unknown vendor $1"
 260         exit 1
 261         ;;
 262     esac
 263 }
 264
 265 checkOS() {
 266     case $1 in
 267     linux|freebsd|netbsd|openbsd|dragonfly|osf1|osf3|hpux|linuxaout|kfreebsdgnu|freebsd2|solaris2|cygwin32|mingw32|darwin|gnu|nextstep2|nextstep3|sunos4|ultrix|irix|aix|haiku)
 268         ;;
 269     *)
 270         echo "Unknown OS '$1'"
 271         exit 1
 272         ;;
 273     esac
 274 }
 275
 276 BuildPlatform="$BuildArch-$BuildVendor-$BuildOS"
 277 BuildPlatform_CPP=`echo "$BuildPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 278 BuildArch_CPP=`    echo "$BuildArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 279 BuildVendor_CPP=`  echo "$BuildVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 280 BuildOS_CPP=`      echo "$BuildOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 281
 282 checkArch "$BuildArch"
 283 checkVendor "$BuildVendor"
 284 checkOS "$BuildOS"
 285
 286 HostPlatform="$HostArch-$HostVendor-$HostOS"
 287 HostPlatform_CPP=`echo "$HostPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 288 HostArch_CPP=`    echo "$HostArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 289 HostVendor_CPP=`  echo "$HostVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 290 HostOS_CPP=`      echo "$HostOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 291
 292 checkArch "$HostArch"
 293 checkVendor "$HostVendor"
 294 checkOS "$HostOS"
 295
 296 TargetPlatform="$TargetArch-$TargetVendor-$TargetOS"
 297 TargetPlatform_CPP=`echo "$TargetPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 298 TargetArch_CPP=`    echo "$TargetArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 299 TargetVendor_CPP=`  echo "$TargetVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 300 TargetOS_CPP=`      echo "$TargetOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 301
 302 checkArch "$TargetArch"
 303 checkVendor "$TargetVendor"
 304 checkOS "$TargetOS"
 305
 306 # Verify that the installed (bootstrap) GHC is capable of generating
 307 # code for the requested build platform.
 308 if test "$BootingFromHc" = "NO"
 309 then
 310     if test "$BuildPlatform" != "$bootstrap_target"
 311     then
 312         echo "This GHC (${WithGhc}) does not generate code for the build platform"
 313         echo "   GHC target platform    : $bootstrap_target"
 314         echo "   Desired build platform : $BuildPlatform"
 315         exit 1
 316     fi
 317 fi
 318
 319 echo "GHC build  : $BuildPlatform"
 320 echo "GHC host   : $HostPlatform"
 321 echo "GHC target : $TargetPlatform"
 322
 323 AC_SUBST(BuildPlatform)
 324 AC_SUBST(HostPlatform)
 325 AC_SUBST(TargetPlatform)
 326 AC_SUBST(HostPlatform_CPP)
 327 AC_SUBST(BuildPlatform_CPP)
 328 AC_SUBST(TargetPlatform_CPP)
 329
 330 AC_SUBST(HostArch_CPP)
 331 AC_SUBST(BuildArch_CPP)
 332 AC_SUBST(TargetArch_CPP)
 333
 334 AC_SUBST(HostOS_CPP)
 335 AC_SUBST(BuildOS_CPP)
 336 AC_SUBST(TargetOS_CPP)
 337
 338 AC_SUBST(HostVendor_CPP)
 339 AC_SUBST(BuildVendor_CPP)
 340 AC_SUBST(TargetVendor_CPP)
 341
 342 AC_SUBST(exeext)
 343 AC_SUBST(soext)
 344
 345 AC_SUBST(SOLARIS_BROKEN_SHLD)
 346
 347 AC_ARG_WITH(hc,
 348 [AC_HELP_STRING([--with-hc=ARG],
 349         [Use ARG as the path to the compiler for compiling ordinary
 350          Haskell code  (default= value of --with-ghc)])],
 351 [WithHc="$withval"],
 352 [WithHc=$WithGhc]
 353 )
 354 AC_SUBST(WithHc)
 355
 356 # This uses GHC, so put it after the "GHC is required" check above:
 357 FP_INTREE_GHC_PWD
 358 FP_FIND_ROOT
 359
 360 if test "$HostOS" = "mingw32"
 361 then
 362     test -d inplace || mkdir inplace
 363
 364     CC="$hardtop/inplace/mingw/bin/gcc.exe"
 365     LD="$hardtop/inplace/mingw/bin/ld.exe"
 366     NM="$hardtop/inplace/mingw/bin/nm.exe"
 367     fp_prog_ar_raw="$hardtop/inplace/mingw/bin/ar.exe"
 368
 369     # NB. If you update the tarbballs to a new version of gcc, don't
 370     # forget to tweak the paths in driver/gcc/gcc.c.
 371     if ! test -d inplace/mingw ||
 372          test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.lzma  ||
 373          test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.lzma  ||
 374          test inplace/mingw -ot ghc-tarballs/mingw/gcc-c++*.tar.lzma   ||
 375          test inplace/mingw -ot ghc-tarballs/mingw/libgcc*.tar.gz      ||
 376          test inplace/mingw -ot ghc-tarballs/mingw/libgmp*.tar.gz      ||
 377          test inplace/mingw -ot ghc-tarballs/mingw/libmpc*.tar.gz      ||
 378          test inplace/mingw -ot ghc-tarballs/mingw/libmpfr*.tar.gz     ||
 379          test inplace/mingw -ot ghc-tarballs/mingw/libstdc*.tar.lzma   ||
 380          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dev.tar.gz ||
 381          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dll.tar.gz ||
 382          test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.lzma
 383     then
 384         AC_MSG_NOTICE([Making in-tree mingw tree])
 385         rm -rf inplace/mingw
 386         mkdir inplace/mingw
 387         (
 388             cd inplace/mingw &&
 389             tar --lzma -xf ../../ghc-tarballs/mingw/binutils*.tar.lzma  &&
 390             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-core*.tar.lzma  &&
 391             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-c++*.tar.lzma   &&
 392             tar --lzma -xf ../../ghc-tarballs/mingw/libgcc*.tar.lzma    &&
 393             tar --lzma -xf ../../ghc-tarballs/mingw/libgmp*.tar.lzma    &&
 394             tar --lzma -xf ../../ghc-tarballs/mingw/libmpc*.tar.lzma    &&
 395             tar --lzma -xf ../../ghc-tarballs/mingw/libmpfr*.tar.lzma   &&
 396             tar --lzma -xf ../../ghc-tarballs/mingw/libstdc*.tar.lzma   &&
 397             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dev.tar.gz &&
 398             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dll.tar.gz &&
 399             tar --lzma -xf ../../ghc-tarballs/mingw/w32api*.tar.lzma    &&
 400             mv bin/gcc.exe bin/realgcc.exe
 401         )
 402         PATH=`pwd`/inplace/mingw/bin:$PATH inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
 403         if ! test -e inplace/mingw/bin/gcc.exe
 404         then
 405             AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 406         fi
 407         AC_MSG_NOTICE([In-tree mingw tree created])
 408     fi
 409     if ! test -d inplace/perl ||
 410          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
 411     then
 412         AC_MSG_NOTICE([Making in-tree perl tree])
 413         rm -rf inplace/perl
 414         mkdir inplace
 415         mkdir inplace/perl
 416         (
 417             cd inplace/perl &&
 418             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
 419         )
 420         AC_MSG_NOTICE([In-tree perl tree created])
 421     fi
 422 fi
 423
 424 dnl ** Which gcc to use?
 425 dnl --------------------------------------------------------------
 426 FP_ARG_WITH_PATH_GNU_PROG([CC], [gcc])
 427 export CC
 428 WhatGccIsCalled="$CC"
 429 AC_SUBST(WhatGccIsCalled)
 430
 431 dnl ** Which ld to use?
 432 dnl --------------------------------------------------------------
 433 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld])
 434 LdCmd="$LD"
 435 AC_SUBST([LdCmd])
 436
 437 dnl ** Which nm to use?
 438 dnl --------------------------------------------------------------
 439 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm])
 440 NmCmd="$NM"
 441 AC_SUBST([NmCmd])
 442
 443 SplitObjsBroken=NO
 444 if test "$TargetOS_CPP" = "darwin"
 445 then
 446     AC_MSG_CHECKING(XCode version)
 447     XCodeVersion=`xcodebuild -version | grep Xcode | sed "s/Xcode //"`
 448     # Old XCode versions don't actually give the XCode version
 449     if test "$XCodeVersion" = ""
 450     then
 451         AC_MSG_RESULT(not found (too old?))
 452         SplitObjsBroken=YES
 453     else
 454         AC_MSG_RESULT($XCodeVersion)
 455         XCodeVersion1=`echo "$XCodeVersion" | sed 's/\..*//'`
 456 changequote(, )dnl
 457         XCodeVersion2=`echo "$XCodeVersion" | sed 's/[^.]*\.\([^.]*\).*/\1/'`
 458 changequote([, ])dnl
 459         AC_MSG_NOTICE(XCode version component 1: $XCodeVersion1)
 460         AC_MSG_NOTICE(XCode version component 2: $XCodeVersion2)
 461         # Split objects is broken (#4013) with XCode < 3.2
 462         if test "$XCodeVersion1" -lt 3
 463         then
 464             SplitObjsBroken=YES
 465         else
 466             if test "$XCodeVersion1" -eq 3
 467             then
 468                 if test "$XCodeVersion2" -lt 2
 469                 then
 470                     SplitObjsBroken=YES
 471                 fi
 472             fi
 473         fi
 474     fi
 475 fi
 476 AC_SUBST([SplitObjsBroken])
 477
 478 dnl ** Mac OS X: explicit deployment target
 479 dnl --------------------------------------------------------------
 480 AC_ARG_WITH([macosx-deployment-target],
 481 [AC_HELP_STRING([--with-macosx-deployment-target=VERSION],
 482         [Build for Mac OS VERSION and higher  (default= version of build host)])],
 483 [FP_MACOSX_DEPLOYMENT_TARGET="$withval"
 484  if test "x$TargetOS_CPP-$TargetVendor_CPP" != "xdarwin-apple"; then
 485    # ignore everywhere, but on Mac OS
 486    AC_MSG_WARN([--macosx-deployment-target is only available on Mac OS X])
 487    FP_MACOSX_DEPLOYMENT_TARGET=none
 488  fi],
 489 [FP_MACOSX_DEPLOYMENT_TARGET=none]
 490 )
 491 FP_CHECK_MACOSX_DEPLOYMENT_TARGET
 492 AC_SUBST(MACOSX_DEPLOYMENT_VERSION)
 493 AC_SUBST(MACOSX_DEPLOYMENT_SDK)
 494
 495 dnl --------------------------------------------------------------
 496 dnl End of configure script option section
 497 dnl --------------------------------------------------------------
 498
 499
 500 dnl --------------------------------------------------------------
 501 dnl * General configuration checks
 502 dnl --------------------------------------------------------------
 503
 504 dnl ** Can the unix package be built?
 505 dnl --------------------------------------------------------------
 506
 507 if test x"$TargetPlatform" = x"i386-unknown-mingw32"; then
 508    GhcLibsWithUnix=NO
 509 else
 510    GhcLibsWithUnix=YES
 511 fi
 512 AC_SUBST([GhcLibsWithUnix])
 513
 514 dnl ** does #! work?
 515 AC_SYS_INTERPRETER()
 516
 517 dnl ** look for `perl'
 518 case $HostOS_CPP in
 519 cygwin32|mingw32)
 520     PerlCmd=$hardtop/inplace/perl/perl
 521     ;;
 522 *)
 523     AC_PATH_PROG(PerlCmd,perl)
 524     if test -z "$PerlCmd"
 525     then
 526         echo "You must install perl before you can continue"
 527         echo "Perhaps it is already installed, but not in your PATH?"
 528         exit 1
 529     else
 530         FPTOOLS_CHECK_PERL_VERSION
 531     fi
 532     ;;
 533 esac
 534
 535 dnl ** does #! path/to/perl work? (sometimes it's too long...)
 536 FPTOOLS_SHEBANG_PERL
 537
 538 dnl ** check for Python
 539 AC_PATH_PROG(PythonCmd,python)
 540
 541 dnl ** look for GCC and find out which version
 542 dnl     Figure out which C compiler to use.  Gcc is preferred.
 543 dnl     If gcc, make sure it's at least 2.1
 544 dnl
 545 FP_GCC_VERSION
 546
 547 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
 548 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
 549 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
 550 # Stage 3 won't be supported by cross-compilation
 551 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
 552
 553 FP_GCC_EXTRA_FLAGS
 554
 555 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
 556 AC_PROG_CPP
 557
 558 AC_SUBST(CONF_CC_OPTS_STAGE0)
 559 AC_SUBST(CONF_CC_OPTS_STAGE1)
 560 AC_SUBST(CONF_CC_OPTS_STAGE2)
 561 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
 562 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
 563 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
 564 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
 565 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
 566 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
 567 AC_SUBST(CONF_CPP_OPTS_STAGE0)
 568 AC_SUBST(CONF_CPP_OPTS_STAGE1)
 569 AC_SUBST(CONF_CPP_OPTS_STAGE2)
 570
 571 dnl ** figure out how to do context diffs
 572 FP_PROG_CONTEXT_DIFF
 573
 574 dnl Let's make sure install-sh is executable here.  If we got it from
 575 dnl a darcs repo, it might not be (see bug #978).
 576 chmod +x install-sh
 577 dnl ** figure out how to do a BSD-ish install
 578 AC_PROG_INSTALL
 579
 580 dnl If you can run configure, you certainly have /bin/sh
 581 AC_DEFINE([HAVE_BIN_SH], [1], [Define to 1 if you have /bin/sh.])
 582
 583 dnl ** how to invoke `ar' and `ranlib'
 584 FP_PROG_AR_SUPPORTS_ATFILE
 585 FP_PROG_AR_NEEDS_RANLIB
 586
 587 dnl ** Check to see whether ln -s works
 588 AC_PROG_LN_S
 589
 590
 591 dnl ** Find the path to sed
 592 AC_PATH_PROGS(SedCmd,gsed sed,sed)
 593
 594
 595 dnl ** check for time command
 596 AC_PATH_PROG(TimeCmd,time)
 597
 598 dnl ** check for tar
 599 dnl   if GNU tar is named gtar, look for it first.
 600 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
 601
 602 dnl ** check for patch
 603 dnl if GNU patch is named gpatch, look for it first
 604 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
 605
 606 dnl ** check for dtrace (currently only implemented for Mac OS X)
 607 HaveDtrace=NO
 608 AC_PATH_PROG(DtraceCmd,dtrace)
 609 if test -n "$DtraceCmd"; then
 610   if test "x$TargetOS_CPP-$TargetVendor_CPP" == "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" == "xsolaris2-unknown"; then
 611     HaveDtrace=YES
 612   fi
 613 fi
 614 AC_SUBST(HaveDtrace)
 615
 616 AC_PATH_PROG(HSCOLOUR,HsColour)
 617 # HsColour is passed to Cabal, so we need a native path
 618 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 619    test "${OSTYPE}"      != "msys"                  && \
 620    test "${HSCOLOUR}"    != ""
 621 then
 622     # Canonicalise to <drive>:/path/to/gcc
 623     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
 624 fi
 625
 626 dnl ** check for DocBook toolchain
 627 FP_CHECK_DOCBOOK_DTD
 628 FP_DOCBOOK_XSL
 629 FP_PROG_DBLATEX
 630
 631 FP_PROG_HSTAGS
 632
 633 dnl ** check for ghc-pkg command
 634 FP_PROG_GHC_PKG
 635
 636 dnl ** check for installed happy binary + version
 637 dnl    (don't do it if we're booting from .hc files though.)
 638 if test "$BootingFromHc" = "NO"; then
 639 FPTOOLS_HAPPY
 640 fi;
 641
 642 dnl ** check for installed alex binary + version
 643 dnl    (don't do it if we're booting from .hc files though.)
 644 if test "$BootingFromHc" = "NO"; then
 645 FPTOOLS_ALEX
 646 fi;
 647
 648 dnl --------------------------------------------------
 649 dnl ### program checking section ends here ###
 650 dnl --------------------------------------------------
 651
 652 dnl --------------------------------------------------
 653 dnl * Platform header file and syscall feature tests
 654 dnl ### checking the state of the local header files and syscalls ###
 655
 656 dnl ** check for full ANSI header (.h) files
 657 AC_HEADER_STDC
 658
 659 dnl ** Enable large file support.  NB. do this before testing the type of
 660 dnl    off_t, because it will affect the result of that test.
 661 AC_SYS_LARGEFILE
 662
 663 dnl ** check for specific header (.h) files that we are interested in
 664 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/cpuset.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
 665
 666 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
 667 AC_HEADER_TIME
 668
 669 dnl ** do we have long longs?
 670 AC_CHECK_TYPES([long long])
 671
 672 dnl ** what are the sizes of various types
 673 AC_CHECK_SIZEOF(char,               1)
 674 AC_CHECK_SIZEOF(double,             8)
 675 AC_CHECK_SIZEOF(float,              4)
 676 AC_CHECK_SIZEOF(int,                4)
 677 AC_CHECK_SIZEOF(long,               4)
 678 if test "$ac_cv_type_long_long" = yes; then
 679 AC_CHECK_SIZEOF(long long,          8)
 680 fi
 681 AC_CHECK_SIZEOF(short,              2)
 682 AC_CHECK_SIZEOF(unsigned char,      1)
 683 AC_CHECK_SIZEOF(unsigned int,       4)
 684 AC_CHECK_SIZEOF(unsigned long,      4)
 685 if test "$ac_cv_type_long_long" = yes; then
 686 AC_CHECK_SIZEOF(unsigned long long, 8)
 687 fi
 688 AC_CHECK_SIZEOF(unsigned short,     2)
 689 AC_CHECK_SIZEOF(void *,             4)
 690
 691 dnl ** what are alignment constraints on various types
 692 FP_CHECK_ALIGNMENT(char)
 693 FP_CHECK_ALIGNMENT(double)
 694 FP_CHECK_ALIGNMENT(float)
 695 FP_CHECK_ALIGNMENT(int)
 696 FP_CHECK_ALIGNMENT(long)
 697 if test "$ac_cv_type_long_long" = yes; then
 698 FP_CHECK_ALIGNMENT(long long)
 699 fi
 700 FP_CHECK_ALIGNMENT(short)
 701 FP_CHECK_ALIGNMENT(unsigned char)
 702 FP_CHECK_ALIGNMENT(unsigned int)
 703 FP_CHECK_ALIGNMENT(unsigned long)
 704 if test "$ac_cv_type_long_long" = yes; then
 705 FP_CHECK_ALIGNMENT(unsigned long long)
 706 fi
 707 FP_CHECK_ALIGNMENT(unsigned short)
 708 FP_CHECK_ALIGNMENT(void *)
 709
 710 FP_CHECK_FUNC([WinExec],
 711   [@%:@include <windows.h>], [WinExec("",0)])
 712
 713 FP_CHECK_FUNC([GetModuleFileName],
 714   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
 715
 716 dnl ** check return type of signal handlers
 717 dnl Foo: assumes we can use prototypes.
 718 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 719 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
 720 dnl [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 721 dnl #include <signal.h>
 722 dnl #ifdef signal
 723 dnl #undef signal
 724 dnl #endif
 725 dnl void (*signal (int, void (*)(int)))(int);
 726 dnl ]],
 727 dnl [[int i;]])],
 728 dnl [ac_cv_type_signal_handler=void_int],
 729 dnl [ac_cv_type_signal_handler=int_void])])
 730 dnl if test "$ac_cv_type_signal_handler" = void_int; then
 731 dnl AC_DEFINE(VOID_INT_SIGNALS)
 732 dnl fi
 733
 734 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 735 AC_TYPE_SIGNAL
 736 if test "$ac_cv_type_signal" = void; then
 737   AC_DEFINE([VOID_INT_SIGNALS], [1], [Define to 1 if signal handlers have type void (*)(int). Otherwise, they're assumed to have type int (*)(void).])
 738 fi
 739
 740 dnl ** check for more functions
 741 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
 742 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
 743
 744 AC_TRY_RUN([
 745 #include <sys/types.h>
 746 #include <sys/time.h>
 747 int main(void) {
 748   struct itimerval tval;
 749   tval.it_value.tv_sec = 1;
 750   tval.it_value.tv_usec = 0;
 751   tval.it_interval = tval.it_value;
 752   return setitimer(ITIMER_VIRTUAL, &tval, (void*)0) != 0;
 753 }
 754 ],[AC_DEFINE([HAVE_SETITIMER_VIRTUAL], [1], [Define to 1 if setitimer accepts ITIMER_VIRTUAL, 0 else.])])
 755
 756 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
 757 dnl ** _POSIX_C_SOURCE is defined
 758 AC_CHECK_DECLS([ctime_r], , ,
 759 [#define _POSIX_SOURCE 1
 760 #define _POSIX_C_SOURCE 199506L
 761 #include <time.h>])
 762
 763 dnl ** check for mingwex library
 764 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
 765 AC_SUBST(HaveLibMingwEx)
 766
 767 if test $HaveLibMingwEx = YES ; then
 768   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
 769 fi
 770
 771 dnl ** check for math library
 772 dnl    Keep that check as early as possible.
 773 dnl    as we need to know whether we need libm
 774 dnl    for math functions or not
 775 dnl    (see http://hackage.haskell.org/trac/ghc/ticket/3730)
 776 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
 777 if test $HaveLibM = YES
 778 then
 779   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
 780 fi
 781
 782 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
 783 dnl    the order of these tests matters: bfd needs liberty
 784 AC_CHECK_LIB(iberty, xmalloc)
 785 AC_CHECK_LIB(bfd,    bfd_init)
 786
 787 dnl ################################################################
 788 dnl Check for libraries
 789 dnl ################################################################
 790
 791 dnl ** check whether we need -ldl to get dlopen()
 792
 793 AC_CHECK_LIB(dl, dlopen,
 794     [HaveLibDL=YES
 795      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
 796      LIBS="$LIBS -ldl"],
 797     [HaveLibDL=NO])
 798 AC_SUBST(HaveLibDL)
 799
 800 dnl --------------------------------------------------
 801 dnl * Miscellaneous feature tests
 802 dnl --------------------------------------------------
 803
 804 dnl ** can we get alloca?
 805 AC_FUNC_ALLOCA
 806
 807 dnl ** Working vfork?
 808 AC_FUNC_FORK
 809
 810 dnl ** determine whether or not const works
 811 AC_C_CONST
 812
 813 dnl ** are we big endian?
 814 AC_C_BIGENDIAN
 815 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
 816
 817 dnl ** check for leading underscores in symbol names
 818 FP_LEADING_UNDERSCORE
 819
 820 dnl ** check for ld, whether it has an -x option, and if it is GNU ld
 821 FP_PROG_LD_X
 822 FP_PROG_LD_IS_GNU
 823 FP_PROG_LD_BUILD_ID
 824
 825 dnl ** check for Apple-style dead-stripping support
 826 dnl    (.subsections-via-symbols assembler directive)
 827
 828
 829 AC_MSG_CHECKING(for .subsections_via_symbols)
 830 AC_COMPILE_IFELSE(
 831     [AC_LANG_PROGRAM([], [__asm__ (".subsections_via_symbols");])],
 832     [AC_MSG_RESULT(yes)
 833      AC_DEFINE([HAVE_SUBSECTIONS_VIA_SYMBOLS],[1],
 834                [Define to 1 if Apple-style dead-stripping is supported.])
 835     ],
 836     [AC_MSG_RESULT(no)])
 837
 838 dnl *** check for GNU non-executable stack note support (ELF only)
 839 dnl     (.section .note.GNU-stack,"",@progbits)
 840
 841 dnl This test doesn't work with "gcc -g" in gcc 4.4 (GHC trac #3889:
 842 dnl     Error: can't resolve `.note.GNU-stack' {.note.GNU-stack section} - `.Ltext0' {.text section}
 843 dnl so we empty CFLAGS while running this test
 844 CFLAGS2="$CFLAGS"
 845 CFLAGS=
 846 AC_MSG_CHECKING(for GNU non-executable stack support)
 847 AC_COMPILE_IFELSE(
 848     [AC_LANG_PROGRAM([__asm__ (".section .note.GNU-stack,\"\",@progbits");], [0])],
 849     [AC_MSG_RESULT(yes)
 850      AC_DEFINE([HAVE_GNU_NONEXEC_STACK],[1],
 851                [Define to 1 if GNU non-executable stack notes are supported.])
 852     ],
 853     [AC_MSG_RESULT(no)])
 854 CFLAGS="$CFLAGS2"
 855
 856 FP_VISIBILITY_HIDDEN
 857
 858 dnl ** check for librt
 859 AC_CHECK_LIB(rt, clock_gettime)
 860 AC_CHECK_FUNCS(clock_gettime timer_create timer_settime)
 861 FP_CHECK_TIMER_CREATE
 862
 863 dnl ** check for Apple's "interesting" long double compatibility scheme
 864 AC_MSG_CHECKING(for printf\$LDBLStub)
 865 AC_TRY_LINK_FUNC(printf\$LDBLStub,
 866     [
 867         AC_MSG_RESULT(yes)
 868         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
 869             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 870     ],
 871     [
 872         AC_MSG_RESULT(no)
 873         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
 874             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 875     ])
 876
 877 dnl ** check for eventfd which is needed by the I/O manager
 878 AC_CHECK_HEADERS([sys/eventfd.h])
 879 AC_CHECK_FUNCS([eventfd])
 880
 881 # test for GTK+
 882 AC_PATH_PROGS([GTK_CONFIG], [pkg-config])
 883 if test -n "$GTK_CONFIG"; then
 884   if $GTK_CONFIG gtk+-2.0 --atleast-version=2.0; then
 885     GTK_CONFIG="$GTK_CONFIG gtk+-2.0"
 886   else
 887     AC_MSG_WARN([GTK+ not usable, need at least version 2.0])
 888     GTK_CONFIG=
 889   fi
 890 fi
 891 AC_SUBST([GTK_CONFIG])
 892
 893 #Checking for PAPI
 894 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
 895 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
 896 AC_SUBST(HavePapiLib)
 897 AC_SUBST(HavePapiHeader)
 898
 899 AC_CHECK_FUNCS(__mingw_vfprintf)
 900
 901 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
 902    HavePapi=YES
 903 else
 904    HavePapi=NO
 905 fi
 906 AC_SUBST(HavePapi)
 907
 908 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
 909    test "$XsltprocCmd" = ""
 910 then
 911     BUILD_DOCBOOK_HTML=NO
 912 else
 913     BUILD_DOCBOOK_HTML=YES
 914 fi
 915 AC_SUBST(BUILD_DOCBOOK_HTML)
 916
 917 if test "$DblatexCmd" = ""
 918 then
 919     BUILD_DOCBOOK_PS=NO
 920     BUILD_DOCBOOK_PDF=NO
 921 else
 922     BUILD_DOCBOOK_PS=YES
 923     BUILD_DOCBOOK_PDF=YES
 924 fi
 925 AC_SUBST(BUILD_DOCBOOK_PS)
 926 AC_SUBST(BUILD_DOCBOOK_PDF)
 927
 928 LIBRARY_VERSION(base)
 929 LIBRARY_VERSION(Cabal)
 930 LIBRARY_VERSION(ghc-prim)
 931 LIBRARY_ghc_VERSION="$ProjectVersion"
 932 AC_SUBST(LIBRARY_ghc_VERSION)
 933
 934 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
 935    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
 936 fi
 937
 938 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal ghc.spec settings docs/users_guide/ug-book.xml docs/users_guide/ug-ent.xml docs/index.html libraries/prologue.txt distrib/ghc.iss distrib/configure.ac])
 939 AC_CONFIG_COMMANDS([mk/stamp-h],[echo timestamp > mk/stamp-h])
 940 AC_OUTPUT
 941
 942 # We get caught by
 943 #     http://savannah.gnu.org/bugs/index.php?1516
 944 #     $(eval ...) inside conditionals causes errors
 945 # with make 3.80, so warn the user if it looks like they're about to
 946 # try to use it.
 947 # We would use "grep -q" here, but Solaris's grep doesn't support it.
 948 checkMake380() {
 949     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
 950     then
 951         echo
 952         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
 953         echo "This version cannot be used to build GHC."
 954         echo "Please use GNU make >= 3.81."
 955     fi
 956 }
 957
 958 checkMake380 make
 959 checkMake380 gmake
 960
 961 echo ["
 962 ----------------------------------------------------------------------
 963 Configure completed successfully.
 964
 965    Building GHC version  : $ProjectVersion
 966
 967    Build platform        : $BuildPlatform
 968    Host platform         : $HostPlatform
 969    Target platform       : $TargetPlatform
 970 "]
 971
 972 if test "$BootingFromHc" = "YES"; then
 973 echo ["\
 974    Bootstrapping from HC files.
 975 "]
 976 else
 977 echo ["\
 978    Bootstrapping using   : $WithGhc
 979       which is version   : $GhcVersion
 980 "]
 981 fi
 982
 983 echo ["\
 984    Using GCC             : $WhatGccIsCalled
 985       which is version   : $GccVersion
 986
 987    ld       : $LdCmd
 988    Happy    : $HappyCmd ($HappyVersion)
 989    Alex     : $AlexCmd ($AlexVersion)
 990    Python   : $PythonCmd
 991    Perl     : $PerlCmd
 992    dblatex  : $DblatexCmd
 993    xsltproc : $XsltprocCmd"]
 994
 995 if test "$HSCOLOUR" = ""; then
 996 echo ["
 997    HsColour was not found; documentation will not contain source links
 998 "]
 999 else
1000 echo ["\
1001    HsColour : $HSCOLOUR
1002 "]
1003 fi
1004
1005 echo ["\
1006    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
1007    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
1008    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
1009
1010 echo ["----------------------------------------------------------------------
1011 "]
1012
1013 echo "\
1014 For a standard build of GHC (fully optimised with profiling), type (g)make.
1015
1016 To make changes to the default build configuration, copy the file
1017 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1018
1019 For more information on how to configure your GHC build, see
1020    http://hackage.haskell.org/trac/ghc/wiki/Building
1021 "