configure.ac

   1 dnl == autoconf source for the Glasgow FP tools ==
   2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
   3 dnl  (or some such) to see the outline of this file)
   4 dnl
   5 #
   6 # (c) The University of Glasgow 1994-2004
   7 #
   8 # Configure script template for GHC
   9 #
  10 # Process with 'autoreconf' to get a working configure script.
  11 #
  12 # For the generated configure script, do "./configure --help" to
  13 # see what flags are available. (Better yet, read the documentation!)
  14 #
  15
  16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [7.1], [glasgow-haskell-bugs@haskell.org], [ghc])
  17
  18 # Set this to YES for a released version, otherwise NO
  19 : ${RELEASE=NO}
  20
  21 # The primary version (e.g. 6.7, 6.6.1) is set in the AC_INIT line
  22 # above.  If this is not a released version, then we will append the
  23 # date to the version number (e.g. 6.7.20070204).  The date is
  24 # constructed by finding the date of the most recent patch in the
  25 # darcs repository.  If this is a source distribution (not a darcs
  26 # checkout), then we ship a file 'VERSION' containing the full version
  27 # when the source distribution was created.
  28
  29 if test ! -f mk/config.h.in; then
  30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
  31    exit 1
  32 fi
  33
  34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
  35
  36 dnl ----------------------------------------------------------
  37 dnl ** Find unixy sort and find commands,
  38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
  39
  40 dnl ** Find find command (for Win32's benefit)
  41 FP_PROG_FIND
  42
  43 dnl ** Find sort command (for the benefit of Win32 environs)
  44 FP_PROG_SORT
  45
  46 dnl ----------------------------------------------------------
  47 FP_SETUP_PROJECT_VERSION
  48
  49 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
  50 AC_SUBST([release], [1])
  51
  52 # First off, a distrib sanity check..
  53 AC_CONFIG_SRCDIR([mk/config.mk.in])
  54
  55 dnl * We require autoconf version 2.52
  56 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
  57 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
  58 AC_PREREQ([2.52])
  59
  60 # -------------------------------------------------------------------------
  61 # Prepare to generate the following header files
  62 #
  63 #
  64 AC_CONFIG_HEADER(mk/config.h)
  65
  66 # No, semi-sadly, we don't do `--srcdir'...
  67 if test x"$srcdir" != 'x.' ; then
  68     echo "This configuration does not support the \`--srcdir' option.."
  69     exit 1
  70 fi
  71
  72 dnl --------------------------------------------------------------
  73 dnl * Project specific configuration options
  74 dnl --------------------------------------------------------------
  75 dnl What follows is a bunch of options that can either be configured
  76 dnl through command line options to the configure script or by
  77 dnl supplying defns in the build tree's mk/build.mk. Having the option to
  78 dnl use either is considered a Feature.
  79
  80 dnl ** What command to use to compile compiler sources ?
  81 dnl --------------------------------------------------------------
  82
  83 AC_ARG_WITH([ghc],
  84 [AC_HELP_STRING([--with-ghc=ARG],
  85   [Use ARG as the path to GHC  [default=autodetect]])],
  86   [WithGhc="$withval"],
  87   [if test "$GHC" = ""; then
  88     AC_PATH_PROG([GHC], [ghc])
  89   fi
  90   WithGhc="$GHC"])
  91
  92 dnl ** Booting from .hc files?
  93 dnl --------------------------------------------------------------
  94 AC_ARG_ENABLE(hc-boot,
  95 [AC_HELP_STRING([--enable-hc-boot],
  96 [Boot the Glasgow Haskell Compiler from intermediate .hc files.
  97  (This option is mostly of interest to porters.) [default=no]])],
  98 [ if test x"$enableval" = x"yes"; then
  99         BootingFromHc=YES
 100   else
 101         BootingFromHc=NO
 102   fi
 103 ],
 104 [BootingFromHc=NO]
 105 )
 106 AC_SUBST(BootingFromHc)
 107
 108 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
 109 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
 110                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
 111         EnableBootstrapWithDevelSnaphost=YES,
 112         EnableBootstrapWithDevelSnaphost=NO
 113 )
 114
 115 if test "$WithGhc" != ""; then
 116   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
 117
 118   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
 119      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
 120   fi
 121
 122   AC_SUBST(GhcVersion)dnl
 123   AC_SUBST(GhcMajVersion)dnl
 124   AC_SUBST(GhcMinVersion)dnl
 125   AC_SUBST(GhcPatchLevel)dnl
 126   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
 127   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
 128   if test $GhcCanonVersion -ge 613; then ghc_ge_613=YES; else ghc_ge_613=NO; fi
 129   AC_SUBST(ghc_ge_613)dnl
 130 fi
 131
 132 dnl ** Must have GHC to build GHC, unless --enable-hc-boot is on
 133 if test "$BootingFromHc" = "NO" -a -d "$srcdir/compiler"; then
 134   if test "$WithGhc" = ""; then
 135      AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 136   fi
 137   FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[6.12],
 138     [AC_MSG_ERROR([GHC version 6.12 or later is required to compile GHC.])])dnl
 139
 140   if test `expr $GhcMinVersion % 2` = "1"; then
 141      if test "$EnableBootstrapWithDevelSnaphost" = "NO"; then
 142         AC_MSG_ERROR([
 143      $WithGhc is a development snapshot of GHC, version $GhcVersion.
 144      Bootstrapping using this version of GHC is not supported, and may not
 145      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
 146      or --with-ghc to specify a different GHC to use.])
 147      fi
 148   fi
 149 fi;
 150
 151 # GHC is passed to Cabal, so we need a native path
 152 if test "${WithGhc}" != ""
 153 then
 154     ghc_host=`"${WithGhc}" +RTS --info | grep 'Host platform' | sed -e 's/.*, "//' -e 's/")//'`
 155
 156     if test "$ghc_host" = "i386-unknown-mingw32"
 157     then
 158         if test "${OSTYPE}" = "msys"
 159         then
 160             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
 161         else
 162             # Canonicalise to <drive>:/path/to/ghc
 163             WithGhc=`cygpath -m "${WithGhc}"`
 164         fi
 165         echo "GHC path canonicalised to: ${WithGhc}"
 166     fi
 167 fi
 168 AC_SUBST([WithGhc])
 169
 170 dnl ** Without optimization some INLINE trickery fails for GHCi
 171 SRC_CC_OPTS="-O"
 172
 173 FP_ICONV
 174 FP_GMP
 175
 176 dnl--------------------------------------------------------------------
 177 dnl * Choose host(/target/build) platform
 178 dnl--------------------------------------------------------------------
 179 dnl If we aren't explicitly told what values to use with configure flags,
 180 dnl we ask the bootstrapping compiler what platform it is for
 181
 182 if test "${WithGhc}" != ""
 183 then
 184         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 185         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 186         if test "$bootstrap_host" != "$bootstrap_target"
 187         then
 188                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
 189         fi
 190 fi
 191
 192 # We have to run these unconditionally, but we may discard their
 193 # results in the following code
 194 AC_CANONICAL_BUILD
 195 AC_CANONICAL_HOST
 196 AC_CANONICAL_TARGET
 197
 198 # If no argument was given for a configuration variable, then discard
 199 # the guessed canonical system and use the configuration of the
 200 # bootstrapping ghc. If an argument was given, map it from gnu format
 201 # to ghc format.
 202 #
 203 # For why we do it this way, see: #3637, #1717, #2951
 204
 205 if test "$build_alias" = ""
 206 then
 207     if test "${WithGhc}" != ""
 208     then
 209         build=$bootstrap_target
 210         echo "Build platform inferred as: $build"
 211     else
 212         echo "Can't work out build platform"
 213         exit 1
 214     fi
 215
 216     BuildArch=`echo "$build" | sed 's/-.*//'`
 217     BuildVendor=`echo "$build" | sed -e 's/.*-\(.*\)-.*/\1/'`
 218     BuildOS=`echo "$build" | sed 's/.*-//'`
 219 else
 220     GHC_CONVERT_CPU([$build_cpu], [BuildArch])
 221     GHC_CONVERT_VENDOR([$build_vendor], [BuildVendor])
 222     GHC_CONVERT_OS([$build_os], [BuildOS])
 223 fi
 224
 225 if test "$host_alias" = ""
 226 then
 227     if test "${WithGhc}" != ""
 228     then
 229         host=$bootstrap_target
 230         echo "Host platform inferred as: $host"
 231     else
 232         echo "Can't work out host platform"
 233         exit 1
 234     fi
 235
 236     HostArch=`echo "$host" | sed 's/-.*//'`
 237     HostVendor=`echo "$host" | sed -e 's/.*-\(.*\)-.*/\1/'`
 238     HostOS=`echo "$host" | sed 's/.*-//'`
 239 else
 240     GHC_CONVERT_CPU([$host_cpu], [HostArch])
 241     GHC_CONVERT_VENDOR([$host_vendor], [HostVendor])
 242     GHC_CONVERT_OS([$host_os], [HostOS])
 243 fi
 244
 245 if test "$target_alias" = ""
 246 then
 247     if test "${WithGhc}" != ""
 248     then
 249         target=$bootstrap_target
 250         echo "Target platform inferred as: $target"
 251     else
 252         echo "Can't work out target platform"
 253         exit 1
 254     fi
 255
 256     TargetArch=`echo "$target" | sed 's/-.*//'`
 257     TargetVendor=`echo "$target" | sed -e 's/.*-\(.*\)-.*/\1/'`
 258     TargetOS=`echo "$target" | sed 's/.*-//'`
 259 else
 260     GHC_CONVERT_CPU([$target_cpu], [TargetArch])
 261     GHC_CONVERT_VENDOR([$target_vendor], [TargetVendor])
 262     GHC_CONVERT_OS([$target_os], [TargetOS])
 263 fi
 264
 265 exeext=''
 266 soext='.so'
 267 case $host in
 268 *-unknown-cygwin32)
 269     AC_MSG_WARN([GHC does not support the Cygwin target at the moment])
 270     AC_MSG_WARN([I'm assuming you wanted to build for i386-unknown-mingw32])
 271     exit 1
 272     ;;
 273 *-unknown-mingw32)
 274     exeext='.exe'
 275     soext='.dll'
 276     ;;
 277 i386-apple-darwin|powerpc-apple-darwin)
 278     soext='.dylib'
 279     ;;
 280 x86_64-apple-darwin)
 281     soext='.dylib'
 282     ;;
 283 esac
 284
 285 # Sync this with cTargetArch in compiler/ghc.mk
 286 checkArch() {
 287     case $1 in
 288     alpha|arm|hppa|hppa1_1|i386|ia64|m68k|mips|mipseb|mipsel|powerpc|powerpc64|rs6000|s390|sparc|sparc64|vax|x86_64)
 289         ;;
 290     *)
 291         echo "Unknown arch $1"
 292         exit 1
 293         ;;
 294     esac
 295 }
 296
 297 checkVendor() {
 298     case $1 in
 299     dec|unknown|hp|apple|next|sun|sgi|ibm)
 300         ;;
 301     *)
 302         echo "Unknown vendor $1"
 303         exit 1
 304         ;;
 305     esac
 306 }
 307
 308 checkOS() {
 309     case $1 in
 310     linux|freebsd|netbsd|openbsd|dragonfly|osf1|osf3|hpux|linuxaout|kfreebsdgnu|freebsd2|solaris2|cygwin32|mingw32|darwin|gnu|nextstep2|nextstep3|sunos4|ultrix|irix|aix|haiku)
 311         ;;
 312     *)
 313         echo "Unknown OS '$1'"
 314         exit 1
 315         ;;
 316     esac
 317 }
 318
 319 BuildPlatform="$BuildArch-$BuildVendor-$BuildOS"
 320 BuildPlatform_CPP=`echo "$BuildPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 321 BuildArch_CPP=`    echo "$BuildArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 322 BuildVendor_CPP=`  echo "$BuildVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 323 BuildOS_CPP=`      echo "$BuildOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 324
 325 checkArch "$BuildArch"
 326 checkVendor "$BuildVendor"
 327 checkOS "$BuildOS"
 328
 329 HostPlatform="$HostArch-$HostVendor-$HostOS"
 330 HostPlatform_CPP=`echo "$HostPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 331 HostArch_CPP=`    echo "$HostArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 332 HostVendor_CPP=`  echo "$HostVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 333 HostOS_CPP=`      echo "$HostOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 334
 335 checkArch "$HostArch"
 336 checkVendor "$HostVendor"
 337 checkOS "$HostOS"
 338
 339 TargetPlatform="$TargetArch-$TargetVendor-$TargetOS"
 340 TargetPlatform_CPP=`echo "$TargetPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 341 TargetArch_CPP=`    echo "$TargetArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 342 TargetVendor_CPP=`  echo "$TargetVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 343 TargetOS_CPP=`      echo "$TargetOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 344
 345 checkArch "$TargetArch"
 346 checkVendor "$TargetVendor"
 347 checkOS "$TargetOS"
 348
 349 # Verify that the installed (bootstrap) GHC is capable of generating
 350 # code for the requested build platform.
 351 if test "$build" != "$bootstrap_target"
 352 then
 353     echo "This GHC (${WithGhc}) does not generate code for the build platform"
 354     echo "   GHC target platform    : $bootstrap_target"
 355     echo "   Desired build platform : $BuildPlatform"
 356     exit 1
 357 fi
 358
 359 AC_SUBST(BuildPlatform)
 360 AC_SUBST(HostPlatform)
 361 AC_SUBST(TargetPlatform)
 362 AC_SUBST(HostPlatform_CPP)
 363 AC_SUBST(BuildPlatform_CPP)
 364 AC_SUBST(TargetPlatform_CPP)
 365
 366 AC_SUBST(HostArch_CPP)
 367 AC_SUBST(BuildArch_CPP)
 368 AC_SUBST(TargetArch_CPP)
 369
 370 AC_SUBST(HostOS_CPP)
 371 AC_SUBST(BuildOS_CPP)
 372 AC_SUBST(TargetOS_CPP)
 373
 374 AC_SUBST(HostVendor_CPP)
 375 AC_SUBST(BuildVendor_CPP)
 376 AC_SUBST(TargetVendor_CPP)
 377
 378 AC_SUBST(exeext)
 379 AC_SUBST(soext)
 380
 381 AC_ARG_WITH(hc,
 382 [AC_HELP_STRING([--with-hc=ARG],
 383         [Use ARG as the path to the compiler for compiling ordinary
 384          Haskell code  (default= value of --with-ghc)])],
 385 [WithHc="$withval"],
 386 [WithHc=$WithGhc]
 387 )
 388 AC_SUBST(WithHc)
 389
 390 # This uses GHC, so put it after the "GHC is required" check above:
 391 FP_INTREE_GHC_PWD
 392 FP_FIND_ROOT
 393
 394 if test "$HostOS" = "mingw32"
 395 then
 396     test -d inplace || mkdir inplace
 397
 398     CC="$hardtop/inplace/mingw/bin/gcc.exe"
 399     LD="$hardtop/inplace/mingw/bin/ld.exe"
 400     NM="$hardtop/inplace/mingw/bin/nm.exe"
 401     fp_prog_ar_raw="$hardtop/inplace/mingw/bin/ar.exe"
 402
 403     # NB. If you update the tarbballs to a new version of gcc, don't
 404     # forget to tweak the paths in driver/gcc/gcc.c.
 405     if ! test -d inplace/mingw ||
 406          test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.lzma  ||
 407          test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.lzma  ||
 408          test inplace/mingw -ot ghc-tarballs/mingw/gcc-c++*.tar.lzma   ||
 409          test inplace/mingw -ot ghc-tarballs/mingw/libgmp*.tar.gz      ||
 410          test inplace/mingw -ot ghc-tarballs/mingw/libmpc*.tar.gz      ||
 411          test inplace/mingw -ot ghc-tarballs/mingw/libmpfr*.tar.gz     ||
 412          test inplace/mingw -ot ghc-tarballs/mingw/libstdc*.tar.lzma   ||
 413          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dev.tar.gz ||
 414          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dll.tar.gz ||
 415          test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.lzma
 416     then
 417         AC_MSG_NOTICE([Making in-tree mingw tree])
 418         rm -rf inplace/mingw
 419         mkdir inplace/mingw
 420         (
 421             cd inplace/mingw &&
 422             tar --lzma -xf ../../ghc-tarballs/mingw/binutils*.tar.lzma  &&
 423             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-core*.tar.lzma  &&
 424             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-c++*.tar.lzma   &&
 425             tar --lzma -xf ../../ghc-tarballs/mingw/libgmp*.tar.lzma    &&
 426             tar --lzma -xf ../../ghc-tarballs/mingw/libmpc*.tar.lzma    &&
 427             tar --lzma -xf ../../ghc-tarballs/mingw/libmpfr*.tar.lzma   &&
 428             tar --lzma -xf ../../ghc-tarballs/mingw/libstdc*.tar.lzma   &&
 429             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dev.tar.gz &&
 430             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dll.tar.gz &&
 431             tar --lzma -xf ../../ghc-tarballs/mingw/w32api*.tar.lzma    &&
 432             mv bin/gcc.exe bin/realgcc.exe
 433         )
 434         PATH=`pwd`/inplace/mingw/bin:$PATH inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
 435         if ! test -e inplace/mingw/bin/gcc.exe
 436         then
 437             AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 438         fi
 439         AC_MSG_NOTICE([In-tree mingw tree created])
 440     fi
 441     if ! test -d inplace/perl ||
 442          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
 443     then
 444         AC_MSG_NOTICE([Making in-tree perl tree])
 445         rm -rf inplace/perl
 446         mkdir inplace
 447         mkdir inplace/perl
 448         (
 449             cd inplace/perl &&
 450             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
 451         )
 452         AC_MSG_NOTICE([In-tree perl tree created])
 453     fi
 454 fi
 455
 456 dnl ** Which gcc to use?
 457 dnl --------------------------------------------------------------
 458 FP_ARG_WITH_PATH_GNU_PROG([CC], [gcc])
 459 export CC
 460 WhatGccIsCalled="$CC"
 461 AC_SUBST(WhatGccIsCalled)
 462
 463 dnl ** Which ld to use?
 464 dnl --------------------------------------------------------------
 465 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld])
 466 LdCmd="$LD"
 467 AC_SUBST([LdCmd])
 468
 469 dnl ** Which nm to use?
 470 dnl --------------------------------------------------------------
 471 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm])
 472 NmCmd="$NM"
 473 AC_SUBST([NmCmd])
 474
 475 dnl ** Mac OS X: explicit deployment target
 476 dnl --------------------------------------------------------------
 477 AC_ARG_WITH([macosx-deployment-target],
 478 [AC_HELP_STRING([--with-macosx-deployment-target=VERSION],
 479         [Build for Mac OS VERSION and higher  (default= version of build host)])],
 480 [FP_MACOSX_DEPLOYMENT_TARGET="$withval"
 481  if test "x$TargetOS_CPP-$TargetVendor_CPP" != "xdarwin-apple"; then
 482    # ignore everywhere, but on Mac OS
 483    AC_MSG_WARN([--macosx-deployment-target is only available on Mac OS X])
 484    FP_MACOSX_DEPLOYMENT_TARGET=none
 485  fi],
 486 [FP_MACOSX_DEPLOYMENT_TARGET=none]
 487 )
 488 FP_CHECK_MACOSX_DEPLOYMENT_TARGET
 489 AC_SUBST(MACOSX_DEPLOYMENT_VERSION)
 490 AC_SUBST(MACOSX_DEPLOYMENT_SDK)
 491
 492 dnl --------------------------------------------------------------
 493 dnl End of configure script option section
 494 dnl --------------------------------------------------------------
 495
 496
 497 dnl --------------------------------------------------------------
 498 dnl * General configuration checks
 499 dnl --------------------------------------------------------------
 500
 501 dnl ** Can the unix package be built?
 502 dnl --------------------------------------------------------------
 503
 504 if test x"$TargetPlatform" = x"i386-unknown-mingw32"; then
 505    GhcLibsWithUnix=NO
 506 else
 507    GhcLibsWithUnix=YES
 508 fi
 509 AC_SUBST([GhcLibsWithUnix])
 510
 511 dnl ** does #! work?
 512 AC_SYS_INTERPRETER()
 513
 514 dnl ** look for `perl'
 515 case $HostOS_CPP in
 516 cygwin32|mingw32)
 517     PerlCmd=$hardtop/inplace/perl/perl
 518     ;;
 519 *)
 520     AC_PATH_PROG(PerlCmd,perl)
 521     if test -z "$PerlCmd"
 522     then
 523         echo "You must install perl before you can continue"
 524         echo "Perhaps it is already installed, but not in your PATH?"
 525         exit 1
 526     else
 527         FPTOOLS_CHECK_PERL_VERSION
 528     fi
 529     ;;
 530 esac
 531
 532 dnl ** does #! path/to/perl work? (sometimes it's too long...)
 533 FPTOOLS_SHEBANG_PERL
 534
 535 dnl ** check for Python
 536 AC_PATH_PROG(PythonCmd,python)
 537
 538 dnl ** look for GCC and find out which version
 539 dnl     Figure out which C compiler to use.  Gcc is preferred.
 540 dnl     If gcc, make sure it's at least 2.1
 541 dnl
 542 FP_HAVE_GCC
 543
 544 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[CPPFLAGS])
 545 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_LD_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
 546 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_LD_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
 547 # Stage 3 won't be supported by cross-compilation
 548 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_LD_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
 549
 550 FP_GCC_EXTRA_FLAGS
 551
 552 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
 553 AC_PROG_CPP
 554
 555 AC_SUBST(CONF_CC_OPTS_STAGE0)
 556 AC_SUBST(CONF_CC_OPTS_STAGE1)
 557 AC_SUBST(CONF_CC_OPTS_STAGE2)
 558 AC_SUBST(CONF_LD_OPTS_STAGE0)
 559 AC_SUBST(CONF_LD_OPTS_STAGE1)
 560 AC_SUBST(CONF_LD_OPTS_STAGE2)
 561 AC_SUBST(CONF_CPP_OPTS_STAGE0)
 562 AC_SUBST(CONF_CPP_OPTS_STAGE1)
 563 AC_SUBST(CONF_CPP_OPTS_STAGE2)
 564
 565 dnl ** figure out how to do context diffs
 566 FP_PROG_CONTEXT_DIFF
 567
 568 dnl Let's make sure install-sh is executable here.  If we got it from
 569 dnl a darcs repo, it might not be (see bug #978).
 570 chmod +x install-sh
 571 dnl ** figure out how to do a BSD-ish install
 572 AC_PROG_INSTALL
 573
 574 dnl If you can run configure, you certainly have /bin/sh
 575 AC_DEFINE([HAVE_BIN_SH], [1], [Define to 1 if you have /bin/sh.])
 576
 577 dnl ** how to invoke `ar' and `ranlib'
 578 FP_PROG_AR_SUPPORTS_ATFILE
 579 FP_PROG_AR_NEEDS_RANLIB
 580 FP_PROG_AR_SUPPORTS_INPUT
 581
 582 dnl ** Check to see whether ln -s works
 583 AC_PROG_LN_S
 584
 585
 586 dnl ** Find the path to sed
 587 AC_PATH_PROGS(SedCmd,gsed sed,sed)
 588
 589
 590 dnl ** check for time command
 591 AC_PATH_PROG(TimeCmd,time)
 592
 593 dnl ** check for tar
 594 dnl   if GNU tar is named gtar, look for it first.
 595 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
 596
 597 dnl ** check for patch
 598 dnl if GNU patch is named gpatch, look for it first
 599 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
 600
 601 dnl ** check for dtrace (currently only implemented for Mac OS X)
 602 HaveDtrace=NO
 603 AC_PATH_PROG(DtraceCmd,dtrace)
 604 if test -n "$DtraceCmd"; then
 605   if test "x$TargetOS_CPP-$TargetVendor_CPP" == "xdarwin-apple"; then
 606     HaveDtrace=YES
 607   fi
 608 fi
 609 AC_SUBST(HaveDtrace)
 610
 611 AC_PATH_PROG(HSCOLOUR,HsColour)
 612 # HsColour is passed to Cabal, so we need a native path
 613 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 614    test "${OSTYPE}"      != "msys"                  && \
 615    test "${HSCOLOUR}"    != ""
 616 then
 617     # Canonicalise to <drive>:/path/to/gcc
 618     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
 619 fi
 620
 621 dnl ** check for DocBook toolchain
 622 FP_CHECK_DOCBOOK_DTD
 623 FP_DOCBOOK_XSL
 624 FP_PROG_DBLATEX
 625
 626 FP_PROG_HSTAGS
 627
 628 dnl ** check for ghc-pkg command
 629 FP_PROG_GHC_PKG
 630
 631 dnl ** check for installed happy binary + version
 632 dnl    (don't do it if we're booting from .hc files though.)
 633 if test "$BootingFromHc" = "NO"; then
 634 FPTOOLS_HAPPY
 635 fi;
 636
 637 dnl ** check for installed alex binary + version
 638 dnl    (don't do it if we're booting from .hc files though.)
 639 if test "$BootingFromHc" = "NO"; then
 640 FPTOOLS_ALEX
 641 fi;
 642
 643 dnl --------------------------------------------------
 644 dnl ### program checking section ends here ###
 645 dnl --------------------------------------------------
 646
 647 dnl --------------------------------------------------
 648 dnl * Platform header file and syscall feature tests
 649 dnl ### checking the state of the local header files and syscalls ###
 650
 651 dnl ** check for full ANSI header (.h) files
 652 AC_HEADER_STDC
 653
 654 dnl ** Enable large file support.  NB. do this before testing the type of
 655 dnl    off_t, because it will affect the result of that test.
 656 AC_SYS_LARGEFILE
 657
 658 dnl ** check for specific header (.h) files that we are interested in
 659 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/cpuset.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
 660
 661 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
 662 AC_HEADER_TIME
 663
 664 dnl ** do we have long longs?
 665 AC_CHECK_TYPES([long long])
 666
 667 dnl ** what are the sizes of various types
 668 AC_CHECK_SIZEOF(char,               1)
 669 AC_CHECK_SIZEOF(double,             8)
 670 AC_CHECK_SIZEOF(float,              4)
 671 AC_CHECK_SIZEOF(int,                4)
 672 AC_CHECK_SIZEOF(long,               4)
 673 if test "$ac_cv_type_long_long" = yes; then
 674 AC_CHECK_SIZEOF(long long,          8)
 675 fi
 676 AC_CHECK_SIZEOF(short,              2)
 677 AC_CHECK_SIZEOF(unsigned char,      1)
 678 AC_CHECK_SIZEOF(unsigned int,       4)
 679 AC_CHECK_SIZEOF(unsigned long,      4)
 680 if test "$ac_cv_type_long_long" = yes; then
 681 AC_CHECK_SIZEOF(unsigned long long, 8)
 682 fi
 683 AC_CHECK_SIZEOF(unsigned short,     2)
 684 AC_CHECK_SIZEOF(void *,             4)
 685
 686 dnl ** what are alignment constraints on various types
 687 FP_CHECK_ALIGNMENT(char)
 688 FP_CHECK_ALIGNMENT(double)
 689 FP_CHECK_ALIGNMENT(float)
 690 FP_CHECK_ALIGNMENT(int)
 691 FP_CHECK_ALIGNMENT(long)
 692 if test "$ac_cv_type_long_long" = yes; then
 693 FP_CHECK_ALIGNMENT(long long)
 694 fi
 695 FP_CHECK_ALIGNMENT(short)
 696 FP_CHECK_ALIGNMENT(unsigned char)
 697 FP_CHECK_ALIGNMENT(unsigned int)
 698 FP_CHECK_ALIGNMENT(unsigned long)
 699 if test "$ac_cv_type_long_long" = yes; then
 700 FP_CHECK_ALIGNMENT(unsigned long long)
 701 fi
 702 FP_CHECK_ALIGNMENT(unsigned short)
 703 FP_CHECK_ALIGNMENT(void *)
 704
 705 FP_CHECK_FUNC([WinExec],
 706   [@%:@include <windows.h>], [WinExec("",0)])
 707
 708 FP_CHECK_FUNC([GetModuleFileName],
 709   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
 710
 711 dnl ** check return type of signal handlers
 712 dnl Foo: assumes we can use prototypes.
 713 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 714 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
 715 dnl [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 716 dnl #include <signal.h>
 717 dnl #ifdef signal
 718 dnl #undef signal
 719 dnl #endif
 720 dnl void (*signal (int, void (*)(int)))(int);
 721 dnl ]],
 722 dnl [[int i;]])],
 723 dnl [ac_cv_type_signal_handler=void_int],
 724 dnl [ac_cv_type_signal_handler=int_void])])
 725 dnl if test "$ac_cv_type_signal_handler" = void_int; then
 726 dnl AC_DEFINE(VOID_INT_SIGNALS)
 727 dnl fi
 728
 729 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 730 AC_TYPE_SIGNAL
 731 if test "$ac_cv_type_signal" = void; then
 732   AC_DEFINE([VOID_INT_SIGNALS], [1], [Define to 1 if signal handlers have type void (*)(int). Otherwise, they're assumed to have type int (*)(void).])
 733 fi
 734
 735 dnl ** check for more functions
 736 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
 737 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
 738
 739 AC_TRY_RUN([
 740 #include <sys/types.h>
 741 #include <sys/time.h>
 742 int main(void) {
 743   struct itimerval tval;
 744   tval.it_value.tv_sec = 1;
 745   tval.it_value.tv_usec = 0;
 746   tval.it_interval = tval.it_value;
 747   return setitimer(ITIMER_VIRTUAL, &tval, (void*)0) != 0;
 748 }
 749 ],[AC_DEFINE([HAVE_SETITIMER_VIRTUAL], [1], [Define to 1 if setitimer accepts ITIMER_VIRTUAL, 0 else.])])
 750
 751 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
 752 dnl ** _POSIX_C_SOURCE is defined
 753 AC_CHECK_DECLS([ctime_r], , ,
 754 [#define _POSIX_SOURCE 1
 755 #define _POSIX_C_SOURCE 199506L
 756 #include <time.h>])
 757
 758 dnl ** check for mingwex library
 759 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
 760 AC_SUBST(HaveLibMingwEx)
 761
 762 if test $HaveLibMingwEx = YES ; then
 763   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
 764 fi
 765
 766 dnl ** check for math library
 767 dnl    Keep that check as early as possible.
 768 dnl    as we need to know whether we need libm
 769 dnl    for math functions or not
 770 dnl    (see http://hackage.haskell.org/trac/ghc/ticket/3730)
 771 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
 772 if test $HaveLibM = YES
 773 then
 774   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
 775 fi
 776
 777 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
 778 dnl    the order of these tests matters: bfd needs liberty
 779 AC_CHECK_LIB(iberty, xmalloc)
 780 AC_CHECK_LIB(bfd,    bfd_init)
 781
 782 dnl ################################################################
 783 dnl Check for libraries
 784 dnl ################################################################
 785
 786 dnl ** check whether we need -ldl to get dlopen()
 787
 788 AC_CHECK_LIB(dl, dlopen,
 789     [HaveLibDL=YES
 790      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
 791      LIBS="$LIBS -ldl"],
 792     [HaveLibDL=NO])
 793 AC_SUBST(HaveLibDL)
 794
 795 dnl --------------------------------------------------
 796 dnl * Miscellaneous feature tests
 797 dnl --------------------------------------------------
 798
 799 dnl ** can we get alloca?
 800 AC_FUNC_ALLOCA
 801
 802 dnl ** Working vfork?
 803 AC_FUNC_FORK
 804
 805 dnl ** determine whether or not const works
 806 AC_C_CONST
 807
 808 dnl ** are we big endian?
 809 AC_C_BIGENDIAN
 810 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
 811
 812 dnl ** check for leading underscores in symbol names
 813 FP_LEADING_UNDERSCORE
 814
 815 dnl ** check for ld, whether it has an -x option, and if it is GNU ld
 816 FP_PROG_LD_X
 817 FP_PROG_LD_IS_GNU
 818
 819 dnl ** check for Apple-style dead-stripping support
 820 dnl    (.subsections-via-symbols assembler directive)
 821
 822
 823 AC_MSG_CHECKING(for .subsections_via_symbols)
 824 AC_COMPILE_IFELSE(
 825     [AC_LANG_PROGRAM([], [__asm__ (".subsections_via_symbols");])],
 826     [AC_MSG_RESULT(yes)
 827      AC_DEFINE([HAVE_SUBSECTIONS_VIA_SYMBOLS],[1],
 828                [Define to 1 if Apple-style dead-stripping is supported.])
 829     ],
 830     [AC_MSG_RESULT(no)])
 831
 832 dnl *** check for GNU non-executable stack note support (ELF only)
 833 dnl     (.section .note.GNU-stack,"",@progbits)
 834
 835 dnl This test doesn't work with "gcc -g" in gcc 4.4 (GHC trac #3889:
 836 dnl     Error: can't resolve `.note.GNU-stack' {.note.GNU-stack section} - `.Ltext0' {.text section}
 837 dnl so we empty CFLAGS while running this test
 838 CFLAGS2="$CFLAGS"
 839 CFLAGS=
 840 AC_MSG_CHECKING(for GNU non-executable stack support)
 841 AC_COMPILE_IFELSE(
 842     [AC_LANG_PROGRAM([__asm__ (".section .note.GNU-stack,\"\",@progbits");], [0])],
 843     [AC_MSG_RESULT(yes)
 844      AC_DEFINE([HAVE_GNU_NONEXEC_STACK],[1],
 845                [Define to 1 if GNU non-executable stack notes are supported.])
 846     ],
 847     [AC_MSG_RESULT(no)])
 848 CFLAGS="$CFLAGS2"
 849
 850 FP_VISIBILITY_HIDDEN
 851
 852 dnl ** check for librt
 853 AC_CHECK_LIB(rt, clock_gettime)
 854 AC_CHECK_FUNCS(clock_gettime timer_create timer_settime)
 855 FP_CHECK_TIMER_CREATE
 856
 857 dnl ** check for Apple's "interesting" long double compatibility scheme
 858 AC_MSG_CHECKING(for printf\$LDBLStub)
 859 AC_TRY_LINK_FUNC(printf\$LDBLStub,
 860     [
 861         AC_MSG_RESULT(yes)
 862         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
 863             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 864     ],
 865     [
 866         AC_MSG_RESULT(no)
 867         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
 868             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 869     ])
 870
 871 dnl ** check for eventfd which is needed by the I/O manager
 872 AC_CHECK_HEADERS([sys/eventfd.h])
 873 AC_CHECK_FUNCS([eventfd])
 874
 875 # test for GTK+
 876 AC_PATH_PROGS([GTK_CONFIG], [pkg-config])
 877 if test -n "$GTK_CONFIG"; then
 878   if $GTK_CONFIG gtk+-2.0 --atleast-version=2.0; then
 879     GTK_CONFIG="$GTK_CONFIG gtk+-2.0"
 880   else
 881     AC_MSG_WARN([GTK+ not usable, need at least version 2.0])
 882     GTK_CONFIG=
 883   fi
 884 fi
 885 AC_SUBST([GTK_CONFIG])
 886
 887 #Checking for PAPI
 888 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
 889 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
 890 AC_SUBST(HavePapiLib)
 891 AC_SUBST(HavePapiHeader)
 892
 893 AC_CHECK_FUNCS(__mingw_vfprintf)
 894
 895 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
 896    HavePapi=YES
 897 else
 898    HavePapi=NO
 899 fi
 900 AC_SUBST(HavePapi)
 901
 902 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
 903    test "$XsltprocCmd" = ""
 904 then
 905     BUILD_DOCBOOK_HTML=NO
 906 else
 907     BUILD_DOCBOOK_HTML=YES
 908 fi
 909 AC_SUBST(BUILD_DOCBOOK_HTML)
 910
 911 if test "$DblatexCmd" = ""
 912 then
 913     BUILD_DOCBOOK_PS=NO
 914     BUILD_DOCBOOK_PDF=NO
 915 else
 916     BUILD_DOCBOOK_PS=YES
 917     BUILD_DOCBOOK_PDF=YES
 918 fi
 919 AC_SUBST(BUILD_DOCBOOK_PS)
 920 AC_SUBST(BUILD_DOCBOOK_PDF)
 921
 922 LIBRARY_VERSION(base)
 923 LIBRARY_VERSION(Cabal)
 924 LIBRARY_VERSION(ghc-prim)
 925 LIBRARY_ghc_VERSION="$ProjectVersion"
 926 AC_SUBST(LIBRARY_ghc_VERSION)
 927
 928 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
 929    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
 930 fi
 931
 932 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal ghc.spec extra-gcc-opts docs/users_guide/ug-book.xml docs/users_guide/ug-ent.xml docs/index.html libraries/prologue.txt distrib/ghc.iss distrib/configure.ac distrib/MacOS/installer-scripts/create-links distrib/MacOS/installer-scripts/Uninstaller distrib/MacOS/GHC-system.pmdoc/index.xml])
 933 AC_CONFIG_COMMANDS([mk/stamp-h],[echo timestamp > mk/stamp-h])
 934 AC_OUTPUT
 935
 936 # We get caught by
 937 #     http://savannah.gnu.org/bugs/index.php?1516
 938 #     $(eval ...) inside conditionals causes errors
 939 # with make 3.80, so warn the user if it looks like they're about to
 940 # try to use it.
 941 # We would use "grep -q" here, but Solaris's grep doesn't support it.
 942 checkMake380() {
 943     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
 944     then
 945         echo
 946         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
 947         echo "This version cannot be used to build GHC."
 948         echo "Please use GNU make >= 3.81."
 949     fi
 950 }
 951
 952 checkMake380 make
 953 checkMake380 gmake
 954
 955 echo ["
 956 ----------------------------------------------------------------------
 957 Configure completed successfully.
 958
 959    Building GHC version  : $ProjectVersion
 960
 961    Build platform        : $BuildPlatform
 962    Host platform         : $HostPlatform
 963    Target platform       : $TargetPlatform
 964 "]
 965
 966 if test "$BootingFromHc" = "YES"; then
 967 echo ["\
 968    Bootstrapping from HC files.
 969 "]
 970 else
 971 echo ["\
 972    Bootstrapping using   : $WithGhc
 973       which is version   : $GhcVersion
 974 "]
 975 fi
 976
 977 echo ["\
 978    Using GCC             : $WhatGccIsCalled
 979       which is version   : $GccVersion
 980
 981    ld       : $LdCmd
 982    Happy    : $HappyCmd ($HappyVersion)
 983    Alex     : $AlexCmd ($AlexVersion)
 984    Python   : $PythonCmd
 985    Perl     : $PerlCmd
 986    dblatex  : $DblatexCmd
 987    xsltproc : $XsltprocCmd"]
 988
 989 if test "$HSCOLOUR" = ""; then
 990 echo ["
 991    HsColour was not found; documentation will not contain source links
 992 "]
 993 else
 994 echo ["\
 995    HsColour : $HSCOLOUR
 996 "]
 997 fi
 998
 999 echo ["\
1000    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
1001    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
1002    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
1003
1004 echo ["----------------------------------------------------------------------
1005 "]
1006
1007 echo "\
1008 For a standard build of GHC (fully optimised with profiling), type (g)make.
1009
1010 To make changes to the default build configuration, copy the file
1011 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1012
1013 For more information on how to configure your GHC build, see
1014    http://hackage.haskell.org/trac/ghc/wiki/Building
1015 "